C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use Koha::DateUtils;
  28 use C4::Context;
  29 use C4::Stats;
  30 use C4::Reserves;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Members;
  34 use C4::Accounts;
  35 use C4::ItemCirculationAlertPreference;
  36 use C4::Message;
  37 use C4::Debug;
  38 use C4::Log; # logaction
  39 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  40 use C4::RotatingCollections qw(GetCollectionItemBranches);
  41 use Algorithm::CheckDigits;
  42
  43 use Data::Dumper;
  44 use Koha::Account;
  45 use Koha::AuthorisedValues;
  46 use Koha::Biblioitems;
  47 use Koha::DateUtils;
  48 use Koha::Calendar;
  49 use Koha::Checkouts;
  50 use Koha::Illrequests;
  51 use Koha::Items;
  52 use Koha::Patrons;
  53 use Koha::Patron::Debarments;
  54 use Koha::Database;
  55 use Koha::Libraries;
  56 use Koha::Account::Lines;
  57 use Koha::Holds;
  58 use Koha::Account::Lines;
  59 use Koha::Account::Offsets;
  60 use Koha::Config::SysPrefs;
  61 use Koha::Charges::Fees;
  62 use Koha::Config::SysPref;
  63 use Koha::Checkouts::ReturnClaims;
  64 use Koha::SearchEngine::Indexer;
  65 use Koha::Exceptions::Checkout;
  66 use Carp;
  67 use List::MoreUtils qw( uniq any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Try::Tiny;
  70 use Date::Calc qw(
  71   Today
  72   Today_and_Now
  73   Add_Delta_YM
  74   Add_Delta_DHMS
  75   Date_to_Days
  76   Day_of_Week
  77   Add_Delta_Days
  78 );
  79 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  80
  81 BEGIN {
  82         require Exporter;
  83         @ISA    = qw(Exporter);
  84
  85         # FIXME subs that should probably be elsewhere
  86         push @EXPORT, qw(
  87                 &barcodedecode
  88         &LostItem
  89         &ReturnLostItem
  90         &GetPendingOnSiteCheckouts
  91         );
  92
  93         # subs to deal with issuing a book
  94         push @EXPORT, qw(
  95                 &CanBookBeIssued
  96                 &CanBookBeRenewed
  97                 &AddIssue
  98                 &AddRenewal
  99                 &GetRenewCount
 100         &GetSoonestRenewDate
 101         &GetLatestAutoRenewDate
 102                 &GetIssuingCharges
 103         &GetBranchBorrowerCircRule
 104         &GetBranchItemRule
 105                 &GetOpenIssue
 106         &CheckIfIssuedToPatron
 107         &IsItemIssued
 108         GetTopIssues
 109         );
 110
 111         # subs to deal with returns
 112         push @EXPORT, qw(
 113                 &AddReturn
 114         &MarkIssueReturned
 115         );
 116
 117         # subs to deal with transfers
 118         push @EXPORT, qw(
 119                 &transferbook
 120                 &GetTransfers
 121                 &GetTransfersFromTo
 122                 &updateWrongTransfer
 123                 &DeleteTransfer
 124                 &IsBranchTransferAllowed
 125                 &CreateBranchTransferLimit
 126                 &DeleteBranchTransferLimits
 127         &TransferSlip
 128         );
 129
 130     # subs to deal with offline circulation
 131     push @EXPORT, qw(
 132       &GetOfflineOperations
 133       &GetOfflineOperation
 134       &AddOfflineOperation
 135       &DeleteOfflineOperation
 136       &ProcessOfflineOperation
 137     );
 138 }
 139
 140 =head1 NAME
 141
 142 C4::Circulation - Koha circulation module
 143
 144 =head1 SYNOPSIS
 145
 146 use C4::Circulation;
 147
 148 =head1 DESCRIPTION
 149
 150 The functions in this module deal with circulation, issues, and
 151 returns, as well as general information about the library.
 152 Also deals with inventory.
 153
 154 =head1 FUNCTIONS
 155
 156 =head2 barcodedecode
 157
 158   $str = &barcodedecode($barcode, [$filter]);
 159
 160 Generic filter function for barcode string.
 161 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 162 Will do some manipulation of the barcode for systems that deliver a barcode
 163 to circulation.pl that differs from the barcode stored for the item.
 164 For proper functioning of this filter, calling the function on the
 165 correct barcode string (items.barcode) should return an unaltered barcode.
 166
 167 The optional $filter argument is to allow for testing or explicit
 168 behavior that ignores the System Pref.  Valid values are the same as the
 169 System Pref options.
 170
 171 =cut
 172
 173 # FIXME -- the &decode fcn below should be wrapped into this one.
 174 # FIXME -- these plugins should be moved out of Circulation.pm
 175 #
 176 sub barcodedecode {
 177     my ($barcode, $filter) = @_;
 178     my $branch = C4::Context::mybranch();
 179     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 180     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 181         if ($filter eq 'whitespace') {
 182                 $barcode =~ s/\s//g;
 183         } elsif ($filter eq 'cuecat') {
 184                 chomp($barcode);
 185             my @fields = split( /\./, $barcode );
 186             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 187             ($#results == 2) and return $results[2];
 188         } elsif ($filter eq 'T-prefix') {
 189                 if ($barcode =~ /^[Tt](\d)/) {
 190                         (defined($1) and $1 eq '0') and return $barcode;
 191             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 192                 }
 193         return sprintf("T%07d", $barcode);
 194         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 195         # Why drop the nonzero digit after the T?
 196         # Why pass non-digits (or empty string) to "T%07d"?
 197         } elsif ($filter eq 'libsuite8') {
 198                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 199                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 200                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 201                         }else{
 202                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 203                         }
 204                 }
 205     } elsif ($filter eq 'EAN13') {
 206         my $ean = CheckDigits('ean');
 207         if ( $ean->is_valid($barcode) ) {
 208             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 209             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 210         } else {
 211             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 212         }
 213         }
 214     return $barcode;    # return barcode, modified or not
 215 }
 216
 217 =head2 _decode
 218
 219   $str = &_decode($chunk);
 220
 221 Decodes a segment of a string emitted by a CueCat barcode scanner and
 222 returns it.
 223
 224 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 225 or Javascript based decoding on the client side.
 226
 227 =cut
 228
 229 sub _decode {
 230     my ($encoded) = @_;
 231     my $seq =
 232       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 233     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 234     my $l = ( $#s + 1 ) % 4;
 235     if ($l) {
 236         if ( $l == 1 ) {
 237             # warn "Error: Cuecat decode parsing failed!";
 238             return;
 239         }
 240         $l = 4 - $l;
 241         $#s += $l;
 242     }
 243     my $r = '';
 244     while ( $#s >= 0 ) {
 245         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 246         $r .=
 247             chr( ( $n >> 16 ) ^ 67 )
 248          .chr( ( $n >> 8 & 255 ) ^ 67 )
 249          .chr( ( $n & 255 ) ^ 67 );
 250         @s = @s[ 4 .. $#s ];
 251     }
 252     $r = substr( $r, 0, length($r) - $l );
 253     return $r;
 254 }
 255
 256 =head2 transferbook
 257
 258   ($dotransfer, $messages, $iteminformation) = &transferbook({
 259                                                    from_branch => $frombranch
 260                                                    to_branch => $tobranch,
 261                                                    barcode => $barcode,
 262                                                    ignore_reserves => $ignore_reserves,
 263                                                    trigger => $trigger
 264                                                 });
 265
 266 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 267
 268 C<$fbr> is the code for the branch initiating the transfer.
 269 C<$tbr> is the code for the branch to which the item should be transferred.
 270
 271 C<$barcode> is the barcode of the item to be transferred.
 272
 273 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 274 Otherwise, if an item is reserved, the transfer fails.
 275
 276 C<$trigger> is the enum value for what triggered the transfer.
 277
 278 Returns three values:
 279
 280 =over
 281
 282 =item $dotransfer
 283
 284 is true if the transfer was successful.
 285
 286 =item $messages
 287
 288 is a reference-to-hash which may have any of the following keys:
 289
 290 =over
 291
 292 =item C<BadBarcode>
 293
 294 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 295
 296 =item C<DestinationEqualsHolding>
 297
 298 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 299
 300 =item C<WasReturned>
 301
 302 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 303
 304 =item C<ResFound>
 305
 306 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 307
 308 =item C<WasTransferred>
 309
 310 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 311
 312 =back
 313
 314 =back
 315
 316 =cut
 317
 318 sub transferbook {
 319     my $params = shift;
 320     my $tbr      = $params->{to_branch};
 321     my $fbr      = $params->{from_branch};
 322     my $ignoreRs = $params->{ignore_reserves};
 323     my $barcode  = $params->{barcode};
 324     my $trigger  = $params->{trigger};
 325     my $messages;
 326     my $dotransfer      = 1;
 327     my $item = Koha::Items->find( { barcode => $barcode } );
 328
 329     Koha::Exceptions::MissingParameter->throw(
 330         "Missing mandatory parameter: from_branch")
 331       unless $fbr;
 332
 333     Koha::Exceptions::MissingParameter->throw(
 334         "Missing mandatory parameter: to_branch")
 335       unless $tbr;
 336
 337     # bad barcode..
 338     unless ( $item ) {
 339         $messages->{'BadBarcode'} = $barcode;
 340         $dotransfer = 0;
 341         return ( $dotransfer, $messages );
 342     }
 343
 344     my $itemnumber = $item->itemnumber;
 345     # get branches of book...
 346     my $hbr = $item->homebranch;
 347
 348     # if using Branch Transfer Limits
 349     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 350         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 351         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 352             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 353                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 354                 $dotransfer = 0;
 355             }
 356         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 357             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 358             $dotransfer = 0;
 359         }
 360     }
 361
 362     # can't transfer book if is already there....
 363     if ( $fbr eq $tbr ) {
 364         $messages->{'DestinationEqualsHolding'} = 1;
 365         $dotransfer = 0;
 366     }
 367
 368     # check if it is still issued to someone, return it...
 369     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 370     if ( $issue ) {
 371         AddReturn( $barcode, $fbr );
 372         $messages->{'WasReturned'} = $issue->borrowernumber;
 373     }
 374
 375     # find reserves.....
 376     # That'll save a database query.
 377     my ( $resfound, $resrec, undef ) =
 378       CheckReserves( $itemnumber );
 379     if ( $resfound and not $ignoreRs ) {
 380         $resrec->{'ResFound'} = $resfound;
 381         $messages->{'ResFound'} = $resrec;
 382         $dotransfer = 1;
 383     }
 384
 385     #actually do the transfer....
 386     if ($dotransfer) {
 387         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 388
 389         # don't need to update MARC anymore, we do it in batch now
 390         $messages->{'WasTransfered'} = $tbr;
 391
 392     }
 393     ModDateLastSeen( $itemnumber );
 394     return ( $dotransfer, $messages );
 395 }
 396
 397
 398 sub TooMany {
 399     my $borrower        = shift;
 400     my $item_object = shift;
 401     my $params = shift;
 402     my $onsite_checkout = $params->{onsite_checkout} || 0;
 403     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 404     my $cat_borrower    = $borrower->{'categorycode'};
 405     my $dbh             = C4::Context->dbh;
 406     # Get which branchcode we need
 407     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 408     my $type = $item_object->effective_itemtype;
 409
 410     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 411     $type_object = Koha::ItemTypes->find( $type );
 412     $parent_type = $type_object->parent_type if $type_object;
 413     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 414     # Find any children if we are a parent_type;
 415
 416     # given branch, patron category, and item type, determine
 417     # applicable issuing rule
 418
 419     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 420         {
 421             categorycode => $cat_borrower,
 422             itemtype     => $parent_type,
 423             branchcode   => $branch,
 424             rule_name    => 'maxissueqty',
 425         }
 426     ) if $parent_type;
 427     # If the parent rule is for default type we discount it
 428     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 429
 430     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 431         {
 432             categorycode => $cat_borrower,
 433             itemtype     => $type,
 434             branchcode   => $branch,
 435             rule_name    => 'maxissueqty',
 436         }
 437     );
 438
 439     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 440         {
 441             categorycode => $cat_borrower,
 442             itemtype     => $type,
 443             branchcode   => $branch,
 444             rule_name    => 'maxonsiteissueqty',
 445         }
 446     );
 447
 448
 449     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 450     # if a rule is found and has a loan limit set, count
 451     # how many loans the patron already has that meet that
 452     # rule
 453     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 454
 455         my $checkouts;
 456         if ( $maxissueqty_rule->branchcode ) {
 457             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 458                 $checkouts = $patron->checkouts->search(
 459                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 460             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 461                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 462             } else {
 463                 $checkouts = $patron->checkouts->search(
 464                     { 'item.homebranch' => $maxissueqty_rule->branchcode },
 465                     { prefetch          => 'item' } );
 466             }
 467         } else {
 468             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 469         }
 470         my $sum_checkouts;
 471         my $rule_itemtype = $maxissueqty_rule->itemtype;
 472         while ( my $c = $checkouts->next ) {
 473             my $itemtype = $c->item->effective_itemtype;
 474             my @types;
 475             unless ( $rule_itemtype ) {
 476                 # matching rule has the default item type, so count only
 477                 # those existing loans that don't fall under a more
 478                 # specific rule
 479                 @types = Koha::CirculationRules->search(
 480                     {
 481                         branchcode => $maxissueqty_rule->branchcode,
 482                         categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 483                         itemtype  => { '!=' => undef },
 484                         rule_name => 'maxissueqty'
 485                     }
 486                 )->get_column('itemtype');
 487
 488                 next if grep {$_ eq $itemtype} @types;
 489             } else {
 490                 my @types;
 491                 if ( $parent_maxissueqty_rule ) {
 492                 # if we have a parent item type then we count loans of the
 493                 # specific item type or its siblings or parent
 494                     my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 495                     @types = $children->get_column('itemtype');
 496                     push @types, $parent_type;
 497                 } elsif ( $child_types ) {
 498                 # If we are a parent type, we need to count all child types and our own type
 499                     @types = $child_types->get_column('itemtype');
 500                     push @types, $type; # And don't forget to count our own types
 501                 } else { push @types, $type; } # Otherwise only count the specific itemtype
 502
 503                 next unless grep {$_ eq $itemtype} @types;
 504             }
 505             $sum_checkouts->{total}++;
 506             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 507             $sum_checkouts->{itemtype}->{$itemtype}++;
 508         }
 509
 510         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 511         my $checkout_count = $sum_checkouts->{total} || 0;
 512         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 513
 514         my $checkout_rules = {
 515             checkout_count               => $checkout_count,
 516             onsite_checkout_count        => $onsite_checkout_count,
 517             onsite_checkout              => $onsite_checkout,
 518             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 519             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 520             switch_onsite_checkout       => $switch_onsite_checkout,
 521         };
 522         # If parent rules exists
 523         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 524             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 525             my $qty_over = _check_max_qty($checkout_rules);
 526             return $qty_over if defined $qty_over;
 527
 528             # If the parent rule is less than or equal to the child, we only need check the parent
 529             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 530                 $checkout_rules->{checkout_count} = $checkout_count_type;
 531                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 532                 my $qty_over = _check_max_qty($checkout_rules);
 533                 return $qty_over if defined $qty_over;
 534             }
 535         } else {
 536             my $qty_over = _check_max_qty($checkout_rules);
 537             return $qty_over if defined $qty_over;
 538         }
 539     }
 540
 541     # Now count total loans against the limit for the branch
 542     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 543     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 544         my $checkouts;
 545         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 546             $checkouts = $patron->checkouts->search(
 547                 { 'me.branchcode' => $branch} );
 548         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 549             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 550         } else {
 551             $checkouts = $patron->checkouts->search(
 552                 { 'item.homebranch' => $branch},
 553                 { prefetch          => 'item' } );
 554         }
 555
 556         my $checkout_count = $checkouts->count;
 557         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 558         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 559         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 560
 561         my $qty_over = _check_max_qty(
 562             {
 563                 checkout_count               => $checkout_count,
 564                 onsite_checkout_count        => $onsite_checkout_count,
 565                 onsite_checkout              => $onsite_checkout,
 566                 max_checkouts_allowed        => $max_checkouts_allowed,
 567                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 568                 switch_onsite_checkout       => $switch_onsite_checkout
 569             }
 570         );
 571         return $qty_over if defined $qty_over;
 572     }
 573
 574     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 575         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 576     }
 577
 578     # OK, the patron can issue !!!
 579     return;
 580 }
 581
 582 sub _check_max_qty {
 583     my $params                       = shift;
 584     my $checkout_count               = $params->{checkout_count};
 585     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 586     my $onsite_checkout              = $params->{onsite_checkout};
 587     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 588     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 589     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 590
 591     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 592         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 593         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 594             return {
 595                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 596                 count       => $onsite_checkout_count,
 597                 max_allowed => $max_onsite_checkouts_allowed,
 598             };
 599         }
 600     }
 601     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 602         if ( $max_checkouts_allowed eq '' ) { return; }
 603         my $delta = $switch_onsite_checkout ? 1 : 0;
 604         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 605             return {
 606                 reason      => 'TOO_MANY_CHECKOUTS',
 607                 count       => $checkout_count,
 608                 max_allowed => $max_checkouts_allowed,
 609             };
 610         }
 611     }
 612     elsif ( not $onsite_checkout ) {
 613         if ( $max_checkouts_allowed eq '' ) { return; }
 614         if (
 615             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 616         {
 617             return {
 618                 reason      => 'TOO_MANY_CHECKOUTS',
 619                 count       => $checkout_count - $onsite_checkout_count,
 620                 max_allowed => $max_checkouts_allowed,
 621             };
 622         }
 623     }
 624
 625     return;
 626 }
 627
 628 =head2 CanBookBeIssued
 629
 630   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 631                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 632
 633 Check if a book can be issued.
 634
 635 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 636
 637 IMPORTANT: The assumption by users of this routine is that causes blocking
 638 the issue are keyed by uppercase labels and other returned
 639 data is keyed in lower case!
 640
 641 =over 4
 642
 643 =item C<$patron> is a Koha::Patron
 644
 645 =item C<$barcode> is the bar code of the book being issued.
 646
 647 =item C<$duedates> is a DateTime object.
 648
 649 =item C<$inprocess> boolean switch
 650
 651 =item C<$ignore_reserves> boolean switch
 652
 653 =item C<$params> Hashref of additional parameters
 654
 655 Available keys:
 656     override_high_holds - Ignore high holds
 657     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 658
 659 =back
 660
 661 Returns :
 662
 663 =over 4
 664
 665 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 666 Possible values are :
 667
 668 =back
 669
 670 =head3 INVALID_DATE
 671
 672 sticky due date is invalid
 673
 674 =head3 GNA
 675
 676 borrower gone with no address
 677
 678 =head3 CARD_LOST
 679
 680 borrower declared it's card lost
 681
 682 =head3 DEBARRED
 683
 684 borrower debarred
 685
 686 =head3 UNKNOWN_BARCODE
 687
 688 barcode unknown
 689
 690 =head3 NOT_FOR_LOAN
 691
 692 item is not for loan
 693
 694 =head3 WTHDRAWN
 695
 696 item withdrawn.
 697
 698 =head3 RESTRICTED
 699
 700 item is restricted (set by ??)
 701
 702 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 703 could be prevented, but ones that can be overriden by the operator.
 704
 705 Possible values are :
 706
 707 =head3 DEBT
 708
 709 borrower has debts.
 710
 711 =head3 RENEW_ISSUE
 712
 713 renewing, not issuing
 714
 715 =head3 ISSUED_TO_ANOTHER
 716
 717 issued to someone else.
 718
 719 =head3 RESERVED
 720
 721 reserved for someone else.
 722
 723 =head3 TRANSFERRED
 724
 725 reserved and being transferred for someone else.
 726
 727 =head3 INVALID_DATE
 728
 729 sticky due date is invalid or due date in the past
 730
 731 =head3 TOO_MANY
 732
 733 if the borrower borrows to much things
 734
 735 =cut
 736
 737 sub CanBookBeIssued {
 738     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 739     my %needsconfirmation;    # filled with problems that needs confirmations
 740     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 741     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 742     my %messages;             # filled with information messages that should be displayed.
 743
 744     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 745     my $override_high_holds = $params->{override_high_holds} || 0;
 746
 747     my $item_object = Koha::Items->find({barcode => $barcode });
 748
 749     # MANDATORY CHECKS - unless item exists, nothing else matters
 750     unless ( $item_object ) {
 751         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 752     }
 753     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 754
 755     my $item_unblessed = $item_object->unblessed; # Transition...
 756     my $issue = $item_object->checkout;
 757     my $biblio = $item_object->biblio;
 758
 759     my $biblioitem = $biblio->biblioitem;
 760     my $effective_itemtype = $item_object->effective_itemtype;
 761     my $dbh             = C4::Context->dbh;
 762     my $patron_unblessed = $patron->unblessed;
 763
 764     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 765     #
 766     # DUE DATE is OK ? -- should already have checked.
 767     #
 768     if ($duedate && ref $duedate ne 'DateTime') {
 769         $duedate = dt_from_string($duedate);
 770     }
 771     my $now = dt_from_string();
 772     unless ( $duedate ) {
 773         my $issuedate = $now->clone();
 774
 775         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 776
 777         # Offline circ calls AddIssue directly, doesn't run through here
 778         #  So issuingimpossible should be ok.
 779     }
 780
 781     my $fees = Koha::Charges::Fees->new(
 782         {
 783             patron    => $patron,
 784             library   => $circ_library,
 785             item      => $item_object,
 786             to_date   => $duedate,
 787         }
 788     );
 789
 790     if ($duedate) {
 791         my $today = $now->clone();
 792         $today->truncate( to => 'minute');
 793         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 794             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 795         }
 796     } else {
 797             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 798     }
 799
 800     #
 801     # BORROWER STATUS
 802     #
 803     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 804         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 805         &UpdateStats({
 806                      branch => C4::Context->userenv->{'branch'},
 807                      type => 'localuse',
 808                      itemnumber => $item_object->itemnumber,
 809                      itemtype => $effective_itemtype,
 810                      borrowernumber => $patron->borrowernumber,
 811                      ccode => $item_object->ccode}
 812                     );
 813         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 814         return( { STATS => 1 }, {});
 815     }
 816
 817     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 818         $issuingimpossible{GNA} = 1;
 819     }
 820
 821     if ( $patron->lost && $patron->lost == 1 ) {
 822         $issuingimpossible{CARD_LOST} = 1;
 823     }
 824     if ( $patron->is_debarred ) {
 825         $issuingimpossible{DEBARRED} = 1;
 826     }
 827
 828     if ( $patron->is_expired ) {
 829         $issuingimpossible{EXPIRED} = 1;
 830     }
 831
 832     #
 833     # BORROWER STATUS
 834     #
 835
 836     # DEBTS
 837     my $account = $patron->account;
 838     my $balance = $account->balance;
 839     my $non_issues_charges = $account->non_issues_charges;
 840     my $other_charges = $balance - $non_issues_charges;
 841
 842     my $amountlimit = C4::Context->preference("noissuescharge");
 843     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 844     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 845
 846     # Check the debt of this patrons guarantees
 847     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 848     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 849     if ( defined $no_issues_charge_guarantees ) {
 850         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 851         my $guarantees_non_issues_charges = 0;
 852         foreach my $g ( @guarantees ) {
 853             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 854         }
 855
 856         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 857             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 858         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 859             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 860         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 861             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 862         }
 863     }
 864
 865     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 866     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 867     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 868     if ( defined $no_issues_charge_guarantors ) {
 869         my $guarantors_non_issues_charges += $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 870
 871         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 872             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 873         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 874             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 875         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 876             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 877         }
 878     }
 879
 880     if ( C4::Context->preference("IssuingInProcess") ) {
 881         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 882             $issuingimpossible{DEBT} = $non_issues_charges;
 883         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 884             $needsconfirmation{DEBT} = $non_issues_charges;
 885         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 886             $needsconfirmation{DEBT} = $non_issues_charges;
 887         }
 888     }
 889     else {
 890         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 891             $needsconfirmation{DEBT} = $non_issues_charges;
 892         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 893             $issuingimpossible{DEBT} = $non_issues_charges;
 894         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 895             $needsconfirmation{DEBT} = $non_issues_charges;
 896         }
 897     }
 898
 899     if ($balance > 0 && $other_charges > 0) {
 900         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 901     }
 902
 903     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 904     $patron_unblessed = $patron->unblessed;
 905
 906     if ( my $debarred_date = $patron->is_debarred ) {
 907          # patron has accrued fine days or has a restriction. $count is a date
 908         if ($debarred_date eq '9999-12-31') {
 909             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 910         }
 911         else {
 912             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 913         }
 914     } elsif ( my $num_overdues = $patron->has_overdues ) {
 915         ## patron has outstanding overdue loans
 916         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 917             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 918         }
 919         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 920             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 921         }
 922     }
 923
 924     # Additional Materials Check
 925     if ( C4::Context->preference("CircConfirmItemParts")
 926         && $item_object->materials )
 927     {
 928         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 929     }
 930
 931     #
 932     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 933     #
 934     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 935
 936         # Already issued to current borrower.
 937         # If it is an on-site checkout if it can be switched to a normal checkout
 938         # or ask whether the loan should be renewed
 939
 940         if ( $issue->onsite_checkout
 941                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 942             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 943         } else {
 944             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 945                 $patron->borrowernumber,
 946                 $item_object->itemnumber,
 947             );
 948             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 949                 if ( $renewerror eq 'onsite_checkout' ) {
 950                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 951                 }
 952                 else {
 953                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 954                 }
 955             }
 956             else {
 957                 $needsconfirmation{RENEW_ISSUE} = 1;
 958             }
 959         }
 960     }
 961     elsif ( $issue ) {
 962
 963         # issued to someone else
 964
 965         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 966
 967         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 968
 969         unless ( $can_be_returned ) {
 970             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 971             $issuingimpossible{branch_to_return} = $message;
 972         } else {
 973             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 974                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 975             } else {
 976             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 977             $needsconfirmation{issued_firstname} = $patron->firstname;
 978             $needsconfirmation{issued_surname} = $patron->surname;
 979             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 980             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 981             }
 982         }
 983     }
 984
 985     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 986     #
 987     my $switch_onsite_checkout = (
 988           C4::Context->preference('SwitchOnSiteCheckouts')
 989       and $issue
 990       and $issue->onsite_checkout
 991       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 992     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 993     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 994     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 995         if ( $toomany->{max_allowed} == 0 ) {
 996             $needsconfirmation{PATRON_CANT} = 1;
 997         }
 998         if ( C4::Context->preference("AllowTooManyOverride") ) {
 999             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1000             $needsconfirmation{current_loan_count} = $toomany->{count};
1001             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1002         } else {
1003             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1004             $issuingimpossible{current_loan_count} = $toomany->{count};
1005             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1006         }
1007     }
1008
1009     #
1010     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1011     #
1012     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1013     my $wants_check = $patron->wants_check_for_previous_checkout;
1014     $needsconfirmation{PREVISSUE} = 1
1015         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1016
1017     #
1018     # ITEM CHECKING
1019     #
1020     if ( $item_object->notforloan )
1021     {
1022         if(!C4::Context->preference("AllowNotForLoanOverride")){
1023             $issuingimpossible{NOT_FOR_LOAN} = 1;
1024             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1025         }else{
1026             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1027             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1028         }
1029     }
1030     else {
1031         # we have to check itemtypes.notforloan also
1032         if (C4::Context->preference('item-level_itypes')){
1033             # this should probably be a subroutine
1034             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1035             $sth->execute($effective_itemtype);
1036             my $notforloan=$sth->fetchrow_hashref();
1037             if ($notforloan->{'notforloan'}) {
1038                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1039                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1040                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1041                 } else {
1042                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1043                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1044                 }
1045             }
1046         }
1047         else {
1048             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1049             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1050                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1051                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1052                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1053                 } else {
1054                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1055                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1056                 }
1057             }
1058         }
1059     }
1060     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1061     {
1062         $issuingimpossible{WTHDRAWN} = 1;
1063     }
1064     if (   $item_object->restricted
1065         && $item_object->restricted == 1 )
1066     {
1067         $issuingimpossible{RESTRICTED} = 1;
1068     }
1069     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1070         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1071         my $code = $av->count ? $av->next->lib : '';
1072         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1073         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1074     }
1075     if ( C4::Context->preference("IndependentBranches") ) {
1076         my $userenv = C4::Context->userenv;
1077         unless ( C4::Context->IsSuperLibrarian() ) {
1078             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1079             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1080                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1081                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1082             }
1083             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1084               if ( $patron->branchcode ne $userenv->{branch} );
1085         }
1086     }
1087
1088     #
1089     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1090     #
1091     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1092     if ($rentalConfirmation) {
1093         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1094
1095         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1096         if ($itemtype_object) {
1097             my $accumulate_charge = $fees->accumulate_rentalcharge();
1098             if ( $accumulate_charge > 0 ) {
1099                 $rentalCharge += $accumulate_charge;
1100             }
1101         }
1102
1103         if ( $rentalCharge > 0 ) {
1104             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1105         }
1106     }
1107
1108     unless ( $ignore_reserves ) {
1109         # See if the item is on reserve.
1110         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1111         if ($restype) {
1112             my $resbor = $res->{'borrowernumber'};
1113             if ( $resbor ne $patron->borrowernumber ) {
1114                 my $patron = Koha::Patrons->find( $resbor );
1115                 if ( $restype eq "Waiting" )
1116                 {
1117                     # The item is on reserve and waiting, but has been
1118                     # reserved by some other patron.
1119                     $needsconfirmation{RESERVE_WAITING} = 1;
1120                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1121                     $needsconfirmation{'ressurname'} = $patron->surname;
1122                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1123                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1124                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1125                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1126                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1127                 }
1128                 elsif ( $restype eq "Reserved" ) {
1129                     # The item is on reserve for someone else.
1130                     $needsconfirmation{RESERVED} = 1;
1131                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1132                     $needsconfirmation{'ressurname'} = $patron->surname;
1133                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1134                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1135                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1136                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1137                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1138                 }
1139                 elsif ( $restype eq "Transferred" ) {
1140                     # The item is determined hold being transferred for someone else.
1141                     $needsconfirmation{TRANSFERRED} = 1;
1142                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1143                     $needsconfirmation{'ressurname'} = $patron->surname;
1144                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1145                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1146                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1147                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1148                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1149                 }
1150                 elsif ( $restype eq "Processing" ) {
1151                     # The item is determined hold being processed for someone else.
1152                     $needsconfirmation{PROCESSING} = 1;
1153                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1154                     $needsconfirmation{'ressurname'} = $patron->surname;
1155                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1156                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1157                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1158                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1159                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1160                 }
1161             }
1162         }
1163     }
1164
1165     ## CHECK AGE RESTRICTION
1166     my $agerestriction  = $biblioitem->agerestriction;
1167     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1168     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1169         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1170             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1171         }
1172         else {
1173             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1174         }
1175     }
1176
1177     ## check for high holds decreasing loan period
1178     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1179         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1180
1181         if ( $check->{exceeded} ) {
1182             if ($override_high_holds) {
1183                 $alerts{HIGHHOLDS} = {
1184                     num_holds  => $check->{outstanding},
1185                     duration   => $check->{duration},
1186                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1187                 };
1188             }
1189             else {
1190                 $needsconfirmation{HIGHHOLDS} = {
1191                     num_holds  => $check->{outstanding},
1192                     duration   => $check->{duration},
1193                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1194                 };
1195             }
1196         }
1197     }
1198
1199     if (
1200         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1201         # don't do the multiple loans per bib check if we've
1202         # already determined that we've got a loan on the same item
1203         !$issuingimpossible{NO_MORE_RENEWALS} &&
1204         !$needsconfirmation{RENEW_ISSUE}
1205     ) {
1206         # Check if borrower has already issued an item from the same biblio
1207         # Only if it's not a subscription
1208         my $biblionumber = $item_object->biblionumber;
1209         require C4::Serials;
1210         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1211         unless ($is_a_subscription) {
1212             # FIXME Should be $patron->checkouts($args);
1213             my $checkouts = Koha::Checkouts->search(
1214                 {
1215                     borrowernumber => $patron->borrowernumber,
1216                     biblionumber   => $biblionumber,
1217                 },
1218                 {
1219                     join => 'item',
1220                 }
1221             );
1222             # if we get here, we don't already have a loan on this item,
1223             # so if there are any loans on this bib, ask for confirmation
1224             if ( $checkouts->count ) {
1225                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1226             }
1227         }
1228     }
1229
1230     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1231 }
1232
1233 =head2 CanBookBeReturned
1234
1235   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1236
1237 Check whether the item can be returned to the provided branch
1238
1239 =over 4
1240
1241 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1242
1243 =item C<$branch> is the branchcode where the return is taking place
1244
1245 =back
1246
1247 Returns:
1248
1249 =over 4
1250
1251 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1252
1253 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1254
1255 =back
1256
1257 =cut
1258
1259 sub CanBookBeReturned {
1260   my ($item, $branch) = @_;
1261   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1262
1263   # assume return is allowed to start
1264   my $allowed = 1;
1265   my $message;
1266
1267   # identify all cases where return is forbidden
1268   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1269      $allowed = 0;
1270      $message = $item->{'homebranch'};
1271   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1272      $allowed = 0;
1273      $message = $item->{'holdingbranch'};
1274   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1275      $allowed = 0;
1276      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1277   }
1278
1279   return ($allowed, $message);
1280 }
1281
1282 =head2 CheckHighHolds
1283
1284     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1285     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1286     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1287
1288 =cut
1289
1290 sub checkHighHolds {
1291     my ( $item, $borrower ) = @_;
1292     my $branchcode = _GetCircControlBranch( $item, $borrower );
1293     my $item_object = Koha::Items->find( $item->{itemnumber} );
1294
1295     my $return_data = {
1296         exceeded    => 0,
1297         outstanding => 0,
1298         duration    => 0,
1299         due_date    => undef,
1300     };
1301
1302     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1303
1304     if ( $holds->count() ) {
1305         $return_data->{outstanding} = $holds->count();
1306
1307         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1308         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1309         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1310
1311         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1312
1313         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1314
1315             # static means just more than a given number of holds on the record
1316
1317             # If the number of holds is less than the threshold, we can stop here
1318             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1319                 return $return_data;
1320             }
1321         }
1322         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1323
1324             # dynamic means X more than the number of holdable items on the record
1325
1326             # let's get the items
1327             my @items = $holds->next()->biblio()->items()->as_list;
1328
1329             # Remove any items with status defined to be ignored even if the would not make item unholdable
1330             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1331                 @items = grep { !$_->$status } @items;
1332             }
1333
1334             # Remove any items that are not holdable for this patron
1335             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1336
1337             my $items_count = scalar @items;
1338
1339             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1340
1341             # If the number of holds is less than the count of items we have
1342             # plus the number of holds allowed above that count, we can stop here
1343             if ( $holds->count() <= $threshold ) {
1344                 return $return_data;
1345             }
1346         }
1347
1348         my $issuedate = dt_from_string();
1349
1350         my $itype = $item_object->effective_itemtype;
1351         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1352             {
1353                 categorycode => $borrower->{categorycode},
1354                 itemtype     => $itype,
1355                 branchcode   => $branchcode,
1356             }
1357         );
1358         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1359
1360         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1361
1362         my $rule = Koha::CirculationRules->get_effective_rule(
1363             {
1364                 categorycode => $borrower->{categorycode},
1365                 itemtype     => $item_object->effective_itemtype,
1366                 branchcode   => $branchcode,
1367                 rule_name    => 'decreaseloanholds',
1368             }
1369         );
1370
1371         my $duration;
1372         if ( defined($rule) && $rule->rule_value ne '' ){
1373             # overrides decreaseLoanHighHoldsDuration syspref
1374             $duration = $rule->rule_value;
1375         } else {
1376             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1377         }
1378         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1379         $reduced_datedue->set_hour($orig_due->hour);
1380         $reduced_datedue->set_minute($orig_due->minute);
1381         $reduced_datedue->truncate( to => 'minute' );
1382
1383         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1384             $return_data->{exceeded} = 1;
1385             $return_data->{duration} = $duration;
1386             $return_data->{due_date} = $reduced_datedue;
1387         }
1388     }
1389
1390     return $return_data;
1391 }
1392
1393 =head2 AddIssue
1394
1395   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1396
1397 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1398
1399 =over 4
1400
1401 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1402
1403 =item C<$barcode> is the barcode of the item being issued.
1404
1405 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1406 Calculated if empty.
1407
1408 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1409
1410 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1411 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1412
1413 AddIssue does the following things :
1414
1415   - step 01: check that there is a borrowernumber & a barcode provided
1416   - check for RENEWAL (book issued & being issued to the same patron)
1417       - renewal YES = Calculate Charge & renew
1418       - renewal NO  =
1419           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1420           * RESERVE PLACED ?
1421               - fill reserve if reserve to this patron
1422               - cancel reserve or not, otherwise
1423           * TRANSFERT PENDING ?
1424               - complete the transfert
1425           * ISSUE THE BOOK
1426
1427 =back
1428
1429 =cut
1430
1431 sub AddIssue {
1432     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1433
1434     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1435     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1436     my $auto_renew = $params && $params->{auto_renew};
1437     my $dbh          = C4::Context->dbh;
1438     my $barcodecheck = CheckValidBarcode($barcode);
1439
1440     my $issue;
1441
1442     if ( $datedue && ref $datedue ne 'DateTime' ) {
1443         $datedue = dt_from_string($datedue);
1444     }
1445
1446     # $issuedate defaults to today.
1447     if ( !defined $issuedate ) {
1448         $issuedate = dt_from_string();
1449     }
1450     else {
1451         if ( ref $issuedate ne 'DateTime' ) {
1452             $issuedate = dt_from_string($issuedate);
1453
1454         }
1455     }
1456
1457     # Stop here if the patron or barcode doesn't exist
1458     if ( $borrower && $barcode && $barcodecheck ) {
1459         # find which item we issue
1460         my $item_object = Koha::Items->find({ barcode => $barcode })
1461           or return;    # if we don't get an Item, abort.
1462         my $item_unblessed = $item_object->unblessed;
1463
1464         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1465
1466         # get actual issuing if there is one
1467         my $actualissue = $item_object->checkout;
1468
1469         # check if we just renew the issue.
1470         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1471                 and not $switch_onsite_checkout ) {
1472             $datedue = AddRenewal(
1473                 $borrower->{'borrowernumber'},
1474                 $item_object->itemnumber,
1475                 $branchcode,
1476                 $datedue,
1477                 $issuedate,    # here interpreted as the renewal date
1478             );
1479         }
1480         else {
1481             unless ($datedue) {
1482                 my $itype = $item_object->effective_itemtype;
1483                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1484
1485             }
1486             $datedue->truncate( to => 'minute' );
1487
1488             my $patron = Koha::Patrons->find( $borrower );
1489             my $library = Koha::Libraries->find( $branchcode );
1490             my $fees = Koha::Charges::Fees->new(
1491                 {
1492                     patron    => $patron,
1493                     library   => $library,
1494                     item      => $item_object,
1495                     to_date   => $datedue,
1496                 }
1497             );
1498
1499             # it's NOT a renewal
1500             if ( $actualissue and not $switch_onsite_checkout ) {
1501                 # This book is currently on loan, but not to the person
1502                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1503                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1504                 return unless $allowed;
1505                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1506                 # AddReturn certainly has side-effects, like onloan => undef
1507                 $item_object->discard_changes;
1508             }
1509
1510             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1511
1512             # Starting process for transfer job (checking transfert and validate it if we have one)
1513             if ( my $transfer = $item_object->get_transfer ) {
1514                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1515                 $transfer->set(
1516                     {
1517                         datearrived => dt_from_string,
1518                         tobranch    => C4::Context->userenv->{branch},
1519                         comments    => 'Forced branchtransfer'
1520                     }
1521                 )->store;
1522                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1523                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1524                     if ( $hold ) { # Is this really needed?
1525                         $hold->set( { found => undef } )->store;
1526                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1527                     }
1528                 }
1529             }
1530
1531             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1532             unless ($auto_renew) {
1533                 my $rule = Koha::CirculationRules->get_effective_rule(
1534                     {
1535                         categorycode => $borrower->{categorycode},
1536                         itemtype     => $item_object->effective_itemtype,
1537                         branchcode   => $branchcode,
1538                         rule_name    => 'auto_renew'
1539                     }
1540                 );
1541
1542                 $auto_renew = $rule->rule_value if $rule;
1543             }
1544
1545             my $issue_attributes = {
1546                 borrowernumber  => $borrower->{'borrowernumber'},
1547                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1548                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1549                 branchcode      => C4::Context->userenv->{'branch'},
1550                 onsite_checkout => $onsite_checkout,
1551                 auto_renew      => $auto_renew ? 1 : 0,
1552             };
1553
1554             # Get ID of logged in user.  if called from a batch job,
1555             # no user session exists and C4::Context->userenv() returns
1556             # the scalar '0'. Only do this if the syspref says so
1557             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1558                 my $userenv = C4::Context->userenv();
1559                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1560                 if ($usernumber) {
1561                     $issue_attributes->{issuer_id} = $usernumber;
1562                 }
1563             }
1564
1565             # In the case that the borrower has an on-site checkout
1566             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1567             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1568             if ($issue) {
1569                 $issue->set($issue_attributes)->store;
1570             }
1571             else {
1572                 $issue = Koha::Checkout->new(
1573                     {
1574                         itemnumber => $item_object->itemnumber,
1575                         %$issue_attributes,
1576                     }
1577                 )->store;
1578             }
1579             $issue->discard_changes;
1580             if ( $item_object->location && $item_object->location eq 'CART'
1581                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1582             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1583                 CartToShelf( $item_object->itemnumber );
1584             }
1585
1586             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1587                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1588             }
1589
1590             # Record if item was lost
1591             my $was_lost = $item_object->itemlost;
1592
1593             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1594             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1595             $item_object->itemlost(0);
1596             $item_object->onloan($datedue->ymd());
1597             $item_object->datelastborrowed( dt_from_string()->ymd() );
1598             $item_object->datelastseen( dt_from_string()->ymd() );
1599             $item_object->store({log_action => 0});
1600
1601             # If the item was lost, it has now been found, charge the overdue if necessary
1602             if ($was_lost) {
1603                 if ( $item_object->{_charge} ) {
1604                     $actualissue //= Koha::Old::Checkouts->search(
1605                         { itemnumber => $item_unblessed->{itemnumber} },
1606                         {
1607                             order_by => { '-desc' => 'returndate' },
1608                             rows     => 1
1609                         }
1610                     )->single;
1611                     unless ( exists( $borrower->{branchcode} ) ) {
1612                         my $patron = $actualissue->patron;
1613                         $borrower = $patron->unblessed;
1614                     }
1615                     _CalculateAndUpdateFine(
1616                         {
1617                             issue       => $actualissue,
1618                             item        => $item_unblessed,
1619                             borrower    => $borrower,
1620                             return_date => $issuedate
1621                         }
1622                     );
1623                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1624                         $item_object->itemnumber, undef, 'RENEWED' );
1625                 }
1626             }
1627
1628             # If it costs to borrow this book, charge it to the patron's account.
1629             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1630             if ( $charge && $charge > 0 ) {
1631                 AddIssuingCharge( $issue, $charge, 'RENT' );
1632             }
1633
1634             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1635             if ( $itemtype_object ) {
1636                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1637                 if ( $accumulate_charge > 0 ) {
1638                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1639                     $charge += $accumulate_charge;
1640                     $item_unblessed->{charge} = $charge;
1641                 }
1642             }
1643
1644             # Record the fact that this book was issued.
1645             &UpdateStats(
1646                 {
1647                     branch => C4::Context->userenv->{'branch'},
1648                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1649                     amount         => $charge,
1650                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1651                     itemnumber     => $item_object->itemnumber,
1652                     itemtype       => $item_object->effective_itemtype,
1653                     location       => $item_object->location,
1654                     borrowernumber => $borrower->{'borrowernumber'},
1655                     ccode          => $item_object->ccode,
1656                 }
1657             );
1658
1659             # Send a checkout slip.
1660             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1661             my %conditions        = (
1662                 branchcode   => $branchcode,
1663                 categorycode => $borrower->{categorycode},
1664                 item_type    => $item_object->effective_itemtype,
1665                 notification => 'CHECKOUT',
1666             );
1667             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1668                 SendCirculationAlert(
1669                     {
1670                         type     => 'CHECKOUT',
1671                         item     => $item_object->unblessed,
1672                         borrower => $borrower,
1673                         branch   => $branchcode,
1674                     }
1675                 );
1676             }
1677             logaction(
1678                 "CIRCULATION", "ISSUE",
1679                 $borrower->{'borrowernumber'},
1680                 $item_object->itemnumber,
1681             ) if C4::Context->preference("IssueLog");
1682
1683             Koha::Plugins->call('after_circ_action', {
1684                 action  => 'checkout',
1685                 payload => {
1686                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1687                     checkout => $issue->get_from_storage
1688                 }
1689             });
1690         }
1691     }
1692     return $issue;
1693 }
1694
1695 =head2 GetLoanLength
1696
1697   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1698
1699 Get loan length for an itemtype, a borrower type and a branch
1700
1701 =cut
1702
1703 sub GetLoanLength {
1704     my ( $categorycode, $itemtype, $branchcode ) = @_;
1705
1706     # Initialize default values
1707     my $rules = {
1708         issuelength   => 0,
1709         renewalperiod => 0,
1710         lengthunit    => 'days',
1711     };
1712
1713     my $found = Koha::CirculationRules->get_effective_rules( {
1714         branchcode => $branchcode,
1715         categorycode => $categorycode,
1716         itemtype => $itemtype,
1717         rules => [
1718             'issuelength',
1719             'renewalperiod',
1720             'lengthunit'
1721         ],
1722     } );
1723
1724     # Search for rules!
1725     foreach my $rule_name (keys %$found) {
1726         $rules->{$rule_name} = $found->{$rule_name};
1727     }
1728
1729     return $rules;
1730 }
1731
1732
1733 =head2 GetHardDueDate
1734
1735   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1736
1737 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1738
1739 =cut
1740
1741 sub GetHardDueDate {
1742     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1743
1744     my $rules = Koha::CirculationRules->get_effective_rules(
1745         {
1746             categorycode => $borrowertype,
1747             itemtype     => $itemtype,
1748             branchcode   => $branchcode,
1749             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1750         }
1751     );
1752
1753     if ( defined( $rules->{hardduedate} ) ) {
1754         if ( $rules->{hardduedate} ) {
1755             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1756         }
1757         else {
1758             return ( undef, undef );
1759         }
1760     }
1761 }
1762
1763 =head2 GetBranchBorrowerCircRule
1764
1765   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1766
1767 Retrieves circulation rule attributes that apply to the given
1768 branch and patron category, regardless of item type.
1769 The return value is a hashref containing the following key:
1770
1771 patron_maxissueqty - maximum number of loans that a
1772 patron of the given category can have at the given
1773 branch.  If the value is undef, no limit.
1774
1775 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1776 patron of the given category can have at the given
1777 branch.  If the value is undef, no limit.
1778
1779 This will check for different branch/category combinations in the following order:
1780 branch and category
1781 branch only
1782 category only
1783 default branch and category
1784
1785 If no rule has been found in the database, it will default to
1786 the buillt in rule:
1787
1788 patron_maxissueqty - undef
1789 patron_maxonsiteissueqty - undef
1790
1791 C<$branchcode> and C<$categorycode> should contain the
1792 literal branch code and patron category code, respectively - no
1793 wildcards.
1794
1795 =cut
1796
1797 sub GetBranchBorrowerCircRule {
1798     my ( $branchcode, $categorycode ) = @_;
1799
1800     # Initialize default values
1801     my $rules = {
1802         patron_maxissueqty       => undef,
1803         patron_maxonsiteissueqty => undef,
1804     };
1805
1806     # Search for rules!
1807     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1808         my $rule = Koha::CirculationRules->get_effective_rule(
1809             {
1810                 categorycode => $categorycode,
1811                 itemtype     => undef,
1812                 branchcode   => $branchcode,
1813                 rule_name    => $rule_name,
1814             }
1815         );
1816
1817         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1818     }
1819
1820     return $rules;
1821 }
1822
1823 =head2 GetBranchItemRule
1824
1825   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1826
1827 Retrieves circulation rule attributes that apply to the given
1828 branch and item type, regardless of patron category.
1829
1830 The return value is a hashref containing the following keys:
1831
1832 holdallowed => Hold policy for this branch and itemtype. Possible values:
1833   not_allowed:           No holds allowed.
1834   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1835   from_any_library:      Holds allowed from any patron.
1836   from_local_hold_group: Holds allowed from libraries in hold group
1837
1838 returnbranch => branch to which to return item.  Possible values:
1839   noreturn: do not return, let item remain where checked in (floating collections)
1840   homebranch: return to item's home branch
1841   holdingbranch: return to issuer branch
1842
1843 This searches branchitemrules in the following order:
1844
1845   * Same branchcode and itemtype
1846   * Same branchcode, itemtype '*'
1847   * branchcode '*', same itemtype
1848   * branchcode and itemtype '*'
1849
1850 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1851
1852 =cut
1853
1854 sub GetBranchItemRule {
1855     my ( $branchcode, $itemtype ) = @_;
1856
1857     # Search for rules!
1858     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1859         {
1860             branchcode => $branchcode,
1861             itemtype   => $itemtype,
1862             rule_name  => 'holdallowed',
1863         }
1864     );
1865     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1866         {
1867             branchcode => $branchcode,
1868             itemtype   => $itemtype,
1869             rule_name  => 'hold_fulfillment_policy',
1870         }
1871     );
1872     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1873         {
1874             branchcode => $branchcode,
1875             itemtype   => $itemtype,
1876             rule_name  => 'returnbranch',
1877         }
1878     );
1879
1880     # built-in default circulation rule
1881     my $rules;
1882     $rules->{holdallowed} = defined $holdallowed_rule
1883         ? $holdallowed_rule->rule_value
1884         : 'from_any_library';
1885     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1886         ? $hold_fulfillment_policy_rule->rule_value
1887         : 'any';
1888     $rules->{returnbranch} = defined $returnbranch_rule
1889         ? $returnbranch_rule->rule_value
1890         : 'homebranch';
1891
1892     return $rules;
1893 }
1894
1895 =head2 AddReturn
1896
1897   ($doreturn, $messages, $iteminformation, $borrower) =
1898       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1899
1900 Returns a book.
1901
1902 =over 4
1903
1904 =item C<$barcode> is the bar code of the book being returned.
1905
1906 =item C<$branch> is the code of the branch where the book is being returned.
1907
1908 =item C<$exemptfine> indicates that overdue charges for the item will be
1909 removed. Optional.
1910
1911 =item C<$return_date> allows the default return date to be overridden
1912 by the given return date. Optional.
1913
1914 =back
1915
1916 C<&AddReturn> returns a list of four items:
1917
1918 C<$doreturn> is true iff the return succeeded.
1919
1920 C<$messages> is a reference-to-hash giving feedback on the operation.
1921 The keys of the hash are:
1922
1923 =over 4
1924
1925 =item C<BadBarcode>
1926
1927 No item with this barcode exists. The value is C<$barcode>.
1928
1929 =item C<NotIssued>
1930
1931 The book is not currently on loan. The value is C<$barcode>.
1932
1933 =item C<withdrawn>
1934
1935 This book has been withdrawn/cancelled. The value should be ignored.
1936
1937 =item C<Wrongbranch>
1938
1939 This book has was returned to the wrong branch.  The value is a hashref
1940 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1941 contain the branchcode of the incorrect and correct return library, respectively.
1942
1943 =item C<ResFound>
1944
1945 The item was reserved. The value is a reference-to-hash whose keys are
1946 fields from the reserves table of the Koha database, and
1947 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1948 either C<Waiting>, C<Reserved>, or 0.
1949
1950 =item C<WasReturned>
1951
1952 Value 1 if return is successful.
1953
1954 =item C<NeedsTransfer>
1955
1956 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1957
1958 =back
1959
1960 C<$iteminformation> is a reference-to-hash, giving information about the
1961 returned item from the issues table.
1962
1963 C<$borrower> is a reference-to-hash, giving information about the
1964 patron who last borrowed the book.
1965
1966 =cut
1967
1968 sub AddReturn {
1969     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1970
1971     if ($branch and not Koha::Libraries->find($branch)) {
1972         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1973         undef $branch;
1974     }
1975     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1976     my $return_date_specified = !!$return_date;
1977     $return_date //= dt_from_string();
1978     my $messages;
1979     my $patron;
1980     my $doreturn       = 1;
1981     my $validTransfer = 1;
1982     my $stat_type = 'return';
1983
1984     # get information on item
1985     my $item = Koha::Items->find({ barcode => $barcode });
1986     unless ($item) {
1987         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1988     }
1989
1990     my $itemnumber = $item->itemnumber;
1991     my $itemtype = $item->effective_itemtype;
1992
1993     my $issue  = $item->checkout;
1994     if ( $issue ) {
1995         $patron = $issue->patron
1996             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1997                 . Dumper($issue->unblessed) . "\n";
1998     } else {
1999         $messages->{'NotIssued'} = $barcode;
2000         $item->onloan(undef)->store({skip_record_index=>1}) if defined $item->onloan;
2001
2002         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2003         $doreturn = 0;
2004         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2005         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2006         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2007            $messages->{'LocalUse'} = 1;
2008            $stat_type = 'localuse';
2009         }
2010     }
2011
2012         # full item data, but no borrowernumber or checkout info (no issue)
2013     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2014         # get the proper branch to which to return the item
2015     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2016         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2017     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2018
2019     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2020     my $patron_unblessed = $patron ? $patron->unblessed : {};
2021
2022     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2023     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2024     if ($update_loc_rules) {
2025         if (defined $update_loc_rules->{_ALL_}) {
2026             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2027             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2028             if ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) {
2029                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2030                 $item->location($update_loc_rules->{_ALL_})->store({skip_record_index=>1});
2031             }
2032         }
2033         else {
2034             foreach my $key ( keys %$update_loc_rules ) {
2035                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2036                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2037                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2038                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2039                     $item->location($update_loc_rules->{$key})->store({skip_record_index=>1});
2040                     last;
2041                 }
2042             }
2043         }
2044     }
2045
2046     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2047     if ($yaml) {
2048         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2049         my $rules;
2050         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2051         if ($@) {
2052             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2053         }
2054         else {
2055             foreach my $key ( keys %$rules ) {
2056                 if ( $item->notforloan eq $key ) {
2057                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2058                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
2059                     last;
2060                 }
2061             }
2062         }
2063     }
2064
2065     # check if the return is allowed at this branch
2066     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2067     unless ($returnallowed){
2068         $messages->{'Wrongbranch'} = {
2069             Wrongbranch => $branch,
2070             Rightbranch => $message
2071         };
2072         $doreturn = 0;
2073         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2074         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2075         return ( $doreturn, $messages, $issue, $patron_unblessed);
2076     }
2077
2078     if ( $item->withdrawn ) { # book has been cancelled
2079         $messages->{'withdrawn'} = 1;
2080         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2081     }
2082
2083     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2084         $doreturn = 0;
2085     }
2086
2087     # case of a return of document (deal with issues and holdingbranch)
2088     if ($doreturn) {
2089         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2090         $patron or warn "AddReturn without current borrower";
2091
2092         if ($patron) {
2093             eval {
2094                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1} );
2095             };
2096             unless ( $@ ) {
2097                 if (
2098                     (
2099                         C4::Context->preference('CalculateFinesOnReturn')
2100                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2101                     )
2102                     && !$item->itemlost
2103                   )
2104                 {
2105                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2106                 }
2107             } else {
2108                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2109
2110                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2111                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2112
2113                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2114             }
2115
2116             # FIXME is the "= 1" right?  This could be the borrower hash.
2117             $messages->{'WasReturned'} = 1;
2118
2119         } else {
2120             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1 });
2121         }
2122     }
2123
2124     # the holdingbranch is updated if the document is returned to another location.
2125     # this is always done regardless of whether the item was on loan or not
2126     if ($item->holdingbranch ne $branch) {
2127         $item->holdingbranch($branch)->store({ skip_record_index => 1 });
2128     }
2129
2130     my $item_was_lost = $item->itemlost;
2131     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2132     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1 } ); # will unset itemlost if needed
2133
2134     # fix up the accounts.....
2135     if ($item_was_lost) {
2136         $messages->{'WasLost'} = 1;
2137         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2138             $messages->{'LostItemFeeRefunded'} = $updated_item->{_refunded};
2139             $messages->{'LostItemFeeRestored'} = $updated_item->{_restored};
2140
2141             if ( $updated_item->{_charge} ) {
2142                 $issue //= Koha::Old::Checkouts->search(
2143                     { itemnumber => $item->itemnumber },
2144                     { order_by   => { '-desc' => 'returndate' }, rows => 1 } )
2145                   ->single;
2146                 unless ( exists( $patron_unblessed->{branchcode} ) ) {
2147                     my $patron = $issue->patron;
2148                     $patron_unblessed = $patron->unblessed;
2149                 }
2150                 _CalculateAndUpdateFine(
2151                     {
2152                         issue       => $issue,
2153                         item        => $item->unblessed,
2154                         borrower    => $patron_unblessed,
2155                         return_date => $return_date
2156                     }
2157                 );
2158                 _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2159                     $item->itemnumber, undef, 'RETURNED' );
2160                 $messages->{'LostItemFeeCharged'} = 1;
2161             }
2162         }
2163     }
2164
2165     # check if we have a transfer for this document
2166     my $transfer = $item->get_transfer;
2167
2168     # if we have a transfer to complete, we update the line of transfers with the datearrived
2169     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2170     if ($transfer) {
2171         $validTransfer = 0;
2172         if ( $transfer->in_transit ) {
2173             if ( $transfer->tobranch eq $branch ) {
2174                 $transfer->receive;
2175                 $messages->{'TransferArrived'} = $transfer->frombranch;
2176             }
2177             else {
2178                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2179                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2180             }
2181         }
2182         else {
2183             if ( $transfer->tobranch eq $branch ) {
2184                 $transfer->receive;
2185                 $messages->{'TransferArrived'} = $transfer->frombranch;
2186             }
2187             else {
2188                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2189                 $messages->{'TransferTrigger'} = $transfer->reason;
2190             }
2191         }
2192     }
2193
2194     # fix up the overdues in accounts...
2195     if ($borrowernumber) {
2196         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2197         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2198
2199         if ( $issue and $issue->is_overdue($return_date) ) {
2200         # fix fine days
2201             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2202             if ($reminder){
2203                 $messages->{'PrevDebarred'} = $debardate;
2204             } else {
2205                 $messages->{'Debarred'} = $debardate if $debardate;
2206             }
2207         # there's no overdue on the item but borrower had been previously debarred
2208         } elsif ( $issue->date_due and $patron->debarred ) {
2209              if ( $patron->debarred eq "9999-12-31") {
2210                 $messages->{'ForeverDebarred'} = $patron->debarred;
2211              } else {
2212                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2213                   $borrower_debar_dt->truncate(to => 'day');
2214                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2215                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2216                       $messages->{'PrevDebarred'} = $patron->debarred;
2217                   }
2218              }
2219         }
2220     }
2221
2222     # find reserves.....
2223     # launch the Checkreserves routine to find any holds
2224     my ($resfound, $resrec);
2225     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2226     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2227     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2228     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2229         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2230         $resfound = 'Reserved';
2231         $resrec = $hold->unblessed;
2232     }
2233     if ($resfound) {
2234           $resrec->{'ResFound'} = $resfound;
2235         $messages->{'ResFound'} = $resrec;
2236     }
2237
2238     # Record the fact that this book was returned.
2239     UpdateStats({
2240         branch         => $branch,
2241         type           => $stat_type,
2242         itemnumber     => $itemnumber,
2243         itemtype       => $itemtype,
2244         location       => $item->location,
2245         borrowernumber => $borrowernumber,
2246         ccode          => $item->ccode,
2247     });
2248
2249     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2250     if ( $patron ) {
2251         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2252         my %conditions = (
2253             branchcode   => $branch,
2254             categorycode => $patron->categorycode,
2255             item_type    => $itemtype,
2256             notification => 'CHECKIN',
2257         );
2258         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2259             SendCirculationAlert({
2260                 type     => 'CHECKIN',
2261                 item     => $item->unblessed,
2262                 borrower => $patron->unblessed,
2263                 branch   => $branch,
2264             });
2265         }
2266
2267         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2268             if C4::Context->preference("ReturnLog");
2269         }
2270
2271     # Check if this item belongs to a biblio record that is attached to an
2272     # ILL request, if it is we need to update the ILL request's status
2273     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2274         my $request = Koha::Illrequests->find(
2275             { biblio_id => $item->biblio->biblionumber }
2276         );
2277         $request->status('RET') if $request;
2278     }
2279
2280     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2281     if ( $validTransfer && !$is_in_rotating_collection
2282         && ( $doreturn or $messages->{'NotIssued'} )
2283         and !$resfound
2284         and ( $branch ne $returnbranch )
2285         and not $messages->{'WrongTransfer'}
2286         and not $messages->{'WasTransfered'} )
2287     {
2288         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2289         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2290             (C4::Context->preference("UseBranchTransferLimits") and
2291              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2292            )) {
2293             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2294             $debug and warn "item: " . Dumper($item->unblessed);
2295             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2296             $messages->{'WasTransfered'} = $returnbranch;
2297             $messages->{'TransferTrigger'} = $transfer_trigger;
2298         } else {
2299             $messages->{'NeedsTransfer'} = $returnbranch;
2300             $messages->{'TransferTrigger'} = $transfer_trigger;
2301         }
2302     }
2303
2304     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2305         my $claims = Koha::Checkouts::ReturnClaims->search(
2306            {
2307                itemnumber => $item->id,
2308                resolution => undef,
2309            }
2310         );
2311
2312         if ( $claims->count ) {
2313             $messages->{ReturnClaims} = $claims;
2314         }
2315     }
2316
2317     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2318     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2319
2320     if ( $doreturn and $issue ) {
2321         my $checkin = Koha::Old::Checkouts->find($issue->id);
2322
2323         Koha::Plugins->call('after_circ_action', {
2324             action  => 'checkin',
2325             payload => {
2326                 checkout=> $checkin
2327             }
2328         });
2329     }
2330
2331     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2332 }
2333
2334 =head2 MarkIssueReturned
2335
2336   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2337
2338 Unconditionally marks an issue as being returned by
2339 moving the C<issues> row to C<old_issues> and
2340 setting C<returndate> to the current date.
2341
2342 if C<$returndate> is specified (in iso format), it is used as the date
2343 of the return.
2344
2345 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2346 the old_issue is immediately anonymised
2347
2348 Ideally, this function would be internal to C<C4::Circulation>,
2349 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2350 and offline_circ/process_koc.pl.
2351
2352 The last optional parameter allos passing skip_record_index to the item store call.
2353
2354 =cut
2355
2356 sub MarkIssueReturned {
2357     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2358
2359     # Retrieve the issue
2360     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2361
2362     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2363
2364     my $issue_id = $issue->issue_id;
2365
2366     my $anonymouspatron;
2367     if ( $privacy && $privacy == 2 ) {
2368         # The default of 0 will not work due to foreign key constraints
2369         # The anonymisation will fail if AnonymousPatron is not a valid entry
2370         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2371         # Note that a warning should appear on the about page (System information tab).
2372         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2373         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2374             unless Koha::Patrons->find( $anonymouspatron );
2375     }
2376
2377     my $schema = Koha::Database->schema;
2378
2379     # FIXME Improve the return value and handle it from callers
2380     $schema->txn_do(sub {
2381
2382         my $patron = Koha::Patrons->find( $borrowernumber );
2383
2384         # Update the returndate value
2385         if ( $returndate ) {
2386             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2387         }
2388         else {
2389             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2390         }
2391
2392         # Create the old_issues entry
2393         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2394
2395         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2396         if ( $privacy && $privacy == 2) {
2397             $old_checkout->borrowernumber($anonymouspatron)->store;
2398         }
2399
2400         # And finally delete the issue
2401         $issue->delete;
2402
2403         $issue->item->onloan(undef)->store({ log_action => 0, skip_record_index => $params->{skip_record_index} });
2404
2405         if ( C4::Context->preference('StoreLastBorrower') ) {
2406             my $item = Koha::Items->find( $itemnumber );
2407             $item->last_returned_by( $patron );
2408         }
2409
2410         # Remove any OVERDUES related debarment if the borrower has no overdues
2411         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2412           && $patron->debarred
2413           && !$patron->has_overdues
2414           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2415         ) {
2416             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2417         }
2418
2419     });
2420
2421     return $issue_id;
2422 }
2423
2424 =head2 _debar_user_on_return
2425
2426     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2427
2428 C<$borrower> borrower hashref
2429
2430 C<$item> item hashref
2431
2432 C<$datedue> date due DateTime object
2433
2434 C<$returndate> DateTime object representing the return time
2435
2436 Internal function, called only by AddReturn that calculates and updates
2437  the user fine days, and debars them if necessary.
2438
2439 Should only be called for overdue returns
2440
2441 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2442 to ease testing.
2443
2444 =cut
2445
2446 sub _calculate_new_debar_dt {
2447     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2448
2449     my $branchcode = _GetCircControlBranch( $item, $borrower );
2450     my $circcontrol = C4::Context->preference('CircControl');
2451     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2452         {   categorycode => $borrower->{categorycode},
2453             itemtype     => $item->{itype},
2454             branchcode   => $branchcode,
2455             rules => [
2456                 'finedays',
2457                 'lengthunit',
2458                 'firstremind',
2459                 'maxsuspensiondays',
2460                 'suspension_chargeperiod',
2461             ]
2462         }
2463     );
2464     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2465     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2466     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2467
2468     return unless $finedays;
2469
2470     # finedays is in days, so hourly loans must multiply by 24
2471     # thus 1 hour late equals 1 day suspension * finedays rate
2472     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2473
2474     # grace period is measured in the same units as the loan
2475     my $grace =
2476       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2477
2478     my $deltadays = DateTime::Duration->new(
2479         days => $chargeable_units
2480     );
2481
2482     if ( $deltadays->subtract($grace)->is_positive() ) {
2483         my $suspension_days = $deltadays * $finedays;
2484
2485         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2486             # No need to / 1 and do not consider / 0
2487             $suspension_days = DateTime::Duration->new(
2488                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2489             );
2490         }
2491
2492         # If the max suspension days is < than the suspension days
2493         # the suspension days is limited to this maximum period.
2494         my $max_sd = $issuing_rule->{maxsuspensiondays};
2495         if ( defined $max_sd && $max_sd ne '' ) {
2496             $max_sd = DateTime::Duration->new( days => $max_sd );
2497             $suspension_days = $max_sd
2498               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2499         }
2500
2501         my ( $has_been_extended );
2502         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2503             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2504             if ( $debarment ) {
2505                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2506                 $has_been_extended = 1;
2507             }
2508         }
2509
2510         my $new_debar_dt;
2511         # Use the calendar or not to calculate the debarment date
2512         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2513             my $calendar = Koha::Calendar->new(
2514                 branchcode => $branchcode,
2515                 days_mode  => 'Calendar'
2516             );
2517             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2518         }
2519         else {
2520             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2521         }
2522         return $new_debar_dt;
2523     }
2524     return;
2525 }
2526
2527 sub _debar_user_on_return {
2528     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2529
2530     $return_date //= dt_from_string();
2531
2532     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2533
2534     return unless $new_debar_dt;
2535
2536     Koha::Patron::Debarments::AddUniqueDebarment({
2537         borrowernumber => $borrower->{borrowernumber},
2538         expiration     => $new_debar_dt->ymd(),
2539         type           => 'SUSPENSION',
2540     });
2541     # if borrower was already debarred but does not get an extra debarment
2542     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2543     my ($new_debarment_str, $is_a_reminder);
2544     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2545         $is_a_reminder = 1;
2546         $new_debarment_str = $borrower->{debarred};
2547     } else {
2548         $new_debarment_str = $new_debar_dt->ymd();
2549     }
2550     # FIXME Should return a DateTime object
2551     return $new_debarment_str, $is_a_reminder;
2552 }
2553
2554 =head2 _FixOverduesOnReturn
2555
2556    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2557
2558 C<$borrowernumber> borrowernumber
2559
2560 C<$itemnumber> itemnumber
2561
2562 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2563
2564 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2565
2566 Internal function
2567
2568 =cut
2569
2570 sub _FixOverduesOnReturn {
2571     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2572     unless( $borrowernumber ) {
2573         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2574         return;
2575     }
2576     unless( $item ) {
2577         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2578         return;
2579     }
2580     unless( $status ) {
2581         warn "_FixOverduesOnReturn() not supplied valid status";
2582         return;
2583     }
2584
2585     my $schema = Koha::Database->schema;
2586
2587     my $result = $schema->txn_do(
2588         sub {
2589             # check for overdue fine
2590             my $accountlines = Koha::Account::Lines->search(
2591                 {
2592                     borrowernumber  => $borrowernumber,
2593                     itemnumber      => $item,
2594                     debit_type_code => 'OVERDUE',
2595                     status          => 'UNRETURNED'
2596                 }
2597             );
2598             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2599
2600             my $accountline = $accountlines->next;
2601             my $payments = $accountline->credits;
2602
2603             my $amountoutstanding = $accountline->amountoutstanding;
2604             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2605                 $accountline->delete;
2606                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2607             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2608                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2609                 my $credit = $account->add_credit(
2610                     {
2611                         amount     => $amountoutstanding,
2612                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2613                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2614                         interface  => C4::Context->interface,
2615                         type       => 'FORGIVEN',
2616                         item_id    => $item
2617                     }
2618                 );
2619
2620                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2621
2622                 if (C4::Context->preference("FinesLog")) {
2623                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2624                 }
2625             }
2626
2627             $accountline->status($status);
2628             return $accountline->store();
2629         }
2630     );
2631
2632     return $result;
2633 }
2634
2635 =head2 _GetCircControlBranch
2636
2637    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2638
2639 Internal function :
2640
2641 Return the library code to be used to determine which circulation
2642 policy applies to a transaction.  Looks up the CircControl and
2643 HomeOrHoldingBranch system preferences.
2644
2645 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2646
2647 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2648
2649 =cut
2650
2651 sub _GetCircControlBranch {
2652     my ($item, $borrower) = @_;
2653     my $circcontrol = C4::Context->preference('CircControl');
2654     my $branch;
2655
2656     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2657         $branch= C4::Context->userenv->{'branch'};
2658     } elsif ($circcontrol eq 'PatronLibrary') {
2659         $branch=$borrower->{branchcode};
2660     } else {
2661         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2662         $branch = $item->{$branchfield};
2663         # default to item home branch if holdingbranch is used
2664         # and is not defined
2665         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2666             $branch = $item->{homebranch};
2667         }
2668     }
2669     return $branch;
2670 }
2671
2672 =head2 GetOpenIssue
2673
2674   $issue = GetOpenIssue( $itemnumber );
2675
2676 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2677
2678 C<$itemnumber> is the item's itemnumber
2679
2680 Returns a hashref
2681
2682 =cut
2683
2684 sub GetOpenIssue {
2685   my ( $itemnumber ) = @_;
2686   return unless $itemnumber;
2687   my $dbh = C4::Context->dbh;
2688   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2689   $sth->execute( $itemnumber );
2690   return $sth->fetchrow_hashref();
2691
2692 }
2693
2694 =head2 GetUpcomingDueIssues
2695
2696   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2697
2698 =cut
2699
2700 sub GetUpcomingDueIssues {
2701     my $params = shift;
2702
2703     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2704     my $dbh = C4::Context->dbh;
2705     my $statement;
2706     $statement = q{
2707         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2708         FROM issues
2709         LEFT JOIN items USING (itemnumber)
2710         LEFT JOIN branches ON branches.branchcode =
2711     };
2712     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2713     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2714     my @bind_parameters = ( $params->{'days_in_advance'} );
2715
2716     my $sth = $dbh->prepare( $statement );
2717     $sth->execute( @bind_parameters );
2718     my $upcoming_dues = $sth->fetchall_arrayref({});
2719
2720     return $upcoming_dues;
2721 }
2722
2723 =head2 CanBookBeRenewed
2724
2725   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2726
2727 Find out whether a borrowed item may be renewed.
2728
2729 C<$borrowernumber> is the borrower number of the patron who currently
2730 has the item on loan.
2731
2732 C<$itemnumber> is the number of the item to renew.
2733
2734 C<$override_limit>, if supplied with a true value, causes
2735 the limit on the number of times that the loan can be renewed
2736 (as controlled by the item type) to be ignored. Overriding also allows
2737 to renew sooner than "No renewal before" and to manually renew loans
2738 that are automatically renewed.
2739
2740 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2741 item must currently be on loan to the specified borrower; renewals
2742 must be allowed for the item's type; and the borrower must not have
2743 already renewed the loan. $error will contain the reason the renewal can not proceed
2744
2745 =cut
2746
2747 sub CanBookBeRenewed {
2748     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2749
2750     my $dbh    = C4::Context->dbh;
2751     my $renews = 1;
2752     my $auto_renew = "no";
2753
2754     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2755     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2756     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2757     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2758
2759     my $patron = $issue->patron or return;
2760
2761     # override_limit will override anything else except on_reserve
2762     unless ( $override_limit ){
2763         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2764         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2765             {
2766                 categorycode => $patron->categorycode,
2767                 itemtype     => $item->effective_itemtype,
2768                 branchcode   => $branchcode,
2769                 rules => [
2770                     'renewalsallowed',
2771                     'no_auto_renewal_after',
2772                     'no_auto_renewal_after_hard_limit',
2773                     'lengthunit',
2774                     'norenewalbefore',
2775                     'unseen_renewals_allowed'
2776                 ]
2777             }
2778         );
2779
2780         return ( 0, "too_many" )
2781           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2782
2783         return ( 0, "too_unseen" )
2784           if C4::Context->preference('UnseenRenewals') &&
2785             $issuing_rule->{unseen_renewals_allowed} &&
2786             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2787
2788         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2789         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2790         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2791         my $restricted  = $patron->is_debarred;
2792         my $hasoverdues = $patron->has_overdues;
2793
2794         if ( $restricted and $restrictionblockrenewing ) {
2795             return ( 0, 'restriction');
2796         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2797             return ( 0, 'overdue');
2798         }
2799
2800         if ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2801
2802             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2803                 return ( 0, 'auto_account_expired' );
2804             }
2805
2806             if ( defined $issuing_rule->{no_auto_renewal_after}
2807                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2808                 # Get issue_date and add no_auto_renewal_after
2809                 # If this is greater than today, it's too late for renewal.
2810                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2811                 $maximum_renewal_date->add(
2812                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2813                 );
2814                 my $now = dt_from_string;
2815                 if ( $now >= $maximum_renewal_date ) {
2816                     return ( 0, "auto_too_late" );
2817                 }
2818             }
2819             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2820                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2821                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2822                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2823                     return ( 0, "auto_too_late" );
2824                 }
2825             }
2826
2827             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2828                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2829                 my $amountoutstanding =
2830                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2831                   ? $patron->account->balance
2832                   : $patron->account->outstanding_debits->total_outstanding;
2833                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2834                     return ( 0, "auto_too_much_oweing" );
2835                 }
2836             }
2837         }
2838
2839         if ( defined $issuing_rule->{norenewalbefore}
2840             and $issuing_rule->{norenewalbefore} ne "" )
2841         {
2842
2843             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2844             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2845                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2846
2847             # Depending on syspref reset the exact time, only check the date
2848             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2849                 and $issuing_rule->{lengthunit} eq 'days' )
2850             {
2851                 $soonestrenewal->truncate( to => 'day' );
2852             }
2853
2854             if ( $soonestrenewal > dt_from_string() )
2855             {
2856                 $auto_renew = ($issue->auto_renew && $patron->autorenew_checkouts) ? "auto_too_soon" : "too_soon";
2857             }
2858             elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2859                 $auto_renew = "ok";
2860             }
2861         }
2862
2863         # Fallback for automatic renewals:
2864         # If norenewalbefore is undef, don't renew before due date.
2865         if ( $issue->auto_renew && $auto_renew eq "no" && $patron->autorenew_checkouts ) {
2866             my $now = dt_from_string;
2867             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2868                 $auto_renew = "ok";
2869             } else {
2870                 $auto_renew = "auto_too_soon";
2871             }
2872         }
2873     }
2874
2875     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2876
2877     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2878     if ( $resfound && $resrec->{non_priority} ) {
2879         $resfound = Koha::Holds->search(
2880             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2881           ->count > 0;
2882     }
2883
2884
2885
2886     # This item can fill one or more unfilled reserve, can those unfilled reserves
2887     # all be filled by other available items?
2888     if ( $resfound
2889         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2890     {
2891         my $schema = Koha::Database->new()->schema();
2892
2893         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2894         if ($item_holds) {
2895             # There is an item level hold on this item, no other item can fill the hold
2896             $resfound = 1;
2897         }
2898         else {
2899
2900             # Get all other items that could possibly fill reserves
2901             my @itemnumbers = $schema->resultset('Item')->search(
2902                 {
2903                     biblionumber => $resrec->{biblionumber},
2904                     onloan       => undef,
2905                     notforloan   => 0,
2906                     -not         => { itemnumber => $itemnumber }
2907                 },
2908                 { columns => 'itemnumber' }
2909             )->get_column('itemnumber')->all();
2910
2911             # Get all other reserves that could have been filled by this item
2912             my @borrowernumbers;
2913             while (1) {
2914                 my ( $reserve_found, $reserve, undef ) =
2915                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2916
2917                 if ($reserve_found) {
2918                     push( @borrowernumbers, $reserve->{borrowernumber} );
2919                 }
2920                 else {
2921                     last;
2922                 }
2923             }
2924
2925             # If the count of the union of the lists of reservable items for each borrower
2926             # is equal or greater than the number of borrowers, we know that all reserves
2927             # can be filled with available items. We can get the union of the sets simply
2928             # by pushing all the elements onto an array and removing the duplicates.
2929             my @reservable;
2930             my %patrons;
2931             ITEM: foreach my $itemnumber (@itemnumbers) {
2932                 my $item = Koha::Items->find( $itemnumber );
2933                 next if IsItemOnHoldAndFound( $itemnumber );
2934                 for my $borrowernumber (@borrowernumbers) {
2935                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2936                     next unless IsAvailableForItemLevelRequest($item, $patron);
2937                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2938
2939                     push @reservable, $itemnumber;
2940                     if (@reservable >= @borrowernumbers) {
2941                         $resfound = 0;
2942                         last ITEM;
2943                     }
2944                     last;
2945                 }
2946             }
2947         }
2948     }
2949     if( $cron ) { #The cron wants to return 'too_soon' over 'on_reserve'
2950         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2951         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2952     } else { # For other purposes we want 'on_reserve' before 'too_soon'
2953         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2954         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2955     }
2956
2957     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2958
2959     return ( 1, undef );
2960 }
2961
2962 =head2 AddRenewal
2963
2964   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
2965
2966 Renews a loan.
2967
2968 C<$borrowernumber> is the borrower number of the patron who currently
2969 has the item.
2970
2971 C<$itemnumber> is the number of the item to renew.
2972
2973 C<$branch> is the library where the renewal took place (if any).
2974            The library that controls the circ policies for the renewal is retrieved from the issues record.
2975
2976 C<$datedue> can be a DateTime object used to set the due date.
2977
2978 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2979 this parameter is not supplied, lastreneweddate is set to the current date.
2980
2981 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2982 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2983 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2984 syspref)
2985
2986 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2987 from the book's item type.
2988
2989 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
2990 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
2991 fallback to a true value
2992
2993 =cut
2994
2995 sub AddRenewal {
2996     my $borrowernumber  = shift;
2997     my $itemnumber      = shift or return;
2998     my $branch          = shift;
2999     my $datedue         = shift;
3000     my $lastreneweddate = shift || dt_from_string();
3001     my $skipfinecalc    = shift;
3002     my $seen            = shift;
3003
3004     # Fallback on a 'seen' renewal
3005     $seen = defined $seen && $seen == 0 ? 0 : 1;
3006
3007     my $item_object   = Koha::Items->find($itemnumber) or return;
3008     my $biblio = $item_object->biblio;
3009     my $issue  = $item_object->checkout;
3010     my $item_unblessed = $item_object->unblessed;
3011
3012     my $dbh = C4::Context->dbh;
3013
3014     return unless $issue;
3015
3016     $borrowernumber ||= $issue->borrowernumber;
3017
3018     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3019         carp 'Invalid date passed to AddRenewal.';
3020         return;
3021     }
3022
3023     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3024     my $patron_unblessed = $patron->unblessed;
3025
3026     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3027
3028     my $schema = Koha::Database->schema;
3029     $schema->txn_do(sub{
3030
3031         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3032             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3033         }
3034         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3035
3036         # If the due date wasn't specified, calculate it by adding the
3037         # book's loan length to today's date or the current due date
3038         # based on the value of the RenewalPeriodBase syspref.
3039         my $itemtype = $item_object->effective_itemtype;
3040         unless ($datedue) {
3041
3042             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3043                                             dt_from_string( $issue->date_due, 'sql' ) :
3044                                             dt_from_string();
3045             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3046         }
3047
3048         my $fees = Koha::Charges::Fees->new(
3049             {
3050                 patron    => $patron,
3051                 library   => $circ_library,
3052                 item      => $item_object,
3053                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3054                 to_date   => dt_from_string($datedue),
3055             }
3056         );
3057
3058         # Increment the unseen renewals, if appropriate
3059         # We only do so if the syspref is enabled and
3060         # a maximum value has been set in the circ rules
3061         my $unseen_renewals = $issue->unseen_renewals;
3062         if (C4::Context->preference('UnseenRenewals')) {
3063             my $rule = Koha::CirculationRules->get_effective_rule(
3064                 {   categorycode => $patron->categorycode,
3065                     itemtype     => $item_object->effective_itemtype,
3066                     branchcode   => $circ_library->branchcode,
3067                     rule_name    => 'unseen_renewals_allowed'
3068                 }
3069             );
3070             if (!$seen && $rule && $rule->rule_value) {
3071                 $unseen_renewals++;
3072             } else {
3073                 # If the renewal is seen, unseen should revert to 0
3074                 $unseen_renewals = 0;
3075             }
3076         }
3077
3078         # Update the issues record to have the new due date, and a new count
3079         # of how many times it has been renewed.
3080         my $renews = ( $issue->renewals || 0 ) + 1;
3081         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3082
3083         eval{
3084             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3085         };
3086         if( $sth->err ){
3087             Koha::Exceptions::Checkout::FailedRenewal->throw(
3088                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3089             );
3090         }
3091
3092         # Update the renewal count on the item, and tell zebra to reindex
3093         $renews = ( $item_object->renewals || 0 ) + 1;
3094         $item_object->renewals($renews);
3095         $item_object->onloan($datedue);
3096         $item_object->store({ log_action => 0 });
3097
3098         # Charge a new rental fee, if applicable
3099         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3100         if ( $charge > 0 ) {
3101             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3102         }
3103
3104         # Charge a new accumulate rental fee, if applicable
3105         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3106         if ( $itemtype_object ) {
3107             my $accumulate_charge = $fees->accumulate_rentalcharge();
3108             if ( $accumulate_charge > 0 ) {
3109                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3110             }
3111             $charge += $accumulate_charge;
3112         }
3113
3114         # Send a renewal slip according to checkout alert preferencei
3115         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3116             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3117             my %conditions        = (
3118                 branchcode   => $branch,
3119                 categorycode => $patron->categorycode,
3120                 item_type    => $itemtype,
3121                 notification => 'CHECKOUT',
3122             );
3123             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3124                 SendCirculationAlert(
3125                     {
3126                         type     => 'RENEWAL',
3127                         item     => $item_unblessed,
3128                         borrower => $patron->unblessed,
3129                         branch   => $branch,
3130                     }
3131                 );
3132             }
3133         }
3134
3135         # Remove any OVERDUES related debarment if the borrower has no overdues
3136         if ( $patron
3137           && $patron->is_debarred
3138           && ! $patron->has_overdues
3139           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3140         ) {
3141             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3142         }
3143
3144         # Add the renewal to stats
3145         UpdateStats(
3146             {
3147                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3148                 type           => 'renew',
3149                 amount         => $charge,
3150                 itemnumber     => $itemnumber,
3151                 itemtype       => $itemtype,
3152                 location       => $item_object->location,
3153                 borrowernumber => $borrowernumber,
3154                 ccode          => $item_object->ccode,
3155             }
3156         );
3157
3158         #Log the renewal
3159         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3160
3161         Koha::Plugins->call('after_circ_action', {
3162             action  => 'renewal',
3163             payload => {
3164                 checkout  => $issue->get_from_storage
3165             }
3166         });
3167     });
3168
3169     return $datedue;
3170 }
3171
3172 sub GetRenewCount {
3173     # check renewal status
3174     my ( $bornum, $itemno ) = @_;
3175     my $dbh           = C4::Context->dbh;
3176     my $renewcount    = 0;
3177     my $unseencount    = 0;
3178     my $renewsallowed = 0;
3179     my $unseenallowed = 0;
3180     my $renewsleft    = 0;
3181     my $unseenleft    = 0;
3182
3183     my $patron = Koha::Patrons->find( $bornum );
3184     my $item   = Koha::Items->find($itemno);
3185
3186     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3187
3188     # Look in the issues table for this item, lent to this borrower,
3189     # and not yet returned.
3190
3191     # FIXME - I think this function could be redone to use only one SQL call.
3192     my $sth = $dbh->prepare(
3193         "select * from issues
3194                                 where (borrowernumber = ?)
3195                                 and (itemnumber = ?)"
3196     );
3197     $sth->execute( $bornum, $itemno );
3198     my $data = $sth->fetchrow_hashref;
3199     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3200     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3201     # $item and $borrower should be calculated
3202     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3203
3204     my $rules = Koha::CirculationRules->get_effective_rules(
3205         {
3206             categorycode => $patron->categorycode,
3207             itemtype     => $item->effective_itemtype,
3208             branchcode   => $branchcode,
3209             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3210         }
3211     );
3212     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3213     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3214         $rules->{unseen_renewals_allowed} :
3215         0;
3216     $renewsleft    = $renewsallowed - $renewcount;
3217     $unseenleft    = $unseenallowed - $unseencount;
3218     if($renewsleft < 0){ $renewsleft = 0; }
3219     if($unseenleft < 0){ $unseenleft = 0; }
3220     return (
3221         $renewcount,
3222         $renewsallowed,
3223         $renewsleft,
3224         $unseencount,
3225         $unseenallowed,
3226         $unseenleft
3227     );
3228 }
3229
3230 =head2 GetSoonestRenewDate
3231
3232   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3233
3234 Find out the soonest possible renew date of a borrowed item.
3235
3236 C<$borrowernumber> is the borrower number of the patron who currently
3237 has the item on loan.
3238
3239 C<$itemnumber> is the number of the item to renew.
3240
3241 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3242 renew date, based on the value "No renewal before" of the applicable
3243 issuing rule. Returns the current date if the item can already be
3244 renewed, and returns undefined if the borrower, loan, or item
3245 cannot be found.
3246
3247 =cut
3248
3249 sub GetSoonestRenewDate {
3250     my ( $borrowernumber, $itemnumber ) = @_;
3251
3252     my $dbh = C4::Context->dbh;
3253
3254     my $item      = Koha::Items->find($itemnumber)      or return;
3255     my $itemissue = $item->checkout or return;
3256
3257     $borrowernumber ||= $itemissue->borrowernumber;
3258     my $patron = Koha::Patrons->find( $borrowernumber )
3259       or return;
3260
3261     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3262     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3263         {   categorycode => $patron->categorycode,
3264             itemtype     => $item->effective_itemtype,
3265             branchcode   => $branchcode,
3266             rules => [
3267                 'norenewalbefore',
3268                 'lengthunit',
3269             ]
3270         }
3271     );
3272
3273     my $now = dt_from_string;
3274     return $now unless $issuing_rule;
3275
3276     if ( defined $issuing_rule->{norenewalbefore}
3277         and $issuing_rule->{norenewalbefore} ne "" )
3278     {
3279         my $soonestrenewal =
3280           dt_from_string( $itemissue->date_due )->subtract(
3281             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3282
3283         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3284             and $issuing_rule->{lengthunit} eq 'days' )
3285         {
3286             $soonestrenewal->truncate( to => 'day' );
3287         }
3288         return $soonestrenewal if $now < $soonestrenewal;
3289     }
3290     return $now;
3291 }
3292
3293 =head2 GetLatestAutoRenewDate
3294
3295   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3296
3297 Find out the latest possible auto renew date of a borrowed item.
3298
3299 C<$borrowernumber> is the borrower number of the patron who currently
3300 has the item on loan.
3301
3302 C<$itemnumber> is the number of the item to renew.
3303
3304 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3305 auto renew date, based on the value "No auto renewal after" and the "No auto
3306 renewal after (hard limit) of the applicable issuing rule.
3307 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3308 or item cannot be found.
3309
3310 =cut
3311
3312 sub GetLatestAutoRenewDate {
3313     my ( $borrowernumber, $itemnumber ) = @_;
3314
3315     my $dbh = C4::Context->dbh;
3316
3317     my $item      = Koha::Items->find($itemnumber)  or return;
3318     my $itemissue = $item->checkout                 or return;
3319
3320     $borrowernumber ||= $itemissue->borrowernumber;
3321     my $patron = Koha::Patrons->find( $borrowernumber )
3322       or return;
3323
3324     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3325     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3326         {
3327             categorycode => $patron->categorycode,
3328             itemtype     => $item->effective_itemtype,
3329             branchcode   => $branchcode,
3330             rules => [
3331                 'no_auto_renewal_after',
3332                 'no_auto_renewal_after_hard_limit',
3333                 'lengthunit',
3334             ]
3335         }
3336     );
3337
3338     return unless $circulation_rules;
3339     return
3340       if ( not $circulation_rules->{no_auto_renewal_after}
3341             or $circulation_rules->{no_auto_renewal_after} eq '' )
3342       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3343              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3344
3345     my $maximum_renewal_date;
3346     if ( $circulation_rules->{no_auto_renewal_after} ) {
3347         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3348         $maximum_renewal_date->add(
3349             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3350         );
3351     }
3352
3353     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3354         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3355         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3356     }
3357     return $maximum_renewal_date;
3358 }
3359
3360
3361 =head2 GetIssuingCharges
3362
3363   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3364
3365 Calculate how much it would cost for a given patron to borrow a given
3366 item, including any applicable discounts.
3367
3368 C<$itemnumber> is the item number of item the patron wishes to borrow.
3369
3370 C<$borrowernumber> is the patron's borrower number.
3371
3372 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3373 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3374 if it's a video).
3375
3376 =cut
3377
3378 sub GetIssuingCharges {
3379
3380     # calculate charges due
3381     my ( $itemnumber, $borrowernumber ) = @_;
3382     my $charge = 0;
3383     my $dbh    = C4::Context->dbh;
3384     my $item_type;
3385
3386     # Get the book's item type and rental charge (via its biblioitem).
3387     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3388         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3389     $charge_query .= (C4::Context->preference('item-level_itypes'))
3390         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3391         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3392
3393     $charge_query .= ' WHERE items.itemnumber =?';
3394
3395     my $sth = $dbh->prepare($charge_query);
3396     $sth->execute($itemnumber);
3397     if ( my $item_data = $sth->fetchrow_hashref ) {
3398         $item_type = $item_data->{itemtype};
3399         $charge    = $item_data->{rentalcharge};
3400         # FIXME This should follow CircControl
3401         my $branch = C4::Context::mybranch();
3402         my $patron = Koha::Patrons->find( $borrowernumber );
3403         my $discount = Koha::CirculationRules->get_effective_rule({
3404             categorycode => $patron->categorycode,
3405             branchcode   => $branch,
3406             itemtype     => $item_type,
3407             rule_name    => 'rentaldiscount'
3408         });
3409         if ($discount) {
3410             $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3411         }
3412         if ($charge) {
3413             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3414         }
3415     }
3416
3417     return ( $charge, $item_type );
3418 }
3419
3420 =head2 AddIssuingCharge
3421
3422   &AddIssuingCharge( $checkout, $charge, $type )
3423
3424 =cut
3425
3426 sub AddIssuingCharge {
3427     my ( $checkout, $charge, $type ) = @_;
3428
3429     # FIXME What if checkout does not exist?
3430
3431     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3432     my $accountline = $account->add_debit(
3433         {
3434             amount      => $charge,
3435             note        => undef,
3436             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3437             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3438             interface   => C4::Context->interface,
3439             type        => $type,
3440             item_id     => $checkout->itemnumber,
3441             issue_id    => $checkout->issue_id,
3442         }
3443     );
3444 }
3445
3446 =head2 GetTransfers
3447
3448   GetTransfers($itemnumber);
3449
3450 =cut
3451
3452 sub GetTransfers {
3453     my ($itemnumber) = @_;
3454
3455     my $dbh = C4::Context->dbh;
3456
3457     my $query = '
3458         SELECT datesent,
3459                frombranch,
3460                tobranch,
3461                branchtransfer_id,
3462                daterequested,
3463                reason
3464         FROM branchtransfers
3465         WHERE itemnumber = ?
3466           AND datearrived IS NULL
3467           AND datecancelled IS NULL
3468         ';
3469     my $sth = $dbh->prepare($query);
3470     $sth->execute($itemnumber);
3471     my @row = $sth->fetchrow_array();
3472     return @row;
3473 }
3474
3475 =head2 GetTransfersFromTo
3476
3477   @results = GetTransfersFromTo($frombranch,$tobranch);
3478
3479 Returns the list of pending transfers between $from and $to branch
3480
3481 =cut
3482
3483 sub GetTransfersFromTo {
3484     my ( $frombranch, $tobranch ) = @_;
3485     return unless ( $frombranch && $tobranch );
3486     my $dbh   = C4::Context->dbh;
3487     my $query = "
3488         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3489         FROM   branchtransfers
3490         WHERE  frombranch=?
3491           AND  tobranch=?
3492           AND datecancelled IS NULL
3493           AND datesent IS NOT NULL
3494           AND datearrived IS NULL
3495     ";
3496     my $sth = $dbh->prepare($query);
3497     $sth->execute( $frombranch, $tobranch );
3498     my @gettransfers;
3499
3500     while ( my $data = $sth->fetchrow_hashref ) {
3501         push @gettransfers, $data;
3502     }
3503     return (@gettransfers);
3504 }
3505
3506 =head2 DeleteTransfer
3507
3508   &DeleteTransfer($itemnumber);
3509
3510 =cut
3511
3512 sub DeleteTransfer {
3513     my ($itemnumber) = @_;
3514     return unless $itemnumber;
3515     my $dbh          = C4::Context->dbh;
3516     my $sth          = $dbh->prepare(
3517         "DELETE FROM branchtransfers
3518          WHERE itemnumber=?
3519          AND datearrived IS NULL "
3520     );
3521     return $sth->execute($itemnumber);
3522 }
3523
3524 =head2 SendCirculationAlert
3525
3526 Send out a C<check-in> or C<checkout> alert using the messaging system.
3527
3528 B<Parameters>:
3529
3530 =over 4
3531
3532 =item type
3533
3534 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3535
3536 =item item
3537
3538 Hashref of information about the item being checked in or out.
3539
3540 =item borrower
3541
3542 Hashref of information about the borrower of the item.
3543
3544 =item branch
3545
3546 The branchcode from where the checkout or check-in took place.
3547
3548 =back
3549
3550 B<Example>:
3551
3552     SendCirculationAlert({
3553         type     => 'CHECKOUT',
3554         item     => $item,
3555         borrower => $borrower,
3556         branch   => $branch,
3557     });
3558
3559 =cut
3560
3561 sub SendCirculationAlert {
3562     my ($opts) = @_;
3563     my ($type, $item, $borrower, $branch) =
3564         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3565     my %message_name = (
3566         CHECKIN  => 'Item_Check_in',
3567         CHECKOUT => 'Item_Checkout',
3568         RENEWAL  => 'Item_Checkout',
3569     );
3570     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3571         borrowernumber => $borrower->{borrowernumber},
3572         message_name   => $message_name{$type},
3573     });
3574     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3575
3576     my $schema = Koha::Database->new->schema;
3577     my @transports = keys %{ $borrower_preferences->{transports} };
3578
3579     # From the MySQL doc:
3580     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3581     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3582     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3583     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3584
3585     for my $mtt (@transports) {
3586         my $letter =  C4::Letters::GetPreparedLetter (
3587             module => 'circulation',
3588             letter_code => $type,
3589             branchcode => $branch,
3590             message_transport_type => $mtt,
3591             lang => $borrower->{lang},
3592             tables => {
3593                 $issues_table => $item->{itemnumber},
3594                 'items'       => $item->{itemnumber},
3595                 'biblio'      => $item->{biblionumber},
3596                 'biblioitems' => $item->{biblionumber},
3597                 'borrowers'   => $borrower,
3598                 'branches'    => $branch,
3599             }
3600         ) or next;
3601
3602         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3603         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3604         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3605         unless ( $message ) {
3606             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3607             C4::Message->enqueue($letter, $borrower, $mtt);
3608         } else {
3609             $message->append($letter);
3610             $message->update;
3611         }
3612         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3613     }
3614
3615     return;
3616 }
3617
3618 =head2 updateWrongTransfer
3619
3620   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3621
3622 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3623
3624 =cut
3625
3626 sub updateWrongTransfer {
3627         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3628         my $dbh = C4::Context->dbh;
3629 # first step validate the actual line of transfert .
3630         my $sth =
3631                 $dbh->prepare(
3632                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3633                 );
3634                 $sth->execute($FromLibrary,$itemNumber);
3635
3636 # second step create a new line of branchtransfer to the right location .
3637         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3638
3639 #third step changing holdingbranch of item
3640     my $item = Koha::Items->find($itemNumber)->holdingbranch($FromLibrary)->store;
3641 }
3642
3643 =head2 CalcDateDue
3644
3645 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3646
3647 this function calculates the due date given the start date and configured circulation rules,
3648 checking against the holidays calendar as per the daysmode circulation rule.
3649 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3650 C<$itemtype>  = itemtype code of item in question
3651 C<$branch>  = location whose calendar to use
3652 C<$borrower> = Borrower object
3653 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3654
3655 =cut
3656
3657 sub CalcDateDue {
3658     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3659
3660     $isrenewal ||= 0;
3661
3662     # loanlength now a href
3663     my $loanlength =
3664             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3665
3666     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3667             ? qq{renewalperiod}
3668             : qq{issuelength};
3669
3670     my $datedue;
3671     if ( $startdate ) {
3672         if (ref $startdate ne 'DateTime' ) {
3673             $datedue = dt_from_string($datedue);
3674         } else {
3675             $datedue = $startdate->clone;
3676         }
3677     } else {
3678         $datedue = dt_from_string()->truncate( to => 'minute' );
3679     }
3680
3681
3682     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3683         {
3684             categorycode => $borrower->{categorycode},
3685             itemtype     => $itemtype,
3686             branchcode   => $branch,
3687         }
3688     );
3689
3690     # calculate the datedue as normal
3691     if ( $daysmode eq 'Days' )
3692     {    # ignoring calendar
3693         if ( $loanlength->{lengthunit} eq 'hours' ) {
3694             $datedue->add( hours => $loanlength->{$length_key} );
3695         } else {    # days
3696             $datedue->add( days => $loanlength->{$length_key} );
3697             $datedue->set_hour(23);
3698             $datedue->set_minute(59);
3699         }
3700     } else {
3701         my $dur;
3702         if ($loanlength->{lengthunit} eq 'hours') {
3703             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3704         }
3705         else { # days
3706             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3707         }
3708         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3709         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3710         if ($loanlength->{lengthunit} eq 'days') {
3711             $datedue->set_hour(23);
3712             $datedue->set_minute(59);
3713         }
3714     }
3715
3716     # if Hard Due Dates are used, retrieve them and apply as necessary
3717     my ( $hardduedate, $hardduedatecompare ) =
3718       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3719     if ($hardduedate) {    # hardduedates are currently dates
3720         $hardduedate->truncate( to => 'minute' );
3721         $hardduedate->set_hour(23);
3722         $hardduedate->set_minute(59);
3723         my $cmp = DateTime->compare( $hardduedate, $datedue );
3724
3725 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3726 # if the calculated date is before the 'after' Hard Due Date (floor), override
3727 # if the hard due date is set to 'exactly', overrride
3728         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3729             $datedue = $hardduedate->clone;
3730         }
3731
3732         # in all other cases, keep the date due as it is
3733
3734     }
3735
3736     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3737     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3738         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3739         if( $expiry_dt ) { #skip empty expiry date..
3740             $expiry_dt->set( hour => 23, minute => 59);
3741             my $d1= $datedue->clone->set_time_zone('floating');
3742             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3743                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3744             }
3745         }
3746         if ( $daysmode ne 'Days' ) {
3747           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3748           if ( $calendar->is_holiday($datedue) ) {
3749               # Don't return on a closed day
3750               $datedue = $calendar->prev_open_days( $datedue, 1 );
3751           }
3752         }
3753     }
3754
3755     return $datedue;
3756 }
3757
3758
3759 sub CheckValidBarcode{
3760 my ($barcode) = @_;
3761 my $dbh = C4::Context->dbh;
3762 my $query=qq|SELECT count(*)
3763              FROM items
3764              WHERE barcode=?
3765             |;
3766 my $sth = $dbh->prepare($query);
3767 $sth->execute($barcode);
3768 my $exist=$sth->fetchrow ;
3769 return $exist;
3770 }
3771
3772 =head2 IsBranchTransferAllowed
3773
3774   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3775
3776 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3777
3778 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3779 Koha::Item->can_be_transferred.
3780
3781 =cut
3782
3783 sub IsBranchTransferAllowed {
3784         my ( $toBranch, $fromBranch, $code ) = @_;
3785
3786         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3787
3788         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3789         my $dbh = C4::Context->dbh;
3790
3791         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3792         $sth->execute( $toBranch, $fromBranch, $code );
3793         my $limit = $sth->fetchrow_hashref();
3794
3795         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3796         if ( $limit->{'limitId'} ) {
3797                 return 0;
3798         } else {
3799                 return 1;
3800         }
3801 }
3802
3803 =head2 CreateBranchTransferLimit
3804
3805   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3806
3807 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3808
3809 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3810
3811 =cut
3812
3813 sub CreateBranchTransferLimit {
3814    my ( $toBranch, $fromBranch, $code ) = @_;
3815    return unless defined($toBranch) && defined($fromBranch);
3816    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3817
3818    my $dbh = C4::Context->dbh;
3819
3820    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3821    return $sth->execute( $code, $toBranch, $fromBranch );
3822 }
3823
3824 =head2 DeleteBranchTransferLimits
3825
3826     my $result = DeleteBranchTransferLimits($frombranch);
3827
3828 Deletes all the library transfer limits for one library.  Returns the
3829 number of limits deleted, 0e0 if no limits were deleted, or undef if
3830 no arguments are supplied.
3831
3832 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3833     fromBranch => $fromBranch
3834     })->delete.
3835
3836 =cut
3837
3838 sub DeleteBranchTransferLimits {
3839     my $branch = shift;
3840     return unless defined $branch;
3841     my $dbh    = C4::Context->dbh;
3842     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3843     return $sth->execute($branch);
3844 }
3845
3846 sub ReturnLostItem{
3847     my ( $borrowernumber, $itemnum ) = @_;
3848     MarkIssueReturned( $borrowernumber, $itemnum );
3849 }
3850
3851 =head2 LostItem
3852
3853   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3854
3855 The final optional parameter, C<$params>, expected to contain
3856 'skip_record_index' key, which relayed down to Koha::Item/store,
3857 there it prevents calling of ModZebra index_records,
3858 which takes most of the time in batch adds/deletes: index_records better
3859 to be called later in C<additem.pl> after the whole loop.
3860
3861 $params:
3862     skip_record_index => 1|0
3863
3864 =cut
3865
3866 sub LostItem{
3867     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3868
3869     unless ( $mark_lost_from ) {
3870         # Temporary check to avoid regressions
3871         die q|LostItem called without $mark_lost_from, check the API.|;
3872     }
3873
3874     my $mark_returned;
3875     if ( $force_mark_returned ) {
3876         $mark_returned = 1;
3877     } else {
3878         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3879         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3880     }
3881
3882     my $dbh = C4::Context->dbh();
3883     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3884                            FROM issues
3885                            JOIN items USING (itemnumber)
3886                            JOIN biblio USING (biblionumber)
3887                            WHERE issues.itemnumber=?");
3888     $sth->execute($itemnumber);
3889     my $issues=$sth->fetchrow_hashref();
3890
3891     # If a borrower lost the item, add a replacement cost to the their record
3892     if ( my $borrowernumber = $issues->{borrowernumber} ){
3893         my $patron = Koha::Patrons->find( $borrowernumber );
3894
3895         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3896         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3897
3898         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3899             C4::Accounts::chargelostitem(
3900                 $borrowernumber,
3901                 $itemnumber,
3902                 $issues->{'replacementprice'},
3903                 sprintf( "%s %s %s",
3904                     $issues->{'title'}          || q{},
3905                     $issues->{'barcode'}        || q{},
3906                     $issues->{'itemcallnumber'} || q{},
3907                 ),
3908             );
3909             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3910             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3911         }
3912
3913         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3914     }
3915
3916     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3917     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3918         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store({ skip_record_index => $params->{skip_record_index} });
3919     }
3920     my $transferdeleted = DeleteTransfer($itemnumber);
3921 }
3922
3923 sub GetOfflineOperations {
3924     my $dbh = C4::Context->dbh;
3925     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3926     $sth->execute(C4::Context->userenv->{'branch'});
3927     my $results = $sth->fetchall_arrayref({});
3928     return $results;
3929 }
3930
3931 sub GetOfflineOperation {
3932     my $operationid = shift;
3933     return unless $operationid;
3934     my $dbh = C4::Context->dbh;
3935     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3936     $sth->execute( $operationid );
3937     return $sth->fetchrow_hashref;
3938 }
3939
3940 sub AddOfflineOperation {
3941     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3942     my $dbh = C4::Context->dbh;
3943     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3944     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3945     return "Added.";
3946 }
3947
3948 sub DeleteOfflineOperation {
3949     my $dbh = C4::Context->dbh;
3950     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3951     $sth->execute( shift );
3952     return "Deleted.";
3953 }
3954
3955 sub ProcessOfflineOperation {
3956     my $operation = shift;
3957
3958     my $report;
3959     if ( $operation->{action} eq 'return' ) {
3960         $report = ProcessOfflineReturn( $operation );
3961     } elsif ( $operation->{action} eq 'issue' ) {
3962         $report = ProcessOfflineIssue( $operation );
3963     } elsif ( $operation->{action} eq 'payment' ) {
3964         $report = ProcessOfflinePayment( $operation );
3965     }
3966
3967     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3968
3969     return $report;
3970 }
3971
3972 sub ProcessOfflineReturn {
3973     my $operation = shift;
3974
3975     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3976
3977     if ( $item ) {
3978         my $itemnumber = $item->itemnumber;
3979         my $issue = GetOpenIssue( $itemnumber );
3980         if ( $issue ) {
3981             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3982             ModDateLastSeen( $itemnumber, $leave_item_lost );
3983             MarkIssueReturned(
3984                 $issue->{borrowernumber},
3985                 $itemnumber,
3986                 $operation->{timestamp},
3987             );
3988             $item->renewals(0);
3989             $item->onloan(undef);
3990             $item->store({ log_action => 0 });
3991             return "Success.";
3992         } else {
3993             return "Item not issued.";
3994         }
3995     } else {
3996         return "Item not found.";
3997     }
3998 }
3999
4000 sub ProcessOfflineIssue {
4001     my $operation = shift;
4002
4003     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4004
4005     if ( $patron ) {
4006         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4007         unless ($item) {
4008             return "Barcode not found.";
4009         }
4010         my $itemnumber = $item->itemnumber;
4011         my $issue = GetOpenIssue( $itemnumber );
4012
4013         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4014             MarkIssueReturned(
4015                 $issue->{borrowernumber},
4016                 $itemnumber,
4017                 $operation->{timestamp},
4018             );
4019         }
4020         AddIssue(
4021             $patron->unblessed,
4022             $operation->{'barcode'},
4023             undef,
4024             1,
4025             $operation->{timestamp},
4026             undef,
4027         );
4028         return "Success.";
4029     } else {
4030         return "Borrower not found.";
4031     }
4032 }
4033
4034 sub ProcessOfflinePayment {
4035     my $operation = shift;
4036
4037     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4038
4039     $patron->account->pay(
4040         {
4041             amount     => $operation->{amount},
4042             library_id => $operation->{branchcode},
4043             interface  => 'koc'
4044         }
4045     );
4046
4047     return "Success.";
4048 }
4049
4050 =head2 TransferSlip
4051
4052   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4053
4054   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4055
4056 =cut
4057
4058 sub TransferSlip {
4059     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4060
4061     my $item =
4062       $itemnumber
4063       ? Koha::Items->find($itemnumber)
4064       : Koha::Items->find( { barcode => $barcode } );
4065
4066     $item or return;
4067
4068     return C4::Letters::GetPreparedLetter (
4069         module => 'circulation',
4070         letter_code => 'TRANSFERSLIP',
4071         branchcode => $branch,
4072         tables => {
4073             'branches'    => $to_branch,
4074             'biblio'      => $item->biblionumber,
4075             'items'       => $item->unblessed,
4076         },
4077     );
4078 }
4079
4080 =head2 CheckIfIssuedToPatron
4081
4082   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4083
4084   Return 1 if any record item is issued to patron, otherwise return 0
4085
4086 =cut
4087
4088 sub CheckIfIssuedToPatron {
4089     my ($borrowernumber, $biblionumber) = @_;
4090
4091     my $dbh = C4::Context->dbh;
4092     my $query = q|
4093         SELECT COUNT(*) FROM issues
4094         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4095         WHERE items.biblionumber = ?
4096         AND issues.borrowernumber = ?
4097     |;
4098     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4099     return 1 if $is_issued;
4100     return;
4101 }
4102
4103 =head2 IsItemIssued
4104
4105   IsItemIssued( $itemnumber )
4106
4107   Return 1 if the item is on loan, otherwise return 0
4108
4109 =cut
4110
4111 sub IsItemIssued {
4112     my $itemnumber = shift;
4113     my $dbh = C4::Context->dbh;
4114     my $sth = $dbh->prepare(q{
4115         SELECT COUNT(*)
4116         FROM issues
4117         WHERE itemnumber = ?
4118     });
4119     $sth->execute($itemnumber);
4120     return $sth->fetchrow;
4121 }
4122
4123 =head2 GetAgeRestriction
4124
4125   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4126   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4127
4128   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4129   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4130
4131 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4132 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4133 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4134          Negative days mean the borrower has gone past the age restriction age.
4135
4136 =cut
4137
4138 sub GetAgeRestriction {
4139     my ($record_restrictions, $borrower) = @_;
4140     my $markers = C4::Context->preference('AgeRestrictionMarker');
4141
4142     return unless $record_restrictions;
4143     # Split $record_restrictions to something like FSK 16 or PEGI 6
4144     my @values = split ' ', uc($record_restrictions);
4145     return unless @values;
4146
4147     # Search first occurrence of one of the markers
4148     my @markers = split /\|/, uc($markers);
4149     return unless @markers;
4150
4151     my $index            = 0;
4152     my $restriction_year = 0;
4153     for my $value (@values) {
4154         $index++;
4155         for my $marker (@markers) {
4156             $marker =~ s/^\s+//;    #remove leading spaces
4157             $marker =~ s/\s+$//;    #remove trailing spaces
4158             if ( $marker eq $value ) {
4159                 if ( $index <= $#values ) {
4160                     $restriction_year += $values[$index];
4161                 }
4162                 last;
4163             }
4164             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4165
4166                 # Perhaps it is something like "K16" (as in Finland)
4167                 $restriction_year += $1;
4168                 last;
4169             }
4170         }
4171         last if ( $restriction_year > 0 );
4172     }
4173
4174     #Check if the borrower is age restricted for this material and for how long.
4175     if ($restriction_year && $borrower) {
4176         if ( $borrower->{'dateofbirth'} ) {
4177             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4178             $alloweddate[0] += $restriction_year;
4179
4180             #Prevent runime eror on leap year (invalid date)
4181             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4182                 $alloweddate[2] = 28;
4183             }
4184
4185             #Get how many days the borrower has to reach the age restriction
4186             my @Today = split /-/, dt_from_string()->ymd();
4187             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4188             #Negative days means the borrower went past the age restriction age
4189             return ($restriction_year, $daysToAgeRestriction);
4190         }
4191     }
4192
4193     return ($restriction_year);
4194 }
4195
4196
4197 =head2 GetPendingOnSiteCheckouts
4198
4199 =cut
4200
4201 sub GetPendingOnSiteCheckouts {
4202     my $dbh = C4::Context->dbh;
4203     return $dbh->selectall_arrayref(q|
4204         SELECT
4205           items.barcode,
4206           items.biblionumber,
4207           items.itemnumber,
4208           items.itemnotes,
4209           items.itemcallnumber,
4210           items.location,
4211           issues.date_due,
4212           issues.branchcode,
4213           issues.date_due < NOW() AS is_overdue,
4214           biblio.author,
4215           biblio.title,
4216           borrowers.firstname,
4217           borrowers.surname,
4218           borrowers.cardnumber,
4219           borrowers.borrowernumber
4220         FROM items
4221         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4222         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4223         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4224         WHERE issues.onsite_checkout = 1
4225     |, { Slice => {} } );
4226 }
4227
4228 sub GetTopIssues {
4229     my ($params) = @_;
4230
4231     my ($count, $branch, $itemtype, $ccode, $newness)
4232         = @$params{qw(count branch itemtype ccode newness)};
4233
4234     my $dbh = C4::Context->dbh;
4235     my $query = q{
4236         SELECT * FROM (
4237         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4238           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4239           i.ccode, SUM(i.issues) AS count
4240         FROM biblio b
4241         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4242         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4243     };
4244
4245     my (@where_strs, @where_args);
4246
4247     if ($branch) {
4248         push @where_strs, 'i.homebranch = ?';
4249         push @where_args, $branch;
4250     }
4251     if ($itemtype) {
4252         if (C4::Context->preference('item-level_itypes')){
4253             push @where_strs, 'i.itype = ?';
4254             push @where_args, $itemtype;
4255         } else {
4256             push @where_strs, 'bi.itemtype = ?';
4257             push @where_args, $itemtype;
4258         }
4259     }
4260     if ($ccode) {
4261         push @where_strs, 'i.ccode = ?';
4262         push @where_args, $ccode;
4263     }
4264     if ($newness) {
4265         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4266         push @where_args, $newness;
4267     }
4268
4269     if (@where_strs) {
4270         $query .= 'WHERE ' . join(' AND ', @where_strs);
4271     }
4272
4273     $query .= q{
4274         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4275           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4276           i.ccode
4277         ORDER BY count DESC
4278     };
4279
4280     $query .= q{ ) xxx WHERE count > 0 };
4281     $count = int($count);
4282     if ($count > 0) {
4283         $query .= "LIMIT $count";
4284     }
4285
4286     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4287
4288     return @$rows;
4289 }
4290
4291 =head2 Internal methods
4292
4293 =cut
4294
4295 sub _CalculateAndUpdateFine {
4296     my ($params) = @_;
4297
4298     my $borrower    = $params->{borrower};
4299     my $item        = $params->{item};
4300     my $issue       = $params->{issue};
4301     my $return_date = $params->{return_date};
4302
4303     unless ($borrower) { carp "No borrower passed in!" && return; }
4304     unless ($item)     { carp "No item passed in!"     && return; }
4305     unless ($issue)    { carp "No issue passed in!"    && return; }
4306
4307     my $datedue = dt_from_string( $issue->date_due );
4308
4309     # we only need to calculate and change the fines if we want to do that on return
4310     # Should be on for hourly loans
4311     my $control = C4::Context->preference('CircControl');
4312     my $control_branchcode =
4313         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4314       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4315       :                                     $issue->branchcode;
4316
4317     my $date_returned = $return_date ? $return_date : dt_from_string();
4318
4319     my ( $amount, $unitcounttotal, $unitcount  ) =
4320       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4321
4322     if ( C4::Context->preference('finesMode') eq 'production' ) {
4323         if ( $amount > 0 ) {
4324             C4::Overdues::UpdateFine({
4325                 issue_id       => $issue->issue_id,
4326                 itemnumber     => $issue->itemnumber,
4327                 borrowernumber => $issue->borrowernumber,
4328                 amount         => $amount,
4329                 due            => output_pref($datedue),
4330             });
4331         }
4332         elsif ($return_date) {
4333
4334             # Backdated returns may have fines that shouldn't exist,
4335             # so in this case, we need to drop those fines to 0
4336
4337             C4::Overdues::UpdateFine({
4338                 issue_id       => $issue->issue_id,
4339                 itemnumber     => $issue->itemnumber,
4340                 borrowernumber => $issue->borrowernumber,
4341                 amount         => 0,
4342                 due            => output_pref($datedue),
4343             });
4344         }
4345     }
4346 }
4347
4348 sub _item_denied_renewal {
4349     my ($params) = @_;
4350
4351     my $item = $params->{item};
4352     return unless $item;
4353
4354     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4355     return unless $denyingrules;
4356     foreach my $field (keys %$denyingrules) {
4357         my $val = $item->$field;
4358         if( !defined $val) {
4359             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4360                 return 1;
4361             }
4362         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4363            # If the results matches the values in the syspref
4364            # We return true if match found
4365             return 1;
4366         }
4367     }
4368     return 0;
4369 }
4370
4371 1;
4372
4373 __END__
4374
4375 =head1 AUTHOR
4376
4377 Koha Development Team <http://koha-community.org/>
4378
4379 =cut