misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Getopt::Long qw( GetOptions );
  24 use Pod::Usage qw( pod2usage );
  25 use Text::CSV_XS;
  26 use DateTime;
  27 use DateTime::Duration;
  28
  29 use Koha::Script -cron;
  30 use C4::Context;
  31 use C4::Letters;
  32 use C4::Overdues qw( GetOverdueMessageTransportTypes parse_overdues_letter );
  33 use C4::Log qw( cronlogaction );
  34 use Koha::Patron::Debarments qw( AddUniqueDebarment );
  35 use Koha::DateUtils qw( dt_from_string output_pref );
  36 use Koha::Calendar;
  37 use Koha::Libraries;
  38 use Koha::Acquisition::Currencies;
  39 use Koha::Patrons;
  40
  41 =head1 NAME
  42
  43 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  44
  45 =head1 SYNOPSIS
  46
  47 overdue_notices.pl
  48   [ -n ][ --library <branchcode> ][ --library <branchcode> ... ]
  49   [ --max <number of days> ][ --csv [<filename>] ][ --itemscontent <field list> ]
  50   [ --email <email_type> ... ]
  51
  52  Options:
  53    --help                          Brief help message.
  54    --man                           Full documentation.
  55    --verbose | -v                  Verbose mode.
  56    --nomail | -n                   No email will be sent.
  57    --max          <days>           Maximum days overdue to deal with.
  58    --library      <branchcode>     Only deal with overdues from this library.
  59                                    (repeatable : several libraries can be given)
  60    --csv          <filename>       Populate CSV file.
  61    --html         <directory>      Output html to a file in the given directory.
  62    --text         <directory>      Output plain text to a file in the given directory.
  63    --itemscontent <list of fields> Item information in templates.
  64    --borcat       <categorycode>   Category code that must be included.
  65    --borcatout    <categorycode>   Category code that must be excluded.
  66    --triggered | -t                Only include triggered overdues.
  67    --test                          Run in test mode. No changes will be made on the DB.
  68    --list-all                      List all overdues.
  69    --date         <yyyy-mm-dd>     Emulate overdues run for this date.
  70    --email        <email_type>     Type of email that will be used.
  71                                    Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  72    --frombranch                    Set the from address for the notice to one of 'item-homebranch' or 'item-issuebranch'.
  73
  74 =head1 OPTIONS
  75
  76 =over 8
  77
  78 =item B<--help>
  79
  80 Print a brief help message and exits.
  81
  82 =item B<--man>
  83
  84 Prints the manual page and exits.
  85
  86 =item B<-v> | B<--verbose>
  87
  88 Verbose. Without this flag set, only fatal errors are reported.
  89
  90 =item B<-n> | B<--nomail>
  91
  92 Do not send any email. Overdue notices that would have been sent to
  93 the patrons or to the admin are printed to standard out. CSV data (if
  94 the --csv flag is set) is written to standard out or to any csv
  95 filename given.
  96
  97 =item B<--max>
  98
  99 Items older than max days are assumed to be handled somewhere else,
 100 probably the F<longoverdues.pl> script. They are therefore ignored by
 101 this program. No notices are sent for them, and they are not added to
 102 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 103
 104 =item B<--library>
 105
 106 select overdues for one specific library. Use the value in the
 107 branches.branchcode table. This option can be repeated in order
 108 to select overdues for a group of libraries.
 109
 110 =item B<--csv>
 111
 112 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 113 sent to standard out or to a filename if provided. Otherwise, only
 114 overdues that could not be emailed are sent in CSV format to the admin.
 115
 116 =item B<--html>
 117
 118 Produces html data. If patron does not have an email address or
 119 -n (no mail) flag is set, an HTML file is generated in the specified
 120 directory. This can be downloaded or further processed by library staff.
 121 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 122 specified.
 123
 124 =item B<--text>
 125
 126 Produces plain text data. If patron does not have an email address or
 127 -n (no mail) flag is set, a text file is generated in the specified
 128 directory. This can be downloaded or further processed by library staff.
 129 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 130 specified.
 131
 132 =item B<--itemscontent>
 133
 134 comma separated list of fields that get substituted into templates in
 135 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 136 defaults to due date,title,barcode,author
 137
 138 Other possible values come from fields in the biblios, items and
 139 issues tables.
 140
 141 =item B<--borcat>
 142
 143 Repeatable field, that permits to select only some patron categories.
 144
 145 =item B<--borcatout>
 146
 147 Repeatable field, that permits to exclude some patron categories.
 148
 149 =item B<-t> | B<--triggered>
 150
 151 This option causes a notice to be generated if and only if
 152 an item is overdue by the number of days defined in a notice trigger.
 153
 154 By default, a notice is sent each time the script runs, which is suitable for
 155 less frequent run cron script, but requires syncing notice triggers with
 156 the  cron schedule to ensure proper behavior.
 157 Add the --triggered option for daily cron, at the risk of no notice
 158 being generated if the cron fails to run on time.
 159
 160 =item B<--test>
 161
 162 This option makes the script run in test mode.
 163
 164 In test mode, the script won't make any changes on the DB. This is useful
 165 for debugging configuration.
 166
 167 =item B<--list-all>
 168
 169 Default items.content lists only those items that fall in the
 170 range of the currently processing notice.
 171 Choose --list-all to include all overdue items in the list (limited by B<--max> setting).
 172
 173 =item B<--date>
 174
 175 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 176
 177 =item B<--email>
 178
 179 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 180
 181 =item B<--frombranch>
 182
 183 Use the address information from the item homebranch library instead of the issuing library.
 184
 185 Defaults to 'item-issuebranch'
 186
 187 =back
 188
 189 =head1 DESCRIPTION
 190
 191 This script is designed to alert patrons and administrators of overdue
 192 items.
 193
 194 =head2 Configuration
 195
 196 This script pays attention to the overdue notice configuration
 197 performed in the "Overdue notice/status triggers" section of the
 198 "Tools" area of the staff interface to Koha. There, you can choose
 199 which letter templates are sent out after a configurable number of
 200 days to patrons of each library. More information about the use of this
 201 section of Koha is available in the Koha manual.
 202
 203 The templates used to craft the emails are defined in the "Tools:
 204 Notices" section of the staff interface to Koha.
 205
 206 =head2 Outgoing emails
 207
 208 Typically, messages are prepared for each patron with overdue
 209 items. Messages for whom there is no email address on file are
 210 collected and sent as attachments in a single email to each library
 211 administrator, or if that is not set, then to the email address in the
 212 C<KohaAdminEmailAddress> system preference.
 213
 214 These emails are staged in the outgoing message queue, as are messages
 215 produced by other features of Koha. This message queue must be
 216 processed regularly by the
 217 F<misc/cronjobs/process_message_queue.pl> program.
 218
 219 In the event that the C<-n> flag is passed to this program, no emails
 220 are sent. Instead, messages are sent on standard output from this
 221 program. They may be redirected to a file if desired.
 222
 223 =head2 Templates
 224
 225 Templates can contain variables enclosed in double angle brackets like
 226 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 227 specific to the overdue items or relevant patron. Available variables
 228 are:
 229
 230 =over
 231
 232 =item E<lt>E<lt>bibE<gt>E<gt>
 233
 234 the name of the library
 235
 236 =item E<lt>E<lt>items.contentE<gt>E<gt>
 237
 238 one line for each item, each line containing a tab separated list of
 239 title, author, barcode, issuedate
 240
 241 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 242
 243 any field from the borrowers table
 244
 245 =item E<lt>E<lt>branches.*E<gt>E<gt>
 246
 247 any field from the branches table
 248
 249 =back
 250
 251 =head2 CSV output
 252
 253 The C<-csv> command line option lets you specify a file to which
 254 overdues data should be output in CSV format.
 255
 256 With the C<-n> flag set, data about all overdues is written to the
 257 file. Without that flag, only information about overdues that were
 258 unable to be sent directly to the patrons will be written. In other
 259 words, this CSV file replaces the data that is typically sent to the
 260 administrator email address.
 261
 262 =head1 USAGE EXAMPLES
 263
 264 C<overdue_notices.pl> - In this most basic usage, with no command line
 265 arguments, all libraries are processed individually, and notices are
 266 prepared for all patrons with overdue items for whom we have email
 267 addresses. Messages for those patrons for whom we have no email
 268 address are sent in a single attachment to the library administrator's
 269 email address, or to the address in the KohaAdminEmailAddress system
 270 preference.
 271
 272 C<overdue_notices.pl -n --csv /tmp/overdues.csv> - sends no email and
 273 populates F</tmp/overdues.csv> with information about all overdue
 274 items.
 275
 276 C<overdue_notices.pl --library MAIN max 14> - prepare notices of
 277 overdues in the last 2 weeks for the MAIN library.
 278
 279 =head1 SEE ALSO
 280
 281 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 282 messages to patrons in advance of their items becoming due, or to
 283 alert them of items that have just become due.
 284
 285 =cut
 286
 287 # These variables are set by command line options.
 288 # They are initially set to default values.
 289 my $dbh = C4::Context->dbh();
 290 my $help    = 0;
 291 my $man     = 0;
 292 my $verbose = 0;
 293 my $nomail  = 0;
 294 my $MAX     = 90;
 295 my $test_mode = 0;
 296 my $frombranch = 'item-issuebranch';
 297 my @branchcodes; # Branch(es) passed as parameter
 298 my @emails_to_use;    # Emails to use for messaging
 299 my @emails;           # Emails given in command-line parameters
 300 my $csvfilename;
 301 my $htmlfilename;
 302 my $text_filename;
 303 my $triggered = 0;
 304 my $listall = 0;
 305 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 306 my @myborcat;
 307 my @myborcatout;
 308 my ( $date_input, $today );
 309
 310 GetOptions(
 311     'help|?'         => \$help,
 312     'man'            => \$man,
 313     'v|verbose'      => \$verbose,
 314     'n|nomail'       => \$nomail,
 315     'max=s'          => \$MAX,
 316     'library=s'      => \@branchcodes,
 317     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 318     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 319     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 320     'itemscontent=s' => \$itemscontent,
 321     'list-all'       => \$listall,
 322     't|triggered'    => \$triggered,
 323     'test'           => \$test_mode,
 324     'date=s'         => \$date_input,
 325     'borcat=s'       => \@myborcat,
 326     'borcatout=s'    => \@myborcatout,
 327     'email=s'        => \@emails,
 328     'frombranch=s'   => \$frombranch,
 329 ) or pod2usage(2);
 330 pod2usage(1) if $help;
 331 pod2usage( -verbose => 2 ) if $man;
 332 cronlogaction() unless $test_mode;
 333
 334 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 335     warn qq(using "$csvfilename" as filename, that seems odd);
 336 }
 337
 338 die "--frombranch takes item-homebranch or item-issuebranch only"
 339     unless ( $frombranch eq 'item-issuebranch'
 340         || $frombranch eq 'item-homebranch' );
 341 my $owning_library = ( $frombranch eq 'item-homebranch' ) ? 1 : 0;
 342
 343 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();    # Branches with overdue rules
 344 my @branches;                                    # Branches passed as parameter with overdue rules
 345 my $branchcount = scalar(@overduebranches);
 346
 347 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 348 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 349
 350 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 351
 352 if ($branchcount) {
 353     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 354 } else {
 355     die 'No branches with active overduerules';
 356 }
 357
 358 if (@branchcodes) {
 359     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 360
 361     # Getting libraries which have overdue rules
 362     my %seen = map { $_ => 1 } @branchcodes;
 363     @branches = grep { $seen{$_} } @overduebranches;
 364
 365
 366     if (@branches) {
 367
 368         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 369     $verbose and warn "$branch_word @branches have overdue rules\n";
 370
 371     } else {
 372
 373         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 374         ( scalar grep { '' eq $_ } @branches )
 375           or die "No active overduerules for DEFAULT either!";
 376         $verbose and warn "Falling back on default rules for @branchcodes\n";
 377         @branches = ('');
 378     }
 379 }
 380 my $date_to_run;
 381 my $date;
 382 if ( $date_input ){
 383     eval {
 384         $date_to_run = dt_from_string( $date_input, 'iso' );
 385     };
 386     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 387         if $@ or not $date_to_run;
 388
 389     # It's certainly useless to escape $date_input
 390     # dt_from_string should not return something if $date_input is not correctly set.
 391     $date = $dbh->quote( $date_input );
 392 }
 393 else {
 394     $date="NOW()";
 395     $date_to_run = dt_from_string();
 396 }
 397
 398 # these are the fields that will be substituted into <<item.content>>
 399 my @item_content_fields = split( /,/, $itemscontent );
 400
 401 binmode( STDOUT, ':encoding(UTF-8)' );
 402
 403
 404 our $csv;       # the Text::CSV_XS object
 405 our $csv_fh;    # the filehandle to the CSV file.
 406 if ( defined $csvfilename ) {
 407     my $sep_char = C4::Context->csv_delimiter;
 408     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 409     if ( $csvfilename eq '' ) {
 410         $csv_fh = *STDOUT;
 411     } else {
 412         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 413     }
 414     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 415         print $csv_fh $csv->string, "\n";
 416     } else {
 417         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 418     }
 419 }
 420
 421 @branches = @overduebranches unless @branches;
 422 our $fh;
 423 if ( defined $htmlfilename ) {
 424   if ( $htmlfilename eq '' ) {
 425     $fh = *STDOUT;
 426   } else {
 427     my $today = dt_from_string();
 428     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 429   }
 430
 431   print $fh "<html>\n";
 432   print $fh "<head>\n";
 433   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 434   print $fh "<style type='text/css'>\n";
 435   print $fh "pre {page-break-after: always;}\n";
 436   print $fh "pre {white-space: pre-wrap;}\n";
 437   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 438   print $fh "pre {white-space: -o-pre-wrap;}\n";
 439   print $fh "pre {word-wrap: break-work;}\n";
 440   print $fh "</style>\n";
 441   print $fh "</head>\n";
 442   print $fh "<body>\n";
 443 }
 444 elsif ( defined $text_filename ) {
 445   if ( $text_filename eq '' ) {
 446     $fh = *STDOUT;
 447   } else {
 448     my $today = dt_from_string();
 449     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 450   }
 451 }
 452
 453 foreach my $branchcode (@branches) {
 454     my $calendar;
 455     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 456         $calendar = Koha::Calendar->new( branchcode => $branchcode );
 457         if ( $calendar->is_holiday($date_to_run) ) {
 458             next;
 459         }
 460     }
 461
 462     my $library             = Koha::Libraries->find($branchcode);
 463     my $admin_email_address = $library->from_email_address;
 464     my $branch_email_address = C4::Context->preference('AddressForFailedOverdueNotices')
 465       || $library->inbound_email_address;
 466     my @output_chunks;    # may be sent to mail or stdout or csv file.
 467
 468     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $branch_email_address;
 469
 470     my $sql2 = <<"END_SQL";
 471 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 472   FROM issues,items,biblio, biblioitems, branches b
 473   WHERE items.itemnumber=issues.itemnumber
 474     AND biblio.biblionumber   = items.biblionumber
 475     AND b.branchcode = items.homebranch
 476     AND biblio.biblionumber   = biblioitems.biblionumber
 477     AND issues.borrowernumber = ?
 478     AND items.itemlost = 0
 479     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 480 END_SQL
 481
 482     if($owning_library) {
 483       $sql2 .= ' AND items.homebranch = ? ';
 484     } else {
 485       $sql2 .= ' AND issues.branchcode = ? ';
 486     }
 487     my $sth2 = $dbh->prepare($sql2);
 488
 489     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 490     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 491     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 492
 493     my $rqoverduerules =  $dbh->prepare($query);
 494     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 495
 496     # We get default rules is there is no rule for this branch
 497     if($rqoverduerules->rows == 0){
 498         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 499         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 500         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 501
 502         $rqoverduerules = $dbh->prepare($query);
 503         $rqoverduerules->execute(@myborcat, @myborcatout);
 504     }
 505
 506     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 507     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 508       PERIOD: foreach my $i ( 1 .. 3 ) {
 509
 510             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 511
 512             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 513             my $maxdays = (
 514                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 515                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 516                 : ($MAX)
 517             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 518
 519             next unless defined $mindays;
 520
 521             if ( !$overdue_rules->{"letter$i"} ) {
 522                 $verbose and warn "No letter$i code for branch '$branchcode'";
 523                 next PERIOD;
 524             }
 525
 526             # $letter->{'content'} is the text of the mail that is sent.
 527             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 528             # The following fields are available :
 529         # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 530             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 531
 532             my $borrower_sql = <<"END_SQL";
 533 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 534 FROM   issues,borrowers,categories,items
 535 WHERE  issues.borrowernumber=borrowers.borrowernumber
 536 AND    borrowers.categorycode=categories.categorycode
 537 AND    issues.itemnumber = items.itemnumber
 538 AND    items.itemlost = 0
 539 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 540 END_SQL
 541             my @borrower_parameters;
 542             if ($branchcode) {
 543         if($owning_library) {
 544             $borrower_sql .= ' AND items.homebranch=? ';
 545         } else {
 546             $borrower_sql .= ' AND issues.branchcode=? ';
 547         }
 548                 push @borrower_parameters, $branchcode;
 549             }
 550             if ( $overdue_rules->{categorycode} ) {
 551                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 552                 push @borrower_parameters, $overdue_rules->{categorycode};
 553             }
 554             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 555
 556             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 557             my $sth = $dbh->prepare($borrower_sql);
 558             $sth->execute(@borrower_parameters);
 559
 560             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 561             my $borrowernumber;
 562             while ( my $data = $sth->fetchrow_hashref ) {
 563
 564                 # check the borrower has at least one item that matches
 565                 my $days_between;
 566                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 567                 {
 568                     $days_between =
 569                       $calendar->days_between( dt_from_string($data->{date_due}),
 570                         $date_to_run );
 571                 }
 572                 else {
 573                     $days_between =
 574                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 575                 }
 576                 $days_between = $days_between->in_units('days');
 577                 if ($triggered) {
 578                     if ( $mindays != $days_between ) {
 579                         next;
 580                     }
 581                 }
 582                 else {
 583                     unless (   $days_between >= $mindays
 584                         && $days_between <= $maxdays )
 585                     {
 586                         next;
 587                     }
 588                 }
 589                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 590 # we have already dealt with this borrower
 591                     $verbose and warn "already dealt with this borrower $borrowernumber";
 592                     next;
 593                 }
 594                 $borrowernumber = $data->{'borrowernumber'};
 595                 my $borr = sprintf( "%s%s%s (%s)",
 596                     $data->{'surname'} || '',
 597                     $data->{'firstname'} && $data->{'surname'} ? ', ' : '',
 598                     $data->{'firstname'} || '',
 599                     $borrowernumber );
 600                 $verbose
 601                   and warn "borrower $borr has items triggering level $i.";
 602
 603                 my $patron = Koha::Patrons->find( $borrowernumber );
 604                 @emails_to_use = ();
 605                 my $notice_email = $patron->notice_email_address;
 606                 unless ($nomail) {
 607                     if (@emails) {
 608                         foreach (@emails) {
 609                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 610                         }
 611                     }
 612                     else {
 613                         push @emails_to_use, $notice_email if ($notice_email);
 614                     }
 615                 }
 616
 617                 my $letter = Koha::Notice::Templates->find_effective_template(
 618                     {
 619                         module     => 'circulation',
 620                         code       => $overdue_rules->{"letter$i"},
 621                         branchcode => $branchcode,
 622                         lang       => $patron->lang
 623                     }
 624                 );
 625
 626                 unless ($letter) {
 627                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 628
 629                     # might as well skip while PERIOD, no other borrowers are going to work.
 630                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 631                     next PERIOD;
 632                 }
 633
 634                 if ( $overdue_rules->{"debarred$i"} ) {
 635
 636                     #action taken is debarring
 637                     AddUniqueDebarment(
 638                         {
 639                             borrowernumber => $borrowernumber,
 640                             type           => 'OVERDUES',
 641                             comment => "OVERDUES_PROCESS " .  output_pref( dt_from_string() ),
 642                         }
 643                     ) unless $test_mode;
 644                     $verbose and warn "debarring $borr\n";
 645                 }
 646                 my @params = ($borrowernumber,$branchcode);
 647                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 648
 649                 $sth2->execute(@params);
 650                 my $itemcount = 0;
 651                 my $titles = "";
 652                 my @items = ();
 653
 654                 my $j = 0;
 655                 my $exceededPrintNoticesMaxLines = 0;
 656                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 657                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 658                         $days_between =
 659                           $calendar->days_between(
 660                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 661                     }
 662                     else {
 663                         $days_between =
 664                           $date_to_run->delta_days(
 665                             dt_from_string( $item_info->{date_due} ) );
 666                     }
 667                     $days_between = $days_between->in_units('days');
 668                     if ($listall){
 669                         unless ($days_between >= 1 and $days_between <= $MAX){
 670                             next;
 671                         }
 672                     }
 673                     else {
 674                         if ($triggered) {
 675                             if ( $mindays != $days_between ) {
 676                                 next;
 677                             }
 678                         }
 679                         else {
 680                             unless ( $days_between >= $mindays
 681                                 && $days_between <= $maxdays )
 682                             {
 683                                 next;
 684                             }
 685                         }
 686                     }
 687
 688                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 689                       $exceededPrintNoticesMaxLines = 1;
 690                       last;
 691                     }
 692                     $j++;
 693
 694                     $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields, dateonly => 1 } );
 695                     $itemcount++;
 696                     push @items, $item_info;
 697                 }
 698                 $sth2->finish;
 699
 700                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 701                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 702                     unless @message_transport_types;
 703
 704
 705                 my $print_sent = 0; # A print notice is not yet sent for this patron
 706                 for my $mtt ( @message_transport_types ) {
 707                     next if $mtt eq 'itiva';
 708                     my $effective_mtt = $mtt;
 709                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 710                         # email or sms is requested but not exist, do a print.
 711                         $effective_mtt = 'print';
 712                     }
 713                     splice @items, $PrintNoticesMaxLines if $effective_mtt eq 'print' && $PrintNoticesMaxLines && scalar @items > $PrintNoticesMaxLines;
 714                     #catch the case where we are sending a print to someone with an email
 715
 716                     my $letter_exists = Koha::Notice::Templates->find_effective_template(
 717                         {
 718                             module     => 'circulation',
 719                             code       => $overdue_rules->{"letter$i"},
 720                             message_transport_type => $effective_mtt,
 721                             branchcode => $branchcode,
 722                             lang       => $patron->lang
 723                         }
 724                     );
 725
 726                     my $letter = parse_overdues_letter(
 727                         {   letter_code     => $overdue_rules->{"letter$i"},
 728                             borrowernumber  => $borrowernumber,
 729                             branchcode      => $branchcode,
 730                             items           => \@items,
 731                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 732                                                 bib             => $library->branchname, # maybe 'bib' is a typo for 'lib<rary>'?
 733                                                 'items.content' => $titles,
 734                                                 'count'         => $itemcount,
 735                                                },
 736                             # If there is no template defined for the requested letter
 737                             # Fallback on the original type
 738                             message_transport_type => $letter_exists ? $effective_mtt : $mtt,
 739                         }
 740                     );
 741                     unless ($letter && $letter->{content}) {
 742                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 743                         # this transport doesn't have a configured notice, so try another
 744                         next;
 745                     }
 746
 747                     if ( $exceededPrintNoticesMaxLines ) {
 748                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 749                     }
 750
 751                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 752                     if (@misses) {
 753                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 754                     }
 755
 756                     if ($nomail) {
 757                         push @output_chunks,
 758                           prepare_letter_for_printing(
 759                           {   letter         => $letter,
 760                               borrowernumber => $borrowernumber,
 761                               firstname      => $data->{'firstname'},
 762                               lastname       => $data->{'surname'},
 763                               address1       => $data->{'address'},
 764                               address2       => $data->{'address2'},
 765                               city           => $data->{'city'},
 766                               phone          => $data->{'phone'},
 767                               cardnumber     => $data->{'cardnumber'},
 768                               branchname     => $library->branchname,
 769                               letternumber   => $i,
 770                               postcode       => $data->{'zipcode'},
 771                               country        => $data->{'country'},
 772                               email          => $notice_email,
 773                               itemcount      => $itemcount,
 774                               titles         => $titles,
 775                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 776                             }
 777                           );
 778                     } else {
 779                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 780                             push @output_chunks,
 781                               prepare_letter_for_printing(
 782                               {   letter         => $letter,
 783                                   borrowernumber => $borrowernumber,
 784                                   firstname      => $data->{'firstname'},
 785                                   lastname       => $data->{'surname'},
 786                                   address1       => $data->{'address'},
 787                                   address2       => $data->{'address2'},
 788                                   city           => $data->{'city'},
 789                                   postcode       => $data->{'zipcode'},
 790                                   country        => $data->{'country'},
 791                                   email          => $notice_email,
 792                                   itemcount      => $itemcount,
 793                                   titles         => $titles,
 794                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 795                                 }
 796                               );
 797                         }
 798                         unless ( $effective_mtt eq 'print' and $print_sent == 1 ) {
 799                             # Just sent a print if not already done.
 800                             C4::Letters::EnqueueLetter(
 801                                 {   letter                 => $letter,
 802                                     borrowernumber         => $borrowernumber,
 803                                     message_transport_type => $effective_mtt,
 804                                     from_address           => $admin_email_address,
 805                                     to_address             => join(',', @emails_to_use),
 806                                     reply_address          => $library->inbound_email_address,
 807                                 }
 808                             ) unless $test_mode;
 809                             # A print notice should be sent only once per overdue level.
 810                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 811                             $print_sent = 1 if $effective_mtt eq 'print';
 812                         }
 813                     }
 814                 }
 815             }
 816             $sth->finish;
 817         }
 818     }
 819
 820     if (@output_chunks) {
 821         if ( defined $csvfilename ) {
 822             print $csv_fh @output_chunks;
 823         }
 824         elsif ( defined $htmlfilename ) {
 825             print $fh @output_chunks;
 826         }
 827         elsif ( defined $text_filename ) {
 828             print $fh @output_chunks;
 829         }
 830         elsif ($nomail){
 831                 local $, = "\f";    # pagebreak
 832                 print @output_chunks;
 833         }
 834         # Generate the content of the csv with headers
 835         my $content;
 836         if ( defined $csvfilename ) {
 837             my $delimiter = C4::Context->csv_delimiter;
 838             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 839         }
 840         else {
 841             $content = "";
 842         }
 843         $content .= join( "\n", @output_chunks );
 844
 845         if ( C4::Context->preference('EmailOverduesNoEmail') ) {
 846             my $attachment = {
 847                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 848                 type => 'text/plain',
 849                 content => $content,
 850             };
 851
 852             my $letter = {
 853                 title   => 'Overdue Notices',
 854                 content => 'These messages were not sent directly to the patrons.',
 855             };
 856
 857             C4::Letters::EnqueueLetter(
 858                 {   letter                 => $letter,
 859                     borrowernumber         => undef,
 860                     message_transport_type => 'email',
 861                     attachments            => [$attachment],
 862                     to_address             => $branch_email_address,
 863                 }
 864             ) unless $test_mode;
 865         }
 866     }
 867
 868 }
 869 if ($csvfilename) {
 870     # note that we're not testing on $csv_fh to prevent closing
 871     # STDOUT.
 872     close $csv_fh;
 873 }
 874
 875 if ( defined $htmlfilename ) {
 876   print $fh "</body>\n";
 877   print $fh "</html>\n";
 878   close $fh;
 879 } elsif ( defined $text_filename ) {
 880   close $fh;
 881 }
 882
 883 =head1 INTERNAL METHODS
 884
 885 These methods are internal to the operation of overdue_notices.pl.
 886
 887 =head2 prepare_letter_for_printing
 888
 889 returns a string of text appropriate for printing in the event that an
 890 overdue notice will not be sent to the patron's email
 891 address. Depending on the desired output format, this may be a CSV
 892 string, or a human-readable representation of the notice.
 893
 894 required parameters:
 895   letter
 896   borrowernumber
 897
 898 optional parameters:
 899   outputformat
 900
 901 =cut
 902
 903 sub prepare_letter_for_printing {
 904     my $params = shift;
 905
 906     return unless ref $params eq 'HASH';
 907
 908     foreach my $required_parameter (qw( letter borrowernumber )) {
 909         return unless defined $params->{$required_parameter};
 910     }
 911
 912     my $return;
 913     chomp $params->{titles};
 914     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 915         if ($csv->combine(
 916                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 917                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 918                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 919             )
 920           ) {
 921             return $csv->string, "\n";
 922         } else {
 923             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 924         }
 925     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 926       $return = "<pre>\n";
 927       $return .= "$params->{'letter'}->{'content'}\n";
 928       $return .= "\n</pre>\n";
 929     } else {
 930         $return .= "$params->{'letter'}->{'content'}\n";
 931
 932         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 933     }
 934     return $return;
 935 }
 936