opac/opac-sendbasket.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Doxulting 2004
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode;
  24 use Carp qw( carp );
  25 use Try::Tiny qw( catch try );
  26
  27 use C4::Biblio qw(
  28   GetMarcSubjects
  29 );
  30 use C4::Auth qw( get_template_and_user );
  31 use C4::Output qw( output_html_with_http_headers );
  32 use C4::Templates;
  33 use Koha::Biblios;
  34 use Koha::Email;
  35 use Koha::Patrons;
  36
  37 my $query = CGI->new;
  38
  39 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  40     {
  41         template_name => "opac-sendbasketform.tt",
  42         query         => $query,
  43         type          => "opac",
  44     }
  45 );
  46
  47 my $op        = $query->param('op') || q{};
  48 my $bib_list  = $query->param('bib_list') || '';
  49 my $email_add = $query->param('email_add');
  50
  51 if ( $op eq "cud-send" && $email_add ) {
  52
  53     my $patron     = Koha::Patrons->find($borrowernumber);
  54     my $user_email = $patron->notice_email_address;
  55
  56     my $comment = $query->param('comment');
  57
  58     my @bibs = split( /\//, $bib_list );
  59     my $iso2709;
  60     foreach my $bib (@bibs) {
  61         my $biblio = Koha::Biblios->find($bib) or next;
  62         $iso2709 .= $biblio->metadata->record->as_usmarc();
  63     }
  64
  65     if ( !defined $iso2709 ) {
  66         carp "Error sending mail: empty basket";
  67         $template->param( error => 1 );
  68     }
  69     elsif ( !defined $user_email or $user_email eq '' ) {
  70         carp "Error sending mail: sender's email address is invalid";
  71         $template->param( error => 1 );
  72     }
  73     else {
  74         my %loops = ( biblio => \@bibs, );
  75
  76         my %substitute = ( comment => $comment, );
  77
  78         my $letter = C4::Letters::GetPreparedLetter(
  79             module      => 'catalogue',
  80             letter_code => 'CART',
  81             lang        => $patron->lang,
  82             tables      => {
  83                 borrowers => $borrowernumber,
  84             },
  85             message_transport_type => 'email',
  86             loops                  => \%loops,
  87             substitute             => \%substitute,
  88         );
  89
  90         my $attachment = {
  91             filename => 'basket.iso2709',
  92             type     => 'application/octet-stream',
  93             content  => Encode::encode( "UTF-8", $iso2709 ),
  94         };
  95
  96         my $message_id = C4::Letters::EnqueueLetter(
  97             {
  98                 letter                 => $letter,
  99                 message_transport_type => 'email',
 100                 to_address             => $email_add,
 101                 reply_address          => $user_email,
 102                 attachments            => [$attachment],
 103             }
 104         );
 105
 106         C4::Letters::SendQueuedMessages( { message_id => $message_id } ) if $message_id;
 107
 108         $template->param( SENT => 1 );
 109     }
 110
 111     $template->param( email_add => $email_add );
 112     output_html_with_http_headers $query, $cookie, $template->output, undef,
 113       { force_no_caching => 1 };
 114 }
 115 else {
 116     my $new_session_id = $query->cookie('CGISESSID');
 117     $template->param(
 118         bib_list       => $bib_list,
 119         url            => "/cgi-bin/koha/opac-sendbasket.pl",
 120         suggestion     => C4::Context->preference("suggestion"),
 121         virtualshelves => C4::Context->preference("virtualshelves"),
 122     );
 123     output_html_with_http_headers $query, $cookie, $template->output, undef,
 124       { force_no_caching => 1 };
 125 }