misc/cronjobs/recalls/expire_recalls.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2020 Aleisha Amohia <aleisha@catalyst.net.nz>
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 BEGIN {
  23     # find Koha's Perl modules
  24     # test carefully before changing this
  25     use FindBin;
  26     eval { require "$FindBin::Bin/../kohalib.pl" };
  27 }
  28
  29 # set overdue recalls as overdue. This includes:
  30 # - recalls that have been requested and not fulfilled and have passed their expiration date
  31 # - recalls that have been awaiting pickup for longer than the specified recall_shelf_time circulation rule, or the RecallsMaxPickUpDelay if circ rule is unset
  32
  33 use Koha::Script -cron;
  34 use Koha::DateUtils qw( dt_from_string );
  35 use Koha::Recalls;
  36 use C4::Log;
  37
  38 my $command_line_options = join(" ",@ARGV);
  39
  40 cronlogaction({ info => $command_line_options });
  41
  42 my $recalls = Koha::Recalls->search({ completed => 0 });
  43 my $today = dt_from_string()->truncate( to  => 'day' );
  44 while( my $recall = $recalls->next ) {
  45     if ( ( $recall->requested or $recall->overdue or $recall->waiting ) and $recall->expiration_date ) {
  46         my $expiration_date = dt_from_string( $recall->expiration_date )->truncate( to  => 'day' );
  47         if ( $expiration_date < $today ){
  48             # recall is requested or overdue and has surpassed the specified expiration date
  49             $recall->set_expired({ interface => 'COMMANDLINE' });
  50         }
  51     }
  52     if ( $recall->waiting ) {
  53         my $recall_shelf_time = Koha::CirculationRules->get_effective_rule({
  54             categorycode => $recall->patron->categorycode,
  55             itemtype => $recall->item->effective_itemtype,
  56             branchcode => $recall->pickup_library_id,
  57             rule_name => 'recall_shelf_time',
  58         });
  59         my $waitingdate = dt_from_string( $recall->waiting_date )->truncate( to  => 'day' );
  60         my $days_waiting = $today->subtract_datetime( $waitingdate );
  61         if ( defined $recall_shelf_time and $recall_shelf_time->rule_value >= 0 ) {
  62             if ( $days_waiting->days > $recall_shelf_time->rule_value ) {
  63                 # recall has been awaiting pickup for longer than the circ rules allow
  64                 $recall->set_expired({ interface => 'COMMANDLINE' });
  65             }
  66         } else {
  67             if ( $days_waiting->days >= C4::Context->preference('RecallsMaxPickUpDelay') ) {
  68                 # recall has been awaiting pickup for longer than the syspref allows
  69                 $recall->set_expired({ interface => 'COMMANDLINE' });
  70             }
  71         }
  72     }
  73 }
  74
  75 cronlogaction({ action => 'End', info => "COMPLETED" });