C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Circulation qw( CheckIfIssuedToPatron GetAgeRestriction GetBranchItemRule );
  28 use C4::Context;
  29 use C4::Items qw( CartToShelf get_hostitemnumbers_of );
  30 use C4::Letters;
  31 use C4::Log qw( logaction );
  32 use C4::Members::Messaging;
  33 use C4::Members;
  34 use Koha::Account::Lines;
  35 use Koha::Biblios;
  36 use Koha::Calendar;
  37 use Koha::CirculationRules;
  38 use Koha::Database;
  39 use Koha::DateUtils qw( dt_from_string output_pref );
  40 use Koha::Hold;
  41 use Koha::Holds;
  42 use Koha::ItemTypes;
  43 use Koha::Items;
  44 use Koha::Libraries;
  45 use Koha::Old::Hold;
  46 use Koha::Patrons;
  47 use Koha::Plugins;
  48
  49 use List::MoreUtils qw( any );
  50
  51 =head1 NAME
  52
  53 C4::Reserves - Koha functions for dealing with reservation.
  54
  55 =head1 SYNOPSIS
  56
  57   use C4::Reserves;
  58
  59 =head1 DESCRIPTION
  60
  61 This modules provides somes functions to deal with reservations.
  62
  63   Reserves are stored in reserves table.
  64   The following columns contains important values :
  65   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  66              =0      : then the reserve is being dealed
  67   - found : NULL         : means the patron requested the 1st available, and we haven't chosen the item
  68             T(ransit)    : the reserve is linked to an item but is in transit to the pickup branch
  69             W(aiting)    : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  70             F(inished)   : the reserve has been completed, and is done
  71             P(rocessing) : reserved item has been returned using self-check machine and reserve needs to be confirmed
  72                            by librarian before notice is send and status changed to waiting.
  73                            Applicable only if HoldsNeedProcessingSIP system preference is set.
  74   - itemnumber : empty : the reserve is still unaffected to an item
  75                  filled: the reserve is attached to an item
  76   The complete workflow is :
  77   ==== 1st use case ====
  78   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  79   a library having it run "transfertodo", and clic on the list
  80          if there is no transfer to do, the reserve waiting
  81          patron can pick it up                                    P =0, F=W,    I=filled
  82          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  83            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  84   The patron borrow the book                                      P =0, F=F,    I=filled
  85
  86   ==== 2nd use case ====
  87   patron requests a document, a given item,
  88     If pickup is holding branch                                   P =0, F=W,   I=filled
  89     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  90         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  91   The patron borrow the book                                      P =0, F=F,    I=filled
  92
  93 =head1 FUNCTIONS
  94
  95 =cut
  96
  97 our (@ISA, @EXPORT_OK);
  98 BEGIN {
  99     require Exporter;
 100     @ISA = qw(Exporter);
 101     @EXPORT_OK = qw(
 102       AddReserve
 103
 104       GetReserveStatus
 105
 106       GetOtherReserves
 107       ChargeReserveFee
 108       GetReserveFee
 109
 110       ModReserveFill
 111       ModReserveAffect
 112       ModReserve
 113       ModReserveStatus
 114       ModReserveCancelAll
 115       ModReserveMinusPriority
 116       MoveReserve
 117
 118       CheckReserves
 119       CanBookBeReserved
 120       CanItemBeReserved
 121       CanReserveBeCanceledFromOpac
 122       CancelExpiredReserves
 123
 124       AutoUnsuspendReserves
 125
 126       IsAvailableForItemLevelRequest
 127       ItemsAnyAvailableAndNotRestricted
 128
 129       AlterPriority
 130       ToggleLowestPriority
 131
 132       ReserveSlip
 133       ToggleSuspend
 134       SuspendAll
 135
 136       GetReservesControlBranch
 137
 138       CalculatePriority
 139
 140       IsItemOnHoldAndFound
 141
 142       GetMaxPatronHoldsForRecord
 143
 144       MergeHolds
 145
 146       RevertWaitingStatus
 147     );
 148 }
 149
 150 =head2 AddReserve
 151
 152     AddReserve(
 153         {
 154             branchcode       => $branchcode,
 155             borrowernumber   => $borrowernumber,
 156             biblionumber     => $biblionumber,
 157             priority         => $priority,
 158             reservation_date => $reservation_date,
 159             expiration_date  => $expiration_date,
 160             notes            => $notes,
 161             title            => $title,
 162             itemnumber       => $itemnumber,
 163             found            => $found,
 164             itemtype         => $itemtype,
 165         }
 166     );
 167
 168 Adds reserve and generates HOLDPLACED message.
 169
 170 The following tables are available witin the HOLDPLACED message:
 171
 172     branches
 173     borrowers
 174     biblio
 175     biblioitems
 176     items
 177     reserves
 178
 179 =cut
 180
 181 sub AddReserve {
 182     my ($params)       = @_;
 183     my $branch         = $params->{branchcode};
 184     my $borrowernumber = $params->{borrowernumber};
 185     my $biblionumber   = $params->{biblionumber};
 186     my $priority       = $params->{priority};
 187     my $resdate        = $params->{reservation_date};
 188     my $expdate        = $params->{expiration_date};
 189     my $notes          = $params->{notes};
 190     my $title          = $params->{title};
 191     my $checkitem      = $params->{itemnumber};
 192     my $found          = $params->{found};
 193     my $itemtype       = $params->{itemtype};
 194     my $non_priority   = $params->{non_priority};
 195
 196     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 197         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 198
 199     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 200
 201     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 202     # of the document, we force the value $priority and $found .
 203     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 204         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 205
 206         if (
 207             # If item is already checked out, it cannot be set waiting
 208             !$item->onloan
 209
 210             # The item can't be waiting if it needs a transfer
 211             && $item->holdingbranch eq $branch
 212
 213             # Similarly, if in transit it can't be waiting
 214             && !$item->get_transfer
 215
 216             # If we can't hold damaged items, and it is damaged, it can't be waiting
 217             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 218
 219             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 220             && !$item->current_holds->count )
 221         {
 222             $priority = 0;
 223             $found = 'W';
 224         }
 225     }
 226
 227     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 228
 229         # Make room in reserves for this before those of a later reserve date
 230         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 231     }
 232
 233     my $waitingdate;
 234
 235     # If the reserv had the waiting status, we had the value of the resdate
 236     if ( $found && $found eq 'W' ) {
 237         $waitingdate = $resdate;
 238     }
 239
 240     # Don't add itemtype limit if specific item is selected
 241     $itemtype = undef if $checkitem;
 242
 243     # updates take place here
 244     my $hold = Koha::Hold->new(
 245         {
 246             borrowernumber => $borrowernumber,
 247             biblionumber   => $biblionumber,
 248             reservedate    => $resdate,
 249             branchcode     => $branch,
 250             priority       => $priority,
 251             reservenotes   => $notes,
 252             itemnumber     => $checkitem,
 253             found          => $found,
 254             waitingdate    => $waitingdate,
 255             expirationdate => $expdate,
 256             itemtype       => $itemtype,
 257             item_level_hold => $checkitem ? 1 : 0,
 258             non_priority   => $non_priority ? 1 : 0,
 259         }
 260     )->store();
 261     $hold->set_waiting() if $found && $found eq 'W';
 262
 263     logaction( 'HOLDS', 'CREATE', $hold->id, $hold )
 264         if C4::Context->preference('HoldsLog');
 265
 266     my $reserve_id = $hold->id();
 267
 268     # add a reserve fee if needed
 269     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 270         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 271         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 272     }
 273
 274     _FixPriority({ biblionumber => $biblionumber});
 275
 276     # Send e-mail to librarian if syspref is active
 277     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 278         my $patron = Koha::Patrons->find( $borrowernumber );
 279         my $library = $patron->library;
 280         if ( my $letter =  C4::Letters::GetPreparedLetter (
 281             module => 'reserves',
 282             letter_code => 'HOLDPLACED',
 283             branchcode => $branch,
 284             lang => $patron->lang,
 285             tables => {
 286                 'branches'    => $library->unblessed,
 287                 'borrowers'   => $patron->unblessed,
 288                 'biblio'      => $biblionumber,
 289                 'biblioitems' => $biblionumber,
 290                 'items'       => $checkitem,
 291                 'reserves'    => $hold->unblessed,
 292             },
 293         ) ) {
 294
 295             my $branch_email_address = $library->inbound_email_address;
 296
 297             C4::Letters::EnqueueLetter(
 298                 {
 299                     letter                 => $letter,
 300                     borrowernumber         => $borrowernumber,
 301                     message_transport_type => 'email',
 302                     to_address             => $branch_email_address,
 303                 }
 304             );
 305         }
 306     }
 307
 308     Koha::Plugins->call('after_hold_create', $hold);
 309
 310     return $reserve_id;
 311 }
 312
 313 =head2 CanBookBeReserved
 314
 315   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode, $params)
 316   if ($canReserve eq 'OK') { #We can reserve this Item! }
 317
 318   $params are passed directly through to CanItemBeReserved
 319
 320 See CanItemBeReserved() for possible return values.
 321
 322 =cut
 323
 324 sub CanBookBeReserved{
 325     my ($borrowernumber, $biblionumber, $pickup_branchcode, $params) = @_;
 326
 327     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 328     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 329         && C4::Circulation::CheckIfIssuedToPatron( $borrowernumber, $biblionumber ) ) {
 330         return { status =>'alreadypossession' };
 331     }
 332
 333     my @itemnumbers = Koha::Items->search({ biblionumber => $biblionumber})->get_column("itemnumber");
 334     #get items linked via host records
 335     my @hostitems = get_hostitemnumbers_of($biblionumber);
 336     if (@hostitems){
 337         push (@itemnumbers, @hostitems);
 338     }
 339
 340     my $canReserve = { status => '' };
 341     foreach my $itemnumber (@itemnumbers) {
 342         $canReserve = CanItemBeReserved( $borrowernumber, $itemnumber, $pickup_branchcode, $params );
 343         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 344     }
 345     return $canReserve;
 346 }
 347
 348 =head2 CanItemBeReserved
 349
 350   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber, $branchcode, $params)
 351   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 352
 353   current params are:
 354   'ignore_found_holds' - if true holds that have been trapped are not counted
 355   toward the patron limit, used by checkHighHolds to avoid counting the hold we will fill with the
 356   current checkout against the high holds threshold
 357   'ignore_hold_counts' - we use this routine to check if an item can fill a hold - on this case we
 358   should not check if there are too many holds as we only csre about reservability
 359
 360 @RETURNS { status => OK },              if the Item can be reserved.
 361          { status => ageRestricted },   if the Item is age restricted for this borrower.
 362          { status => damaged },         if the Item is damaged.
 363          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 364          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 365          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 366          { status => notReservable },   if holds on this item are not allowed
 367          { status => libraryNotFound },   if given branchcode is not an existing library
 368          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 369          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 370          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 371
 372 =cut
 373
 374 sub CanItemBeReserved {
 375     my ( $borrowernumber, $itemnumber, $pickup_branchcode, $params ) = @_;
 376
 377     my $dbh = C4::Context->dbh;
 378     my $ruleitemtype;    # itemtype of the matching issuing rule
 379     my $allowedreserves  = 0; # Total number of holds allowed across all records, default to none
 380
 381     # we retrieve borrowers and items informations #
 382     # item->{itype} will come for biblioitems if necessery
 383     my $item       = Koha::Items->find($itemnumber);
 384     my $biblio     = $item->biblio;
 385     my $patron = Koha::Patrons->find( $borrowernumber );
 386     my $borrower = $patron->unblessed;
 387
 388     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 389     return { status =>'damaged' }
 390       if ( $item->damaged
 391         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 392
 393     # Check for the age restriction
 394     my ( $ageRestriction, $daysToAgeRestriction ) =
 395       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 396     return { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 397
 398     # Check that the patron doesn't have an item level hold on this item already
 399     return { status =>'itemAlreadyOnHold' }
 400       if ( !$params->{ignore_hold_counts} && Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count() );
 401
 402     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 403     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 404         && C4::Circulation::CheckIfIssuedToPatron( $patron->borrowernumber, $biblio->biblionumber ) ) {
 405         return { status =>'alreadypossession' };
 406     }
 407
 408     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 409
 410     my $querycount = q{
 411         SELECT count(*) AS count
 412           FROM reserves
 413      LEFT JOIN items USING (itemnumber)
 414      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 415      LEFT JOIN borrowers USING (borrowernumber)
 416          WHERE borrowernumber = ?
 417     };
 418
 419     my $branchcode  = "";
 420     my $branchfield = "reserves.branchcode";
 421
 422     if ( $controlbranch eq "ItemHomeLibrary" ) {
 423         $branchfield = "items.homebranch";
 424         $branchcode  = $item->homebranch;
 425     }
 426     elsif ( $controlbranch eq "PatronLibrary" ) {
 427         $branchfield = "borrowers.branchcode";
 428         $branchcode  = $borrower->{branchcode};
 429     }
 430
 431     # we retrieve rights
 432     if (
 433         my $reservesallowed = Koha::CirculationRules->get_effective_rule({
 434                 itemtype     => $item->effective_itemtype,
 435                 categorycode => $borrower->{categorycode},
 436                 branchcode   => $branchcode,
 437                 rule_name    => 'reservesallowed',
 438         })
 439     ) {
 440         $ruleitemtype     = $reservesallowed->itemtype;
 441         $allowedreserves  = $reservesallowed->rule_value // 0; #undefined is 0, blank is unlimited
 442     }
 443     else {
 444         $ruleitemtype = undef;
 445     }
 446
 447     my $rights = Koha::CirculationRules->get_effective_rules({
 448         categorycode => $borrower->{'categorycode'},
 449         itemtype     => $item->effective_itemtype,
 450         branchcode   => $branchcode,
 451         rules        => ['holds_per_record','holds_per_day']
 452     });
 453     my $holds_per_record = $rights->{holds_per_record} // 1;
 454     my $holds_per_day    = $rights->{holds_per_day};
 455
 456     my $search_params = {
 457         borrowernumber => $borrowernumber,
 458         biblionumber   => $item->biblionumber,
 459     };
 460     $search_params->{found} = undef if $params->{ignore_found_holds};
 461
 462     my $holds = Koha::Holds->search($search_params);
 463     if (   defined $holds_per_record && $holds_per_record ne '' ){
 464         if ( $holds_per_record == 0 ) {
 465             return { status => "noReservesAllowed" };
 466         }
 467         if ( !$params->{ignore_hold_counts} && $holds->count() >= $holds_per_record ) {
 468             return { status => "tooManyHoldsForThisRecord", limit => $holds_per_record };
 469         }
 470     }
 471
 472     my $today_holds = Koha::Holds->search({
 473         borrowernumber => $borrowernumber,
 474         reservedate    => dt_from_string->date
 475     });
 476
 477     if (!$params->{ignore_hold_counts} && defined $holds_per_day && $holds_per_day ne ''
 478         && $today_holds->count() >= $holds_per_day )
 479     {
 480         return { status => 'tooManyReservesToday', limit => $holds_per_day };
 481     }
 482
 483     # we retrieve count
 484
 485     $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 486
 487     # If using item-level itypes, fall back to the record
 488     # level itemtype if the hold has no associated item
 489     $querycount .=
 490       C4::Context->preference('item-level_itypes')
 491       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 492       : " AND biblioitems.itemtype = ?"
 493       if defined $ruleitemtype;
 494
 495     my $sthcount = $dbh->prepare($querycount);
 496
 497     if ( defined $ruleitemtype ) {
 498         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 499     }
 500     else {
 501         $sthcount->execute( $borrowernumber, $branchcode );
 502     }
 503
 504     my $reservecount = "0";
 505     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 506         $reservecount = $rowcount->{count};
 507     }
 508
 509     # we check if it's ok or not
 510     if ( defined $allowedreserves && $allowedreserves ne '' ){
 511         if( $allowedreserves == 0 ){
 512             return { status => 'noReservesAllowed' };
 513         }
 514         if ( !$params->{ignore_hold_counts} && $reservecount >= $allowedreserves ) {
 515             return { status => 'tooManyReserves', limit => $allowedreserves };
 516         }
 517     }
 518
 519     # Now we need to check hold limits by patron category
 520     my $rule = Koha::CirculationRules->get_effective_rule(
 521         {
 522             categorycode => $borrower->{categorycode},
 523             branchcode   => $branchcode,
 524             rule_name    => 'max_holds',
 525         }
 526     );
 527     if (!$params->{ignore_hold_counts} && $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 528         my $total_holds_count = Koha::Holds->search(
 529             {
 530                 borrowernumber => $borrower->{borrowernumber}
 531             }
 532         )->count();
 533
 534         return { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 535     }
 536
 537     my $reserves_control_branch =
 538       GetReservesControlBranch( $item->unblessed(), $borrower );
 539     my $branchitemrule =
 540       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->effective_itemtype );
 541
 542     if ( $branchitemrule->{holdallowed} eq 'not_allowed' ) {
 543         return { status => 'notReservable' };
 544     }
 545
 546     if (   $branchitemrule->{holdallowed} eq 'from_home_library'
 547         && $borrower->{branchcode} ne $item->homebranch )
 548     {
 549         return { status => 'cannotReserveFromOtherBranches' };
 550     }
 551
 552     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 553     if ( $branchitemrule->{holdallowed} eq 'from_local_hold_group') {
 554         if($borrower->{branchcode} ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $borrower->{branchcode}} )) {
 555             return { status => 'branchNotInHoldGroup' };
 556         }
 557     }
 558
 559     # If reservecount is ok, we check item branch if IndependentBranches is ON
 560     # and canreservefromotherbranches is OFF
 561     if ( C4::Context->preference('IndependentBranches')
 562         and !C4::Context->preference('canreservefromotherbranches') )
 563     {
 564         if ( $item->homebranch ne $borrower->{branchcode} ) {
 565             return { status => 'cannotReserveFromOtherBranches' };
 566         }
 567     }
 568
 569     if ($pickup_branchcode) {
 570         my $destination = Koha::Libraries->find({
 571             branchcode => $pickup_branchcode,
 572         });
 573
 574         unless ($destination) {
 575             return { status => 'libraryNotFound' };
 576         }
 577         unless ($destination->pickup_location) {
 578             return { status => 'libraryNotPickupLocation' };
 579         }
 580         unless ($item->can_be_transferred({ to => $destination })) {
 581             return { status => 'cannotBeTransferred' };
 582         }
 583         if ($branchitemrule->{hold_fulfillment_policy} eq 'holdgroup' && !$item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 584             return { status => 'pickupNotInHoldGroup' };
 585         }
 586         if ($branchitemrule->{hold_fulfillment_policy} eq 'patrongroup' && !Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 587             return { status => 'pickupNotInHoldGroup' };
 588         }
 589     }
 590
 591     return { status => 'OK' };
 592 }
 593
 594 =head2 CanReserveBeCanceledFromOpac
 595
 596     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 597
 598     returns 1 if reserve can be cancelled by user from OPAC.
 599     First check if reserve belongs to user, next checks if reserve is not in
 600     transfer or waiting status
 601
 602 =cut
 603
 604 sub CanReserveBeCanceledFromOpac {
 605     my ($reserve_id, $borrowernumber) = @_;
 606
 607     return unless $reserve_id and $borrowernumber;
 608     my $reserve = Koha::Holds->find($reserve_id) or return;
 609
 610     return 0 unless $reserve->borrowernumber == $borrowernumber;
 611     return $reserve->is_cancelable_from_opac;
 612 }
 613
 614 =head2 GetOtherReserves
 615
 616   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 617
 618 Check queued list of this document and check if this document must be transferred
 619
 620 =cut
 621
 622 sub GetOtherReserves {
 623     my ($itemnumber) = @_;
 624     my $messages;
 625     my $nextreservinfo;
 626     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 627     if ($checkreserves) {
 628         my $item = Koha::Items->find($itemnumber);
 629         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 630             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 631             #minus priorities of others reservs
 632             ModReserveMinusPriority(
 633                 $itemnumber,
 634                 $checkreserves->{'reserve_id'},
 635             );
 636
 637             #launch the subroutine dotransfer
 638             C4::Items::ModItemTransfer(
 639                 $itemnumber,
 640                 $item->holdingbranch,
 641                 $checkreserves->{'branchcode'},
 642                 'Reserve'
 643               ),
 644               ;
 645         }
 646
 647      #step 2b : case of a reservation on the same branch, set the waiting status
 648         else {
 649             $messages->{'waiting'} = 1;
 650             ModReserveMinusPriority(
 651                 $itemnumber,
 652                 $checkreserves->{'reserve_id'},
 653             );
 654             ModReserveStatus($itemnumber,'W');
 655         }
 656
 657         $nextreservinfo = $checkreserves;
 658     }
 659
 660     return ( $messages, $nextreservinfo );
 661 }
 662
 663 =head2 ChargeReserveFee
 664
 665     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 666
 667     Charge the fee for a reserve (if $fee > 0)
 668
 669 =cut
 670
 671 sub ChargeReserveFee {
 672     my ( $borrowernumber, $fee, $title ) = @_;
 673     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 674     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 675         {
 676             amount       => $fee,
 677             description  => $title,
 678             note         => undef,
 679             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 680             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 681             interface    => C4::Context->interface,
 682             invoice_type => undef,
 683             type         => 'RESERVE',
 684             item_id      => undef
 685         }
 686     );
 687 }
 688
 689 =head2 GetReserveFee
 690
 691     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 692
 693     Calculate the fee for a reserve (if applicable).
 694
 695 =cut
 696
 697 sub GetReserveFee {
 698     my ( $borrowernumber, $biblionumber ) = @_;
 699     my $borquery = qq{
 700 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 701     };
 702     my $issue_qry = qq{
 703 SELECT COUNT(*) FROM items
 704 LEFT JOIN issues USING (itemnumber)
 705 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 706     };
 707     my $holds_qry = qq{
 708 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 709     };
 710
 711     my $dbh = C4::Context->dbh;
 712     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 713     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 714     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 715         # This is a reconstruction of the old code:
 716         # Compare number of items with items issued, and optionally check holds
 717         # If not all items are issued and there are no holds: charge no fee
 718         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 719         my ( $notissued, $reserved );
 720         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 721             ( $biblionumber ) );
 722         if( $notissued ) {
 723             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 724                 ( $biblionumber, $borrowernumber ) );
 725             $fee = 0 if $reserved == 0;
 726         }
 727     }
 728     return $fee;
 729 }
 730
 731 =head2 GetReserveStatus
 732
 733   $reservestatus = GetReserveStatus($itemnumber);
 734
 735 Takes an itemnumber and returns the status of the reserve placed on it.
 736 If several reserves exist, the reserve with the lower priority is given.
 737
 738 =cut
 739
 740 ## FIXME: I don't think this does what it thinks it does.
 741 ## It only ever checks the first reserve result, even though
 742 ## multiple reserves for that bib can have the itemnumber set
 743 ## the sub is only used once in the codebase.
 744 sub GetReserveStatus {
 745     my ($itemnumber) = @_;
 746
 747     my $dbh = C4::Context->dbh;
 748
 749     my ($sth, $found, $priority);
 750     if ( $itemnumber ) {
 751         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 752         $sth->execute($itemnumber);
 753         ($found, $priority) = $sth->fetchrow_array;
 754     }
 755
 756     if(defined $found) {
 757         return 'Waiting'  if $found eq 'W' and $priority == 0;
 758         return 'Processing'  if $found eq 'P';
 759         return 'Finished' if $found eq 'F';
 760     }
 761
 762     return 'Reserved' if defined $priority && $priority > 0;
 763
 764     return ''; # empty string here will remove need for checking undef, or less log lines
 765 }
 766
 767 =head2 CheckReserves
 768
 769   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber);
 770   ($status, $matched_reserve, $possible_reserves) = &CheckReserves(undef, $barcode);
 771   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 772
 773 Find a book in the reserves.
 774
 775 C<$itemnumber> is the book's item number.
 776 C<$lookahead> is the number of days to look in advance for future reserves.
 777
 778 As I understand it, C<&CheckReserves> looks for the given item in the
 779 reserves. If it is found, that's a match, and C<$status> is set to
 780 C<Waiting>.
 781
 782 Otherwise, it finds the most important item in the reserves with the
 783 same biblio number as this book (I'm not clear on this) and returns it
 784 with C<$status> set to C<Reserved>.
 785
 786 C<&CheckReserves> returns a two-element list:
 787
 788 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 789
 790 C<$reserve> is the reserve item that matched. It is a
 791 reference-to-hash whose keys are mostly the fields of the reserves
 792 table in the Koha database.
 793
 794 =cut
 795
 796 sub CheckReserves {
 797     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 798     my $dbh = C4::Context->dbh;
 799     my $sth;
 800     my $select;
 801     if (C4::Context->preference('item-level_itypes')){
 802         $select = "
 803            SELECT items.biblionumber,
 804            items.biblioitemnumber,
 805            itemtypes.notforloan,
 806            items.notforloan AS itemnotforloan,
 807            items.itemnumber,
 808            items.damaged,
 809            items.homebranch,
 810            items.holdingbranch
 811            FROM   items
 812            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 813            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 814         ";
 815     }
 816     else {
 817         $select = "
 818            SELECT items.biblionumber,
 819            items.biblioitemnumber,
 820            itemtypes.notforloan,
 821            items.notforloan AS itemnotforloan,
 822            items.itemnumber,
 823            items.damaged,
 824            items.homebranch,
 825            items.holdingbranch
 826            FROM   items
 827            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 828            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 829         ";
 830     }
 831
 832     if ($item) {
 833         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 834         $sth->execute($item);
 835     }
 836     else {
 837         $sth = $dbh->prepare("$select WHERE barcode = ?");
 838         $sth->execute($barcode);
 839     }
 840     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 841     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 842     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 843
 844     return unless $itemnumber; # bail if we got nothing.
 845     # if item is not for loan it cannot be reserved either.....
 846     # except where items.notforloan < 0 :  This indicates the item is holdable.
 847
 848     my @SkipHoldTrapOnNotForLoanValue = split( '\|', C4::Context->preference('SkipHoldTrapOnNotForLoanValue') );
 849     return if grep { $_ eq $notforloan_per_item } @SkipHoldTrapOnNotForLoanValue;
 850
 851     my $dont_trap = C4::Context->preference('TrapHoldsOnOrder') ? ($notforloan_per_item > 0) : ($notforloan_per_item && 1 );
 852     return if $dont_trap or $notforloan_per_itemtype;
 853
 854     # Find this item in the reserves
 855     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 856
 857     # $priority and $highest are used to find the most important item
 858     # in the list returned by &_Findgroupreserve. (The lower $priority,
 859     # the more important the item.)
 860     # $highest is the most important item we've seen so far.
 861     my $highest;
 862
 863     if (scalar @reserves) {
 864         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 865         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 866         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 867
 868         my $priority = 10000000;
 869         foreach my $res (@reserves) {
 870             if ($res->{'found'} && $res->{'found'} eq 'W') {
 871                 return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 872             } elsif ($res->{'found'} && $res->{'found'} eq 'P') {
 873                 return ( "Processing", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 874             } elsif ($res->{'found'} && $res->{'found'} eq 'T') {
 875                 return ( "Transferred", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 876             } else {
 877                 my $patron;
 878                 my $item;
 879                 my $local_hold_match;
 880
 881                 if ($LocalHoldsPriority) {
 882                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 883                     $item = Koha::Items->find($itemnumber);
 884
 885                     unless ($item->exclude_from_local_holds_priority || $patron->category->exclude_from_local_holds_priority) {
 886                         my $local_holds_priority_item_branchcode =
 887                             $item->$LocalHoldsPriorityItemControl;
 888                         my $local_holds_priority_patron_branchcode =
 889                             ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 890                             ? $res->{branchcode}
 891                             : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 892                             ? $patron->branchcode
 893                             : undef;
 894                         $local_hold_match =
 895                             $local_holds_priority_item_branchcode eq
 896                             $local_holds_priority_patron_branchcode;
 897                     }
 898                 }
 899
 900                 # See if this item is more important than what we've got so far
 901                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 902                     $item ||= Koha::Items->find($itemnumber);
 903                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 904                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 905                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 906                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 907                     next if ($branchitemrule->{'holdallowed'} eq 'not_allowed');
 908                     next if (($branchitemrule->{'holdallowed'} eq 'from_home_library') && ($item->homebranch ne $patron->branchcode));
 909                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 910                     next if (($branchitemrule->{'holdallowed'} eq 'from_local_hold_group') && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 911                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 912                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 913                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 914                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 915                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 916                     $priority = $res->{'priority'};
 917                     $highest  = $res;
 918                     last if $local_hold_match;
 919                 }
 920             }
 921         }
 922     }
 923
 924     # If we get this far, then no exact match was found.
 925     # We return the most important (i.e. next) reservation.
 926     if ($highest) {
 927         $highest->{'itemnumber'} = $item;
 928         return ( "Reserved", $highest, \@reserves );
 929     }
 930
 931     return ( '' );
 932 }
 933
 934 =head2 CancelExpiredReserves
 935
 936   CancelExpiredReserves();
 937
 938 Cancels all reserves with an expiration date from before today.
 939
 940 =cut
 941
 942 sub CancelExpiredReserves {
 943     my $cancellation_reason = shift;
 944     my $today = dt_from_string();
 945     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 946     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 947
 948     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 949     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 950     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 951
 952     # FIXME To move to Koha::Holds->search_expired (?)
 953     my $holds = Koha::Holds->search( $params );
 954
 955     while ( my $hold = $holds->next ) {
 956         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 957
 958         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 959
 960         my $cancel_params = {};
 961         $cancel_params->{cancellation_reason} = $cancellation_reason if defined($cancellation_reason);
 962         if ( defined($hold->found) && $hold->found eq 'W' ) {
 963             $cancel_params->{charge_cancel_fee} = 1;
 964         }
 965         $hold->cancel( $cancel_params );
 966     }
 967 }
 968
 969 =head2 AutoUnsuspendReserves
 970
 971   AutoUnsuspendReserves();
 972
 973 Unsuspends all suspended reserves with a suspend_until date from before today.
 974
 975 =cut
 976
 977 sub AutoUnsuspendReserves {
 978     my $today = dt_from_string();
 979
 980     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } );
 981
 982     map { $_->resume() } @holds;
 983 }
 984
 985 =head2 ModReserve
 986
 987   ModReserve({ rank => $rank,
 988                reserve_id => $reserve_id,
 989                branchcode => $branchcode
 990                [, itemnumber => $itemnumber ]
 991                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 992               });
 993
 994 Change a hold request's priority or cancel it.
 995
 996 C<$rank> specifies the effect of the change.  If C<$rank>
 997 is 'n', nothing happens.  This corresponds to leaving a
 998 request alone when changing its priority in the holds queue
 999 for a bib.
1000
1001 If C<$rank> is 'del', the hold request is cancelled.
1002
1003 If C<$rank> is an integer greater than zero, the priority of
1004 the request is set to that value.  Since priority != 0 means
1005 that the item is not waiting on the hold shelf, setting the
1006 priority to a non-zero value also sets the request's found
1007 status and waiting date to NULL.
1008
1009 If the hold is 'found' (waiting, in-transit, processing) the
1010 only field that can be updated is the expiration date.
1011
1012 The optional C<$itemnumber> parameter is used only when
1013 C<$rank> is a non-zero integer; if supplied, the itemnumber
1014 of the hold request is set accordingly; if omitted, the itemnumber
1015 is cleared.
1016
1017 B<FIXME:> Note that the forgoing can have the effect of causing
1018 item-level hold requests to turn into title-level requests.  This
1019 will be fixed once reserves has separate columns for requested
1020 itemnumber and supplying itemnumber.
1021
1022 =cut
1023
1024 sub ModReserve {
1025     my ( $params ) = @_;
1026
1027     my $rank = $params->{'rank'};
1028     my $reserve_id = $params->{'reserve_id'};
1029     my $branchcode = $params->{'branchcode'};
1030     my $itemnumber = $params->{'itemnumber'};
1031     my $suspend_until = $params->{'suspend_until'};
1032     my $borrowernumber = $params->{'borrowernumber'};
1033     my $biblionumber = $params->{'biblionumber'};
1034     my $cancellation_reason = $params->{'cancellation_reason'};
1035     my $date = $params->{expirationdate};
1036
1037     return if defined $rank && $rank eq "n";
1038
1039     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
1040
1041     my $hold;
1042     unless ( $reserve_id ) {
1043         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
1044         return unless $holds->count; # FIXME Should raise an exception
1045         $hold = $holds->next;
1046         $reserve_id = $hold->reserve_id;
1047     }
1048
1049     $hold ||= Koha::Holds->find($reserve_id);
1050
1051     # FIXME Other calls may fail
1052     Koha::Exceptions::ObjectNotFound->throw( 'No hold with id ' . $reserve_id ) unless $hold;
1053
1054     if ( $rank eq "del" ) {
1055         $hold->cancel({ cancellation_reason => $cancellation_reason });
1056     }
1057     elsif ($hold->found && $hold->priority eq '0' && $date) {
1058         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold )
1059             if C4::Context->preference('HoldsLog');
1060
1061         # The only column that can be updated for a found hold is the expiration date
1062         $hold->expirationdate(dt_from_string($date))->store();
1063     }
1064     elsif ($rank =~ /^\d+/ and $rank > 0) {
1065         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold )
1066             if C4::Context->preference('HoldsLog');
1067
1068         my $properties = {
1069             priority    => $rank,
1070             branchcode  => $branchcode,
1071             itemnumber  => $itemnumber,
1072             found       => undef,
1073             waitingdate => undef
1074         };
1075         if (exists $params->{reservedate}) {
1076             $properties->{reservedate} = $params->{reservedate} || undef;
1077         }
1078         if (exists $params->{expirationdate}) {
1079             $properties->{expirationdate} = $params->{expirationdate} || undef;
1080         }
1081
1082         $hold->set($properties)->store();
1083
1084         if ( defined( $suspend_until ) ) {
1085             if ( $suspend_until ) {
1086                 $suspend_until = eval { dt_from_string( $suspend_until ) };
1087                 $hold->suspend_hold( $suspend_until );
1088             } else {
1089                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1090                 # If the hold is not suspended, this does nothing.
1091                 $hold->set( { suspend_until => undef } )->store();
1092             }
1093         }
1094
1095         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
1096     }
1097 }
1098
1099 =head2 ModReserveFill
1100
1101   &ModReserveFill($reserve);
1102
1103 Fill a reserve. If I understand this correctly, this means that the
1104 reserved book has been found and given to the patron who reserved it.
1105
1106 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
1107 whose keys are fields from the reserves table in the Koha database.
1108
1109 =cut
1110
1111 sub ModReserveFill {
1112     my ($res) = @_;
1113     my $reserve_id = $res->{'reserve_id'};
1114
1115     my $hold = Koha::Holds->find($reserve_id);
1116     # get the priority on this record....
1117     my $priority = $hold->priority;
1118
1119     # update the hold statuses, no need to store it though, we will be deleting it anyway
1120     $hold->set(
1121         {
1122             found    => 'F',
1123             priority => 0,
1124         }
1125     );
1126
1127     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold )
1128         if C4::Context->preference('HoldsLog');
1129
1130     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
1131     my $old_hold = Koha::Old::Hold->new( $hold->unblessed() )->store();
1132
1133     Koha::Plugins->call(
1134         'after_hold_action',
1135         {
1136             action  => 'fill',
1137             payload => { hold => $old_hold->get_from_storage }
1138         }
1139     );
1140
1141     $hold->delete();
1142
1143     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
1144         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
1145         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
1146     }
1147
1148     # now fix the priority on the others (if the priority wasn't
1149     # already sorted!)....
1150     unless ( $priority == 0 ) {
1151         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
1152     }
1153 }
1154
1155 =head2 ModReserveStatus
1156
1157   &ModReserveStatus($itemnumber, $newstatus);
1158
1159 Update the reserve status for the active (priority=0) reserve.
1160
1161 $itemnumber is the itemnumber the reserve is on
1162
1163 $newstatus is the new status.
1164
1165 =cut
1166
1167 sub ModReserveStatus {
1168
1169     #first : check if we have a reservation for this item .
1170     my ($itemnumber, $newstatus) = @_;
1171     my $dbh = C4::Context->dbh;
1172
1173     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1174     my $sth_set = $dbh->prepare($query);
1175     $sth_set->execute( $newstatus, $itemnumber );
1176
1177     my $item = Koha::Items->find($itemnumber);
1178     if ( $item->location && $item->location eq 'CART'
1179         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1180         && $newstatus ) {
1181       CartToShelf( $itemnumber );
1182     }
1183 }
1184
1185 =head2 ModReserveAffect
1186
1187   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id, $desk_id);
1188
1189 This function affect an item and a status for a given reserve, either fetched directly
1190 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1191 is given, only first reserve returned is affected, which is ok for anything but
1192 multi-item holds.
1193
1194 if $transferToDo is not set, then the status is set to "Waiting" as well.
1195 otherwise, a transfer is on the way, and the end of the transfer will
1196 take care of the waiting status
1197
1198 This function also removes any entry of the hold in holds queue table.
1199
1200 =cut
1201
1202 sub ModReserveAffect {
1203     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id, $desk_id ) = @_;
1204     my $dbh = C4::Context->dbh;
1205
1206     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1207     # attached to $itemnumber
1208     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1209     $sth->execute($itemnumber);
1210     my ($biblionumber) = $sth->fetchrow;
1211
1212     # get request - need to find out if item is already
1213     # waiting in order to not send duplicate hold filled notifications
1214
1215     my $hold;
1216     # Find hold by id if we have it
1217     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1218     # Find item level hold for this item if there is one
1219     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1220     # Find record level hold if there is no item level hold
1221     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1222
1223     return unless $hold;
1224
1225     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1226
1227     $hold->itemnumber($itemnumber);
1228
1229     if ($transferToDo) {
1230         $hold->set_transfer();
1231     } elsif (C4::Context->preference('HoldsNeedProcessingSIP')
1232              && C4::Context->interface eq 'sip'
1233              && !$already_on_shelf) {
1234         $hold->set_processing();
1235     } else {
1236         $hold->set_waiting($desk_id);
1237         _koha_notify_reserve( $hold->reserve_id ) unless $already_on_shelf;
1238         # Complete transfer if one exists
1239         my $transfer = $hold->item->get_transfer;
1240         $transfer->receive if $transfer;
1241     }
1242
1243     _FixPriority( { biblionumber => $biblionumber } );
1244     my $item = Koha::Items->find($itemnumber);
1245     if ( $item->location && $item->location eq 'CART'
1246         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1247       CartToShelf( $itemnumber );
1248     }
1249
1250     my $std = $dbh->prepare(q{
1251         DELETE  q, t
1252         FROM    tmp_holdsqueue q
1253         INNER JOIN hold_fill_targets t
1254         ON  q.borrowernumber = t.borrowernumber
1255             AND q.biblionumber = t.biblionumber
1256             AND q.itemnumber = t.itemnumber
1257             AND q.item_level_request = t.item_level_request
1258             AND q.holdingbranch = t.source_branchcode
1259         WHERE t.reserve_id = ?
1260     });
1261     $std->execute($hold->reserve_id);
1262
1263     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, $hold )
1264         if C4::Context->preference('HoldsLog');
1265
1266     return;
1267 }
1268
1269 =head2 ModReserveCancelAll
1270
1271   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber,$reason);
1272
1273 function to cancel reserv,check other reserves, and transfer document if it's necessary
1274
1275 =cut
1276
1277 sub ModReserveCancelAll {
1278     my $messages;
1279     my $nextreservinfo;
1280     my ( $itemnumber, $borrowernumber, $cancellation_reason ) = @_;
1281
1282     #step 1 : cancel the reservation
1283     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1284     return unless $holds->count;
1285     $holds->next->cancel({ cancellation_reason => $cancellation_reason });
1286
1287     #step 2 launch the subroutine of the others reserves
1288     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1289
1290     return ( $messages, $nextreservinfo->{borrowernumber} );
1291 }
1292
1293 =head2 ModReserveMinusPriority
1294
1295   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1296
1297 Reduce the values of queued list
1298
1299 =cut
1300
1301 sub ModReserveMinusPriority {
1302     my ( $itemnumber, $reserve_id ) = @_;
1303
1304     #first step update the value of the first person on reserv
1305     my $dbh   = C4::Context->dbh;
1306     my $query = "
1307         UPDATE reserves
1308         SET    priority = 0 , itemnumber = ?
1309         WHERE  reserve_id = ?
1310     ";
1311     my $sth_upd = $dbh->prepare($query);
1312     $sth_upd->execute( $itemnumber, $reserve_id );
1313     # second step update all others reserves
1314     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1315 }
1316
1317 =head2 IsAvailableForItemLevelRequest
1318
1319   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1320
1321 Checks whether a given item record is available for an
1322 item-level hold request.  An item is available if
1323
1324 * it is not lost AND
1325 * it is not damaged AND
1326 * it is not withdrawn AND
1327 * a waiting or in transit reserve is placed on
1328 * does not have a not for loan value > 0
1329
1330 Need to check the issuingrules onshelfholds column,
1331 if this is set items on the shelf can be placed on hold
1332
1333 Note that IsAvailableForItemLevelRequest() does not
1334 check if the staff operator is authorized to place
1335 a request on the item - in particular,
1336 this routine does not check IndependentBranches
1337 and canreservefromotherbranches.
1338
1339 Note also that this subroutine does not checks smart
1340 rules limits for item by reservesallowed/holds_per_record
1341 values, this complemented in calling code with calls and
1342 checks with CanItemBeReserved or CanBookBeReserved.
1343
1344 =cut
1345
1346 sub IsAvailableForItemLevelRequest {
1347     my $item                = shift;
1348     my $patron              = shift;
1349     my $pickup_branchcode   = shift;
1350     # items_any_available is precalculated status passed from request.pl when set of items
1351     # looped outside of IsAvailableForItemLevelRequest to avoid nested loops:
1352     my $items_any_available = shift;
1353
1354     my $dbh = C4::Context->dbh;
1355     # must check the notforloan setting of the itemtype
1356     # FIXME - a lot of places in the code do this
1357     #         or something similar - need to be
1358     #         consolidated
1359     my $itemtype = $item->effective_itemtype;
1360     return 0
1361       unless defined $itemtype;
1362     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1363
1364     return 0 if
1365         $notforloan_per_itemtype ||
1366         $item->itemlost        ||
1367         $item->notforloan > 0  || # item with negative or zero notforloan value is holdable
1368         $item->withdrawn        ||
1369         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1370
1371     if ($pickup_branchcode) {
1372         my $destination = Koha::Libraries->find($pickup_branchcode);
1373         return 0 unless $destination;
1374         return 0 unless $destination->pickup_location;
1375         return 0 unless $item->can_be_transferred( { to => $destination } );
1376         my $reserves_control_branch =
1377             GetReservesControlBranch( $item->unblessed(), $patron->unblessed() );
1378         my $branchitemrule =
1379             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1380         my $home_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
1381         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1382     }
1383
1384     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1385
1386     if ( $on_shelf_holds == 1 ) {
1387         return 1;
1388     } elsif ( $on_shelf_holds == 2 ) {
1389
1390         # if we have this param predefined from outer caller sub, we just need
1391         # to return it, so we saving from having loop inside other loop:
1392         return  $items_any_available ? 0 : 1
1393             if defined $items_any_available;
1394
1395         my $any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
1396         return $any_available ? 0 : 1;
1397     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1398         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1399     }
1400 }
1401
1402 =head2 ItemsAnyAvailableAndNotRestricted
1403
1404   ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblionumber, patron => $patron });
1405
1406 This function checks all items for specified biblionumber (numeric) against patron (object)
1407 and returns true (1) if at least one item available for loan/check out/present/not held
1408 and also checks other parameters logic which not restricts item for hold at all (for ex.
1409 AllowHoldsOnDamagedItems or 'holdallowed' own/sibling library)
1410
1411 =cut
1412
1413 sub ItemsAnyAvailableAndNotRestricted {
1414     my $param = shift;
1415
1416     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } );
1417
1418     foreach my $i (@items) {
1419         my $reserves_control_branch =
1420             GetReservesControlBranch( $i->unblessed(), $param->{patron}->unblessed );
1421         my $branchitemrule =
1422             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1423         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1424
1425         # we can return (end the loop) when first one found:
1426         return 1
1427             unless $i->itemlost
1428             || $i->notforloan # items with non-zero notforloan cannot be checked out
1429             || $i->withdrawn
1430             || $i->onloan
1431             || IsItemOnHoldAndFound( $i->id )
1432             || ( $i->damaged
1433                  && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1434             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1435             || $branchitemrule->{holdallowed} eq 'from_home_library' && $param->{patron}->branchcode ne $i->homebranch
1436             || $branchitemrule->{holdallowed} eq 'from_local_hold_group' && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } )
1437             || CanItemBeReserved( $param->{patron}->borrowernumber, $i->id )->{status} ne 'OK';
1438     }
1439
1440     return 0;
1441 }
1442
1443 =head2 AlterPriority
1444
1445   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1446
1447 This function changes a reserve's priority up, down, to the top, or to the bottom.
1448 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1449
1450 =cut
1451
1452 sub AlterPriority {
1453     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1454
1455     my $hold = Koha::Holds->find( $reserve_id );
1456     return unless $hold;
1457
1458     if ( $hold->cancellationdate ) {
1459         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1460         return;
1461     }
1462
1463     if ( $where eq 'up' ) {
1464       return unless $prev_priority;
1465       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1466     } elsif ( $where eq 'down' ) {
1467       return unless $next_priority;
1468       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1469     } elsif ( $where eq 'top' ) {
1470       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1471     } elsif ( $where eq 'bottom' ) {
1472       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1473     }
1474
1475     # FIXME Should return the new priority
1476 }
1477
1478 =head2 ToggleLowestPriority
1479
1480   ToggleLowestPriority( $borrowernumber, $biblionumber );
1481
1482 This function sets the lowestPriority field to true if is false, and false if it is true.
1483
1484 =cut
1485
1486 sub ToggleLowestPriority {
1487     my ( $reserve_id ) = @_;
1488
1489     my $dbh = C4::Context->dbh;
1490
1491     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1492     $sth->execute( $reserve_id );
1493
1494     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1495 }
1496
1497 =head2 ToggleSuspend
1498
1499   ToggleSuspend( $reserve_id );
1500
1501 This function sets the suspend field to true if is false, and false if it is true.
1502 If the reserve is currently suspended with a suspend_until date, that date will
1503 be cleared when it is unsuspended.
1504
1505 =cut
1506
1507 sub ToggleSuspend {
1508     my ( $reserve_id, $suspend_until ) = @_;
1509
1510     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1511
1512     my $hold = Koha::Holds->find( $reserve_id );
1513
1514     if ( $hold->is_suspended ) {
1515         $hold->resume()
1516     } else {
1517         $hold->suspend_hold( $suspend_until );
1518     }
1519 }
1520
1521 =head2 SuspendAll
1522
1523   SuspendAll(
1524       borrowernumber   => $borrowernumber,
1525       [ biblionumber   => $biblionumber, ]
1526       [ suspend_until  => $suspend_until, ]
1527       [ suspend        => $suspend ]
1528   );
1529
1530   This function accepts a set of hash keys as its parameters.
1531   It requires either borrowernumber or biblionumber, or both.
1532
1533   suspend_until is wholly optional.
1534
1535 =cut
1536
1537 sub SuspendAll {
1538     my %params = @_;
1539
1540     my $borrowernumber = $params{'borrowernumber'} || undef;
1541     my $biblionumber   = $params{'biblionumber'}   || undef;
1542     my $suspend_until  = $params{'suspend_until'}  || undef;
1543     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1544
1545     $suspend_until = eval { dt_from_string($suspend_until) }
1546       if ( defined($suspend_until) );
1547
1548     return unless ( $borrowernumber || $biblionumber );
1549
1550     my $params;
1551     $params->{found}          = undef;
1552     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1553     $params->{biblionumber}   = $biblionumber if $biblionumber;
1554
1555     my @holds = Koha::Holds->search($params);
1556
1557     if ($suspend) {
1558         map { $_->suspend_hold($suspend_until) } @holds;
1559     }
1560     else {
1561         map { $_->resume() } @holds;
1562     }
1563 }
1564
1565
1566 =head2 _FixPriority
1567
1568   _FixPriority({
1569     reserve_id => $reserve_id,
1570     [rank => $rank,]
1571     [ignoreSetLowestRank => $ignoreSetLowestRank]
1572   });
1573
1574   or
1575
1576   _FixPriority({ biblionumber => $biblionumber});
1577
1578 This routine adjusts the priority of a hold request and holds
1579 on the same bib.
1580
1581 In the first form, where a reserve_id is passed, the priority of the
1582 hold is set to supplied rank, and other holds for that bib are adjusted
1583 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1584 is supplied, all of the holds on that bib have their priority adjusted
1585 as if the second form had been used.
1586
1587 In the second form, where a biblionumber is passed, the holds on that
1588 bib (that are not captured) are sorted in order of increasing priority,
1589 then have reserves.priority set so that the first non-captured hold
1590 has its priority set to 1, the second non-captured hold has its priority
1591 set to 2, and so forth.
1592
1593 In both cases, holds that have the lowestPriority flag on are have their
1594 priority adjusted to ensure that they remain at the end of the line.
1595
1596 Note that the ignoreSetLowestRank parameter is meant to be used only
1597 when _FixPriority calls itself.
1598
1599 =cut
1600
1601 sub _FixPriority {
1602     my ( $params ) = @_;
1603     my $reserve_id = $params->{reserve_id};
1604     my $rank = $params->{rank} // '';
1605     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1606     my $biblionumber = $params->{biblionumber};
1607
1608     my $dbh = C4::Context->dbh;
1609
1610     my $hold;
1611     if ( $reserve_id ) {
1612         $hold = Koha::Holds->find( $reserve_id );
1613         if (!defined $hold){
1614             # may have already been checked out and hold fulfilled
1615             $hold = Koha::Old::Holds->find( $reserve_id );
1616         }
1617         return unless $hold;
1618     }
1619
1620     unless ( $biblionumber ) { # FIXME This is a very weird API
1621         $biblionumber = $hold->biblionumber;
1622     }
1623
1624     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1625         $hold->cancel;
1626     }
1627     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1628
1629         # make sure priority for waiting or in-transit items is 0
1630         my $query = "
1631             UPDATE reserves
1632             SET    priority = 0
1633             WHERE reserve_id = ?
1634             AND found IN ('W', 'T', 'P')
1635         ";
1636         my $sth = $dbh->prepare($query);
1637         $sth->execute( $reserve_id );
1638     }
1639     my @priority;
1640
1641     # get whats left
1642     my $query = "
1643         SELECT reserve_id, borrowernumber, reservedate
1644         FROM   reserves
1645         WHERE  biblionumber   = ?
1646           AND  ((found <> 'W' AND found <> 'T' AND found <> 'P') OR found IS NULL)
1647         ORDER BY priority ASC
1648     ";
1649     my $sth = $dbh->prepare($query);
1650     $sth->execute( $biblionumber );
1651     while ( my $line = $sth->fetchrow_hashref ) {
1652         push( @priority,     $line );
1653     }
1654
1655     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1656     # To find the matching index
1657     my $i;
1658     my $key = -1;    # to allow for 0 to be a valid result
1659     for ( $i = 0 ; $i < @priority ; $i++ ) {
1660         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1661             $key = $i;    # save the index
1662             last;
1663         }
1664     }
1665
1666     # if index exists in array then move it to new position
1667     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1668         my $new_rank = $rank - 1; # $new_rank is what you want the new index to be in the array
1669         my $moving_item = splice( @priority, $key, 1 );
1670         $new_rank = scalar @priority if $new_rank > scalar @priority;
1671         splice( @priority, $new_rank, 0, $moving_item );
1672     }
1673
1674     # now fix the priority on those that are left....
1675     $query = "
1676         UPDATE reserves
1677         SET    priority = ?
1678         WHERE  reserve_id = ?
1679     ";
1680     $sth = $dbh->prepare($query);
1681     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1682         $sth->execute(
1683             $j + 1,
1684             $priority[$j]->{'reserve_id'}
1685         );
1686     }
1687
1688     unless ( $ignoreSetLowestRank ) {
1689         $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 AND biblionumber = ? ORDER BY priority" );
1690         $sth->execute($biblionumber);
1691       while ( my $res = $sth->fetchrow_hashref() ) {
1692         _FixPriority({
1693             reserve_id => $res->{'reserve_id'},
1694             rank => '999999',
1695             ignoreSetLowestRank => 1
1696         });
1697       }
1698     }
1699 }
1700
1701 =head2 _Findgroupreserve
1702
1703   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1704
1705 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1706 first match found.  If neither, then we look for non-holds-queue based holds.
1707 Lookahead is the number of days to look in advance.
1708
1709 C<&_Findgroupreserve> returns :
1710 C<@results> is an array of references-to-hash whose keys are mostly
1711 fields from the reserves table of the Koha database, plus
1712 C<biblioitemnumber>.
1713
1714 This routine with either return:
1715 1 - Item specific holds from the holds queue
1716 2 - Title level holds from the holds queue
1717 3 - All holds for this biblionumber
1718
1719 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1720
1721 =cut
1722
1723 sub _Findgroupreserve {
1724     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1725     my $dbh   = C4::Context->dbh;
1726
1727     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1728     # check for exact targeted match
1729     my $item_level_target_query = qq{
1730         SELECT reserves.biblionumber        AS biblionumber,
1731                reserves.borrowernumber      AS borrowernumber,
1732                reserves.reservedate         AS reservedate,
1733                reserves.branchcode          AS branchcode,
1734                reserves.cancellationdate    AS cancellationdate,
1735                reserves.found               AS found,
1736                reserves.reservenotes        AS reservenotes,
1737                reserves.priority            AS priority,
1738                reserves.timestamp           AS timestamp,
1739                biblioitems.biblioitemnumber AS biblioitemnumber,
1740                reserves.itemnumber          AS itemnumber,
1741                reserves.reserve_id          AS reserve_id,
1742                reserves.itemtype            AS itemtype,
1743                reserves.non_priority        AS non_priority
1744         FROM reserves
1745         JOIN biblioitems USING (biblionumber)
1746         JOIN hold_fill_targets USING (reserve_id)
1747         WHERE found IS NULL
1748         AND priority > 0
1749         AND item_level_request = 1
1750         AND hold_fill_targets.itemnumber = ?
1751         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1752         AND suspend = 0
1753         ORDER BY priority
1754     };
1755     my $sth = $dbh->prepare($item_level_target_query);
1756     $sth->execute($itemnumber, $lookahead||0);
1757     my @results;
1758     if ( my $data = $sth->fetchrow_hashref ) {
1759         push( @results, $data )
1760           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1761     }
1762     return @results if @results;
1763
1764     # check for title-level targeted match
1765     my $title_level_target_query = qq{
1766         SELECT reserves.biblionumber        AS biblionumber,
1767                reserves.borrowernumber      AS borrowernumber,
1768                reserves.reservedate         AS reservedate,
1769                reserves.branchcode          AS branchcode,
1770                reserves.cancellationdate    AS cancellationdate,
1771                reserves.found               AS found,
1772                reserves.reservenotes        AS reservenotes,
1773                reserves.priority            AS priority,
1774                reserves.timestamp           AS timestamp,
1775                biblioitems.biblioitemnumber AS biblioitemnumber,
1776                reserves.itemnumber          AS itemnumber,
1777                reserves.reserve_id          AS reserve_id,
1778                reserves.itemtype            AS itemtype,
1779                reserves.non_priority        AS non_priority
1780         FROM reserves
1781         JOIN biblioitems USING (biblionumber)
1782         JOIN hold_fill_targets USING (reserve_id)
1783         WHERE found IS NULL
1784         AND priority > 0
1785         AND item_level_request = 0
1786         AND hold_fill_targets.itemnumber = ?
1787         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1788         AND suspend = 0
1789         ORDER BY priority
1790     };
1791     $sth = $dbh->prepare($title_level_target_query);
1792     $sth->execute($itemnumber, $lookahead||0);
1793     @results = ();
1794     if ( my $data = $sth->fetchrow_hashref ) {
1795         push( @results, $data )
1796           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1797     }
1798     return @results if @results;
1799
1800     my $query = qq{
1801         SELECT reserves.biblionumber               AS biblionumber,
1802                reserves.borrowernumber             AS borrowernumber,
1803                reserves.reservedate                AS reservedate,
1804                reserves.waitingdate                AS waitingdate,
1805                reserves.branchcode                 AS branchcode,
1806                reserves.cancellationdate           AS cancellationdate,
1807                reserves.found                      AS found,
1808                reserves.reservenotes               AS reservenotes,
1809                reserves.priority                   AS priority,
1810                reserves.timestamp                  AS timestamp,
1811                reserves.itemnumber                 AS itemnumber,
1812                reserves.reserve_id                 AS reserve_id,
1813                reserves.itemtype                   AS itemtype,
1814                reserves.non_priority        AS non_priority
1815         FROM reserves
1816         WHERE reserves.biblionumber = ?
1817           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1818           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1819           AND suspend = 0
1820           ORDER BY priority
1821     };
1822     $sth = $dbh->prepare($query);
1823     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1824     @results = ();
1825     while ( my $data = $sth->fetchrow_hashref ) {
1826         push( @results, $data )
1827           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1828     }
1829     return @results;
1830 }
1831
1832 =head2 _koha_notify_reserve
1833
1834   _koha_notify_reserve( $hold->reserve_id );
1835
1836 Sends a notification to the patron that their hold has been filled (through
1837 ModReserveAffect, _not_ ModReserveFill)
1838
1839 The letter code for this notice may be found using the following query:
1840
1841     select distinct letter_code
1842     from message_transports
1843     inner join message_attributes using (message_attribute_id)
1844     where message_name = 'Hold_Filled'
1845
1846 This will probably sipmly be 'HOLD', but because it is defined in the database,
1847 it is subject to addition or change.
1848
1849 The following tables are availalbe witin the notice:
1850
1851     branches
1852     borrowers
1853     biblio
1854     biblioitems
1855     reserves
1856     items
1857
1858 =cut
1859
1860 sub _koha_notify_reserve {
1861     my $reserve_id = shift;
1862     my $hold = Koha::Holds->find($reserve_id);
1863     my $borrowernumber = $hold->borrowernumber;
1864
1865     my $patron = Koha::Patrons->find( $borrowernumber );
1866
1867     # Try to get the borrower's email address
1868     my $to_address = $patron->notice_email_address;
1869
1870     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1871             borrowernumber => $borrowernumber,
1872             message_name => 'Hold_Filled'
1873     } );
1874
1875     my $library = Koha::Libraries->find( $hold->branchcode );
1876     my $admin_email_address = $library->from_email_address;
1877     $library = $library->unblessed;
1878
1879     my %letter_params = (
1880         module => 'reserves',
1881         branchcode => $hold->branchcode,
1882         lang => $patron->lang,
1883         tables => {
1884             'branches'       => $library,
1885             'borrowers'      => $patron->unblessed,
1886             'biblio'         => $hold->biblionumber,
1887             'biblioitems'    => $hold->biblionumber,
1888             'reserves'       => $hold->unblessed,
1889             'items'          => $hold->itemnumber,
1890         },
1891     );
1892
1893     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1894     my $send_notification = sub {
1895         my ( $mtt, $letter_code ) = (@_);
1896         return unless defined $letter_code;
1897         $letter_params{letter_code} = $letter_code;
1898         $letter_params{message_transport_type} = $mtt;
1899         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1900         unless ($letter) {
1901             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1902             return;
1903         }
1904
1905         C4::Letters::EnqueueLetter( {
1906             letter => $letter,
1907             borrowernumber => $borrowernumber,
1908             from_address => $admin_email_address,
1909             message_transport_type => $mtt,
1910         } );
1911     };
1912
1913     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1914         next if (
1915                ( $mtt eq 'email' and not $to_address ) # No email address
1916             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1917             or ( $mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1918             or ( $mtt eq 'phone' and not $patron->phone ) # No phone number to call
1919         );
1920
1921         &$send_notification($mtt, $letter_code);
1922         $notification_sent++;
1923     }
1924     #Making sure that a print notification is sent if no other transport types can be utilized.
1925     if (! $notification_sent) {
1926         &$send_notification('print', 'HOLD');
1927     }
1928
1929 }
1930
1931 =head2 _ShiftPriorityByDateAndPriority
1932
1933   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1934
1935 This increments the priority of all reserves after the one
1936 with either the lowest date after C<$reservedate>
1937 or the lowest priority after C<$priority>.
1938
1939 It effectively makes room for a new reserve to be inserted with a certain
1940 priority, which is returned.
1941
1942 This is most useful when the reservedate can be set by the user.  It allows
1943 the new reserve to be placed before other reserves that have a later
1944 reservedate.  Since priority also is set by the form in reserves/request.pl
1945 the sub accounts for that too.
1946
1947 =cut
1948
1949 sub _ShiftPriorityByDateAndPriority {
1950     my ( $biblio, $resdate, $new_priority ) = @_;
1951
1952     my $dbh = C4::Context->dbh;
1953     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1954     my $sth = $dbh->prepare( $query );
1955     $sth->execute( $biblio, $resdate, $new_priority );
1956     my $min_priority = $sth->fetchrow;
1957     # if no such matches are found, $new_priority remains as original value
1958     $new_priority = $min_priority if ( $min_priority );
1959
1960     # Shift the priority up by one; works in conjunction with the next SQL statement
1961     $query = "UPDATE reserves
1962               SET priority = priority+1
1963               WHERE biblionumber = ?
1964               AND borrowernumber = ?
1965               AND reservedate = ?
1966               AND found IS NULL";
1967     my $sth_update = $dbh->prepare( $query );
1968
1969     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1970     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1971     $sth = $dbh->prepare( $query );
1972     $sth->execute( $new_priority, $biblio );
1973     while ( my $row = $sth->fetchrow_hashref ) {
1974         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1975     }
1976
1977     return $new_priority;  # so the caller knows what priority they wind up receiving
1978 }
1979
1980 =head2 MoveReserve
1981
1982   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1983
1984 Use when checking out an item to handle reserves
1985 If $cancelreserve boolean is set to true, it will remove existing reserve
1986
1987 =cut
1988
1989 sub MoveReserve {
1990     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1991
1992     $cancelreserve //= 0;
1993
1994     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1995     my ( $restype, $res, undef ) = CheckReserves( $itemnumber, undef, $lookahead );
1996     return unless $res;
1997
1998     my $biblionumber     =  $res->{biblionumber};
1999
2000     if ($res->{borrowernumber} == $borrowernumber) {
2001         ModReserveFill($res);
2002     }
2003     else {
2004         # warn "Reserved";
2005         # The item is reserved by someone else.
2006         # Find this item in the reserves
2007
2008         my $borr_res  = Koha::Holds->search({
2009             borrowernumber => $borrowernumber,
2010             biblionumber   => $biblionumber,
2011         },{
2012             order_by       => 'priority'
2013         })->next();
2014
2015         if ( $borr_res ) {
2016             # The item is reserved by the current patron
2017             ModReserveFill($borr_res->unblessed);
2018         }
2019
2020         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
2021             RevertWaitingStatus({ itemnumber => $itemnumber });
2022         }
2023         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
2024             my $hold = Koha::Holds->find( $res->{reserve_id} );
2025             $hold->cancel;
2026         }
2027     }
2028 }
2029
2030 =head2 MergeHolds
2031
2032   MergeHolds($dbh,$to_biblio, $from_biblio);
2033
2034 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
2035
2036 =cut
2037
2038 sub MergeHolds {
2039     my ( $dbh, $to_biblio, $from_biblio ) = @_;
2040     my $sth = $dbh->prepare(
2041         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
2042     );
2043     $sth->execute($from_biblio);
2044     if ( my $data = $sth->fetchrow_hashref() ) {
2045
2046         # holds exist on old record, if not we don't need to do anything
2047         $sth = $dbh->prepare(
2048             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
2049         $sth->execute( $to_biblio, $from_biblio );
2050
2051         # Reorder by date
2052         # don't reorder those already waiting
2053
2054         $sth = $dbh->prepare(
2055 "SELECT * FROM reserves WHERE biblionumber = ? AND (found NOT IN ('W', 'T', 'P') OR found is NULL) ORDER BY reservedate ASC"
2056         );
2057         my $upd_sth = $dbh->prepare(
2058 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
2059         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
2060         );
2061         $sth->execute( $to_biblio );
2062         my $priority = 1;
2063         while ( my $reserve = $sth->fetchrow_hashref() ) {
2064             $upd_sth->execute(
2065                 $priority,                    $to_biblio,
2066                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
2067                 $reserve->{'itemnumber'}
2068             );
2069             $priority++;
2070         }
2071     }
2072 }
2073
2074 =head2 RevertWaitingStatus
2075
2076   RevertWaitingStatus({ itemnumber => $itemnumber });
2077
2078   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
2079
2080   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
2081           item level hold, even if it was only a bibliolevel hold to
2082           begin with. This is because we can no longer know if a hold
2083           was item-level or bib-level after a hold has been set to
2084           waiting status.
2085
2086 =cut
2087
2088 sub RevertWaitingStatus {
2089     my ( $params ) = @_;
2090     my $itemnumber = $params->{'itemnumber'};
2091
2092     return unless ( $itemnumber );
2093
2094     my $dbh = C4::Context->dbh;
2095
2096     ## Get the waiting reserve we want to revert
2097     my $hold = Koha::Holds->search(
2098         {
2099             itemnumber => $itemnumber,
2100             found => { not => undef },
2101         }
2102     )->next;
2103
2104     ## Increment the priority of all other non-waiting
2105     ## reserves for this bib record
2106     my $holds = Koha::Holds->search({ biblionumber => $hold->biblionumber, priority => { '>' => 0 } })
2107                            ->update({ priority => \'priority + 1' }, { no_triggers => 1 });
2108
2109     ## Fix up the currently waiting reserve
2110     $hold->set(
2111         {
2112             priority    => 1,
2113             found       => undef,
2114             waitingdate => undef,
2115             itemnumber  => $hold->item_level_hold ? $hold->itemnumber : undef,
2116         }
2117     )->store();
2118
2119     _FixPriority( { biblionumber => $hold->biblionumber } );
2120
2121     return $hold;
2122 }
2123
2124 =head2 ReserveSlip
2125
2126 ReserveSlip(
2127     {
2128         branchcode     => $branchcode,
2129         borrowernumber => $borrowernumber,
2130         biblionumber   => $biblionumber,
2131         [ itemnumber   => $itemnumber, ]
2132         [ barcode      => $barcode, ]
2133     }
2134   )
2135
2136 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2137
2138 The letter code will be HOLD_SLIP, and the following tables are
2139 available within the slip:
2140
2141     reserves
2142     branches
2143     borrowers
2144     biblio
2145     biblioitems
2146     items
2147
2148 =cut
2149
2150 sub ReserveSlip {
2151     my ($args) = @_;
2152     my $branchcode     = $args->{branchcode};
2153     my $reserve_id = $args->{reserve_id};
2154
2155     my $hold = Koha::Holds->find($reserve_id);
2156     return unless $hold;
2157
2158     my $patron = $hold->borrower;
2159     my $reserve = $hold->unblessed;
2160
2161     return  C4::Letters::GetPreparedLetter (
2162         module => 'circulation',
2163         letter_code => 'HOLD_SLIP',
2164         branchcode => $branchcode,
2165         lang => $patron->lang,
2166         tables => {
2167             'reserves'    => $reserve,
2168             'branches'    => $reserve->{branchcode},
2169             'borrowers'   => $reserve->{borrowernumber},
2170             'biblio'      => $reserve->{biblionumber},
2171             'biblioitems' => $reserve->{biblionumber},
2172             'items'       => $reserve->{itemnumber},
2173         },
2174     );
2175 }
2176
2177 =head2 GetReservesControlBranch
2178
2179   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2180
2181   Return the branchcode to be used to determine which reserves
2182   policy applies to a transaction.
2183
2184   C<$item> is a hashref for an item. Only 'homebranch' is used.
2185
2186   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2187
2188 =cut
2189
2190 sub GetReservesControlBranch {
2191     my ( $item, $borrower ) = @_;
2192
2193     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2194
2195     my $branchcode =
2196         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2197       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2198       :                                              undef;
2199
2200     return $branchcode;
2201 }
2202
2203 =head2 CalculatePriority
2204
2205     my $p = CalculatePriority($biblionumber, $resdate);
2206
2207 Calculate priority for a new reserve on biblionumber, placing it at
2208 the end of the line of all holds whose start date falls before
2209 the current system time and that are neither on the hold shelf
2210 or in transit.
2211
2212 The reserve date parameter is optional; if it is supplied, the
2213 priority is based on the set of holds whose start date falls before
2214 the parameter value.
2215
2216 After calculation of this priority, it is recommended to call
2217 _ShiftPriorityByDateAndPriority. Note that this is currently done in
2218 AddReserves.
2219
2220 =cut
2221
2222 sub CalculatePriority {
2223     my ( $biblionumber, $resdate ) = @_;
2224
2225     my $sql = q{
2226         SELECT COUNT(*) FROM reserves
2227         WHERE biblionumber = ?
2228         AND   priority > 0
2229         AND   (found IS NULL OR found = '')
2230     };
2231     #skip found==W or found==T or found==P (waiting, transit or processing holds)
2232     if( $resdate ) {
2233         $sql.= ' AND ( reservedate <= ? )';
2234     }
2235     else {
2236         $sql.= ' AND ( reservedate < NOW() )';
2237     }
2238     my $dbh = C4::Context->dbh();
2239     my @row = $dbh->selectrow_array(
2240         $sql,
2241         undef,
2242         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2243     );
2244
2245     return @row ? $row[0]+1 : 1;
2246 }
2247
2248 =head2 IsItemOnHoldAndFound
2249
2250     my $bool = IsItemFoundHold( $itemnumber );
2251
2252     Returns true if the item is currently on hold
2253     and that hold has a non-null found status ( W, T, etc. )
2254
2255 =cut
2256
2257 sub IsItemOnHoldAndFound {
2258     my ($itemnumber) = @_;
2259
2260     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2261
2262     my $found = $rs->count(
2263         {
2264             itemnumber => $itemnumber,
2265             found      => { '!=' => undef }
2266         }
2267     );
2268
2269     return $found;
2270 }
2271
2272 =head2 GetMaxPatronHoldsForRecord
2273
2274 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2275
2276 For multiple holds on a given record for a given patron, the max
2277 number of record level holds that a patron can be placed is the highest
2278 value of the holds_per_record rule for each item if the record for that
2279 patron. This subroutine finds and returns the highest holds_per_record
2280 rule value for a given patron id and record id.
2281
2282 =cut
2283
2284 sub GetMaxPatronHoldsForRecord {
2285     my ( $borrowernumber, $biblionumber ) = @_;
2286
2287     my $patron = Koha::Patrons->find($borrowernumber);
2288     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2289
2290     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2291
2292     my $categorycode = $patron->categorycode;
2293     my $branchcode;
2294     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2295
2296     my $max = 0;
2297     foreach my $item (@items) {
2298         my $itemtype = $item->effective_itemtype();
2299
2300         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2301
2302         my $rule = Koha::CirculationRules->get_effective_rule({
2303             categorycode => $categorycode,
2304             itemtype     => $itemtype,
2305             branchcode   => $branchcode,
2306             rule_name    => 'holds_per_record'
2307         });
2308         my $holds_per_record = $rule ? $rule->rule_value : 0;
2309         $max = $holds_per_record if $holds_per_record > $max;
2310     }
2311
2312     return $max;
2313 }
2314
2315 =head1 AUTHOR
2316
2317 Koha Development Team <http://koha-community.org/>
2318
2319 =cut
2320
2321 1;