virtualshelves/sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw( encode );
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Auth;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Output;
  34 use C4::VirtualShelves;
  35 use Koha::Email;
  36
  37 my $query = new CGI;
  38
  39 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  40     {
  41         template_name   => "virtualshelves/sendshelfform.tt",
  42         query           => $query,
  43         type            => "intranet",
  44         authnotrequired => 0,
  45         flagsrequired   => { catalogue => 1 },
  46     }
  47 );
  48
  49 my $shelfid = $query->param('shelfid');
  50 my $email   = $query->param('email');
  51
  52 my $dbh = C4::Context->dbh;
  53
  54 if ($email) {
  55     my $comment = $query->param('comment');
  56     my $message = Koha::Email->new();
  57     my %mail    = $message->create_message_headers(
  58         {
  59             to => $email
  60         }
  61     );
  62
  63     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  64         {
  65         template_name   => "virtualshelves/sendshelf.tt",
  66         query           => $query,
  67         type            => "intranet",
  68         authnotrequired => 0,
  69         flagsrequired   => { catalogue => 1 },
  70         }
  71     );
  72
  73     my @shelf = GetShelf($shelfid);
  74     my ( $items, $totitems ) = GetShelfContents($shelfid);
  75     my $marcflavour = C4::Context->preference('marcflavour');
  76     my $iso2709;
  77     my @results;
  78
  79     # retrieve biblios from shelf
  80     foreach my $biblio (@$items) {
  81         my $biblionumber     = $biblio->{biblionumber};
  82         my $fw               = GetFrameworkCode($biblionumber);
  83         my $dat              = GetBiblioData($biblionumber);
  84         my $record           = GetMarcBiblio($biblionumber, 1);
  85         my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
  86         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  87         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  88         my $subtitle         = GetRecordValue( 'subtitle', $record, $fw );
  89
  90         my @items = GetItemsInfo($biblionumber);
  91
  92         $dat->{MARCNOTES}      = $marcnotesarray;
  93         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  94         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  95         $dat->{'biblionumber'} = $biblionumber;
  96         $dat->{ITEM_RESULTS}   = \@items;
  97         $dat->{subtitle}       = $subtitle;
  98
  99         $iso2709 .= $record->as_usmarc();
 100
 101         push( @results, $dat );
 102     }
 103
 104     if ( C4::Context->preference('OPACBaseURL') ) {
 105         $template2->param(
 106             OPACBaseURL => C4::Context->preference('OPACBaseURL') );
 107     }
 108
 109     $template2->param(
 110         BIBLIO_RESULTS => \@results,
 111         email_sender   => $mail{'from'},
 112         comment        => $comment,
 113         shelfname      => $shelf[1],
 114     );
 115
 116     # Getting template result
 117     my $template_res = $template2->output();
 118     my $body;
 119
 120     # Analysing information and getting mail properties
 121     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 122         $mail{'subject'} = Encode::encode("UTF-8", $1);
 123         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 124     }
 125     else { $mail{'subject'} = "no subject"; }
 126
 127     my $email_header = "";
 128     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 129         $email_header = $1;
 130         $email_header =~ s|\n?(.*)\n?|$1|;
 131         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 132     }
 133
 134     my $email_file = "list.txt";
 135     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 136         $email_file = $1;
 137         $email_file =~ s|\n?(.*)\n?|$1|;
 138     }
 139
 140     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 141         $body = $1;
 142         $body =~ s|\n?(.*)\n?|$1|;
 143         $body = encode_qp(Encode::encode("UTF-8", $body));
 144     }
 145
 146     my $boundary = "====" . time() . "====";
 147
 148     # We set and put the multipart content
 149     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 150
 151     my $isofile = encode_base64( encode( "UTF-8", $iso2709 ) );
 152     $boundary = '--' . $boundary;
 153
 154     $mail{body} = <<END_OF_BODY;
 155 $boundary
 156 Content-Type: text/plain; charset="utf-8"
 157 Content-Transfer-Encoding: quoted-printable
 158
 159 $email_header
 160 $body
 161 $boundary
 162 Content-Type: application/octet-stream; name="shelf.iso2709"
 163 Content-Transfer-Encoding: base64
 164 Content-Disposition: attachment; filename="shelf.iso2709"
 165
 166 $isofile
 167 $boundary--
 168 END_OF_BODY
 169
 170     # Sending mail
 171     if ( sendmail %mail ) {
 172
 173         # do something if it works....
 174         $template->param( SENT => "1" );
 175     }
 176     else {
 177         # do something if it doesnt work....
 178         carp "Error sending mail: $Mail::Sendmail::error \n";
 179         $template->param( error => 1 );
 180     }
 181
 182     $template->param( email => $email );
 183     output_html_with_http_headers $query, $cookie, $template->output;
 184
 185 }
 186 else {
 187     $template->param(
 188         shelfid => $shelfid,
 189         url     => "/cgi-bin/koha/virtualshelves/sendshelf.pl",
 190     );
 191     output_html_with_http_headers $query, $cookie, $template->output;
 192 }