Koha/REST/Plugin/Objects.pm

   1 package Koha::REST::Plugin::Objects;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Plugin';
  21
  22 use JSON;
  23
  24 =head1 NAME
  25
  26 Koha::REST::Plugin::Objects
  27
  28 =head1 API
  29
  30 =head2 Helper methods
  31
  32 =cut
  33
  34 sub register {
  35     my ( $self, $app ) = @_;
  36
  37 =head3 objects.find
  38
  39     my $patrons_rs = Koha::Patrons->new;
  40     my $patrons = $c->objects->find( $patrons_rs, $id );
  41
  42 Performs a database search using given Koha::Objects object and the $id.
  43
  44 Returns I<undef> if no object is found Returns the I<API representation> of
  45 the requested object. It passes through any embeds if specified.
  46
  47 =cut
  48
  49     $app->helper(
  50         'objects.find' => sub {
  51             my ( $c, $result_set, $id ) = @_;
  52
  53             my $attributes = {};
  54
  55             # Look for embeds
  56             my $embed = $c->stash('koha.embed');
  57             # Generate prefetches for embedded stuff
  58             $c->dbic_merge_prefetch(
  59                 {
  60                     attributes => $attributes,
  61                     result_set => $result_set
  62                 }
  63             );
  64
  65             my $object = $result_set->find( $id, $attributes );
  66
  67             return unless $object;
  68
  69             return $object->to_api({ embed => $embed });
  70         }
  71     );
  72
  73 =head3 objects.search
  74
  75     my $patrons_rs = Koha::Patrons->new;
  76     my $patrons = $c->objects->search( $patrons_rs );
  77
  78 Performs a database search using given Koha::Objects object and query parameters.
  79
  80 Returns an arrayref of the hashrefs representing the resulting objects
  81 for API rendering.
  82
  83 =cut
  84
  85     $app->helper(
  86         'objects.search' => sub {
  87             my ( $c, $result_set ) = @_;
  88
  89             my $args = $c->validation->output;
  90             my $attributes = {};
  91
  92             # Extract reserved params
  93             my ( $filtered_params, $reserved_params, $path_params ) = $c->extract_reserved_params($args);
  94             # Privileged reques?
  95             my $is_public = $c->stash('is_public');
  96             # Look for embeds
  97             my $embed = $c->stash('koha.embed');
  98
  99             # Merge sorting into query attributes
 100             $c->dbic_merge_sorting(
 101                 {
 102                     attributes => $attributes,
 103                     params     => $reserved_params,
 104                     result_set => $result_set
 105                 }
 106             );
 107
 108             # If no pagination parameters are passed, default
 109             $reserved_params->{_per_page} //= C4::Context->preference('RESTdefaultPageSize');
 110             $reserved_params->{_page}     //= 1;
 111
 112             unless ( $reserved_params->{_per_page} == -1 ) {
 113                 # Merge pagination into query attributes
 114                 $c->dbic_merge_pagination(
 115                     {
 116                         filter => $attributes,
 117                         params => $reserved_params
 118                     }
 119                 );
 120             }
 121
 122             # Generate prefetches for embedded stuff
 123             $c->dbic_merge_prefetch(
 124                 {
 125                     attributes => $attributes,
 126                     result_set => $result_set
 127                 }
 128             );
 129
 130             # Call the to_model function by reference, if defined
 131             if ( defined $filtered_params ) {
 132
 133                 # Apply the mapping function to the passed params
 134                 $filtered_params = $result_set->attributes_from_api($filtered_params);
 135                 $filtered_params = $c->build_query_params( $filtered_params, $reserved_params );
 136             }
 137
 138             if( defined $reserved_params->{q} || defined $reserved_params->{query} || defined $reserved_params->{'x-koha-query'}) {
 139                 $filtered_params //={};
 140                 my @query_params_array;
 141                 my $query_params;
 142                 push @query_params_array, $reserved_params->{query} if defined $reserved_params->{query};
 143                 my $json = JSON->new;
 144                 push @query_params_array, $json->decode($reserved_params->{q}) if defined $reserved_params->{q};
 145                 push @query_params_array, $json->decode($reserved_params->{'x-koha-query'}) if defined $reserved_params->{'x-koha-query'};
 146
 147                 if(scalar(@query_params_array) > 1) {
 148                     $query_params = {'-and' => \@query_params_array};
 149                 } else {
 150                     $query_params = $query_params_array[0];
 151                 }
 152
 153                 $filtered_params = $c->merge_q_params( $filtered_params, $query_params, $result_set );
 154             }
 155             # Perform search
 156             my $objects = $result_set->search( $filtered_params, $attributes );
 157             my $total   = $result_set->search->count;
 158
 159             $c->add_pagination_headers(
 160                 {
 161                     total      => ($objects->is_paged ? $objects->pager->total_entries : $objects->count),
 162                     base_total => $total,
 163                     params     => $args,
 164                 }
 165             );
 166
 167             return $objects->to_api({ embed => $embed, public => $is_public });
 168         }
 169     );
 170 }
 171
 172 1;