t/db_dependent/Items.t

   1 #!/usr/bin/perl
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  17 #
  18
  19 use Modern::Perl;
  20 use Data::Dumper;
  21
  22 use MARC::Record;
  23 use C4::Items;
  24 use C4::Biblio;
  25 use Koha::Items;
  26 use Koha::Database;
  27 use Koha::DateUtils qw( dt_from_string );
  28 use Koha::Library;
  29 use Koha::DateUtils;
  30 use Koha::MarcSubfieldStructures;
  31 use Koha::Caches;
  32 use Koha::AuthorisedValues;
  33
  34 use t::lib::Mocks;
  35 use t::lib::TestBuilder;
  36
  37 use Test::More tests => 15;
  38
  39 use Test::Warn;
  40
  41 my $schema = Koha::Database->new->schema;
  42 my $location = 'My Location';
  43
  44 subtest 'General Add, Get and Del tests' => sub {
  45
  46     plan tests => 16;
  47
  48     $schema->storage->txn_begin;
  49
  50     my $builder = t::lib::TestBuilder->new;
  51     my $library = $builder->build({
  52         source => 'Branch',
  53     });
  54     my $itemtype = $builder->build({
  55         source => 'Itemtype',
  56     });
  57
  58     # Create a biblio instance for testing
  59     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
  60     my $biblio = $builder->build_sample_biblio();
  61
  62     # Add an item.
  63     my ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $library->{branchcode}, holdingbranch => $library->{branchcode}, location => $location, itype => $itemtype->{itemtype} } , $biblio->biblionumber);
  64     cmp_ok($item_bibnum, '==', $biblio->biblionumber, "New item is linked to correct biblionumber.");
  65     cmp_ok($item_bibitemnum, '==', $biblio->biblioitem->biblioitemnumber, "New item is linked to correct biblioitemnumber.");
  66
  67     # Get item.
  68     my $getitem = Koha::Items->find($itemnumber);
  69     cmp_ok($getitem->itemnumber, '==', $itemnumber, "Retrieved item has correct itemnumber.");
  70     cmp_ok($getitem->biblioitemnumber, '==', $item_bibitemnum, "Retrieved item has correct biblioitemnumber.");
  71     is( $getitem->location, $location, "The location should not have been modified" );
  72     is( $getitem->permanent_location, $location, "The permanent_location should have been set to the location value" );
  73
  74
  75     # Do not modify anything, and do not explode!
  76     my $dbh = C4::Context->dbh;
  77     local $dbh->{RaiseError} = 1;
  78     ModItem({}, $biblio->biblionumber, $itemnumber);
  79
  80     # Modify item; setting barcode.
  81     ModItem({ barcode => '987654321' }, $biblio->biblionumber, $itemnumber);
  82     my $moditem = Koha::Items->find($itemnumber);
  83     cmp_ok($moditem->barcode, '==', '987654321', 'Modified item barcode successfully to: '.$moditem->barcode . '.');
  84
  85     # Delete item.
  86     DelItem({ biblionumber => $biblio->biblionumber, itemnumber => $itemnumber });
  87     my $getdeleted = Koha::Items->find($itemnumber);
  88     is($getdeleted, undef, "Item deleted as expected.");
  89
  90     ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $library->{branchcode}, holdingbranch => $library->{branchcode}, location => $location, permanent_location => 'my permanent location', itype => $itemtype->{itemtype} } , $biblio->biblionumber);
  91     $getitem = Koha::Items->find($itemnumber);
  92     is( $getitem->location, $location, "The location should not have been modified" );
  93     is( $getitem->permanent_location, 'my permanent location', "The permanent_location should not have modified" );
  94
  95     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber);
  96     $getitem = Koha::Items->find($itemnumber);
  97     is( $getitem->location, $location, "The location should have been set to correct location" );
  98     is( $getitem->permanent_location, $location, "The permanent_location should have been set to location" );
  99
 100     ModItem({ location => 'CART' }, $biblio->biblionumber, $itemnumber);
 101     $getitem = Koha::Items->find($itemnumber);
 102     is( $getitem->location, 'CART', "The location should have been set to CART" );
 103     is( $getitem->permanent_location, $location, "The permanent_location should not have been set to CART" );
 104
 105     t::lib::Mocks::mock_preference('item-level_itypes', '1');
 106     $getitem = Koha::Items->find($itemnumber);
 107     is( $getitem->effective_itemtype, $itemtype->{itemtype}, "Itemtype set correctly when using item-level_itypes" );
 108     t::lib::Mocks::mock_preference('item-level_itypes', '0');
 109     $getitem = Koha::Items->find($itemnumber);
 110     is( $getitem->effective_itemtype, $biblio->biblioitem->itemtype, "Itemtype set correctly when not using item-level_itypes" );
 111
 112     $schema->storage->txn_rollback;
 113 };
 114
 115 subtest 'ModItem tests' => sub {
 116     plan tests => 6;
 117
 118     $schema->storage->txn_begin;
 119
 120     my $builder = t::lib::TestBuilder->new;
 121     my $item = $builder->build({
 122         source => 'Item',
 123         value  => {
 124             itemlost     => 0,
 125             damaged      => 0,
 126             withdrawn    => 0,
 127             itemlost_on  => undef,
 128             damaged_on   => undef,
 129             withdrawn_on => undef,
 130         }
 131     });
 132
 133     my @fields = qw( itemlost withdrawn damaged );
 134     for my $field (@fields) {
 135         $item->{$field} = 1;
 136         ModItem( $item, $item->{biblionumber}, $item->{itemnumber} );
 137         my $post_mod_item = Koha::Items->find({ itemnumber => $item->{itemnumber} })->unblessed;
 138         is( output_pref({ str => $post_mod_item->{$field."_on"}, dateonly => 1 }), output_pref({ dt => dt_from_string(), dateonly => 1 }), "When updating $field, $field"."_on is updated" );
 139
 140         $item->{$field} = 0;
 141         ModItem( $item, $item->{biblionumber}, $item->{itemnumber} );
 142         $post_mod_item = Koha::Items->find({ itemnumber => $item->{itemnumber} })->unblessed;
 143         is( $post_mod_item->{$field."_on"}, undef, "When clearing $field, $field"."_on is cleared" );
 144     }
 145
 146     $schema->storage->txn_rollback;
 147
 148 };
 149
 150 subtest 'GetHiddenItemnumbers tests' => sub {
 151
 152     plan tests => 11;
 153
 154     # This sub is controlled by the OpacHiddenItems system preference.
 155
 156     $schema->storage->txn_begin;
 157
 158     my $builder = t::lib::TestBuilder->new;
 159     my $library1 = $builder->build({
 160         source => 'Branch',
 161     });
 162
 163     my $library2 = $builder->build({
 164         source => 'Branch',
 165     });
 166     my $itemtype = $builder->build({
 167         source => 'Itemtype',
 168     });
 169
 170     # Create a new biblio
 171     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 172     my $biblio = $builder->build_sample_biblio();
 173
 174     # Add two items
 175     my ( $item1_bibnum, $item1_bibitemnum, $item1_itemnumber ) = AddItem(
 176         {
 177             homebranch    => $library1->{branchcode},
 178             holdingbranch => $library1->{branchcode},
 179             withdrawn     => 1,
 180             itype         => $itemtype->{itemtype},
 181         },
 182         $biblio->biblionumber
 183     );
 184     my ( $item2_bibnum, $item2_bibitemnum, $item2_itemnumber ) = AddItem(
 185         {
 186             homebranch    => $library2->{branchcode},
 187             holdingbranch => $library2->{branchcode},
 188             withdrawn     => 0,
 189             itype         => $itemtype->{itemtype},
 190         },
 191         $biblio->biblionumber
 192     );
 193
 194     my $opachiddenitems;
 195     my @itemnumbers = ($item1_itemnumber,$item2_itemnumber);
 196     my @hidden;
 197     my @items;
 198     push @items, Koha::Items->find( $item1_itemnumber )->unblessed;
 199     push @items, Koha::Items->find( $item2_itemnumber )->unblessed;
 200
 201     # Empty OpacHiddenItems
 202     t::lib::Mocks::mock_preference('OpacHiddenItems','');
 203     ok( !defined( GetHiddenItemnumbers( { items => \@items } ) ),
 204         "Hidden items list undef if OpacHiddenItems empty");
 205
 206     # Blank spaces
 207     t::lib::Mocks::mock_preference('OpacHiddenItems','  ');
 208     ok( scalar GetHiddenItemnumbers( { items => \@items } ) == 0,
 209         "Hidden items list empty if OpacHiddenItems only contains blanks");
 210
 211     # One variable / value
 212     $opachiddenitems = "
 213         withdrawn: [1]";
 214     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 215     @hidden = GetHiddenItemnumbers( { items => \@items } );
 216     ok( scalar @hidden == 1, "Only one hidden item");
 217     is( $hidden[0], $item1_itemnumber, "withdrawn=1 is hidden");
 218
 219     # One variable, two values
 220     $opachiddenitems = "
 221         withdrawn: [1,0]";
 222     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 223     @hidden = GetHiddenItemnumbers( { items => \@items } );
 224     ok( scalar @hidden == 2, "Two items hidden");
 225     is_deeply( \@hidden, \@itemnumbers, "withdrawn=1 and withdrawn=0 hidden");
 226
 227     # Two variables, a value each
 228     $opachiddenitems = "
 229         withdrawn: [1]
 230         homebranch: [$library2->{branchcode}]
 231     ";
 232     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 233     @hidden = GetHiddenItemnumbers( { items => \@items } );
 234     ok( scalar @hidden == 2, "Two items hidden");
 235     is_deeply( \@hidden, \@itemnumbers, "withdrawn=1 and homebranch library2 hidden");
 236
 237     # Override hidden with patron category
 238     t::lib::Mocks::mock_preference( 'OpacHiddenItemsExceptions', 'S' );
 239     @hidden = GetHiddenItemnumbers( { items => \@items, borcat => 'PT' } );
 240     ok( scalar @hidden == 2, "Two items still hidden");
 241     @hidden = GetHiddenItemnumbers( { items => \@items, borcat => 'S' } );
 242     ok( scalar @hidden == 0, "Two items not hidden");
 243
 244     # Valid OpacHiddenItems, empty list
 245     @items = ();
 246     @hidden = GetHiddenItemnumbers( { items => \@items } );
 247     ok( scalar @hidden == 0, "Empty items list, no item hidden");
 248
 249     $schema->storage->txn_rollback;
 250 };
 251
 252 subtest 'GetItemsInfo tests' => sub {
 253
 254     plan tests => 9;
 255
 256     $schema->storage->txn_begin;
 257
 258     my $builder = t::lib::TestBuilder->new;
 259     my $library1 = $builder->build({
 260         source => 'Branch',
 261     });
 262     my $library2 = $builder->build({
 263         source => 'Branch',
 264     });
 265     my $itemtype = $builder->build({
 266         source => 'Itemtype',
 267     });
 268
 269     Koha::AuthorisedValues->delete;
 270     my $av1 = Koha::AuthorisedValue->new(
 271         {
 272             category         => 'RESTRICTED',
 273             authorised_value => '1',
 274             lib              => 'Restricted Access',
 275             lib_opac         => 'Restricted Access OPAC',
 276         }
 277     )->store();
 278
 279     # Add a biblio
 280     my $biblio = $builder->build_sample_biblio();
 281     # Add an item
 282     my ( $item_bibnum, $item_bibitemnum, $itemnumber ) = AddItem(
 283         {
 284             homebranch    => $library1->{branchcode},
 285             holdingbranch => $library2->{branchcode},
 286             itype         => $itemtype->{itemtype},
 287             restricted    => 1,
 288         },
 289         $biblio->biblionumber
 290     );
 291
 292     my $library = Koha::Libraries->find( $library1->{branchcode} );
 293     $library->opac_info("homebranch OPAC info");
 294     $library->store;
 295
 296     $library = Koha::Libraries->find( $library2->{branchcode} );
 297     $library->opac_info("holdingbranch OPAC info");
 298     $library->store;
 299
 300     my @results = GetItemsInfo( $biblio->biblionumber );
 301     ok( @results, 'GetItemsInfo returns results');
 302
 303     is( $results[0]->{ home_branch_opac_info }, "homebranch OPAC info",
 304         'GetItemsInfo returns the correct home branch OPAC info notice' );
 305     is( $results[0]->{ holding_branch_opac_info }, "holdingbranch OPAC info",
 306         'GetItemsInfo returns the correct holding branch OPAC info notice' );
 307     is( exists( $results[0]->{ onsite_checkout } ), 1,
 308         'GetItemsInfo returns a onsite_checkout key' );
 309     is( $results[0]->{ restricted }, 1,
 310         'GetItemsInfo returns a restricted value code' );
 311     is( $results[0]->{ restrictedvalue }, "Restricted Access",
 312         'GetItemsInfo returns a restricted value description (staff)' );
 313     is( $results[0]->{ restrictedvalueopac }, "Restricted Access OPAC",
 314         'GetItemsInfo returns a restricted value description (OPAC)' );
 315
 316     #place item into holds queue
 317     my $dbh = C4::Context->dbh;
 318     @results = GetItemsInfo( $biblio->biblionumber );
 319     is( $results[0]->{ has_pending_hold }, "0",
 320         'Hold not marked as pending/unavailable if nothing in tmp_holdsqueue for item' );
 321
 322     $dbh->do(q{INSERT INTO tmp_holdsqueue (biblionumber, itemnumber, surname, borrowernumber ) VALUES (?, ?, "Zorro", 42)}, undef, $item_bibnum, $itemnumber);
 323     @results = GetItemsInfo( $biblio->biblionumber );
 324     is( $results[0]->{ has_pending_hold }, "1",
 325         'Hold marked as pending/unavailable if tmp_holdsqueue is not empty for item' );
 326
 327     $schema->storage->txn_rollback;
 328 };
 329
 330 subtest q{Test Koha::Database->schema()->resultset('Item')->itemtype()} => sub {
 331
 332     plan tests => 4;
 333
 334     $schema->storage->txn_begin;
 335
 336     my $biblio = $schema->resultset('Biblio')->create({
 337         title       => "Test title",
 338         datecreated => dt_from_string,
 339         biblioitems => [ { itemtype => 'BIB_LEVEL' } ],
 340     });
 341     my $biblioitem = $biblio->biblioitems->first;
 342     my $item = $schema->resultset('Item')->create({
 343         biblioitemnumber => $biblioitem->biblioitemnumber,
 344         biblionumber     => $biblio->biblionumber,
 345         itype            => "ITEM_LEVEL",
 346     });
 347
 348     t::lib::Mocks::mock_preference( 'item-level_itypes', 0 );
 349     is( $item->effective_itemtype(), 'BIB_LEVEL', '$item->itemtype() returns biblioitem.itemtype when item-level_itypes is disabled' );
 350
 351     t::lib::Mocks::mock_preference( 'item-level_itypes', 1 );
 352     is( $item->effective_itemtype(), 'ITEM_LEVEL', '$item->itemtype() returns items.itype when item-level_itypes is enabled' );
 353
 354     # If itemtype is not defined and item-level_level item types are set
 355     # fallback to biblio-level itemtype (Bug 14651) and warn
 356     $item->itype( undef );
 357     $item->update();
 358     my $effective_itemtype;
 359     warning_is { $effective_itemtype = $item->effective_itemtype() }
 360                 "item-level_itypes set but no itemtype set for item (".$item->itemnumber.")",
 361                 '->effective_itemtype() raises a warning when falling back to bib-level';
 362
 363     ok( defined $effective_itemtype &&
 364                 $effective_itemtype eq 'BIB_LEVEL',
 365         '$item->effective_itemtype() falls back to biblioitems.itemtype when item-level_itypes is enabled but undef' );
 366
 367     $schema->storage->txn_rollback;
 368 };
 369
 370 subtest 'SearchItems test' => sub {
 371     plan tests => 14;
 372
 373     $schema->storage->txn_begin;
 374     my $dbh = C4::Context->dbh;
 375     my $builder = t::lib::TestBuilder->new;
 376
 377     my $library1 = $builder->build({
 378         source => 'Branch',
 379     });
 380     my $library2 = $builder->build({
 381         source => 'Branch',
 382     });
 383     my $itemtype = $builder->build({
 384         source => 'Itemtype',
 385     });
 386
 387     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 388     my $cpl_items_before = SearchItemsByField( 'homebranch', $library1->{branchcode});
 389
 390     my $biblio = $builder->build_sample_biblio({ title => 'Silence in the library' });
 391     $builder->build_sample_biblio({ title => 'Silence in the shadow' });
 392
 393     my (undef, $initial_items_count) = SearchItems(undef, {rows => 1});
 394
 395     # Add two items
 396     my (undef, undef, $item1_itemnumber) = AddItem({
 397         homebranch => $library1->{branchcode},
 398         holdingbranch => $library1->{branchcode},
 399         itype => $itemtype->{itemtype},
 400     }, $biblio->biblionumber);
 401     my (undef, undef, $item2_itemnumber) = AddItem({
 402         homebranch => $library2->{branchcode},
 403         holdingbranch => $library2->{branchcode},
 404         itype => $itemtype->{itemtype},
 405     }, $biblio->biblionumber);
 406
 407     my ($items, $total_results);
 408
 409     ($items, $total_results) = SearchItems();
 410     is($total_results, $initial_items_count + 2, "Created 2 new items");
 411     is(scalar @$items, $total_results, "SearchItems() returns all items");
 412
 413     ($items, $total_results) = SearchItems(undef, {rows => 1});
 414     is($total_results, $initial_items_count + 2);
 415     is(scalar @$items, 1, "SearchItems(undef, {rows => 1}) returns only 1 item");
 416
 417     # Search all items where homebranch = 'CPL'
 418     my $filter = {
 419         field => 'homebranch',
 420         query => $library1->{branchcode},
 421         operator => '=',
 422     };
 423     ($items, $total_results) = SearchItems($filter);
 424     ok($total_results > 0, "There is at least one CPL item");
 425     my $all_items_are_CPL = 1;
 426     foreach my $item (@$items) {
 427         if ($item->{homebranch} ne $library1->{branchcode}) {
 428             $all_items_are_CPL = 0;
 429             last;
 430         }
 431     }
 432     ok($all_items_are_CPL, "All items returned by SearchItems are from CPL");
 433
 434     # Search all items where homebranch != 'CPL'
 435     $filter = {
 436         field => 'homebranch',
 437         query => $library1->{branchcode},
 438         operator => '!=',
 439     };
 440     ($items, $total_results) = SearchItems($filter);
 441     ok($total_results > 0, "There is at least one non-CPL item");
 442     my $all_items_are_not_CPL = 1;
 443     foreach my $item (@$items) {
 444         if ($item->{homebranch} eq $library1->{branchcode}) {
 445             $all_items_are_not_CPL = 0;
 446             last;
 447         }
 448     }
 449     ok($all_items_are_not_CPL, "All items returned by SearchItems are not from CPL");
 450
 451     # Search all items where biblio title (245$a) is like 'Silence in the %'
 452     $filter = {
 453         field => 'marc:245$a',
 454         query => 'Silence in the %',
 455         operator => 'like',
 456     };
 457     ($items, $total_results) = SearchItems($filter);
 458     ok($total_results >= 2, "There is at least 2 items with a biblio title like 'Silence in the %'");
 459
 460     # Search all items where biblio title is 'Silence in the library'
 461     # and homebranch is 'CPL'
 462     $filter = {
 463         conjunction => 'AND',
 464         filters => [
 465             {
 466                 field => 'marc:245$a',
 467                 query => 'Silence in the %',
 468                 operator => 'like',
 469             },
 470             {
 471                 field => 'homebranch',
 472                 query => $library1->{branchcode},
 473                 operator => '=',
 474             },
 475         ],
 476     };
 477     ($items, $total_results) = SearchItems($filter);
 478     my $found = 0;
 479     foreach my $item (@$items) {
 480         if ($item->{itemnumber} == $item1_itemnumber) {
 481             $found = 1;
 482             last;
 483         }
 484     }
 485     ok($found, "item1 found");
 486
 487     my $frameworkcode = q||;
 488     my ($itemfield) = GetMarcFromKohaField('items.itemnumber', $frameworkcode);
 489
 490     # Create item subfield 'z' without link
 491     $dbh->do('DELETE FROM marc_subfield_structure WHERE tagfield=? AND tagsubfield="z" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 492     $dbh->do('INSERT INTO marc_subfield_structure (tagfield, tagsubfield, frameworkcode) VALUES (?, "z", ?)', undef, $itemfield, $frameworkcode);
 493
 494     # Clear cache
 495     my $cache = Koha::Caches->get_instance();
 496     $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
 497     $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
 498     $cache->clear_from_cache("default_value_for_mod_marc-");
 499     $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
 500
 501     my $item3_record = new MARC::Record;
 502     $item3_record->append_fields(
 503         new MARC::Field(
 504             $itemfield, '', '',
 505             'z' => 'foobar',
 506             'y' => $itemtype->{itemtype}
 507         )
 508     );
 509     my (undef, undef, $item3_itemnumber) = AddItemFromMarc($item3_record,
 510         $biblio->biblionumber);
 511
 512     # Search item where item subfield z is "foobar"
 513     $filter = {
 514         field => 'marc:' . $itemfield . '$z',
 515         query => 'foobar',
 516         operator => 'like',
 517     };
 518     ($items, $total_results) = SearchItems($filter);
 519     ok(scalar @$items == 1, 'found 1 item with $z = "foobar"');
 520
 521     # Link $z to items.itemnotes (and make sure there is no other subfields
 522     # linked to it)
 523     $dbh->do('DELETE FROM marc_subfield_structure WHERE kohafield="items.itemnotes" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 524     $dbh->do('UPDATE marc_subfield_structure SET kohafield="items.itemnotes" WHERE tagfield=? AND tagsubfield="z" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 525
 526     # Clear cache
 527     $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
 528     $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
 529     $cache->clear_from_cache("default_value_for_mod_marc-");
 530     $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
 531
 532     ModItemFromMarc($item3_record, $biblio->biblionumber, $item3_itemnumber);
 533
 534     # Make sure the link is used
 535     my $item3 = Koha::Items->find($item3_itemnumber);
 536     ok($item3->itemnotes eq 'foobar', 'itemnotes eq "foobar"');
 537
 538     # Do the same search again.
 539     # This time it will search in items.itemnotes
 540     ($items, $total_results) = SearchItems($filter);
 541     ok(scalar @$items == 1, 'found 1 item with itemnotes = "foobar"');
 542
 543     my $cpl_items_after = SearchItemsByField( 'homebranch', $library1->{branchcode});
 544     is( ( scalar( @$cpl_items_after ) - scalar ( @$cpl_items_before ) ), 1, 'SearchItemsByField should return something' );
 545
 546     $schema->storage->txn_rollback;
 547 };
 548
 549 subtest 'Koha::Item(s) tests' => sub {
 550
 551     plan tests => 5;
 552
 553     $schema->storage->txn_begin();
 554
 555     my $builder = t::lib::TestBuilder->new;
 556     my $library1 = $builder->build({
 557         source => 'Branch',
 558     });
 559     my $library2 = $builder->build({
 560         source => 'Branch',
 561     });
 562     my $itemtype = $builder->build({
 563         source => 'Itemtype',
 564     });
 565
 566     # Create a biblio and item for testing
 567     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 568     my $biblio = $builder->build_sample_biblio();
 569     my ( $item_bibnum, $item_bibitemnum, $itemnumber ) = AddItem(
 570         {
 571             homebranch    => $library1->{branchcode},
 572             holdingbranch => $library2->{branchcode},
 573             itype         => $itemtype->{itemtype},
 574         },
 575         $biblio->biblionumber
 576     );
 577
 578     # Get item.
 579     my $item = Koha::Items->find( $itemnumber );
 580     is( ref($item), 'Koha::Item', "Got Koha::Item" );
 581
 582     my $homebranch = $item->home_branch();
 583     is( ref($homebranch), 'Koha::Library', "Got Koha::Library from home_branch method" );
 584     is( $homebranch->branchcode(), $library1->{branchcode}, "Home branch code matches homebranch" );
 585
 586     my $holdingbranch = $item->holding_branch();
 587     is( ref($holdingbranch), 'Koha::Library', "Got Koha::Library from holding_branch method" );
 588     is( $holdingbranch->branchcode(), $library2->{branchcode}, "Home branch code matches holdingbranch" );
 589
 590     $schema->storage->txn_rollback;
 591 };
 592
 593 subtest 'C4::Biblio::EmbedItemsInMarcBiblio' => sub {
 594     plan tests => 8;
 595
 596     $schema->storage->txn_begin();
 597
 598     my $builder = t::lib::TestBuilder->new;
 599     my $library1 = $builder->build({
 600         source => 'Branch',
 601     });
 602     my $library2 = $builder->build({
 603         source => 'Branch',
 604     });
 605     my $itemtype = $builder->build({
 606         source => 'Itemtype',
 607     });
 608
 609     my $biblio = $builder->build_sample_biblio();
 610     my $item_infos = [
 611         { homebranch => $library1->{branchcode}, holdingbranch => $library1->{branchcode} },
 612         { homebranch => $library1->{branchcode}, holdingbranch => $library1->{branchcode} },
 613         { homebranch => $library1->{branchcode}, holdingbranch => $library1->{branchcode} },
 614         { homebranch => $library2->{branchcode}, holdingbranch => $library2->{branchcode} },
 615         { homebranch => $library2->{branchcode}, holdingbranch => $library2->{branchcode} },
 616         { homebranch => $library1->{branchcode}, holdingbranch => $library2->{branchcode} },
 617         { homebranch => $library1->{branchcode}, holdingbranch => $library2->{branchcode} },
 618         { homebranch => $library1->{branchcode}, holdingbranch => $library2->{branchcode} },
 619     ];
 620     my $number_of_items = scalar @$item_infos;
 621     my $number_of_items_with_homebranch_is_CPL =
 622       grep { $_->{homebranch} eq $library1->{branchcode} } @$item_infos;
 623
 624     my @itemnumbers;
 625     for my $item_info (@$item_infos) {
 626         my ( undef, undef, $itemnumber ) = AddItem(
 627             {
 628                 homebranch    => $item_info->{homebranch},
 629                 holdingbranch => $item_info->{holdingbanch},
 630                 itype         => $itemtype->{itemtype},
 631             },
 632             $biblio->biblionumber
 633         );
 634         push @itemnumbers, $itemnumber;
 635     }
 636
 637     # Emptied the OpacHiddenItems pref
 638     t::lib::Mocks::mock_preference( 'OpacHiddenItems', '' );
 639
 640     my ($itemfield) =
 641       C4::Biblio::GetMarcFromKohaField( 'items.itemnumber', '' );
 642     my $record = C4::Biblio::GetMarcBiblio({ biblionumber => $biblio->biblionumber });
 643     warning_is { C4::Biblio::EmbedItemsInMarcBiblio() }
 644     { carped => 'EmbedItemsInMarcBiblio: No MARC record passed' },
 645       'Should carp is no record passed.';
 646
 647     C4::Biblio::EmbedItemsInMarcBiblio({
 648         marc_record  => $record,
 649         biblionumber => $biblio->biblionumber });
 650     my @items = $record->field($itemfield);
 651     is( scalar @items, $number_of_items, 'Should return all items' );
 652
 653     my $marc_with_items = C4::Biblio::GetMarcBiblio({
 654         biblionumber => $biblio->biblionumber,
 655         embed_items  => 1 });
 656     is_deeply( $record, $marc_with_items, 'A direct call to GetMarcBiblio with items matches');
 657
 658     C4::Biblio::EmbedItemsInMarcBiblio({
 659         marc_record  => $record,
 660         biblionumber => $biblio->biblionumber,
 661         item_numbers => [ $itemnumbers[1], $itemnumbers[3] ] });
 662     @items = $record->field($itemfield);
 663     is( scalar @items, 2, 'Should return all items present in the list' );
 664
 665     C4::Biblio::EmbedItemsInMarcBiblio({
 666         marc_record  => $record,
 667         biblionumber => $biblio->biblionumber,
 668         opac         => 1 });
 669     @items = $record->field($itemfield);
 670     is( scalar @items, $number_of_items, 'Should return all items for opac' );
 671
 672     my $opachiddenitems = "
 673         homebranch: ['$library1->{branchcode}']";
 674     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 675
 676     C4::Biblio::EmbedItemsInMarcBiblio({
 677         marc_record  => $record,
 678         biblionumber => $biblio->biblionumber });
 679     @items = $record->field($itemfield);
 680     is( scalar @items,
 681         $number_of_items,
 682         'Even with OpacHiddenItems set, all items should have been embedded' );
 683
 684     C4::Biblio::EmbedItemsInMarcBiblio({
 685         marc_record  => $record,
 686         biblionumber => $biblio->biblionumber,
 687         opac         => 1 });
 688     @items = $record->field($itemfield);
 689     is(
 690         scalar @items,
 691         $number_of_items - $number_of_items_with_homebranch_is_CPL,
 692 'For OPAC, the pref OpacHiddenItems should have been take into account. Only items with homebranch ne CPL should have been embedded'
 693     );
 694
 695     $opachiddenitems = "
 696         homebranch: ['$library1->{branchcode}', '$library2->{branchcode}']";
 697     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 698     C4::Biblio::EmbedItemsInMarcBiblio({
 699         marc_record  => $record,
 700         biblionumber => $biblio->biblionumber,
 701         opac         => 1 });
 702     @items = $record->field($itemfield);
 703     is(
 704         scalar @items,
 705         0,
 706 'For OPAC, If all items are hidden, no item should have been embedded'
 707     );
 708
 709     $schema->storage->txn_rollback;
 710 };
 711
 712
 713 subtest 'C4::Items::_build_default_values_for_mod_marc' => sub {
 714     plan tests => 4;
 715
 716     $schema->storage->txn_begin();
 717
 718     my $builder = t::lib::TestBuilder->new;
 719     my $framework = $builder->build({ source => 'BiblioFramework' });
 720
 721     # Link biblio.biblionumber and biblioitems.biblioitemnumber to avoid _koha_marc_update_bib_ids to fail with 'no biblio[item]number tag for framework"
 722     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '999', tagsubfield => [ 'c', 'd' ] })->delete;
 723     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '999', tagsubfield => 'c', kohafield => 'biblio.biblionumber' })->store;
 724     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '999', tagsubfield => 'd', kohafield => 'biblioitems.biblioitemnumber' })->store;
 725
 726     # Same for item fields: itemnumber, barcode, itype
 727     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '952', tagsubfield => [ '9', 'p', 'y' ] })->delete;
 728     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '952', tagsubfield => '9', kohafield => 'items.itemnumber' })->store;
 729     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '952', tagsubfield => 'p', kohafield => 'items.barcode' })->store;
 730     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '952', tagsubfield => 'y', kohafield => 'items.itype' })->store;
 731     Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 732
 733     my $itemtype = $builder->build({ source => 'Itemtype' })->{itemtype};
 734
 735     # Create a record with a barcode
 736     my $biblio = $builder->build_sample_biblio({ frameworkcode => $framework->{frameworkcode} });
 737     my $item_record = new MARC::Record;
 738     my $a_barcode = 'a barcode';
 739     my $barcode_field = MARC::Field->new(
 740         '952', ' ', ' ',
 741         p => $a_barcode,
 742         y => $itemtype
 743     );
 744     my $itemtype_field = MARC::Field->new(
 745         '952', ' ', ' ',
 746         y => $itemtype
 747     );
 748     $item_record->append_fields( $barcode_field );
 749     my (undef, undef, $item_itemnumber) = AddItemFromMarc($item_record, $biblio->biblionumber);
 750
 751     # Make sure everything has been set up
 752     my $item = Koha::Items->find($item_itemnumber);
 753     is( $item->barcode, $a_barcode, 'Everything has been set up correctly, the barcode is defined as expected' );
 754
 755     # Delete the barcode field and save the record
 756     $item_record->delete_fields( $barcode_field );
 757     $item_record->append_fields( $itemtype_field ); # itemtype is mandatory
 758     ModItemFromMarc($item_record, $biblio->biblionumber, $item_itemnumber);
 759     $item = Koha::Items->find($item_itemnumber);
 760     is( $item->barcode, undef, 'The default value should have been set to the barcode, the field is mapped to a kohafield' );
 761
 762     # Re-add the barcode field and save the record
 763     $item_record->append_fields( $barcode_field );
 764     ModItemFromMarc($item_record, $biblio->biblionumber, $item_itemnumber);
 765     $item = Koha::Items->find($item_itemnumber);
 766     is( $item->barcode, $a_barcode, 'Everything has been set up correctly, the barcode is defined as expected' );
 767
 768     # Remove the mapping for barcode
 769     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '952', tagsubfield => 'p' })->delete;
 770
 771     # And make sure the caches are cleared
 772     my $cache = Koha::Caches->get_instance();
 773     $cache->clear_from_cache("default_value_for_mod_marc-");
 774     $cache->clear_from_cache("MarcSubfieldStructure-");
 775
 776     # Update the MARC field with another value
 777     $item_record->delete_fields( $barcode_field );
 778     my $another_barcode = 'another_barcode';
 779     my $another_barcode_field = MARC::Field->new(
 780         '952', ' ', ' ',
 781         p => $another_barcode,
 782     );
 783     $item_record->append_fields( $another_barcode_field );
 784     # The DB value should not have been updated
 785     ModItemFromMarc($item_record, $biblio->biblionumber, $item_itemnumber);
 786     $item = Koha::Items->find($item_itemnumber);
 787     is ( $item->barcode, $a_barcode, 'items.barcode is not mapped anymore, so the DB column has not been updated' );
 788
 789     $cache->clear_from_cache("default_value_for_mod_marc-");
 790     $cache->clear_from_cache( "MarcSubfieldStructure-" );
 791     $schema->storage->txn_rollback;
 792 };
 793
 794 subtest '_mod_item_dates' => sub {
 795     plan tests => 11;
 796
 797     is( C4::Items::_mod_item_dates(), undef, 'Call without parameters' );
 798     is( C4::Items::_mod_item_dates(1), undef, 'Call without hashref' );
 799
 800     my $orgitem;
 801     my $item = {
 802         itemcallnumber  => 'V II 149 1963',
 803         barcode         => '109304',
 804     };
 805     $orgitem = { %$item };
 806     C4::Items::_mod_item_dates($item);
 807     is_deeply( $item, $orgitem, 'No dates passed to _mod_item_dates' );
 808
 809     # add two correct dates
 810     t::lib::Mocks::mock_preference('dateformat', 'us');
 811     $item->{dateaccessioned} = '01/31/2016';
 812     $item->{onloan} =  $item->{dateaccessioned};
 813     $orgitem = { %$item };
 814     C4::Items::_mod_item_dates($item);
 815     is( $item->{dateaccessioned}, '2016-01-31', 'dateaccessioned is fine' );
 816     is( $item->{onloan}, '2016-01-31', 'onloan is fine too' );
 817
 818
 819     # add some invalid dates
 820     $item->{notexistingcolumndate} = '13/1/2015'; # wrong format
 821     $item->{anotherdate} = 'tralala'; # even worse
 822     $item->{myzerodate} = '0000-00-00'; # wrong too
 823     C4::Items::_mod_item_dates($item);
 824     is( $item->{notexistingcolumndate}, undef, 'Invalid date became NULL' );
 825     is( $item->{anotherdate}, undef, 'Second invalid date became NULL too' );
 826     is( $item->{myzerodate}, undef, '0000-00-00 became NULL too' );
 827
 828     # check if itemlost_on was not touched
 829     $item->{itemlost_on} = '12345678';
 830     $item->{withdrawn_on} = '12/31/2015 23:59:00';
 831     $item->{damaged_on} = '01/20/2017 09:00:00';
 832     $orgitem = { %$item };
 833     C4::Items::_mod_item_dates($item);
 834     is_deeply( $item, $orgitem, 'Colums with _on are not touched' );
 835
 836     t::lib::Mocks::mock_preference('dateformat', 'metric');
 837     $item->{dateaccessioned} = '01/31/2016'; #wrong
 838     $item->{yetanotherdatetime} = '20/01/2016 13:58:00'; #okay
 839     C4::Items::_mod_item_dates($item);
 840     is( $item->{dateaccessioned}, undef, 'dateaccessioned wrong format' );
 841     is( $item->{yetanotherdatetime}, '2016-01-20 13:58:00',
 842         'yetanotherdatetime is ok' );
 843 };
 844
 845 subtest 'get_hostitemnumbers_of' => sub {
 846     plan tests => 3;
 847
 848     $schema->storage->txn_begin;
 849     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 850     my $builder = t::lib::TestBuilder->new;
 851
 852     # Host item field without 0 or 9
 853     my $bib1 = MARC::Record->new();
 854     $bib1->append_fields(
 855         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 856         MARC::Field->new('245', ' ', ' ', a => 'Silence in the library'),
 857         MARC::Field->new('773', ' ', ' ', b => 'b without 0 or 9'),
 858     );
 859     my ($biblionumber1, $bibitemnum1) = AddBiblio($bib1, '');
 860     my @itemnumbers1 = C4::Items::get_hostitemnumbers_of( $biblionumber1 );
 861     is( scalar @itemnumbers1, 0, '773 without 0 or 9');
 862
 863     # Correct host item field, analytical records on
 864     t::lib::Mocks::mock_preference('EasyAnalyticalRecords', 1);
 865     my $hostitem = $builder->build_sample_item();
 866     my $bib2 = MARC::Record->new();
 867     $bib2->append_fields(
 868         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 869         MARC::Field->new('245', ' ', ' ', a => 'Silence in the library'),
 870         MARC::Field->new('773', ' ', ' ', 0 => $hostitem->biblionumber , 9 => $hostitem->itemnumber, b => 'b' ),
 871     );
 872     my ($biblionumber2, $bibitemnum2) = AddBiblio($bib2, '');
 873     my @itemnumbers2 = C4::Items::get_hostitemnumbers_of( $biblionumber2 );
 874     is( scalar @itemnumbers2, 1, '773 with 0 and 9, EasyAnalyticalRecords on');
 875
 876     # Correct host item field, analytical records off
 877     t::lib::Mocks::mock_preference('EasyAnalyticalRecords', 0);
 878     @itemnumbers2 = C4::Items::get_hostitemnumbers_of( $biblionumber2 );
 879     is( scalar @itemnumbers2, 0, '773 with 0 and 9, EasyAnalyticalRecords off');
 880
 881     $schema->storage->txn_rollback;
 882 };
 883
 884 subtest 'Test logging for ModItem' => sub {
 885
 886     plan tests => 3;
 887
 888     t::lib::Mocks::mock_preference('CataloguingLog', 1);
 889
 890     $schema->storage->txn_begin;
 891
 892     my $builder = t::lib::TestBuilder->new;
 893     my $library = $builder->build({
 894         source => 'Branch',
 895     });
 896     my $itemtype = $builder->build({
 897         source => 'Itemtype',
 898     });
 899
 900     # Create a biblio instance for testing
 901     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 902     my $biblio = $builder->build_sample_biblio();
 903
 904     # Add an item.
 905     my ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $library->{branchcode}, holdingbranch => $library->{branchcode}, location => $location, itype => $itemtype->{itemtype} } , $biblio->biblionumber);
 906
 907     # False means no logging
 908     $schema->resultset('ActionLog')->search()->delete();
 909     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber, { log_action => 0 });
 910     is( $schema->resultset('ActionLog')->count(), 0, 'False value does not trigger logging' );
 911
 912     # True means logging
 913     $schema->resultset('ActionLog')->search()->delete();
 914     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber, { log_action => 1 });
 915     is( $schema->resultset('ActionLog')->count(), 1, 'True value does trigger logging' );
 916
 917     # Undefined defaults to true
 918     $schema->resultset('ActionLog')->search()->delete();
 919     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber);
 920     is( $schema->resultset('ActionLog')->count(), 1, 'Undefined value defaults to true, triggers logging' );
 921
 922     $schema->storage->txn_rollback;
 923 };
 924
 925 subtest 'Check stockrotationitem relationship' => sub {
 926     plan tests => 1;
 927
 928     $schema->storage->txn_begin();
 929
 930     my $builder = t::lib::TestBuilder->new;
 931     my $item = $builder->build({ source => 'Item' });
 932
 933     $builder->build({
 934         source => 'Stockrotationitem',
 935         value  => { itemnumber_id => $item->{itemnumber} }
 936     });
 937
 938     my $sritem = Koha::Items->find($item->{itemnumber})->stockrotationitem;
 939     isa_ok( $sritem, 'Koha::StockRotationItem', "Relationship works and correctly creates Koha::Object." );
 940
 941     $schema->storage->txn_rollback;
 942 };
 943
 944 subtest 'Check add_to_rota method' => sub {
 945     plan tests => 2;
 946
 947     $schema->storage->txn_begin();
 948
 949     my $builder = t::lib::TestBuilder->new;
 950     my $item = $builder->build({ source => 'Item' });
 951     my $rota = $builder->build({ source => 'Stockrotationrota' });
 952     my $srrota = Koha::StockRotationRotas->find($rota->{rota_id});
 953
 954     $builder->build({
 955         source => 'Stockrotationstage',
 956         value  => { rota_id => $rota->{rota_id} },
 957     });
 958
 959     my $sritem = Koha::Items->find($item->{itemnumber});
 960     $sritem->add_to_rota($rota->{rota_id});
 961
 962     is(
 963         Koha::StockRotationItems->find($item->{itemnumber})->stage_id,
 964         $srrota->stockrotationstages->next->stage_id,
 965         "Adding to a rota a new sritem item being assigned to its first stage."
 966     );
 967
 968     my $newrota = $builder->build({ source => 'Stockrotationrota' });
 969
 970     my $srnewrota = Koha::StockRotationRotas->find($newrota->{rota_id});
 971
 972     $builder->build({
 973         source => 'Stockrotationstage',
 974         value  => { rota_id => $newrota->{rota_id} },
 975     });
 976
 977     $sritem->add_to_rota($newrota->{rota_id});
 978
 979     is(
 980         Koha::StockRotationItems->find($item->{itemnumber})->stage_id,
 981         $srnewrota->stockrotationstages->next->stage_id,
 982         "Moving an item results in that sritem being assigned to the new first stage."
 983     );
 984
 985     $schema->storage->txn_rollback;
 986 };
 987
 988 subtest 'Split subfields in Item2Marc (Bug 21774)' => sub {
 989     plan tests => 3;
 990     $schema->storage->txn_begin;
 991
 992     my $builder = t::lib::TestBuilder->new;
 993     my $biblio = $builder->build({ source => 'Biblio', value => { frameworkcode => q{} } });
 994     my $item = $builder->build({ source => 'Item', value => { biblionumber => $biblio->{biblionumber}, ccode => 'A|B' } });
 995
 996     Koha::MarcSubfieldStructures->search({ tagfield => '952', tagsubfield => '8' })->delete; # theoretical precaution
 997     Koha::MarcSubfieldStructures->search({ kohafield => 'items.ccode' })->delete;
 998     my $mapping = Koha::MarcSubfieldStructure->new({ frameworkcode => q{}, tagfield => '952', tagsubfield => '8', kohafield => 'items.ccode' })->store;
 999
1000     # Start testing
1001     my $marc = C4::Items::Item2Marc( $item, $biblio->{biblionumber} );
1002     my @subs = $marc->subfield( $mapping->tagfield, $mapping->tagsubfield );
1003     is( @subs, 2, 'Expect two subfields' );
1004     is( $subs[0], 'A', 'First subfield matches' );
1005     is( $subs[1], 'B', 'Second subfield matches' );
1006
1007     $schema->storage->txn_rollback;
1008 };