Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use List::MoreUtils qw( any uniq );
  25 use JSON qw( to_json );
  26 use Unicode::Normalize;
  27
  28 use C4::Context;
  29 use C4::Log;
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use Koha::AuthUtils;
  33 use Koha::Checkouts;
  34 use Koha::Club::Enrollments;
  35 use Koha::Database;
  36 use Koha::DateUtils;
  37 use Koha::Exceptions::Password;
  38 use Koha::Holds;
  39 use Koha::Old::Checkouts;
  40 use Koha::Patron::Attributes;
  41 use Koha::Patron::Categories;
  42 use Koha::Patron::HouseboundProfile;
  43 use Koha::Patron::HouseboundRole;
  44 use Koha::Patron::Images;
  45 use Koha::Patron::Modifications;
  46 use Koha::Patron::Relationships;
  47 use Koha::Patrons;
  48 use Koha::Plugins;
  49 use Koha::Subscription::Routinglists;
  50 use Koha::Token;
  51 use Koha::Virtualshelves;
  52
  53 use base qw(Koha::Object);
  54
  55 use constant ADMINISTRATIVE_LOCKOUT => -1;
  56
  57 our $RESULTSET_PATRON_ID_MAPPING = {
  58     Accountline          => 'borrowernumber',
  59     Aqbasketuser         => 'borrowernumber',
  60     Aqbudget             => 'budget_owner_id',
  61     Aqbudgetborrower     => 'borrowernumber',
  62     ArticleRequest       => 'borrowernumber',
  63     BorrowerAttribute    => 'borrowernumber',
  64     BorrowerDebarment    => 'borrowernumber',
  65     BorrowerFile         => 'borrowernumber',
  66     BorrowerModification => 'borrowernumber',
  67     ClubEnrollment       => 'borrowernumber',
  68     Issue                => 'borrowernumber',
  69     ItemsLastBorrower    => 'borrowernumber',
  70     Linktracker          => 'borrowernumber',
  71     Message              => 'borrowernumber',
  72     MessageQueue         => 'borrowernumber',
  73     OldIssue             => 'borrowernumber',
  74     OldReserve           => 'borrowernumber',
  75     Rating               => 'borrowernumber',
  76     Reserve              => 'borrowernumber',
  77     Review               => 'borrowernumber',
  78     SearchHistory        => 'userid',
  79     Statistic            => 'borrowernumber',
  80     Suggestion           => 'suggestedby',
  81     TagAll               => 'borrowernumber',
  82     Virtualshelfcontent  => 'borrowernumber',
  83     Virtualshelfshare    => 'borrowernumber',
  84     Virtualshelve        => 'owner',
  85 };
  86
  87 =head1 NAME
  88
  89 Koha::Patron - Koha Patron Object class
  90
  91 =head1 API
  92
  93 =head2 Class Methods
  94
  95 =head3 new
  96
  97 =cut
  98
  99 sub new {
 100     my ( $class, $params ) = @_;
 101
 102     return $class->SUPER::new($params);
 103 }
 104
 105 =head3 fixup_cardnumber
 106
 107 Autogenerate next cardnumber from highest value found in database
 108
 109 =cut
 110
 111 sub fixup_cardnumber {
 112     my ( $self ) = @_;
 113     my $max = Koha::Patrons->search({
 114         cardnumber => {-regexp => '^-?[0-9]+$'}
 115     }, {
 116         select => \'CAST(cardnumber AS SIGNED)',
 117         as => ['cast_cardnumber']
 118     })->_resultset->get_column('cast_cardnumber')->max;
 119     $self->cardnumber(($max || 0) +1);
 120 }
 121
 122 =head3 trim_whitespace
 123
 124 trim whitespace from data which has some non-whitespace in it.
 125 Could be moved to Koha::Object if need to be reused
 126
 127 =cut
 128
 129 sub trim_whitespaces {
 130     my( $self ) = @_;
 131
 132     my $schema  = Koha::Database->new->schema;
 133     my @columns = $schema->source($self->_type)->columns;
 134
 135     for my $column( @columns ) {
 136         my $value = $self->$column;
 137         if ( defined $value ) {
 138             $value =~ s/^\s*|\s*$//g;
 139             $self->$column($value);
 140         }
 141     }
 142     return $self;
 143 }
 144
 145 =head3 plain_text_password
 146
 147 $patron->plain_text_password( $password );
 148
 149 stores a copy of the unencrypted password in the object
 150 for use in code before encrypting for db
 151
 152 =cut
 153
 154 sub plain_text_password {
 155     my ( $self, $password ) = @_;
 156     if ( $password ) {
 157         $self->{_plain_text_password} = $password;
 158         return $self;
 159     }
 160     return $self->{_plain_text_password}
 161         if $self->{_plain_text_password};
 162
 163     return;
 164 }
 165
 166 =head3 store
 167
 168 Patron specific store method to cleanup record
 169 and do other necessary things before saving
 170 to db
 171
 172 =cut
 173
 174 sub store {
 175     my ($self) = @_;
 176
 177     $self->_result->result_source->schema->txn_do(
 178         sub {
 179             if (
 180                 C4::Context->preference("autoMemberNum")
 181                 and ( not defined $self->cardnumber
 182                     or $self->cardnumber eq '' )
 183               )
 184             {
 185                 # Warning: The caller is responsible for locking the members table in write
 186                 # mode, to avoid database corruption.
 187                 # We are in a transaction but the table is not locked
 188                 $self->fixup_cardnumber;
 189             }
 190
 191             unless( $self->category->in_storage ) {
 192                 Koha::Exceptions::Object::FKConstraint->throw(
 193                     broken_fk => 'categorycode',
 194                     value     => $self->categorycode,
 195                 );
 196             }
 197
 198             $self->trim_whitespaces;
 199
 200             # Set surname to uppercase if uppercasesurname is true
 201             $self->surname( uc($self->surname) )
 202                 if C4::Context->preference("uppercasesurnames");
 203
 204             $self->relationship(undef) # We do not want to store an empty string in this field
 205               if defined $self->relationship
 206                      and $self->relationship eq "";
 207
 208             unless ( $self->in_storage ) {    #AddMember
 209
 210                 # Generate a valid userid/login if needed
 211                 $self->generate_userid
 212                   if not $self->userid or not $self->has_valid_userid;
 213
 214                 # Add expiration date if it isn't already there
 215                 unless ( $self->dateexpiry ) {
 216                     $self->dateexpiry( $self->category->get_expiry_date );
 217                 }
 218
 219                 # Add enrollment date if it isn't already there
 220                 unless ( $self->dateenrolled ) {
 221                     $self->dateenrolled(dt_from_string);
 222                 }
 223
 224                 # Set the privacy depending on the patron's category
 225                 my $default_privacy = $self->category->default_privacy || q{};
 226                 $default_privacy =
 227                     $default_privacy eq 'default' ? 1
 228                   : $default_privacy eq 'never'   ? 2
 229                   : $default_privacy eq 'forever' ? 0
 230                   :                                                   undef;
 231                 $self->privacy($default_privacy);
 232
 233                 # Call any check_password plugins if password is passed
 234                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 235                     my @plugins = Koha::Plugins->new()->GetPlugins({
 236                         method => 'check_password',
 237                     });
 238                     foreach my $plugin ( @plugins ) {
 239                         # This plugin hook will also be used by a plugin for the Norwegian national
 240                         # patron database. This is why we need to pass both the password and the
 241                         # borrowernumber to the plugin.
 242                         my $ret = $plugin->check_password(
 243                             {
 244                                 password       => $self->password,
 245                                 borrowernumber => $self->borrowernumber
 246                             }
 247                         );
 248                         if ( $ret->{'error'} == 1 ) {
 249                             Koha::Exceptions::Password::Plugin->throw();
 250                         }
 251                     }
 252                 }
 253
 254                 # Make a copy of the plain text password for later use
 255                 $self->plain_text_password( $self->password );
 256
 257                 # Create a disabled account if no password provided
 258                 $self->password( $self->password
 259                     ? Koha::AuthUtils::hash_password( $self->password )
 260                     : '!' );
 261
 262                 $self->borrowernumber(undef);
 263
 264                 $self = $self->SUPER::store;
 265
 266                 $self->add_enrolment_fee_if_needed(0);
 267
 268                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 269                   if C4::Context->preference("BorrowersLog");
 270             }
 271             else {    #ModMember
 272
 273                 my $self_from_storage = $self->get_from_storage;
 274                 # FIXME We should not deal with that here, callers have to do this job
 275                 # Moved from ModMember to prevent regressions
 276                 unless ( $self->userid ) {
 277                     my $stored_userid = $self_from_storage->userid;
 278                     $self->userid($stored_userid);
 279                 }
 280
 281                 # Password must be updated using $self->set_password
 282                 $self->password($self_from_storage->password);
 283
 284                 if ( $self->category->categorycode ne
 285                     $self_from_storage->category->categorycode )
 286                 {
 287                     # Add enrolement fee on category change if required
 288                     $self->add_enrolment_fee_if_needed(1)
 289                       if C4::Context->preference('FeeOnChangePatronCategory');
 290
 291                     # Clean up guarantors on category change if required
 292                     $self->guarantor_relationships->delete
 293                       if ( $self->category->category_type ne 'C'
 294                         && $self->category->category_type ne 'P' );
 295
 296                 }
 297
 298                 # Actionlogs
 299                 if ( C4::Context->preference("BorrowersLog") ) {
 300                     my $info;
 301                     my $from_storage = $self_from_storage->unblessed;
 302                     my $from_object  = $self->unblessed;
 303                     my @skip_fields  = (qw/lastseen updated_on/);
 304                     for my $key ( keys %{$from_storage} ) {
 305                         next if any { /$key/ } @skip_fields;
 306                         if (
 307                             (
 308                                   !defined( $from_storage->{$key} )
 309                                 && defined( $from_object->{$key} )
 310                             )
 311                             || ( defined( $from_storage->{$key} )
 312                                 && !defined( $from_object->{$key} ) )
 313                             || (
 314                                    defined( $from_storage->{$key} )
 315                                 && defined( $from_object->{$key} )
 316                                 && ( $from_storage->{$key} ne
 317                                     $from_object->{$key} )
 318                             )
 319                           )
 320                         {
 321                             $info->{$key} = {
 322                                 before => $from_storage->{$key},
 323                                 after  => $from_object->{$key}
 324                             };
 325                         }
 326                     }
 327
 328                     if ( defined($info) ) {
 329                         logaction(
 330                             "MEMBERS",
 331                             "MODIFY",
 332                             $self->borrowernumber,
 333                             to_json(
 334                                 $info,
 335                                 { utf8 => 1, pretty => 1, canonical => 1 }
 336                             )
 337                         );
 338                     }
 339                 }
 340
 341                 # Final store
 342                 $self = $self->SUPER::store;
 343             }
 344         }
 345     );
 346     return $self;
 347 }
 348
 349 =head3 delete
 350
 351 $patron->delete
 352
 353 Delete patron's holds, lists and finally the patron.
 354
 355 Lists owned by the borrower are deleted, but entries from the borrower to
 356 other lists are kept.
 357
 358 =cut
 359
 360 sub delete {
 361     my ($self) = @_;
 362
 363     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 364     return $self if $anonymous_patron && $self->id eq $anonymous_patron;
 365
 366     $self->_result->result_source->schema->txn_do(
 367         sub {
 368             # Cancel Patron's holds
 369             my $holds = $self->holds;
 370             while( my $hold = $holds->next ){
 371                 $hold->cancel;
 372             }
 373
 374             # Delete all lists and all shares of this borrower
 375             # Consistent with the approach Koha uses on deleting individual lists
 376             # Note that entries in virtualshelfcontents added by this borrower to
 377             # lists of others will be handled by a table constraint: the borrower
 378             # is set to NULL in those entries.
 379             # NOTE:
 380             # We could handle the above deletes via a constraint too.
 381             # But a new BZ report 11889 has been opened to discuss another approach.
 382             # Instead of deleting we could also disown lists (based on a pref).
 383             # In that way we could save shared and public lists.
 384             # The current table constraints support that idea now.
 385             # This pref should then govern the results of other routines/methods such as
 386             # Koha::Virtualshelf->new->delete too.
 387             # FIXME Could be $patron->get_lists
 388             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } );
 389
 390             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 391             # for patron selfreg
 392             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } );
 393
 394             $self->SUPER::delete;
 395
 396             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 397         }
 398     );
 399     return $self;
 400 }
 401
 402
 403 =head3 category
 404
 405 my $patron_category = $patron->category
 406
 407 Return the patron category for this patron
 408
 409 =cut
 410
 411 sub category {
 412     my ( $self ) = @_;
 413     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 414 }
 415
 416 =head3 image
 417
 418 =cut
 419
 420 sub image {
 421     my ( $self ) = @_;
 422
 423     return Koha::Patron::Images->find( $self->borrowernumber );
 424 }
 425
 426 =head3 library
 427
 428 Returns a Koha::Library object representing the patron's home library.
 429
 430 =cut
 431
 432 sub library {
 433     my ( $self ) = @_;
 434     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 435 }
 436
 437 =head3 sms_provider
 438
 439 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 440
 441 =cut
 442
 443 sub sms_provider {
 444     my ( $self ) = @_;
 445     my $sms_provider_rs = $self->_result->sms_provider;
 446     return unless $sms_provider_rs;
 447     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 448 }
 449
 450 =head3 guarantor_relationships
 451
 452 Returns Koha::Patron::Relationships object for this patron's guarantors
 453
 454 Returns the set of relationships for the patrons that are guarantors for this patron.
 455
 456 This is returned instead of a Koha::Patron object because the guarantor
 457 may not exist as a patron in Koha. If this is true, the guarantors name
 458 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 459
 460 =cut
 461
 462 sub guarantor_relationships {
 463     my ($self) = @_;
 464
 465     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 466 }
 467
 468 =head3 guarantee_relationships
 469
 470 Returns Koha::Patron::Relationships object for this patron's guarantors
 471
 472 Returns the set of relationships for the patrons that are guarantees for this patron.
 473
 474 The method returns Koha::Patron::Relationship objects for the sake
 475 of consistency with the guantors method.
 476 A guarantee by definition must exist as a patron in Koha.
 477
 478 =cut
 479
 480 sub guarantee_relationships {
 481     my ($self) = @_;
 482
 483     return Koha::Patron::Relationships->search(
 484         { guarantor_id => $self->id },
 485         {
 486             prefetch => 'guarantee',
 487             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 488         }
 489     );
 490 }
 491
 492 =head3 relationships_debt
 493
 494 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 495
 496 =cut
 497
 498 sub relationships_debt {
 499     my ($self, $params) = @_;
 500
 501     my $include_guarantors  = $params->{include_guarantors};
 502     my $only_this_guarantor = $params->{only_this_guarantor};
 503     my $include_this_patron = $params->{include_this_patron};
 504
 505     my @guarantors;
 506     if ( $only_this_guarantor ) {
 507         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 508         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 509     } elsif ( $self->guarantor_relationships->count ) {
 510         # I am a guarantee, just get all my guarantors
 511         @guarantors = $self->guarantor_relationships->guarantors;
 512     } else {
 513         # I am a guarantor, I need to get all the guarantors of all my guarantees
 514         @guarantors = map { $_->guarantor_relationships->guarantors } $self->guarantee_relationships->guarantees;
 515     }
 516
 517     my $non_issues_charges = 0;
 518     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 519     foreach my $guarantor (@guarantors) {
 520         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 521
 522         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 523         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships();
 524         my $guarantees_non_issues_charges = 0;
 525         foreach my $guarantee (@guarantees) {
 526             next if $seen->{ $guarantee->id };
 527             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 528             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 529             $seen->{ $guarantee->id } = 1;
 530         }
 531
 532         $non_issues_charges += $guarantees_non_issues_charges;
 533         $seen->{ $guarantor->id } = 1;
 534     }
 535
 536     return $non_issues_charges;
 537 }
 538
 539 =head3 housebound_profile
 540
 541 Returns the HouseboundProfile associated with this patron.
 542
 543 =cut
 544
 545 sub housebound_profile {
 546     my ( $self ) = @_;
 547     my $profile = $self->_result->housebound_profile;
 548     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 549         if ( $profile );
 550     return;
 551 }
 552
 553 =head3 housebound_role
 554
 555 Returns the HouseboundRole associated with this patron.
 556
 557 =cut
 558
 559 sub housebound_role {
 560     my ( $self ) = @_;
 561
 562     my $role = $self->_result->housebound_role;
 563     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 564     return;
 565 }
 566
 567 =head3 siblings
 568
 569 Returns the siblings of this patron.
 570
 571 =cut
 572
 573 sub siblings {
 574     my ($self) = @_;
 575
 576     my @guarantors = $self->guarantor_relationships()->guarantors();
 577
 578     return unless @guarantors;
 579
 580     my @siblings =
 581       map { $_->guarantee_relationships()->guarantees() } @guarantors;
 582
 583     return unless @siblings;
 584
 585     my %seen;
 586     @siblings =
 587       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 588
 589     return wantarray ? @siblings : Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 590 }
 591
 592 =head3 merge_with
 593
 594     my $patron = Koha::Patrons->find($id);
 595     $patron->merge_with( \@patron_ids );
 596
 597     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 598     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 599     of the keeper patron.
 600
 601 =cut
 602
 603 sub merge_with {
 604     my ( $self, $patron_ids ) = @_;
 605
 606     my @patron_ids = @{ $patron_ids };
 607
 608     # Ensure the keeper isn't in the list of patrons to merge
 609     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 610
 611     my $schema = Koha::Database->new()->schema();
 612
 613     my $results;
 614
 615     $self->_result->result_source->schema->txn_do( sub {
 616         foreach my $patron_id (@patron_ids) {
 617             my $patron = Koha::Patrons->find( $patron_id );
 618
 619             next unless $patron;
 620
 621             # Unbless for safety, the patron will end up being deleted
 622             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 623
 624             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 625                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 626                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 627                 $rs->update({ $field => $self->id });
 628             }
 629
 630             $patron->move_to_deleted();
 631             $patron->delete();
 632         }
 633     });
 634
 635     return $results;
 636 }
 637
 638
 639
 640 =head3 wants_check_for_previous_checkout
 641
 642     $wants_check = $patron->wants_check_for_previous_checkout;
 643
 644 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 645
 646 =cut
 647
 648 sub wants_check_for_previous_checkout {
 649     my ( $self ) = @_;
 650     my $syspref = C4::Context->preference("checkPrevCheckout");
 651
 652     # Simple cases
 653     ## Hard syspref trumps all
 654     return 1 if ($syspref eq 'hardyes');
 655     return 0 if ($syspref eq 'hardno');
 656     ## Now, patron pref trumps all
 657     return 1 if ($self->checkprevcheckout eq 'yes');
 658     return 0 if ($self->checkprevcheckout eq 'no');
 659
 660     # More complex: patron inherits -> determine category preference
 661     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 662     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 663     return 0 if ($checkPrevCheckoutByCat eq 'no');
 664
 665     # Finally: category preference is inherit, default to 0
 666     if ($syspref eq 'softyes') {
 667         return 1;
 668     } else {
 669         return 0;
 670     }
 671 }
 672
 673 =head3 do_check_for_previous_checkout
 674
 675     $do_check = $patron->do_check_for_previous_checkout($item);
 676
 677 Return 1 if the bib associated with $ITEM has previously been checked out to
 678 $PATRON, 0 otherwise.
 679
 680 =cut
 681
 682 sub do_check_for_previous_checkout {
 683     my ( $self, $item ) = @_;
 684
 685     my @item_nos;
 686     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 687     if ( $biblio->is_serial ) {
 688         push @item_nos, $item->{itemnumber};
 689     } else {
 690         # Get all itemnumbers for given bibliographic record.
 691         @item_nos = $biblio->items->get_column( 'itemnumber' );
 692     }
 693
 694     # Create (old)issues search criteria
 695     my $criteria = {
 696         borrowernumber => $self->borrowernumber,
 697         itemnumber => \@item_nos,
 698     };
 699
 700     # Check current issues table
 701     my $issues = Koha::Checkouts->search($criteria);
 702     return 1 if $issues->count; # 0 || N
 703
 704     # Check old issues table
 705     my $old_issues = Koha::Old::Checkouts->search($criteria);
 706     return $old_issues->count;  # 0 || N
 707 }
 708
 709 =head3 is_debarred
 710
 711 my $debarment_expiration = $patron->is_debarred;
 712
 713 Returns the date a patron debarment will expire, or undef if the patron is not
 714 debarred
 715
 716 =cut
 717
 718 sub is_debarred {
 719     my ($self) = @_;
 720
 721     return unless $self->debarred;
 722     return $self->debarred
 723       if $self->debarred =~ '^9999'
 724       or dt_from_string( $self->debarred ) > dt_from_string;
 725     return;
 726 }
 727
 728 =head3 is_expired
 729
 730 my $is_expired = $patron->is_expired;
 731
 732 Returns 1 if the patron is expired or 0;
 733
 734 =cut
 735
 736 sub is_expired {
 737     my ($self) = @_;
 738     return 0 unless $self->dateexpiry;
 739     return 0 if $self->dateexpiry =~ '^9999';
 740     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 741     return 0;
 742 }
 743
 744 =head3 is_going_to_expire
 745
 746 my $is_going_to_expire = $patron->is_going_to_expire;
 747
 748 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 749
 750 =cut
 751
 752 sub is_going_to_expire {
 753     my ($self) = @_;
 754
 755     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 756
 757     return 0 unless $delay;
 758     return 0 unless $self->dateexpiry;
 759     return 0 if $self->dateexpiry =~ '^9999';
 760     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 761     return 0;
 762 }
 763
 764 =head3 set_password
 765
 766     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 767
 768 Set the patron's password.
 769
 770 =head4 Exceptions
 771
 772 The passed string is validated against the current password enforcement policy.
 773 Validation can be skipped by passing the I<skip_validation> parameter.
 774
 775 Exceptions are thrown if the password is not good enough.
 776
 777 =over 4
 778
 779 =item Koha::Exceptions::Password::TooShort
 780
 781 =item Koha::Exceptions::Password::WhitespaceCharacters
 782
 783 =item Koha::Exceptions::Password::TooWeak
 784
 785 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 786
 787 =back
 788
 789 =cut
 790
 791 sub set_password {
 792     my ( $self, $args ) = @_;
 793
 794     my $password = $args->{password};
 795
 796     unless ( $args->{skip_validation} ) {
 797         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 798
 799         if ( !$is_valid ) {
 800             if ( $error eq 'too_short' ) {
 801                 my $min_length = $self->category->effective_min_password_length;
 802                 $min_length = 3 if not $min_length or $min_length < 3;
 803
 804                 my $password_length = length($password);
 805                 Koha::Exceptions::Password::TooShort->throw(
 806                     length => $password_length, min_length => $min_length );
 807             }
 808             elsif ( $error eq 'has_whitespaces' ) {
 809                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 810             }
 811             elsif ( $error eq 'too_weak' ) {
 812                 Koha::Exceptions::Password::TooWeak->throw();
 813             }
 814         }
 815     }
 816
 817     if ( C4::Context->config("enable_plugins") ) {
 818         # Call any check_password plugins
 819         my @plugins = Koha::Plugins->new()->GetPlugins({
 820             method => 'check_password',
 821         });
 822         foreach my $plugin ( @plugins ) {
 823             # This plugin hook will also be used by a plugin for the Norwegian national
 824             # patron database. This is why we need to pass both the password and the
 825             # borrowernumber to the plugin.
 826             my $ret = $plugin->check_password(
 827                 {
 828                     password       => $password,
 829                     borrowernumber => $self->borrowernumber
 830                 }
 831             );
 832             # This plugin hook will also be used by a plugin for the Norwegian national
 833             # patron database. This is why we need to call the actual plugins and then
 834             # check skip_validation afterwards.
 835             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 836                 Koha::Exceptions::Password::Plugin->throw();
 837             }
 838         }
 839     }
 840
 841     my $digest = Koha::AuthUtils::hash_password($password);
 842
 843     # We do not want to call $self->store and retrieve password from DB
 844     $self->password($digest);
 845     $self->login_attempts(0);
 846     $self->SUPER::store;
 847
 848     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 849         if C4::Context->preference("BorrowersLog");
 850
 851     return $self;
 852 }
 853
 854
 855 =head3 renew_account
 856
 857 my $new_expiry_date = $patron->renew_account
 858
 859 Extending the subscription to the expiry date.
 860
 861 =cut
 862
 863 sub renew_account {
 864     my ($self) = @_;
 865     my $date;
 866     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 867         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 868     } else {
 869         $date =
 870             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 871             ? dt_from_string( $self->dateexpiry )
 872             : dt_from_string;
 873     }
 874     my $expiry_date = $self->category->get_expiry_date($date);
 875
 876     $self->dateexpiry($expiry_date);
 877     $self->date_renewed( dt_from_string() );
 878     $self->store();
 879
 880     $self->add_enrolment_fee_if_needed(1);
 881
 882     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 883     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 884 }
 885
 886 =head3 has_overdues
 887
 888 my $has_overdues = $patron->has_overdues;
 889
 890 Returns the number of patron's overdues
 891
 892 =cut
 893
 894 sub has_overdues {
 895     my ($self) = @_;
 896     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 897     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 898 }
 899
 900 =head3 track_login
 901
 902     $patron->track_login;
 903     $patron->track_login({ force => 1 });
 904
 905     Tracks a (successful) login attempt.
 906     The preference TrackLastPatronActivity must be enabled. Or you
 907     should pass the force parameter.
 908
 909 =cut
 910
 911 sub track_login {
 912     my ( $self, $params ) = @_;
 913     return if
 914         !$params->{force} &&
 915         !C4::Context->preference('TrackLastPatronActivity');
 916     $self->lastseen( dt_from_string() )->store;
 917 }
 918
 919 =head3 move_to_deleted
 920
 921 my $is_moved = $patron->move_to_deleted;
 922
 923 Move a patron to the deletedborrowers table.
 924 This can be done before deleting a patron, to make sure the data are not completely deleted.
 925
 926 =cut
 927
 928 sub move_to_deleted {
 929     my ($self) = @_;
 930     my $patron_infos = $self->unblessed;
 931     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 932     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 933 }
 934
 935 =head3 article_requests
 936
 937 my @requests = $borrower->article_requests();
 938 my $requests = $borrower->article_requests();
 939
 940 Returns either a list of ArticleRequests objects,
 941 or an ArtitleRequests object, depending on the
 942 calling context.
 943
 944 =cut
 945
 946 sub article_requests {
 947     my ( $self ) = @_;
 948
 949     $self->{_article_requests} ||= Koha::ArticleRequests->search({ borrowernumber => $self->borrowernumber() });
 950
 951     return $self->{_article_requests};
 952 }
 953
 954 =head3 article_requests_current
 955
 956 my @requests = $patron->article_requests_current
 957
 958 Returns the article requests associated with this patron that are incomplete
 959
 960 =cut
 961
 962 sub article_requests_current {
 963     my ( $self ) = @_;
 964
 965     $self->{_article_requests_current} ||= Koha::ArticleRequests->search(
 966         {
 967             borrowernumber => $self->id(),
 968             -or          => [
 969                 { status => Koha::ArticleRequest::Status::Pending },
 970                 { status => Koha::ArticleRequest::Status::Processing }
 971             ]
 972         }
 973     );
 974
 975     return $self->{_article_requests_current};
 976 }
 977
 978 =head3 article_requests_finished
 979
 980 my @requests = $biblio->article_requests_finished
 981
 982 Returns the article requests associated with this patron that are completed
 983
 984 =cut
 985
 986 sub article_requests_finished {
 987     my ( $self, $borrower ) = @_;
 988
 989     $self->{_article_requests_finished} ||= Koha::ArticleRequests->search(
 990         {
 991             borrowernumber => $self->id(),
 992             -or          => [
 993                 { status => Koha::ArticleRequest::Status::Completed },
 994                 { status => Koha::ArticleRequest::Status::Canceled }
 995             ]
 996         }
 997     );
 998
 999     return $self->{_article_requests_finished};
1000 }
1001
1002 =head3 add_enrolment_fee_if_needed
1003
1004 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1005
1006 Add enrolment fee for a patron if needed.
1007
1008 $renewal - boolean denoting whether this is an account renewal or not
1009
1010 =cut
1011
1012 sub add_enrolment_fee_if_needed {
1013     my ($self, $renewal) = @_;
1014     my $enrolment_fee = $self->category->enrolmentfee;
1015     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1016         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1017         $self->account->add_debit(
1018             {
1019                 amount     => $enrolment_fee,
1020                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1021                 interface  => C4::Context->interface,
1022                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1023                 type       => $type
1024             }
1025         );
1026     }
1027     return $enrolment_fee || 0;
1028 }
1029
1030 =head3 checkouts
1031
1032 my $checkouts = $patron->checkouts
1033
1034 =cut
1035
1036 sub checkouts {
1037     my ($self) = @_;
1038     my $checkouts = $self->_result->issues;
1039     return Koha::Checkouts->_new_from_dbic( $checkouts );
1040 }
1041
1042 =head3 pending_checkouts
1043
1044 my $pending_checkouts = $patron->pending_checkouts
1045
1046 This method will return the same as $self->checkouts, but with a prefetch on
1047 items, biblio and biblioitems.
1048
1049 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1050
1051 It should not be used directly, prefer to access fields you need instead of
1052 retrieving all these fields in one go.
1053
1054 =cut
1055
1056 sub pending_checkouts {
1057     my( $self ) = @_;
1058     my $checkouts = $self->_result->issues->search(
1059         {},
1060         {
1061             order_by => [
1062                 { -desc => 'me.timestamp' },
1063                 { -desc => 'issuedate' },
1064                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1065             ],
1066             prefetch => { item => { biblio => 'biblioitems' } },
1067         }
1068     );
1069     return Koha::Checkouts->_new_from_dbic( $checkouts );
1070 }
1071
1072 =head3 old_checkouts
1073
1074 my $old_checkouts = $patron->old_checkouts
1075
1076 =cut
1077
1078 sub old_checkouts {
1079     my ($self) = @_;
1080     my $old_checkouts = $self->_result->old_issues;
1081     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1082 }
1083
1084 =head3 get_overdues
1085
1086 my $overdue_items = $patron->get_overdues
1087
1088 Return the overdue items
1089
1090 =cut
1091
1092 sub get_overdues {
1093     my ($self) = @_;
1094     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1095     return $self->checkouts->search(
1096         {
1097             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1098         },
1099         {
1100             prefetch => { item => { biblio => 'biblioitems' } },
1101         }
1102     );
1103 }
1104
1105 =head3 get_routing_lists
1106
1107 my @routinglists = $patron->get_routing_lists
1108
1109 Returns the routing lists a patron is subscribed to.
1110
1111 =cut
1112
1113 sub get_routing_lists {
1114     my ($self) = @_;
1115     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1116     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1117 }
1118
1119 =head3 get_age
1120
1121 my $age = $patron->get_age
1122
1123 Return the age of the patron
1124
1125 =cut
1126
1127 sub get_age {
1128     my ($self)    = @_;
1129     my $today_str = dt_from_string->strftime("%Y-%m-%d");
1130     return unless $self->dateofbirth;
1131     my $dob_str   = dt_from_string( $self->dateofbirth )->strftime("%Y-%m-%d");
1132
1133     my ( $dob_y,   $dob_m,   $dob_d )   = split /-/, $dob_str;
1134     my ( $today_y, $today_m, $today_d ) = split /-/, $today_str;
1135
1136     my $age = $today_y - $dob_y;
1137     if ( $dob_m . $dob_d > $today_m . $today_d ) {
1138         $age--;
1139     }
1140
1141     return $age;
1142 }
1143
1144 =head3 is_valid_age
1145
1146 my $is_valid = $patron->is_valid_age
1147
1148 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1149
1150 =cut
1151
1152 sub is_valid_age {
1153     my ($self) = @_;
1154     my $age = $self->get_age;
1155
1156     my $patroncategory = $self->category;
1157     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1158
1159     return (defined($age) && (($high && ($age > $high)) or ($age < $low))) ? 0 : 1;
1160 }
1161
1162 =head3 account
1163
1164 my $account = $patron->account
1165
1166 =cut
1167
1168 sub account {
1169     my ($self) = @_;
1170     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1171 }
1172
1173 =head3 holds
1174
1175 my $holds = $patron->holds
1176
1177 Return all the holds placed by this patron
1178
1179 =cut
1180
1181 sub holds {
1182     my ($self) = @_;
1183     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1184     return Koha::Holds->_new_from_dbic($holds_rs);
1185 }
1186
1187 =head3 old_holds
1188
1189 my $old_holds = $patron->old_holds
1190
1191 Return all the historical holds for this patron
1192
1193 =cut
1194
1195 sub old_holds {
1196     my ($self) = @_;
1197     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1198     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1199 }
1200
1201 =head3 return_claims
1202
1203 my $return_claims = $patron->return_claims
1204
1205 =cut
1206
1207 sub return_claims {
1208     my ($self) = @_;
1209     my $return_claims = $self->_result->return_claims_borrowernumbers;
1210     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1211 }
1212
1213 =head3 notice_email_address
1214
1215   my $email = $patron->notice_email_address;
1216
1217 Return the email address of patron used for notices.
1218 Returns the empty string if no email address.
1219
1220 =cut
1221
1222 sub notice_email_address{
1223     my ( $self ) = @_;
1224
1225     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1226     # if syspref is set to 'first valid' (value == OFF), look up email address
1227     if ( $which_address eq 'OFF' ) {
1228         return $self->first_valid_email_address;
1229     }
1230
1231     return $self->$which_address || '';
1232 }
1233
1234 =head3 first_valid_email_address
1235
1236 my $first_valid_email_address = $patron->first_valid_email_address
1237
1238 Return the first valid email address for a patron.
1239 For now, the order  is defined as email, emailpro, B_email.
1240 Returns the empty string if the borrower has no email addresses.
1241
1242 =cut
1243
1244 sub first_valid_email_address {
1245     my ($self) = @_;
1246
1247     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1248 }
1249
1250 =head3 get_club_enrollments
1251
1252 =cut
1253
1254 sub get_club_enrollments {
1255     my ( $self, $return_scalar ) = @_;
1256
1257     my $e = Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1258
1259     return $e if $return_scalar;
1260
1261     return wantarray ? $e->as_list : $e;
1262 }
1263
1264 =head3 get_enrollable_clubs
1265
1266 =cut
1267
1268 sub get_enrollable_clubs {
1269     my ( $self, $is_enrollable_from_opac, $return_scalar ) = @_;
1270
1271     my $params;
1272     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1273       if $is_enrollable_from_opac;
1274     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1275
1276     $params->{borrower} = $self;
1277
1278     my $e = Koha::Clubs->get_enrollable($params);
1279
1280     return $e if $return_scalar;
1281
1282     return wantarray ? $e->as_list : $e;
1283 }
1284
1285 =head3 account_locked
1286
1287 my $is_locked = $patron->account_locked
1288
1289 Return true if the patron has reached the maximum number of login attempts
1290 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1291 as an administrative lockout (independent of FailedLoginAttempts; see also
1292 Koha::Patron->lock).
1293 Otherwise return false.
1294 If the pref is not set (empty string, null or 0), the feature is considered as
1295 disabled.
1296
1297 =cut
1298
1299 sub account_locked {
1300     my ($self) = @_;
1301     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1302     return 1 if $FailedLoginAttempts
1303           and $self->login_attempts
1304           and $self->login_attempts >= $FailedLoginAttempts;
1305     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1306     return 0;
1307 }
1308
1309 =head3 can_see_patron_infos
1310
1311 my $can_see = $patron->can_see_patron_infos( $patron );
1312
1313 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1314
1315 =cut
1316
1317 sub can_see_patron_infos {
1318     my ( $self, $patron ) = @_;
1319     return unless $patron;
1320     return $self->can_see_patrons_from( $patron->library->branchcode );
1321 }
1322
1323 =head3 can_see_patrons_from
1324
1325 my $can_see = $patron->can_see_patrons_from( $branchcode );
1326
1327 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1328
1329 =cut
1330
1331 sub can_see_patrons_from {
1332     my ( $self, $branchcode ) = @_;
1333     my $can = 0;
1334     if ( $self->branchcode eq $branchcode ) {
1335         $can = 1;
1336     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1337         $can = 1;
1338     } elsif ( my $library_groups = $self->library->library_groups ) {
1339         while ( my $library_group = $library_groups->next ) {
1340             if ( $library_group->parent->has_child( $branchcode ) ) {
1341                 $can = 1;
1342                 last;
1343             }
1344         }
1345     }
1346     return $can;
1347 }
1348
1349 =head3 libraries_where_can_see_patrons
1350
1351 my $libraries = $patron-libraries_where_can_see_patrons;
1352
1353 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1354 The branchcodes are arbitrarily returned sorted.
1355 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1356
1357 An empty array means no restriction, the patron can see patron's infos from any libraries.
1358
1359 =cut
1360
1361 sub libraries_where_can_see_patrons {
1362     my ( $self ) = @_;
1363     my $userenv = C4::Context->userenv;
1364
1365     return () unless $userenv; # For tests, but userenv should be defined in tests...
1366
1367     my @restricted_branchcodes;
1368     if (C4::Context::only_my_library) {
1369         push @restricted_branchcodes, $self->branchcode;
1370     }
1371     else {
1372         unless (
1373             $self->has_permission(
1374                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1375             )
1376           )
1377         {
1378             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1379             if ( $library_groups->count )
1380             {
1381                 while ( my $library_group = $library_groups->next ) {
1382                     my $parent = $library_group->parent;
1383                     if ( $parent->has_child( $self->branchcode ) ) {
1384                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1385                     }
1386                 }
1387             }
1388
1389             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1390         }
1391     }
1392
1393     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1394     @restricted_branchcodes = uniq(@restricted_branchcodes);
1395     @restricted_branchcodes = sort(@restricted_branchcodes);
1396     return @restricted_branchcodes;
1397 }
1398
1399 =head3 has_permission
1400
1401 my $permission = $patron->has_permission($required);
1402
1403 See C4::Auth::haspermission for details of syntax for $required
1404
1405 =cut
1406
1407 sub has_permission {
1408     my ( $self, $flagsrequired ) = @_;
1409     return unless $self->userid;
1410     # TODO code from haspermission needs to be moved here!
1411     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1412 }
1413
1414 =head3 is_superlibrarian
1415
1416   my $is_superlibrarian = $patron->is_superlibrarian;
1417
1418 Return true if the patron is a superlibrarian.
1419
1420 =cut
1421
1422 sub is_superlibrarian {
1423     my ($self) = @_;
1424     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1425 }
1426
1427 =head3 is_adult
1428
1429 my $is_adult = $patron->is_adult
1430
1431 Return true if the patron has a category with a type Adult (A) or Organization (I)
1432
1433 =cut
1434
1435 sub is_adult {
1436     my ( $self ) = @_;
1437     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1438 }
1439
1440 =head3 is_child
1441
1442 my $is_child = $patron->is_child
1443
1444 Return true if the patron has a category with a type Child (C)
1445
1446 =cut
1447
1448 sub is_child {
1449     my( $self ) = @_;
1450     return $self->category->category_type eq 'C' ? 1 : 0;
1451 }
1452
1453 =head3 has_valid_userid
1454
1455 my $patron = Koha::Patrons->find(42);
1456 $patron->userid( $new_userid );
1457 my $has_a_valid_userid = $patron->has_valid_userid
1458
1459 my $patron = Koha::Patron->new( $params );
1460 my $has_a_valid_userid = $patron->has_valid_userid
1461
1462 Return true if the current userid of this patron is valid/unique, otherwise false.
1463
1464 Note that this should be done in $self->store instead and raise an exception if needed.
1465
1466 =cut
1467
1468 sub has_valid_userid {
1469     my ($self) = @_;
1470
1471     return 0 unless $self->userid;
1472
1473     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1474
1475     my $already_exists = Koha::Patrons->search(
1476         {
1477             userid => $self->userid,
1478             (
1479                 $self->in_storage
1480                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1481                 : ()
1482             ),
1483         }
1484     )->count;
1485     return $already_exists ? 0 : 1;
1486 }
1487
1488 =head3 generate_userid
1489
1490 my $patron = Koha::Patron->new( $params );
1491 $patron->generate_userid
1492
1493 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1494
1495 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1496
1497 =cut
1498
1499 sub generate_userid {
1500     my ($self) = @_;
1501     my $offset = 0;
1502     my $firstname = $self->firstname // q{};
1503     my $surname = $self->surname // q{};
1504     #The script will "do" the following code and increment the $offset until the generated userid is unique
1505     do {
1506       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1507       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1508       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1509       $userid = NFKD( $userid );
1510       $userid =~ s/\p{NonspacingMark}//g;
1511       $userid .= $offset unless $offset == 0;
1512       $self->userid( $userid );
1513       $offset++;
1514      } while (! $self->has_valid_userid );
1515
1516      return $self;
1517 }
1518
1519 =head3 add_extended_attribute
1520
1521 =cut
1522
1523 sub add_extended_attribute {
1524     my ($self, $attribute) = @_;
1525     $attribute->{borrowernumber} = $self->borrowernumber;
1526     return Koha::Patron::Attribute->new($attribute)->store;
1527 }
1528
1529 =head3 extended_attributes
1530
1531 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1532
1533 Or setter FIXME
1534
1535 =cut
1536
1537 sub extended_attributes {
1538     my ( $self, $attributes ) = @_;
1539     if ($attributes) {    # setter
1540         my $schema = $self->_result->result_source->schema;
1541         $schema->txn_do(
1542             sub {
1543                 # Remove the existing one
1544                 $self->extended_attributes->filter_by_branch_limitations->delete;
1545
1546                 # Insert the new ones
1547                 for my $attribute (@$attributes) {
1548                     eval {
1549                         $self->_result->create_related('borrower_attributes', $attribute);
1550                     };
1551                     # FIXME We should:
1552                     # 1 - Raise an exception
1553                     # 2 - Execute in a transaction and don't save
1554                     #  or Insert anyway but display a message on the UI
1555                     warn $@ if $@;
1556                 }
1557             }
1558         );
1559     }
1560
1561     my $rs = $self->_result->borrower_attributes;
1562     # We call search to use the filters in Koha::Patron::Attributes->search
1563     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1564 }
1565
1566 =head3 lock
1567
1568     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1569
1570     Lock and optionally expire a patron account.
1571     Remove holds and article requests if remove flag set.
1572     In order to distinguish from locking by entering a wrong password, let's
1573     call this an administrative lockout.
1574
1575 =cut
1576
1577 sub lock {
1578     my ( $self, $params ) = @_;
1579     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1580     if( $params->{expire} ) {
1581         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1582     }
1583     $self->store;
1584     if( $params->{remove} ) {
1585         $self->holds->delete;
1586         $self->article_requests->delete;
1587     }
1588     return $self;
1589 }
1590
1591 =head3 anonymize
1592
1593     Koha::Patrons->find($id)->anonymize;
1594
1595     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1596     are randomized, other personal data is cleared too.
1597     Patrons with issues are skipped.
1598
1599 =cut
1600
1601 sub anonymize {
1602     my ( $self ) = @_;
1603     if( $self->_result->issues->count ) {
1604         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1605         return;
1606     }
1607     # Mandatory fields come from the corresponding pref, but email fields
1608     # are removed since scrambled email addresses only generate errors
1609     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1610         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1611     $mandatory->{userid} = 1; # needed since sub store does not clear field
1612     my @columns = $self->_result->result_source->columns;
1613     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized/ } @columns;
1614     push @columns, 'dateofbirth'; # add this date back in
1615     foreach my $col (@columns) {
1616         $self->_anonymize_column($col, $mandatory->{lc $col} );
1617     }
1618     $self->anonymized(1)->store;
1619 }
1620
1621 sub _anonymize_column {
1622     my ( $self, $col, $mandatory ) = @_;
1623     my $col_info = $self->_result->result_source->column_info($col);
1624     my $type = $col_info->{data_type};
1625     my $nullable = $col_info->{is_nullable};
1626     my $val;
1627     if( $type =~ /char|text/ ) {
1628         $val = $mandatory
1629             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1630             : $nullable
1631             ? undef
1632             : q{};
1633     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1634         $val = $nullable ? undef : 0;
1635     } elsif( $type =~ /date|time/ ) {
1636         $val = $nullable ? undef : dt_from_string;
1637     }
1638     $self->$col($val);
1639 }
1640
1641 =head3 add_guarantor
1642
1643     my @relationships = $patron->add_guarantor(
1644         {
1645             borrowernumber => $borrowernumber,
1646             relationships  => $relationship,
1647         }
1648     );
1649
1650     Adds a new guarantor to a patron.
1651
1652 =cut
1653
1654 sub add_guarantor {
1655     my ( $self, $params ) = @_;
1656
1657     my $guarantor_id = $params->{guarantor_id};
1658     my $relationship = $params->{relationship};
1659
1660     return Koha::Patron::Relationship->new(
1661         {
1662             guarantee_id => $self->id,
1663             guarantor_id => $guarantor_id,
1664             relationship => $relationship
1665         }
1666     )->store();
1667 }
1668
1669 =head3 get_extended_attribute
1670
1671 my $attribute_value = $patron->get_extended_attribute( $code );
1672
1673 Return the attribute for the code passed in parameter.
1674
1675 It not exist it returns undef
1676
1677 Note that this will not work for repeatable attribute types.
1678
1679 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1680 (which should be a real patron's attribute (not extended)
1681
1682 =cut
1683
1684 sub get_extended_attribute {
1685     my ( $self, $code, $value ) = @_;
1686     my $rs = $self->_result->borrower_attributes;
1687     return unless $rs;
1688     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1689     return unless $attribute->count;
1690     return $attribute->next;
1691 }
1692
1693 =head3 to_api
1694
1695     my $json = $patron->to_api;
1696
1697 Overloaded method that returns a JSON representation of the Koha::Patron object,
1698 suitable for API output.
1699
1700 =cut
1701
1702 sub to_api {
1703     my ( $self, $params ) = @_;
1704
1705     my $json_patron = $self->SUPER::to_api( $params );
1706
1707     $json_patron->{restricted} = ( $self->is_debarred )
1708                                     ? Mojo::JSON->true
1709                                     : Mojo::JSON->false;
1710
1711     return $json_patron;
1712 }
1713
1714 =head3 to_api_mapping
1715
1716 This method returns the mapping for representing a Koha::Patron object
1717 on the API.
1718
1719 =cut
1720
1721 sub to_api_mapping {
1722     return {
1723         borrowernotes       => 'staff_notes',
1724         borrowernumber      => 'patron_id',
1725         branchcode          => 'library_id',
1726         categorycode        => 'category_id',
1727         checkprevcheckout   => 'check_previous_checkout',
1728         contactfirstname    => undef,                     # Unused
1729         contactname         => undef,                     # Unused
1730         contactnote         => 'altaddress_notes',
1731         contacttitle        => undef,                     # Unused
1732         dateenrolled        => 'date_enrolled',
1733         dateexpiry          => 'expiry_date',
1734         dateofbirth         => 'date_of_birth',
1735         debarred            => undef,                     # replaced by 'restricted'
1736         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1737         emailpro            => 'secondary_email',
1738         flags               => undef,    # permissions manipulation handled in /permissions
1739         gonenoaddress       => 'incorrect_address',
1740         guarantorid         => 'guarantor_id',
1741         lastseen            => 'last_seen',
1742         lost                => 'patron_card_lost',
1743         opacnote            => 'opac_notes',
1744         othernames          => 'other_name',
1745         password            => undef,            # password manipulation handled in /password
1746         phonepro            => 'secondary_phone',
1747         relationship        => 'relationship_type',
1748         sex                 => 'gender',
1749         smsalertnumber      => 'sms_number',
1750         sort1               => 'statistics_1',
1751         sort2               => 'statistics_2',
1752         autorenew_checkouts => 'autorenew_checkouts',
1753         streetnumber        => 'street_number',
1754         streettype          => 'street_type',
1755         zipcode             => 'postal_code',
1756         B_address           => 'altaddress_address',
1757         B_address2          => 'altaddress_address2',
1758         B_city              => 'altaddress_city',
1759         B_country           => 'altaddress_country',
1760         B_email             => 'altaddress_email',
1761         B_phone             => 'altaddress_phone',
1762         B_state             => 'altaddress_state',
1763         B_streetnumber      => 'altaddress_street_number',
1764         B_streettype        => 'altaddress_street_type',
1765         B_zipcode           => 'altaddress_postal_code',
1766         altcontactaddress1  => 'altcontact_address',
1767         altcontactaddress2  => 'altcontact_address2',
1768         altcontactaddress3  => 'altcontact_city',
1769         altcontactcountry   => 'altcontact_country',
1770         altcontactfirstname => 'altcontact_firstname',
1771         altcontactphone     => 'altcontact_phone',
1772         altcontactsurname   => 'altcontact_surname',
1773         altcontactstate     => 'altcontact_state',
1774         altcontactzipcode   => 'altcontact_postal_code'
1775     };
1776 }
1777
1778 =head2 Internal methods
1779
1780 =head3 _type
1781
1782 =cut
1783
1784 sub _type {
1785     return 'Borrower';
1786 }
1787
1788 =head1 AUTHORS
1789
1790 Kyle M Hall <kyle@bywatersolutions.com>
1791 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
1792 Martin Renvoize <martin.renvoize@ptfs-europe.com>
1793
1794 =cut
1795
1796 1;