C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use Koha::DateUtils;
  25 use C4::Context;
  26 use C4::Stats;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Members;
  31 use C4::Accounts;
  32 use C4::ItemCirculationAlertPreference;
  33 use C4::Message;
  34 use C4::Debug;
  35 use C4::Log; # logaction
  36 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits;
  39
  40 use Data::Dumper;
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::Biblioitems;
  44 use Koha::DateUtils;
  45 use Koha::Calendar;
  46 use Koha::Checkouts;
  47 use Koha::Illrequests;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments;
  51 use Koha::Database;
  52 use Koha::Libraries;
  53 use Koha::Account::Lines;
  54 use Koha::Holds;
  55 use Koha::RefundLostItemFeeRules;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Util::SystemPreferences;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Carp;
  63 use List::MoreUtils qw( uniq any );
  64 use Scalar::Util qw( looks_like_number );
  65 use Date::Calc qw(
  66   Today
  67   Today_and_Now
  68   Add_Delta_YM
  69   Add_Delta_DHMS
  70   Date_to_Days
  71   Day_of_Week
  72   Add_Delta_Days
  73 );
  74 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  75
  76 BEGIN {
  77         require Exporter;
  78         @ISA    = qw(Exporter);
  79
  80         # FIXME subs that should probably be elsewhere
  81         push @EXPORT, qw(
  82                 &barcodedecode
  83         &LostItem
  84         &ReturnLostItem
  85         &GetPendingOnSiteCheckouts
  86         );
  87
  88         # subs to deal with issuing a book
  89         push @EXPORT, qw(
  90                 &CanBookBeIssued
  91                 &CanBookBeRenewed
  92                 &AddIssue
  93                 &AddRenewal
  94                 &GetRenewCount
  95         &GetSoonestRenewDate
  96         &GetLatestAutoRenewDate
  97                 &GetIssuingCharges
  98         &GetBranchBorrowerCircRule
  99         &GetBranchItemRule
 100                 &GetBiblioIssues
 101                 &GetOpenIssue
 102         &CheckIfIssuedToPatron
 103         &IsItemIssued
 104         GetTopIssues
 105         );
 106
 107         # subs to deal with returns
 108         push @EXPORT, qw(
 109                 &AddReturn
 110         &MarkIssueReturned
 111         );
 112
 113         # subs to deal with transfers
 114         push @EXPORT, qw(
 115                 &transferbook
 116                 &GetTransfers
 117                 &GetTransfersFromTo
 118                 &updateWrongTransfer
 119                 &DeleteTransfer
 120                 &IsBranchTransferAllowed
 121                 &CreateBranchTransferLimit
 122                 &DeleteBranchTransferLimits
 123         &TransferSlip
 124         );
 125
 126     # subs to deal with offline circulation
 127     push @EXPORT, qw(
 128       &GetOfflineOperations
 129       &GetOfflineOperation
 130       &AddOfflineOperation
 131       &DeleteOfflineOperation
 132       &ProcessOfflineOperation
 133     );
 134 }
 135
 136 =head1 NAME
 137
 138 C4::Circulation - Koha circulation module
 139
 140 =head1 SYNOPSIS
 141
 142 use C4::Circulation;
 143
 144 =head1 DESCRIPTION
 145
 146 The functions in this module deal with circulation, issues, and
 147 returns, as well as general information about the library.
 148 Also deals with inventory.
 149
 150 =head1 FUNCTIONS
 151
 152 =head2 barcodedecode
 153
 154   $str = &barcodedecode($barcode, [$filter]);
 155
 156 Generic filter function for barcode string.
 157 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 158 Will do some manipulation of the barcode for systems that deliver a barcode
 159 to circulation.pl that differs from the barcode stored for the item.
 160 For proper functioning of this filter, calling the function on the
 161 correct barcode string (items.barcode) should return an unaltered barcode.
 162
 163 The optional $filter argument is to allow for testing or explicit
 164 behavior that ignores the System Pref.  Valid values are the same as the
 165 System Pref options.
 166
 167 =cut
 168
 169 # FIXME -- the &decode fcn below should be wrapped into this one.
 170 # FIXME -- these plugins should be moved out of Circulation.pm
 171 #
 172 sub barcodedecode {
 173     my ($barcode, $filter) = @_;
 174     my $branch = C4::Context::mybranch();
 175     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 176     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 177         if ($filter eq 'whitespace') {
 178                 $barcode =~ s/\s//g;
 179         } elsif ($filter eq 'cuecat') {
 180                 chomp($barcode);
 181             my @fields = split( /\./, $barcode );
 182             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 183             ($#results == 2) and return $results[2];
 184         } elsif ($filter eq 'T-prefix') {
 185                 if ($barcode =~ /^[Tt](\d)/) {
 186                         (defined($1) and $1 eq '0') and return $barcode;
 187             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 188                 }
 189         return sprintf("T%07d", $barcode);
 190         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 191         # Why drop the nonzero digit after the T?
 192         # Why pass non-digits (or empty string) to "T%07d"?
 193         } elsif ($filter eq 'libsuite8') {
 194                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 195                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 196                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 197                         }else{
 198                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 199                         }
 200                 }
 201     } elsif ($filter eq 'EAN13') {
 202         my $ean = CheckDigits('ean');
 203         if ( $ean->is_valid($barcode) ) {
 204             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 205             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 206         } else {
 207             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 208         }
 209         }
 210     return $barcode;    # return barcode, modified or not
 211 }
 212
 213 =head2 decode
 214
 215   $str = &decode($chunk);
 216
 217 Decodes a segment of a string emitted by a CueCat barcode scanner and
 218 returns it.
 219
 220 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 221 or Javascript based decoding on the client side.
 222
 223 =cut
 224
 225 sub decode {
 226     my ($encoded) = @_;
 227     my $seq =
 228       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 229     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 230     my $l = ( $#s + 1 ) % 4;
 231     if ($l) {
 232         if ( $l == 1 ) {
 233             # warn "Error: Cuecat decode parsing failed!";
 234             return;
 235         }
 236         $l = 4 - $l;
 237         $#s += $l;
 238     }
 239     my $r = '';
 240     while ( $#s >= 0 ) {
 241         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 242         $r .=
 243             chr( ( $n >> 16 ) ^ 67 )
 244          .chr( ( $n >> 8 & 255 ) ^ 67 )
 245          .chr( ( $n & 255 ) ^ 67 );
 246         @s = @s[ 4 .. $#s ];
 247     }
 248     $r = substr( $r, 0, length($r) - $l );
 249     return $r;
 250 }
 251
 252 =head2 transferbook
 253
 254   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 255                                             $barcode, $ignore_reserves, $trigger);
 256
 257 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 258
 259 C<$newbranch> is the code for the branch to which the item should be transferred.
 260
 261 C<$barcode> is the barcode of the item to be transferred.
 262
 263 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 264 Otherwise, if an item is reserved, the transfer fails.
 265
 266 C<$trigger> is the enum value for what triggered the transfer.
 267
 268 Returns three values:
 269
 270 =over
 271
 272 =item $dotransfer
 273
 274 is true if the transfer was successful.
 275
 276 =item $messages
 277
 278 is a reference-to-hash which may have any of the following keys:
 279
 280 =over
 281
 282 =item C<BadBarcode>
 283
 284 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 285
 286 =item C<DestinationEqualsHolding>
 287
 288 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 289
 290 =item C<WasReturned>
 291
 292 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 293
 294 =item C<ResFound>
 295
 296 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 297
 298 =item C<WasTransferred>
 299
 300 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 301
 302 =back
 303
 304 =back
 305
 306 =cut
 307
 308 sub transferbook {
 309     my ( $tbr, $barcode, $ignoreRs, $trigger ) = @_;
 310     my $messages;
 311     my $dotransfer      = 1;
 312     my $item = Koha::Items->find( { barcode => $barcode } );
 313
 314     # bad barcode..
 315     unless ( $item ) {
 316         $messages->{'BadBarcode'} = $barcode;
 317         $dotransfer = 0;
 318         return ( $dotransfer, $messages );
 319     }
 320
 321     my $itemnumber = $item->itemnumber;
 322     # get branches of book...
 323     my $hbr = $item->homebranch;
 324     my $fbr = $item->holdingbranch;
 325
 326     # if using Branch Transfer Limits
 327     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 328         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 329         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 330             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 331                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 332                 $dotransfer = 0;
 333             }
 334         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 335             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 336             $dotransfer = 0;
 337         }
 338     }
 339
 340     # can't transfer book if is already there....
 341     if ( $fbr eq $tbr ) {
 342         $messages->{'DestinationEqualsHolding'} = 1;
 343         $dotransfer = 0;
 344     }
 345
 346     # check if it is still issued to someone, return it...
 347     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 348     if ( $issue ) {
 349         AddReturn( $barcode, $fbr );
 350         $messages->{'WasReturned'} = $issue->borrowernumber;
 351     }
 352
 353     # find reserves.....
 354     # That'll save a database query.
 355     my ( $resfound, $resrec, undef ) =
 356       CheckReserves( $itemnumber );
 357     if ( $resfound and not $ignoreRs ) {
 358         $resrec->{'ResFound'} = $resfound;
 359         $messages->{'ResFound'} = $resrec;
 360         $dotransfer = 1;
 361     }
 362
 363     #actually do the transfer....
 364     if ($dotransfer) {
 365         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 366
 367         # don't need to update MARC anymore, we do it in batch now
 368         $messages->{'WasTransfered'} = 1;
 369
 370     }
 371     ModDateLastSeen( $itemnumber );
 372     return ( $dotransfer, $messages );
 373 }
 374
 375
 376 sub TooMany {
 377     my $borrower        = shift;
 378     my $item_object = shift;
 379     my $params = shift;
 380     my $onsite_checkout = $params->{onsite_checkout} || 0;
 381     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 382     my $cat_borrower    = $borrower->{'categorycode'};
 383     my $dbh             = C4::Context->dbh;
 384         my $branch;
 385         # Get which branchcode we need
 386     $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 387     my $type = $item_object->effective_itemtype;
 388
 389     # given branch, patron category, and item type, determine
 390     # applicable issuing rule
 391     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 392         {
 393             categorycode => $cat_borrower,
 394             itemtype     => $type,
 395             branchcode   => $branch,
 396             rule_name    => 'maxissueqty',
 397         }
 398     );
 399     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 400         {
 401             categorycode => $cat_borrower,
 402             itemtype     => $type,
 403             branchcode   => $branch,
 404             rule_name    => 'maxonsiteissueqty',
 405         }
 406     );
 407
 408
 409     # if a rule is found and has a loan limit set, count
 410     # how many loans the patron already has that meet that
 411     # rule
 412     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne '') {
 413         my @bind_params;
 414         my $count_query = q|
 415             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 416             FROM issues
 417             JOIN items USING (itemnumber)
 418         |;
 419
 420         my $rule_itemtype = $maxissueqty_rule->itemtype;
 421         unless ($rule_itemtype) {
 422             # matching rule has the default item type, so count only
 423             # those existing loans that don't fall under a more
 424             # specific rule
 425             if (C4::Context->preference('item-level_itypes')) {
 426                 $count_query .= " WHERE items.itype NOT IN (
 427                                     SELECT itemtype FROM circulation_rules
 428                                     WHERE branchcode = ?
 429                                     AND   (categorycode = ? OR categorycode = ?)
 430                                     AND   itemtype IS NOT NULL
 431                                     AND   rule_name = 'maxissueqty'
 432                                   ) ";
 433             } else {
 434                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 435                                   WHERE biblioitems.itemtype NOT IN (
 436                                     SELECT itemtype FROM circulation_rules
 437                                     WHERE branchcode = ?
 438                                     AND   (categorycode = ? OR categorycode = ?)
 439                                     AND   itemtype IS NOT NULL
 440                                     AND   rule_name = 'maxissueqty'
 441                                   ) ";
 442             }
 443             push @bind_params, $maxissueqty_rule->branchcode;
 444             push @bind_params, $maxissueqty_rule->categorycode;
 445             push @bind_params, $cat_borrower;
 446         } else {
 447             # rule has specific item type, so count loans of that
 448             # specific item type
 449             if (C4::Context->preference('item-level_itypes')) {
 450                 $count_query .= " WHERE items.itype = ? ";
 451             } else {
 452                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 453                                   WHERE biblioitems.itemtype= ? ";
 454             }
 455             push @bind_params, $type;
 456         }
 457
 458         $count_query .= " AND borrowernumber = ? ";
 459         push @bind_params, $borrower->{'borrowernumber'};
 460         my $rule_branch = $maxissueqty_rule->branchcode;
 461         if ($rule_branch) {
 462             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 463                 $count_query .= " AND issues.branchcode = ? ";
 464                 push @bind_params, $rule_branch;
 465             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 466                 ; # if branch is the patron's home branch, then count all loans by patron
 467             } else {
 468                 $count_query .= " AND items.homebranch = ? ";
 469                 push @bind_params, $rule_branch;
 470             }
 471         }
 472
 473         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 474
 475         my $max_checkouts_allowed = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 476         my $max_onsite_checkouts_allowed = $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef;
 477
 478         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 479             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 480                 return {
 481                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 482                     count => $onsite_checkout_count,
 483                     max_allowed => $max_onsite_checkouts_allowed,
 484                 }
 485             }
 486         }
 487         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 488             my $delta = $switch_onsite_checkout ? 1 : 0;
 489             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 490                 return {
 491                     reason => 'TOO_MANY_CHECKOUTS',
 492                     count => $checkout_count,
 493                     max_allowed => $max_checkouts_allowed,
 494                 };
 495             }
 496         } elsif ( not $onsite_checkout ) {
 497             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 498                 return {
 499                     reason => 'TOO_MANY_CHECKOUTS',
 500                     count => $checkout_count - $onsite_checkout_count,
 501                     max_allowed => $max_checkouts_allowed,
 502                 };
 503             }
 504         }
 505     }
 506
 507     # Now count total loans against the limit for the branch
 508     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 509     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 510         my @bind_params = ();
 511         my $branch_count_query = q|
 512             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 513             FROM issues
 514             JOIN items USING (itemnumber)
 515             WHERE borrowernumber = ?
 516         |;
 517         push @bind_params, $borrower->{borrowernumber};
 518
 519         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 520             $branch_count_query .= " AND issues.branchcode = ? ";
 521             push @bind_params, $branch;
 522         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 523             ; # if branch is the patron's home branch, then count all loans by patron
 524         } else {
 525             $branch_count_query .= " AND items.homebranch = ? ";
 526             push @bind_params, $branch;
 527         }
 528         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 529         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 530         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty};
 531
 532         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 533             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 534                 return {
 535                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 536                     count => $onsite_checkout_count,
 537                     max_allowed => $max_onsite_checkouts_allowed,
 538                 }
 539             }
 540         }
 541         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 542             my $delta = $switch_onsite_checkout ? 1 : 0;
 543             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 544                 return {
 545                     reason => 'TOO_MANY_CHECKOUTS',
 546                     count => $checkout_count,
 547                     max_allowed => $max_checkouts_allowed,
 548                 };
 549             }
 550         } elsif ( not $onsite_checkout ) {
 551             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 552                 return {
 553                     reason => 'TOO_MANY_CHECKOUTS',
 554                     count => $checkout_count - $onsite_checkout_count,
 555                     max_allowed => $max_checkouts_allowed,
 556                 };
 557             }
 558         }
 559     }
 560
 561     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 562         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 563     }
 564
 565     # OK, the patron can issue !!!
 566     return;
 567 }
 568
 569 =head2 CanBookBeIssued
 570
 571   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 572                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 573
 574 Check if a book can be issued.
 575
 576 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 577
 578 IMPORTANT: The assumption by users of this routine is that causes blocking
 579 the issue are keyed by uppercase labels and other returned
 580 data is keyed in lower case!
 581
 582 =over 4
 583
 584 =item C<$patron> is a Koha::Patron
 585
 586 =item C<$barcode> is the bar code of the book being issued.
 587
 588 =item C<$duedates> is a DateTime object.
 589
 590 =item C<$inprocess> boolean switch
 591
 592 =item C<$ignore_reserves> boolean switch
 593
 594 =item C<$params> Hashref of additional parameters
 595
 596 Available keys:
 597     override_high_holds - Ignore high holds
 598     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 599
 600 =back
 601
 602 Returns :
 603
 604 =over 4
 605
 606 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 607 Possible values are :
 608
 609 =back
 610
 611 =head3 INVALID_DATE
 612
 613 sticky due date is invalid
 614
 615 =head3 GNA
 616
 617 borrower gone with no address
 618
 619 =head3 CARD_LOST
 620
 621 borrower declared it's card lost
 622
 623 =head3 DEBARRED
 624
 625 borrower debarred
 626
 627 =head3 UNKNOWN_BARCODE
 628
 629 barcode unknown
 630
 631 =head3 NOT_FOR_LOAN
 632
 633 item is not for loan
 634
 635 =head3 WTHDRAWN
 636
 637 item withdrawn.
 638
 639 =head3 RESTRICTED
 640
 641 item is restricted (set by ??)
 642
 643 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 644 could be prevented, but ones that can be overriden by the operator.
 645
 646 Possible values are :
 647
 648 =head3 DEBT
 649
 650 borrower has debts.
 651
 652 =head3 RENEW_ISSUE
 653
 654 renewing, not issuing
 655
 656 =head3 ISSUED_TO_ANOTHER
 657
 658 issued to someone else.
 659
 660 =head3 RESERVED
 661
 662 reserved for someone else.
 663
 664 =head3 INVALID_DATE
 665
 666 sticky due date is invalid or due date in the past
 667
 668 =head3 TOO_MANY
 669
 670 if the borrower borrows to much things
 671
 672 =cut
 673
 674 sub CanBookBeIssued {
 675     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 676     my %needsconfirmation;    # filled with problems that needs confirmations
 677     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 678     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 679     my %messages;             # filled with information messages that should be displayed.
 680
 681     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 682     my $override_high_holds = $params->{override_high_holds} || 0;
 683
 684     my $item_object = Koha::Items->find({barcode => $barcode });
 685
 686     # MANDATORY CHECKS - unless item exists, nothing else matters
 687     unless ( $item_object ) {
 688         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 689     }
 690     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 691
 692     my $item_unblessed = $item_object->unblessed; # Transition...
 693     my $issue = $item_object->checkout;
 694     my $biblio = $item_object->biblio;
 695
 696     my $biblioitem = $biblio->biblioitem;
 697     my $effective_itemtype = $item_object->effective_itemtype;
 698     my $dbh             = C4::Context->dbh;
 699     my $patron_unblessed = $patron->unblessed;
 700
 701     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 702     #
 703     # DUE DATE is OK ? -- should already have checked.
 704     #
 705     if ($duedate && ref $duedate ne 'DateTime') {
 706         $duedate = dt_from_string($duedate);
 707     }
 708     my $now = DateTime->now( time_zone => C4::Context->tz() );
 709     unless ( $duedate ) {
 710         my $issuedate = $now->clone();
 711
 712         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 713
 714         # Offline circ calls AddIssue directly, doesn't run through here
 715         #  So issuingimpossible should be ok.
 716     }
 717
 718     my $fees = Koha::Charges::Fees->new(
 719         {
 720             patron    => $patron,
 721             library   => $circ_library,
 722             item      => $item_object,
 723             to_date   => $duedate,
 724         }
 725     );
 726
 727     if ($duedate) {
 728         my $today = $now->clone();
 729         $today->truncate( to => 'minute');
 730         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 731             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 732         }
 733     } else {
 734             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 735     }
 736
 737     #
 738     # BORROWER STATUS
 739     #
 740     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 741         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 742         &UpdateStats({
 743                      branch => C4::Context->userenv->{'branch'},
 744                      type => 'localuse',
 745                      itemnumber => $item_object->itemnumber,
 746                      itemtype => $effective_itemtype,
 747                      borrowernumber => $patron->borrowernumber,
 748                      ccode => $item_object->ccode}
 749                     );
 750         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 751         return( { STATS => 1 }, {});
 752     }
 753
 754     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 755         $issuingimpossible{GNA} = 1;
 756     }
 757
 758     if ( $patron->lost && $patron->lost == 1 ) {
 759         $issuingimpossible{CARD_LOST} = 1;
 760     }
 761     if ( $patron->is_debarred ) {
 762         $issuingimpossible{DEBARRED} = 1;
 763     }
 764
 765     if ( $patron->is_expired ) {
 766         $issuingimpossible{EXPIRED} = 1;
 767     }
 768
 769     #
 770     # BORROWER STATUS
 771     #
 772
 773     # DEBTS
 774     my $account = $patron->account;
 775     my $balance = $account->balance;
 776     my $non_issues_charges = $account->non_issues_charges;
 777     my $other_charges = $balance - $non_issues_charges;
 778
 779     my $amountlimit = C4::Context->preference("noissuescharge");
 780     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 781     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 782
 783     # Check the debt of this patrons guarantees
 784     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 785     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 786     if ( defined $no_issues_charge_guarantees ) {
 787         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 788         my $guarantees_non_issues_charges;
 789         foreach my $g ( @guarantees ) {
 790             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 791         }
 792
 793         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 794             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 795         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 796             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 797         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 798             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 799         }
 800     }
 801
 802     if ( C4::Context->preference("IssuingInProcess") ) {
 803         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 804             $issuingimpossible{DEBT} = $non_issues_charges;
 805         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 806             $needsconfirmation{DEBT} = $non_issues_charges;
 807         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 808             $needsconfirmation{DEBT} = $non_issues_charges;
 809         }
 810     }
 811     else {
 812         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 813             $needsconfirmation{DEBT} = $non_issues_charges;
 814         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 815             $issuingimpossible{DEBT} = $non_issues_charges;
 816         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 817             $needsconfirmation{DEBT} = $non_issues_charges;
 818         }
 819     }
 820
 821     if ($balance > 0 && $other_charges > 0) {
 822         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 823     }
 824
 825     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 826     $patron_unblessed = $patron->unblessed;
 827
 828     if ( my $debarred_date = $patron->is_debarred ) {
 829          # patron has accrued fine days or has a restriction. $count is a date
 830         if ($debarred_date eq '9999-12-31') {
 831             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 832         }
 833         else {
 834             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 835         }
 836     } elsif ( my $num_overdues = $patron->has_overdues ) {
 837         ## patron has outstanding overdue loans
 838         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 839             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 840         }
 841         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 842             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 843         }
 844     }
 845
 846     #
 847     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 848     #
 849     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 850
 851         # Already issued to current borrower.
 852         # If it is an on-site checkout if it can be switched to a normal checkout
 853         # or ask whether the loan should be renewed
 854
 855         if ( $issue->onsite_checkout
 856                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 857             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 858         } else {
 859             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 860                 $patron->borrowernumber,
 861                 $item_object->itemnumber,
 862             );
 863             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 864                 if ( $renewerror eq 'onsite_checkout' ) {
 865                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 866                 }
 867                 else {
 868                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 869                 }
 870             }
 871             else {
 872                 $needsconfirmation{RENEW_ISSUE} = 1;
 873             }
 874         }
 875     }
 876     elsif ( $issue ) {
 877
 878         # issued to someone else
 879
 880         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 881
 882         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 883
 884         unless ( $can_be_returned ) {
 885             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 886             $issuingimpossible{branch_to_return} = $message;
 887         } else {
 888             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 889                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 890             } else {
 891             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 892             $needsconfirmation{issued_firstname} = $patron->firstname;
 893             $needsconfirmation{issued_surname} = $patron->surname;
 894             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 895             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 896             }
 897         }
 898     }
 899
 900     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 901     #
 902     my $switch_onsite_checkout = (
 903           C4::Context->preference('SwitchOnSiteCheckouts')
 904       and $issue
 905       and $issue->onsite_checkout
 906       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 907     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 908     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 909     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 910         if ( $toomany->{max_allowed} == 0 ) {
 911             $needsconfirmation{PATRON_CANT} = 1;
 912         }
 913         if ( C4::Context->preference("AllowTooManyOverride") ) {
 914             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 915             $needsconfirmation{current_loan_count} = $toomany->{count};
 916             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 917         } else {
 918             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 919             $issuingimpossible{current_loan_count} = $toomany->{count};
 920             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 921         }
 922     }
 923
 924     #
 925     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 926     #
 927     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 928     my $wants_check = $patron->wants_check_for_previous_checkout;
 929     $needsconfirmation{PREVISSUE} = 1
 930         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
 931
 932     #
 933     # ITEM CHECKING
 934     #
 935     if ( $item_object->notforloan )
 936     {
 937         if(!C4::Context->preference("AllowNotForLoanOverride")){
 938             $issuingimpossible{NOT_FOR_LOAN} = 1;
 939             $issuingimpossible{item_notforloan} = $item_object->notforloan;
 940         }else{
 941             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 942             $needsconfirmation{item_notforloan} = $item_object->notforloan;
 943         }
 944     }
 945     else {
 946         # we have to check itemtypes.notforloan also
 947         if (C4::Context->preference('item-level_itypes')){
 948             # this should probably be a subroutine
 949             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 950             $sth->execute($effective_itemtype);
 951             my $notforloan=$sth->fetchrow_hashref();
 952             if ($notforloan->{'notforloan'}) {
 953                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 954                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 955                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 956                 } else {
 957                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 958                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 959                 }
 960             }
 961         }
 962         else {
 963             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
 964             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
 965                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 966                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 967                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 968                 } else {
 969                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 970                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 971                 }
 972             }
 973         }
 974     }
 975     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
 976     {
 977         $issuingimpossible{WTHDRAWN} = 1;
 978     }
 979     if (   $item_object->restricted
 980         && $item_object->restricted == 1 )
 981     {
 982         $issuingimpossible{RESTRICTED} = 1;
 983     }
 984     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 985         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
 986         my $code = $av->count ? $av->next->lib : '';
 987         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 988         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 989     }
 990     if ( C4::Context->preference("IndependentBranches") ) {
 991         my $userenv = C4::Context->userenv;
 992         unless ( C4::Context->IsSuperLibrarian() ) {
 993             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
 994             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
 995                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 996                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
 997             }
 998             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
 999               if ( $patron->branchcode ne $userenv->{branch} );
1000         }
1001     }
1002
1003     #
1004     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1005     #
1006     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1007     if ($rentalConfirmation) {
1008         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1009
1010         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1011         if ($itemtype_object) {
1012             my $accumulate_charge = $fees->accumulate_rentalcharge();
1013             if ( $accumulate_charge > 0 ) {
1014                 $rentalCharge += $accumulate_charge;
1015             }
1016         }
1017
1018         if ( $rentalCharge > 0 ) {
1019             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1020         }
1021     }
1022
1023     unless ( $ignore_reserves ) {
1024         # See if the item is on reserve.
1025         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1026         if ($restype) {
1027             my $resbor = $res->{'borrowernumber'};
1028             if ( $resbor ne $patron->borrowernumber ) {
1029                 my $patron = Koha::Patrons->find( $resbor );
1030                 if ( $restype eq "Waiting" )
1031                 {
1032                     # The item is on reserve and waiting, but has been
1033                     # reserved by some other patron.
1034                     $needsconfirmation{RESERVE_WAITING} = 1;
1035                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1036                     $needsconfirmation{'ressurname'} = $patron->surname;
1037                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1038                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1039                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1040                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1041                 }
1042                 elsif ( $restype eq "Reserved" ) {
1043                     # The item is on reserve for someone else.
1044                     $needsconfirmation{RESERVED} = 1;
1045                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1046                     $needsconfirmation{'ressurname'} = $patron->surname;
1047                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1048                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1049                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1050                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1051                 }
1052             }
1053         }
1054     }
1055
1056     ## CHECK AGE RESTRICTION
1057     my $agerestriction  = $biblioitem->agerestriction;
1058     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1059     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1060         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1061             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1062         }
1063         else {
1064             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1065         }
1066     }
1067
1068     ## check for high holds decreasing loan period
1069     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1070         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1071
1072         if ( $check->{exceeded} ) {
1073             if ($override_high_holds) {
1074                 $alerts{HIGHHOLDS} = {
1075                     num_holds  => $check->{outstanding},
1076                     duration   => $check->{duration},
1077                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1078                 };
1079             }
1080             else {
1081                 $needsconfirmation{HIGHHOLDS} = {
1082                     num_holds  => $check->{outstanding},
1083                     duration   => $check->{duration},
1084                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1085                 };
1086             }
1087         }
1088     }
1089
1090     if (
1091         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1092         # don't do the multiple loans per bib check if we've
1093         # already determined that we've got a loan on the same item
1094         !$issuingimpossible{NO_MORE_RENEWALS} &&
1095         !$needsconfirmation{RENEW_ISSUE}
1096     ) {
1097         # Check if borrower has already issued an item from the same biblio
1098         # Only if it's not a subscription
1099         my $biblionumber = $item_object->biblionumber;
1100         require C4::Serials;
1101         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1102         unless ($is_a_subscription) {
1103             # FIXME Should be $patron->checkouts($args);
1104             my $checkouts = Koha::Checkouts->search(
1105                 {
1106                     borrowernumber => $patron->borrowernumber,
1107                     biblionumber   => $biblionumber,
1108                 },
1109                 {
1110                     join => 'item',
1111                 }
1112             );
1113             # if we get here, we don't already have a loan on this item,
1114             # so if there are any loans on this bib, ask for confirmation
1115             if ( $checkouts->count ) {
1116                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1117             }
1118         }
1119     }
1120
1121     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1122 }
1123
1124 =head2 CanBookBeReturned
1125
1126   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1127
1128 Check whether the item can be returned to the provided branch
1129
1130 =over 4
1131
1132 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1133
1134 =item C<$branch> is the branchcode where the return is taking place
1135
1136 =back
1137
1138 Returns:
1139
1140 =over 4
1141
1142 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1143
1144 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1145
1146 =back
1147
1148 =cut
1149
1150 sub CanBookBeReturned {
1151   my ($item, $branch) = @_;
1152   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1153
1154   # assume return is allowed to start
1155   my $allowed = 1;
1156   my $message;
1157
1158   # identify all cases where return is forbidden
1159   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1160      $allowed = 0;
1161      $message = $item->{'homebranch'};
1162   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1163      $allowed = 0;
1164      $message = $item->{'holdingbranch'};
1165   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1166      $allowed = 0;
1167      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1168   }
1169
1170   return ($allowed, $message);
1171 }
1172
1173 =head2 CheckHighHolds
1174
1175     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1176     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1177     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1178
1179 =cut
1180
1181 sub checkHighHolds {
1182     my ( $item, $borrower ) = @_;
1183     my $branchcode = _GetCircControlBranch( $item, $borrower );
1184     my $item_object = Koha::Items->find( $item->{itemnumber} );
1185
1186     my $return_data = {
1187         exceeded    => 0,
1188         outstanding => 0,
1189         duration    => 0,
1190         due_date    => undef,
1191     };
1192
1193     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1194
1195     if ( $holds->count() ) {
1196         $return_data->{outstanding} = $holds->count();
1197
1198         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1199         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1200         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1201
1202         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1203
1204         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1205
1206             # static means just more than a given number of holds on the record
1207
1208             # If the number of holds is less than the threshold, we can stop here
1209             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1210                 return $return_data;
1211             }
1212         }
1213         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1214
1215             # dynamic means X more than the number of holdable items on the record
1216
1217             # let's get the items
1218             my @items = $holds->next()->biblio()->items()->as_list;
1219
1220             # Remove any items with status defined to be ignored even if the would not make item unholdable
1221             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1222                 @items = grep { !$_->$status } @items;
1223             }
1224
1225             # Remove any items that are not holdable for this patron
1226             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber )->{status} eq 'OK' } @items;
1227
1228             my $items_count = scalar @items;
1229
1230             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1231
1232             # If the number of holds is less than the count of items we have
1233             # plus the number of holds allowed above that count, we can stop here
1234             if ( $holds->count() <= $threshold ) {
1235                 return $return_data;
1236             }
1237         }
1238
1239         my $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1240
1241         my $calendar = Koha::Calendar->new( branchcode => $branchcode );
1242
1243         my $itype = $item_object->effective_itemtype;
1244         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1245
1246         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1247
1248         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1249         $reduced_datedue->set_hour($orig_due->hour);
1250         $reduced_datedue->set_minute($orig_due->minute);
1251         $reduced_datedue->truncate( to => 'minute' );
1252
1253         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1254             $return_data->{exceeded} = 1;
1255             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1256             $return_data->{due_date} = $reduced_datedue;
1257         }
1258     }
1259
1260     return $return_data;
1261 }
1262
1263 =head2 AddIssue
1264
1265   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1266
1267 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1268
1269 =over 4
1270
1271 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1272
1273 =item C<$barcode> is the barcode of the item being issued.
1274
1275 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1276 Calculated if empty.
1277
1278 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1279
1280 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1281 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1282
1283 AddIssue does the following things :
1284
1285   - step 01: check that there is a borrowernumber & a barcode provided
1286   - check for RENEWAL (book issued & being issued to the same patron)
1287       - renewal YES = Calculate Charge & renew
1288       - renewal NO  =
1289           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1290           * RESERVE PLACED ?
1291               - fill reserve if reserve to this patron
1292               - cancel reserve or not, otherwise
1293           * TRANSFERT PENDING ?
1294               - complete the transfert
1295           * ISSUE THE BOOK
1296
1297 =back
1298
1299 =cut
1300
1301 sub AddIssue {
1302     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1303
1304     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1305     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1306     my $auto_renew = $params && $params->{auto_renew};
1307     my $dbh          = C4::Context->dbh;
1308     my $barcodecheck = CheckValidBarcode($barcode);
1309
1310     my $issue;
1311
1312     if ( $datedue && ref $datedue ne 'DateTime' ) {
1313         $datedue = dt_from_string($datedue);
1314     }
1315
1316     # $issuedate defaults to today.
1317     if ( !defined $issuedate ) {
1318         $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1319     }
1320     else {
1321         if ( ref $issuedate ne 'DateTime' ) {
1322             $issuedate = dt_from_string($issuedate);
1323
1324         }
1325     }
1326
1327     # Stop here if the patron or barcode doesn't exist
1328     if ( $borrower && $barcode && $barcodecheck ) {
1329         # find which item we issue
1330         my $item_object = Koha::Items->find({ barcode => $barcode })
1331           or return;    # if we don't get an Item, abort.
1332         my $item_unblessed = $item_object->unblessed;
1333
1334         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1335
1336         # get actual issuing if there is one
1337         my $actualissue = $item_object->checkout;
1338
1339         # check if we just renew the issue.
1340         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1341                 and not $switch_onsite_checkout ) {
1342             $datedue = AddRenewal(
1343                 $borrower->{'borrowernumber'},
1344                 $item_object->itemnumber,
1345                 $branchcode,
1346                 $datedue,
1347                 $issuedate,    # here interpreted as the renewal date
1348             );
1349         }
1350         else {
1351             unless ($datedue) {
1352                 my $itype = $item_object->effective_itemtype;
1353                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1354
1355             }
1356             $datedue->truncate( to => 'minute' );
1357
1358             my $patron = Koha::Patrons->find( $borrower );
1359             my $library = Koha::Libraries->find( $branchcode );
1360             my $fees = Koha::Charges::Fees->new(
1361                 {
1362                     patron    => $patron,
1363                     library   => $library,
1364                     item      => $item_object,
1365                     to_date   => $datedue,
1366                 }
1367             );
1368
1369             # it's NOT a renewal
1370             if ( $actualissue and not $switch_onsite_checkout ) {
1371                 # This book is currently on loan, but not to the person
1372                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1373                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1374                 return unless $allowed;
1375                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1376             }
1377
1378             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1379
1380             # Starting process for transfer job (checking transfert and validate it if we have one)
1381             my ($datesent) = GetTransfers( $item_object->itemnumber );
1382             if ($datesent) {
1383                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1384                 my $sth = $dbh->prepare(
1385                     "UPDATE branchtransfers
1386                         SET datearrived = now(),
1387                         tobranch = ?,
1388                         comments = 'Forced branchtransfer'
1389                     WHERE itemnumber= ? AND datearrived IS NULL"
1390                 );
1391                 $sth->execute( C4::Context->userenv->{'branch'},
1392                     $item_object->itemnumber );
1393             }
1394
1395             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1396             unless ($auto_renew) {
1397                 my $rule = Koha::CirculationRules->get_effective_rule(
1398                     {
1399                         categorycode => $borrower->{categorycode},
1400                         itemtype     => $item_object->effective_itemtype,
1401                         branchcode   => $branchcode,
1402                         rule_name    => 'auto_renew'
1403                     }
1404                 );
1405
1406                 $auto_renew = $rule->rule_value if $rule;
1407             }
1408
1409             # Record in the database the fact that the book was issued.
1410             unless ($datedue) {
1411                 my $itype = $item_object->effective_itemtype;
1412                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1413
1414             }
1415             $datedue->truncate( to => 'minute' );
1416
1417             my $issue_attributes = {
1418                 borrowernumber  => $borrower->{'borrowernumber'},
1419                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1420                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1421                 branchcode      => C4::Context->userenv->{'branch'},
1422                 onsite_checkout => $onsite_checkout,
1423                 auto_renew      => $auto_renew ? 1 : 0,
1424             };
1425
1426             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1427             if ($issue) {
1428                 $issue->set($issue_attributes)->store;
1429             }
1430             else {
1431                 $issue = Koha::Checkout->new(
1432                     {
1433                         itemnumber => $item_object->itemnumber,
1434                         %$issue_attributes,
1435                     }
1436                 )->store;
1437             }
1438             if ( $item_object->location && $item_object->location eq 'CART'
1439                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1440             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1441                 CartToShelf( $item_object->itemnumber );
1442             }
1443
1444             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1445                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1446             }
1447
1448             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1449             if ( $item_object->itemlost ) {
1450                 if (
1451                     Koha::RefundLostItemFeeRules->should_refund(
1452                         {
1453                             current_branch      => C4::Context->userenv->{branch},
1454                             item_home_branch    => $item_object->homebranch,
1455                             item_holding_branch => $item_object->holdingbranch,
1456                         }
1457                     )
1458                   )
1459                 {
1460                     _FixAccountForLostAndFound( $item_object->itemnumber, undef,
1461                         $item_object->barcode );
1462                 }
1463             }
1464
1465             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1466             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1467             $item_object->itemlost(0);
1468             $item_object->onloan($datedue->ymd());
1469             $item_object->datelastborrowed(DateTime->now( time_zone => C4::Context->tz() )->ymd()); # FIXME we should use dt_from_string here
1470             $item_object->store({log_action => 0});
1471             ModDateLastSeen( $item_object->itemnumber );
1472
1473             # If it costs to borrow this book, charge it to the patron's account.
1474             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1475             if ( $charge && $charge > 0 ) {
1476                 AddIssuingCharge( $issue, $charge, 'RENT' );
1477             }
1478
1479             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1480             if ( $itemtype_object ) {
1481                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1482                 if ( $accumulate_charge > 0 ) {
1483                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1484                     $charge += $accumulate_charge;
1485                     $item_unblessed->{charge} = $charge;
1486                 }
1487             }
1488
1489             # Record the fact that this book was issued.
1490             &UpdateStats(
1491                 {
1492                     branch => C4::Context->userenv->{'branch'},
1493                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1494                     amount         => $charge,
1495                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1496                     itemnumber     => $item_object->itemnumber,
1497                     itemtype       => $item_object->effective_itemtype,
1498                     location       => $item_object->location,
1499                     borrowernumber => $borrower->{'borrowernumber'},
1500                     ccode          => $item_object->ccode,
1501                 }
1502             );
1503
1504             # Send a checkout slip.
1505             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1506             my %conditions        = (
1507                 branchcode   => $branchcode,
1508                 categorycode => $borrower->{categorycode},
1509                 item_type    => $item_object->effective_itemtype,
1510                 notification => 'CHECKOUT',
1511             );
1512             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1513                 SendCirculationAlert(
1514                     {
1515                         type     => 'CHECKOUT',
1516                         item     => $item_object->unblessed,
1517                         borrower => $borrower,
1518                         branch   => $branchcode,
1519                     }
1520                 );
1521             }
1522             logaction(
1523                 "CIRCULATION", "ISSUE",
1524                 $borrower->{'borrowernumber'},
1525                 $item_object->itemnumber,
1526             ) if C4::Context->preference("IssueLog");
1527         }
1528     }
1529     return $issue;
1530 }
1531
1532 =head2 GetLoanLength
1533
1534   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1535
1536 Get loan length for an itemtype, a borrower type and a branch
1537
1538 =cut
1539
1540 sub GetLoanLength {
1541     my ( $categorycode, $itemtype, $branchcode ) = @_;
1542
1543     # Set search precedences
1544     my @params = (
1545         {
1546             categorycode => $categorycode,
1547             itemtype     => $itemtype,
1548             branchcode   => $branchcode,
1549         },
1550         {
1551             categorycode => $categorycode,
1552             itemtype     => undef,
1553             branchcode   => $branchcode,
1554         },
1555         {
1556             categorycode => undef,
1557             itemtype     => $itemtype,
1558             branchcode   => $branchcode,
1559         },
1560         {
1561             categorycode => undef,
1562             itemtype     => undef,
1563             branchcode   => $branchcode,
1564         },
1565         {
1566             categorycode => $categorycode,
1567             itemtype     => $itemtype,
1568             branchcode   => undef,
1569         },
1570         {
1571             categorycode => $categorycode,
1572             itemtype     => undef,
1573             branchcode   => undef,
1574         },
1575         {
1576             categorycode => undef,
1577             itemtype     => $itemtype,
1578             branchcode   => undef,
1579         },
1580         {
1581             categorycode => undef,
1582             itemtype     => undef,
1583             branchcode   => undef,
1584         },
1585     );
1586
1587     # Initialize default values
1588     my $rules = {
1589         issuelength   => 0,
1590         renewalperiod => 0,
1591         lengthunit    => 'days',
1592     };
1593
1594     # Search for rules!
1595     foreach my $rule_name (qw( issuelength renewalperiod lengthunit )) {
1596         foreach my $params (@params) {
1597             my $rule = Koha::CirculationRules->search(
1598                 {
1599                     rule_name => $rule_name,
1600                     %$params,
1601                 }
1602             )->next();
1603
1604             if ($rule) {
1605                 $rules->{$rule_name} = $rule->rule_value;
1606                 last;
1607             }
1608         }
1609     }
1610
1611     return $rules;
1612 }
1613
1614
1615 =head2 GetHardDueDate
1616
1617   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1618
1619 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1620
1621 =cut
1622
1623 sub GetHardDueDate {
1624     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1625
1626     my $rules = Koha::CirculationRules->get_effective_rules(
1627         {
1628             categorycode => $borrowertype,
1629             itemtype     => $itemtype,
1630             branchcode   => $branchcode,
1631             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1632         }
1633     );
1634
1635     if ( defined( $rules->{hardduedate} ) ) {
1636         if ( $rules->{hardduedate} ) {
1637             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1638         }
1639         else {
1640             return ( undef, undef );
1641         }
1642     }
1643 }
1644
1645 =head2 GetBranchBorrowerCircRule
1646
1647   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1648
1649 Retrieves circulation rule attributes that apply to the given
1650 branch and patron category, regardless of item type.
1651 The return value is a hashref containing the following key:
1652
1653 patron_maxissueqty - maximum number of loans that a
1654 patron of the given category can have at the given
1655 branch.  If the value is undef, no limit.
1656
1657 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1658 patron of the given category can have at the given
1659 branch.  If the value is undef, no limit.
1660
1661 This will check for different branch/category combinations in the following order:
1662 branch and category
1663 branch only
1664 category only
1665 default branch and category
1666
1667 If no rule has been found in the database, it will default to
1668 the buillt in rule:
1669
1670 patron_maxissueqty - undef
1671 patron_maxonsiteissueqty - undef
1672
1673 C<$branchcode> and C<$categorycode> should contain the
1674 literal branch code and patron category code, respectively - no
1675 wildcards.
1676
1677 =cut
1678
1679 sub GetBranchBorrowerCircRule {
1680     my ( $branchcode, $categorycode ) = @_;
1681
1682     # Initialize default values
1683     my $rules = {
1684         patron_maxissueqty       => undef,
1685         patron_maxonsiteissueqty => undef,
1686     };
1687
1688     # Search for rules!
1689     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1690         my $rule = Koha::CirculationRules->get_effective_rule(
1691             {
1692                 categorycode => $categorycode,
1693                 itemtype     => undef,
1694                 branchcode   => $branchcode,
1695                 rule_name    => $rule_name,
1696             }
1697         );
1698
1699         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1700     }
1701
1702     return $rules;
1703 }
1704
1705 =head2 GetBranchItemRule
1706
1707   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1708
1709 Retrieves circulation rule attributes that apply to the given
1710 branch and item type, regardless of patron category.
1711
1712 The return value is a hashref containing the following keys:
1713
1714 holdallowed => Hold policy for this branch and itemtype. Possible values:
1715   0: No holds allowed.
1716   1: Holds allowed only by patrons that have the same homebranch as the item.
1717   2: Holds allowed from any patron.
1718
1719 returnbranch => branch to which to return item.  Possible values:
1720   noreturn: do not return, let item remain where checked in (floating collections)
1721   homebranch: return to item's home branch
1722   holdingbranch: return to issuer branch
1723
1724 This searches branchitemrules in the following order:
1725
1726   * Same branchcode and itemtype
1727   * Same branchcode, itemtype '*'
1728   * branchcode '*', same itemtype
1729   * branchcode and itemtype '*'
1730
1731 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1732
1733 =cut
1734
1735 sub GetBranchItemRule {
1736     my ( $branchcode, $itemtype ) = @_;
1737
1738     # Search for rules!
1739     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1740         {
1741             branchcode => $branchcode,
1742             itemtype => $itemtype,
1743             rule_name => 'holdallowed',
1744         }
1745     );
1746     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1747         {
1748             branchcode => $branchcode,
1749             itemtype => $itemtype,
1750             rule_name => 'hold_fulfillment_policy',
1751         }
1752     );
1753     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1754         {
1755             branchcode => $branchcode,
1756             itemtype => $itemtype,
1757             rule_name => 'returnbranch',
1758         }
1759     );
1760
1761     # built-in default circulation rule
1762     my $rules;
1763     $rules->{holdallowed} = defined $holdallowed_rule
1764         ? $holdallowed_rule->rule_value
1765         : 2;
1766     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1767         ? $hold_fulfillment_policy_rule->rule_value
1768         : 'any';
1769     $rules->{returnbranch} = defined $returnbranch_rule
1770         ? $returnbranch_rule->rule_value
1771         : 'homebranch';
1772
1773     return $rules;
1774 }
1775
1776 =head2 AddReturn
1777
1778   ($doreturn, $messages, $iteminformation, $borrower) =
1779       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1780
1781 Returns a book.
1782
1783 =over 4
1784
1785 =item C<$barcode> is the bar code of the book being returned.
1786
1787 =item C<$branch> is the code of the branch where the book is being returned.
1788
1789 =item C<$exemptfine> indicates that overdue charges for the item will be
1790 removed. Optional.
1791
1792 =item C<$return_date> allows the default return date to be overridden
1793 by the given return date. Optional.
1794
1795 =back
1796
1797 C<&AddReturn> returns a list of four items:
1798
1799 C<$doreturn> is true iff the return succeeded.
1800
1801 C<$messages> is a reference-to-hash giving feedback on the operation.
1802 The keys of the hash are:
1803
1804 =over 4
1805
1806 =item C<BadBarcode>
1807
1808 No item with this barcode exists. The value is C<$barcode>.
1809
1810 =item C<NotIssued>
1811
1812 The book is not currently on loan. The value is C<$barcode>.
1813
1814 =item C<withdrawn>
1815
1816 This book has been withdrawn/cancelled. The value should be ignored.
1817
1818 =item C<Wrongbranch>
1819
1820 This book has was returned to the wrong branch.  The value is a hashref
1821 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1822 contain the branchcode of the incorrect and correct return library, respectively.
1823
1824 =item C<ResFound>
1825
1826 The item was reserved. The value is a reference-to-hash whose keys are
1827 fields from the reserves table of the Koha database, and
1828 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1829 either C<Waiting>, C<Reserved>, or 0.
1830
1831 =item C<WasReturned>
1832
1833 Value 1 if return is successful.
1834
1835 =item C<NeedsTransfer>
1836
1837 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1838
1839 =back
1840
1841 C<$iteminformation> is a reference-to-hash, giving information about the
1842 returned item from the issues table.
1843
1844 C<$borrower> is a reference-to-hash, giving information about the
1845 patron who last borrowed the book.
1846
1847 =cut
1848
1849 sub AddReturn {
1850     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1851
1852     if ($branch and not Koha::Libraries->find($branch)) {
1853         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1854         undef $branch;
1855     }
1856     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1857     $return_date //= dt_from_string();
1858     my $messages;
1859     my $patron;
1860     my $doreturn       = 1;
1861     my $validTransfert = 0;
1862     my $stat_type = 'return';
1863
1864     # get information on item
1865     my $item = Koha::Items->find({ barcode => $barcode });
1866     unless ($item) {
1867         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1868     }
1869
1870     my $itemnumber = $item->itemnumber;
1871     my $itemtype = $item->effective_itemtype;
1872
1873     my $issue  = $item->checkout;
1874     if ( $issue ) {
1875         $patron = $issue->patron
1876             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1877                 . Dumper($issue->unblessed) . "\n";
1878     } else {
1879         $messages->{'NotIssued'} = $barcode;
1880         $item->onloan(undef)->store if defined $item->onloan;
1881
1882         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1883         $doreturn = 0;
1884         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1885         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1886         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1887            $messages->{'LocalUse'} = 1;
1888            $stat_type = 'localuse';
1889         }
1890     }
1891
1892         # full item data, but no borrowernumber or checkout info (no issue)
1893     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1894         # get the proper branch to which to return the item
1895     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1896         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1897     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
1898
1899     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1900     my $patron_unblessed = $patron ? $patron->unblessed : {};
1901
1902     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1903     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1904     if ($update_loc_rules) {
1905         if (defined $update_loc_rules->{_ALL_}) {
1906             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1907             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1908             if ( $item->location ne $update_loc_rules->{_ALL_}) {
1909                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1910                 $item->location($update_loc_rules->{_ALL_})->store;
1911             }
1912         }
1913         else {
1914             foreach my $key ( keys %$update_loc_rules ) {
1915                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1916                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1917                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1918                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1919                     $item->location($update_loc_rules->{$key})->store;
1920                     last;
1921                 }
1922             }
1923         }
1924     }
1925
1926     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1927     if ($yaml) {
1928         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1929         my $rules;
1930         eval { $rules = YAML::Load($yaml); };
1931         if ($@) {
1932             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1933         }
1934         else {
1935             foreach my $key ( keys %$rules ) {
1936                 if ( $item->notforloan eq $key ) {
1937                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1938                     $item->notforloan($rules->{$key})->store({ log_action => 0 });
1939                     last;
1940                 }
1941             }
1942         }
1943     }
1944
1945     # check if the return is allowed at this branch
1946     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
1947     unless ($returnallowed){
1948         $messages->{'Wrongbranch'} = {
1949             Wrongbranch => $branch,
1950             Rightbranch => $message
1951         };
1952         $doreturn = 0;
1953         return ( $doreturn, $messages, $issue, $patron_unblessed);
1954     }
1955
1956     if ( $item->withdrawn ) { # book has been cancelled
1957         $messages->{'withdrawn'} = 1;
1958         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1959     }
1960
1961     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
1962         $doreturn = 0;
1963     }
1964
1965     # case of a return of document (deal with issues and holdingbranch)
1966     if ($doreturn) {
1967         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1968         $patron or warn "AddReturn without current borrower";
1969
1970         if ($patron) {
1971             eval {
1972                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy );
1973             };
1974             unless ( $@ ) {
1975                 if ( C4::Context->preference('CalculateFinesOnReturn') && !$item->itemlost ) {
1976                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
1977                 }
1978             } else {
1979                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
1980
1981                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
1982             }
1983
1984             # FIXME is the "= 1" right?  This could be the borrower hash.
1985             $messages->{'WasReturned'} = 1;
1986
1987         }
1988
1989         $item->onloan(undef)->store({ log_action => 0 });
1990     }
1991
1992     # the holdingbranch is updated if the document is returned to another location.
1993     # this is always done regardless of whether the item was on loan or not
1994     my $item_holding_branch = $item->holdingbranch;
1995     if ($item->holdingbranch ne $branch) {
1996         UpdateHoldingbranch($branch, $item->itemnumber);
1997         $item->holdingbranch($branch); # update item data holdingbranch too # FIXME I guess this is for the _debar_user_on_return call later
1998     }
1999
2000     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2001     ModDateLastSeen( $item->itemnumber, $leave_item_lost );
2002
2003     # check if we have a transfer for this document
2004     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
2005
2006     # if we have a transfer to do, we update the line of transfers with the datearrived
2007     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2008     if ($datesent) {
2009         if ( $tobranch eq $branch ) {
2010             my $sth = C4::Context->dbh->prepare(
2011                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2012             );
2013             $sth->execute( $item->itemnumber );
2014             # if we have a reservation with valid transfer, we can set it's status to 'W'
2015             C4::Reserves::ModReserveStatus($item->itemnumber, 'W');
2016         } else {
2017             $messages->{'WrongTransfer'}     = $tobranch;
2018             $messages->{'WrongTransferItem'} = $item->itemnumber;
2019         }
2020         $validTransfert = 1;
2021     }
2022
2023     # fix up the accounts.....
2024     if ( $item->itemlost ) {
2025         $messages->{'WasLost'} = 1;
2026         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2027             if (
2028                 Koha::RefundLostItemFeeRules->should_refund(
2029                     {
2030                         current_branch      => C4::Context->userenv->{branch},
2031                         item_home_branch    => $item->homebranch,
2032                         item_holding_branch => $item_holding_branch
2033                     }
2034                 )
2035               )
2036             {
2037                 _FixAccountForLostAndFound( $item->itemnumber,
2038                     $borrowernumber, $barcode );
2039                 $messages->{'LostItemFeeRefunded'} = 1;
2040             }
2041         }
2042     }
2043
2044     # fix up the overdues in accounts...
2045     if ($borrowernumber) {
2046         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2047         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $item->itemnumber...) failed!";  # zero is OK, check defined
2048
2049         if ( $issue and $issue->is_overdue ) {
2050         # fix fine days
2051             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2052             if ($reminder){
2053                 $messages->{'PrevDebarred'} = $debardate;
2054             } else {
2055                 $messages->{'Debarred'} = $debardate if $debardate;
2056             }
2057         # there's no overdue on the item but borrower had been previously debarred
2058         } elsif ( $issue->date_due and $patron->debarred ) {
2059              if ( $patron->debarred eq "9999-12-31") {
2060                 $messages->{'ForeverDebarred'} = $patron->debarred;
2061              } else {
2062                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2063                   $borrower_debar_dt->truncate(to => 'day');
2064                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2065                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2066                       $messages->{'PrevDebarred'} = $patron->debarred;
2067                   }
2068              }
2069         }
2070     }
2071
2072     # find reserves.....
2073     # launch the Checkreserves routine to find any holds
2074     my ($resfound, $resrec);
2075     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2076     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2077     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2078     if ( $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2079         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2080         $resfound = 'Reserved';
2081         $resrec = $hold->unblessed;
2082     }
2083     if ($resfound) {
2084           $resrec->{'ResFound'} = $resfound;
2085         $messages->{'ResFound'} = $resrec;
2086     }
2087
2088     # Record the fact that this book was returned.
2089     UpdateStats({
2090         branch         => $branch,
2091         type           => $stat_type,
2092         itemnumber     => $itemnumber,
2093         itemtype       => $itemtype,
2094         borrowernumber => $borrowernumber,
2095         ccode          => $item->ccode,
2096     });
2097
2098     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2099     if ( $patron ) {
2100         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2101         my %conditions = (
2102             branchcode   => $branch,
2103             categorycode => $patron->categorycode,
2104             item_type    => $itemtype,
2105             notification => 'CHECKIN',
2106         );
2107         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2108             SendCirculationAlert({
2109                 type     => 'CHECKIN',
2110                 item     => $item->unblessed,
2111                 borrower => $patron->unblessed,
2112                 branch   => $branch,
2113             });
2114         }
2115
2116         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2117             if C4::Context->preference("ReturnLog");
2118         }
2119
2120     # Remove any OVERDUES related debarment if the borrower has no overdues
2121     if ( $borrowernumber
2122       && $patron->debarred
2123       && C4::Context->preference('AutoRemoveOverduesRestrictions')
2124       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2125       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2126     ) {
2127         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2128     }
2129
2130     # Check if this item belongs to a biblio record that is attached to an
2131     # ILL request, if it is we need to update the ILL request's status
2132     if (C4::Context->preference('CirculateILL')) {
2133         my $request = Koha::Illrequests->find(
2134             { biblio_id => $item->biblio->biblionumber }
2135         );
2136         $request->status('RET') if $request;
2137     }
2138
2139     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2140     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2141         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2142         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2143             (C4::Context->preference("UseBranchTransferLimits") and
2144              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2145            )) {
2146             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2147             $debug and warn "item: " . Dumper($item->unblessed);
2148             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger);
2149             $messages->{'WasTransfered'} = 1;
2150         } else {
2151             $messages->{'NeedsTransfer'} = $returnbranch;
2152             $messages->{'TransferTrigger'} = $transfer_trigger;
2153         }
2154     }
2155
2156     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2157         my $claims = Koha::Checkouts::ReturnClaims->search(
2158            {
2159                itemnumber => $item->id,
2160                resolution => undef,
2161            }
2162         );
2163
2164         if ( $claims->count ) {
2165             $messages->{ReturnClaims} = $claims;
2166         }
2167     }
2168
2169     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2170 }
2171
2172 =head2 MarkIssueReturned
2173
2174   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2175
2176 Unconditionally marks an issue as being returned by
2177 moving the C<issues> row to C<old_issues> and
2178 setting C<returndate> to the current date.
2179
2180 if C<$returndate> is specified (in iso format), it is used as the date
2181 of the return.
2182
2183 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2184 the old_issue is immediately anonymised
2185
2186 Ideally, this function would be internal to C<C4::Circulation>,
2187 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2188 and offline_circ/process_koc.pl.
2189
2190 =cut
2191
2192 sub MarkIssueReturned {
2193     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2194
2195     # Retrieve the issue
2196     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2197
2198     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2199
2200     my $issue_id = $issue->issue_id;
2201
2202     my $anonymouspatron;
2203     if ( $privacy && $privacy == 2 ) {
2204         # The default of 0 will not work due to foreign key constraints
2205         # The anonymisation will fail if AnonymousPatron is not a valid entry
2206         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2207         # Note that a warning should appear on the about page (System information tab).
2208         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2209         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2210             unless Koha::Patrons->find( $anonymouspatron );
2211     }
2212
2213     my $schema = Koha::Database->schema;
2214
2215     # FIXME Improve the return value and handle it from callers
2216     $schema->txn_do(sub {
2217
2218         # Update the returndate value
2219         if ( $returndate ) {
2220             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2221         }
2222         else {
2223             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2224         }
2225
2226         # Create the old_issues entry
2227         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2228
2229         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2230         if ( $privacy && $privacy == 2) {
2231             $old_checkout->borrowernumber($anonymouspatron)->store;
2232         }
2233
2234         # And finally delete the issue
2235         $issue->delete;
2236
2237         $issue->item->onloan(undef)->store({ log_action => 0 });
2238
2239         if ( C4::Context->preference('StoreLastBorrower') ) {
2240             my $item = Koha::Items->find( $itemnumber );
2241             my $patron = Koha::Patrons->find( $borrowernumber );
2242             $item->last_returned_by( $patron );
2243         }
2244     });
2245
2246     return $issue_id;
2247 }
2248
2249 =head2 _debar_user_on_return
2250
2251     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2252
2253 C<$borrower> borrower hashref
2254
2255 C<$item> item hashref
2256
2257 C<$datedue> date due DateTime object
2258
2259 C<$returndate> DateTime object representing the return time
2260
2261 Internal function, called only by AddReturn that calculates and updates
2262  the user fine days, and debars them if necessary.
2263
2264 Should only be called for overdue returns
2265
2266 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2267 to ease testing.
2268
2269 =cut
2270
2271 sub _calculate_new_debar_dt {
2272     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2273
2274     my $branchcode = _GetCircControlBranch( $item, $borrower );
2275     my $circcontrol = C4::Context->preference('CircControl');
2276     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2277         {   categorycode => $borrower->{categorycode},
2278             itemtype     => $item->{itype},
2279             branchcode   => $branchcode,
2280             rules => [
2281                 'finedays',
2282                 'lengthunit',
2283                 'firstremind',
2284                 'maxsuspensiondays',
2285                 'suspension_chargeperiod',
2286             ]
2287         }
2288     );
2289     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2290     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2291     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2292
2293     return unless $finedays;
2294
2295     # finedays is in days, so hourly loans must multiply by 24
2296     # thus 1 hour late equals 1 day suspension * finedays rate
2297     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2298
2299     # grace period is measured in the same units as the loan
2300     my $grace =
2301       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} );
2302
2303     my $deltadays = DateTime::Duration->new(
2304         days => $chargeable_units
2305     );
2306
2307     if ( $deltadays->subtract($grace)->is_positive() ) {
2308         my $suspension_days = $deltadays * $finedays;
2309
2310         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2311             # No need to / 1 and do not consider / 0
2312             $suspension_days = DateTime::Duration->new(
2313                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2314             );
2315         }
2316
2317         # If the max suspension days is < than the suspension days
2318         # the suspension days is limited to this maximum period.
2319         my $max_sd = $issuing_rule->{maxsuspensiondays};
2320         if ( defined $max_sd && $max_sd ne '' ) {
2321             $max_sd = DateTime::Duration->new( days => $max_sd );
2322             $suspension_days = $max_sd
2323               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2324         }
2325
2326         my ( $has_been_extended );
2327         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2328             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2329             if ( $debarment ) {
2330                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2331                 $has_been_extended = 1;
2332             }
2333         }
2334
2335         my $new_debar_dt;
2336         # Use the calendar or not to calculate the debarment date
2337         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2338             my $calendar = Koha::Calendar->new(
2339                 branchcode => $branchcode,
2340                 days_mode  => 'Calendar'
2341             );
2342             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2343         }
2344         else {
2345             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2346         }
2347         return $new_debar_dt;
2348     }
2349     return;
2350 }
2351
2352 sub _debar_user_on_return {
2353     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2354
2355     $return_date //= dt_from_string();
2356
2357     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2358
2359     return unless $new_debar_dt;
2360
2361     Koha::Patron::Debarments::AddUniqueDebarment({
2362         borrowernumber => $borrower->{borrowernumber},
2363         expiration     => $new_debar_dt->ymd(),
2364         type           => 'SUSPENSION',
2365     });
2366     # if borrower was already debarred but does not get an extra debarment
2367     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2368     my ($new_debarment_str, $is_a_reminder);
2369     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2370         $is_a_reminder = 1;
2371         $new_debarment_str = $borrower->{debarred};
2372     } else {
2373         $new_debarment_str = $new_debar_dt->ymd();
2374     }
2375     # FIXME Should return a DateTime object
2376     return $new_debarment_str, $is_a_reminder;
2377 }
2378
2379 =head2 _FixOverduesOnReturn
2380
2381    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2382
2383 C<$borrowernumber> borrowernumber
2384
2385 C<$itemnumber> itemnumber
2386
2387 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2388
2389 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2390
2391 Internal function
2392
2393 =cut
2394
2395 sub _FixOverduesOnReturn {
2396     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2397     unless( $borrowernumber ) {
2398         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2399         return;
2400     }
2401     unless( $item ) {
2402         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2403         return;
2404     }
2405     unless( $status ) {
2406         warn "_FixOverduesOnReturn() not supplied valid status";
2407         return;
2408     }
2409
2410     my $schema = Koha::Database->schema;
2411
2412     my $result = $schema->txn_do(
2413         sub {
2414             # check for overdue fine
2415             my $accountlines = Koha::Account::Lines->search(
2416                 {
2417                     borrowernumber  => $borrowernumber,
2418                     itemnumber      => $item,
2419                     debit_type_code => 'OVERDUE',
2420                     status          => 'UNRETURNED'
2421                 }
2422             );
2423             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2424
2425             my $accountline = $accountlines->next;
2426             if ($exemptfine) {
2427                 my $amountoutstanding = $accountline->amountoutstanding;
2428
2429                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2430                 my $credit = $account->add_credit(
2431                     {
2432                         amount     => $amountoutstanding,
2433                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2434                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2435                         interface  => C4::Context->interface,
2436                         type       => 'FORGIVEN',
2437                         item_id    => $item
2438                     }
2439                 );
2440
2441                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2442
2443                 $accountline->status('FORGIVEN');
2444
2445                 if (C4::Context->preference("FinesLog")) {
2446                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2447                 }
2448             } else {
2449                 $accountline->status($status);
2450             }
2451
2452             return $accountline->store();
2453         }
2454     );
2455
2456     return $result;
2457 }
2458
2459 =head2 _FixAccountForLostAndFound
2460
2461   &_FixAccountForLostAndFound($itemnumber, [$borrowernumber, $barcode]);
2462
2463 Finds the most recent lost item charge for this item and refunds the borrower
2464 appropriatly, taking into account any payments or writeoffs already applied
2465 against the charge.
2466
2467 Internal function, not exported, called only by AddReturn.
2468
2469 =cut
2470
2471 sub _FixAccountForLostAndFound {
2472     my $itemnumber     = shift or return;
2473     my $borrowernumber = @_ ? shift : undef;
2474     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2475
2476     my $credit;
2477
2478     # check for charge made for lost book
2479     my $accountlines = Koha::Account::Lines->search(
2480         {
2481             itemnumber      => $itemnumber,
2482             debit_type_code => 'LOST',
2483             status          => [ undef, { '<>' => 'FOUND' } ]
2484         },
2485         {
2486             order_by => { -desc => [ 'date', 'accountlines_id' ] }
2487         }
2488     );
2489
2490     return unless $accountlines->count > 0;
2491     my $accountline     = $accountlines->next;
2492     my $total_to_refund = 0;
2493
2494     return unless $accountline->borrowernumber;
2495     my $patron = Koha::Patrons->find( $accountline->borrowernumber );
2496     return unless $patron; # Patron has been deleted, nobody to credit the return to
2497
2498     my $account = $patron->account;
2499
2500     # Use cases
2501     if ( $accountline->amount > $accountline->amountoutstanding ) {
2502         # some amount has been cancelled. collect the offsets that are not writeoffs
2503         # this works because the only way to subtract from this kind of a debt is
2504         # using the UI buttons 'Pay' and 'Write off'
2505         my $credits_offsets = Koha::Account::Offsets->search({
2506             debit_id  => $accountline->id,
2507             credit_id => { '!=' => undef }, # it is not the debit itself
2508             type      => { '!=' => 'Writeoff' },
2509             amount    => { '<'  => 0 } # credits are negative on the DB
2510         });
2511
2512         $total_to_refund = ( $credits_offsets->count > 0 )
2513                             ? $credits_offsets->total * -1 # credits are negative on the DB
2514                             : 0;
2515     }
2516
2517     my $credit_total = $accountline->amountoutstanding + $total_to_refund;
2518
2519     if ( $credit_total > 0 ) {
2520         my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
2521         $credit = $account->add_credit(
2522             {
2523                 amount      => $credit_total,
2524                 description => 'Item found ' . $item_id,
2525                 type        => 'LOST_FOUND',
2526                 interface   => C4::Context->interface,
2527                 library_id  => $branchcode,
2528                 item_id     => $itemnumber
2529             }
2530         );
2531
2532         $credit->apply( { debits => [ $accountline ] } );
2533     }
2534
2535     # Update the account status
2536     $accountline->discard_changes->status('FOUND');
2537     $accountline->store;
2538
2539     $accountline->item->paidfor('')->store({ log_action => 0 });
2540
2541     if ( defined $account and C4::Context->preference('AccountAutoReconcile') ) {
2542         $account->reconcile_balance;
2543     }
2544
2545     return ($credit) ? $credit->id : undef;
2546 }
2547
2548 =head2 _GetCircControlBranch
2549
2550    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2551
2552 Internal function :
2553
2554 Return the library code to be used to determine which circulation
2555 policy applies to a transaction.  Looks up the CircControl and
2556 HomeOrHoldingBranch system preferences.
2557
2558 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2559
2560 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2561
2562 =cut
2563
2564 sub _GetCircControlBranch {
2565     my ($item, $borrower) = @_;
2566     my $circcontrol = C4::Context->preference('CircControl');
2567     my $branch;
2568
2569     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2570         $branch= C4::Context->userenv->{'branch'};
2571     } elsif ($circcontrol eq 'PatronLibrary') {
2572         $branch=$borrower->{branchcode};
2573     } else {
2574         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2575         $branch = $item->{$branchfield};
2576         # default to item home branch if holdingbranch is used
2577         # and is not defined
2578         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2579             $branch = $item->{homebranch};
2580         }
2581     }
2582     return $branch;
2583 }
2584
2585 =head2 GetOpenIssue
2586
2587   $issue = GetOpenIssue( $itemnumber );
2588
2589 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2590
2591 C<$itemnumber> is the item's itemnumber
2592
2593 Returns a hashref
2594
2595 =cut
2596
2597 sub GetOpenIssue {
2598   my ( $itemnumber ) = @_;
2599   return unless $itemnumber;
2600   my $dbh = C4::Context->dbh;
2601   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2602   $sth->execute( $itemnumber );
2603   return $sth->fetchrow_hashref();
2604
2605 }
2606
2607 =head2 GetBiblioIssues
2608
2609   $issues = GetBiblioIssues($biblionumber);
2610
2611 this function get all issues from a biblionumber.
2612
2613 Return:
2614 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2615 tables issues and the firstname,surname & cardnumber from borrowers.
2616
2617 =cut
2618
2619 sub GetBiblioIssues {
2620     my $biblionumber = shift;
2621     return unless $biblionumber;
2622     my $dbh   = C4::Context->dbh;
2623     my $query = "
2624         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2625         FROM issues
2626             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2627             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2628             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2629             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2630         WHERE biblio.biblionumber = ?
2631         UNION ALL
2632         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2633         FROM old_issues
2634             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2635             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2636             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2637             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2638         WHERE biblio.biblionumber = ?
2639         ORDER BY timestamp
2640     ";
2641     my $sth = $dbh->prepare($query);
2642     $sth->execute($biblionumber, $biblionumber);
2643
2644     my @issues;
2645     while ( my $data = $sth->fetchrow_hashref ) {
2646         push @issues, $data;
2647     }
2648     return \@issues;
2649 }
2650
2651 =head2 GetUpcomingDueIssues
2652
2653   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2654
2655 =cut
2656
2657 sub GetUpcomingDueIssues {
2658     my $params = shift;
2659
2660     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2661     my $dbh = C4::Context->dbh;
2662
2663     my $statement = <<END_SQL;
2664 SELECT *
2665 FROM (
2666     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2667     FROM issues
2668     LEFT JOIN items USING (itemnumber)
2669     LEFT OUTER JOIN branches USING (branchcode)
2670     WHERE returndate is NULL
2671 ) tmp
2672 WHERE days_until_due >= 0 AND days_until_due <= ?
2673 END_SQL
2674
2675     my @bind_parameters = ( $params->{'days_in_advance'} );
2676
2677     my $sth = $dbh->prepare( $statement );
2678     $sth->execute( @bind_parameters );
2679     my $upcoming_dues = $sth->fetchall_arrayref({});
2680
2681     return $upcoming_dues;
2682 }
2683
2684 =head2 CanBookBeRenewed
2685
2686   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2687
2688 Find out whether a borrowed item may be renewed.
2689
2690 C<$borrowernumber> is the borrower number of the patron who currently
2691 has the item on loan.
2692
2693 C<$itemnumber> is the number of the item to renew.
2694
2695 C<$override_limit>, if supplied with a true value, causes
2696 the limit on the number of times that the loan can be renewed
2697 (as controlled by the item type) to be ignored. Overriding also allows
2698 to renew sooner than "No renewal before" and to manually renew loans
2699 that are automatically renewed.
2700
2701 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2702 item must currently be on loan to the specified borrower; renewals
2703 must be allowed for the item's type; and the borrower must not have
2704 already renewed the loan. $error will contain the reason the renewal can not proceed
2705
2706 =cut
2707
2708 sub CanBookBeRenewed {
2709     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2710
2711     my $dbh    = C4::Context->dbh;
2712     my $renews = 1;
2713     my $auto_renew = 0;
2714
2715     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2716     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2717     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2718     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2719
2720     my $patron = $issue->patron or return;
2721
2722     # override_limit will override anything else except on_reserve
2723     unless ( $override_limit ){
2724         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2725         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2726             {
2727                 categorycode => $patron->categorycode,
2728                 itemtype     => $item->effective_itemtype,
2729                 branchcode   => $branchcode,
2730                 rules => [
2731                     'renewalsallowed',
2732                     'no_auto_renewal_after',
2733                     'no_auto_renewal_after_hard_limit',
2734                     'lengthunit',
2735                     'norenewalbefore',
2736                 ]
2737             }
2738         );
2739
2740         return ( 0, "too_many" )
2741           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2742
2743         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2744         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2745         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2746         my $restricted  = $patron->is_debarred;
2747         my $hasoverdues = $patron->has_overdues;
2748
2749         if ( $restricted and $restrictionblockrenewing ) {
2750             return ( 0, 'restriction');
2751         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2752             return ( 0, 'overdue');
2753         }
2754
2755         if ( $issue->auto_renew ) {
2756
2757             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2758                 return ( 0, 'auto_account_expired' );
2759             }
2760
2761             if ( defined $issuing_rule->{no_auto_renewal_after}
2762                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2763                 # Get issue_date and add no_auto_renewal_after
2764                 # If this is greater than today, it's too late for renewal.
2765                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2766                 $maximum_renewal_date->add(
2767                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2768                 );
2769                 my $now = dt_from_string;
2770                 if ( $now >= $maximum_renewal_date ) {
2771                     return ( 0, "auto_too_late" );
2772                 }
2773             }
2774             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2775                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2776                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2777                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2778                     return ( 0, "auto_too_late" );
2779                 }
2780             }
2781
2782             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2783                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2784                 my $amountoutstanding =
2785                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2786                   ? $patron->account->balance
2787                   : $patron->account->outstanding_debits->total_outstanding;
2788                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2789                     return ( 0, "auto_too_much_oweing" );
2790                 }
2791             }
2792         }
2793
2794         if ( defined $issuing_rule->{norenewalbefore}
2795             and $issuing_rule->{norenewalbefore} ne "" )
2796         {
2797
2798             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2799             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2800                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2801
2802             # Depending on syspref reset the exact time, only check the date
2803             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2804                 and $issuing_rule->{lengthunit} eq 'days' )
2805             {
2806                 $soonestrenewal->truncate( to => 'day' );
2807             }
2808
2809             if ( $soonestrenewal > DateTime->now( time_zone => C4::Context->tz() ) )
2810             {
2811                 return ( 0, "auto_too_soon" ) if $issue->auto_renew;
2812                 return ( 0, "too_soon" );
2813             }
2814             elsif ( $issue->auto_renew ) {
2815                 $auto_renew = 1;
2816             }
2817         }
2818
2819         # Fallback for automatic renewals:
2820         # If norenewalbefore is undef, don't renew before due date.
2821         if ( $issue->auto_renew && !$auto_renew ) {
2822             my $now = dt_from_string;
2823             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2824                 $auto_renew = 1;
2825             } else {
2826                 return ( 0, "auto_too_soon" );
2827             }
2828         }
2829     }
2830
2831     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2832
2833     # This item can fill one or more unfilled reserve, can those unfilled reserves
2834     # all be filled by other available items?
2835     if ( $resfound
2836         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2837     {
2838         my $schema = Koha::Database->new()->schema();
2839
2840         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2841         if ($item_holds) {
2842             # There is an item level hold on this item, no other item can fill the hold
2843             $resfound = 1;
2844         }
2845         else {
2846
2847             # Get all other items that could possibly fill reserves
2848             my @itemnumbers = $schema->resultset('Item')->search(
2849                 {
2850                     biblionumber => $resrec->{biblionumber},
2851                     onloan       => undef,
2852                     notforloan   => 0,
2853                     -not         => { itemnumber => $itemnumber }
2854                 },
2855                 { columns => 'itemnumber' }
2856             )->get_column('itemnumber')->all();
2857
2858             # Get all other reserves that could have been filled by this item
2859             my @borrowernumbers;
2860             while (1) {
2861                 my ( $reserve_found, $reserve, undef ) =
2862                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2863
2864                 if ($reserve_found) {
2865                     push( @borrowernumbers, $reserve->{borrowernumber} );
2866                 }
2867                 else {
2868                     last;
2869                 }
2870             }
2871
2872             # If the count of the union of the lists of reservable items for each borrower
2873             # is equal or greater than the number of borrowers, we know that all reserves
2874             # can be filled with available items. We can get the union of the sets simply
2875             # by pushing all the elements onto an array and removing the duplicates.
2876             my @reservable;
2877             my %patrons;
2878             ITEM: foreach my $itemnumber (@itemnumbers) {
2879                 my $item = Koha::Items->find( $itemnumber );
2880                 next if IsItemOnHoldAndFound( $itemnumber );
2881                 for my $borrowernumber (@borrowernumbers) {
2882                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2883                     next unless IsAvailableForItemLevelRequest($item, $patron);
2884                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2885
2886                     push @reservable, $itemnumber;
2887                     if (@reservable >= @borrowernumbers) {
2888                         $resfound = 0;
2889                         last ITEM;
2890                     }
2891                     last;
2892                 }
2893             }
2894         }
2895     }
2896     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2897     return ( 0, "auto_renew" ) if $auto_renew && !$override_limit; # 0 if auto-renewal should not succeed
2898
2899     return ( 1, undef );
2900 }
2901
2902 =head2 AddRenewal
2903
2904   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2905
2906 Renews a loan.
2907
2908 C<$borrowernumber> is the borrower number of the patron who currently
2909 has the item.
2910
2911 C<$itemnumber> is the number of the item to renew.
2912
2913 C<$branch> is the library where the renewal took place (if any).
2914            The library that controls the circ policies for the renewal is retrieved from the issues record.
2915
2916 C<$datedue> can be a DateTime object used to set the due date.
2917
2918 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2919 this parameter is not supplied, lastreneweddate is set to the current date.
2920
2921 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2922 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2923 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2924 syspref)
2925
2926 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2927 from the book's item type.
2928
2929 =cut
2930
2931 sub AddRenewal {
2932     my $borrowernumber  = shift;
2933     my $itemnumber      = shift or return;
2934     my $branch          = shift;
2935     my $datedue         = shift;
2936     my $lastreneweddate = shift || DateTime->now(time_zone => C4::Context->tz);
2937     my $skipfinecalc    = shift;
2938
2939     my $item_object   = Koha::Items->find($itemnumber) or return;
2940     my $biblio = $item_object->biblio;
2941     my $issue  = $item_object->checkout;
2942     my $item_unblessed = $item_object->unblessed;
2943
2944     my $dbh = C4::Context->dbh;
2945
2946     return unless $issue;
2947
2948     $borrowernumber ||= $issue->borrowernumber;
2949
2950     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2951         carp 'Invalid date passed to AddRenewal.';
2952         return;
2953     }
2954
2955     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2956     my $patron_unblessed = $patron->unblessed;
2957
2958     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
2959
2960     my $schema = Koha::Database->schema;
2961     $schema->txn_do(sub{
2962
2963         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
2964             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2965         }
2966         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
2967
2968         # If the due date wasn't specified, calculate it by adding the
2969         # book's loan length to today's date or the current due date
2970         # based on the value of the RenewalPeriodBase syspref.
2971         my $itemtype = $item_object->effective_itemtype;
2972         unless ($datedue) {
2973
2974             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2975                                             dt_from_string( $issue->date_due, 'sql' ) :
2976                                             DateTime->now( time_zone => C4::Context->tz());
2977             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
2978         }
2979
2980         my $fees = Koha::Charges::Fees->new(
2981             {
2982                 patron    => $patron,
2983                 library   => $circ_library,
2984                 item      => $item_object,
2985                 from_date => dt_from_string( $issue->date_due, 'sql' ),
2986                 to_date   => dt_from_string($datedue),
2987             }
2988         );
2989
2990         # Update the issues record to have the new due date, and a new count
2991         # of how many times it has been renewed.
2992         my $renews = ( $issue->renewals || 0 ) + 1;
2993         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2994                                 WHERE borrowernumber=?
2995                                 AND itemnumber=?"
2996         );
2997
2998         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2999
3000         # Update the renewal count on the item, and tell zebra to reindex
3001         $renews = ( $item_object->renewals || 0 ) + 1;
3002         $item_object->renewals($renews);
3003         $item_object->onloan($datedue);
3004         $item_object->store({ log_action => 0 });
3005
3006         # Charge a new rental fee, if applicable
3007         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3008         if ( $charge > 0 ) {
3009             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3010         }
3011
3012         # Charge a new accumulate rental fee, if applicable
3013         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3014         if ( $itemtype_object ) {
3015             my $accumulate_charge = $fees->accumulate_rentalcharge();
3016             if ( $accumulate_charge > 0 ) {
3017                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3018             }
3019             $charge += $accumulate_charge;
3020         }
3021
3022         # Send a renewal slip according to checkout alert preferencei
3023         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3024             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3025             my %conditions        = (
3026                 branchcode   => $branch,
3027                 categorycode => $patron->categorycode,
3028                 item_type    => $itemtype,
3029                 notification => 'CHECKOUT',
3030             );
3031             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3032                 SendCirculationAlert(
3033                     {
3034                         type     => 'RENEWAL',
3035                         item     => $item_unblessed,
3036                         borrower => $patron->unblessed,
3037                         branch   => $branch,
3038                     }
3039                 );
3040             }
3041         }
3042
3043         # Remove any OVERDUES related debarment if the borrower has no overdues
3044         if ( $patron
3045           && $patron->is_debarred
3046           && ! $patron->has_overdues
3047           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3048         ) {
3049             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3050         }
3051
3052         unless ( C4::Context->interface eq 'opac' ) { #if from opac we are obeying OpacRenewalBranch as calculated in opac-renew.pl
3053             $branch = ( C4::Context->userenv && defined C4::Context->userenv->{branch} ) ? C4::Context->userenv->{branch} : $branch;
3054         }
3055
3056         # Add the renewal to stats
3057         UpdateStats(
3058             {
3059                 branch         => $branch,
3060                 type           => 'renew',
3061                 amount         => $charge,
3062                 itemnumber     => $itemnumber,
3063                 itemtype       => $itemtype,
3064                 location       => $item_object->location,
3065                 borrowernumber => $borrowernumber,
3066                 ccode          => $item_object->ccode,
3067             }
3068         );
3069
3070         #Log the renewal
3071         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3072     });
3073
3074     return $datedue;
3075 }
3076
3077 sub GetRenewCount {
3078     # check renewal status
3079     my ( $bornum, $itemno ) = @_;
3080     my $dbh           = C4::Context->dbh;
3081     my $renewcount    = 0;
3082     my $renewsallowed = 0;
3083     my $renewsleft    = 0;
3084
3085     my $patron = Koha::Patrons->find( $bornum );
3086     my $item   = Koha::Items->find($itemno);
3087
3088     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3089
3090     # Look in the issues table for this item, lent to this borrower,
3091     # and not yet returned.
3092
3093     # FIXME - I think this function could be redone to use only one SQL call.
3094     my $sth = $dbh->prepare(
3095         "select * from issues
3096                                 where (borrowernumber = ?)
3097                                 and (itemnumber = ?)"
3098     );
3099     $sth->execute( $bornum, $itemno );
3100     my $data = $sth->fetchrow_hashref;
3101     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3102     # $item and $borrower should be calculated
3103     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3104
3105     my $rule = Koha::CirculationRules->get_effective_rule(
3106         {
3107             categorycode => $patron->categorycode,
3108             itemtype     => $item->effective_itemtype,
3109             branchcode   => $branchcode,
3110             rule_name    => 'renewalsallowed',
3111         }
3112     );
3113
3114     $renewsallowed = $rule ? $rule->rule_value : 0;
3115     $renewsleft    = $renewsallowed - $renewcount;
3116     if($renewsleft < 0){ $renewsleft = 0; }
3117     return ( $renewcount, $renewsallowed, $renewsleft );
3118 }
3119
3120 =head2 GetSoonestRenewDate
3121
3122   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3123
3124 Find out the soonest possible renew date of a borrowed item.
3125
3126 C<$borrowernumber> is the borrower number of the patron who currently
3127 has the item on loan.
3128
3129 C<$itemnumber> is the number of the item to renew.
3130
3131 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3132 renew date, based on the value "No renewal before" of the applicable
3133 issuing rule. Returns the current date if the item can already be
3134 renewed, and returns undefined if the borrower, loan, or item
3135 cannot be found.
3136
3137 =cut
3138
3139 sub GetSoonestRenewDate {
3140     my ( $borrowernumber, $itemnumber ) = @_;
3141
3142     my $dbh = C4::Context->dbh;
3143
3144     my $item      = Koha::Items->find($itemnumber)      or return;
3145     my $itemissue = $item->checkout or return;
3146
3147     $borrowernumber ||= $itemissue->borrowernumber;
3148     my $patron = Koha::Patrons->find( $borrowernumber )
3149       or return;
3150
3151     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3152     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3153         {   categorycode => $patron->categorycode,
3154             itemtype     => $item->effective_itemtype,
3155             branchcode   => $branchcode,
3156             rules => [
3157                 'norenewalbefore',
3158                 'lengthunit',
3159             ]
3160         }
3161     );
3162
3163     my $now = dt_from_string;
3164     return $now unless $issuing_rule;
3165
3166     if ( defined $issuing_rule->{norenewalbefore}
3167         and $issuing_rule->{norenewalbefore} ne "" )
3168     {
3169         my $soonestrenewal =
3170           dt_from_string( $itemissue->date_due )->subtract(
3171             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3172
3173         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3174             and $issuing_rule->{lengthunit} eq 'days' )
3175         {
3176             $soonestrenewal->truncate( to => 'day' );
3177         }
3178         return $soonestrenewal if $now < $soonestrenewal;
3179     }
3180     return $now;
3181 }
3182
3183 =head2 GetLatestAutoRenewDate
3184
3185   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3186
3187 Find out the latest possible auto renew date of a borrowed item.
3188
3189 C<$borrowernumber> is the borrower number of the patron who currently
3190 has the item on loan.
3191
3192 C<$itemnumber> is the number of the item to renew.
3193
3194 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3195 auto renew date, based on the value "No auto renewal after" and the "No auto
3196 renewal after (hard limit) of the applicable issuing rule.
3197 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3198 or item cannot be found.
3199
3200 =cut
3201
3202 sub GetLatestAutoRenewDate {
3203     my ( $borrowernumber, $itemnumber ) = @_;
3204
3205     my $dbh = C4::Context->dbh;
3206
3207     my $item      = Koha::Items->find($itemnumber)  or return;
3208     my $itemissue = $item->checkout                 or return;
3209
3210     $borrowernumber ||= $itemissue->borrowernumber;
3211     my $patron = Koha::Patrons->find( $borrowernumber )
3212       or return;
3213
3214     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3215     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3216         {
3217             categorycode => $patron->categorycode,
3218             itemtype     => $item->effective_itemtype,
3219             branchcode   => $branchcode,
3220             rules => [
3221                 'no_auto_renewal_after',
3222                 'no_auto_renewal_after_hard_limit',
3223                 'lengthunit',
3224             ]
3225         }
3226     );
3227
3228     return unless $circulation_rules;
3229     return
3230       if ( not $circulation_rules->{no_auto_renewal_after}
3231             or $circulation_rules->{no_auto_renewal_after} eq '' )
3232       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3233              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3234
3235     my $maximum_renewal_date;
3236     if ( $circulation_rules->{no_auto_renewal_after} ) {
3237         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3238         $maximum_renewal_date->add(
3239             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3240         );
3241     }
3242
3243     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3244         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3245         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3246     }
3247     return $maximum_renewal_date;
3248 }
3249
3250
3251 =head2 GetIssuingCharges
3252
3253   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3254
3255 Calculate how much it would cost for a given patron to borrow a given
3256 item, including any applicable discounts.
3257
3258 C<$itemnumber> is the item number of item the patron wishes to borrow.
3259
3260 C<$borrowernumber> is the patron's borrower number.
3261
3262 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3263 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3264 if it's a video).
3265
3266 =cut
3267
3268 sub GetIssuingCharges {
3269
3270     # calculate charges due
3271     my ( $itemnumber, $borrowernumber ) = @_;
3272     my $charge = 0;
3273     my $dbh    = C4::Context->dbh;
3274     my $item_type;
3275
3276     # Get the book's item type and rental charge (via its biblioitem).
3277     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3278         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3279     $charge_query .= (C4::Context->preference('item-level_itypes'))
3280         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3281         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3282
3283     $charge_query .= ' WHERE items.itemnumber =?';
3284
3285     my $sth = $dbh->prepare($charge_query);
3286     $sth->execute($itemnumber);
3287     if ( my $item_data = $sth->fetchrow_hashref ) {
3288         $item_type = $item_data->{itemtype};
3289         $charge    = $item_data->{rentalcharge};
3290         my $branch = C4::Context::mybranch();
3291         my $patron = Koha::Patrons->find( $borrowernumber );
3292         my $discount = _get_discount_from_rule($patron->categorycode, $branch, $item_type);
3293         if ($discount) {
3294             # We may have multiple rules so get the most specific
3295             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3296         }
3297         if ($charge) {
3298             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3299         }
3300     }
3301
3302     return ( $charge, $item_type );
3303 }
3304
3305 # Select most appropriate discount rule from those returned
3306 sub _get_discount_from_rule {
3307     my ($categorycode, $branchcode, $itemtype) = @_;
3308
3309     # Set search precedences
3310     my @params = (
3311         {
3312             branchcode   => $branchcode,
3313             itemtype     => $itemtype,
3314             categorycode => $categorycode,
3315         },
3316         {
3317             branchcode   => undef,
3318             categorycode => $categorycode,
3319             itemtype     => $itemtype,
3320         },
3321         {
3322             branchcode   => $branchcode,
3323             categorycode => $categorycode,
3324             itemtype     => undef,
3325         },
3326         {
3327             branchcode   => undef,
3328             categorycode => $categorycode,
3329             itemtype     => undef,
3330         },
3331     );
3332
3333     foreach my $params (@params) {
3334         my $rule = Koha::CirculationRules->search(
3335             {
3336                 rule_name => 'rentaldiscount',
3337                 %$params,
3338             }
3339         )->next();
3340
3341         return $rule->rule_value if $rule;
3342     }
3343
3344     # none of the above
3345     return 0;
3346 }
3347
3348 =head2 AddIssuingCharge
3349
3350   &AddIssuingCharge( $checkout, $charge, $type )
3351
3352 =cut
3353
3354 sub AddIssuingCharge {
3355     my ( $checkout, $charge, $type ) = @_;
3356
3357     # FIXME What if checkout does not exist?
3358
3359     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3360     my $accountline = $account->add_debit(
3361         {
3362             amount      => $charge,
3363             note        => undef,
3364             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3365             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3366             interface   => C4::Context->interface,
3367             type        => $type,
3368             item_id     => $checkout->itemnumber,
3369             issue_id    => $checkout->issue_id,
3370         }
3371     );
3372 }
3373
3374 =head2 GetTransfers
3375
3376   GetTransfers($itemnumber);
3377
3378 =cut
3379
3380 sub GetTransfers {
3381     my ($itemnumber) = @_;
3382
3383     my $dbh = C4::Context->dbh;
3384
3385     my $query = '
3386         SELECT datesent,
3387                frombranch,
3388                tobranch,
3389                branchtransfer_id
3390         FROM branchtransfers
3391         WHERE itemnumber = ?
3392           AND datearrived IS NULL
3393         ';
3394     my $sth = $dbh->prepare($query);
3395     $sth->execute($itemnumber);
3396     my @row = $sth->fetchrow_array();
3397     return @row;
3398 }
3399
3400 =head2 GetTransfersFromTo
3401
3402   @results = GetTransfersFromTo($frombranch,$tobranch);
3403
3404 Returns the list of pending transfers between $from and $to branch
3405
3406 =cut
3407
3408 sub GetTransfersFromTo {
3409     my ( $frombranch, $tobranch ) = @_;
3410     return unless ( $frombranch && $tobranch );
3411     my $dbh   = C4::Context->dbh;
3412     my $query = "
3413         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3414         FROM   branchtransfers
3415         WHERE  frombranch=?
3416           AND  tobranch=?
3417           AND datearrived IS NULL
3418     ";
3419     my $sth = $dbh->prepare($query);
3420     $sth->execute( $frombranch, $tobranch );
3421     my @gettransfers;
3422
3423     while ( my $data = $sth->fetchrow_hashref ) {
3424         push @gettransfers, $data;
3425     }
3426     return (@gettransfers);
3427 }
3428
3429 =head2 DeleteTransfer
3430
3431   &DeleteTransfer($itemnumber);
3432
3433 =cut
3434
3435 sub DeleteTransfer {
3436     my ($itemnumber) = @_;
3437     return unless $itemnumber;
3438     my $dbh          = C4::Context->dbh;
3439     my $sth          = $dbh->prepare(
3440         "DELETE FROM branchtransfers
3441          WHERE itemnumber=?
3442          AND datearrived IS NULL "
3443     );
3444     return $sth->execute($itemnumber);
3445 }
3446
3447 =head2 SendCirculationAlert
3448
3449 Send out a C<check-in> or C<checkout> alert using the messaging system.
3450
3451 B<Parameters>:
3452
3453 =over 4
3454
3455 =item type
3456
3457 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3458
3459 =item item
3460
3461 Hashref of information about the item being checked in or out.
3462
3463 =item borrower
3464
3465 Hashref of information about the borrower of the item.
3466
3467 =item branch
3468
3469 The branchcode from where the checkout or check-in took place.
3470
3471 =back
3472
3473 B<Example>:
3474
3475     SendCirculationAlert({
3476         type     => 'CHECKOUT',
3477         item     => $item,
3478         borrower => $borrower,
3479         branch   => $branch,
3480     });
3481
3482 =cut
3483
3484 sub SendCirculationAlert {
3485     my ($opts) = @_;
3486     my ($type, $item, $borrower, $branch) =
3487         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3488     my %message_name = (
3489         CHECKIN  => 'Item_Check_in',
3490         CHECKOUT => 'Item_Checkout',
3491         RENEWAL  => 'Item_Checkout',
3492     );
3493     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3494         borrowernumber => $borrower->{borrowernumber},
3495         message_name   => $message_name{$type},
3496     });
3497     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3498
3499     my $schema = Koha::Database->new->schema;
3500     my @transports = keys %{ $borrower_preferences->{transports} };
3501
3502     # From the MySQL doc:
3503     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3504     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3505     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3506     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_NO_TABLE_LOCKS};
3507
3508     for my $mtt (@transports) {
3509         my $letter =  C4::Letters::GetPreparedLetter (
3510             module => 'circulation',
3511             letter_code => $type,
3512             branchcode => $branch,
3513             message_transport_type => $mtt,
3514             lang => $borrower->{lang},
3515             tables => {
3516                 $issues_table => $item->{itemnumber},
3517                 'items'       => $item->{itemnumber},
3518                 'biblio'      => $item->{biblionumber},
3519                 'biblioitems' => $item->{biblionumber},
3520                 'borrowers'   => $borrower,
3521                 'branches'    => $branch,
3522             }
3523         ) or next;
3524
3525         $schema->storage->txn_begin;
3526         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3527         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3528         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3529         unless ( $message ) {
3530             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3531             C4::Message->enqueue($letter, $borrower, $mtt);
3532         } else {
3533             $message->append($letter);
3534             $message->update;
3535         }
3536         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3537         $schema->storage->txn_commit;
3538     }
3539
3540     return;
3541 }
3542
3543 =head2 updateWrongTransfer
3544
3545   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3546
3547 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3548
3549 =cut
3550
3551 sub updateWrongTransfer {
3552         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3553         my $dbh = C4::Context->dbh;
3554 # first step validate the actual line of transfert .
3555         my $sth =
3556                 $dbh->prepare(
3557                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3558                 );
3559                 $sth->execute($FromLibrary,$itemNumber);
3560
3561 # second step create a new line of branchtransfer to the right location .
3562         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3563
3564 #third step changing holdingbranch of item
3565         UpdateHoldingbranch($FromLibrary,$itemNumber);
3566 }
3567
3568 =head2 UpdateHoldingbranch
3569
3570   $items = UpdateHoldingbranch($branch,$itmenumber);
3571
3572 Simple methode for updating hodlingbranch in items BDD line
3573
3574 =cut
3575
3576 sub UpdateHoldingbranch {
3577         my ( $branch,$itemnumber ) = @_;
3578     ModItem({ holdingbranch => $branch }, undef, $itemnumber);
3579 }
3580
3581 =head2 CalcDateDue
3582
3583 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3584
3585 this function calculates the due date given the start date and configured circulation rules,
3586 checking against the holidays calendar as per the 'useDaysMode' syspref.
3587 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3588 C<$itemtype>  = itemtype code of item in question
3589 C<$branch>  = location whose calendar to use
3590 C<$borrower> = Borrower object
3591 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3592
3593 =cut
3594
3595 sub CalcDateDue {
3596     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3597
3598     $isrenewal ||= 0;
3599
3600     # loanlength now a href
3601     my $loanlength =
3602             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3603
3604     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3605             ? qq{renewalperiod}
3606             : qq{issuelength};
3607
3608     my $datedue;
3609     if ( $startdate ) {
3610         if (ref $startdate ne 'DateTime' ) {
3611             $datedue = dt_from_string($datedue);
3612         } else {
3613             $datedue = $startdate->clone;
3614         }
3615     } else {
3616         $datedue =
3617           DateTime->now( time_zone => C4::Context->tz() )
3618           ->truncate( to => 'minute' );
3619     }
3620
3621
3622     # calculate the datedue as normal
3623     if ( C4::Context->preference('useDaysMode') eq 'Days' )
3624     {    # ignoring calendar
3625         if ( $loanlength->{lengthunit} eq 'hours' ) {
3626             $datedue->add( hours => $loanlength->{$length_key} );
3627         } else {    # days
3628             $datedue->add( days => $loanlength->{$length_key} );
3629             $datedue->set_hour(23);
3630             $datedue->set_minute(59);
3631         }
3632     } else {
3633         my $dur;
3634         if ($loanlength->{lengthunit} eq 'hours') {
3635             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3636         }
3637         else { # days
3638             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3639         }
3640         my $calendar = Koha::Calendar->new( branchcode => $branch );
3641         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3642         if ($loanlength->{lengthunit} eq 'days') {
3643             $datedue->set_hour(23);
3644             $datedue->set_minute(59);
3645         }
3646     }
3647
3648     # if Hard Due Dates are used, retrieve them and apply as necessary
3649     my ( $hardduedate, $hardduedatecompare ) =
3650       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3651     if ($hardduedate) {    # hardduedates are currently dates
3652         $hardduedate->truncate( to => 'minute' );
3653         $hardduedate->set_hour(23);
3654         $hardduedate->set_minute(59);
3655         my $cmp = DateTime->compare( $hardduedate, $datedue );
3656
3657 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3658 # if the calculated date is before the 'after' Hard Due Date (floor), override
3659 # if the hard due date is set to 'exactly', overrride
3660         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3661             $datedue = $hardduedate->clone;
3662         }
3663
3664         # in all other cases, keep the date due as it is
3665
3666     }
3667
3668     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3669     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3670         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3671         if( $expiry_dt ) { #skip empty expiry date..
3672             $expiry_dt->set( hour => 23, minute => 59);
3673             my $d1= $datedue->clone->set_time_zone('floating');
3674             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3675                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3676             }
3677         }
3678         if ( C4::Context->preference('useDaysMode') ne 'Days' ) {
3679           my $calendar = Koha::Calendar->new( branchcode => $branch );
3680           if ( $calendar->is_holiday($datedue) ) {
3681               # Don't return on a closed day
3682               $datedue = $calendar->prev_open_days( $datedue, 1 );
3683           }
3684         }
3685     }
3686
3687     return $datedue;
3688 }
3689
3690
3691 sub CheckValidBarcode{
3692 my ($barcode) = @_;
3693 my $dbh = C4::Context->dbh;
3694 my $query=qq|SELECT count(*)
3695              FROM items
3696              WHERE barcode=?
3697             |;
3698 my $sth = $dbh->prepare($query);
3699 $sth->execute($barcode);
3700 my $exist=$sth->fetchrow ;
3701 return $exist;
3702 }
3703
3704 =head2 IsBranchTransferAllowed
3705
3706   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3707
3708 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3709
3710 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3711 Koha::Item->can_be_transferred.
3712
3713 =cut
3714
3715 sub IsBranchTransferAllowed {
3716         my ( $toBranch, $fromBranch, $code ) = @_;
3717
3718         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3719
3720         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3721         my $dbh = C4::Context->dbh;
3722
3723         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3724         $sth->execute( $toBranch, $fromBranch, $code );
3725         my $limit = $sth->fetchrow_hashref();
3726
3727         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3728         if ( $limit->{'limitId'} ) {
3729                 return 0;
3730         } else {
3731                 return 1;
3732         }
3733 }
3734
3735 =head2 CreateBranchTransferLimit
3736
3737   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3738
3739 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3740
3741 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3742
3743 =cut
3744
3745 sub CreateBranchTransferLimit {
3746    my ( $toBranch, $fromBranch, $code ) = @_;
3747    return unless defined($toBranch) && defined($fromBranch);
3748    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3749
3750    my $dbh = C4::Context->dbh;
3751
3752    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3753    return $sth->execute( $code, $toBranch, $fromBranch );
3754 }
3755
3756 =head2 DeleteBranchTransferLimits
3757
3758     my $result = DeleteBranchTransferLimits($frombranch);
3759
3760 Deletes all the library transfer limits for one library.  Returns the
3761 number of limits deleted, 0e0 if no limits were deleted, or undef if
3762 no arguments are supplied.
3763
3764 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3765     fromBranch => $fromBranch
3766     })->delete.
3767
3768 =cut
3769
3770 sub DeleteBranchTransferLimits {
3771     my $branch = shift;
3772     return unless defined $branch;
3773     my $dbh    = C4::Context->dbh;
3774     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3775     return $sth->execute($branch);
3776 }
3777
3778 sub ReturnLostItem{
3779     my ( $borrowernumber, $itemnum ) = @_;
3780     MarkIssueReturned( $borrowernumber, $itemnum );
3781 }
3782
3783
3784 sub LostItem{
3785     my ($itemnumber, $mark_lost_from, $force_mark_returned) = @_;
3786
3787     unless ( $mark_lost_from ) {
3788         # Temporary check to avoid regressions
3789         die q|LostItem called without $mark_lost_from, check the API.|;
3790     }
3791
3792     my $mark_returned;
3793     if ( $force_mark_returned ) {
3794         $mark_returned = 1;
3795     } else {
3796         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3797         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3798     }
3799
3800     my $dbh = C4::Context->dbh();
3801     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3802                            FROM issues
3803                            JOIN items USING (itemnumber)
3804                            JOIN biblio USING (biblionumber)
3805                            WHERE issues.itemnumber=?");
3806     $sth->execute($itemnumber);
3807     my $issues=$sth->fetchrow_hashref();
3808
3809     # If a borrower lost the item, add a replacement cost to the their record
3810     if ( my $borrowernumber = $issues->{borrowernumber} ){
3811         my $patron = Koha::Patrons->find( $borrowernumber );
3812
3813         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3814         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3815
3816         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3817             C4::Accounts::chargelostitem(
3818                 $borrowernumber,
3819                 $itemnumber,
3820                 $issues->{'replacementprice'},
3821                 sprintf( "%s %s %s",
3822                     $issues->{'title'}          || q{},
3823                     $issues->{'barcode'}        || q{},
3824                     $issues->{'itemcallnumber'} || q{},
3825                 ),
3826             );
3827             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3828             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3829         }
3830
3831         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3832     }
3833
3834     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3835     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3836         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store;
3837     }
3838     my $transferdeleted = DeleteTransfer($itemnumber);
3839 }
3840
3841 sub GetOfflineOperations {
3842     my $dbh = C4::Context->dbh;
3843     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3844     $sth->execute(C4::Context->userenv->{'branch'});
3845     my $results = $sth->fetchall_arrayref({});
3846     return $results;
3847 }
3848
3849 sub GetOfflineOperation {
3850     my $operationid = shift;
3851     return unless $operationid;
3852     my $dbh = C4::Context->dbh;
3853     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3854     $sth->execute( $operationid );
3855     return $sth->fetchrow_hashref;
3856 }
3857
3858 sub AddOfflineOperation {
3859     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3860     my $dbh = C4::Context->dbh;
3861     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3862     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3863     return "Added.";
3864 }
3865
3866 sub DeleteOfflineOperation {
3867     my $dbh = C4::Context->dbh;
3868     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3869     $sth->execute( shift );
3870     return "Deleted.";
3871 }
3872
3873 sub ProcessOfflineOperation {
3874     my $operation = shift;
3875
3876     my $report;
3877     if ( $operation->{action} eq 'return' ) {
3878         $report = ProcessOfflineReturn( $operation );
3879     } elsif ( $operation->{action} eq 'issue' ) {
3880         $report = ProcessOfflineIssue( $operation );
3881     } elsif ( $operation->{action} eq 'payment' ) {
3882         $report = ProcessOfflinePayment( $operation );
3883     }
3884
3885     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3886
3887     return $report;
3888 }
3889
3890 sub ProcessOfflineReturn {
3891     my $operation = shift;
3892
3893     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3894
3895     if ( $item ) {
3896         my $itemnumber = $item->itemnumber;
3897         my $issue = GetOpenIssue( $itemnumber );
3898         if ( $issue ) {
3899             MarkIssueReturned(
3900                 $issue->{borrowernumber},
3901                 $itemnumber,
3902                 $operation->{timestamp},
3903             );
3904             $item->renewals(0);
3905             $item->onloan(undef);
3906             $item->store({ log_action => 0 });
3907             return "Success.";
3908         } else {
3909             return "Item not issued.";
3910         }
3911     } else {
3912         return "Item not found.";
3913     }
3914 }
3915
3916 sub ProcessOfflineIssue {
3917     my $operation = shift;
3918
3919     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3920
3921     if ( $patron ) {
3922         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3923         unless ($item) {
3924             return "Barcode not found.";
3925         }
3926         my $itemnumber = $item->itemnumber;
3927         my $issue = GetOpenIssue( $itemnumber );
3928
3929         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3930             MarkIssueReturned(
3931                 $issue->{borrowernumber},
3932                 $itemnumber,
3933                 $operation->{timestamp},
3934             );
3935         }
3936         AddIssue(
3937             $patron->unblessed,
3938             $operation->{'barcode'},
3939             undef,
3940             1,
3941             $operation->{timestamp},
3942             undef,
3943         );
3944         return "Success.";
3945     } else {
3946         return "Borrower not found.";
3947     }
3948 }
3949
3950 sub ProcessOfflinePayment {
3951     my $operation = shift;
3952
3953     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3954
3955     $patron->account->pay(
3956         {
3957             amount     => $operation->{amount},
3958             library_id => $operation->{branchcode},
3959             interface  => 'koc'
3960         }
3961     );
3962
3963     return "Success.";
3964 }
3965
3966 =head2 TransferSlip
3967
3968   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3969
3970   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3971
3972 =cut
3973
3974 sub TransferSlip {
3975     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3976
3977     my $item =
3978       $itemnumber
3979       ? Koha::Items->find($itemnumber)
3980       : Koha::Items->find( { barcode => $barcode } );
3981
3982     $item or return;
3983
3984     return C4::Letters::GetPreparedLetter (
3985         module => 'circulation',
3986         letter_code => 'TRANSFERSLIP',
3987         branchcode => $branch,
3988         tables => {
3989             'branches'    => $to_branch,
3990             'biblio'      => $item->biblionumber,
3991             'items'       => $item->unblessed,
3992         },
3993     );
3994 }
3995
3996 =head2 CheckIfIssuedToPatron
3997
3998   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3999
4000   Return 1 if any record item is issued to patron, otherwise return 0
4001
4002 =cut
4003
4004 sub CheckIfIssuedToPatron {
4005     my ($borrowernumber, $biblionumber) = @_;
4006
4007     my $dbh = C4::Context->dbh;
4008     my $query = q|
4009         SELECT COUNT(*) FROM issues
4010         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4011         WHERE items.biblionumber = ?
4012         AND issues.borrowernumber = ?
4013     |;
4014     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4015     return 1 if $is_issued;
4016     return;
4017 }
4018
4019 =head2 IsItemIssued
4020
4021   IsItemIssued( $itemnumber )
4022
4023   Return 1 if the item is on loan, otherwise return 0
4024
4025 =cut
4026
4027 sub IsItemIssued {
4028     my $itemnumber = shift;
4029     my $dbh = C4::Context->dbh;
4030     my $sth = $dbh->prepare(q{
4031         SELECT COUNT(*)
4032         FROM issues
4033         WHERE itemnumber = ?
4034     });
4035     $sth->execute($itemnumber);
4036     return $sth->fetchrow;
4037 }
4038
4039 =head2 GetAgeRestriction
4040
4041   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4042   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4043
4044   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4045   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4046
4047 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4048 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4049 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4050          Negative days mean the borrower has gone past the age restriction age.
4051
4052 =cut
4053
4054 sub GetAgeRestriction {
4055     my ($record_restrictions, $borrower) = @_;
4056     my $markers = C4::Context->preference('AgeRestrictionMarker');
4057
4058     return unless $record_restrictions;
4059     # Split $record_restrictions to something like FSK 16 or PEGI 6
4060     my @values = split ' ', uc($record_restrictions);
4061     return unless @values;
4062
4063     # Search first occurrence of one of the markers
4064     my @markers = split /\|/, uc($markers);
4065     return unless @markers;
4066
4067     my $index            = 0;
4068     my $restriction_year = 0;
4069     for my $value (@values) {
4070         $index++;
4071         for my $marker (@markers) {
4072             $marker =~ s/^\s+//;    #remove leading spaces
4073             $marker =~ s/\s+$//;    #remove trailing spaces
4074             if ( $marker eq $value ) {
4075                 if ( $index <= $#values ) {
4076                     $restriction_year += $values[$index];
4077                 }
4078                 last;
4079             }
4080             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4081
4082                 # Perhaps it is something like "K16" (as in Finland)
4083                 $restriction_year += $1;
4084                 last;
4085             }
4086         }
4087         last if ( $restriction_year > 0 );
4088     }
4089
4090     #Check if the borrower is age restricted for this material and for how long.
4091     if ($restriction_year && $borrower) {
4092         if ( $borrower->{'dateofbirth'} ) {
4093             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4094             $alloweddate[0] += $restriction_year;
4095
4096             #Prevent runime eror on leap year (invalid date)
4097             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4098                 $alloweddate[2] = 28;
4099             }
4100
4101             #Get how many days the borrower has to reach the age restriction
4102             my @Today = split /-/, DateTime->today->ymd();
4103             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4104             #Negative days means the borrower went past the age restriction age
4105             return ($restriction_year, $daysToAgeRestriction);
4106         }
4107     }
4108
4109     return ($restriction_year);
4110 }
4111
4112
4113 =head2 GetPendingOnSiteCheckouts
4114
4115 =cut
4116
4117 sub GetPendingOnSiteCheckouts {
4118     my $dbh = C4::Context->dbh;
4119     return $dbh->selectall_arrayref(q|
4120         SELECT
4121           items.barcode,
4122           items.biblionumber,
4123           items.itemnumber,
4124           items.itemnotes,
4125           items.itemcallnumber,
4126           items.location,
4127           issues.date_due,
4128           issues.branchcode,
4129           issues.date_due < NOW() AS is_overdue,
4130           biblio.author,
4131           biblio.title,
4132           borrowers.firstname,
4133           borrowers.surname,
4134           borrowers.cardnumber,
4135           borrowers.borrowernumber
4136         FROM items
4137         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4138         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4139         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4140         WHERE issues.onsite_checkout = 1
4141     |, { Slice => {} } );
4142 }
4143
4144 sub GetTopIssues {
4145     my ($params) = @_;
4146
4147     my ($count, $branch, $itemtype, $ccode, $newness)
4148         = @$params{qw(count branch itemtype ccode newness)};
4149
4150     my $dbh = C4::Context->dbh;
4151     my $query = q{
4152         SELECT * FROM (
4153         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4154           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4155           i.ccode, SUM(i.issues) AS count
4156         FROM biblio b
4157         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4158         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4159     };
4160
4161     my (@where_strs, @where_args);
4162
4163     if ($branch) {
4164         push @where_strs, 'i.homebranch = ?';
4165         push @where_args, $branch;
4166     }
4167     if ($itemtype) {
4168         if (C4::Context->preference('item-level_itypes')){
4169             push @where_strs, 'i.itype = ?';
4170             push @where_args, $itemtype;
4171         } else {
4172             push @where_strs, 'bi.itemtype = ?';
4173             push @where_args, $itemtype;
4174         }
4175     }
4176     if ($ccode) {
4177         push @where_strs, 'i.ccode = ?';
4178         push @where_args, $ccode;
4179     }
4180     if ($newness) {
4181         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4182         push @where_args, $newness;
4183     }
4184
4185     if (@where_strs) {
4186         $query .= 'WHERE ' . join(' AND ', @where_strs);
4187     }
4188
4189     $query .= q{
4190         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4191           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4192           i.ccode
4193         ORDER BY count DESC
4194     };
4195
4196     $query .= q{ ) xxx WHERE count > 0 };
4197     $count = int($count);
4198     if ($count > 0) {
4199         $query .= "LIMIT $count";
4200     }
4201
4202     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4203
4204     return @$rows;
4205 }
4206
4207 sub _CalculateAndUpdateFine {
4208     my ($params) = @_;
4209
4210     my $borrower    = $params->{borrower};
4211     my $item        = $params->{item};
4212     my $issue       = $params->{issue};
4213     my $return_date = $params->{return_date};
4214
4215     unless ($borrower) { carp "No borrower passed in!" && return; }
4216     unless ($item)     { carp "No item passed in!"     && return; }
4217     unless ($issue)    { carp "No issue passed in!"    && return; }
4218
4219     my $datedue = dt_from_string( $issue->date_due );
4220
4221     # we only need to calculate and change the fines if we want to do that on return
4222     # Should be on for hourly loans
4223     my $control = C4::Context->preference('CircControl');
4224     my $control_branchcode =
4225         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4226       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4227       :                                     $issue->branchcode;
4228
4229     my $date_returned = $return_date ? $return_date : dt_from_string();
4230
4231     my ( $amount, $unitcounttotal, $unitcount  ) =
4232       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4233
4234     if ( C4::Context->preference('finesMode') eq 'production' ) {
4235         if ( $amount > 0 ) {
4236             C4::Overdues::UpdateFine({
4237                 issue_id       => $issue->issue_id,
4238                 itemnumber     => $issue->itemnumber,
4239                 borrowernumber => $issue->borrowernumber,
4240                 amount         => $amount,
4241                 due            => output_pref($datedue),
4242             });
4243         }
4244         elsif ($return_date) {
4245
4246             # Backdated returns may have fines that shouldn't exist,
4247             # so in this case, we need to drop those fines to 0
4248
4249             C4::Overdues::UpdateFine({
4250                 issue_id       => $issue->issue_id,
4251                 itemnumber     => $issue->itemnumber,
4252                 borrowernumber => $issue->borrowernumber,
4253                 amount         => 0,
4254                 due            => output_pref($datedue),
4255             });
4256         }
4257     }
4258 }
4259
4260 sub _item_denied_renewal {
4261     my ($params) = @_;
4262
4263     my $item = $params->{item};
4264     return unless $item;
4265
4266     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4267     return unless $denyingrules;
4268     foreach my $field (keys %$denyingrules) {
4269         my $val = $item->$field;
4270         if( !defined $val) {
4271             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4272                 return 1;
4273             }
4274         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4275            # If the results matches the values in the syspref
4276            # We return true if match found
4277             return 1;
4278         }
4279     }
4280     return 0;
4281 }
4282
4283
4284 1;
4285
4286 __END__
4287
4288 =head1 AUTHOR
4289
4290 Koha Development Team <http://koha-community.org/>
4291
4292 =cut