circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 # FIXME There are too many calls to Koha::Patrons->find in this script
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use URI::Escape qw( uri_escape_utf8 );
  30 use DateTime;
  31 use DateTime::Duration;
  32 use Scalar::Util qw( looks_like_number );
  33 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  34 use C4::Auth qw( get_session get_template_and_user );
  35 use C4::Koha;
  36 use C4::Circulation qw( barcodedecode CanBookBeIssued AddIssue );
  37 use C4::Members;
  38 use C4::Biblio qw( TransformMarcToKoha );
  39 use C4::Search qw( new_record_from_zebra );
  40 use C4::Reserves;
  41 use Koha::Holds;
  42 use C4::Context;
  43 use CGI::Session;
  44 use Koha::AuthorisedValues;
  45 use Koha::CsvProfiles;
  46 use Koha::Patrons;
  47 use Koha::DateUtils qw( dt_from_string );
  48 use Koha::Patron::Restriction::Types;
  49 use Koha::Plugins;
  50 use Koha::Database;
  51 use Koha::BiblioFrameworks;
  52 use Koha::Items;
  53 use Koha::SearchEngine;
  54 use Koha::SearchEngine::Search;
  55 use Koha::Patron::Modifications;
  56 use Koha::Token;
  57
  58 use List::MoreUtils qw( uniq );
  59
  60 #
  61 # PARAMETERS READING
  62 #
  63 my $query = CGI->new;
  64
  65 my $override_high_holds     = $query->param('override_high_holds');
  66 my $override_high_holds_tmp = $query->param('override_high_holds_tmp');
  67
  68 my $sessionID = $query->cookie("CGISESSID") ;
  69 my $session = get_session($sessionID);
  70
  71 my $barcodes = [];
  72 my $barcode =  $query->param('barcode');
  73 my $findborrower;
  74 my $autoswitched;
  75 my $borrowernumber = $query->param('borrowernumber');
  76
  77 if (C4::Context->preference("AutoSwitchPatron") && $barcode) {
  78     my $new_barcode = $barcode;
  79     Koha::Plugins->call( 'patron_barcode_transform', \$new_barcode );
  80     if (Koha::Patrons->search( { cardnumber => $new_barcode} )->count() > 0) {
  81         $findborrower = $barcode;
  82         undef $barcode;
  83         undef $borrowernumber;
  84         $autoswitched = 1;
  85     }
  86 }
  87 $findborrower ||= $query->param('findborrower') || q{};
  88 $findborrower =~ s|,| |g;
  89
  90 # Barcode given by user could be '0'
  91 if ( $barcode || ( defined($barcode) && $barcode eq '0' ) ) {
  92     $barcodes = [ $barcode ];
  93 } else {
  94     my $filefh = $query->upload('uploadfile');
  95     if ( $filefh ) {
  96         while ( my $content = <$filefh> ) {
  97             $content =~ s/[\r\n]*$//g;
  98             push @$barcodes, $content if $content;
  99         }
 100     } elsif ( my $list = $query->param('barcodelist') ) {
 101         push @$barcodes, split( /\s\n/, $list );
 102         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
 103     } else {
 104         @$barcodes = $query->multi_param('barcodes');
 105     }
 106 }
 107
 108 $barcodes = [ uniq @$barcodes ];
 109
 110 my $template_name = q|circ/circulation.tt|;
 111 my $patron = $borrowernumber ? Koha::Patrons->find( $borrowernumber ) : undef;
 112 my $batch = $query->param('batch');
 113 my $batch_allowed = 0;
 114 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
 115     $template_name = q|circ/circulation_batch_checkouts.tt|;
 116     my @batch_category_codes = split ',', C4::Context->preference('BatchCheckoutsValidCategories');
 117     my $categorycode = $patron->categorycode;
 118     if ( $categorycode && grep { $_ eq $categorycode } @batch_category_codes ) {
 119         $batch_allowed = 1;
 120     } else {
 121         $barcodes = [];
 122     }
 123 }
 124
 125 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
 126     {
 127         template_name   => $template_name,
 128         query           => $query,
 129         type            => "intranet",
 130         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
 131     }
 132 );
 133 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
 134
 135 my $force_allow_issue = $query->param('forceallow') || 0;
 136 if (!C4::Auth::haspermission( C4::Context->userenv->{id} , { circulate => 'force_checkout' } )) {
 137     $force_allow_issue = 0;
 138 }
 139 my $onsite_checkout = $query->param('onsite_checkout');
 140
 141 if (C4::Context->preference("OnSiteCheckoutAutoCheck") && $onsite_checkout eq "on") {
 142     $template->param(onsite_checkout => $onsite_checkout);
 143 }
 144
 145 my @failedrenews = $query->multi_param('failedrenew');    # expected to be itemnumbers
 146 our %renew_failed = ();
 147 for (@failedrenews) { $renew_failed{$_} = 1; }
 148
 149 my @failedreturns = $query->multi_param('failedreturn');
 150 our %return_failed = ();
 151 for (@failedreturns) { $return_failed{$_} = 1; }
 152
 153 my $branch = C4::Context->userenv->{'branch'};
 154
 155 for my $barcode ( @$barcodes ) {
 156     $barcode = barcodedecode( $barcode ) if $barcode;
 157 }
 158
 159 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 160 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 161 my $restoreduedatespec  = $query->param('restoreduedatespec') || $duedatespec || $session->param('stickyduedate');
 162 if ( $restoreduedatespec && $restoreduedatespec eq "highholds_empty" ) {
 163     undef $restoreduedatespec;
 164 }
 165 my $issueconfirmed = $query->param('issueconfirmed');
 166 my $cancelreserve  = $query->param('cancelreserve');
 167 my $cancel_recall  = $query->param('cancel_recall');
 168 my $recall_id      = $query->param('recall_id');
 169 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 170 my $charges        = $query->param('charges') || q{};
 171
 172 # Check if stickyduedate is turned off
 173 if ( @$barcodes ) {
 174     # was stickyduedate loaded from session?
 175     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 176         $session->clear( 'stickyduedate' );
 177         $stickyduedate  = $query->param('stickyduedate');
 178         $duedatespec    = $query->param('duedatespec');
 179     }
 180     $session->param('auto_renew', scalar $query->param('auto_renew'));
 181 }
 182 else {
 183     $session->clear('auto_renew');
 184 }
 185
 186 $template->param( auto_renew => $session->param('auto_renew') );
 187
 188 my ($datedue,$invalidduedate);
 189
 190 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 191 if( $onsite_checkout && !$duedatespec_allow ) {
 192     $datedue = dt_from_string()->truncate(to => 'day');
 193     $datedue->set_hour(23);
 194     $datedue->set_minute(59);
 195 } elsif( $duedatespec_allow ) {
 196     if ( $duedatespec ) {
 197         $datedue = eval { dt_from_string( $duedatespec ) };
 198         if (! $datedue ) {
 199             $invalidduedate = 1;
 200             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
 201         }
 202     }
 203 }
 204
 205 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
 206 if ( @$barcodes == 0 && $charges eq 'yes' ) {
 207     $template->param(
 208         PAYCHARGES     => 'yes',
 209         borrowernumber => $borrowernumber
 210     );
 211 }
 212
 213 #
 214 # STEP 2 : FIND BORROWER
 215 # if there is a list of find borrowers....
 216 #
 217 my $message;
 218 if ($findborrower) {
 219     Koha::Plugins->call( 'patron_barcode_transform', \$findborrower );
 220     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 221     if ( $patron ) {
 222         $borrowernumber = $patron->borrowernumber;
 223     } else {
 224         print $query->redirect( "/cgi-bin/koha/members/member.pl?quicksearch=1&circsearch=1&searchmember=" . uri_escape_utf8($findborrower) );
 225         exit;
 226     }
 227 }
 228
 229 # get the borrower information.....
 230 my $balance = 0;
 231 $patron ||= Koha::Patrons->find( $borrowernumber ) if $borrowernumber;
 232 if ($patron) {
 233
 234     $template->param( borrowernumber => $patron->borrowernumber );
 235     output_and_exit_if_error( $query, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
 236
 237     my $overdues = $patron->overdues;
 238     my $issues = $patron->checkouts;
 239     $balance = $patron->account->balance;
 240
 241
 242     # if the expiry date is before today ie they have expired
 243     if ( $patron->is_expired ) {
 244         #borrowercard expired, no issues
 245         $template->param(
 246             noissues => ($force_allow_issue) ? 0 : "1",
 247             forceallow => $force_allow_issue,
 248             expired => "1",
 249         );
 250     }
 251     # check for NotifyBorrowerDeparture
 252     elsif ( $patron->is_going_to_expire ) {
 253         # borrower card soon to expire warn librarian
 254         $template->param( "warndeparture" => $patron->dateexpiry ,
 255                         );
 256         if (C4::Context->preference('ReturnBeforeExpiry')){
 257             $template->param("returnbeforeexpiry" => 1);
 258         }
 259     }
 260     $template->param(
 261         overduecount => $overdues->count,
 262         issuecount   => $issues->count,
 263         finetotal    => $balance,
 264     );
 265
 266     if ( $patron and $patron->is_debarred ) {
 267         $template->param(
 268             'userdebarred'    => $patron->debarred,
 269             'debarredcomment' => $patron->debarredcomment,
 270         );
 271
 272         if ( $patron->debarred ne "9999-12-31" ) {
 273             $template->param( 'userdebarreddate' => $patron->debarred );
 274         }
 275     }
 276
 277     # Calculate and display patron's age
 278     if ( !$patron->is_valid_age ) {
 279         $template->param( age_limitations => 1 );
 280         $template->param( age_low => $patron->category->dateofbirthrequired );
 281         $template->param( age_high => $patron->category->upperagelimit );
 282     }
 283
 284 }
 285
 286 #
 287 # STEP 3 : ISSUING
 288 #
 289 #
 290 if (@$barcodes) {
 291   my $checkout_infos;
 292   for my $barcode ( @$barcodes ) {
 293
 294     my $template_params = {
 295         barcode         => $barcode,
 296         onsite_checkout => $onsite_checkout,
 297     };
 298
 299     # always check for blockers on issuing
 300     my ( $error, $question, $alerts, $messages ) = CanBookBeIssued(
 301         $patron,
 302         $barcode, $datedue,
 303         $inprocess,
 304         undef,
 305         {
 306             onsite_checkout     => $onsite_checkout,
 307             override_high_holds => $override_high_holds || $override_high_holds_tmp || 0,
 308         }
 309     );
 310
 311     my $blocker = $invalidduedate ? 1 : 0;
 312
 313     $template_params->{alert} = $alerts;
 314     $template_params->{messages} = $messages;
 315
 316     my $item = Koha::Items->find({ barcode => $barcode });
 317
 318     my $biblio;
 319     if ( $item ) {
 320         $biblio = $item->biblio;
 321     }
 322
 323     # Fix for bug 7494: optional checkout-time fallback search for a book
 324
 325     if ( $error->{'UNKNOWN_BARCODE'}
 326         && C4::Context->preference("itemBarcodeFallbackSearch")
 327         && not $batch
 328     )
 329     {
 330      $template_params->{FALLBACK} = 1;
 331
 332         my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
 333         my $query = "kw=" . $barcode;
 334         my ( $searcherror, $results, $total_hits ) = $searcher->simple_search_compat($query, 0, 10);
 335
 336         # if multiple hits, offer options to librarian
 337         if ( $total_hits > 0 ) {
 338             my @barcodes;
 339             foreach my $hit ( @{$results} ) {
 340                 my $chosen = # Maybe easier to retrieve the itemnumber from $hit?
 341                   TransformMarcToKoha({ record => C4::Search::new_record_from_zebra('biblioserver',$hit) });
 342
 343                 # offer all barcodes individually
 344                 if ( $chosen->{barcode} ) {
 345                     push @barcodes, sort split(/\s*\|\s*/, $chosen->{barcode});
 346                 }
 347             }
 348             my $items = Koha::Items->search({ barcode => {-in => \@barcodes}});
 349             $template_params->{options} = $items;
 350         }
 351     }
 352
 353     # Only some errors will block when performing forced onsite checkout,
 354     # for other cases all errors will block
 355     my @blocking_error_codes = ($onsite_checkout and C4::Context->preference("OnSiteCheckoutsForce")) ?
 356         qw( UNKNOWN_BARCODE ) : (keys %$error);
 357
 358     foreach my $code ( @blocking_error_codes ) {
 359         if ($error->{$code}) {
 360             $template_params->{$code} = $error->{$code};
 361             $template_params->{IMPOSSIBLE} = 1;
 362             $blocker = 1;
 363         }
 364     }
 365
 366     delete $question->{'DEBT'} if ($debt_confirmed);
 367
 368     if( $item and ( !$blocker or $force_allow_issue ) ){
 369         my $confirm_required = 0;
 370         unless($issueconfirmed){
 371             #  Get the item title for more information
 372             my $materials = $item->materials;
 373             my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.materials', authorised_value => $materials });
 374             $materials = $descriptions->{lib} // $materials;
 375             $template_params->{ADDITIONAL_MATERIALS} = $materials;
 376             $template_params->{itemhomebranch} = $item->homebranch;
 377
 378             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 379             foreach my $needsconfirmation ( keys %$question ) {
 380                 $template_params->{$needsconfirmation} = $$question{$needsconfirmation};
 381                 $template_params->{getTitleMessageIteminfo} = $biblio->title;
 382                 $template_params->{getBarcodeMessageIteminfo} = $item->barcode;
 383                 $template_params->{NEEDSCONFIRMATION} = 1;
 384                 $confirm_required = 1;
 385             }
 386         }
 387         unless($confirm_required) {
 388             my $switch_onsite_checkout = exists $messages->{ONSITE_CHECKOUT_WILL_BE_SWITCHED};
 389             if ( C4::Context->preference('UseRecalls') && !$recall_id ) {
 390                 my $recall = Koha::Recalls->find(
 391                     {
 392                         biblio_id => $item->biblionumber,
 393                         item_id   => [ undef, $item->itemnumber ],
 394                         status    => [ 'requested', 'waiting' ],
 395                         completed => 0,
 396                         patron_id => $patron->borrowernumber,
 397                     }
 398                 );
 399                 $recall_id = ( $recall and $recall->id ) ? $recall->id : undef;
 400             }
 401             my $issue = AddIssue( $patron->unblessed, $barcode, $datedue, $cancelreserve, undef, undef, { onsite_checkout => $onsite_checkout, auto_renew => $session->param('auto_renew'), switch_onsite_checkout => $switch_onsite_checkout, cancel_recall => $cancel_recall, recall_id => $recall_id, } );
 402             $template_params->{issue} = $issue;
 403             $session->clear('auto_renew');
 404             $inprocess = 1;
 405         }
 406     }
 407
 408     if ($question->{RESERVE_WAITING} or $question->{RESERVED} or $question->{TRANSFERRED} or $question->{PROCESSING}){
 409         $template->param(
 410             reserveborrowernumber => $question->{'resborrowernumber'},
 411             reserve_id => $question->{reserve_id},
 412         );
 413     }
 414
 415
 416     # FIXME If the issue is confirmed, we launch another time checkouts->count, now display the issue count after issue
 417     $patron = Koha::Patrons->find( $borrowernumber );
 418     $template_params->{issuecount} = $patron->checkouts->count;
 419
 420     if ( $item ) {
 421         $template_params->{item} = $item;
 422         $template_params->{biblio} = $biblio;
 423         $template_params->{itembiblionumber} = $biblio->biblionumber;
 424     }
 425     push @$checkout_infos, $template_params;
 426   }
 427   unless ( $batch ) {
 428     $template->param( %{$checkout_infos->[0]} );
 429     $template->param( barcode => $barcodes->[0] );
 430   } else {
 431     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
 432     $template->param(
 433         checkout_infos => $checkout_infos,
 434         confirmation_needed => $confirmation_needed,
 435     );
 436   }
 437 }
 438
 439 ##################################################################################
 440 # BUILD HTML
 441 # show all reserves of this borrower, and the position of the reservation ....
 442 if ($patron) {
 443     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } ); # FIXME must be Koha::Patron->holds
 444     my $waiting_holds = $holds->waiting;
 445     $template->param(
 446         holds_count  => $holds->count(),
 447         WaitingHolds => $waiting_holds,
 448     );
 449
 450     if ( C4::Context->preference('UseRecalls') ) {
 451         my $waiting_recalls = $patron->recalls->search({ status => 'waiting' });
 452         $template->param(
 453             recalls => $patron->recalls->filter_by_current->search({},{ order_by => { -asc => 'created_date' } }),
 454             specific_patron => 1,
 455             waiting_recalls => $waiting_recalls,
 456         );
 457     }
 458 }
 459
 460 if ( $patron ) {
 461     my $noissues;
 462     if ( $patron->gonenoaddress ) {
 463         $template->param( gonenoaddress => 1 );
 464         $noissues = 1;
 465     }
 466     if ( $patron->lost ) {
 467         $template->param( lost=> 1 );
 468         $noissues = 1;
 469     }
 470     if ( $patron->is_debarred ) {
 471         $template->param( is_debarred=> 1 );
 472         $noissues = 1;
 473     }
 474     my $account = $patron->account;
 475     if( ( my $owing = $account->non_issues_charges ) > 0 ) {
 476         my $noissuescharge = C4::Context->preference("noissuescharge") || 5; # FIXME If noissuescharge == 0 then 5, why??
 477         $noissues ||= ( not C4::Context->preference("AllowFineOverride") and ( $owing > $noissuescharge ) );
 478         $template->param(
 479             charges => 1,
 480             chargesamount => $owing,
 481         )
 482     } elsif ( $balance < 0 ) {
 483         $template->param(
 484             credits => 1,
 485             creditsamount => -$balance,
 486         );
 487     }
 488
 489     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 490     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 491     if ( $no_issues_charge_guarantors ) {
 492         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 493
 494         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors ) {
 495             $template->param(
 496                 charges_guarantors_guarantees => $guarantors_non_issues_charges
 497             );
 498             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 499         }
 500     }
 501
 502     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 503     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 504     if ( defined $no_issues_charge_guarantees ) {
 505         my $guarantees_non_issues_charges = 0;
 506         my $guarantees = $patron->guarantee_relationships->guarantees;
 507         while ( my $g = $guarantees->next ) {
 508             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 509         }
 510         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees ) {
 511             $template->param(
 512                 charges_guarantees    => 1,
 513                 chargesamount_guarantees => $guarantees_non_issues_charges,
 514             );
 515             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 516         }
 517     }
 518
 519     if ( $patron->has_overdues ) {
 520         $template->param( odues => 1 );
 521     }
 522
 523     if ( $patron->borrowernotes ) {
 524         my $borrowernotes = $patron->borrowernotes;
 525         $borrowernotes =~ s#\n#<br />#g;
 526         $template->param(
 527             notes =>1,
 528             notesmsg => $borrowernotes,
 529         )
 530     }
 531
 532     if ( $noissues ) {
 533         $template->param(
 534             noissues => ($force_allow_issue) ? 0 : 'true',
 535             forceallow => $force_allow_issue,
 536         );
 537     }
 538
 539     my $patron_messages = $patron->messages->search(
 540         {},
 541         {
 542            join => 'manager',
 543            '+select' => ['manager.surname', 'manager.firstname' ],
 544            '+as' => ['manager_surname', 'manager_firstname'],
 545         }
 546     );
 547     $template->param( patron_messages => $patron_messages );
 548
 549 }
 550
 551 my $fast_cataloging = 0;
 552 if ( Koha::BiblioFrameworks->find('FA') ) {
 553     $fast_cataloging = 1
 554 }
 555
 556 my $view = $batch
 557     ?'batch_checkout_view'
 558     : 'circview';
 559
 560 my @relatives;
 561 if ( $patron ) {
 562     if ( my @guarantors = $patron->guarantor_relationships()->guarantors->as_list ) {
 563         push( @relatives, $_->id ) for @guarantors;
 564         push( @relatives, $_->id ) for $patron->siblings->as_list;
 565     } else {
 566         push( @relatives, $_->id ) for $patron->guarantee_relationships()->guarantees->as_list;
 567     }
 568 }
 569 my $relatives_issues_count =
 570   Koha::Database->new()->schema()->resultset('Issue')
 571   ->count( { borrowernumber => \@relatives } );
 572
 573 if ( $patron ) {
 574     my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $patron->streettype });
 575     my $roadtype = $av->count ? $av->next->lib : '';
 576     $template->param(
 577         roadtype          => $roadtype,
 578         patron            => $patron,
 579         categoryname      => $patron->category->description,
 580         expiry            => $patron->dateexpiry,
 581     );
 582 }
 583
 584 # Restore date if changed by holds and/or save stickyduedate to session
 585 if ($restoreduedatespec || $stickyduedate) {
 586     $duedatespec = $restoreduedatespec || $duedatespec;
 587
 588     if ($stickyduedate) {
 589         $session->param( 'stickyduedate', $duedatespec );
 590     }
 591 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
 592     undef $duedatespec;
 593 }
 594
 595 $template->param(
 596     borrowernumber    => $borrowernumber,
 597     branch            => $branch,
 598     was_renewed       => scalar $query->param('was_renewed') ? 1 : 0,
 599     barcodes          => $barcodes,
 600     stickyduedate     => $stickyduedate,
 601     duedatespec       => $duedatespec,
 602     restoreduedatespec => $restoreduedatespec,
 603     message           => $message,
 604     totaldue          => sprintf('%.2f', $balance), # FIXME not used in template?
 605     inprocess         => $inprocess,
 606     $view             => 1,
 607     batch_allowed     => $batch_allowed,
 608     batch             => $batch,
 609     AudioAlerts           => C4::Context->preference("AudioAlerts"),
 610     fast_cataloging   => $fast_cataloging,
 611     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 612     RoutingSerials => C4::Context->preference('RoutingSerials'),
 613     relatives_issues_count => $relatives_issues_count,
 614     relatives_borrowernumbers => \@relatives,
 615 );
 616
 617
 618 if ( C4::Context->preference("ExportCircHistory") ) {
 619     $template->param(csv_profiles => Koha::CsvProfiles->search({ type => 'marc' }));
 620 }
 621
 622 my $has_modifications = Koha::Patron::Modifications->search( { borrowernumber => $borrowernumber } )->count;
 623 $template->param(
 624     debt_confirmed            => $debt_confirmed,
 625     SpecifyDueDate            => $duedatespec_allow,
 626     PatronAutoComplete        => C4::Context->preference("PatronAutoComplete"),
 627     today_due_date_and_time   => dt_from_string()->set(hour => 23)->set(minute => 59),
 628     restriction_types         => scalar Koha::Patron::Restriction::Types->search(),
 629     has_modifications         => $has_modifications,
 630     override_high_holds       => $override_high_holds,
 631     nopermission              => scalar $query->param('nopermission'),
 632     autoswitched              => $autoswitched,
 633     logged_in_user            => $logged_in_user,
 634 );
 635
 636 # Generate CSRF token for upload and delete image buttons
 637 $template->param(
 638     csrf_token => Koha::Token->new->generate_csrf({ session_id => $query->cookie('CGISESSID'),}),
 639 );
 640
 641 output_html_with_http_headers $query, $cookie, $template->output;