C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use Encode;
 101 use ZOOM;
 102 use XML::Simple;
 103 use Koha::Cache;
 104 use POSIX ();
 105 use DateTime::TimeZone;
 106 use Module::Load::Conditional qw(can_load);
 107 use Carp;
 108
 109 use C4::Boolean;
 110 use C4::Debug;
 111 use Koha;
 112 use Koha::Config::SysPref;
 113 use Koha::Config::SysPrefs;
 114
 115 =head1 NAME
 116
 117 C4::Context - Maintain and manipulate the context of a Koha script
 118
 119 =head1 SYNOPSIS
 120
 121   use C4::Context;
 122
 123   use C4::Context("/path/to/koha-conf.xml");
 124
 125   $config_value = C4::Context->config("config_variable");
 126
 127   $koha_preference = C4::Context->preference("preference");
 128
 129   $db_handle = C4::Context->dbh;
 130
 131   $Zconn = C4::Context->Zconn;
 132
 133 =head1 DESCRIPTION
 134
 135 When a Koha script runs, it makes use of a certain number of things:
 136 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 137 databases, and so forth. These things make up the I<context> in which
 138 the script runs.
 139
 140 This module takes care of setting up the context for a script:
 141 figuring out which configuration file to load, and loading it, opening
 142 a connection to the right database, and so forth.
 143
 144 Most scripts will only use one context. They can simply have
 145
 146   use C4::Context;
 147
 148 at the top.
 149
 150 Other scripts may need to use several contexts. For instance, if a
 151 library has two databases, one for a certain collection, and the other
 152 for everything else, it might be necessary for a script to use two
 153 different contexts to search both databases. Such scripts should use
 154 the C<&set_context> and C<&restore_context> functions, below.
 155
 156 By default, C4::Context reads the configuration from
 157 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 158 environment variable to the pathname of a configuration file to use.
 159
 160 =head1 METHODS
 161
 162 =cut
 163
 164 #'
 165 # In addition to what is said in the POD above, a Context object is a
 166 # reference-to-hash with the following fields:
 167 #
 168 # config
 169 #    A reference-to-hash whose keys and values are the
 170 #    configuration variables and values specified in the config
 171 #    file (/etc/koha/koha-conf.xml).
 172 # dbh
 173 #    A handle to the appropriate database for this context.
 174 # dbh_stack
 175 #    Used by &set_dbh and &restore_dbh to hold other database
 176 #    handles for this context.
 177 # Zconn
 178 #     A connection object for the Zebra server
 179
 180 # Koha's main configuration file koha-conf.xml
 181 # is searched for according to this priority list:
 182 #
 183 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 184 # 2. Path supplied in KOHA_CONF environment variable.
 185 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 186 #    as value has changed from its default of
 187 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 188 #    when Koha is installed in 'standard' or 'single'
 189 #    mode.
 190 # 4. Path supplied in CONFIG_FNAME.
 191 #
 192 # The first entry that refers to a readable file is used.
 193
 194 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 195                 # Default config file, if none is specified
 196
 197 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 198                 # path to config file set by installer
 199                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 200                 # when Koha is installed in 'standard' or 'single'
 201                 # mode.  If Koha was installed in 'dev' mode,
 202                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 203                 # developers should set the KOHA_CONF environment variable
 204
 205 $context = undef;        # Initially, no context is set
 206 @context_stack = ();        # Initially, no saved contexts
 207
 208
 209 =head2 read_config_file
 210
 211 Reads the specified Koha config file.
 212
 213 Returns an object containing the configuration variables. The object's
 214 structure is a bit complex to the uninitiated ... take a look at the
 215 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 216 here are a few examples that may give you what you need:
 217
 218 The simple elements nested within the <config> element:
 219
 220     my $pass = $koha->{'config'}->{'pass'};
 221
 222 The <listen> elements:
 223
 224     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 225
 226 The elements nested within the <server> element:
 227
 228     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 229
 230 Returns undef in case of error.
 231
 232 =cut
 233
 234 sub read_config_file {          # Pass argument naming config file to read
 235     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 236
 237     if ($ismemcached) {
 238       $memcached->set('kohaconf',$koha);
 239     }
 240
 241     return $koha;                       # Return value: ref-to-hash holding the configuration
 242 }
 243
 244 =head2 ismemcached
 245
 246 Returns the value of the $ismemcached variable (0/1)
 247
 248 =cut
 249
 250 sub ismemcached {
 251     return $ismemcached;
 252 }
 253
 254 =head2 memcached
 255
 256 If $ismemcached is true, returns the $memcache variable.
 257 Returns undef otherwise
 258
 259 =cut
 260
 261 sub memcached {
 262     if ($ismemcached) {
 263       return $memcached;
 264     } else {
 265       return;
 266     }
 267 }
 268
 269 =head2 db_scheme2dbi
 270
 271     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 272
 273 This routines translates a database type to part of the name
 274 of the appropriate DBD driver to use when establishing a new
 275 database connection.  It recognizes 'mysql' and 'Pg'; if any
 276 other scheme is supplied it defaults to 'mysql'.
 277
 278 =cut
 279
 280 sub db_scheme2dbi {
 281     my $scheme = shift // '';
 282     return $scheme eq 'Pg' ? $scheme : 'mysql';
 283 }
 284
 285 sub import {
 286     # Create the default context ($C4::Context::Context)
 287     # the first time the module is called
 288     # (a config file can be optionaly passed)
 289
 290     # default context already exists?
 291     return if $context;
 292
 293     # no ? so load it!
 294     my ($pkg,$config_file) = @_ ;
 295     my $new_ctx = __PACKAGE__->new($config_file);
 296     return unless $new_ctx;
 297
 298     # if successfully loaded, use it by default
 299     $new_ctx->set_context;
 300     1;
 301 }
 302
 303 =head2 new
 304
 305   $context = new C4::Context;
 306   $context = new C4::Context("/path/to/koha-conf.xml");
 307
 308 Allocates a new context. Initializes the context from the specified
 309 file, which defaults to either the file given by the C<$KOHA_CONF>
 310 environment variable, or F</etc/koha/koha-conf.xml>.
 311
 312 It saves the koha-conf.xml values in the declared memcached server(s)
 313 if currently available and uses those values until them expire and
 314 re-reads them.
 315
 316 C<&new> does not set this context as the new default context; for
 317 that, use C<&set_context>.
 318
 319 =cut
 320
 321 #'
 322 # Revision History:
 323 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 324 sub new {
 325     my $class = shift;
 326     my $conf_fname = shift;        # Config file to load
 327     my $self = {};
 328
 329     # check that the specified config file exists and is not empty
 330     undef $conf_fname unless
 331         (defined $conf_fname && -s $conf_fname);
 332     # Figure out a good config file to load if none was specified.
 333     if (!defined($conf_fname))
 334     {
 335         # If the $KOHA_CONF environment variable is set, use
 336         # that. Otherwise, use the built-in default.
 337         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 338             $conf_fname = $ENV{"KOHA_CONF"};
 339         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 340             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 341             # regex to anything else -- don't want installer to rewrite it
 342             $conf_fname = $INSTALLED_CONFIG_FNAME;
 343         } elsif (-s CONFIG_FNAME) {
 344             $conf_fname = CONFIG_FNAME;
 345         } else {
 346             warn "unable to locate Koha configuration file koha-conf.xml";
 347             return;
 348         }
 349     }
 350
 351     if ($ismemcached) {
 352         # retrieve from memcached
 353         $self = $memcached->get('kohaconf');
 354         if (not defined $self) {
 355             # not in memcached yet
 356             $self = read_config_file($conf_fname);
 357         }
 358     } else {
 359         # non-memcached env, read from file
 360         $self = read_config_file($conf_fname);
 361     }
 362
 363     $self->{"config_file"} = $conf_fname;
 364     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 365     return if !defined($self->{"config"});
 366
 367     $self->{"Zconn"} = undef;    # Zebra Connections
 368     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 369     $self->{"userenv"} = undef;        # User env
 370     $self->{"activeuser"} = undef;        # current active user
 371     $self->{"shelves"} = undef;
 372     $self->{tz} = undef; # local timezone object
 373
 374     bless $self, $class;
 375     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 376     return $self;
 377 }
 378
 379 =head2 set_context
 380
 381   $context = new C4::Context;
 382   $context->set_context();
 383 or
 384   set_context C4::Context $context;
 385
 386   ...
 387   restore_context C4::Context;
 388
 389 In some cases, it might be necessary for a script to use multiple
 390 contexts. C<&set_context> saves the current context on a stack, then
 391 sets the context to C<$context>, which will be used in future
 392 operations. To restore the previous context, use C<&restore_context>.
 393
 394 =cut
 395
 396 #'
 397 sub set_context
 398 {
 399     my $self = shift;
 400     my $new_context;    # The context to set
 401
 402     # Figure out whether this is a class or instance method call.
 403     #
 404     # We're going to make the assumption that control got here
 405     # through valid means, i.e., that the caller used an instance
 406     # or class method call, and that control got here through the
 407     # usual inheritance mechanisms. The caller can, of course,
 408     # break this assumption by playing silly buggers, but that's
 409     # harder to do than doing it properly, and harder to check
 410     # for.
 411     if (ref($self) eq "")
 412     {
 413         # Class method. The new context is the next argument.
 414         $new_context = shift;
 415     } else {
 416         # Instance method. The new context is $self.
 417         $new_context = $self;
 418     }
 419
 420     # Save the old context, if any, on the stack
 421     push @context_stack, $context if defined($context);
 422
 423     # Set the new context
 424     $context = $new_context;
 425 }
 426
 427 =head2 restore_context
 428
 429   &restore_context;
 430
 431 Restores the context set by C<&set_context>.
 432
 433 =cut
 434
 435 #'
 436 sub restore_context
 437 {
 438     my $self = shift;
 439
 440     if ($#context_stack < 0)
 441     {
 442         # Stack underflow.
 443         die "Context stack underflow";
 444     }
 445
 446     # Pop the old context and set it.
 447     $context = pop @context_stack;
 448
 449     # FIXME - Should this return something, like maybe the context
 450     # that was current when this was called?
 451 }
 452
 453 =head2 config
 454
 455   $value = C4::Context->config("config_variable");
 456
 457   $value = C4::Context->config_variable;
 458
 459 Returns the value of a variable specified in the configuration file
 460 from which the current context was created.
 461
 462 The second form is more compact, but of course may conflict with
 463 method names. If there is a configuration variable called "new", then
 464 C<C4::Config-E<gt>new> will not return it.
 465
 466 =cut
 467
 468 sub _common_config {
 469         my $var = shift;
 470         my $term = shift;
 471     return if !defined($context->{$term});
 472        # Presumably $self->{$term} might be
 473        # undefined if the config file given to &new
 474        # didn't exist, and the caller didn't bother
 475        # to check the return value.
 476
 477     # Return the value of the requested config variable
 478     return $context->{$term}->{$var};
 479 }
 480
 481 sub config {
 482         return _common_config($_[1],'config');
 483 }
 484 sub zebraconfig {
 485         return _common_config($_[1],'server');
 486 }
 487 sub ModZebrations {
 488         return _common_config($_[1],'serverinfo');
 489 }
 490
 491 =head2 preference
 492
 493   $sys_preference = C4::Context->preference('some_variable');
 494
 495 Looks up the value of the given system preference in the
 496 systempreferences table of the Koha database, and returns it. If the
 497 variable is not set or does not exist, undef is returned.
 498
 499 In case of an error, this may return 0.
 500
 501 Note: It is impossible to tell the difference between system
 502 preferences which do not exist, and those whose values are set to NULL
 503 with this method.
 504
 505 =cut
 506
 507 my $syspref_cache = Koha::Cache->get_instance();
 508 my %syspref_L1_cache;
 509 my $use_syspref_cache = 1;
 510 sub preference {
 511     my $self = shift;
 512     my $var  = shift;    # The system preference to return
 513
 514     $var = lc $var;
 515
 516     # Return the value if the var has already been accessed
 517     if ($use_syspref_cache && exists $syspref_L1_cache{$var}) {
 518         return $syspref_L1_cache{$var};
 519     }
 520
 521     my $cached_var = $use_syspref_cache
 522         ? $syspref_cache->get_from_cache("syspref_$var")
 523         : undef;
 524     return $cached_var if defined $cached_var;
 525
 526     my $value;
 527     if ( defined $ENV{"OVERRIDE_SYSPREF_$var"} ) {
 528         $value = $ENV{"OVERRIDE_SYSPREF_$var"};
 529     } else {
 530         my $syspref;
 531         eval { $syspref = Koha::Config::SysPrefs->find( lc $var ) };
 532         $value = $syspref ? $syspref->value() : undef;
 533     }
 534
 535     if ( $use_syspref_cache ) {
 536         $syspref_cache->set_in_cache("syspref_$var", $value);
 537         $syspref_L1_cache{$var} = $value;
 538     }
 539     return $value;
 540 }
 541
 542 sub boolean_preference {
 543     my $self = shift;
 544     my $var = shift;        # The system preference to return
 545     my $it = preference($self, $var);
 546     return defined($it)? C4::Boolean::true_p($it): undef;
 547 }
 548
 549 =head2 enable_syspref_cache
 550
 551   C4::Context->enable_syspref_cache();
 552
 553 Enable the in-memory syspref cache used by C4::Context. This is the
 554 default behavior.
 555
 556 =cut
 557
 558 sub enable_syspref_cache {
 559     my ($self) = @_;
 560     $use_syspref_cache = 1;
 561     # We need to clear the cache to have it up-to-date
 562     $self->clear_syspref_cache();
 563 }
 564
 565 =head2 disable_syspref_cache
 566
 567   C4::Context->disable_syspref_cache();
 568
 569 Disable the in-memory syspref cache used by C4::Context. This should be
 570 used with Plack and other persistent environments.
 571
 572 =cut
 573
 574 sub disable_syspref_cache {
 575     my ($self) = @_;
 576     $use_syspref_cache = 0;
 577     $self->clear_syspref_cache();
 578 }
 579
 580 =head2 clear_syspref_cache
 581
 582   C4::Context->clear_syspref_cache();
 583
 584 cleans the internal cache of sysprefs. Please call this method if
 585 you update the systempreferences table. Otherwise, your new changes
 586 will not be seen by this process.
 587
 588 =cut
 589
 590 sub clear_syspref_cache {
 591     return unless $use_syspref_cache;
 592     $syspref_cache->flush_all;
 593     clear_syspref_L1_cache()
 594 }
 595
 596 sub clear_syspref_L1_cache {
 597     %syspref_L1_cache = ();
 598 }
 599
 600 =head2 set_preference
 601
 602   C4::Context->set_preference( $variable, $value, [ $explanation, $type, $options ] );
 603
 604 This updates a preference's value both in the systempreferences table and in
 605 the sysprefs cache. If the optional parameters are provided, then the query
 606 becomes a create. It won't update the parameters (except value) for an existing
 607 preference.
 608
 609 =cut
 610
 611 sub set_preference {
 612     my ( $self, $variable, $value, $explanation, $type, $options ) = @_;
 613
 614     $variable = lc $variable;
 615
 616     my $syspref = Koha::Config::SysPrefs->find($variable);
 617     $type =
 618         $type    ? $type
 619       : $syspref ? $syspref->type
 620       :            undef;
 621
 622     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 623
 624     # force explicit protocol on OPACBaseURL
 625     if ( $variable eq 'opacbaseurl' && substr( $value, 0, 4 ) !~ /http/ ) {
 626         $value = 'http://' . $value;
 627     }
 628
 629     if ($syspref) {
 630         $syspref->set(
 631             {   ( defined $value ? ( value       => $value )       : () ),
 632                 ( $explanation   ? ( explanation => $explanation ) : () ),
 633                 ( $type          ? ( type        => $type )        : () ),
 634                 ( $options       ? ( options     => $options )     : () ),
 635             }
 636         )->store;
 637     } else {
 638         $syspref = Koha::Config::SysPref->new(
 639             {   variable    => $variable,
 640                 value       => $value,
 641                 explanation => $explanation || undef,
 642                 type        => $type,
 643                 options     => $options || undef,
 644             }
 645         )->store();
 646     }
 647
 648     if ( $use_syspref_cache ) {
 649         $syspref_cache->set_in_cache( "syspref_$variable", $value );
 650         $syspref_L1_cache{$variable} = $value;
 651     }
 652
 653     return $syspref;
 654 }
 655
 656 =head2 delete_preference
 657
 658     C4::Context->delete_preference( $variable );
 659
 660 This deletes a system preference from the database. Returns a true value on
 661 success. Failure means there was an issue with the database, not that there
 662 was no syspref of the name.
 663
 664 =cut
 665
 666 sub delete_preference {
 667     my ( $self, $var ) = @_;
 668
 669     if ( Koha::Config::SysPrefs->find( $var )->delete ) {
 670         if ( $use_syspref_cache ) {
 671             $syspref_cache->clear_from_cache("syspref_$var");
 672             delete $syspref_L1_cache{$var};
 673         }
 674
 675         return 1;
 676     }
 677     return 0;
 678 }
 679
 680 =head2 Zconn
 681
 682   $Zconn = C4::Context->Zconn
 683
 684 Returns a connection to the Zebra database
 685
 686 C<$self>
 687
 688 C<$server> one of the servers defined in the koha-conf.xml file
 689
 690 C<$async> whether this is a asynchronous connection
 691
 692 =cut
 693
 694 sub Zconn {
 695     my ($self, $server, $async ) = @_;
 696     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 697     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 698         # if we are running the script from the commandline, lets try to use the caching
 699         return $context->{"Zconn"}->{$cache_key};
 700     }
 701     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 702     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 703     return $context->{"Zconn"}->{$cache_key};
 704 }
 705
 706 =head2 _new_Zconn
 707
 708 $context->{"Zconn"} = &_new_Zconn($server,$async);
 709
 710 Internal function. Creates a new database connection from the data given in the current context and returns it.
 711
 712 C<$server> one of the servers defined in the koha-conf.xml file
 713
 714 C<$async> whether this is a asynchronous connection
 715
 716 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 717
 718 =cut
 719
 720 sub _new_Zconn {
 721     my ( $server, $async ) = @_;
 722
 723     my $tried=0; # first attempt
 724     my $Zconn; # connection object
 725     my $elementSetName;
 726     my $index_mode;
 727     my $syntax;
 728
 729     $server //= "biblioserver";
 730
 731     if ( $server eq 'biblioserver' ) {
 732         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'dom';
 733     } elsif ( $server eq 'authorityserver' ) {
 734         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 735     }
 736
 737     if ( $index_mode eq 'grs1' ) {
 738         $elementSetName = 'F';
 739         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 740                 ? 'unimarc'
 741                 : 'usmarc';
 742
 743     } else { # $index_mode eq 'dom'
 744         $syntax = 'xml';
 745         $elementSetName = 'marcxml';
 746     }
 747
 748     my $host = $context->{'listen'}->{$server}->{'content'};
 749     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 750     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 751     eval {
 752         # set options
 753         my $o = new ZOOM::Options();
 754         $o->option(user => $user) if $user && $password;
 755         $o->option(password => $password) if $user && $password;
 756         $o->option(async => 1) if $async;
 757         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 758         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 759         $o->option(preferredRecordSyntax => $syntax);
 760         $o->option(elementSetName => $elementSetName) if $elementSetName;
 761         $o->option(databaseName => $context->{"config"}->{$server}||"biblios");
 762
 763         # create a new connection object
 764         $Zconn= create ZOOM::Connection($o);
 765
 766         # forge to server
 767         $Zconn->connect($host, 0);
 768
 769         # check for errors and warn
 770         if ($Zconn->errcode() !=0) {
 771             warn "something wrong with the connection: ". $Zconn->errmsg();
 772         }
 773     };
 774     return $Zconn;
 775 }
 776
 777 # _new_dbh
 778 # Internal helper function (not a method!). This creates a new
 779 # database connection from the data given in the current context, and
 780 # returns it.
 781 sub _new_dbh
 782 {
 783
 784     Koha::Database->schema({ new => 1 })->storage->dbh;
 785 }
 786
 787 =head2 dbh
 788
 789   $dbh = C4::Context->dbh;
 790
 791 Returns a database handle connected to the Koha database for the
 792 current context. If no connection has yet been made, this method
 793 creates one, and connects to the database.
 794
 795 This database handle is cached for future use: if you call
 796 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 797 times. If you need a second database handle, use C<&new_dbh> and
 798 possibly C<&set_dbh>.
 799
 800 =cut
 801
 802 #'
 803 sub dbh
 804 {
 805     my $self = shift;
 806     my $params = shift;
 807     my $sth;
 808
 809     unless ( $params->{new} ) {
 810         return Koha::Database->schema->storage->dbh;
 811     }
 812
 813     return Koha::Database->schema({ new => 1 })->storage->dbh;
 814 }
 815
 816 =head2 new_dbh
 817
 818   $dbh = C4::Context->new_dbh;
 819
 820 Creates a new connection to the Koha database for the current context,
 821 and returns the database handle (a C<DBI::db> object).
 822
 823 The handle is not saved anywhere: this method is strictly a
 824 convenience function; the point is that it knows which database to
 825 connect to so that the caller doesn't have to know.
 826
 827 =cut
 828
 829 #'
 830 sub new_dbh
 831 {
 832     my $self = shift;
 833
 834     return &dbh({ new => 1 });
 835 }
 836
 837 =head2 set_dbh
 838
 839   $my_dbh = C4::Connect->new_dbh;
 840   C4::Connect->set_dbh($my_dbh);
 841   ...
 842   C4::Connect->restore_dbh;
 843
 844 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 845 C<&set_context> and C<&restore_context>.
 846
 847 C<&set_dbh> saves the current database handle on a stack, then sets
 848 the current database handle to C<$my_dbh>.
 849
 850 C<$my_dbh> is assumed to be a good database handle.
 851
 852 =cut
 853
 854 #'
 855 sub set_dbh
 856 {
 857     my $self = shift;
 858     my $new_dbh = shift;
 859
 860     # Save the current database handle on the handle stack.
 861     # We assume that $new_dbh is all good: if the caller wants to
 862     # screw himself by passing an invalid handle, that's fine by
 863     # us.
 864     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 865     $context->{"dbh"} = $new_dbh;
 866 }
 867
 868 =head2 restore_dbh
 869
 870   C4::Context->restore_dbh;
 871
 872 Restores the database handle saved by an earlier call to
 873 C<C4::Context-E<gt>set_dbh>.
 874
 875 =cut
 876
 877 #'
 878 sub restore_dbh
 879 {
 880     my $self = shift;
 881
 882     if ($#{$context->{"dbh_stack"}} < 0)
 883     {
 884         # Stack underflow
 885         die "DBH stack underflow";
 886     }
 887
 888     # Pop the old database handle and set it.
 889     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 890
 891     # FIXME - If it is determined that restore_context should
 892     # return something, then this function should, too.
 893 }
 894
 895 =head2 queryparser
 896
 897   $queryparser = C4::Context->queryparser
 898
 899 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 900
 901 =cut
 902
 903 sub queryparser {
 904     my $self = shift;
 905     unless (defined $context->{"queryparser"}) {
 906         $context->{"queryparser"} = &_new_queryparser();
 907     }
 908
 909     return
 910       defined( $context->{"queryparser"} )
 911       ? $context->{"queryparser"}->new
 912       : undef;
 913 }
 914
 915 =head2 _new_queryparser
 916
 917 Internal helper function to create a new QueryParser object. QueryParser
 918 is loaded dynamically so as to keep the lack of the QueryParser library from
 919 getting in anyone's way.
 920
 921 =cut
 922
 923 sub _new_queryparser {
 924     my $qpmodules = {
 925         'OpenILS::QueryParser'           => undef,
 926         'Koha::QueryParser::Driver::PQF' => undef
 927     };
 928     if ( can_load( 'modules' => $qpmodules ) ) {
 929         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 930         my $config_file = $context->config('queryparser_config');
 931         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 932         if ( $QParser->load_config($config_file) ) {
 933             # Set 'keyword' as the default search class
 934             $QParser->default_search_class('keyword');
 935             # TODO: allow indexes to be configured in the database
 936             return $QParser;
 937         }
 938     }
 939     return;
 940 }
 941
 942 =head2 marcfromkohafield
 943
 944   $dbh = C4::Context->marcfromkohafield;
 945
 946 Returns a hash with marcfromkohafield.
 947
 948 This hash is cached for future use: if you call
 949 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
 950
 951 =cut
 952
 953 #'
 954 sub marcfromkohafield
 955 {
 956     my $retval = {};
 957
 958     # If the hash already exists, return it.
 959     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
 960
 961     # No hash. Create one.
 962     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
 963
 964     return $context->{"marcfromkohafield"};
 965 }
 966
 967 # _new_marcfromkohafield
 968 sub _new_marcfromkohafield
 969 {
 970     my $dbh = C4::Context->dbh;
 971     my $marcfromkohafield;
 972     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
 973     $sth->execute;
 974     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
 975         my $retval = {};
 976         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
 977     }
 978     return $marcfromkohafield;
 979 }
 980
 981 =head2 userenv
 982
 983   C4::Context->userenv;
 984
 985 Retrieves a hash for user environment variables.
 986
 987 This hash shall be cached for future use: if you call
 988 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 989
 990 =cut
 991
 992 #'
 993 sub userenv {
 994     my $var = $context->{"activeuser"};
 995     if (defined $var and defined $context->{"userenv"}->{$var}) {
 996         return $context->{"userenv"}->{$var};
 997     } else {
 998         return;
 999     }
1000 }
1001
1002 =head2 set_userenv
1003
1004   C4::Context->set_userenv($usernum, $userid, $usercnum,
1005                            $userfirstname, $usersurname,
1006                            $userbranch, $branchname, $userflags,
1007                            $emailaddress, $branchprinter, $persona);
1008
1009 Establish a hash of user environment variables.
1010
1011 set_userenv is called in Auth.pm
1012
1013 =cut
1014
1015 #'
1016 sub set_userenv {
1017     shift @_;
1018     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona, $shibboleth)=
1019     map { Encode::is_utf8( $_ ) ? $_ : Encode::decode('UTF-8', $_) } # CGI::Session doesn't handle utf-8, so we decode it here
1020     @_;
1021     my $var=$context->{"activeuser"} || '';
1022     my $cell = {
1023         "number"     => $usernum,
1024         "id"         => $userid,
1025         "cardnumber" => $usercnum,
1026         "firstname"  => $userfirstname,
1027         "surname"    => $usersurname,
1028         #possibly a law problem
1029         "branch"     => $userbranch,
1030         "branchname" => $branchname,
1031         "flags"      => $userflags,
1032         "emailaddress"     => $emailaddress,
1033         "branchprinter"    => $branchprinter,
1034         "persona"    => $persona,
1035         "shibboleth" => $shibboleth,
1036     };
1037     $context->{userenv}->{$var} = $cell;
1038     return $cell;
1039 }
1040
1041 sub set_shelves_userenv {
1042         my ($type, $shelves) = @_ or return;
1043         my $activeuser = $context->{activeuser} or return;
1044         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1045         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1046         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1047 }
1048
1049 sub get_shelves_userenv {
1050         my $active;
1051         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1052                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1053                 return;
1054         }
1055         my $totshelves = $active->{totshelves} or undef;
1056         my $pubshelves = $active->{pubshelves} or undef;
1057         my $barshelves = $active->{barshelves} or undef;
1058         return ($totshelves, $pubshelves, $barshelves);
1059 }
1060
1061 =head2 _new_userenv
1062
1063   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1064
1065 Builds a hash for user environment variables.
1066
1067 This hash shall be cached for future use: if you call
1068 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1069
1070 _new_userenv is called in Auth.pm
1071
1072 =cut
1073
1074 #'
1075 sub _new_userenv
1076 {
1077     shift;  # Useless except it compensates for bad calling style
1078     my ($sessionID)= @_;
1079      $context->{"activeuser"}=$sessionID;
1080 }
1081
1082 =head2 _unset_userenv
1083
1084   C4::Context->_unset_userenv;
1085
1086 Destroys the hash for activeuser user environment variables.
1087
1088 =cut
1089
1090 #'
1091
1092 sub _unset_userenv
1093 {
1094     my ($sessionID)= @_;
1095     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1096 }
1097
1098
1099 =head2 get_versions
1100
1101   C4::Context->get_versions
1102
1103 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1104
1105 =cut
1106
1107 #'
1108
1109 # A little example sub to show more debugging info for CGI::Carp
1110 sub get_versions {
1111     my %versions;
1112     $versions{kohaVersion}  = Koha::version();
1113     $versions{kohaDbVersion} = C4::Context->preference('version');
1114     $versions{osVersion} = join(" ", POSIX::uname());
1115     $versions{perlVersion} = $];
1116     {
1117         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1118         $versions{mysqlVersion}  = `mysql -V`;
1119         $versions{apacheVersion} = (`apache2ctl -v`)[0];
1120         $versions{apacheVersion} = `httpd -v`             unless  $versions{apacheVersion} ;
1121         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1122         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1123         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1124     }
1125     return %versions;
1126 }
1127
1128
1129 =head2 tz
1130
1131   C4::Context->tz
1132
1133   Returns a DateTime::TimeZone object for the system timezone
1134
1135 =cut
1136
1137 sub tz {
1138     my $self = shift;
1139     if (!defined $context->{tz}) {
1140         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1141     }
1142     return $context->{tz};
1143 }
1144
1145
1146 =head2 IsSuperLibrarian
1147
1148     C4::Context->IsSuperLibrarian();
1149
1150 =cut
1151
1152 sub IsSuperLibrarian {
1153     my $userenv = C4::Context->userenv;
1154
1155     unless ( $userenv and exists $userenv->{flags} ) {
1156         # If we reach this without a user environment,
1157         # assume that we're running from a command-line script,
1158         # and act as a superlibrarian.
1159         carp("C4::Context->userenv not defined!");
1160         return 1;
1161     }
1162
1163     return ($userenv->{flags}//0) % 2;
1164 }
1165
1166 =head2 interface
1167
1168 Sets the current interface for later retrieval in any Perl module
1169
1170     C4::Context->interface('opac');
1171     C4::Context->interface('intranet');
1172     my $interface = C4::Context->interface;
1173
1174 =cut
1175
1176 sub interface {
1177     my ($class, $interface) = @_;
1178
1179     if (defined $interface) {
1180         $interface = lc $interface;
1181         if ($interface eq 'opac' || $interface eq 'intranet' || $interface eq 'sip' || $interface eq 'commandline') {
1182             $context->{interface} = $interface;
1183         } else {
1184             warn "invalid interface : '$interface'";
1185         }
1186     }
1187
1188     return $context->{interface} // 'opac';
1189 }
1190
1191 1;
1192 __END__
1193
1194 =head1 ENVIRONMENT
1195
1196 =head2 C<KOHA_CONF>
1197
1198 Specifies the configuration file to read.
1199
1200 =head1 SEE ALSO
1201
1202 XML::Simple
1203
1204 =head1 AUTHORS
1205
1206 Andrew Arensburger <arensb at ooblick dot com>
1207
1208 Joshua Ferraro <jmf at liblime dot com>
1209