C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use DateTime;
  25 use POSIX qw( floor );
  26 use Koha::DateUtils;
  27 use C4::Context;
  28 use C4::Stats;
  29 use C4::Reserves;
  30 use C4::Biblio;
  31 use C4::Items;
  32 use C4::Members;
  33 use C4::Accounts;
  34 use C4::ItemCirculationAlertPreference;
  35 use C4::Message;
  36 use C4::Debug;
  37 use C4::Log; # logaction
  38 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  39 use C4::RotatingCollections qw(GetCollectionItemBranches);
  40 use Algorithm::CheckDigits;
  41
  42 use Data::Dumper;
  43 use Koha::Account;
  44 use Koha::AuthorisedValues;
  45 use Koha::Biblioitems;
  46 use Koha::DateUtils;
  47 use Koha::Calendar;
  48 use Koha::Checkouts;
  49 use Koha::IssuingRules;
  50 use Koha::Items;
  51 use Koha::Patrons;
  52 use Koha::Patron::Debarments;
  53 use Koha::Database;
  54 use Koha::Libraries;
  55 use Koha::Account::Lines;
  56 use Koha::Holds;
  57 use Koha::RefundLostItemFeeRules;
  58 use Koha::Account::Lines;
  59 use Koha::Account::Offsets;
  60 use Koha::Config::SysPrefs;
  61 use Koha::Charges::Fees;
  62 use Koha::Util::SystemPreferences;
  63 use Koha::Checkouts::ReturnClaims;
  64 use Carp;
  65 use List::MoreUtils qw( uniq any );
  66 use Scalar::Util qw( looks_like_number );
  67 use Date::Calc qw(
  68   Today
  69   Today_and_Now
  70   Add_Delta_YM
  71   Add_Delta_DHMS
  72   Date_to_Days
  73   Day_of_Week
  74   Add_Delta_Days
  75 );
  76 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  77
  78 BEGIN {
  79         require Exporter;
  80         @ISA    = qw(Exporter);
  81
  82         # FIXME subs that should probably be elsewhere
  83         push @EXPORT, qw(
  84                 &barcodedecode
  85         &LostItem
  86         &ReturnLostItem
  87         &GetPendingOnSiteCheckouts
  88         );
  89
  90         # subs to deal with issuing a book
  91         push @EXPORT, qw(
  92                 &CanBookBeIssued
  93                 &CanBookBeRenewed
  94                 &AddIssue
  95                 &AddRenewal
  96                 &GetRenewCount
  97         &GetSoonestRenewDate
  98         &GetLatestAutoRenewDate
  99                 &GetIssuingCharges
 100         &GetBranchBorrowerCircRule
 101         &GetBranchItemRule
 102                 &GetBiblioIssues
 103                 &GetOpenIssue
 104         &CheckIfIssuedToPatron
 105         &IsItemIssued
 106         GetTopIssues
 107         );
 108
 109         # subs to deal with returns
 110         push @EXPORT, qw(
 111                 &AddReturn
 112         &MarkIssueReturned
 113         );
 114
 115         # subs to deal with transfers
 116         push @EXPORT, qw(
 117                 &transferbook
 118                 &GetTransfers
 119                 &GetTransfersFromTo
 120                 &updateWrongTransfer
 121                 &DeleteTransfer
 122                 &IsBranchTransferAllowed
 123                 &CreateBranchTransferLimit
 124                 &DeleteBranchTransferLimits
 125         &TransferSlip
 126         );
 127
 128     # subs to deal with offline circulation
 129     push @EXPORT, qw(
 130       &GetOfflineOperations
 131       &GetOfflineOperation
 132       &AddOfflineOperation
 133       &DeleteOfflineOperation
 134       &ProcessOfflineOperation
 135     );
 136 }
 137
 138 =head1 NAME
 139
 140 C4::Circulation - Koha circulation module
 141
 142 =head1 SYNOPSIS
 143
 144 use C4::Circulation;
 145
 146 =head1 DESCRIPTION
 147
 148 The functions in this module deal with circulation, issues, and
 149 returns, as well as general information about the library.
 150 Also deals with inventory.
 151
 152 =head1 FUNCTIONS
 153
 154 =head2 barcodedecode
 155
 156   $str = &barcodedecode($barcode, [$filter]);
 157
 158 Generic filter function for barcode string.
 159 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 160 Will do some manipulation of the barcode for systems that deliver a barcode
 161 to circulation.pl that differs from the barcode stored for the item.
 162 For proper functioning of this filter, calling the function on the
 163 correct barcode string (items.barcode) should return an unaltered barcode.
 164
 165 The optional $filter argument is to allow for testing or explicit
 166 behavior that ignores the System Pref.  Valid values are the same as the
 167 System Pref options.
 168
 169 =cut
 170
 171 # FIXME -- the &decode fcn below should be wrapped into this one.
 172 # FIXME -- these plugins should be moved out of Circulation.pm
 173 #
 174 sub barcodedecode {
 175     my ($barcode, $filter) = @_;
 176     my $branch = C4::Context::mybranch();
 177     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 178     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 179         if ($filter eq 'whitespace') {
 180                 $barcode =~ s/\s//g;
 181         } elsif ($filter eq 'cuecat') {
 182                 chomp($barcode);
 183             my @fields = split( /\./, $barcode );
 184             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 185             ($#results == 2) and return $results[2];
 186         } elsif ($filter eq 'T-prefix') {
 187                 if ($barcode =~ /^[Tt](\d)/) {
 188                         (defined($1) and $1 eq '0') and return $barcode;
 189             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 190                 }
 191         return sprintf("T%07d", $barcode);
 192         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 193         # Why drop the nonzero digit after the T?
 194         # Why pass non-digits (or empty string) to "T%07d"?
 195         } elsif ($filter eq 'libsuite8') {
 196                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 197                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 198                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 199                         }else{
 200                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 201                         }
 202                 }
 203     } elsif ($filter eq 'EAN13') {
 204         my $ean = CheckDigits('ean');
 205         if ( $ean->is_valid($barcode) ) {
 206             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 207             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 208         } else {
 209             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 210         }
 211         }
 212     return $barcode;    # return barcode, modified or not
 213 }
 214
 215 =head2 decode
 216
 217   $str = &decode($chunk);
 218
 219 Decodes a segment of a string emitted by a CueCat barcode scanner and
 220 returns it.
 221
 222 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 223 or Javascript based decoding on the client side.
 224
 225 =cut
 226
 227 sub decode {
 228     my ($encoded) = @_;
 229     my $seq =
 230       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 231     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 232     my $l = ( $#s + 1 ) % 4;
 233     if ($l) {
 234         if ( $l == 1 ) {
 235             # warn "Error: Cuecat decode parsing failed!";
 236             return;
 237         }
 238         $l = 4 - $l;
 239         $#s += $l;
 240     }
 241     my $r = '';
 242     while ( $#s >= 0 ) {
 243         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 244         $r .=
 245             chr( ( $n >> 16 ) ^ 67 )
 246          .chr( ( $n >> 8 & 255 ) ^ 67 )
 247          .chr( ( $n & 255 ) ^ 67 );
 248         @s = @s[ 4 .. $#s ];
 249     }
 250     $r = substr( $r, 0, length($r) - $l );
 251     return $r;
 252 }
 253
 254 =head2 transferbook
 255
 256   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 257                                             $barcode, $ignore_reserves);
 258
 259 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 260
 261 C<$newbranch> is the code for the branch to which the item should be transferred.
 262
 263 C<$barcode> is the barcode of the item to be transferred.
 264
 265 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 266 Otherwise, if an item is reserved, the transfer fails.
 267
 268 Returns three values:
 269
 270 =over
 271
 272 =item $dotransfer
 273
 274 is true if the transfer was successful.
 275
 276 =item $messages
 277
 278 is a reference-to-hash which may have any of the following keys:
 279
 280 =over
 281
 282 =item C<BadBarcode>
 283
 284 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 285
 286 =item C<DestinationEqualsHolding>
 287
 288 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 289
 290 =item C<WasReturned>
 291
 292 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 293
 294 =item C<ResFound>
 295
 296 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 297
 298 =item C<WasTransferred>
 299
 300 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 301
 302 =back
 303
 304 =back
 305
 306 =cut
 307
 308 sub transferbook {
 309     my ( $tbr, $barcode, $ignoreRs ) = @_;
 310     my $messages;
 311     my $dotransfer      = 1;
 312     my $item = Koha::Items->find( { barcode => $barcode } );
 313
 314     # bad barcode..
 315     unless ( $item ) {
 316         $messages->{'BadBarcode'} = $barcode;
 317         $dotransfer = 0;
 318         return ( $dotransfer, $messages );
 319     }
 320
 321     my $itemnumber = $item->itemnumber;
 322     # get branches of book...
 323     my $hbr = $item->homebranch;
 324     my $fbr = $item->holdingbranch;
 325
 326     # if using Branch Transfer Limits
 327     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 328         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 329         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 330             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 331                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 332                 $dotransfer = 0;
 333             }
 334         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 335             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 336             $dotransfer = 0;
 337         }
 338     }
 339
 340     # can't transfer book if is already there....
 341     if ( $fbr eq $tbr ) {
 342         $messages->{'DestinationEqualsHolding'} = 1;
 343         $dotransfer = 0;
 344     }
 345
 346     # check if it is still issued to someone, return it...
 347     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 348     if ( $issue ) {
 349         AddReturn( $barcode, $fbr );
 350         $messages->{'WasReturned'} = $issue->borrowernumber;
 351     }
 352
 353     # find reserves.....
 354     # That'll save a database query.
 355     my ( $resfound, $resrec, undef ) =
 356       CheckReserves( $itemnumber );
 357     if ( $resfound and not $ignoreRs ) {
 358         $resrec->{'ResFound'} = $resfound;
 359
 360         #         $messages->{'ResFound'} = $resrec;
 361         $dotransfer = 1;
 362     }
 363
 364     #actually do the transfer....
 365     if ($dotransfer) {
 366         ModItemTransfer( $itemnumber, $fbr, $tbr );
 367
 368         # don't need to update MARC anymore, we do it in batch now
 369         $messages->{'WasTransfered'} = 1;
 370
 371     }
 372     ModDateLastSeen( $itemnumber );
 373     return ( $dotransfer, $messages );
 374 }
 375
 376
 377 sub TooMany {
 378     my $borrower        = shift;
 379     my $item_object = shift;
 380     my $params = shift;
 381     my $onsite_checkout = $params->{onsite_checkout} || 0;
 382     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 383     my $cat_borrower    = $borrower->{'categorycode'};
 384     my $dbh             = C4::Context->dbh;
 385         my $branch;
 386         # Get which branchcode we need
 387     $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 388     my $type = $item_object->effective_itemtype;
 389
 390     # given branch, patron category, and item type, determine
 391     # applicable issuing rule
 392     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 393         {
 394             categorycode => $cat_borrower,
 395             itemtype     => $type,
 396             branchcode   => $branch,
 397             rule_name    => 'maxissueqty',
 398         }
 399     );
 400     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 401         {
 402             categorycode => $cat_borrower,
 403             itemtype     => $type,
 404             branchcode   => $branch,
 405             rule_name    => 'maxonsiteissueqty',
 406         }
 407     );
 408
 409
 410     # if a rule is found and has a loan limit set, count
 411     # how many loans the patron already has that meet that
 412     # rule
 413     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne '') {
 414         my @bind_params;
 415         my $count_query = q|
 416             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 417             FROM issues
 418             JOIN items USING (itemnumber)
 419         |;
 420
 421         my $rule_itemtype = $maxissueqty_rule->itemtype;
 422         unless ($rule_itemtype) {
 423             # matching rule has the default item type, so count only
 424             # those existing loans that don't fall under a more
 425             # specific rule
 426             if (C4::Context->preference('item-level_itypes')) {
 427                 $count_query .= " WHERE items.itype NOT IN (
 428                                     SELECT itemtype FROM issuingrules
 429                                     WHERE branchcode = ?
 430                                     AND   (categorycode = ? OR categorycode = ?)
 431                                     AND   itemtype <> '*'
 432                                   ) ";
 433             } else {
 434                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 435                                   WHERE biblioitems.itemtype NOT IN (
 436                                     SELECT itemtype FROM issuingrules
 437                                     WHERE branchcode = ?
 438                                     AND   (categorycode = ? OR categorycode = ?)
 439                                     AND   itemtype <> '*'
 440                                   ) ";
 441             }
 442             push @bind_params, $maxissueqty_rule->branchcode;
 443             push @bind_params, $maxissueqty_rule->categorycode;
 444             push @bind_params, $cat_borrower;
 445         } else {
 446             # rule has specific item type, so count loans of that
 447             # specific item type
 448             if (C4::Context->preference('item-level_itypes')) {
 449                 $count_query .= " WHERE items.itype = ? ";
 450             } else {
 451                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 452                                   WHERE biblioitems.itemtype= ? ";
 453             }
 454             push @bind_params, $type;
 455         }
 456
 457         $count_query .= " AND borrowernumber = ? ";
 458         push @bind_params, $borrower->{'borrowernumber'};
 459         my $rule_branch = $maxissueqty_rule->branchcode;
 460         if ($rule_branch) {
 461             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 462                 $count_query .= " AND issues.branchcode = ? ";
 463                 push @bind_params, $rule_branch;
 464             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 465                 ; # if branch is the patron's home branch, then count all loans by patron
 466             } else {
 467                 $count_query .= " AND items.homebranch = ? ";
 468                 push @bind_params, $rule_branch;
 469             }
 470         }
 471
 472         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 473
 474         my $max_checkouts_allowed = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 475         my $max_onsite_checkouts_allowed = $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef;
 476
 477         if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 478             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 479                 return {
 480                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 481                     count => $onsite_checkout_count,
 482                     max_allowed => $max_onsite_checkouts_allowed,
 483                 }
 484             }
 485         }
 486         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 487             my $delta = $switch_onsite_checkout ? 1 : 0;
 488             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 489                 return {
 490                     reason => 'TOO_MANY_CHECKOUTS',
 491                     count => $checkout_count,
 492                     max_allowed => $max_checkouts_allowed,
 493                 };
 494             }
 495         } elsif ( not $onsite_checkout ) {
 496             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 497                 return {
 498                     reason => 'TOO_MANY_CHECKOUTS',
 499                     count => $checkout_count - $onsite_checkout_count,
 500                     max_allowed => $max_checkouts_allowed,
 501                 };
 502             }
 503         }
 504     }
 505
 506     # Now count total loans against the limit for the branch
 507     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 508     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 509         my @bind_params = ();
 510         my $branch_count_query = q|
 511             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 512             FROM issues
 513             JOIN items USING (itemnumber)
 514             WHERE borrowernumber = ?
 515         |;
 516         push @bind_params, $borrower->{borrowernumber};
 517
 518         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 519             $branch_count_query .= " AND issues.branchcode = ? ";
 520             push @bind_params, $branch;
 521         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 522             ; # if branch is the patron's home branch, then count all loans by patron
 523         } else {
 524             $branch_count_query .= " AND items.homebranch = ? ";
 525             push @bind_params, $branch;
 526         }
 527         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 528         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 529         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty};
 530
 531         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 532             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 533                 return {
 534                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 535                     count => $onsite_checkout_count,
 536                     max_allowed => $max_onsite_checkouts_allowed,
 537                 }
 538             }
 539         }
 540         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 541             my $delta = $switch_onsite_checkout ? 1 : 0;
 542             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 543                 return {
 544                     reason => 'TOO_MANY_CHECKOUTS',
 545                     count => $checkout_count,
 546                     max_allowed => $max_checkouts_allowed,
 547                 };
 548             }
 549         } elsif ( not $onsite_checkout ) {
 550             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 551                 return {
 552                     reason => 'TOO_MANY_CHECKOUTS',
 553                     count => $checkout_count - $onsite_checkout_count,
 554                     max_allowed => $max_checkouts_allowed,
 555                 };
 556             }
 557         }
 558     }
 559
 560     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 561         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 562     }
 563
 564     # OK, the patron can issue !!!
 565     return;
 566 }
 567
 568 =head2 CanBookBeIssued
 569
 570   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 571                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 572
 573 Check if a book can be issued.
 574
 575 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 576
 577 IMPORTANT: The assumption by users of this routine is that causes blocking
 578 the issue are keyed by uppercase labels and other returned
 579 data is keyed in lower case!
 580
 581 =over 4
 582
 583 =item C<$patron> is a Koha::Patron
 584
 585 =item C<$barcode> is the bar code of the book being issued.
 586
 587 =item C<$duedates> is a DateTime object.
 588
 589 =item C<$inprocess> boolean switch
 590
 591 =item C<$ignore_reserves> boolean switch
 592
 593 =item C<$params> Hashref of additional parameters
 594
 595 Available keys:
 596     override_high_holds - Ignore high holds
 597     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 598
 599 =back
 600
 601 Returns :
 602
 603 =over 4
 604
 605 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 606 Possible values are :
 607
 608 =back
 609
 610 =head3 INVALID_DATE
 611
 612 sticky due date is invalid
 613
 614 =head3 GNA
 615
 616 borrower gone with no address
 617
 618 =head3 CARD_LOST
 619
 620 borrower declared it's card lost
 621
 622 =head3 DEBARRED
 623
 624 borrower debarred
 625
 626 =head3 UNKNOWN_BARCODE
 627
 628 barcode unknown
 629
 630 =head3 NOT_FOR_LOAN
 631
 632 item is not for loan
 633
 634 =head3 WTHDRAWN
 635
 636 item withdrawn.
 637
 638 =head3 RESTRICTED
 639
 640 item is restricted (set by ??)
 641
 642 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 643 could be prevented, but ones that can be overriden by the operator.
 644
 645 Possible values are :
 646
 647 =head3 DEBT
 648
 649 borrower has debts.
 650
 651 =head3 RENEW_ISSUE
 652
 653 renewing, not issuing
 654
 655 =head3 ISSUED_TO_ANOTHER
 656
 657 issued to someone else.
 658
 659 =head3 RESERVED
 660
 661 reserved for someone else.
 662
 663 =head3 INVALID_DATE
 664
 665 sticky due date is invalid or due date in the past
 666
 667 =head3 TOO_MANY
 668
 669 if the borrower borrows to much things
 670
 671 =cut
 672
 673 sub CanBookBeIssued {
 674     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 675     my %needsconfirmation;    # filled with problems that needs confirmations
 676     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 677     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 678     my %messages;             # filled with information messages that should be displayed.
 679
 680     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 681     my $override_high_holds = $params->{override_high_holds} || 0;
 682
 683     my $item_object = Koha::Items->find({barcode => $barcode });
 684
 685     # MANDATORY CHECKS - unless item exists, nothing else matters
 686     unless ( $item_object ) {
 687         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 688     }
 689     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 690
 691     my $item_unblessed = $item_object->unblessed; # Transition...
 692     my $issue = $item_object->checkout;
 693     my $biblio = $item_object->biblio;
 694
 695     my $biblioitem = $biblio->biblioitem;
 696     my $effective_itemtype = $item_object->effective_itemtype;
 697     my $dbh             = C4::Context->dbh;
 698     my $patron_unblessed = $patron->unblessed;
 699
 700     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 701     #
 702     # DUE DATE is OK ? -- should already have checked.
 703     #
 704     if ($duedate && ref $duedate ne 'DateTime') {
 705         $duedate = dt_from_string($duedate);
 706     }
 707     my $now = DateTime->now( time_zone => C4::Context->tz() );
 708     unless ( $duedate ) {
 709         my $issuedate = $now->clone();
 710
 711         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 712
 713         # Offline circ calls AddIssue directly, doesn't run through here
 714         #  So issuingimpossible should be ok.
 715     }
 716
 717     my $fees = Koha::Charges::Fees->new(
 718         {
 719             patron    => $patron,
 720             library   => $circ_library,
 721             item      => $item_object,
 722             to_date   => $duedate,
 723         }
 724     );
 725
 726     if ($duedate) {
 727         my $today = $now->clone();
 728         $today->truncate( to => 'minute');
 729         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 730             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 731         }
 732     } else {
 733             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 734     }
 735
 736     #
 737     # BORROWER STATUS
 738     #
 739     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 740         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 741         &UpdateStats({
 742                      branch => C4::Context->userenv->{'branch'},
 743                      type => 'localuse',
 744                      itemnumber => $item_object->itemnumber,
 745                      itemtype => $effective_itemtype,
 746                      borrowernumber => $patron->borrowernumber,
 747                      ccode => $item_object->ccode}
 748                     );
 749         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 750         return( { STATS => 1 }, {});
 751     }
 752
 753     if ( $patron->gonenoaddress == 1 ) {
 754         $issuingimpossible{GNA} = 1;
 755     }
 756
 757     if ( $patron->lost == 1 ) {
 758         $issuingimpossible{CARD_LOST} = 1;
 759     }
 760     if ( $patron->is_debarred ) {
 761         $issuingimpossible{DEBARRED} = 1;
 762     }
 763
 764     if ( $patron->is_expired ) {
 765         $issuingimpossible{EXPIRED} = 1;
 766     }
 767
 768     #
 769     # BORROWER STATUS
 770     #
 771
 772     # DEBTS
 773     my $account = $patron->account;
 774     my $balance = $account->balance;
 775     my $non_issues_charges = $account->non_issues_charges;
 776     my $other_charges = $balance - $non_issues_charges;
 777
 778     my $amountlimit = C4::Context->preference("noissuescharge");
 779     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 780     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 781
 782     # Check the debt of this patrons guarantees
 783     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 784     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 785     if ( defined $no_issues_charge_guarantees ) {
 786         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 787         my $guarantees_non_issues_charges;
 788         foreach my $g ( @guarantees ) {
 789             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 790         }
 791
 792         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 793             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 794         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 795             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 796         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 797             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 798         }
 799     }
 800
 801     if ( C4::Context->preference("IssuingInProcess") ) {
 802         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 803             $issuingimpossible{DEBT} = $non_issues_charges;
 804         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 805             $needsconfirmation{DEBT} = $non_issues_charges;
 806         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 807             $needsconfirmation{DEBT} = $non_issues_charges;
 808         }
 809     }
 810     else {
 811         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 812             $needsconfirmation{DEBT} = $non_issues_charges;
 813         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 814             $issuingimpossible{DEBT} = $non_issues_charges;
 815         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 816             $needsconfirmation{DEBT} = $non_issues_charges;
 817         }
 818     }
 819
 820     if ($balance > 0 && $other_charges > 0) {
 821         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 822     }
 823
 824     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 825     $patron_unblessed = $patron->unblessed;
 826
 827     if ( my $debarred_date = $patron->is_debarred ) {
 828          # patron has accrued fine days or has a restriction. $count is a date
 829         if ($debarred_date eq '9999-12-31') {
 830             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 831         }
 832         else {
 833             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 834         }
 835     } elsif ( my $num_overdues = $patron->has_overdues ) {
 836         ## patron has outstanding overdue loans
 837         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 838             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 839         }
 840         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 841             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 842         }
 843     }
 844
 845     #
 846     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 847     #
 848     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 849
 850         # Already issued to current borrower.
 851         # If it is an on-site checkout if it can be switched to a normal checkout
 852         # or ask whether the loan should be renewed
 853
 854         if ( $issue->onsite_checkout
 855                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 856             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 857         } else {
 858             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 859                 $patron->borrowernumber,
 860                 $item_object->itemnumber,
 861             );
 862             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 863                 if ( $renewerror eq 'onsite_checkout' ) {
 864                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 865                 }
 866                 else {
 867                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 868                 }
 869             }
 870             else {
 871                 $needsconfirmation{RENEW_ISSUE} = 1;
 872             }
 873         }
 874     }
 875     elsif ( $issue ) {
 876
 877         # issued to someone else
 878
 879         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 880
 881         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 882
 883         unless ( $can_be_returned ) {
 884             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 885             $issuingimpossible{branch_to_return} = $message;
 886         } else {
 887             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 888                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 889             } else {
 890             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 891             $needsconfirmation{issued_firstname} = $patron->firstname;
 892             $needsconfirmation{issued_surname} = $patron->surname;
 893             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 894             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 895             }
 896         }
 897     }
 898
 899     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 900     #
 901     my $switch_onsite_checkout = (
 902           C4::Context->preference('SwitchOnSiteCheckouts')
 903       and $issue
 904       and $issue->onsite_checkout
 905       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 906     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 907     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 908     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 909         if ( $toomany->{max_allowed} == 0 ) {
 910             $needsconfirmation{PATRON_CANT} = 1;
 911         }
 912         if ( C4::Context->preference("AllowTooManyOverride") ) {
 913             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 914             $needsconfirmation{current_loan_count} = $toomany->{count};
 915             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 916         } else {
 917             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 918             $issuingimpossible{current_loan_count} = $toomany->{count};
 919             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 920         }
 921     }
 922
 923     #
 924     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 925     #
 926     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 927     my $wants_check = $patron->wants_check_for_previous_checkout;
 928     $needsconfirmation{PREVISSUE} = 1
 929         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
 930
 931     #
 932     # ITEM CHECKING
 933     #
 934     if ( $item_object->notforloan )
 935     {
 936         if(!C4::Context->preference("AllowNotForLoanOverride")){
 937             $issuingimpossible{NOT_FOR_LOAN} = 1;
 938             $issuingimpossible{item_notforloan} = $item_object->notforloan;
 939         }else{
 940             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 941             $needsconfirmation{item_notforloan} = $item_object->notforloan;
 942         }
 943     }
 944     else {
 945         # we have to check itemtypes.notforloan also
 946         if (C4::Context->preference('item-level_itypes')){
 947             # this should probably be a subroutine
 948             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 949             $sth->execute($effective_itemtype);
 950             my $notforloan=$sth->fetchrow_hashref();
 951             if ($notforloan->{'notforloan'}) {
 952                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 953                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 954                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 955                 } else {
 956                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 957                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 958                 }
 959             }
 960         }
 961         else {
 962             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
 963             if ( $itemtype and $itemtype->notforloan == 1){
 964                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 965                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 966                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 967                 } else {
 968                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 969                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 970                 }
 971             }
 972         }
 973     }
 974     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
 975     {
 976         $issuingimpossible{WTHDRAWN} = 1;
 977     }
 978     if (   $item_object->restricted
 979         && $item_object->restricted == 1 )
 980     {
 981         $issuingimpossible{RESTRICTED} = 1;
 982     }
 983     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 984         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
 985         my $code = $av->count ? $av->next->lib : '';
 986         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 987         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 988     }
 989     if ( C4::Context->preference("IndependentBranches") ) {
 990         my $userenv = C4::Context->userenv;
 991         unless ( C4::Context->IsSuperLibrarian() ) {
 992             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
 993             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
 994                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 995                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
 996             }
 997             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
 998               if ( $patron->branchcode ne $userenv->{branch} );
 999         }
