opac/opac-reserve.pl

   1 #!/usr/bin/perl
   2
   3
   4 # Copyright Katipo Communications 2002
   5 # Copyright Koha Development team 2012
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use C4::Auth qw( get_template_and_user );
  26 use C4::Koha qw( getitemtypeimagelocation getitemtypeimagesrc );
  27 use C4::Circulation qw( GetBranchItemRule );
  28 use C4::Reserves qw( CanItemBeReserved CanBookBeReserved AddReserve GetReservesControlBranch ItemsAnyAvailableAndNotRestricted IsAvailableForItemLevelRequest );
  29 use C4::Biblio qw( GetBiblioData GetFrameworkCode );
  30 use C4::Output qw( output_html_with_http_headers );
  31 use C4::Context;
  32 use C4::Members;
  33 use C4::Overdues;
  34
  35 use Koha::AuthorisedValues;
  36 use Koha::Biblios;
  37 use Koha::CirculationRules;
  38 use Koha::Items;
  39 use Koha::ItemTypes;
  40 use Koha::Checkouts;
  41 use Koha::Libraries;
  42 use Koha::Patrons;
  43 use List::MoreUtils qw( uniq );
  44
  45 my $maxreserves = C4::Context->preference("maxreserves");
  46
  47 my $query = CGI->new;
  48
  49 # if OPACHoldRequests (for placing holds) is disabled, leave immediately
  50 if ( ! C4::Context->preference('OPACHoldRequests') ) {
  51     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  52     exit;
  53 }
  54
  55 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  56     {
  57         template_name   => "opac-reserve.tt",
  58         query           => $query,
  59         type            => "opac",
  60     }
  61 );
  62
  63 my $patron = Koha::Patrons->find( $borrowernumber, { prefetch => ['categorycode'] } );
  64 my $category = $patron->category;
  65
  66 my $can_place_hold_if_available_at_pickup = C4::Context->preference('OPACHoldsIfAvailableAtPickup');
  67 unless ( $can_place_hold_if_available_at_pickup ) {
  68     my @patron_categories = split ',', C4::Context->preference('OPACHoldsIfAvailableAtPickupExceptions');
  69     if ( @patron_categories ) {
  70         my $categorycode = $patron->categorycode;
  71         $can_place_hold_if_available_at_pickup = grep { $_ eq $categorycode } @patron_categories;
  72     }
  73 }
  74
  75 # check if this user can place a reserve, -1 means use sys pref, 0 means dont block, 1 means block
  76 if ( $category->effective_BlockExpiredPatronOpacActions ) {
  77
  78     if ( $patron->is_expired ) {
  79
  80         # cannot reserve, their card has expired and the rules set mean this is not allowed
  81         $template->param( message => 1, expired_patron => 1 );
  82         output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };
  83         exit;
  84     }
  85 }
  86
  87 # Pass through any reserve charge
  88 my $reservefee = $category->reservefee;
  89 if ( $reservefee > 0){
  90     $template->param( RESERVE_CHARGE => $reservefee);
  91 }
  92
  93 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
  94
  95 # There are two ways of calling this script, with a single biblio num
  96 # or multiple biblio nums.
  97 my $biblionumbers = $query->param('biblionumbers');
  98 my $reserveMode = $query->param('reserve_mode');
  99 if ($reserveMode && ($reserveMode eq 'single')) {
 100     my $bib = $query->param('single_bib');
 101     $biblionumbers = "$bib/";
 102 }
 103 if (! $biblionumbers) {
 104     $biblionumbers = $query->param('biblionumber');
 105 }
 106
 107 if ((! $biblionumbers) && (! $query->param('place_reserve'))) {
 108     $template->param(message=>1, no_biblionumber=>1);
 109     output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };
 110     exit;
 111 }
 112
 113 # Pass the numbers to the page so they can be fed back
 114 # when the hold is confirmed. TODO: Not necessary?
 115 $template->param( biblionumbers => $biblionumbers );
 116
 117 # Each biblio number is suffixed with '/', e.g. "1/2/3/"
 118 my @biblionumbers = split /\//, $biblionumbers;
 119 if (($#biblionumbers < 0) && (! $query->param('place_reserve'))) {
 120     # TODO: New message?
 121     $template->param(message=>1, no_biblionumber=>1);
 122     output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };
 123     exit;
 124 }
 125
 126
 127 # pass the pickup branch along....
 128 my $branch = $query->param('branch') || $patron->branchcode || C4::Context->userenv->{branch} || '' ;
 129 $template->param( branch => $branch );
 130
 131 #
 132 #
 133 # Build hashes of the requested biblio(item)s and items.
 134 #
 135 #
 136
 137 my %biblioDataHash; # Hash of biblionumber to biblio/biblioitems record.
 138 foreach my $biblioNumber (@biblionumbers) {
 139
 140     my $biblioData = GetBiblioData($biblioNumber);
 141     $biblioDataHash{$biblioNumber} = $biblioData;
 142
 143     my $biblio = Koha::Biblios->find( $biblioNumber );
 144     next unless $biblio;
 145
 146     my $marcrecord = $biblio->metadata->record;
 147
 148     my $items = Koha::Items->search_ordered(
 149         [
 150             biblionumber => $biblioNumber,
 151             'me.itemnumber' => {
 152                 -in => [
 153                     $biblio->host_items->get_column('itemnumber')
 154                 ]
 155             }
 156         ],
 157         { prefetch => [ 'issue', 'homebranch', 'holdingbranch' ] }
 158     )->filter_by_visible_in_opac({ patron => $patron });
 159
 160     $biblioData->{items} = [$items->as_list]; # FIXME Potentially a lot in memory here!
 161
 162     # Compute the priority rank.
 163     $biblioData->{object} = $biblio;
 164     my $reservecount = $biblio->holds->search({ found => [ {"!=" => "W"},undef] })->count;
 165     $biblioData->{reservecount} = $reservecount;
 166     $biblioData->{rank} = $reservecount + 1;
 167 }
 168
 169 #
 170 #
 171 # If this is the second time through this script, it
 172 # means we are carrying out the hold request, possibly
 173 # with a specific item for each biblionumber.
 174 #
 175 #
 176 if ( $query->param('place_reserve') ) {
 177     my $reserve_cnt = 0;
 178     if ($maxreserves) {
 179         $reserve_cnt = $patron->holds->count;
 180     }
 181
 182     # List is composed of alternating biblio/item/branch
 183     my $selectedItems = $query->param('selecteditems');
 184
 185     if ($query->param('reserve_mode') eq 'single') {
 186         # This indicates non-JavaScript mode, so there was
 187         # only a single biblio number selected.
 188         my $bib = $query->param('single_bib');
 189         my $item = $query->param("checkitem_$bib");
 190         if ($item eq 'any') {
 191             $item = '';
 192         }
 193         my $branch = $query->param('branch');
 194         $selectedItems = "$bib/$item/$branch/";
 195     }
 196
 197     $selectedItems =~ s!/$!!;
 198     my @selectedItems = split /\//, $selectedItems, -1;
 199
 200     # Make sure there is a biblionum/itemnum/branch triplet for each item.
 201     # The itemnum can be 'any', meaning next available.
 202     my $selectionCount = @selectedItems;
 203     if (($selectionCount == 0) || (($selectionCount % 3) != 0)) {
 204         $template->param(message=>1, bad_data=>1);
 205         output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };
 206         exit;
 207     }
 208
 209     my $failed_holds = 0;
 210     while (@selectedItems) {
 211         my $biblioNum = shift(@selectedItems);
 212         my $itemNum   = shift(@selectedItems);
 213         my $branch    = shift(@selectedItems);    # i.e., branch code, not name
 214
 215         my $canreserve = 0;
 216
 217         my $singleBranchMode = Koha::Libraries->search->count == 1;
 218         if ( $singleBranchMode || ! C4::Context->preference("OPACAllowUserToChooseBranch") )
 219         {    # single branch mode or disabled user choosing
 220             $branch = $patron->branchcode;
 221         }
 222
 223         # FIXME We shouldn't need to fetch the item here
 224         my $item = $itemNum ? Koha::Items->find( $itemNum ) : undef;
 225         # When choosing a specific item, the default pickup library should be dictated by the default hold policy
 226         if ( ! C4::Context->preference("OPACAllowUserToChooseBranch") && $item ) {
 227             my $type = $item->effective_itemtype;
 228             my $rule = GetBranchItemRule( $patron->branchcode, $type );
 229
 230             if ( $rule->{hold_fulfillment_policy} eq 'any' || $rule->{hold_fulfillment_policy} eq 'patrongroup' ) {
 231                 $branch = $patron->branchcode;
 232             } elsif ( $rule->{hold_fulfillment_policy} eq 'holdgroup' ){
 233                 $branch = $item->homebranch;
 234             } else {
 235                 my $policy = $rule->{hold_fulfillment_policy};
 236                 $branch = $item->$policy;
 237             }
 238         }
 239
 240         # if we have an item, we are placing the hold on the item's bib, in case of analytics
 241         if ( $item ) {
 242             $biblioNum = $item->biblionumber;
 243         }
 244
 245         my $biblioData = $biblioDataHash{$biblioNum};
 246
 247         # Check for user supplied reserve date
 248         my $startdate;
 249         if (   C4::Context->preference('AllowHoldDateInFuture')
 250             && C4::Context->preference('OPACAllowHoldDateInFuture') )
 251         {
 252             $startdate = $query->param("reserve_date_$biblioNum");
 253         }
 254
 255         my $patron_expiration_date = $query->param("expiration_date_$biblioNum");
 256
 257         my $itemtype = $query->param('itemtype') || undef;
 258         $itemtype = undef if $itemNum;
 259
 260         my $rank = $biblioData->{rank};
 261         if ( $item ) {
 262             $canreserve = 1 if CanItemBeReserved( $patron, $item, $branch )->{status} eq 'OK';
 263         }
 264         else {
 265             $canreserve = 1
 266               if CanBookBeReserved( $borrowernumber, $biblioNum, $branch, { itemtype => $itemtype } )->{status} eq 'OK';
 267
 268             # Inserts a null into the 'itemnumber' field of 'reserves' table.
 269             $itemNum = undef;
 270         }
 271         my $notes = $query->param('notes_'.$biblioNum)||'';
 272
 273         if (   $maxreserves
 274             && $reserve_cnt >= $maxreserves )
 275         {
 276             $canreserve = 0;
 277         }
 278
 279         unless ( $can_place_hold_if_available_at_pickup ) {
 280             my $items_in_this_library = Koha::Items->search({ biblionumber => $biblioNum, holdingbranch => $branch });
 281             my $nb_of_items_issued = $items_in_this_library->search({ 'issue.itemnumber' => { not => undef }}, { join => 'issue' })->count;
 282             my $nb_of_items_unavailable = $items_in_this_library->search({ -or => { lost => { '!=' => 0 }, damaged => { '!=' => 0 }, } });
 283             if ( $items_in_this_library->count > $nb_of_items_issued + $nb_of_items_unavailable ) {
 284                 $canreserve = 0
 285             }
 286         }
 287
 288         # Here we actually do the reserveration. Stage 3.
 289         if ($canreserve) {
 290             my $reserve_id = AddReserve(
 291                 {
 292                     branchcode       => $branch,
 293                     borrowernumber   => $borrowernumber,
 294                     biblionumber     => $biblioNum,
 295                     priority         => $rank,
 296                     reservation_date => $startdate,
 297                     expiration_date  => $patron_expiration_date,
 298                     notes            => $notes,
 299                     title            => $biblioData->{title},
 300                     itemnumber       => $itemNum,
 301                     found            => undef,
 302                     itemtype         => $itemtype,
 303                 }
 304             );
 305             $failed_holds++ unless $reserve_id;
 306             ++$reserve_cnt;
 307         }
 308     }
 309
 310     print $query->redirect("/cgi-bin/koha/opac-user.pl?" . ( $failed_holds ? "failed_holds=$failed_holds" : q|| ) . "#opac-user-holds");
 311     exit;
 312 }
 313
 314 #
 315 #
 316 # Here we check that the borrower can actually make reserves Stage 1.
 317 #
 318 #
 319 my $noreserves     = 0;
 320 my $maxoutstanding = C4::Context->preference("maxoutstanding");
 321 my $amountoutstanding = $patron->account->balance;
 322 if ( $amountoutstanding && ($amountoutstanding > $maxoutstanding) ) {
 323     my $amount = sprintf "%.02f", $amountoutstanding;
 324     $template->param( message => 1 );
 325     $noreserves = 1;
 326     $template->param( too_much_oweing => $amount );
 327 }
 328
 329 if ( $patron->gonenoaddress && ($patron->gonenoaddress == 1) ) {
 330     $noreserves = 1;
 331     $template->param(
 332         message => 1,
 333         GNA     => 1
 334     );
 335 }
 336
 337 if ( $patron->lost && ($patron->lost == 1) ) {
 338     $noreserves = 1;
 339     $template->param(
 340         message => 1,
 341         lost    => 1
 342     );
 343 }
 344
 345 if ( $patron->is_debarred ) {
 346     $noreserves = 1;
 347     $template->param(
 348         message          => 1,
 349         debarred         => 1,
 350         debarred_comment => $patron->debarredcomment,
 351         debarred_date    => $patron->debarred,
 352     );
 353 }
 354
 355 my $holds = $patron->holds;
 356 my $reserves_count = $holds->count;
 357 $template->param( RESERVES => $holds->unblessed );
 358 if ( $maxreserves && ( $reserves_count >= $maxreserves ) ) {
 359     $template->param( message => 1 );
 360     $noreserves = 1;
 361     $template->param( too_many_reserves => $holds->count );
 362 }
 363
 364 unless ( $noreserves ) {
 365     my $requested_reserves_count = scalar( @biblionumbers );
 366     if ( $maxreserves && ( $reserves_count + $requested_reserves_count > $maxreserves ) ) {
 367         $template->param( new_reserves_allowed => $maxreserves - $reserves_count );
 368     }
 369 }
 370
 371 unless ($noreserves) {
 372     $template->param( select_item_types => 1 );
 373 }
 374
 375
 376 #
 377 #
 378 # Build the template parameters that will show the info
 379 # and items for each biblionumber.
 380 #
 381 #
 382
 383 my $biblioLoop = [];
 384 my $numBibsAvailable = 0;
 385 my $itemdata_enumchron = 0;
 386 my $itemdata_ccode = 0;
 387 my $anyholdable = 0;
 388 my $itemLevelTypes = C4::Context->preference('item-level_itypes');
 389 my $pickup_locations = Koha::Libraries->search({ pickup_location => 1 });
 390 $template->param('item_level_itypes' => $itemLevelTypes);
 391
 392 my $patron_unblessed = $patron->unblessed;
 393 foreach my $biblioNum (@biblionumbers) {
 394
 395     # Init the bib item with the choices for branch pickup
 396     my %biblioLoopIter;
 397
 398     # Get relevant biblio data.
 399     my $biblioData = $biblioDataHash{$biblioNum};
 400     if (! $biblioData) {
 401         $template->param(message=>1, bad_biblionumber=>$biblioNum);
 402         output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };
 403         exit;
 404     }
 405
 406     my @not_available_at = ();
 407     my $biblio = $biblioData->{object};
 408     foreach my $library ( $pickup_locations->as_list ) {
 409         push( @not_available_at, $library->branchcode ) unless $biblio->can_be_transferred({ to => $library });
 410     }
 411
 412     my $frameworkcode = GetFrameworkCode( $biblioData->{biblionumber} );
 413     $biblioLoopIter{biblionumber} = $biblioData->{biblionumber};
 414     $biblioLoopIter{title} = $biblioData->{title};
 415     $biblioLoopIter{subtitle} = $biblioData->{'subtitle'};
 416     $biblioLoopIter{medium} = $biblioData->{medium};
 417     $biblioLoopIter{part_number} = $biblioData->{part_number};
 418     $biblioLoopIter{part_name} = $biblioData->{part_name};
 419     $biblioLoopIter{author} = $biblioData->{author};
 420     $biblioLoopIter{rank} = $biblioData->{rank};
 421     $biblioLoopIter{reservecount} = $biblioData->{reservecount};
 422     $biblioLoopIter{already_reserved} = $biblioData->{already_reserved};
 423     $biblioLoopIter{reqholdnotes}=0; #TODO: For future use
 424
 425     if (!$itemLevelTypes && $biblioData->{itemtype}) {
 426         $biblioLoopIter{translated_description} = $itemtypes->{$biblioData->{itemtype}}{translated_description};
 427         $biblioLoopIter{imageurl} = getitemtypeimagesrc() . "/". $itemtypes->{$biblioData->{itemtype}}{imageurl};
 428     }
 429
 430
 431
 432     $biblioLoopIter{itemLoop} = [];
 433     my $numCopiesAvailable = 0;
 434     my $numCopiesOPACAvailable = 0;
 435     # iterating through all items first to check if any of them available
 436     # to pass this value further inside down to IsAvailableForItemLevelRequest to
 437     # it's complicated logic to analyse.
 438     # (before this loop was inside that sub loop so it was O(n^2) )
 439     my $items_any_available;
 440     $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblioNum, patron => $patron }) if $patron;
 441     foreach my $item (@{$biblioData->{items}}) {
 442
 443         my $item_info = $item->unblessed;
 444         $item_info->{holding_branch} = $item->holding_branch;
 445         $item_info->{home_branch}    = $item->home_branch;
 446         if ($itemLevelTypes) {
 447             my $itemtype = $item->itemtype;
 448             $item_info->{'imageurl'} = getitemtypeimagelocation( 'opac',
 449                 $itemtypes->{ $itemtype->itemtype }->{'imageurl'} );
 450             $item_info->{'translated_description'} =
 451               $itemtypes->{ $itemtype->itemtype }->{translated_description};
 452         }
 453
 454         # checking for holds
 455         my $holds = $item->current_holds;
 456         if ( my $first_hold = $holds->next ) {
 457             $item_info->{first_hold} = $first_hold;
 458         }
 459
 460         $item_info->{checkout} = $item->checkout;
 461
 462         # Check of the transferred documents
 463         my $transfer = $item->get_transfer;
 464         if ( $transfer && $transfer->in_transit ) {
 465             $item_info->{transfertwhen} = $transfer->datesent;
 466             $item_info->{transfertfrom} = $transfer->frombranch;
 467             $item_info->{transfertto} = $transfer->tobranch;
 468             $item_info->{nocancel} = 1;
 469         }
 470
 471         # if the items belongs to a host record, show link to host record
 472         if ( $item_info->{biblionumber} ne $biblioNum ) {
 473             $item_info->{hostbiblionumber} = $item->biblionumber;
 474             $item_info->{hosttitle}        = Koha::Biblios->find( $item_info->{biblionumber} )->title;
 475         }
 476
 477         my $branch = GetReservesControlBranch( $item_info, $patron_unblessed );
 478
 479         # items_any_available defined outside of the current loop,
 480         # so we avoiding loop inside IsAvailableForItemLevelRequest:
 481         my $policy_holdallowed =
 482             CanItemBeReserved( $patron, $item )->{status} eq 'OK' &&
 483             IsAvailableForItemLevelRequest($item, $patron, undef, $items_any_available);
 484
 485         if ($policy_holdallowed) {
 486             my $opac_hold_policy = Koha::CirculationRules->get_opacitemholds_policy( { item => $item, patron => $patron } );
 487             if ( $opac_hold_policy ne 'N' ) { # If Y or F
 488                 $item_info->{available} = 1;
 489                 $numCopiesOPACAvailable++;
 490                 $biblioLoopIter{force_hold} = 1 if $opac_hold_policy eq 'F';
 491             }
 492             $numCopiesAvailable++;
 493
 494             unless ( $can_place_hold_if_available_at_pickup ) {
 495                 my $items_in_this_library = Koha::Items->search({ biblionumber => $item->biblionumber, holdingbranch => $item->holdingbranch });
 496                 my $nb_of_items_issued = $items_in_this_library->search({ 'issue.itemnumber' => { not => undef }}, { join => 'issue' })->count;
 497                 if ( $items_in_this_library->count > $nb_of_items_issued ) {
 498                     push @not_available_at, $item->holdingbranch;
 499                 }
 500             }
 501         }
 502
 503         # Show serial enumeration when needed
 504         if ($item_info->{enumchron}) {
 505             $itemdata_enumchron = 1;
 506         }
 507         # Show collection when needed
 508         if ($item_info->{ccode}) {
 509             $itemdata_ccode = 1;
 510         }
 511
 512         push @{$biblioLoopIter{itemLoop}}, $item_info;
 513     }
 514     $template->param(
 515         itemdata_enumchron => $itemdata_enumchron,
 516         itemdata_ccode     => $itemdata_ccode,
 517     );
 518
 519     if ($numCopiesAvailable > 0) {
 520         $numBibsAvailable++;
 521         $biblioLoopIter{bib_available} = 1;
 522         $biblioLoopIter{holdable} = 1;
 523         $biblioLoopIter{itemholdable} = 1 if $numCopiesOPACAvailable;
 524     }
 525     if ($biblioLoopIter{already_reserved}) {
 526         $biblioLoopIter{holdable} = undef;
 527         $biblioLoopIter{itemholdable} = undef;
 528     }
 529     if ( $biblioLoopIter{holdable} ) {
 530         @not_available_at = uniq @not_available_at;
 531         $biblioLoopIter{not_available_at} = \@not_available_at ;
 532     }
 533
 534     unless ( $can_place_hold_if_available_at_pickup ) {
 535         @not_available_at = uniq @not_available_at;
 536         $biblioLoopIter{not_available_at} = \@not_available_at ;
 537         # The record is not holdable is not available at any of the libraries
 538         if ( Koha::Libraries->search->count == @not_available_at ) {
 539             $biblioLoopIter{holdable} = 0;
 540         }
 541     }
 542
 543     my $status = CanBookBeReserved( $borrowernumber, $biblioNum )->{status};
 544     $biblioLoopIter{holdable} &&= $status eq 'OK';
 545     $biblioLoopIter{$status} = 1;
 546
 547     if ( $biblioLoopIter{holdable} and C4::Context->preference('AllowHoldItemTypeSelection') ) {
 548         # build the allowed item types loop
 549         my $rs = $biblio->items->search_ordered(
 550             undef,
 551             {   select => [ { distinct => 'itype' } ],
 552                 as     => 'item_type'
 553             }
 554         );
 555
 556         my @item_types =
 557           grep { CanBookBeReserved( $borrowernumber, $biblioNum, $branch, { itemtype => $_ } )->{status} eq 'OK' }
 558           $rs->get_column('item_type');
 559
 560         $biblioLoopIter{allowed_item_types} = \@item_types;
 561     }
 562
 563     if ( $status eq 'recall' ) {
 564         $biblioLoopIter{recall} = 1;
 565     }
 566
 567     # For multiple holds per record, if a patron has previously placed a hold,
 568     # the patron can only place more holds of the same type. That is, if the
 569     # patron placed a record level hold, all the holds the patron places must
 570     # be record level. If the patron placed an item level hold, all holds
 571     # the patron places must be item level
 572     my $forced_hold_level = Koha::Holds->search(
 573         {
 574             borrowernumber => $borrowernumber,
 575             biblionumber   => $biblioNum,
 576             found          => undef,
 577         }
 578     )->forced_hold_level();
 579     if ($forced_hold_level) {
 580         $biblioLoopIter{force_hold}   = 1 if $forced_hold_level eq 'item';
 581         $biblioLoopIter{itemholdable} = 0 if $forced_hold_level eq 'record';
 582         $biblioLoopIter{forced_hold_level} = $forced_hold_level;
 583     }
 584
 585
 586     push @$biblioLoop, \%biblioLoopIter;
 587
 588     $anyholdable = 1 if $biblioLoopIter{holdable};
 589 }
 590
 591 unless ($pickup_locations->count) {
 592     $numBibsAvailable = 0;
 593     $anyholdable = 0;
 594     $template->param(
 595         message => 1,
 596         no_pickup_locations => 1
 597     );
 598 }
 599
 600 if ( $numBibsAvailable == 0 || $anyholdable == 0) {
 601     $template->param( none_available => 1 );
 602 }
 603
 604 if (scalar @biblionumbers > 1) {
 605     $template->param( multi_hold => 1);
 606 }
 607
 608 my $show_notes=C4::Context->preference('OpacHoldNotes');
 609 $template->param(OpacHoldNotes=>$show_notes);
 610
 611 # display infos
 612 $template->param(bibitemloop => $biblioLoop);
 613 # can set reserve date in future
 614 if (
 615     C4::Context->preference( 'AllowHoldDateInFuture' ) &&
 616     C4::Context->preference( 'OPACAllowHoldDateInFuture' )
 617     ) {
 618     $template->param(
 619             reserve_in_future         => 1,
 620     );
 621 }
 622
 623 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };