Koha/Checkout.pm

   1 package Koha::Checkout;
   2
   3 # Copyright ByWater Solutions 2015
   4 # Copyright 2016 Koha Development Team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use DateTime;
  24 use Try::Tiny qw( catch try );
  25
  26 use C4::Circulation qw( AddRenewal CanBookBeRenewed LostItem MarkIssueReturned );
  27 use Koha::Checkouts::Renewals;
  28 use Koha::Checkouts::ReturnClaims;
  29 use Koha::Database;
  30 use Koha::DateUtils qw( dt_from_string );
  31 use Koha::Items;
  32 use Koha::Libraries;
  33
  34 use base qw(Koha::Object);
  35
  36 =head1 NAME
  37
  38 Koha::Checkout - Koha Checkout object class
  39
  40 =head1 API
  41
  42 =head2 Class methods
  43
  44 =cut
  45
  46 =head3 is_overdue
  47
  48 my  $is_overdue = $checkout->is_overdue( [ $reference_dt ] );
  49
  50 Return 1 if the checkout is overdue.
  51
  52 A reference date can be passed, in this case it will be used, otherwise today
  53 will be the reference date.
  54
  55 =cut
  56
  57 sub is_overdue {
  58     my ( $self, $dt ) = @_;
  59     $dt ||= dt_from_string();
  60
  61     my $is_overdue =
  62       DateTime->compare( dt_from_string( $self->date_due, 'sql' ), $dt ) == -1
  63       ? 1
  64       : 0;
  65     return $is_overdue;
  66 }
  67
  68 =head3 item
  69
  70 my $item = $checkout->item;
  71
  72 Return the checked out item
  73
  74 =cut
  75
  76 sub item {
  77     my ( $self ) = @_;
  78     my $item_rs = $self->_result->item;
  79     return Koha::Item->_new_from_dbic( $item_rs );
  80 }
  81
  82 =head3 account_lines
  83
  84 my $account_lines = $checkout->account_lines;
  85
  86 Return the checked out account_lines
  87
  88 =cut
  89
  90 sub account_lines {
  91     my ( $self ) = @_;
  92     my $account_lines_rs = $self->_result->account_lines;
  93     return Koha::Account::Lines->_new_from_dbic( $account_lines_rs );
  94 }
  95
  96 =head3 library
  97
  98 my $library = $checkout->library;
  99
 100 Return the library in which the transaction took place
 101
 102 =cut
 103
 104 sub library {
 105     my ( $self ) = @_;
 106     my $library_rs = $self->_result->library;
 107     return Koha::Library->_new_from_dbic( $library_rs );
 108 }
 109
 110 =head3 patron
 111
 112 my $patron = $checkout->patron
 113
 114 Return the patron for who the checkout has been done
 115
 116 =cut
 117
 118 sub patron {
 119     my ( $self ) = @_;
 120     my $patron_rs = $self->_result->patron;
 121     return Koha::Patron->_new_from_dbic( $patron_rs );
 122 }
 123
 124 =head3 issuer
 125
 126 my $issuer = $checkout->issuer
 127
 128 Return the patron by whom the checkout was done
 129
 130 =cut
 131
 132 sub issuer {
 133     my ( $self ) = @_;
 134     my $issuer_rs = $self->_result->issuer;
 135     return unless $issuer_rs;
 136     return Koha::Patron->_new_from_dbic( $issuer_rs );
 137 }
 138
 139 =head3 renewals
 140
 141   my $renewals = $checkout->renewals;
 142
 143 Return a Koha::Checkouts::Renewals set attached to this checkout
 144
 145 =cut
 146
 147 sub renewals {
 148     my ( $self ) = @_;
 149     my $renewals_rs = $self->_result->renewals;
 150     return unless $renewals_rs;
 151     return Koha::Checkouts::Renewals->_new_from_dbic( $renewals_rs );
 152 }
 153
 154 =head3 attempt_auto_renew
 155
 156   my ($success, $error, $updated) = $checkout->auto_renew({ confirm => 1 });
 157
 158 Attempt to automatically renew a book. Return error reason if it cannot be renewed.
 159 Also return whether a change has been made to avoid notifying on more than one attempt.
 160
 161 If not passed confirm, we will only report and no changes will be made.
 162
 163 =cut
 164
 165 sub attempt_auto_renew {
 166     my ( $self, $params ) = @_;
 167     my $confirm = $params->{confirm} // 0;
 168
 169     # CanBookBeRenewed returns 'auto_renew' when the renewal should be done by this script
 170     my ( $ok, $error ) = C4::Circulation::CanBookBeRenewed( $self->patron, $self, undef, 1 );
 171     if ( $error eq 'auto_renew' ) {
 172         if ($confirm) {
 173             my $date_due = C4::Circulation::AddRenewal(
 174                 {
 175                     borrowernumber => $self->borrowernumber,
 176                     itemnumber     => $self->itemnumber,
 177                     branch         => $self->branchcode,
 178                     seen           => 0,
 179                     automatic      => 1,
 180                 }
 181             );
 182             $self->auto_renew_error(undef)->store;
 183         }
 184         return ( 1, undef, 1 );
 185     } else {
 186         my $updated = 0;
 187         if ( !$self->auto_renew_error || $error ne $self->auto_renew_error ) {
 188             $self->auto_renew_error($error)->store if $confirm;
 189             $updated = 1;
 190         }
 191         return ( 0, $error, $updated );
 192     }
 193
 194 }
 195
 196 =head3 to_api_mapping
 197
 198 This method returns the mapping for representing a Koha::Checkout object
 199 on the API.
 200
 201 =cut
 202
 203 sub to_api_mapping {
 204     return {
 205         issue_id        => 'checkout_id',
 206         borrowernumber  => 'patron_id',
 207         itemnumber      => 'item_id',
 208         date_due        => 'due_date',
 209         branchcode      => 'library_id',
 210         returndate      => 'checkin_date',
 211         lastreneweddate => 'last_renewed_date',
 212         issuedate       => 'checkout_date',
 213         notedate        => 'note_date',
 214         noteseen        => 'note_seen',
 215     };
 216 }
 217
 218 =head3 claim_returned
 219
 220   my $return_claim = $checkout->claim_returned();
 221
 222 This method sets the checkout as claimed return.  It will:
 223
 224 1.  Add a new row to the `return_claims` table
 225 2.  Set the item as lost using the 'ClaimReturnedLostValue'
 226 3.  Charge a fee depending on the value of ClaimReturnedChargeFee
 227 3a. If set to charge, then accruing overdues will be halted
 228 3b. If set to charge, then any existing transfers will be cancelled
 229     and the holding branch will be set back to 'frombranch'.
 230 4.  The issue will be marked as returned as per the 'MarkLostItemsAsReturned' preference
 231
 232 =cut
 233
 234 sub claim_returned {
 235     my ( $self, $params ) = @_;
 236
 237     my $charge_lost_fee = $params->{charge_lost_fee};
 238
 239     try {
 240         $self->_result->result_source->schema->txn_do(
 241             sub {
 242                 my $claim = Koha::Checkouts::ReturnClaim->new(
 243                     {
 244                         issue_id       => $self->id,
 245                         itemnumber     => $self->itemnumber,
 246                         borrowernumber => $self->borrowernumber,
 247                         notes          => $params->{notes},
 248                         created_by     => $params->{created_by},
 249                         created_on     => dt_from_string,
 250                     }
 251                 )->store();
 252
 253                 my $ClaimReturnedLostValue = C4::Context->preference('ClaimReturnedLostValue');
 254                 $self->item->itemlost($ClaimReturnedLostValue)->store;
 255
 256                 my $ClaimReturnedChargeFee = C4::Context->preference('ClaimReturnedChargeFee');
 257                 $charge_lost_fee =
 258                     $ClaimReturnedChargeFee eq 'charge'    ? 1
 259                 : $ClaimReturnedChargeFee eq 'no_charge' ? 0
 260                 :   $charge_lost_fee;    # $ClaimReturnedChargeFee eq 'ask'
 261
 262                 if ( $charge_lost_fee ) {
 263                     C4::Circulation::LostItem( $self->itemnumber, 'claim_returned' );
 264                 }
 265                 elsif ( C4::Context->preference( 'MarkLostItemsAsReturned' ) =~ m/claim_returned/ ) {
 266                     C4::Circulation::MarkIssueReturned( $self->borrowernumber, $self->itemnumber, undef, $self->patron->privacy );
 267                 }
 268
 269                 return $claim;
 270             }
 271         );
 272     }
 273     catch {
 274         if ( $_->isa('Koha::Exception') ) {
 275             $_->rethrow();
 276         }
 277         else {
 278             # ?
 279             Koha::Exception->throw( "Unhandled exception" );
 280         }
 281     };
 282 }
 283
 284 =head2 Internal methods
 285
 286 =head3 _type
 287
 288 =cut
 289
 290 sub _type {
 291     return 'Issue';
 292 }
 293
 294 =head1 AUTHOR
 295
 296 Kyle M Hall <kyle@bywatersolutions.com>
 297
 298 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 299
 300 =cut
 301
 302 1;