C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use Koha::DateUtils;
  28 use C4::Context;
  29 use C4::Stats;
  30 use C4::Reserves;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Members;
  34 use C4::Accounts;
  35 use C4::ItemCirculationAlertPreference;
  36 use C4::Message;
  37 use C4::Debug;
  38 use C4::Log; # logaction
  39 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  40 use C4::RotatingCollections qw(GetCollectionItemBranches);
  41 use Algorithm::CheckDigits;
  42
  43 use Data::Dumper;
  44 use Koha::Account;
  45 use Koha::AuthorisedValues;
  46 use Koha::Biblioitems;
  47 use Koha::DateUtils;
  48 use Koha::Calendar;
  49 use Koha::Checkouts;
  50 use Koha::Illrequests;
  51 use Koha::Items;
  52 use Koha::Patrons;
  53 use Koha::Patron::Debarments;
  54 use Koha::Database;
  55 use Koha::Libraries;
  56 use Koha::Account::Lines;
  57 use Koha::Holds;
  58 use Koha::Account::Lines;
  59 use Koha::Account::Offsets;
  60 use Koha::Config::SysPrefs;
  61 use Koha::Charges::Fees;
  62 use Koha::Config::SysPref;
  63 use Koha::Checkouts::ReturnClaims;
  64 use Koha::SearchEngine::Indexer;
  65 use Koha::Exceptions::Checkout;
  66 use Carp;
  67 use List::MoreUtils qw( uniq any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Try::Tiny;
  70 use Date::Calc qw(
  71   Today
  72   Today_and_Now
  73   Add_Delta_YM
  74   Add_Delta_DHMS
  75   Date_to_Days
  76   Day_of_Week
  77   Add_Delta_Days
  78 );
  79 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  80
  81 BEGIN {
  82         require Exporter;
  83         @ISA    = qw(Exporter);
  84
  85         # FIXME subs that should probably be elsewhere
  86         push @EXPORT, qw(
  87                 &barcodedecode
  88         &LostItem
  89         &ReturnLostItem
  90         &GetPendingOnSiteCheckouts
  91         );
  92
  93         # subs to deal with issuing a book
  94         push @EXPORT, qw(
  95                 &CanBookBeIssued
  96                 &CanBookBeRenewed
  97                 &AddIssue
  98                 &AddRenewal
  99                 &GetRenewCount
 100         &GetSoonestRenewDate
 101         &GetLatestAutoRenewDate
 102                 &GetIssuingCharges
 103         &GetBranchBorrowerCircRule
 104         &GetBranchItemRule
 105                 &GetOpenIssue
 106         &CheckIfIssuedToPatron
 107         &IsItemIssued
 108         GetTopIssues
 109         );
 110
 111         # subs to deal with returns
 112         push @EXPORT, qw(
 113                 &AddReturn
 114         &MarkIssueReturned
 115         );
 116
 117         # subs to deal with transfers
 118         push @EXPORT, qw(
 119                 &transferbook
 120                 &GetTransfers
 121                 &GetTransfersFromTo
 122                 &updateWrongTransfer
 123                 &DeleteTransfer
 124                 &IsBranchTransferAllowed
 125                 &CreateBranchTransferLimit
 126                 &DeleteBranchTransferLimits
 127         &TransferSlip
 128         );
 129
 130     # subs to deal with offline circulation
 131     push @EXPORT, qw(
 132       &GetOfflineOperations
 133       &GetOfflineOperation
 134       &AddOfflineOperation
 135       &DeleteOfflineOperation
 136       &ProcessOfflineOperation
 137     );
 138 }
 139
 140 =head1 NAME
 141
 142 C4::Circulation - Koha circulation module
 143
 144 =head1 SYNOPSIS
 145
 146 use C4::Circulation;
 147
 148 =head1 DESCRIPTION
 149
 150 The functions in this module deal with circulation, issues, and
 151 returns, as well as general information about the library.
 152 Also deals with inventory.
 153
 154 =head1 FUNCTIONS
 155
 156 =head2 barcodedecode
 157
 158   $str = &barcodedecode($barcode, [$filter]);
 159
 160 Generic filter function for barcode string.
 161 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 162 Will do some manipulation of the barcode for systems that deliver a barcode
 163 to circulation.pl that differs from the barcode stored for the item.
 164 For proper functioning of this filter, calling the function on the
 165 correct barcode string (items.barcode) should return an unaltered barcode.
 166
 167 The optional $filter argument is to allow for testing or explicit
 168 behavior that ignores the System Pref.  Valid values are the same as the
 169 System Pref options.
 170
 171 =cut
 172
 173 # FIXME -- the &decode fcn below should be wrapped into this one.
 174 # FIXME -- these plugins should be moved out of Circulation.pm
 175 #
 176 sub barcodedecode {
 177     my ($barcode, $filter) = @_;
 178     my $branch = C4::Context::mybranch();
 179     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 180     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 181         if ($filter eq 'whitespace') {
 182                 $barcode =~ s/\s//g;
 183         } elsif ($filter eq 'cuecat') {
 184                 chomp($barcode);
 185             my @fields = split( /\./, $barcode );
 186             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 187             ($#results == 2) and return $results[2];
 188         } elsif ($filter eq 'T-prefix') {
 189                 if ($barcode =~ /^[Tt](\d)/) {
 190                         (defined($1) and $1 eq '0') and return $barcode;
 191             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 192                 }
 193         return sprintf("T%07d", $barcode);
 194         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 195         # Why drop the nonzero digit after the T?
 196         # Why pass non-digits (or empty string) to "T%07d"?
 197         } elsif ($filter eq 'libsuite8') {
 198                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 199                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 200                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 201                         }else{
 202                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 203                         }
 204                 }
 205     } elsif ($filter eq 'EAN13') {
 206         my $ean = CheckDigits('ean');
 207         if ( $ean->is_valid($barcode) ) {
 208             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 209             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 210         } else {
 211             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 212         }
 213         }
 214     return $barcode;    # return barcode, modified or not
 215 }
 216
 217 =head2 _decode
 218
 219   $str = &_decode($chunk);
 220
 221 Decodes a segment of a string emitted by a CueCat barcode scanner and
 222 returns it.
 223
 224 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 225 or Javascript based decoding on the client side.
 226
 227 =cut
 228
 229 sub _decode {
 230     my ($encoded) = @_;
 231     my $seq =
 232       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 233     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 234     my $l = ( $#s + 1 ) % 4;
 235     if ($l) {
 236         if ( $l == 1 ) {
 237             # warn "Error: Cuecat decode parsing failed!";
 238             return;
 239         }
 240         $l = 4 - $l;
 241         $#s += $l;
 242     }
 243     my $r = '';
 244     while ( $#s >= 0 ) {
 245         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 246         $r .=
 247             chr( ( $n >> 16 ) ^ 67 )
 248          .chr( ( $n >> 8 & 255 ) ^ 67 )
 249          .chr( ( $n & 255 ) ^ 67 );
 250         @s = @s[ 4 .. $#s ];
 251     }
 252     $r = substr( $r, 0, length($r) - $l );
 253     return $r;
 254 }
 255
 256 =head2 transferbook
 257
 258   ($dotransfer, $messages, $iteminformation) = &transferbook({
 259                                                    from_branch => $frombranch
 260                                                    to_branch => $tobranch,
 261                                                    barcode => $barcode,
 262                                                    ignore_reserves => $ignore_reserves,
 263                                                    trigger => $trigger
 264                                                 });
 265
 266 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 267
 268 C<$fbr> is the code for the branch initiating the transfer.
 269 C<$tbr> is the code for the branch to which the item should be transferred.
 270
 271 C<$barcode> is the barcode of the item to be transferred.
 272
 273 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 274 Otherwise, if an item is reserved, the transfer fails.
 275
 276 C<$trigger> is the enum value for what triggered the transfer.
 277
 278 Returns three values:
 279
 280 =over
 281
 282 =item $dotransfer
 283
 284 is true if the transfer was successful.
 285
 286 =item $messages
 287
 288 is a reference-to-hash which may have any of the following keys:
 289
 290 =over
 291
 292 =item C<BadBarcode>
 293
 294 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 295
 296 =item C<DestinationEqualsHolding>
 297
 298 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 299
 300 =item C<WasReturned>
 301
 302 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 303
 304 =item C<ResFound>
 305
 306 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 307
 308 =item C<WasTransferred>
 309
 310 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 311
 312 =back
 313
 314 =back
 315
 316 =cut
 317
 318 sub transferbook {
 319     my $params = shift;
 320     my $tbr      = $params->{to_branch};
 321     my $fbr      = $params->{from_branch};
 322     my $ignoreRs = $params->{ignore_reserves};
 323     my $barcode  = $params->{barcode};
 324     my $trigger  = $params->{trigger};
 325     my $messages;
 326     my $dotransfer      = 1;
 327     my $item = Koha::Items->find( { barcode => $barcode } );
 328
 329     Koha::Exceptions::MissingParameter->throw(
 330         "Missing mandatory parameter: from_branch")
 331       unless $fbr;
 332
 333     Koha::Exceptions::MissingParameter->throw(
 334         "Missing mandatory parameter: to_branch")
 335       unless $tbr;
 336
 337     # bad barcode..
 338     unless ( $item ) {
 339         $messages->{'BadBarcode'} = $barcode;
 340         $dotransfer = 0;
 341         return ( $dotransfer, $messages );
 342     }
 343
 344     my $itemnumber = $item->itemnumber;
 345     # get branches of book...
 346     my $hbr = $item->homebranch;
 347
 348     # if using Branch Transfer Limits
 349     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 350         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 351         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 352             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 353                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 354                 $dotransfer = 0;
 355             }
 356         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 357             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 358             $dotransfer = 0;
 359         }
 360     }
 361
 362     # can't transfer book if is already there....
 363     if ( $fbr eq $tbr ) {
 364         $messages->{'DestinationEqualsHolding'} = 1;
 365         $dotransfer = 0;
 366     }
 367
 368     # check if it is still issued to someone, return it...
 369     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 370     if ( $issue ) {
 371         AddReturn( $barcode, $fbr );
 372         $messages->{'WasReturned'} = $issue->borrowernumber;
 373     }
 374
 375     # find reserves.....
 376     # That'll save a database query.
 377     my ( $resfound, $resrec, undef ) =
 378       CheckReserves( $itemnumber );
 379     if ( $resfound and not $ignoreRs ) {
 380         $resrec->{'ResFound'} = $resfound;
 381         $messages->{'ResFound'} = $resrec;
 382         $dotransfer = 1;
 383     }
 384
 385     #actually do the transfer....
 386     if ($dotransfer) {
 387         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 388
 389         # don't need to update MARC anymore, we do it in batch now
 390         $messages->{'WasTransfered'} = $tbr;
 391
 392     }
 393     ModDateLastSeen( $itemnumber );
 394     return ( $dotransfer, $messages );
 395 }
 396
 397
 398 sub TooMany {
 399     my $borrower        = shift;
 400     my $item_object = shift;
 401     my $params = shift;
 402     my $onsite_checkout = $params->{onsite_checkout} || 0;
 403     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 404     my $cat_borrower    = $borrower->{'categorycode'};
 405     my $dbh             = C4::Context->dbh;
 406     # Get which branchcode we need
 407     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 408     my $type = $item_object->effective_itemtype;
 409
 410     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 411     $type_object = Koha::ItemTypes->find( $type );
 412     $parent_type = $type_object->parent_type if $type_object;
 413     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 414     # Find any children if we are a parent_type;
 415
 416     # given branch, patron category, and item type, determine
 417     # applicable issuing rule
 418
 419     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 420         {
 421             categorycode => $cat_borrower,
 422             itemtype     => $parent_type,
 423             branchcode   => $branch,
 424             rule_name    => 'maxissueqty',
 425         }
 426     ) if $parent_type;
 427     # If the parent rule is for default type we discount it
 428     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 429
 430     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 431         {
 432             categorycode => $cat_borrower,
 433             itemtype     => $type,
 434             branchcode   => $branch,
 435             rule_name    => 'maxissueqty',
 436         }
 437     );
 438
 439     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 440         {
 441             categorycode => $cat_borrower,
 442             itemtype     => $type,
 443             branchcode   => $branch,
 444             rule_name    => 'maxonsiteissueqty',
 445         }
 446     );
 447
 448
 449     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 450     # if a rule is found and has a loan limit set, count
 451     # how many loans the patron already has that meet that
 452     # rule
 453     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 454
 455         my $checkouts;
 456         if ( $maxissueqty_rule->branchcode ) {
 457             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 458                 $checkouts = $patron->checkouts->search(
 459                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 460             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 461                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 462             } else {
 463                 $checkouts = $patron->checkouts->search(
 464                     { 'item.homebranch' => $maxissueqty_rule->branchcode },
 465                     { prefetch          => 'item' } );
 466             }
 467         } else {
 468             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 469         }
 470         my $sum_checkouts;
 471         my $rule_itemtype = $maxissueqty_rule->itemtype;
 472         while ( my $c = $checkouts->next ) {
 473             my $itemtype = $c->item->effective_itemtype;
 474             my @types;
 475             unless ( $rule_itemtype ) {
 476                 # matching rule has the default item type, so count only
 477                 # those existing loans that don't fall under a more
 478                 # specific rule
 479                 @types = Koha::CirculationRules->search(
 480                     {
 481                         branchcode => $maxissueqty_rule->branchcode,
 482                         categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 483                         itemtype  => { '!=' => undef },
 484                         rule_name => 'maxissueqty'
 485                     }
 486                 )->get_column('itemtype');
 487
 488                 next if grep {$_ eq $itemtype} @types;
 489             } else {
 490                 my @types;
 491                 if ( $parent_maxissueqty_rule ) {
 492                 # if we have a parent item type then we count loans of the
 493                 # specific item type or its siblings or parent
 494                     my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 495                     @types = $children->get_column('itemtype');
 496                     push @types, $parent_type;
 497                 } elsif ( $child_types ) {
 498                 # If we are a parent type, we need to count all child types and our own type
 499                     @types = $child_types->get_column('itemtype');
 500                     push @types, $type; # And don't forget to count our own types
 501                 } else { push @types, $type; } # Otherwise only count the specific itemtype
 502
 503                 next unless grep {$_ eq $itemtype} @types;
 504             }
 505             $sum_checkouts->{total}++;
 506             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 507             $sum_checkouts->{itemtype}->{$itemtype}++;
 508         }
 509
 510         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 511         my $checkout_count = $sum_checkouts->{total} || 0;
 512         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 513
 514         my $checkout_rules = {
 515             checkout_count               => $checkout_count,
 516             onsite_checkout_count        => $onsite_checkout_count,
 517             onsite_checkout              => $onsite_checkout,
 518             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 519             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 520             switch_onsite_checkout       => $switch_onsite_checkout,
 521         };
 522         # If parent rules exists
 523         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 524             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 525             my $qty_over = _check_max_qty($checkout_rules);
 526             return $qty_over if defined $qty_over;
 527
 528             # If the parent rule is less than or equal to the child, we only need check the parent
 529             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 530                 $checkout_rules->{checkout_count} = $checkout_count_type;
 531                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 532                 my $qty_over = _check_max_qty($checkout_rules);
 533                 return $qty_over if defined $qty_over;
 534             }
 535         } else {
 536             my $qty_over = _check_max_qty($checkout_rules);
 537             return $qty_over if defined $qty_over;
 538         }
 539     }
 540
 541     # Now count total loans against the limit for the branch
 542     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 543     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 544         my $checkouts;
 545         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 546             $checkouts = $patron->checkouts->search(
 547                 { 'me.branchcode' => $branch} );
 548         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 549             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 550         } else {
 551             $checkouts = $patron->checkouts->search(
 552                 { 'item.homebranch' => $branch},
 553                 { prefetch          => 'item' } );
 554         }
 555
 556         my $checkout_count = $checkouts->count;
 557         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 558         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 559         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 560
 561         my $qty_over = _check_max_qty(
 562             {
 563                 checkout_count               => $checkout_count,
 564                 onsite_checkout_count        => $onsite_checkout_count,
 565                 onsite_checkout              => $onsite_checkout,
 566                 max_checkouts_allowed        => $max_checkouts_allowed,
 567                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 568                 switch_onsite_checkout       => $switch_onsite_checkout
 569             }
 570         );
 571         return $qty_over if defined $qty_over;
 572     }
 573
 574     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 575         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 576     }
 577
 578     # OK, the patron can issue !!!
 579     return;
 580 }
 581
 582 sub _check_max_qty {
 583     my $params                       = shift;
 584     my $checkout_count               = $params->{checkout_count};
 585     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 586     my $onsite_checkout              = $params->{onsite_checkout};
 587     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 588     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 589     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 590
 591     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 592         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 593         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 594             return {
 595                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 596                 count       => $onsite_checkout_count,
 597                 max_allowed => $max_onsite_checkouts_allowed,
 598             };
 599         }
 600     }
 601     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 602         if ( $max_checkouts_allowed eq '' ) { return; }
 603         my $delta = $switch_onsite_checkout ? 1 : 0;
 604         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 605             return {
 606                 reason      => 'TOO_MANY_CHECKOUTS',
 607                 count       => $checkout_count,
 608                 max_allowed => $max_checkouts_allowed,
 609             };
 610         }
 611     }
 612     elsif ( not $onsite_checkout ) {
 613         if ( $max_checkouts_allowed eq '' ) { return; }
 614         if (
 615             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 616         {
 617             return {
 618                 reason      => 'TOO_MANY_CHECKOUTS',
 619                 count       => $checkout_count - $onsite_checkout_count,
 620                 max_allowed => $max_checkouts_allowed,
 621             };
 622         }
 623     }
 624
 625     return;
 626 }
 627
 628 =head2 CanBookBeIssued
 629
 630   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 631                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 632
 633 Check if a book can be issued.
 634
 635 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 636
 637 IMPORTANT: The assumption by users of this routine is that causes blocking
 638 the issue are keyed by uppercase labels and other returned
 639 data is keyed in lower case!
 640
 641 =over 4
 642
 643 =item C<$patron> is a Koha::Patron
 644
 645 =item C<$barcode> is the bar code of the book being issued.
 646
 647 =item C<$duedates> is a DateTime object.
 648
 649 =item C<$inprocess> boolean switch
 650
 651 =item C<$ignore_reserves> boolean switch
 652
 653 =item C<$params> Hashref of additional parameters
 654
 655 Available keys:
 656     override_high_holds - Ignore high holds
 657     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 658
 659 =back
 660
 661 Returns :
 662
 663 =over 4
 664
 665 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 666 Possible values are :
 667
 668 =back
 669
 670 =head3 INVALID_DATE
 671
 672 sticky due date is invalid
 673
 674 =head3 GNA
 675
 676 borrower gone with no address
 677
 678 =head3 CARD_LOST
 679
 680 borrower declared it's card lost
 681
 682 =head3 DEBARRED
 683
 684 borrower debarred
 685
 686 =head3 UNKNOWN_BARCODE
 687
 688 barcode unknown
 689
 690 =head3 NOT_FOR_LOAN
 691
 692 item is not for loan
 693
 694 =head3 WTHDRAWN
 695
 696 item withdrawn.
 697
 698 =head3 RESTRICTED
 699
 700 item is restricted (set by ??)
 701
 702 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 703 could be prevented, but ones that can be overriden by the operator.
 704
 705 Possible values are :
 706
 707 =head3 DEBT
 708
 709 borrower has debts.
 710
 711 =head3 RENEW_ISSUE
 712
 713 renewing, not issuing
 714
 715 =head3 ISSUED_TO_ANOTHER
 716
 717 issued to someone else.
 718
 719 =head3 RESERVED
 720
 721 reserved for someone else.
 722
 723 =head3 TRANSFERRED
 724
 725 reserved and being transferred for someone else.
 726
 727 =head3 INVALID_DATE
 728
 729 sticky due date is invalid or due date in the past
 730
 731 =head3 TOO_MANY
 732
 733 if the borrower borrows to much things
 734
 735 =cut
 736
 737 sub CanBookBeIssued {
 738     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 739     my %needsconfirmation;    # filled with problems that needs confirmations
 740     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 741     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 742     my %messages;             # filled with information messages that should be displayed.
 743
 744     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 745     my $override_high_holds = $params->{override_high_holds} || 0;
 746
 747     my $item_object = Koha::Items->find({barcode => $barcode });
 748
 749     # MANDATORY CHECKS - unless item exists, nothing else matters
 750     unless ( $item_object ) {
 751         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 752     }
 753     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 754
 755     my $item_unblessed = $item_object->unblessed; # Transition...
 756     my $issue = $item_object->checkout;
 757     my $biblio = $item_object->biblio;
 758
 759     my $biblioitem = $biblio->biblioitem;
 760     my $effective_itemtype = $item_object->effective_itemtype;
 761     my $dbh             = C4::Context->dbh;
 762     my $patron_unblessed = $patron->unblessed;
 763
 764     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 765     #
 766     # DUE DATE is OK ? -- should already have checked.
 767     #
 768     if ($duedate && ref $duedate ne 'DateTime') {
 769         $duedate = dt_from_string($duedate);
 770     }
 771     my $now = dt_from_string();
 772     unless ( $duedate ) {
 773         my $issuedate = $now->clone();
 774
 775         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 776
 777         # Offline circ calls AddIssue directly, doesn't run through here
 778         #  So issuingimpossible should be ok.
 779     }
 780
 781     my $fees = Koha::Charges::Fees->new(
 782         {
 783             patron    => $patron,
 784             library   => $circ_library,
 785             item      => $item_object,
 786             to_date   => $duedate,
 787         }
 788     );
 789
 790     if ($duedate) {
 791         my $today = $now->clone();
 792         $today->truncate( to => 'minute');
 793         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 794             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 795         }
 796     } else {
 797             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 798     }
 799
 800     #
 801     # BORROWER STATUS
 802     #
 803     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 804         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 805         &UpdateStats({
 806                      branch => C4::Context->userenv->{'branch'},
 807                      type => 'localuse',
 808                      itemnumber => $item_object->itemnumber,
 809                      itemtype => $effective_itemtype,
 810                      borrowernumber => $patron->borrowernumber,
 811                      ccode => $item_object->ccode}
 812                     );
 813         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 814         return( { STATS => 1 }, {});
 815     }
 816
 817     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 818         $issuingimpossible{GNA} = 1;
 819     }
 820
 821     if ( $patron->lost && $patron->lost == 1 ) {
 822         $issuingimpossible{CARD_LOST} = 1;
 823     }
 824     if ( $patron->is_debarred ) {
 825         $issuingimpossible{DEBARRED} = 1;
 826     }
 827
 828     if ( $patron->is_expired ) {
 829         $issuingimpossible{EXPIRED} = 1;
 830     }
 831
 832     #
 833     # BORROWER STATUS
 834     #
 835
 836     # DEBTS
 837     my $account = $patron->account;
 838     my $balance = $account->balance;
 839     my $non_issues_charges = $account->non_issues_charges;
 840     my $other_charges = $balance - $non_issues_charges;
 841
 842     my $amountlimit = C4::Context->preference("noissuescharge");
 843     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 844     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 845
 846     # Check the debt of this patrons guarantees
 847     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 848     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 849     if ( defined $no_issues_charge_guarantees ) {
 850         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 851         my $guarantees_non_issues_charges = 0;
 852         foreach my $g ( @guarantees ) {
 853             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 854         }
 855
 856         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 857             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 858         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 859             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 860         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 861             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 862         }
 863     }
 864
 865     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 866     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 867     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 868     if ( defined $no_issues_charge_guarantors ) {
 869         my $guarantors_non_issues_charges += $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 870
 871         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 872             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 873         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 874             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 875         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 876             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 877         }
 878     }
 879
 880     if ( C4::Context->preference("IssuingInProcess") ) {
 881         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 882             $issuingimpossible{DEBT} = $non_issues_charges;
 883         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 884             $needsconfirmation{DEBT} = $non_issues_charges;
 885         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 886             $needsconfirmation{DEBT} = $non_issues_charges;
 887         }
 888     }
 889     else {
 890         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 891             $needsconfirmation{DEBT} = $non_issues_charges;
 892         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 893             $issuingimpossible{DEBT} = $non_issues_charges;
 894         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 895             $needsconfirmation{DEBT} = $non_issues_charges;
 896         }
 897     }
 898
 899     if ($balance > 0 && $other_charges > 0) {
 900         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 901     }
 902
 903     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 904     $patron_unblessed = $patron->unblessed;
 905
 906     if ( my $debarred_date = $patron->is_debarred ) {
 907          # patron has accrued fine days or has a restriction. $count is a date
 908         if ($debarred_date eq '9999-12-31') {
 909             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 910         }
 911         else {
 912             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 913         }
 914     } elsif ( my $num_overdues = $patron->has_overdues ) {
 915         ## patron has outstanding overdue loans
 916         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 917             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 918         }
 919         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 920             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 921         }
 922     }
 923
 924     # Additional Materials Check
 925     if ( C4::Context->preference("CircConfirmItemParts")
 926         && $item_object->materials )
 927     {
 928         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 929     }
 930
 931     #
 932     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 933     #
 934     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 935
 936         # Already issued to current borrower.
 937         # If it is an on-site checkout if it can be switched to a normal checkout
 938         # or ask whether the loan should be renewed
 939
 940         if ( $issue->onsite_checkout
 941                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 942             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 943         } else {
 944             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 945                 $patron->borrowernumber,
 946                 $item_object->itemnumber,
 947             );
 948             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 949                 if ( $renewerror eq 'onsite_checkout' ) {
 950                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 951                 }
 952                 else {
 953                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 954                 }
 955             }
 956             else {
 957                 $needsconfirmation{RENEW_ISSUE} = 1;
 958             }
 959         }
 960     }
 961     elsif ( $issue ) {
 962
 963         # issued to someone else
 964
 965         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 966
 967         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 968
 969         unless ( $can_be_returned ) {
 970             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 971             $issuingimpossible{branch_to_return} = $message;
 972         } else {
 973             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 974                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 975             } else {
 976             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 977             $needsconfirmation{issued_firstname} = $patron->firstname;
 978             $needsconfirmation{issued_surname} = $patron->surname;
 979             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 980             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 981             }
 982         }
 983     }
 984
 985     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 986     #
 987     my $switch_onsite_checkout = (
 988           C4::Context->preference('SwitchOnSiteCheckouts')
 989       and $issue
 990       and $issue->onsite_checkout
 991       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 992     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 993     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 994     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 995         if ( $toomany->{max_allowed} == 0 ) {
 996             $needsconfirmation{PATRON_CANT} = 1;
 997         }
 998         if ( C4::Context->preference("AllowTooManyOverride") ) {
 999             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1000             $needsconfirmation{current_loan_count} = $toomany->{count};
1001             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1002         } else {
1003             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1004             $issuingimpossible{current_loan_count} = $toomany->{count};
1005             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1006         }
1007     }
1008
1009     #
1010     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1011     #
1012     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1013     my $wants_check = $patron->wants_check_for_previous_checkout;
1014     $needsconfirmation{PREVISSUE} = 1
1015         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1016
1017     #
1018     # ITEM CHECKING
1019     #
1020     if ( $item_object->notforloan )
1021     {
1022         if(!C4::Context->preference("AllowNotForLoanOverride")){
1023             $issuingimpossible{NOT_FOR_LOAN} = 1;
1024             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1025         }else{
1026             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1027             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1028         }
1029     }
1030     else {
1031         # we have to check itemtypes.notforloan also
1032         if (C4::Context->preference('item-level_itypes')){
1033             # this should probably be a subroutine
1034             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1035             $sth->execute($effective_itemtype);
1036             my $notforloan=$sth->fetchrow_hashref();
1037             if ($notforloan->{'notforloan'}) {
1038                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1039                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1040                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1041                 } else {
1042                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1043                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1044                 }
1045             }
1046         }
1047         else {
1048             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1049             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1050                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1051                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1052                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1053                 } else {
1054                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1055                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1056                 }
1057             }
1058         }
1059     }
1060     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1061     {
1062         $issuingimpossible{WTHDRAWN} = 1;
1063     }
1064     if (   $item_object->restricted
1065         && $item_object->restricted == 1 )
1066     {
1067         $issuingimpossible{RESTRICTED} = 1;
1068     }
1069     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1070         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1071         my $code = $av->count ? $av->next->lib : '';
1072         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1073         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1074     }
1075     if ( C4::Context->preference("IndependentBranches") ) {
1076         my $userenv = C4::Context->userenv;
1077         unless ( C4::Context->IsSuperLibrarian() ) {
1078             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1079             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1080                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1081                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1082             }
1083             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1084               if ( $patron->branchcode ne $userenv->{branch} );
1085         }
1086     }
1087
1088     #
1089     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1090     #
1091     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1092     if ($rentalConfirmation) {
1093         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1094
1095         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1096         if ($itemtype_object) {
1097             my $accumulate_charge = $fees->accumulate_rentalcharge();
1098             if ( $accumulate_charge > 0 ) {
1099                 $rentalCharge += $accumulate_charge;
1100             }
1101         }
1102
1103         if ( $rentalCharge > 0 ) {
1104             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1105         }
1106     }
1107
1108     unless ( $ignore_reserves ) {
1109         # See if the item is on reserve.
1110         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1111         if ($restype) {
1112             my $resbor = $res->{'borrowernumber'};
1113             if ( $resbor ne $patron->borrowernumber ) {
1114                 my $patron = Koha::Patrons->find( $resbor );
1115                 if ( $restype eq "Waiting" )
1116                 {
1117                     # The item is on reserve and waiting, but has been
1118                     # reserved by some other patron.
1119                     $needsconfirmation{RESERVE_WAITING} = 1;
1120                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1121                     $needsconfirmation{'ressurname'} = $patron->surname;
1122                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1123                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1124                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1125                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1126                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1127                 }
1128                 elsif ( $restype eq "Reserved" ) {
1129                     # The item is on reserve for someone else.
1130                     $needsconfirmation{RESERVED} = 1;
1131                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1132                     $needsconfirmation{'ressurname'} = $patron->surname;
1133                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1134                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1135                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1136                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1137                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1138                 }
1139                 elsif ( $restype eq "Transferred" ) {
1140                     # The item is determined hold being transferred for someone else.
1141                     $needsconfirmation{TRANSFERRED} = 1;
1142                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1143                     $needsconfirmation{'ressurname'} = $patron->surname;
1144                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1145                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1146                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1147                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1148                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1149                 }
1150             }
1151         }
1152     }
1153
1154     ## CHECK AGE RESTRICTION
1155     my $agerestriction  = $biblioitem->agerestriction;
1156     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1157     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1158         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1159             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1160         }
1161         else {
1162             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1163         }
1164     }
1165
1166     ## check for high holds decreasing loan period
1167     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1168         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1169
1170         if ( $check->{exceeded} ) {
1171             if ($override_high_holds) {
1172                 $alerts{HIGHHOLDS} = {
1173                     num_holds  => $check->{outstanding},
1174                     duration   => $check->{duration},
1175                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1176                 };
1177             }
1178             else {
1179                 $needsconfirmation{HIGHHOLDS} = {
1180                     num_holds  => $check->{outstanding},
1181                     duration   => $check->{duration},
1182                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1183                 };
1184             }
1185         }
1186     }
1187
1188     if (
1189         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1190         # don't do the multiple loans per bib check if we've
1191         # already determined that we've got a loan on the same item
1192         !$issuingimpossible{NO_MORE_RENEWALS} &&
1193         !$needsconfirmation{RENEW_ISSUE}
1194     ) {
1195         # Check if borrower has already issued an item from the same biblio
1196         # Only if it's not a subscription
1197         my $biblionumber = $item_object->biblionumber;
1198         require C4::Serials;
1199         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1200         unless ($is_a_subscription) {
1201             # FIXME Should be $patron->checkouts($args);
1202             my $checkouts = Koha::Checkouts->search(
1203                 {
1204                     borrowernumber => $patron->borrowernumber,
1205                     biblionumber   => $biblionumber,
1206                 },
1207                 {
1208                     join => 'item',
1209                 }
1210             );
1211             # if we get here, we don't already have a loan on this item,
1212             # so if there are any loans on this bib, ask for confirmation
1213             if ( $checkouts->count ) {
1214                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1215             }
1216         }
1217     }
1218
1219     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1220 }
1221
1222 =head2 CanBookBeReturned
1223
1224   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1225
1226 Check whether the item can be returned to the provided branch
1227
1228 =over 4
1229
1230 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1231
1232 =item C<$branch> is the branchcode where the return is taking place
1233
1234 =back
1235
1236 Returns:
1237
1238 =over 4
1239
1240 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1241
1242 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1243
1244 =back
1245
1246 =cut
1247
1248 sub CanBookBeReturned {
1249   my ($item, $branch) = @_;
1250   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1251
1252   # assume return is allowed to start
1253   my $allowed = 1;
1254   my $message;
1255
1256   # identify all cases where return is forbidden
1257   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1258      $allowed = 0;
1259      $message = $item->{'homebranch'};
1260   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1261      $allowed = 0;
1262      $message = $item->{'holdingbranch'};
1263   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1264      $allowed = 0;
1265      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1266   }
1267
1268   return ($allowed, $message);
1269 }
1270
1271 =head2 CheckHighHolds
1272
1273     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1274     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1275     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1276
1277 =cut
1278
1279 sub checkHighHolds {
1280     my ( $item, $borrower ) = @_;
1281     my $branchcode = _GetCircControlBranch( $item, $borrower );
1282     my $item_object = Koha::Items->find( $item->{itemnumber} );
1283
1284     my $return_data = {
1285         exceeded    => 0,
1286         outstanding => 0,
1287         duration    => 0,
1288         due_date    => undef,
1289     };
1290
1291     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1292
1293     if ( $holds->count() ) {
1294         $return_data->{outstanding} = $holds->count();
1295
1296         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1297         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1298         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1299
1300         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1301
1302         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1303
1304             # static means just more than a given number of holds on the record
1305
1306             # If the number of holds is less than the threshold, we can stop here
1307             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1308                 return $return_data;
1309             }
1310         }
1311         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1312
1313             # dynamic means X more than the number of holdable items on the record
1314
1315             # let's get the items
1316             my @items = $holds->next()->biblio()->items()->as_list;
1317
1318             # Remove any items with status defined to be ignored even if the would not make item unholdable
1319             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1320                 @items = grep { !$_->$status } @items;
1321             }
1322
1323             # Remove any items that are not holdable for this patron
1324             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1325
1326             my $items_count = scalar @items;
1327
1328             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1329
1330             # If the number of holds is less than the count of items we have
1331             # plus the number of holds allowed above that count, we can stop here
1332             if ( $holds->count() <= $threshold ) {
1333                 return $return_data;
1334             }
1335         }
1336
1337         my $issuedate = dt_from_string();
1338
1339         my $itype = $item_object->effective_itemtype;
1340         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1341             {
1342                 categorycode => $borrower->{categorycode},
1343                 itemtype     => $itype,
1344                 branchcode   => $branchcode,
1345             }
1346         );
1347         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1348
1349         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1350
1351         my $rule = Koha::CirculationRules->get_effective_rule(
1352             {
1353                 categorycode => $borrower->{categorycode},
1354                 itemtype     => $item_object->effective_itemtype,
1355                 branchcode   => $branchcode,
1356                 rule_name    => 'decreaseloanholds',
1357             }
1358         );
1359
1360         my $duration;
1361         if ( defined($rule) && $rule->rule_value ne '' ){
1362             # overrides decreaseLoanHighHoldsDuration syspref
1363             $duration = $rule->rule_value;
1364         } else {
1365             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1366         }
1367         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1368         $reduced_datedue->set_hour($orig_due->hour);
1369         $reduced_datedue->set_minute($orig_due->minute);
1370         $reduced_datedue->truncate( to => 'minute' );
1371
1372         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1373             $return_data->{exceeded} = 1;
1374             $return_data->{duration} = $duration;
1375             $return_data->{due_date} = $reduced_datedue;
1376         }
1377     }
1378
1379     return $return_data;
1380 }
1381
1382 =head2 AddIssue
1383
1384   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1385
1386 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1387
1388 =over 4
1389
1390 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1391
1392 =item C<$barcode> is the barcode of the item being issued.
1393
1394 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1395 Calculated if empty.
1396
1397 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1398
1399 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1400 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1401
1402 AddIssue does the following things :
1403
1404   - step 01: check that there is a borrowernumber & a barcode provided
1405   - check for RENEWAL (book issued & being issued to the same patron)
1406       - renewal YES = Calculate Charge & renew
1407       - renewal NO  =
1408           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1409           * RESERVE PLACED ?
1410               - fill reserve if reserve to this patron
1411               - cancel reserve or not, otherwise
1412           * TRANSFERT PENDING ?
1413               - complete the transfert
1414           * ISSUE THE BOOK
1415
1416 =back
1417
1418 =cut
1419
1420 sub AddIssue {
1421     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1422
1423     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1424     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1425     my $auto_renew = $params && $params->{auto_renew};
1426     my $dbh          = C4::Context->dbh;
1427     my $barcodecheck = CheckValidBarcode($barcode);
1428
1429     my $issue;
1430
1431     if ( $datedue && ref $datedue ne 'DateTime' ) {
1432         $datedue = dt_from_string($datedue);
1433     }
1434
1435     # $issuedate defaults to today.
1436     if ( !defined $issuedate ) {
1437         $issuedate = dt_from_string();
1438     }
1439     else {
1440         if ( ref $issuedate ne 'DateTime' ) {
1441             $issuedate = dt_from_string($issuedate);
1442
1443         }
1444     }
1445
1446     # Stop here if the patron or barcode doesn't exist
1447     if ( $borrower && $barcode && $barcodecheck ) {
1448         # find which item we issue
1449         my $item_object = Koha::Items->find({ barcode => $barcode })
1450           or return;    # if we don't get an Item, abort.
1451         my $item_unblessed = $item_object->unblessed;
1452
1453         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1454
1455         # get actual issuing if there is one
1456         my $actualissue = $item_object->checkout;
1457
1458         # check if we just renew the issue.
1459         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1460                 and not $switch_onsite_checkout ) {
1461             $datedue = AddRenewal(
1462                 $borrower->{'borrowernumber'},
1463                 $item_object->itemnumber,
1464                 $branchcode,
1465                 $datedue,
1466                 $issuedate,    # here interpreted as the renewal date
1467             );
1468         }
1469         else {
1470             unless ($datedue) {
1471                 my $itype = $item_object->effective_itemtype;
1472                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1473
1474             }
1475             $datedue->truncate( to => 'minute' );
1476
1477             my $patron = Koha::Patrons->find( $borrower );
1478             my $library = Koha::Libraries->find( $branchcode );
1479             my $fees = Koha::Charges::Fees->new(
1480                 {
1481                     patron    => $patron,
1482                     library   => $library,
1483                     item      => $item_object,
1484                     to_date   => $datedue,
1485                 }
1486             );
1487
1488             # it's NOT a renewal
1489             if ( $actualissue and not $switch_onsite_checkout ) {
1490                 # This book is currently on loan, but not to the person
1491                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1492                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1493                 return unless $allowed;
1494                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1495                 # AddReturn certainly has side-effects, like onloan => undef
1496                 $item_object->discard_changes;
1497             }
1498
1499             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1500
1501             # Starting process for transfer job (checking transfert and validate it if we have one)
1502             if ( my $transfer = $item_object->get_transfer ) {
1503                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1504                 $transfer->set(
1505                     {
1506                         datearrived => dt_from_string,
1507                         tobranch    => C4::Context->userenv->{branch},
1508                         comments    => 'Forced branchtransfer'
1509                     }
1510                 )->store;
1511                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1512                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1513                     if ( $hold ) { # Is this really needed?
1514                         $hold->set( { found => undef } )->store;
1515                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1516                     }
1517                 }
1518             }
1519
1520             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1521             unless ($auto_renew) {
1522                 my $rule = Koha::CirculationRules->get_effective_rule(
1523                     {
1524                         categorycode => $borrower->{categorycode},
1525                         itemtype     => $item_object->effective_itemtype,
1526                         branchcode   => $branchcode,
1527                         rule_name    => 'auto_renew'
1528                     }
1529                 );
1530
1531                 $auto_renew = $rule->rule_value if $rule;
1532             }
1533
1534             my $issue_attributes = {
1535                 borrowernumber  => $borrower->{'borrowernumber'},
1536                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1537                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1538                 branchcode      => C4::Context->userenv->{'branch'},
1539                 onsite_checkout => $onsite_checkout,
1540                 auto_renew      => $auto_renew ? 1 : 0,
1541             };
1542
1543             # Get ID of logged in user.  if called from a batch job,
1544             # no user session exists and C4::Context->userenv() returns
1545             # the scalar '0'. Only do this if the syspref says so
1546             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1547                 my $userenv = C4::Context->userenv();
1548                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1549                 if ($usernumber) {
1550                     $issue_attributes->{issuer_id} = $usernumber;
1551                 }
1552             }
1553
1554             # In the case that the borrower has an on-site checkout
1555             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1556             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1557             if ($issue) {
1558                 $issue->set($issue_attributes)->store;
1559             }
1560             else {
1561                 $issue = Koha::Checkout->new(
1562                     {
1563                         itemnumber => $item_object->itemnumber,
1564                         %$issue_attributes,
1565                     }
1566                 )->store;
1567             }
1568             $issue->discard_changes;
1569             if ( $item_object->location && $item_object->location eq 'CART'
1570                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1571             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1572                 CartToShelf( $item_object->itemnumber );
1573             }
1574
1575             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1576                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1577             }
1578
1579             # Record if item was lost
1580             my $was_lost = $item_object->itemlost;
1581
1582             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1583             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1584             $item_object->itemlost(0);
1585             $item_object->onloan($datedue->ymd());
1586             $item_object->datelastborrowed( dt_from_string()->ymd() );
1587             $item_object->datelastseen( dt_from_string()->ymd() );
1588             $item_object->store({log_action => 0});
1589
1590             # If the item was lost, it has now been found, charge the overdue if necessary
1591             if ($was_lost) {
1592                 if ( $item_object->{_charge} ) {
1593                     $actualissue //= Koha::Old::Checkouts->search(
1594                         { itemnumber => $item_unblessed->{itemnumber} },
1595                         {
1596                             order_by => { '-desc' => 'returndate' },
1597                             rows     => 1
1598                         }
1599                     )->single;
1600                     unless ( exists( $borrower->{branchcode} ) ) {
1601                         my $patron = $actualissue->patron;
1602                         $borrower = $patron->unblessed;
1603                     }
1604                     _CalculateAndUpdateFine(
1605                         {
1606                             issue       => $actualissue,
1607                             item        => $item_unblessed,
1608                             borrower    => $borrower,
1609                             return_date => $issuedate
1610                         }
1611                     );
1612                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1613                         $item_object->itemnumber, undef, 'RENEWED' );
1614                 }
1615             }
1616
1617             # If it costs to borrow this book, charge it to the patron's account.
1618             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1619             if ( $charge && $charge > 0 ) {
1620                 AddIssuingCharge( $issue, $charge, 'RENT' );
1621             }
1622
1623             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1624             if ( $itemtype_object ) {
1625                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1626                 if ( $accumulate_charge > 0 ) {
1627                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1628                     $charge += $accumulate_charge;
1629                     $item_unblessed->{charge} = $charge;
1630                 }
1631             }
1632
1633             # Record the fact that this book was issued.
1634             &UpdateStats(
1635                 {
1636                     branch => C4::Context->userenv->{'branch'},
1637                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1638                     amount         => $charge,
1639                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1640                     itemnumber     => $item_object->itemnumber,
1641                     itemtype       => $item_object->effective_itemtype,
1642                     location       => $item_object->location,
1643                     borrowernumber => $borrower->{'borrowernumber'},
1644                     ccode          => $item_object->ccode,
1645                 }
1646             );
1647
1648             # Send a checkout slip.
1649             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1650             my %conditions        = (
1651                 branchcode   => $branchcode,
1652                 categorycode => $borrower->{categorycode},
1653                 item_type    => $item_object->effective_itemtype,
1654                 notification => 'CHECKOUT',
1655             );
1656             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1657                 SendCirculationAlert(
1658                     {
1659                         type     => 'CHECKOUT',
1660                         item     => $item_object->unblessed,
1661                         borrower => $borrower,
1662                         branch   => $branchcode,
1663                     }
1664                 );
1665             }
1666             logaction(
1667                 "CIRCULATION", "ISSUE",
1668                 $borrower->{'borrowernumber'},
1669                 $item_object->itemnumber,
1670             ) if C4::Context->preference("IssueLog");
1671
1672             Koha::Plugins->call('after_circ_action', {
1673                 action  => 'checkout',
1674                 payload => {
1675                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1676                     checkout => $issue->get_from_storage
1677                 }
1678             });
1679         }
1680     }
1681     return $issue;
1682 }
1683
1684 =head2 GetLoanLength
1685
1686   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1687
1688 Get loan length for an itemtype, a borrower type and a branch
1689
1690 =cut
1691
1692 sub GetLoanLength {
1693     my ( $categorycode, $itemtype, $branchcode ) = @_;
1694
1695     # Initialize default values
1696     my $rules = {
1697         issuelength   => 0,
1698         renewalperiod => 0,
1699         lengthunit    => 'days',
1700     };
1701
1702     my $found = Koha::CirculationRules->get_effective_rules( {
1703         branchcode => $branchcode,
1704         categorycode => $categorycode,
1705         itemtype => $itemtype,
1706         rules => [
1707             'issuelength',
1708             'renewalperiod',
1709             'lengthunit'
1710         ],
1711     } );
1712
1713     # Search for rules!
1714     foreach my $rule_name (keys %$found) {
1715         $rules->{$rule_name} = $found->{$rule_name};
1716     }
1717
1718     return $rules;
1719 }
1720
1721
1722 =head2 GetHardDueDate
1723
1724   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1725
1726 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1727
1728 =cut
1729
1730 sub GetHardDueDate {
1731     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1732
1733     my $rules = Koha::CirculationRules->get_effective_rules(
1734         {
1735             categorycode => $borrowertype,
1736             itemtype     => $itemtype,
1737             branchcode   => $branchcode,
1738             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1739         }
1740     );
1741
1742     if ( defined( $rules->{hardduedate} ) ) {
1743         if ( $rules->{hardduedate} ) {
1744             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1745         }
1746         else {
1747             return ( undef, undef );
1748         }
1749     }
1750 }
1751
1752 =head2 GetBranchBorrowerCircRule
1753
1754   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1755
1756 Retrieves circulation rule attributes that apply to the given
1757 branch and patron category, regardless of item type.
1758 The return value is a hashref containing the following key:
1759
1760 patron_maxissueqty - maximum number of loans that a
1761 patron of the given category can have at the given
1762 branch.  If the value is undef, no limit.
1763
1764 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1765 patron of the given category can have at the given
1766 branch.  If the value is undef, no limit.
1767
1768 This will check for different branch/category combinations in the following order:
1769 branch and category
1770 branch only
1771 category only
1772 default branch and category
1773
1774 If no rule has been found in the database, it will default to
1775 the buillt in rule:
1776
1777 patron_maxissueqty - undef
1778 patron_maxonsiteissueqty - undef
1779
1780 C<$branchcode> and C<$categorycode> should contain the
1781 literal branch code and patron category code, respectively - no
1782 wildcards.
1783
1784 =cut
1785
1786 sub GetBranchBorrowerCircRule {
1787     my ( $branchcode, $categorycode ) = @_;
1788
1789     # Initialize default values
1790     my $rules = {
1791         patron_maxissueqty       => undef,
1792         patron_maxonsiteissueqty => undef,
1793     };
1794
1795     # Search for rules!
1796     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1797         my $rule = Koha::CirculationRules->get_effective_rule(
1798             {
1799                 categorycode => $categorycode,
1800                 itemtype     => undef,
1801                 branchcode   => $branchcode,
1802                 rule_name    => $rule_name,
1803             }
1804         );
1805
1806         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1807     }
1808
1809     return $rules;
1810 }
1811
1812 =head2 GetBranchItemRule
1813
1814   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1815
1816 Retrieves circulation rule attributes that apply to the given
1817 branch and item type, regardless of patron category.
1818
1819 The return value is a hashref containing the following keys:
1820
1821 holdallowed => Hold policy for this branch and itemtype. Possible values:
1822   0: No holds allowed.
1823   1: Holds allowed only by patrons that have the same homebranch as the item.
1824   2: Holds allowed from any patron.
1825
1826 returnbranch => branch to which to return item.  Possible values:
1827   noreturn: do not return, let item remain where checked in (floating collections)
1828   homebranch: return to item's home branch
1829   holdingbranch: return to issuer branch
1830
1831 This searches branchitemrules in the following order:
1832
1833   * Same branchcode and itemtype
1834   * Same branchcode, itemtype '*'
1835   * branchcode '*', same itemtype
1836   * branchcode and itemtype '*'
1837
1838 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1839
1840 =cut
1841
1842 sub GetBranchItemRule {
1843     my ( $branchcode, $itemtype ) = @_;
1844
1845     # Search for rules!
1846     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1847         {
1848             branchcode => $branchcode,
1849             itemtype => $itemtype,
1850             rule_name => 'holdallowed',
1851         }
1852     );
1853     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1854         {
1855             branchcode => $branchcode,
1856             itemtype => $itemtype,
1857             rule_name => 'hold_fulfillment_policy',
1858         }
1859     );
1860     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1861         {
1862             branchcode => $branchcode,
1863             itemtype => $itemtype,
1864             rule_name => 'returnbranch',
1865         }
1866     );
1867
1868     # built-in default circulation rule
1869     my $rules;
1870     $rules->{holdallowed} = defined $holdallowed_rule
1871         ? $holdallowed_rule->rule_value
1872         : 2;
1873     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1874         ? $hold_fulfillment_policy_rule->rule_value
1875         : 'any';
1876     $rules->{returnbranch} = defined $returnbranch_rule
1877         ? $returnbranch_rule->rule_value
1878         : 'homebranch';
1879
1880     return $rules;
1881 }
1882
1883 =head2 AddReturn
1884
1885   ($doreturn, $messages, $iteminformation, $borrower) =
1886       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1887
1888 Returns a book.
1889
1890 =over 4
1891
1892 =item C<$barcode> is the bar code of the book being returned.
1893
1894 =item C<$branch> is the code of the branch where the book is being returned.
1895
1896 =item C<$exemptfine> indicates that overdue charges for the item will be
1897 removed. Optional.
1898
1899 =item C<$return_date> allows the default return date to be overridden
1900 by the given return date. Optional.
1901
1902 =back
1903
1904 C<&AddReturn> returns a list of four items:
1905
1906 C<$doreturn> is true iff the return succeeded.
1907
1908 C<$messages> is a reference-to-hash giving feedback on the operation.
1909 The keys of the hash are:
1910
1911 =over 4
1912
1913 =item C<BadBarcode>
1914
1915 No item with this barcode exists. The value is C<$barcode>.
1916
1917 =item C<NotIssued>
1918
1919 The book is not currently on loan. The value is C<$barcode>.
1920
1921 =item C<withdrawn>
1922
1923 This book has been withdrawn/cancelled. The value should be ignored.
1924
1925 =item C<Wrongbranch>
1926
1927 This book has was returned to the wrong branch.  The value is a hashref
1928 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1929 contain the branchcode of the incorrect and correct return library, respectively.
1930
1931 =item C<ResFound>
1932
1933 The item was reserved. The value is a reference-to-hash whose keys are
1934 fields from the reserves table of the Koha database, and
1935 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1936 either C<Waiting>, C<Reserved>, or 0.
1937
1938 =item C<WasReturned>
1939
1940 Value 1 if return is successful.
1941
1942 =item C<NeedsTransfer>
1943
1944 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1945
1946 =back
1947
1948 C<$iteminformation> is a reference-to-hash, giving information about the
1949 returned item from the issues table.
1950
1951 C<$borrower> is a reference-to-hash, giving information about the
1952 patron who last borrowed the book.
1953
1954 =cut
1955
1956 sub AddReturn {
1957     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1958
1959     if ($branch and not Koha::Libraries->find($branch)) {
1960         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1961         undef $branch;
1962     }
1963     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1964     my $return_date_specified = !!$return_date;
1965     $return_date //= dt_from_string();
1966     my $messages;
1967     my $patron;
1968     my $doreturn       = 1;
1969     my $validTransfer = 1;
1970     my $stat_type = 'return';
1971
1972     # get information on item
1973     my $item = Koha::Items->find({ barcode => $barcode });
1974     unless ($item) {
1975         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1976     }
1977
1978     my $itemnumber = $item->itemnumber;
1979     my $itemtype = $item->effective_itemtype;
1980
1981     my $issue  = $item->checkout;
1982     if ( $issue ) {
1983         $patron = $issue->patron
1984             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1985                 . Dumper($issue->unblessed) . "\n";
1986     } else {
1987         $messages->{'NotIssued'} = $barcode;
1988         $item->onloan(undef)->store({skip_record_index=>1}) if defined $item->onloan;
1989
1990         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1991         $doreturn = 0;
1992         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1993         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1994         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1995            $messages->{'LocalUse'} = 1;
1996            $stat_type = 'localuse';
1997         }
1998     }
1999
2000         # full item data, but no borrowernumber or checkout info (no issue)
2001     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2002         # get the proper branch to which to return the item
2003     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2004         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2005     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2006
2007     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2008     my $patron_unblessed = $patron ? $patron->unblessed : {};
2009
2010     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2011     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2012     if ($update_loc_rules) {
2013         if (defined $update_loc_rules->{_ALL_}) {
2014             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2015             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2016             if ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) {
2017                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2018                 $item->location($update_loc_rules->{_ALL_})->store({skip_record_index=>1});
2019             }
2020         }
2021         else {
2022             foreach my $key ( keys %$update_loc_rules ) {
2023                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2024                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2025                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2026                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2027                     $item->location($update_loc_rules->{$key})->store({skip_record_index=>1});
2028                     last;
2029                 }
2030             }
2031         }
2032     }
2033
2034     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2035     if ($yaml) {
2036         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2037         my $rules;
2038         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2039         if ($@) {
2040             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2041         }
2042         else {
2043             foreach my $key ( keys %$rules ) {
2044                 if ( $item->notforloan eq $key ) {
2045                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2046                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
2047                     last;
2048                 }
2049             }
2050         }
2051     }
2052
2053     # check if the return is allowed at this branch
2054     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2055     unless ($returnallowed){
2056         $messages->{'Wrongbranch'} = {
2057             Wrongbranch => $branch,
2058             Rightbranch => $message
2059         };
2060         $doreturn = 0;
2061         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2062         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2063         return ( $doreturn, $messages, $issue, $patron_unblessed);
2064     }
2065
2066     if ( $item->withdrawn ) { # book has been cancelled
2067         $messages->{'withdrawn'} = 1;
2068         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2069     }
2070
2071     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2072         $doreturn = 0;
2073     }
2074
2075     # case of a return of document (deal with issues and holdingbranch)
2076     if ($doreturn) {
2077         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2078         $patron or warn "AddReturn without current borrower";
2079
2080         if ($patron) {
2081             eval {
2082                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1} );
2083             };
2084             unless ( $@ ) {
2085                 if (
2086                     (
2087                         C4::Context->preference('CalculateFinesOnReturn')
2088                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2089                     )
2090                     && !$item->itemlost
2091                   )
2092                 {
2093                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2094                 }
2095             } else {
2096                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2097
2098                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2099                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2100
2101                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2102             }
2103
2104             # FIXME is the "= 1" right?  This could be the borrower hash.
2105             $messages->{'WasReturned'} = 1;
2106
2107         } else {
2108             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1 });
2109         }
2110     }
2111
2112     # the holdingbranch is updated if the document is returned to another location.
2113     # this is always done regardless of whether the item was on loan or not
2114     if ($item->holdingbranch ne $branch) {
2115         $item->holdingbranch($branch)->store({ skip_record_index => 1 });
2116     }
2117
2118     my $item_was_lost = $item->itemlost;
2119     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2120     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1 } ); # will unset itemlost if needed
2121
2122     # fix up the accounts.....
2123     if ($item_was_lost) {
2124         $messages->{'WasLost'} = 1;
2125         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2126             $messages->{'LostItemFeeRefunded'} = $updated_item->{_refunded};
2127             $messages->{'LostItemFeeRestored'} = $updated_item->{_restored};
2128
2129             if ( $updated_item->{_charge} ) {
2130                 $issue //= Koha::Old::Checkouts->search(
2131                     { itemnumber => $item->itemnumber },
2132                     { order_by   => { '-desc' => 'returndate' }, rows => 1 } )
2133                   ->single;
2134                 unless ( exists( $patron_unblessed->{branchcode} ) ) {
2135                     my $patron = $issue->patron;
2136                     $patron_unblessed = $patron->unblessed;
2137                 }
2138                 _CalculateAndUpdateFine(
2139                     {
2140                         issue       => $issue,
2141                         item        => $item->unblessed,
2142                         borrower    => $patron_unblessed,
2143                         return_date => $return_date
2144                     }
2145                 );
2146                 _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2147                     $item->itemnumber, undef, 'RETURNED' );
2148                 $messages->{'LostItemFeeCharged'} = 1;
2149             }
2150         }
2151     }
2152
2153     # check if we have a transfer for this document
2154     my $transfer = $item->get_transfer;
2155
2156     # if we have a transfer to complete, we update the line of transfers with the datearrived
2157     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2158     if ($transfer) {
2159         $validTransfer = 0;
2160         if ( $transfer->in_transit ) {
2161             if ( $transfer->tobranch eq $branch ) {
2162                 $transfer->receive;
2163                 $messages->{'TransferArrived'} = $transfer->frombranch;
2164             }
2165             else {
2166                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2167                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2168             }
2169         }
2170         else {
2171             if ( $transfer->tobranch eq $branch ) {
2172                 $transfer->receive;
2173                 $messages->{'TransferArrived'} = $transfer->frombranch;
2174             }
2175             else {
2176                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2177                 $messages->{'TransferTrigger'} = $transfer->reason;
2178             }
2179         }
2180     }
2181
2182     # fix up the overdues in accounts...
2183     if ($borrowernumber) {
2184         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2185         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2186
2187         if ( $issue and $issue->is_overdue($return_date) ) {
2188         # fix fine days
2189             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2190             if ($reminder){
2191                 $messages->{'PrevDebarred'} = $debardate;
2192             } else {
2193                 $messages->{'Debarred'} = $debardate if $debardate;
2194             }
2195         # there's no overdue on the item but borrower had been previously debarred
2196         } elsif ( $issue->date_due and $patron->debarred ) {
2197              if ( $patron->debarred eq "9999-12-31") {
2198                 $messages->{'ForeverDebarred'} = $patron->debarred;
2199              } else {
2200                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2201                   $borrower_debar_dt->truncate(to => 'day');
2202                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2203                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2204                       $messages->{'PrevDebarred'} = $patron->debarred;
2205                   }
2206              }
2207         }
2208     }
2209
2210     # find reserves.....
2211     # launch the Checkreserves routine to find any holds
2212     my ($resfound, $resrec);
2213     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2214     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2215     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2216     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2217         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2218         $resfound = 'Reserved';
2219         $resrec = $hold->unblessed;
2220     }
2221     if ($resfound) {
2222           $resrec->{'ResFound'} = $resfound;
2223         $messages->{'ResFound'} = $resrec;
2224     }
2225
2226     # Record the fact that this book was returned.
2227     UpdateStats({
2228         branch         => $branch,
2229         type           => $stat_type,
2230         itemnumber     => $itemnumber,
2231         itemtype       => $itemtype,
2232         location       => $item->location,
2233         borrowernumber => $borrowernumber,
2234         ccode          => $item->ccode,
2235     });
2236
2237     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2238     if ( $patron ) {
2239         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2240         my %conditions = (
2241             branchcode   => $branch,
2242             categorycode => $patron->categorycode,
2243             item_type    => $itemtype,
2244             notification => 'CHECKIN',
2245         );
2246         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2247             SendCirculationAlert({
2248                 type     => 'CHECKIN',
2249                 item     => $item->unblessed,
2250                 borrower => $patron->unblessed,
2251                 branch   => $branch,
2252             });
2253         }
2254
2255         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2256             if C4::Context->preference("ReturnLog");
2257         }
2258
2259     # Check if this item belongs to a biblio record that is attached to an
2260     # ILL request, if it is we need to update the ILL request's status
2261     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2262         my $request = Koha::Illrequests->find(
2263             { biblio_id => $item->biblio->biblionumber }
2264         );
2265         $request->status('RET') if $request;
2266     }
2267
2268     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2269     if ( $validTransfer && !$is_in_rotating_collection
2270         && ( $doreturn or $messages->{'NotIssued'} )
2271         and !$resfound
2272         and ( $branch ne $returnbranch )
2273         and not $messages->{'WrongTransfer'}
2274         and not $messages->{'WasTransfered'} )
2275     {
2276         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2277         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2278             (C4::Context->preference("UseBranchTransferLimits") and
2279              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2280            )) {
2281             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2282             $debug and warn "item: " . Dumper($item->unblessed);
2283             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2284             $messages->{'WasTransfered'} = $returnbranch;
2285             $messages->{'TransferTrigger'} = $transfer_trigger;
2286         } else {
2287             $messages->{'NeedsTransfer'} = $returnbranch;
2288             $messages->{'TransferTrigger'} = $transfer_trigger;
2289         }
2290     }
2291
2292     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2293         my $claims = Koha::Checkouts::ReturnClaims->search(
2294            {
2295                itemnumber => $item->id,
2296                resolution => undef,
2297            }
2298         );
2299
2300         if ( $claims->count ) {
2301             $messages->{ReturnClaims} = $claims;
2302         }
2303     }
2304
2305     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2306     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2307
2308     if ( $doreturn and $issue ) {
2309         my $checkin = Koha::Old::Checkouts->find($issue->id);
2310
2311         Koha::Plugins->call('after_circ_action', {
2312             action  => 'checkin',
2313             payload => {
2314                 checkout=> $checkin
2315             }
2316         });
2317     }
2318
2319     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2320 }
2321
2322 =head2 MarkIssueReturned
2323
2324   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2325
2326 Unconditionally marks an issue as being returned by
2327 moving the C<issues> row to C<old_issues> and
2328 setting C<returndate> to the current date.
2329
2330 if C<$returndate> is specified (in iso format), it is used as the date
2331 of the return.
2332
2333 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2334 the old_issue is immediately anonymised
2335
2336 Ideally, this function would be internal to C<C4::Circulation>,
2337 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2338 and offline_circ/process_koc.pl.
2339
2340 The last optional parameter allos passing skip_record_index to the item store call.
2341
2342 =cut
2343
2344 sub MarkIssueReturned {
2345     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2346
2347     # Retrieve the issue
2348     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2349
2350     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2351
2352     my $issue_id = $issue->issue_id;
2353
2354     my $anonymouspatron;
2355     if ( $privacy && $privacy == 2 ) {
2356         # The default of 0 will not work due to foreign key constraints
2357         # The anonymisation will fail if AnonymousPatron is not a valid entry
2358         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2359         # Note that a warning should appear on the about page (System information tab).
2360         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2361         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2362             unless Koha::Patrons->find( $anonymouspatron );
2363     }
2364
2365     my $schema = Koha::Database->schema;
2366
2367     # FIXME Improve the return value and handle it from callers
2368     $schema->txn_do(sub {
2369
2370         my $patron = Koha::Patrons->find( $borrowernumber );
2371
2372         # Update the returndate value
2373         if ( $returndate ) {
2374             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2375         }
2376         else {
2377             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2378         }
2379
2380         # Create the old_issues entry
2381         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2382
2383         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2384         if ( $privacy && $privacy == 2) {
2385             $old_checkout->borrowernumber($anonymouspatron)->store;
2386         }
2387
2388         # And finally delete the issue
2389         $issue->delete;
2390
2391         $issue->item->onloan(undef)->store({ log_action => 0, skip_record_index => $params->{skip_record_index} });
2392
2393         if ( C4::Context->preference('StoreLastBorrower') ) {
2394             my $item = Koha::Items->find( $itemnumber );
2395             $item->last_returned_by( $patron );
2396         }
2397
2398         # Remove any OVERDUES related debarment if the borrower has no overdues
2399         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2400           && $patron->debarred
2401           && !$patron->has_overdues
2402           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2403         ) {
2404             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2405         }
2406
2407     });
2408
2409     return $issue_id;
2410 }
2411
2412 =head2 _debar_user_on_return
2413
2414     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2415
2416 C<$borrower> borrower hashref
2417
2418 C<$item> item hashref
2419
2420 C<$datedue> date due DateTime object
2421
2422 C<$returndate> DateTime object representing the return time
2423
2424 Internal function, called only by AddReturn that calculates and updates
2425  the user fine days, and debars them if necessary.
2426
2427 Should only be called for overdue returns
2428
2429 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2430 to ease testing.
2431
2432 =cut
2433
2434 sub _calculate_new_debar_dt {
2435     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2436
2437     my $branchcode = _GetCircControlBranch( $item, $borrower );
2438     my $circcontrol = C4::Context->preference('CircControl');
2439     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2440         {   categorycode => $borrower->{categorycode},
2441             itemtype     => $item->{itype},
2442             branchcode   => $branchcode,
2443             rules => [
2444                 'finedays',
2445                 'lengthunit',
2446                 'firstremind',
2447                 'maxsuspensiondays',
2448                 'suspension_chargeperiod',
2449             ]
2450         }
2451     );
2452     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2453     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2454     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2455
2456     return unless $finedays;
2457
2458     # finedays is in days, so hourly loans must multiply by 24
2459     # thus 1 hour late equals 1 day suspension * finedays rate
2460     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2461
2462     # grace period is measured in the same units as the loan
2463     my $grace =
2464       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2465
2466     my $deltadays = DateTime::Duration->new(
2467         days => $chargeable_units
2468     );
2469
2470     if ( $deltadays->subtract($grace)->is_positive() ) {
2471         my $suspension_days = $deltadays * $finedays;
2472
2473         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2474             # No need to / 1 and do not consider / 0
2475             $suspension_days = DateTime::Duration->new(
2476                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2477             );
2478         }
2479
2480         # If the max suspension days is < than the suspension days
2481         # the suspension days is limited to this maximum period.
2482         my $max_sd = $issuing_rule->{maxsuspensiondays};
2483         if ( defined $max_sd && $max_sd ne '' ) {
2484             $max_sd = DateTime::Duration->new( days => $max_sd );
2485             $suspension_days = $max_sd
2486               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2487         }
2488
2489         my ( $has_been_extended );
2490         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2491             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2492             if ( $debarment ) {
2493                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2494                 $has_been_extended = 1;
2495             }
2496         }
2497
2498         my $new_debar_dt;
2499         # Use the calendar or not to calculate the debarment date
2500         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2501             my $calendar = Koha::Calendar->new(
2502                 branchcode => $branchcode,
2503                 days_mode  => 'Calendar'
2504             );
2505             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2506         }
2507         else {
2508             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2509         }
2510         return $new_debar_dt;
2511     }
2512     return;
2513 }
2514
2515 sub _debar_user_on_return {
2516     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2517
2518     $return_date //= dt_from_string();
2519
2520     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2521
2522     return unless $new_debar_dt;
2523
2524     Koha::Patron::Debarments::AddUniqueDebarment({
2525         borrowernumber => $borrower->{borrowernumber},
2526         expiration     => $new_debar_dt->ymd(),
2527         type           => 'SUSPENSION',
2528     });
2529     # if borrower was already debarred but does not get an extra debarment
2530     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2531     my ($new_debarment_str, $is_a_reminder);
2532     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2533         $is_a_reminder = 1;
2534         $new_debarment_str = $borrower->{debarred};
2535     } else {
2536         $new_debarment_str = $new_debar_dt->ymd();
2537     }
2538     # FIXME Should return a DateTime object
2539     return $new_debarment_str, $is_a_reminder;
2540 }
2541
2542 =head2 _FixOverduesOnReturn
2543
2544    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2545
2546 C<$borrowernumber> borrowernumber
2547
2548 C<$itemnumber> itemnumber
2549
2550 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2551
2552 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2553
2554 Internal function
2555
2556 =cut
2557
2558 sub _FixOverduesOnReturn {
2559     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2560     unless( $borrowernumber ) {
2561         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2562         return;
2563     }
2564     unless( $item ) {
2565         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2566         return;
2567     }
2568     unless( $status ) {
2569         warn "_FixOverduesOnReturn() not supplied valid status";
2570         return;
2571     }
2572
2573     my $schema = Koha::Database->schema;
2574
2575     my $result = $schema->txn_do(
2576         sub {
2577             # check for overdue fine
2578             my $accountlines = Koha::Account::Lines->search(
2579                 {
2580                     borrowernumber  => $borrowernumber,
2581                     itemnumber      => $item,
2582                     debit_type_code => 'OVERDUE',
2583                     status          => 'UNRETURNED'
2584                 }
2585             );
2586             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2587
2588             my $accountline = $accountlines->next;
2589             my $payments = $accountline->credits;
2590
2591             my $amountoutstanding = $accountline->amountoutstanding;
2592             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2593                 $accountline->delete;
2594                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2595             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2596                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2597                 my $credit = $account->add_credit(
2598                     {
2599                         amount     => $amountoutstanding,
2600                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2601                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2602                         interface  => C4::Context->interface,
2603                         type       => 'FORGIVEN',
2604                         item_id    => $item
2605                     }
2606                 );
2607
2608                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2609
2610                 if (C4::Context->preference("FinesLog")) {
2611                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2612                 }
2613             }
2614
2615             $accountline->status($status);
2616             return $accountline->store();
2617         }
2618     );
2619
2620     return $result;
2621 }
2622
2623 =head2 _GetCircControlBranch
2624
2625    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2626
2627 Internal function :
2628
2629 Return the library code to be used to determine which circulation
2630 policy applies to a transaction.  Looks up the CircControl and
2631 HomeOrHoldingBranch system preferences.
2632
2633 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2634
2635 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2636
2637 =cut
2638
2639 sub _GetCircControlBranch {
2640     my ($item, $borrower) = @_;
2641     my $circcontrol = C4::Context->preference('CircControl');
2642     my $branch;
2643
2644     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2645         $branch= C4::Context->userenv->{'branch'};
2646     } elsif ($circcontrol eq 'PatronLibrary') {
2647         $branch=$borrower->{branchcode};
2648     } else {
2649         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2650         $branch = $item->{$branchfield};
2651         # default to item home branch if holdingbranch is used
2652         # and is not defined
2653         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2654             $branch = $item->{homebranch};
2655         }
2656     }
2657     return $branch;
2658 }
2659
2660 =head2 GetOpenIssue
2661
2662   $issue = GetOpenIssue( $itemnumber );
2663
2664 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2665
2666 C<$itemnumber> is the item's itemnumber
2667
2668 Returns a hashref
2669
2670 =cut
2671
2672 sub GetOpenIssue {
2673   my ( $itemnumber ) = @_;
2674   return unless $itemnumber;
2675   my $dbh = C4::Context->dbh;
2676   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2677   $sth->execute( $itemnumber );
2678   return $sth->fetchrow_hashref();
2679
2680 }
2681
2682 =head2 GetUpcomingDueIssues
2683
2684   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2685
2686 =cut
2687
2688 sub GetUpcomingDueIssues {
2689     my $params = shift;
2690
2691     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2692     my $dbh = C4::Context->dbh;
2693     my $statement;
2694     $statement = q{
2695         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2696         FROM issues
2697         LEFT JOIN items USING (itemnumber)
2698         LEFT JOIN branches ON branches.branchcode =
2699     };
2700     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2701     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2702     my @bind_parameters = ( $params->{'days_in_advance'} );
2703
2704     my $sth = $dbh->prepare( $statement );
2705     $sth->execute( @bind_parameters );
2706     my $upcoming_dues = $sth->fetchall_arrayref({});
2707
2708     return $upcoming_dues;
2709 }
2710
2711 =head2 CanBookBeRenewed
2712
2713   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2714
2715 Find out whether a borrowed item may be renewed.
2716
2717 C<$borrowernumber> is the borrower number of the patron who currently
2718 has the item on loan.
2719
2720 C<$itemnumber> is the number of the item to renew.
2721
2722 C<$override_limit>, if supplied with a true value, causes
2723 the limit on the number of times that the loan can be renewed
2724 (as controlled by the item type) to be ignored. Overriding also allows
2725 to renew sooner than "No renewal before" and to manually renew loans
2726 that are automatically renewed.
2727
2728 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2729 item must currently be on loan to the specified borrower; renewals
2730 must be allowed for the item's type; and the borrower must not have
2731 already renewed the loan. $error will contain the reason the renewal can not proceed
2732
2733 =cut
2734
2735 sub CanBookBeRenewed {
2736     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2737
2738     my $dbh    = C4::Context->dbh;
2739     my $renews = 1;
2740     my $auto_renew = "no";
2741
2742     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2743     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2744     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2745     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2746
2747     my $patron = $issue->patron or return;
2748
2749     # override_limit will override anything else except on_reserve
2750     unless ( $override_limit ){
2751         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2752         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2753             {
2754                 categorycode => $patron->categorycode,
2755                 itemtype     => $item->effective_itemtype,
2756                 branchcode   => $branchcode,
2757                 rules => [
2758                     'renewalsallowed',
2759                     'no_auto_renewal_after',
2760                     'no_auto_renewal_after_hard_limit',
2761                     'lengthunit',
2762                     'norenewalbefore',
2763                     'unseen_renewals_allowed'
2764                 ]
2765             }
2766         );
2767
2768         return ( 0, "too_many" )
2769           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2770
2771         return ( 0, "too_unseen" )
2772           if C4::Context->preference('UnseenRenewals') &&
2773             $issuing_rule->{unseen_renewals_allowed} &&
2774             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2775
2776         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2777         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2778         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2779         my $restricted  = $patron->is_debarred;
2780         my $hasoverdues = $patron->has_overdues;
2781
2782         if ( $restricted and $restrictionblockrenewing ) {
2783             return ( 0, 'restriction');
2784         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2785             return ( 0, 'overdue');
2786         }
2787
2788         if ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2789
2790             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2791                 return ( 0, 'auto_account_expired' );
2792             }
2793
2794             if ( defined $issuing_rule->{no_auto_renewal_after}
2795                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2796                 # Get issue_date and add no_auto_renewal_after
2797                 # If this is greater than today, it's too late for renewal.
2798                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2799                 $maximum_renewal_date->add(
2800                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2801                 );
2802                 my $now = dt_from_string;
2803                 if ( $now >= $maximum_renewal_date ) {
2804                     return ( 0, "auto_too_late" );
2805                 }
2806             }
2807             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2808                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2809                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2810                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2811                     return ( 0, "auto_too_late" );
2812                 }
2813             }
2814
2815             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2816                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2817                 my $amountoutstanding =
2818                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2819                   ? $patron->account->balance
2820                   : $patron->account->outstanding_debits->total_outstanding;
2821                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2822                     return ( 0, "auto_too_much_oweing" );
2823                 }
2824             }
2825         }
2826
2827         if ( defined $issuing_rule->{norenewalbefore}
2828             and $issuing_rule->{norenewalbefore} ne "" )
2829         {
2830
2831             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2832             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2833                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2834
2835             # Depending on syspref reset the exact time, only check the date
2836             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2837                 and $issuing_rule->{lengthunit} eq 'days' )
2838             {
2839                 $soonestrenewal->truncate( to => 'day' );
2840             }
2841
2842             if ( $soonestrenewal > dt_from_string() )
2843             {
2844                 $auto_renew = ($issue->auto_renew && $patron->autorenew_checkouts) ? "auto_too_soon" : "too_soon";
2845             }
2846             elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2847                 $auto_renew = "ok";
2848             }
2849         }
2850
2851         # Fallback for automatic renewals:
2852         # If norenewalbefore is undef, don't renew before due date.
2853         if ( $issue->auto_renew && $auto_renew eq "no" && $patron->autorenew_checkouts ) {
2854             my $now = dt_from_string;
2855             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2856                 $auto_renew = "ok";
2857             } else {
2858                 $auto_renew = "auto_too_soon";
2859             }
2860         }
2861     }
2862
2863     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2864
2865     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2866     if ( $resfound && $resrec->{non_priority} ) {
2867         $resfound = Koha::Holds->search(
2868             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2869           ->count > 0;
2870     }
2871
2872
2873
2874     # This item can fill one or more unfilled reserve, can those unfilled reserves
2875     # all be filled by other available items?
2876     if ( $resfound
2877         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2878     {
2879         my $schema = Koha::Database->new()->schema();
2880
2881         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2882         if ($item_holds) {
2883             # There is an item level hold on this item, no other item can fill the hold
2884             $resfound = 1;
2885         }
2886         else {
2887
2888             # Get all other items that could possibly fill reserves
2889             my @itemnumbers = $schema->resultset('Item')->search(
2890                 {
2891                     biblionumber => $resrec->{biblionumber},
2892                     onloan       => undef,
2893                     notforloan   => 0,
2894                     -not         => { itemnumber => $itemnumber }
2895                 },
2896                 { columns => 'itemnumber' }
2897             )->get_column('itemnumber')->all();
2898
2899             # Get all other reserves that could have been filled by this item
2900             my @borrowernumbers;
2901             while (1) {
2902                 my ( $reserve_found, $reserve, undef ) =
2903                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2904
2905                 if ($reserve_found) {
2906                     push( @borrowernumbers, $reserve->{borrowernumber} );
2907                 }
2908                 else {
2909                     last;
2910                 }
2911             }
2912
2913             # If the count of the union of the lists of reservable items for each borrower
2914             # is equal or greater than the number of borrowers, we know that all reserves
2915             # can be filled with available items. We can get the union of the sets simply
2916             # by pushing all the elements onto an array and removing the duplicates.
2917             my @reservable;
2918             my %patrons;
2919             ITEM: foreach my $itemnumber (@itemnumbers) {
2920                 my $item = Koha::Items->find( $itemnumber );
2921                 next if IsItemOnHoldAndFound( $itemnumber );
2922                 for my $borrowernumber (@borrowernumbers) {
2923                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2924                     next unless IsAvailableForItemLevelRequest($item, $patron);
2925                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2926
2927                     push @reservable, $itemnumber;
2928                     if (@reservable >= @borrowernumbers) {
2929                         $resfound = 0;
2930                         last ITEM;
2931                     }
2932                     last;
2933                 }
2934             }
2935         }
2936     }
2937     if( $cron ) { #The cron wants to return 'too_soon' over 'on_reserve'
2938         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2939         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2940     } else { # For other purposes we want 'on_reserve' before 'too_soon'
2941         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2942         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2943     }
2944
2945     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2946
2947     return ( 1, undef );
2948 }
2949
2950 =head2 AddRenewal
2951
2952   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
2953
2954 Renews a loan.
2955
2956 C<$borrowernumber> is the borrower number of the patron who currently
2957 has the item.
2958
2959 C<$itemnumber> is the number of the item to renew.
2960
2961 C<$branch> is the library where the renewal took place (if any).
2962            The library that controls the circ policies for the renewal is retrieved from the issues record.
2963
2964 C<$datedue> can be a DateTime object used to set the due date.
2965
2966 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2967 this parameter is not supplied, lastreneweddate is set to the current date.
2968
2969 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2970 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2971 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2972 syspref)
2973
2974 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2975 from the book's item type.
2976
2977 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
2978 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
2979 fallback to a true value
2980
2981 =cut
2982
2983 sub AddRenewal {
2984     my $borrowernumber  = shift;
2985     my $itemnumber      = shift or return;
2986     my $branch          = shift;
2987     my $datedue         = shift;
2988     my $lastreneweddate = shift || dt_from_string();
2989     my $skipfinecalc    = shift;
2990     my $seen            = shift;
2991
2992     # Fallback on a 'seen' renewal
2993     $seen = defined $seen && $seen == 0 ? 0 : 1;
2994
2995     my $item_object   = Koha::Items->find($itemnumber) or return;
2996     my $biblio = $item_object->biblio;
2997     my $issue  = $item_object->checkout;
2998     my $item_unblessed = $item_object->unblessed;
2999
3000     my $dbh = C4::Context->dbh;
3001
3002     return unless $issue;
3003
3004     $borrowernumber ||= $issue->borrowernumber;
3005
3006     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3007         carp 'Invalid date passed to AddRenewal.';
3008         return;
3009     }
3010
3011     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3012     my $patron_unblessed = $patron->unblessed;
3013
3014     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3015
3016     my $schema = Koha::Database->schema;
3017     $schema->txn_do(sub{
3018
3019         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3020             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3021         }
3022         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3023
3024         # If the due date wasn't specified, calculate it by adding the
3025         # book's loan length to today's date or the current due date
3026         # based on the value of the RenewalPeriodBase syspref.
3027         my $itemtype = $item_object->effective_itemtype;
3028         unless ($datedue) {
3029
3030             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3031                                             dt_from_string( $issue->date_due, 'sql' ) :
3032                                             dt_from_string();
3033             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3034         }
3035
3036         my $fees = Koha::Charges::Fees->new(
3037             {
3038                 patron    => $patron,
3039                 library   => $circ_library,
3040                 item      => $item_object,
3041                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3042                 to_date   => dt_from_string($datedue),
3043             }
3044         );
3045
3046         # Increment the unseen renewals, if appropriate
3047         # We only do so if the syspref is enabled and
3048         # a maximum value has been set in the circ rules
3049         my $unseen_renewals = $issue->unseen_renewals;
3050         if (C4::Context->preference('UnseenRenewals')) {
3051             my $rule = Koha::CirculationRules->get_effective_rule(
3052                 {   categorycode => $patron->categorycode,
3053                     itemtype     => $item_object->effective_itemtype,
3054                     branchcode   => $circ_library->branchcode,
3055                     rule_name    => 'unseen_renewals_allowed'
3056                 }
3057             );
3058             if (!$seen && $rule && $rule->rule_value) {
3059                 $unseen_renewals++;
3060             } else {
3061                 # If the renewal is seen, unseen should revert to 0
3062                 $unseen_renewals = 0;
3063             }
3064         }
3065
3066         # Update the issues record to have the new due date, and a new count
3067         # of how many times it has been renewed.
3068         my $renews = ( $issue->renewals || 0 ) + 1;
3069         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3070
3071         eval{
3072             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3073         };
3074         if( $sth->err ){
3075             Koha::Exceptions::Checkout::FailedRenewal->throw(
3076                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3077             );
3078         }
3079
3080         # Update the renewal count on the item, and tell zebra to reindex
3081         $renews = ( $item_object->renewals || 0 ) + 1;
3082         $item_object->renewals($renews);
3083         $item_object->onloan($datedue);
3084         $item_object->store({ log_action => 0 });
3085
3086         # Charge a new rental fee, if applicable
3087         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3088         if ( $charge > 0 ) {
3089             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3090         }
3091
3092         # Charge a new accumulate rental fee, if applicable
3093         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3094         if ( $itemtype_object ) {
3095             my $accumulate_charge = $fees->accumulate_rentalcharge();
3096             if ( $accumulate_charge > 0 ) {
3097                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3098             }
3099             $charge += $accumulate_charge;
3100         }
3101
3102         # Send a renewal slip according to checkout alert preferencei
3103         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3104             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3105             my %conditions        = (
3106                 branchcode   => $branch,
3107                 categorycode => $patron->categorycode,
3108                 item_type    => $itemtype,
3109                 notification => 'CHECKOUT',
3110             );
3111             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3112                 SendCirculationAlert(
3113                     {
3114                         type     => 'RENEWAL',
3115                         item     => $item_unblessed,
3116                         borrower => $patron->unblessed,
3117                         branch   => $branch,
3118                     }
3119                 );
3120             }
3121         }
3122
3123         # Remove any OVERDUES related debarment if the borrower has no overdues
3124         if ( $patron
3125           && $patron->is_debarred
3126           && ! $patron->has_overdues
3127           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3128         ) {
3129             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3130         }
3131
3132         # Add the renewal to stats
3133         UpdateStats(
3134             {
3135                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3136                 type           => 'renew',
3137                 amount         => $charge,
3138                 itemnumber     => $itemnumber,
3139                 itemtype       => $itemtype,
3140                 location       => $item_object->location,
3141                 borrowernumber => $borrowernumber,
3142                 ccode          => $item_object->ccode,
3143             }
3144         );
3145
3146         #Log the renewal
3147         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3148
3149         Koha::Plugins->call('after_circ_action', {
3150             action  => 'renewal',
3151             payload => {
3152                 checkout  => $issue->get_from_storage
3153             }
3154         });
3155     });
3156
3157     return $datedue;
3158 }
3159
3160 sub GetRenewCount {
3161     # check renewal status
3162     my ( $bornum, $itemno ) = @_;
3163     my $dbh           = C4::Context->dbh;
3164     my $renewcount    = 0;
3165     my $unseencount    = 0;
3166     my $renewsallowed = 0;
3167     my $unseenallowed = 0;
3168     my $renewsleft    = 0;
3169     my $unseenleft    = 0;
3170
3171     my $patron = Koha::Patrons->find( $bornum );
3172     my $item   = Koha::Items->find($itemno);
3173
3174     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3175
3176     # Look in the issues table for this item, lent to this borrower,
3177     # and not yet returned.
3178
3179     # FIXME - I think this function could be redone to use only one SQL call.
3180     my $sth = $dbh->prepare(
3181         "select * from issues
3182                                 where (borrowernumber = ?)
3183                                 and (itemnumber = ?)"
3184     );
3185     $sth->execute( $bornum, $itemno );
3186     my $data = $sth->fetchrow_hashref;
3187     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3188     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3189     # $item and $borrower should be calculated
3190     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3191
3192     my $rules = Koha::CirculationRules->get_effective_rules(
3193         {
3194             categorycode => $patron->categorycode,
3195             itemtype     => $item->effective_itemtype,
3196             branchcode   => $branchcode,
3197             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3198         }
3199     );
3200     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3201     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3202         $rules->{unseen_renewals_allowed} :
3203         0;
3204     $renewsleft    = $renewsallowed - $renewcount;
3205     $unseenleft    = $unseenallowed - $unseencount;
3206     if($renewsleft < 0){ $renewsleft = 0; }
3207     if($unseenleft < 0){ $unseenleft = 0; }
3208     return (
3209         $renewcount,
3210         $renewsallowed,
3211         $renewsleft,
3212         $unseencount,
3213         $unseenallowed,
3214         $unseenleft
3215     );
3216 }
3217
3218 =head2 GetSoonestRenewDate
3219
3220   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3221
3222 Find out the soonest possible renew date of a borrowed item.
3223
3224 C<$borrowernumber> is the borrower number of the patron who currently
3225 has the item on loan.
3226
3227 C<$itemnumber> is the number of the item to renew.
3228
3229 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3230 renew date, based on the value "No renewal before" of the applicable
3231 issuing rule. Returns the current date if the item can already be
3232 renewed, and returns undefined if the borrower, loan, or item
3233 cannot be found.
3234
3235 =cut
3236
3237 sub GetSoonestRenewDate {
3238     my ( $borrowernumber, $itemnumber ) = @_;
3239
3240     my $dbh = C4::Context->dbh;
3241
3242     my $item      = Koha::Items->find($itemnumber)      or return;
3243     my $itemissue = $item->checkout or return;
3244
3245     $borrowernumber ||= $itemissue->borrowernumber;
3246     my $patron = Koha::Patrons->find( $borrowernumber )
3247       or return;
3248
3249     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3250     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3251         {   categorycode => $patron->categorycode,
3252             itemtype     => $item->effective_itemtype,
3253             branchcode   => $branchcode,
3254             rules => [
3255                 'norenewalbefore',
3256                 'lengthunit',
3257             ]
3258         }
3259     );
3260
3261     my $now = dt_from_string;
3262     return $now unless $issuing_rule;
3263
3264     if ( defined $issuing_rule->{norenewalbefore}
3265         and $issuing_rule->{norenewalbefore} ne "" )
3266     {
3267         my $soonestrenewal =
3268           dt_from_string( $itemissue->date_due )->subtract(
3269             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3270
3271         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3272             and $issuing_rule->{lengthunit} eq 'days' )
3273         {
3274             $soonestrenewal->truncate( to => 'day' );
3275         }
3276         return $soonestrenewal if $now < $soonestrenewal;
3277     }
3278     return $now;
3279 }
3280
3281 =head2 GetLatestAutoRenewDate
3282
3283   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3284
3285 Find out the latest possible auto renew date of a borrowed item.
3286
3287 C<$borrowernumber> is the borrower number of the patron who currently
3288 has the item on loan.
3289
3290 C<$itemnumber> is the number of the item to renew.
3291
3292 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3293 auto renew date, based on the value "No auto renewal after" and the "No auto
3294 renewal after (hard limit) of the applicable issuing rule.
3295 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3296 or item cannot be found.
3297
3298 =cut
3299
3300 sub GetLatestAutoRenewDate {
3301     my ( $borrowernumber, $itemnumber ) = @_;
3302
3303     my $dbh = C4::Context->dbh;
3304
3305     my $item      = Koha::Items->find($itemnumber)  or return;
3306     my $itemissue = $item->checkout                 or return;
3307
3308     $borrowernumber ||= $itemissue->borrowernumber;
3309     my $patron = Koha::Patrons->find( $borrowernumber )
3310       or return;
3311
3312     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3313     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3314         {
3315             categorycode => $patron->categorycode,
3316             itemtype     => $item->effective_itemtype,
3317             branchcode   => $branchcode,
3318             rules => [
3319                 'no_auto_renewal_after',
3320                 'no_auto_renewal_after_hard_limit',
3321                 'lengthunit',
3322             ]
3323         }
3324     );
3325
3326     return unless $circulation_rules;
3327     return
3328       if ( not $circulation_rules->{no_auto_renewal_after}
3329             or $circulation_rules->{no_auto_renewal_after} eq '' )
3330       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3331              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3332
3333     my $maximum_renewal_date;
3334     if ( $circulation_rules->{no_auto_renewal_after} ) {
3335         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3336         $maximum_renewal_date->add(
3337             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3338         );
3339     }
3340
3341     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3342         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3343         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3344     }
3345     return $maximum_renewal_date;
3346 }
3347
3348
3349 =head2 GetIssuingCharges
3350
3351   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3352
3353 Calculate how much it would cost for a given patron to borrow a given
3354 item, including any applicable discounts.
3355
3356 C<$itemnumber> is the item number of item the patron wishes to borrow.
3357
3358 C<$borrowernumber> is the patron's borrower number.
3359
3360 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3361 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3362 if it's a video).
3363
3364 =cut
3365
3366 sub GetIssuingCharges {
3367
3368     # calculate charges due
3369     my ( $itemnumber, $borrowernumber ) = @_;
3370     my $charge = 0;
3371     my $dbh    = C4::Context->dbh;
3372     my $item_type;
3373
3374     # Get the book's item type and rental charge (via its biblioitem).
3375     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3376         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3377     $charge_query .= (C4::Context->preference('item-level_itypes'))
3378         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3379         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3380
3381     $charge_query .= ' WHERE items.itemnumber =?';
3382
3383     my $sth = $dbh->prepare($charge_query);
3384     $sth->execute($itemnumber);
3385     if ( my $item_data = $sth->fetchrow_hashref ) {
3386         $item_type = $item_data->{itemtype};
3387         $charge    = $item_data->{rentalcharge};
3388         # FIXME This should follow CircControl
3389         my $branch = C4::Context::mybranch();
3390         my $patron = Koha::Patrons->find( $borrowernumber );
3391         my $discount = Koha::CirculationRules->get_effective_rule({
3392             categorycode => $patron->categorycode,
3393             branchcode   => $branch,
3394             itemtype     => $item_type,
3395             rule_name    => 'rentaldiscount'
3396         });
3397         if ($discount) {
3398             $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3399         }
3400         if ($charge) {
3401             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3402         }
3403     }
3404
3405     return ( $charge, $item_type );
3406 }
3407
3408 =head2 AddIssuingCharge
3409
3410   &AddIssuingCharge( $checkout, $charge, $type )
3411
3412 =cut
3413
3414 sub AddIssuingCharge {
3415     my ( $checkout, $charge, $type ) = @_;
3416
3417     # FIXME What if checkout does not exist?
3418
3419     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3420     my $accountline = $account->add_debit(
3421         {
3422             amount      => $charge,
3423             note        => undef,
3424             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3425             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3426             interface   => C4::Context->interface,
3427             type        => $type,
3428             item_id     => $checkout->itemnumber,
3429             issue_id    => $checkout->issue_id,
3430         }
3431     );
3432 }
3433
3434 =head2 GetTransfers
3435
3436   GetTransfers($itemnumber);
3437
3438 =cut
3439
3440 sub GetTransfers {
3441     my ($itemnumber) = @_;
3442
3443     my $dbh = C4::Context->dbh;
3444
3445     my $query = '
3446         SELECT datesent,
3447                frombranch,
3448                tobranch,
3449                branchtransfer_id,
3450                daterequested,
3451                reason
3452         FROM branchtransfers
3453         WHERE itemnumber = ?
3454           AND datearrived IS NULL
3455           AND datecancelled IS NULL
3456         ';
3457     my $sth = $dbh->prepare($query);
3458     $sth->execute($itemnumber);
3459     my @row = $sth->fetchrow_array();
3460     return @row;
3461 }
3462
3463 =head2 GetTransfersFromTo
3464
3465   @results = GetTransfersFromTo($frombranch,$tobranch);
3466
3467 Returns the list of pending transfers between $from and $to branch
3468
3469 =cut
3470
3471 sub GetTransfersFromTo {
3472     my ( $frombranch, $tobranch ) = @_;
3473     return unless ( $frombranch && $tobranch );
3474     my $dbh   = C4::Context->dbh;
3475     my $query = "
3476         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3477         FROM   branchtransfers
3478         WHERE  frombranch=?
3479           AND  tobranch=?
3480           AND datecancelled IS NULL
3481           AND datesent IS NOT NULL
3482           AND datearrived IS NULL
3483     ";
3484     my $sth = $dbh->prepare($query);
3485     $sth->execute( $frombranch, $tobranch );
3486     my @gettransfers;
3487
3488     while ( my $data = $sth->fetchrow_hashref ) {
3489         push @gettransfers, $data;
3490     }
3491     return (@gettransfers);
3492 }
3493
3494 =head2 DeleteTransfer
3495
3496   &DeleteTransfer($itemnumber);
3497
3498 =cut
3499
3500 sub DeleteTransfer {
3501     my ($itemnumber) = @_;
3502     return unless $itemnumber;
3503     my $dbh          = C4::Context->dbh;
3504     my $sth          = $dbh->prepare(
3505         "DELETE FROM branchtransfers
3506          WHERE itemnumber=?
3507          AND datearrived IS NULL "
3508     );
3509     return $sth->execute($itemnumber);
3510 }
3511
3512 =head2 SendCirculationAlert
3513
3514 Send out a C<check-in> or C<checkout> alert using the messaging system.
3515
3516 B<Parameters>:
3517
3518 =over 4
3519
3520 =item type
3521
3522 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3523
3524 =item item
3525
3526 Hashref of information about the item being checked in or out.
3527
3528 =item borrower
3529
3530 Hashref of information about the borrower of the item.
3531
3532 =item branch
3533
3534 The branchcode from where the checkout or check-in took place.
3535
3536 =back
3537
3538 B<Example>:
3539
3540     SendCirculationAlert({
3541         type     => 'CHECKOUT',
3542         item     => $item,
3543         borrower => $borrower,
3544         branch   => $branch,
3545     });
3546
3547 =cut
3548
3549 sub SendCirculationAlert {
3550     my ($opts) = @_;
3551     my ($type, $item, $borrower, $branch) =
3552         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3553     my %message_name = (
3554         CHECKIN  => 'Item_Check_in',
3555         CHECKOUT => 'Item_Checkout',
3556         RENEWAL  => 'Item_Checkout',
3557     );
3558     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3559         borrowernumber => $borrower->{borrowernumber},
3560         message_name   => $message_name{$type},
3561     });
3562     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3563
3564     my $schema = Koha::Database->new->schema;
3565     my @transports = keys %{ $borrower_preferences->{transports} };
3566
3567     # From the MySQL doc:
3568     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3569     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3570     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3571     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3572
3573     for my $mtt (@transports) {
3574         my $letter =  C4::Letters::GetPreparedLetter (
3575             module => 'circulation',
3576             letter_code => $type,
3577             branchcode => $branch,
3578             message_transport_type => $mtt,
3579             lang => $borrower->{lang},
3580             tables => {
3581                 $issues_table => $item->{itemnumber},
3582                 'items'       => $item->{itemnumber},
3583                 'biblio'      => $item->{biblionumber},
3584                 'biblioitems' => $item->{biblionumber},
3585                 'borrowers'   => $borrower,
3586                 'branches'    => $branch,
3587             }
3588         ) or next;
3589
3590         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3591         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3592         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3593         unless ( $message ) {
3594             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3595             C4::Message->enqueue($letter, $borrower, $mtt);
3596         } else {
3597             $message->append($letter);
3598             $message->update;
3599         }
3600         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3601     }
3602
3603     return;
3604 }
3605
3606 =head2 updateWrongTransfer
3607
3608   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3609
3610 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3611
3612 =cut
3613
3614 sub updateWrongTransfer {
3615         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3616         my $dbh = C4::Context->dbh;
3617 # first step validate the actual line of transfert .
3618         my $sth =
3619                 $dbh->prepare(
3620                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3621                 );
3622                 $sth->execute($FromLibrary,$itemNumber);
3623
3624 # second step create a new line of branchtransfer to the right location .
3625         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3626
3627 #third step changing holdingbranch of item
3628     my $item = Koha::Items->find($itemNumber)->holdingbranch($FromLibrary)->store;
3629 }
3630
3631 =head2 CalcDateDue
3632
3633 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3634
3635 this function calculates the due date given the start date and configured circulation rules,
3636 checking against the holidays calendar as per the daysmode circulation rule.
3637 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3638 C<$itemtype>  = itemtype code of item in question
3639 C<$branch>  = location whose calendar to use
3640 C<$borrower> = Borrower object
3641 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3642
3643 =cut
3644
3645 sub CalcDateDue {
3646     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3647
3648     $isrenewal ||= 0;
3649
3650     # loanlength now a href
3651     my $loanlength =
3652             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3653
3654     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3655             ? qq{renewalperiod}
3656             : qq{issuelength};
3657
3658     my $datedue;
3659     if ( $startdate ) {
3660         if (ref $startdate ne 'DateTime' ) {
3661             $datedue = dt_from_string($datedue);
3662         } else {
3663             $datedue = $startdate->clone;
3664         }
3665     } else {
3666         $datedue = dt_from_string()->truncate( to => 'minute' );
3667     }
3668
3669
3670     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3671         {
3672             categorycode => $borrower->{categorycode},
3673             itemtype     => $itemtype,
3674             branchcode   => $branch,
3675         }
3676     );
3677
3678     # calculate the datedue as normal
3679     if ( $daysmode eq 'Days' )
3680     {    # ignoring calendar
3681         if ( $loanlength->{lengthunit} eq 'hours' ) {
3682             $datedue->add( hours => $loanlength->{$length_key} );
3683         } else {    # days
3684             $datedue->add( days => $loanlength->{$length_key} );
3685             $datedue->set_hour(23);
3686             $datedue->set_minute(59);
3687         }
3688     } else {
3689         my $dur;
3690         if ($loanlength->{lengthunit} eq 'hours') {
3691             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3692         }
3693         else { # days
3694             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3695         }
3696         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3697         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3698         if ($loanlength->{lengthunit} eq 'days') {
3699             $datedue->set_hour(23);
3700             $datedue->set_minute(59);
3701         }
3702     }
3703
3704     # if Hard Due Dates are used, retrieve them and apply as necessary
3705     my ( $hardduedate, $hardduedatecompare ) =
3706       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3707     if ($hardduedate) {    # hardduedates are currently dates
3708         $hardduedate->truncate( to => 'minute' );
3709         $hardduedate->set_hour(23);
3710         $hardduedate->set_minute(59);
3711         my $cmp = DateTime->compare( $hardduedate, $datedue );
3712
3713 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3714 # if the calculated date is before the 'after' Hard Due Date (floor), override
3715 # if the hard due date is set to 'exactly', overrride
3716         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3717             $datedue = $hardduedate->clone;
3718         }
3719
3720         # in all other cases, keep the date due as it is
3721
3722     }
3723
3724     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3725     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3726         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3727         if( $expiry_dt ) { #skip empty expiry date..
3728             $expiry_dt->set( hour => 23, minute => 59);
3729             my $d1= $datedue->clone->set_time_zone('floating');
3730             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3731                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3732             }
3733         }
3734         if ( $daysmode ne 'Days' ) {
3735           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3736           if ( $calendar->is_holiday($datedue) ) {
3737               # Don't return on a closed day
3738               $datedue = $calendar->prev_open_days( $datedue, 1 );
3739           }
3740         }
3741     }
3742
3743     return $datedue;
3744 }
3745
3746
3747 sub CheckValidBarcode{
3748 my ($barcode) = @_;
3749 my $dbh = C4::Context->dbh;
3750 my $query=qq|SELECT count(*)
3751              FROM items
3752              WHERE barcode=?
3753             |;
3754 my $sth = $dbh->prepare($query);
3755 $sth->execute($barcode);
3756 my $exist=$sth->fetchrow ;
3757 return $exist;
3758 }
3759
3760 =head2 IsBranchTransferAllowed
3761
3762   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3763
3764 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3765
3766 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3767 Koha::Item->can_be_transferred.
3768
3769 =cut
3770
3771 sub IsBranchTransferAllowed {
3772         my ( $toBranch, $fromBranch, $code ) = @_;
3773
3774         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3775
3776         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3777         my $dbh = C4::Context->dbh;
3778
3779         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3780         $sth->execute( $toBranch, $fromBranch, $code );
3781         my $limit = $sth->fetchrow_hashref();
3782
3783         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3784         if ( $limit->{'limitId'} ) {
3785                 return 0;
3786         } else {
3787                 return 1;
3788         }
3789 }
3790
3791 =head2 CreateBranchTransferLimit
3792
3793   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3794
3795 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3796
3797 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3798
3799 =cut
3800
3801 sub CreateBranchTransferLimit {
3802    my ( $toBranch, $fromBranch, $code ) = @_;
3803    return unless defined($toBranch) && defined($fromBranch);
3804    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3805
3806    my $dbh = C4::Context->dbh;
3807
3808    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3809    return $sth->execute( $code, $toBranch, $fromBranch );
3810 }
3811
3812 =head2 DeleteBranchTransferLimits
3813
3814     my $result = DeleteBranchTransferLimits($frombranch);
3815
3816 Deletes all the library transfer limits for one library.  Returns the
3817 number of limits deleted, 0e0 if no limits were deleted, or undef if
3818 no arguments are supplied.
3819
3820 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3821     fromBranch => $fromBranch
3822     })->delete.
3823
3824 =cut
3825
3826 sub DeleteBranchTransferLimits {
3827     my $branch = shift;
3828     return unless defined $branch;
3829     my $dbh    = C4::Context->dbh;
3830     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3831     return $sth->execute($branch);
3832 }
3833
3834 sub ReturnLostItem{
3835     my ( $borrowernumber, $itemnum ) = @_;
3836     MarkIssueReturned( $borrowernumber, $itemnum );
3837 }
3838
3839 =head2 LostItem
3840
3841   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3842
3843 The final optional parameter, C<$params>, expected to contain
3844 'skip_record_index' key, which relayed down to Koha::Item/store,
3845 there it prevents calling of ModZebra index_records,
3846 which takes most of the time in batch adds/deletes: index_records better
3847 to be called later in C<additem.pl> after the whole loop.
3848
3849 $params:
3850     skip_record_index => 1|0
3851
3852 =cut
3853
3854 sub LostItem{
3855     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3856
3857     unless ( $mark_lost_from ) {
3858         # Temporary check to avoid regressions
3859         die q|LostItem called without $mark_lost_from, check the API.|;
3860     }
3861
3862     my $mark_returned;
3863     if ( $force_mark_returned ) {
3864         $mark_returned = 1;
3865     } else {
3866         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3867         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3868     }
3869
3870     my $dbh = C4::Context->dbh();
3871     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3872                            FROM issues
3873                            JOIN items USING (itemnumber)
3874                            JOIN biblio USING (biblionumber)
3875                            WHERE issues.itemnumber=?");
3876     $sth->execute($itemnumber);
3877     my $issues=$sth->fetchrow_hashref();
3878
3879     # If a borrower lost the item, add a replacement cost to the their record
3880     if ( my $borrowernumber = $issues->{borrowernumber} ){
3881         my $patron = Koha::Patrons->find( $borrowernumber );
3882
3883         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3884         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3885
3886         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3887             C4::Accounts::chargelostitem(
3888                 $borrowernumber,
3889                 $itemnumber,
3890                 $issues->{'replacementprice'},
3891                 sprintf( "%s %s %s",
3892                     $issues->{'title'}          || q{},
3893                     $issues->{'barcode'}        || q{},
3894                     $issues->{'itemcallnumber'} || q{},
3895                 ),
3896             );
3897             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3898             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3899         }
3900
3901         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3902     }
3903
3904     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3905     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3906         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store({ skip_record_index => $params->{skip_record_index} });
3907     }
3908     my $transferdeleted = DeleteTransfer($itemnumber);
3909 }
3910
3911 sub GetOfflineOperations {
3912     my $dbh = C4::Context->dbh;
3913     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3914     $sth->execute(C4::Context->userenv->{'branch'});
3915     my $results = $sth->fetchall_arrayref({});
3916     return $results;
3917 }
3918
3919 sub GetOfflineOperation {
3920     my $operationid = shift;
3921     return unless $operationid;
3922     my $dbh = C4::Context->dbh;
3923     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3924     $sth->execute( $operationid );
3925     return $sth->fetchrow_hashref;
3926 }
3927
3928 sub AddOfflineOperation {
3929     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3930     my $dbh = C4::Context->dbh;
3931     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3932     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3933     return "Added.";
3934 }
3935
3936 sub DeleteOfflineOperation {
3937     my $dbh = C4::Context->dbh;
3938     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3939     $sth->execute( shift );
3940     return "Deleted.";
3941 }
3942
3943 sub ProcessOfflineOperation {
3944     my $operation = shift;
3945
3946     my $report;
3947     if ( $operation->{action} eq 'return' ) {
3948         $report = ProcessOfflineReturn( $operation );
3949     } elsif ( $operation->{action} eq 'issue' ) {
3950         $report = ProcessOfflineIssue( $operation );
3951     } elsif ( $operation->{action} eq 'payment' ) {
3952         $report = ProcessOfflinePayment( $operation );
3953     }
3954
3955     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3956
3957     return $report;
3958 }
3959
3960 sub ProcessOfflineReturn {
3961     my $operation = shift;
3962
3963     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3964
3965     if ( $item ) {
3966         my $itemnumber = $item->itemnumber;
3967         my $issue = GetOpenIssue( $itemnumber );
3968         if ( $issue ) {
3969             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3970             ModDateLastSeen( $itemnumber, $leave_item_lost );
3971             MarkIssueReturned(
3972                 $issue->{borrowernumber},
3973                 $itemnumber,
3974                 $operation->{timestamp},
3975             );
3976             $item->renewals(0);
3977             $item->onloan(undef);
3978             $item->store({ log_action => 0 });
3979             return "Success.";
3980         } else {
3981             return "Item not issued.";
3982         }
3983     } else {
3984         return "Item not found.";
3985     }
3986 }
3987
3988 sub ProcessOfflineIssue {
3989     my $operation = shift;
3990
3991     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3992
3993     if ( $patron ) {
3994         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3995         unless ($item) {
3996             return "Barcode not found.";
3997         }
3998         my $itemnumber = $item->itemnumber;
3999         my $issue = GetOpenIssue( $itemnumber );
4000
4001         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4002             MarkIssueReturned(
4003                 $issue->{borrowernumber},
4004                 $itemnumber,
4005                 $operation->{timestamp},
4006             );
4007         }
4008         AddIssue(
4009             $patron->unblessed,
4010             $operation->{'barcode'},
4011             undef,
4012             1,
4013             $operation->{timestamp},
4014             undef,
4015         );
4016         return "Success.";
4017     } else {
4018         return "Borrower not found.";
4019     }
4020 }
4021
4022 sub ProcessOfflinePayment {
4023     my $operation = shift;
4024
4025     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4026
4027     $patron->account->pay(
4028         {
4029             amount     => $operation->{amount},
4030             library_id => $operation->{branchcode},
4031             interface  => 'koc'
4032         }
4033     );
4034
4035     return "Success.";
4036 }
4037
4038 =head2 TransferSlip
4039
4040   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4041
4042   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4043
4044 =cut
4045
4046 sub TransferSlip {
4047     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4048
4049     my $item =
4050       $itemnumber
4051       ? Koha::Items->find($itemnumber)
4052       : Koha::Items->find( { barcode => $barcode } );
4053
4054     $item or return;
4055
4056     return C4::Letters::GetPreparedLetter (
4057         module => 'circulation',
4058         letter_code => 'TRANSFERSLIP',
4059         branchcode => $branch,
4060         tables => {
4061             'branches'    => $to_branch,
4062             'biblio'      => $item->biblionumber,
4063             'items'       => $item->unblessed,
4064         },
4065     );
4066 }
4067
4068 =head2 CheckIfIssuedToPatron
4069
4070   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4071
4072   Return 1 if any record item is issued to patron, otherwise return 0
4073
4074 =cut
4075
4076 sub CheckIfIssuedToPatron {
4077     my ($borrowernumber, $biblionumber) = @_;
4078
4079     my $dbh = C4::Context->dbh;
4080     my $query = q|
4081         SELECT COUNT(*) FROM issues
4082         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4083         WHERE items.biblionumber = ?
4084         AND issues.borrowernumber = ?
4085     |;
4086     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4087     return 1 if $is_issued;
4088     return;
4089 }
4090
4091 =head2 IsItemIssued
4092
4093   IsItemIssued( $itemnumber )
4094
4095   Return 1 if the item is on loan, otherwise return 0
4096
4097 =cut
4098
4099 sub IsItemIssued {
4100     my $itemnumber = shift;
4101     my $dbh = C4::Context->dbh;
4102     my $sth = $dbh->prepare(q{
4103         SELECT COUNT(*)
4104         FROM issues
4105         WHERE itemnumber = ?
4106     });
4107     $sth->execute($itemnumber);
4108     return $sth->fetchrow;
4109 }
4110
4111 =head2 GetAgeRestriction
4112
4113   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4114   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4115
4116   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4117   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4118
4119 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4120 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4121 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4122          Negative days mean the borrower has gone past the age restriction age.
4123
4124 =cut
4125
4126 sub GetAgeRestriction {
4127     my ($record_restrictions, $borrower) = @_;
4128     my $markers = C4::Context->preference('AgeRestrictionMarker');
4129
4130     return unless $record_restrictions;
4131     # Split $record_restrictions to something like FSK 16 or PEGI 6
4132     my @values = split ' ', uc($record_restrictions);
4133     return unless @values;
4134
4135     # Search first occurrence of one of the markers
4136     my @markers = split /\|/, uc($markers);
4137     return unless @markers;
4138
4139     my $index            = 0;
4140     my $restriction_year = 0;
4141     for my $value (@values) {
4142         $index++;
4143         for my $marker (@markers) {
4144             $marker =~ s/^\s+//;    #remove leading spaces
4145             $marker =~ s/\s+$//;    #remove trailing spaces
4146             if ( $marker eq $value ) {
4147                 if ( $index <= $#values ) {
4148                     $restriction_year += $values[$index];
4149                 }
4150                 last;
4151             }
4152             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4153
4154                 # Perhaps it is something like "K16" (as in Finland)
4155                 $restriction_year += $1;
4156                 last;
4157             }
4158         }
4159         last if ( $restriction_year > 0 );
4160     }
4161
4162     #Check if the borrower is age restricted for this material and for how long.
4163     if ($restriction_year && $borrower) {
4164         if ( $borrower->{'dateofbirth'} ) {
4165             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4166             $alloweddate[0] += $restriction_year;
4167
4168             #Prevent runime eror on leap year (invalid date)
4169             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4170                 $alloweddate[2] = 28;
4171             }
4172
4173             #Get how many days the borrower has to reach the age restriction
4174             my @Today = split /-/, dt_from_string()->ymd();
4175             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4176             #Negative days means the borrower went past the age restriction age
4177             return ($restriction_year, $daysToAgeRestriction);
4178         }
4179     }
4180
4181     return ($restriction_year);
4182 }
4183
4184
4185 =head2 GetPendingOnSiteCheckouts
4186
4187 =cut
4188
4189 sub GetPendingOnSiteCheckouts {
4190     my $dbh = C4::Context->dbh;
4191     return $dbh->selectall_arrayref(q|
4192         SELECT
4193           items.barcode,
4194           items.biblionumber,
4195           items.itemnumber,
4196           items.itemnotes,
4197           items.itemcallnumber,
4198           items.location,
4199           issues.date_due,
4200           issues.branchcode,
4201           issues.date_due < NOW() AS is_overdue,
4202           biblio.author,
4203           biblio.title,
4204           borrowers.firstname,
4205           borrowers.surname,
4206           borrowers.cardnumber,
4207           borrowers.borrowernumber
4208         FROM items
4209         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4210         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4211         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4212         WHERE issues.onsite_checkout = 1
4213     |, { Slice => {} } );
4214 }
4215
4216 sub GetTopIssues {
4217     my ($params) = @_;
4218
4219     my ($count, $branch, $itemtype, $ccode, $newness)
4220         = @$params{qw(count branch itemtype ccode newness)};
4221
4222     my $dbh = C4::Context->dbh;
4223     my $query = q{
4224         SELECT * FROM (
4225         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4226           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4227           i.ccode, SUM(i.issues) AS count
4228         FROM biblio b
4229         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4230         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4231     };
4232
4233     my (@where_strs, @where_args);
4234
4235     if ($branch) {
4236         push @where_strs, 'i.homebranch = ?';
4237         push @where_args, $branch;
4238     }
4239     if ($itemtype) {
4240         if (C4::Context->preference('item-level_itypes')){
4241             push @where_strs, 'i.itype = ?';
4242             push @where_args, $itemtype;
4243         } else {
4244             push @where_strs, 'bi.itemtype = ?';
4245             push @where_args, $itemtype;
4246         }
4247     }
4248     if ($ccode) {
4249         push @where_strs, 'i.ccode = ?';
4250         push @where_args, $ccode;
4251     }
4252     if ($newness) {
4253         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4254         push @where_args, $newness;
4255     }
4256
4257     if (@where_strs) {
4258         $query .= 'WHERE ' . join(' AND ', @where_strs);
4259     }
4260
4261     $query .= q{
4262         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4263           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4264           i.ccode
4265         ORDER BY count DESC
4266     };
4267
4268     $query .= q{ ) xxx WHERE count > 0 };
4269     $count = int($count);
4270     if ($count > 0) {
4271         $query .= "LIMIT $count";
4272     }
4273
4274     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4275
4276     return @$rows;
4277 }
4278
4279 =head2 Internal methods
4280
4281 =cut
4282
4283 sub _CalculateAndUpdateFine {
4284     my ($params) = @_;
4285
4286     my $borrower    = $params->{borrower};
4287     my $item        = $params->{item};
4288     my $issue       = $params->{issue};
4289     my $return_date = $params->{return_date};
4290
4291     unless ($borrower) { carp "No borrower passed in!" && return; }
4292     unless ($item)     { carp "No item passed in!"     && return; }
4293     unless ($issue)    { carp "No issue passed in!"    && return; }
4294
4295     my $datedue = dt_from_string( $issue->date_due );
4296
4297     # we only need to calculate and change the fines if we want to do that on return
4298     # Should be on for hourly loans
4299     my $control = C4::Context->preference('CircControl');
4300     my $control_branchcode =
4301         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4302       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4303       :                                     $issue->branchcode;
4304
4305     my $date_returned = $return_date ? $return_date : dt_from_string();
4306
4307     my ( $amount, $unitcounttotal, $unitcount  ) =
4308       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4309
4310     if ( C4::Context->preference('finesMode') eq 'production' ) {
4311         if ( $amount > 0 ) {
4312             C4::Overdues::UpdateFine({
4313                 issue_id       => $issue->issue_id,
4314                 itemnumber     => $issue->itemnumber,
4315                 borrowernumber => $issue->borrowernumber,
4316                 amount         => $amount,
4317                 due            => output_pref($datedue),
4318             });
4319         }
4320         elsif ($return_date) {
4321
4322             # Backdated returns may have fines that shouldn't exist,
4323             # so in this case, we need to drop those fines to 0
4324
4325             C4::Overdues::UpdateFine({
4326                 issue_id       => $issue->issue_id,
4327                 itemnumber     => $issue->itemnumber,
4328                 borrowernumber => $issue->borrowernumber,
4329                 amount         => 0,
4330                 due            => output_pref($datedue),
4331             });
4332         }
4333     }
4334 }
4335
4336 sub _item_denied_renewal {
4337     my ($params) = @_;
4338
4339     my $item = $params->{item};
4340     return unless $item;
4341
4342     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4343     return unless $denyingrules;
4344     foreach my $field (keys %$denyingrules) {
4345         my $val = $item->$field;
4346         if( !defined $val) {
4347             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4348                 return 1;
4349             }
4350         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4351            # If the results matches the values in the syspref
4352            # We return true if match found
4353             return 1;
4354         }
4355     }
4356     return 0;
4357 }
4358
4359 1;
4360
4361 __END__
4362
4363 =head1 AUTHOR
4364
4365 Koha Development Team <http://koha-community.org/>
4366
4367 =cut