tools/koha-news.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Script to manage the opac news.
   6 # written 11/04
   7 # Casta�eda, Carlos Sebastian - seba3c@yahoo.com.ar - Physics Library UNLP Argentina
   8 # Modified to include news to KOHA intranet - tgarip@neu.edu.tr NEU library -Cyprus
   9 # Copyright 2000-2002 Katipo Communications
  10 # Copyright (C) 2013    Mark Tompsett
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 use Modern::Perl;
  26 use CGI qw ( -utf8 );
  27 use C4::Auth;
  28 use C4::Koha;
  29 use C4::Context;
  30 use C4::Output;
  31 use C4::NewsChannels;
  32 use C4::Languages qw(getTranslatedLanguages);
  33 use Date::Calc qw/Date_to_Days Today/;
  34 use Koha::DateUtils;
  35
  36 my $cgi = CGI->new;
  37
  38 my $id             = $cgi->param('id');
  39 my $title          = $cgi->param('title');
  40 my $content        = $cgi->param('content');
  41 my $expirationdate;
  42 if ( $cgi->param('expirationdate') ) {
  43     $expirationdate = output_pref({ dt => dt_from_string( scalar $cgi->param('expirationdate') ), dateformat => 'iso', dateonly => 1 });
  44 }
  45 my $published_on= output_pref({ dt => dt_from_string( scalar $cgi->param('published_on') ), dateformat => 'iso', dateonly => 1 });
  46 my $number         = $cgi->param('number');
  47 my $lang           = $cgi->param('lang');
  48 my $branchcode     = $cgi->param('branch');
  49 my $error_message  = $cgi->param('error_message');
  50 my $wysiwyg;
  51 if( $cgi->param('editmode') ){
  52     $wysiwyg = $cgi->param('editmode') eq "wysiwyg" ? 1 : 0;
  53 } else {
  54     $wysiwyg = C4::Context->preference("NewsToolEditor") eq "tinymce" ? 1 : 0;
  55 }
  56
  57 # Foreign Key constraints work with NULL, not ''
  58 # NULL = All branches.
  59 $branchcode = undef if (defined($branchcode) && $branchcode eq '');
  60
  61 my $new_detail = get_opac_new($id);
  62
  63 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  64     {
  65         template_name   => "tools/koha-news.tt",
  66         query           => $cgi,
  67         type            => "intranet",
  68         flagsrequired   => { tools => 'edit_news' },
  69     }
  70 );
  71
  72 # Pass error message if there is one.
  73 $template->param( error_message => $error_message ) if $error_message;
  74
  75 # get lang list
  76 my @lang_list;
  77 my $tlangs = getTranslatedLanguages() ;
  78
  79 foreach my $language ( @$tlangs ) {
  80     foreach my $sublanguage ( @{$language->{'sublanguages_loop'}} ) {
  81         push @lang_list,
  82         {
  83             language => $sublanguage->{'rfc4646_subtag'},
  84             selected => ( $new_detail->{lang} eq $sublanguage->{'rfc4646_subtag'} ? 1 : 0 ),
  85         };
  86     }
  87 }
  88
  89 $template->param( lang_list   => \@lang_list,
  90                   branchcode  => $branchcode );
  91
  92 my $op = $cgi->param('op') // '';
  93
  94 if ( $op eq 'add_form' ) {
  95     $template->param( add_form => 1 );
  96     if ($id) {
  97         if($new_detail->{lang} eq "slip"){ $template->param( slip => 1); }
  98         $template->param(
  99             op => 'edit',
 100             id => $new_detail->{'idnew'}
 101         );
 102         $template->{VARS}->{'new_detail'} = $new_detail;
 103     }
 104     else {
 105         $template->param( op => 'add' );
 106     }
 107 }
 108 elsif ( $op eq 'add' ) {
 109     if ($title) {
 110         add_opac_new(
 111             {
 112                 title          => $title,
 113                 content        => $content,
 114                 lang           => $lang,
 115                 expirationdate => $expirationdate,
 116                 published_on=> $published_on,
 117                 number         => $number,
 118                 branchcode     => $branchcode,
 119                 borrowernumber => $borrowernumber,
 120             }
 121         );
 122         print $cgi->redirect("/cgi-bin/koha/tools/koha-news.pl");
 123     }
 124     else {
 125         print $cgi->redirect("/cgi-bin/koha/tools/koha-news.pl?error_message=title_missing");
 126     }
 127 }
 128 elsif ( $op eq 'edit' ) {
 129     upd_opac_new(
 130         {
 131             idnew          => $id,
 132             title          => $title,
 133             content        => $content,
 134             lang           => $lang,
 135             expirationdate => $expirationdate,
 136             published_on=> $published_on,
 137             number         => $number,
 138             branchcode     => $branchcode,
 139         }
 140     );
 141     print $cgi->redirect("/cgi-bin/koha/tools/koha-news.pl");
 142 }
 143 elsif ( $op eq 'del' ) {
 144     my @ids = $cgi->multi_param('ids');
 145     del_opac_new( join ",", @ids );
 146     print $cgi->redirect("/cgi-bin/koha/tools/koha-news.pl");
 147 }
 148
 149 else {
 150
 151     my ( $opac_news_count, $opac_news ) = &get_opac_news( undef, undef, undef );
 152
 153     foreach my $new ( @$opac_news ) {
 154         next unless $new->{'expirationdate'};
 155         my @date = split (/-/,$new->{'expirationdate'});
 156         if ($date[0]*$date[1]*$date[2]>0 && Date_to_Days( @date ) < Date_to_Days(&Today) ){
 157                         $new->{'expired'} = 1;
 158         }
 159     }
 160
 161     $template->param(
 162         opac_news       => $opac_news,
 163         opac_news_count => $opac_news_count,
 164                 );
 165 }
 166 $template->param(
 167     lang => $lang,
 168     wysiwyg => $wysiwyg,
 169 );
 170 output_html_with_http_headers $cgi, $cookie, $template->output;