Koha/Plugins/Base.pm

   1 package Koha::Plugins::Base;
   2
   3 # Copyright 2012 Kyle Hall
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Module::Pluggable require => 1;
  23 use Cwd qw(abs_path);
  24
  25 use base qw{Module::Bundled::Files};
  26
  27 use C4::Context;
  28
  29 =head1 NAME
  30
  31 Koha::Plugins::Base - Base Module for plugins
  32
  33 =cut
  34
  35 sub new {
  36     my ( $class, $args ) = @_;
  37
  38     return unless ( C4::Context->config("enable_plugins") || $args->{'enable_plugins'} );
  39
  40     $args->{'class'} = $class;
  41     $args->{'template'} = Template->new( { ABSOLUTE => 1 } );
  42
  43     my $self = bless( $args, $class );
  44
  45     ## Run the installation method if it exists and hasn't been run before
  46     if ( $self->can('install') && !$self->retrieve_data('__INSTALLED__') ) {
  47         if ( $self->install() ) {
  48             $self->store_data( { '__INSTALLED__' => 1 } );
  49         } else {
  50             warn "Plugin $class failed during installation!";
  51         }
  52     }
  53
  54     return $self;
  55 }
  56
  57 =head2 store_data
  58
  59 store_data allows a plugin to store key value pairs in the database for future use.
  60
  61 usage: $self->store_data({ param1 => 'param1val', param2 => 'param2value' })
  62
  63 =cut
  64
  65 sub store_data {
  66     my ( $self, $data ) = @_;
  67
  68     my $dbh = C4::Context->dbh;
  69     my $sql = "REPLACE INTO plugin_data SET plugin_class = ?, plugin_key = ?, plugin_value = ?";
  70     my $sth = $dbh->prepare($sql);
  71
  72     foreach my $key ( keys %$data ) {
  73         $sth->execute( $self->{'class'}, $key, $data->{$key} );
  74     }
  75 }
  76
  77 =head2 retrieve_data
  78
  79 retrieve_data allows a plugin to read the values that were previously saved with store_data
  80
  81 usage: my $value = $self->retrieve_data( $key );
  82
  83 =cut
  84
  85 sub retrieve_data {
  86     my ( $self, $key ) = @_;
  87
  88     my $dbh = C4::Context->dbh;
  89     my $sql = "SELECT plugin_value FROM plugin_data WHERE plugin_class = ? AND plugin_key = ?";
  90     my $sth = $dbh->prepare($sql);
  91     $sth->execute( $self->{'class'}, $key );
  92     my $row = $sth->fetchrow_hashref();
  93
  94     return $row->{'plugin_value'};
  95 }
  96
  97 =head2 get_template
  98
  99 get_template returns a Template object. Eventually this will probably be calling
 100 C4:Template, but at the moment, it does not.
 101
 102 =cut
 103
 104 sub get_template {
 105     my ( $self, $args ) = @_;
 106
 107     require C4::Auth;
 108
 109     my $template_name = $args->{'file'} // '';
 110     # if not absolute, call mbf_path, which dies if file does not exist
 111     $template_name = $self->mbf_path( $template_name )
 112         if $template_name !~ m/^\//;
 113     my ( $template, $loggedinuser, $cookie ) = C4::Auth::get_template_and_user(
 114         {   template_name   => $template_name,
 115             query           => $self->{'cgi'},
 116             type            => "intranet",
 117             authnotrequired => 1,
 118         }
 119     );
 120
 121     $template->param(
 122         CLASS       => $self->{'class'},
 123         METHOD      => scalar $self->{'cgi'}->param('method'),
 124         PLUGIN_PATH => $self->get_plugin_http_path(),
 125     );
 126
 127     return $template;
 128 }
 129
 130 sub get_metadata {
 131     my ( $self, $args ) = @_;
 132
 133     return $self->{'metadata'};
 134 }
 135
 136 =head2 get_qualified_table_name
 137
 138 To avoid naming conflict, each plugins tables should use a fully qualified namespace.
 139 To avoid hardcoding and make plugins more flexible, this method will return the proper
 140 fully qualified table name.
 141
 142 usage: my $table = $self->get_qualified_table_name( 'myTable' );
 143
 144 =cut
 145
 146 sub get_qualified_table_name {
 147     my ( $self, $table_name ) = @_;
 148
 149     return lc( join( '_', split( '::', $self->{'class'} ), $table_name ) );
 150 }
 151
 152 =head2 get_plugin_http_path
 153
 154 To access a plugin's own resources ( images, js files, css files, etc... )
 155 a plugin will need to know what path to use in the template files. This
 156 method returns that path.
 157
 158 usage: my $path = $self->get_plugin_http_path();
 159
 160 =cut
 161
 162 sub get_plugin_http_path {
 163     my ($self) = @_;
 164
 165     return "/plugin/" . join( '/', split( '::', $self->{'class'} ) );
 166 }
 167
 168 =head2 go_home
 169
 170    go_home is a quick redirect to the Koha plugins home page
 171
 172 =cut
 173
 174 sub go_home {
 175     my ( $self, $params ) = @_;
 176
 177     print $self->{'cgi'}->redirect("/cgi-bin/koha/plugins/plugins-home.pl");
 178 }
 179
 180 1;
 181 __END__
 182
 183 =head1 AUTHOR
 184
 185 Kyle M Hall <kyle.m.hall@gmail.com>
 186
 187 =cut