C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use Koha::DateUtils qw( dt_from_string output_pref );
  28 use C4::Context;
  29 use C4::Stats qw( UpdateStats );
  30 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest );
  31 use C4::Biblio qw( UpdateTotalIssues );
  32 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  33 use C4::Accounts;
  34 use C4::ItemCirculationAlertPreference;
  35 use C4::Message;
  36 use C4::Log qw( logaction ); # logaction
  37 use C4::Overdues;
  38 use C4::RotatingCollections qw(GetCollectionItemBranches);
  39 use Algorithm::CheckDigits qw( CheckDigits );
  40
  41 use Data::Dumper qw( Dumper );
  42 use Koha::Account;
  43 use Koha::AuthorisedValues;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string output_pref );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetOpenIssue
  99       GetUpcomingDueIssues
 100       CheckIfIssuedToPatron
 101       IsItemIssued
 102       GetAgeRestriction
 103       GetTopIssues
 104
 105       AddReturn
 106       MarkIssueReturned
 107
 108       transferbook
 109       TooMany
 110       GetTransfers
 111       GetTransfersFromTo
 112       updateWrongTransfer
 113       CalcDateDue
 114       CheckValidBarcode
 115       IsBranchTransferAllowed
 116       CreateBranchTransferLimit
 117       DeleteBranchTransferLimits
 118       TransferSlip
 119
 120       GetOfflineOperations
 121       GetOfflineOperation
 122       AddOfflineOperation
 123       DeleteOfflineOperation
 124       ProcessOfflineOperation
 125       ProcessOfflinePayment
 126     );
 127     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 128 }
 129
 130 =head1 NAME
 131
 132 C4::Circulation - Koha circulation module
 133
 134 =head1 SYNOPSIS
 135
 136 use C4::Circulation;
 137
 138 =head1 DESCRIPTION
 139
 140 The functions in this module deal with circulation, issues, and
 141 returns, as well as general information about the library.
 142 Also deals with inventory.
 143
 144 =head1 FUNCTIONS
 145
 146 =head2 barcodedecode
 147
 148   $str = &barcodedecode($barcode, [$filter]);
 149
 150 Generic filter function for barcode string.
 151 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 152 Will do some manipulation of the barcode for systems that deliver a barcode
 153 to circulation.pl that differs from the barcode stored for the item.
 154 For proper functioning of this filter, calling the function on the
 155 correct barcode string (items.barcode) should return an unaltered barcode.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168     my $branch = C4::Context::mybranch();
 169     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 170     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 171     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 172         if ($filter eq 'whitespace') {
 173                 $barcode =~ s/\s//g;
 174         } elsif ($filter eq 'cuecat') {
 175                 chomp($barcode);
 176             my @fields = split( /\./, $barcode );
 177             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 178             ($#results == 2) and return $results[2];
 179         } elsif ($filter eq 'T-prefix') {
 180                 if ($barcode =~ /^[Tt](\d)/) {
 181                         (defined($1) and $1 eq '0') and return $barcode;
 182             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 183                 }
 184         return sprintf("T%07d", $barcode);
 185         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 186         # Why drop the nonzero digit after the T?
 187         # Why pass non-digits (or empty string) to "T%07d"?
 188         } elsif ($filter eq 'libsuite8') {
 189                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 190                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 191                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 192                         }else{
 193                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 194                         }
 195                 }
 196     } elsif ($filter eq 'EAN13') {
 197         my $ean = CheckDigits('ean');
 198         if ( $ean->is_valid($barcode) ) {
 199             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 200             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 201         } else {
 202             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 203         }
 204         }
 205     return $barcode;    # return barcode, modified or not
 206 }
 207
 208 =head2 _decode
 209
 210   $str = &_decode($chunk);
 211
 212 Decodes a segment of a string emitted by a CueCat barcode scanner and
 213 returns it.
 214
 215 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 216 or Javascript based decoding on the client side.
 217
 218 =cut
 219
 220 sub _decode {
 221     my ($encoded) = @_;
 222     my $seq =
 223       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 224     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 225     my $l = ( $#s + 1 ) % 4;
 226     if ($l) {
 227         if ( $l == 1 ) {
 228             # warn "Error: Cuecat decode parsing failed!";
 229             return;
 230         }
 231         $l = 4 - $l;
 232         $#s += $l;
 233     }
 234     my $r = '';
 235     while ( $#s >= 0 ) {
 236         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 237         $r .=
 238             chr( ( $n >> 16 ) ^ 67 )
 239          .chr( ( $n >> 8 & 255 ) ^ 67 )
 240          .chr( ( $n & 255 ) ^ 67 );
 241         @s = @s[ 4 .. $#s ];
 242     }
 243     $r = substr( $r, 0, length($r) - $l );
 244     return $r;
 245 }
 246
 247 =head2 transferbook
 248
 249   ($dotransfer, $messages, $iteminformation) = &transferbook({
 250                                                    from_branch => $frombranch
 251                                                    to_branch => $tobranch,
 252                                                    barcode => $barcode,
 253                                                    ignore_reserves => $ignore_reserves,
 254                                                    trigger => $trigger
 255                                                 });
 256
 257 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 258
 259 C<$fbr> is the code for the branch initiating the transfer.
 260 C<$tbr> is the code for the branch to which the item should be transferred.
 261
 262 C<$barcode> is the barcode of the item to be transferred.
 263
 264 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 265 Otherwise, if an item is reserved, the transfer fails.
 266
 267 C<$trigger> is the enum value for what triggered the transfer.
 268
 269 Returns three values:
 270
 271 =over
 272
 273 =item $dotransfer
 274
 275 is true if the transfer was successful.
 276
 277 =item $messages
 278
 279 is a reference-to-hash which may have any of the following keys:
 280
 281 =over
 282
 283 =item C<BadBarcode>
 284
 285 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 286
 287 =item C<DestinationEqualsHolding>
 288
 289 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 290
 291 =item C<WasReturned>
 292
 293 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 294
 295 =item C<ResFound>
 296
 297 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 298
 299 =item C<WasTransferred>
 300
 301 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 302
 303 =item C<RecallPlacedAtHoldingBranch>
 304
 305 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 306
 307 =item C<RecallFound>
 308
 309 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 310
 311 =back
 312
 313 =back
 314
 315 =cut
 316
 317 sub transferbook {
 318     my $params = shift;
 319     my $tbr      = $params->{to_branch};
 320     my $fbr      = $params->{from_branch};
 321     my $ignoreRs = $params->{ignore_reserves};
 322     my $barcode  = $params->{barcode};
 323     my $trigger  = $params->{trigger};
 324     my $messages;
 325     my $dotransfer      = 1;
 326     my $item = Koha::Items->find( { barcode => $barcode } );
 327
 328     Koha::Exceptions::MissingParameter->throw(
 329         "Missing mandatory parameter: from_branch")
 330       unless $fbr;
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: to_branch")
 334       unless $tbr;
 335
 336     # bad barcode..
 337     unless ( $item ) {
 338         $messages->{'BadBarcode'} = $barcode;
 339         $dotransfer = 0;
 340         return ( $dotransfer, $messages );
 341     }
 342
 343     my $itemnumber = $item->itemnumber;
 344     # get branches of book...
 345     my $hbr = $item->homebranch;
 346
 347     # if using Branch Transfer Limits
 348     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 349         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 350         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 351             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 352                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 353                 $dotransfer = 0;
 354             }
 355         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 356             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 357             $dotransfer = 0;
 358         }
 359     }
 360
 361     # can't transfer book if is already there....
 362     if ( $fbr eq $tbr ) {
 363         $messages->{'DestinationEqualsHolding'} = 1;
 364         $dotransfer = 0;
 365     }
 366
 367     # check if it is still issued to someone, return it...
 368     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 369     if ( $issue ) {
 370         AddReturn( $barcode, $fbr );
 371         $messages->{'WasReturned'} = $issue->borrowernumber;
 372     }
 373
 374     # find reserves.....
 375     # That'll save a database query.
 376     my ( $resfound, $resrec, undef ) =
 377       CheckReserves( $itemnumber );
 378     if ( $resfound ) {
 379         $resrec->{'ResFound'} = $resfound;
 380         $messages->{'ResFound'} = $resrec;
 381         $dotransfer = 0 unless $ignoreRs;
 382     }
 383
 384     # find recall
 385     if ( C4::Context->preference('UseRecalls') ) {
 386         my $recall = Koha::Recalls->find({ itemnumber => $itemnumber, status => 'in_transit' });
 387         if ( defined $recall ) {
 388             # do a transfer if the recall branch is different to the item holding branch
 389             if ( $recall->branchcode eq $fbr ) {
 390                 $dotransfer = 0;
 391                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 392             } else {
 393                 $dotransfer = 1;
 394                 $messages->{'RecallFound'} = $recall;
 395             }
 396         }
 397     }
 398
 399     #actually do the transfer....
 400     if ($dotransfer) {
 401         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 402
 403         # don't need to update MARC anymore, we do it in batch now
 404         $messages->{'WasTransfered'} = $tbr;
 405
 406     }
 407     ModDateLastSeen( $itemnumber );
 408     return ( $dotransfer, $messages );
 409 }
 410
 411
 412 sub TooMany {
 413     my $borrower        = shift;
 414     my $item_object = shift;
 415     my $params = shift;
 416     my $onsite_checkout = $params->{onsite_checkout} || 0;
 417     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 418     my $cat_borrower    = $borrower->{'categorycode'};
 419     my $dbh             = C4::Context->dbh;
 420     # Get which branchcode we need
 421     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 422     my $type = $item_object->effective_itemtype;
 423
 424     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 425     $type_object = Koha::ItemTypes->find( $type );
 426     $parent_type = $type_object->parent_type if $type_object;
 427     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 428     # Find any children if we are a parent_type;
 429
 430     # given branch, patron category, and item type, determine
 431     # applicable issuing rule
 432
 433     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 434         {
 435             categorycode => $cat_borrower,
 436             itemtype     => $parent_type,
 437             branchcode   => $branch,
 438             rule_name    => 'maxissueqty',
 439         }
 440     ) if $parent_type;
 441     # If the parent rule is for default type we discount it
 442     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 443
 444     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 445         {
 446             categorycode => $cat_borrower,
 447             itemtype     => $type,
 448             branchcode   => $branch,
 449             rule_name    => 'maxissueqty',
 450         }
 451     );
 452
 453     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 454         {
 455             categorycode => $cat_borrower,
 456             itemtype     => $type,
 457             branchcode   => $branch,
 458             rule_name    => 'maxonsiteissueqty',
 459         }
 460     );
 461
 462
 463     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 464     # if a rule is found and has a loan limit set, count
 465     # how many loans the patron already has that meet that
 466     # rule
 467     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 468
 469         my $checkouts;
 470         if ( $maxissueqty_rule->branchcode ) {
 471             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 472                 $checkouts = $patron->checkouts->search(
 473                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 474             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 475                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 476             } else {
 477                 $checkouts = $patron->checkouts->search(
 478                     { 'item.homebranch' => $maxissueqty_rule->branchcode },
 479                     { prefetch          => 'item' } );
 480             }
 481         } else {
 482             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 483         }
 484         my $sum_checkouts;
 485         my $rule_itemtype = $maxissueqty_rule->itemtype;
 486         while ( my $c = $checkouts->next ) {
 487             my $itemtype = $c->item->effective_itemtype;
 488             my @types;
 489             unless ( $rule_itemtype ) {
 490                 # matching rule has the default item type, so count only
 491                 # those existing loans that don't fall under a more
 492                 # specific rule
 493                 @types = Koha::CirculationRules->search(
 494                     {
 495                         branchcode => $maxissueqty_rule->branchcode,
 496                         categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 497                         itemtype  => { '!=' => undef },
 498                         rule_name => 'maxissueqty'
 499                     }
 500                 )->get_column('itemtype');
 501
 502                 next if grep {$_ eq $itemtype} @types;
 503             } else {
 504                 my @types;
 505                 if ( $parent_maxissueqty_rule ) {
 506                 # if we have a parent item type then we count loans of the
 507                 # specific item type or its siblings or parent
 508                     my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 509                     @types = $children->get_column('itemtype');
 510                     push @types, $parent_type;
 511                 } elsif ( $child_types ) {
 512                 # If we are a parent type, we need to count all child types and our own type
 513                     @types = $child_types->get_column('itemtype');
 514                     push @types, $type; # And don't forget to count our own types
 515                 } else { push @types, $type; } # Otherwise only count the specific itemtype
 516
 517                 next unless grep {$_ eq $itemtype} @types;
 518             }
 519             $sum_checkouts->{total}++;
 520             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 521             $sum_checkouts->{itemtype}->{$itemtype}++;
 522         }
 523
 524         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 525         my $checkout_count = $sum_checkouts->{total} || 0;
 526         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 527
 528         my $checkout_rules = {
 529             checkout_count               => $checkout_count,
 530             onsite_checkout_count        => $onsite_checkout_count,
 531             onsite_checkout              => $onsite_checkout,
 532             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 533             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 534             switch_onsite_checkout       => $switch_onsite_checkout,
 535         };
 536         # If parent rules exists
 537         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 538             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 539             my $qty_over = _check_max_qty($checkout_rules);
 540             return $qty_over if defined $qty_over;
 541
 542             # If the parent rule is less than or equal to the child, we only need check the parent
 543             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 544                 $checkout_rules->{checkout_count} = $checkout_count_type;
 545                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 546                 my $qty_over = _check_max_qty($checkout_rules);
 547                 return $qty_over if defined $qty_over;
 548             }
 549         } else {
 550             my $qty_over = _check_max_qty($checkout_rules);
 551             return $qty_over if defined $qty_over;
 552         }
 553     }
 554
 555     # Now count total loans against the limit for the branch
 556     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 557     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 558         my $checkouts;
 559         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 560             $checkouts = $patron->checkouts->search(
 561                 { 'me.branchcode' => $branch} );
 562         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 563             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 564         } else {
 565             $checkouts = $patron->checkouts->search(
 566                 { 'item.homebranch' => $branch},
 567                 { prefetch          => 'item' } );
 568         }
 569
 570         my $checkout_count = $checkouts->count;
 571         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 572         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 573         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 574
 575         my $qty_over = _check_max_qty(
 576             {
 577                 checkout_count               => $checkout_count,
 578                 onsite_checkout_count        => $onsite_checkout_count,
 579                 onsite_checkout              => $onsite_checkout,
 580                 max_checkouts_allowed        => $max_checkouts_allowed,
 581                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 582                 switch_onsite_checkout       => $switch_onsite_checkout
 583             }
 584         );
 585         return $qty_over if defined $qty_over;
 586     }
 587
 588     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 589         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 590     }
 591
 592     # OK, the patron can issue !!!
 593     return;
 594 }
 595
 596 sub _check_max_qty {
 597     my $params                       = shift;
 598     my $checkout_count               = $params->{checkout_count};
 599     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 600     my $onsite_checkout              = $params->{onsite_checkout};
 601     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 602     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 603     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 604
 605     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 606         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 607         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 608             return {
 609                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 610                 count       => $onsite_checkout_count,
 611                 max_allowed => $max_onsite_checkouts_allowed,
 612             };
 613         }
 614     }
 615     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 616         if ( $max_checkouts_allowed eq '' ) { return; }
 617         my $delta = $switch_onsite_checkout ? 1 : 0;
 618         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 619             return {
 620                 reason      => 'TOO_MANY_CHECKOUTS',
 621                 count       => $checkout_count,
 622                 max_allowed => $max_checkouts_allowed,
 623             };
 624         }
 625     }
 626     elsif ( not $onsite_checkout ) {
 627         if ( $max_checkouts_allowed eq '' ) { return; }
 628         if (
 629             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 630         {
 631             return {
 632                 reason      => 'TOO_MANY_CHECKOUTS',
 633                 count       => $checkout_count - $onsite_checkout_count,
 634                 max_allowed => $max_checkouts_allowed,
 635             };
 636         }
 637     }
 638
 639     return;
 640 }
 641
 642 =head2 CanBookBeIssued
 643
 644   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 645                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 646
 647 Check if a book can be issued.
 648
 649 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 650
 651 IMPORTANT: The assumption by users of this routine is that causes blocking
 652 the issue are keyed by uppercase labels and other returned
 653 data is keyed in lower case!
 654
 655 =over 4
 656
 657 =item C<$patron> is a Koha::Patron
 658
 659 =item C<$barcode> is the bar code of the book being issued.
 660
 661 =item C<$duedates> is a DateTime object.
 662
 663 =item C<$inprocess> boolean switch
 664
 665 =item C<$ignore_reserves> boolean switch
 666
 667 =item C<$params> Hashref of additional parameters
 668
 669 Available keys:
 670     override_high_holds - Ignore high holds
 671     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 672
 673 =back
 674
 675 Returns :
 676
 677 =over 4
 678
 679 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 680 Possible values are :
 681
 682 =back
 683
 684 =head3 INVALID_DATE
 685
 686 sticky due date is invalid
 687
 688 =head3 GNA
 689
 690 borrower gone with no address
 691
 692 =head3 CARD_LOST
 693
 694 borrower declared it's card lost
 695
 696 =head3 DEBARRED
 697
 698 borrower debarred
 699
 700 =head3 UNKNOWN_BARCODE
 701
 702 barcode unknown
 703
 704 =head3 NOT_FOR_LOAN
 705
 706 item is not for loan
 707
 708 =head3 WTHDRAWN
 709
 710 item withdrawn.
 711
 712 =head3 RESTRICTED
 713
 714 item is restricted (set by ??)
 715
 716 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 717 could be prevented, but ones that can be overriden by the operator.
 718
 719 Possible values are :
 720
 721 =head3 DEBT
 722
 723 borrower has debts.
 724
 725 =head3 RENEW_ISSUE
 726
 727 renewing, not issuing
 728
 729 =head3 ISSUED_TO_ANOTHER
 730
 731 issued to someone else.
 732
 733 =head3 RESERVED
 734
 735 reserved for someone else.
 736
 737 =head3 TRANSFERRED
 738
 739 reserved and being transferred for someone else.
 740
 741 =head3 INVALID_DATE
 742
 743 sticky due date is invalid or due date in the past
 744
 745 =head3 TOO_MANY
 746
 747 if the borrower borrows to much things
 748
 749 =head3 RECALLED
 750
 751 recalled by someone else
 752
 753 =cut
 754
 755 sub CanBookBeIssued {
 756     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 757     my %needsconfirmation;    # filled with problems that needs confirmations
 758     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 759     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 760     my %messages;             # filled with information messages that should be displayed.
 761
 762     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 763     my $override_high_holds = $params->{override_high_holds} || 0;
 764
 765     my $item_object = Koha::Items->find({barcode => $barcode });
 766
 767     # MANDATORY CHECKS - unless item exists, nothing else matters
 768     unless ( $item_object ) {
 769         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 770     }
 771     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 772
 773     my $item_unblessed = $item_object->unblessed; # Transition...
 774     my $issue = $item_object->checkout;
 775     my $biblio = $item_object->biblio;
 776
 777     my $biblioitem = $biblio->biblioitem;
 778     my $effective_itemtype = $item_object->effective_itemtype;
 779     my $dbh             = C4::Context->dbh;
 780     my $patron_unblessed = $patron->unblessed;
 781
 782     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 783     #
 784     # DUE DATE is OK ? -- should already have checked.
 785     #
 786     if ($duedate && ref $duedate ne 'DateTime') {
 787         $duedate = dt_from_string($duedate);
 788     }
 789     my $now = dt_from_string();
 790     unless ( $duedate ) {
 791         my $issuedate = $now->clone();
 792
 793         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 794
 795         # Offline circ calls AddIssue directly, doesn't run through here
 796         #  So issuingimpossible should be ok.
 797     }
 798
 799     my $fees = Koha::Charges::Fees->new(
 800         {
 801             patron    => $patron,
 802             library   => $circ_library,
 803             item      => $item_object,
 804             to_date   => $duedate,
 805         }
 806     );
 807
 808     if ($duedate) {
 809         my $today = $now->clone();
 810         $today->truncate( to => 'minute');
 811         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 812             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 813         }
 814     } else {
 815             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 816     }
 817
 818     #
 819     # BORROWER STATUS
 820     #
 821     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 822         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 823         C4::Stats::UpdateStats({
 824                      branch => C4::Context->userenv->{'branch'},
 825                      type => 'localuse',
 826                      itemnumber => $item_object->itemnumber,
 827                      itemtype => $effective_itemtype,
 828                      borrowernumber => $patron->borrowernumber,
 829                      ccode => $item_object->ccode}
 830                     );
 831         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 832         return( { STATS => 1 }, {});
 833     }
 834
 835     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 836         $issuingimpossible{GNA} = 1;
 837     }
 838
 839     if ( $patron->lost && $patron->lost == 1 ) {
 840         $issuingimpossible{CARD_LOST} = 1;
 841     }
 842     if ( $patron->is_debarred ) {
 843         $issuingimpossible{DEBARRED} = 1;
 844     }
 845
 846     if ( $patron->is_expired ) {
 847         $issuingimpossible{EXPIRED} = 1;
 848     }
 849
 850     #
 851     # BORROWER STATUS
 852     #
 853
 854     # DEBTS
 855     my $account = $patron->account;
 856     my $balance = $account->balance;
 857     my $non_issues_charges = $account->non_issues_charges;
 858     my $other_charges = $balance - $non_issues_charges;
 859
 860     my $amountlimit = C4::Context->preference("noissuescharge");
 861     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 862     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 863
 864     # Check the debt of this patrons guarantees
 865     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 866     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 867     if ( defined $no_issues_charge_guarantees ) {
 868         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 869         my $guarantees_non_issues_charges = 0;
 870         foreach my $g ( @guarantees ) {
 871             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 872         }
 873
 874         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 875             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 876         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 877             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 878         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 879             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 880         }
 881     }
 882
 883     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 884     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 885     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 886     if ( defined $no_issues_charge_guarantors ) {
 887         my $guarantors_non_issues_charges += $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 888
 889         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 890             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 891         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 892             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 893         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 894             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 895         }
 896     }
 897
 898     if ( C4::Context->preference("IssuingInProcess") ) {
 899         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 900             $issuingimpossible{DEBT} = $non_issues_charges;
 901         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 902             $needsconfirmation{DEBT} = $non_issues_charges;
 903         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 904             $needsconfirmation{DEBT} = $non_issues_charges;
 905         }
 906     }
 907     else {
 908         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 909             $needsconfirmation{DEBT} = $non_issues_charges;
 910         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 911             $issuingimpossible{DEBT} = $non_issues_charges;
 912         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 913             $needsconfirmation{DEBT} = $non_issues_charges;
 914         }
 915     }
 916
 917     if ($balance > 0 && $other_charges > 0) {
 918         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 919     }
 920
 921     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 922     $patron_unblessed = $patron->unblessed;
 923
 924     if ( my $debarred_date = $patron->is_debarred ) {
 925          # patron has accrued fine days or has a restriction. $count is a date
 926         if ($debarred_date eq '9999-12-31') {
 927             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 928         }
 929         else {
 930             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 931         }
 932     } elsif ( my $num_overdues = $patron->has_overdues ) {
 933         ## patron has outstanding overdue loans
 934         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 935             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 936         }
 937         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 938             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 939         }
 940     }
 941
 942     # Additional Materials Check
 943     if ( C4::Context->preference("CircConfirmItemParts")
 944         && $item_object->materials )
 945     {
 946         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 947     }
 948
 949     #
 950     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 951     #
 952     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 953
 954         # Already issued to current borrower.
 955         # If it is an on-site checkout if it can be switched to a normal checkout
 956         # or ask whether the loan should be renewed
 957
 958         if ( $issue->onsite_checkout
 959                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 960             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 961         } else {
 962             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 963                 $patron->borrowernumber,
 964                 $item_object->itemnumber,
 965             );
 966             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 967                 if ( $renewerror eq 'onsite_checkout' ) {
 968                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 969                 }
 970                 else {
 971                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 972                 }
 973             }
 974             else {
 975                 $needsconfirmation{RENEW_ISSUE} = 1;
 976             }
 977         }
 978     }
 979     elsif ( $issue ) {
 980
 981         # issued to someone else
 982
 983         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 984
 985         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 986
 987         unless ( $can_be_returned ) {
 988             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 989             $issuingimpossible{branch_to_return} = $message;
 990         } else {
 991             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 992                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 993             } else {
 994             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 995             $needsconfirmation{issued_firstname} = $patron->firstname;
 996             $needsconfirmation{issued_surname} = $patron->surname;
 997             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 998             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 999             }
1000         }
1001     }
1002
1003     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1004     #
1005     my $switch_onsite_checkout = (
1006           C4::Context->preference('SwitchOnSiteCheckouts')
1007       and $issue
1008       and $issue->onsite_checkout
1009       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1010     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1011     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1012     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1013         if ( $toomany->{max_allowed} == 0 ) {
1014             $needsconfirmation{PATRON_CANT} = 1;
1015         }
1016         if ( C4::Context->preference("AllowTooManyOverride") ) {
1017             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1018             $needsconfirmation{current_loan_count} = $toomany->{count};
1019             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1020         } else {
1021             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1022             $issuingimpossible{current_loan_count} = $toomany->{count};
1023             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1024         }
1025     }
1026
1027     #
1028     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1029     #
1030     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1031     my $wants_check = $patron->wants_check_for_previous_checkout;
1032     $needsconfirmation{PREVISSUE} = 1
1033         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1034
1035     #
1036     # ITEM CHECKING
1037     #
1038     if ( $item_object->notforloan )
1039     {
1040         if(!C4::Context->preference("AllowNotForLoanOverride")){
1041             $issuingimpossible{NOT_FOR_LOAN} = 1;
1042             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1043         }else{
1044             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1045             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1046         }
1047     }
1048     else {
1049         # we have to check itemtypes.notforloan also
1050         if (C4::Context->preference('item-level_itypes')){
1051             # this should probably be a subroutine
1052             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1053             $sth->execute($effective_itemtype);
1054             my $notforloan=$sth->fetchrow_hashref();
1055             if ($notforloan->{'notforloan'}) {
1056                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1057                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1058                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1059                 } else {
1060                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1061                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1062                 }
1063             }
1064         }
1065         else {
1066             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1067             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1068                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1069                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1070                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1071                 } else {
1072                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1073                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1074                 }
1075             }
1076         }
1077     }
1078     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1079     {
1080         $issuingimpossible{WTHDRAWN} = 1;
1081     }
1082     if (   $item_object->restricted
1083         && $item_object->restricted == 1 )
1084     {
1085         $issuingimpossible{RESTRICTED} = 1;
1086     }
1087     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1088         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1089         my $code = $av->count ? $av->next->lib : '';
1090         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1091         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1092     }
1093     if ( C4::Context->preference("IndependentBranches") ) {
1094         my $userenv = C4::Context->userenv;
1095         unless ( C4::Context->IsSuperLibrarian() ) {
1096             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1097             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1098                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1099                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1100             }
1101             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1102               if ( $patron->branchcode ne $userenv->{branch} );
1103         }
1104     }
1105
1106     #
1107     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1108     #
1109     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1110     if ($rentalConfirmation) {
1111         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1112
1113         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1114         if ($itemtype_object) {
1115             my $accumulate_charge = $fees->accumulate_rentalcharge();
1116             if ( $accumulate_charge > 0 ) {
1117                 $rentalCharge += $accumulate_charge;
1118             }
1119         }
1120
1121         if ( $rentalCharge > 0 ) {
1122             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1123         }
1124     }
1125
1126     my $recall;
1127     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1128     # Only bother doing this if UseRecalls is enabled and the item is recallable
1129     # Don't look at recalls that are in transit
1130     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1131         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'recalldate' } })->filter_by_current->as_list;
1132
1133         foreach my $r ( @recalls ) {
1134             if ( $r->itemnumber and
1135                 $r->itemnumber == $item_object->itemnumber and
1136                 $r->borrowernumber == $patron->borrowernumber and
1137                 ( $r->waiting or $r->requested ) ) {
1138                 $messages{RECALLED} = $r->recall_id;
1139                 $recall = $r;
1140                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1141                 last;
1142             }
1143             elsif ( $r->itemnumber and
1144                 $r->itemnumber == $item_object->itemnumber and
1145                 $r->in_transit ) {
1146                 # recalled item is in transit
1147                 $issuingimpossible{RECALLED_INTRANSIT} = $r->branchcode;
1148             }
1149             elsif ( $r->item_level_recall and
1150                 $r->itemnumber == $item_object->itemnumber and
1151                 $r->borrowernumber != $patron->borrowernumber and
1152                 !$r->in_transit ) {
1153                 # this specific item has been recalled by a different patron
1154                 $needsconfirmation{RECALLED} = $r;
1155                 $recall = $r;
1156                 last;
1157             }
1158             elsif ( !$r->item_level_recall and
1159                 $r->borrowernumber != $patron->borrowernumber and
1160                 !$r->in_transit ) {
1161                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1162                 $needsconfirmation{RECALLED} = $r;
1163                 $recall = $r;
1164                 last;
1165             }
1166         }
1167     }
1168
1169     unless ( $ignore_reserves and defined $recall ) {
1170         # See if the item is on reserve.
1171         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1172         if ($restype) {
1173             my $resbor = $res->{'borrowernumber'};
1174             if ( $resbor ne $patron->borrowernumber ) {
1175                 my $patron = Koha::Patrons->find( $resbor );
1176                 if ( $restype eq "Waiting" )
1177                 {
1178                     # The item is on reserve and waiting, but has been
1179                     # reserved by some other patron.
1180                     $needsconfirmation{RESERVE_WAITING} = 1;
1181                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1182                     $needsconfirmation{'ressurname'} = $patron->surname;
1183                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1184                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1185                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1186                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1187                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1188                 }
1189                 elsif ( $restype eq "Reserved" ) {
1190                     # The item is on reserve for someone else.
1191                     $needsconfirmation{RESERVED} = 1;
1192                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1193                     $needsconfirmation{'ressurname'} = $patron->surname;
1194                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1195                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1196                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1197                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1198                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1199                 }
1200                 elsif ( $restype eq "Transferred" ) {
1201                     # The item is determined hold being transferred for someone else.
1202                     $needsconfirmation{TRANSFERRED} = 1;
1203                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1204                     $needsconfirmation{'ressurname'} = $patron->surname;
1205                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1206                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1207                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1208                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1209                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1210                 }
1211                 elsif ( $restype eq "Processing" ) {
1212                     # The item is determined hold being processed for someone else.
1213                     $needsconfirmation{PROCESSING} = 1;
1214                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1215                     $needsconfirmation{'ressurname'} = $patron->surname;
1216                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1217                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1218                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1219                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1220                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1221                 }
1222             }
1223         }
1224     }
1225
1226     ## CHECK AGE RESTRICTION
1227     my $agerestriction  = $biblioitem->agerestriction;
1228     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1229     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1230         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1231             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1232         }
1233         else {
1234             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1235         }
1236     }
1237
1238     ## check for high holds decreasing loan period
1239     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1240         my $check = checkHighHolds( $item_object, $patron );
1241
1242         if ( $check->{exceeded} ) {
1243             if ($override_high_holds) {
1244                 $alerts{HIGHHOLDS} = {
1245                     num_holds  => $check->{outstanding},
1246                     duration   => $check->{duration},
1247                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1248                 };
1249             }
1250             else {
1251                 $needsconfirmation{HIGHHOLDS} = {
1252                     num_holds  => $check->{outstanding},
1253                     duration   => $check->{duration},
1254                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1255                 };
1256             }
1257         }
1258     }
1259
1260     if (
1261         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1262         # don't do the multiple loans per bib check if we've
1263         # already determined that we've got a loan on the same item
1264         !$issuingimpossible{NO_MORE_RENEWALS} &&
1265         !$needsconfirmation{RENEW_ISSUE}
1266     ) {
1267         # Check if borrower has already issued an item from the same biblio
1268         # Only if it's not a subscription
1269         my $biblionumber = $item_object->biblionumber;
1270         require C4::Serials;
1271         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1272         unless ($is_a_subscription) {
1273             # FIXME Should be $patron->checkouts($args);
1274             my $checkouts = Koha::Checkouts->search(
1275                 {
1276                     borrowernumber => $patron->borrowernumber,
1277                     biblionumber   => $biblionumber,
1278                 },
1279                 {
1280                     join => 'item',
1281                 }
1282             );
1283             # if we get here, we don't already have a loan on this item,
1284             # so if there are any loans on this bib, ask for confirmation
1285             if ( $checkouts->count ) {
1286                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1287             }
1288         }
1289     }
1290
1291     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1292 }
1293
1294 =head2 CanBookBeReturned
1295
1296   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1297
1298 Check whether the item can be returned to the provided branch
1299
1300 =over 4
1301
1302 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1303
1304 =item C<$branch> is the branchcode where the return is taking place
1305
1306 =back
1307
1308 Returns:
1309
1310 =over 4
1311
1312 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1313
1314 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1315
1316 =back
1317
1318 =cut
1319
1320 sub CanBookBeReturned {
1321   my ($item, $branch) = @_;
1322   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1323
1324   # assume return is allowed to start
1325   my $allowed = 1;
1326   my $message;
1327
1328   # identify all cases where return is forbidden
1329   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1330      $allowed = 0;
1331      $message = $item->{'homebranch'};
1332   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1333      $allowed = 0;
1334      $message = $item->{'holdingbranch'};
1335   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1336      $allowed = 0;
1337      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1338   }
1339
1340   return ($allowed, $message);
1341 }
1342
1343 =head2 CheckHighHolds
1344
1345     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1346     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1347     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1348
1349 =cut
1350
1351 sub checkHighHolds {
1352     my ( $item, $patron ) = @_;
1353     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1354
1355     my $return_data = {
1356         exceeded    => 0,
1357         outstanding => 0,
1358         duration    => 0,
1359         due_date    => undef,
1360     };
1361
1362     my $holds = Koha::Holds->search( { biblionumber => $item->biblionumber } );
1363
1364     if ( $holds->count() ) {
1365         $return_data->{outstanding} = $holds->count();
1366
1367         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1368         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1369         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1370
1371         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1372
1373         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1374
1375             # static means just more than a given number of holds on the record
1376
1377             # If the number of holds is less than the threshold, we can stop here
1378             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1379                 return $return_data;
1380             }
1381         }
1382         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1383
1384             # dynamic means X more than the number of holdable items on the record
1385
1386             # let's get the items
1387             my @items = $holds->next()->biblio()->items()->as_list;
1388
1389             # Remove any items with status defined to be ignored even if the would not make item unholdable
1390             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1391                 @items = grep { !$_->$status } @items;
1392             }
1393
1394             # Remove any items that are not holdable for this patron
1395             @items = grep { CanItemBeReserved( $patron , $_, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1396
1397             my $items_count = scalar @items;
1398
1399             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1400
1401             # If the number of holds is less than the count of items we have
1402             # plus the number of holds allowed above that count, we can stop here
1403             if ( $holds->count() <= $threshold ) {
1404                 return $return_data;
1405             }
1406         }
1407
1408         my $issuedate = dt_from_string();
1409
1410         my $itype = $item->effective_itemtype;
1411         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1412             {
1413                 categorycode => $patron->categorycode,
1414                 itemtype     => $itype,
1415                 branchcode   => $branchcode,
1416             }
1417         );
1418         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1419
1420         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1421
1422         my $rule = Koha::CirculationRules->get_effective_rule(
1423             {
1424                 categorycode => $patron->categorycode,
1425                 itemtype     => $item->effective_itemtype,
1426                 branchcode   => $branchcode,
1427                 rule_name    => 'decreaseloanholds',
1428             }
1429         );
1430
1431         my $duration;
1432         if ( defined($rule) && $rule->rule_value ne '' ){
1433             # overrides decreaseLoanHighHoldsDuration syspref
1434             $duration = $rule->rule_value;
1435         } else {
1436             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1437         }
1438         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1439         $reduced_datedue->set_hour($orig_due->hour);
1440         $reduced_datedue->set_minute($orig_due->minute);
1441         $reduced_datedue->truncate( to => 'minute' );
1442
1443         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1444             $return_data->{exceeded} = 1;
1445             $return_data->{duration} = $duration;
1446             $return_data->{due_date} = $reduced_datedue;
1447         }
1448     }
1449
1450     return $return_data;
1451 }
1452
1453 =head2 AddIssue
1454
1455   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1456
1457 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1458
1459 =over 4
1460
1461 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1462
1463 =item C<$barcode> is the barcode of the item being issued.
1464
1465 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1466 Calculated if empty.
1467
1468 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1469
1470 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1471 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1472
1473 AddIssue does the following things :
1474
1475   - step 01: check that there is a borrowernumber & a barcode provided
1476   - check for RENEWAL (book issued & being issued to the same patron)
1477       - renewal YES = Calculate Charge & renew
1478       - renewal NO  =
1479           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1480           * RESERVE PLACED ?
1481               - fill reserve if reserve to this patron
1482               - cancel reserve or not, otherwise
1483           * RECALL PLACED ?
1484               - fill recall if recall to this patron
1485               - cancel recall or not
1486               - revert recall's waiting status or not
1487           * TRANSFERT PENDING ?
1488               - complete the transfert
1489           * ISSUE THE BOOK
1490
1491 =back
1492
1493 =cut
1494
1495 sub AddIssue {
1496     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1497
1498     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1499     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1500     my $auto_renew = $params && $params->{auto_renew};
1501     my $cancel_recall = $params && $params->{cancel_recall};
1502     my $recall_id = $params && $params->{recall_id};
1503     my $dbh          = C4::Context->dbh;
1504     my $barcodecheck = CheckValidBarcode($barcode);
1505
1506     my $issue;
1507
1508     if ( $datedue && ref $datedue ne 'DateTime' ) {
1509         $datedue = dt_from_string($datedue);
1510     }
1511
1512     # $issuedate defaults to today.
1513     if ( !defined $issuedate ) {
1514         $issuedate = dt_from_string();
1515     }
1516     else {
1517         if ( ref $issuedate ne 'DateTime' ) {
1518             $issuedate = dt_from_string($issuedate);
1519
1520         }
1521     }
1522
1523     # Stop here if the patron or barcode doesn't exist
1524     if ( $borrower && $barcode && $barcodecheck ) {
1525         # find which item we issue
1526         my $item_object = Koha::Items->find({ barcode => $barcode })
1527           or return;    # if we don't get an Item, abort.
1528         my $item_unblessed = $item_object->unblessed;
1529
1530         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1531
1532         # get actual issuing if there is one
1533         my $actualissue = $item_object->checkout;
1534
1535         # check if we just renew the issue.
1536         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1537                 and not $switch_onsite_checkout ) {
1538             $datedue = AddRenewal(
1539                 $borrower->{'borrowernumber'},
1540                 $item_object->itemnumber,
1541                 $branchcode,
1542                 $datedue,
1543                 $issuedate,    # here interpreted as the renewal date
1544             );
1545         }
1546         else {
1547             unless ($datedue) {
1548                 my $itype = $item_object->effective_itemtype;
1549                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1550
1551             }
1552             $datedue->truncate( to => 'minute' );
1553
1554             my $patron = Koha::Patrons->find( $borrower );
1555             my $library = Koha::Libraries->find( $branchcode );
1556             my $fees = Koha::Charges::Fees->new(
1557                 {
1558                     patron    => $patron,
1559                     library   => $library,
1560                     item      => $item_object,
1561                     to_date   => $datedue,
1562                 }
1563             );
1564
1565             # it's NOT a renewal
1566             if ( $actualissue and not $switch_onsite_checkout ) {
1567                 # This book is currently on loan, but not to the person
1568                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1569                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1570                 return unless $allowed;
1571                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1572                 # AddReturn certainly has side-effects, like onloan => undef
1573                 $item_object->discard_changes;
1574             }
1575
1576             if ( C4::Context->preference('UseRecalls') ) {
1577                 Koha::Recalls->move_recall(
1578                     {
1579                         action         => $cancel_recall,
1580                         recall_id      => $recall_id,
1581                         item           => $item_object,
1582                         borrowernumber => $borrower->{borrowernumber},
1583                     }
1584                 );
1585             }
1586
1587             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1588
1589             # Starting process for transfer job (checking transfert and validate it if we have one)
1590             if ( my $transfer = $item_object->get_transfer ) {
1591                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1592                 $transfer->set(
1593                     {
1594                         datearrived => dt_from_string,
1595                         tobranch    => C4::Context->userenv->{branch},
1596                         comments    => 'Forced branchtransfer'
1597                     }
1598                 )->store;
1599                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1600                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1601                     if ( $hold ) { # Is this really needed?
1602                         $hold->set( { found => undef } )->store;
1603                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1604                     }
1605                 }
1606             }
1607
1608             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1609             unless ($auto_renew) {
1610                 my $rule = Koha::CirculationRules->get_effective_rule(
1611                     {
1612                         categorycode => $borrower->{categorycode},
1613                         itemtype     => $item_object->effective_itemtype,
1614                         branchcode   => $branchcode,
1615                         rule_name    => 'auto_renew'
1616                     }
1617                 );
1618
1619                 $auto_renew = $rule->rule_value if $rule;
1620             }
1621
1622             my $issue_attributes = {
1623                 borrowernumber  => $borrower->{'borrowernumber'},
1624                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1625                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1626                 branchcode      => C4::Context->userenv->{'branch'},
1627                 onsite_checkout => $onsite_checkout,
1628                 auto_renew      => $auto_renew ? 1 : 0,
1629             };
1630
1631             # Get ID of logged in user.  if called from a batch job,
1632             # no user session exists and C4::Context->userenv() returns
1633             # the scalar '0'. Only do this if the syspref says so
1634             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1635                 my $userenv = C4::Context->userenv();
1636                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1637                 if ($usernumber) {
1638                     $issue_attributes->{issuer_id} = $usernumber;
1639                 }
1640             }
1641
1642             # In the case that the borrower has an on-site checkout
1643             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1644             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1645             if ($issue) {
1646                 $issue->set($issue_attributes)->store;
1647             }
1648             else {
1649                 $issue = Koha::Checkout->new(
1650                     {
1651                         itemnumber => $item_object->itemnumber,
1652                         %$issue_attributes,
1653                     }
1654                 )->store;
1655             }
1656             $issue->discard_changes;
1657             C4::Auth::track_login_daily( $borrower->{userid} );
1658             if ( $item_object->location && $item_object->location eq 'CART'
1659                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1660             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1661                 CartToShelf( $item_object->itemnumber );
1662             }
1663
1664             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1665                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1666             }
1667
1668             # Record if item was lost
1669             my $was_lost = $item_object->itemlost;
1670
1671             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1672             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1673             $item_object->itemlost(0);
1674             $item_object->onloan($datedue->ymd());
1675             $item_object->datelastborrowed( dt_from_string()->ymd() );
1676             $item_object->datelastseen( dt_from_string()->ymd() );
1677             $item_object->store({log_action => 0});
1678
1679             # If the item was lost, it has now been found, charge the overdue if necessary
1680             if ($was_lost) {
1681                 if ( $item_object->{_charge} ) {
1682                     $actualissue //= Koha::Old::Checkouts->search(
1683                         { itemnumber => $item_unblessed->{itemnumber} },
1684                         {
1685                             order_by => { '-desc' => 'returndate' },
1686                             rows     => 1
1687                         }
1688                     )->single;
1689                     unless ( exists( $borrower->{branchcode} ) ) {
1690                         my $patron = $actualissue->patron;
1691                         $borrower = $patron->unblessed;
1692                     }
1693                     _CalculateAndUpdateFine(
1694                         {
1695                             issue       => $actualissue,
1696                             item        => $item_unblessed,
1697                             borrower    => $borrower,
1698                             return_date => $issuedate
1699                         }
1700                     );
1701                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1702                         $item_object->itemnumber, undef, 'RENEWED' );
1703                 }
1704             }
1705
1706             # If it costs to borrow this book, charge it to the patron's account.
1707             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1708             if ( $charge && $charge > 0 ) {
1709                 AddIssuingCharge( $issue, $charge, 'RENT' );
1710             }
1711
1712             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1713             if ( $itemtype_object ) {
1714                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1715                 if ( $accumulate_charge > 0 ) {
1716                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1717                     $charge += $accumulate_charge;
1718                     $item_unblessed->{charge} = $charge;
1719                 }
1720             }
1721
1722             # Record the fact that this book was issued.
1723             C4::Stats::UpdateStats(
1724                 {
1725                     branch => C4::Context->userenv->{'branch'},
1726                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1727                     amount         => $charge,
1728                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1729                     itemnumber     => $item_object->itemnumber,
1730                     itemtype       => $item_object->effective_itemtype,
1731                     location       => $item_object->location,
1732                     borrowernumber => $borrower->{'borrowernumber'},
1733                     ccode          => $item_object->ccode,
1734                 }
1735             );
1736
1737             # Send a checkout slip.
1738             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1739             my %conditions        = (
1740                 branchcode   => $branchcode,
1741                 categorycode => $borrower->{categorycode},
1742                 item_type    => $item_object->effective_itemtype,
1743                 notification => 'CHECKOUT',
1744             );
1745             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1746                 SendCirculationAlert(
1747                     {
1748                         type     => 'CHECKOUT',
1749                         item     => $item_object->unblessed,
1750                         borrower => $borrower,
1751                         branch   => $branchcode,
1752                     }
1753                 );
1754             }
1755             logaction(
1756                 "CIRCULATION", "ISSUE",
1757                 $borrower->{'borrowernumber'},
1758                 $item_object->itemnumber,
1759             ) if C4::Context->preference("IssueLog");
1760
1761             Koha::Plugins->call('after_circ_action', {
1762                 action  => 'checkout',
1763                 payload => {
1764                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1765                     checkout => $issue->get_from_storage
1766                 }
1767             });
1768         }
1769     }
1770     return $issue;
1771 }
1772
1773 =head2 GetLoanLength
1774
1775   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1776
1777 Get loan length for an itemtype, a borrower type and a branch
1778
1779 =cut
1780
1781 sub GetLoanLength {
1782     my ( $categorycode, $itemtype, $branchcode ) = @_;
1783
1784     # Initialize default values
1785     my $rules = {
1786         issuelength   => 0,
1787         renewalperiod => 0,
1788         lengthunit    => 'days',
1789     };
1790
1791     my $found = Koha::CirculationRules->get_effective_rules( {
1792         branchcode => $branchcode,
1793         categorycode => $categorycode,
1794         itemtype => $itemtype,
1795         rules => [
1796             'issuelength',
1797             'renewalperiod',
1798             'lengthunit'
1799         ],
1800     } );
1801
1802     # Search for rules!
1803     foreach my $rule_name (keys %$found) {
1804         $rules->{$rule_name} = $found->{$rule_name};
1805     }
1806
1807     return $rules;
1808 }
1809
1810
1811 =head2 GetHardDueDate
1812
1813   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1814
1815 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1816
1817 =cut
1818
1819 sub GetHardDueDate {
1820     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1821
1822     my $rules = Koha::CirculationRules->get_effective_rules(
1823         {
1824             categorycode => $borrowertype,
1825             itemtype     => $itemtype,
1826             branchcode   => $branchcode,
1827             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1828         }
1829     );
1830
1831     if ( defined( $rules->{hardduedate} ) ) {
1832         if ( $rules->{hardduedate} ) {
1833             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1834         }
1835         else {
1836             return ( undef, undef );
1837         }
1838     }
1839 }
1840
1841 =head2 GetBranchBorrowerCircRule
1842
1843   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1844
1845 Retrieves circulation rule attributes that apply to the given
1846 branch and patron category, regardless of item type.
1847 The return value is a hashref containing the following key:
1848
1849 patron_maxissueqty - maximum number of loans that a
1850 patron of the given category can have at the given
1851 branch.  If the value is undef, no limit.
1852
1853 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1854 patron of the given category can have at the given
1855 branch.  If the value is undef, no limit.
1856
1857 This will check for different branch/category combinations in the following order:
1858 branch and category
1859 branch only
1860 category only
1861 default branch and category
1862
1863 If no rule has been found in the database, it will default to
1864 the buillt in rule:
1865
1866 patron_maxissueqty - undef
1867 patron_maxonsiteissueqty - undef
1868
1869 C<$branchcode> and C<$categorycode> should contain the
1870 literal branch code and patron category code, respectively - no
1871 wildcards.
1872
1873 =cut
1874
1875 sub GetBranchBorrowerCircRule {
1876     my ( $branchcode, $categorycode ) = @_;
1877
1878     # Initialize default values
1879     my $rules = {
1880         patron_maxissueqty       => undef,
1881         patron_maxonsiteissueqty => undef,
1882     };
1883
1884     # Search for rules!
1885     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1886         my $rule = Koha::CirculationRules->get_effective_rule(
1887             {
1888                 categorycode => $categorycode,
1889                 itemtype     => undef,
1890                 branchcode   => $branchcode,
1891                 rule_name    => $rule_name,
1892             }
1893         );
1894
1895         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1896     }
1897
1898     return $rules;
1899 }
1900
1901 =head2 GetBranchItemRule
1902
1903   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1904
1905 Retrieves circulation rule attributes that apply to the given
1906 branch and item type, regardless of patron category.
1907
1908 The return value is a hashref containing the following keys:
1909
1910 holdallowed => Hold policy for this branch and itemtype. Possible values:
1911   not_allowed:           No holds allowed.
1912   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1913   from_any_library:      Holds allowed from any patron.
1914   from_local_hold_group: Holds allowed from libraries in hold group
1915
1916 returnbranch => branch to which to return item.  Possible values:
1917   noreturn: do not return, let item remain where checked in (floating collections)
1918   homebranch: return to item's home branch
1919   holdingbranch: return to issuer branch
1920
1921 This searches branchitemrules in the following order:
1922
1923   * Same branchcode and itemtype
1924   * Same branchcode, itemtype '*'
1925   * branchcode '*', same itemtype
1926   * branchcode and itemtype '*'
1927
1928 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1929
1930 =cut
1931
1932 sub GetBranchItemRule {
1933     my ( $branchcode, $itemtype ) = @_;
1934
1935     # Search for rules!
1936     my $rules = Koha::CirculationRules->get_effective_rules({
1937         branchcode => $branchcode,
1938         itemtype => $itemtype,
1939         rules => ['holdallowed', 'hold_fulfillment_policy', 'returnbranch']
1940     });
1941
1942     # built-in default circulation rule
1943     $rules->{holdallowed} //= 'from_any_library';
1944     $rules->{hold_fulfillment_policy} //= 'any';
1945     $rules->{returnbranch} //= 'homebranch';
1946
1947     return $rules;
1948 }
1949
1950 =head2 AddReturn
1951
1952   ($doreturn, $messages, $iteminformation, $borrower) =
1953       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1954
1955 Returns a book.
1956
1957 =over 4
1958
1959 =item C<$barcode> is the bar code of the book being returned.
1960
1961 =item C<$branch> is the code of the branch where the book is being returned.
1962
1963 =item C<$exemptfine> indicates that overdue charges for the item will be
1964 removed. Optional.
1965
1966 =item C<$return_date> allows the default return date to be overridden
1967 by the given return date. Optional.
1968
1969 =back
1970
1971 C<&AddReturn> returns a list of four items:
1972
1973 C<$doreturn> is true iff the return succeeded.
1974
1975 C<$messages> is a reference-to-hash giving feedback on the operation.
1976 The keys of the hash are:
1977
1978 =over 4
1979
1980 =item C<BadBarcode>
1981
1982 No item with this barcode exists. The value is C<$barcode>.
1983
1984 =item C<NotIssued>
1985
1986 The book is not currently on loan. The value is C<$barcode>.
1987
1988 =item C<withdrawn>
1989
1990 This book has been withdrawn/cancelled. The value should be ignored.
1991
1992 =item C<Wrongbranch>
1993
1994 This book has was returned to the wrong branch.  The value is a hashref
1995 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1996 contain the branchcode of the incorrect and correct return library, respectively.
1997
1998 =item C<ResFound>
1999
2000 The item was reserved. The value is a reference-to-hash whose keys are
2001 fields from the reserves table of the Koha database, and
2002 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2003 either C<Waiting>, C<Reserved>, or 0.
2004
2005 =item C<WasReturned>
2006
2007 Value 1 if return is successful.
2008
2009 =item C<NeedsTransfer>
2010
2011 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2012
2013 =item C<RecallFound>
2014
2015 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2016 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2017 branchcode.
2018
2019 =item C<TransferredRecall>
2020
2021 This item has been transferred to this branch to fill a recall. The recall object is returned.
2022
2023 =back
2024
2025 C<$iteminformation> is a reference-to-hash, giving information about the
2026 returned item from the issues table.
2027
2028 C<$borrower> is a reference-to-hash, giving information about the
2029 patron who last borrowed the book.
2030
2031 =cut
2032
2033 sub AddReturn {
2034     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2035
2036     if ($branch and not Koha::Libraries->find($branch)) {
2037         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2038         undef $branch;
2039     }
2040     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2041     my $return_date_specified = !!$return_date;
2042     $return_date //= dt_from_string();
2043     my $messages;
2044     my $patron;
2045     my $doreturn       = 1;
2046     my $validTransfer = 1;
2047     my $stat_type = 'return';
2048
2049     # get information on item
2050     my $item = Koha::Items->find({ barcode => $barcode });
2051     unless ($item) {
2052         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2053     }
2054
2055     my $itemnumber = $item->itemnumber;
2056     my $itemtype = $item->effective_itemtype;
2057
2058     my $issue  = $item->checkout;
2059     if ( $issue ) {
2060         $patron = $issue->patron
2061             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2062                 . Dumper($issue->unblessed) . "\n";
2063     } else {
2064         $messages->{'NotIssued'} = $barcode;
2065         $item->onloan(undef)->store({skip_record_index=>1}) if defined $item->onloan;
2066
2067         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2068         $doreturn = 0;
2069         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2070         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2071         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2072            $messages->{'LocalUse'} = 1;
2073            $stat_type = 'localuse';
2074         }
2075     }
2076
2077         # full item data, but no borrowernumber or checkout info (no issue)
2078     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2079         # get the proper branch to which to return the item
2080     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2081         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2082     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2083
2084     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2085     my $patron_unblessed = $patron ? $patron->unblessed : {};
2086
2087     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2088     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2089     if ($update_loc_rules) {
2090         if (defined $update_loc_rules->{_ALL_}) {
2091             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2092             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2093             if (
2094                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2095                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2096                ) {
2097                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2098                 $item->location($update_loc_rules->{_ALL_})->store({skip_record_index=>1});
2099             }
2100         }
2101         else {
2102             foreach my $key ( keys %$update_loc_rules ) {
2103                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2104                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2105                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2106                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2107                     $item->location($update_loc_rules->{$key})->store({skip_record_index=>1});
2108                     last;
2109                 }
2110             }
2111         }
2112     }
2113
2114     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2115     if ($yaml) {
2116         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2117         my $rules;
2118         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2119         if ($@) {
2120             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2121         }
2122         else {
2123             foreach my $key ( keys %$rules ) {
2124                 if ( $item->notforloan eq $key ) {
2125                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2126                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
2127                     last;
2128                 }
2129             }
2130         }
2131     }
2132
2133     # check if the return is allowed at this branch
2134     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2135     unless ($returnallowed){
2136         $messages->{'Wrongbranch'} = {
2137             Wrongbranch => $branch,
2138             Rightbranch => $message
2139         };
2140         $doreturn = 0;
2141         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2142         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2143         return ( $doreturn, $messages, $issue, $patron_unblessed);
2144     }
2145
2146     if ( $item->withdrawn ) { # book has been cancelled
2147         $messages->{'withdrawn'} = 1;
2148         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2149     }
2150
2151     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2152         $doreturn = 0;
2153     }
2154
2155     # case of a return of document (deal with issues and holdingbranch)
2156     if ($doreturn) {
2157         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2158         $patron or warn "AddReturn without current borrower";
2159
2160         if ($patron) {
2161             eval {
2162                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1} );
2163             };
2164             unless ( $@ ) {
2165                 if (
2166                     (
2167                         C4::Context->preference('CalculateFinesOnReturn')
2168                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2169                     )
2170                     && !$item->itemlost
2171                   )
2172                 {
2173                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2174                 }
2175             } else {
2176                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2177
2178                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2179                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2180
2181                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2182             }
2183
2184             # FIXME is the "= 1" right?  This could be the borrower hash.
2185             $messages->{'WasReturned'} = 1;
2186
2187         } else {
2188             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1 });
2189         }
2190     }
2191
2192     # the holdingbranch is updated if the document is returned to another location.
2193     # this is always done regardless of whether the item was on loan or not
2194     if ($item->holdingbranch ne $branch) {
2195         $item->holdingbranch($branch)->store({ skip_record_index => 1 });
2196     }
2197
2198     my $item_was_lost = $item->itemlost;
2199     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2200     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1 } ); # will unset itemlost if needed
2201
2202     # fix up the accounts.....
2203     if ($item_was_lost) {
2204         $messages->{'WasLost'} = 1;
2205         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2206             my @object_messages = @{ $updated_item->object_messages };
2207             for my $message (@object_messages) {
2208                 $messages->{'LostItemFeeRefunded'} = 1
2209                   if $message->message eq 'lost_refunded';
2210                 $messages->{'LostItemFeeRestored'} = 1
2211                   if $message->message eq 'lost_restored';
2212
2213                 if ( $message->message eq 'lost_charge' ) {
2214                     $issue //= Koha::Old::Checkouts->search(
2215                         { itemnumber => $item->itemnumber },
2216                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2217                     )->single;
2218                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2219                         my $patron = $issue->patron;
2220                         $patron_unblessed = $patron->unblessed;
2221                     }
2222                     _CalculateAndUpdateFine(
2223                         {
2224                             issue       => $issue,
2225                             item        => $item->unblessed,
2226                             borrower    => $patron_unblessed,
2227                             return_date => $return_date
2228                         }
2229                     );
2230                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2231                         $item->itemnumber, undef, 'RETURNED' );
2232                     $messages->{'LostItemFeeCharged'} = 1;
2233                 }
2234             }
2235         }
2236     }
2237
2238     # check if we have a transfer for this document
2239     my $transfer = $item->get_transfer;
2240
2241     # if we have a transfer to complete, we update the line of transfers with the datearrived
2242     if ($transfer) {
2243         $validTransfer = 0;
2244         if ( $transfer->in_transit ) {
2245             if ( $transfer->tobranch eq $branch ) {
2246                 $transfer->receive;
2247                 $messages->{'TransferArrived'} = $transfer->frombranch;
2248                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2249                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2250             }
2251             else {
2252                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2253                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2254                 $messages->{'TransferTrigger'}   = $transfer->reason;
2255             }
2256         }
2257         else {
2258             if ( $transfer->tobranch eq $branch ) {
2259                 $transfer->receive;
2260                 $messages->{'TransferArrived'} = $transfer->frombranch;
2261                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2262                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2263             }
2264             else {
2265                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2266                 $messages->{'TransferTrigger'} = $transfer->reason;
2267             }
2268         }
2269     }
2270
2271     # fix up the overdues in accounts...
2272     if ($borrowernumber) {
2273         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2274         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2275
2276         if ( $issue and $issue->is_overdue($return_date) ) {
2277         # fix fine days
2278             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2279             if ($reminder){
2280                 $messages->{'PrevDebarred'} = $debardate;
2281             } else {
2282                 $messages->{'Debarred'} = $debardate if $debardate;
2283             }
2284         # there's no overdue on the item but borrower had been previously debarred
2285         } elsif ( $issue->date_due and $patron->debarred ) {
2286              if ( $patron->debarred eq "9999-12-31") {
2287                 $messages->{'ForeverDebarred'} = $patron->debarred;
2288              } else {
2289                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2290                   $borrower_debar_dt->truncate(to => 'day');
2291                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2292                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2293                       $messages->{'PrevDebarred'} = $patron->debarred;
2294                   }
2295              }
2296         }
2297     }
2298
2299     # find recalls...
2300     if ( C4::Context->preference('UseRecalls') ) {
2301         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2302         my $recall = undef;
2303         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2304         if ( defined $recall ) {
2305             $messages->{RecallFound} = $recall;
2306             if ( $recall->branchcode ne $branch ) {
2307                 $messages->{RecallNeedsTransfer} = $branch;
2308             }
2309         }
2310     }
2311
2312     # find reserves.....
2313     # launch the Checkreserves routine to find any holds
2314     my ($resfound, $resrec);
2315     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2316     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2317     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2318     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2319         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2320         $resfound = 'Reserved';
2321         $resrec = $hold->unblessed;
2322     }
2323     if ($resfound) {
2324           $resrec->{'ResFound'} = $resfound;
2325         $messages->{'ResFound'} = $resrec;
2326     }
2327
2328     # Record the fact that this book was returned.
2329     C4::Stats::UpdateStats({
2330         branch         => $branch,
2331         type           => $stat_type,
2332         itemnumber     => $itemnumber,
2333         itemtype       => $itemtype,
2334         location       => $item->location,
2335         borrowernumber => $borrowernumber,
2336         ccode          => $item->ccode,
2337     });
2338
2339     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2340     if ( $patron ) {
2341         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2342         my %conditions = (
2343             branchcode   => $branch,
2344             categorycode => $patron->categorycode,
2345             item_type    => $itemtype,
2346             notification => 'CHECKIN',
2347         );
2348         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2349             SendCirculationAlert({
2350                 type     => 'CHECKIN',
2351                 item     => $item->unblessed,
2352                 borrower => $patron->unblessed,
2353                 branch   => $branch,
2354                 issue    => $issue
2355             });
2356         }
2357
2358         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2359             if C4::Context->preference("ReturnLog");
2360         }
2361
2362     # Check if this item belongs to a biblio record that is attached to an
2363     # ILL request, if it is we need to update the ILL request's status
2364     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2365         my $request = Koha::Illrequests->find(
2366             { biblio_id => $item->biblio->biblionumber }
2367         );
2368         $request->status('RET') if $request;
2369     }
2370
2371     if ( C4::Context->preference('UseRecalls') ) {
2372         # all recalls that have triggered a transfer will have an allocated itemnumber
2373         my $transfer_recall = Koha::Recalls->find({ itemnumber => $item->itemnumber, status => 'in_transit' });
2374         if ( $transfer_recall and $transfer_recall->branchcode eq $branch ) {
2375             $messages->{TransferredRecall} = $transfer_recall;
2376         }
2377     }
2378
2379     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2380     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2381         && ( $doreturn or $messages->{'NotIssued'} )
2382         and !$resfound
2383         and ( $branch ne $returnbranch )
2384         and not $messages->{'WrongTransfer'}
2385         and not $messages->{'WasTransfered'}
2386         and not $messages->{TransferredRecall}
2387         and not $messages->{RecallNeedsTransfer} )
2388     {
2389         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2390         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2391             (C4::Context->preference("UseBranchTransferLimits") and
2392              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2393            )) {
2394             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2395             $messages->{'WasTransfered'} = $returnbranch;
2396             $messages->{'TransferTrigger'} = $transfer_trigger;
2397         } else {
2398             $messages->{'NeedsTransfer'} = $returnbranch;
2399             $messages->{'TransferTrigger'} = $transfer_trigger;
2400         }
2401     }
2402
2403     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2404         my $claims = Koha::Checkouts::ReturnClaims->search(
2405            {
2406                itemnumber => $item->id,
2407                resolution => undef,
2408            }
2409         );
2410
2411         if ( $claims->count ) {
2412             $messages->{ReturnClaims} = $claims;
2413         }
2414     }
2415
2416     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2417     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2418
2419     if ( $doreturn and $issue ) {
2420         my $checkin = Koha::Old::Checkouts->find($issue->id);
2421
2422         Koha::Plugins->call('after_circ_action', {
2423             action  => 'checkin',
2424             payload => {
2425                 checkout=> $checkin
2426             }
2427         });
2428     }
2429
2430     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2431 }
2432
2433 =head2 MarkIssueReturned
2434
2435   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2436
2437 Unconditionally marks an issue as being returned by
2438 moving the C<issues> row to C<old_issues> and
2439 setting C<returndate> to the current date.
2440
2441 if C<$returndate> is specified (in iso format), it is used as the date
2442 of the return.
2443
2444 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2445 the old_issue is immediately anonymised
2446
2447 Ideally, this function would be internal to C<C4::Circulation>,
2448 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2449 and offline_circ/process_koc.pl.
2450
2451 The last optional parameter allos passing skip_record_index to the item store call.
2452
2453 =cut
2454
2455 sub MarkIssueReturned {
2456     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2457
2458     # Retrieve the issue
2459     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2460
2461     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2462
2463     my $issue_id = $issue->issue_id;
2464
2465     my $schema = Koha::Database->schema;
2466
2467     # FIXME Improve the return value and handle it from callers
2468     $schema->txn_do(sub {
2469
2470         my $patron = Koha::Patrons->find( $borrowernumber );
2471
2472         # Update the returndate value
2473         if ( $returndate ) {
2474             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2475         }
2476         else {
2477             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2478         }
2479
2480         # Create the old_issues entry
2481         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2482
2483         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2484         if ( $privacy && $privacy == 2) {
2485             $old_checkout->anonymize;
2486         }
2487
2488         # And finally delete the issue
2489         $issue->delete;
2490
2491         $issue->item->onloan(undef)->store({ log_action => 0, skip_record_index => $params->{skip_record_index} });
2492
2493         if ( C4::Context->preference('StoreLastBorrower') ) {
2494             my $item = Koha::Items->find( $itemnumber );
2495             $item->last_returned_by( $patron );
2496         }
2497
2498         # Remove any OVERDUES related debarment if the borrower has no overdues
2499         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2500           && $patron->debarred
2501           && !$patron->has_overdues
2502           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2503         ) {
2504             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2505         }
2506
2507     });
2508
2509     return $issue_id;
2510 }
2511
2512 =head2 _debar_user_on_return
2513
2514     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2515
2516 C<$borrower> borrower hashref
2517
2518 C<$item> item hashref
2519
2520 C<$datedue> date due DateTime object
2521
2522 C<$returndate> DateTime object representing the return time
2523
2524 Internal function, called only by AddReturn that calculates and updates
2525  the user fine days, and debars them if necessary.
2526
2527 Should only be called for overdue returns
2528
2529 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2530 to ease testing.
2531
2532 =cut
2533
2534 sub _calculate_new_debar_dt {
2535     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2536
2537     my $branchcode = _GetCircControlBranch( $item, $borrower );
2538     my $circcontrol = C4::Context->preference('CircControl');
2539     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2540         {   categorycode => $borrower->{categorycode},
2541             itemtype     => $item->{itype},
2542             branchcode   => $branchcode,
2543             rules => [
2544                 'finedays',
2545                 'lengthunit',
2546                 'firstremind',
2547                 'maxsuspensiondays',
2548                 'suspension_chargeperiod',
2549             ]
2550         }
2551     );
2552     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2553     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2554     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2555
2556     return unless $finedays;
2557
2558     # finedays is in days, so hourly loans must multiply by 24
2559     # thus 1 hour late equals 1 day suspension * finedays rate
2560     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2561
2562     # grace period is measured in the same units as the loan
2563     my $grace =
2564       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2565
2566     my $deltadays = DateTime::Duration->new(
2567         days => $chargeable_units
2568     );
2569
2570     if ( $deltadays->subtract($grace)->is_positive() ) {
2571         my $suspension_days = $deltadays * $finedays;
2572
2573         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2574             # No need to / 1 and do not consider / 0
2575             $suspension_days = DateTime::Duration->new(
2576                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2577             );
2578         }
2579
2580         # If the max suspension days is < than the suspension days
2581         # the suspension days is limited to this maximum period.
2582         my $max_sd = $issuing_rule->{maxsuspensiondays};
2583         if ( defined $max_sd && $max_sd ne '' ) {
2584             $max_sd = DateTime::Duration->new( days => $max_sd );
2585             $suspension_days = $max_sd
2586               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2587         }
2588
2589         my ( $has_been_extended );
2590         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2591             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2592             if ( $debarment ) {
2593                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2594                 $has_been_extended = 1;
2595             }
2596         }
2597
2598         my $new_debar_dt;
2599         # Use the calendar or not to calculate the debarment date
2600         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2601             my $calendar = Koha::Calendar->new(
2602                 branchcode => $branchcode,
2603                 days_mode  => 'Calendar'
2604             );
2605             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2606         }
2607         else {
2608             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2609         }
2610         return $new_debar_dt;
2611     }
2612     return;
2613 }
2614
2615 sub _debar_user_on_return {
2616     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2617
2618     $return_date //= dt_from_string();
2619
2620     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2621
2622     return unless $new_debar_dt;
2623
2624     Koha::Patron::Debarments::AddUniqueDebarment({
2625         borrowernumber => $borrower->{borrowernumber},
2626         expiration     => $new_debar_dt->ymd(),
2627         type           => 'SUSPENSION',
2628     });
2629     # if borrower was already debarred but does not get an extra debarment
2630     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2631     my ($new_debarment_str, $is_a_reminder);
2632     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2633         $is_a_reminder = 1;
2634         $new_debarment_str = $borrower->{debarred};
2635     } else {
2636         $new_debarment_str = $new_debar_dt->ymd();
2637     }
2638     # FIXME Should return a DateTime object
2639     return $new_debarment_str, $is_a_reminder;
2640 }
2641
2642 =head2 _FixOverduesOnReturn
2643
2644    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2645
2646 C<$borrowernumber> borrowernumber
2647
2648 C<$itemnumber> itemnumber
2649
2650 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2651
2652 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2653
2654 Internal function
2655
2656 =cut
2657
2658 sub _FixOverduesOnReturn {
2659     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2660     unless( $borrowernumber ) {
2661         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2662         return;
2663     }
2664     unless( $item ) {
2665         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2666         return;
2667     }
2668     unless( $status ) {
2669         warn "_FixOverduesOnReturn() not supplied valid status";
2670         return;
2671     }
2672
2673     my $schema = Koha::Database->schema;
2674
2675     my $result = $schema->txn_do(
2676         sub {
2677             # check for overdue fine
2678             my $accountlines = Koha::Account::Lines->search(
2679                 {
2680                     borrowernumber  => $borrowernumber,
2681                     itemnumber      => $item,
2682                     debit_type_code => 'OVERDUE',
2683                     status          => 'UNRETURNED'
2684                 }
2685             );
2686             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2687
2688             my $accountline = $accountlines->next;
2689             my $payments = $accountline->credits;
2690
2691             my $amountoutstanding = $accountline->amountoutstanding;
2692             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2693                 $accountline->delete;
2694                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2695             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2696                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2697                 my $credit = $account->add_credit(
2698                     {
2699                         amount     => $amountoutstanding,
2700                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2701                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2702                         interface  => C4::Context->interface,
2703                         type       => 'FORGIVEN',
2704                         item_id    => $item
2705                     }
2706                 );
2707
2708                 $credit->apply({ debits => [ $accountline ] });
2709
2710                 if (C4::Context->preference("FinesLog")) {
2711                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2712                 }
2713             }
2714
2715             $accountline->status($status);
2716             return $accountline->store();
2717         }
2718     );
2719
2720     return $result;
2721 }
2722
2723 =head2 _GetCircControlBranch
2724
2725    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2726
2727 Internal function :
2728
2729 Return the library code to be used to determine which circulation
2730 policy applies to a transaction.  Looks up the CircControl and
2731 HomeOrHoldingBranch system preferences.
2732
2733 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2734
2735 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2736
2737 =cut
2738
2739 sub _GetCircControlBranch {
2740     my ($item, $borrower) = @_;
2741     my $circcontrol = C4::Context->preference('CircControl');
2742     my $branch;
2743
2744     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2745         $branch= C4::Context->userenv->{'branch'};
2746     } elsif ($circcontrol eq 'PatronLibrary') {
2747         $branch=$borrower->{branchcode};
2748     } else {
2749         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2750         $branch = $item->{$branchfield};
2751         # default to item home branch if holdingbranch is used
2752         # and is not defined
2753         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2754             $branch = $item->{homebranch};
2755         }
2756     }
2757     return $branch;
2758 }
2759
2760 =head2 GetOpenIssue
2761
2762   $issue = GetOpenIssue( $itemnumber );
2763
2764 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2765
2766 C<$itemnumber> is the item's itemnumber
2767
2768 Returns a hashref
2769
2770 =cut
2771
2772 sub GetOpenIssue {
2773   my ( $itemnumber ) = @_;
2774   return unless $itemnumber;
2775   my $dbh = C4::Context->dbh;
2776   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2777   $sth->execute( $itemnumber );
2778   return $sth->fetchrow_hashref();
2779
2780 }
2781
2782 =head2 GetUpcomingDueIssues
2783
2784   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2785
2786 =cut
2787
2788 sub GetUpcomingDueIssues {
2789     my $params = shift;
2790
2791     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2792     my $dbh = C4::Context->dbh;
2793     my $statement;
2794     $statement = q{
2795         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2796         FROM issues
2797         LEFT JOIN items USING (itemnumber)
2798         LEFT JOIN branches ON branches.branchcode =
2799     };
2800     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2801     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2802     my @bind_parameters = ( $params->{'days_in_advance'} );
2803
2804     my $sth = $dbh->prepare( $statement );
2805     $sth->execute( @bind_parameters );
2806     my $upcoming_dues = $sth->fetchall_arrayref({});
2807
2808     return $upcoming_dues;
2809 }
2810
2811 =head2 CanBookBeRenewed
2812
2813   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2814
2815 Find out whether a borrowed item may be renewed.
2816
2817 C<$borrowernumber> is the borrower number of the patron who currently
2818 has the item on loan.
2819
2820 C<$itemnumber> is the number of the item to renew.
2821
2822 C<$override_limit>, if supplied with a true value, causes
2823 the limit on the number of times that the loan can be renewed
2824 (as controlled by the item type) to be ignored. Overriding also allows
2825 to renew sooner than "No renewal before" and to manually renew loans
2826 that are automatically renewed.
2827
2828 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2829 item must currently be on loan to the specified borrower; renewals
2830 must be allowed for the item's type; and the borrower must not have
2831 already renewed the loan. $error will contain the reason the renewal can not proceed
2832
2833 =cut
2834
2835 sub CanBookBeRenewed {
2836     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2837
2838     my $auto_renew = "no";
2839
2840     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2841     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2842     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2843     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2844
2845     my $patron = $issue->patron or return;
2846
2847     # override_limit will override anything else except on_reserve
2848     unless ( $override_limit ){
2849         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2850         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2851             {
2852                 categorycode => $patron->categorycode,
2853                 itemtype     => $item->effective_itemtype,
2854                 branchcode   => $branchcode,
2855                 rules => [
2856                     'renewalsallowed',
2857                     'lengthunit',
2858                     'unseen_renewals_allowed'
2859                 ]
2860             }
2861         );
2862
2863         return ( 0, "too_many" )
2864           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2865
2866         return ( 0, "too_unseen" )
2867           if C4::Context->preference('UnseenRenewals') &&
2868             $issuing_rule->{unseen_renewals_allowed} &&
2869             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2870
2871         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2872         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2873         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2874         my $restricted  = $patron->is_debarred;
2875         my $hasoverdues = $patron->has_overdues;
2876
2877         if ( $restricted and $restrictionblockrenewing ) {
2878             return ( 0, 'restriction');
2879         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2880             return ( 0, 'overdue');
2881         }
2882
2883         $auto_renew = _CanBookBeAutoRenewed({
2884             patron     => $patron,
2885             item       => $item,
2886             branchcode => $branchcode,
2887             issue      => $issue
2888         });
2889         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_soon' && $cron;
2890         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2891         # extra notices being sent. Cron also implies no override
2892         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2893         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2894         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2895     }
2896
2897     if ( C4::Context->preference('UseRecalls') ) {
2898         my $recall = undef;
2899         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2900         if ( defined $recall ) {
2901             if ( $recall->item_level_recall ) {
2902                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2903                 return ( 0, 'recalled' ) if ( $recall->itemnumber == $item->itemnumber );
2904             } else {
2905                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2906                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2907             }
2908         }
2909     }
2910
2911     my ( $resfound, $resrec, $possible_reserves ) = C4::Reserves::CheckReserves($itemnumber);
2912
2913     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2914     if ( $resfound && $resrec->{non_priority} ) {
2915         $resfound = Koha::Holds->search(
2916             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2917           ->count > 0;
2918     }
2919
2920
2921
2922     # This item can fill one or more unfilled reserve, can those unfilled reserves
2923     # all be filled by other available items?
2924     if ( $resfound
2925         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2926     {
2927         my $item_holds = Koha::Holds->search( { itemnumber => $itemnumber, found => undef } )->count();
2928         if ($item_holds) {
2929             # There is an item level hold on this item, no other item can fill the hold
2930             $resfound = 1;
2931         }
2932         else {
2933
2934             # Get all other items that could possibly fill reserves
2935             my $items = Koha::Items->search({
2936                 biblionumber => $resrec->{biblionumber},
2937                 onloan       => undef,
2938                 notforloan   => 0,
2939                 -not         => { itemnumber => $itemnumber }
2940             });
2941
2942             # Get all other reserves that could have been filled by this item
2943             my @borrowernumbers = map { $_->{borrowernumber} } @$possible_reserves;
2944             my $patrons = Koha::Patrons->search({
2945                 borrowernumber => { -in => \@borrowernumbers }
2946             });
2947
2948             # If the count of the union of the lists of reservable items for each borrower
2949             # is equal or greater than the number of borrowers, we know that all reserves
2950             # can be filled with available items. We can get the union of the sets simply
2951             # by pushing all the elements onto an array and removing the duplicates.
2952             my @reservable;
2953             ITEM: while ( my $item = $items->next ) {
2954                 next if IsItemOnHoldAndFound( $item->itemnumber );
2955                 while ( my $patron = $patrons->next ) {
2956                     next unless IsAvailableForItemLevelRequest($item, $patron);
2957                     next unless CanItemBeReserved($patron,$item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
2958                     push @reservable, $item->itemnumber;
2959                     if (@reservable >= @borrowernumbers) {
2960                         $resfound = 0;
2961                         last ITEM;
2962                     }
2963                     last;
2964                 }
2965                 $patrons->reset;
2966             }
2967         }
2968     }
2969
2970     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2971     return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2972     if ( GetSoonestRenewDate($borrowernumber, $itemnumber) > dt_from_string() ){
2973         return (0, "too_soon") unless $override_limit;
2974     }
2975
2976     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2977
2978     return ( 1, undef );
2979 }
2980
2981 =head2 AddRenewal
2982
2983   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
2984
2985 Renews a loan.
2986
2987 C<$borrowernumber> is the borrower number of the patron who currently
2988 has the item.
2989
2990 C<$itemnumber> is the number of the item to renew.
2991
2992 C<$branch> is the library where the renewal took place (if any).
2993            The library that controls the circ policies for the renewal is retrieved from the issues record.
2994
2995 C<$datedue> can be a DateTime object used to set the due date.
2996
2997 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2998 this parameter is not supplied, lastreneweddate is set to the current date.
2999
3000 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3001 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3002 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3003 syspref)
3004
3005 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3006 from the book's item type.
3007
3008 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3009 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3010 fallback to a true value
3011
3012 =cut
3013
3014 sub AddRenewal {
3015     my $borrowernumber  = shift;
3016     my $itemnumber      = shift or return;
3017     my $branch          = shift;
3018     my $datedue         = shift;
3019     my $lastreneweddate = shift || dt_from_string();
3020     my $skipfinecalc    = shift;
3021     my $seen            = shift;
3022
3023     # Fallback on a 'seen' renewal
3024     $seen = defined $seen && $seen == 0 ? 0 : 1;
3025
3026     my $item_object   = Koha::Items->find($itemnumber) or return;
3027     my $biblio = $item_object->biblio;
3028     my $issue  = $item_object->checkout;
3029     my $item_unblessed = $item_object->unblessed;
3030
3031     my $dbh = C4::Context->dbh;
3032
3033     return unless $issue;
3034
3035     $borrowernumber ||= $issue->borrowernumber;
3036
3037     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3038         carp 'Invalid date passed to AddRenewal.';
3039         return;
3040     }
3041
3042     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3043     my $patron_unblessed = $patron->unblessed;
3044
3045     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3046
3047     my $schema = Koha::Database->schema;
3048     $schema->txn_do(sub{
3049
3050         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3051             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3052         }
3053         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3054
3055         # If the due date wasn't specified, calculate it by adding the
3056         # book's loan length to today's date or the current due date
3057         # based on the value of the RenewalPeriodBase syspref.
3058         my $itemtype = $item_object->effective_itemtype;
3059         unless ($datedue) {
3060
3061             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3062                                             dt_from_string( $issue->date_due, 'sql' ) :
3063                                             dt_from_string();
3064             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3065         }
3066
3067         my $fees = Koha::Charges::Fees->new(
3068             {
3069                 patron    => $patron,
3070                 library   => $circ_library,
3071                 item      => $item_object,
3072                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3073                 to_date   => dt_from_string($datedue),
3074             }
3075         );
3076
3077         # Increment the unseen renewals, if appropriate
3078         # We only do so if the syspref is enabled and
3079         # a maximum value has been set in the circ rules
3080         my $unseen_renewals = $issue->unseen_renewals;
3081         if (C4::Context->preference('UnseenRenewals')) {
3082             my $rule = Koha::CirculationRules->get_effective_rule(
3083                 {   categorycode => $patron->categorycode,
3084                     itemtype     => $item_object->effective_itemtype,
3085                     branchcode   => $circ_library->branchcode,
3086                     rule_name    => 'unseen_renewals_allowed'
3087                 }
3088             );
3089             if (!$seen && $rule && $rule->rule_value) {
3090                 $unseen_renewals++;
3091             } else {
3092                 # If the renewal is seen, unseen should revert to 0
3093                 $unseen_renewals = 0;
3094             }
3095         }
3096
3097         # Update the issues record to have the new due date, and a new count
3098         # of how many times it has been renewed.
3099         my $renews = ( $issue->renewals || 0 ) + 1;
3100         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3101
3102         eval{
3103             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3104         };
3105         if( $sth->err ){
3106             Koha::Exceptions::Checkout::FailedRenewal->throw(
3107                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3108             );
3109         }
3110
3111         # Update the renewal count on the item, and tell zebra to reindex
3112         $renews = ( $item_object->renewals || 0 ) + 1;
3113         $item_object->renewals($renews);
3114         $item_object->onloan($datedue);
3115         $item_object->store({ log_action => 0 });
3116
3117         # Charge a new rental fee, if applicable
3118         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3119         if ( $charge > 0 ) {
3120             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3121         }
3122
3123         # Charge a new accumulate rental fee, if applicable
3124         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3125         if ( $itemtype_object ) {
3126             my $accumulate_charge = $fees->accumulate_rentalcharge();
3127             if ( $accumulate_charge > 0 ) {
3128                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3129             }
3130             $charge += $accumulate_charge;
3131         }
3132
3133         # Send a renewal slip according to checkout alert preferencei
3134         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3135             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3136             my %conditions        = (
3137                 branchcode   => $branch,
3138                 categorycode => $patron->categorycode,
3139                 item_type    => $itemtype,
3140                 notification => 'CHECKOUT',
3141             );
3142             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3143                 SendCirculationAlert(
3144                     {
3145                         type     => 'RENEWAL',
3146                         item     => $item_unblessed,
3147                         borrower => $patron->unblessed,
3148                         branch   => $branch,
3149                     }
3150                 );
3151             }
3152         }
3153
3154         # Remove any OVERDUES related debarment if the borrower has no overdues
3155         if ( $patron
3156           && $patron->is_debarred
3157           && ! $patron->has_overdues
3158           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3159         ) {
3160             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3161         }
3162
3163         # Add the renewal to stats
3164         C4::Stats::UpdateStats(
3165             {
3166                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3167                 type           => 'renew',
3168                 amount         => $charge,
3169                 itemnumber     => $itemnumber,
3170                 itemtype       => $itemtype,
3171                 location       => $item_object->location,
3172                 borrowernumber => $borrowernumber,
3173                 ccode          => $item_object->ccode,
3174             }
3175         );
3176
3177         #Log the renewal
3178         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3179
3180         Koha::Plugins->call('after_circ_action', {
3181             action  => 'renewal',
3182             payload => {
3183                 checkout  => $issue->get_from_storage
3184             }
3185         });
3186     });
3187
3188     return $datedue;
3189 }
3190
3191 sub GetRenewCount {
3192     # check renewal status
3193     my ( $bornum, $itemno ) = @_;
3194     my $dbh           = C4::Context->dbh;
3195     my $renewcount    = 0;
3196     my $unseencount    = 0;
3197     my $renewsallowed = 0;
3198     my $unseenallowed = 0;
3199     my $renewsleft    = 0;
3200     my $unseenleft    = 0;
3201
3202     my $patron = Koha::Patrons->find( $bornum );
3203     my $item   = Koha::Items->find($itemno);
3204
3205     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3206
3207     # Look in the issues table for this item, lent to this borrower,
3208     # and not yet returned.
3209
3210     # FIXME - I think this function could be redone to use only one SQL call.
3211     my $sth = $dbh->prepare(
3212         "select * from issues
3213                                 where (borrowernumber = ?)
3214                                 and (itemnumber = ?)"
3215     );
3216     $sth->execute( $bornum, $itemno );
3217     my $data = $sth->fetchrow_hashref;
3218     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3219     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3220     # $item and $borrower should be calculated
3221     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3222
3223     my $rules = Koha::CirculationRules->get_effective_rules(
3224         {
3225             categorycode => $patron->categorycode,
3226             itemtype     => $item->effective_itemtype,
3227             branchcode   => $branchcode,
3228             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3229         }
3230     );
3231     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3232     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3233         $rules->{unseen_renewals_allowed} :
3234         0;
3235     $renewsleft    = $renewsallowed - $renewcount;
3236     $unseenleft    = $unseenallowed - $unseencount;
3237     if($renewsleft < 0){ $renewsleft = 0; }
3238     if($unseenleft < 0){ $unseenleft = 0; }
3239     return (
3240         $renewcount,
3241         $renewsallowed,
3242         $renewsleft,
3243         $unseencount,
3244         $unseenallowed,
3245         $unseenleft
3246     );
3247 }
3248
3249 =head2 GetSoonestRenewDate
3250
3251   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3252
3253 Find out the soonest possible renew date of a borrowed item.
3254
3255 C<$borrowernumber> is the borrower number of the patron who currently
3256 has the item on loan.
3257
3258 C<$itemnumber> is the number of the item to renew.
3259
3260 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3261 renew date, based on the value "No renewal before" of the applicable
3262 issuing rule. Returns the current date if the item can already be
3263 renewed, and returns undefined if the borrower, loan, or item
3264 cannot be found.
3265
3266 =cut
3267
3268 sub GetSoonestRenewDate {
3269     my ( $borrowernumber, $itemnumber ) = @_;
3270
3271     my $dbh = C4::Context->dbh;
3272
3273     my $item      = Koha::Items->find($itemnumber)      or return;
3274     my $itemissue = $item->checkout or return;
3275
3276     $borrowernumber ||= $itemissue->borrowernumber;
3277     my $patron = Koha::Patrons->find( $borrowernumber )
3278       or return;
3279
3280     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3281     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3282         {   categorycode => $patron->categorycode,
3283             itemtype     => $item->effective_itemtype,
3284             branchcode   => $branchcode,
3285             rules => [
3286                 'norenewalbefore',
3287                 'lengthunit',
3288             ]
3289         }
3290     );
3291
3292     my $now = dt_from_string;
3293
3294     if ( defined $issuing_rule->{norenewalbefore}
3295         and $issuing_rule->{norenewalbefore} ne "" )
3296     {
3297         my $soonestrenewal =
3298           dt_from_string( $itemissue->date_due )->subtract(
3299             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3300
3301         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3302             and $issuing_rule->{lengthunit} eq 'days' )
3303         {
3304             $soonestrenewal->truncate( to => 'day' );
3305         }
3306         return $soonestrenewal if $now < $soonestrenewal;
3307     } elsif ( $itemissue->auto_renew && $patron->autorenew_checkouts ) {
3308         # Checkouts with auto-renewing fall back to due date
3309         my $soonestrenewal = dt_from_string( $itemissue->date_due );
3310         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3311             and $issuing_rule->{lengthunit} eq 'days' )
3312         {
3313             $soonestrenewal->truncate( to => 'day' );
3314         }
3315         return $soonestrenewal;
3316     }
3317     return $now;
3318 }
3319
3320 =head2 GetLatestAutoRenewDate
3321
3322   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3323
3324 Find out the latest possible auto renew date of a borrowed item.
3325
3326 C<$borrowernumber> is the borrower number of the patron who currently
3327 has the item on loan.
3328
3329 C<$itemnumber> is the number of the item to renew.
3330
3331 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3332 auto renew date, based on the value "No auto renewal after" and the "No auto
3333 renewal after (hard limit) of the applicable issuing rule.
3334 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3335 or item cannot be found.
3336
3337 =cut
3338
3339 sub GetLatestAutoRenewDate {
3340     my ( $borrowernumber, $itemnumber ) = @_;
3341
3342     my $dbh = C4::Context->dbh;
3343
3344     my $item      = Koha::Items->find($itemnumber)  or return;
3345     my $itemissue = $item->checkout                 or return;
3346
3347     $borrowernumber ||= $itemissue->borrowernumber;
3348     my $patron = Koha::Patrons->find( $borrowernumber )
3349       or return;
3350
3351     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3352     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3353         {
3354             categorycode => $patron->categorycode,
3355             itemtype     => $item->effective_itemtype,
3356             branchcode   => $branchcode,
3357             rules => [
3358                 'no_auto_renewal_after',
3359                 'no_auto_renewal_after_hard_limit',
3360                 'lengthunit',
3361             ]
3362         }
3363     );
3364
3365     return unless $circulation_rules;
3366     return
3367       if ( not $circulation_rules->{no_auto_renewal_after}
3368             or $circulation_rules->{no_auto_renewal_after} eq '' )
3369       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3370              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3371
3372     my $maximum_renewal_date;
3373     if ( $circulation_rules->{no_auto_renewal_after} ) {
3374         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3375         $maximum_renewal_date->add(
3376             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3377         );
3378     }
3379
3380     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3381         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3382         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3383     }
3384     return $maximum_renewal_date;
3385 }
3386
3387
3388 =head2 GetIssuingCharges
3389
3390   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3391
3392 Calculate how much it would cost for a given patron to borrow a given
3393 item, including any applicable discounts.
3394
3395 C<$itemnumber> is the item number of item the patron wishes to borrow.
3396
3397 C<$borrowernumber> is the patron's borrower number.
3398
3399 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3400 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3401 if it's a video).
3402
3403 =cut
3404
3405 sub GetIssuingCharges {
3406
3407     # calculate charges due
3408     my ( $itemnumber, $borrowernumber ) = @_;
3409     my $charge = 0;
3410     my $dbh    = C4::Context->dbh;
3411     my $item_type;
3412
3413     # Get the book's item type and rental charge (via its biblioitem).
3414     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3415         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3416     $charge_query .= (C4::Context->preference('item-level_itypes'))
3417         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3418         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3419
3420     $charge_query .= ' WHERE items.itemnumber =?';
3421
3422     my $sth = $dbh->prepare($charge_query);
3423     $sth->execute($itemnumber);
3424     if ( my $item_data = $sth->fetchrow_hashref ) {
3425         $item_type = $item_data->{itemtype};
3426         $charge    = $item_data->{rentalcharge};
3427         if ($charge) {
3428             # FIXME This should follow CircControl
3429             my $branch = C4::Context::mybranch();
3430             my $patron = Koha::Patrons->find( $borrowernumber );
3431             my $discount = Koha::CirculationRules->get_effective_rule({
3432                 categorycode => $patron->categorycode,
3433                 branchcode   => $branch,
3434                 itemtype     => $item_type,
3435                 rule_name    => 'rentaldiscount'
3436             });
3437             if ($discount) {
3438                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3439             }
3440             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3441         }
3442     }
3443
3444     return ( $charge, $item_type );
3445 }
3446
3447 =head2 AddIssuingCharge
3448
3449   &AddIssuingCharge( $checkout, $charge, $type )
3450
3451 =cut
3452
3453 sub AddIssuingCharge {
3454     my ( $checkout, $charge, $type ) = @_;
3455
3456     # FIXME What if checkout does not exist?
3457
3458     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3459     my $accountline = $account->add_debit(
3460         {
3461             amount      => $charge,
3462             note        => undef,
3463             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3464             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3465             interface   => C4::Context->interface,
3466             type        => $type,
3467             item_id     => $checkout->itemnumber,
3468             issue_id    => $checkout->issue_id,
3469         }
3470     );
3471 }
3472
3473 =head2 GetTransfers
3474
3475   GetTransfers($itemnumber);
3476
3477 =cut
3478
3479 sub GetTransfers {
3480     my ($itemnumber) = @_;
3481
3482     my $dbh = C4::Context->dbh;
3483
3484     my $query = '
3485         SELECT datesent,
3486                frombranch,
3487                tobranch,
3488                branchtransfer_id,
3489                daterequested,
3490                reason
3491         FROM branchtransfers
3492         WHERE itemnumber = ?
3493           AND datearrived IS NULL
3494           AND datecancelled IS NULL
3495         ';
3496     my $sth = $dbh->prepare($query);
3497     $sth->execute($itemnumber);
3498     my @row = $sth->fetchrow_array();
3499     return @row;
3500 }
3501
3502 =head2 GetTransfersFromTo
3503
3504   @results = GetTransfersFromTo($frombranch,$tobranch);
3505
3506 Returns the list of pending transfers between $from and $to branch
3507
3508 =cut
3509
3510 sub GetTransfersFromTo {
3511     my ( $frombranch, $tobranch ) = @_;
3512     return unless ( $frombranch && $tobranch );
3513     my $dbh   = C4::Context->dbh;
3514     my $query = "
3515         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3516         FROM   branchtransfers
3517         WHERE  frombranch=?
3518           AND  tobranch=?
3519           AND datecancelled IS NULL
3520           AND datesent IS NOT NULL
3521           AND datearrived IS NULL
3522     ";
3523     my $sth = $dbh->prepare($query);
3524     $sth->execute( $frombranch, $tobranch );
3525     my @gettransfers;
3526
3527     while ( my $data = $sth->fetchrow_hashref ) {
3528         push @gettransfers, $data;
3529     }
3530     return (@gettransfers);
3531 }
3532
3533 =head2 SendCirculationAlert
3534
3535 Send out a C<check-in> or C<checkout> alert using the messaging system.
3536
3537 B<Parameters>:
3538
3539 =over 4
3540
3541 =item type
3542
3543 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3544
3545 =item item
3546
3547 Hashref of information about the item being checked in or out.
3548
3549 =item borrower
3550
3551 Hashref of information about the borrower of the item.
3552
3553 =item branch
3554
3555 The branchcode from where the checkout or check-in took place.
3556
3557 =back
3558
3559 B<Example>:
3560
3561     SendCirculationAlert({
3562         type     => 'CHECKOUT',
3563         item     => $item,
3564         borrower => $borrower,
3565         branch   => $branch,
3566     });
3567
3568 =cut
3569
3570 sub SendCirculationAlert {
3571     my ($opts) = @_;
3572     my ($type, $item, $borrower, $branch, $issue) =
3573         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3574     my %message_name = (
3575         CHECKIN  => 'Item_Check_in',
3576         CHECKOUT => 'Item_Checkout',
3577         RENEWAL  => 'Item_Checkout',
3578     );
3579     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3580         borrowernumber => $borrower->{borrowernumber},
3581         message_name   => $message_name{$type},
3582     });
3583
3584
3585     my $tables = {
3586         items => $item->{itemnumber},
3587         biblio      => $item->{biblionumber},
3588         biblioitems => $item->{biblionumber},
3589         borrowers   => $borrower,
3590         branches    => $branch,
3591     };
3592
3593     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3594     # See C4::Letters:: _parseletter_sth
3595     if( $type eq 'CHECKIN' ){
3596         $tables->{old_issues} = $issue->issue_id;
3597     } else {
3598         $tables->{issues} = $item->{itemnumber};
3599     }
3600
3601     my $schema = Koha::Database->new->schema;
3602     my @transports = keys %{ $borrower_preferences->{transports} };
3603
3604     # From the MySQL doc:
3605     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3606     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3607     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3608     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3609
3610     for my $mtt (@transports) {
3611         my $letter =  C4::Letters::GetPreparedLetter (
3612             module => 'circulation',
3613             letter_code => $type,
3614             branchcode => $branch,
3615             message_transport_type => $mtt,
3616             lang => $borrower->{lang},
3617             tables => $tables,
3618         ) or next;
3619
3620         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3621         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3622         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3623         unless ( $message ) {
3624             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3625             C4::Message->enqueue($letter, $borrower, $mtt);
3626         } else {
3627             $message->append($letter);
3628             $message->update;
3629         }
3630         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3631     }
3632
3633     return;
3634 }
3635
3636 =head2 updateWrongTransfer
3637
3638   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3639
3640 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3641
3642 =cut
3643
3644 sub updateWrongTransfer {
3645         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3646
3647     # first step: cancel the original transfer
3648     my $item = Koha::Items->find($itemNumber);
3649     my $transfer = $item->get_transfer;
3650     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3651
3652     # second step: create a new transfer to the right location
3653     my $new_transfer = $item->request_transfer(
3654         {
3655             to            => $transfer->to_library,
3656             reason        => $transfer->reason,
3657             comment       => $transfer->comments,
3658             ignore_limits => 1,
3659             enqueue       => 1
3660         }
3661     );
3662
3663     return $new_transfer;
3664 }
3665
3666 =head2 CalcDateDue
3667
3668 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3669
3670 this function calculates the due date given the start date and configured circulation rules,
3671 checking against the holidays calendar as per the daysmode circulation rule.
3672 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3673 C<$itemtype>  = itemtype code of item in question
3674 C<$branch>  = location whose calendar to use
3675 C<$borrower> = Borrower object
3676 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3677
3678 =cut
3679
3680 sub CalcDateDue {
3681     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3682
3683     $isrenewal ||= 0;
3684
3685     # loanlength now a href
3686     my $loanlength =
3687             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3688
3689     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3690             ? qq{renewalperiod}
3691             : qq{issuelength};
3692
3693     my $datedue;
3694     if ( $startdate ) {
3695         if (ref $startdate ne 'DateTime' ) {
3696             $datedue = dt_from_string($datedue);
3697         } else {
3698             $datedue = $startdate->clone;
3699         }
3700     } else {
3701         $datedue = dt_from_string()->truncate( to => 'minute' );
3702     }
3703
3704
3705     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3706         {
3707             categorycode => $borrower->{categorycode},
3708             itemtype     => $itemtype,
3709             branchcode   => $branch,
3710         }
3711     );
3712
3713     # calculate the datedue as normal
3714     if ( $daysmode eq 'Days' )
3715     {    # ignoring calendar
3716         if ( $loanlength->{lengthunit} eq 'hours' ) {
3717             $datedue->add( hours => $loanlength->{$length_key} );
3718         } else {    # days
3719             $datedue->add( days => $loanlength->{$length_key} );
3720             $datedue->set_hour(23);
3721             $datedue->set_minute(59);
3722         }
3723     } else {
3724         my $dur;
3725         if ($loanlength->{lengthunit} eq 'hours') {
3726             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3727         }
3728         else { # days
3729             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3730         }
3731         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3732         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3733         if ($loanlength->{lengthunit} eq 'days') {
3734             $datedue->set_hour(23);
3735             $datedue->set_minute(59);
3736         }
3737     }
3738
3739     # if Hard Due Dates are used, retrieve them and apply as necessary
3740     my ( $hardduedate, $hardduedatecompare ) =
3741       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3742     if ($hardduedate) {    # hardduedates are currently dates
3743         $hardduedate->truncate( to => 'minute' );
3744         $hardduedate->set_hour(23);
3745         $hardduedate->set_minute(59);
3746         my $cmp = DateTime->compare( $hardduedate, $datedue );
3747
3748 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3749 # if the calculated date is before the 'after' Hard Due Date (floor), override
3750 # if the hard due date is set to 'exactly', overrride
3751         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3752             $datedue = $hardduedate->clone;
3753         }
3754
3755         # in all other cases, keep the date due as it is
3756
3757     }
3758
3759     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3760     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3761         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3762         if( $expiry_dt ) { #skip empty expiry date..
3763             $expiry_dt->set( hour => 23, minute => 59);
3764             my $d1= $datedue->clone->set_time_zone('floating');
3765             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3766                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3767             }
3768         }
3769         if ( $daysmode ne 'Days' ) {
3770           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3771           if ( $calendar->is_holiday($datedue) ) {
3772               # Don't return on a closed day
3773               $datedue = $calendar->prev_open_days( $datedue, 1 );
3774           }
3775         }
3776     }
3777
3778     return $datedue;
3779 }
3780
3781
3782 sub CheckValidBarcode{
3783 my ($barcode) = @_;
3784 my $dbh = C4::Context->dbh;
3785 my $query=qq|SELECT count(*)
3786              FROM items
3787              WHERE barcode=?
3788             |;
3789 my $sth = $dbh->prepare($query);
3790 $sth->execute($barcode);
3791 my $exist=$sth->fetchrow ;
3792 return $exist;
3793 }
3794
3795 =head2 IsBranchTransferAllowed
3796
3797   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3798
3799 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3800
3801 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3802 Koha::Item->can_be_transferred.
3803
3804 =cut
3805
3806 sub IsBranchTransferAllowed {
3807         my ( $toBranch, $fromBranch, $code ) = @_;
3808
3809         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3810
3811         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3812         my $dbh = C4::Context->dbh;
3813
3814         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3815         $sth->execute( $toBranch, $fromBranch, $code );
3816         my $limit = $sth->fetchrow_hashref();
3817
3818         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3819         if ( $limit->{'limitId'} ) {
3820                 return 0;
3821         } else {
3822                 return 1;
3823         }
3824 }
3825
3826 =head2 CreateBranchTransferLimit
3827
3828   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3829
3830 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3831
3832 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3833
3834 =cut
3835
3836 sub CreateBranchTransferLimit {
3837    my ( $toBranch, $fromBranch, $code ) = @_;
3838    return unless defined($toBranch) && defined($fromBranch);
3839    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3840
3841    my $dbh = C4::Context->dbh;
3842
3843    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3844    return $sth->execute( $code, $toBranch, $fromBranch );
3845 }
3846
3847 =head2 DeleteBranchTransferLimits
3848
3849     my $result = DeleteBranchTransferLimits($frombranch);
3850
3851 Deletes all the library transfer limits for one library.  Returns the
3852 number of limits deleted, 0e0 if no limits were deleted, or undef if
3853 no arguments are supplied.
3854
3855 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3856     fromBranch => $fromBranch
3857     })->delete.
3858
3859 =cut
3860
3861 sub DeleteBranchTransferLimits {
3862     my $branch = shift;
3863     return unless defined $branch;
3864     my $dbh    = C4::Context->dbh;
3865     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3866     return $sth->execute($branch);
3867 }
3868
3869 sub ReturnLostItem{
3870     my ( $borrowernumber, $itemnum ) = @_;
3871     MarkIssueReturned( $borrowernumber, $itemnum );
3872 }
3873
3874 =head2 LostItem
3875
3876   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3877
3878 The final optional parameter, C<$params>, expected to contain
3879 'skip_record_index' key, which relayed down to Koha::Item/store,
3880 there it prevents calling of ModZebra index_records,
3881 which takes most of the time in batch adds/deletes: index_records better
3882 to be called later in C<additem.pl> after the whole loop.
3883
3884 $params:
3885     skip_record_index => 1|0
3886
3887 =cut
3888
3889 sub LostItem{
3890     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3891
3892     unless ( $mark_lost_from ) {
3893         # Temporary check to avoid regressions
3894         die q|LostItem called without $mark_lost_from, check the API.|;
3895     }
3896
3897     my $mark_returned;
3898     if ( $force_mark_returned ) {
3899         $mark_returned = 1;
3900     } else {
3901         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3902         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3903     }
3904
3905     my $dbh = C4::Context->dbh();
3906     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3907                            FROM issues
3908                            JOIN items USING (itemnumber)
3909                            JOIN biblio USING (biblionumber)
3910                            WHERE issues.itemnumber=?");
3911     $sth->execute($itemnumber);
3912     my $issues=$sth->fetchrow_hashref();
3913
3914     # If a borrower lost the item, add a replacement cost to the their record
3915     if ( my $borrowernumber = $issues->{borrowernumber} ){
3916         my $patron = Koha::Patrons->find( $borrowernumber );
3917
3918         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3919         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3920
3921         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3922             C4::Accounts::chargelostitem(
3923                 $borrowernumber,
3924                 $itemnumber,
3925                 $issues->{'replacementprice'},
3926                 sprintf( "%s %s %s",
3927                     $issues->{'title'}          || q{},
3928                     $issues->{'barcode'}        || q{},
3929                     $issues->{'itemcallnumber'} || q{},
3930                 ),
3931             );
3932             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3933             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3934         }
3935
3936         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
3937     }
3938
3939     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
3940     my $item = Koha::Items->find($itemnumber);
3941     my $transfers = $item->get_transfers;
3942     while (my $transfer = $transfers->next) {
3943         $transfer->cancel({ reason => 'ItemLost', force => 1 });
3944     }
3945 }
3946
3947 sub GetOfflineOperations {
3948     my $dbh = C4::Context->dbh;
3949     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3950     $sth->execute(C4::Context->userenv->{'branch'});
3951     my $results = $sth->fetchall_arrayref({});
3952     return $results;
3953 }
3954
3955 sub GetOfflineOperation {
3956     my $operationid = shift;
3957     return unless $operationid;
3958     my $dbh = C4::Context->dbh;
3959     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3960     $sth->execute( $operationid );
3961     return $sth->fetchrow_hashref;
3962 }
3963
3964 sub AddOfflineOperation {
3965     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3966     my $dbh = C4::Context->dbh;
3967     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3968     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3969     return "Added.";
3970 }
3971
3972 sub DeleteOfflineOperation {
3973     my $dbh = C4::Context->dbh;
3974     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3975     $sth->execute( shift );
3976     return "Deleted.";
3977 }
3978
3979 sub ProcessOfflineOperation {
3980     my $operation = shift;
3981
3982     my $report;
3983     if ( $operation->{action} eq 'return' ) {
3984         $report = ProcessOfflineReturn( $operation );
3985     } elsif ( $operation->{action} eq 'issue' ) {
3986         $report = ProcessOfflineIssue( $operation );
3987     } elsif ( $operation->{action} eq 'payment' ) {
3988         $report = ProcessOfflinePayment( $operation );
3989     }
3990
3991     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3992
3993     return $report;
3994 }
3995
3996 sub ProcessOfflineReturn {
3997     my $operation = shift;
3998
3999     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4000
4001     if ( $item ) {
4002         my $itemnumber = $item->itemnumber;
4003         my $issue = GetOpenIssue( $itemnumber );
4004         if ( $issue ) {
4005             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4006             ModDateLastSeen( $itemnumber, $leave_item_lost );
4007             MarkIssueReturned(
4008                 $issue->{borrowernumber},
4009                 $itemnumber,
4010                 $operation->{timestamp},
4011             );
4012             $item->renewals(0);
4013             $item->onloan(undef);
4014             $item->store({ log_action => 0 });
4015             return "Success.";
4016         } else {
4017             return "Item not issued.";
4018         }
4019     } else {
4020         return "Item not found.";
4021     }
4022 }
4023
4024 sub ProcessOfflineIssue {
4025     my $operation = shift;
4026
4027     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4028
4029     if ( $patron ) {
4030         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4031         unless ($item) {
4032             return "Barcode not found.";
4033         }
4034         my $itemnumber = $item->itemnumber;
4035         my $issue = GetOpenIssue( $itemnumber );
4036
4037         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4038             MarkIssueReturned(
4039                 $issue->{borrowernumber},
4040                 $itemnumber,
4041                 $operation->{timestamp},
4042             );
4043         }
4044         AddIssue(
4045             $patron->unblessed,
4046             $operation->{'barcode'},
4047             undef,
4048             1,
4049             $operation->{timestamp},
4050             undef,
4051         );
4052         return "Success.";
4053     } else {
4054         return "Borrower not found.";
4055     }
4056 }
4057
4058 sub ProcessOfflinePayment {
4059     my $operation = shift;
4060
4061     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4062
4063     $patron->account->pay(
4064         {
4065             amount     => $operation->{amount},
4066             library_id => $operation->{branchcode},
4067             interface  => 'koc'
4068         }
4069     );
4070
4071     return "Success.";
4072 }
4073
4074 =head2 TransferSlip
4075
4076   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4077
4078   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4079
4080 =cut
4081
4082 sub TransferSlip {
4083     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4084
4085     my $item =
4086       $itemnumber
4087       ? Koha::Items->find($itemnumber)
4088       : Koha::Items->find( { barcode => $barcode } );
4089
4090     $item or return;
4091
4092     return C4::Letters::GetPreparedLetter (
4093         module => 'circulation',
4094         letter_code => 'TRANSFERSLIP',
4095         branchcode => $branch,
4096         tables => {
4097             'branches'    => $to_branch,
4098             'biblio'      => $item->biblionumber,
4099             'items'       => $item->unblessed,
4100         },
4101     );
4102 }
4103
4104 =head2 CheckIfIssuedToPatron
4105
4106   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4107
4108   Return 1 if any record item is issued to patron, otherwise return 0
4109
4110 =cut
4111
4112 sub CheckIfIssuedToPatron {
4113     my ($borrowernumber, $biblionumber) = @_;
4114
4115     my $dbh = C4::Context->dbh;
4116     my $query = q|
4117         SELECT COUNT(*) FROM issues
4118         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4119         WHERE items.biblionumber = ?
4120         AND issues.borrowernumber = ?
4121     |;
4122     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4123     return 1 if $is_issued;
4124     return;
4125 }
4126
4127 =head2 IsItemIssued
4128
4129   IsItemIssued( $itemnumber )
4130
4131   Return 1 if the item is on loan, otherwise return 0
4132
4133 =cut
4134
4135 sub IsItemIssued {
4136     my $itemnumber = shift;
4137     my $dbh = C4::Context->dbh;
4138     my $sth = $dbh->prepare(q{
4139         SELECT COUNT(*)
4140         FROM issues
4141         WHERE itemnumber = ?
4142     });
4143     $sth->execute($itemnumber);
4144     return $sth->fetchrow;
4145 }
4146
4147 =head2 GetAgeRestriction
4148
4149   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4150   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4151
4152   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4153   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4154
4155 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4156 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4157 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4158          Negative days mean the borrower has gone past the age restriction age.
4159
4160 =cut
4161
4162 sub GetAgeRestriction {
4163     my ($record_restrictions, $borrower) = @_;
4164     my $markers = C4::Context->preference('AgeRestrictionMarker');
4165
4166     return unless $record_restrictions;
4167     # Split $record_restrictions to something like FSK 16 or PEGI 6
4168     my @values = split ' ', uc($record_restrictions);
4169     return unless @values;
4170
4171     # Search first occurrence of one of the markers
4172     my @markers = split /\|/, uc($markers);
4173     return unless @markers;
4174
4175     my $index            = 0;
4176     my $restriction_year = 0;
4177     for my $value (@values) {
4178         $index++;
4179         for my $marker (@markers) {
4180             $marker =~ s/^\s+//;    #remove leading spaces
4181             $marker =~ s/\s+$//;    #remove trailing spaces
4182             if ( $marker eq $value ) {
4183                 if ( $index <= $#values ) {
4184                     $restriction_year += $values[$index];
4185                 }
4186                 last;
4187             }
4188             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4189
4190                 # Perhaps it is something like "K16" (as in Finland)
4191                 $restriction_year += $1;
4192                 last;
4193             }
4194         }
4195         last if ( $restriction_year > 0 );
4196     }
4197
4198     #Check if the borrower is age restricted for this material and for how long.
4199     if ($restriction_year && $borrower) {
4200         if ( $borrower->{'dateofbirth'} ) {
4201             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4202             $alloweddate[0] += $restriction_year;
4203
4204             #Prevent runime eror on leap year (invalid date)
4205             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4206                 $alloweddate[2] = 28;
4207             }
4208
4209             #Get how many days the borrower has to reach the age restriction
4210             my @Today = split /-/, dt_from_string()->ymd();
4211             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4212             #Negative days means the borrower went past the age restriction age
4213             return ($restriction_year, $daysToAgeRestriction);
4214         }
4215     }
4216
4217     return ($restriction_year);
4218 }
4219
4220
4221 =head2 GetPendingOnSiteCheckouts
4222
4223 =cut
4224
4225 sub GetPendingOnSiteCheckouts {
4226     my $dbh = C4::Context->dbh;
4227     return $dbh->selectall_arrayref(q|
4228         SELECT
4229           items.barcode,
4230           items.biblionumber,
4231           items.itemnumber,
4232           items.itemnotes,
4233           items.itemcallnumber,
4234           items.location,
4235           issues.date_due,
4236           issues.branchcode,
4237           issues.date_due < NOW() AS is_overdue,
4238           biblio.author,
4239           biblio.title,
4240           borrowers.firstname,
4241           borrowers.surname,
4242           borrowers.cardnumber,
4243           borrowers.borrowernumber
4244         FROM items
4245         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4246         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4247         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4248         WHERE issues.onsite_checkout = 1
4249     |, { Slice => {} } );
4250 }
4251
4252 sub GetTopIssues {
4253     my ($params) = @_;
4254
4255     my ($count, $branch, $itemtype, $ccode, $newness)
4256         = @$params{qw(count branch itemtype ccode newness)};
4257
4258     my $dbh = C4::Context->dbh;
4259     my $query = q{
4260         SELECT * FROM (
4261         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4262           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4263           i.ccode, SUM(i.issues) AS count
4264         FROM biblio b
4265         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4266         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4267     };
4268
4269     my (@where_strs, @where_args);
4270
4271     if ($branch) {
4272         push @where_strs, 'i.homebranch = ?';
4273         push @where_args, $branch;
4274     }
4275     if ($itemtype) {
4276         if (C4::Context->preference('item-level_itypes')){
4277             push @where_strs, 'i.itype = ?';
4278             push @where_args, $itemtype;
4279         } else {
4280             push @where_strs, 'bi.itemtype = ?';
4281             push @where_args, $itemtype;
4282         }
4283     }
4284     if ($ccode) {
4285         push @where_strs, 'i.ccode = ?';
4286         push @where_args, $ccode;
4287     }
4288     if ($newness) {
4289         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4290         push @where_args, $newness;
4291     }
4292
4293     if (@where_strs) {
4294         $query .= 'WHERE ' . join(' AND ', @where_strs);
4295     }
4296
4297     $query .= q{
4298         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4299           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4300           i.ccode
4301         ORDER BY count DESC
4302     };
4303
4304     $query .= q{ ) xxx WHERE count > 0 };
4305     $count = int($count);
4306     if ($count > 0) {
4307         $query .= "LIMIT $count";
4308     }
4309
4310     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4311
4312     return @$rows;
4313 }
4314
4315 =head2 Internal methods
4316
4317 =cut
4318
4319 sub _CalculateAndUpdateFine {
4320     my ($params) = @_;
4321
4322     my $borrower    = $params->{borrower};
4323     my $item        = $params->{item};
4324     my $issue       = $params->{issue};
4325     my $return_date = $params->{return_date};
4326
4327     unless ($borrower) { carp "No borrower passed in!" && return; }
4328     unless ($item)     { carp "No item passed in!"     && return; }
4329     unless ($issue)    { carp "No issue passed in!"    && return; }
4330
4331     my $datedue = dt_from_string( $issue->date_due );
4332
4333     # we only need to calculate and change the fines if we want to do that on return
4334     # Should be on for hourly loans
4335     my $control = C4::Context->preference('CircControl');
4336     my $control_branchcode =
4337         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4338       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4339       :                                     $issue->branchcode;
4340
4341     my $date_returned = $return_date ? $return_date : dt_from_string();
4342
4343     my ( $amount, $unitcounttotal, $unitcount  ) =
4344       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4345
4346     if ( C4::Context->preference('finesMode') eq 'production' ) {
4347         if ( $amount > 0 ) {
4348             C4::Overdues::UpdateFine({
4349                 issue_id       => $issue->issue_id,
4350                 itemnumber     => $issue->itemnumber,
4351                 borrowernumber => $issue->borrowernumber,
4352                 amount         => $amount,
4353                 due            => output_pref($datedue),
4354             });
4355         }
4356         elsif ($return_date) {
4357
4358             # Backdated returns may have fines that shouldn't exist,
4359             # so in this case, we need to drop those fines to 0
4360
4361             C4::Overdues::UpdateFine({
4362                 issue_id       => $issue->issue_id,
4363                 itemnumber     => $issue->itemnumber,
4364                 borrowernumber => $issue->borrowernumber,
4365                 amount         => 0,
4366                 due            => output_pref($datedue),
4367             });
4368         }
4369     }
4370 }
4371
4372 sub _CanBookBeAutoRenewed {
4373     my ( $params ) = @_;
4374     my $patron = $params->{patron};
4375     my $item = $params->{item};
4376     my $branchcode = $params->{branchcode};
4377     my $issue = $params->{issue};
4378
4379     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4380
4381     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4382         {
4383             categorycode => $patron->categorycode,
4384             itemtype     => $item->effective_itemtype,
4385             branchcode   => $branchcode,
4386             rules => [
4387                 'no_auto_renewal_after',
4388                 'no_auto_renewal_after_hard_limit',
4389                 'lengthunit',
4390                 'norenewalbefore',
4391             ]
4392         }
4393     );
4394
4395     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4396         return 'auto_account_expired';
4397     }
4398
4399     if ( defined $issuing_rule->{no_auto_renewal_after}
4400             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4401         # Get issue_date and add no_auto_renewal_after
4402         # If this is greater than today, it's too late for renewal.
4403         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4404         $maximum_renewal_date->add(
4405             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4406         );
4407         my $now = dt_from_string;
4408         if ( $now >= $maximum_renewal_date ) {
4409             return "auto_too_late";
4410         }
4411     }
4412     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4413                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4414         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4415         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4416             return "auto_too_late";
4417         }
4418     }
4419
4420     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4421         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4422         my $amountoutstanding =
4423           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4424           ? $patron->account->balance
4425           : $patron->account->outstanding_debits->total_outstanding;
4426         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4427             return "auto_too_much_oweing";
4428         }
4429     }
4430
4431     if ( defined $issuing_rule->{norenewalbefore}
4432         and $issuing_rule->{norenewalbefore} ne "" ) {
4433         if ( GetSoonestRenewDate($patron->id, $item->id) > dt_from_string()) {
4434             return "auto_too_soon";
4435         } else {
4436             return "ok";
4437         }
4438     }
4439
4440     # Fallback for automatic renewals:
4441     # If norenewalbefore is undef, don't renew before due date.
4442     my $now = dt_from_string;
4443     if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
4444         return "ok";
4445     } else {
4446         return "auto_too_soon";
4447     }
4448 }
4449
4450 sub _item_denied_renewal {
4451     my ($params) = @_;
4452
4453     my $item = $params->{item};
4454     return unless $item;
4455
4456     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4457     return unless $denyingrules;
4458     foreach my $field (keys %$denyingrules) {
4459         my $val = $item->$field;
4460         if( !defined $val) {
4461             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4462                 return 1;
4463             }
4464         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4465            # If the results matches the values in the syspref
4466            # We return true if match found
4467             return 1;
4468         }
4469     }
4470     return 0;
4471 }
4472
4473 1;
4474
4475 __END__
4476
4477 =head1 AUTHOR
4478
4479 Koha Development Team <http://koha-community.org/>
4480
4481 =cut