Koha/Plugins.pm

   1 package Koha::Plugins;
   2
   3 # Copyright 2012 Kyle Hall
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Array::Utils qw( array_minus );
  23 use Class::Inspector;
  24 use List::MoreUtils qw( any );
  25 use Module::Load::Conditional qw( can_load );
  26 use Module::Load;
  27 use Module::Pluggable search_path => ['Koha::Plugin'], except => qr/::Edifact(|::Line|::Message|::Order|::Segment|::Transport)$/;
  28 use Try::Tiny;
  29
  30 use C4::Context;
  31 use C4::Output;
  32
  33 use Koha::Cache::Memory::Lite;
  34 use Koha::Exceptions::Plugin;
  35 use Koha::Plugins::Methods;
  36
  37 use constant ENABLED_PLUGINS_CACHE_KEY => 'enabled_plugins';
  38
  39 BEGIN {
  40     my $pluginsdir = C4::Context->config("pluginsdir");
  41     my @pluginsdir = ref($pluginsdir) eq 'ARRAY' ? @$pluginsdir : $pluginsdir;
  42     push @INC, array_minus(@pluginsdir, @INC) ;
  43     pop @INC if $INC[-1] eq '.';
  44 }
  45
  46 =head1 NAME
  47
  48 Koha::Plugins - Module for loading and managing plugins.
  49
  50 =head2 new
  51
  52 Constructor
  53
  54 =cut
  55
  56 sub new {
  57     my ( $class, $args ) = @_;
  58
  59     return unless ( C4::Context->config("enable_plugins") || $args->{'enable_plugins'} );
  60
  61     $args->{'pluginsdir'} = C4::Context->config("pluginsdir");
  62
  63     return bless( $args, $class );
  64 }
  65
  66 =head2 call
  67
  68 Calls a plugin method for all enabled plugins
  69
  70     @responses = Koha::Plugins->call($method, @args)
  71
  72 Note: Pass your arguments as refs, when you want subsequent plugins to use the value
  73 updated by preceding plugins, provided that these plugins support that.
  74
  75 =cut
  76
  77 sub call {
  78     my ($class, $method, @args) = @_;
  79
  80     return unless C4::Context->config('enable_plugins');
  81
  82     my @responses;
  83     my @plugins = $class->get_enabled_plugins();
  84     @plugins = grep { $_->can($method) } @plugins;
  85
  86     # TODO: Remove warn when after_hold_create is removed from the codebase
  87     warn "after_hold_create is deprecated and will be removed soon. Contact the following plugin's authors: " . join( ', ', map {$_->{metadata}->{name}} @plugins)
  88         if $method eq 'after_hold_create' and @plugins;
  89
  90     foreach my $plugin (@plugins) {
  91         my $response = eval { $plugin->$method(@args) };
  92         if ($@) {
  93             warn sprintf("Plugin error (%s): %s", $plugin->get_metadata->{name}, $@);
  94             next;
  95         }
  96
  97         push @responses, $response;
  98     }
  99
 100     return @responses;
 101 }
 102
 103 =head2 get_enabled_plugins
 104
 105 Returns a list of enabled plugins.
 106
 107     @plugins = Koha::Plugins->get_enabled_plugins( [ verbose => 1 ] );
 108
 109 =cut
 110
 111 sub get_enabled_plugins {
 112     my ( $class, $params ) = @_;
 113
 114     return unless C4::Context->config('enable_plugins');
 115
 116     my $enabled_plugins = Koha::Cache::Memory::Lite->get_from_cache(ENABLED_PLUGINS_CACHE_KEY);
 117     unless ($enabled_plugins) {
 118         my $verbose = $params->{verbose} // $class->_verbose;
 119         $enabled_plugins = [];
 120
 121         my @plugin_classes;
 122         try {
 123             my $rs = Koha::Database->schema->resultset('PluginData');
 124             $rs = $rs->search({ plugin_key => '__ENABLED__', plugin_value => 1 });
 125             @plugin_classes = $rs->get_column('plugin_class')->all();
 126         } catch {
 127             warn "$_";
 128         };
 129
 130         foreach my $plugin_class (@plugin_classes) {
 131             next unless can_load( modules => { $plugin_class => undef }, verbose => $verbose, nocache => 1 );
 132
 133             my $plugin = eval { $plugin_class->new() };
 134             if ($@ || !$plugin) {
 135                 warn "Failed to instantiate plugin $plugin_class: $@";
 136                 next;
 137             }
 138
 139             push @$enabled_plugins, $plugin;
 140         }
 141         Koha::Cache::Memory::Lite->set_in_cache(ENABLED_PLUGINS_CACHE_KEY, $enabled_plugins);
 142     }
 143
 144     return @$enabled_plugins;
 145 }
 146
 147 sub _verbose {
 148     my $class = shift;
 149     # Return false when running unit tests
 150     return exists $ENV{_} && $ENV{_} =~ /\/prove(\s|$)|\.t$/ ? 0 : 1;
 151 }
 152
 153 =head2 feature_enabled
 154
 155 Returns a boolean denoting whether a plugin based feature is enabled or not.
 156
 157     $enabled = Koha::Plugins->feature_enabled('method_name');
 158
 159 =cut
 160
 161 sub feature_enabled {
 162     my ( $class, $method ) = @_;
 163
 164     return 0 unless C4::Context->config('enable_plugins');
 165
 166     my $key     = "ENABLED_PLUGIN_FEATURE_" . $method;
 167     my $feature = Koha::Cache::Memory::Lite->get_from_cache($key);
 168     unless ( defined($feature) ) {
 169         my @plugins = $class->get_enabled_plugins();
 170         my $enabled = any { $_->can($method) } @plugins;
 171         Koha::Cache::Memory::Lite->set_in_cache( $key, $enabled );
 172     }
 173     return $feature;
 174 }
 175
 176 =head2 GetPlugins
 177
 178 This will return a list of all available plugins, optionally limited by
 179 method or metadata value.
 180
 181     my @plugins = Koha::Plugins::GetPlugins({
 182         method => 'some_method',
 183         metadata => { some_key => 'some_value' },
 184         [ verbose => 1 ],
 185     });
 186
 187 The method and metadata parameters are optional.
 188 If you pass multiple keys in the metadata hash, all keys must match.
 189
 190 =cut
 191
 192 sub GetPlugins {
 193     my ( $self, $params ) = @_;
 194
 195     my $method       = $params->{method};
 196     my $req_metadata = $params->{metadata} // {};
 197     my $verbose      = delete $params->{verbose} // $self->_verbose;
 198
 199     my $filter = ( $method ) ? { plugin_method => $method } : undef;
 200
 201     my $plugin_classes = Koha::Plugins::Methods->search(
 202         $filter,
 203         {   columns  => 'plugin_class',
 204             distinct => 1
 205         }
 206     )->_resultset->get_column('plugin_class');
 207
 208     my @plugins;
 209
 210     # Loop through all plugins that implement at least a method
 211     while ( my $plugin_class = $plugin_classes->next ) {
 212
 213         if ( can_load( modules => { $plugin_class => undef }, verbose => $verbose, nocache => 1 ) ) {
 214
 215             my $plugin;
 216             my $failed_instantiation;
 217
 218             try {
 219                 $plugin = $plugin_class->new({
 220                     enable_plugins => $self->{'enable_plugins'}
 221                         # loads even if plugins are disabled
 222                         # FIXME: is this for testing without bothering to mock config?
 223                 });
 224             }
 225             catch {
 226                 warn "$_";
 227                 $failed_instantiation = 1;
 228             };
 229
 230             next if $failed_instantiation;
 231
 232             next unless $plugin->is_enabled or
 233                         defined($params->{all}) && $params->{all};
 234
 235             # filter the plugin out by metadata
 236             my $plugin_metadata = $plugin->get_metadata;
 237             next
 238                 if $plugin_metadata
 239                 and %$req_metadata
 240                 and any { !$plugin_metadata->{$_} || $plugin_metadata->{$_} ne $req_metadata->{$_} } keys %$req_metadata;
 241
 242             push @plugins, $plugin;
 243         } elsif ( defined($params->{errors}) && $params->{errors} ){
 244             push @plugins, { error => 'cannot_load', name => $plugin_class };
 245         }
 246
 247     }
 248
 249     return @plugins;
 250 }
 251
 252 =head2 InstallPlugins
 253
 254 Koha::Plugins::InstallPlugins( [ verbose => 1 ] )
 255
 256 This method iterates through all plugins physically present on a system.
 257 For each plugin module found, it will test that the plugin can be loaded,
 258 and if it can, will store its available methods in the plugin_methods table.
 259
 260 NOTE: We reload all plugins here as a protective measure in case someone
 261 has removed a plugin directly from the system without using the UI
 262
 263 =cut
 264
 265 sub InstallPlugins {
 266     my ( $self, $params ) = @_;
 267     my $verbose = $params->{verbose} // $self->_verbose;
 268
 269     my @plugin_classes = $self->plugins();
 270     my @plugins;
 271
 272     foreach my $plugin_class (@plugin_classes) {
 273         if ( can_load( modules => { $plugin_class => undef }, verbose => $verbose, nocache => 1 ) ) {
 274             next unless $plugin_class->isa('Koha::Plugins::Base');
 275
 276             my $plugin;
 277             my $failed_instantiation;
 278
 279             try {
 280                 $plugin = $plugin_class->new({ enable_plugins => $self->{'enable_plugins'} });
 281             }
 282             catch {
 283                 warn "$_";
 284                 $failed_instantiation = 1;
 285             };
 286
 287             next if $failed_instantiation;
 288
 289             Koha::Plugins::Methods->search({ plugin_class => $plugin_class })->delete();
 290
 291             foreach my $method ( @{ Class::Inspector->methods( $plugin_class, 'public' ) } ) {
 292                 Koha::Plugins::Method->new(
 293                     {
 294                         plugin_class  => $plugin_class,
 295                         plugin_method => $method,
 296                     }
 297                 )->store();
 298             }
 299
 300             push @plugins, $plugin;
 301         }
 302     }
 303
 304     Koha::Cache::Memory::Lite->clear_from_cache(ENABLED_PLUGINS_CACHE_KEY);
 305
 306     return @plugins;
 307 }
 308
 309 1;
 310 __END__
 311
 312 =head1 AUTHOR
 313
 314 Kyle M Hall <kyle.m.hall@gmail.com>
 315
 316 =cut