Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use List::MoreUtils qw( any uniq );
  25 use JSON qw( to_json );
  26 use Unicode::Normalize;
  27
  28 use C4::Context;
  29 use C4::Log;
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use Koha::AuthUtils;
  33 use Koha::Checkouts;
  34 use Koha::Club::Enrollments;
  35 use Koha::Database;
  36 use Koha::DateUtils;
  37 use Koha::Exceptions::Password;
  38 use Koha::Holds;
  39 use Koha::Old::Checkouts;
  40 use Koha::Patron::Attributes;
  41 use Koha::Patron::Categories;
  42 use Koha::Patron::HouseboundProfile;
  43 use Koha::Patron::HouseboundRole;
  44 use Koha::Patron::Images;
  45 use Koha::Patron::Modifications;
  46 use Koha::Patron::Relationships;
  47 use Koha::Patrons;
  48 use Koha::Plugins;
  49 use Koha::Subscription::Routinglists;
  50 use Koha::Token;
  51 use Koha::Virtualshelves;
  52
  53 use base qw(Koha::Object);
  54
  55 use constant ADMINISTRATIVE_LOCKOUT => -1;
  56
  57 our $RESULTSET_PATRON_ID_MAPPING = {
  58     Accountline          => 'borrowernumber',
  59     Aqbasketuser         => 'borrowernumber',
  60     Aqbudget             => 'budget_owner_id',
  61     Aqbudgetborrower     => 'borrowernumber',
  62     ArticleRequest       => 'borrowernumber',
  63     BorrowerAttribute    => 'borrowernumber',
  64     BorrowerDebarment    => 'borrowernumber',
  65     BorrowerFile         => 'borrowernumber',
  66     BorrowerModification => 'borrowernumber',
  67     ClubEnrollment       => 'borrowernumber',
  68     Issue                => 'borrowernumber',
  69     ItemsLastBorrower    => 'borrowernumber',
  70     Linktracker          => 'borrowernumber',
  71     Message              => 'borrowernumber',
  72     MessageQueue         => 'borrowernumber',
  73     OldIssue             => 'borrowernumber',
  74     OldReserve           => 'borrowernumber',
  75     Rating               => 'borrowernumber',
  76     Reserve              => 'borrowernumber',
  77     Review               => 'borrowernumber',
  78     SearchHistory        => 'userid',
  79     Statistic            => 'borrowernumber',
  80     Suggestion           => 'suggestedby',
  81     TagAll               => 'borrowernumber',
  82     Virtualshelfcontent  => 'borrowernumber',
  83     Virtualshelfshare    => 'borrowernumber',
  84     Virtualshelve        => 'owner',
  85 };
  86
  87 =head1 NAME
  88
  89 Koha::Patron - Koha Patron Object class
  90
  91 =head1 API
  92
  93 =head2 Class Methods
  94
  95 =head3 new
  96
  97 =cut
  98
  99 sub new {
 100     my ( $class, $params ) = @_;
 101
 102     return $class->SUPER::new($params);
 103 }
 104
 105 =head3 fixup_cardnumber
 106
 107 Autogenerate next cardnumber from highest value found in database
 108
 109 =cut
 110
 111 sub fixup_cardnumber {
 112     my ( $self ) = @_;
 113     my $max = Koha::Patrons->search({
 114         cardnumber => {-regexp => '^-?[0-9]+$'}
 115     }, {
 116         select => \'CAST(cardnumber AS SIGNED)',
 117         as => ['cast_cardnumber']
 118     })->_resultset->get_column('cast_cardnumber')->max;
 119     $self->cardnumber(($max || 0) +1);
 120 }
 121
 122 =head3 trim_whitespace
 123
 124 trim whitespace from data which has some non-whitespace in it.
 125 Could be moved to Koha::Object if need to be reused
 126
 127 =cut
 128
 129 sub trim_whitespaces {
 130     my( $self ) = @_;
 131
 132     my $schema  = Koha::Database->new->schema;
 133     my @columns = $schema->source($self->_type)->columns;
 134
 135     for my $column( @columns ) {
 136         my $value = $self->$column;
 137         if ( defined $value ) {
 138             $value =~ s/^\s*|\s*$//g;
 139             $self->$column($value);
 140         }
 141     }
 142     return $self;
 143 }
 144
 145 =head3 plain_text_password
 146
 147 $patron->plain_text_password( $password );
 148
 149 stores a copy of the unencrypted password in the object
 150 for use in code before encrypting for db
 151
 152 =cut
 153
 154 sub plain_text_password {
 155     my ( $self, $password ) = @_;
 156     if ( $password ) {
 157         $self->{_plain_text_password} = $password;
 158         return $self;
 159     }
 160     return $self->{_plain_text_password}
 161         if $self->{_plain_text_password};
 162
 163     return;
 164 }
 165
 166 =head3 store
 167
 168 Patron specific store method to cleanup record
 169 and do other necessary things before saving
 170 to db
 171
 172 =cut
 173
 174 sub store {
 175     my ($self) = @_;
 176
 177     $self->_result->result_source->schema->txn_do(
 178         sub {
 179             if (
 180                 C4::Context->preference("autoMemberNum")
 181                 and ( not defined $self->cardnumber
 182                     or $self->cardnumber eq '' )
 183               )
 184             {
 185                 # Warning: The caller is responsible for locking the members table in write
 186                 # mode, to avoid database corruption.
 187                 # We are in a transaction but the table is not locked
 188                 $self->fixup_cardnumber;
 189             }
 190
 191             unless( $self->category->in_storage ) {
 192                 Koha::Exceptions::Object::FKConstraint->throw(
 193                     broken_fk => 'categorycode',
 194                     value     => $self->categorycode,
 195                 );
 196             }
 197
 198             $self->trim_whitespaces;
 199
 200             # Set surname to uppercase if uppercasesurname is true
 201             $self->surname( uc($self->surname) )
 202                 if C4::Context->preference("uppercasesurnames");
 203
 204             $self->relationship(undef) # We do not want to store an empty string in this field
 205               if defined $self->relationship
 206                      and $self->relationship eq "";
 207
 208             unless ( $self->in_storage ) {    #AddMember
 209
 210                 # Generate a valid userid/login if needed
 211                 $self->generate_userid
 212                   if not $self->userid or not $self->has_valid_userid;
 213
 214                 # Add expiration date if it isn't already there
 215                 unless ( $self->dateexpiry ) {
 216                     $self->dateexpiry( $self->category->get_expiry_date );
 217                 }
 218
 219                 # Add enrollment date if it isn't already there
 220                 unless ( $self->dateenrolled ) {
 221                     $self->dateenrolled(dt_from_string);
 222                 }
 223
 224                 # Set the privacy depending on the patron's category
 225                 my $default_privacy = $self->category->default_privacy || q{};
 226                 $default_privacy =
 227                     $default_privacy eq 'default' ? 1
 228                   : $default_privacy eq 'never'   ? 2
 229                   : $default_privacy eq 'forever' ? 0
 230                   :                                                   undef;
 231                 $self->privacy($default_privacy);
 232
 233                 # Call any check_password plugins if password is passed
 234                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 235                     my @plugins = Koha::Plugins->new()->GetPlugins({
 236                         method => 'check_password',
 237                     });
 238                     foreach my $plugin ( @plugins ) {
 239                         # This plugin hook will also be used by a plugin for the Norwegian national
 240                         # patron database. This is why we need to pass both the password and the
 241                         # borrowernumber to the plugin.
 242                         my $ret = $plugin->check_password(
 243                             {
 244                                 password       => $self->password,
 245                                 borrowernumber => $self->borrowernumber
 246                             }
 247                         );
 248                         if ( $ret->{'error'} == 1 ) {
 249                             Koha::Exceptions::Password::Plugin->throw();
 250                         }
 251                     }
 252                 }
 253
 254                 # Make a copy of the plain text password for later use
 255                 $self->plain_text_password( $self->password );
 256
 257                 # Create a disabled account if no password provided
 258                 $self->password( $self->password
 259                     ? Koha::AuthUtils::hash_password( $self->password )
 260                     : '!' );
 261
 262                 $self->borrowernumber(undef);
 263
 264                 $self = $self->SUPER::store;
 265
 266                 $self->add_enrolment_fee_if_needed(0);
 267
 268                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 269                   if C4::Context->preference("BorrowersLog");
 270             }
 271             else {    #ModMember
 272
 273                 my $self_from_storage = $self->get_from_storage;
 274                 # FIXME We should not deal with that here, callers have to do this job
 275                 # Moved from ModMember to prevent regressions
 276                 unless ( $self->userid ) {
 277                     my $stored_userid = $self_from_storage->userid;
 278                     $self->userid($stored_userid);
 279                 }
 280
 281                 # Password must be updated using $self->set_password
 282                 $self->password($self_from_storage->password);
 283
 284                 if ( $self->category->categorycode ne
 285                     $self_from_storage->category->categorycode )
 286                 {
 287                     # Add enrolement fee on category change if required
 288                     $self->add_enrolment_fee_if_needed(1)
 289                       if C4::Context->preference('FeeOnChangePatronCategory');
 290
 291                     # Clean up guarantors on category change if required
 292                     $self->guarantor_relationships->delete
 293                       if ( $self->category->category_type ne 'C'
 294                         && $self->category->category_type ne 'P' );
 295
 296                 }
 297
 298                 # Actionlogs
 299                 if ( C4::Context->preference("BorrowersLog") ) {
 300                     my $info;
 301                     my $from_storage = $self_from_storage->unblessed;
 302                     my $from_object  = $self->unblessed;
 303                     my @skip_fields  = (qw/lastseen updated_on/);
 304                     for my $key ( keys %{$from_storage} ) {
 305                         next if any { /$key/ } @skip_fields;
 306                         if (
 307                             (
 308                                   !defined( $from_storage->{$key} )
 309                                 && defined( $from_object->{$key} )
 310                             )
 311                             || ( defined( $from_storage->{$key} )
 312                                 && !defined( $from_object->{$key} ) )
 313                             || (
 314                                    defined( $from_storage->{$key} )
 315                                 && defined( $from_object->{$key} )
 316                                 && ( $from_storage->{$key} ne
 317                                     $from_object->{$key} )
 318                             )
 319                           )
 320                         {
 321                             $info->{$key} = {
 322                                 before => $from_storage->{$key},
 323                                 after  => $from_object->{$key}
 324                             };
 325                         }
 326                     }
 327
 328                     if ( defined($info) ) {
 329                         logaction(
 330                             "MEMBERS",
 331                             "MODIFY",
 332                             $self->borrowernumber,
 333                             to_json(
 334                                 $info,
 335                                 { utf8 => 1, pretty => 1, canonical => 1 }
 336                             )
 337                         );
 338                     }
 339                 }
 340
 341                 # Final store
 342                 $self = $self->SUPER::store;
 343             }
 344         }
 345     );
 346     return $self;
 347 }
 348
 349 =head3 delete
 350
 351 $patron->delete
 352
 353 Delete patron's holds, lists and finally the patron.
 354
 355 Lists owned by the borrower are deleted, but entries from the borrower to
 356 other lists are kept.
 357
 358 =cut
 359
 360 sub delete {
 361     my ($self) = @_;
 362
 363     $self->_result->result_source->schema->txn_do(
 364         sub {
 365             # Cancel Patron's holds
 366             my $holds = $self->holds;
 367             while( my $hold = $holds->next ){
 368                 $hold->cancel;
 369             }
 370
 371             # Delete all lists and all shares of this borrower
 372             # Consistent with the approach Koha uses on deleting individual lists
 373             # Note that entries in virtualshelfcontents added by this borrower to
 374             # lists of others will be handled by a table constraint: the borrower
 375             # is set to NULL in those entries.
 376             # NOTE:
 377             # We could handle the above deletes via a constraint too.
 378             # But a new BZ report 11889 has been opened to discuss another approach.
 379             # Instead of deleting we could also disown lists (based on a pref).
 380             # In that way we could save shared and public lists.
 381             # The current table constraints support that idea now.
 382             # This pref should then govern the results of other routines/methods such as
 383             # Koha::Virtualshelf->new->delete too.
 384             # FIXME Could be $patron->get_lists
 385             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } );
 386
 387             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 388             # for patron selfreg
 389             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } );
 390
 391             $self->SUPER::delete;
 392
 393             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 394         }
 395     );
 396     return $self;
 397 }
 398
 399
 400 =head3 category
 401
 402 my $patron_category = $patron->category
 403
 404 Return the patron category for this patron
 405
 406 =cut
 407
 408 sub category {
 409     my ( $self ) = @_;
 410     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 411 }
 412
 413 =head3 image
 414
 415 =cut
 416
 417 sub image {
 418     my ( $self ) = @_;
 419
 420     return Koha::Patron::Images->find( $self->borrowernumber );
 421 }
 422
 423 =head3 library
 424
 425 Returns a Koha::Library object representing the patron's home library.
 426
 427 =cut
 428
 429 sub library {
 430     my ( $self ) = @_;
 431     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 432 }
 433
 434 =head3 guarantor_relationships
 435
 436 Returns Koha::Patron::Relationships object for this patron's guarantors
 437
 438 Returns the set of relationships for the patrons that are guarantors for this patron.
 439
 440 This is returned instead of a Koha::Patron object because the guarantor
 441 may not exist as a patron in Koha. If this is true, the guarantors name
 442 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 443
 444 =cut
 445
 446 sub guarantor_relationships {
 447     my ($self) = @_;
 448
 449     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 450 }
 451
 452 =head3 guarantee_relationships
 453
 454 Returns Koha::Patron::Relationships object for this patron's guarantors
 455
 456 Returns the set of relationships for the patrons that are guarantees for this patron.
 457
 458 The method returns Koha::Patron::Relationship objects for the sake
 459 of consistency with the guantors method.
 460 A guarantee by definition must exist as a patron in Koha.
 461
 462 =cut
 463
 464 sub guarantee_relationships {
 465     my ($self) = @_;
 466
 467     return Koha::Patron::Relationships->search(
 468         { guarantor_id => $self->id },
 469         {
 470             prefetch => 'guarantee',
 471             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 472         }
 473     );
 474 }
 475
 476 =head3 housebound_profile
 477
 478 Returns the HouseboundProfile associated with this patron.
 479
 480 =cut
 481
 482 sub housebound_profile {
 483     my ( $self ) = @_;
 484     my $profile = $self->_result->housebound_profile;
 485     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 486         if ( $profile );
 487     return;
 488 }
 489
 490 =head3 housebound_role
 491
 492 Returns the HouseboundRole associated with this patron.
 493
 494 =cut
 495
 496 sub housebound_role {
 497     my ( $self ) = @_;
 498
 499     my $role = $self->_result->housebound_role;
 500     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 501     return;
 502 }
 503
 504 =head3 siblings
 505
 506 Returns the siblings of this patron.
 507
 508 =cut
 509
 510 sub siblings {
 511     my ($self) = @_;
 512
 513     my @guarantors = $self->guarantor_relationships()->guarantors();
 514
 515     return unless @guarantors;
 516
 517     my @siblings =
 518       map { $_->guarantee_relationships()->guarantees() } @guarantors;
 519
 520     return unless @siblings;
 521
 522     my %seen;
 523     @siblings =
 524       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 525
 526     return wantarray ? @siblings : Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 527 }
 528
 529 =head3 merge_with
 530
 531     my $patron = Koha::Patrons->find($id);
 532     $patron->merge_with( \@patron_ids );
 533
 534     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 535     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 536     of the keeper patron.
 537
 538 =cut
 539
 540 sub merge_with {
 541     my ( $self, $patron_ids ) = @_;
 542
 543     my @patron_ids = @{ $patron_ids };
 544
 545     # Ensure the keeper isn't in the list of patrons to merge
 546     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 547
 548     my $schema = Koha::Database->new()->schema();
 549
 550     my $results;
 551
 552     $self->_result->result_source->schema->txn_do( sub {
 553         foreach my $patron_id (@patron_ids) {
 554             my $patron = Koha::Patrons->find( $patron_id );
 555
 556             next unless $patron;
 557
 558             # Unbless for safety, the patron will end up being deleted
 559             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 560
 561             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 562                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 563                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 564                 $rs->update({ $field => $self->id });
 565             }
 566
 567             $patron->move_to_deleted();
 568             $patron->delete();
 569         }
 570     });
 571
 572     return $results;
 573 }
 574
 575
 576
 577 =head3 wants_check_for_previous_checkout
 578
 579     $wants_check = $patron->wants_check_for_previous_checkout;
 580
 581 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 582
 583 =cut
 584
 585 sub wants_check_for_previous_checkout {
 586     my ( $self ) = @_;
 587     my $syspref = C4::Context->preference("checkPrevCheckout");
 588
 589     # Simple cases
 590     ## Hard syspref trumps all
 591     return 1 if ($syspref eq 'hardyes');
 592     return 0 if ($syspref eq 'hardno');
 593     ## Now, patron pref trumps all
 594     return 1 if ($self->checkprevcheckout eq 'yes');
 595     return 0 if ($self->checkprevcheckout eq 'no');
 596
 597     # More complex: patron inherits -> determine category preference
 598     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 599     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 600     return 0 if ($checkPrevCheckoutByCat eq 'no');
 601
 602     # Finally: category preference is inherit, default to 0
 603     if ($syspref eq 'softyes') {
 604         return 1;
 605     } else {
 606         return 0;
 607     }
 608 }
 609
 610 =head3 do_check_for_previous_checkout
 611
 612     $do_check = $patron->do_check_for_previous_checkout($item);
 613
 614 Return 1 if the bib associated with $ITEM has previously been checked out to
 615 $PATRON, 0 otherwise.
 616
 617 =cut
 618
 619 sub do_check_for_previous_checkout {
 620     my ( $self, $item ) = @_;
 621
 622     my @item_nos;
 623     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 624     if ( $biblio->is_serial ) {
 625         push @item_nos, $item->{itemnumber};
 626     } else {
 627         # Get all itemnumbers for given bibliographic record.
 628         @item_nos = $biblio->items->get_column( 'itemnumber' );
 629     }
 630
 631     # Create (old)issues search criteria
 632     my $criteria = {
 633         borrowernumber => $self->borrowernumber,
 634         itemnumber => \@item_nos,
 635     };
 636
 637     # Check current issues table
 638     my $issues = Koha::Checkouts->search($criteria);
 639     return 1 if $issues->count; # 0 || N
 640
 641     # Check old issues table
 642     my $old_issues = Koha::Old::Checkouts->search($criteria);
 643     return $old_issues->count;  # 0 || N
 644 }
 645
 646 =head3 is_debarred
 647
 648 my $debarment_expiration = $patron->is_debarred;
 649
 650 Returns the date a patron debarment will expire, or undef if the patron is not
 651 debarred
 652
 653 =cut
 654
 655 sub is_debarred {
 656     my ($self) = @_;
 657
 658     return unless $self->debarred;
 659     return $self->debarred
 660       if $self->debarred =~ '^9999'
 661       or dt_from_string( $self->debarred ) > dt_from_string;
 662     return;
 663 }
 664
 665 =head3 is_expired
 666
 667 my $is_expired = $patron->is_expired;
 668
 669 Returns 1 if the patron is expired or 0;
 670
 671 =cut
 672
 673 sub is_expired {
 674     my ($self) = @_;
 675     return 0 unless $self->dateexpiry;
 676     return 0 if $self->dateexpiry =~ '^9999';
 677     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 678     return 0;
 679 }
 680
 681 =head3 is_going_to_expire
 682
 683 my $is_going_to_expire = $patron->is_going_to_expire;
 684
 685 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 686
 687 =cut
 688
 689 sub is_going_to_expire {
 690     my ($self) = @_;
 691
 692     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 693
 694     return 0 unless $delay;
 695     return 0 unless $self->dateexpiry;
 696     return 0 if $self->dateexpiry =~ '^9999';
 697     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 698     return 0;
 699 }
 700
 701 =head3 set_password
 702
 703     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 704
 705 Set the patron's password.
 706
 707 =head4 Exceptions
 708
 709 The passed string is validated against the current password enforcement policy.
 710 Validation can be skipped by passing the I<skip_validation> parameter.
 711
 712 Exceptions are thrown if the password is not good enough.
 713
 714 =over 4
 715
 716 =item Koha::Exceptions::Password::TooShort
 717
 718 =item Koha::Exceptions::Password::WhitespaceCharacters
 719
 720 =item Koha::Exceptions::Password::TooWeak
 721
 722 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 723
 724 =back
 725
 726 =cut
 727
 728 sub set_password {
 729     my ( $self, $args ) = @_;
 730
 731     my $password = $args->{password};
 732
 733     unless ( $args->{skip_validation} ) {
 734         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password );
 735
 736         if ( !$is_valid ) {
 737             if ( $error eq 'too_short' ) {
 738                 my $min_length = C4::Context->preference('minPasswordLength');
 739                 $min_length = 3 if not $min_length or $min_length < 3;
 740
 741                 my $password_length = length($password);
 742                 Koha::Exceptions::Password::TooShort->throw(
 743                     length => $password_length, min_length => $min_length );
 744             }
 745             elsif ( $error eq 'has_whitespaces' ) {
 746                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 747             }
 748             elsif ( $error eq 'too_weak' ) {
 749                 Koha::Exceptions::Password::TooWeak->throw();
 750             }
 751         }
 752     }
 753
 754     if ( C4::Context->config("enable_plugins") ) {
 755         # Call any check_password plugins
 756         my @plugins = Koha::Plugins->new()->GetPlugins({
 757             method => 'check_password',
 758         });
 759         foreach my $plugin ( @plugins ) {
 760             # This plugin hook will also be used by a plugin for the Norwegian national
 761             # patron database. This is why we need to pass both the password and the
 762             # borrowernumber to the plugin.
 763             my $ret = $plugin->check_password(
 764                 {
 765                     password       => $password,
 766                     borrowernumber => $self->borrowernumber
 767                 }
 768             );
 769             # This plugin hook will also be used by a plugin for the Norwegian national
 770             # patron database. This is why we need to call the actual plugins and then
 771             # check skip_validation afterwards.
 772             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 773                 Koha::Exceptions::Password::Plugin->throw();
 774             }
 775         }
 776     }
 777
 778     my $digest = Koha::AuthUtils::hash_password($password);
 779
 780     # We do not want to call $self->store and retrieve password from DB
 781     $self->password($digest);
 782     $self->login_attempts(0);
 783     $self->SUPER::store;
 784
 785     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 786         if C4::Context->preference("BorrowersLog");
 787
 788     return $self;
 789 }
 790
 791
 792 =head3 renew_account
 793
 794 my $new_expiry_date = $patron->renew_account
 795
 796 Extending the subscription to the expiry date.
 797
 798 =cut
 799
 800 sub renew_account {
 801     my ($self) = @_;
 802     my $date;
 803     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 804         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 805     } else {
 806         $date =
 807             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 808             ? dt_from_string( $self->dateexpiry )
 809             : dt_from_string;
 810     }
 811     my $expiry_date = $self->category->get_expiry_date($date);
 812
 813     $self->dateexpiry($expiry_date);
 814     $self->date_renewed( dt_from_string() );
 815     $self->store();
 816
 817     $self->add_enrolment_fee_if_needed(1);
 818
 819     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 820     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 821 }
 822
 823 =head3 has_overdues
 824
 825 my $has_overdues = $patron->has_overdues;
 826
 827 Returns the number of patron's overdues
 828
 829 =cut
 830
 831 sub has_overdues {
 832     my ($self) = @_;
 833     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 834     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 835 }
 836
 837 =head3 track_login
 838
 839     $patron->track_login;
 840     $patron->track_login({ force => 1 });
 841
 842     Tracks a (successful) login attempt.
 843     The preference TrackLastPatronActivity must be enabled. Or you
 844     should pass the force parameter.
 845
 846 =cut
 847
 848 sub track_login {
 849     my ( $self, $params ) = @_;
 850     return if
 851         !$params->{force} &&
 852         !C4::Context->preference('TrackLastPatronActivity');
 853     $self->lastseen( dt_from_string() )->store;
 854 }
 855
 856 =head3 move_to_deleted
 857
 858 my $is_moved = $patron->move_to_deleted;
 859
 860 Move a patron to the deletedborrowers table.
 861 This can be done before deleting a patron, to make sure the data are not completely deleted.
 862
 863 =cut
 864
 865 sub move_to_deleted {
 866     my ($self) = @_;
 867     my $patron_infos = $self->unblessed;
 868     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 869     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 870 }
 871
 872 =head3 article_requests
 873
 874 my @requests = $borrower->article_requests();
 875 my $requests = $borrower->article_requests();
 876
 877 Returns either a list of ArticleRequests objects,
 878 or an ArtitleRequests object, depending on the
 879 calling context.
 880
 881 =cut
 882
 883 sub article_requests {
 884     my ( $self ) = @_;
 885
 886     $self->{_article_requests} ||= Koha::ArticleRequests->search({ borrowernumber => $self->borrowernumber() });
 887
 888     return $self->{_article_requests};
 889 }
 890
 891 =head3 article_requests_current
 892
 893 my @requests = $patron->article_requests_current
 894
 895 Returns the article requests associated with this patron that are incomplete
 896
 897 =cut
 898
 899 sub article_requests_current {
 900     my ( $self ) = @_;
 901
 902     $self->{_article_requests_current} ||= Koha::ArticleRequests->search(
 903         {
 904             borrowernumber => $self->id(),
 905             -or          => [
 906                 { status => Koha::ArticleRequest::Status::Pending },
 907                 { status => Koha::ArticleRequest::Status::Processing }
 908             ]
 909         }
 910     );
 911
 912     return $self->{_article_requests_current};
 913 }
 914
 915 =head3 article_requests_finished
 916
 917 my @requests = $biblio->article_requests_finished
 918
 919 Returns the article requests associated with this patron that are completed
 920
 921 =cut
 922
 923 sub article_requests_finished {
 924     my ( $self, $borrower ) = @_;
 925
 926     $self->{_article_requests_finished} ||= Koha::ArticleRequests->search(
 927         {
 928             borrowernumber => $self->id(),
 929             -or          => [
 930                 { status => Koha::ArticleRequest::Status::Completed },
 931                 { status => Koha::ArticleRequest::Status::Canceled }
 932             ]
 933         }
 934     );
 935
 936     return $self->{_article_requests_finished};
 937 }
 938
 939 =head3 add_enrolment_fee_if_needed
 940
 941 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
 942
 943 Add enrolment fee for a patron if needed.
 944
 945 $renewal - boolean denoting whether this is an account renewal or not
 946
 947 =cut
 948
 949 sub add_enrolment_fee_if_needed {
 950     my ($self, $renewal) = @_;
 951     my $enrolment_fee = $self->category->enrolmentfee;
 952     if ( $enrolment_fee && $enrolment_fee > 0 ) {
 953         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
 954         $self->account->add_debit(
 955             {
 956                 amount     => $enrolment_fee,
 957                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 958                 interface  => C4::Context->interface,
 959                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 960                 type       => $type
 961             }
 962         );
 963     }
 964     return $enrolment_fee || 0;
 965 }
 966
 967 =head3 checkouts
 968
 969 my $checkouts = $patron->checkouts
 970
 971 =cut
 972
 973 sub checkouts {
 974     my ($self) = @_;
 975     my $checkouts = $self->_result->issues;
 976     return Koha::Checkouts->_new_from_dbic( $checkouts );
 977 }
 978
 979 =head3 pending_checkouts
 980
 981 my $pending_checkouts = $patron->pending_checkouts
 982
 983 This method will return the same as $self->checkouts, but with a prefetch on
 984 items, biblio and biblioitems.
 985
 986 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
 987
 988 It should not be used directly, prefer to access fields you need instead of
 989 retrieving all these fields in one go.
 990
 991 =cut
 992
 993 sub pending_checkouts {
 994     my( $self ) = @_;
 995     my $checkouts = $self->_result->issues->search(
 996         {},
 997         {
 998             order_by => [
 999                 { -desc => 'me.timestamp' },
1000                 { -desc => 'issuedate' },
1001                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1002             ],
1003             prefetch => { item => { biblio => 'biblioitems' } },
1004         }
1005     );
1006     return Koha::Checkouts->_new_from_dbic( $checkouts );
1007 }
1008
1009 =head3 old_checkouts
1010
1011 my $old_checkouts = $patron->old_checkouts
1012
1013 =cut
1014
1015 sub old_checkouts {
1016     my ($self) = @_;
1017     my $old_checkouts = $self->_result->old_issues;
1018     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1019 }
1020
1021 =head3 get_overdues
1022
1023 my $overdue_items = $patron->get_overdues
1024
1025 Return the overdue items
1026
1027 =cut
1028
1029 sub get_overdues {
1030     my ($self) = @_;
1031     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1032     return $self->checkouts->search(
1033         {
1034             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1035         },
1036         {
1037             prefetch => { item => { biblio => 'biblioitems' } },
1038         }
1039     );
1040 }
1041
1042 =head3 get_routing_lists
1043
1044 my @routinglists = $patron->get_routing_lists
1045
1046 Returns the routing lists a patron is subscribed to.
1047
1048 =cut
1049
1050 sub get_routing_lists {
1051     my ($self) = @_;
1052     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1053     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1054 }
1055
1056 =head3 get_age
1057
1058 my $age = $patron->get_age
1059
1060 Return the age of the patron
1061
1062 =cut
1063
1064 sub get_age {
1065     my ($self)    = @_;
1066     my $today_str = dt_from_string->strftime("%Y-%m-%d");
1067     return unless $self->dateofbirth;
1068     my $dob_str   = dt_from_string( $self->dateofbirth )->strftime("%Y-%m-%d");
1069
1070     my ( $dob_y,   $dob_m,   $dob_d )   = split /-/, $dob_str;
1071     my ( $today_y, $today_m, $today_d ) = split /-/, $today_str;
1072
1073     my $age = $today_y - $dob_y;
1074     if ( $dob_m . $dob_d > $today_m . $today_d ) {
1075         $age--;
1076     }
1077
1078     return $age;
1079 }
1080
1081 =head3 is_valid_age
1082
1083 my $is_valid = $patron->is_valid_age
1084
1085 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1086
1087 =cut
1088
1089 sub is_valid_age {
1090     my ($self) = @_;
1091     my $age = $self->get_age;
1092
1093     my $patroncategory = $self->category;
1094     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1095
1096     return (defined($age) && (($high && ($age > $high)) or ($age < $low))) ? 0 : 1;
1097 }
1098
1099 =head3 account
1100
1101 my $account = $patron->account
1102
1103 =cut
1104
1105 sub account {
1106     my ($self) = @_;
1107     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1108 }
1109
1110 =head3 holds
1111
1112 my $holds = $patron->holds
1113
1114 Return all the holds placed by this patron
1115
1116 =cut
1117
1118 sub holds {
1119     my ($self) = @_;
1120     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1121     return Koha::Holds->_new_from_dbic($holds_rs);
1122 }
1123
1124 =head3 old_holds
1125
1126 my $old_holds = $patron->old_holds
1127
1128 Return all the historical holds for this patron
1129
1130 =cut
1131
1132 sub old_holds {
1133     my ($self) = @_;
1134     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1135     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1136 }
1137
1138 =head3 return_claims
1139
1140 my $return_claims = $patron->return_claims
1141
1142 =cut
1143
1144 sub return_claims {
1145     my ($self) = @_;
1146     my $return_claims = $self->_result->return_claims_borrowernumbers;
1147     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1148 }
1149
1150 =head3 notice_email_address
1151
1152   my $email = $patron->notice_email_address;
1153
1154 Return the email address of patron used for notices.
1155 Returns the empty string if no email address.
1156
1157 =cut
1158
1159 sub notice_email_address{
1160     my ( $self ) = @_;
1161
1162     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1163     # if syspref is set to 'first valid' (value == OFF), look up email address
1164     if ( $which_address eq 'OFF' ) {
1165         return $self->first_valid_email_address;
1166     }
1167
1168     return $self->$which_address || '';
1169 }
1170
1171 =head3 first_valid_email_address
1172
1173 my $first_valid_email_address = $patron->first_valid_email_address
1174
1175 Return the first valid email address for a patron.
1176 For now, the order  is defined as email, emailpro, B_email.
1177 Returns the empty string if the borrower has no email addresses.
1178
1179 =cut
1180
1181 sub first_valid_email_address {
1182     my ($self) = @_;
1183
1184     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1185 }
1186
1187 =head3 get_club_enrollments
1188
1189 =cut
1190
1191 sub get_club_enrollments {
1192     my ( $self, $return_scalar ) = @_;
1193
1194     my $e = Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1195
1196     return $e if $return_scalar;
1197
1198     return wantarray ? $e->as_list : $e;
1199 }
1200
1201 =head3 get_enrollable_clubs
1202
1203 =cut
1204
1205 sub get_enrollable_clubs {
1206     my ( $self, $is_enrollable_from_opac, $return_scalar ) = @_;
1207
1208     my $params;
1209     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1210       if $is_enrollable_from_opac;
1211     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1212
1213     $params->{borrower} = $self;
1214
1215     my $e = Koha::Clubs->get_enrollable($params);
1216
1217     return $e if $return_scalar;
1218
1219     return wantarray ? $e->as_list : $e;
1220 }
1221
1222 =head3 account_locked
1223
1224 my $is_locked = $patron->account_locked
1225
1226 Return true if the patron has reached the maximum number of login attempts
1227 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1228 as an administrative lockout (independent of FailedLoginAttempts; see also
1229 Koha::Patron->lock).
1230 Otherwise return false.
1231 If the pref is not set (empty string, null or 0), the feature is considered as
1232 disabled.
1233
1234 =cut
1235
1236 sub account_locked {
1237     my ($self) = @_;
1238     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1239     return 1 if $FailedLoginAttempts
1240           and $self->login_attempts
1241           and $self->login_attempts >= $FailedLoginAttempts;
1242     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1243     return 0;
1244 }
1245
1246 =head3 can_see_patron_infos
1247
1248 my $can_see = $patron->can_see_patron_infos( $patron );
1249
1250 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1251
1252 =cut
1253
1254 sub can_see_patron_infos {
1255     my ( $self, $patron ) = @_;
1256     return unless $patron;
1257     return $self->can_see_patrons_from( $patron->library->branchcode );
1258 }
1259
1260 =head3 can_see_patrons_from
1261
1262 my $can_see = $patron->can_see_patrons_from( $branchcode );
1263
1264 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1265
1266 =cut
1267
1268 sub can_see_patrons_from {
1269     my ( $self, $branchcode ) = @_;
1270     my $can = 0;
1271     if ( $self->branchcode eq $branchcode ) {
1272         $can = 1;
1273     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1274         $can = 1;
1275     } elsif ( my $library_groups = $self->library->library_groups ) {
1276         while ( my $library_group = $library_groups->next ) {
1277             if ( $library_group->parent->has_child( $branchcode ) ) {
1278                 $can = 1;
1279                 last;
1280             }
1281         }
1282     }
1283     return $can;
1284 }
1285
1286 =head3 libraries_where_can_see_patrons
1287
1288 my $libraries = $patron-libraries_where_can_see_patrons;
1289
1290 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1291 The branchcodes are arbitrarily returned sorted.
1292 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1293
1294 An empty array means no restriction, the patron can see patron's infos from any libraries.
1295
1296 =cut
1297
1298 sub libraries_where_can_see_patrons {
1299     my ( $self ) = @_;
1300     my $userenv = C4::Context->userenv;
1301
1302     return () unless $userenv; # For tests, but userenv should be defined in tests...
1303
1304     my @restricted_branchcodes;
1305     if (C4::Context::only_my_library) {
1306         push @restricted_branchcodes, $self->branchcode;
1307     }
1308     else {
1309         unless (
1310             $self->has_permission(
1311                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1312             )
1313           )
1314         {
1315             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1316             if ( $library_groups->count )
1317             {
1318                 while ( my $library_group = $library_groups->next ) {
1319                     my $parent = $library_group->parent;
1320                     if ( $parent->has_child( $self->branchcode ) ) {
1321                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1322                     }
1323                 }
1324             }
1325
1326             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1327         }
1328     }
1329
1330     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1331     @restricted_branchcodes = uniq(@restricted_branchcodes);
1332     @restricted_branchcodes = sort(@restricted_branchcodes);
1333     return @restricted_branchcodes;
1334 }
1335
1336 =head3 has_permission
1337
1338 my $permission = $patron->has_permission($required);
1339
1340 See C4::Auth::haspermission for details of syntax for $required
1341
1342 =cut
1343
1344 sub has_permission {
1345     my ( $self, $flagsrequired ) = @_;
1346     return unless $self->userid;
1347     # TODO code from haspermission needs to be moved here!
1348     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1349 }
1350
1351 =head3 is_adult
1352
1353 my $is_adult = $patron->is_adult
1354
1355 Return true if the patron has a category with a type Adult (A) or Organization (I)
1356
1357 =cut
1358
1359 sub is_adult {
1360     my ( $self ) = @_;
1361     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1362 }
1363
1364 =head3 is_child
1365
1366 my $is_child = $patron->is_child
1367
1368 Return true if the patron has a category with a type Child (C)
1369
1370 =cut
1371
1372 sub is_child {
1373     my( $self ) = @_;
1374     return $self->category->category_type eq 'C' ? 1 : 0;
1375 }
1376
1377 =head3 has_valid_userid
1378
1379 my $patron = Koha::Patrons->find(42);
1380 $patron->userid( $new_userid );
1381 my $has_a_valid_userid = $patron->has_valid_userid
1382
1383 my $patron = Koha::Patron->new( $params );
1384 my $has_a_valid_userid = $patron->has_valid_userid
1385
1386 Return true if the current userid of this patron is valid/unique, otherwise false.
1387
1388 Note that this should be done in $self->store instead and raise an exception if needed.
1389
1390 =cut
1391
1392 sub has_valid_userid {
1393     my ($self) = @_;
1394
1395     return 0 unless $self->userid;
1396
1397     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1398
1399     my $already_exists = Koha::Patrons->search(
1400         {
1401             userid => $self->userid,
1402             (
1403                 $self->in_storage
1404                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1405                 : ()
1406             ),
1407         }
1408     )->count;
1409     return $already_exists ? 0 : 1;
1410 }
1411
1412 =head3 generate_userid
1413
1414 my $patron = Koha::Patron->new( $params );
1415 $patron->generate_userid
1416
1417 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1418
1419 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1420
1421 =cut
1422
1423 sub generate_userid {
1424     my ($self) = @_;
1425     my $offset = 0;
1426     my $firstname = $self->firstname // q{};
1427     my $surname = $self->surname // q{};
1428     #The script will "do" the following code and increment the $offset until the generated userid is unique
1429     do {
1430       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1431       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1432       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1433       $userid = NFKD( $userid );
1434       $userid =~ s/\p{NonspacingMark}//g;
1435       $userid .= $offset unless $offset == 0;
1436       $self->userid( $userid );
1437       $offset++;
1438      } while (! $self->has_valid_userid );
1439
1440      return $self;
1441 }
1442
1443 =head3 add_extended_attribute
1444
1445 =cut
1446
1447 sub add_extended_attribute {
1448     my ($self, $attribute) = @_;
1449     $attribute->{borrowernumber} = $self->borrowernumber;
1450     return Koha::Patron::Attribute->new($attribute)->store;
1451 }
1452
1453 =head3 extended_attributes
1454
1455 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1456
1457 Or setter FIXME
1458
1459 =cut
1460
1461 sub extended_attributes {
1462     my ( $self, $attributes ) = @_;
1463     if ($attributes) {    # setter
1464         my $schema = $self->_result->result_source->schema;
1465         $schema->txn_do(
1466             sub {
1467                 # Remove the existing one
1468                 $self->extended_attributes->filter_by_branch_limitations->delete;
1469
1470                 # Insert the new ones
1471                 for my $attribute (@$attributes) {
1472                     eval {
1473                         $self->_result->create_related('borrower_attributes', $attribute);
1474                     };
1475                     # FIXME We should:
1476                     # 1 - Raise an exception
1477                     # 2 - Execute in a transaction and don't save
1478                     #  or Insert anyway but display a message on the UI
1479                     warn $@ if $@;
1480                 }
1481             }
1482         );
1483     }
1484
1485     my $rs = $self->_result->borrower_attributes;
1486     # We call search to use the filters in Koha::Patron::Attributes->search
1487     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1488 }
1489
1490 =head3 lock
1491
1492     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1493
1494     Lock and optionally expire a patron account.
1495     Remove holds and article requests if remove flag set.
1496     In order to distinguish from locking by entering a wrong password, let's
1497     call this an administrative lockout.
1498
1499 =cut
1500
1501 sub lock {
1502     my ( $self, $params ) = @_;
1503     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1504     if( $params->{expire} ) {
1505         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1506     }
1507     $self->store;
1508     if( $params->{remove} ) {
1509         $self->holds->delete;
1510         $self->article_requests->delete;
1511     }
1512     return $self;
1513 }
1514
1515 =head3 anonymize
1516
1517     Koha::Patrons->find($id)->anonymize;
1518
1519     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1520     are randomized, other personal data is cleared too.
1521     Patrons with issues are skipped.
1522
1523 =cut
1524
1525 sub anonymize {
1526     my ( $self ) = @_;
1527     if( $self->_result->issues->count ) {
1528         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1529         return;
1530     }
1531     # Mandatory fields come from the corresponding pref, but email fields
1532     # are removed since scrambled email addresses only generate errors
1533     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1534         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1535     $mandatory->{userid} = 1; # needed since sub store does not clear field
1536     my @columns = $self->_result->result_source->columns;
1537     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized/ } @columns;
1538     push @columns, 'dateofbirth'; # add this date back in
1539     foreach my $col (@columns) {
1540         $self->_anonymize_column($col, $mandatory->{lc $col} );
1541     }
1542     $self->anonymized(1)->store;
1543 }
1544
1545 sub _anonymize_column {
1546     my ( $self, $col, $mandatory ) = @_;
1547     my $col_info = $self->_result->result_source->column_info($col);
1548     my $type = $col_info->{data_type};
1549     my $nullable = $col_info->{is_nullable};
1550     my $val;
1551     if( $type =~ /char|text/ ) {
1552         $val = $mandatory
1553             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1554             : $nullable
1555             ? undef
1556             : q{};
1557     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1558         $val = $nullable ? undef : 0;
1559     } elsif( $type =~ /date|time/ ) {
1560         $val = $nullable ? undef : dt_from_string;
1561     }
1562     $self->$col($val);
1563 }
1564
1565 =head3 add_guarantor
1566
1567     my @relationships = $patron->add_guarantor(
1568         {
1569             borrowernumber => $borrowernumber,
1570             relationships  => $relationship,
1571         }
1572     );
1573
1574     Adds a new guarantor to a patron.
1575
1576 =cut
1577
1578 sub add_guarantor {
1579     my ( $self, $params ) = @_;
1580
1581     my $guarantor_id = $params->{guarantor_id};
1582     my $relationship = $params->{relationship};
1583
1584     return Koha::Patron::Relationship->new(
1585         {
1586             guarantee_id => $self->id,
1587             guarantor_id => $guarantor_id,
1588             relationship => $relationship
1589         }
1590     )->store();
1591 }
1592
1593 =head3 get_extended_attribute
1594
1595 my $attribute_value = $patron->get_extended_attribute( $code );
1596
1597 Return the attribute for the code passed in parameter.
1598
1599 It not exist it returns undef
1600
1601 Note that this will not work for repeatable attribute types.
1602
1603 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1604 (which should be a real patron's attribute (not extended)
1605
1606 =cut
1607
1608 sub get_extended_attribute {
1609     my ( $self, $code, $value ) = @_;
1610     my $rs = $self->_result->borrower_attributes;
1611     return unless $rs;
1612     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1613     return unless $attribute->count;
1614     return $attribute->next;
1615 }
1616
1617 =head3 to_api
1618
1619     my $json = $patron->to_api;
1620
1621 Overloaded method that returns a JSON representation of the Koha::Patron object,
1622 suitable for API output.
1623
1624 =cut
1625
1626 sub to_api {
1627     my ( $self, $params ) = @_;
1628
1629     my $json_patron = $self->SUPER::to_api( $params );
1630
1631     $json_patron->{restricted} = ( $self->is_debarred )
1632                                     ? Mojo::JSON->true
1633                                     : Mojo::JSON->false;
1634
1635     return $json_patron;
1636 }
1637
1638 =head3 to_api_mapping
1639
1640 This method returns the mapping for representing a Koha::Patron object
1641 on the API.
1642
1643 =cut
1644
1645 sub to_api_mapping {
1646     return {
1647         borrowernotes       => 'staff_notes',
1648         borrowernumber      => 'patron_id',
1649         branchcode          => 'library_id',
1650         categorycode        => 'category_id',
1651         checkprevcheckout   => 'check_previous_checkout',
1652         contactfirstname    => undef,                     # Unused
1653         contactname         => undef,                     # Unused
1654         contactnote         => 'altaddress_notes',
1655         contacttitle        => undef,                     # Unused
1656         dateenrolled        => 'date_enrolled',
1657         dateexpiry          => 'expiry_date',
1658         dateofbirth         => 'date_of_birth',
1659         debarred            => undef,                     # replaced by 'restricted'
1660         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1661         emailpro            => 'secondary_email',
1662         flags               => undef,    # permissions manipulation handled in /permissions
1663         gonenoaddress       => 'incorrect_address',
1664         guarantorid         => 'guarantor_id',
1665         lastseen            => 'last_seen',
1666         lost                => 'patron_card_lost',
1667         opacnote            => 'opac_notes',
1668         othernames          => 'other_name',
1669         password            => undef,            # password manipulation handled in /password
1670         phonepro            => 'secondary_phone',
1671         relationship        => 'relationship_type',
1672         sex                 => 'gender',
1673         smsalertnumber      => 'sms_number',
1674         sort1               => 'statistics_1',
1675         sort2               => 'statistics_2',
1676         autorenew_checkouts => 'autorenew_checkouts',
1677         streetnumber        => 'street_number',
1678         streettype          => 'street_type',
1679         zipcode             => 'postal_code',
1680         B_address           => 'altaddress_address',
1681         B_address2          => 'altaddress_address2',
1682         B_city              => 'altaddress_city',
1683         B_country           => 'altaddress_country',
1684         B_email             => 'altaddress_email',
1685         B_phone             => 'altaddress_phone',
1686         B_state             => 'altaddress_state',
1687         B_streetnumber      => 'altaddress_street_number',
1688         B_streettype        => 'altaddress_street_type',
1689         B_zipcode           => 'altaddress_postal_code',
1690         altcontactaddress1  => 'altcontact_address',
1691         altcontactaddress2  => 'altcontact_address2',
1692         altcontactaddress3  => 'altcontact_city',
1693         altcontactcountry   => 'altcontact_country',
1694         altcontactfirstname => 'altcontact_firstname',
1695         altcontactphone     => 'altcontact_phone',
1696         altcontactsurname   => 'altcontact_surname',
1697         altcontactstate     => 'altcontact_state',
1698         altcontactzipcode   => 'altcontact_postal_code'
1699     };
1700 }
1701
1702 =head2 Internal methods
1703
1704 =head3 _type
1705
1706 =cut
1707
1708 sub _type {
1709     return 'Borrower';
1710 }
1711
1712 =head1 AUTHORS
1713
1714 Kyle M Hall <kyle@bywatersolutions.com>
1715 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
1716 Martin Renvoize <martin.renvoize@ptfs-europe.com>
1717
1718 =cut
1719
1720 1;