1000     }
1001
1002     #
1003     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1004     #
1005     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1006     if ($rentalConfirmation) {
1007         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1008
1009         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1010         if ($itemtype_object) {
1011             my $accumulate_charge = $fees->accumulate_rentalcharge();
1012             if ( $accumulate_charge > 0 ) {
1013                 $rentalCharge += $accumulate_charge;
1014             }
1015         }
1016
1017         if ( $rentalCharge > 0 ) {
1018             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1019         }
1020     }
1021
1022     unless ( $ignore_reserves ) {
1023         # See if the item is on reserve.
1024         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1025         if ($restype) {
1026             my $resbor = $res->{'borrowernumber'};
1027             if ( $resbor ne $patron->borrowernumber ) {
1028                 my $patron = Koha::Patrons->find( $resbor );
1029                 if ( $restype eq "Waiting" )
1030                 {
1031                     # The item is on reserve and waiting, but has been
1032                     # reserved by some other patron.
1033                     $needsconfirmation{RESERVE_WAITING} = 1;
1034                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1035                     $needsconfirmation{'ressurname'} = $patron->surname;
1036                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1037                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1038                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1039                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1040                 }
1041                 elsif ( $restype eq "Reserved" ) {
1042                     # The item is on reserve for someone else.
1043                     $needsconfirmation{RESERVED} = 1;
1044                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1045                     $needsconfirmation{'ressurname'} = $patron->surname;
1046                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1047                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1048                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1049                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1050                 }
1051             }
1052         }
1053     }
1054
1055     ## CHECK AGE RESTRICTION
1056     my $agerestriction  = $biblioitem->agerestriction;
1057     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1058     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1059         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1060             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1061         }
1062         else {
1063             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1064         }
1065     }
1066
1067     ## check for high holds decreasing loan period
1068     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1069         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1070
1071         if ( $check->{exceeded} ) {
1072             if ($override_high_holds) {
1073                 $alerts{HIGHHOLDS} = {
1074                     num_holds  => $check->{outstanding},
1075                     duration   => $check->{duration},
1076                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1077                 };
1078             }
1079             else {
1080                 $needsconfirmation{HIGHHOLDS} = {
1081                     num_holds  => $check->{outstanding},
1082                     duration   => $check->{duration},
1083                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1084                 };
1085             }
1086         }
1087     }
1088
1089     if (
1090         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1091         # don't do the multiple loans per bib check if we've
1092         # already determined that we've got a loan on the same item
1093         !$issuingimpossible{NO_MORE_RENEWALS} &&
1094         !$needsconfirmation{RENEW_ISSUE}
1095     ) {
1096         # Check if borrower has already issued an item from the same biblio
1097         # Only if it's not a subscription
1098         my $biblionumber = $item_object->biblionumber;
1099         require C4::Serials;
1100         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1101         unless ($is_a_subscription) {
1102             # FIXME Should be $patron->checkouts($args);
1103             my $checkouts = Koha::Checkouts->search(
1104                 {
1105                     borrowernumber => $patron->borrowernumber,
1106                     biblionumber   => $biblionumber,
1107                 },
1108                 {
1109                     join => 'item',
1110                 }
1111             );
1112             # if we get here, we don't already have a loan on this item,
1113             # so if there are any loans on this bib, ask for confirmation
1114             if ( $checkouts->count ) {
1115                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1116             }
1117         }
1118     }
1119
1120     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1121 }
1122
1123 =head2 CanBookBeReturned
1124
1125   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1126
1127 Check whether the item can be returned to the provided branch
1128
1129 =over 4
1130
1131 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1132
1133 =item C<$branch> is the branchcode where the return is taking place
1134
1135 =back
1136
1137 Returns:
1138
1139 =over 4
1140
1141 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1142
1143 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1144
1145 =back
1146
1147 =cut
1148
1149 sub CanBookBeReturned {
1150   my ($item, $branch) = @_;
1151   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1152
1153   # assume return is allowed to start
1154   my $allowed = 1;
1155   my $message;
1156
1157   # identify all cases where return is forbidden
1158   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1159      $allowed = 0;
1160      $message = $item->{'homebranch'};
1161   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1162      $allowed = 0;
1163      $message = $item->{'holdingbranch'};
1164   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1165      $allowed = 0;
1166      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1167   }
1168
1169   return ($allowed, $message);
1170 }
1171
1172 =head2 CheckHighHolds
1173
1174     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1175     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1176     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1177
1178 =cut
1179
1180 sub checkHighHolds {
1181     my ( $item, $borrower ) = @_;
1182     my $branchcode = _GetCircControlBranch( $item, $borrower );
1183     my $item_object = Koha::Items->find( $item->{itemnumber} );
1184
1185     my $return_data = {
1186         exceeded    => 0,
1187         outstanding => 0,
1188         duration    => 0,
1189         due_date    => undef,
1190     };
1191
1192     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1193
1194     if ( $holds->count() ) {
1195         $return_data->{outstanding} = $holds->count();
1196
1197         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1198         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1199         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1200
1201         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1202
1203         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1204
1205             # static means just more than a given number of holds on the record
1206
1207             # If the number of holds is less than the threshold, we can stop here
1208             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1209                 return $return_data;
1210             }
1211         }
1212         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1213
1214             # dynamic means X more than the number of holdable items on the record
1215
1216             # let's get the items
1217             my @items = $holds->next()->biblio()->items()->as_list;
1218
1219             # Remove any items with status defined to be ignored even if the would not make item unholdable
1220             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1221                 @items = grep { !$_->$status } @items;
1222             }
1223
1224             # Remove any items that are not holdable for this patron
1225             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber )->{status} eq 'OK' } @items;
1226
1227             my $items_count = scalar @items;
1228
1229             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1230
1231             # If the number of holds is less than the count of items we have
1232             # plus the number of holds allowed above that count, we can stop here
1233             if ( $holds->count() <= $threshold ) {
1234                 return $return_data;
1235             }
1236         }
1237
1238         my $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1239
1240         my $calendar = Koha::Calendar->new( branchcode => $branchcode );
1241
1242         my $itype = $item_object->effective_itemtype;
1243         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1244
1245         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1246
1247         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1248         $reduced_datedue->set_hour($orig_due->hour);
1249         $reduced_datedue->set_minute($orig_due->minute);
1250         $reduced_datedue->truncate( to => 'minute' );
1251
1252         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1253             $return_data->{exceeded} = 1;
1254             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1255             $return_data->{due_date} = $reduced_datedue;
1256         }
1257     }
1258
1259     return $return_data;
1260 }
1261
1262 =head2 AddIssue
1263
1264   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1265
1266 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1267
1268 =over 4
1269
1270 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1271
1272 =item C<$barcode> is the barcode of the item being issued.
1273
1274 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1275 Calculated if empty.
1276
1277 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1278
1279 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1280 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1281
1282 AddIssue does the following things :
1283
1284   - step 01: check that there is a borrowernumber & a barcode provided
1285   - check for RENEWAL (book issued & being issued to the same patron)
1286       - renewal YES = Calculate Charge & renew
1287       - renewal NO  =
1288           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1289           * RESERVE PLACED ?
1290               - fill reserve if reserve to this patron
1291               - cancel reserve or not, otherwise
1292           * TRANSFERT PENDING ?
1293               - complete the transfert
1294           * ISSUE THE BOOK
1295
1296 =back
1297
1298 =cut
1299
1300 sub AddIssue {
1301     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1302
1303     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1304     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1305     my $auto_renew = $params && $params->{auto_renew};
1306     my $dbh          = C4::Context->dbh;
1307     my $barcodecheck = CheckValidBarcode($barcode);
1308
1309     my $issue;
1310
1311     if ( $datedue && ref $datedue ne 'DateTime' ) {
1312         $datedue = dt_from_string($datedue);
1313     }
1314
1315     # $issuedate defaults to today.
1316     if ( !defined $issuedate ) {
1317         $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1318     }
1319     else {
1320         if ( ref $issuedate ne 'DateTime' ) {
1321             $issuedate = dt_from_string($issuedate);
1322
1323         }
1324     }
1325
1326     # Stop here if the patron or barcode doesn't exist
1327     if ( $borrower && $barcode && $barcodecheck ) {
1328         # find which item we issue
1329         my $item_object = Koha::Items->find({ barcode => $barcode })
1330           or return;    # if we don't get an Item, abort.
1331         my $item_unblessed = $item_object->unblessed;
1332
1333         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1334
1335         # get actual issuing if there is one
1336         my $actualissue = $item_object->checkout;
1337
1338         # check if we just renew the issue.
1339         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1340                 and not $switch_onsite_checkout ) {
1341             $datedue = AddRenewal(
1342                 $borrower->{'borrowernumber'},
1343                 $item_object->itemnumber,
1344                 $branchcode,
1345                 $datedue,
1346                 $issuedate,    # here interpreted as the renewal date
1347             );
1348         }
1349         else {
1350             unless ($datedue) {
1351                 my $itype = $item_object->effective_itemtype;
1352                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1353
1354             }
1355             $datedue->truncate( to => 'minute' );
1356
1357             my $patron = Koha::Patrons->find( $borrower );
1358             my $library = Koha::Libraries->find( $branchcode );
1359             my $fees = Koha::Charges::Fees->new(
1360                 {
1361                     patron    => $patron,
1362                     library   => $library,
1363                     item      => $item_object,
1364                     to_date   => $datedue,
1365                 }
1366             );
1367
1368             # it's NOT a renewal
1369             if ( $actualissue and not $switch_onsite_checkout ) {
1370                 # This book is currently on loan, but not to the person
1371                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1372                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1373                 return unless $allowed;
1374                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1375             }
1376
1377             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1378
1379             # Starting process for transfer job (checking transfert and validate it if we have one)
1380             my ($datesent) = GetTransfers( $item_object->itemnumber );
1381             if ($datesent) {
1382                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1383                 my $sth = $dbh->prepare(
1384                     "UPDATE branchtransfers
1385                         SET datearrived = now(),
1386                         tobranch = ?,
1387                         comments = 'Forced branchtransfer'
1388                     WHERE itemnumber= ? AND datearrived IS NULL"
1389                 );
1390                 $sth->execute( C4::Context->userenv->{'branch'},
1391                     $item_object->itemnumber );
1392             }
1393
1394             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1395             unless ($auto_renew) {
1396                 my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1397                     {   categorycode => $borrower->{categorycode},
1398                         itemtype     => $item_object->effective_itemtype,
1399                         branchcode   => $branchcode
1400                     }
1401                 );
1402
1403                 $auto_renew = $issuing_rule->auto_renew if $issuing_rule;
1404             }
1405
1406             # Record in the database the fact that the book was issued.
1407             unless ($datedue) {
1408                 my $itype = $item_object->effective_itemtype;
1409                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1410
1411             }
1412             $datedue->truncate( to => 'minute' );
1413
1414             my $issue_attributes = {
1415                 borrowernumber  => $borrower->{'borrowernumber'},
1416                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1417                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1418                 branchcode      => C4::Context->userenv->{'branch'},
1419                 onsite_checkout => $onsite_checkout,
1420                 auto_renew      => $auto_renew ? 1 : 0,
1421             };
1422
1423             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1424             if ($issue) {
1425                 $issue->set($issue_attributes)->store;
1426             }
1427             else {
1428                 $issue = Koha::Checkout->new(
1429                     {
1430                         itemnumber => $item_object->itemnumber,
1431                         %$issue_attributes,
1432                     }
1433                 )->store;
1434             }
1435             if ( $item_object->location eq 'CART' && $item_object->permanent_location ne 'CART'  ) {
1436             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1437                 CartToShelf( $item_object->itemnumber );
1438             }
1439
1440             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1441                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1442             }
1443
1444             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1445             if ( $item_object->itemlost ) {
1446                 if (
1447                     Koha::RefundLostItemFeeRules->should_refund(
1448                         {
1449                             current_branch      => C4::Context->userenv->{branch},
1450                             item_home_branch    => $item_object->homebranch,
1451                             item_holding_branch => $item_object->holdingbranch,
1452                         }
1453                     )
1454                   )
1455                 {
1456                     _FixAccountForLostAndReturned( $item_object->itemnumber, undef,
1457                         $item_object->barcode );
1458                 }
1459             }
1460
1461             ModItem(
1462                 {
1463                     issues        => $item_object->issues + 1,
1464                     holdingbranch => C4::Context->userenv->{'branch'},
1465                     itemlost      => 0,
1466                     onloan        => $datedue->ymd(),
1467                     datelastborrowed => DateTime->now( time_zone => C4::Context->tz() )->ymd(),
1468                 },
1469                 $item_object->biblionumber,
1470                 $item_object->itemnumber,
1471                 { log_action => 0 }
1472             );
1473             ModDateLastSeen( $item_object->itemnumber );
1474
1475             # If it costs to borrow this book, charge it to the patron's account.
1476             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1477             if ( $charge > 0 ) {
1478                 AddIssuingCharge( $issue, $charge, 'RENT' );
1479             }
1480
1481             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1482             if ( $itemtype_object ) {
1483                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1484                 if ( $accumulate_charge > 0 ) {
1485                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1486                     $charge += $accumulate_charge;
1487                     $item_unblessed->{charge} = $charge;
1488                 }
1489             }
1490
1491             # Record the fact that this book was issued.
1492             &UpdateStats(
1493                 {
1494                     branch => C4::Context->userenv->{'branch'},
1495                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1496                     amount         => $charge,
1497                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1498                     itemnumber     => $item_object->itemnumber,
1499                     itemtype       => $item_object->effective_itemtype,
1500                     location       => $item_object->location,
1501                     borrowernumber => $borrower->{'borrowernumber'},
1502                     ccode          => $item_object->ccode,
1503                 }
1504             );
1505
1506             # Send a checkout slip.
1507             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1508             my %conditions        = (
1509                 branchcode   => $branchcode,
1510                 categorycode => $borrower->{categorycode},
1511                 item_type    => $item_object->effective_itemtype,
1512                 notification => 'CHECKOUT',
1513             );
1514             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1515                 SendCirculationAlert(
1516                     {
1517                         type     => 'CHECKOUT',
1518                         item     => $item_object->unblessed,
1519                         borrower => $borrower,
1520                         branch   => $branchcode,
1521                     }
1522                 );
1523             }
1524             logaction(
1525                 "CIRCULATION", "ISSUE",
1526                 $borrower->{'borrowernumber'},
1527                 $item_object->itemnumber,
1528             ) if C4::Context->preference("IssueLog");
1529         }
1530     }
1531     return $issue;
1532 }
1533
1534 =head2 GetLoanLength
1535
1536   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1537
1538 Get loan length for an itemtype, a borrower type and a branch
1539
1540 =cut
1541
1542 sub GetLoanLength {
1543     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1544     my $dbh = C4::Context->dbh;
1545     my $sth = $dbh->prepare(qq{
1546         SELECT issuelength, lengthunit, renewalperiod
1547         FROM issuingrules
1548         WHERE   categorycode=?
1549             AND itemtype=?
1550             AND branchcode=?
1551             AND issuelength IS NOT NULL
1552     });
1553
1554     # try to find issuelength & return the 1st available.
1555     # check with borrowertype, itemtype and branchcode, then without one of those parameters
1556     $sth->execute( $borrowertype, $itemtype, $branchcode );
1557     my $loanlength = $sth->fetchrow_hashref;
1558
1559     return $loanlength
1560       if defined($loanlength) && defined $loanlength->{issuelength};
1561
1562     $sth->execute( $borrowertype, '*', $branchcode );
1563     $loanlength = $sth->fetchrow_hashref;
1564     return $loanlength
1565       if defined($loanlength) && defined $loanlength->{issuelength};
1566
1567     $sth->execute( '*', $itemtype, $branchcode );
1568     $loanlength = $sth->fetchrow_hashref;
1569     return $loanlength
1570       if defined($loanlength) && defined $loanlength->{issuelength};
1571
1572     $sth->execute( '*', '*', $branchcode );
1573     $loanlength = $sth->fetchrow_hashref;
1574     return $loanlength
1575       if defined($loanlength) && defined $loanlength->{issuelength};
1576
1577     $sth->execute( $borrowertype, $itemtype, '*' );
1578     $loanlength = $sth->fetchrow_hashref;
1579     return $loanlength
1580       if defined($loanlength) && defined $loanlength->{issuelength};
1581
1582     $sth->execute( $borrowertype, '*', '*' );
1583     $loanlength = $sth->fetchrow_hashref;
1584     return $loanlength
1585       if defined($loanlength) && defined $loanlength->{issuelength};
1586
1587     $sth->execute( '*', $itemtype, '*' );
1588     $loanlength = $sth->fetchrow_hashref;
1589     return $loanlength
1590       if defined($loanlength) && defined $loanlength->{issuelength};
1591
1592     $sth->execute( '*', '*', '*' );
1593     $loanlength = $sth->fetchrow_hashref;
1594     return $loanlength
1595       if defined($loanlength) && defined $loanlength->{issuelength};
1596
1597     # if no rule is set => 0 day (hardcoded)
1598     return {
1599         issuelength => 0,
1600         renewalperiod => 0,
1601         lengthunit => 'days',
1602     };
1603
1604 }
1605
1606
1607 =head2 GetHardDueDate
1608
1609   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1610
1611 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1612
1613 =cut
1614
1615 sub GetHardDueDate {
1616     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1617
1618     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1619         {   categorycode => $borrowertype,
1620             itemtype     => $itemtype,
1621             branchcode   => $branchcode
1622         }
1623     );
1624
1625
1626     if ( defined( $issuing_rule ) ) {
1627         if ( $issuing_rule->hardduedate ) {
1628             return (dt_from_string($issuing_rule->hardduedate, 'iso'),$issuing_rule->hardduedatecompare);
1629         } else {
1630             return (undef, undef);
1631         }
1632     }
1633 }
1634
1635 =head2 GetBranchBorrowerCircRule
1636
1637   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1638
1639 Retrieves circulation rule attributes that apply to the given
1640 branch and patron category, regardless of item type.
1641 The return value is a hashref containing the following key:
1642
1643 patron_maxissueqty - maximum number of loans that a
1644 patron of the given category can have at the given
1645 branch.  If the value is undef, no limit.
1646
1647 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1648 patron of the given category can have at the given
1649 branch.  If the value is undef, no limit.
1650
1651 This will check for different branch/category combinations in the following order:
1652 branch and category
1653 branch only
1654 category only
1655 default branch and category
1656
1657 If no rule has been found in the database, it will default to
1658 the buillt in rule:
1659
1660 patron_maxissueqty - undef
1661 patron_maxonsiteissueqty - undef
1662
1663 C<$branchcode> and C<$categorycode> should contain the
1664 literal branch code and patron category code, respectively - no
1665 wildcards.
1666
1667 =cut
1668
1669 sub GetBranchBorrowerCircRule {
1670     my ( $branchcode, $categorycode ) = @_;
1671
1672     # Initialize default values
1673     my $rules = {
1674         patron_maxissueqty       => undef,
1675         patron_maxonsiteissueqty => undef,
1676     };
1677
1678     # Search for rules!
1679     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1680         my $rule = Koha::CirculationRules->get_effective_rule(
1681             {
1682                 categorycode => $categorycode,
1683                 itemtype     => undef,
1684                 branchcode   => $branchcode,
1685                 rule_name    => $rule_name,
1686             }
1687         );
1688
1689         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1690     }
1691
1692     return $rules;
1693 }
1694
1695 =head2 GetBranchItemRule
1696
1697   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1698
1699 Retrieves circulation rule attributes that apply to the given
1700 branch and item type, regardless of patron category.
1701
1702 The return value is a hashref containing the following keys:
1703
1704 holdallowed => Hold policy for this branch and itemtype. Possible values:
1705   0: No holds allowed.
1706   1: Holds allowed only by patrons that have the same homebranch as the item.
1707   2: Holds allowed from any patron.
1708
1709 returnbranch => branch to which to return item.  Possible values:
1710   noreturn: do not return, let item remain where checked in (floating collections)
1711   homebranch: return to item's home branch
1712   holdingbranch: return to issuer branch
1713
1714 This searches branchitemrules in the following order:
1715
1716   * Same branchcode and itemtype
1717   * Same branchcode, itemtype '*'
1718   * branchcode '*', same itemtype
1719   * branchcode and itemtype '*'
1720
1721 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1722
1723 =cut
1724
1725 sub GetBranchItemRule {
1726     my ( $branchcode, $itemtype ) = @_;
1727
1728     # Search for rules!
1729     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1730         {
1731             branchcode => $branchcode,
1732             itemtype => $itemtype,
1733             rule_name => 'holdallowed',
1734         }
1735     );
1736     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1737         {
1738             branchcode => $branchcode,
1739             itemtype => $itemtype,
1740             rule_name => 'hold_fulfillment_policy',
1741         }
1742     );
1743     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1744         {
1745             branchcode => $branchcode,
1746             itemtype => $itemtype,
1747             rule_name => 'returnbranch',
1748         }
1749     );
1750
1751     # built-in default circulation rule
1752     my $rules;
1753     $rules->{holdallowed} = defined $holdallowed_rule
1754         ? $holdallowed_rule->rule_value
1755         : 2;
1756     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1757         ? $hold_fulfillment_policy_rule->rule_value
1758         : 'any';
1759     $rules->{returnbranch} = defined $returnbranch_rule
1760         ? $returnbranch_rule->rule_value
1761         : 'homebranch';
1762
1763     return $rules;
1764 }
1765
1766 =head2 AddReturn
1767
1768   ($doreturn, $messages, $iteminformation, $borrower) =
1769       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1770
1771 Returns a book.
1772
1773 =over 4
1774
1775 =item C<$barcode> is the bar code of the book being returned.
1776
1777 =item C<$branch> is the code of the branch where the book is being returned.
1778
1779 =item C<$exemptfine> indicates that overdue charges for the item will be
1780 removed. Optional.
1781
1782 =item C<$return_date> allows the default return date to be overridden
1783 by the given return date. Optional.
1784
1785 =back
1786
1787 C<&AddReturn> returns a list of four items:
1788
1789 C<$doreturn> is true iff the return succeeded.
1790
1791 C<$messages> is a reference-to-hash giving feedback on the operation.
1792 The keys of the hash are:
1793
1794 =over 4
1795
1796 =item C<BadBarcode>
1797
1798 No item with this barcode exists. The value is C<$barcode>.
1799
1800 =item C<NotIssued>
1801
1802 The book is not currently on loan. The value is C<$barcode>.
1803
1804 =item C<withdrawn>
1805
1806 This book has been withdrawn/cancelled. The value should be ignored.
1807
1808 =item C<Wrongbranch>
1809
1810 This book has was returned to the wrong branch.  The value is a hashref
1811 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1812 contain the branchcode of the incorrect and correct return library, respectively.
1813
1814 =item C<ResFound>
1815
1816 The item was reserved. The value is a reference-to-hash whose keys are
1817 fields from the reserves table of the Koha database, and
1818 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1819 either C<Waiting>, C<Reserved>, or 0.
1820
1821 =item C<WasReturned>
1822
1823 Value 1 if return is successful.
1824
1825 =item C<NeedsTransfer>
1826
1827 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1828
1829 =back
1830
1831 C<$iteminformation> is a reference-to-hash, giving information about the
1832 returned item from the issues table.
1833
1834 C<$borrower> is a reference-to-hash, giving information about the
1835 patron who last borrowed the book.
1836
1837 =cut
1838
1839 sub AddReturn {
1840     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1841
1842     if ($branch and not Koha::Libraries->find($branch)) {
1843         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1844         undef $branch;
1845     }
1846     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1847     $return_date //= dt_from_string();
1848     my $messages;
1849     my $patron;
1850     my $doreturn       = 1;
1851     my $validTransfert = 0;
1852     my $stat_type = 'return';
1853
1854     # get information on item
1855     my $item = Koha::Items->find({ barcode => $barcode });
1856     unless ($item) {
1857         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1858     }
1859
1860     my $itemnumber = $item->itemnumber;
1861     my $itemtype = $item->effective_itemtype;
1862
1863     my $issue  = $item->checkout;
1864     if ( $issue ) {
1865         $patron = $issue->patron
1866             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1867                 . Dumper($issue->unblessed) . "\n";
1868     } else {
1869         $messages->{'NotIssued'} = $barcode;
1870         ModItem({ onloan => undef }, $item->biblionumber, $item->itemnumber) if defined $item->onloan;
1871         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1872         $doreturn = 0;
1873         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1874         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1875         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1876            $messages->{'LocalUse'} = 1;
1877            $stat_type = 'localuse';
1878         }
1879     }
1880
1881     my $item_unblessed = $item->unblessed;
1882         # full item data, but no borrowernumber or checkout info (no issue)
1883     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1884         # get the proper branch to which to return the item
1885     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1886         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1887
1888     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1889     my $patron_unblessed = $patron ? $patron->unblessed : {};
1890
1891     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1892     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1893     if ($update_loc_rules) {
1894         if (defined $update_loc_rules->{_ALL_}) {
1895             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1896             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1897             if ( $item->location ne $update_loc_rules->{_ALL_}) {
1898                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1899                 ModItem( { location => $update_loc_rules->{_ALL_} }, undef, $itemnumber );
1900             }
1901         }
1902         else {
1903             foreach my $key ( keys %$update_loc_rules ) {
1904                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1905                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1906                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1907                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1908                     ModItem( { location => $update_loc_rules->{$key} }, undef, $itemnumber );
1909                     last;
1910                 }
1911             }
1912         }
1913     }
1914
1915     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1916     if ($yaml) {
1917         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1918         my $rules;
1919         eval { $rules = YAML::Load($yaml); };
1920         if ($@) {
1921             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1922         }
1923         else {
1924             foreach my $key ( keys %$rules ) {
1925                 if ( $item->notforloan eq $key ) {
1926                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1927                     ModItem( { notforloan => $rules->{$key} }, undef, $itemnumber, { log_action => 0 } );
1928                     last;
1929                 }
1930             }
1931         }
1932     }
1933
1934     # check if the return is allowed at this branch
1935     my ($returnallowed, $message) = CanBookBeReturned($item_unblessed, $branch);
1936     unless ($returnallowed){
1937         $messages->{'Wrongbranch'} = {
1938             Wrongbranch => $branch,
1939             Rightbranch => $message
1940         };
1941         $doreturn = 0;
1942         return ( $doreturn, $messages, $issue, $patron_unblessed);
1943     }
1944
1945     if ( $item->withdrawn ) { # book has been cancelled
1946         $messages->{'withdrawn'} = 1;
1947         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1948     }
1949
1950     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
1951         $doreturn = 0;
1952     }
1953
1954     # case of a return of document (deal with issues and holdingbranch)
1955     if ($doreturn) {
1956         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1957         $patron or warn "AddReturn without current borrower";
1958
1959         if ($patron) {
1960             eval {
1961                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy );
1962             };
1963             unless ( $@ ) {
1964                 if ( C4::Context->preference('CalculateFinesOnReturn') && !$item->itemlost ) {
1965                     _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed, return_date => $return_date } );
1966                 }
1967             } else {
1968                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
1969
1970                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
1971             }
1972
1973             # FIXME is the "= 1" right?  This could be the borrower hash.
1974             $messages->{'WasReturned'} = 1;
1975
1976         }
1977
1978         ModItem( { onloan => undef }, $item->biblionumber, $item->itemnumber, { log_action => 0 } );
1979     }
1980
1981     # the holdingbranch is updated if the document is returned to another location.
1982     # this is always done regardless of whether the item was on loan or not
1983     my $item_holding_branch = $item->holdingbranch;
1984     if ($item->holdingbranch ne $branch) {
1985         UpdateHoldingbranch($branch, $item->itemnumber);
1986         $item_unblessed->{'holdingbranch'} = $branch; # update item data holdingbranch too # FIXME I guess this is for the _debar_user_on_return call later
1987     }
1988
1989     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
1990     ModDateLastSeen( $item->itemnumber, $leave_item_lost );
1991
1992     # check if we have a transfer for this document
1993     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
1994
1995     # if we have a transfer to do, we update the line of transfers with the datearrived
1996     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
1997     if ($datesent) {
1998         if ( $tobranch eq $branch ) {
1999             my $sth = C4::Context->dbh->prepare(
2000                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2001             );
2002             $sth->execute( $item->itemnumber );
2003             # if we have a reservation with valid transfer, we can set it's status to 'W'
2004             C4::Reserves::ModReserveStatus($item->itemnumber, 'W');
2005         } else {
2006             $messages->{'WrongTransfer'}     = $tobranch;
2007             $messages->{'WrongTransferItem'} = $item->itemnumber;
2008         }
2009         $validTransfert = 1;
2010     }
2011
2012     # fix up the accounts.....
2013     if ( $item->itemlost ) {
2014         $messages->{'WasLost'} = 1;
2015         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2016             if (
2017                 Koha::RefundLostItemFeeRules->should_refund(
2018                     {
2019                         current_branch      => C4::Context->userenv->{branch},
2020                         item_home_branch    => $item->homebranch,
2021                         item_holding_branch => $item_holding_branch
2022                     }
2023                 )
2024               )
2025             {
2026                 _FixAccountForLostAndReturned( $item->itemnumber,
2027                     $borrowernumber, $barcode );
2028                 $messages->{'LostItemFeeRefunded'} = 1;
2029             }
2030         }
2031     }
2032
2033     # fix up the overdues in accounts...
2034     if ($borrowernumber) {
2035         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2036         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $item->itemnumber...) failed!";  # zero is OK, check defined
2037
2038         if ( $issue and $issue->is_overdue ) {
2039         # fix fine days
2040             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item_unblessed, dt_from_string($issue->date_due), $return_date );
2041             if ($reminder){
2042                 $messages->{'PrevDebarred'} = $debardate;
2043             } else {
2044                 $messages->{'Debarred'} = $debardate if $debardate;
2045             }
2046         # there's no overdue on the item but borrower had been previously debarred
2047         } elsif ( $issue->date_due and $patron->debarred ) {
2048              if ( $patron->debarred eq "9999-12-31") {
2049                 $messages->{'ForeverDebarred'} = $patron->debarred;
2050              } else {
2051                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2052                   $borrower_debar_dt->truncate(to => 'day');
2053                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2054                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2055                       $messages->{'PrevDebarred'} = $patron->debarred;
2056                   }
2057              }
2058         }
2059     }
2060
2061     # find reserves.....
2062     # if we don't have a reserve with the status W, we launch the Checkreserves routine
2063     my ($resfound, $resrec);
2064     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2065     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2066     if ($resfound) {
2067           $resrec->{'ResFound'} = $resfound;
2068         $messages->{'ResFound'} = $resrec;
2069     }
2070
2071     # Record the fact that this book was returned.
2072     UpdateStats({
2073         branch         => $branch,
2074         type           => $stat_type,
2075         itemnumber     => $itemnumber,
2076         itemtype       => $itemtype,
2077         borrowernumber => $borrowernumber,
2078         ccode          => $item->ccode,
2079     });
2080
2081     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2082     if ( $patron ) {
2083         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2084         my %conditions = (
2085             branchcode   => $branch,
2086             categorycode => $patron->categorycode,
2087             item_type    => $itemtype,
2088             notification => 'CHECKIN',
2089         );
2090         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2091             SendCirculationAlert({
2092                 type     => 'CHECKIN',
2093                 item     => $item_unblessed,
2094                 borrower => $patron->unblessed,
2095                 branch   => $branch,
2096             });
2097         }
2098
2099         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2100             if C4::Context->preference("ReturnLog");
2101         }
2102
2103     # Remove any OVERDUES related debarment if the borrower has no overdues
2104     if ( $borrowernumber
2105       && $patron->debarred
2106       && C4::Context->preference('AutoRemoveOverduesRestrictions')
2107       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2108       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2109     ) {
2110         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2111     }
2112
2113     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2114     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2115         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType");
2116         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2117             (C4::Context->preference("UseBranchTransferLimits") and
2118              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2119            )) {
2120             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s)", $item->itemnumber,$branch, $returnbranch;
2121             $debug and warn "item: " . Dumper($item_unblessed);
2122             ModItemTransfer($item->itemnumber, $branch, $returnbranch);
2123             $messages->{'WasTransfered'} = 1;
2124         } else {
2125             $messages->{'NeedsTransfer'} = $returnbranch;
2126         }
2127     }
2128
2129     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2130         my $claims = Koha::Checkouts::ReturnClaims->search(
2131            {
2132                itemnumber => $item->id,
2133                resolution => undef,
2134            }
2135         );
2136
2137         if ( $claims->count ) {
2138             $messages->{ReturnClaims} = $claims;
2139         }
2140     }
2141
2142     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2143 }
2144
2145 =head2 MarkIssueReturned
2146
2147   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2148
2149 Unconditionally marks an issue as being returned by
2150 moving the C<issues> row to C<old_issues> and
2151 setting C<returndate> to the current date.
2152
2153 if C<$returndate> is specified (in iso format), it is used as the date
2154 of the return.
2155
2156 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2157 the old_issue is immediately anonymised
2158
2159 Ideally, this function would be internal to C<C4::Circulation>,
2160 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2161 and offline_circ/process_koc.pl.
2162
2163 =cut
2164
2165 sub MarkIssueReturned {
2166     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2167
2168     # Retrieve the issue
2169     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2170     my $issue_id = $issue->issue_id;
2171
2172     my $anonymouspatron;
2173     if ( $privacy == 2 ) {
2174         # The default of 0 will not work due to foreign key constraints
2175         # The anonymisation will fail if AnonymousPatron is not a valid entry
2176         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2177         # Note that a warning should appear on the about page (System information tab).
2178         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2179         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2180             unless Koha::Patrons->find( $anonymouspatron );
2181     }
2182
2183     my $schema = Koha::Database->schema;
2184
2185     # FIXME Improve the return value and handle it from callers
2186     $schema->txn_do(sub {
2187
2188         # Update the returndate value
2189         if ( $returndate ) {
2190             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2191         }
2192         else {
2193             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2194         }
2195
2196         # Create the old_issues entry
2197         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2198
2199         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2200         if ( $privacy == 2) {
2201             $old_checkout->borrowernumber($anonymouspatron)->store;
2202         }
2203
2204         # And finally delete the issue
2205         $issue->delete;
2206
2207         ModItem( { 'onloan' => undef }, undef, $itemnumber, { log_action => 0 } );
2208
2209         if ( C4::Context->preference('StoreLastBorrower') ) {
2210             my $item = Koha::Items->find( $itemnumber );
2211             my $patron = Koha::Patrons->find( $borrowernumber );
2212             $item->last_returned_by( $patron );
2213         }
2214     });
2215
2216     return $issue_id;
2217 }
2218
2219 =head2 _debar_user_on_return
2220
2221     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2222
2223 C<$borrower> borrower hashref
2224
2225 C<$item> item hashref
2226
2227 C<$datedue> date due DateTime object
2228
2229 C<$returndate> DateTime object representing the return time
2230
2231 Internal function, called only by AddReturn that calculates and updates
2232  the user fine days, and debars them if necessary.
2233
2234 Should only be called for overdue returns
2235
2236 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2237 to ease testing.
2238
2239 =cut
2240
2241 sub _calculate_new_debar_dt {
2242     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2243
2244     my $branchcode = _GetCircControlBranch( $item, $borrower );
2245     my $circcontrol = C4::Context->preference('CircControl');
2246     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2247         {   categorycode => $borrower->{categorycode},
2248             itemtype     => $item->{itype},
2249             branchcode   => $branchcode
2250         }
2251     );
2252     my $finedays = $issuing_rule ? $issuing_rule->finedays : undef;
2253     my $unit     = $issuing_rule ? $issuing_rule->lengthunit : undef;
2254     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2255
2256     return unless $finedays;
2257
2258     # finedays is in days, so hourly loans must multiply by 24
2259     # thus 1 hour late equals 1 day suspension * finedays rate
2260     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2261
2262     # grace period is measured in the same units as the loan
2263     my $grace =
2264       DateTime::Duration->new( $unit => $issuing_rule->firstremind );
2265
2266     my $deltadays = DateTime::Duration->new(
2267         days => $chargeable_units
2268     );
2269     if ( $deltadays->subtract($grace)->is_positive() ) {
2270         my $suspension_days = $deltadays * $finedays;
2271
2272         # If the max suspension days is < than the suspension days
2273         # the suspension days is limited to this maximum period.
2274         my $max_sd = $issuing_rule->maxsuspensiondays;
2275         if ( defined $max_sd ) {
2276             $max_sd = DateTime::Duration->new( days => $max_sd );
2277             $suspension_days = $max_sd
2278               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2279         }
2280
2281         my ( $has_been_extended );
2282         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2283             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2284             if ( $debarment ) {
2285                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2286                 $has_been_extended = 1;
2287             }
2288         }
2289
2290         if ( $issuing_rule->suspension_chargeperiod > 1 ) {
2291             # No need to / 1 and do not consider / 0
2292             $suspension_days = DateTime::Duration->new(
2293                 days => floor( $suspension_days->in_units('days') / $issuing_rule->suspension_chargeperiod )
2294             );
2295         }
2296
2297         my $new_debar_dt;
2298         # Use the calendar or not to calculate the debarment date
2299         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2300             my $calendar = Koha::Calendar->new(
2301                 branchcode => $branchcode,
2302                 days_mode  => 'Calendar'
2303             );
2304             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2305         }
2306         else {
2307             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2308         }
2309         return $new_debar_dt;
2310     }
2311     return;
2312 }
2313
2314 sub _debar_user_on_return {
2315     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2316
2317     $return_date //= dt_from_string();
2318
2319     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2320
2321     return unless $new_debar_dt;
2322
2323     Koha::Patron::Debarments::AddUniqueDebarment({
2324         borrowernumber => $borrower->{borrowernumber},
2325         expiration     => $new_debar_dt->ymd(),
2326         type           => 'SUSPENSION',
2327     });
2328     # if borrower was already debarred but does not get an extra debarment
2329     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2330     my ($new_debarment_str, $is_a_reminder);
2331     if ( $borrower->{debarred} eq $patron->is_debarred ) {
2332         $is_a_reminder = 1;
2333         $new_debarment_str = $borrower->{debarred};
2334     } else {
2335         $new_debarment_str = $new_debar_dt->ymd();
2336     }
2337     # FIXME Should return a DateTime object
2338     return $new_debarment_str, $is_a_reminder;
2339 }
2340
2341 =head2 _FixOverduesOnReturn
2342
2343    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2344
2345 C<$borrowernumber> borrowernumber
2346
2347 C<$itemnumber> itemnumber
2348
2349 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2350
2351 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2352
2353 Internal function
2354
2355 =cut
2356
2357 sub _FixOverduesOnReturn {
2358     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2359     unless( $borrowernumber ) {
2360         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2361         return;
2362     }
2363     unless( $item ) {
2364         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2365         return;
2366     }
2367     unless( $status ) {
2368         warn "_FixOverduesOnReturn() not supplied valid status";
2369         return;
2370     }
2371
2372     my $schema = Koha::Database->schema;
2373
2374     my $result = $schema->txn_do(
2375         sub {
2376             # check for overdue fine
2377             my $accountlines = Koha::Account::Lines->search(
2378                 {
2379                     borrowernumber  => $borrowernumber,
2380                     itemnumber      => $item,
2381                     debit_type_code => 'OVERDUE',
2382                     status          => 'UNRETURNED'
2383                 }
2384             );
2385             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2386
2387             my $accountline = $accountlines->next;
2388             if ($exemptfine) {
2389                 my $amountoutstanding = $accountline->amountoutstanding;
2390
2391                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2392                 my $credit = $account->add_credit(
2393                     {
2394                         amount     => $amountoutstanding,
2395                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2396                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2397                         interface  => C4::Context->interface,
2398                         type       => 'FORGIVEN',
2399                         item_id    => $item
2400                     }
2401                 );
2402
2403                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2404
2405                 $accountline->status('FORGIVEN');
2406
2407                 if (C4::Context->preference("FinesLog")) {
2408                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2409                 }
2410             } else {
2411                 $accountline->status($status);
2412             }
2413
2414             return $accountline->store();
2415         }
2416     );
2417
2418     return $result;
2419 }
2420
2421 =head2 _FixAccountForLostAndReturned
2422
2423   &_FixAccountForLostAndReturned($itemnumber, [$borrowernumber, $barcode]);
2424
2425 Finds the most recent lost item charge for this item and refunds the borrower
2426 appropriatly, taking into account any payments or writeoffs already applied
2427 against the charge.
2428
2429 Internal function, not exported, called only by AddReturn.
2430
2431 =cut
2432
2433 sub _FixAccountForLostAndReturned {
2434     my $itemnumber     = shift or return;
2435     my $borrowernumber = @_ ? shift : undef;
2436     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2437
2438     my $credit;
2439
2440     # check for charge made for lost book
2441     my $accountlines = Koha::Account::Lines->search(
2442         {
2443             itemnumber      => $itemnumber,
2444             debit_type_code => 'LOST',
2445             status          => [ undef, { '<>' => 'RETURNED' } ]
2446         },
2447         {
2448             order_by => { -desc => [ 'date', 'accountlines_id' ] }
2449         }
2450     );
2451
2452     return unless $accountlines->count > 0;
2453     my $accountline     = $accountlines->next;
2454     my $total_to_refund = 0;
2455
2456     return unless $accountline->borrowernumber;
2457     my $patron = Koha::Patrons->find( $accountline->borrowernumber );
2458     return unless $patron; # Patron has been deleted, nobody to credit the return to
2459
2460     my $account = $patron->account;
2461
2462     # Use cases
2463     if ( $accountline->amount > $accountline->amountoutstanding ) {
2464         # some amount has been cancelled. collect the offsets that are not writeoffs
2465         # this works because the only way to subtract from this kind of a debt is
2466         # using the UI buttons 'Pay' and 'Write off'
2467         my $credits_offsets = Koha::Account::Offsets->search({
2468             debit_id  => $accountline->id,
2469             credit_id => { '!=' => undef }, # it is not the debit itself
2470             type      => { '!=' => 'Writeoff' },
2471             amount    => { '<'  => 0 } # credits are negative on the DB
2472         });
2473
2474         $total_to_refund = ( $credits_offsets->count > 0 )
2475                             ? $credits_offsets->total * -1 # credits are negative on the DB
2476                             : 0;
2477     }
2478
2479     my $credit_total = $accountline->amountoutstanding + $total_to_refund;
2480
2481     if ( $credit_total > 0 ) {
2482         my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
2483         $credit = $account->add_credit(
2484             {   amount      => $credit_total,
2485                 description => 'Item Returned ' . $item_id,
2486                 type        => 'LOST_RETURN',
2487                 interface   => C4::Context->interface,
2488                 library_id  => $branchcode
2489             }
2490         );
2491
2492         $credit->apply( { debits => [ $accountline ] } );
2493     }
2494
2495     # Update the account status
2496     $accountline->discard_changes->status('RETURNED');
2497     $accountline->store;
2498
2499     if ( defined $account and C4::Context->preference('AccountAutoReconcile') ) {
2500         $account->reconcile_balance;
2501     }
2502
2503     return ($credit) ? $credit->id : undef;
2504 }
2505
2506 =head2 _GetCircControlBranch
2507
2508    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2509
2510 Internal function :
2511
2512 Return the library code to be used to determine which circulation
2513 policy applies to a transaction.  Looks up the CircControl and
2514 HomeOrHoldingBranch system preferences.
2515
2516 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2517
2518 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2519
2520 =cut
2521
2522 sub _GetCircControlBranch {
2523     my ($item, $borrower) = @_;
2524     my $circcontrol = C4::Context->preference('CircControl');
2525     my $branch;
2526
2527     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2528         $branch= C4::Context->userenv->{'branch'};
2529     } elsif ($circcontrol eq 'PatronLibrary') {
2530         $branch=$borrower->{branchcode};
2531     } else {
2532         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2533         $branch = $item->{$branchfield};
2534         # default to item home branch if holdingbranch is used
2535         # and is not defined
2536         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2537             $branch = $item->{homebranch};
2538         }
2539     }
2540     return $branch;
2541 }
2542
2543 =head2 GetOpenIssue
2544
2545   $issue = GetOpenIssue( $itemnumber );
2546
2547 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2548
2549 C<$itemnumber> is the item's itemnumber
2550
2551 Returns a hashref
2552
2553 =cut
2554
2555 sub GetOpenIssue {
2556   my ( $itemnumber ) = @_;
2557   return unless $itemnumber;
2558   my $dbh = C4::Context->dbh;
2559   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2560   $sth->execute( $itemnumber );
2561   return $sth->fetchrow_hashref();
2562
2563 }
2564
2565 =head2 GetBiblioIssues
2566
2567   $issues = GetBiblioIssues($biblionumber);
2568
2569 this function get all issues from a biblionumber.
2570
2571 Return:
2572 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2573 tables issues and the firstname,surname & cardnumber from borrowers.
2574
2575 =cut
2576
2577 sub GetBiblioIssues {
2578     my $biblionumber = shift;
2579     return unless $biblionumber;
2580     my $dbh   = C4::Context->dbh;
2581     my $query = "
2582         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2583         FROM issues
2584             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2585             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2586             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2587             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2588         WHERE biblio.biblionumber = ?
2589         UNION ALL
2590         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2591         FROM old_issues
2592             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2593             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2594             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2595             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2596         WHERE biblio.biblionumber = ?
2597         ORDER BY timestamp
2598     ";
2599     my $sth = $dbh->prepare($query);
2600     $sth->execute($biblionumber, $biblionumber);
2601
2602     my @issues;
2603     while ( my $data = $sth->fetchrow_hashref ) {
2604         push @issues, $data;
2605     }
2606     return \@issues;
2607 }
2608
2609 =head2 GetUpcomingDueIssues
2610
2611   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2612
2613 =cut
2614
2615 sub GetUpcomingDueIssues {
2616     my $params = shift;
2617
2618     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2619     my $dbh = C4::Context->dbh;
2620
2621     my $statement = <<END_SQL;
2622 SELECT *
2623 FROM (
2624     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2625     FROM issues
2626     LEFT JOIN items USING (itemnumber)
2627     LEFT OUTER JOIN branches USING (branchcode)
2628     WHERE returndate is NULL
2629 ) tmp
2630 WHERE days_until_due >= 0 AND days_until_due <= ?
2631 END_SQL
2632
2633     my @bind_parameters = ( $params->{'days_in_advance'} );
2634
2635     my $sth = $dbh->prepare( $statement );
2636     $sth->execute( @bind_parameters );
2637     my $upcoming_dues = $sth->fetchall_arrayref({});
2638
2639     return $upcoming_dues;
2640 }
2641
2642 =head2 CanBookBeRenewed
2643
2644   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2645
2646 Find out whether a borrowed item may be renewed.
2647
2648 C<$borrowernumber> is the borrower number of the patron who currently
2649 has the item on loan.
2650
2651 C<$itemnumber> is the number of the item to renew.
2652
2653 C<$override_limit>, if supplied with a true value, causes
2654 the limit on the number of times that the loan can be renewed
2655 (as controlled by the item type) to be ignored. Overriding also allows
2656 to renew sooner than "No renewal before" and to manually renew loans
2657 that are automatically renewed.
2658
2659 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2660 item must currently be on loan to the specified borrower; renewals
2661 must be allowed for the item's type; and the borrower must not have
2662 already renewed the loan. $error will contain the reason the renewal can not proceed
2663
2664 =cut
2665
2666 sub CanBookBeRenewed {
2667     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2668
2669     my $dbh    = C4::Context->dbh;
2670     my $renews = 1;
2671
2672     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2673     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2674     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2675     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2676
2677     my $patron = $issue->patron or return;
2678
2679     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2680
2681     # This item can fill one or more unfilled reserve, can those unfilled reserves
2682     # all be filled by other available items?
2683     if ( $resfound
2684         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2685     {
2686         my $schema = Koha::Database->new()->schema();
2687
2688         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2689         if ($item_holds) {
2690             # There is an item level hold on this item, no other item can fill the hold
2691             $resfound = 1;
2692         }
2693         else {
2694
2695             # Get all other items that could possibly fill reserves
2696             my @itemnumbers = $schema->resultset('Item')->search(
2697                 {
2698                     biblionumber => $resrec->{biblionumber},
2699                     onloan       => undef,
2700                     notforloan   => 0,
2701                     -not         => { itemnumber => $itemnumber }
2702                 },
2703                 { columns => 'itemnumber' }
2704             )->get_column('itemnumber')->all();
2705
2706             # Get all other reserves that could have been filled by this item
2707             my @borrowernumbers;
2708             while (1) {
2709                 my ( $reserve_found, $reserve, undef ) =
2710                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2711
2712                 if ($reserve_found) {
2713                     push( @borrowernumbers, $reserve->{borrowernumber} );
2714                 }
2715                 else {
2716                     last;
2717                 }
2718             }
2719
2720             # If the count of the union of the lists of reservable items for each borrower
2721             # is equal or greater than the number of borrowers, we know that all reserves
2722             # can be filled with available items. We can get the union of the sets simply
2723             # by pushing all the elements onto an array and removing the duplicates.
2724             my @reservable;
2725             my %patrons;
2726             ITEM: foreach my $itemnumber (@itemnumbers) {
2727                 my $item = Koha::Items->find( $itemnumber );
2728                 next if IsItemOnHoldAndFound( $itemnumber );
2729                 for my $borrowernumber (@borrowernumbers) {
2730                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2731                     next unless IsAvailableForItemLevelRequest($item, $patron);
2732                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2733
2734                     push @reservable, $itemnumber;
2735                     if (@reservable >= @borrowernumbers) {
2736                         $resfound = 0;
2737                         last ITEM;
2738                     }
2739                     last;
2740                 }
2741             }
2742         }
2743     }
2744     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2745
2746     return ( 1, undef ) if $override_limit;
2747
2748     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2749     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2750         {   categorycode => $patron->categorycode,
2751             itemtype     => $item->effective_itemtype,
2752             branchcode   => $branchcode
2753         }
2754     );
2755
2756     return ( 0, "too_many" )
2757       if not $issuing_rule or $issuing_rule->renewalsallowed <= $issue->renewals;
2758
2759     my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2760     my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2761     $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2762     my $restricted  = $patron->is_debarred;
2763     my $hasoverdues = $patron->has_overdues;
2764
2765     if ( $restricted and $restrictionblockrenewing ) {
2766         return ( 0, 'restriction');
2767     } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2768         return ( 0, 'overdue');
2769     }
2770
2771     if ( $issue->auto_renew ) {
2772
2773         if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2774             return ( 0, 'auto_account_expired' );
2775         }
2776
2777         if ( defined $issuing_rule->no_auto_renewal_after
2778                 and $issuing_rule->no_auto_renewal_after ne "" ) {
2779             # Get issue_date and add no_auto_renewal_after
2780             # If this is greater than today, it's too late for renewal.
2781             my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2782             $maximum_renewal_date->add(
2783                 $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
2784             );
2785             my $now = dt_from_string;
2786             if ( $now >= $maximum_renewal_date ) {
2787                 return ( 0, "auto_too_late" );
2788             }
2789         }
2790         if ( defined $issuing_rule->no_auto_renewal_after_hard_limit
2791                       and $issuing_rule->no_auto_renewal_after_hard_limit ne "" ) {
2792             # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2793             if ( dt_from_string >= dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit ) ) {
2794                 return ( 0, "auto_too_late" );
2795             }
2796         }
2797
2798         if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2799             my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2800             my $amountoutstanding =
2801               C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2802               ? $patron->account->balance
2803               : $patron->account->outstanding_debits->total_outstanding;
2804             if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2805                 return ( 0, "auto_too_much_oweing" );
2806             }
2807         }
2808     }
2809
2810     if ( defined $issuing_rule->norenewalbefore
2811         and $issuing_rule->norenewalbefore ne "" )
2812     {
2813
2814         # Calculate soonest renewal by subtracting 'No renewal before' from due date
2815         my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2816             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
2817
2818         # Depending on syspref reset the exact time, only check the date
2819         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2820             and $issuing_rule->lengthunit eq 'days' )
2821         {
2822             $soonestrenewal->truncate( to => 'day' );
2823         }
2824
2825         if ( $soonestrenewal > DateTime->now( time_zone => C4::Context->tz() ) )
2826         {
2827             return ( 0, "auto_too_soon" ) if $issue->auto_renew;
2828             return ( 0, "too_soon" );
2829         }
2830         elsif ( $issue->auto_renew ) {
2831             return ( 0, "auto_renew" );
2832         }
2833     }
2834
2835     # Fallback for automatic renewals:
2836     # If norenewalbefore is undef, don't renew before due date.
2837     if ( $issue->auto_renew ) {
2838         my $now = dt_from_string;
2839         return ( 0, "auto_renew" )
2840           if $now >= dt_from_string( $issue->date_due, 'sql' );
2841         return ( 0, "auto_too_soon" );
2842     }
2843
2844     return ( 1, undef );
2845 }
2846
2847 =head2 AddRenewal
2848
2849   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2850
2851 Renews a loan.
2852
2853 C<$borrowernumber> is the borrower number of the patron who currently
2854 has the item.
2855
2856 C<$itemnumber> is the number of the item to renew.
2857
2858 C<$branch> is the library where the renewal took place (if any).
2859            The library that controls the circ policies for the renewal is retrieved from the issues record.
2860
2861 C<$datedue> can be a DateTime object used to set the due date.
2862
2863 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2864 this parameter is not supplied, lastreneweddate is set to the current date.
2865
2866 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2867 from the book's item type.
2868
2869 =cut
2870
2871 sub AddRenewal {
2872     my $borrowernumber  = shift;
2873     my $itemnumber      = shift or return;
2874     my $branch          = shift;
2875     my $datedue         = shift;
2876     my $lastreneweddate = shift || DateTime->now(time_zone => C4::Context->tz);
2877
2878     my $item_object   = Koha::Items->find($itemnumber) or return;
2879     my $biblio = $item_object->biblio;
2880     my $issue  = $item_object->checkout;
2881     my $item_unblessed = $item_object->unblessed;
2882
2883     my $dbh = C4::Context->dbh;
2884
2885     return unless $issue;
2886
2887     $borrowernumber ||= $issue->borrowernumber;
2888
2889     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2890         carp 'Invalid date passed to AddRenewal.';
2891         return;
2892     }
2893
2894     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2895     my $patron_unblessed = $patron->unblessed;
2896
2897     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
2898
2899     my $schema = Koha::Database->schema;
2900     $schema->txn_do(sub{
2901
2902         if ( C4::Context->preference('CalculateFinesOnReturn') ) {
2903             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2904         }
2905         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
2906
2907         # If the due date wasn't specified, calculate it by adding the
2908         # book's loan length to today's date or the current due date
2909         # based on the value of the RenewalPeriodBase syspref.
2910         my $itemtype = $item_object->effective_itemtype;
2911         unless ($datedue) {
2912
2913             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2914                                             dt_from_string( $issue->date_due, 'sql' ) :
2915                                             DateTime->now( time_zone => C4::Context->tz());
2916             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
2917         }
2918
2919         my $fees = Koha::Charges::Fees->new(
2920             {
2921                 patron    => $patron,
2922                 library   => $circ_library,
2923                 item      => $item_object,
2924                 from_date => dt_from_string( $issue->date_due, 'sql' ),
2925                 to_date   => dt_from_string($datedue),
2926             }
2927         );
2928
2929         # Update the issues record to have the new due date, and a new count
2930         # of how many times it has been renewed.
2931         my $renews = $issue->renewals + 1;
2932         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2933                                 WHERE borrowernumber=?
2934                                 AND itemnumber=?"
2935         );
2936
2937         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2938
2939         # Update the renewal count on the item, and tell zebra to reindex
2940         $renews = $item_object->renewals + 1;
2941         ModItem( { renewals => $renews, onloan => $datedue->strftime('%Y-%m-%d %H:%M')}, $item_object->biblionumber, $itemnumber, { log_action => 0 } );
2942
2943         # Charge a new rental fee, if applicable
2944         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
2945         if ( $charge > 0 ) {
2946             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
2947         }
2948
2949         # Charge a new accumulate rental fee, if applicable
2950         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
2951         if ( $itemtype_object ) {
2952             my $accumulate_charge = $fees->accumulate_rentalcharge();
2953             if ( $accumulate_charge > 0 ) {
2954                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
2955             }
2956             $charge += $accumulate_charge;
2957         }
2958
2959         # Send a renewal slip according to checkout alert preferencei
2960         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
2961             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2962             my %conditions        = (
2963                 branchcode   => $branch,
2964                 categorycode => $patron->categorycode,
2965                 item_type    => $itemtype,
2966                 notification => 'CHECKOUT',
2967             );
2968             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
2969                 SendCirculationAlert(
2970                     {
2971                         type     => 'RENEWAL',
2972                         item     => $item_unblessed,
2973                         borrower => $patron->unblessed,
2974                         branch   => $branch,
2975                     }
2976                 );
2977             }
2978         }
2979
2980         # Remove any OVERDUES related debarment if the borrower has no overdues
2981         if ( $patron
2982           && $patron->is_debarred
2983           && ! $patron->has_overdues
2984           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2985         ) {
2986             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2987         }
2988
2989         unless ( C4::Context->interface eq 'opac' ) { #if from opac we are obeying OpacRenewalBranch as calculated in opac-renew.pl
2990             $branch = C4::Context->userenv ? C4::Context->userenv->{branch} : $branch;
2991         }
2992
2993         # Add the renewal to stats
2994         UpdateStats(
2995             {
2996                 branch         => $branch,
2997                 type           => 'renew',
2998                 amount         => $charge,
2999                 itemnumber     => $itemnumber,
3000                 itemtype       => $itemtype,
3001                 location       => $item_object->location,
3002                 borrowernumber => $borrowernumber,
3003                 ccode          => $item_object->ccode,
3004             }
3005         );
3006
3007         #Log the renewal
3008         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3009     });
3010
3011     return $datedue;
3012 }
3013
3014 sub GetRenewCount {
3015     # check renewal status
3016     my ( $bornum, $itemno ) = @_;
3017     my $dbh           = C4::Context->dbh;
3018     my $renewcount    = 0;
3019     my $renewsallowed = 0;
3020     my $renewsleft    = 0;
3021
3022     my $patron = Koha::Patrons->find( $bornum );
3023     my $item   = Koha::Items->find($itemno);
3024
3025     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3026
3027     # Look in the issues table for this item, lent to this borrower,
3028     # and not yet returned.
3029
3030     # FIXME - I think this function could be redone to use only one SQL call.
3031     my $sth = $dbh->prepare(
3032         "select * from issues
3033                                 where (borrowernumber = ?)
3034                                 and (itemnumber = ?)"
3035     );
3036     $sth->execute( $bornum, $itemno );
3037     my $data = $sth->fetchrow_hashref;
3038     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3039     # $item and $borrower should be calculated
3040     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3041
3042     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3043         {   categorycode => $patron->categorycode,
3044             itemtype     => $item->effective_itemtype,
3045             branchcode   => $branchcode
3046         }
3047     );
3048
3049     $renewsallowed = $issuing_rule ? $issuing_rule->renewalsallowed : 0;
3050     $renewsleft    = $renewsallowed - $renewcount;
3051     if($renewsleft < 0){ $renewsleft = 0; }
3052     return ( $renewcount, $renewsallowed, $renewsleft );
3053 }
3054
3055 =head2 GetSoonestRenewDate
3056
3057   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3058
3059 Find out the soonest possible renew date of a borrowed item.
3060
3061 C<$borrowernumber> is the borrower number of the patron who currently
3062 has the item on loan.
3063
3064 C<$itemnumber> is the number of the item to renew.
3065
3066 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3067 renew date, based on the value "No renewal before" of the applicable
3068 issuing rule. Returns the current date if the item can already be
3069 renewed, and returns undefined if the borrower, loan, or item
3070 cannot be found.
3071
3072 =cut
3073
3074 sub GetSoonestRenewDate {
3075     my ( $borrowernumber, $itemnumber ) = @_;
3076
3077     my $dbh = C4::Context->dbh;
3078
3079     my $item      = Koha::Items->find($itemnumber)      or return;
3080     my $itemissue = $item->checkout or return;
3081
3082     $borrowernumber ||= $itemissue->borrowernumber;
3083     my $patron = Koha::Patrons->find( $borrowernumber )
3084       or return;
3085
3086     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3087     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3088         {   categorycode => $patron->categorycode,
3089             itemtype     => $item->effective_itemtype,
3090             branchcode   => $branchcode
3091         }
3092     );
3093
3094     my $now = dt_from_string;
3095     return $now unless $issuing_rule;
3096
3097     if ( defined $issuing_rule->norenewalbefore
3098         and $issuing_rule->norenewalbefore ne "" )
3099     {
3100         my $soonestrenewal =
3101           dt_from_string( $itemissue->date_due )->subtract(
3102             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
3103
3104         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3105             and $issuing_rule->lengthunit eq 'days' )
3106         {
3107             $soonestrenewal->truncate( to => 'day' );
3108         }
3109         return $soonestrenewal if $now < $soonestrenewal;
3110     }
3111     return $now;
3112 }
3113
3114 =head2 GetLatestAutoRenewDate
3115
3116   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3117
3118 Find out the latest possible auto renew date of a borrowed item.
3119
3120 C<$borrowernumber> is the borrower number of the patron who currently
3121 has the item on loan.
3122
3123 C<$itemnumber> is the number of the item to renew.
3124
3125 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3126 auto renew date, based on the value "No auto renewal after" and the "No auto
3127 renewal after (hard limit) of the applicable issuing rule.
3128 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3129 or item cannot be found.
3130
3131 =cut
3132
3133 sub GetLatestAutoRenewDate {
3134     my ( $borrowernumber, $itemnumber ) = @_;
3135
3136     my $dbh = C4::Context->dbh;
3137
3138     my $item      = Koha::Items->find($itemnumber)  or return;
3139     my $itemissue = $item->checkout                 or return;
3140
3141     $borrowernumber ||= $itemissue->borrowernumber;
3142     my $patron = Koha::Patrons->find( $borrowernumber )
3143       or return;
3144
3145     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3146     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3147         {   categorycode => $patron->categorycode,
3148             itemtype     => $item->effective_itemtype,
3149             branchcode   => $branchcode
3150         }
3151     );
3152
3153     return unless $issuing_rule;
3154     return
3155       if ( not $issuing_rule->no_auto_renewal_after
3156             or $issuing_rule->no_auto_renewal_after eq '' )
3157       and ( not $issuing_rule->no_auto_renewal_after_hard_limit
3158              or $issuing_rule->no_auto_renewal_after_hard_limit eq '' );
3159
3160     my $maximum_renewal_date;
3161     if ( $issuing_rule->no_auto_renewal_after ) {
3162         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3163         $maximum_renewal_date->add(
3164             $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
3165         );
3166     }
3167
3168     if ( $issuing_rule->no_auto_renewal_after_hard_limit ) {
3169         my $dt = dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit );
3170         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3171     }
3172     return $maximum_renewal_date;
3173 }
3174
3175
3176 =head2 GetIssuingCharges
3177
3178   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3179
3180 Calculate how much it would cost for a given patron to borrow a given
3181 item, including any applicable discounts.
3182
3183 C<$itemnumber> is the item number of item the patron wishes to borrow.
3184
3185 C<$borrowernumber> is the patron's borrower number.
3186
3187 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3188 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3189 if it's a video).
3190
3191 =cut
3192
3193 sub GetIssuingCharges {
3194
3195     # calculate charges due
3196     my ( $itemnumber, $borrowernumber ) = @_;
3197     my $charge = 0;
3198     my $dbh    = C4::Context->dbh;
3199     my $item_type;
3200
3201     # Get the book's item type and rental charge (via its biblioitem).
3202     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3203         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3204     $charge_query .= (C4::Context->preference('item-level_itypes'))
3205         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3206         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3207
3208     $charge_query .= ' WHERE items.itemnumber =?';
3209
3210     my $sth = $dbh->prepare($charge_query);
3211     $sth->execute($itemnumber);
3212     if ( my $item_data = $sth->fetchrow_hashref ) {
3213         $item_type = $item_data->{itemtype};
3214         $charge    = $item_data->{rentalcharge};
3215         my $branch = C4::Context::mybranch();
3216         my $discount_query = q|SELECT rentaldiscount,
3217             issuingrules.itemtype, issuingrules.branchcode
3218             FROM borrowers
3219             LEFT JOIN issuingrules ON borrowers.categorycode = issuingrules.categorycode
3220             WHERE borrowers.borrowernumber = ?
3221             AND (issuingrules.itemtype = ? OR issuingrules.itemtype = '*')
3222             AND (issuingrules.branchcode = ? OR issuingrules.branchcode = '*')|;
3223         my $discount_sth = $dbh->prepare($discount_query);
3224         $discount_sth->execute( $borrowernumber, $item_type, $branch );
3225         my $discount_rules = $discount_sth->fetchall_arrayref({});
3226         if (@{$discount_rules}) {
3227             # We may have multiple rules so get the most specific
3228             my $discount = _get_discount_from_rule($discount_rules, $branch, $item_type);
3229             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3230         }
3231         if ($charge) {
3232             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3233         }
3234     }
3235
3236     return ( $charge, $item_type );
3237 }
3238
3239 # Select most appropriate discount rule from those returned
3240 sub _get_discount_from_rule {
3241     my ($rules_ref, $branch, $itemtype) = @_;
3242     my $discount;
3243
3244     if (@{$rules_ref} == 1) { # only 1 applicable rule use it
3245         $discount = $rules_ref->[0]->{rentaldiscount};
3246         return (defined $discount) ? $discount : 0;
3247     }
3248     # could have up to 4 does one match $branch and $itemtype
3249     my @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq $itemtype } @{$rules_ref};
3250     if (@d) {
3251         $discount = $d[0]->{rentaldiscount};
3252         return (defined $discount) ? $discount : 0;
3253     }
3254     # do we have item type + all branches
3255     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq $itemtype } @{$rules_ref};
3256     if (@d) {
3257         $discount = $d[0]->{rentaldiscount};
3258         return (defined $discount) ? $discount : 0;
3259     }
3260     # do we all item types + this branch
3261     @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq q{*} } @{$rules_ref};
3262     if (@d) {
3263         $discount = $d[0]->{rentaldiscount};
3264         return (defined $discount) ? $discount : 0;
3265     }
3266     # so all and all (surely we wont get here)
3267     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq q{*} } @{$rules_ref};
3268     if (@d) {
3269         $discount = $d[0]->{rentaldiscount};
3270         return (defined $discount) ? $discount : 0;
3271     }
3272     # none of the above
3273     return 0;
3274 }
3275
3276 =head2 AddIssuingCharge
3277
3278   &AddIssuingCharge( $checkout, $charge, $type )
3279
3280 =cut
3281
3282 sub AddIssuingCharge {
3283     my ( $checkout, $charge, $type ) = @_;
3284
3285     # FIXME What if checkout does not exist?
3286
3287     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3288     my $accountline = $account->add_debit(
3289         {
3290             amount      => $charge,
3291             note        => undef,
3292             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3293             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3294             interface   => C4::Context->interface,
3295             type        => $type,
3296             item_id     => $checkout->itemnumber,
3297             issue_id    => $checkout->issue_id,
3298         }
3299     );
3300 }
3301
3302 =head2 GetTransfers
3303
3304   GetTransfers($itemnumber);
3305
3306 =cut
3307
3308 sub GetTransfers {
3309     my ($itemnumber) = @_;
3310
3311     my $dbh = C4::Context->dbh;
3312
3313     my $query = '
3314         SELECT datesent,
3315                frombranch,
3316                tobranch,
3317                branchtransfer_id
3318         FROM branchtransfers
3319         WHERE itemnumber = ?
3320           AND datearrived IS NULL
3321         ';
3322     my $sth = $dbh->prepare($query);
3323     $sth->execute($itemnumber);
3324     my @row = $sth->fetchrow_array();
3325     return @row;
3326 }
3327
3328 =head2 GetTransfersFromTo
3329
3330   @results = GetTransfersFromTo($frombranch,$tobranch);
3331
3332 Returns the list of pending transfers between $from and $to branch
3333
3334 =cut
3335
3336 sub GetTransfersFromTo {
3337     my ( $frombranch, $tobranch ) = @_;
3338     return unless ( $frombranch && $tobranch );
3339     my $dbh   = C4::Context->dbh;
3340     my $query = "
3341         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3342         FROM   branchtransfers
3343         WHERE  frombranch=?
3344           AND  tobranch=?
3345           AND datearrived IS NULL
3346     ";
3347     my $sth = $dbh->prepare($query);
3348     $sth->execute( $frombranch, $tobranch );
3349     my @gettransfers;
3350
3351     while ( my $data = $sth->fetchrow_hashref ) {
3352         push @gettransfers, $data;
3353     }
3354     return (@gettransfers);
3355 }
3356
3357 =head2 DeleteTransfer
3358
3359   &DeleteTransfer($itemnumber);
3360
3361 =cut
3362
3363 sub DeleteTransfer {
3364     my ($itemnumber) = @_;
3365     return unless $itemnumber;
3366     my $dbh          = C4::Context->dbh;
3367     my $sth          = $dbh->prepare(
3368         "DELETE FROM branchtransfers
3369          WHERE itemnumber=?
3370          AND datearrived IS NULL "
3371     );
3372     return $sth->execute($itemnumber);
3373 }
3374
3375 =head2 SendCirculationAlert
3376
3377 Send out a C<check-in> or C<checkout> alert using the messaging system.
3378
3379 B<Parameters>:
3380
3381 =over 4
3382
3383 =item type
3384
3385 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3386
3387 =item item
3388
3389 Hashref of information about the item being checked in or out.
3390
3391 =item borrower
3392
3393 Hashref of information about the borrower of the item.
3394
3395 =item branch
3396
3397 The branchcode from where the checkout or check-in took place.
3398
3399 =back
3400
3401 B<Example>:
3402
3403     SendCirculationAlert({
3404         type     => 'CHECKOUT',
3405         item     => $item,
3406         borrower => $borrower,
3407         branch   => $branch,
3408     });
3409
3410 =cut
3411
3412 sub SendCirculationAlert {
3413     my ($opts) = @_;
3414     my ($type, $item, $borrower, $branch) =
3415         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3416     my %message_name = (
3417         CHECKIN  => 'Item_Check_in',
3418         CHECKOUT => 'Item_Checkout',
3419         RENEWAL  => 'Item_Checkout',
3420     );
3421     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3422         borrowernumber => $borrower->{borrowernumber},
3423         message_name   => $message_name{$type},
3424     });
3425     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3426
3427     my $schema = Koha::Database->new->schema;
3428     my @transports = keys %{ $borrower_preferences->{transports} };
3429
3430     # From the MySQL doc:
3431     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3432     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3433     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3434     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_NO_TABLE_LOCKS};
3435
3436     for my $mtt (@transports) {
3437         my $letter =  C4::Letters::GetPreparedLetter (
3438             module => 'circulation',
3439             letter_code => $type,
3440             branchcode => $branch,
3441             message_transport_type => $mtt,
3442             lang => $borrower->{lang},
3443             tables => {
3444                 $issues_table => $item->{itemnumber},
3445                 'items'       => $item->{itemnumber},
3446                 'biblio'      => $item->{biblionumber},
3447                 'biblioitems' => $item->{biblionumber},
3448                 'borrowers'   => $borrower,
3449                 'branches'    => $branch,
3450             }
3451         ) or next;
3452
3453         $schema->storage->txn_begin;
3454         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3455         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3456         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3457         unless ( $message ) {
3458             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3459             C4::Message->enqueue($letter, $borrower, $mtt);
3460         } else {
3461             $message->append($letter);
3462             $message->update;
3463         }
3464         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3465         $schema->storage->txn_commit;
3466     }
3467
3468     return;
3469 }
3470
3471 =head2 updateWrongTransfer
3472
3473   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3474
3475 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3476
3477 =cut
3478
3479 sub updateWrongTransfer {
3480         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3481         my $dbh = C4::Context->dbh;
3482 # first step validate the actual line of transfert .
3483         my $sth =
3484                 $dbh->prepare(
3485                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3486                 );
3487                 $sth->execute($FromLibrary,$itemNumber);
3488
3489 # second step create a new line of branchtransfer to the right location .
3490         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3491
3492 #third step changing holdingbranch of item
3493         UpdateHoldingbranch($FromLibrary,$itemNumber);
3494 }
3495
3496 =head2 UpdateHoldingbranch
3497
3498   $items = UpdateHoldingbranch($branch,$itmenumber);
3499
3500 Simple methode for updating hodlingbranch in items BDD line
3501
3502 =cut
3503
3504 sub UpdateHoldingbranch {
3505         my ( $branch,$itemnumber ) = @_;
3506     ModItem({ holdingbranch => $branch }, undef, $itemnumber);
3507 }
3508
3509 =head2 CalcDateDue
3510
3511 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3512
3513 this function calculates the due date given the start date and configured circulation rules,
3514 checking against the holidays calendar as per the 'useDaysMode' syspref.
3515 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3516 C<$itemtype>  = itemtype code of item in question
3517 C<$branch>  = location whose calendar to use
3518 C<$borrower> = Borrower object
3519 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3520
3521 =cut
3522
3523 sub CalcDateDue {
3524     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3525
3526     $isrenewal ||= 0;
3527
3528     # loanlength now a href
3529     my $loanlength =
3530             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3531
3532     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3533             ? qq{renewalperiod}
3534             : qq{issuelength};
3535
3536     my $datedue;
3537     if ( $startdate ) {
3538         if (ref $startdate ne 'DateTime' ) {
3539             $datedue = dt_from_string($datedue);
3540         } else {
3541             $datedue = $startdate->clone;
3542         }
3543     } else {
3544         $datedue =
3545           DateTime->now( time_zone => C4::Context->tz() )
3546           ->truncate( to => 'minute' );
3547     }
3548
3549
3550     # calculate the datedue as normal
3551     if ( C4::Context->preference('useDaysMode') eq 'Days' )
3552     {    # ignoring calendar
3553         if ( $loanlength->{lengthunit} eq 'hours' ) {
3554             $datedue->add( hours => $loanlength->{$length_key} );
3555         } else {    # days
3556             $datedue->add( days => $loanlength->{$length_key} );
3557             $datedue->set_hour(23);
3558             $datedue->set_minute(59);
3559         }
3560     } else {
3561         my $dur;
3562         if ($loanlength->{lengthunit} eq 'hours') {
3563             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3564         }
3565         else { # days
3566             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3567         }
3568         my $calendar = Koha::Calendar->new( branchcode => $branch );
3569         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3570         if ($loanlength->{lengthunit} eq 'days') {
3571             $datedue->set_hour(23);
3572             $datedue->set_minute(59);
3573         }
3574     }
3575
3576     # if Hard Due Dates are used, retrieve them and apply as necessary
3577     my ( $hardduedate, $hardduedatecompare ) =
3578       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3579     if ($hardduedate) {    # hardduedates are currently dates
3580         $hardduedate->truncate( to => 'minute' );
3581         $hardduedate->set_hour(23);
3582         $hardduedate->set_minute(59);
3583         my $cmp = DateTime->compare( $hardduedate, $datedue );
3584
3585 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3586 # if the calculated date is before the 'after' Hard Due Date (floor), override
3587 # if the hard due date is set to 'exactly', overrride
3588         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3589             $datedue = $hardduedate->clone;
3590         }
3591
3592         # in all other cases, keep the date due as it is
3593
3594     }
3595
3596     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3597     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3598         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3599         if( $expiry_dt ) { #skip empty expiry date..
3600             $expiry_dt->set( hour => 23, minute => 59);
3601             my $d1= $datedue->clone->set_time_zone('floating');
3602             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3603                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3604             }
3605         }
3606         if ( C4::Context->preference('useDaysMode') ne 'Days' ) {
3607           my $calendar = Koha::Calendar->new( branchcode => $branch );
3608           if ( $calendar->is_holiday($datedue) ) {
3609               # Don't return on a closed day
3610               $datedue = $calendar->prev_open_days( $datedue, 1 );
3611           }
3612         }
3613     }
3614
3615     return $datedue;
3616 }
3617
3618
3619 sub CheckValidBarcode{
3620 my ($barcode) = @_;
3621 my $dbh = C4::Context->dbh;
3622 my $query=qq|SELECT count(*)
3623              FROM items
3624              WHERE barcode=?
3625             |;
3626 my $sth = $dbh->prepare($query);
3627 $sth->execute($barcode);
3628 my $exist=$sth->fetchrow ;
3629 return $exist;
3630 }
3631
3632 =head2 IsBranchTransferAllowed
3633
3634   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3635
3636 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3637
3638 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3639 Koha::Item->can_be_transferred.
3640
3641 =cut
3642
3643 sub IsBranchTransferAllowed {
3644         my ( $toBranch, $fromBranch, $code ) = @_;
3645
3646         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3647
3648         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3649         my $dbh = C4::Context->dbh;
3650
3651         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3652         $sth->execute( $toBranch, $fromBranch, $code );
3653         my $limit = $sth->fetchrow_hashref();
3654
3655         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3656         if ( $limit->{'limitId'} ) {
3657                 return 0;
3658         } else {
3659                 return 1;
3660         }
3661 }
3662
3663 =head2 CreateBranchTransferLimit
3664
3665   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3666
3667 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3668
3669 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3670
3671 =cut
3672
3673 sub CreateBranchTransferLimit {
3674    my ( $toBranch, $fromBranch, $code ) = @_;
3675    return unless defined($toBranch) && defined($fromBranch);
3676    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3677
3678    my $dbh = C4::Context->dbh;
3679
3680    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3681    return $sth->execute( $code, $toBranch, $fromBranch );
3682 }
3683
3684 =head2 DeleteBranchTransferLimits
3685
3686     my $result = DeleteBranchTransferLimits($frombranch);
3687
3688 Deletes all the library transfer limits for one library.  Returns the
3689 number of limits deleted, 0e0 if no limits were deleted, or undef if
3690 no arguments are supplied.
3691
3692 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3693     fromBranch => $fromBranch
3694     })->delete.
3695
3696 =cut
3697
3698 sub DeleteBranchTransferLimits {
3699     my $branch = shift;
3700     return unless defined $branch;
3701     my $dbh    = C4::Context->dbh;
3702     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3703     return $sth->execute($branch);
3704 }
3705
3706 sub ReturnLostItem{
3707     my ( $borrowernumber, $itemnum ) = @_;
3708     MarkIssueReturned( $borrowernumber, $itemnum );
3709 }
3710
3711
3712 sub LostItem{
3713     my ($itemnumber, $mark_lost_from, $force_mark_returned) = @_;
3714
3715     unless ( $mark_lost_from ) {
3716         # Temporary check to avoid regressions
3717         die q|LostItem called without $mark_lost_from, check the API.|;
3718     }
3719
3720     my $mark_returned;
3721     if ( $force_mark_returned ) {
3722         $mark_returned = 1;
3723     } else {
3724         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3725         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3726     }
3727
3728     my $dbh = C4::Context->dbh();
3729     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3730                            FROM issues
3731                            JOIN items USING (itemnumber)
3732                            JOIN biblio USING (biblionumber)
3733                            WHERE issues.itemnumber=?");
3734     $sth->execute($itemnumber);
3735     my $issues=$sth->fetchrow_hashref();
3736
3737     # If a borrower lost the item, add a replacement cost to the their record
3738     if ( my $borrowernumber = $issues->{borrowernumber} ){
3739         my $patron = Koha::Patrons->find( $borrowernumber );
3740
3741         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3742         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3743
3744         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3745             C4::Accounts::chargelostitem($borrowernumber, $itemnumber, $issues->{'replacementprice'}, "$issues->{'title'} $issues->{'barcode'} $issues->{'itemcallnumber'}");
3746             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3747             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3748         }
3749
3750         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3751     }
3752
3753     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3754     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3755         ModItem({holdingbranch => $frombranch}, undef, $itemnumber);
3756     }
3757     my $transferdeleted = DeleteTransfer($itemnumber);
3758 }
3759
3760 sub GetOfflineOperations {
3761     my $dbh = C4::Context->dbh;
3762     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3763     $sth->execute(C4::Context->userenv->{'branch'});
3764     my $results = $sth->fetchall_arrayref({});
3765     return $results;
3766 }
3767
3768 sub GetOfflineOperation {
3769     my $operationid = shift;
3770     return unless $operationid;
3771     my $dbh = C4::Context->dbh;
3772     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3773     $sth->execute( $operationid );
3774     return $sth->fetchrow_hashref;
3775 }
3776
3777 sub AddOfflineOperation {
3778     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3779     my $dbh = C4::Context->dbh;
3780     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3781     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3782     return "Added.";
3783 }
3784
3785 sub DeleteOfflineOperation {
3786     my $dbh = C4::Context->dbh;
3787     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3788     $sth->execute( shift );
3789     return "Deleted.";
3790 }
3791
3792 sub ProcessOfflineOperation {
3793     my $operation = shift;
3794
3795     my $report;
3796     if ( $operation->{action} eq 'return' ) {
3797         $report = ProcessOfflineReturn( $operation );
3798     } elsif ( $operation->{action} eq 'issue' ) {
3799         $report = ProcessOfflineIssue( $operation );
3800     } elsif ( $operation->{action} eq 'payment' ) {
3801         $report = ProcessOfflinePayment( $operation );
3802     }
3803
3804     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3805
3806     return $report;
3807 }
3808
3809 sub ProcessOfflineReturn {
3810     my $operation = shift;
3811
3812     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3813
3814     if ( $item ) {
3815         my $itemnumber = $item->itemnumber;
3816         my $issue = GetOpenIssue( $itemnumber );
3817         if ( $issue ) {
3818             MarkIssueReturned(
3819                 $issue->{borrowernumber},
3820                 $itemnumber,
3821                 $operation->{timestamp},
3822             );
3823             ModItem(
3824                 { renewals => 0, onloan => undef },
3825                 $issue->{'biblionumber'},
3826                 $itemnumber,
3827                 { log_action => 0 }
3828             );
3829             return "Success.";
3830         } else {
3831             return "Item not issued.";
3832         }
3833     } else {
3834         return "Item not found.";
3835     }
3836 }
3837
3838 sub ProcessOfflineIssue {
3839     my $operation = shift;
3840
3841     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3842
3843     if ( $patron ) {
3844         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3845         unless ($item) {
3846             return "Barcode not found.";
3847         }
3848         my $itemnumber = $item->itemnumber;
3849         my $issue = GetOpenIssue( $itemnumber );
3850
3851         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3852             MarkIssueReturned(
3853                 $issue->{borrowernumber},
3854                 $itemnumber,
3855                 $operation->{timestamp},
3856             );
3857         }
3858         AddIssue(
3859             $patron->unblessed,
3860             $operation->{'barcode'},
3861             undef,
3862             1,
3863             $operation->{timestamp},
3864             undef,
3865         );
3866         return "Success.";
3867     } else {
3868         return "Borrower not found.";
3869     }
3870 }
3871
3872 sub ProcessOfflinePayment {
3873     my $operation = shift;
3874
3875     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3876
3877     $patron->account->pay(
3878         {
3879             amount     => $operation->{amount},
3880             library_id => $operation->{branchcode},
3881             interface  => 'koc'
3882         }
3883     );
3884
3885     return "Success.";
3886 }
3887
3888 =head2 TransferSlip
3889
3890   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3891
3892   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3893
3894 =cut
3895
3896 sub TransferSlip {
3897     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3898
3899     my $item =
3900       $itemnumber
3901       ? Koha::Items->find($itemnumber)
3902       : Koha::Items->find( { barcode => $barcode } );
3903
3904     $item or return;
3905
3906     return C4::Letters::GetPreparedLetter (
3907         module => 'circulation',
3908         letter_code => 'TRANSFERSLIP',
3909         branchcode => $branch,
3910         tables => {
3911             'branches'    => $to_branch,
3912             'biblio'      => $item->biblionumber,
3913             'items'       => $item->unblessed,
3914         },
3915     );
3916 }
3917
3918 =head2 CheckIfIssuedToPatron
3919
3920   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3921
3922   Return 1 if any record item is issued to patron, otherwise return 0
3923
3924 =cut
3925
3926 sub CheckIfIssuedToPatron {
3927     my ($borrowernumber, $biblionumber) = @_;
3928
3929     my $dbh = C4::Context->dbh;
3930     my $query = q|
3931         SELECT COUNT(*) FROM issues
3932         LEFT JOIN items ON items.itemnumber = issues.itemnumber
3933         WHERE items.biblionumber = ?
3934         AND issues.borrowernumber = ?
3935     |;
3936     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
3937     return 1 if $is_issued;
3938     return;
3939 }
3940
3941 =head2 IsItemIssued
3942
3943   IsItemIssued( $itemnumber )
3944
3945   Return 1 if the item is on loan, otherwise return 0
3946
3947 =cut
3948
3949 sub IsItemIssued {
3950     my $itemnumber = shift;
3951     my $dbh = C4::Context->dbh;
3952     my $sth = $dbh->prepare(q{
3953         SELECT COUNT(*)
3954         FROM issues
3955         WHERE itemnumber = ?
3956     });
3957     $sth->execute($itemnumber);
3958     return $sth->fetchrow;
3959 }
3960
3961 =head2 GetAgeRestriction
3962
3963   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
3964   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
3965
3966   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
3967   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
3968
3969 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
3970 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
3971 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
3972          Negative days mean the borrower has gone past the age restriction age.
3973
3974 =cut
3975
3976 sub GetAgeRestriction {
3977     my ($record_restrictions, $borrower) = @_;
3978     my $markers = C4::Context->preference('AgeRestrictionMarker');
3979
3980     # Split $record_restrictions to something like FSK 16 or PEGI 6
3981     my @values = split ' ', uc($record_restrictions);
3982     return unless @values;
3983
3984     # Search first occurrence of one of the markers
3985     my @markers = split /\|/, uc($markers);
3986     return unless @markers;
3987
3988     my $index            = 0;
3989     my $restriction_year = 0;
3990     for my $value (@values) {
3991         $index++;
3992         for my $marker (@markers) {
3993             $marker =~ s/^\s+//;    #remove leading spaces
3994             $marker =~ s/\s+$//;    #remove trailing spaces
3995             if ( $marker eq $value ) {
3996                 if ( $index <= $#values ) {
3997                     $restriction_year += $values[$index];
3998                 }
3999                 last;
4000             }
4001             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4002
4003                 # Perhaps it is something like "K16" (as in Finland)
4004                 $restriction_year += $1;
4005                 last;
4006             }
4007         }
4008         last if ( $restriction_year > 0 );
4009     }
4010
4011     #Check if the borrower is age restricted for this material and for how long.
4012     if ($restriction_year && $borrower) {
4013         if ( $borrower->{'dateofbirth'} ) {
4014             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4015             $alloweddate[0] += $restriction_year;
4016
4017             #Prevent runime eror on leap year (invalid date)
4018             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4019                 $alloweddate[2] = 28;
4020             }
4021
4022             #Get how many days the borrower has to reach the age restriction
4023             my @Today = split /-/, DateTime->today->ymd();
4024             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4025             #Negative days means the borrower went past the age restriction age
4026             return ($restriction_year, $daysToAgeRestriction);
4027         }
4028     }
4029
4030     return ($restriction_year);
4031 }
4032
4033
4034 =head2 GetPendingOnSiteCheckouts
4035
4036 =cut
4037
4038 sub GetPendingOnSiteCheckouts {
4039     my $dbh = C4::Context->dbh;
4040     return $dbh->selectall_arrayref(q|
4041         SELECT
4042           items.barcode,
4043           items.biblionumber,
4044           items.itemnumber,
4045           items.itemnotes,
4046           items.itemcallnumber,
4047           items.location,
4048           issues.date_due,
4049           issues.branchcode,
4050           issues.date_due < NOW() AS is_overdue,
4051           biblio.author,
4052           biblio.title,
4053           borrowers.firstname,
4054           borrowers.surname,
4055           borrowers.cardnumber,
4056           borrowers.borrowernumber
4057         FROM items
4058         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4059         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4060         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4061         WHERE issues.onsite_checkout = 1
4062     |, { Slice => {} } );
4063 }
4064
4065 sub GetTopIssues {
4066     my ($params) = @_;
4067
4068     my ($count, $branch, $itemtype, $ccode, $newness)
4069         = @$params{qw(count branch itemtype ccode newness)};
4070
4071     my $dbh = C4::Context->dbh;
4072     my $query = q{
4073         SELECT * FROM (
4074         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4075           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4076           i.ccode, SUM(i.issues) AS count
4077         FROM biblio b
4078         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4079         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4080     };
4081
4082     my (@where_strs, @where_args);
4083
4084     if ($branch) {
4085         push @where_strs, 'i.homebranch = ?';
4086         push @where_args, $branch;
4087     }
4088     if ($itemtype) {
4089         if (C4::Context->preference('item-level_itypes')){
4090             push @where_strs, 'i.itype = ?';
4091             push @where_args, $itemtype;
4092         } else {
4093             push @where_strs, 'bi.itemtype = ?';
4094             push @where_args, $itemtype;
4095         }
4096     }
4097     if ($ccode) {
4098         push @where_strs, 'i.ccode = ?';
4099         push @where_args, $ccode;
4100     }
4101     if ($newness) {
4102         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4103         push @where_args, $newness;
4104     }
4105
4106     if (@where_strs) {
4107         $query .= 'WHERE ' . join(' AND ', @where_strs);
4108     }
4109
4110     $query .= q{
4111         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4112           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4113           i.ccode
4114         ORDER BY count DESC
4115     };
4116
4117     $query .= q{ ) xxx WHERE count > 0 };
4118     $count = int($count);
4119     if ($count > 0) {
4120         $query .= "LIMIT $count";
4121     }
4122
4123     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4124
4125     return @$rows;
4126 }
4127
4128 sub _CalculateAndUpdateFine {
4129     my ($params) = @_;
4130
4131     my $borrower    = $params->{borrower};
4132     my $item        = $params->{item};
4133     my $issue       = $params->{issue};
4134     my $return_date = $params->{return_date};
4135
4136     unless ($borrower) { carp "No borrower passed in!" && return; }
4137     unless ($item)     { carp "No item passed in!"     && return; }
4138     unless ($issue)    { carp "No issue passed in!"    && return; }
4139
4140     my $datedue = dt_from_string( $issue->date_due );
4141
4142     # we only need to calculate and change the fines if we want to do that on return
4143     # Should be on for hourly loans
4144     my $control = C4::Context->preference('CircControl');
4145     my $control_branchcode =
4146         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4147       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4148       :                                     $issue->branchcode;
4149
4150     my $date_returned = $return_date ? $return_date : dt_from_string();
4151
4152     my ( $amount, $unitcounttotal, $unitcount  ) =
4153       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4154
4155     if ( C4::Context->preference('finesMode') eq 'production' ) {
4156         if ( $amount > 0 ) {
4157             C4::Overdues::UpdateFine({
4158                 issue_id       => $issue->issue_id,
4159                 itemnumber     => $issue->itemnumber,
4160                 borrowernumber => $issue->borrowernumber,
4161                 amount         => $amount,
4162                 due            => output_pref($datedue),
4163             });
4164         }
4165         elsif ($return_date) {
4166
4167             # Backdated returns may have fines that shouldn't exist,
4168             # so in this case, we need to drop those fines to 0
4169
4170             C4::Overdues::UpdateFine({
4171                 issue_id       => $issue->issue_id,
4172                 itemnumber     => $issue->itemnumber,
4173                 borrowernumber => $issue->borrowernumber,
4174                 amount         => 0,
4175                 due            => output_pref($datedue),
4176             });
4177         }
4178     }
4179 }
4180
4181 sub _item_denied_renewal {
4182     my ($params) = @_;
4183
4184     my $item = $params->{item};
4185     return unless $item;
4186
4187     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4188     return unless $denyingrules;
4189     foreach my $field (keys %$denyingrules) {
4190         my $val = $item->$field;
4191         if( !defined $val) {
4192             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4193                 return 1;
4194             }
4195         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4196            # If the results matches the values in the syspref
4197            # We return true if match found
4198             return 1;
4199         }
4200     }
4201     return 0;
4202 }
4203
4204
4205 1;
4206
4207 __END__
4208
4209 =head1 AUTHOR
4210
4211 Koha Development Team <http://koha-community.org/>
4212
4213 =cut