members/maninvoice.pl

   1 #!/usr/bin/perl
   2
   3 #written 11/1/2000 by chris@katipo.oc.nz
   4 #script to display borrowers account details
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 # Copyright 2010 BibLibre
   8 # Copyright 2019 PTFS Europe
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 use Modern::Perl;
  26 use Try::Tiny qw( catch try );
  27 use URI::Escape qw( uri_escape_utf8 );
  28
  29 use C4::Auth qw( get_template_and_user );
  30 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  31 use CGI qw ( -utf8 );
  32 use C4::Members;
  33 use C4::Accounts;
  34
  35 use Koha::Patrons;
  36 use Koha::Items;
  37 use Koha::Old::Items;
  38 use Koha::Checkouts;
  39 use Koha::Old::Checkouts;
  40
  41 use Koha::Patron::Categories;
  42 use Koha::Account::DebitTypes;
  43 use Koha::AdditionalFields;
  44
  45 my $input = CGI->new;
  46 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  47     {
  48         template_name   => "members/maninvoice.tt",
  49         query           => $input,
  50         type            => "intranet",
  51         flagsrequired   => {
  52             borrowers     => 'edit_borrowers',
  53             updatecharges => 'manual_invoice'
  54         }
  55     }
  56 );
  57
  58 my $borrowernumber = $input->param('borrowernumber');
  59 my $patron         = Koha::Patrons->find($borrowernumber);
  60 unless ($patron) {
  61     print $input->redirect(
  62         "/cgi-bin/koha/circ/circulation.pl?borrowernumber=$borrowernumber");
  63     exit;
  64 }
  65
  66 my $logged_in_user = Koha::Patrons->find($loggedinuser);
  67 output_and_exit_if_error(
  68     $input, $cookie,
  69     $template,
  70     {
  71         module         => 'members',
  72         logged_in_user => $logged_in_user,
  73         current_patron => $patron
  74     }
  75 );
  76
  77 my $library_id = C4::Context->userenv->{'branch'};
  78 my $desc       = $input->param('desc');
  79 my $amount     = $input->param('amount');
  80 my $note       = $input->param('note');
  81 my $debit_type = $input->param('type');
  82 my $barcode    = $input->param('barcode');
  83 $template->param(
  84     desc    => $desc,
  85     amount  => $amount,
  86     note    => $note,
  87     type    => $debit_type,
  88     barcode => $barcode
  89 );
  90
  91 my $add = $input->param('cud-add');
  92 if ($add) {
  93     # Note: If the logged in user is not allowed to see this patron an invoice can be forced
  94     # Here we are trusting librarians not to hack the system
  95     my $desc       = $input->param('desc');
  96     my $amount     = $input->param('amount');
  97     my $note       = $input->param('note');
  98     my $debit_type = $input->param('type');
  99
 100     # If barcode is passed, attempt to find the associated item
 101     my $failed;
 102     my $item_id;
 103     my $olditem; # FIXME: When items and deleted_items are merged, we can remove this
 104     my $issue_id;
 105     if ($barcode) {
 106         my $item = Koha::Items->find( { barcode => $barcode } );
 107         if ($item) {
 108             $item_id = $item->itemnumber;
 109         }
 110         else {
 111             $item = Koha::Old::Items->search( { barcode => $barcode },
 112                 { order_by => { -desc => 'timestamp' }, rows => 1 } );
 113             if ($item->count) {
 114                 $item_id = $item->next->itemnumber;
 115                 $olditem = 1;
 116             }
 117             else {
 118                 $template->param( error => 'itemnumber' );
 119                 $failed = 1;
 120             }
 121         }
 122
 123         if ( ( $debit_type eq 'LOST' ) && $item_id ) {
 124             my $checkouts = Koha::Checkouts->search(
 125                 {
 126                     itemnumber     => $item_id,
 127                     borrowernumber => $borrowernumber
 128                 }
 129             );
 130             my $checkout =
 131                 $checkouts->count
 132               ? $checkouts->next
 133               : Koha::Old::Checkouts->search(
 134                 {
 135                     itemnumber     => $item_id,
 136                     borrowernumber => $borrowernumber
 137                 },
 138                 { order_by => { -desc => 'returndate' }, rows => 1 }
 139             )->next;
 140             $issue_id = $checkout ? $checkout->issue_id : undef;
 141         }
 142     }
 143
 144     unless ($failed) {
 145         try {
 146             my $line = $patron->account->add_debit(
 147                 {
 148                     amount      => $amount,
 149                     description => $desc,
 150                     note        => $note,
 151                     user_id     => $logged_in_user->borrowernumber,
 152                     interface   => 'intranet',
 153                     library_id  => $library_id,
 154                     type        => $debit_type,
 155                     ( $olditem ? () : ( item_id => $item_id ) ),
 156                     issue_id    => $issue_id
 157                 }
 158             );
 159
 160             my @additional_fields;
 161             my $accountline_fields = Koha::AdditionalFields->search({ tablename => 'accountlines:debit' });
 162             while ( my $field = $accountline_fields->next ) {
 163                 my $value = $input->param('additional_field_' . $field->id);
 164                 if (defined $value) {
 165                     push @additional_fields, {
 166                         id => $field->id,
 167                         value => $value,
 168                     };
 169                 }
 170             }
 171             if (@additional_fields) {
 172                 $line->set_additional_fields(\@additional_fields);
 173             }
 174
 175             if ( C4::Context->preference('AccountAutoReconcile') ) {
 176                 $patron->account->reconcile_balance;
 177             }
 178
 179             if ( $add eq 'save and pay' ) {
 180                 my $url = sprintf(
 181                     '/cgi-bin/koha/members/paycollect.pl?borrowernumber=%s&pay_individual=1&debit_type_code=%s&amount=%s&amountoutstanding=%s&description=%s&itemnumber=%s&accountlines_id=%s',
 182                     map { uri_escape_utf8($_) } (
 183                         $borrowernumber,
 184                         $line->debit_type_code,
 185                         $line->amount,
 186                         $line->amountoutstanding,
 187                         $line->description,
 188                         $line->itemnumber,
 189                         $line->id
 190                     )
 191                 );
 192
 193                 print $input->redirect($url);
 194             }
 195             else {
 196                 print $input->redirect(
 197                     "/cgi-bin/koha/members/boraccount.pl?borrowernumber=$borrowernumber"
 198                 );
 199             }
 200
 201             exit;
 202         }
 203         catch {
 204             my $error = $_;
 205             if ( ref($error) eq 'Koha::Exceptions::Object::FKConstraint' ) {
 206                 $template->param( error => $error->broken_fk );
 207             }
 208             else {
 209                 $template->param( error => $error );
 210             }
 211         }
 212     }
 213 }
 214
 215 my $debit_types = Koha::Account::DebitTypes->search_with_library_limits(
 216   { can_be_invoiced => 1, archived => 0 },
 217   {}, $library_id );
 218
 219 $template->param(
 220   debit_types => $debit_types,
 221   patron    => $patron,
 222   finesview => 1,
 223   available_additional_fields => [ Koha::AdditionalFields->search({ tablename => 'accountlines:debit' })->as_list ],
 224   );
 225 output_html_with_http_headers $input, $cookie, $template->output;