C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use Koha::DateUtils qw( dt_from_string output_pref );
  28 use C4::Context;
  29 use C4::Stats qw( UpdateStats );
  30 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  31 use C4::Biblio qw( UpdateTotalIssues );
  32 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  33 use C4::Accounts;
  34 use C4::ItemCirculationAlertPreference;
  35 use C4::Message;
  36 use C4::Log qw( logaction ); # logaction
  37 use C4::Overdues;
  38 use C4::RotatingCollections qw(GetCollectionItemBranches);
  39 use Algorithm::CheckDigits qw( CheckDigits );
  40
  41 use Data::Dumper qw( Dumper );
  42 use Koha::Account;
  43 use Koha::AuthorisedValues;
  44 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  45 use Koha::Biblioitems;
  46 use Koha::DateUtils qw( dt_from_string output_pref );
  47 use Koha::Calendar;
  48 use Koha::Checkouts;
  49 use Koha::Illrequests;
  50 use Koha::Items;
  51 use Koha::Patrons;
  52 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  53 use Koha::Database;
  54 use Koha::Libraries;
  55 use Koha::Account::Lines;
  56 use Koha::Holds;
  57 use Koha::Account::Lines;
  58 use Koha::Account::Offsets;
  59 use Koha::Config::SysPrefs;
  60 use Koha::Charges::Fees;
  61 use Koha::Config::SysPref;
  62 use Koha::Checkouts::ReturnClaims;
  63 use Koha::SearchEngine::Indexer;
  64 use Koha::Exceptions::Checkout;
  65 use Koha::Plugins;
  66 use Koha::Recalls;
  67 use Carp qw( carp );
  68 use List::MoreUtils qw( any );
  69 use Scalar::Util qw( looks_like_number );
  70 use Date::Calc qw( Date_to_Days );
  71 our (@ISA, @EXPORT_OK);
  72 BEGIN {
  73
  74     require Exporter;
  75     @ISA = qw(Exporter);
  76
  77     # FIXME subs that should probably be elsewhere
  78     push @EXPORT_OK, qw(
  79       barcodedecode
  80       LostItem
  81       ReturnLostItem
  82       GetPendingOnSiteCheckouts
  83
  84       CanBookBeIssued
  85       checkHighHolds
  86       CanBookBeRenewed
  87       AddIssue
  88       GetLoanLength
  89       GetHardDueDate
  90       AddRenewal
  91       GetRenewCount
  92       GetSoonestRenewDate
  93       GetLatestAutoRenewDate
  94       GetIssuingCharges
  95       AddIssuingCharge
  96       GetBranchBorrowerCircRule
  97       GetBranchItemRule
  98       GetBiblioIssues
  99       GetOpenIssue
 100       GetUpcomingDueIssues
 101       CheckIfIssuedToPatron
 102       IsItemIssued
 103       GetAgeRestriction
 104       GetTopIssues
 105
 106       AddReturn
 107       MarkIssueReturned
 108
 109       transferbook
 110       TooMany
 111       GetTransfers
 112       GetTransfersFromTo
 113       updateWrongTransfer
 114       CalcDateDue
 115       CheckValidBarcode
 116       IsBranchTransferAllowed
 117       CreateBranchTransferLimit
 118       DeleteBranchTransferLimits
 119       TransferSlip
 120
 121       GetOfflineOperations
 122       GetOfflineOperation
 123       AddOfflineOperation
 124       DeleteOfflineOperation
 125       ProcessOfflineOperation
 126       ProcessOfflinePayment
 127       ProcessOfflineIssue
 128     );
 129     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 130 }
 131
 132 =head1 NAME
 133
 134 C4::Circulation - Koha circulation module
 135
 136 =head1 SYNOPSIS
 137
 138 use C4::Circulation;
 139
 140 =head1 DESCRIPTION
 141
 142 The functions in this module deal with circulation, issues, and
 143 returns, as well as general information about the library.
 144 Also deals with inventory.
 145
 146 =head1 FUNCTIONS
 147
 148 =head2 barcodedecode
 149
 150   $str = &barcodedecode($barcode, [$filter]);
 151
 152 Generic filter function for barcode string.
 153 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 154 Will do some manipulation of the barcode for systems that deliver a barcode
 155 to circulation.pl that differs from the barcode stored for the item.
 156 For proper functioning of this filter, calling the function on the
 157 correct barcode string (items.barcode) should return an unaltered barcode.
 158 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 159
 160 The optional $filter argument is to allow for testing or explicit
 161 behavior that ignores the System Pref.  Valid values are the same as the
 162 System Pref options.
 163
 164 =cut
 165
 166 # FIXME -- the &decode fcn below should be wrapped into this one.
 167 # FIXME -- these plugins should be moved out of Circulation.pm
 168 #
 169 sub barcodedecode {
 170     my ($barcode, $filter) = @_;
 171
 172     return unless defined $barcode;
 173
 174     my $branch = C4::Context::mybranch();
 175     $barcode =~ s/^\s+|\s+$//g;
 176     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 177     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 178     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 179         if ($filter eq 'whitespace') {
 180                 $barcode =~ s/\s//g;
 181         } elsif ($filter eq 'cuecat') {
 182                 chomp($barcode);
 183             my @fields = split( /\./, $barcode );
 184             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 185             ($#results == 2) and return $results[2];
 186         } elsif ($filter eq 'T-prefix') {
 187                 if ($barcode =~ /^[Tt](\d)/) {
 188                         (defined($1) and $1 eq '0') and return $barcode;
 189             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 190                 }
 191         return sprintf("T%07d", $barcode);
 192         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 193         # Why drop the nonzero digit after the T?
 194         # Why pass non-digits (or empty string) to "T%07d"?
 195         } elsif ($filter eq 'libsuite8') {
 196                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 197                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 198                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 199                         }else{
 200                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 201                         }
 202                 }
 203     } elsif ($filter eq 'EAN13') {
 204         my $ean = CheckDigits('ean');
 205         if ( $ean->is_valid($barcode) ) {
 206             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 207             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 208         } else {
 209             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 210         }
 211         }
 212     return $barcode;    # return barcode, modified or not
 213 }
 214
 215 =head2 _decode
 216
 217   $str = &_decode($chunk);
 218
 219 Decodes a segment of a string emitted by a CueCat barcode scanner and
 220 returns it.
 221
 222 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 223 or Javascript based decoding on the client side.
 224
 225 =cut
 226
 227 sub _decode {
 228     my ($encoded) = @_;
 229     my $seq =
 230       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 231     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 232     my $l = ( $#s + 1 ) % 4;
 233     if ($l) {
 234         if ( $l == 1 ) {
 235             # warn "Error: Cuecat decode parsing failed!";
 236             return;
 237         }
 238         $l = 4 - $l;
 239         $#s += $l;
 240     }
 241     my $r = '';
 242     while ( $#s >= 0 ) {
 243         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 244         $r .=
 245             chr( ( $n >> 16 ) ^ 67 )
 246          .chr( ( $n >> 8 & 255 ) ^ 67 )
 247          .chr( ( $n & 255 ) ^ 67 );
 248         @s = @s[ 4 .. $#s ];
 249     }
 250     $r = substr( $r, 0, length($r) - $l );
 251     return $r;
 252 }
 253
 254 =head2 transferbook
 255
 256   ($dotransfer, $messages, $iteminformation) = &transferbook({
 257                                                    from_branch => $frombranch
 258                                                    to_branch => $tobranch,
 259                                                    barcode => $barcode,
 260                                                    ignore_reserves => $ignore_reserves,
 261                                                    trigger => $trigger
 262                                                 });
 263
 264 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 265
 266 C<$fbr> is the code for the branch initiating the transfer.
 267 C<$tbr> is the code for the branch to which the item should be transferred.
 268
 269 C<$barcode> is the barcode of the item to be transferred.
 270
 271 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 272 Otherwise, if an item is reserved, the transfer fails.
 273
 274 C<$trigger> is the enum value for what triggered the transfer.
 275
 276 Returns three values:
 277
 278 =over
 279
 280 =item $dotransfer
 281
 282 is true if the transfer was successful.
 283
 284 =item $messages
 285
 286 is a reference-to-hash which may have any of the following keys:
 287
 288 =over
 289
 290 =item C<BadBarcode>
 291
 292 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 293
 294 =item C<DestinationEqualsHolding>
 295
 296 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 297
 298 =item C<WasReturned>
 299
 300 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 301
 302 =item C<ResFound>
 303
 304 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 305
 306 =item C<WasTransferred>
 307
 308 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 309
 310 =item C<RecallPlacedAtHoldingBranch>
 311
 312 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 313
 314 =item C<RecallFound>
 315
 316 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 317
 318 =back
 319
 320 =back
 321
 322 =cut
 323
 324 sub transferbook {
 325     my $params = shift;
 326     my $tbr      = $params->{to_branch};
 327     my $fbr      = $params->{from_branch};
 328     my $ignoreRs = $params->{ignore_reserves};
 329     my $barcode  = $params->{barcode};
 330     my $trigger  = $params->{trigger};
 331     my $messages;
 332     my $dotransfer      = 1;
 333     my $item = Koha::Items->find( { barcode => $barcode } );
 334
 335     Koha::Exceptions::MissingParameter->throw(
 336         "Missing mandatory parameter: from_branch")
 337       unless $fbr;
 338
 339     Koha::Exceptions::MissingParameter->throw(
 340         "Missing mandatory parameter: to_branch")
 341       unless $tbr;
 342
 343     # bad barcode..
 344     unless ( $item ) {
 345         $messages->{'BadBarcode'} = $barcode;
 346         $dotransfer = 0;
 347         return ( $dotransfer, $messages );
 348     }
 349
 350     my $itemnumber = $item->itemnumber;
 351     # get branches of book...
 352     my $hbr = $item->homebranch;
 353
 354     # if using Branch Transfer Limits
 355     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 356         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 357         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 358             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 359                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 360                 $dotransfer = 0;
 361             }
 362         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 363             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 364             $dotransfer = 0;
 365         }
 366     }
 367
 368     # can't transfer book if is already there....
 369     if ( $fbr eq $tbr ) {
 370         $messages->{'DestinationEqualsHolding'} = 1;
 371         $dotransfer = 0;
 372     }
 373
 374     # check if it is still issued to someone, return it...
 375     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 376     if ( $issue ) {
 377         AddReturn( $barcode, $fbr );
 378         $messages->{'WasReturned'} = $issue->borrowernumber;
 379     }
 380
 381     # find reserves.....
 382     # That'll save a database query.
 383     my ( $resfound, $resrec, undef ) =
 384       CheckReserves( $itemnumber );
 385     if ( $resfound ) {
 386         $resrec->{'ResFound'} = $resfound;
 387         $messages->{'ResFound'} = $resrec;
 388         $dotransfer = 0 unless $ignoreRs;
 389     }
 390
 391     # find recall
 392     if ( C4::Context->preference('UseRecalls') ) {
 393         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 394         if ( defined $recall ) {
 395             # do a transfer if the recall branch is different to the item holding branch
 396             if ( $recall->pickup_library_id eq $fbr ) {
 397                 $dotransfer = 0;
 398                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 399             } else {
 400                 $dotransfer = 1;
 401                 $messages->{'RecallFound'} = $recall;
 402             }
 403         }
 404     }
 405
 406     #actually do the transfer....
 407     if ($dotransfer) {
 408         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 409
 410         # don't need to update MARC anymore, we do it in batch now
 411         $messages->{'WasTransfered'} = $tbr;
 412
 413     }
 414     ModDateLastSeen( $itemnumber );
 415     return ( $dotransfer, $messages );
 416 }
 417
 418
 419 sub TooMany {
 420     my $borrower        = shift;
 421     my $item_object = shift;
 422     my $params = shift;
 423     my $onsite_checkout = $params->{onsite_checkout} || 0;
 424     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 425     my $cat_borrower    = $borrower->{'categorycode'};
 426     my $dbh             = C4::Context->dbh;
 427     # Get which branchcode we need
 428     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 429     my $type = $item_object->effective_itemtype;
 430
 431     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 432     $type_object = Koha::ItemTypes->find( $type );
 433     $parent_type = $type_object->parent_type if $type_object;
 434     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 435     # Find any children if we are a parent_type;
 436
 437     # given branch, patron category, and item type, determine
 438     # applicable issuing rule
 439
 440     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 441         {
 442             categorycode => $cat_borrower,
 443             itemtype     => $parent_type,
 444             branchcode   => $branch,
 445             rule_name    => 'maxissueqty',
 446         }
 447     ) if $parent_type;
 448     # If the parent rule is for default type we discount it
 449     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 450
 451     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 452         {
 453             categorycode => $cat_borrower,
 454             itemtype     => $type,
 455             branchcode   => $branch,
 456             rule_name    => 'maxissueqty',
 457         }
 458     );
 459
 460     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 461         {
 462             categorycode => $cat_borrower,
 463             itemtype     => $type,
 464             branchcode   => $branch,
 465             rule_name    => 'maxonsiteissueqty',
 466         }
 467     );
 468
 469
 470     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 471     # if a rule is found and has a loan limit set, count
 472     # how many loans the patron already has that meet that
 473     # rule
 474     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 475
 476         my $checkouts;
 477         if ( $maxissueqty_rule->branchcode ) {
 478             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 479                 $checkouts = $patron->checkouts->search(
 480                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 481             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 482                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 483             } else {
 484                 $checkouts = $patron->checkouts->search(
 485                     { 'item.homebranch' => $maxissueqty_rule->branchcode } );
 486             }
 487         } else {
 488             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 489         }
 490         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 491
 492         my $sum_checkouts;
 493         my $rule_itemtype = $maxissueqty_rule->itemtype;
 494
 495         my @types;
 496         unless ( $rule_itemtype ) {
 497             # matching rule has the default item type, so count only
 498             # those existing loans that don't fall under a more
 499             # specific rule
 500             @types = Koha::CirculationRules->search(
 501                 {
 502                     branchcode => $maxissueqty_rule->branchcode,
 503                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 504                     itemtype  => { '!=' => undef },
 505                     rule_name => 'maxissueqty'
 506                 }
 507             )->get_column('itemtype');
 508         } else {
 509             if ( $parent_maxissueqty_rule ) {
 510                 # if we have a parent item type then we count loans of the
 511                 # specific item type or its siblings or parent
 512                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 513                 @types = $children->get_column('itemtype');
 514                 push @types, $parent_type;
 515             } elsif ( $child_types ) {
 516                 # If we are a parent type, we need to count all child types and our own type
 517                 @types = $child_types->get_column('itemtype');
 518                 push @types, $type; # And don't forget to count our own types
 519             } else {
 520                 # Otherwise only count the specific itemtype
 521                 push @types, $type;
 522             }
 523         }
 524
 525         while ( my $c = $checkouts->next ) {
 526             my $itemtype = $c->item->effective_itemtype;
 527
 528             unless ( $rule_itemtype ) {
 529                 next if grep {$_ eq $itemtype} @types;
 530             } else {
 531                 next unless grep {$_ eq $itemtype} @types;
 532             }
 533
 534             $sum_checkouts->{total}++;
 535             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 536             $sum_checkouts->{itemtype}->{$itemtype}++;
 537         }
 538
 539         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 540         my $checkout_count = $sum_checkouts->{total} || 0;
 541         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 542
 543         my $checkout_rules = {
 544             checkout_count               => $checkout_count,
 545             onsite_checkout_count        => $onsite_checkout_count,
 546             onsite_checkout              => $onsite_checkout,
 547             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 548             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 549             switch_onsite_checkout       => $switch_onsite_checkout,
 550         };
 551         # If parent rules exists
 552         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 553             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 554             my $qty_over = _check_max_qty($checkout_rules);
 555             return $qty_over if defined $qty_over;
 556
 557             # If the parent rule is less than or equal to the child, we only need check the parent
 558             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 559                 $checkout_rules->{checkout_count} = $checkout_count_type;
 560                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 561                 my $qty_over = _check_max_qty($checkout_rules);
 562                 return $qty_over if defined $qty_over;
 563             }
 564         } else {
 565             my $qty_over = _check_max_qty($checkout_rules);
 566             return $qty_over if defined $qty_over;
 567         }
 568     }
 569
 570     # Now count total loans against the limit for the branch
 571     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 572     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 573         my $checkouts;
 574         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 575             $checkouts = $patron->checkouts->search(
 576                 { 'me.branchcode' => $branch} );
 577         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 578             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 579         } else {
 580             $checkouts = $patron->checkouts->search(
 581                 { 'item.homebranch' => $branch},
 582                 { prefetch          => 'item' } );
 583         }
 584
 585         my $checkout_count = $checkouts->count;
 586         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 587         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 588         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 589
 590         my $qty_over = _check_max_qty(
 591             {
 592                 checkout_count               => $checkout_count,
 593                 onsite_checkout_count        => $onsite_checkout_count,
 594                 onsite_checkout              => $onsite_checkout,
 595                 max_checkouts_allowed        => $max_checkouts_allowed,
 596                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 597                 switch_onsite_checkout       => $switch_onsite_checkout
 598             }
 599         );
 600         return $qty_over if defined $qty_over;
 601     }
 602
 603     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 604         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 605     }
 606
 607     # OK, the patron can issue !!!
 608     return;
 609 }
 610
 611 sub _check_max_qty {
 612     my $params                       = shift;
 613     my $checkout_count               = $params->{checkout_count};
 614     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 615     my $onsite_checkout              = $params->{onsite_checkout};
 616     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 617     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 618     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 619
 620     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 621         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 622         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 623             return {
 624                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 625                 count       => $onsite_checkout_count,
 626                 max_allowed => $max_onsite_checkouts_allowed,
 627             };
 628         }
 629     }
 630     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 631         if ( $max_checkouts_allowed eq '' ) { return; }
 632         my $delta = $switch_onsite_checkout ? 1 : 0;
 633         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 634             return {
 635                 reason      => 'TOO_MANY_CHECKOUTS',
 636                 count       => $checkout_count,
 637                 max_allowed => $max_checkouts_allowed,
 638             };
 639         }
 640     }
 641     elsif ( not $onsite_checkout ) {
 642         if ( $max_checkouts_allowed eq '' ) { return; }
 643         if (
 644             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 645         {
 646             return {
 647                 reason      => 'TOO_MANY_CHECKOUTS',
 648                 count       => $checkout_count - $onsite_checkout_count,
 649                 max_allowed => $max_checkouts_allowed,
 650             };
 651         }
 652     }
 653
 654     return;
 655 }
 656
 657 =head2 CanBookBeIssued
 658
 659   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 660                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 661
 662 Check if a book can be issued.
 663
 664 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 665
 666 IMPORTANT: The assumption by users of this routine is that causes blocking
 667 the issue are keyed by uppercase labels and other returned
 668 data is keyed in lower case!
 669
 670 =over 4
 671
 672 =item C<$patron> is a Koha::Patron
 673
 674 =item C<$barcode> is the bar code of the book being issued.
 675
 676 =item C<$duedates> is a DateTime object.
 677
 678 =item C<$inprocess> boolean switch
 679
 680 =item C<$ignore_reserves> boolean switch
 681
 682 =item C<$params> Hashref of additional parameters
 683
 684 Available keys:
 685     override_high_holds - Ignore high holds
 686     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 687
 688 =back
 689
 690 Returns :
 691
 692 =over 4
 693
 694 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 695 Possible values are :
 696
 697 =back
 698
 699 =head3 INVALID_DATE
 700
 701 sticky due date is invalid
 702
 703 =head3 GNA
 704
 705 borrower gone with no address
 706
 707 =head3 CARD_LOST
 708
 709 borrower declared it's card lost
 710
 711 =head3 DEBARRED
 712
 713 borrower debarred
 714
 715 =head3 UNKNOWN_BARCODE
 716
 717 barcode unknown
 718
 719 =head3 NOT_FOR_LOAN
 720
 721 item is not for loan
 722
 723 =head3 WTHDRAWN
 724
 725 item withdrawn.
 726
 727 =head3 RESTRICTED
 728
 729 item is restricted (set by ??)
 730
 731 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 732 could be prevented, but ones that can be overriden by the operator.
 733
 734 Possible values are :
 735
 736 =head3 DEBT
 737
 738 borrower has debts.
 739
 740 =head3 RENEW_ISSUE
 741
 742 renewing, not issuing
 743
 744 =head3 ISSUED_TO_ANOTHER
 745
 746 issued to someone else.
 747
 748 =head3 RESERVED
 749
 750 reserved for someone else.
 751
 752 =head3 TRANSFERRED
 753
 754 reserved and being transferred for someone else.
 755
 756 =head3 INVALID_DATE
 757
 758 sticky due date is invalid or due date in the past
 759
 760 =head3 TOO_MANY
 761
 762 if the borrower borrows to much things
 763
 764 =head3 RECALLED
 765
 766 recalled by someone else
 767
 768 =cut
 769
 770 sub CanBookBeIssued {
 771     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 772     my %needsconfirmation;    # filled with problems that needs confirmations
 773     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 774     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 775     my %messages;             # filled with information messages that should be displayed.
 776
 777     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 778     my $override_high_holds = $params->{override_high_holds} || 0;
 779
 780     my $item_object = Koha::Items->find({barcode => $barcode });
 781
 782     # MANDATORY CHECKS - unless item exists, nothing else matters
 783     unless ( $item_object ) {
 784         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 785     }
 786     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 787
 788     my $item_unblessed = $item_object->unblessed; # Transition...
 789     my $issue = $item_object->checkout;
 790     my $biblio = $item_object->biblio;
 791
 792     my $biblioitem = $biblio->biblioitem;
 793     my $effective_itemtype = $item_object->effective_itemtype;
 794     my $dbh             = C4::Context->dbh;
 795     my $patron_unblessed = $patron->unblessed;
 796
 797     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 798     #
 799     # DUE DATE is OK ? -- should already have checked.
 800     #
 801     if ($duedate && ref $duedate ne 'DateTime') {
 802         $duedate = dt_from_string($duedate);
 803     }
 804     my $now = dt_from_string();
 805     unless ( $duedate ) {
 806         my $issuedate = $now->clone();
 807
 808         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 809
 810         # Offline circ calls AddIssue directly, doesn't run through here
 811         #  So issuingimpossible should be ok.
 812     }
 813
 814     my $fees = Koha::Charges::Fees->new(
 815         {
 816             patron    => $patron,
 817             library   => $circ_library,
 818             item      => $item_object,
 819             to_date   => $duedate,
 820         }
 821     );
 822
 823     if ($duedate) {
 824         my $today = $now->clone();
 825         $today->truncate( to => 'minute');
 826         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 827             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 828         }
 829     } else {
 830             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 831     }
 832
 833     #
 834     # BORROWER STATUS
 835     #
 836     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 837         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 838         C4::Stats::UpdateStats({
 839                      branch => C4::Context->userenv->{'branch'},
 840                      type => 'localuse',
 841                      itemnumber => $item_object->itemnumber,
 842                      itemtype => $effective_itemtype,
 843                      borrowernumber => $patron->borrowernumber,
 844                      ccode => $item_object->ccode}
 845                     );
 846         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 847         return( { STATS => 1 }, {});
 848     }
 849
 850     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 851         $issuingimpossible{GNA} = 1;
 852     }
 853
 854     if ( $patron->lost && $patron->lost == 1 ) {
 855         $issuingimpossible{CARD_LOST} = 1;
 856     }
 857     if ( $patron->is_debarred ) {
 858         $issuingimpossible{DEBARRED} = 1;
 859     }
 860
 861     if ( $patron->is_expired ) {
 862         $issuingimpossible{EXPIRED} = 1;
 863     }
 864
 865     #
 866     # BORROWER STATUS
 867     #
 868
 869     # DEBTS
 870     my $account = $patron->account;
 871     my $balance = $account->balance;
 872     my $non_issues_charges = $account->non_issues_charges;
 873     my $other_charges = $balance - $non_issues_charges;
 874
 875     my $amountlimit = C4::Context->preference("noissuescharge");
 876     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 877     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 878
 879     # Check the debt of this patrons guarantees
 880     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 881     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 882     if ( defined $no_issues_charge_guarantees ) {
 883         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 884         my $guarantees_non_issues_charges = 0;
 885         foreach my $g ( @guarantees ) {
 886             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 887         }
 888
 889         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 890             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 891         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 892             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 893         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 894             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 895         }
 896     }
 897
 898     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 899     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 900     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 901     if ( defined $no_issues_charge_guarantors ) {
 902         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 903
 904         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 905             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 906         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 907             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 908         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 909             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 910         }
 911     }
 912
 913     if ( C4::Context->preference("IssuingInProcess") ) {
 914         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 915             $issuingimpossible{DEBT} = $non_issues_charges;
 916         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 917             $needsconfirmation{DEBT} = $non_issues_charges;
 918         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 919             $needsconfirmation{DEBT} = $non_issues_charges;
 920         }
 921     }
 922     else {
 923         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 924             $needsconfirmation{DEBT} = $non_issues_charges;
 925         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 926             $issuingimpossible{DEBT} = $non_issues_charges;
 927         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 928             $needsconfirmation{DEBT} = $non_issues_charges;
 929         }
 930     }
 931
 932     if ($balance > 0 && $other_charges > 0) {
 933         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 934     }
 935
 936     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 937     $patron_unblessed = $patron->unblessed;
 938
 939     if ( my $debarred_date = $patron->is_debarred ) {
 940          # patron has accrued fine days or has a restriction. $count is a date
 941         if ($debarred_date eq '9999-12-31') {
 942             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 943         }
 944         else {
 945             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 946         }
 947     } elsif ( my $num_overdues = $patron->has_overdues ) {
 948         ## patron has outstanding overdue loans
 949         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 950             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 951         }
 952         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 953             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 954         }
 955     }
 956
 957     # Additional Materials Check
 958     if ( C4::Context->preference("CircConfirmItemParts")
 959         && $item_object->materials )
 960     {
 961         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 962     }
 963
 964     #
 965     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 966     #
 967     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 968
 969         # Already issued to current borrower.
 970         # If it is an on-site checkout if it can be switched to a normal checkout
 971         # or ask whether the loan should be renewed
 972
 973         if ( $issue->onsite_checkout
 974                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 975             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 976         } else {
 977             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 978                 $patron->borrowernumber,
 979                 $item_object->itemnumber,
 980             );
 981             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 982                 if ( $renewerror eq 'onsite_checkout' ) {
 983                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 984                 }
 985                 else {
 986                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 987                 }
 988             }
 989             else {
 990                 $needsconfirmation{RENEW_ISSUE} = 1;
 991             }
 992         }
 993     }
 994     elsif ( $issue ) {
 995
 996         # issued to someone else
 997
 998         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 999
1000         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1001
1002         unless ( $can_be_returned ) {
1003             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
1004             $issuingimpossible{branch_to_return} = $message;
1005         } else {
1006             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
1007                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
1008             } else {
1009             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
1010             $needsconfirmation{issued_firstname} = $patron->firstname;
1011             $needsconfirmation{issued_surname} = $patron->surname;
1012             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
1013             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
1014             }
1015         }
1016     }
1017
1018     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1019     #
1020     my $switch_onsite_checkout = (
1021           C4::Context->preference('SwitchOnSiteCheckouts')
1022       and $issue
1023       and $issue->onsite_checkout
1024       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1025     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1026     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1027     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1028         if ( $toomany->{max_allowed} == 0 ) {
1029             $needsconfirmation{PATRON_CANT} = 1;
1030         }
1031         if ( C4::Context->preference("AllowTooManyOverride") ) {
1032             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1033             $needsconfirmation{current_loan_count} = $toomany->{count};
1034             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1035         } else {
1036             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1037             $issuingimpossible{current_loan_count} = $toomany->{count};
1038             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1039         }
1040     }
1041
1042     #
1043     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1044     #
1045     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1046     my $wants_check = $patron->wants_check_for_previous_checkout;
1047     $needsconfirmation{PREVISSUE} = 1
1048         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1049
1050     #
1051     # ITEM CHECKING
1052     #
1053     if ( $item_object->notforloan )
1054     {
1055         if(!C4::Context->preference("AllowNotForLoanOverride")){
1056             $issuingimpossible{NOT_FOR_LOAN} = 1;
1057             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1058         }else{
1059             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1060             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1061         }
1062     }
1063     else {
1064         # we have to check itemtypes.notforloan also
1065         if (C4::Context->preference('item-level_itypes')){
1066             # this should probably be a subroutine
1067             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1068             $sth->execute($effective_itemtype);
1069             my $notforloan=$sth->fetchrow_hashref();
1070             if ($notforloan->{'notforloan'}) {
1071                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1072                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1073                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1074                 } else {
1075                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1076                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1077                 }
1078             }
1079         }
1080         else {
1081             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1082             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1083                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1084                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1085                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1086                 } else {
1087                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1088                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1089                 }
1090             }
1091         }
1092     }
1093     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1094     {
1095         $issuingimpossible{WTHDRAWN} = 1;
1096     }
1097     if (   $item_object->restricted
1098         && $item_object->restricted == 1 )
1099     {
1100         $issuingimpossible{RESTRICTED} = 1;
1101     }
1102     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1103         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1104         my $code = $av->count ? $av->next->lib : '';
1105         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1106         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1107     }
1108     if ( C4::Context->preference("IndependentBranches") ) {
1109         my $userenv = C4::Context->userenv;
1110         unless ( C4::Context->IsSuperLibrarian() ) {
1111             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1112             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1113                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1114                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1115             }
1116             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1117               if ( $patron->branchcode ne $userenv->{branch} );
1118         }
1119     }
1120
1121     #
1122     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1123     #
1124     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1125     if ($rentalConfirmation) {
1126         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1127
1128         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1129         if ($itemtype_object) {
1130             my $accumulate_charge = $fees->accumulate_rentalcharge();
1131             if ( $accumulate_charge > 0 ) {
1132                 $rentalCharge += $accumulate_charge;
1133             }
1134         }
1135
1136         if ( $rentalCharge > 0 ) {
1137             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1138         }
1139     }
1140
1141     my $recall;
1142     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1143     # Only bother doing this if UseRecalls is enabled and the item is recallable
1144     # Don't look at recalls that are in transit
1145     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1146         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1147
1148         foreach my $r ( @recalls ) {
1149             if ( $r->item_id and
1150                 $r->item_id == $item_object->itemnumber and
1151                 $r->patron_id == $patron->borrowernumber and
1152                 ( $r->waiting or $r->requested ) ) {
1153                 $messages{RECALLED} = $r->id;
1154                 $recall = $r;
1155                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1156                 last;
1157             }
1158             elsif ( $r->item_id and
1159                 $r->item_id == $item_object->itemnumber and
1160                 $r->in_transit ) {
1161                 # recalled item is in transit
1162                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1163             }
1164             elsif ( $r->item_level and
1165                 $r->item_id == $item_object->itemnumber and
1166                 $r->patron_id != $patron->borrowernumber and
1167                 !$r->in_transit ) {
1168                 # this specific item has been recalled by a different patron
1169                 $needsconfirmation{RECALLED} = $r;
1170                 $recall = $r;
1171                 last;
1172             }
1173             elsif ( !$r->item_level and
1174                 $r->patron_id != $patron->borrowernumber and
1175                 !$r->in_transit ) {
1176                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1177                 $needsconfirmation{RECALLED} = $r;
1178                 $recall = $r;
1179                 last;
1180             }
1181         }
1182     }
1183
1184     unless ( $ignore_reserves and defined $recall ) {
1185         # See if the item is on reserve.
1186         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1187         if ($restype) {
1188             my $resbor = $res->{'borrowernumber'};
1189             if ( $resbor ne $patron->borrowernumber ) {
1190                 my $patron = Koha::Patrons->find( $resbor );
1191                 if ( $restype eq "Waiting" )
1192                 {
1193                     # The item is on reserve and waiting, but has been
1194                     # reserved by some other patron.
1195                     $needsconfirmation{RESERVE_WAITING} = 1;
1196                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1197                     $needsconfirmation{'ressurname'} = $patron->surname;
1198                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1199                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1200                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1201                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1202                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1203                 }
1204                 elsif ( $restype eq "Reserved" ) {
1205                     # The item is on reserve for someone else.
1206                     $needsconfirmation{RESERVED} = 1;
1207                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1208                     $needsconfirmation{'ressurname'} = $patron->surname;
1209                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1210                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1211                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1212                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1213                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1214                 }
1215                 elsif ( $restype eq "Transferred" ) {
1216                     # The item is determined hold being transferred for someone else.
1217                     $needsconfirmation{TRANSFERRED} = 1;
1218                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1219                     $needsconfirmation{'ressurname'} = $patron->surname;
1220                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1221                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1222                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1223                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1224                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1225                 }
1226                 elsif ( $restype eq "Processing" ) {
1227                     # The item is determined hold being processed for someone else.
1228                     $needsconfirmation{PROCESSING} = 1;
1229                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1230                     $needsconfirmation{'ressurname'} = $patron->surname;
1231                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1232                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1233                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1234                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1235                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1236                 }
1237             }
1238         }
1239     }
1240
1241     ## CHECK AGE RESTRICTION
1242     my $agerestriction  = $biblioitem->agerestriction;
1243     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1244     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1245         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1246             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1247         }
1248         else {
1249             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1250         }
1251     }
1252
1253     ## check for high holds decreasing loan period
1254     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1255         my $check = checkHighHolds( $item_object, $patron );
1256
1257         if ( $check->{exceeded} ) {
1258             if ($override_high_holds) {
1259                 $alerts{HIGHHOLDS} = {
1260                     num_holds  => $check->{outstanding},
1261                     duration   => $check->{duration},
1262                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1263                 };
1264             }
1265             else {
1266                 $needsconfirmation{HIGHHOLDS} = {
1267                     num_holds  => $check->{outstanding},
1268                     duration   => $check->{duration},
1269                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1270                 };
1271             }
1272         }
1273     }
1274
1275     if (
1276         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1277         # don't do the multiple loans per bib check if we've
1278         # already determined that we've got a loan on the same item
1279         !$issuingimpossible{NO_MORE_RENEWALS} &&
1280         !$needsconfirmation{RENEW_ISSUE}
1281     ) {
1282         # Check if borrower has already issued an item from the same biblio
1283         # Only if it's not a subscription
1284         my $biblionumber = $item_object->biblionumber;
1285         require C4::Serials;
1286         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1287         unless ($is_a_subscription) {
1288             # FIXME Should be $patron->checkouts($args);
1289             my $checkouts = Koha::Checkouts->search(
1290                 {
1291                     borrowernumber => $patron->borrowernumber,
1292                     biblionumber   => $biblionumber,
1293                 },
1294                 {
1295                     join => 'item',
1296                 }
1297             );
1298             # if we get here, we don't already have a loan on this item,
1299             # so if there are any loans on this bib, ask for confirmation
1300             if ( $checkouts->count ) {
1301                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1302             }
1303         }
1304     }
1305
1306     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1307 }
1308
1309 =head2 CanBookBeReturned
1310
1311   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1312
1313 Check whether the item can be returned to the provided branch
1314
1315 =over 4
1316
1317 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1318
1319 =item C<$branch> is the branchcode where the return is taking place
1320
1321 =back
1322
1323 Returns:
1324
1325 =over 4
1326
1327 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1328
1329 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1330
1331 =back
1332
1333 =cut
1334
1335 sub CanBookBeReturned {
1336   my ($item, $branch) = @_;
1337   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1338
1339   # assume return is allowed to start
1340   my $allowed = 1;
1341   my $message;
1342
1343   # identify all cases where return is forbidden
1344   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1345      $allowed = 0;
1346      $message = $item->{'homebranch'};
1347   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1348      $allowed = 0;
1349      $message = $item->{'holdingbranch'};
1350   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1351      $allowed = 0;
1352      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1353   }
1354
1355   return ($allowed, $message);
1356 }
1357
1358 =head2 CheckHighHolds
1359
1360     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1361     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1362     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1363
1364 =cut
1365
1366 sub checkHighHolds {
1367     my ( $item, $patron ) = @_;
1368     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1369
1370     my $return_data = {
1371         exceeded    => 0,
1372         outstanding => 0,
1373         duration    => 0,
1374         due_date    => undef,
1375     };
1376
1377     my $holds = Koha::Holds->search( { biblionumber => $item->biblionumber } );
1378
1379     if ( $holds->count() ) {
1380         $return_data->{outstanding} = $holds->count();
1381
1382         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1383         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1384         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1385
1386         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1387
1388         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1389
1390             # static means just more than a given number of holds on the record
1391
1392             # If the number of holds is less than the threshold, we can stop here
1393             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1394                 return $return_data;
1395             }
1396         }
1397         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1398
1399             # dynamic means X more than the number of holdable items on the record
1400
1401             # let's get the items
1402             my @items = $holds->next()->biblio()->items()->as_list;
1403
1404             # Remove any items with status defined to be ignored even if the would not make item unholdable
1405             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1406                 @items = grep { !$_->$status } @items;
1407             }
1408
1409             # Remove any items that are not holdable for this patron
1410             @items = grep { CanItemBeReserved( $patron , $_, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1411
1412             my $items_count = scalar @items;
1413
1414             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1415
1416             # If the number of holds is less than the count of items we have
1417             # plus the number of holds allowed above that count, we can stop here
1418             if ( $holds->count() <= $threshold ) {
1419                 return $return_data;
1420             }
1421         }
1422
1423         my $issuedate = dt_from_string();
1424
1425         my $itype = $item->effective_itemtype;
1426         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1427             {
1428                 categorycode => $patron->categorycode,
1429                 itemtype     => $itype,
1430                 branchcode   => $branchcode,
1431             }
1432         );
1433         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1434
1435         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1436
1437         my $rule = Koha::CirculationRules->get_effective_rule(
1438             {
1439                 categorycode => $patron->categorycode,
1440                 itemtype     => $item->effective_itemtype,
1441                 branchcode   => $branchcode,
1442                 rule_name    => 'decreaseloanholds',
1443             }
1444         );
1445
1446         my $duration;
1447         if ( defined($rule) && $rule->rule_value ne '' ){
1448             # overrides decreaseLoanHighHoldsDuration syspref
1449             $duration = $rule->rule_value;
1450         } else {
1451             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1452         }
1453         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1454         $reduced_datedue->set_hour($orig_due->hour);
1455         $reduced_datedue->set_minute($orig_due->minute);
1456         $reduced_datedue->truncate( to => 'minute' );
1457
1458         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1459             $return_data->{exceeded} = 1;
1460             $return_data->{duration} = $duration;
1461             $return_data->{due_date} = $reduced_datedue;
1462         }
1463     }
1464
1465     return $return_data;
1466 }
1467
1468 =head2 AddIssue
1469
1470   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1471
1472 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1473
1474 =over 4
1475
1476 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1477
1478 =item C<$barcode> is the barcode of the item being issued.
1479
1480 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1481 Calculated if empty.
1482
1483 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1484
1485 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1486 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1487
1488 AddIssue does the following things :
1489
1490   - step 01: check that there is a borrowernumber & a barcode provided
1491   - check for RENEWAL (book issued & being issued to the same patron)
1492       - renewal YES = Calculate Charge & renew
1493       - renewal NO  =
1494           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1495           * RESERVE PLACED ?
1496               - fill reserve if reserve to this patron
1497               - cancel reserve or not, otherwise
1498           * RECALL PLACED ?
1499               - fill recall if recall to this patron
1500               - cancel recall or not
1501               - revert recall's waiting status or not
1502           * TRANSFERT PENDING ?
1503               - complete the transfert
1504           * ISSUE THE BOOK
1505
1506 =back
1507
1508 =cut
1509
1510 sub AddIssue {
1511     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1512
1513     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1514     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1515     my $auto_renew = $params && $params->{auto_renew};
1516     my $cancel_recall = $params && $params->{cancel_recall};
1517     my $recall_id = $params && $params->{recall_id};
1518     my $dbh          = C4::Context->dbh;
1519     my $barcodecheck = CheckValidBarcode($barcode);
1520
1521     my $issue;
1522
1523     if ( $datedue && ref $datedue ne 'DateTime' ) {
1524         $datedue = dt_from_string($datedue);
1525     }
1526
1527     # $issuedate defaults to today.
1528     if ( !defined $issuedate ) {
1529         $issuedate = dt_from_string();
1530     }
1531     else {
1532         if ( ref $issuedate ne 'DateTime' ) {
1533             $issuedate = dt_from_string($issuedate);
1534
1535         }
1536     }
1537
1538     # Stop here if the patron or barcode doesn't exist
1539     if ( $borrower && $barcode && $barcodecheck ) {
1540         # find which item we issue
1541         my $item_object = Koha::Items->find({ barcode => $barcode })
1542           or return;    # if we don't get an Item, abort.
1543         my $item_unblessed = $item_object->unblessed;
1544
1545         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1546
1547         # get actual issuing if there is one
1548         my $actualissue = $item_object->checkout;
1549
1550         # check if we just renew the issue.
1551         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1552                 and not $switch_onsite_checkout ) {
1553             $datedue = AddRenewal(
1554                 $borrower->{'borrowernumber'},
1555                 $item_object->itemnumber,
1556                 $branchcode,
1557                 $datedue,
1558                 $issuedate,    # here interpreted as the renewal date
1559             );
1560         }
1561         else {
1562             unless ($datedue) {
1563                 my $itype = $item_object->effective_itemtype;
1564                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1565
1566             }
1567             $datedue->truncate( to => 'minute' );
1568
1569             my $patron = Koha::Patrons->find( $borrower );
1570             my $library = Koha::Libraries->find( $branchcode );
1571             my $fees = Koha::Charges::Fees->new(
1572                 {
1573                     patron    => $patron,
1574                     library   => $library,
1575                     item      => $item_object,
1576                     to_date   => $datedue,
1577                 }
1578             );
1579
1580             # it's NOT a renewal
1581             if ( $actualissue and not $switch_onsite_checkout ) {
1582                 # This book is currently on loan, but not to the person
1583                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1584                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1585                 return unless $allowed;
1586                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1587                 # AddReturn certainly has side-effects, like onloan => undef
1588                 $item_object->discard_changes;
1589             }
1590
1591             if ( C4::Context->preference('UseRecalls') ) {
1592                 Koha::Recalls->move_recall(
1593                     {
1594                         action         => $cancel_recall,
1595                         recall_id      => $recall_id,
1596                         item           => $item_object,
1597                         borrowernumber => $borrower->{borrowernumber},
1598                     }
1599                 );
1600             }
1601
1602             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1603
1604             # Starting process for transfer job (checking transfert and validate it if we have one)
1605             if ( my $transfer = $item_object->get_transfer ) {
1606                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1607                 $transfer->set(
1608                     {
1609                         datearrived => dt_from_string,
1610                         tobranch    => C4::Context->userenv->{branch},
1611                         comments    => 'Forced branchtransfer'
1612                     }
1613                 )->store;
1614                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1615                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1616                     if ( $hold ) { # Is this really needed?
1617                         $hold->set( { found => undef } )->store;
1618                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1619                     }
1620                 }
1621             }
1622
1623             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1624             unless ($auto_renew) {
1625                 my $rule = Koha::CirculationRules->get_effective_rule(
1626                     {
1627                         categorycode => $borrower->{categorycode},
1628                         itemtype     => $item_object->effective_itemtype,
1629                         branchcode   => $branchcode,
1630                         rule_name    => 'auto_renew'
1631                     }
1632                 );
1633
1634                 $auto_renew = $rule->rule_value if $rule;
1635             }
1636
1637             my $issue_attributes = {
1638                 borrowernumber  => $borrower->{'borrowernumber'},
1639                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1640                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1641                 branchcode      => C4::Context->userenv->{'branch'},
1642                 onsite_checkout => $onsite_checkout,
1643                 auto_renew      => $auto_renew ? 1 : 0,
1644             };
1645
1646             # Get ID of logged in user.  if called from a batch job,
1647             # no user session exists and C4::Context->userenv() returns
1648             # the scalar '0'. Only do this if the syspref says so
1649             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1650                 my $userenv = C4::Context->userenv();
1651                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1652                 if ($usernumber) {
1653                     $issue_attributes->{issuer_id} = $usernumber;
1654                 }
1655             }
1656
1657             # In the case that the borrower has an on-site checkout
1658             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1659             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1660             if ($issue) {
1661                 $issue->set($issue_attributes)->store;
1662             }
1663             else {
1664                 $issue = Koha::Checkout->new(
1665                     {
1666                         itemnumber => $item_object->itemnumber,
1667                         %$issue_attributes,
1668                     }
1669                 )->store;
1670             }
1671             $issue->discard_changes;
1672             C4::Auth::track_login_daily( $borrower->{userid} );
1673             if ( $item_object->location && $item_object->location eq 'CART'
1674                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1675             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1676                 CartToShelf( $item_object->itemnumber );
1677             }
1678
1679             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1680                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1681             }
1682
1683             # Record if item was lost
1684             my $was_lost = $item_object->itemlost;
1685
1686             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1687             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1688             $item_object->itemlost(0);
1689             $item_object->onloan($datedue->ymd());
1690             $item_object->datelastborrowed( dt_from_string()->ymd() );
1691             $item_object->datelastseen( dt_from_string()->ymd() );
1692             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1693
1694             # If the item was lost, it has now been found, charge the overdue if necessary
1695             if ($was_lost) {
1696                 if ( $item_object->{_charge} ) {
1697                     $actualissue //= Koha::Old::Checkouts->search(
1698                         { itemnumber => $item_unblessed->{itemnumber} },
1699                         {
1700                             order_by => { '-desc' => 'returndate' },
1701                             rows     => 1
1702                         }
1703                     )->single;
1704                     unless ( exists( $borrower->{branchcode} ) ) {
1705                         my $patron = $actualissue->patron;
1706                         $borrower = $patron->unblessed;
1707                     }
1708                     _CalculateAndUpdateFine(
1709                         {
1710                             issue       => $actualissue,
1711                             item        => $item_unblessed,
1712                             borrower    => $borrower,
1713                             return_date => $issuedate
1714                         }
1715                     );
1716                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1717                         $item_object->itemnumber, undef, 'RENEWED' );
1718                 }
1719             }
1720
1721             # If it costs to borrow this book, charge it to the patron's account.
1722             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1723             if ( $charge && $charge > 0 ) {
1724                 AddIssuingCharge( $issue, $charge, 'RENT' );
1725             }
1726
1727             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1728             if ( $itemtype_object ) {
1729                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1730                 if ( $accumulate_charge > 0 ) {
1731                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1732                     $charge += $accumulate_charge;
1733                     $item_unblessed->{charge} = $charge;
1734                 }
1735             }
1736
1737             # Record the fact that this book was issued.
1738             C4::Stats::UpdateStats(
1739                 {
1740                     branch => C4::Context->userenv->{'branch'},
1741                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1742                     amount         => $charge,
1743                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1744                     itemnumber     => $item_object->itemnumber,
1745                     itemtype       => $item_object->effective_itemtype,
1746                     location       => $item_object->location,
1747                     borrowernumber => $borrower->{'borrowernumber'},
1748                     ccode          => $item_object->ccode,
1749                 }
1750             );
1751
1752             # Send a checkout slip.
1753             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1754             my %conditions        = (
1755                 branchcode   => $branchcode,
1756                 categorycode => $borrower->{categorycode},
1757                 item_type    => $item_object->effective_itemtype,
1758                 notification => 'CHECKOUT',
1759             );
1760             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1761                 SendCirculationAlert(
1762                     {
1763                         type     => 'CHECKOUT',
1764                         item     => $item_object->unblessed,
1765                         borrower => $borrower,
1766                         branch   => $branchcode,
1767                     }
1768                 );
1769             }
1770             logaction(
1771                 "CIRCULATION", "ISSUE",
1772                 $borrower->{'borrowernumber'},
1773                 $item_object->itemnumber,
1774             ) if C4::Context->preference("IssueLog");
1775
1776             Koha::Plugins->call('after_circ_action', {
1777                 action  => 'checkout',
1778                 payload => {
1779                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1780                     checkout => $issue->get_from_storage
1781                 }
1782             });
1783
1784             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1785                 {
1786                     biblio_ids => [ $item_object->biblionumber ]
1787                 }
1788             ) if C4::Context->preference('RealTimeHoldsQueue');
1789         }
1790     }
1791     return $issue;
1792 }
1793
1794 =head2 GetLoanLength
1795
1796   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1797
1798 Get loan length for an itemtype, a borrower type and a branch
1799
1800 =cut
1801
1802 sub GetLoanLength {
1803     my ( $categorycode, $itemtype, $branchcode ) = @_;
1804
1805     # Initialize default values
1806     my $rules = {
1807         issuelength   => 0,
1808         renewalperiod => 0,
1809         lengthunit    => 'days',
1810     };
1811
1812     my $found = Koha::CirculationRules->get_effective_rules( {
1813         branchcode => $branchcode,
1814         categorycode => $categorycode,
1815         itemtype => $itemtype,
1816         rules => [
1817             'issuelength',
1818             'renewalperiod',
1819             'lengthunit'
1820         ],
1821     } );
1822
1823     # Search for rules!
1824     foreach my $rule_name (keys %$found) {
1825         $rules->{$rule_name} = $found->{$rule_name};
1826     }
1827
1828     return $rules;
1829 }
1830
1831
1832 =head2 GetHardDueDate
1833
1834   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1835
1836 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1837
1838 =cut
1839
1840 sub GetHardDueDate {
1841     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1842
1843     my $rules = Koha::CirculationRules->get_effective_rules(
1844         {
1845             categorycode => $borrowertype,
1846             itemtype     => $itemtype,
1847             branchcode   => $branchcode,
1848             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1849         }
1850     );
1851
1852     if ( defined( $rules->{hardduedate} ) ) {
1853         if ( $rules->{hardduedate} ) {
1854             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1855         }
1856         else {
1857             return ( undef, undef );
1858         }
1859     }
1860 }
1861
1862 =head2 GetBranchBorrowerCircRule
1863
1864   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1865
1866 Retrieves circulation rule attributes that apply to the given
1867 branch and patron category, regardless of item type.
1868 The return value is a hashref containing the following key:
1869
1870 patron_maxissueqty - maximum number of loans that a
1871 patron of the given category can have at the given
1872 branch.  If the value is undef, no limit.
1873
1874 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1875 patron of the given category can have at the given
1876 branch.  If the value is undef, no limit.
1877
1878 This will check for different branch/category combinations in the following order:
1879 branch and category
1880 branch only
1881 category only
1882 default branch and category
1883
1884 If no rule has been found in the database, it will default to
1885 the buillt in rule:
1886
1887 patron_maxissueqty - undef
1888 patron_maxonsiteissueqty - undef
1889
1890 C<$branchcode> and C<$categorycode> should contain the
1891 literal branch code and patron category code, respectively - no
1892 wildcards.
1893
1894 =cut
1895
1896 sub GetBranchBorrowerCircRule {
1897     my ( $branchcode, $categorycode ) = @_;
1898
1899     # Initialize default values
1900     my $rules = {
1901         patron_maxissueqty       => undef,
1902         patron_maxonsiteissueqty => undef,
1903     };
1904
1905     # Search for rules!
1906     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1907         my $rule = Koha::CirculationRules->get_effective_rule(
1908             {
1909                 categorycode => $categorycode,
1910                 itemtype     => undef,
1911                 branchcode   => $branchcode,
1912                 rule_name    => $rule_name,
1913             }
1914         );
1915
1916         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1917     }
1918
1919     return $rules;
1920 }
1921
1922 =head2 GetBranchItemRule
1923
1924   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1925
1926 Retrieves circulation rule attributes that apply to the given
1927 branch and item type, regardless of patron category.
1928
1929 The return value is a hashref containing the following keys:
1930
1931 holdallowed => Hold policy for this branch and itemtype. Possible values:
1932   not_allowed:           No holds allowed.
1933   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1934   from_any_library:      Holds allowed from any patron.
1935   from_local_hold_group: Holds allowed from libraries in hold group
1936
1937 returnbranch => branch to which to return item.  Possible values:
1938   noreturn: do not return, let item remain where checked in (floating collections)
1939   homebranch: return to item's home branch
1940   holdingbranch: return to issuer branch
1941
1942 This searches branchitemrules in the following order:
1943
1944   * Same branchcode and itemtype
1945   * Same branchcode, itemtype '*'
1946   * branchcode '*', same itemtype
1947   * branchcode and itemtype '*'
1948
1949 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1950
1951 =cut
1952
1953 sub GetBranchItemRule {
1954     my ( $branchcode, $itemtype ) = @_;
1955
1956     # Search for rules!
1957     my $rules = Koha::CirculationRules->get_effective_rules({
1958         branchcode => $branchcode,
1959         itemtype => $itemtype,
1960         rules => ['holdallowed', 'hold_fulfillment_policy', 'returnbranch']
1961     });
1962
1963     # built-in default circulation rule
1964     $rules->{holdallowed} //= 'from_any_library';
1965     $rules->{hold_fulfillment_policy} //= 'any';
1966     $rules->{returnbranch} //= 'homebranch';
1967
1968     return $rules;
1969 }
1970
1971 =head2 AddReturn
1972
1973   ($doreturn, $messages, $iteminformation, $borrower) =
1974       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1975
1976 Returns a book.
1977
1978 =over 4
1979
1980 =item C<$barcode> is the bar code of the book being returned.
1981
1982 =item C<$branch> is the code of the branch where the book is being returned.
1983
1984 =item C<$exemptfine> indicates that overdue charges for the item will be
1985 removed. Optional.
1986
1987 =item C<$return_date> allows the default return date to be overridden
1988 by the given return date. Optional.
1989
1990 =back
1991
1992 C<&AddReturn> returns a list of four items:
1993
1994 C<$doreturn> is true iff the return succeeded.
1995
1996 C<$messages> is a reference-to-hash giving feedback on the operation.
1997 The keys of the hash are:
1998
1999 =over 4
2000
2001 =item C<BadBarcode>
2002
2003 No item with this barcode exists. The value is C<$barcode>.
2004
2005 =item C<NotIssued>
2006
2007 The book is not currently on loan. The value is C<$barcode>.
2008
2009 =item C<withdrawn>
2010
2011 This book has been withdrawn/cancelled. The value should be ignored.
2012
2013 =item C<Wrongbranch>
2014
2015 This book has was returned to the wrong branch.  The value is a hashref
2016 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2017 contain the branchcode of the incorrect and correct return library, respectively.
2018
2019 =item C<ResFound>
2020
2021 The item was reserved. The value is a reference-to-hash whose keys are
2022 fields from the reserves table of the Koha database, and
2023 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2024 either C<Waiting>, C<Reserved>, or 0.
2025
2026 =item C<WasReturned>
2027
2028 Value 1 if return is successful.
2029
2030 =item C<NeedsTransfer>
2031
2032 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2033
2034 =item C<RecallFound>
2035
2036 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2037 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2038 branchcode.
2039
2040 =item C<TransferredRecall>
2041
2042 This item has been transferred to this branch to fill a recall. The recall object is returned.
2043
2044 =back
2045
2046 C<$iteminformation> is a reference-to-hash, giving information about the
2047 returned item from the issues table.
2048
2049 C<$borrower> is a reference-to-hash, giving information about the
2050 patron who last borrowed the book.
2051
2052 =cut
2053
2054 sub AddReturn {
2055     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2056
2057     if ($branch and not Koha::Libraries->find($branch)) {
2058         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2059         undef $branch;
2060     }
2061     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2062     my $return_date_specified = !!$return_date;
2063     $return_date //= dt_from_string();
2064     my $messages;
2065     my $patron;
2066     my $doreturn       = 1;
2067     my $validTransfer = 1;
2068     my $stat_type = 'return';
2069
2070     # get information on item
2071     my $item = Koha::Items->find({ barcode => $barcode });
2072     unless ($item) {
2073         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2074     }
2075
2076     my $itemnumber = $item->itemnumber;
2077     my $itemtype = $item->effective_itemtype;
2078
2079     my $issue  = $item->checkout;
2080     if ( $issue ) {
2081         $patron = $issue->patron
2082             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2083                 . Dumper($issue->unblessed) . "\n";
2084     } else {
2085         $messages->{'NotIssued'} = $barcode;
2086         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2087
2088         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2089         $doreturn = 0;
2090         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2091         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2092         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2093            $messages->{'LocalUse'} = 1;
2094            $stat_type = 'localuse';
2095         }
2096     }
2097
2098         # full item data, but no borrowernumber or checkout info (no issue)
2099     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2100         # get the proper branch to which to return the item
2101     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2102         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2103     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2104
2105     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2106     my $patron_unblessed = $patron ? $patron->unblessed : {};
2107
2108     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2109     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2110     if ($update_loc_rules) {
2111         if (defined $update_loc_rules->{_ALL_}) {
2112             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2113             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2114             if (
2115                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2116                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2117                ) {
2118                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2119                 $item->location($update_loc_rules->{_ALL_})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2120             }
2121         }
2122         else {
2123             foreach my $key ( keys %$update_loc_rules ) {
2124                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2125                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2126                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2127                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2128                     $item->location($update_loc_rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2129                     last;
2130                 }
2131             }
2132         }
2133     }
2134
2135     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2136     if ($yaml) {
2137         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2138         my $rules;
2139         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2140         if ($@) {
2141             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2142         }
2143         else {
2144             foreach my $key ( keys %$rules ) {
2145                 if ( $item->notforloan eq $key ) {
2146                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2147                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2148                     last;
2149                 }
2150             }
2151         }
2152     }
2153
2154     # check if the return is allowed at this branch
2155     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2156     unless ($returnallowed){
2157         $messages->{'Wrongbranch'} = {
2158             Wrongbranch => $branch,
2159             Rightbranch => $message
2160         };
2161         $doreturn = 0;
2162         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2163         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2164         return ( $doreturn, $messages, $issue, $patron_unblessed);
2165     }
2166
2167     if ( $item->withdrawn ) { # book has been cancelled
2168         $messages->{'withdrawn'} = 1;
2169         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2170     }
2171
2172     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2173         $doreturn = 0;
2174     }
2175
2176     # case of a return of document (deal with issues and holdingbranch)
2177     if ($doreturn) {
2178         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2179         $patron or warn "AddReturn without current borrower";
2180
2181         if ($patron) {
2182             eval {
2183                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2184             };
2185             unless ( $@ ) {
2186                 if (
2187                     (
2188                         C4::Context->preference('CalculateFinesOnReturn')
2189                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2190                     )
2191                     && !$item->itemlost
2192                   )
2193                 {
2194                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2195                 }
2196             } else {
2197                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2198
2199                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2200                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2201
2202                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2203             }
2204
2205             # FIXME is the "= 1" right?  This could be the borrower hash.
2206             $messages->{'WasReturned'} = 1;
2207
2208         } else {
2209             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2210         }
2211     }
2212
2213     # the holdingbranch is updated if the document is returned to another location.
2214     # this is always done regardless of whether the item was on loan or not
2215     if ($item->holdingbranch ne $branch) {
2216         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2217     }
2218
2219     my $item_was_lost = $item->itemlost;
2220     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2221     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2222
2223     # fix up the accounts.....
2224     if ($item_was_lost) {
2225         $messages->{'WasLost'} = 1;
2226         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2227             my @object_messages = @{ $updated_item->object_messages };
2228             for my $message (@object_messages) {
2229                 $messages->{'LostItemFeeRefunded'} = 1
2230                   if $message->message eq 'lost_refunded';
2231                 $messages->{'LostItemFeeRestored'} = 1
2232                   if $message->message eq 'lost_restored';
2233
2234                 if ( $message->message eq 'lost_charge' ) {
2235                     $issue //= Koha::Old::Checkouts->search(
2236                         { itemnumber => $item->itemnumber },
2237                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2238                     )->single;
2239                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2240                         my $patron = $issue->patron;
2241                         $patron_unblessed = $patron->unblessed;
2242                     }
2243                     _CalculateAndUpdateFine(
2244                         {
2245                             issue       => $issue,
2246                             item        => $item->unblessed,
2247                             borrower    => $patron_unblessed,
2248                             return_date => $return_date
2249                         }
2250                     );
2251                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2252                         $item->itemnumber, undef, 'RETURNED' );
2253                     $messages->{'LostItemFeeCharged'} = 1;
2254                 }
2255             }
2256         }
2257     }
2258
2259     # check if we have a transfer for this document
2260     my $transfer = $item->get_transfer;
2261
2262     # if we have a transfer to complete, we update the line of transfers with the datearrived
2263     if ($transfer) {
2264         $validTransfer = 0;
2265         if ( $transfer->in_transit ) {
2266             if ( $transfer->tobranch eq $branch ) {
2267                 $transfer->receive;
2268                 $messages->{'TransferArrived'} = $transfer->frombranch;
2269                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2270                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2271             }
2272             else {
2273                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2274                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2275                 $messages->{'TransferTrigger'}   = $transfer->reason;
2276             }
2277         }
2278         else {
2279             if ( $transfer->tobranch eq $branch ) {
2280                 $transfer->receive;
2281                 $messages->{'TransferArrived'} = $transfer->frombranch;
2282                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2283                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2284             }
2285             else {
2286                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2287                 $messages->{'TransferTrigger'} = $transfer->reason;
2288             }
2289         }
2290     }
2291
2292     # fix up the overdues in accounts...
2293     if ($borrowernumber) {
2294         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2295         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2296
2297         if ( $issue and $issue->is_overdue($return_date) ) {
2298         # fix fine days
2299             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2300             if ($reminder){
2301                 $messages->{'PrevDebarred'} = $debardate;
2302             } else {
2303                 $messages->{'Debarred'} = $debardate if $debardate;
2304             }
2305         # there's no overdue on the item but borrower had been previously debarred
2306         } elsif ( $issue->date_due and $patron->debarred ) {
2307              if ( $patron->debarred eq "9999-12-31") {
2308                 $messages->{'ForeverDebarred'} = $patron->debarred;
2309              } else {
2310                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2311                   $borrower_debar_dt->truncate(to => 'day');
2312                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2313                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2314                       $messages->{'PrevDebarred'} = $patron->debarred;
2315                   }
2316              }
2317         }
2318     }
2319
2320     # find recalls...
2321     if ( C4::Context->preference('UseRecalls') ) {
2322         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2323         my $recall = undef;
2324         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2325         if ( defined $recall ) {
2326             $messages->{RecallFound} = $recall;
2327             if ( $recall->pickup_library_id ne $branch ) {
2328                 $messages->{RecallNeedsTransfer} = $branch;
2329             }
2330         }
2331     }
2332
2333     # find reserves.....
2334     # launch the Checkreserves routine to find any holds
2335     my ($resfound, $resrec);
2336     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2337     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2338     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2339     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2340         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2341         $resfound = 'Reserved';
2342         $resrec = $hold->unblessed;
2343     }
2344     if ($resfound) {
2345           $resrec->{'ResFound'} = $resfound;
2346         $messages->{'ResFound'} = $resrec;
2347     }
2348
2349     # Record the fact that this book was returned.
2350     C4::Stats::UpdateStats({
2351         branch         => $branch,
2352         type           => $stat_type,
2353         itemnumber     => $itemnumber,
2354         itemtype       => $itemtype,
2355         location       => $item->location,
2356         borrowernumber => $borrowernumber,
2357         ccode          => $item->ccode,
2358     });
2359
2360     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2361     if ( $patron ) {
2362         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2363         my %conditions = (
2364             branchcode   => $branch,
2365             categorycode => $patron->categorycode,
2366             item_type    => $itemtype,
2367             notification => 'CHECKIN',
2368         );
2369         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2370             SendCirculationAlert({
2371                 type     => 'CHECKIN',
2372                 item     => $item->unblessed,
2373                 borrower => $patron->unblessed,
2374                 branch   => $branch,
2375                 issue    => $issue
2376             });
2377         }
2378
2379         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2380             if C4::Context->preference("ReturnLog");
2381         }
2382
2383     # Check if this item belongs to a biblio record that is attached to an
2384     # ILL request, if it is we need to update the ILL request's status
2385     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2386         my $request = Koha::Illrequests->find(
2387             { biblio_id => $item->biblio->biblionumber }
2388         );
2389         $request->status('RET') if $request;
2390     }
2391
2392     if ( C4::Context->preference('UseRecalls') ) {
2393         # all recalls that have triggered a transfer will have an allocated itemnumber
2394         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2395         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2396             $messages->{TransferredRecall} = $transfer_recall;
2397         }
2398     }
2399
2400     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2401     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2402         && ( $doreturn or $messages->{'NotIssued'} )
2403         and !$resfound
2404         and ( $branch ne $returnbranch )
2405         and not $messages->{'WrongTransfer'}
2406         and not $messages->{'WasTransfered'}
2407         and not $messages->{TransferredRecall}
2408         and not $messages->{RecallNeedsTransfer} )
2409     {
2410         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2411         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2412             (C4::Context->preference("UseBranchTransferLimits") and
2413              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2414            )) {
2415             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2416             $messages->{'WasTransfered'} = $returnbranch;
2417             $messages->{'TransferTrigger'} = $transfer_trigger;
2418         } else {
2419             $messages->{'NeedsTransfer'} = $returnbranch;
2420             $messages->{'TransferTrigger'} = $transfer_trigger;
2421         }
2422     }
2423
2424     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2425         my $claims = Koha::Checkouts::ReturnClaims->search(
2426            {
2427                itemnumber => $item->id,
2428                resolution => undef,
2429            }
2430         );
2431
2432         if ( $claims->count ) {
2433             $messages->{ReturnClaims} = $claims;
2434         }
2435     }
2436
2437     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2438     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2439
2440     if ( $doreturn and $issue ) {
2441         my $checkin = Koha::Old::Checkouts->find($issue->id);
2442
2443         Koha::Plugins->call('after_circ_action', {
2444             action  => 'checkin',
2445             payload => {
2446                 checkout=> $checkin
2447             }
2448         });
2449
2450         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2451             {
2452                 biblio_ids => [ $item->biblionumber ]
2453             }
2454         ) if C4::Context->preference('RealTimeHoldsQueue');
2455     }
2456
2457     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2458 }
2459
2460 =head2 MarkIssueReturned
2461
2462   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2463
2464 Unconditionally marks an issue as being returned by
2465 moving the C<issues> row to C<old_issues> and
2466 setting C<returndate> to the current date.
2467
2468 if C<$returndate> is specified (in iso format), it is used as the date
2469 of the return.
2470
2471 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2472 the old_issue is immediately anonymised
2473
2474 Ideally, this function would be internal to C<C4::Circulation>,
2475 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2476 and offline_circ/process_koc.pl.
2477
2478 The last optional parameter allos passing skip_record_index to the item store call.
2479
2480 =cut
2481
2482 sub MarkIssueReturned {
2483     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2484
2485     # Retrieve the issue
2486     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2487
2488     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2489
2490     my $issue_id = $issue->issue_id;
2491
2492     my $schema = Koha::Database->schema;
2493
2494     # FIXME Improve the return value and handle it from callers
2495     $schema->txn_do(sub {
2496
2497         my $patron = Koha::Patrons->find( $borrowernumber );
2498
2499         # Update the returndate value
2500         if ( $returndate ) {
2501             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2502         }
2503         else {
2504             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2505         }
2506
2507         # Create the old_issues entry
2508         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2509
2510         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2511         if ( $privacy && $privacy == 2) {
2512             $old_checkout->anonymize;
2513         }
2514
2515         # And finally delete the issue
2516         $issue->delete;
2517
2518         $issue->item->onloan(undef)->store(
2519             {   log_action        => 0,
2520                 skip_record_index => $params->{skip_record_index},
2521                 skip_holds_queue  => $params->{skip_holds_queue}
2522             }
2523         );
2524
2525         if ( C4::Context->preference('StoreLastBorrower') ) {
2526             my $item = Koha::Items->find( $itemnumber );
2527             $item->last_returned_by( $patron );
2528         }
2529
2530         # Remove any OVERDUES related debarment if the borrower has no overdues
2531         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2532           && $patron->debarred
2533           && !$patron->has_overdues
2534           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2535         ) {
2536             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2537         }
2538
2539     });
2540
2541     return $issue_id;
2542 }
2543
2544 =head2 _debar_user_on_return
2545
2546     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2547
2548 C<$borrower> borrower hashref
2549
2550 C<$item> item hashref
2551
2552 C<$datedue> date due DateTime object
2553
2554 C<$returndate> DateTime object representing the return time
2555
2556 Internal function, called only by AddReturn that calculates and updates
2557  the user fine days, and debars them if necessary.
2558
2559 Should only be called for overdue returns
2560
2561 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2562 to ease testing.
2563
2564 =cut
2565
2566 sub _calculate_new_debar_dt {
2567     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2568
2569     my $branchcode = _GetCircControlBranch( $item, $borrower );
2570     my $circcontrol = C4::Context->preference('CircControl');
2571     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2572         {   categorycode => $borrower->{categorycode},
2573             itemtype     => $item->{itype},
2574             branchcode   => $branchcode,
2575             rules => [
2576                 'finedays',
2577                 'lengthunit',
2578                 'firstremind',
2579                 'maxsuspensiondays',
2580                 'suspension_chargeperiod',
2581             ]
2582         }
2583     );
2584     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2585     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2586     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2587
2588     return unless $finedays;
2589
2590     # finedays is in days, so hourly loans must multiply by 24
2591     # thus 1 hour late equals 1 day suspension * finedays rate
2592     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2593
2594     # grace period is measured in the same units as the loan
2595     my $grace =
2596       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2597
2598     my $deltadays = DateTime::Duration->new(
2599         days => $chargeable_units
2600     );
2601
2602     if ( $deltadays->subtract($grace)->is_positive() ) {
2603         my $suspension_days = $deltadays * $finedays;
2604
2605         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2606             # No need to / 1 and do not consider / 0
2607             $suspension_days = DateTime::Duration->new(
2608                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2609             );
2610         }
2611
2612         # If the max suspension days is < than the suspension days
2613         # the suspension days is limited to this maximum period.
2614         my $max_sd = $issuing_rule->{maxsuspensiondays};
2615         if ( defined $max_sd && $max_sd ne '' ) {
2616             $max_sd = DateTime::Duration->new( days => $max_sd );
2617             $suspension_days = $max_sd
2618               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2619         }
2620
2621         my ( $has_been_extended );
2622         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2623             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2624             if ( $debarment ) {
2625                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2626                 $has_been_extended = 1;
2627             }
2628         }
2629
2630         my $new_debar_dt;
2631         # Use the calendar or not to calculate the debarment date
2632         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2633             my $calendar = Koha::Calendar->new(
2634                 branchcode => $branchcode,
2635                 days_mode  => 'Calendar'
2636             );
2637             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2638         }
2639         else {
2640             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2641         }
2642         return $new_debar_dt;
2643     }
2644     return;
2645 }
2646
2647 sub _debar_user_on_return {
2648     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2649
2650     $return_date //= dt_from_string();
2651
2652     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2653
2654     return unless $new_debar_dt;
2655
2656     Koha::Patron::Debarments::AddUniqueDebarment({
2657         borrowernumber => $borrower->{borrowernumber},
2658         expiration     => $new_debar_dt->ymd(),
2659         type           => 'SUSPENSION',
2660     });
2661     # if borrower was already debarred but does not get an extra debarment
2662     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2663     my ($new_debarment_str, $is_a_reminder);
2664     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2665         $is_a_reminder = 1;
2666         $new_debarment_str = $borrower->{debarred};
2667     } else {
2668         $new_debarment_str = $new_debar_dt->ymd();
2669     }
2670     # FIXME Should return a DateTime object
2671     return $new_debarment_str, $is_a_reminder;
2672 }
2673
2674 =head2 _FixOverduesOnReturn
2675
2676    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2677
2678 C<$borrowernumber> borrowernumber
2679
2680 C<$itemnumber> itemnumber
2681
2682 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2683
2684 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2685
2686 Internal function
2687
2688 =cut
2689
2690 sub _FixOverduesOnReturn {
2691     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2692     unless( $borrowernumber ) {
2693         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2694         return;
2695     }
2696     unless( $item ) {
2697         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2698         return;
2699     }
2700     unless( $status ) {
2701         warn "_FixOverduesOnReturn() not supplied valid status";
2702         return;
2703     }
2704
2705     my $schema = Koha::Database->schema;
2706
2707     my $result = $schema->txn_do(
2708         sub {
2709             # check for overdue fine
2710             my $accountlines = Koha::Account::Lines->search(
2711                 {
2712                     borrowernumber  => $borrowernumber,
2713                     itemnumber      => $item,
2714                     debit_type_code => 'OVERDUE',
2715                     status          => 'UNRETURNED'
2716                 }
2717             );
2718             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2719
2720             my $accountline = $accountlines->next;
2721             my $payments = $accountline->credits;
2722
2723             my $amountoutstanding = $accountline->amountoutstanding;
2724             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2725                 $accountline->delete;
2726                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2727             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2728                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2729                 my $credit = $account->add_credit(
2730                     {
2731                         amount     => $amountoutstanding,
2732                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2733                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2734                         interface  => C4::Context->interface,
2735                         type       => 'FORGIVEN',
2736                         item_id    => $item
2737                     }
2738                 );
2739
2740                 $credit->apply({ debits => [ $accountline ] });
2741
2742                 if (C4::Context->preference("FinesLog")) {
2743                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2744                 }
2745             }
2746
2747             $accountline->status($status);
2748             return $accountline->store();
2749         }
2750     );
2751
2752     return $result;
2753 }
2754
2755 =head2 _GetCircControlBranch
2756
2757    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2758
2759 Internal function :
2760
2761 Return the library code to be used to determine which circulation
2762 policy applies to a transaction.  Looks up the CircControl and
2763 HomeOrHoldingBranch system preferences.
2764
2765 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2766
2767 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2768
2769 =cut
2770
2771 sub _GetCircControlBranch {
2772     my ($item, $borrower) = @_;
2773     my $circcontrol = C4::Context->preference('CircControl');
2774     my $branch;
2775
2776     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2777         $branch= C4::Context->userenv->{'branch'};
2778     } elsif ($circcontrol eq 'PatronLibrary') {
2779         $branch=$borrower->{branchcode};
2780     } else {
2781         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2782         $branch = $item->{$branchfield};
2783         # default to item home branch if holdingbranch is used
2784         # and is not defined
2785         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2786             $branch = $item->{homebranch};
2787         }
2788     }
2789     return $branch;
2790 }
2791
2792 =head2 GetOpenIssue
2793
2794   $issue = GetOpenIssue( $itemnumber );
2795
2796 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2797
2798 C<$itemnumber> is the item's itemnumber
2799
2800 Returns a hashref
2801
2802 =cut
2803
2804 sub GetOpenIssue {
2805   my ( $itemnumber ) = @_;
2806   return unless $itemnumber;
2807   my $dbh = C4::Context->dbh;
2808   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2809   $sth->execute( $itemnumber );
2810   return $sth->fetchrow_hashref();
2811
2812 }
2813
2814 =head2 GetUpcomingDueIssues
2815
2816   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2817
2818 =cut
2819
2820 sub GetUpcomingDueIssues {
2821     my $params = shift;
2822
2823     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2824     my $dbh = C4::Context->dbh;
2825     my $statement;
2826     $statement = q{
2827         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2828         FROM issues
2829         LEFT JOIN items USING (itemnumber)
2830         LEFT JOIN branches ON branches.branchcode =
2831     };
2832     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2833     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2834     my @bind_parameters = ( $params->{'days_in_advance'} );
2835
2836     my $sth = $dbh->prepare( $statement );
2837     $sth->execute( @bind_parameters );
2838     my $upcoming_dues = $sth->fetchall_arrayref({});
2839
2840     return $upcoming_dues;
2841 }
2842
2843 =head2 CanBookBeRenewed
2844
2845   ($ok,$error,$info) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2846
2847 Find out whether a borrowed item may be renewed.
2848
2849 C<$borrowernumber> is the borrower number of the patron who currently
2850 has the item on loan.
2851
2852 C<$itemnumber> is the number of the item to renew.
2853
2854 C<$override_limit>, if supplied with a true value, causes
2855 the limit on the number of times that the loan can be renewed
2856 (as controlled by the item type) to be ignored. Overriding also allows
2857 to renew sooner than "No renewal before" and to manually renew loans
2858 that are automatically renewed.
2859
2860 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2861 item must currently be on loan to the specified borrower; renewals
2862 must be allowed for the item's type; and the borrower must not have
2863 already renewed the loan.
2864     $error will contain the reason the renewal can not proceed
2865     $info will contain a hash of additional info
2866       currently 'soonest_renew_date' if error is 'too soon'
2867
2868 =cut
2869
2870 sub CanBookBeRenewed {
2871     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2872
2873     my $auto_renew = "no";
2874     my $soonest;
2875
2876     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2877     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2878     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2879     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2880
2881     my $patron = $issue->patron or return;
2882
2883     # override_limit will override anything else except on_reserve
2884     unless ( $override_limit ){
2885         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2886         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2887             {
2888                 categorycode => $patron->categorycode,
2889                 itemtype     => $item->effective_itemtype,
2890                 branchcode   => $branchcode,
2891                 rules => [
2892                     'renewalsallowed',
2893                     'lengthunit',
2894                     'unseen_renewals_allowed'
2895                 ]
2896             }
2897         );
2898
2899         return ( 0, "too_many" )
2900           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2901
2902         return ( 0, "too_unseen" )
2903           if C4::Context->preference('UnseenRenewals') &&
2904             $issuing_rule->{unseen_renewals_allowed} &&
2905             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2906
2907         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2908         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2909         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2910         my $restricted  = $patron->is_debarred;
2911         my $hasoverdues = $patron->has_overdues;
2912
2913         if ( $restricted and $restrictionblockrenewing ) {
2914             return ( 0, 'restriction');
2915         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2916             return ( 0, 'overdue');
2917         }
2918
2919         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
2920             patron     => $patron,
2921             item       => $item,
2922             branchcode => $branchcode,
2923             issue      => $issue
2924         });
2925         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
2926         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2927         # extra notices being sent. Cron also implies no override
2928         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2929         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2930         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2931     }
2932
2933     if ( C4::Context->preference('UseRecalls') ) {
2934         my $recall = undef;
2935         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2936         if ( defined $recall ) {
2937             if ( $recall->item_level ) {
2938                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2939                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
2940             } else {
2941                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2942                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2943             }
2944         }
2945     }
2946
2947     my $biblio_has_holds = Koha::Holds->search({ biblionumber => $item->biblionumber, non_priority => 0 } )->count > 0;
2948     if ( $biblio_has_holds && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') && !Koha::Holds->search( { itemnumber => $itemnumber, found => undef } )->count()
2949  )
2950     {
2951         my $biblio = Koha::Biblios->find($item->biblionumber);
2952         my @possible_holds = $biblio->current_holds->unfilled->search(
2953             {non_priority => 0},
2954             { prefetch => 'patron' }
2955         )->as_list;
2956
2957         # Get all other items that could possibly fill reserves
2958         # FIXME We could join reserves (or more tables) here to eliminate some checks later
2959         my @other_items = Koha::Items->search({
2960             biblionumber => $biblio->biblionumber,
2961             onloan       => undef,
2962             notforloan   => 0,
2963             -not         => { itemnumber => $itemnumber } })->as_list;
2964
2965         return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
2966
2967         my %matched_items;
2968         foreach my $possible_hold (@possible_holds) {
2969             my $fillable = 0;
2970             my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
2971             my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron_with_reserve });
2972
2973             # FIXME: We are not checking whether the item we are renewing can fill the hold
2974
2975             foreach my $other_item (@other_items) {
2976               next if defined $matched_items{$other_item->itemnumber};
2977               next if IsItemOnHoldAndFound( $other_item->itemnumber );
2978               next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef, $items_any_available);
2979               next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
2980               # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
2981               # CanItemBeReserved checks 'rules' and 'policies' which means
2982               # items will fill holds at checkin that are rejected here
2983               $fillable = 1;
2984               $matched_items{$other_item->itemnumber} = 1;
2985               last;
2986             }
2987             return ( 0, "on_reserve" ) unless $fillable;
2988         }
2989
2990     } elsif ($biblio_has_holds) {
2991         my ($status, $matched_reserve, $possible_reserves) = CheckReserves($itemnumber);
2992         return ( 0, "on_reserve" ) if $status;
2993     }
2994
2995     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2996     $soonest = GetSoonestRenewDate($borrowernumber, $itemnumber);
2997     if ( $soonest > dt_from_string() ){
2998         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
2999     }
3000
3001     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
3002
3003     return ( 1, undef );
3004 }
3005
3006 =head2 AddRenewal
3007
3008   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
3009
3010 Renews a loan.
3011
3012 C<$borrowernumber> is the borrower number of the patron who currently
3013 has the item.
3014
3015 C<$itemnumber> is the number of the item to renew.
3016
3017 C<$branch> is the library where the renewal took place (if any).
3018            The library that controls the circ policies for the renewal is retrieved from the issues record.
3019
3020 C<$datedue> can be a DateTime object used to set the due date.
3021
3022 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3023 this parameter is not supplied, lastreneweddate is set to the current date.
3024
3025 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3026 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3027 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3028 syspref)
3029
3030 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3031 from the book's item type.
3032
3033 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3034 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3035 fallback to a true value
3036
3037 =cut
3038
3039 sub AddRenewal {
3040     my $borrowernumber  = shift;
3041     my $itemnumber      = shift or return;
3042     my $branch          = shift;
3043     my $datedue         = shift;
3044     my $lastreneweddate = shift || dt_from_string();
3045     my $skipfinecalc    = shift;
3046     my $seen            = shift;
3047
3048     # Fallback on a 'seen' renewal
3049     $seen = defined $seen && $seen == 0 ? 0 : 1;
3050
3051     my $item_object   = Koha::Items->find($itemnumber) or return;
3052     my $biblio = $item_object->biblio;
3053     my $issue  = $item_object->checkout;
3054     my $item_unblessed = $item_object->unblessed;
3055
3056     my $dbh = C4::Context->dbh;
3057
3058     return unless $issue;
3059
3060     $borrowernumber ||= $issue->borrowernumber;
3061
3062     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3063         carp 'Invalid date passed to AddRenewal.';
3064         return;
3065     }
3066
3067     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3068     my $patron_unblessed = $patron->unblessed;
3069
3070     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3071
3072     my $schema = Koha::Database->schema;
3073     $schema->txn_do(sub{
3074
3075         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3076             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3077         }
3078         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3079
3080         # If the due date wasn't specified, calculate it by adding the
3081         # book's loan length to today's date or the current due date
3082         # based on the value of the RenewalPeriodBase syspref.
3083         my $itemtype = $item_object->effective_itemtype;
3084         unless ($datedue) {
3085
3086             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3087                                             dt_from_string( $issue->date_due, 'sql' ) :
3088                                             dt_from_string();
3089             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3090         }
3091
3092         my $fees = Koha::Charges::Fees->new(
3093             {
3094                 patron    => $patron,
3095                 library   => $circ_library,
3096                 item      => $item_object,
3097                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3098                 to_date   => dt_from_string($datedue),
3099             }
3100         );
3101
3102         # Increment the unseen renewals, if appropriate
3103         # We only do so if the syspref is enabled and
3104         # a maximum value has been set in the circ rules
3105         my $unseen_renewals = $issue->unseen_renewals;
3106         if (C4::Context->preference('UnseenRenewals')) {
3107             my $rule = Koha::CirculationRules->get_effective_rule(
3108                 {   categorycode => $patron->categorycode,
3109                     itemtype     => $item_object->effective_itemtype,
3110                     branchcode   => $circ_library->branchcode,
3111                     rule_name    => 'unseen_renewals_allowed'
3112                 }
3113             );
3114             if (!$seen && $rule && $rule->rule_value) {
3115                 $unseen_renewals++;
3116             } else {
3117                 # If the renewal is seen, unseen should revert to 0
3118                 $unseen_renewals = 0;
3119             }
3120         }
3121
3122         # Update the issues record to have the new due date, and a new count
3123         # of how many times it has been renewed.
3124         my $renews = ( $issue->renewals || 0 ) + 1;
3125         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3126
3127         eval{
3128             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3129         };
3130         if( $sth->err ){
3131             Koha::Exceptions::Checkout::FailedRenewal->throw(
3132                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3133             );
3134         }
3135
3136         # Update the renewal count on the item, and tell zebra to reindex
3137         $renews = ( $item_object->renewals || 0 ) + 1;
3138         $item_object->renewals($renews);
3139         $item_object->onloan($datedue);
3140         $item_object->store({ log_action => 0 });
3141
3142         # Charge a new rental fee, if applicable
3143         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3144         if ( $charge > 0 ) {
3145             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3146         }
3147
3148         # Charge a new accumulate rental fee, if applicable
3149         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3150         if ( $itemtype_object ) {
3151             my $accumulate_charge = $fees->accumulate_rentalcharge();
3152             if ( $accumulate_charge > 0 ) {
3153                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3154             }
3155             $charge += $accumulate_charge;
3156         }
3157
3158         # Send a renewal slip according to checkout alert preferencei
3159         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3160             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3161             my %conditions        = (
3162                 branchcode   => $branch,
3163                 categorycode => $patron->categorycode,
3164                 item_type    => $itemtype,
3165                 notification => 'CHECKOUT',
3166             );
3167             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3168                 SendCirculationAlert(
3169                     {
3170                         type     => 'RENEWAL',
3171                         item     => $item_unblessed,
3172                         borrower => $patron->unblessed,
3173                         branch   => $branch,
3174                     }
3175                 );
3176             }
3177         }
3178
3179         # Remove any OVERDUES related debarment if the borrower has no overdues
3180         if ( $patron
3181           && $patron->is_debarred
3182           && ! $patron->has_overdues
3183           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3184         ) {
3185             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3186         }
3187
3188         # Add the renewal to stats
3189         C4::Stats::UpdateStats(
3190             {
3191                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3192                 type           => 'renew',
3193                 amount         => $charge,
3194                 itemnumber     => $itemnumber,
3195                 itemtype       => $itemtype,
3196                 location       => $item_object->location,
3197                 borrowernumber => $borrowernumber,
3198                 ccode          => $item_object->ccode,
3199             }
3200         );
3201
3202         #Log the renewal
3203         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3204
3205         Koha::Plugins->call('after_circ_action', {
3206             action  => 'renewal',
3207             payload => {
3208                 checkout  => $issue->get_from_storage
3209             }
3210         });
3211     });
3212
3213     return $datedue;
3214 }
3215
3216 sub GetRenewCount {
3217     # check renewal status
3218     my ( $bornum, $itemno ) = @_;
3219     my $dbh           = C4::Context->dbh;
3220     my $renewcount    = 0;
3221     my $unseencount    = 0;
3222     my $renewsallowed = 0;
3223     my $unseenallowed = 0;
3224     my $renewsleft    = 0;
3225     my $unseenleft    = 0;
3226
3227     my $patron = Koha::Patrons->find( $bornum );
3228     my $item   = Koha::Items->find($itemno);
3229
3230     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3231
3232     # Look in the issues table for this item, lent to this borrower,
3233     # and not yet returned.
3234
3235     # FIXME - I think this function could be redone to use only one SQL call.
3236     my $sth = $dbh->prepare(
3237         "select * from issues
3238                                 where (borrowernumber = ?)
3239                                 and (itemnumber = ?)"
3240     );
3241     $sth->execute( $bornum, $itemno );
3242     my $data = $sth->fetchrow_hashref;
3243     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3244     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3245     # $item and $borrower should be calculated
3246     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3247
3248     my $rules = Koha::CirculationRules->get_effective_rules(
3249         {
3250             categorycode => $patron->categorycode,
3251             itemtype     => $item->effective_itemtype,
3252             branchcode   => $branchcode,
3253             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3254         }
3255     );
3256     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3257     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3258         $rules->{unseen_renewals_allowed} :
3259         0;
3260     $renewsleft    = $renewsallowed - $renewcount;
3261     $unseenleft    = $unseenallowed - $unseencount;
3262     if($renewsleft < 0){ $renewsleft = 0; }
3263     if($unseenleft < 0){ $unseenleft = 0; }
3264     return (
3265         $renewcount,
3266         $renewsallowed,
3267         $renewsleft,
3268         $unseencount,
3269         $unseenallowed,
3270         $unseenleft
3271     );
3272 }
3273
3274 =head2 GetSoonestRenewDate
3275
3276   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3277
3278 Find out the soonest possible renew date of a borrowed item.
3279
3280 C<$borrowernumber> is the borrower number of the patron who currently
3281 has the item on loan.
3282
3283 C<$itemnumber> is the number of the item to renew.
3284
3285 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3286 renew date, based on the value "No renewal before" of the applicable
3287 issuing rule. Returns the current date if the item can already be
3288 renewed, and returns undefined if the borrower, loan, or item
3289 cannot be found.
3290
3291 =cut
3292
3293 sub GetSoonestRenewDate {
3294     my ( $borrowernumber, $itemnumber ) = @_;
3295
3296     my $dbh = C4::Context->dbh;
3297
3298     my $item      = Koha::Items->find($itemnumber)      or return;
3299     my $itemissue = $item->checkout or return;
3300
3301     $borrowernumber ||= $itemissue->borrowernumber;
3302     my $patron = Koha::Patrons->find( $borrowernumber )
3303       or return;
3304
3305     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3306     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3307         {   categorycode => $patron->categorycode,
3308             itemtype     => $item->effective_itemtype,
3309             branchcode   => $branchcode,
3310             rules => [
3311                 'norenewalbefore',
3312                 'lengthunit',
3313             ]
3314         }
3315     );
3316
3317     my $now = dt_from_string;
3318
3319     if ( defined $issuing_rule->{norenewalbefore}
3320         and $issuing_rule->{norenewalbefore} ne "" )
3321     {
3322         my $soonestrenewal =
3323           dt_from_string( $itemissue->date_due )->subtract(
3324             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3325
3326         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3327             and $issuing_rule->{lengthunit} eq 'days' )
3328         {
3329             $soonestrenewal->truncate( to => 'day' );
3330         }
3331         return $soonestrenewal if $now < $soonestrenewal;
3332     } elsif ( $itemissue->auto_renew && $patron->autorenew_checkouts ) {
3333         # Checkouts with auto-renewing fall back to due date
3334         my $soonestrenewal = dt_from_string( $itemissue->date_due );
3335         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3336             and $issuing_rule->{lengthunit} eq 'days' )
3337         {
3338             $soonestrenewal->truncate( to => 'day' );
3339         }
3340         return $soonestrenewal;
3341     }
3342     return $now;
3343 }
3344
3345 =head2 GetLatestAutoRenewDate
3346
3347   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3348
3349 Find out the latest possible auto renew date of a borrowed item.
3350
3351 C<$borrowernumber> is the borrower number of the patron who currently
3352 has the item on loan.
3353
3354 C<$itemnumber> is the number of the item to renew.
3355
3356 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3357 auto renew date, based on the value "No auto renewal after" and the "No auto
3358 renewal after (hard limit) of the applicable issuing rule.
3359 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3360 or item cannot be found.
3361
3362 =cut
3363
3364 sub GetLatestAutoRenewDate {
3365     my ( $borrowernumber, $itemnumber ) = @_;
3366
3367     my $dbh = C4::Context->dbh;
3368
3369     my $item      = Koha::Items->find($itemnumber)  or return;
3370     my $itemissue = $item->checkout                 or return;
3371
3372     $borrowernumber ||= $itemissue->borrowernumber;
3373     my $patron = Koha::Patrons->find( $borrowernumber )
3374       or return;
3375
3376     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3377     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3378         {
3379             categorycode => $patron->categorycode,
3380             itemtype     => $item->effective_itemtype,
3381             branchcode   => $branchcode,
3382             rules => [
3383                 'no_auto_renewal_after',
3384                 'no_auto_renewal_after_hard_limit',
3385                 'lengthunit',
3386             ]
3387         }
3388     );
3389
3390     return unless $circulation_rules;
3391     return
3392       if ( not $circulation_rules->{no_auto_renewal_after}
3393             or $circulation_rules->{no_auto_renewal_after} eq '' )
3394       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3395              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3396
3397     my $maximum_renewal_date;
3398     if ( $circulation_rules->{no_auto_renewal_after} ) {
3399         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3400         $maximum_renewal_date->add(
3401             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3402         );
3403     }
3404
3405     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3406         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3407         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3408     }
3409     return $maximum_renewal_date;
3410 }
3411
3412
3413 =head2 GetIssuingCharges
3414
3415   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3416
3417 Calculate how much it would cost for a given patron to borrow a given
3418 item, including any applicable discounts.
3419
3420 C<$itemnumber> is the item number of item the patron wishes to borrow.
3421
3422 C<$borrowernumber> is the patron's borrower number.
3423
3424 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3425 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3426 if it's a video).
3427
3428 =cut
3429
3430 sub GetIssuingCharges {
3431
3432     # calculate charges due
3433     my ( $itemnumber, $borrowernumber ) = @_;
3434     my $charge = 0;
3435     my $dbh    = C4::Context->dbh;
3436     my $item_type;
3437
3438     # Get the book's item type and rental charge (via its biblioitem).
3439     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3440         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3441     $charge_query .= (C4::Context->preference('item-level_itypes'))
3442         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3443         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3444
3445     $charge_query .= ' WHERE items.itemnumber =?';
3446
3447     my $sth = $dbh->prepare($charge_query);
3448     $sth->execute($itemnumber);
3449     if ( my $item_data = $sth->fetchrow_hashref ) {
3450         $item_type = $item_data->{itemtype};
3451         $charge    = $item_data->{rentalcharge};
3452         if ($charge) {
3453             # FIXME This should follow CircControl
3454             my $branch = C4::Context::mybranch();
3455             my $patron = Koha::Patrons->find( $borrowernumber );
3456             my $discount = Koha::CirculationRules->get_effective_rule({
3457                 categorycode => $patron->categorycode,
3458                 branchcode   => $branch,
3459                 itemtype     => $item_type,
3460                 rule_name    => 'rentaldiscount'
3461             });
3462             if ($discount) {
3463                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3464             }
3465             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3466         }
3467     }
3468
3469     return ( $charge, $item_type );
3470 }
3471
3472 =head2 AddIssuingCharge
3473
3474   &AddIssuingCharge( $checkout, $charge, $type )
3475
3476 =cut
3477
3478 sub AddIssuingCharge {
3479     my ( $checkout, $charge, $type ) = @_;
3480
3481     # FIXME What if checkout does not exist?
3482
3483     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3484     my $accountline = $account->add_debit(
3485         {
3486             amount      => $charge,
3487             note        => undef,
3488             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3489             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3490             interface   => C4::Context->interface,
3491             type        => $type,
3492             item_id     => $checkout->itemnumber,
3493             issue_id    => $checkout->issue_id,
3494         }
3495     );
3496 }
3497
3498 =head2 GetTransfers
3499
3500   GetTransfers($itemnumber);
3501
3502 =cut
3503
3504 sub GetTransfers {
3505     my ($itemnumber) = @_;
3506
3507     my $dbh = C4::Context->dbh;
3508
3509     my $query = '
3510         SELECT datesent,
3511                frombranch,
3512                tobranch,
3513                branchtransfer_id,
3514                daterequested,
3515                reason
3516         FROM branchtransfers
3517         WHERE itemnumber = ?
3518           AND datearrived IS NULL
3519           AND datecancelled IS NULL
3520         ';
3521     my $sth = $dbh->prepare($query);
3522     $sth->execute($itemnumber);
3523     my @row = $sth->fetchrow_array();
3524     return @row;
3525 }
3526
3527 =head2 GetTransfersFromTo
3528
3529   @results = GetTransfersFromTo($frombranch,$tobranch);
3530
3531 Returns the list of pending transfers between $from and $to branch
3532
3533 =cut
3534
3535 sub GetTransfersFromTo {
3536     my ( $frombranch, $tobranch ) = @_;
3537     return unless ( $frombranch && $tobranch );
3538     my $dbh   = C4::Context->dbh;
3539     my $query = "
3540         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3541         FROM   branchtransfers
3542         WHERE  frombranch=?
3543           AND  tobranch=?
3544           AND datecancelled IS NULL
3545           AND datesent IS NOT NULL
3546           AND datearrived IS NULL
3547     ";
3548     my $sth = $dbh->prepare($query);
3549     $sth->execute( $frombranch, $tobranch );
3550     my @gettransfers;
3551
3552     while ( my $data = $sth->fetchrow_hashref ) {
3553         push @gettransfers, $data;
3554     }
3555     return (@gettransfers);
3556 }
3557
3558 =head2 SendCirculationAlert
3559
3560 Send out a C<check-in> or C<checkout> alert using the messaging system.
3561
3562 B<Parameters>:
3563
3564 =over 4
3565
3566 =item type
3567
3568 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3569
3570 =item item
3571
3572 Hashref of information about the item being checked in or out.
3573
3574 =item borrower
3575
3576 Hashref of information about the borrower of the item.
3577
3578 =item branch
3579
3580 The branchcode from where the checkout or check-in took place.
3581
3582 =back
3583
3584 B<Example>:
3585
3586     SendCirculationAlert({
3587         type     => 'CHECKOUT',
3588         item     => $item,
3589         borrower => $borrower,
3590         branch   => $branch,
3591     });
3592
3593 =cut
3594
3595 sub SendCirculationAlert {
3596     my ($opts) = @_;
3597     my ($type, $item, $borrower, $branch, $issue) =
3598         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3599     my %message_name = (
3600         CHECKIN  => 'Item_Check_in',
3601         CHECKOUT => 'Item_Checkout',
3602         RENEWAL  => 'Item_Checkout',
3603     );
3604     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3605         borrowernumber => $borrower->{borrowernumber},
3606         message_name   => $message_name{$type},
3607     });
3608
3609
3610     my $tables = {
3611         items => $item->{itemnumber},
3612         biblio      => $item->{biblionumber},
3613         biblioitems => $item->{biblionumber},
3614         borrowers   => $borrower,
3615         branches    => $branch,
3616     };
3617
3618     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3619     # See C4::Letters:: _parseletter_sth
3620     if( $type eq 'CHECKIN' ){
3621         $tables->{old_issues} = $issue->issue_id;
3622     } else {
3623         $tables->{issues} = $item->{itemnumber};
3624     }
3625
3626     my $schema = Koha::Database->new->schema;
3627     my @transports = keys %{ $borrower_preferences->{transports} };
3628
3629     # From the MySQL doc:
3630     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3631     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3632     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3633     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3634
3635     for my $mtt (@transports) {
3636         my $letter =  C4::Letters::GetPreparedLetter (
3637             module => 'circulation',
3638             letter_code => $type,
3639             branchcode => $branch,
3640             message_transport_type => $mtt,
3641             lang => $borrower->{lang},
3642             tables => $tables,
3643         ) or next;
3644
3645         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3646         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3647         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3648         unless ( $message ) {
3649             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3650             C4::Message->enqueue($letter, $borrower, $mtt);
3651         } else {
3652             $message->append($letter);
3653             $message->update;
3654         }
3655         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3656     }
3657
3658     return;
3659 }
3660
3661 =head2 updateWrongTransfer
3662
3663   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3664
3665 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3666
3667 =cut
3668
3669 sub updateWrongTransfer {
3670         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3671
3672     # first step: cancel the original transfer
3673     my $item = Koha::Items->find($itemNumber);
3674     my $transfer = $item->get_transfer;
3675     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3676
3677     # second step: create a new transfer to the right location
3678     my $new_transfer = $item->request_transfer(
3679         {
3680             to            => $transfer->to_library,
3681             reason        => $transfer->reason,
3682             comment       => $transfer->comments,
3683             ignore_limits => 1,
3684             enqueue       => 1
3685         }
3686     );
3687
3688     return $new_transfer;
3689 }
3690
3691 =head2 CalcDateDue
3692
3693 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3694
3695 this function calculates the due date given the start date and configured circulation rules,
3696 checking against the holidays calendar as per the daysmode circulation rule.
3697 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3698 C<$itemtype>  = itemtype code of item in question
3699 C<$branch>  = location whose calendar to use
3700 C<$borrower> = Borrower object
3701 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3702
3703 =cut
3704
3705 sub CalcDateDue {
3706     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3707
3708     $isrenewal ||= 0;
3709
3710     # loanlength now a href
3711     my $loanlength =
3712             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3713
3714     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3715             ? qq{renewalperiod}
3716             : qq{issuelength};
3717
3718     my $datedue;
3719     if ( $startdate ) {
3720         if (ref $startdate ne 'DateTime' ) {
3721             $datedue = dt_from_string($datedue);
3722         } else {
3723             $datedue = $startdate->clone;
3724         }
3725     } else {
3726         $datedue = dt_from_string()->truncate( to => 'minute' );
3727     }
3728
3729
3730     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3731         {
3732             categorycode => $borrower->{categorycode},
3733             itemtype     => $itemtype,
3734             branchcode   => $branch,
3735         }
3736     );
3737
3738     # calculate the datedue as normal
3739     if ( $daysmode eq 'Days' )
3740     {    # ignoring calendar
3741         if ( $loanlength->{lengthunit} eq 'hours' ) {
3742             $datedue->add( hours => $loanlength->{$length_key} );
3743         } else {    # days
3744             $datedue->add( days => $loanlength->{$length_key} );
3745             $datedue->set_hour(23);
3746             $datedue->set_minute(59);
3747         }
3748     } else {
3749         my $dur;
3750         if ($loanlength->{lengthunit} eq 'hours') {
3751             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3752         }
3753         else { # days
3754             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3755         }
3756         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3757         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3758         if ($loanlength->{lengthunit} eq 'days') {
3759             $datedue->set_hour(23);
3760             $datedue->set_minute(59);
3761         }
3762     }
3763
3764     # if Hard Due Dates are used, retrieve them and apply as necessary
3765     my ( $hardduedate, $hardduedatecompare ) =
3766       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3767     if ($hardduedate) {    # hardduedates are currently dates
3768         $hardduedate->truncate( to => 'minute' );
3769         $hardduedate->set_hour(23);
3770         $hardduedate->set_minute(59);
3771         my $cmp = DateTime->compare( $hardduedate, $datedue );
3772
3773 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3774 # if the calculated date is before the 'after' Hard Due Date (floor), override
3775 # if the hard due date is set to 'exactly', overrride
3776         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3777             $datedue = $hardduedate->clone;
3778         }
3779
3780         # in all other cases, keep the date due as it is
3781
3782     }
3783
3784     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3785     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3786         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3787         if( $expiry_dt ) { #skip empty expiry date..
3788             $expiry_dt->set( hour => 23, minute => 59);
3789             my $d1= $datedue->clone->set_time_zone('floating');
3790             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3791                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3792             }
3793         }
3794         if ( $daysmode ne 'Days' ) {
3795           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3796           if ( $calendar->is_holiday($datedue) ) {
3797               # Don't return on a closed day
3798               $datedue = $calendar->prev_open_days( $datedue, 1 );
3799           }
3800         }
3801     }
3802
3803     return $datedue;
3804 }
3805
3806
3807 sub CheckValidBarcode{
3808 my ($barcode) = @_;
3809 my $dbh = C4::Context->dbh;
3810 my $query=qq|SELECT count(*)
3811              FROM items
3812              WHERE barcode=?
3813             |;
3814 my $sth = $dbh->prepare($query);
3815 $sth->execute($barcode);
3816 my $exist=$sth->fetchrow ;
3817 return $exist;
3818 }
3819
3820 =head2 IsBranchTransferAllowed
3821
3822   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3823
3824 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3825
3826 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3827 Koha::Item->can_be_transferred.
3828
3829 =cut
3830
3831 sub IsBranchTransferAllowed {
3832         my ( $toBranch, $fromBranch, $code ) = @_;
3833
3834         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3835
3836         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3837         my $dbh = C4::Context->dbh;
3838
3839         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3840         $sth->execute( $toBranch, $fromBranch, $code );
3841         my $limit = $sth->fetchrow_hashref();
3842
3843         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3844         if ( $limit->{'limitId'} ) {
3845                 return 0;
3846         } else {
3847                 return 1;
3848         }
3849 }
3850
3851 =head2 CreateBranchTransferLimit
3852
3853   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3854
3855 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3856
3857 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3858
3859 =cut
3860
3861 sub CreateBranchTransferLimit {
3862    my ( $toBranch, $fromBranch, $code ) = @_;
3863    return unless defined($toBranch) && defined($fromBranch);
3864    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3865
3866    my $dbh = C4::Context->dbh;
3867
3868    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3869    return $sth->execute( $code, $toBranch, $fromBranch );
3870 }
3871
3872 =head2 DeleteBranchTransferLimits
3873
3874     my $result = DeleteBranchTransferLimits($frombranch);
3875
3876 Deletes all the library transfer limits for one library.  Returns the
3877 number of limits deleted, 0e0 if no limits were deleted, or undef if
3878 no arguments are supplied.
3879
3880 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3881     fromBranch => $fromBranch
3882     })->delete.
3883
3884 =cut
3885
3886 sub DeleteBranchTransferLimits {
3887     my $branch = shift;
3888     return unless defined $branch;
3889     my $dbh    = C4::Context->dbh;
3890     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3891     return $sth->execute($branch);
3892 }
3893
3894 sub ReturnLostItem{
3895     my ( $borrowernumber, $itemnum ) = @_;
3896     MarkIssueReturned( $borrowernumber, $itemnum );
3897 }
3898
3899 =head2 LostItem
3900
3901   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3902
3903 The final optional parameter, C<$params>, expected to contain
3904 'skip_record_index' key, which relayed down to Koha::Item/store,
3905 there it prevents calling of ModZebra index_records,
3906 which takes most of the time in batch adds/deletes: index_records better
3907 to be called later in C<additem.pl> after the whole loop.
3908
3909 $params:
3910     skip_record_index => 1|0
3911
3912 =cut
3913
3914 sub LostItem{
3915     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3916
3917     unless ( $mark_lost_from ) {
3918         # Temporary check to avoid regressions
3919         die q|LostItem called without $mark_lost_from, check the API.|;
3920     }
3921
3922     my $mark_returned;
3923     if ( $force_mark_returned ) {
3924         $mark_returned = 1;
3925     } else {
3926         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3927         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3928     }
3929
3930     my $dbh = C4::Context->dbh();
3931     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3932                            FROM issues
3933                            JOIN items USING (itemnumber)
3934                            JOIN biblio USING (biblionumber)
3935                            WHERE issues.itemnumber=?");
3936     $sth->execute($itemnumber);
3937     my $issues=$sth->fetchrow_hashref();
3938
3939     # If a borrower lost the item, add a replacement cost to the their record
3940     if ( my $borrowernumber = $issues->{borrowernumber} ){
3941         my $patron = Koha::Patrons->find( $borrowernumber );
3942
3943         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3944         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3945
3946         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3947             C4::Accounts::chargelostitem(
3948                 $borrowernumber,
3949                 $itemnumber,
3950                 $issues->{'replacementprice'},
3951                 sprintf( "%s %s %s",
3952                     $issues->{'title'}          || q{},
3953                     $issues->{'barcode'}        || q{},
3954                     $issues->{'itemcallnumber'} || q{},
3955                 ),
3956             );
3957             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3958             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3959         }
3960
3961         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
3962     }
3963
3964     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
3965     my $item = Koha::Items->find($itemnumber);
3966     my $transfers = $item->get_transfers;
3967     while (my $transfer = $transfers->next) {
3968         $transfer->cancel({ reason => 'ItemLost', force => 1 });
3969     }
3970 }
3971
3972 sub GetOfflineOperations {
3973     my $dbh = C4::Context->dbh;
3974     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3975     $sth->execute(C4::Context->userenv->{'branch'});
3976     my $results = $sth->fetchall_arrayref({});
3977     return $results;
3978 }
3979
3980 sub GetOfflineOperation {
3981     my $operationid = shift;
3982     return unless $operationid;
3983     my $dbh = C4::Context->dbh;
3984     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3985     $sth->execute( $operationid );
3986     return $sth->fetchrow_hashref;
3987 }
3988
3989 sub AddOfflineOperation {
3990     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3991     my $dbh = C4::Context->dbh;
3992     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3993     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3994     return "Added.";
3995 }
3996
3997 sub DeleteOfflineOperation {
3998     my $dbh = C4::Context->dbh;
3999     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4000     $sth->execute( shift );
4001     return "Deleted.";
4002 }
4003
4004 sub ProcessOfflineOperation {
4005     my $operation = shift;
4006
4007     my $report;
4008     if ( $operation->{action} eq 'return' ) {
4009         $report = ProcessOfflineReturn( $operation );
4010     } elsif ( $operation->{action} eq 'issue' ) {
4011         $report = ProcessOfflineIssue( $operation );
4012     } elsif ( $operation->{action} eq 'payment' ) {
4013         $report = ProcessOfflinePayment( $operation );
4014     }
4015
4016     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4017
4018     return $report;
4019 }
4020
4021 sub ProcessOfflineReturn {
4022     my $operation = shift;
4023
4024     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4025
4026     if ( $item ) {
4027         my $itemnumber = $item->itemnumber;
4028         my $issue = GetOpenIssue( $itemnumber );
4029         if ( $issue ) {
4030             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4031             ModDateLastSeen( $itemnumber, $leave_item_lost );
4032             MarkIssueReturned(
4033                 $issue->{borrowernumber},
4034                 $itemnumber,
4035                 $operation->{timestamp},
4036             );
4037             $item->renewals(0);
4038             $item->onloan(undef);
4039             $item->store({ log_action => 0 });
4040             return "Success.";
4041         } else {
4042             return "Item not issued.";
4043         }
4044     } else {
4045         return "Item not found.";
4046     }
4047 }
4048
4049 sub ProcessOfflineIssue {
4050     my $operation = shift;
4051
4052     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4053
4054     if ( $patron ) {
4055         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4056         unless ($item) {
4057             return "Barcode not found.";
4058         }
4059         my $itemnumber = $item->itemnumber;
4060         my $issue = GetOpenIssue( $itemnumber );
4061
4062         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4063             MarkIssueReturned(
4064                 $issue->{borrowernumber},
4065                 $itemnumber,
4066                 $operation->{timestamp},
4067             );
4068         }
4069         AddIssue(
4070             $patron->unblessed,
4071             $operation->{'barcode'},
4072             undef,
4073             undef,
4074             $operation->{timestamp},
4075             undef,
4076         );
4077         return "Success.";
4078     } else {
4079         return "Borrower not found.";
4080     }
4081 }
4082
4083 sub ProcessOfflinePayment {
4084     my $operation = shift;
4085
4086     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4087
4088     $patron->account->pay(
4089         {
4090             amount     => $operation->{amount},
4091             library_id => $operation->{branchcode},
4092             interface  => 'koc'
4093         }
4094     );
4095
4096     return "Success.";
4097 }
4098
4099 =head2 TransferSlip
4100
4101   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4102
4103   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4104
4105 =cut
4106
4107 sub TransferSlip {
4108     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4109
4110     my $item =
4111       $itemnumber
4112       ? Koha::Items->find($itemnumber)
4113       : Koha::Items->find( { barcode => $barcode } );
4114
4115     $item or return;
4116
4117     return C4::Letters::GetPreparedLetter (
4118         module => 'circulation',
4119         letter_code => 'TRANSFERSLIP',
4120         branchcode => $branch,
4121         tables => {
4122             'branches'    => $to_branch,
4123             'biblio'      => $item->biblionumber,
4124             'items'       => $item->unblessed,
4125         },
4126     );
4127 }
4128
4129 =head2 CheckIfIssuedToPatron
4130
4131   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4132
4133   Return 1 if any record item is issued to patron, otherwise return 0
4134
4135 =cut
4136
4137 sub CheckIfIssuedToPatron {
4138     my ($borrowernumber, $biblionumber) = @_;
4139
4140     my $dbh = C4::Context->dbh;
4141     my $query = q|
4142         SELECT COUNT(*) FROM issues
4143         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4144         WHERE items.biblionumber = ?
4145         AND issues.borrowernumber = ?
4146     |;
4147     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4148     return 1 if $is_issued;
4149     return;
4150 }
4151
4152 =head2 IsItemIssued
4153
4154   IsItemIssued( $itemnumber )
4155
4156   Return 1 if the item is on loan, otherwise return 0
4157
4158 =cut
4159
4160 sub IsItemIssued {
4161     my $itemnumber = shift;
4162     my $dbh = C4::Context->dbh;
4163     my $sth = $dbh->prepare(q{
4164         SELECT COUNT(*)
4165         FROM issues
4166         WHERE itemnumber = ?
4167     });
4168     $sth->execute($itemnumber);
4169     return $sth->fetchrow;
4170 }
4171
4172 =head2 GetAgeRestriction
4173
4174   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4175   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4176
4177   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4178   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4179
4180 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4181 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4182 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4183          Negative days mean the borrower has gone past the age restriction age.
4184
4185 =cut
4186
4187 sub GetAgeRestriction {
4188     my ($record_restrictions, $borrower) = @_;
4189     my $markers = C4::Context->preference('AgeRestrictionMarker');
4190
4191     return unless $record_restrictions;
4192     # Split $record_restrictions to something like FSK 16 or PEGI 6
4193     my @values = split ' ', uc($record_restrictions);
4194     return unless @values;
4195
4196     # Search first occurrence of one of the markers
4197     my @markers = split /\|/, uc($markers);
4198     return unless @markers;
4199
4200     my $index            = 0;
4201     my $restriction_year = 0;
4202     for my $value (@values) {
4203         $index++;
4204         for my $marker (@markers) {
4205             $marker =~ s/^\s+//;    #remove leading spaces
4206             $marker =~ s/\s+$//;    #remove trailing spaces
4207             if ( $marker eq $value ) {
4208                 if ( $index <= $#values ) {
4209                     $restriction_year += $values[$index];
4210                 }
4211                 last;
4212             }
4213             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4214
4215                 # Perhaps it is something like "K16" (as in Finland)
4216                 $restriction_year += $1;
4217                 last;
4218             }
4219         }
4220         last if ( $restriction_year > 0 );
4221     }
4222
4223     #Check if the borrower is age restricted for this material and for how long.
4224     if ($restriction_year && $borrower) {
4225         if ( $borrower->{'dateofbirth'} ) {
4226             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4227             $alloweddate[0] += $restriction_year;
4228
4229             #Prevent runime eror on leap year (invalid date)
4230             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4231                 $alloweddate[2] = 28;
4232             }
4233
4234             #Get how many days the borrower has to reach the age restriction
4235             my @Today = split /-/, dt_from_string()->ymd();
4236             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4237             #Negative days means the borrower went past the age restriction age
4238             return ($restriction_year, $daysToAgeRestriction);
4239         }
4240     }
4241
4242     return ($restriction_year);
4243 }
4244
4245
4246 =head2 GetPendingOnSiteCheckouts
4247
4248 =cut
4249
4250 sub GetPendingOnSiteCheckouts {
4251     my $dbh = C4::Context->dbh;
4252     return $dbh->selectall_arrayref(q|
4253         SELECT
4254           items.barcode,
4255           items.biblionumber,
4256           items.itemnumber,
4257           items.itemnotes,
4258           items.itemcallnumber,
4259           items.location,
4260           issues.date_due,
4261           issues.branchcode,
4262           issues.date_due < NOW() AS is_overdue,
4263           biblio.author,
4264           biblio.title,
4265           borrowers.firstname,
4266           borrowers.surname,
4267           borrowers.cardnumber,
4268           borrowers.borrowernumber
4269         FROM items
4270         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4271         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4272         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4273         WHERE issues.onsite_checkout = 1
4274     |, { Slice => {} } );
4275 }
4276
4277 sub GetTopIssues {
4278     my ($params) = @_;
4279
4280     my ($count, $branch, $itemtype, $ccode, $newness)
4281         = @$params{qw(count branch itemtype ccode newness)};
4282
4283     my $dbh = C4::Context->dbh;
4284     my $query = q{
4285         SELECT * FROM (
4286         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4287           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4288           i.ccode, SUM(i.issues) AS count
4289         FROM biblio b
4290         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4291         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4292     };
4293
4294     my (@where_strs, @where_args);
4295
4296     if ($branch) {
4297         push @where_strs, 'i.homebranch = ?';
4298         push @where_args, $branch;
4299     }
4300     if ($itemtype) {
4301         if (C4::Context->preference('item-level_itypes')){
4302             push @where_strs, 'i.itype = ?';
4303             push @where_args, $itemtype;
4304         } else {
4305             push @where_strs, 'bi.itemtype = ?';
4306             push @where_args, $itemtype;
4307         }
4308     }
4309     if ($ccode) {
4310         push @where_strs, 'i.ccode = ?';
4311         push @where_args, $ccode;
4312     }
4313     if ($newness) {
4314         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4315         push @where_args, $newness;
4316     }
4317
4318     if (@where_strs) {
4319         $query .= 'WHERE ' . join(' AND ', @where_strs);
4320     }
4321
4322     $query .= q{
4323         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4324           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4325           i.ccode
4326         ORDER BY count DESC
4327     };
4328
4329     $query .= q{ ) xxx WHERE count > 0 };
4330     $count = int($count);
4331     if ($count > 0) {
4332         $query .= "LIMIT $count";
4333     }
4334
4335     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4336
4337     return @$rows;
4338 }
4339
4340 =head2 Internal methods
4341
4342 =cut
4343
4344 sub _CalculateAndUpdateFine {
4345     my ($params) = @_;
4346
4347     my $borrower    = $params->{borrower};
4348     my $item        = $params->{item};
4349     my $issue       = $params->{issue};
4350     my $return_date = $params->{return_date};
4351
4352     unless ($borrower) { carp "No borrower passed in!" && return; }
4353     unless ($item)     { carp "No item passed in!"     && return; }
4354     unless ($issue)    { carp "No issue passed in!"    && return; }
4355
4356     my $datedue = dt_from_string( $issue->date_due );
4357
4358     # we only need to calculate and change the fines if we want to do that on return
4359     # Should be on for hourly loans
4360     my $control = C4::Context->preference('CircControl');
4361     my $control_branchcode =
4362         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4363       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4364       :                                     $issue->branchcode;
4365
4366     my $date_returned = $return_date ? $return_date : dt_from_string();
4367
4368     my ( $amount, $unitcounttotal, $unitcount  ) =
4369       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4370
4371     if ( C4::Context->preference('finesMode') eq 'production' ) {
4372         if ( $amount > 0 ) {
4373             C4::Overdues::UpdateFine({
4374                 issue_id       => $issue->issue_id,
4375                 itemnumber     => $issue->itemnumber,
4376                 borrowernumber => $issue->borrowernumber,
4377                 amount         => $amount,
4378                 due            => output_pref($datedue),
4379             });
4380         }
4381         elsif ($return_date) {
4382
4383             # Backdated returns may have fines that shouldn't exist,
4384             # so in this case, we need to drop those fines to 0
4385
4386             C4::Overdues::UpdateFine({
4387                 issue_id       => $issue->issue_id,
4388                 itemnumber     => $issue->itemnumber,
4389                 borrowernumber => $issue->borrowernumber,
4390                 amount         => 0,
4391                 due            => output_pref($datedue),
4392             });
4393         }
4394     }
4395 }
4396
4397 sub _CanBookBeAutoRenewed {
4398     my ( $params ) = @_;
4399     my $patron = $params->{patron};
4400     my $item = $params->{item};
4401     my $branchcode = $params->{branchcode};
4402     my $issue = $params->{issue};
4403
4404     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4405
4406     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4407         {
4408             categorycode => $patron->categorycode,
4409             itemtype     => $item->effective_itemtype,
4410             branchcode   => $branchcode,
4411             rules => [
4412                 'no_auto_renewal_after',
4413                 'no_auto_renewal_after_hard_limit',
4414                 'lengthunit',
4415                 'norenewalbefore',
4416             ]
4417         }
4418     );
4419
4420     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4421         return 'auto_account_expired';
4422     }
4423
4424     if ( defined $issuing_rule->{no_auto_renewal_after}
4425             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4426         # Get issue_date and add no_auto_renewal_after
4427         # If this is greater than today, it's too late for renewal.
4428         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4429         $maximum_renewal_date->add(
4430             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4431         );
4432         my $now = dt_from_string;
4433         if ( $now >= $maximum_renewal_date ) {
4434             return "auto_too_late";
4435         }
4436     }
4437     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4438                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4439         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4440         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4441             return "auto_too_late";
4442         }
4443     }
4444
4445     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4446         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4447         my $amountoutstanding =
4448           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4449           ? $patron->account->balance
4450           : $patron->account->outstanding_debits->total_outstanding;
4451         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4452             return "auto_too_much_oweing";
4453         }
4454     }
4455
4456     my $soonest = GetSoonestRenewDate($patron->id, $item->id);
4457     if ( $soonest > dt_from_string() )
4458     {
4459         return ( "auto_too_soon", $soonest );
4460     }
4461
4462     return "ok";
4463 }
4464
4465 sub _item_denied_renewal {
4466     my ($params) = @_;
4467
4468     my $item = $params->{item};
4469     return unless $item;
4470
4471     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4472     return unless $denyingrules;
4473     foreach my $field (keys %$denyingrules) {
4474         my $val = $item->$field;
4475         if( !defined $val) {
4476             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4477                 return 1;
4478             }
4479         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4480            # If the results matches the values in the syspref
4481            # We return true if match found
4482             return 1;
4483         }
4484     }
4485     return 0;
4486 }
4487
4488 1;
4489
4490 __END__
4491
4492 =head1 AUTHOR
4493
4494 Koha Development Team <http://koha-community.org/>
4495
4496 =cut