C4/Acquisition.pm

   1 package C4::Acquisition;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20
  21 use Modern::Perl;
  22 use Carp;
  23 use C4::Context;
  24 use C4::Debug;
  25 use C4::Suggestions;
  26 use C4::Biblio;
  27 use C4::Contract;
  28 use C4::Debug;
  29 use C4::Templates qw(gettemplate);
  30 use Koha::DateUtils qw( dt_from_string output_pref );
  31 use Koha::Acquisition::Baskets;
  32 use Koha::Acquisition::Booksellers;
  33 use Koha::Acquisition::Orders;
  34 use Koha::Biblios;
  35 use Koha::Exceptions;
  36 use Koha::Items;
  37 use Koha::Number::Price;
  38 use Koha::Libraries;
  39 use Koha::CsvProfiles;
  40 use Koha::Patrons;
  41
  42 use C4::Koha;
  43
  44 use MARC::Field;
  45 use MARC::Record;
  46
  47 use Time::localtime;
  48
  49 use vars qw(@ISA @EXPORT);
  50
  51 BEGIN {
  52     require Exporter;
  53     @ISA    = qw(Exporter);
  54     @EXPORT = qw(
  55         &GetBasket &NewBasket &CloseBasket &ReopenBasket &DelBasket &ModBasket
  56         &GetBasketAsCSV &GetBasketGroupAsCSV
  57         &GetBasketsByBookseller &GetBasketsByBasketgroup
  58         &GetBasketsInfosByBookseller
  59
  60         &GetBasketUsers &ModBasketUsers
  61         &CanUserManageBasket
  62
  63         &ModBasketHeader
  64
  65         &ModBasketgroup &NewBasketgroup &DelBasketgroup &GetBasketgroup &CloseBasketgroup
  66         &GetBasketgroups &ReOpenBasketgroup
  67
  68         &DelOrder &ModOrder &GetOrder &GetOrders &GetOrdersByBiblionumber
  69         &GetLateOrders &GetOrderFromItemnumber
  70         &SearchOrders &GetHistory &GetRecentAcqui
  71         &ModReceiveOrder &CancelReceipt
  72         &TransferOrder
  73         &GetLastOrderNotReceivedFromSubscriptionid &GetLastOrderReceivedFromSubscriptionid
  74         &ModItemOrder
  75
  76         &GetParcels
  77
  78         &GetInvoices
  79         &GetInvoice
  80         &GetInvoiceDetails
  81         &AddInvoice
  82         &ModInvoice
  83         &CloseInvoice
  84         &ReopenInvoice
  85         &DelInvoice
  86         &MergeInvoices
  87
  88         &AddClaim
  89         &GetBiblioCountByBasketno
  90
  91         &GetOrderUsers
  92         &ModOrderUsers
  93         &NotifyOrderUsers
  94
  95         &FillWithDefaultValues
  96
  97         &get_rounded_price
  98         &get_rounding_sql
  99     );
 100 }
 101
 102
 103
 104
 105
 106 sub GetOrderFromItemnumber {
 107     my ($itemnumber) = @_;
 108     my $dbh          = C4::Context->dbh;
 109     my $query        = qq|
 110
 111     SELECT  * from aqorders    LEFT JOIN aqorders_items
 112     ON (     aqorders.ordernumber = aqorders_items.ordernumber   )
 113     WHERE itemnumber = ?  |;
 114
 115     my $sth = $dbh->prepare($query);
 116
 117 #    $sth->trace(3);
 118
 119     $sth->execute($itemnumber);
 120
 121     my $order = $sth->fetchrow_hashref;
 122     return ( $order  );
 123
 124 }
 125
 126 =head1 NAME
 127
 128 C4::Acquisition - Koha functions for dealing with orders and acquisitions
 129
 130 =head1 SYNOPSIS
 131
 132 use C4::Acquisition;
 133
 134 =head1 DESCRIPTION
 135
 136 The functions in this module deal with acquisitions, managing book
 137 orders, basket and parcels.
 138
 139 =head1 FUNCTIONS
 140
 141 =head2 FUNCTIONS ABOUT BASKETS
 142
 143 =head3 GetBasket
 144
 145   $aqbasket = &GetBasket($basketnumber);
 146
 147 get all basket informations in aqbasket for a given basket
 148
 149 B<returns:> informations for a given basket returned as a hashref.
 150
 151 =cut
 152
 153 sub GetBasket {
 154     my ($basketno) = @_;
 155     my $dbh        = C4::Context->dbh;
 156     my $query = "
 157         SELECT  aqbasket.*,
 158                 concat( b.firstname,' ',b.surname) AS authorisedbyname
 159         FROM    aqbasket
 160         LEFT JOIN borrowers b ON aqbasket.authorisedby=b.borrowernumber
 161         WHERE basketno=?
 162     ";
 163     my $sth=$dbh->prepare($query);
 164     $sth->execute($basketno);
 165     my $basket = $sth->fetchrow_hashref;
 166     return ( $basket );
 167 }
 168
 169 #------------------------------------------------------------#
 170
 171 =head3 NewBasket
 172
 173   $basket = &NewBasket( $booksellerid, $authorizedby, $basketname,
 174       $basketnote, $basketbooksellernote, $basketcontractnumber, $deliveryplace, $billingplace, $is_standing, $create_items );
 175
 176 Create a new basket in aqbasket table
 177
 178 =over
 179
 180 =item C<$booksellerid> is a foreign key in the aqbasket table
 181
 182 =item C<$authorizedby> is the username of who created the basket
 183
 184 =back
 185
 186 The other parameters are optional, see ModBasketHeader for more info on them.
 187
 188 =cut
 189
 190 sub NewBasket {
 191     my ( $booksellerid, $authorisedby, $basketname, $basketnote,
 192         $basketbooksellernote, $basketcontractnumber, $deliveryplace,
 193         $billingplace, $is_standing, $create_items ) = @_;
 194     my $dbh = C4::Context->dbh;
 195     my $query =
 196         'INSERT INTO aqbasket (creationdate,booksellerid,authorisedby) '
 197       . 'VALUES  (now(),?,?)';
 198     $dbh->do( $query, {}, $booksellerid, $authorisedby );
 199
 200     my $basket = $dbh->{mysql_insertid};
 201     $basketname           ||= q{}; # default to empty strings
 202     $basketnote           ||= q{};
 203     $basketbooksellernote ||= q{};
 204     ModBasketHeader( $basket, $basketname, $basketnote, $basketbooksellernote,
 205         $basketcontractnumber, $booksellerid, $deliveryplace, $billingplace, $is_standing, $create_items );
 206     return $basket;
 207 }
 208
 209 #------------------------------------------------------------#
 210
 211 =head3 CloseBasket
 212
 213   &CloseBasket($basketno);
 214
 215 close a basket (becomes unmodifiable, except for receives)
 216
 217 =cut
 218
 219 sub CloseBasket {
 220     my ($basketno) = @_;
 221     my $dbh        = C4::Context->dbh;
 222     $dbh->do('UPDATE aqbasket SET closedate=now() WHERE basketno=?', {}, $basketno );
 223
 224     $dbh->do(
 225 q{UPDATE aqorders SET orderstatus = 'ordered' WHERE basketno = ? AND orderstatus NOT IN ( 'complete', 'cancelled')},
 226         {}, $basketno
 227     );
 228     return;
 229 }
 230
 231 =head3 ReopenBasket
 232
 233   &ReopenBasket($basketno);
 234
 235 reopen a basket
 236
 237 =cut
 238
 239 sub ReopenBasket {
 240     my ($basketno) = @_;
 241     my $dbh        = C4::Context->dbh;
 242     $dbh->do( q{UPDATE aqbasket SET closedate=NULL WHERE  basketno=?}, {}, $basketno );
 243
 244     $dbh->do( q{
 245         UPDATE aqorders
 246         SET orderstatus = 'new'
 247         WHERE basketno = ?
 248         AND orderstatus NOT IN ( 'complete', 'cancelled' )
 249         }, {}, $basketno);
 250     return;
 251 }
 252
 253 #------------------------------------------------------------#
 254
 255 =head3 GetBasketAsCSV
 256
 257   &GetBasketAsCSV($basketno);
 258
 259 Export a basket as CSV
 260
 261 $cgi parameter is needed for column name translation
 262
 263 =cut
 264
 265 sub GetBasketAsCSV {
 266     my ($basketno, $cgi, $csv_profile_id) = @_;
 267     my $basket = GetBasket($basketno);
 268     my @orders = GetOrders($basketno);
 269     my $contract = GetContract({
 270         contractnumber => $basket->{'contractnumber'}
 271     });
 272
 273     my $template = C4::Templates::gettemplate("acqui/csv/basket.tt", "intranet", $cgi);
 274     my @rows;
 275     if ($csv_profile_id) {
 276         my $csv_profile = Koha::CsvProfiles->find( $csv_profile_id );
 277         Koha::Exceptions::ObjectNotFound->throw( 'There is no valid csv profile given') unless $csv_profile;
 278
 279         my $csv = Text::CSV_XS->new({'quote_char'=>'"','escape_char'=>'"','sep_char'=>$csv_profile->csv_separator,'binary'=>1});
 280         my $csv_profile_content = $csv_profile->content;
 281         my ( @headers, @fields );
 282         while ( $csv_profile_content =~ /
 283             ([^=\|]+) # header
 284             =?
 285             ([^\|]*) # fieldname (table.row or row)
 286             \|? /gxms
 287         ) {
 288             my $header = $1;
 289             my $field = ($2 eq '') ? $1 : $2;
 290
 291             $header =~ s/^\s+|\s+$//g; # Trim whitespaces
 292             push @headers, $header;
 293
 294             $field =~ s/[^\.]*\.{1}//; # Remove the table name if exists.
 295             $field =~ s/^\s+|\s+$//g; # Trim whitespaces
 296             push @fields, $field;
 297         }
 298         for my $order (@orders) {
 299             my @row;
 300             my $biblio = Koha::Biblios->find( $order->{biblionumber} );
 301             my $biblioitem = $biblio->biblioitem;
 302             $order = { %$order, %{ $biblioitem->unblessed } };
 303             if ($contract) {
 304                 $order = {%$order, %$contract};
 305             }
 306             $order = {%$order, %$basket, %{ $biblio->unblessed }};
 307             for my $field (@fields) {
 308                 push @row, $order->{$field};
 309             }
 310             push @rows, \@row;
 311         }
 312         my $content = join( $csv_profile->csv_separator, @headers ) . "\n";
 313         for my $row ( @rows ) {
 314             $csv->combine(@$row);
 315             my $string = $csv->string;
 316             $content .= $string . "\n";
 317         }
 318         return $content;
 319     }
 320     else {
 321         foreach my $order (@orders) {
 322             my $biblio = Koha::Biblios->find( $order->{biblionumber} );
 323             my $biblioitem = $biblio->biblioitem;
 324             my $row = {
 325                 contractname => $contract->{'contractname'},
 326                 ordernumber => $order->{'ordernumber'},
 327                 entrydate => $order->{'entrydate'},
 328                 isbn => $order->{'isbn'},
 329                 author => $biblio->author,
 330                 title => $biblio->title,
 331                 publicationyear => $biblioitem->publicationyear,
 332                 publishercode => $biblioitem->publishercode,
 333                 collectiontitle => $biblioitem->collectiontitle,
 334                 notes => $order->{'order_vendornote'},
 335                 quantity => $order->{'quantity'},
 336                 rrp => $order->{'rrp'},
 337             };
 338             for my $place ( qw( deliveryplace billingplace ) ) {
 339                 if ( my $library = Koha::Libraries->find( $row->{deliveryplace} ) ) {
 340                     $row->{$place} = $library->branchname
 341                 }
 342             }
 343             foreach(qw(
 344                 contractname author title publishercode collectiontitle notes
 345                 deliveryplace billingplace
 346             ) ) {
 347                 # Double the quotes to not be interpreted as a field end
 348                 $row->{$_} =~ s/"/""/g if $row->{$_};
 349             }
 350             push @rows, $row;
 351          }
 352
 353         @rows = sort {
 354             if(defined $a->{publishercode} and defined $b->{publishercode}) {
 355                 $a->{publishercode} cmp $b->{publishercode};
 356             }
 357         } @rows;
 358
 359         $template->param(rows => \@rows);
 360
 361         return $template->output;
 362     }
 363 }
 364
 365
 366 =head3 GetBasketGroupAsCSV
 367
 368   &GetBasketGroupAsCSV($basketgroupid);
 369
 370 Export a basket group as CSV
 371
 372 $cgi parameter is needed for column name translation
 373
 374 =cut
 375
 376 sub GetBasketGroupAsCSV {
 377     my ($basketgroupid, $cgi) = @_;
 378     my $baskets = GetBasketsByBasketgroup($basketgroupid);
 379
 380     my $template = C4::Templates::gettemplate('acqui/csv/basketgroup.tt', 'intranet', $cgi);
 381
 382     my @rows;
 383     for my $basket (@$baskets) {
 384         my @orders     = GetOrders( $basket->{basketno} );
 385         my $contract   = GetContract({
 386             contractnumber => $basket->{contractnumber}
 387         });
 388         my $bookseller = Koha::Acquisition::Booksellers->find( $basket->{booksellerid} );
 389         my $basketgroup = GetBasketgroup( $$basket{basketgroupid} );
 390
 391         foreach my $order (@orders) {
 392             my $biblio = Koha::Biblios->find( $order->{biblionumber} );
 393             my $biblioitem = $biblio->biblioitem;
 394             my $row = {
 395                 clientnumber => $bookseller->accountnumber,
 396                 basketname => $basket->{basketname},
 397                 ordernumber => $order->{ordernumber},
 398                 author => $biblio->author,
 399                 title => $biblio->title,
 400                 publishercode => $biblioitem->publishercode,
 401                 publicationyear => $biblioitem->publicationyear,
 402                 collectiontitle => $biblioitem->collectiontitle,
 403                 isbn => $order->{isbn},
 404                 quantity => $order->{quantity},
 405                 rrp_tax_included => $order->{rrp_tax_included},
 406                 rrp_tax_excluded => $order->{rrp_tax_excluded},
 407                 discount => $bookseller->discount,
 408                 ecost_tax_included => $order->{ecost_tax_included},
 409                 ecost_tax_excluded => $order->{ecost_tax_excluded},
 410                 notes => $order->{order_vendornote},
 411                 entrydate => $order->{entrydate},
 412                 booksellername => $bookseller->name,
 413                 bookselleraddress => $bookseller->address1,
 414                 booksellerpostal => $bookseller->postal,
 415                 contractnumber => $contract->{contractnumber},
 416                 contractname => $contract->{contractname},
 417             };
 418             my $temp = {
 419                 basketgroupdeliveryplace => $basketgroup->{deliveryplace},
 420                 basketgroupbillingplace  => $basketgroup->{billingplace},
 421                 basketdeliveryplace      => $basket->{deliveryplace},
 422                 basketbillingplace       => $basket->{billingplace},
 423             };
 424             for my $place (qw( basketgroupdeliveryplace basketgroupbillingplace basketdeliveryplace basketbillingplace )) {
 425                 if ( my $library = Koha::Libraries->find( $temp->{$place} ) ) {
 426                     $row->{$place} = $library->branchname;
 427                 }
 428             }
 429             foreach(qw(
 430                 basketname author title publishercode collectiontitle notes
 431                 booksellername bookselleraddress booksellerpostal contractname
 432                 basketgroupdeliveryplace basketgroupbillingplace
 433                 basketdeliveryplace basketbillingplace
 434             ) ) {
 435                 # Double the quotes to not be interpreted as a field end
 436                 $row->{$_} =~ s/"/""/g if $row->{$_};
 437             }
 438             push @rows, $row;
 439          }
 440      }
 441     $template->param(rows => \@rows);
 442
 443     return $template->output;
 444
 445 }
 446
 447 =head3 CloseBasketgroup
 448
 449   &CloseBasketgroup($basketgroupno);
 450
 451 close a basketgroup
 452
 453 =cut
 454
 455 sub CloseBasketgroup {
 456     my ($basketgroupno) = @_;
 457     my $dbh        = C4::Context->dbh;
 458     my $sth = $dbh->prepare("
 459         UPDATE aqbasketgroups
 460         SET    closed=1
 461         WHERE  id=?
 462     ");
 463     $sth->execute($basketgroupno);
 464 }
 465
 466 #------------------------------------------------------------#
 467
 468 =head3 ReOpenBaskergroup($basketgroupno)
 469
 470   &ReOpenBaskergroup($basketgroupno);
 471
 472 reopen a basketgroup
 473
 474 =cut
 475
 476 sub ReOpenBasketgroup {
 477     my ($basketgroupno) = @_;
 478     my $dbh        = C4::Context->dbh;
 479     my $sth = $dbh->prepare("
 480         UPDATE aqbasketgroups
 481         SET    closed=0
 482         WHERE  id=?
 483     ");
 484     $sth->execute($basketgroupno);
 485 }
 486
 487 #------------------------------------------------------------#
 488
 489
 490 =head3 DelBasket
 491
 492   &DelBasket($basketno);
 493
 494 Deletes the basket that has basketno field $basketno in the aqbasket table.
 495
 496 =over
 497
 498 =item C<$basketno> is the primary key of the basket in the aqbasket table.
 499
 500 =back
 501
 502 =cut
 503
 504 sub DelBasket {
 505     my ( $basketno ) = @_;
 506     my $query = "DELETE FROM aqbasket WHERE basketno=?";
 507     my $dbh = C4::Context->dbh;
 508     my $sth = $dbh->prepare($query);
 509     $sth->execute($basketno);
 510     return;
 511 }
 512
 513 #------------------------------------------------------------#
 514
 515 =head3 ModBasket
 516
 517   &ModBasket($basketinfo);
 518
 519 Modifies a basket, using a hashref $basketinfo for the relevant information, only $basketinfo->{'basketno'} is required.
 520
 521 =over
 522
 523 =item C<$basketno> is the primary key of the basket in the aqbasket table.
 524
 525 =back
 526
 527 =cut
 528
 529 sub ModBasket {
 530     my $basketinfo = shift;
 531     my $query = "UPDATE aqbasket SET ";
 532     my @params;
 533     foreach my $key (keys %$basketinfo){
 534         if ($key ne 'basketno'){
 535             $query .= "$key=?, ";
 536             push(@params, $basketinfo->{$key} || undef );
 537         }
 538     }
 539 # get rid of the "," at the end of $query
 540     if (substr($query, length($query)-2) eq ', '){
 541         chop($query);
 542         chop($query);
 543         $query .= ' ';
 544     }
 545     $query .= "WHERE basketno=?";
 546     push(@params, $basketinfo->{'basketno'});
 547     my $dbh = C4::Context->dbh;
 548     my $sth = $dbh->prepare($query);
 549     $sth->execute(@params);
 550
 551     return;
 552 }
 553
 554 #------------------------------------------------------------#
 555
 556 =head3 ModBasketHeader
 557
 558   &ModBasketHeader($basketno, $basketname, $note, $booksellernote, $contractnumber, $booksellerid);
 559
 560 Modifies a basket's header.
 561
 562 =over
 563
 564 =item C<$basketno> is the "basketno" field in the "aqbasket" table;
 565
 566 =item C<$basketname> is the "basketname" field in the "aqbasket" table;
 567
 568 =item C<$note> is the "note" field in the "aqbasket" table;
 569
 570 =item C<$booksellernote> is the "booksellernote" field in the "aqbasket" table;
 571
 572 =item C<$contractnumber> is the "contractnumber" (foreign) key in the "aqbasket" table.
 573
 574 =item C<$booksellerid> is the id (foreign) key in the "aqbooksellers" table for the vendor.
 575
 576 =item C<$deliveryplace> is the "deliveryplace" field in the aqbasket table.
 577
 578 =item C<$billingplace> is the "billingplace" field in the aqbasket table.
 579
 580 =item C<$is_standing> is the "is_standing" field in the aqbasket table.
 581
 582 =item C<$create_items> should be set to 'ordering', 'receiving' or 'cataloguing' (or undef, in which
 583 case the AcqCreateItem syspref takes precedence).
 584
 585 =back
 586
 587 =cut
 588
 589 sub ModBasketHeader {
 590     my ($basketno, $basketname, $note, $booksellernote, $contractnumber, $booksellerid, $deliveryplace, $billingplace, $is_standing, $create_items) = @_;
 591
 592     $is_standing ||= 0;
 593     my $query = qq{
 594         UPDATE aqbasket
 595         SET basketname=?, note=?, booksellernote=?, booksellerid=?, deliveryplace=?, billingplace=?, is_standing=?, create_items=?
 596         WHERE basketno=?
 597     };
 598
 599     my $dbh = C4::Context->dbh;
 600     my $sth = $dbh->prepare($query);
 601     $sth->execute($basketname, $note, $booksellernote, $booksellerid, $deliveryplace, $billingplace, $is_standing, $create_items || undef, $basketno);
 602
 603     if ( $contractnumber ) {
 604         my $query2 ="UPDATE aqbasket SET contractnumber=? WHERE basketno=?";
 605         my $sth2 = $dbh->prepare($query2);
 606         $sth2->execute($contractnumber,$basketno);
 607     }
 608     return;
 609 }
 610
 611 #------------------------------------------------------------#
 612
 613 =head3 GetBasketsByBookseller
 614
 615   @results = &GetBasketsByBookseller($booksellerid, $extra);
 616
 617 Returns a list of hashes of all the baskets that belong to bookseller 'booksellerid'.
 618
 619 =over
 620
 621 =item C<$booksellerid> is the 'id' field of the bookseller in the aqbooksellers table
 622
 623 =item C<$extra> is the extra sql parameters, can be
 624
 625  $extra->{groupby}: group baskets by column
 626     ex. $extra->{groupby} = aqbasket.basketgroupid
 627  $extra->{orderby}: order baskets by column
 628  $extra->{limit}: limit number of results (can be helpful for pagination)
 629
 630 =back
 631
 632 =cut
 633
 634 sub GetBasketsByBookseller {
 635     my ($booksellerid, $extra) = @_;
 636     my $query = "SELECT * FROM aqbasket WHERE booksellerid=?";
 637     if ($extra){
 638         if ($extra->{groupby}) {
 639             $query .= " GROUP by $extra->{groupby}";
 640         }
 641         if ($extra->{orderby}){
 642             $query .= " ORDER by $extra->{orderby}";
 643         }
 644         if ($extra->{limit}){
 645             $query .= " LIMIT $extra->{limit}";
 646         }
 647     }
 648     my $dbh = C4::Context->dbh;
 649     my $sth = $dbh->prepare($query);
 650     $sth->execute($booksellerid);
 651     return $sth->fetchall_arrayref({});
 652 }
 653
 654 =head3 GetBasketsInfosByBookseller
 655
 656     my $baskets = GetBasketsInfosByBookseller($supplierid, $allbaskets);
 657
 658 The optional second parameter allbaskets is a boolean allowing you to
 659 select all baskets from the supplier; by default only active baskets (open or
 660 closed but still something to receive) are returned.
 661
 662 Returns in a arrayref of hashref all about booksellers baskets, plus:
 663     total_biblios: Number of distinct biblios in basket
 664     total_items: Number of items in basket
 665     expected_items: Number of non-received items in basket
 666
 667 =cut
 668
 669 sub GetBasketsInfosByBookseller {
 670     my ($supplierid, $allbaskets) = @_;
 671
 672     return unless $supplierid;
 673
 674     my $dbh = C4::Context->dbh;
 675     my $query = q{
 676         SELECT aqbasket.basketno, aqbasket.basketname, aqbasket.note, aqbasket.booksellernote, aqbasket.contractnumber, aqbasket.creationdate, aqbasket.closedate, aqbasket.booksellerid, aqbasket.authorisedby, aqbasket.booksellerinvoicenumber, aqbasket.basketgroupid, aqbasket.deliveryplace, aqbasket.billingplace, aqbasket.branch, aqbasket.is_standing, aqbasket.create_items,
 677           SUM(aqorders.quantity) AS total_items,
 678           SUM(
 679             IF ( aqorders.orderstatus = 'cancelled', aqorders.quantity, 0 )
 680           ) AS total_items_cancelled,
 681           COUNT(DISTINCT aqorders.biblionumber) AS total_biblios,
 682           SUM(
 683             IF(aqorders.datereceived IS NULL
 684               AND (aqorders.datecancellationprinted IS NULL OR aqorders.datecancellationprinted='0000-00-00')
 685             , aqorders.quantity
 686             , 0)
 687           ) AS expected_items,
 688         SUM( aqorders.uncertainprice ) AS uncertainprices
 689         FROM aqbasket
 690           LEFT JOIN aqorders ON aqorders.basketno = aqbasket.basketno
 691         WHERE booksellerid = ?};
 692
 693     $query.=" GROUP BY aqbasket.basketno, aqbasket.basketname, aqbasket.note, aqbasket.booksellernote, aqbasket.contractnumber, aqbasket.creationdate, aqbasket.closedate, aqbasket.booksellerid, aqbasket.authorisedby, aqbasket.booksellerinvoicenumber, aqbasket.basketgroupid, aqbasket.deliveryplace, aqbasket.billingplace, aqbasket.branch, aqbasket.is_standing, aqbasket.create_items";
 694
 695     unless ( $allbaskets ) {
 696         # Don't show the basket if it's NOT CLOSED or is FULLY RECEIVED
 697         $query.=" HAVING (closedate IS NULL OR (
 698           SUM(
 699             IF(aqorders.datereceived IS NULL
 700               AND (aqorders.datecancellationprinted IS NULL OR aqorders.datecancellationprinted='0000-00-00')
 701             , aqorders.quantity
 702             , 0)
 703             ) > 0))"
 704     }
 705
 706     my $sth = $dbh->prepare($query);
 707     $sth->execute($supplierid);
 708     my $baskets = $sth->fetchall_arrayref({});
 709
 710     # Retrieve the number of biblios cancelled
 711     my $cancelled_biblios = $dbh->selectall_hashref( q|
 712         SELECT COUNT(DISTINCT(biblionumber)) AS total_biblios_cancelled, aqbasket.basketno
 713         FROM aqbasket
 714         LEFT JOIN aqorders ON aqorders.basketno = aqbasket.basketno
 715         WHERE booksellerid = ?
 716         AND aqorders.orderstatus = 'cancelled'
 717         GROUP BY aqbasket.basketno
 718     |, 'basketno', {}, $supplierid );
 719     map {
 720         $_->{total_biblios_cancelled} = $cancelled_biblios->{$_->{basketno}}{total_biblios_cancelled} || 0
 721     } @$baskets;
 722
 723     return $baskets;
 724 }
 725
 726 =head3 GetBasketUsers
 727
 728     $basketusers_ids = &GetBasketUsers($basketno);
 729
 730 Returns a list of all borrowernumbers that are in basket users list
 731
 732 =cut
 733
 734 sub GetBasketUsers {
 735     my $basketno = shift;
 736
 737     return unless $basketno;
 738
 739     my $query = qq{
 740         SELECT borrowernumber
 741         FROM aqbasketusers
 742         WHERE basketno = ?
 743     };
 744     my $dbh = C4::Context->dbh;
 745     my $sth = $dbh->prepare($query);
 746     $sth->execute($basketno);
 747     my $results = $sth->fetchall_arrayref( {} );
 748
 749     my @borrowernumbers;
 750     foreach (@$results) {
 751         push @borrowernumbers, $_->{'borrowernumber'};
 752     }
 753
 754     return @borrowernumbers;
 755 }
 756
 757 =head3 ModBasketUsers
 758
 759     my @basketusers_ids = (1, 2, 3);
 760     &ModBasketUsers($basketno, @basketusers_ids);
 761
 762 Delete all users from basket users list, and add users in C<@basketusers_ids>
 763 to this users list.
 764
 765 =cut
 766
 767 sub ModBasketUsers {
 768     my ($basketno, @basketusers_ids) = @_;
 769
 770     return unless $basketno;
 771
 772     my $dbh = C4::Context->dbh;
 773     my $query = qq{
 774         DELETE FROM aqbasketusers
 775         WHERE basketno = ?
 776     };
 777     my $sth = $dbh->prepare($query);
 778     $sth->execute($basketno);
 779
 780     $query = qq{
 781         INSERT INTO aqbasketusers (basketno, borrowernumber)
 782         VALUES (?, ?)
 783     };
 784     $sth = $dbh->prepare($query);
 785     foreach my $basketuser_id (@basketusers_ids) {
 786         $sth->execute($basketno, $basketuser_id);
 787     }
 788     return;
 789 }
 790
 791 =head3 CanUserManageBasket
 792
 793     my $bool = CanUserManageBasket($borrower, $basket[, $userflags]);
 794     my $bool = CanUserManageBasket($borrowernumber, $basketno[, $userflags]);
 795
 796 Check if a borrower can manage a basket, according to system preference
 797 AcqViewBaskets, user permissions and basket properties (creator, users list,
 798 branch).
 799
 800 First parameter can be either a borrowernumber or a hashref as returned by
 801 Koha::Patron->unblessed
 802
 803 Second parameter can be either a basketno or a hashref as returned by
 804 C4::Acquisition::GetBasket.
 805
 806 The third parameter is optional. If given, it should be a hashref as returned
 807 by C4::Auth::getuserflags. If not, getuserflags is called.
 808
 809 If user is authorised to manage basket, returns 1.
 810 Otherwise returns 0.
 811
 812 =cut
 813
 814 sub CanUserManageBasket {
 815     my ($borrower, $basket, $userflags) = @_;
 816
 817     if (!ref $borrower) {
 818         # FIXME This needs to be replaced
 819         # We should not accept both scalar and array
 820         # Tests need to be updated
 821         $borrower = Koha::Patrons->find( $borrower )->unblessed;
 822     }
 823     if (!ref $basket) {
 824         $basket = GetBasket($basket);
 825     }
 826
 827     return 0 unless ($basket and $borrower);
 828
 829     my $borrowernumber = $borrower->{borrowernumber};
 830     my $basketno = $basket->{basketno};
 831
 832     my $AcqViewBaskets = C4::Context->preference('AcqViewBaskets');
 833
 834     if (!defined $userflags) {
 835         my $dbh = C4::Context->dbh;
 836         my $sth = $dbh->prepare("SELECT flags FROM borrowers WHERE borrowernumber = ?");
 837         $sth->execute($borrowernumber);
 838         my ($flags) = $sth->fetchrow_array;
 839         $sth->finish;
 840
 841         $userflags = C4::Auth::getuserflags($flags, $borrower->{userid}, $dbh);
 842     }
 843
 844     unless ($userflags->{superlibrarian}
 845     || (ref $userflags->{acquisition} && $userflags->{acquisition}->{order_manage_all})
 846     || (!ref $userflags->{acquisition} && $userflags->{acquisition}))
 847     {
 848         if (not exists $userflags->{acquisition}) {
 849             return 0;
 850         }
 851
 852         if ( (ref $userflags->{acquisition} && !$userflags->{acquisition}->{order_manage})
 853         || (!ref $userflags->{acquisition} && !$userflags->{acquisition}) ) {
 854             return 0;
 855         }
 856
 857         if ($AcqViewBaskets eq 'user'
 858         && $basket->{authorisedby} != $borrowernumber
 859         && ! grep { $borrowernumber eq $_ } GetBasketUsers($basketno)) {
 860              return 0;
 861         }
 862
 863         if ($AcqViewBaskets eq 'branch' && defined $basket->{branch}
 864         && $basket->{branch} ne $borrower->{branchcode}) {
 865             return 0;
 866         }
 867     }
 868
 869     return 1;
 870 }
 871
 872 #------------------------------------------------------------#
 873
 874 =head3 GetBasketsByBasketgroup
 875
 876   $baskets = &GetBasketsByBasketgroup($basketgroupid);
 877
 878 Returns a reference to all baskets that belong to basketgroup $basketgroupid.
 879
 880 =cut
 881
 882 sub GetBasketsByBasketgroup {
 883     my $basketgroupid = shift;
 884     my $query = qq{
 885         SELECT *, aqbasket.booksellerid as booksellerid
 886         FROM aqbasket
 887         LEFT JOIN aqcontract USING(contractnumber) WHERE basketgroupid=?
 888     };
 889     my $dbh = C4::Context->dbh;
 890     my $sth = $dbh->prepare($query);
 891     $sth->execute($basketgroupid);
 892     return $sth->fetchall_arrayref({});
 893 }
 894
 895 #------------------------------------------------------------#
 896
 897 =head3 NewBasketgroup
 898
 899   $basketgroupid = NewBasketgroup(\%hashref);
 900
 901 Adds a basketgroup to the aqbasketgroups table, and add the initial baskets to it.
 902
 903 $hashref->{'booksellerid'} is the 'id' field of the bookseller in the aqbooksellers table,
 904
 905 $hashref->{'name'} is the 'name' field of the basketgroup in the aqbasketgroups table,
 906
 907 $hashref->{'basketlist'} is a list reference of the 'id's of the baskets that belong to this group,
 908
 909 $hashref->{'billingplace'} is the 'billingplace' field of the basketgroup in the aqbasketgroups table,
 910
 911 $hashref->{'deliveryplace'} is the 'deliveryplace' field of the basketgroup in the aqbasketgroups table,
 912
 913 $hashref->{'freedeliveryplace'} is the 'freedeliveryplace' field of the basketgroup in the aqbasketgroups table,
 914
 915 $hashref->{'deliverycomment'} is the 'deliverycomment' field of the basketgroup in the aqbasketgroups table,
 916
 917 $hashref->{'closed'} is the 'closed' field of the aqbasketgroups table, it is false if 0, true otherwise.
 918
 919 =cut
 920
 921 sub NewBasketgroup {
 922     my $basketgroupinfo = shift;
 923     die "booksellerid is required to create a basketgroup" unless $basketgroupinfo->{'booksellerid'};
 924     my $query = "INSERT INTO aqbasketgroups (";
 925     my @params;
 926     foreach my $field (qw(name billingplace deliveryplace freedeliveryplace deliverycomment closed)) {
 927         if ( defined $basketgroupinfo->{$field} ) {
 928             $query .= "$field, ";
 929             push(@params, $basketgroupinfo->{$field});
 930         }
 931     }
 932     $query .= "booksellerid) VALUES (";
 933     foreach (@params) {
 934         $query .= "?, ";
 935     }
 936     $query .= "?)";
 937     push(@params, $basketgroupinfo->{'booksellerid'});
 938     my $dbh = C4::Context->dbh;
 939     my $sth = $dbh->prepare($query);
 940     $sth->execute(@params);
 941     my $basketgroupid = $dbh->{'mysql_insertid'};
 942     if( $basketgroupinfo->{'basketlist'} ) {
 943         foreach my $basketno (@{$basketgroupinfo->{'basketlist'}}) {
 944             my $query2 = "UPDATE aqbasket SET basketgroupid=? WHERE basketno=?";
 945             my $sth2 = $dbh->prepare($query2);
 946             $sth2->execute($basketgroupid, $basketno);
 947         }
 948     }
 949     return $basketgroupid;
 950 }
 951
 952 #------------------------------------------------------------#
 953
 954 =head3 ModBasketgroup
 955
 956   ModBasketgroup(\%hashref);
 957
 958 Modifies a basketgroup in the aqbasketgroups table, and add the baskets to it.
 959
 960 $hashref->{'id'} is the 'id' field of the basketgroup in the aqbasketgroup table, this parameter is mandatory,
 961
 962 $hashref->{'name'} is the 'name' field of the basketgroup in the aqbasketgroups table,
 963
 964 $hashref->{'basketlist'} is a list reference of the 'id's of the baskets that belong to this group,
 965
 966 $hashref->{'billingplace'} is the 'billingplace' field of the basketgroup in the aqbasketgroups table,
 967
 968 $hashref->{'deliveryplace'} is the 'deliveryplace' field of the basketgroup in the aqbasketgroups table,
 969
 970 $hashref->{'freedeliveryplace'} is the 'freedeliveryplace' field of the basketgroup in the aqbasketgroups table,
 971
 972 $hashref->{'deliverycomment'} is the 'deliverycomment' field of the basketgroup in the aqbasketgroups table,
 973
 974 $hashref->{'closed'} is the 'closed' field of the aqbasketgroups table, it is false if 0, true otherwise.
 975
 976 =cut
 977
 978 sub ModBasketgroup {
 979     my $basketgroupinfo = shift;
 980     die "basketgroup id is required to edit a basketgroup" unless $basketgroupinfo->{'id'};
 981     my $dbh = C4::Context->dbh;
 982     my $query = "UPDATE aqbasketgroups SET ";
 983     my @params;
 984     foreach my $field (qw(name billingplace deliveryplace freedeliveryplace deliverycomment closed)) {
 985         if ( defined $basketgroupinfo->{$field} ) {
 986             $query .= "$field=?, ";
 987             push(@params, $basketgroupinfo->{$field});
 988         }
 989     }
 990     chop($query);
 991     chop($query);
 992     $query .= " WHERE id=?";
 993     push(@params, $basketgroupinfo->{'id'});
 994     my $sth = $dbh->prepare($query);
 995     $sth->execute(@params);
 996
 997     $sth = $dbh->prepare('UPDATE aqbasket SET basketgroupid = NULL WHERE basketgroupid = ?');
 998     $sth->execute($basketgroupinfo->{'id'});
 999
1000     if($basketgroupinfo->{'basketlist'} && @{$basketgroupinfo->{'basketlist'}}){
1001         $sth = $dbh->prepare("UPDATE aqbasket SET basketgroupid=? WHERE basketno=?");
1002         foreach my $basketno (@{$basketgroupinfo->{'basketlist'}}) {
1003             $sth->execute($basketgroupinfo->{'id'}, $basketno);
1004         }
1005     }
1006     return;
1007 }
1008
1009 #------------------------------------------------------------#
1010
1011 =head3 DelBasketgroup
1012
1013   DelBasketgroup($basketgroupid);
1014
1015 Deletes a basketgroup in the aqbasketgroups table, and removes the reference to it from the baskets,
1016
1017 =over
1018
1019 =item C<$basketgroupid> is the 'id' field of the basket in the aqbasketgroup table
1020
1021 =back
1022
1023 =cut
1024
1025 sub DelBasketgroup {
1026     my $basketgroupid = shift;
1027     die "basketgroup id is required to edit a basketgroup" unless $basketgroupid;
1028     my $query = "DELETE FROM aqbasketgroups WHERE id=?";
1029     my $dbh = C4::Context->dbh;
1030     my $sth = $dbh->prepare($query);
1031     $sth->execute($basketgroupid);
1032     return;
1033 }
1034
1035 #------------------------------------------------------------#
1036
1037
1038 =head2 FUNCTIONS ABOUT ORDERS
1039
1040 =head3 GetBasketgroup
1041
1042   $basketgroup = &GetBasketgroup($basketgroupid);
1043
1044 Returns a reference to the hash containing all information about the basketgroup.
1045
1046 =cut
1047
1048 sub GetBasketgroup {
1049     my $basketgroupid = shift;
1050     die "basketgroup id is required to edit a basketgroup" unless $basketgroupid;
1051     my $dbh = C4::Context->dbh;
1052     my $result_set = $dbh->selectall_arrayref(
1053         'SELECT * FROM aqbasketgroups WHERE id=?',
1054         { Slice => {} },
1055         $basketgroupid
1056     );
1057     return $result_set->[0];    # id is unique
1058 }
1059
1060 #------------------------------------------------------------#
1061
1062 =head3 GetBasketgroups
1063
1064   $basketgroups = &GetBasketgroups($booksellerid);
1065
1066 Returns a reference to the array of all the basketgroups of bookseller $booksellerid.
1067
1068 =cut
1069
1070 sub GetBasketgroups {
1071     my $booksellerid = shift;
1072     die 'bookseller id is required to edit a basketgroup' unless $booksellerid;
1073     my $query = 'SELECT * FROM aqbasketgroups WHERE booksellerid=? ORDER BY id DESC';
1074     my $dbh = C4::Context->dbh;
1075     my $sth = $dbh->prepare($query);
1076     $sth->execute($booksellerid);
1077     return $sth->fetchall_arrayref({});
1078 }
1079
1080 #------------------------------------------------------------#
1081
1082 =head2 FUNCTIONS ABOUT ORDERS
1083
1084 =head3 GetOrders
1085
1086   @orders = &GetOrders( $basketno, { orderby => 'biblio.title', cancelled => 0|1 } );
1087
1088 Looks up the pending (non-cancelled) orders with the given basket
1089 number.
1090
1091 If cancelled is set, only cancelled orders will be returned.
1092
1093 =cut
1094
1095 sub GetOrders {
1096     my ( $basketno, $params ) = @_;
1097
1098     return () unless $basketno;
1099
1100     my $orderby = $params->{orderby};
1101     my $cancelled = $params->{cancelled} || 0;
1102
1103     my $dbh   = C4::Context->dbh;
1104     my $query = q|
1105         SELECT biblio.*,biblioitems.*,
1106                 aqorders.*,
1107                 aqbudgets.*,
1108         |;
1109     $query .= $cancelled
1110       ? q|
1111                 aqorders_transfers.ordernumber_to AS transferred_to,
1112                 aqorders_transfers.timestamp AS transferred_to_timestamp
1113     |
1114       : q|
1115                 aqorders_transfers.ordernumber_from AS transferred_from,
1116                 aqorders_transfers.timestamp AS transferred_from_timestamp
1117     |;
1118     $query .= q|
1119         FROM    aqorders
1120             LEFT JOIN aqbudgets        ON aqbudgets.budget_id = aqorders.budget_id
1121             LEFT JOIN biblio           ON biblio.biblionumber = aqorders.biblionumber
1122             LEFT JOIN biblioitems      ON biblioitems.biblionumber =biblio.biblionumber
1123     |;
1124     $query .= $cancelled
1125       ? q|
1126             LEFT JOIN aqorders_transfers ON aqorders_transfers.ordernumber_from = aqorders.ordernumber
1127     |
1128       : q|
1129             LEFT JOIN aqorders_transfers ON aqorders_transfers.ordernumber_to = aqorders.ordernumber
1130
1131     |;
1132     $query .= q|
1133         WHERE   basketno=?
1134     |;
1135
1136     if ($cancelled) {
1137         $orderby ||= q|biblioitems.publishercode, biblio.title|;
1138         $query .= q|
1139             AND (datecancellationprinted IS NOT NULL
1140                AND datecancellationprinted <> '0000-00-00')
1141         |;
1142     }
1143     else {
1144         $orderby ||=
1145           q|aqorders.datecancellationprinted desc, aqorders.timestamp desc|;
1146         $query .= q|
1147             AND (datecancellationprinted IS NULL OR datecancellationprinted='0000-00-00')
1148         |;
1149     }
1150
1151     $query .= " ORDER BY $orderby";
1152     my $orders =
1153       $dbh->selectall_arrayref( $query, { Slice => {} }, $basketno );
1154     return @{$orders};
1155
1156 }
1157
1158 #------------------------------------------------------------#
1159
1160 =head3 GetOrdersByBiblionumber
1161
1162   @orders = &GetOrdersByBiblionumber($biblionumber);
1163
1164 Looks up the orders with linked to a specific $biblionumber, including
1165 cancelled orders and received orders.
1166
1167 return :
1168 C<@orders> is an array of references-to-hash, whose keys are the
1169 fields from the aqorders, biblio, and biblioitems tables in the Koha database.
1170
1171 =cut
1172
1173 sub GetOrdersByBiblionumber {
1174     my $biblionumber = shift;
1175     return unless $biblionumber;
1176     my $dbh   = C4::Context->dbh;
1177     my $query  ="
1178         SELECT biblio.*,biblioitems.*,
1179                 aqorders.*,
1180                 aqbudgets.*
1181         FROM    aqorders
1182             LEFT JOIN aqbudgets        ON aqbudgets.budget_id = aqorders.budget_id
1183             LEFT JOIN biblio           ON biblio.biblionumber = aqorders.biblionumber
1184             LEFT JOIN biblioitems      ON biblioitems.biblionumber =biblio.biblionumber
1185         WHERE   aqorders.biblionumber=?
1186     ";
1187     my $result_set =
1188       $dbh->selectall_arrayref( $query, { Slice => {} }, $biblionumber );
1189     return @{$result_set};
1190
1191 }
1192
1193 #------------------------------------------------------------#
1194
1195 =head3 GetOrder
1196
1197   $order = &GetOrder($ordernumber);
1198
1199 Looks up an order by order number.
1200
1201 Returns a reference-to-hash describing the order. The keys of
1202 C<$order> are fields from the biblio, biblioitems, aqorders tables of the Koha database.
1203
1204 =cut
1205
1206 sub GetOrder {
1207     my ($ordernumber) = @_;
1208     return unless $ordernumber;
1209
1210     my $dbh      = C4::Context->dbh;
1211     my $query = qq{SELECT
1212                 aqorders.*,
1213                 biblio.title,
1214                 biblio.author,
1215                 aqbasket.basketname,
1216                 borrowers.branchcode,
1217                 biblioitems.publicationyear,
1218                 biblio.copyrightdate,
1219                 biblioitems.editionstatement,
1220                 biblioitems.isbn,
1221                 biblioitems.ean,
1222                 biblio.seriestitle,
1223                 biblioitems.publishercode,
1224                 aqorders.rrp              AS unitpricesupplier,
1225                 aqorders.ecost            AS unitpricelib,
1226                 aqorders.claims_count     AS claims_count,
1227                 aqorders.claimed_date     AS claimed_date,
1228                 aqbudgets.budget_name     AS budget,
1229                 aqbooksellers.name        AS supplier,
1230                 aqbooksellers.id          AS supplierid,
1231                 biblioitems.publishercode AS publisher,
1232                 ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) AS estimateddeliverydate,
1233                 DATE(aqbasket.closedate)  AS orderdate,
1234                 aqorders.quantity - COALESCE(aqorders.quantityreceived,0)                 AS quantity_to_receive,
1235                 (aqorders.quantity - COALESCE(aqorders.quantityreceived,0)) * aqorders.rrp AS subtotal,
1236                 DATEDIFF(CURDATE( ),closedate) AS latesince
1237                 FROM aqorders LEFT JOIN biblio ON biblio.biblionumber = aqorders.biblionumber
1238                 LEFT JOIN biblioitems ON biblioitems.biblionumber = biblio.biblionumber
1239                 LEFT JOIN aqbudgets ON aqorders.budget_id = aqbudgets.budget_id,
1240                 aqbasket LEFT JOIN borrowers  ON aqbasket.authorisedby = borrowers.borrowernumber
1241                 LEFT JOIN aqbooksellers       ON aqbasket.booksellerid = aqbooksellers.id
1242                 WHERE aqorders.basketno = aqbasket.basketno
1243                     AND ordernumber=?};
1244     my $result_set =
1245       $dbh->selectall_arrayref( $query, { Slice => {} }, $ordernumber );
1246
1247     # result_set assumed to contain 1 match
1248     return $result_set->[0];
1249 }
1250
1251 =head3 GetLastOrderNotReceivedFromSubscriptionid
1252
1253   $order = &GetLastOrderNotReceivedFromSubscriptionid($subscriptionid);
1254
1255 Returns a reference-to-hash describing the last order not received for a subscription.
1256
1257 =cut
1258
1259 sub GetLastOrderNotReceivedFromSubscriptionid {
1260     my ( $subscriptionid ) = @_;
1261     my $dbh                = C4::Context->dbh;
1262     my $query              = qq|
1263         SELECT * FROM aqorders
1264         LEFT JOIN subscription
1265             ON ( aqorders.subscriptionid = subscription.subscriptionid )
1266         WHERE aqorders.subscriptionid = ?
1267             AND aqorders.datereceived IS NULL
1268         LIMIT 1
1269     |;
1270     my $result_set =
1271       $dbh->selectall_arrayref( $query, { Slice => {} }, $subscriptionid );
1272
1273     # result_set assumed to contain 1 match
1274     return $result_set->[0];
1275 }
1276
1277 =head3 GetLastOrderReceivedFromSubscriptionid
1278
1279   $order = &GetLastOrderReceivedFromSubscriptionid($subscriptionid);
1280
1281 Returns a reference-to-hash describing the last order received for a subscription.
1282
1283 =cut
1284
1285 sub GetLastOrderReceivedFromSubscriptionid {
1286     my ( $subscriptionid ) = @_;
1287     my $dbh                = C4::Context->dbh;
1288     my $query              = qq|
1289         SELECT * FROM aqorders
1290         LEFT JOIN subscription
1291             ON ( aqorders.subscriptionid = subscription.subscriptionid )
1292         WHERE aqorders.subscriptionid = ?
1293             AND aqorders.datereceived =
1294                 (
1295                     SELECT MAX( aqorders.datereceived )
1296                     FROM aqorders
1297                     LEFT JOIN subscription
1298                         ON ( aqorders.subscriptionid = subscription.subscriptionid )
1299                         WHERE aqorders.subscriptionid = ?
1300                             AND aqorders.datereceived IS NOT NULL
1301                 )
1302         ORDER BY ordernumber DESC
1303         LIMIT 1
1304     |;
1305     my $result_set =
1306       $dbh->selectall_arrayref( $query, { Slice => {} }, $subscriptionid, $subscriptionid );
1307
1308     # result_set assumed to contain 1 match
1309     return $result_set->[0];
1310
1311 }
1312
1313 #------------------------------------------------------------#
1314
1315 =head3 ModOrder
1316
1317   &ModOrder(\%hashref);
1318
1319 Modifies an existing order. Updates the order with order number
1320 $hashref->{'ordernumber'} and biblionumber $hashref->{'biblionumber'}. All
1321 other keys of the hash update the fields with the same name in the aqorders
1322 table of the Koha database.
1323
1324 =cut
1325
1326 sub ModOrder {
1327     my $orderinfo = shift;
1328
1329     die "Ordernumber is required" if $orderinfo->{'ordernumber'} eq '';
1330
1331     my $dbh = C4::Context->dbh;
1332     my @params;
1333
1334     # update uncertainprice to an integer, just in case (under FF, checked boxes have the value "ON" by default)
1335     $orderinfo->{uncertainprice}=1 if $orderinfo->{uncertainprice};
1336
1337 #    delete($orderinfo->{'branchcode'});
1338     # the hash contains a lot of entries not in aqorders, so get the columns ...
1339     my $sth = $dbh->prepare("SELECT * FROM aqorders LIMIT 1;");
1340     $sth->execute;
1341     my $colnames = $sth->{NAME};
1342         #FIXME Be careful. If aqorders would have columns with diacritics,
1343         #you should need to decode what you get back from NAME.
1344         #See report 10110 and guided_reports.pl
1345     my $query = "UPDATE aqorders SET ";
1346
1347     foreach my $orderinfokey (grep(!/ordernumber/, keys %$orderinfo)){
1348         # ... and skip hash entries that are not in the aqorders table
1349         # FIXME : probably not the best way to do it (would be better to have a correct hash)
1350         next unless grep(/^$orderinfokey$/, @$colnames);
1351             $query .= "$orderinfokey=?, ";
1352             push(@params, $orderinfo->{$orderinfokey});
1353     }
1354
1355     $query .= "timestamp=NOW()  WHERE  ordernumber=?";
1356     push(@params, $orderinfo->{'ordernumber'} );
1357     $sth = $dbh->prepare($query);
1358     $sth->execute(@params);
1359     return;
1360 }
1361
1362 #------------------------------------------------------------#
1363
1364 =head3 ModItemOrder
1365
1366     ModItemOrder($itemnumber, $ordernumber);
1367
1368 Modifies the ordernumber of an item in aqorders_items.
1369
1370 =cut
1371
1372 sub ModItemOrder {
1373     my ($itemnumber, $ordernumber) = @_;
1374
1375     return unless ($itemnumber and $ordernumber);
1376
1377     my $dbh = C4::Context->dbh;
1378     my $query = qq{
1379         UPDATE aqorders_items
1380         SET ordernumber = ?
1381         WHERE itemnumber = ?
1382     };
1383     my $sth = $dbh->prepare($query);
1384     return $sth->execute($ordernumber, $itemnumber);
1385 }
1386
1387 #------------------------------------------------------------#
1388
1389 =head3 ModReceiveOrder
1390
1391     my ( $date_received, $new_ordernumber ) = ModReceiveOrder(
1392         {
1393             biblionumber         => $biblionumber,
1394             order                => $order,
1395             quantityreceived     => $quantityreceived,
1396             user                 => $user,
1397             invoice              => $invoice,
1398             budget_id            => $budget_id,
1399             datereceived         => $datereceived,
1400             received_itemnumbers => \@received_itemnumbers,
1401         }
1402     );
1403
1404 Updates an order, to reflect the fact that it was received, at least
1405 in part.
1406
1407 If a partial order is received, splits the order into two.
1408
1409 Updates the order with biblionumber C<$biblionumber> and ordernumber
1410 C<$order->{ordernumber}>.
1411
1412 =cut
1413
1414
1415 sub ModReceiveOrder {
1416     my ($params)       = @_;
1417     my $biblionumber   = $params->{biblionumber};
1418     my $order          = { %{ $params->{order} } }; # Copy the order, we don't want to modify it
1419     my $invoice        = $params->{invoice};
1420     my $quantrec       = $params->{quantityreceived};
1421     my $user           = $params->{user};
1422     my $budget_id      = $params->{budget_id};
1423     my $datereceived   = $params->{datereceived};
1424     my $received_items = $params->{received_items};
1425
1426     my $dbh = C4::Context->dbh;
1427     $datereceived = output_pref(
1428         {
1429             dt => ( $datereceived ? dt_from_string( $datereceived ) : dt_from_string ),
1430             dateformat => 'iso',
1431             dateonly => 1,
1432         }
1433     );
1434
1435     my $suggestionid = GetSuggestionFromBiblionumber( $biblionumber );
1436     if ($suggestionid) {
1437         ModSuggestion( {suggestionid=>$suggestionid,
1438                         STATUS=>'AVAILABLE',
1439                         biblionumber=> $biblionumber}
1440                         );
1441     }
1442
1443     my $result_set = $dbh->selectrow_arrayref(
1444             q{SELECT aqbasket.is_standing
1445             FROM aqbasket
1446             WHERE basketno=?},{ Slice => {} }, $order->{basketno});
1447     my $is_standing = $result_set->[0];  # we assume we have a unique basket
1448
1449     my $new_ordernumber = $order->{ordernumber};
1450     if ( $is_standing || $order->{quantity} > $quantrec ) {
1451         # Split order line in two parts: the first is the original order line
1452         # without received items (the quantity is decreased),
1453         # the second part is a new order line with quantity=quantityrec
1454         # (entirely received)
1455         my $query = q|
1456             UPDATE aqorders
1457             SET quantity = ?,
1458                 orderstatus = 'partial'|;
1459         $query .= q| WHERE ordernumber = ?|;
1460         my $sth = $dbh->prepare($query);
1461
1462         $sth->execute(
1463             ( $is_standing ? 1 : ($order->{quantity} - $quantrec) ),
1464             $order->{ordernumber}
1465         );
1466
1467         if ( not $order->{subscriptionid} && defined $order->{order_internalnote} ) {
1468             $dbh->do(
1469                 q|UPDATE aqorders
1470                 SET order_internalnote = ?
1471                 WHERE ordernumber = ?|, {},
1472                 $order->{order_internalnote}, $order->{ordernumber}
1473             );
1474         }
1475
1476         # Recalculate tax_value
1477         $dbh->do(q|
1478             UPDATE aqorders
1479             SET
1480                 tax_value_on_ordering = quantity * | . get_rounding_sql(q|ecost_tax_excluded|) . q| * tax_rate_on_ordering,
1481                 tax_value_on_receiving = quantity * | . get_rounding_sql(q|unitprice_tax_excluded|) . q| * tax_rate_on_receiving
1482             WHERE ordernumber = ?
1483         |, undef, $order->{ordernumber});
1484
1485         delete $order->{ordernumber};
1486         $order->{budget_id} = ( $budget_id || $order->{budget_id} );
1487         $order->{quantity} = $quantrec;
1488         $order->{quantityreceived} = $quantrec;
1489         $order->{ecost_tax_excluded} //= 0;
1490         $order->{tax_rate_on_ordering} //= 0;
1491         $order->{unitprice_tax_excluded} //= 0;
1492         $order->{tax_rate_on_receiving} //= 0;
1493         $order->{tax_value_on_ordering} = $order->{quantity} * get_rounded_price($order->{ecost_tax_excluded}) * $order->{tax_rate_on_ordering};
1494         $order->{tax_value_on_receiving} = $order->{quantity} * get_rounded_price($order->{unitprice_tax_excluded}) * $order->{tax_rate_on_receiving};
1495         $order->{datereceived} = $datereceived;
1496         $order->{invoiceid} = $invoice->{invoiceid};
1497         $order->{orderstatus} = 'complete';
1498         $new_ordernumber = Koha::Acquisition::Order->new($order)->store->ordernumber; # TODO What if the store fails?
1499
1500         if ($received_items) {
1501             foreach my $itemnumber (@$received_items) {
1502                 ModItemOrder($itemnumber, $new_ordernumber);
1503             }
1504         }
1505     } else {
1506         my $query = q|
1507             UPDATE aqorders
1508             SET quantityreceived = ?,
1509                 datereceived = ?,
1510                 invoiceid = ?,
1511                 budget_id = ?,
1512                 orderstatus = 'complete'
1513         |;
1514
1515         $query .= q|
1516             , replacementprice = ?
1517         | if defined $order->{replacementprice};
1518
1519         $query .= q|
1520             , unitprice = ?, unitprice_tax_included = ?, unitprice_tax_excluded = ?
1521         | if defined $order->{unitprice};
1522
1523         $query .= q|
1524             ,tax_value_on_receiving = ?
1525         | if defined $order->{tax_value_on_receiving};
1526
1527         $query .= q|
1528             ,tax_rate_on_receiving = ?
1529         | if defined $order->{tax_rate_on_receiving};
1530
1531         $query .= q|
1532             , order_internalnote = ?
1533         | if defined $order->{order_internalnote};
1534
1535         $query .= q| where biblionumber=? and ordernumber=?|;
1536
1537         my $sth = $dbh->prepare( $query );
1538         my @params = ( $quantrec, $datereceived, $invoice->{invoiceid}, ( $budget_id ? $budget_id : $order->{budget_id} ) );
1539
1540         if ( defined $order->{replacementprice} ) {
1541             push @params, $order->{replacementprice};
1542         }
1543
1544         if ( defined $order->{unitprice} ) {
1545             push @params, $order->{unitprice}, $order->{unitprice_tax_included}, $order->{unitprice_tax_excluded};
1546         }
1547
1548         if ( defined $order->{tax_value_on_receiving} ) {
1549             push @params, $order->{tax_value_on_receiving};
1550         }
1551
1552         if ( defined $order->{tax_rate_on_receiving} ) {
1553             push @params, $order->{tax_rate_on_receiving};
1554         }
1555
1556         if ( defined $order->{order_internalnote} ) {
1557             push @params, $order->{order_internalnote};
1558         }
1559
1560         push @params, ( $biblionumber, $order->{ordernumber} );
1561
1562         $sth->execute( @params );
1563
1564         # All items have been received, sent a notification to users
1565         NotifyOrderUsers( $order->{ordernumber} );
1566
1567     }
1568     return ($datereceived, $new_ordernumber);
1569 }
1570
1571 =head3 CancelReceipt
1572
1573     my $parent_ordernumber = CancelReceipt($ordernumber);
1574
1575     Cancel an order line receipt and update the parent order line, as if no
1576     receipt was made.
1577     If items are created at receipt (AcqCreateItem = receiving) then delete
1578     these items.
1579
1580 =cut
1581
1582 sub CancelReceipt {
1583     my $ordernumber = shift;
1584
1585     return unless $ordernumber;
1586
1587     my $dbh = C4::Context->dbh;
1588     my $query = qq{
1589         SELECT datereceived, parent_ordernumber, quantity
1590         FROM aqorders
1591         WHERE ordernumber = ?
1592     };
1593     my $sth = $dbh->prepare($query);
1594     $sth->execute($ordernumber);
1595     my $order = $sth->fetchrow_hashref;
1596     unless($order) {
1597         warn "CancelReceipt: order $ordernumber does not exist";
1598         return;
1599     }
1600     unless($order->{'datereceived'}) {
1601         warn "CancelReceipt: order $ordernumber is not received";
1602         return;
1603     }
1604
1605     my $parent_ordernumber = $order->{'parent_ordernumber'};
1606
1607     my $order_obj = Koha::Acquisition::Orders->find( $ordernumber ); # FIXME rewrite all this subroutine using this object
1608     my @itemnumbers = $order_obj->items->get_column('itemnumber');
1609
1610     if($parent_ordernumber == $ordernumber || not $parent_ordernumber) {
1611         # The order line has no parent, just mark it as not received
1612         $query = qq{
1613             UPDATE aqorders
1614             SET quantityreceived = ?,
1615                 datereceived = ?,
1616                 invoiceid = ?,
1617                 orderstatus = 'ordered'
1618             WHERE ordernumber = ?
1619         };
1620         $sth = $dbh->prepare($query);
1621         $sth->execute(0, undef, undef, $ordernumber);
1622         _cancel_items_receipt( $order_obj );
1623     } else {
1624         # The order line has a parent, increase parent quantity and delete
1625         # the order line.
1626         $query = qq{
1627             SELECT quantity, datereceived
1628             FROM aqorders
1629             WHERE ordernumber = ?
1630         };
1631         $sth = $dbh->prepare($query);
1632         $sth->execute($parent_ordernumber);
1633         my $parent_order = $sth->fetchrow_hashref;
1634         unless($parent_order) {
1635             warn "Parent order $parent_ordernumber does not exist.";
1636             return;
1637         }
1638         if($parent_order->{'datereceived'}) {
1639             warn "CancelReceipt: parent order is received.".
1640                 " Can't cancel receipt.";
1641             return;
1642         }
1643         $query = qq{
1644             UPDATE aqorders
1645             SET quantity = ?,
1646                 orderstatus = 'ordered'
1647             WHERE ordernumber = ?
1648         };
1649         $sth = $dbh->prepare($query);
1650         my $rv = $sth->execute(
1651             $order->{'quantity'} + $parent_order->{'quantity'},
1652             $parent_ordernumber
1653         );
1654         unless($rv) {
1655             warn "Cannot update parent order line, so do not cancel".
1656                 " receipt";
1657             return;
1658         }
1659
1660         # Recalculate tax_value
1661         $dbh->do(q|
1662             UPDATE aqorders
1663             SET
1664                 tax_value_on_ordering = quantity * | . get_rounding_sql(q|ecost_tax_excluded|) . q| * tax_rate_on_ordering,
1665                 tax_value_on_receiving = quantity * | . get_rounding_sql(q|unitprice_tax_excluded|) . q| * tax_rate_on_receiving
1666             WHERE ordernumber = ?
1667         |, undef, $parent_ordernumber);
1668
1669         _cancel_items_receipt( $order_obj, $parent_ordernumber );
1670         # Delete order line
1671         $query = qq{
1672             DELETE FROM aqorders
1673             WHERE ordernumber = ?
1674         };
1675         $sth = $dbh->prepare($query);
1676         $sth->execute($ordernumber);
1677
1678     }
1679
1680     if( $order_obj->basket->effective_create_items eq 'ordering' ) {
1681         my @affects = split q{\|}, C4::Context->preference("AcqItemSetSubfieldsWhenReceiptIsCancelled");
1682         if ( @affects ) {
1683             for my $in ( @itemnumbers ) {
1684                 my $item = Koha::Items->find( $in ); # FIXME We do not need that, we already have Koha::Items from $order_obj->items
1685                 my $biblio = $item->biblio;
1686                 my ( $itemfield ) = GetMarcFromKohaField( 'items.itemnumber', $biblio->frameworkcode );
1687                 my $item_marc = C4::Items::GetMarcItem( $biblio->biblionumber, $in );
1688                 for my $affect ( @affects ) {
1689                     my ( $sf, $v ) = split q{=}, $affect, 2;
1690                     foreach ( $item_marc->field($itemfield) ) {
1691                         $_->update( $sf => $v );
1692                     }
1693                 }
1694                 C4::Items::ModItemFromMarc( $item_marc, $biblio->biblionumber, $in );
1695             }
1696         }
1697     }
1698
1699     return $parent_ordernumber;
1700 }
1701
1702 sub _cancel_items_receipt {
1703     my ( $order, $parent_ordernumber ) = @_;
1704     $parent_ordernumber ||= $order->ordernumber;
1705
1706     my $items = $order->items;
1707     if ( $order->basket->effective_create_items eq 'receiving' ) {
1708         # Remove items that were created at receipt
1709         my $query = qq{
1710             DELETE FROM items, aqorders_items
1711             USING items, aqorders_items
1712             WHERE items.itemnumber = ? AND aqorders_items.itemnumber = ?
1713         };
1714         my $dbh = C4::Context->dbh;
1715         my $sth = $dbh->prepare($query);
1716         while ( my $item = $items->next ) {
1717             $sth->execute($item->itemnumber, $item->itemnumber);
1718         }
1719     } else {
1720         # Update items
1721         while ( my $item = $items->next ) {
1722             ModItemOrder($item->itemnumber, $parent_ordernumber);
1723         }
1724     }
1725 }
1726
1727 #------------------------------------------------------------#
1728
1729 =head3 SearchOrders
1730
1731 @results = &SearchOrders({
1732     ordernumber => $ordernumber,
1733     search => $search,
1734     ean => $ean,
1735     booksellerid => $booksellerid,
1736     basketno => $basketno,
1737     basketname => $basketname,
1738     basketgroupname => $basketgroupname,
1739     owner => $owner,
1740     pending => $pending
1741     ordered => $ordered
1742     biblionumber => $biblionumber,
1743     budget_id => $budget_id
1744 });
1745
1746 Searches for orders filtered by criteria.
1747
1748 C<$ordernumber> Finds matching orders or transferred orders by ordernumber.
1749 C<$search> Finds orders matching %$search% in title, author, or isbn.
1750 C<$owner> Finds order for the logged in user.
1751 C<$pending> Finds pending orders. Ignores completed and cancelled orders.
1752 C<$ordered> Finds orders to receive only (status 'ordered' or 'partial').
1753
1754
1755 C<@results> is an array of references-to-hash with the keys are fields
1756 from aqorders, biblio, biblioitems and aqbasket tables.
1757
1758 =cut
1759
1760 sub SearchOrders {
1761     my ( $params ) = @_;
1762     my $ordernumber = $params->{ordernumber};
1763     my $search = $params->{search};
1764     my $ean = $params->{ean};
1765     my $booksellerid = $params->{booksellerid};
1766     my $basketno = $params->{basketno};
1767     my $basketname = $params->{basketname};
1768     my $basketgroupname = $params->{basketgroupname};
1769     my $owner = $params->{owner};
1770     my $pending = $params->{pending};
1771     my $ordered = $params->{ordered};
1772     my $biblionumber = $params->{biblionumber};
1773     my $budget_id = $params->{budget_id};
1774
1775     my $dbh = C4::Context->dbh;
1776     my @args = ();
1777     my $query = q{
1778         SELECT aqbasket.basketno,
1779                borrowers.surname,
1780                borrowers.firstname,
1781                biblio.*,
1782                biblioitems.isbn,
1783                biblioitems.biblioitemnumber,
1784                biblioitems.publishercode,
1785                biblioitems.publicationyear,
1786                aqbasket.authorisedby,
1787                aqbasket.booksellerid,
1788                aqbasket.closedate,
1789                aqbasket.creationdate,
1790                aqbasket.basketname,
1791                aqbasketgroups.id as basketgroupid,
1792                aqbasketgroups.name as basketgroupname,
1793                aqorders.*
1794         FROM aqorders
1795             LEFT JOIN aqbasket ON aqorders.basketno = aqbasket.basketno
1796             LEFT JOIN aqbasketgroups ON aqbasket.basketgroupid = aqbasketgroups.id
1797             LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber
1798             LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
1799             LEFT JOIN biblioitems ON biblioitems.biblionumber=biblio.biblionumber
1800     };
1801
1802     # If we search on ordernumber, we retrieve the transferred order if a transfer has been done.
1803     $query .= q{
1804             LEFT JOIN aqorders_transfers ON aqorders_transfers.ordernumber_to = aqorders.ordernumber
1805     } if $ordernumber;
1806
1807     $query .= q{
1808         WHERE (datecancellationprinted is NULL)
1809     };
1810
1811     if ( $pending or $ordered ) {
1812         $query .= q{
1813             AND (
1814                 ( aqbasket.is_standing AND aqorders.orderstatus IN ( "new", "ordered", "partial" ) )
1815                 OR (
1816                     ( quantity > quantityreceived OR quantityreceived is NULL )
1817         };
1818
1819         if ( $ordered ) {
1820             $query .= q{ AND aqorders.orderstatus IN ( "ordered", "partial" )};
1821         }
1822         $query .= q{
1823                 )
1824             )
1825         };
1826     }
1827
1828     my $userenv = C4::Context->userenv;
1829     if ( C4::Context->preference("IndependentBranches") ) {
1830         unless ( C4::Context->IsSuperLibrarian() ) {
1831             $query .= q{
1832                 AND (
1833                     borrowers.branchcode = ?
1834                     OR borrowers.branchcode  = ''
1835                 )
1836             };
1837             push @args, $userenv->{branch};
1838         }
1839     }
1840
1841     if ( $ordernumber ) {
1842         $query .= ' AND ( aqorders.ordernumber = ? OR aqorders_transfers.ordernumber_from = ? ) ';
1843         push @args, ( $ordernumber, $ordernumber );
1844     }
1845     if ( $biblionumber ) {
1846         $query .= 'AND aqorders.biblionumber = ?';
1847         push @args, $biblionumber;
1848     }
1849     if( $search ) {
1850         $query .= ' AND (biblio.title LIKE ? OR biblio.author LIKE ? OR biblioitems.isbn LIKE ?)';
1851         push @args, ("%$search%","%$search%","%$search%");
1852     }
1853     if ( $ean ) {
1854         $query .= ' AND biblioitems.ean = ?';
1855         push @args, $ean;
1856     }
1857     if ( $booksellerid ) {
1858         $query .= 'AND aqbasket.booksellerid = ?';
1859         push @args, $booksellerid;
1860     }
1861     if( $basketno ) {
1862         $query .= 'AND aqbasket.basketno = ?';
1863         push @args, $basketno;
1864     }
1865     if( $basketname ) {
1866         $query .= 'AND aqbasket.basketname LIKE ?';
1867         push @args, "%$basketname%";
1868     }
1869     if( $basketgroupname ) {
1870         $query .= ' AND aqbasketgroups.name LIKE ?';
1871         push @args, "%$basketgroupname%";
1872     }
1873
1874     if ( $owner ) {
1875         $query .= ' AND aqbasket.authorisedby=? ';
1876         push @args, $userenv->{'number'};
1877     }
1878
1879     if ( $budget_id ) {
1880         $query .= ' AND aqorders.budget_id = ?';
1881         push @args, $budget_id;
1882     }
1883
1884     $query .= ' ORDER BY aqbasket.basketno';
1885
1886     my $sth = $dbh->prepare($query);
1887     $sth->execute(@args);
1888     return $sth->fetchall_arrayref({});
1889 }
1890
1891 #------------------------------------------------------------#
1892
1893 =head3 DelOrder
1894
1895   &DelOrder($biblionumber, $ordernumber);
1896
1897 Cancel the order with the given order and biblio numbers. It does not
1898 delete any entries in the aqorders table, it merely marks them as
1899 cancelled.
1900
1901 =cut
1902
1903 sub DelOrder {
1904     my ( $bibnum, $ordernumber, $delete_biblio, $reason ) = @_;
1905     my $error;
1906     my $dbh = C4::Context->dbh;
1907     my $query = "
1908         UPDATE aqorders
1909         SET    datecancellationprinted=now(), orderstatus='cancelled'
1910     ";
1911     if($reason) {
1912         $query .= ", cancellationreason = ? ";
1913     }
1914     $query .= "
1915         WHERE biblionumber=? AND ordernumber=?
1916     ";
1917     my $sth = $dbh->prepare($query);
1918     if($reason) {
1919         $sth->execute($reason, $bibnum, $ordernumber);
1920     } else {
1921         $sth->execute( $bibnum, $ordernumber );
1922     }
1923     $sth->finish;
1924
1925     my $order = Koha::Acquisition::Orders->find($ordernumber);
1926     my $items = $order->items;
1927     while ( my $item = $items->next ) { # Should be moved to Koha::Acquisition::Order->delete
1928         my $delcheck = C4::Items::DelItemCheck( $bibnum, $item->itemnumber );
1929
1930         if($delcheck != 1) {
1931             $error->{'delitem'} = 1;
1932         }
1933     }
1934
1935     if($delete_biblio) {
1936         # We get the number of remaining items
1937         my $biblio = Koha::Biblios->find( $bibnum );
1938         my $itemcount = $biblio->items->count;
1939
1940         # If there are no items left,
1941         if ( $itemcount == 0 ) {
1942             # We delete the record
1943             my $delcheck = DelBiblio($bibnum);
1944
1945             if($delcheck) {
1946                 $error->{'delbiblio'} = 1;
1947             }
1948         }
1949     }
1950
1951     return $error;
1952 }
1953
1954 =head3 TransferOrder
1955
1956     my $newordernumber = TransferOrder($ordernumber, $basketno);
1957
1958 Transfer an order line to a basket.
1959 Mark $ordernumber as cancelled with an internal note 'Cancelled and transferred
1960 to BOOKSELLER on DATE' and create new order with internal note
1961 'Transferred from BOOKSELLER on DATE'.
1962 Move all attached items to the new order.
1963 Received orders cannot be transferred.
1964 Return the ordernumber of created order.
1965
1966 =cut
1967
1968 sub TransferOrder {
1969     my ($ordernumber, $basketno) = @_;
1970
1971     return unless ($ordernumber and $basketno);
1972
1973     my $order = Koha::Acquisition::Orders->find( $ordernumber ) or return;
1974     return if $order->datereceived;
1975
1976     $order = $order->unblessed;
1977
1978     my $basket = GetBasket($basketno);
1979     return unless $basket;
1980
1981     my $dbh = C4::Context->dbh;
1982     my ($query, $sth, $rv);
1983
1984     $query = q{
1985         UPDATE aqorders
1986         SET datecancellationprinted = CAST(NOW() AS date), orderstatus = ?
1987         WHERE ordernumber = ?
1988     };
1989     $sth = $dbh->prepare($query);
1990     $rv = $sth->execute('cancelled', $ordernumber);
1991
1992     delete $order->{'ordernumber'};
1993     delete $order->{parent_ordernumber};
1994     $order->{'basketno'} = $basketno;
1995
1996     my $newordernumber = Koha::Acquisition::Order->new($order)->store->ordernumber;
1997
1998     $query = q{
1999         UPDATE aqorders_items
2000         SET ordernumber = ?
2001         WHERE ordernumber = ?
2002     };
2003     $sth = $dbh->prepare($query);
2004     $sth->execute($newordernumber, $ordernumber);
2005
2006     $query = q{
2007         INSERT INTO aqorders_transfers (ordernumber_from, ordernumber_to)
2008         VALUES (?, ?)
2009     };
2010     $sth = $dbh->prepare($query);
2011     $sth->execute($ordernumber, $newordernumber);
2012
2013     return $newordernumber;
2014 }
2015
2016 =head3 get_rounding_sql
2017
2018     $rounding_sql = get_rounding_sql($column_name);
2019
2020 returns the correct SQL routine based on OrderPriceRounding system preference.
2021
2022 =cut
2023
2024 sub get_rounding_sql {
2025     my ( $round_string ) = @_;
2026     my $rounding_pref = C4::Context->preference('OrderPriceRounding') // q{};
2027     if ( $rounding_pref eq "nearest_cent"  ) {
2028         return "CAST($round_string*100 AS SIGNED)/100";
2029     }
2030     return $round_string;
2031 }
2032
2033 =head3 get_rounded_price
2034
2035     $rounded_price = get_rounded_price( $price );
2036
2037 returns a price rounded as specified in OrderPriceRounding system preference.
2038
2039 =cut
2040
2041 sub get_rounded_price {
2042     my ( $price ) =  @_;
2043     my $rounding_pref = C4::Context->preference('OrderPriceRounding') // q{};
2044     if( $rounding_pref eq 'nearest_cent' ) {
2045         return Koha::Number::Price->new( $price )->round();
2046     }
2047     return $price;
2048 }
2049
2050
2051 =head2 FUNCTIONS ABOUT PARCELS
2052
2053 =head3 GetParcels
2054
2055   $results = &GetParcels($bookseller, $order, $code, $datefrom, $dateto);
2056
2057 get a lists of parcels.
2058
2059 * Input arg :
2060
2061 =over
2062
2063 =item $bookseller
2064 is the bookseller this function has to get parcels.
2065
2066 =item $order
2067 To know on what criteria the results list has to be ordered.
2068
2069 =item $code
2070 is the booksellerinvoicenumber.
2071
2072 =item $datefrom & $dateto
2073 to know on what date this function has to filter its search.
2074
2075 =back
2076
2077 * return:
2078 a pointer on a hash list containing parcel informations as such :
2079
2080 =over
2081
2082 =item Creation date
2083
2084 =item Last operation
2085
2086 =item Number of biblio
2087
2088 =item Number of items
2089
2090 =back
2091
2092 =cut
2093
2094 sub GetParcels {
2095     my ($bookseller,$order, $code, $datefrom, $dateto) = @_;
2096     my $dbh    = C4::Context->dbh;
2097     my @query_params = ();
2098     my $strsth ="
2099         SELECT  aqinvoices.invoicenumber,
2100                 datereceived,purchaseordernumber,
2101                 count(DISTINCT biblionumber) AS biblio,
2102                 sum(quantity) AS itemsexpected,
2103                 sum(quantityreceived) AS itemsreceived
2104         FROM   aqorders LEFT JOIN aqbasket ON aqbasket.basketno = aqorders.basketno
2105         LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid
2106         WHERE aqbasket.booksellerid = ? and datereceived IS NOT NULL
2107     ";
2108     push @query_params, $bookseller;
2109
2110     if ( defined $code ) {
2111         $strsth .= ' and aqinvoices.invoicenumber like ? ';
2112         # add a % to the end of the code to allow stemming.
2113         push @query_params, "$code%";
2114     }
2115
2116     if ( defined $datefrom ) {
2117         $strsth .= ' and datereceived >= ? ';
2118         push @query_params, $datefrom;
2119     }
2120
2121     if ( defined $dateto ) {
2122         $strsth .=  'and datereceived <= ? ';
2123         push @query_params, $dateto;
2124     }
2125
2126     $strsth .= "group by aqinvoices.invoicenumber,datereceived ";
2127
2128     # can't use a placeholder to place this column name.
2129     # but, we could probably be checking to make sure it is a column that will be fetched.
2130     $strsth .= "order by $order " if ($order);
2131
2132     my $sth = $dbh->prepare($strsth);
2133
2134     $sth->execute( @query_params );
2135     my $results = $sth->fetchall_arrayref({});
2136     return @{$results};
2137 }
2138
2139 #------------------------------------------------------------#
2140
2141 =head3 GetLateOrders
2142
2143   @results = &GetLateOrders;
2144
2145 Searches for bookseller with late orders.
2146
2147 return:
2148 the table of supplier with late issues. This table is full of hashref.
2149
2150 =cut
2151
2152 sub GetLateOrders {
2153     my $delay      = shift;
2154     my $supplierid = shift;
2155     my $branch     = shift;
2156     my $estimateddeliverydatefrom = shift;
2157     my $estimateddeliverydateto = shift;
2158
2159     my $dbh = C4::Context->dbh;
2160
2161     #BEWARE, order of parenthesis and LEFT JOIN is important for speed
2162     my $dbdriver = C4::Context->config("db_scheme") || "mysql";
2163
2164     my @query_params = ();
2165     my $select = "
2166     SELECT aqbasket.basketno,
2167         aqorders.ordernumber,
2168         DATE(aqbasket.closedate)  AS orderdate,
2169         aqbasket.basketname       AS basketname,
2170         aqbasket.basketgroupid    AS basketgroupid,
2171         aqbasketgroups.name       AS basketgroupname,
2172         aqorders.rrp              AS unitpricesupplier,
2173         aqorders.ecost            AS unitpricelib,
2174         aqorders.claims_count     AS claims_count,
2175         aqorders.claimed_date     AS claimed_date,
2176         aqbudgets.budget_name     AS budget,
2177         borrowers.branchcode      AS branch,
2178         aqbooksellers.name        AS supplier,
2179         aqbooksellers.id          AS supplierid,
2180         biblio.author, biblio.title,
2181         biblioitems.publishercode AS publisher,
2182         biblioitems.publicationyear,
2183         ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) AS estimateddeliverydate,
2184     ";
2185     my $from = "
2186     FROM
2187         aqorders LEFT JOIN biblio     ON biblio.biblionumber         = aqorders.biblionumber
2188         LEFT JOIN biblioitems         ON biblioitems.biblionumber    = biblio.biblionumber
2189         LEFT JOIN aqbudgets           ON aqorders.budget_id          = aqbudgets.budget_id,
2190         aqbasket LEFT JOIN borrowers  ON aqbasket.authorisedby       = borrowers.borrowernumber
2191         LEFT JOIN aqbooksellers       ON aqbasket.booksellerid       = aqbooksellers.id
2192         LEFT JOIN aqbasketgroups      ON aqbasket.basketgroupid      = aqbasketgroups.id
2193         WHERE aqorders.basketno = aqbasket.basketno
2194         AND ( datereceived = ''
2195             OR datereceived IS NULL
2196             OR aqorders.quantityreceived < aqorders.quantity
2197         )
2198         AND aqbasket.closedate IS NOT NULL
2199         AND (aqorders.datecancellationprinted IS NULL OR aqorders.datecancellationprinted='0000-00-00')
2200     ";
2201     if ($dbdriver eq "mysql") {
2202         $select .= "
2203         aqorders.quantity - COALESCE(aqorders.quantityreceived,0)                 AS quantity,
2204         (aqorders.quantity - COALESCE(aqorders.quantityreceived,0)) * aqorders.rrp AS subtotal,
2205         DATEDIFF(CAST(now() AS date),closedate) AS latesince
2206         ";
2207         if ( defined $delay ) {
2208             $from .= " AND (closedate <= DATE_SUB(CAST(now() AS date),INTERVAL ? DAY)) " ;
2209             push @query_params, $delay;
2210         }
2211         $from .= " AND aqorders.quantity - COALESCE(aqorders.quantityreceived,0) <> 0";
2212     } else {
2213         # FIXME: account for IFNULL as above
2214         $select .= "
2215                 aqorders.quantity                AS quantity,
2216                 aqorders.quantity * aqorders.rrp AS subtotal,
2217                 (CAST(now() AS date) - closedate)            AS latesince
2218         ";
2219         if ( defined $delay ) {
2220             $from .= " AND (closedate <= (CAST(now() AS date) -(INTERVAL ? DAY)) ";
2221             push @query_params, $delay;
2222         }
2223         $from .= " AND aqorders.quantity <> 0";
2224     }
2225     if (defined $supplierid) {
2226         $from .= ' AND aqbasket.booksellerid = ? ';
2227         push @query_params, $supplierid;
2228     }
2229     if (defined $branch) {
2230         $from .= ' AND borrowers.branchcode LIKE ? ';
2231         push @query_params, $branch;
2232     }
2233
2234     if ( defined $estimateddeliverydatefrom or defined $estimateddeliverydateto ) {
2235         $from .= ' AND aqbooksellers.deliverytime IS NOT NULL ';
2236     }
2237     if ( defined $estimateddeliverydatefrom ) {
2238         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) >= ?';
2239         push @query_params, $estimateddeliverydatefrom;
2240     }
2241     if ( defined $estimateddeliverydateto ) {
2242         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) <= ?';
2243         push @query_params, $estimateddeliverydateto;
2244     }
2245     if ( defined $estimateddeliverydatefrom and not defined $estimateddeliverydateto ) {
2246         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) <= CAST(now() AS date)';
2247     }
2248     if (C4::Context->preference("IndependentBranches")
2249             && !C4::Context->IsSuperLibrarian() ) {
2250         $from .= ' AND borrowers.branchcode LIKE ? ';
2251         push @query_params, C4::Context->userenv->{branch};
2252     }
2253     $from .= " AND orderstatus <> 'cancelled' ";
2254     my $query = "$select $from \nORDER BY latesince, basketno, borrowers.branchcode, supplier";
2255     $debug and print STDERR "GetLateOrders query: $query\nGetLateOrders args: " . join(" ",@query_params);
2256     my $sth = $dbh->prepare($query);
2257     $sth->execute(@query_params);
2258     my @results;
2259     while (my $data = $sth->fetchrow_hashref) {
2260         push @results, $data;
2261     }
2262     return @results;
2263 }
2264
2265 #------------------------------------------------------------#
2266
2267 =head3 GetHistory
2268
2269   \@order_loop = GetHistory( %params );
2270
2271 Retreives some acquisition history information
2272
2273 params:
2274   title
2275   author
2276   name
2277   isbn
2278   ean
2279   from_placed_on
2280   to_placed_on
2281   basket                  - search both basket name and number
2282   booksellerinvoicenumber
2283   basketgroupname
2284   budget
2285   orderstatus (note that orderstatus '' will retrieve orders
2286                of any status except cancelled)
2287   biblionumber
2288   get_canceled_order (if set to a true value, cancelled orders will
2289                       be included)
2290
2291 returns:
2292     $order_loop is a list of hashrefs that each look like this:
2293             {
2294                 'author'           => 'Twain, Mark',
2295                 'basketno'         => '1',
2296                 'biblionumber'     => '215',
2297                 'count'            => 1,
2298                 'creationdate'     => 'MM/DD/YYYY',
2299                 'datereceived'     => undef,
2300                 'ecost'            => '1.00',
2301                 'id'               => '1',
2302                 'invoicenumber'    => undef,
2303                 'name'             => '',
2304                 'ordernumber'      => '1',
2305                 'quantity'         => 1,
2306                 'quantityreceived' => undef,
2307                 'title'            => 'The Adventures of Huckleberry Finn'
2308             }
2309
2310 =cut
2311
2312 sub GetHistory {
2313 # don't run the query if there are no parameters (list would be too long for sure !)
2314     croak "No search params" unless @_;
2315     my %params = @_;
2316     my $title = $params{title};
2317     my $author = $params{author};
2318     my $isbn   = $params{isbn};
2319     my $ean    = $params{ean};
2320     my $name = $params{name};
2321     my $from_placed_on = $params{from_placed_on};
2322     my $to_placed_on = $params{to_placed_on};
2323     my $basket = $params{basket};
2324     my $booksellerinvoicenumber = $params{booksellerinvoicenumber};
2325     my $basketgroupname = $params{basketgroupname};
2326     my $budget = $params{budget};
2327     my $orderstatus = $params{orderstatus};
2328     my $biblionumber = $params{biblionumber};
2329     my $get_canceled_order = $params{get_canceled_order} || 0;
2330     my $ordernumber = $params{ordernumber};
2331     my $search_children_too = $params{search_children_too} || 0;
2332     my $created_by = $params{created_by} || [];
2333     my $ordernumbers = $params{ordernumbers} || [];
2334     my $additional_fields = $params{additional_fields} // [];
2335
2336     my @order_loop;
2337     my $total_qty         = 0;
2338     my $total_qtyreceived = 0;
2339     my $total_price       = 0;
2340
2341     #get variation of isbn
2342     my @isbn_params;
2343     my @isbns;
2344     if ($isbn){
2345         if ( C4::Context->preference("SearchWithISBNVariations") ){
2346             @isbns = C4::Koha::GetVariationsOfISBN( $isbn );
2347             foreach my $isb (@isbns){
2348                 push @isbn_params, '?';
2349             }
2350         }
2351         unless (@isbns){
2352             push @isbns, $isbn;
2353             push @isbn_params, '?';
2354         }
2355     }
2356
2357     my $dbh   = C4::Context->dbh;
2358     my $query ="
2359         SELECT
2360             COALESCE(biblio.title,     deletedbiblio.title)     AS title,
2361             COALESCE(biblio.author,    deletedbiblio.author)    AS author,
2362             COALESCE(biblioitems.isbn, deletedbiblioitems.isbn) AS isbn,
2363             COALESCE(biblioitems.ean,  deletedbiblioitems.ean)  AS ean,
2364             aqorders.basketno,
2365             aqbasket.basketname,
2366             aqbasket.basketgroupid,
2367             aqbasket.authorisedby,
2368             concat( borrowers.firstname,' ',borrowers.surname) AS authorisedbyname,
2369             aqbasketgroups.name as groupname,
2370             aqbooksellers.name,
2371             aqbasket.creationdate,
2372             aqorders.datereceived,
2373             aqorders.quantity,
2374             aqorders.quantityreceived,
2375             aqorders.ecost,
2376             aqorders.ordernumber,
2377             aqorders.invoiceid,
2378             aqinvoices.invoicenumber,
2379             aqbooksellers.id as id,
2380             aqorders.biblionumber,
2381             aqorders.orderstatus,
2382             aqorders.parent_ordernumber,
2383             aqbudgets.budget_name
2384             ";
2385     $query .= ", aqbudgets.budget_id AS budget" if defined $budget;
2386     $query .= "
2387         FROM aqorders
2388         LEFT JOIN aqbasket ON aqorders.basketno=aqbasket.basketno
2389         LEFT JOIN aqbasketgroups ON aqbasket.basketgroupid=aqbasketgroups.id
2390         LEFT JOIN aqbooksellers ON aqbasket.booksellerid=aqbooksellers.id
2391         LEFT JOIN biblioitems ON biblioitems.biblionumber=aqorders.biblionumber
2392         LEFT JOIN biblio ON biblio.biblionumber=aqorders.biblionumber
2393         LEFT JOIN aqbudgets ON aqorders.budget_id=aqbudgets.budget_id
2394         LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid
2395         LEFT JOIN deletedbiblio ON deletedbiblio.biblionumber=aqorders.biblionumber
2396         LEFT JOIN deletedbiblioitems ON deletedbiblioitems.biblionumber=aqorders.biblionumber
2397         LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber
2398         ";
2399
2400     $query .= " WHERE 1 ";
2401
2402     unless ($get_canceled_order or (defined $orderstatus and $orderstatus eq 'cancelled')) {
2403         $query .= " AND (datecancellationprinted is NULL or datecancellationprinted='0000-00-00') ";
2404     }
2405
2406     my @query_params  = ();
2407
2408     if ( $biblionumber ) {
2409         $query .= " AND biblio.biblionumber = ?";
2410         push @query_params, $biblionumber;
2411     }
2412
2413     if ( $title ) {
2414         $query .= " AND biblio.title LIKE ? ";
2415         $title =~ s/\s+/%/g;
2416         push @query_params, "%$title%";
2417     }
2418
2419     if ( $author ) {
2420         $query .= " AND biblio.author LIKE ? ";
2421         push @query_params, "%$author%";
2422     }
2423
2424     if ( @isbns ) {
2425         $query .= " AND ( biblioitems.isbn LIKE " . join (" OR biblioitems.isbn LIKE ", @isbn_params ) . ")";
2426         foreach my $isb (@isbns){
2427             push @query_params, "%$isb%";
2428         }
2429     }
2430
2431     if ( $ean ) {
2432         $query .= " AND biblioitems.ean = ? ";
2433         push @query_params, "$ean";
2434     }
2435     if ( $name ) {
2436         $query .= " AND aqbooksellers.name LIKE ? ";
2437         push @query_params, "%$name%";
2438     }
2439
2440     if ( $budget ) {
2441         $query .= " AND aqbudgets.budget_id = ? ";
2442         push @query_params, "$budget";
2443     }
2444
2445     if ( $from_placed_on ) {
2446         $query .= " AND creationdate >= ? ";
2447         push @query_params, $from_placed_on;
2448     }
2449
2450     if ( $to_placed_on ) {
2451         $query .= " AND creationdate <= ? ";
2452         push @query_params, $to_placed_on;
2453     }
2454
2455     if ( defined $orderstatus and $orderstatus ne '') {
2456         $query .= " AND aqorders.orderstatus = ? ";
2457         push @query_params, "$orderstatus";
2458     }
2459
2460     if ($basket) {
2461         if ($basket =~ m/^\d+$/) {
2462             $query .= " AND aqorders.basketno = ? ";
2463             push @query_params, $basket;
2464         } else {
2465             $query .= " AND aqbasket.basketname LIKE ? ";
2466             push @query_params, "%$basket%";
2467         }
2468     }
2469
2470     if ($booksellerinvoicenumber) {
2471         $query .= " AND aqinvoices.invoicenumber LIKE ? ";
2472         push @query_params, "%$booksellerinvoicenumber%";
2473     }
2474
2475     if ($basketgroupname) {
2476         $query .= " AND aqbasketgroups.name LIKE ? ";
2477         push @query_params, "%$basketgroupname%";
2478     }
2479
2480     if ($ordernumber) {
2481         $query .= " AND (aqorders.ordernumber = ? ";
2482         push @query_params, $ordernumber;
2483         if ($search_children_too) {
2484             $query .= " OR aqorders.parent_ordernumber = ? ";
2485             push @query_params, $ordernumber;
2486         }
2487         $query .= ") ";
2488     }
2489
2490     if ( @$created_by ) {
2491         $query .= ' AND aqbasket.authorisedby IN ( ' . join( ',', ('?') x @$created_by ) . ')';
2492         push @query_params, @$created_by;
2493     }
2494
2495     if ( @$ordernumbers ) {
2496         $query .= ' AND (aqorders.ordernumber IN ( ' . join (',', ('?') x @$ordernumbers ) . '))';
2497         push @query_params, @$ordernumbers;
2498     }
2499     if ( @$additional_fields ) {
2500         my @baskets = Koha::Acquisition::Baskets->filter_by_additional_fields($additional_fields);
2501
2502         return [] unless @baskets;
2503
2504         # No parameterization because record IDs come directly from DB
2505         $query .= ' AND aqbasket.basketno IN ( ' . join( ',', map { $_->basketno } @baskets ) . ' )';
2506     }
2507
2508     if ( C4::Context->preference("IndependentBranches") ) {
2509         unless ( C4::Context->IsSuperLibrarian() ) {
2510             $query .= " AND (borrowers.branchcode = ? OR borrowers.branchcode ='' ) ";
2511             push @query_params, C4::Context->userenv->{branch};
2512         }
2513     }
2514     $query .= " ORDER BY id";
2515
2516     return $dbh->selectall_arrayref( $query, { Slice => {} }, @query_params );
2517 }
2518
2519 =head2 GetRecentAcqui
2520
2521   $results = GetRecentAcqui($days);
2522
2523 C<$results> is a ref to a table which contains hashref
2524
2525 =cut
2526
2527 sub GetRecentAcqui {
2528     my $limit  = shift;
2529     my $dbh    = C4::Context->dbh;
2530     my $query = "
2531         SELECT *
2532         FROM   biblio
2533         ORDER BY timestamp DESC
2534         LIMIT  0,".$limit;
2535
2536     my $sth = $dbh->prepare($query);
2537     $sth->execute;
2538     my $results = $sth->fetchall_arrayref({});
2539     return $results;
2540 }
2541
2542 #------------------------------------------------------------#
2543
2544 =head3 AddClaim
2545
2546   &AddClaim($ordernumber);
2547
2548 Add a claim for an order
2549
2550 =cut
2551
2552 sub AddClaim {
2553     my ($ordernumber) = @_;
2554     my $dbh          = C4::Context->dbh;
2555     my $query        = "
2556         UPDATE aqorders SET
2557             claims_count = claims_count + 1,
2558             claimed_date = CURDATE()
2559         WHERE ordernumber = ?
2560         ";
2561     my $sth = $dbh->prepare($query);
2562     $sth->execute($ordernumber);
2563 }
2564
2565 =head3 GetInvoices
2566
2567     my @invoices = GetInvoices(
2568         invoicenumber => $invoicenumber,
2569         supplierid => $supplierid,
2570         suppliername => $suppliername,
2571         shipmentdatefrom => $shipmentdatefrom, # ISO format
2572         shipmentdateto => $shipmentdateto, # ISO format
2573         billingdatefrom => $billingdatefrom, # ISO format
2574         billingdateto => $billingdateto, # ISO format
2575         isbneanissn => $isbn_or_ean_or_issn,
2576         title => $title,
2577         author => $author,
2578         publisher => $publisher,
2579         publicationyear => $publicationyear,
2580         branchcode => $branchcode,
2581         order_by => $order_by
2582     );
2583
2584 Return a list of invoices that match all given criteria.
2585
2586 $order_by is "column_name (asc|desc)", where column_name is any of
2587 'invoicenumber', 'booksellerid', 'shipmentdate', 'billingdate', 'closedate',
2588 'shipmentcost', 'shipmentcost_budgetid'.
2589
2590 asc is the default if omitted
2591
2592 =cut
2593
2594 sub GetInvoices {
2595     my %args = @_;
2596
2597     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2598         closedate shipmentcost shipmentcost_budgetid);
2599
2600     my $dbh = C4::Context->dbh;
2601     my $query = qq{
2602         SELECT aqinvoices.invoiceid, aqinvoices.invoicenumber, aqinvoices.booksellerid, aqinvoices.shipmentdate, aqinvoices.billingdate, aqinvoices.closedate, aqinvoices.shipmentcost, aqinvoices.shipmentcost_budgetid, aqinvoices.message_id,
2603             aqbooksellers.name AS suppliername,
2604           COUNT(
2605             DISTINCT IF(
2606               aqorders.datereceived IS NOT NULL,
2607               aqorders.biblionumber,
2608               NULL
2609             )
2610           ) AS receivedbiblios,
2611           COUNT(
2612              DISTINCT IF(
2613               aqorders.subscriptionid IS NOT NULL,
2614               aqorders.subscriptionid,
2615               NULL
2616             )
2617           ) AS is_linked_to_subscriptions,
2618           SUM(aqorders.quantityreceived) AS receiveditems
2619         FROM aqinvoices
2620           LEFT JOIN aqbooksellers ON aqbooksellers.id = aqinvoices.booksellerid
2621           LEFT JOIN aqorders ON aqorders.invoiceid = aqinvoices.invoiceid
2622           LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
2623           LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber
2624           LEFT JOIN biblio ON aqorders.biblionumber = biblio.biblionumber
2625           LEFT JOIN biblioitems ON biblio.biblionumber = biblioitems.biblionumber
2626           LEFT JOIN subscription ON biblio.biblionumber = subscription.biblionumber
2627     };
2628
2629     my @bind_args;
2630     my @bind_strs;
2631     if($args{supplierid}) {
2632         push @bind_strs, " aqinvoices.booksellerid = ? ";
2633         push @bind_args, $args{supplierid};
2634     }
2635     if($args{invoicenumber}) {
2636         push @bind_strs, " aqinvoices.invoicenumber LIKE ? ";
2637         push @bind_args, "%$args{invoicenumber}%";
2638     }
2639     if($args{suppliername}) {
2640         push @bind_strs, " aqbooksellers.name LIKE ? ";
2641         push @bind_args, "%$args{suppliername}%";
2642     }
2643     if($args{shipmentdatefrom}) {
2644         push @bind_strs, " aqinvoices.shipmentdate >= ? ";
2645         push @bind_args, $args{shipmentdatefrom};
2646     }
2647     if($args{shipmentdateto}) {
2648         push @bind_strs, " aqinvoices.shipmentdate <= ? ";
2649         push @bind_args, $args{shipmentdateto};
2650     }
2651     if($args{billingdatefrom}) {
2652         push @bind_strs, " aqinvoices.billingdate >= ? ";
2653         push @bind_args, $args{billingdatefrom};
2654     }
2655     if($args{billingdateto}) {
2656         push @bind_strs, " aqinvoices.billingdate <= ? ";
2657         push @bind_args, $args{billingdateto};
2658     }
2659     if($args{isbneanissn}) {
2660         push @bind_strs, " (biblioitems.isbn LIKE CONCAT('%', ?, '%') OR biblioitems.ean LIKE CONCAT('%', ?, '%') OR biblioitems.issn LIKE CONCAT('%', ?, '%') ) ";
2661         push @bind_args, $args{isbneanissn}, $args{isbneanissn}, $args{isbneanissn};
2662     }
2663     if($args{title}) {
2664         push @bind_strs, " biblio.title LIKE CONCAT('%', ?, '%') ";
2665         push @bind_args, $args{title};
2666     }
2667     if($args{author}) {
2668         push @bind_strs, " biblio.author LIKE CONCAT('%', ?, '%') ";
2669         push @bind_args, $args{author};
2670     }
2671     if($args{publisher}) {
2672         push @bind_strs, " biblioitems.publishercode LIKE CONCAT('%', ?, '%') ";
2673         push @bind_args, $args{publisher};
2674     }
2675     if($args{publicationyear}) {
2676         push @bind_strs, " ((biblioitems.publicationyear LIKE CONCAT('%', ?, '%')) OR (biblio.copyrightdate LIKE CONCAT('%', ?, '%'))) ";
2677         push @bind_args, $args{publicationyear}, $args{publicationyear};
2678     }
2679     if($args{branchcode}) {
2680         push @bind_strs, " borrowers.branchcode = ? ";
2681         push @bind_args, $args{branchcode};
2682     }
2683     if($args{message_id}) {
2684         push @bind_strs, " aqinvoices.message_id = ? ";
2685         push @bind_args, $args{message_id};
2686     }
2687
2688     $query .= " WHERE " . join(" AND ", @bind_strs) if @bind_strs;
2689     $query .= " GROUP BY aqinvoices.invoiceid, aqinvoices.invoicenumber, aqinvoices.booksellerid, aqinvoices.shipmentdate, aqinvoices.billingdate, aqinvoices.closedate, aqinvoices.shipmentcost, aqinvoices.shipmentcost_budgetid, aqinvoices.message_id, aqbooksellers.name";
2690
2691     if($args{order_by}) {
2692         my ($column, $direction) = split / /, $args{order_by};
2693         if(grep /^$column$/, @columns) {
2694             $direction ||= 'ASC';
2695             $query .= " ORDER BY $column $direction";
2696         }
2697     }
2698
2699     my $sth = $dbh->prepare($query);
2700     $sth->execute(@bind_args);
2701
2702     my $results = $sth->fetchall_arrayref({});
2703     return @$results;
2704 }
2705
2706 =head3 GetInvoice
2707
2708     my $invoice = GetInvoice($invoiceid);
2709
2710 Get informations about invoice with given $invoiceid
2711
2712 Return a hash filled with aqinvoices.* fields
2713
2714 =cut
2715
2716 sub GetInvoice {
2717     my ($invoiceid) = @_;
2718     my $invoice;
2719
2720     return unless $invoiceid;
2721
2722     my $dbh = C4::Context->dbh;
2723     my $query = qq{
2724         SELECT *
2725         FROM aqinvoices
2726         WHERE invoiceid = ?
2727     };
2728     my $sth = $dbh->prepare($query);
2729     $sth->execute($invoiceid);
2730
2731     $invoice = $sth->fetchrow_hashref;
2732     return $invoice;
2733 }
2734
2735 =head3 GetInvoiceDetails
2736
2737     my $invoice = GetInvoiceDetails($invoiceid)
2738
2739 Return informations about an invoice + the list of related order lines
2740
2741 Orders informations are in $invoice->{orders} (array ref)
2742
2743 =cut
2744
2745 sub GetInvoiceDetails {
2746     my ($invoiceid) = @_;
2747
2748     if ( !defined $invoiceid ) {
2749         carp 'GetInvoiceDetails called without an invoiceid';
2750         return;
2751     }
2752
2753     my $dbh = C4::Context->dbh;
2754     my $query = q{
2755         SELECT aqinvoices.*, aqbooksellers.name AS suppliername
2756         FROM aqinvoices
2757           LEFT JOIN aqbooksellers ON aqinvoices.booksellerid = aqbooksellers.id
2758         WHERE invoiceid = ?
2759     };
2760     my $sth = $dbh->prepare($query);
2761     $sth->execute($invoiceid);
2762
2763     my $invoice = $sth->fetchrow_hashref;
2764
2765     $query = q{
2766         SELECT aqorders.*,
2767                 biblio.*,
2768                 biblio.copyrightdate,
2769                 biblioitems.isbn,
2770                 biblioitems.publishercode,
2771                 biblioitems.publicationyear,
2772                 aqbasket.basketname,
2773                 aqbasketgroups.id AS basketgroupid,
2774                 aqbasketgroups.name AS basketgroupname
2775         FROM aqorders
2776           LEFT JOIN aqbasket ON aqorders.basketno = aqbasket.basketno
2777           LEFT JOIN aqbasketgroups ON aqbasket.basketgroupid = aqbasketgroups.id
2778           LEFT JOIN biblio ON aqorders.biblionumber = biblio.biblionumber
2779           LEFT JOIN biblioitems ON aqorders.biblionumber = biblioitems.biblionumber
2780         WHERE invoiceid = ?
2781     };
2782     $sth = $dbh->prepare($query);
2783     $sth->execute($invoiceid);
2784     $invoice->{orders} = $sth->fetchall_arrayref({});
2785     $invoice->{orders} ||= []; # force an empty arrayref if fetchall_arrayref fails
2786
2787     return $invoice;
2788 }
2789
2790 =head3 AddInvoice
2791
2792     my $invoiceid = AddInvoice(
2793         invoicenumber => $invoicenumber,
2794         booksellerid => $booksellerid,
2795         shipmentdate => $shipmentdate,
2796         billingdate => $billingdate,
2797         closedate => $closedate,
2798         shipmentcost => $shipmentcost,
2799         shipmentcost_budgetid => $shipmentcost_budgetid
2800     );
2801
2802 Create a new invoice and return its id or undef if it fails.
2803
2804 =cut
2805
2806 sub AddInvoice {
2807     my %invoice = @_;
2808
2809     return unless(%invoice and $invoice{invoicenumber});
2810
2811     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2812         closedate shipmentcost shipmentcost_budgetid message_id);
2813
2814     my @set_strs;
2815     my @set_args;
2816     foreach my $key (keys %invoice) {
2817         if(0 < grep(/^$key$/, @columns)) {
2818             push @set_strs, "$key = ?";
2819             push @set_args, ($invoice{$key} || undef);
2820         }
2821     }
2822
2823     my $rv;
2824     if(@set_args > 0) {
2825         my $dbh = C4::Context->dbh;
2826         my $query = "INSERT INTO aqinvoices SET ";
2827         $query .= join (",", @set_strs);
2828         my $sth = $dbh->prepare($query);
2829         $rv = $sth->execute(@set_args);
2830         if($rv) {
2831             $rv = $dbh->last_insert_id(undef, undef, 'aqinvoices', undef);
2832         }
2833     }
2834     return $rv;
2835 }
2836
2837 =head3 ModInvoice
2838
2839     ModInvoice(
2840         invoiceid => $invoiceid,    # Mandatory
2841         invoicenumber => $invoicenumber,
2842         booksellerid => $booksellerid,
2843         shipmentdate => $shipmentdate,
2844         billingdate => $billingdate,
2845         closedate => $closedate,
2846         shipmentcost => $shipmentcost,
2847         shipmentcost_budgetid => $shipmentcost_budgetid
2848     );
2849
2850 Modify an invoice, invoiceid is mandatory.
2851
2852 Return undef if it fails.
2853
2854 =cut
2855
2856 sub ModInvoice {
2857     my %invoice = @_;
2858
2859     return unless(%invoice and $invoice{invoiceid});
2860
2861     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2862         closedate shipmentcost shipmentcost_budgetid);
2863
2864     my @set_strs;
2865     my @set_args;
2866     foreach my $key (keys %invoice) {
2867         if(0 < grep(/^$key$/, @columns)) {
2868             push @set_strs, "$key = ?";
2869             push @set_args, ($invoice{$key} || undef);
2870         }
2871     }
2872
2873     my $dbh = C4::Context->dbh;
2874     my $query = "UPDATE aqinvoices SET ";
2875     $query .= join(",", @set_strs);
2876     $query .= " WHERE invoiceid = ?";
2877
2878     my $sth = $dbh->prepare($query);
2879     $sth->execute(@set_args, $invoice{invoiceid});
2880 }
2881
2882 =head3 CloseInvoice
2883
2884     CloseInvoice($invoiceid);
2885
2886 Close an invoice.
2887
2888 Equivalent to ModInvoice(invoiceid => $invoiceid, closedate => undef);
2889
2890 =cut
2891
2892 sub CloseInvoice {
2893     my ($invoiceid) = @_;
2894
2895     return unless $invoiceid;
2896
2897     my $dbh = C4::Context->dbh;
2898     my $query = qq{
2899         UPDATE aqinvoices
2900         SET closedate = CAST(NOW() AS DATE)
2901         WHERE invoiceid = ?
2902     };
2903     my $sth = $dbh->prepare($query);
2904     $sth->execute($invoiceid);
2905 }
2906
2907 =head3 ReopenInvoice
2908
2909     ReopenInvoice($invoiceid);
2910
2911 Reopen an invoice
2912
2913 Equivalent to ModInvoice(invoiceid => $invoiceid, closedate => output_pref({ dt=>dt_from_string, dateonly=>1, otputpref=>'iso' }))
2914
2915 =cut
2916
2917 sub ReopenInvoice {
2918     my ($invoiceid) = @_;
2919
2920     return unless $invoiceid;
2921
2922     my $dbh = C4::Context->dbh;
2923     my $query = qq{
2924         UPDATE aqinvoices
2925         SET closedate = NULL
2926         WHERE invoiceid = ?
2927     };
2928     my $sth = $dbh->prepare($query);
2929     $sth->execute($invoiceid);
2930 }
2931
2932 =head3 DelInvoice
2933
2934     DelInvoice($invoiceid);
2935
2936 Delete an invoice if there are no items attached to it.
2937
2938 =cut
2939
2940 sub DelInvoice {
2941     my ($invoiceid) = @_;
2942
2943     return unless $invoiceid;
2944
2945     my $dbh   = C4::Context->dbh;
2946     my $query = qq{
2947         SELECT COUNT(*)
2948         FROM aqorders
2949         WHERE invoiceid = ?
2950     };
2951     my $sth = $dbh->prepare($query);
2952     $sth->execute($invoiceid);
2953     my $res = $sth->fetchrow_arrayref;
2954     if ( $res && $res->[0] == 0 ) {
2955         $query = qq{
2956             DELETE FROM aqinvoices
2957             WHERE invoiceid = ?
2958         };
2959         my $sth = $dbh->prepare($query);
2960         return ( $sth->execute($invoiceid) > 0 );
2961     }
2962     return;
2963 }
2964
2965 =head3 MergeInvoices
2966
2967     MergeInvoices($invoiceid, \@sourceids);
2968
2969 Merge the invoices identified by the IDs in \@sourceids into
2970 the invoice identified by $invoiceid.
2971
2972 =cut
2973
2974 sub MergeInvoices {
2975     my ($invoiceid, $sourceids) = @_;
2976
2977     return unless $invoiceid;
2978     foreach my $sourceid (@$sourceids) {
2979         next if $sourceid == $invoiceid;
2980         my $source = GetInvoiceDetails($sourceid);
2981         foreach my $order (@{$source->{'orders'}}) {
2982             $order->{'invoiceid'} = $invoiceid;
2983             ModOrder($order);
2984         }
2985         DelInvoice($source->{'invoiceid'});
2986     }
2987     return;
2988 }
2989
2990 =head3 GetBiblioCountByBasketno
2991
2992 $biblio_count = &GetBiblioCountByBasketno($basketno);
2993
2994 Looks up the biblio's count that has basketno value $basketno
2995
2996 Returns a quantity
2997
2998 =cut
2999
3000 sub GetBiblioCountByBasketno {
3001     my ($basketno) = @_;
3002     my $dbh          = C4::Context->dbh;
3003     my $query        = "
3004         SELECT COUNT( DISTINCT( biblionumber ) )
3005         FROM   aqorders
3006         WHERE  basketno = ?
3007             AND (datecancellationprinted IS NULL OR datecancellationprinted='0000-00-00')
3008         ";
3009
3010     my $sth = $dbh->prepare($query);
3011     $sth->execute($basketno);
3012     return $sth->fetchrow;
3013 }
3014
3015 =head3 populate_order_with_prices
3016
3017 $order = populate_order_with_prices({
3018     order        => $order #a hashref with the order values
3019     booksellerid => $booksellerid #FIXME - should obtain from order basket
3020     receiving    => 1 # boolean representing order stage, should pass only this or ordering
3021     ordering     => 1 # boolean representing order stage
3022 });
3023
3024
3025 Sets calculated values for an order - all values are stored with pull precision regardless of rounding preference except fot
3026 tax value which is calculated on rounded values if requested
3027
3028 For ordering the values set are:
3029     rrp_tax_included
3030     rrp_tax_excluded
3031     ecost_tax_included
3032     ecost_tax_excluded
3033     tax_value_on_ordering
3034 For receiving the value set are:
3035     unitprice_tax_included
3036     unitprice_tax_excluded
3037     tax_value_on_receiving
3038
3039 Note: When receiving if the rounded value of the unitprice matches the rounded value of the ecost then then ecost (full precision) is used.
3040
3041 Returns a hashref of the order
3042
3043 FIXME: Move this to Koha::Acquisition::Order.pm
3044
3045 =cut
3046
3047 sub populate_order_with_prices {
3048     my ($params) = @_;
3049
3050     my $order        = $params->{order};
3051     my $booksellerid = $params->{booksellerid};
3052     return unless $booksellerid;
3053
3054     my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
3055
3056     my $receiving = $params->{receiving};
3057     my $ordering  = $params->{ordering};
3058     my $discount  = $order->{discount};
3059     $discount /= 100 if $discount > 1;
3060
3061     if ($ordering) {
3062         $order->{tax_rate_on_ordering} //= $order->{tax_rate};
3063         if ( $bookseller->listincgst ) {
3064             # The user entered the rrp tax included
3065             $order->{rrp_tax_included} = $order->{rrp};
3066
3067             # rrp tax excluded = rrp tax included / ( 1 + tax rate )
3068             $order->{rrp_tax_excluded} = $order->{rrp_tax_included} / ( 1 + $order->{tax_rate_on_ordering} );
3069
3070             # ecost tax included = rrp tax included  ( 1 - discount )
3071             $order->{ecost_tax_included} = $order->{rrp_tax_included} * ( 1 - $discount );
3072
3073             # ecost tax excluded = rrp tax excluded * ( 1 - discount )
3074             $order->{ecost_tax_excluded} = $order->{rrp_tax_excluded} * ( 1 - $discount );
3075
3076             # tax value = quantity * ecost tax excluded * tax rate
3077             $order->{tax_value_on_ordering} = ( get_rounded_price($order->{ecost_tax_included}) - get_rounded_price($order->{ecost_tax_excluded}) ) * $order->{quantity};
3078
3079         }
3080         else {
3081             # The user entered the rrp tax excluded
3082             $order->{rrp_tax_excluded} = $order->{rrp};
3083
3084             # rrp tax included = rrp tax excluded * ( 1 - tax rate )
3085             $order->{rrp_tax_included} = $order->{rrp_tax_excluded} * ( 1 + $order->{tax_rate_on_ordering} );
3086
3087             # ecost tax excluded = rrp tax excluded * ( 1 - discount )
3088             $order->{ecost_tax_excluded} = $order->{rrp_tax_excluded} * ( 1 - $discount );
3089
3090             # ecost tax included = rrp tax excluded * ( 1 + tax rate ) * ( 1 - discount ) = ecost tax excluded * ( 1 + tax rate )
3091             $order->{ecost_tax_included} = $order->{ecost_tax_excluded} * ( 1 + $order->{tax_rate_on_ordering} );
3092
3093             # tax value = quantity * ecost tax included * tax rate
3094             $order->{tax_value_on_ordering} = $order->{quantity} * get_rounded_price($order->{ecost_tax_excluded}) * $order->{tax_rate_on_ordering};
3095         }
3096     }
3097
3098     if ($receiving) {
3099         $order->{tax_rate_on_receiving} //= $order->{tax_rate};
3100         if ( $bookseller->invoiceincgst ) {
3101             # Trick for unitprice. If the unit price rounded value is the same as the ecost rounded value
3102             # we need to keep the exact ecost value
3103             if ( Koha::Number::Price->new( $order->{unitprice} )->round == Koha::Number::Price->new( $order->{ecost_tax_included} )->round ) {
3104                 $order->{unitprice} = $order->{ecost_tax_included};
3105             }
3106
3107             # The user entered the unit price tax included
3108             $order->{unitprice_tax_included} = $order->{unitprice};
3109
3110             # unit price tax excluded = unit price tax included / ( 1 + tax rate )
3111             $order->{unitprice_tax_excluded} = $order->{unitprice_tax_included} / ( 1 + $order->{tax_rate_on_receiving} );
3112         }
3113         else {
3114             # Trick for unitprice. If the unit price rounded value is the same as the ecost rounded value
3115             # we need to keep the exact ecost value
3116             if ( Koha::Number::Price->new( $order->{unitprice} )->round == Koha::Number::Price->new( $order->{ecost_tax_excluded} )->round ) {
3117                 $order->{unitprice} = $order->{ecost_tax_excluded};
3118             }
3119
3120             # The user entered the unit price tax excluded
3121             $order->{unitprice_tax_excluded} = $order->{unitprice};
3122
3123
3124             # unit price tax included = unit price tax included * ( 1 + tax rate )
3125             $order->{unitprice_tax_included} = $order->{unitprice_tax_excluded} * ( 1 + $order->{tax_rate_on_receiving} );
3126         }
3127
3128         # tax value = quantity * unit price tax excluded * tax rate
3129         $order->{tax_value_on_receiving} = $order->{quantity} * get_rounded_price($order->{unitprice_tax_excluded}) * $order->{tax_rate_on_receiving};
3130     }
3131
3132     return $order;
3133 }
3134
3135 =head3 GetOrderUsers
3136
3137     $order_users_ids = &GetOrderUsers($ordernumber);
3138
3139 Returns a list of all borrowernumbers that are in order users list
3140
3141 =cut
3142
3143 sub GetOrderUsers {
3144     my ($ordernumber) = @_;
3145
3146     return unless $ordernumber;
3147
3148     my $query = q|
3149         SELECT borrowernumber
3150         FROM aqorder_users
3151         WHERE ordernumber = ?
3152     |;
3153     my $dbh = C4::Context->dbh;
3154     my $sth = $dbh->prepare($query);
3155     $sth->execute($ordernumber);
3156     my $results = $sth->fetchall_arrayref( {} );
3157
3158     my @borrowernumbers;
3159     foreach (@$results) {
3160         push @borrowernumbers, $_->{'borrowernumber'};
3161     }
3162
3163     return @borrowernumbers;
3164 }
3165
3166 =head3 ModOrderUsers
3167
3168     my @order_users_ids = (1, 2, 3);
3169     &ModOrderUsers($ordernumber, @basketusers_ids);
3170
3171 Delete all users from order users list, and add users in C<@order_users_ids>
3172 to this users list.
3173
3174 =cut
3175
3176 sub ModOrderUsers {
3177     my ( $ordernumber, @order_users_ids ) = @_;
3178
3179     return unless $ordernumber;
3180
3181     my $dbh   = C4::Context->dbh;
3182     my $query = q|
3183         DELETE FROM aqorder_users
3184         WHERE ordernumber = ?
3185     |;
3186     my $sth = $dbh->prepare($query);
3187     $sth->execute($ordernumber);
3188
3189     $query = q|
3190         INSERT INTO aqorder_users (ordernumber, borrowernumber)
3191         VALUES (?, ?)
3192     |;
3193     $sth = $dbh->prepare($query);
3194     foreach my $order_user_id (@order_users_ids) {
3195         $sth->execute( $ordernumber, $order_user_id );
3196     }
3197 }
3198
3199 sub NotifyOrderUsers {
3200     my ($ordernumber) = @_;
3201
3202     my @borrowernumbers = GetOrderUsers($ordernumber);
3203     return unless @borrowernumbers;
3204
3205     my $order = GetOrder( $ordernumber );
3206     for my $borrowernumber (@borrowernumbers) {
3207         my $patron = Koha::Patrons->find( $borrowernumber );
3208         my $library = $patron->library->unblessed;
3209         my $biblio = Koha::Biblios->find( $order->{biblionumber} )->unblessed;
3210         my $letter = C4::Letters::GetPreparedLetter(
3211             module      => 'acquisition',
3212             letter_code => 'ACQ_NOTIF_ON_RECEIV',
3213             branchcode  => $library->{branchcode},
3214             lang        => $patron->lang,
3215             tables      => {
3216                 'branches'    => $library,
3217                 'borrowers'   => $patron->unblessed,
3218                 'biblio'      => $biblio,
3219                 'aqorders'    => $order,
3220             },
3221         );
3222         if ( $letter ) {
3223             C4::Letters::EnqueueLetter(
3224                 {
3225                     letter         => $letter,
3226                     borrowernumber => $borrowernumber,
3227                     LibraryName    => C4::Context->preference("LibraryName"),
3228                     message_transport_type => 'email',
3229                 }
3230             ) or warn "can't enqueue letter $letter";
3231         }
3232     }
3233 }
3234
3235 =head3 FillWithDefaultValues
3236
3237 FillWithDefaultValues( $marc_record );
3238
3239 This will update the record with default value defined in the ACQ framework.
3240 For all existing fields, if a default value exists and there are no subfield, it will be created.
3241 If the field does not exist, it will be created too.
3242
3243 =cut
3244
3245 sub FillWithDefaultValues {
3246     my ($record) = @_;
3247     my $tagslib = C4::Biblio::GetMarcStructure( 1, 'ACQ', { unsafe => 1 } );
3248     if ($tagslib) {
3249         my ($itemfield) =
3250           C4::Biblio::GetMarcFromKohaField( 'items.itemnumber', '' );
3251         for my $tag ( sort keys %$tagslib ) {
3252             next unless $tag;
3253             next if $tag == $itemfield;
3254             for my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
3255                 next if IsMarcStructureInternal($tagslib->{$tag}{$subfield});
3256                 my $defaultvalue = $tagslib->{$tag}{$subfield}{defaultvalue};
3257                 if ( defined $defaultvalue and $defaultvalue ne '' ) {
3258                     my @fields = $record->field($tag);
3259                     if (@fields) {
3260                         for my $field (@fields) {
3261                             unless ( defined $field->subfield($subfield) ) {
3262                                 $field->add_subfields(
3263                                     $subfield => $defaultvalue );
3264                             }
3265                         }
3266                     }
3267                     else {
3268                         $record->insert_fields_ordered(
3269                             MARC::Field->new(
3270                                 $tag, '', '', $subfield => $defaultvalue
3271                             )
3272                         );
3273                     }
3274                 }
3275             }
3276         }
3277     }
3278 }
3279
3280 1;
3281 __END__
3282
3283 =head1 AUTHOR
3284
3285 Koha Development Team <http://koha-community.org/>
3286
3287 =cut