circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 # FIXME There are too many calls to Koha::Patrons->find in this script
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use URI::Escape qw( uri_escape_utf8 );
  30 use DateTime;
  31 use DateTime::Duration;
  32 use Scalar::Util qw( blessed looks_like_number );
  33 use Try::Tiny;
  34 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  35 use C4::Auth qw( get_session get_template_and_user );
  36 use C4::Koha;
  37 use C4::Circulation qw( barcodedecode CanBookBeIssued AddIssue );
  38 use C4::Members;
  39 use C4::Biblio qw( TransformMarcToKoha );
  40 use C4::Search qw( new_record_from_zebra );
  41 use C4::Reserves;
  42 use Koha::Holds;
  43 use C4::Context;
  44 use CGI::Session;
  45 use Koha::AuthorisedValues;
  46 use Koha::CsvProfiles;
  47 use Koha::Patrons;
  48 use Koha::DateUtils qw( dt_from_string );
  49 use Koha::Patron::Restriction::Types;
  50 use Koha::Plugins;
  51 use Koha::Database;
  52 use Koha::BiblioFrameworks;
  53 use Koha::Items;
  54 use Koha::SearchEngine;
  55 use Koha::SearchEngine::Search;
  56 use Koha::Patron::Modifications;
  57 use Koha::Token;
  58
  59 use List::MoreUtils qw( uniq );
  60
  61 #
  62 # PARAMETERS READING
  63 #
  64 my $query = CGI->new;
  65
  66 my $override_high_holds     = $query->param('override_high_holds');
  67 my $override_high_holds_tmp = $query->param('override_high_holds_tmp');
  68
  69 my $sessionID = $query->cookie("CGISESSID") ;
  70 my $session = get_session($sessionID);
  71
  72 my $barcodes = [];
  73 my $barcode =  $query->param('barcode');
  74 my $findborrower;
  75 my $autoswitched;
  76 my $borrowernumber = $query->param('borrowernumber');
  77
  78 if (C4::Context->preference("AutoSwitchPatron") && $barcode) {
  79     my $new_barcode = $barcode;
  80     Koha::Plugins->call( 'patron_barcode_transform', \$new_barcode );
  81     if (Koha::Patrons->search( { cardnumber => $new_barcode} )->count() > 0) {
  82         $findborrower = $barcode;
  83         undef $barcode;
  84         undef $borrowernumber;
  85         $autoswitched = 1;
  86     }
  87 }
  88 $findborrower ||= $query->param('findborrower') || q{};
  89 $findborrower =~ s|,| |g;
  90
  91 # Barcode given by user could be '0'
  92 if ( $barcode || ( defined($barcode) && $barcode eq '0' ) ) {
  93     $barcodes = [ $barcode ];
  94 } else {
  95     my $filefh = $query->upload('uploadfile');
  96     if ( $filefh ) {
  97         while ( my $content = <$filefh> ) {
  98             $content =~ s/[\r\n]*$//g;
  99             push @$barcodes, $content if $content;
 100         }
 101     } elsif ( my $list = $query->param('barcodelist') ) {
 102         push @$barcodes, split( /\s\n/, $list );
 103         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
 104     } else {
 105         @$barcodes = $query->multi_param('barcodes');
 106     }
 107 }
 108
 109 $barcodes = [ uniq @$barcodes ];
 110
 111 my $template_name = q|circ/circulation.tt|;
 112 my $patron = $borrowernumber ? Koha::Patrons->find( $borrowernumber ) : undef;
 113 my $batch = $query->param('batch');
 114 my $batch_allowed = 0;
 115 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
 116     $template_name = q|circ/circulation_batch_checkouts.tt|;
 117     my @batch_category_codes = split ',', C4::Context->preference('BatchCheckoutsValidCategories');
 118     my $categorycode = $patron->categorycode;
 119     if ( $categorycode && grep { $_ eq $categorycode } @batch_category_codes ) {
 120         $batch_allowed = 1;
 121     } else {
 122         $barcodes = [];
 123     }
 124 }
 125
 126 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
 127     {
 128         template_name   => $template_name,
 129         query           => $query,
 130         type            => "intranet",
 131         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
 132     }
 133 );
 134 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
 135
 136 my $force_allow_issue = $query->param('forceallow') || 0;
 137 if (!C4::Auth::haspermission( C4::Context->userenv->{id} , { circulate => 'force_checkout' } )) {
 138     $force_allow_issue = 0;
 139 }
 140 my $onsite_checkout = $query->param('onsite_checkout');
 141
 142 if (C4::Context->preference("OnSiteCheckoutAutoCheck") && $onsite_checkout eq "on") {
 143     $template->param(onsite_checkout => $onsite_checkout);
 144 }
 145
 146 my @failedrenews = $query->multi_param('failedrenew');    # expected to be itemnumbers
 147 our %renew_failed = ();
 148 for (@failedrenews) { $renew_failed{$_} = 1; }
 149
 150 my @failedreturns = $query->multi_param('failedreturn');
 151 our %return_failed = ();
 152 for (@failedreturns) { $return_failed{$_} = 1; }
 153
 154 my $branch = C4::Context->userenv->{'branch'};
 155
 156 for my $barcode ( @$barcodes ) {
 157     $barcode = barcodedecode( $barcode ) if $barcode;
 158 }
 159
 160 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 161 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 162 my $restoreduedatespec  = $query->param('restoreduedatespec') || $duedatespec || $session->param('stickyduedate');
 163 if ( $restoreduedatespec && $restoreduedatespec eq "highholds_empty" ) {
 164     undef $restoreduedatespec;
 165 }
 166 my $issueconfirmed = $query->param('issueconfirmed');
 167 my $cancelreserve  = $query->param('cancelreserve');
 168 my $cancel_recall  = $query->param('cancel_recall');
 169 my $recall_id      = $query->param('recall_id');
 170 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 171 my $charges        = $query->param('charges') || q{};
 172
 173 # Check if stickyduedate is turned off
 174 if ( @$barcodes ) {
 175     # was stickyduedate loaded from session?
 176     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 177         $session->clear( 'stickyduedate' );
 178         $stickyduedate  = $query->param('stickyduedate');
 179         $duedatespec    = $query->param('duedatespec');
 180     }
 181     $session->param('auto_renew', scalar $query->param('auto_renew'));
 182 }
 183 else {
 184     $session->clear('auto_renew');
 185 }
 186
 187 $template->param( auto_renew => $session->param('auto_renew') );
 188
 189 my ($datedue,$invalidduedate);
 190
 191 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 192 if( $onsite_checkout && !$duedatespec_allow ) {
 193     $datedue = dt_from_string()->truncate(to => 'day');
 194     $datedue->set_hour(23);
 195     $datedue->set_minute(59);
 196 } elsif( $duedatespec_allow ) {
 197     if ( $duedatespec ) {
 198         $datedue = eval { dt_from_string( $duedatespec ) };
 199         if (! $datedue ) {
 200             $invalidduedate = 1;
 201             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
 202         }
 203     }
 204 }
 205
 206 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
 207 if ( @$barcodes == 0 && $charges eq 'yes' ) {
 208     $template->param(
 209         PAYCHARGES     => 'yes',
 210         borrowernumber => $borrowernumber
 211     );
 212 }
 213
 214 #
 215 # STEP 2 : FIND BORROWER
 216 # if there is a list of find borrowers....
 217 #
 218 my $message;
 219 if ($findborrower) {
 220     Koha::Plugins->call( 'patron_barcode_transform', \$findborrower );
 221     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 222     if ( $patron ) {
 223         $borrowernumber = $patron->borrowernumber;
 224     } else {
 225         print $query->redirect( "/cgi-bin/koha/members/member.pl?quicksearch=1&circsearch=1&searchmember=" . uri_escape_utf8($findborrower) );
 226         exit;
 227     }
 228 }
 229
 230 # get the borrower information.....
 231 my $balance = 0;
 232 $patron ||= Koha::Patrons->find( $borrowernumber ) if $borrowernumber;
 233 if ($patron) {
 234
 235     $template->param( borrowernumber => $patron->borrowernumber );
 236     output_and_exit_if_error( $query, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
 237
 238     my $overdues = $patron->overdues;
 239     my $issues = $patron->checkouts;
 240     $balance = $patron->account->balance;
 241
 242
 243     # if the expiry date is before today ie they have expired
 244     if ( $patron->is_expired ) {
 245         #borrowercard expired, no issues
 246         $template->param(
 247             noissues => ($force_allow_issue) ? 0 : "1",
 248             forceallow => $force_allow_issue,
 249             expired => "1",
 250         );
 251     }
 252     # check for NotifyBorrowerDeparture
 253     elsif ( $patron->is_going_to_expire ) {
 254         # borrower card soon to expire warn librarian
 255         $template->param( "warndeparture" => $patron->dateexpiry ,
 256                         );
 257         if (C4::Context->preference('ReturnBeforeExpiry')){
 258             $template->param("returnbeforeexpiry" => 1);
 259         }
 260     }
 261     $template->param(
 262         overduecount => $overdues->count,
 263         issuecount   => $issues->count,
 264         finetotal    => $balance,
 265     );
 266
 267     if ( $patron and $patron->is_debarred ) {
 268         $template->param(
 269             'userdebarred'    => $patron->debarred,
 270             'debarredcomment' => $patron->debarredcomment,
 271         );
 272
 273         if ( $patron->debarred ne "9999-12-31" ) {
 274             $template->param( 'userdebarreddate' => $patron->debarred );
 275         }
 276     }
 277
 278     # Calculate and display patron's age
 279     if ( !$patron->is_valid_age ) {
 280         $template->param( age_limitations => 1 );
 281         $template->param( age_low => $patron->category->dateofbirthrequired );
 282         $template->param( age_high => $patron->category->upperagelimit );
 283     }
 284
 285 }
 286
 287 #
 288 # STEP 3 : ISSUING
 289 #
 290 #
 291 if (@$barcodes) {
 292     my $checkout_infos;
 293     for my $barcode ( @$barcodes ) {
 294
 295         my $template_params = {
 296             barcode         => $barcode,
 297             onsite_checkout => $onsite_checkout,
 298         };
 299
 300         # always check for blockers on issuing
 301         my ( $error, $question, $alerts, $messages );
 302         try {
 303             ( $error, $question, $alerts, $messages ) = CanBookBeIssued(
 304                 $patron,
 305                 $barcode, $datedue,
 306                 $inprocess,
 307                 undef,
 308                 {
 309                     onsite_checkout     => $onsite_checkout,
 310                     override_high_holds => $override_high_holds || $override_high_holds_tmp || 0,
 311                 }
 312             );
 313         } catch {
 314             die $_ unless blessed $_ && $_->can('rethrow');
 315
 316             if ( $_->isa('Koha::Exceptions::Calendar::NoOpenDays') ) {
 317                 $error = { NO_OPEN_DAYS => 1 };
 318             } else {
 319                 $_->rethrow;
 320             }
 321         };
 322
 323     my $blocker = $invalidduedate ? 1 : 0;
 324
 325     $template_params->{alert} = $alerts;
 326     $template_params->{messages} = $messages;
 327
 328     my $item = Koha::Items->find({ barcode => $barcode });
 329
 330     my $biblio;
 331     if ( $item ) {
 332         $biblio = $item->biblio;
 333     }
 334
 335     # Fix for bug 7494: optional checkout-time fallback search for a book
 336
 337     if ( $error->{'UNKNOWN_BARCODE'}
 338         && C4::Context->preference("itemBarcodeFallbackSearch")
 339         && not $batch
 340     )
 341     {
 342      $template_params->{FALLBACK} = 1;
 343
 344         my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
 345         my $query = "kw=" . $barcode;
 346         my ( $searcherror, $results, $total_hits ) = $searcher->simple_search_compat($query, 0, 10);
 347
 348         # if multiple hits, offer options to librarian
 349         if ( $total_hits > 0 ) {
 350             my @barcodes;
 351             foreach my $hit ( @{$results} ) {
 352                 my $chosen = # Maybe easier to retrieve the itemnumber from $hit?
 353                   TransformMarcToKoha({ record => C4::Search::new_record_from_zebra('biblioserver',$hit) });
 354
 355                 # offer all barcodes individually
 356                 if ( $chosen->{barcode} ) {
 357                     push @barcodes, sort split(/\s*\|\s*/, $chosen->{barcode});
 358                 }
 359             }
 360             my $items = Koha::Items->search({ barcode => {-in => \@barcodes}});
 361             $template_params->{options} = $items;
 362         }
 363     }
 364
 365     # Only some errors will block when performing forced onsite checkout,
 366     # for other cases all errors will block
 367     my @blocking_error_codes =
 368         ( $onsite_checkout and C4::Context->preference("OnSiteCheckoutsForce") )
 369         ? qw( UNKNOWN_BARCODE NO_OPEN_DAYS )
 370         : ( keys %$error );
 371
 372     foreach my $code ( @blocking_error_codes ) {
 373         if ($error->{$code}) {
 374             $template_params->{$code} = $error->{$code};
 375             $template_params->{IMPOSSIBLE} = 1;
 376             $blocker = 1;
 377         }
 378     }
 379
 380     delete $question->{'DEBT'} if ($debt_confirmed);
 381
 382     if( $item and ( !$blocker or $force_allow_issue ) ){
 383         my $confirm_required = 0;
 384         unless($issueconfirmed){
 385             #  Get the item title for more information
 386             my $materials = $item->materials;
 387             my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.materials', authorised_value => $materials });
 388             $materials = $descriptions->{lib} // $materials;
 389             $template_params->{ADDITIONAL_MATERIALS} = $materials;
 390             $template_params->{itemhomebranch} = $item->homebranch;
 391
 392             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 393             foreach my $needsconfirmation ( keys %$question ) {
 394                 $template_params->{$needsconfirmation} = $$question{$needsconfirmation};
 395                 $template_params->{getTitleMessageIteminfo} = $biblio->title;
 396                 $template_params->{getBarcodeMessageIteminfo} = $item->barcode;
 397                 $template_params->{NEEDSCONFIRMATION} = 1;
 398                 $confirm_required = 1;
 399             }
 400         }
 401         unless($confirm_required) {
 402             my $switch_onsite_checkout = exists $messages->{ONSITE_CHECKOUT_WILL_BE_SWITCHED};
 403             if ( C4::Context->preference('UseRecalls') && !$recall_id ) {
 404                 my $recall = Koha::Recalls->find(
 405                     {
 406                         biblio_id => $item->biblionumber,
 407                         item_id   => [ undef, $item->itemnumber ],
 408                         status    => [ 'requested', 'waiting' ],
 409                         completed => 0,
 410                         patron_id => $patron->borrowernumber,
 411                     }
 412                 );
 413                 $recall_id = ( $recall and $recall->id ) ? $recall->id : undef;
 414             }
 415             my $issue = AddIssue( $patron->unblessed, $barcode, $datedue, $cancelreserve, undef, undef, { onsite_checkout => $onsite_checkout, auto_renew => $session->param('auto_renew'), switch_onsite_checkout => $switch_onsite_checkout, cancel_recall => $cancel_recall, recall_id => $recall_id, } );
 416             $template_params->{issue} = $issue;
 417             $session->clear('auto_renew');
 418             $inprocess = 1;
 419         }
 420     }
 421
 422     if ($question->{RESERVE_WAITING} or $question->{RESERVED} or $question->{TRANSFERRED} or $question->{PROCESSING}){
 423         $template->param(
 424             reserveborrowernumber => $question->{'resborrowernumber'},
 425             reserve_id => $question->{reserve_id},
 426         );
 427     }
 428
 429
 430     # FIXME If the issue is confirmed, we launch another time checkouts->count, now display the issue count after issue
 431     $patron = Koha::Patrons->find( $borrowernumber );
 432     $template_params->{issuecount} = $patron->checkouts->count;
 433
 434     if ( $item ) {
 435         $template_params->{item} = $item;
 436         $template_params->{biblio} = $biblio;
 437         $template_params->{itembiblionumber} = $biblio->biblionumber;
 438     }
 439     push @$checkout_infos, $template_params;
 440   }
 441   unless ( $batch ) {
 442     $template->param( %{$checkout_infos->[0]} );
 443     $template->param( barcode => $barcodes->[0] );
 444   } else {
 445     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
 446     $template->param(
 447         checkout_infos => $checkout_infos,
 448         confirmation_needed => $confirmation_needed,
 449     );
 450   }
 451 }
 452
 453 ##################################################################################
 454 # BUILD HTML
 455 # show all reserves of this borrower, and the position of the reservation ....
 456 if ($patron) {
 457     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } ); # FIXME must be Koha::Patron->holds
 458     my $waiting_holds = $holds->waiting;
 459     $template->param(
 460         holds_count  => $holds->count(),
 461         WaitingHolds => $waiting_holds,
 462     );
 463
 464     if ( C4::Context->preference('UseRecalls') ) {
 465         my $waiting_recalls = $patron->recalls->search({ status => 'waiting' });
 466         $template->param(
 467             recalls => $patron->recalls->filter_by_current->search({},{ order_by => { -asc => 'created_date' } }),
 468             specific_patron => 1,
 469             waiting_recalls => $waiting_recalls,
 470         );
 471     }
 472 }
 473
 474 if ( $patron ) {
 475     my $noissues;
 476     if ( $patron->gonenoaddress ) {
 477         $template->param( gonenoaddress => 1 );
 478         $noissues = 1;
 479     }
 480     if ( $patron->lost ) {
 481         $template->param( lost=> 1 );
 482         $noissues = 1;
 483     }
 484     if ( $patron->is_debarred ) {
 485         $template->param( is_debarred=> 1 );
 486         $noissues = 1;
 487     }
 488     if ( $patron->borrowernumber eq C4::Context->preference("AnonymousPatron") ) {
 489         $template->param( is_anonymous => 1 );
 490         $noissues = 1;
 491     }
 492     my $account = $patron->account;
 493     if( ( my $owing = $account->non_issues_charges ) > 0 ) {
 494         my $noissuescharge = C4::Context->preference("noissuescharge") || 5; # FIXME If noissuescharge == 0 then 5, why??
 495         $noissues ||= ( not C4::Context->preference("AllowFineOverride") and ( $owing > $noissuescharge ) );
 496         $template->param(
 497             charges => 1,
 498             chargesamount => $owing,
 499         )
 500     } elsif ( $balance < 0 ) {
 501         $template->param(
 502             credits => 1,
 503             creditsamount => -$balance,
 504         );
 505     }
 506
 507     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 508     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 509     if ( $no_issues_charge_guarantors ) {
 510         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 511
 512         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors ) {
 513             $template->param(
 514                 charges_guarantors_guarantees => $guarantors_non_issues_charges
 515             );
 516             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 517         }
 518     }
 519
 520     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 521     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 522     if ( defined $no_issues_charge_guarantees ) {
 523         my $guarantees_non_issues_charges = 0;
 524         my $guarantees = $patron->guarantee_relationships->guarantees;
 525         while ( my $g = $guarantees->next ) {
 526             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 527         }
 528         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees ) {
 529             $template->param(
 530                 charges_guarantees    => 1,
 531                 chargesamount_guarantees => $guarantees_non_issues_charges,
 532             );
 533             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 534         }
 535     }
 536
 537     if ( $patron->has_overdues ) {
 538         $template->param( odues => 1 );
 539     }
 540
 541     if ( $patron->borrowernotes ) {
 542         my $borrowernotes = $patron->borrowernotes;
 543         $borrowernotes =~ s#\n#<br />#g;
 544         $template->param(
 545             notes =>1,
 546             notesmsg => $borrowernotes,
 547         )
 548     }
 549
 550     if ( $noissues ) {
 551         $template->param(
 552             noissues => ($force_allow_issue) ? 0 : 'true',
 553             forceallow => $force_allow_issue,
 554         );
 555     }
 556
 557     my $patron_messages = $patron->messages->search(
 558         {},
 559         {
 560            join => 'manager',
 561            '+select' => ['manager.surname', 'manager.firstname' ],
 562            '+as' => ['manager_surname', 'manager_firstname'],
 563         }
 564     );
 565     $template->param( patron_messages => $patron_messages );
 566
 567 }
 568
 569 my $fast_cataloging = 0;
 570 if ( Koha::BiblioFrameworks->find('FA') ) {
 571     $fast_cataloging = 1
 572 }
 573
 574 my $view = $batch
 575     ?'batch_checkout_view'
 576     : 'circview';
 577
 578 my @relatives;
 579 if ( $patron ) {
 580     if ( my @guarantors = $patron->guarantor_relationships()->guarantors->as_list ) {
 581         push( @relatives, $_->id ) for @guarantors;
 582         push( @relatives, $_->id ) for $patron->siblings->as_list;
 583     } else {
 584         push( @relatives, $_->id ) for $patron->guarantee_relationships()->guarantees->as_list;
 585     }
 586 }
 587 my $relatives_issues_count =
 588   Koha::Database->new()->schema()->resultset('Issue')
 589   ->count( { borrowernumber => \@relatives } );
 590
 591 if ( $patron ) {
 592     my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $patron->streettype });
 593     my $roadtype = $av->count ? $av->next->lib : '';
 594     $template->param(
 595         roadtype          => $roadtype,
 596         patron            => $patron,
 597         categoryname      => $patron->category->description,
 598         expiry            => $patron->dateexpiry,
 599     );
 600 }
 601
 602 # Restore date if changed by holds and/or save stickyduedate to session
 603 if ($restoreduedatespec || $stickyduedate) {
 604     $duedatespec = $restoreduedatespec || $duedatespec;
 605
 606     if ($stickyduedate) {
 607         $session->param( 'stickyduedate', $duedatespec );
 608     }
 609 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
 610     undef $duedatespec;
 611 }
 612
 613 $template->param(
 614     borrowernumber    => $borrowernumber,
 615     branch            => $branch,
 616     was_renewed       => scalar $query->param('was_renewed') ? 1 : 0,
 617     barcodes          => $barcodes,
 618     stickyduedate     => $stickyduedate,
 619     duedatespec       => $duedatespec,
 620     restoreduedatespec => $restoreduedatespec,
 621     message           => $message,
 622     totaldue          => sprintf('%.2f', $balance), # FIXME not used in template?
 623     inprocess         => $inprocess,
 624     $view             => 1,
 625     batch_allowed     => $batch_allowed,
 626     batch             => $batch,
 627     AudioAlerts           => C4::Context->preference("AudioAlerts"),
 628     fast_cataloging   => $fast_cataloging,
 629     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 630     RoutingSerials => C4::Context->preference('RoutingSerials'),
 631     relatives_issues_count => $relatives_issues_count,
 632     relatives_borrowernumbers => \@relatives,
 633 );
 634
 635
 636 if ( C4::Context->preference("ExportCircHistory") ) {
 637     $template->param(csv_profiles => Koha::CsvProfiles->search({ type => 'marc' }));
 638 }
 639
 640 my $has_modifications = Koha::Patron::Modifications->search( { borrowernumber => $borrowernumber } )->count;
 641 $template->param(
 642     debt_confirmed            => $debt_confirmed,
 643     SpecifyDueDate            => $duedatespec_allow,
 644     PatronAutoComplete        => C4::Context->preference("PatronAutoComplete"),
 645     today_due_date_and_time   => dt_from_string()->set(hour => 23)->set(minute => 59),
 646     restriction_types         => scalar Koha::Patron::Restriction::Types->search(),
 647     has_modifications         => $has_modifications,
 648     override_high_holds       => $override_high_holds,
 649     nopermission              => scalar $query->param('nopermission'),
 650     autoswitched              => $autoswitched,
 651     logged_in_user            => $logged_in_user,
 652 );
 653
 654 # Generate CSRF token for upload and delete image buttons
 655 $template->param(
 656     csrf_token => Koha::Token->new->generate_csrf({ session_id => $query->cookie('CGISESSID'),}),
 657 );
 658
 659 output_html_with_http_headers $query, $cookie, $template->output;