C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Biblio;
  28 use C4::Circulation;
  29 use C4::Context;
  30 use C4::Items;
  31 use C4::Letters;
  32 use C4::Log;
  33 use C4::Members::Messaging;
  34 use C4::Members;
  35 use Koha::Account::Lines;
  36 use Koha::Biblios;
  37 use Koha::Calendar;
  38 use Koha::CirculationRules;
  39 use Koha::Database;
  40 use Koha::DateUtils;
  41 use Koha::Hold;
  42 use Koha::Holds;
  43 use Koha::ItemTypes;
  44 use Koha::Items;
  45 use Koha::Libraries;
  46 use Koha::Old::Hold;
  47 use Koha::Patrons;
  48
  49 use Carp;
  50 use Data::Dumper;
  51 use List::MoreUtils qw( firstidx any );
  52
  53 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  54
  55 =head1 NAME
  56
  57 C4::Reserves - Koha functions for dealing with reservation.
  58
  59 =head1 SYNOPSIS
  60
  61   use C4::Reserves;
  62
  63 =head1 DESCRIPTION
  64
  65 This modules provides somes functions to deal with reservations.
  66
  67   Reserves are stored in reserves table.
  68   The following columns contains important values :
  69   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  70              =0      : then the reserve is being dealed
  71   - found : NULL       : means the patron requested the 1st available, and we haven't chosen the item
  72             T(ransit)  : the reserve is linked to an item but is in transit to the pickup branch
  73             W(aiting)  : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  74             F(inished) : the reserve has been completed, and is done
  75   - itemnumber : empty : the reserve is still unaffected to an item
  76                  filled: the reserve is attached to an item
  77   The complete workflow is :
  78   ==== 1st use case ====
  79   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  80   a library having it run "transfertodo", and clic on the list
  81          if there is no transfer to do, the reserve waiting
  82          patron can pick it up                                    P =0, F=W,    I=filled
  83          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  84            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  85   The patron borrow the book                                      P =0, F=F,    I=filled
  86
  87   ==== 2nd use case ====
  88   patron requests a document, a given item,
  89     If pickup is holding branch                                   P =0, F=W,   I=filled
  90     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  91         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  92   The patron borrow the book                                      P =0, F=F,    I=filled
  93
  94 =head1 FUNCTIONS
  95
  96 =cut
  97
  98 BEGIN {
  99     require Exporter;
 100     @ISA = qw(Exporter);
 101     @EXPORT = qw(
 102         &AddReserve
 103
 104         &GetReserveStatus
 105
 106         &GetOtherReserves
 107
 108         &ModReserveFill
 109         &ModReserveAffect
 110         &ModReserve
 111         &ModReserveStatus
 112         &ModReserveCancelAll
 113         &ModReserveMinusPriority
 114         &MoveReserve
 115
 116         &CheckReserves
 117         &CanBookBeReserved
 118         &CanItemBeReserved
 119         &CanReserveBeCanceledFromOpac
 120         &CancelExpiredReserves
 121
 122         &AutoUnsuspendReserves
 123
 124         &IsAvailableForItemLevelRequest
 125         ItemsAnyAvailableForHold
 126
 127         &AlterPriority
 128         &ToggleLowestPriority
 129
 130         &ReserveSlip
 131         &ToggleSuspend
 132         &SuspendAll
 133
 134         &GetReservesControlBranch
 135
 136         IsItemOnHoldAndFound
 137
 138         GetMaxPatronHoldsForRecord
 139     );
 140     @EXPORT_OK = qw( MergeHolds );
 141 }
 142
 143 =head2 AddReserve
 144
 145     AddReserve(
 146         {
 147             branch           => $branchcode,
 148             borrowernumber   => $borrowernumber,
 149             biblionumber     => $biblionumber,
 150             priority         => $priority,
 151             reservation_date => $reservation_date,
 152             expiration_date  => $expiration_date,
 153             notes            => $notes,
 154             title            => $title,
 155             itemnumber       => $itemnumber,
 156             found            => $found,
 157             itemtype         => $itemtype,
 158         }
 159     );
 160
 161 Adds reserve and generates HOLDPLACED message.
 162
 163 The following tables are available witin the HOLDPLACED message:
 164
 165     branches
 166     borrowers
 167     biblio
 168     biblioitems
 169     items
 170     reserves
 171
 172 =cut
 173
 174 sub AddReserve {
 175     my ($params)       = @_;
 176     my $branch         = $params->{branchcode};
 177     my $borrowernumber = $params->{borrowernumber};
 178     my $biblionumber   = $params->{biblionumber};
 179     my $priority       = $params->{priority};
 180     my $resdate        = $params->{reservation_date};
 181     my $expdate        = $params->{expiration_date};
 182     my $notes          = $params->{notes};
 183     my $title          = $params->{title};
 184     my $checkitem      = $params->{itemnumber};
 185     my $found          = $params->{found};
 186     my $itemtype       = $params->{itemtype};
 187
 188     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 189         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 190
 191     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 192
 193     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 194     # of the document, we force the value $priority and $found .
 195     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 196         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 197
 198         if (
 199             # If item is already checked out, it cannot be set waiting
 200             !$item->onloan
 201
 202             # The item can't be waiting if it needs a transfer
 203             && $item->holdingbranch eq $branch
 204
 205             # Similarly, if in transit it can't be waiting
 206             && !$item->get_transfer
 207
 208             # If we can't hold damaged items, and it is damaged, it can't be waiting
 209             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 210
 211             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 212             && !$item->current_holds->count )
 213         {
 214             $priority = 0;
 215             $found = 'W';
 216         }
 217     }
 218
 219     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 220
 221         # Make room in reserves for this before those of a later reserve date
 222         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 223     }
 224
 225     my $waitingdate;
 226
 227     # If the reserv had the waiting status, we had the value of the resdate
 228     if ( $found && $found eq 'W' ) {
 229         $waitingdate = $resdate;
 230     }
 231
 232     # Don't add itemtype limit if specific item is selected
 233     $itemtype = undef if $checkitem;
 234
 235     # updates take place here
 236     my $hold = Koha::Hold->new(
 237         {
 238             borrowernumber => $borrowernumber,
 239             biblionumber   => $biblionumber,
 240             reservedate    => $resdate,
 241             branchcode     => $branch,
 242             priority       => $priority,
 243             reservenotes   => $notes,
 244             itemnumber     => $checkitem,
 245             found          => $found,
 246             waitingdate    => $waitingdate,
 247             expirationdate => $expdate,
 248             itemtype       => $itemtype,
 249             item_level_hold => $checkitem ? 1 : 0,
 250         }
 251     )->store();
 252     $hold->set_waiting() if $found && $found eq 'W';
 253
 254     logaction( 'HOLDS', 'CREATE', $hold->id, Dumper($hold->unblessed) )
 255         if C4::Context->preference('HoldsLog');
 256
 257     my $reserve_id = $hold->id();
 258
 259     # add a reserve fee if needed
 260     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 261         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 262         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 263     }
 264
 265     _FixPriority({ biblionumber => $biblionumber});
 266
 267     # Send e-mail to librarian if syspref is active
 268     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 269         my $patron = Koha::Patrons->find( $borrowernumber );
 270         my $library = $patron->library;
 271         if ( my $letter =  C4::Letters::GetPreparedLetter (
 272             module => 'reserves',
 273             letter_code => 'HOLDPLACED',
 274             branchcode => $branch,
 275             lang => $patron->lang,
 276             tables => {
 277                 'branches'    => $library->unblessed,
 278                 'borrowers'   => $patron->unblessed,
 279                 'biblio'      => $biblionumber,
 280                 'biblioitems' => $biblionumber,
 281                 'items'       => $checkitem,
 282                 'reserves'    => $hold->unblessed,
 283             },
 284         ) ) {
 285
 286             my $branch_email_address = $library->inbound_email_address;
 287
 288             C4::Letters::EnqueueLetter(
 289                 {
 290                     letter                 => $letter,
 291                     borrowernumber         => $borrowernumber,
 292                     message_transport_type => 'email',
 293                     to_address             => $branch_email_address,
 294                 }
 295             );
 296         }
 297     }
 298
 299     return $reserve_id;
 300 }
 301
 302 =head2 CanBookBeReserved
 303
 304   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode)
 305   if ($canReserve eq 'OK') { #We can reserve this Item! }
 306
 307 See CanItemBeReserved() for possible return values.
 308
 309 =cut
 310
 311 sub CanBookBeReserved{
 312     my ($borrowernumber, $biblionumber, $pickup_branchcode) = @_;
 313
 314     my @itemnumbers = Koha::Items->search({ biblionumber => $biblionumber})->get_column("itemnumber");
 315     #get items linked via host records
 316     my @hostitems = get_hostitemnumbers_of($biblionumber);
 317     if (@hostitems){
 318         push (@itemnumbers, @hostitems);
 319     }
 320
 321     my $canReserve = { status => '' };
 322     foreach my $itemnumber (@itemnumbers) {
 323         $canReserve = CanItemBeReserved( $borrowernumber, $itemnumber, $pickup_branchcode );
 324         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 325     }
 326     return $canReserve;
 327 }
 328
 329 =head2 CanItemBeReserved
 330
 331   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber, $branchcode)
 332   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 333
 334 @RETURNS { status => OK },              if the Item can be reserved.
 335          { status => ageRestricted },   if the Item is age restricted for this borrower.
 336          { status => damaged },         if the Item is damaged.
 337          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 338          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 339          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 340          { status => notReservable },   if holds on this item are not allowed
 341          { status => libraryNotFound },   if given branchcode is not an existing library
 342          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 343          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 344          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 345
 346 =cut
 347
 348 sub CanItemBeReserved {
 349     my ( $borrowernumber, $itemnumber, $pickup_branchcode ) = @_;
 350
 351     my $dbh = C4::Context->dbh;
 352     my $ruleitemtype;    # itemtype of the matching issuing rule
 353     my $allowedreserves  = 0; # Total number of holds allowed across all records
 354     my $holds_per_record = 1; # Total number of holds allowed for this one given record
 355     my $holds_per_day;        # Default to unlimited
 356
 357     # we retrieve borrowers and items informations #
 358     # item->{itype} will come for biblioitems if necessery
 359     my $item       = Koha::Items->find($itemnumber);
 360     my $biblio     = $item->biblio;
 361     my $patron = Koha::Patrons->find( $borrowernumber );
 362     my $borrower = $patron->unblessed;
 363
 364     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 365     return { status =>'damaged' }
 366       if ( $item->damaged
 367         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 368
 369     # Check for the age restriction
 370     my ( $ageRestriction, $daysToAgeRestriction ) =
 371       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 372     return { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 373
 374     # Check that the patron doesn't have an item level hold on this item already
 375     return { status =>'itemAlreadyOnHold' }
 376       if Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count();
 377
 378     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 379
 380     my $querycount = q{
 381         SELECT count(*) AS count
 382           FROM reserves
 383      LEFT JOIN items USING (itemnumber)
 384      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 385      LEFT JOIN borrowers USING (borrowernumber)
 386          WHERE borrowernumber = ?
 387     };
 388
 389     my $branchcode  = "";
 390     my $branchfield = "reserves.branchcode";
 391
 392     if ( $controlbranch eq "ItemHomeLibrary" ) {
 393         $branchfield = "items.homebranch";
 394         $branchcode  = $item->homebranch;
 395     }
 396     elsif ( $controlbranch eq "PatronLibrary" ) {
 397         $branchfield = "borrowers.branchcode";
 398         $branchcode  = $borrower->{branchcode};
 399     }
 400
 401     # we retrieve rights
 402     if ( my $rights = GetHoldRule( $borrower->{'categorycode'}, $item->effective_itemtype, $branchcode ) ) {
 403         $ruleitemtype     = $rights->{itemtype};
 404         $allowedreserves  = $rights->{reservesallowed} // $allowedreserves;
 405         $holds_per_record = $rights->{holds_per_record} // $holds_per_record;
 406         $holds_per_day    = $rights->{holds_per_day};
 407     }
 408     else {
 409         $ruleitemtype = undef;
 410     }
 411
 412     my $holds = Koha::Holds->search(
 413         {
 414             borrowernumber => $borrowernumber,
 415             biblionumber   => $item->biblionumber,
 416         }
 417     );
 418     if (   defined $holds_per_record && $holds_per_record ne ''
 419         && $holds->count() >= $holds_per_record ) {
 420         return { status => "tooManyHoldsForThisRecord", limit => $holds_per_record };
 421     }
 422
 423     my $today_holds = Koha::Holds->search({
 424         borrowernumber => $borrowernumber,
 425         reservedate    => dt_from_string->date
 426     });
 427
 428     if (   defined $holds_per_day && $holds_per_day ne ''
 429         && $today_holds->count() >= $holds_per_day )
 430     {
 431         return { status => 'tooManyReservesToday', limit => $holds_per_day };
 432     }
 433
 434     # we retrieve count
 435
 436     $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 437
 438     # If using item-level itypes, fall back to the record
 439     # level itemtype if the hold has no associated item
 440     $querycount .=
 441       C4::Context->preference('item-level_itypes')
 442       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 443       : " AND biblioitems.itemtype = ?"
 444       if defined $ruleitemtype;
 445
 446     my $sthcount = $dbh->prepare($querycount);
 447
 448     if ( defined $ruleitemtype ) {
 449         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 450     }
 451     else {
 452         $sthcount->execute( $borrowernumber, $branchcode );
 453     }
 454
 455     my $reservecount = "0";
 456     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 457         $reservecount = $rowcount->{count};
 458     }
 459
 460     # we check if it's ok or not
 461     if (   defined  $allowedreserves && $allowedreserves ne ''
 462         && $reservecount >= $allowedreserves ) {
 463         return { status => 'tooManyReserves', limit => $allowedreserves };
 464     }
 465
 466     # Now we need to check hold limits by patron category
 467     my $rule = Koha::CirculationRules->get_effective_rule(
 468         {
 469             categorycode => $borrower->{categorycode},
 470             branchcode   => $branchcode,
 471             rule_name    => 'max_holds',
 472         }
 473     );
 474     if ( $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 475         my $total_holds_count = Koha::Holds->search(
 476             {
 477                 borrowernumber => $borrower->{borrowernumber}
 478             }
 479         )->count();
 480
 481         return { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 482     }
 483
 484     my $reserves_control_branch =
 485       GetReservesControlBranch( $item->unblessed(), $borrower );
 486     my $branchitemrule =
 487       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype ); # FIXME Should not be item->effective_itemtype?
 488
 489     if ( $branchitemrule->{holdallowed} == 0 ) {
 490         return { status => 'notReservable' };
 491     }
 492
 493     if (   $branchitemrule->{holdallowed} == 1
 494         && $borrower->{branchcode} ne $item->homebranch )
 495     {
 496         return { status => 'cannotReserveFromOtherBranches' };
 497     }
 498
 499     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 500     if ( $branchitemrule->{holdallowed} == 3) {
 501         if($borrower->{branchcode} ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $borrower->{branchcode}} )) {
 502             return { status => 'branchNotInHoldGroup' };
 503         }
 504     }
 505
 506     # If reservecount is ok, we check item branch if IndependentBranches is ON
 507     # and canreservefromotherbranches is OFF
 508     if ( C4::Context->preference('IndependentBranches')
 509         and !C4::Context->preference('canreservefromotherbranches') )
 510     {
 511         if ( $item->homebranch ne $borrower->{branchcode} ) {
 512             return { status => 'cannotReserveFromOtherBranches' };
 513         }
 514     }
 515
 516     if ($pickup_branchcode) {
 517         my $destination = Koha::Libraries->find({
 518             branchcode => $pickup_branchcode,
 519         });
 520
 521         unless ($destination) {
 522             return { status => 'libraryNotFound' };
 523         }
 524         unless ($destination->pickup_location) {
 525             return { status => 'libraryNotPickupLocation' };
 526         }
 527         unless ($item->can_be_transferred({ to => $destination })) {
 528             return { status => 'cannotBeTransferred' };
 529         }
 530         unless ($branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 531             return { status => 'pickupNotInHoldGroup' };
 532         }
 533         unless ($branchitemrule->{hold_fulfillment_policy} ne 'patrongroup' || Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 534             return { status => 'pickupNotInHoldGroup' };
 535         }
 536     }
 537
 538     return { status => 'OK' };
 539 }
 540
 541 =head2 CanReserveBeCanceledFromOpac
 542
 543     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 544
 545     returns 1 if reserve can be cancelled by user from OPAC.
 546     First check if reserve belongs to user, next checks if reserve is not in
 547     transfer or waiting status
 548
 549 =cut
 550
 551 sub CanReserveBeCanceledFromOpac {
 552     my ($reserve_id, $borrowernumber) = @_;
 553
 554     return unless $reserve_id and $borrowernumber;
 555     my $reserve = Koha::Holds->find($reserve_id);
 556
 557     return 0 unless $reserve->borrowernumber == $borrowernumber;
 558     return 0 if ( $reserve->found eq 'W' ) or ( $reserve->found eq 'T' );
 559
 560     return 1;
 561
 562 }
 563
 564 =head2 GetOtherReserves
 565
 566   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 567
 568 Check queued list of this document and check if this document must be transferred
 569
 570 =cut
 571
 572 sub GetOtherReserves {
 573     my ($itemnumber) = @_;
 574     my $messages;
 575     my $nextreservinfo;
 576     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 577     if ($checkreserves) {
 578         my $item = Koha::Items->find($itemnumber);
 579         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 580             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 581             #minus priorities of others reservs
 582             ModReserveMinusPriority(
 583                 $itemnumber,
 584                 $checkreserves->{'reserve_id'},
 585             );
 586
 587             #launch the subroutine dotransfer
 588             C4::Items::ModItemTransfer(
 589                 $itemnumber,
 590                 $item->holdingbranch,
 591                 $checkreserves->{'branchcode'},
 592                 'Reserve'
 593               ),
 594               ;
 595         }
 596
 597      #step 2b : case of a reservation on the same branch, set the waiting status
 598         else {
 599             $messages->{'waiting'} = 1;
 600             ModReserveMinusPriority(
 601                 $itemnumber,
 602                 $checkreserves->{'reserve_id'},
 603             );
 604             ModReserveStatus($itemnumber,'W');
 605         }
 606
 607         $nextreservinfo = $checkreserves->{'borrowernumber'};
 608     }
 609
 610     return ( $messages, $nextreservinfo );
 611 }
 612
 613 =head2 ChargeReserveFee
 614
 615     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 616
 617     Charge the fee for a reserve (if $fee > 0)
 618
 619 =cut
 620
 621 sub ChargeReserveFee {
 622     my ( $borrowernumber, $fee, $title ) = @_;
 623     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 624     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 625         {
 626             amount       => $fee,
 627             description  => $title,
 628             note         => undef,
 629             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 630             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 631             interface    => C4::Context->interface,
 632             invoice_type => undef,
 633             type         => 'RESERVE',
 634             item_id      => undef
 635         }
 636     );
 637 }
 638
 639 =head2 GetReserveFee
 640
 641     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 642
 643     Calculate the fee for a reserve (if applicable).
 644
 645 =cut
 646
 647 sub GetReserveFee {
 648     my ( $borrowernumber, $biblionumber ) = @_;
 649     my $borquery = qq{
 650 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 651     };
 652     my $issue_qry = qq{
 653 SELECT COUNT(*) FROM items
 654 LEFT JOIN issues USING (itemnumber)
 655 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 656     };
 657     my $holds_qry = qq{
 658 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 659     };
 660
 661     my $dbh = C4::Context->dbh;
 662     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 663     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 664     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 665         # This is a reconstruction of the old code:
 666         # Compare number of items with items issued, and optionally check holds
 667         # If not all items are issued and there are no holds: charge no fee
 668         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 669         my ( $notissued, $reserved );
 670         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 671             ( $biblionumber ) );
 672         if( $notissued ) {
 673             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 674                 ( $biblionumber, $borrowernumber ) );
 675             $fee = 0 if $reserved == 0;
 676         }
 677     }
 678     return $fee;
 679 }
 680
 681 =head2 GetReserveStatus
 682
 683   $reservestatus = GetReserveStatus($itemnumber);
 684
 685 Takes an itemnumber and returns the status of the reserve placed on it.
 686 If several reserves exist, the reserve with the lower priority is given.
 687
 688 =cut
 689
 690 ## FIXME: I don't think this does what it thinks it does.
 691 ## It only ever checks the first reserve result, even though
 692 ## multiple reserves for that bib can have the itemnumber set
 693 ## the sub is only used once in the codebase.
 694 sub GetReserveStatus {
 695     my ($itemnumber) = @_;
 696
 697     my $dbh = C4::Context->dbh;
 698
 699     my ($sth, $found, $priority);
 700     if ( $itemnumber ) {
 701         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 702         $sth->execute($itemnumber);
 703         ($found, $priority) = $sth->fetchrow_array;
 704     }
 705
 706     if(defined $found) {
 707         return 'Waiting'  if $found eq 'W' and $priority == 0;
 708         return 'Finished' if $found eq 'F';
 709     }
 710
 711     return 'Reserved' if defined $priority && $priority > 0;
 712
 713     return ''; # empty string here will remove need for checking undef, or less log lines
 714 }
 715
 716 =head2 CheckReserves
 717
 718   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber);
 719   ($status, $matched_reserve, $possible_reserves) = &CheckReserves(undef, $barcode);
 720   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 721
 722 Find a book in the reserves.
 723
 724 C<$itemnumber> is the book's item number.
 725 C<$lookahead> is the number of days to look in advance for future reserves.
 726
 727 As I understand it, C<&CheckReserves> looks for the given item in the
 728 reserves. If it is found, that's a match, and C<$status> is set to
 729 C<Waiting>.
 730
 731 Otherwise, it finds the most important item in the reserves with the
 732 same biblio number as this book (I'm not clear on this) and returns it
 733 with C<$status> set to C<Reserved>.
 734
 735 C<&CheckReserves> returns a two-element list:
 736
 737 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 738
 739 C<$reserve> is the reserve item that matched. It is a
 740 reference-to-hash whose keys are mostly the fields of the reserves
 741 table in the Koha database.
 742
 743 =cut
 744
 745 sub CheckReserves {
 746     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 747     my $dbh = C4::Context->dbh;
 748     my $sth;
 749     my $select;
 750     if (C4::Context->preference('item-level_itypes')){
 751         $select = "
 752            SELECT items.biblionumber,
 753            items.biblioitemnumber,
 754            itemtypes.notforloan,
 755            items.notforloan AS itemnotforloan,
 756            items.itemnumber,
 757            items.damaged,
 758            items.homebranch,
 759            items.holdingbranch
 760            FROM   items
 761            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 762            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 763         ";
 764     }
 765     else {
 766         $select = "
 767            SELECT items.biblionumber,
 768            items.biblioitemnumber,
 769            itemtypes.notforloan,
 770            items.notforloan AS itemnotforloan,
 771            items.itemnumber,
 772            items.damaged,
 773            items.homebranch,
 774            items.holdingbranch
 775            FROM   items
 776            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 777            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 778         ";
 779     }
 780
 781     if ($item) {
 782         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 783         $sth->execute($item);
 784     }
 785     else {
 786         $sth = $dbh->prepare("$select WHERE barcode = ?");
 787         $sth->execute($barcode);
 788     }
 789     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 790     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 791     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 792
 793     return unless $itemnumber; # bail if we got nothing.
 794     # if item is not for loan it cannot be reserved either.....
 795     # except where items.notforloan < 0 :  This indicates the item is holdable.
 796     return if  ( $notforloan_per_item > 0 ) or $notforloan_per_itemtype;
 797
 798     # Find this item in the reserves
 799     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 800
 801     # $priority and $highest are used to find the most important item
 802     # in the list returned by &_Findgroupreserve. (The lower $priority,
 803     # the more important the item.)
 804     # $highest is the most important item we've seen so far.
 805     my $highest;
 806     if (scalar @reserves) {
 807         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 808         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 809         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 810
 811         my $priority = 10000000;
 812         foreach my $res (@reserves) {
 813             if ( $res->{'itemnumber'} && $res->{'itemnumber'} == $itemnumber && $res->{'priority'} == 0) {
 814                 if ($res->{'found'} eq 'W') {
 815                     return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 816                 } else {
 817                     return ( "Reserved", $res, \@reserves ); # Found determinated hold, e. g. the tranferred one
 818                 }
 819             } else {
 820                 my $patron;
 821                 my $item;
 822                 my $local_hold_match;
 823
 824                 if ($LocalHoldsPriority) {
 825                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 826                     $item = Koha::Items->find($itemnumber);
 827
 828                     my $local_holds_priority_item_branchcode =
 829                       $item->$LocalHoldsPriorityItemControl;
 830                     my $local_holds_priority_patron_branchcode =
 831                       ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 832                       ? $res->{branchcode}
 833                       : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 834                       ? $patron->branchcode
 835                       : undef;
 836                     $local_hold_match =
 837                       $local_holds_priority_item_branchcode eq
 838                       $local_holds_priority_patron_branchcode;
 839                 }
 840
 841                 # See if this item is more important than what we've got so far
 842                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 843                     $item ||= Koha::Items->find($itemnumber);
 844                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 845                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 846                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 847                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 848                     next if ($branchitemrule->{'holdallowed'} == 0);
 849                     next if (($branchitemrule->{'holdallowed'} == 1) && ($branch ne $patron->branchcode));
 850                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 851                     next if (($branchitemrule->{'holdallowed'} == 3) && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 852                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 853                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 854                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 855                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 856                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 857                     $priority = $res->{'priority'};
 858                     $highest  = $res;
 859                     last if $local_hold_match;
 860                 }
 861             }
 862         }
 863     }
 864
 865     # If we get this far, then no exact match was found.
 866     # We return the most important (i.e. next) reservation.
 867     if ($highest) {
 868         $highest->{'itemnumber'} = $item;
 869         return ( "Reserved", $highest, \@reserves );
 870     }
 871
 872     return ( '' );
 873 }
 874
 875 =head2 CancelExpiredReserves
 876
 877   CancelExpiredReserves();
 878
 879 Cancels all reserves with an expiration date from before today.
 880
 881 =cut
 882
 883 sub CancelExpiredReserves {
 884     my $today = dt_from_string();
 885     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 886     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 887
 888     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 889     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 890     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 891
 892     # FIXME To move to Koha::Holds->search_expired (?)
 893     my $holds = Koha::Holds->search( $params );
 894
 895     while ( my $hold = $holds->next ) {
 896         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 897
 898         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 899
 900         my $cancel_params = {};
 901         if ( $hold->found eq 'W' ) {
 902             $cancel_params->{charge_cancel_fee} = 1;
 903         }
 904         $hold->cancel( $cancel_params );
 905     }
 906 }
 907
 908 =head2 AutoUnsuspendReserves
 909
 910   AutoUnsuspendReserves();
 911
 912 Unsuspends all suspended reserves with a suspend_until date from before today.
 913
 914 =cut
 915
 916 sub AutoUnsuspendReserves {
 917     my $today = dt_from_string();
 918
 919     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } );
 920
 921     map { $_->resume() } @holds;
 922 }
 923
 924 =head2 ModReserve
 925
 926   ModReserve({ rank => $rank,
 927                reserve_id => $reserve_id,
 928                branchcode => $branchcode
 929                [, itemnumber => $itemnumber ]
 930                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 931               });
 932
 933 Change a hold request's priority or cancel it.
 934
 935 C<$rank> specifies the effect of the change.  If C<$rank>
 936 is 'W' or 'n', nothing happens.  This corresponds to leaving a
 937 request alone when changing its priority in the holds queue
 938 for a bib.
 939
 940 If C<$rank> is 'del', the hold request is cancelled.
 941
 942 If C<$rank> is an integer greater than zero, the priority of
 943 the request is set to that value.  Since priority != 0 means
 944 that the item is not waiting on the hold shelf, setting the
 945 priority to a non-zero value also sets the request's found
 946 status and waiting date to NULL.
 947
 948 The optional C<$itemnumber> parameter is used only when
 949 C<$rank> is a non-zero integer; if supplied, the itemnumber
 950 of the hold request is set accordingly; if omitted, the itemnumber
 951 is cleared.
 952
 953 B<FIXME:> Note that the forgoing can have the effect of causing
 954 item-level hold requests to turn into title-level requests.  This
 955 will be fixed once reserves has separate columns for requested
 956 itemnumber and supplying itemnumber.
 957
 958 =cut
 959
 960 sub ModReserve {
 961     my ( $params ) = @_;
 962
 963     my $rank = $params->{'rank'};
 964     my $reserve_id = $params->{'reserve_id'};
 965     my $branchcode = $params->{'branchcode'};
 966     my $itemnumber = $params->{'itemnumber'};
 967     my $suspend_until = $params->{'suspend_until'};
 968     my $borrowernumber = $params->{'borrowernumber'};
 969     my $biblionumber = $params->{'biblionumber'};
 970
 971     return if $rank eq "W";
 972     return if $rank eq "n";
 973
 974     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
 975
 976     my $hold;
 977     unless ( $reserve_id ) {
 978         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
 979         return unless $holds->count; # FIXME Should raise an exception
 980         $hold = $holds->next;
 981         $reserve_id = $hold->reserve_id;
 982     }
 983
 984     $hold ||= Koha::Holds->find($reserve_id);
 985
 986     if ( $rank eq "del" ) {
 987         $hold->cancel;
 988     }
 989     elsif ($rank =~ /^\d+/ and $rank > 0) {
 990         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
 991             if C4::Context->preference('HoldsLog');
 992
 993         my $properties = {
 994             priority    => $rank,
 995             branchcode  => $branchcode,
 996             itemnumber  => $itemnumber,
 997             found       => undef,
 998             waitingdate => undef
 999         };
1000         if (exists $params->{reservedate}) {
1001             $properties->{reservedate} = $params->{reservedate} || undef;
1002         }
1003         if (exists $params->{expirationdate}) {
1004             $properties->{expirationdate} = $params->{expirationdate} || undef;
1005         }
1006
1007         $hold->set($properties)->store();
1008
1009         if ( defined( $suspend_until ) ) {
1010             if ( $suspend_until ) {
1011                 $suspend_until = eval { dt_from_string( $suspend_until ) };
1012                 $hold->suspend_hold( $suspend_until );
1013             } else {
1014                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1015                 # If the hold is not suspended, this does nothing.
1016                 $hold->set( { suspend_until => undef } )->store();
1017             }
1018         }
1019
1020         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
1021     }
1022 }
1023
1024 =head2 ModReserveFill
1025
1026   &ModReserveFill($reserve);
1027
1028 Fill a reserve. If I understand this correctly, this means that the
1029 reserved book has been found and given to the patron who reserved it.
1030
1031 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
1032 whose keys are fields from the reserves table in the Koha database.
1033
1034 =cut
1035
1036 sub ModReserveFill {
1037     my ($res) = @_;
1038     my $reserve_id = $res->{'reserve_id'};
1039
1040     my $hold = Koha::Holds->find($reserve_id);
1041     # get the priority on this record....
1042     my $priority = $hold->priority;
1043
1044     # update the hold statuses, no need to store it though, we will be deleting it anyway
1045     $hold->set(
1046         {
1047             found    => 'F',
1048             priority => 0,
1049         }
1050     );
1051
1052     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
1053     Koha::Old::Hold->new( $hold->unblessed() )->store();
1054
1055     $hold->delete();
1056
1057     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
1058         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
1059         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
1060     }
1061
1062     # now fix the priority on the others (if the priority wasn't
1063     # already sorted!)....
1064     unless ( $priority == 0 ) {
1065         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
1066     }
1067 }
1068
1069 =head2 ModReserveStatus
1070
1071   &ModReserveStatus($itemnumber, $newstatus);
1072
1073 Update the reserve status for the active (priority=0) reserve.
1074
1075 $itemnumber is the itemnumber the reserve is on
1076
1077 $newstatus is the new status.
1078
1079 =cut
1080
1081 sub ModReserveStatus {
1082
1083     #first : check if we have a reservation for this item .
1084     my ($itemnumber, $newstatus) = @_;
1085     my $dbh = C4::Context->dbh;
1086
1087     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1088     my $sth_set = $dbh->prepare($query);
1089     $sth_set->execute( $newstatus, $itemnumber );
1090
1091     my $item = Koha::Items->find($itemnumber);
1092     if ( $item->location && $item->location eq 'CART'
1093         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1094         && $newstatus ) {
1095       CartToShelf( $itemnumber );
1096     }
1097 }
1098
1099 =head2 ModReserveAffect
1100
1101   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id);
1102
1103 This function affect an item and a status for a given reserve, either fetched directly
1104 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1105 is given, only first reserve returned is affected, which is ok for anything but
1106 multi-item holds.
1107
1108 if $transferToDo is not set, then the status is set to "Waiting" as well.
1109 otherwise, a transfer is on the way, and the end of the transfer will
1110 take care of the waiting status
1111
1112 =cut
1113
1114 sub ModReserveAffect {
1115     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id ) = @_;
1116     my $dbh = C4::Context->dbh;
1117
1118     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1119     # attached to $itemnumber
1120     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1121     $sth->execute($itemnumber);
1122     my ($biblionumber) = $sth->fetchrow;
1123
1124     # get request - need to find out if item is already
1125     # waiting in order to not send duplicate hold filled notifications
1126
1127     my $hold;
1128     # Find hold by id if we have it
1129     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1130     # Find item level hold for this item if there is one
1131     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1132     # Find record level hold if there is no item level hold
1133     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1134
1135     return unless $hold;
1136
1137     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1138
1139     $hold->itemnumber($itemnumber);
1140     $hold->set_waiting($transferToDo);
1141
1142     _koha_notify_reserve( $hold->reserve_id )
1143       if ( !$transferToDo && !$already_on_shelf );
1144
1145     _FixPriority( { biblionumber => $biblionumber } );
1146     my $item = Koha::Items->find($itemnumber);
1147     if ( $item->location && $item->location eq 'CART'
1148         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1149       CartToShelf( $itemnumber );
1150     }
1151
1152     return;
1153 }
1154
1155 =head2 ModReserveCancelAll
1156
1157   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber);
1158
1159 function to cancel reserv,check other reserves, and transfer document if it's necessary
1160
1161 =cut
1162
1163 sub ModReserveCancelAll {
1164     my $messages;
1165     my $nextreservinfo;
1166     my ( $itemnumber, $borrowernumber ) = @_;
1167
1168     #step 1 : cancel the reservation
1169     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1170     return unless $holds->count;
1171     $holds->next->cancel;
1172
1173     #step 2 launch the subroutine of the others reserves
1174     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1175
1176     return ( $messages, $nextreservinfo );
1177 }
1178
1179 =head2 ModReserveMinusPriority
1180
1181   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1182
1183 Reduce the values of queued list
1184
1185 =cut
1186
1187 sub ModReserveMinusPriority {
1188     my ( $itemnumber, $reserve_id ) = @_;
1189
1190     #first step update the value of the first person on reserv
1191     my $dbh   = C4::Context->dbh;
1192     my $query = "
1193         UPDATE reserves
1194         SET    priority = 0 , itemnumber = ?
1195         WHERE  reserve_id = ?
1196     ";
1197     my $sth_upd = $dbh->prepare($query);
1198     $sth_upd->execute( $itemnumber, $reserve_id );
1199     # second step update all others reserves
1200     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1201 }
1202
1203 =head2 IsAvailableForItemLevelRequest
1204
1205   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1206
1207 Checks whether a given item record is available for an
1208 item-level hold request.  An item is available if
1209
1210 * it is not lost AND
1211 * it is not damaged AND
1212 * it is not withdrawn AND
1213 * a waiting or in transit reserve is placed on
1214 * does not have a not for loan value > 0
1215
1216 Need to check the issuingrules onshelfholds column,
1217 if this is set items on the shelf can be placed on hold
1218
1219 Note that IsAvailableForItemLevelRequest() does not
1220 check if the staff operator is authorized to place
1221 a request on the item - in particular,
1222 this routine does not check IndependentBranches
1223 and canreservefromotherbranches.
1224
1225 =cut
1226
1227 sub IsAvailableForItemLevelRequest {
1228     my ( $item, $patron, $pickup_branchcode ) = @_;
1229
1230     my $dbh = C4::Context->dbh;
1231     # must check the notforloan setting of the itemtype
1232     # FIXME - a lot of places in the code do this
1233     #         or something similar - need to be
1234     #         consolidated
1235     my $itemtype = $item->effective_itemtype;
1236     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1237
1238     return 0 if
1239         $notforloan_per_itemtype ||
1240         $item->itemlost        ||
1241         $item->notforloan > 0  ||
1242         $item->withdrawn        ||
1243         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1244
1245     if ($pickup_branchcode) {
1246         my $destination = Koha::Libraries->find($pickup_branchcode);
1247         return 0 unless $destination;
1248         return 0 unless $destination->pickup_location;
1249         return 0 unless $item->can_be_transferred( { to => $destination } );
1250         my $reserves_control_branch =
1251             GetReservesControlBranch( $item->unblessed(), $patron->unblessed() );
1252         my $branchitemrule =
1253             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1254         my $home_library = Koka::Libraries->find( {branchcode => $item->homebranch} );
1255         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1256     }
1257
1258     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1259
1260     if ( $on_shelf_holds == 1 ) {
1261         return 1;
1262     } elsif ( $on_shelf_holds == 2 ) {
1263         my $any_available = ItemsAnyAvailableForHold( { biblionumber => $item->biblionumber, patron => $patron });
1264         return $any_available ? 0 : 1;
1265     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1266         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1267     }
1268 }
1269
1270 =head2 ItemsAnyAvailableForHold
1271
1272   ItemsAnyAvailableForHold( { biblionumber => $biblionumber, patron => $patron });
1273
1274 This function checks all items for specified biblionumber (num) / patron (object)
1275 and returns true (1) or false (0) depending if any of rules allows at least of
1276 one item to be available for hold including lots of parameters/logic
1277
1278 =cut
1279
1280 sub ItemsAnyAvailableForHold {
1281     my $param = shift;
1282
1283     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } );
1284
1285     my $any_available = 0;
1286
1287     foreach my $i (@items) {
1288         my $reserves_control_branch =
1289             GetReservesControlBranch( $i->unblessed(), $param->{patron}->unblessed );
1290         my $branchitemrule =
1291             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1292         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1293
1294         $any_available = 1
1295             unless $i->itemlost
1296             || $i->notforloan > 0
1297             || $i->withdrawn
1298             || $i->onloan
1299             || IsItemOnHoldAndFound( $i->id )
1300             || ( $i->damaged
1301             && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1302             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1303             || $branchitemrule->{holdallowed} == 1 && $param->{patron}->branchcode ne $i->homebranch
1304             || $branchitemrule->{holdallowed} == 3 && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } );
1305     }
1306
1307     return $any_available;
1308 }
1309
1310 =head2 AlterPriority
1311
1312   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1313
1314 This function changes a reserve's priority up, down, to the top, or to the bottom.
1315 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1316
1317 =cut
1318
1319 sub AlterPriority {
1320     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1321
1322     my $hold = Koha::Holds->find( $reserve_id );
1323     return unless $hold;
1324
1325     if ( $hold->cancellationdate ) {
1326         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1327         return;
1328     }
1329
1330     if ( $where eq 'up' ) {
1331       return unless $prev_priority;
1332       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1333     } elsif ( $where eq 'down' ) {
1334       return unless $next_priority;
1335       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1336     } elsif ( $where eq 'top' ) {
1337       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1338     } elsif ( $where eq 'bottom' ) {
1339       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1340     }
1341
1342     # FIXME Should return the new priority
1343 }
1344
1345 =head2 ToggleLowestPriority
1346
1347   ToggleLowestPriority( $borrowernumber, $biblionumber );
1348
1349 This function sets the lowestPriority field to true if is false, and false if it is true.
1350
1351 =cut
1352
1353 sub ToggleLowestPriority {
1354     my ( $reserve_id ) = @_;
1355
1356     my $dbh = C4::Context->dbh;
1357
1358     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1359     $sth->execute( $reserve_id );
1360
1361     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1362 }
1363
1364 =head2 ToggleSuspend
1365
1366   ToggleSuspend( $reserve_id );
1367
1368 This function sets the suspend field to true if is false, and false if it is true.
1369 If the reserve is currently suspended with a suspend_until date, that date will
1370 be cleared when it is unsuspended.
1371
1372 =cut
1373
1374 sub ToggleSuspend {
1375     my ( $reserve_id, $suspend_until ) = @_;
1376
1377     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1378
1379     my $hold = Koha::Holds->find( $reserve_id );
1380
1381     if ( $hold->is_suspended ) {
1382         $hold->resume()
1383     } else {
1384         $hold->suspend_hold( $suspend_until );
1385     }
1386 }
1387
1388 =head2 SuspendAll
1389
1390   SuspendAll(
1391       borrowernumber   => $borrowernumber,
1392       [ biblionumber   => $biblionumber, ]
1393       [ suspend_until  => $suspend_until, ]
1394       [ suspend        => $suspend ]
1395   );
1396
1397   This function accepts a set of hash keys as its parameters.
1398   It requires either borrowernumber or biblionumber, or both.
1399
1400   suspend_until is wholly optional.
1401
1402 =cut
1403
1404 sub SuspendAll {
1405     my %params = @_;
1406
1407     my $borrowernumber = $params{'borrowernumber'} || undef;
1408     my $biblionumber   = $params{'biblionumber'}   || undef;
1409     my $suspend_until  = $params{'suspend_until'}  || undef;
1410     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1411
1412     $suspend_until = eval { dt_from_string($suspend_until) }
1413       if ( defined($suspend_until) );
1414
1415     return unless ( $borrowernumber || $biblionumber );
1416
1417     my $params;
1418     $params->{found}          = undef;
1419     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1420     $params->{biblionumber}   = $biblionumber if $biblionumber;
1421
1422     my @holds = Koha::Holds->search($params);
1423
1424     if ($suspend) {
1425         map { $_->suspend_hold($suspend_until) } @holds;
1426     }
1427     else {
1428         map { $_->resume() } @holds;
1429     }
1430 }
1431
1432
1433 =head2 _FixPriority
1434
1435   _FixPriority({
1436     reserve_id => $reserve_id,
1437     [rank => $rank,]
1438     [ignoreSetLowestRank => $ignoreSetLowestRank]
1439   });
1440
1441   or
1442
1443   _FixPriority({ biblionumber => $biblionumber});
1444
1445 This routine adjusts the priority of a hold request and holds
1446 on the same bib.
1447
1448 In the first form, where a reserve_id is passed, the priority of the
1449 hold is set to supplied rank, and other holds for that bib are adjusted
1450 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1451 is supplied, all of the holds on that bib have their priority adjusted
1452 as if the second form had been used.
1453
1454 In the second form, where a biblionumber is passed, the holds on that
1455 bib (that are not captured) are sorted in order of increasing priority,
1456 then have reserves.priority set so that the first non-captured hold
1457 has its priority set to 1, the second non-captured hold has its priority
1458 set to 2, and so forth.
1459
1460 In both cases, holds that have the lowestPriority flag on are have their
1461 priority adjusted to ensure that they remain at the end of the line.
1462
1463 Note that the ignoreSetLowestRank parameter is meant to be used only
1464 when _FixPriority calls itself.
1465
1466 =cut
1467
1468 sub _FixPriority {
1469     my ( $params ) = @_;
1470     my $reserve_id = $params->{reserve_id};
1471     my $rank = $params->{rank} // '';
1472     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1473     my $biblionumber = $params->{biblionumber};
1474
1475     my $dbh = C4::Context->dbh;
1476
1477     my $hold;
1478     if ( $reserve_id ) {
1479         $hold = Koha::Holds->find( $reserve_id );
1480         if (!defined $hold){
1481             # may have already been checked out and hold fulfilled
1482             $hold = Koha::Old::Holds->find( $reserve_id );
1483         }
1484         return unless $hold;
1485     }
1486
1487     unless ( $biblionumber ) { # FIXME This is a very weird API
1488         $biblionumber = $hold->biblionumber;
1489     }
1490
1491     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1492         $hold->cancel;
1493     }
1494     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1495
1496         # make sure priority for waiting or in-transit items is 0
1497         my $query = "
1498             UPDATE reserves
1499             SET    priority = 0
1500             WHERE reserve_id = ?
1501             AND found IN ('W', 'T')
1502         ";
1503         my $sth = $dbh->prepare($query);
1504         $sth->execute( $reserve_id );
1505     }
1506     my @priority;
1507
1508     # get whats left
1509     my $query = "
1510         SELECT reserve_id, borrowernumber, reservedate
1511         FROM   reserves
1512         WHERE  biblionumber   = ?
1513           AND  ((found <> 'W' AND found <> 'T') OR found IS NULL)
1514         ORDER BY priority ASC
1515     ";
1516     my $sth = $dbh->prepare($query);
1517     $sth->execute( $biblionumber );
1518     while ( my $line = $sth->fetchrow_hashref ) {
1519         push( @priority,     $line );
1520     }
1521
1522     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1523     # To find the matching index
1524     my $i;
1525     my $key = -1;    # to allow for 0 to be a valid result
1526     for ( $i = 0 ; $i < @priority ; $i++ ) {
1527         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1528             $key = $i;    # save the index
1529             last;
1530         }
1531     }
1532
1533     # if index exists in array then move it to new position
1534     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1535         my $new_rank = $rank -
1536           1;    # $new_rank is what you want the new index to be in the array
1537         my $moving_item = splice( @priority, $key, 1 );
1538         splice( @priority, $new_rank, 0, $moving_item );
1539     }
1540
1541     # now fix the priority on those that are left....
1542     $query = "
1543         UPDATE reserves
1544         SET    priority = ?
1545         WHERE  reserve_id = ?
1546     ";
1547     $sth = $dbh->prepare($query);
1548     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1549         $sth->execute(
1550             $j + 1,
1551             $priority[$j]->{'reserve_id'}
1552         );
1553     }
1554
1555     $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 ORDER BY priority" );
1556     $sth->execute();
1557
1558     unless ( $ignoreSetLowestRank ) {
1559       while ( my $res = $sth->fetchrow_hashref() ) {
1560         _FixPriority({
1561             reserve_id => $res->{'reserve_id'},
1562             rank => '999999',
1563             ignoreSetLowestRank => 1
1564         });
1565       }
1566     }
1567 }
1568
1569 =head2 _Findgroupreserve
1570
1571   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1572
1573 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1574 first match found.  If neither, then we look for non-holds-queue based holds.
1575 Lookahead is the number of days to look in advance.
1576
1577 C<&_Findgroupreserve> returns :
1578 C<@results> is an array of references-to-hash whose keys are mostly
1579 fields from the reserves table of the Koha database, plus
1580 C<biblioitemnumber>.
1581
1582 This routine with either return:
1583 1 - Item specific holds from the holds queue
1584 2 - Title level holds from the holds queue
1585 3 - All holds for this biblionumber
1586
1587 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1588
1589 =cut
1590
1591 sub _Findgroupreserve {
1592     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1593     my $dbh   = C4::Context->dbh;
1594
1595     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1596     # check for exact targeted match
1597     my $item_level_target_query = qq{
1598         SELECT reserves.biblionumber        AS biblionumber,
1599                reserves.borrowernumber      AS borrowernumber,
1600                reserves.reservedate         AS reservedate,
1601                reserves.branchcode          AS branchcode,
1602                reserves.cancellationdate    AS cancellationdate,
1603                reserves.found               AS found,
1604                reserves.reservenotes        AS reservenotes,
1605                reserves.priority            AS priority,
1606                reserves.timestamp           AS timestamp,
1607                biblioitems.biblioitemnumber AS biblioitemnumber,
1608                reserves.itemnumber          AS itemnumber,
1609                reserves.reserve_id          AS reserve_id,
1610                reserves.itemtype            AS itemtype
1611         FROM reserves
1612         JOIN biblioitems USING (biblionumber)
1613         JOIN hold_fill_targets USING (biblionumber, borrowernumber, itemnumber)
1614         WHERE found IS NULL
1615         AND priority > 0
1616         AND item_level_request = 1
1617         AND itemnumber = ?
1618         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1619         AND suspend = 0
1620         ORDER BY priority
1621     };
1622     my $sth = $dbh->prepare($item_level_target_query);
1623     $sth->execute($itemnumber, $lookahead||0);
1624     my @results;
1625     if ( my $data = $sth->fetchrow_hashref ) {
1626         push( @results, $data )
1627           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1628     }
1629     return @results if @results;
1630
1631     # check for title-level targeted match
1632     my $title_level_target_query = qq{
1633         SELECT reserves.biblionumber        AS biblionumber,
1634                reserves.borrowernumber      AS borrowernumber,
1635                reserves.reservedate         AS reservedate,
1636                reserves.branchcode          AS branchcode,
1637                reserves.cancellationdate    AS cancellationdate,
1638                reserves.found               AS found,
1639                reserves.reservenotes        AS reservenotes,
1640                reserves.priority            AS priority,
1641                reserves.timestamp           AS timestamp,
1642                biblioitems.biblioitemnumber AS biblioitemnumber,
1643                reserves.itemnumber          AS itemnumber,
1644                reserves.reserve_id          AS reserve_id,
1645                reserves.itemtype            AS itemtype
1646         FROM reserves
1647         JOIN biblioitems USING (biblionumber)
1648         JOIN hold_fill_targets USING (biblionumber, borrowernumber)
1649         WHERE found IS NULL
1650         AND priority > 0
1651         AND item_level_request = 0
1652         AND hold_fill_targets.itemnumber = ?
1653         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1654         AND suspend = 0
1655         ORDER BY priority
1656     };
1657     $sth = $dbh->prepare($title_level_target_query);
1658     $sth->execute($itemnumber, $lookahead||0);
1659     @results = ();
1660     if ( my $data = $sth->fetchrow_hashref ) {
1661         push( @results, $data )
1662           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1663     }
1664     return @results if @results;
1665
1666     my $query = qq{
1667         SELECT reserves.biblionumber               AS biblionumber,
1668                reserves.borrowernumber             AS borrowernumber,
1669                reserves.reservedate                AS reservedate,
1670                reserves.waitingdate                AS waitingdate,
1671                reserves.branchcode                 AS branchcode,
1672                reserves.cancellationdate           AS cancellationdate,
1673                reserves.found                      AS found,
1674                reserves.reservenotes               AS reservenotes,
1675                reserves.priority                   AS priority,
1676                reserves.timestamp                  AS timestamp,
1677                reserves.itemnumber                 AS itemnumber,
1678                reserves.reserve_id                 AS reserve_id,
1679                reserves.itemtype                   AS itemtype
1680         FROM reserves
1681         WHERE reserves.biblionumber = ?
1682           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1683           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1684           AND suspend = 0
1685           ORDER BY priority
1686     };
1687     $sth = $dbh->prepare($query);
1688     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1689     @results = ();
1690     while ( my $data = $sth->fetchrow_hashref ) {
1691         push( @results, $data )
1692           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1693     }
1694     return @results;
1695 }
1696
1697 =head2 _koha_notify_reserve
1698
1699   _koha_notify_reserve( $hold->reserve_id );
1700
1701 Sends a notification to the patron that their hold has been filled (through
1702 ModReserveAffect, _not_ ModReserveFill)
1703
1704 The letter code for this notice may be found using the following query:
1705
1706     select distinct letter_code
1707     from message_transports
1708     inner join message_attributes using (message_attribute_id)
1709     where message_name = 'Hold_Filled'
1710
1711 This will probably sipmly be 'HOLD', but because it is defined in the database,
1712 it is subject to addition or change.
1713
1714 The following tables are availalbe witin the notice:
1715
1716     branches
1717     borrowers
1718     biblio
1719     biblioitems
1720     reserves
1721     items
1722
1723 =cut
1724
1725 sub _koha_notify_reserve {
1726     my $reserve_id = shift;
1727     my $hold = Koha::Holds->find($reserve_id);
1728     my $borrowernumber = $hold->borrowernumber;
1729
1730     my $patron = Koha::Patrons->find( $borrowernumber );
1731
1732     # Try to get the borrower's email address
1733     my $to_address = $patron->notice_email_address;
1734
1735     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1736             borrowernumber => $borrowernumber,
1737             message_name => 'Hold_Filled'
1738     } );
1739
1740     my $library = Koha::Libraries->find( $hold->branchcode )->unblessed;
1741
1742     my $admin_email_address = $library->{branchemail} || C4::Context->preference('KohaAdminEmailAddress');
1743
1744     my %letter_params = (
1745         module => 'reserves',
1746         branchcode => $hold->branchcode,
1747         lang => $patron->lang,
1748         tables => {
1749             'branches'       => $library,
1750             'borrowers'      => $patron->unblessed,
1751             'biblio'         => $hold->biblionumber,
1752             'biblioitems'    => $hold->biblionumber,
1753             'reserves'       => $hold->unblessed,
1754             'items'          => $hold->itemnumber,
1755         },
1756     );
1757
1758     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1759     my $send_notification = sub {
1760         my ( $mtt, $letter_code ) = (@_);
1761         return unless defined $letter_code;
1762         $letter_params{letter_code} = $letter_code;
1763         $letter_params{message_transport_type} = $mtt;
1764         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1765         unless ($letter) {
1766             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1767             return;
1768         }
1769
1770         C4::Letters::EnqueueLetter( {
1771             letter => $letter,
1772             borrowernumber => $borrowernumber,
1773             from_address => $admin_email_address,
1774             message_transport_type => $mtt,
1775         } );
1776     };
1777
1778     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1779         next if (
1780                ( $mtt eq 'email' and not $to_address ) # No email address
1781             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1782             or ( $mtt eq 'phone' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1783         );
1784
1785         &$send_notification($mtt, $letter_code);
1786         $notification_sent++;
1787     }
1788     #Making sure that a print notification is sent if no other transport types can be utilized.
1789     if (! $notification_sent) {
1790         &$send_notification('print', 'HOLD');
1791     }
1792
1793 }
1794
1795 =head2 _ShiftPriorityByDateAndPriority
1796
1797   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1798
1799 This increments the priority of all reserves after the one
1800 with either the lowest date after C<$reservedate>
1801 or the lowest priority after C<$priority>.
1802
1803 It effectively makes room for a new reserve to be inserted with a certain
1804 priority, which is returned.
1805
1806 This is most useful when the reservedate can be set by the user.  It allows
1807 the new reserve to be placed before other reserves that have a later
1808 reservedate.  Since priority also is set by the form in reserves/request.pl
1809 the sub accounts for that too.
1810
1811 =cut
1812
1813 sub _ShiftPriorityByDateAndPriority {
1814     my ( $biblio, $resdate, $new_priority ) = @_;
1815
1816     my $dbh = C4::Context->dbh;
1817     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1818     my $sth = $dbh->prepare( $query );
1819     $sth->execute( $biblio, $resdate, $new_priority );
1820     my $min_priority = $sth->fetchrow;
1821     # if no such matches are found, $new_priority remains as original value
1822     $new_priority = $min_priority if ( $min_priority );
1823
1824     # Shift the priority up by one; works in conjunction with the next SQL statement
1825     $query = "UPDATE reserves
1826               SET priority = priority+1
1827               WHERE biblionumber = ?
1828               AND borrowernumber = ?
1829               AND reservedate = ?
1830               AND found IS NULL";
1831     my $sth_update = $dbh->prepare( $query );
1832
1833     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1834     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1835     $sth = $dbh->prepare( $query );
1836     $sth->execute( $new_priority, $biblio );
1837     while ( my $row = $sth->fetchrow_hashref ) {
1838         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1839     }
1840
1841     return $new_priority;  # so the caller knows what priority they wind up receiving
1842 }
1843
1844 =head2 MoveReserve
1845
1846   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1847
1848 Use when checking out an item to handle reserves
1849 If $cancelreserve boolean is set to true, it will remove existing reserve
1850
1851 =cut
1852
1853 sub MoveReserve {
1854     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1855
1856     $cancelreserve //= 0;
1857
1858     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1859     my ( $restype, $res, undef ) = CheckReserves( $itemnumber, undef, $lookahead );
1860     return unless $res;
1861
1862     my $biblionumber     =  $res->{biblionumber};
1863
1864     if ($res->{borrowernumber} == $borrowernumber) {
1865         ModReserveFill($res);
1866     }
1867     else {
1868         # warn "Reserved";
1869         # The item is reserved by someone else.
1870         # Find this item in the reserves
1871
1872         my $borr_res  = Koha::Holds->search({
1873             borrowernumber => $borrowernumber,
1874             biblionumber   => $biblionumber,
1875         },{
1876             order_by       => 'priority'
1877         })->next();
1878
1879         if ( $borr_res ) {
1880             # The item is reserved by the current patron
1881             ModReserveFill($borr_res->unblessed);
1882         }
1883
1884         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
1885             RevertWaitingStatus({ itemnumber => $itemnumber });
1886         }
1887         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
1888             my $hold = Koha::Holds->find( $res->{reserve_id} );
1889             $hold->cancel;
1890         }
1891     }
1892 }
1893
1894 =head2 MergeHolds
1895
1896   MergeHolds($dbh,$to_biblio, $from_biblio);
1897
1898 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
1899
1900 =cut
1901
1902 sub MergeHolds {
1903     my ( $dbh, $to_biblio, $from_biblio ) = @_;
1904     my $sth = $dbh->prepare(
1905         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
1906     );
1907     $sth->execute($from_biblio);
1908     if ( my $data = $sth->fetchrow_hashref() ) {
1909
1910         # holds exist on old record, if not we don't need to do anything
1911         $sth = $dbh->prepare(
1912             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
1913         $sth->execute( $to_biblio, $from_biblio );
1914
1915         # Reorder by date
1916         # don't reorder those already waiting
1917
1918         $sth = $dbh->prepare(
1919 "SELECT * FROM reserves WHERE biblionumber = ? AND (found <> ? AND found <> ? OR found is NULL) ORDER BY reservedate ASC"
1920         );
1921         my $upd_sth = $dbh->prepare(
1922 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
1923         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
1924         );
1925         $sth->execute( $to_biblio, 'W', 'T' );
1926         my $priority = 1;
1927         while ( my $reserve = $sth->fetchrow_hashref() ) {
1928             $upd_sth->execute(
1929                 $priority,                    $to_biblio,
1930                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
1931                 $reserve->{'itemnumber'}
1932             );
1933             $priority++;
1934         }
1935     }
1936 }
1937
1938 =head2 RevertWaitingStatus
1939
1940   RevertWaitingStatus({ itemnumber => $itemnumber });
1941
1942   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
1943
1944   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
1945           item level hold, even if it was only a bibliolevel hold to
1946           begin with. This is because we can no longer know if a hold
1947           was item-level or bib-level after a hold has been set to
1948           waiting status.
1949
1950 =cut
1951
1952 sub RevertWaitingStatus {
1953     my ( $params ) = @_;
1954     my $itemnumber = $params->{'itemnumber'};
1955
1956     return unless ( $itemnumber );
1957
1958     my $dbh = C4::Context->dbh;
1959
1960     ## Get the waiting reserve we want to revert
1961     my $query = "
1962         SELECT * FROM reserves
1963         WHERE itemnumber = ?
1964         AND found IS NOT NULL
1965     ";
1966     my $sth = $dbh->prepare( $query );
1967     $sth->execute( $itemnumber );
1968     my $reserve = $sth->fetchrow_hashref();
1969
1970     my $hold = Koha::Holds->find( $reserve->{reserve_id} ); # TODO Remove the next raw SQL statements and use this instead
1971
1972     ## Increment the priority of all other non-waiting
1973     ## reserves for this bib record
1974     $query = "
1975         UPDATE reserves
1976         SET
1977           priority = priority + 1
1978         WHERE
1979           biblionumber =  ?
1980         AND
1981           priority > 0
1982     ";
1983     $sth = $dbh->prepare( $query );
1984     $sth->execute( $reserve->{'biblionumber'} );
1985
1986     $hold->set(
1987         {
1988             priority    => 1,
1989             found       => undef,
1990             waitingdate => undef,
1991             itemnumber  => $hold->item_level_hold ? $hold->itemnumber : undef,
1992         }
1993     )->store();
1994
1995     _FixPriority( { biblionumber => $reserve->{biblionumber} } );
1996
1997     return $hold;
1998 }
1999
2000 =head2 ReserveSlip
2001
2002 ReserveSlip(
2003     {
2004         branchcode     => $branchcode,
2005         borrowernumber => $borrowernumber,
2006         biblionumber   => $biblionumber,
2007         [ itemnumber   => $itemnumber, ]
2008         [ barcode      => $barcode, ]
2009     }
2010   )
2011
2012 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2013
2014 The letter code will be HOLD_SLIP, and the following tables are
2015 available within the slip:
2016
2017     reserves
2018     branches
2019     borrowers
2020     biblio
2021     biblioitems
2022     items
2023
2024 =cut
2025
2026 sub ReserveSlip {
2027     my ($args) = @_;
2028     my $branchcode     = $args->{branchcode};
2029     my $borrowernumber = $args->{borrowernumber};
2030     my $biblionumber   = $args->{biblionumber};
2031     my $itemnumber     = $args->{itemnumber};
2032     my $barcode        = $args->{barcode};
2033
2034
2035     my $patron = Koha::Patrons->find($borrowernumber);
2036
2037     my $hold;
2038     if ($itemnumber || $barcode ) {
2039         $itemnumber ||= Koha::Items->find( { barcode => $barcode } )->itemnumber;
2040
2041         $hold = Koha::Holds->search(
2042             {
2043                 biblionumber   => $biblionumber,
2044                 borrowernumber => $borrowernumber,
2045                 itemnumber     => $itemnumber
2046             }
2047         )->next;
2048     }
2049     else {
2050         $hold = Koha::Holds->search(
2051             {
2052                 biblionumber   => $biblionumber,
2053                 borrowernumber => $borrowernumber
2054             }
2055         )->next;
2056     }
2057
2058     return unless $hold;
2059     my $reserve = $hold->unblessed;
2060
2061     return  C4::Letters::GetPreparedLetter (
2062         module => 'circulation',
2063         letter_code => 'HOLD_SLIP',
2064         branchcode => $branchcode,
2065         lang => $patron->lang,
2066         tables => {
2067             'reserves'    => $reserve,
2068             'branches'    => $reserve->{branchcode},
2069             'borrowers'   => $reserve->{borrowernumber},
2070             'biblio'      => $reserve->{biblionumber},
2071             'biblioitems' => $reserve->{biblionumber},
2072             'items'       => $reserve->{itemnumber},
2073         },
2074     );
2075 }
2076
2077 =head2 GetReservesControlBranch
2078
2079   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2080
2081   Return the branchcode to be used to determine which reserves
2082   policy applies to a transaction.
2083
2084   C<$item> is a hashref for an item. Only 'homebranch' is used.
2085
2086   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2087
2088 =cut
2089
2090 sub GetReservesControlBranch {
2091     my ( $item, $borrower ) = @_;
2092
2093     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2094
2095     my $branchcode =
2096         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2097       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2098       :                                              undef;
2099
2100     return $branchcode;
2101 }
2102
2103 =head2 CalculatePriority
2104
2105     my $p = CalculatePriority($biblionumber, $resdate);
2106
2107 Calculate priority for a new reserve on biblionumber, placing it at
2108 the end of the line of all holds whose start date falls before
2109 the current system time and that are neither on the hold shelf
2110 or in transit.
2111
2112 The reserve date parameter is optional; if it is supplied, the
2113 priority is based on the set of holds whose start date falls before
2114 the parameter value.
2115
2116 After calculation of this priority, it is recommended to call
2117 _ShiftPriorityByDateAndPriority. Note that this is currently done in
2118 AddReserves.
2119
2120 =cut
2121
2122 sub CalculatePriority {
2123     my ( $biblionumber, $resdate ) = @_;
2124
2125     my $sql = q{
2126         SELECT COUNT(*) FROM reserves
2127         WHERE biblionumber = ?
2128         AND   priority > 0
2129         AND   (found IS NULL OR found = '')
2130     };
2131     #skip found==W or found==T (waiting or transit holds)
2132     if( $resdate ) {
2133         $sql.= ' AND ( reservedate <= ? )';
2134     }
2135     else {
2136         $sql.= ' AND ( reservedate < NOW() )';
2137     }
2138     my $dbh = C4::Context->dbh();
2139     my @row = $dbh->selectrow_array(
2140         $sql,
2141         undef,
2142         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2143     );
2144
2145     return @row ? $row[0]+1 : 1;
2146 }
2147
2148 =head2 IsItemOnHoldAndFound
2149
2150     my $bool = IsItemFoundHold( $itemnumber );
2151
2152     Returns true if the item is currently on hold
2153     and that hold has a non-null found status ( W, T, etc. )
2154
2155 =cut
2156
2157 sub IsItemOnHoldAndFound {
2158     my ($itemnumber) = @_;
2159
2160     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2161
2162     my $found = $rs->count(
2163         {
2164             itemnumber => $itemnumber,
2165             found      => { '!=' => undef }
2166         }
2167     );
2168
2169     return $found;
2170 }
2171
2172 =head2 GetMaxPatronHoldsForRecord
2173
2174 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2175
2176 For multiple holds on a given record for a given patron, the max
2177 number of record level holds that a patron can be placed is the highest
2178 value of the holds_per_record rule for each item if the record for that
2179 patron. This subroutine finds and returns the highest holds_per_record
2180 rule value for a given patron id and record id.
2181
2182 =cut
2183
2184 sub GetMaxPatronHoldsForRecord {
2185     my ( $borrowernumber, $biblionumber ) = @_;
2186
2187     my $patron = Koha::Patrons->find($borrowernumber);
2188     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2189
2190     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2191
2192     my $categorycode = $patron->categorycode;
2193     my $branchcode;
2194     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2195
2196     my $max = 0;
2197     foreach my $item (@items) {
2198         my $itemtype = $item->effective_itemtype();
2199
2200         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2201
2202         my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2203         my $holds_per_record = $rule ? $rule->{holds_per_record} : 0;
2204         $max = $holds_per_record if $holds_per_record > $max;
2205     }
2206
2207     return $max;
2208 }
2209
2210 =head2 GetHoldRule
2211
2212 my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2213
2214 Returns the matching hold related issuingrule fields for a given
2215 patron category, itemtype, and library.
2216
2217 =cut
2218
2219 sub GetHoldRule {
2220     my ( $categorycode, $itemtype, $branchcode ) = @_;
2221
2222     my $reservesallowed = Koha::CirculationRules->get_effective_rule(
2223         {
2224             itemtype     => $itemtype,
2225             categorycode => $categorycode,
2226             branchcode   => $branchcode,
2227             rule_name    => 'reservesallowed',
2228             order_by     => {
2229                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2230             }
2231         }
2232     );
2233
2234     my $rules;
2235     if ( $reservesallowed ) {
2236         $rules->{reservesallowed} = $reservesallowed->rule_value;
2237         $rules->{itemtype}        = $reservesallowed->itemtype;
2238         $rules->{categorycode}    = $reservesallowed->categorycode;
2239         $rules->{branchcode}      = $reservesallowed->branchcode;
2240     }
2241
2242     my $holds_per_x_rules = Koha::CirculationRules->get_effective_rules(
2243         {
2244             itemtype     => $itemtype,
2245             categorycode => $categorycode,
2246             branchcode   => $branchcode,
2247             rules        => ['holds_per_record', 'holds_per_day'],
2248             order_by     => {
2249                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2250             }
2251         }
2252     );
2253     $rules->{holds_per_record} = $holds_per_x_rules->{holds_per_record};
2254     $rules->{holds_per_day} = $holds_per_x_rules->{holds_per_day};
2255
2256     return $rules;
2257 }
2258
2259 =head1 AUTHOR
2260
2261 Koha Development Team <http://koha-community.org/>
2262
2263 =cut
2264
2265 1;