catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getLanguages);
 147 use C4::Koha;
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search::History;
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 197     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 198         $template->param(
 199             holdfor => $cgi->cookie("holdfor"),
 200             holdfor_surname => $holdfor_patron->surname,
 201             holdfor_firstname => $holdfor_patron->firstname,
 202             holdfor_cardnumber => $holdfor_patron->cardnumber,
 203         );
 204     }
 205 }
 206
 207 if($cgi->cookie("holdforclub")){
 208     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 209     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 210         $template->param(
 211             holdforclub => $cgi->cookie("holdforclub"),
 212             holdforclub_name => $holdfor_club->name,
 213         );
 214     }
 215 }
 216
 217 if($cgi->cookie("searchToOrder")){
 218     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 219     $template->param(
 220         searchtoorder_basketno => $basketno,
 221         searchtoorder_vendorid => $vendorid
 222     );
 223 }
 224
 225 # get biblionumbers stored in the cart
 226 my @cart_list;
 227
 228 if($cgi->cookie("intranet_bib_list")){
 229     my $cart_list = $cgi->cookie("intranet_bib_list");
 230     @cart_list = split(/\//, $cart_list);
 231 }
 232
 233 my @search_groups =
 234   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 235 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 236
 237 $template->param(
 238     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 239     search_groups    => \@search_groups,
 240 );
 241
 242 # load the Type stuff
 243 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 244 my $advancedsearchesloop = prepare_adv_search_types($types);
 245 $template->param(advancedsearchesloop => $advancedsearchesloop);
 246
 247 $template->param( searchid => scalar $cgi->param('searchid'), );
 248
 249 # The following should only be loaded if we're bringing up the advanced search template
 250 if ( $template_type eq 'advsearch' ) {
 251
 252     # load the servers (used for searching -- to do federated searching, etc.)
 253     my $primary_servers_loop;# = displayPrimaryServers();
 254     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 255
 256     my $secondary_servers_loop;
 257     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 258
 259     # set the default sorting
 260     if (   C4::Context->preference('defaultSortField')
 261         && C4::Context->preference('defaultSortOrder') ) {
 262         my $default_sort_by =
 263             C4::Context->preference('defaultSortField') . '_'
 264           . C4::Context->preference('defaultSortOrder');
 265         $template->param( sort_by => $default_sort_by  );
 266     }
 267
 268     # determine what to display next to the search boxes (ie, boolean option
 269     # shouldn't appear on the first one, scan indexes should, adding a new
 270     # box should only appear on the last, etc.
 271     my @search_boxes_array;
 272     my $search_boxes_count = 3; # begin with 3 boxes
 273     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 274     for (my $i=1;$i<=$search_boxes_count;$i++) {
 275         # if it's the first one, don't display boolean option, but show scan indexes
 276         if ($i==1) {
 277             push @search_boxes_array, {scan_index => 1};
 278         }
 279         # if it's the last one, show the 'add field' box
 280         elsif ($i==$search_boxes_count) {
 281             push @search_boxes_array,
 282                 {
 283                 boolean => 1,
 284                 add_field => 1,
 285                 };
 286         }
 287         else {
 288             push @search_boxes_array,
 289                 {
 290                 boolean => 1,
 291                 };
 292         }
 293
 294     }
 295     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 296                       search_boxes_loop => \@search_boxes_array);
 297
 298     # load the language limits (for search)
 299     my $languages_limit_loop = getLanguages($lang, 1);
 300     $template->param(search_languages_loop => $languages_limit_loop,);
 301
 302     # Expanded search options in advanced search:
 303     # use the global setting by default, but let the user override it
 304     {
 305         my $expanded = $cgi->param('expanded_options');
 306         $expanded = C4::Context->preference("expandedSearchOption") || 0
 307             if !defined($expanded) || $expanded !~ /^0|1$/;
 308         $template->param( expanded_options => $expanded );
 309     }
 310
 311     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 312
 313     output_html_with_http_headers $cgi, $cookie, $template->output;
 314     exit;
 315 }
 316
 317 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 318
 319 # Fetch the paramater list as a hash in scalar context:
 320 #  * returns paramater list as tied hash ref
 321 #  * we can edit the values by changing the key
 322 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 323 my $params = $cgi->Vars;
 324 # Params that can have more than one value
 325 # sort by is used to sort the query
 326 # in theory can have more than one but generally there's just one
 327 my @sort_by;
 328 my $default_sort_by;
 329 if (   C4::Context->preference('defaultSortField')
 330     && C4::Context->preference('defaultSortOrder') ) {
 331     $default_sort_by =
 332         C4::Context->preference('defaultSortField') . '_'
 333       . C4::Context->preference('defaultSortOrder');
 334 }
 335
 336 @sort_by = $cgi->multi_param('sort_by');
 337 $sort_by[0] = $default_sort_by unless $sort_by[0];
 338 foreach my $sort (@sort_by) {
 339     $template->param($sort => 1) if $sort;
 340 }
 341 $template->param('sort_by' => $sort_by[0]);
 342
 343 # Use the servers defined, or just search our local catalog(default)
 344 my @servers = $cgi->multi_param('server');
 345 unless (@servers) {
 346     #FIXME: this should be handled using Context.pm
 347     @servers = ("biblioserver");
 348     # @servers = C4::Context->config("biblioserver");
 349 }
 350 # operators include boolean and proximity operators and are used
 351 # to evaluate multiple operands
 352 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 353
 354 # indexes are query qualifiers, like 'title', 'author', etc. They
 355 # can be single or multiple parameters separated by comma: kw,right-Truncation
 356 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 357
 358 # if a simple index (only one)  display the index used in the top search box
 359 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 360     my $idx = "ms_".$indexes[0];
 361     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 362     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 363     $template->param($idx => 1);
 364 }
 365
 366 # an operand can be a single term, a phrase, or a complete ccl query
 367 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 368
 369 # if a simple search, display the value in the search box
 370 if ($operands[0] && !$operands[1]) {
 371     my $ms_query = $operands[0];
 372     $ms_query =~ s/ #\S+//;
 373     $template->param(ms_value => $ms_query);
 374 }
 375
 376 # limits are use to limit to results to a pre-defined category such as branch or language
 377 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 378 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 379 my %is_nolimit = map { $_ => 1 } @nolimits;
 380 @limits = grep { not $is_nolimit{$_} } @limits;
 381
 382 if($params->{'multibranchlimit'}) {
 383     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 384     my @libraries = $search_group->all_libraries;
 385     my $multibranch = '('.join( " OR ", map { '(homebranch: ' . $_->branchcode .')' } @libraries ) .')';
 386     push @limits, $multibranch if ($multibranch ne  '()');
 387 }
 388
 389 my $available;
 390 foreach my $limit(@limits) {
 391     if ($limit =~/available/) {
 392         $available = 1;
 393     }
 394 }
 395 $template->param(available => $available);
 396
 397 # append year limits if they exist
 398 my $limit_yr;
 399 my $limit_yr_value;
 400 if ($params->{'limit-yr'}) {
 401     if ($params->{'limit-yr'} =~ /\d{4}/) {
 402         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 403         $limit_yr_value = $params->{'limit-yr'};
 404     }
 405     push @limits,$limit_yr;
 406     #FIXME: Should return a error to the user, incorect date format specified
 407 }
 408
 409 # convert indexes and operands to corresponding parameter names for the z3950 search
 410 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 411 my $z3950par;
 412 my $indexes2z3950 = {
 413     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 414     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 415     ti=>'title', 'ti,phr'=>'title', se=>'title'
 416 };
 417 for (my $ii = 0; $ii < @operands; ++$ii)
 418 {
 419     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 420     if (defined $name && defined $operands[$ii])
 421     {
 422         $z3950par ||= {};
 423         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 424     }
 425 }
 426
 427
 428 # Params that can only have one value
 429 my $scan = $params->{'scan'};
 430 my $count = C4::Context->preference('numSearchResults') || 20;
 431 my $results_per_page = $params->{'count'} || $count;
 432 my $offset = $params->{'offset'} || 0;
 433 my $whole_record = $params->{'whole_record'} || 0;
 434 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 435 $offset = 0 if $offset < 0;
 436 my $page = $cgi->param('page') || 1;
 437 #my $offset = ($page-1)*$results_per_page;
 438
 439 # Define some global variables
 440 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 441
 442 my $builder = Koha::SearchEngine::QueryBuilder->new(
 443     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 444 my $searcher = Koha::SearchEngine::Search->new(
 445     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 446
 447 ## I. BUILD THE QUERY
 448 (
 449     $error,             $query, $simple_query, $query_cgi,
 450     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 451     $query_type
 452   )
 453   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 454     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 455
 456 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 457
 458 ## parse the query_cgi string and put it into a form suitable for <input>s
 459 my @query_inputs;
 460 my $scan_index_to_use;
 461 my $scan_search_term_to_use;
 462
 463 if ($query_cgi) {
 464     for my $this_cgi ( split('&', $query_cgi) ) {
 465         next unless $this_cgi;
 466         $this_cgi =~ m/(.*?)=(.*)/;
 467         my $input_name = $1;
 468         my $input_value = $2;
 469         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 470         if ($input_name eq 'idx') {
 471             # The form contains multiple fields, so take the first value as the scan index
 472             $scan_index_to_use = $input_value unless $scan_index_to_use;
 473         }
 474         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 475             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 476         }
 477     }
 478 }
 479
 480 $template->param ( QUERY_INPUTS => \@query_inputs,
 481                    scan_index_to_use => $scan_index_to_use,
 482                    scan_search_term_to_use => $scan_search_term_to_use );
 483
 484 ## parse the limit_cgi string and put it into a form suitable for <input>s
 485 my @limit_inputs;
 486 if ($limit_cgi) {
 487     for my $this_cgi ( split('&', $limit_cgi) ) {
 488         next unless $this_cgi;
 489         # handle special case limit-yr
 490         if ($this_cgi =~ /yr,st-numeric/) {
 491             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 492             next;
 493         }
 494         $this_cgi =~ m/(.*=)(.*)/;
 495         my $input_name = $1;
 496         my $input_value = $2;
 497         $input_name =~ s/=$//;
 498         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 499     }
 500 }
 501 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 502
 503 ## II. DO THE SEARCH AND GET THE RESULTS
 504 my $total = 0; # the total results for the whole set
 505 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 506 my $results_hashref;
 507
 508 eval {
 509     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 510     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 511         $query,            $simple_query, \@sort_by,       \@servers,
 512         $results_per_page, $offset,       undef,           $itemtypes,
 513         $query_type,       $scan
 514     );
 515 };
 516
 517 if ($@ || $error) {
 518     $template->param(query_error => $error.$@);
 519     output_html_with_http_headers $cgi, $cookie, $template->output;
 520     exit;
 521 }
 522
 523 # At this point, each server has given us a result set
 524 # now we build that set for template display
 525 my @sup_results_array;
 526 for (my $i=0;$i<@servers;$i++) {
 527     my $server = $servers[$i];
 528     if ($server =~/biblioserver/) { # this is the local bibliographic server
 529         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 530         my $page = $cgi->param('page') || 0;
 531         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 532                                        $results_hashref->{$server}->{"RECORDS"});
 533         $total = $total + $hits;
 534
 535         # Search history
 536         if (C4::Context->preference('EnableSearchHistory')) {
 537             unless ( $offset ) {
 538                 my $path_info = $cgi->url(-path_info=>1);
 539                 my $query_cgi_history = $cgi->url(-query=>1);
 540                 $query_cgi_history =~ s/^$path_info\?//;
 541                 $query_cgi_history =~ s/;/&/g;
 542                 my $query_desc_history = $query_desc;
 543                 $query_desc_history .= ", $limit_desc"
 544                     if $limit_desc;
 545
 546                 C4::Search::History::add({
 547                     userid => $borrowernumber,
 548                     sessionid => $cgi->cookie("CGISESSID"),
 549                     query_desc => $query_desc_history,
 550                     query_cgi => $query_cgi_history,
 551                     total => $total,
 552                     type => "biblio",
 553                 });
 554             }
 555             $template->param( EnableSearchHistory => 1 );
 556         }
 557
 558         ## If there's just one result, redirect to the detail page unless doing an index scan
 559         if ($total == 1 && !$scan) {
 560             my $biblionumber = $newresults[0]->{biblionumber};
 561             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 562             my $views = { C4::Search::enabled_staff_search_views };
 563             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 564                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 565             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 566                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 567             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 568                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 569             } else {
 570                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 571             }
 572             exit;
 573         }
 574
 575         # set up parameters if user wishes to re-run the search
 576         # as a Z39.50 search
 577         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 578
 579         if ($hits) {
 580             $template->param(total => $hits);
 581             if ($limit_cgi) {
 582                 my $limit_cgi_not_availablity = $limit_cgi;
 583                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 584                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 585             }
 586             $template->param(limit_cgi => $limit_cgi);
 587             $template->param(query_cgi => $query_cgi);
 588             $template->param(query_desc => $query_desc);
 589             $template->param(limit_desc => $limit_desc);
 590             $template->param(offset     => $offset);
 591             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 592             if ($query_desc || $limit_desc) {
 593                 $template->param(searchdesc => 1);
 594             }
 595             $template->param(results_per_page =>  $results_per_page);
 596             # must define a value for size if not present in DB
 597             # in order to avoid problems generated by the default size value in TT
 598             foreach my $line (@newresults) {
 599                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 600                 # while we're checking each line, see if item is in the cart
 601                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 602                     $line->{'incart'} = 1;
 603                 }
 604             }
 605             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 606                 Koha::SearchEngine::Search->pagination_bar(
 607                     {
 608                         hits              => $hits,
 609                         max_result_window => $searcher->max_result_window,
 610                         results_per_page  => $results_per_page,
 611                         offset            => $offset,
 612                         sort_by           => \@sort_by
 613                     }
 614                 );
 615             $template->param( hits_to_paginate => $hits_to_paginate );
 616             $template->param(SEARCH_RESULTS => \@newresults);
 617             # FIXME: no previous_page_offset when pages < 2
 618             $template->param(   PAGE_NUMBERS => $page_numbers,
 619                                 last_page_offset => $last_page_offset,
 620                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 621             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 622         }
 623
 624
 625         # no hits
 626         else {
 627             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 628         }
 629
 630     } # end of the if local
 631
 632     # asynchronously search the authority server
 633     elsif ($server =~/authorityserver/) { # this is the local authority server
 634         my @inner_sup_results_array;
 635         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 636             my $marc_record_object = C4::Search::new_record_from_zebra(
 637                 'authorityserver',
 638                 $sup_record
 639             );
 640             # warn "Authority Found: ".$marc_record_object->as_formatted();
 641             push @inner_sup_results_array, {
 642                 'title' => $marc_record_object->field(100)->subfield('a'),
 643                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 644             };
 645         }
 646         push @sup_results_array, {  servername => $server,
 647                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 648     }
 649     # FIXME: can add support for other targets as needed here
 650     $template->param(           outer_sup_results_loop => \@sup_results_array);
 651 } #/end of the for loop
 652 #$template->param(FEDERATED_RESULTS => \@results_array);
 653
 654 my $gotonumber = $cgi->param('gotoNumber');
 655 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 656     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 657 }
 658 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 659 my $gotopage = $cgi->param('gotoPage');
 660 $template->{'VARS'}->{'gotoPage'} = $gotopage
 661   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 662
 663 for my $facet ( @$facets ) {
 664     for my $entry ( @{ $facet->{facets} } ) {
 665         my $index = $entry->{type_link_value};
 666         my $value = $entry->{facet_link_value};
 667         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 668     }
 669 }
 670
 671 $template->param(
 672             #classlist => $classlist,
 673             total => $total,
 674             opacfacets => 1,
 675             facets_loop => $facets,
 676             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 677             scan => $scan,
 678             search_error => $error,
 679 );
 680
 681 if ($query_desc || $limit_desc) {
 682     $template->param(searchdesc => 1);
 683 }
 684
 685 # VI. BUILD THE TEMPLATE
 686
 687 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 688     {
 689         borrowernumber => $borrowernumber,
 690         add_allowed    => 1,
 691         category       => 1,
 692     }
 693 );
 694 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 695     {
 696         borrowernumber => $borrowernumber,
 697         add_allowed    => 1,
 698         category       => 2,
 699     }
 700 );
 701
 702
 703 $template->param(
 704     add_to_some_private_shelves => $some_private_shelves,
 705     add_to_some_public_shelves  => $some_public_shelves,
 706 );
 707
 708 output_html_with_http_headers $cgi, $cookie, $template->output;
 709
 710
 711 =head2 prepare_adv_search_types
 712
 713     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 714     my @advanced_search_types = prepare_adv_search_types($type);
 715
 716 Different types can be searched for in the advanced search. This takes the
 717 system preference that defines these types and parses it into an arrayref for
 718 the template.
 719
 720 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 721 It also accounts for the "item-level_itypes" system preference.
 722
 723 =cut
 724
 725 sub prepare_adv_search_types {
 726     my ($types) = @_;
 727
 728     my @advanced_search_types = split( /\|/, $types );
 729
 730     # the index parameter is different for item-level itemtypes
 731     my $itype_or_itemtype =
 732       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 733     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 734
 735     my ( $cnt, @result );
 736     foreach my $advanced_srch_type (@advanced_search_types) {
 737         $advanced_srch_type =~ s/^\s*//;
 738         $advanced_srch_type =~ s/\s*$//;
 739         if ( $advanced_srch_type eq 'itemtypes' ) {
 740
 741        # itemtype is a special case, since it's not defined in authorized values
 742             my @itypesloop;
 743             foreach my $thisitemtype (
 744                 sort {
 745                     $itemtypes->{$a}->{'translated_description'}
 746                       cmp $itemtypes->{$b}->{'translated_description'}
 747                 } keys %$itemtypes
 748               )
 749             {
 750                 my %row = (
 751                     number      => $cnt++,
 752                     ccl         => "$itype_or_itemtype,phr",
 753                     code        => $thisitemtype,
 754                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 755                     imageurl    => getitemtypeimagelocation(
 756                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 757                     ),
 758                 );
 759                 push @itypesloop, \%row;
 760             }
 761             my %search_code = (
 762                 advanced_search_type => $advanced_srch_type,
 763                 code_loop            => \@itypesloop
 764             );
 765             push @result, \%search_code;
 766         }
 767         else {
 768             # covers all the other cases: non-itemtype authorized values
 769             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 770             my @authvalueloop;
 771             for my $thisitemtype (@$advsearchtypes) {
 772                 my %row = (
 773                     number      => $cnt++,
 774                     ccl         => $advanced_srch_type,
 775                     code        => $thisitemtype->{authorised_value},
 776                     description => $thisitemtype->{'lib'},
 777                     imageurl    => getitemtypeimagelocation(
 778                         'intranet', $thisitemtype->{'imageurl'}
 779                     ),
 780                 );
 781                 push @authvalueloop, \%row;
 782             }
 783             my %search_code = (
 784                 advanced_search_type => $advanced_srch_type,
 785                 code_loop            => \@authvalueloop
 786             );
 787             push @result, \%search_code;
 788         }
 789     }
 790     return \@result;
 791 }