C4/Auth.pm

   1 package C4::Auth;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use Carp qw( croak );
  23
  24 use Digest::MD5 qw( md5_base64 );
  25 use CGI::Session;
  26 use CGI::Session::ErrorHandler;
  27 use URI;
  28 use URI::QueryParam;
  29
  30 use C4::Context;
  31 use C4::Templates;    # to get the template
  32 use C4::Languages;
  33 use C4::Search::History;
  34 use Koha;
  35 use Koha::Logger;
  36 use Koha::Caches;
  37 use Koha::AuthUtils qw( get_script_name hash_password );
  38 use Koha::Auth::TwoFactorAuth;
  39 use Koha::Checkouts;
  40 use Koha::DateUtils qw( dt_from_string );
  41 use Koha::Library::Groups;
  42 use Koha::Libraries;
  43 use Koha::Cash::Registers;
  44 use Koha::Desks;
  45 use Koha::Patrons;
  46 use Koha::Patron::Consents;
  47 use List::MoreUtils qw( any );
  48 use Encode;
  49 use C4::Auth_with_shibboleth qw( shib_ok get_login_shib login_shib_url logout_shib checkpw_shib );
  50 use Net::CIDR;
  51 use C4::Log qw( logaction );
  52 use Koha::CookieManager;
  53 use Koha::Auth::Permissions;
  54 use Koha::Token;
  55
  56 # use utf8;
  57
  58 use vars qw($ldap $cas $caslogout);
  59 our (@ISA, @EXPORT_OK);
  60
  61 #NOTE: The utility of keeping the safe_exit function is that it can be easily re-defined in unit tests and plugins
  62 sub safe_exit {
  63     # It's fine for us to "exit" because CGI::Compile (used in Plack::App::WrapCGI) redefines "exit" for us automatically.
  64     # Since we only seem to use C4::Auth::safe_exit in a CGI context, we don't actually need PSGI detection at all here.
  65     exit;
  66 }
  67
  68
  69 BEGIN {
  70     C4::Context->set_remote_address;
  71
  72     require Exporter;
  73     @ISA = qw(Exporter);
  74
  75     @EXPORT_OK = qw(
  76         checkauth check_api_auth get_session check_cookie_auth checkpw checkpw_internal checkpw_hash
  77         get_all_subpermissions get_cataloguing_page_permissions get_user_subpermissions in_iprange
  78         get_template_and_user haspermission create_basic_session
  79     );
  80
  81     $ldap      = C4::Context->config('useldapserver') || 0;
  82     $cas       = C4::Context->preference('casAuthentication');
  83     $caslogout = C4::Context->preference('casLogout');
  84
  85     if ($ldap) {
  86         require C4::Auth_with_ldap;
  87         import C4::Auth_with_ldap qw(checkpw_ldap);
  88     }
  89     if ($cas) {
  90         require C4::Auth_with_cas;    # no import
  91         import C4::Auth_with_cas qw(check_api_auth_cas checkpw_cas login_cas logout_cas login_cas_url logout_if_required multipleAuth getMultipleAuth);
  92     }
  93
  94 }
  95
  96 =head1 NAME
  97
  98 C4::Auth - Authenticates Koha users
  99
 100 =head1 SYNOPSIS
 101
 102   use CGI qw ( -utf8 );
 103   use C4::Auth;
 104   use C4::Output;
 105
 106   my $query = CGI->new;
 107
 108   my ($template, $borrowernumber, $cookie)
 109     = get_template_and_user(
 110         {
 111             template_name   => "opac-main.tt",
 112             query           => $query,
 113       type            => "opac",
 114       authnotrequired => 0,
 115       flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 116   }
 117     );
 118
 119   output_html_with_http_headers $query, $cookie, $template->output;
 120
 121 =head1 DESCRIPTION
 122
 123 The main function of this module is to provide
 124 authentification. However the get_template_and_user function has
 125 been provided so that a users login information is passed along
 126 automatically. This gets loaded into the template.
 127
 128 =head1 FUNCTIONS
 129
 130 =head2 get_template_and_user
 131
 132  my ($template, $borrowernumber, $cookie)
 133      = get_template_and_user(
 134        {
 135          template_name   => "opac-main.tt",
 136          query           => $query,
 137          type            => "opac",
 138          authnotrequired => 0,
 139          flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 140        }
 141      );
 142
 143 This call passes the C<query>, C<flagsrequired> and C<authnotrequired>
 144 to C<&checkauth> (in this module) to perform authentification.
 145 See C<&checkauth> for an explanation of these parameters.
 146
 147 The C<template_name> is then used to find the correct template for
 148 the page. The authenticated users details are loaded onto the
 149 template in the logged_in_user variable (which is a Koha::Patron object). Also the
 150 C<sessionID> is passed to the template. This can be used in templates
 151 if cookies are disabled. It needs to be put as and input to every
 152 authenticated page.
 153
 154 More information on the C<gettemplate> sub can be found in the
 155 Output.pm module.
 156
 157 =cut
 158
 159 sub get_template_and_user {
 160
 161     my $in = shift;
 162     my ( $user, $cookie, $sessionID, $flags );
 163     $cookie = [];
 164
 165     my $cookie_mgr = Koha::CookieManager->new;
 166
 167     # Get shibboleth login attribute
 168     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 169     my $shib_login = $shib ? get_login_shib() : undef;
 170
 171     C4::Context->interface( $in->{type} );
 172
 173     $in->{'authnotrequired'} ||= 0;
 174
 175     # the following call includes a bad template check; might croak
 176     my $template = C4::Templates::gettemplate(
 177         $in->{'template_name'},
 178         $in->{'type'},
 179         $in->{'query'},
 180     );
 181
 182     if ( $in->{'template_name'} !~ m/maintenance/ ) {
 183         ( $user, $cookie, $sessionID, $flags ) = checkauth(
 184             $in->{'query'},
 185             $in->{'authnotrequired'},
 186             $in->{'flagsrequired'},
 187             $in->{'type'},
 188             undef,
 189             $in->{template_name},
 190         );
 191     }
 192
 193     # If we enforce GDPR and the user did not consent, redirect
 194     # Exceptions for consent page itself and SCI/SCO system
 195     if( $in->{type} eq 'opac' && $user &&
 196         $in->{'template_name'} !~ /^(opac-page|opac-patron-consent|sc[io]\/)/ &&
 197         C4::Context->preference('PrivacyPolicyConsent') eq 'Enforced' )
 198     {
 199         my $consent = Koha::Patron::Consents->search({
 200             borrowernumber => getborrowernumber($user),
 201             type => 'GDPR_PROCESSING',
 202             given_on => { '!=', undef },
 203         })->next;
 204         if( !$consent ) {
 205             print $in->{query}->redirect(-uri => '/cgi-bin/koha/opac-patron-consent.pl', -cookie => $cookie);
 206             safe_exit;
 207         }
 208     }
 209
 210     if ( $in->{type} eq 'opac' && $user ) {
 211         my $is_sco_user;
 212         if ($sessionID){
 213             my $session = get_session($sessionID);
 214             if ($session){
 215                 $is_sco_user = $session->param('sco_user');
 216             }
 217         }
 218         my $kick_out;
 219
 220         if (
 221 # If the user logged in is the SCO user and they try to go out of the SCO module,
 222 # log the user out removing the CGISESSID cookie
 223             $in->{template_name} !~ m|sco/| && $in->{template_name} !~ m|errors/errorpage.tt|
 224             && (
 225                 $is_sco_user ||
 226                 (
 227                     C4::Context->preference('AutoSelfCheckID')
 228                     && $user eq C4::Context->preference('AutoSelfCheckID')
 229                 )
 230             )
 231           )
 232         {
 233             $kick_out = 1;
 234         }
 235         elsif (
 236 # If the user logged in is the SCI user and they try to go out of the SCI module,
 237 # kick them out unless it is SCO with a valid permission
 238 # or they are a superlibrarian
 239                $in->{template_name} !~ m|sci/|
 240             && haspermission( $user, { self_check => 'self_checkin_module' } )
 241             && !(
 242                 $in->{template_name} =~ m|sco/| && haspermission(
 243                     $user, { self_check => 'self_checkout_module' }
 244                 )
 245             )
 246             && $flags && $flags->{superlibrarian} != 1
 247           )
 248         {
 249             $kick_out = 1;
 250         }
 251
 252         if ($kick_out) {
 253             $template = C4::Templates::gettemplate( 'opac-auth.tt', 'opac',
 254                 $in->{query} );
 255             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 256                 -name     => 'CGISESSID',
 257                 -value    => '',
 258                 -HttpOnly => 1,
 259                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 260                 -sameSite => 'Lax',
 261             ));
 262
 263             #NOTE: This JWT should only be used by the self-check controllers
 264             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 265                 -name     => 'JWT',
 266                 -value    => '',
 267                 -HttpOnly => 1,
 268                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 269                 -sameSite => 'Lax',
 270             ));
 271
 272             my $auth_error = $in->{query}->param('auth_error');
 273
 274             $template->param(
 275                 loginprompt => 1,
 276                 script_name => get_script_name(),
 277                 auth_error  => $auth_error,
 278             );
 279
 280             print $in->{query}->header(
 281                 {
 282                     type              => 'text/html',
 283                     charset           => 'utf-8',
 284                     cookie            => $cookie,
 285                     'X-Frame-Options' => 'SAMEORIGIN'
 286                 }
 287               ),
 288               $template->output;
 289             safe_exit;
 290         }
 291     }
 292
 293     my $borrowernumber;
 294     if ($user) {
 295
 296         # It's possible for $user to be the borrowernumber if they don't have a
 297         # userid defined (and are logging in through some other method, such
 298         # as SSL certs against an email address)
 299         my $patron;
 300         $borrowernumber = getborrowernumber($user) if defined($user);
 301         if ( !defined($borrowernumber) && defined($user) ) {
 302             $patron = Koha::Patrons->find( $user );
 303             if ($patron) {
 304                 $borrowernumber = $user;
 305
 306                 # A bit of a hack, but I don't know there's a nicer way
 307                 # to do it.
 308                 $user = $patron->firstname . ' ' . $patron->surname;
 309             }
 310         } else {
 311             $patron = Koha::Patrons->find( $borrowernumber );
 312             # FIXME What to do if $patron does not exist?
 313         }
 314
 315         # user info
 316         $template->param( loggedinusername   => $user ); # OBSOLETE - Do not reuse this in template, use logged_in_user.userid instead
 317         $template->param( loggedinusernumber => $borrowernumber ); # FIXME Should be replaced with logged_in_user.borrowernumber
 318         $template->param( logged_in_user     => $patron );
 319         $template->param( sessionID          => $sessionID );
 320
 321         if ( $in->{'type'} eq 'opac' ) {
 322             require Koha::Virtualshelves;
 323             my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 324                 {
 325                     borrowernumber => $borrowernumber,
 326                     public         => 0,
 327                 }
 328             );
 329             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 330                 {
 331                     public => 1,
 332                 }
 333             );
 334             $template->param(
 335                 some_private_shelves => $some_private_shelves,
 336                 some_public_shelves  => $some_public_shelves,
 337             );
 338         }
 339
 340         # We are going to use the $flags returned by checkauth
 341         # to create the template's parameters that will indicate
 342         # which menus the user can access.
 343         my $authz = Koha::Auth::Permissions->get_authz_from_flags({ flags => $flags });
 344         foreach my $permission ( keys %{ $authz } ){
 345             $template->param( $permission => $authz->{$permission} );
 346         }
 347
 348         # Logged-in opac search history
 349         # If the requested template is an opac one and opac search history is enabled
 350         if ( $in->{type} eq 'opac' && C4::Context->preference('EnableOpacSearchHistory') ) {
 351             my $dbh   = C4::Context->dbh;
 352             my $query = "SELECT COUNT(*) FROM search_history WHERE userid=?";
 353             my $sth   = $dbh->prepare($query);
 354             $sth->execute($borrowernumber);
 355
 356             # If at least one search has already been performed
 357             if ( $sth->fetchrow_array > 0 ) {
 358
 359                 # We show the link in opac
 360                 $template->param( EnableOpacSearchHistory => 1 );
 361             }
 362             if (C4::Context->preference('LoadSearchHistoryToTheFirstLoggedUser'))
 363             {
 364                 # And if there are searches performed when the user was not logged in,
 365                 # we add them to the logged-in search history
 366                 my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 367                 if (@recentSearches) {
 368                     my $query = q{
 369                         INSERT INTO search_history(userid, sessionid, query_desc, query_cgi, type,  total, time )
 370                         VALUES (?, ?, ?, ?, ?, ?, ?)
 371                     };
 372                     my $sth = $dbh->prepare($query);
 373                     $sth->execute( $borrowernumber,
 374                         $in->{query}->cookie("CGISESSID"),
 375                         $_->{query_desc},
 376                         $_->{query_cgi},
 377                         $_->{type} || 'biblio',
 378                         $_->{total},
 379                         $_->{time},
 380                     ) foreach @recentSearches;
 381
 382                     # clear out the search history from the session now that
 383                     # we've saved it to the database
 384                  }
 385               }
 386               C4::Search::History::set_to_session( { cgi => $in->{'query'}, search_history => [] } );
 387
 388         } elsif ( $in->{type} eq 'intranet' and C4::Context->preference('EnableSearchHistory') ) {
 389             $template->param( EnableSearchHistory => 1 );
 390         }
 391     }
 392     else {    # if this is an anonymous session, setup to display public lists...
 393
 394         # If shibboleth is enabled, and we're in an anonymous session, we should allow
 395         # the user to attempt login via shibboleth.
 396         if ($shib) {
 397             $template->param( shibbolethAuthentication => $shib,
 398                 shibbolethLoginUrl => login_shib_url( $in->{'query'} ),
 399             );
 400
 401             # If shibboleth is enabled and we have a shibboleth login attribute,
 402             # but we are in an anonymous session, then we clearly have an invalid
 403             # shibboleth koha account.
 404             if ($shib_login) {
 405                 $template->param( invalidShibLogin => '1' );
 406             }
 407         }
 408
 409         $template->param( sessionID => $sessionID );
 410
 411         if ( $in->{'type'} eq 'opac' ){
 412             require Koha::Virtualshelves;
 413             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 414                 {
 415                     public => 1,
 416                 }
 417             );
 418             $template->param(
 419                 some_public_shelves  => $some_public_shelves,
 420             );
 421
 422             # Set default branch if one has been passed by the environment.
 423             $template->param( default_branch => $ENV{OPAC_BRANCH_DEFAULT} ) if $ENV{OPAC_BRANCH_DEFAULT};
 424         }
 425     }
 426
 427     # Sysprefs disabled via URL param
 428     # Note that value must be defined in order to override via ENV
 429     foreach my $syspref (
 430         qw(
 431             OPACUserCSS
 432             OPACUserJS
 433             IntranetUserCSS
 434             IntranetUserJS
 435             OpacAdditionalStylesheet
 436             opaclayoutstylesheet
 437             intranetcolorstylesheet
 438             intranetstylesheet
 439         )
 440       )
 441     {
 442         $ENV{"OVERRIDE_SYSPREF_$syspref"} = q{}
 443           if $in->{'query'}->param("DISABLE_SYSPREF_$syspref");
 444     }
 445
 446     # Anonymous opac search history
 447     # If opac search history is enabled and at least one search has already been performed
 448     if ( C4::Context->preference('EnableOpacSearchHistory') ) {
 449         my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 450         if (@recentSearches) {
 451             $template->param( EnableOpacSearchHistory => 1 );
 452         }
 453     }
 454
 455     if ( C4::Context->preference('dateformat') ) {
 456         $template->param( dateformat => C4::Context->preference('dateformat') );
 457     }
 458
 459     $template->param(auth_forwarded_hash => scalar $in->{'query'}->param('auth_forwarded_hash'));
 460
 461     # these template parameters are set the same regardless of $in->{'type'}
 462
 463     my $minPasswordLength = C4::Context->preference('minPasswordLength');
 464     $minPasswordLength = 3 if not $minPasswordLength or $minPasswordLength < 3;
 465     $template->param(
 466         EnhancedMessagingPreferences                                       => C4::Context->preference('EnhancedMessagingPreferences'),
 467         GoogleJackets                                                      => C4::Context->preference("GoogleJackets"),
 468         OpenLibraryCovers                                                  => C4::Context->preference("OpenLibraryCovers"),
 469         KohaAdminEmailAddress                                              => "" . C4::Context->preference("KohaAdminEmailAddress"),
 470         LoginFirstname  => ( C4::Context->userenv ? C4::Context->userenv->{"firstname"} : "Bel" ),
 471         LoginSurname    => C4::Context->userenv ? C4::Context->userenv->{"surname"}      : "Inconnu",
 472         emailaddress    => C4::Context->userenv ? C4::Context->userenv->{"emailaddress"} : undef,
 473         TagsEnabled     => C4::Context->preference("TagsEnabled"),
 474         hide_marc       => C4::Context->preference("hide_marc"),
 475         item_level_itypes  => C4::Context->preference('item-level_itypes'),
 476         patronimages       => C4::Context->preference("patronimages"),
 477         singleBranchMode   => ( Koha::Libraries->search->count == 1 ),
 478         noItemTypeImages   => C4::Context->preference("noItemTypeImages"),
 479         marcflavour        => C4::Context->preference("marcflavour"),
 480         OPACBaseURL        => C4::Context->preference('OPACBaseURL'),
 481         minPasswordLength  => $minPasswordLength,
 482     );
 483     if ( $in->{'type'} eq "intranet" ) {
 484
 485         $template->param(
 486             advancedMARCEditor           => C4::Context->preference("advancedMARCEditor"),
 487             AllowMultipleCovers          => C4::Context->preference('AllowMultipleCovers'),
 488             AmazonCoverImages            => C4::Context->preference("AmazonCoverImages"),
 489             AutoLocation                 => C4::Context->preference("AutoLocation"),
 490             can_see_cataloguing_module   => haspermission( $user, get_cataloguing_page_permissions() ) ? 1 : 0,
 491             canreservefromotherbranches  => C4::Context->preference('canreservefromotherbranches'),
 492             EasyAnalyticalRecords        => C4::Context->preference('EasyAnalyticalRecords'),
 493             EnableBorrowerFiles          => C4::Context->preference('EnableBorrowerFiles'),
 494             FRBRizeEditions              => C4::Context->preference("FRBRizeEditions"),
 495             IndependentBranches          => C4::Context->preference("IndependentBranches"),
 496             intranetcolorstylesheet      => C4::Context->preference("intranetcolorstylesheet"),
 497             IntranetFavicon              => C4::Context->preference("IntranetFavicon"),
 498             IntranetmainUserblock        => C4::Context->preference("IntranetmainUserblock"),
 499             IntranetNav                  => C4::Context->preference("IntranetNav"),
 500             intranetreadinghistory       => C4::Context->preference("intranetreadinghistory"),
 501             IntranetReadingHistoryHolds  => C4::Context->preference("IntranetReadingHistoryHolds"),
 502             intranetstylesheet           => C4::Context->preference("intranetstylesheet"),
 503             IntranetUserCSS              => C4::Context->preference("IntranetUserCSS"),
 504             IntranetUserJS               => C4::Context->preference("IntranetUserJS"),
 505             LibraryName                  => C4::Context->preference("LibraryName"),
 506             LocalCoverImages             => C4::Context->preference('LocalCoverImages'),
 507             OPACLocalCoverImages         => C4::Context->preference('OPACLocalCoverImages'),
 508             PatronAutoComplete           => C4::Context->preference("PatronAutoComplete"),
 509             pending_checkout_notes       => Koha::Checkouts->search( { noteseen => 0 } ),
 510             plugins_enabled              => C4::Context->config("enable_plugins"),
 511             StaffSerialIssueDisplayCount => C4::Context->preference("StaffSerialIssueDisplayCount"),
 512             UseCourseReserves            => C4::Context->preference("UseCourseReserves"),
 513             useDischarge                 => C4::Context->preference('useDischarge'),
 514             virtualshelves               => C4::Context->preference("virtualshelves"),
 515         );
 516     }
 517     else {
 518         warn "template type should be OPAC, here it is=[" . $in->{'type'} . "]" unless ( $in->{'type'} eq 'opac' );
 519
 520         #TODO : replace LibraryName syspref with 'system name', and remove this html processing
 521         my $LibraryNameTitle = C4::Context->preference("LibraryName");
 522         $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
 523         $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
 524
 525         # clean up the busc param in the session
 526         # if the page is not opac-detail and not the "add to list" page
 527         # and not the "edit comments" page
 528         if ( C4::Context->preference("OpacBrowseResults")
 529             && $in->{'template_name'} =~ /opac-(.+)\.(?:tt|tmpl)$/ ) {
 530             my $pagename = $1;
 531             unless ( $pagename =~ /^(?:MARC|ISBD)?detail$/
 532                 or $pagename =~ /^showmarc$/
 533                 or $pagename =~ /^addbybiblionumber$/
 534                 or $pagename =~ /^review$/ )
 535             {
 536                 my $sessionSearch = get_session( $sessionID );
 537                 $sessionSearch->clear( ["busc"] ) if $sessionSearch;
 538             }
 539         }
 540
 541         # variables passed from CGI: opac_css_override and opac_search_limits.
 542         my $opac_search_limit   = $ENV{'OPAC_SEARCH_LIMIT'};
 543         my $opac_limit_override = $ENV{'OPAC_LIMIT_OVERRIDE'};
 544         my $opac_name           = '';
 545         if (
 546             ( $opac_limit_override && $opac_search_limit && $opac_search_limit =~ /branch:([\w-]+)/ ) ||
 547             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /branch:([\w-]+)/ ) ||
 548             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /multibranchlimit:(\w+)/ )
 549           ) {
 550             $opac_name = $1;    # opac_search_limit is a branch, so we use it.
 551         } elsif ( $in->{'query'}->param('multibranchlimit') ) {
 552             $opac_name = $in->{'query'}->param('multibranchlimit');
 553         } elsif ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv && C4::Context->userenv->{'branch'} ) {
 554             $opac_name = C4::Context->userenv->{'branch'};
 555         }
 556
 557         # Decide if the patron can make suggestions in the OPAC
 558         my $can_make_suggestions;
 559         if ( C4::Context->preference('Suggestion') && C4::Context->preference('AnonSuggestions') ) {
 560             $can_make_suggestions = 1;
 561         } elsif ( C4::Context->userenv && C4::Context->userenv->{'number'} ) {
 562             $can_make_suggestions = Koha::Patrons->find(C4::Context->userenv->{'number'})->category->can_make_suggestions;
 563         }
 564
 565         my @search_groups = Koha::Library::Groups->get_search_groups({ interface => 'opac' })->as_list;
 566         $template->param(
 567             AnonSuggestions                       => "" . C4::Context->preference("AnonSuggestions"),
 568             LibrarySearchGroups                   => \@search_groups,
 569             opac_name                             => $opac_name,
 570             LibraryName                           => "" . C4::Context->preference("LibraryName"),
 571             LibraryNameTitle                      => "" . $LibraryNameTitle,
 572             OPACAmazonCoverImages                 => C4::Context->preference("OPACAmazonCoverImages"),
 573             OPACFRBRizeEditions                   => C4::Context->preference("OPACFRBRizeEditions"),
 574             OpacHighlightedWords                  => C4::Context->preference("OpacHighlightedWords"),
 575             OPACShelfBrowser                      => "" . C4::Context->preference("OPACShelfBrowser"),
 576             OPACURLOpenInNewWindow                => "" . C4::Context->preference("OPACURLOpenInNewWindow"),
 577             OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
 578             opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
 579             opac_search_limit                     => $opac_search_limit,
 580             opac_limit_override                   => $opac_limit_override,
 581             OpacBrowser                           => C4::Context->preference("OpacBrowser"),
 582             OpacCloud                             => C4::Context->preference("OpacCloud"),
 583             OpacKohaUrl                           => C4::Context->preference("OpacKohaUrl"),
 584             OpacPasswordChange                    => C4::Context->preference("OpacPasswordChange"),
 585             OPACPatronDetails                     => C4::Context->preference("OPACPatronDetails"),
 586             OPACPrivacy                           => C4::Context->preference("OPACPrivacy"),
 587             OPACFinesTab                          => C4::Context->preference("OPACFinesTab"),
 588             OpacTopissue                          => C4::Context->preference("OpacTopissue"),
 589             'Version'                             => C4::Context->preference('Version'),
 590             hidelostitems                         => C4::Context->preference("hidelostitems"),
 591             mylibraryfirst                        => ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv ) ? C4::Context->userenv->{'branch'} : '',
 592             opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
 593             OpacFavicon                           => C4::Context->preference("OpacFavicon"),
 594             opaclanguagesdisplay                  => "" . C4::Context->preference("opaclanguagesdisplay"),
 595             opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
 596             opacuserlogin                         => "" . C4::Context->preference("opacuserlogin"),
 597             OpenLibrarySearch                     => C4::Context->preference("OpenLibrarySearch"),
 598             ShowReviewer                          => C4::Context->preference("ShowReviewer"),
 599             ShowReviewerPhoto                     => C4::Context->preference("ShowReviewerPhoto"),
 600             suggestion                            => $can_make_suggestions,
 601             virtualshelves                        => "" . C4::Context->preference("virtualshelves"),
 602             OPACSerialIssueDisplayCount           => C4::Context->preference("OPACSerialIssueDisplayCount"),
 603             SyndeticsClientCode                   => C4::Context->preference("SyndeticsClientCode"),
 604             SyndeticsEnabled                      => C4::Context->preference("SyndeticsEnabled"),
 605             SyndeticsCoverImages                  => C4::Context->preference("SyndeticsCoverImages"),
 606             SyndeticsTOC                          => C4::Context->preference("SyndeticsTOC"),
 607             SyndeticsSummary                      => C4::Context->preference("SyndeticsSummary"),
 608             SyndeticsEditions                     => C4::Context->preference("SyndeticsEditions"),
 609             SyndeticsExcerpt                      => C4::Context->preference("SyndeticsExcerpt"),
 610             SyndeticsReviews                      => C4::Context->preference("SyndeticsReviews"),
 611             SyndeticsAuthorNotes                  => C4::Context->preference("SyndeticsAuthorNotes"),
 612             SyndeticsAwards                       => C4::Context->preference("SyndeticsAwards"),
 613             SyndeticsSeries                       => C4::Context->preference("SyndeticsSeries"),
 614             SyndeticsCoverImageSize               => C4::Context->preference("SyndeticsCoverImageSize"),
 615             OPACLocalCoverImages                  => C4::Context->preference("OPACLocalCoverImages"),
 616             PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
 617             PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
 618             useDischarge                 => C4::Context->preference('useDischarge'),
 619         );
 620
 621         $template->param( OpacPublic => '1' ) if ( $user || C4::Context->preference("OpacPublic") );
 622     }
 623
 624     # Check if we were asked using parameters to force a specific language
 625     if ( defined $in->{'query'}->param('language') ) {
 626
 627         # Extract the language, let C4::Languages::getlanguage choose
 628         # what to do
 629         my $language = C4::Languages::getlanguage( $in->{'query'} );
 630         my $languagecookie = C4::Templates::getlanguagecookie( $in->{'query'}, $language );
 631         $cookie = $cookie_mgr->replace_in_list( $cookie, $languagecookie );
 632     }
 633
 634     return ( $template, $borrowernumber, $cookie, $flags );
 635 }
 636
 637 =head2 checkauth
 638
 639   ($userid, $cookie, $sessionID) = &checkauth($query, $noauth, $flagsrequired, $type);
 640
 641 Verifies that the user is authorized to run this script.  If
 642 the user is authorized, a (userid, cookie, session-id, flags)
 643 quadruple is returned.  If the user is not authorized but does
 644 not have the required privilege (see $flagsrequired below), it
 645 displays an error page and exits.  Otherwise, it displays the
 646 login page and exits.
 647
 648 Note that C<&checkauth> will return if and only if the user
 649 is authorized, so it should be called early on, before any
 650 unfinished operations (e.g., if you've opened a file, then
 651 C<&checkauth> won't close it for you).
 652
 653 C<$query> is the CGI object for the script calling C<&checkauth>.
 654
 655 The C<$noauth> argument is optional. If it is set, then no
 656 authorization is required for the script.
 657
 658 C<&checkauth> fetches user and session information from C<$query> and
 659 ensures that the user is authorized to run scripts that require
 660 authorization.
 661
 662 The C<$flagsrequired> argument specifies the required privileges
 663 the user must have if the username and password are correct.
 664 It should be specified as a reference-to-hash; keys in the hash
 665 should be the "flags" for the user, as specified in the Members
 666 intranet module. Any key specified must correspond to a "flag"
 667 in the userflags table. E.g., { circulate => 1 } would specify
 668 that the user must have the "circulate" privilege in order to
 669 proceed. To make sure that access control is correct, the
 670 C<$flagsrequired> parameter must be specified correctly.
 671
 672 Koha also has a concept of sub-permissions, also known as
 673 granular permissions.  This makes the value of each key
 674 in the C<flagsrequired> hash take on an additional
 675 meaning, i.e.,
 676
 677  1
 678
 679 The user must have access to all subfunctions of the module
 680 specified by the hash key.
 681
 682  *
 683
 684 The user must have access to at least one subfunction of the module
 685 specified by the hash key.
 686
 687  specific permission, e.g., 'export_catalog'
 688
 689 The user must have access to the specific subfunction list, which
 690 must correspond to a row in the permissions table.
 691
 692 The C<$type> argument specifies whether the template should be
 693 retrieved from the opac or intranet directory tree.  "opac" is
 694 assumed if it is not specified; however, if C<$type> is specified,
 695 "intranet" is assumed if it is not "opac".
 696
 697 If C<$query> does not have a valid session ID associated with it
 698 (i.e., the user has not logged in) or if the session has expired,
 699 C<&checkauth> presents the user with a login page (from the point of
 700 view of the original script, C<&checkauth> does not return). Once the
 701 user has authenticated, C<&checkauth> restarts the original script
 702 (this time, C<&checkauth> returns).
 703
 704 The login page is provided using a HTML::Template, which is set in the
 705 systempreferences table or at the top of this file. The variable C<$type>
 706 selects which template to use, either the opac or the intranet
 707 authentification template.
 708
 709 C<&checkauth> returns a user ID, a cookie, and a session ID. The
 710 cookie should be sent back to the browser; it verifies that the user
 711 has authenticated.
 712
 713 =cut
 714
 715 sub _version_check {
 716     my $type  = shift;
 717     my $query = shift;
 718     my $version;
 719
 720     # If version syspref is unavailable, it means Koha is being installed,
 721     # and so we must redirect to OPAC maintenance page or to the WebInstaller
 722     # also, if OpacMaintenance is ON, OPAC should redirect to maintenance
 723     if ( C4::Context->preference('OpacMaintenance') && $type eq 'opac' ) {
 724         warn "OPAC Install required, redirecting to maintenance";
 725         print $query->redirect("/cgi-bin/koha/maintenance.pl");
 726         safe_exit;
 727     }
 728     unless ( $version = C4::Context->preference('Version') ) {    # assignment, not comparison
 729         if ( $type ne 'opac' ) {
 730             warn "Install required, redirecting to Installer";
 731             print $query->redirect("/cgi-bin/koha/installer/install.pl");
 732         } else {
 733             warn "OPAC Install required, redirecting to maintenance";
 734             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 735         }
 736         safe_exit;
 737     }
 738
 739     # check that database and koha version are the same
 740     # there is no DB version, it's a fresh install,
 741     # go to web installer
 742     # there is a DB version, compare it to the code version
 743     my $kohaversion = Koha::version();
 744
 745     # remove the 3 last . to have a Perl number
 746     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 747     Koha::Logger->get->debug("kohaversion : $kohaversion");
 748     if ( $version < $kohaversion ) {
 749         my $warning = "Database update needed, redirecting to %s. Database is $version and Koha is $kohaversion";
 750         if ( $type ne 'opac' ) {
 751             warn sprintf( $warning, 'Installer' );
 752             print $query->redirect("/cgi-bin/koha/installer/install.pl?step=1&op=updatestructure");
 753         } else {
 754             warn sprintf( "OPAC: " . $warning, 'maintenance' );
 755             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 756         }
 757         safe_exit;
 758     }
 759 }
 760
 761 sub _timeout_syspref {
 762     my $default_timeout = 600;
 763     my $timeout = C4::Context->preference('timeout') || $default_timeout;
 764
 765     # value in days, convert in seconds
 766     if ( $timeout =~ /^(\d+)[dD]$/ ) {
 767         $timeout = $1 * 86400;
 768     }
 769     # value in hours, convert in seconds
 770     elsif ( $timeout =~ /^(\d+)[hH]$/ ) {
 771         $timeout = $1 * 3600;
 772     }
 773     elsif ( $timeout !~ m/^\d+$/ ) {
 774         warn "The value of the system preference 'timeout' is not correct, defaulting to $default_timeout";
 775         $timeout = $default_timeout;
 776     }
 777
 778     return $timeout;
 779 }
 780
 781 sub checkauth {
 782     my $query = shift;
 783
 784     # Get shibboleth login attribute
 785     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 786     my $shib_login = $shib ? get_login_shib() : undef;
 787
 788     # $authnotrequired will be set for scripts which will run without authentication
 789     my $authnotrequired = shift;
 790     my $flagsrequired   = shift;
 791     my $type            = shift;
 792     my $emailaddress    = shift;
 793     my $template_name   = shift;
 794     $type = 'opac' unless $type;
 795
 796     if ( $type eq 'opac' && !C4::Context->preference("OpacPublic") ) {
 797         my @allowed_scripts_for_private_opac = qw(
 798             opac-memberentry.tt
 799             opac-registration-email-sent.tt
 800             opac-registration-confirmation.tt
 801             opac-memberentry-update-submitted.tt
 802             opac-password-recovery.tt
 803             opac-reset-password.tt
 804             ilsdi.tt
 805         );
 806         $authnotrequired = 0 unless grep { $_ eq $template_name }
 807             @allowed_scripts_for_private_opac;
 808     }
 809
 810     my $timeout = _timeout_syspref();
 811
 812     my $cookie_mgr = Koha::CookieManager->new;
 813
 814     _version_check( $type, $query );
 815
 816     # state variables
 817     my $loggedin = 0;
 818     my $auth_state = 'failed';
 819     my %info;
 820     my ( $userid, $cookie, $sessionID, $flags );
 821     $cookie = [];
 822     my $logout = $query->param('logout.x');
 823
 824     my $anon_search_history;
 825     my $cas_ticket = '';
 826     # This parameter is the name of the CAS server we want to authenticate against,
 827     # when using authentication against multiple CAS servers, as configured in Auth_cas_servers.yaml
 828     my $casparam = $query->param('cas');
 829     my $q_userid = $query->param('userid') // '';
 830
 831     my $session;
 832     my $invalid_otp_token;
 833     my $require_2FA =
 834       ( $type ne "opac" # Only available for the staff interface
 835           && C4::Context->preference('TwoFactorAuthentication') ne "disabled" ) # If "enabled" or "enforced"
 836       ? 1 : 0;
 837
 838     # Basic authentication is incompatible with the use of Shibboleth,
 839     # as Shibboleth may return REMOTE_USER as a Shibboleth attribute,
 840     # and it may not be the attribute we want to use to match the koha login.
 841     #
 842     # Also, do not consider an empty REMOTE_USER.
 843     #
 844     # Finally, after those tests, we can assume (although if it would be better with
 845     # a syspref) that if we get a REMOTE_USER, that's from basic authentication,
 846     # and we can affect it to $userid.
 847     if ( !$shib and defined( $ENV{'REMOTE_USER'} ) and $ENV{'REMOTE_USER'} ne '' and $userid = $ENV{'REMOTE_USER'} ) {
 848
 849         # Using Basic Authentication, no cookies required
 850         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 851             -name     => 'CGISESSID',
 852             -value    => '',
 853             -HttpOnly => 1,
 854             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 855             -sameSite => 'Lax',
 856         ));
 857         $loggedin = 1;
 858     }
 859     elsif ( $emailaddress) {
 860         # the Google OpenID Connect passes an email address
 861     }
 862     elsif ( $sessionID = $query->cookie("CGISESSID") ) {    # assignment, not comparison
 863         my ( $return, $more_info );
 864         # NOTE: $flags in the following call is still undefined !
 865         ( $return, $session, $more_info ) = check_cookie_auth( $sessionID, $flags,
 866             { remote_addr => $ENV{REMOTE_ADDR}, skip_version_check => 1 }
 867         );
 868
 869         if ( $return eq 'ok' || $return eq 'additional-auth-needed' ) {
 870             $userid = $session->param('id');
 871         }
 872
 873         $auth_state =
 874             $return eq 'ok'                     ? 'completed'
 875           : $return eq 'additional-auth-needed' ? 'additional-auth-needed'
 876           :                                       'failed';
 877
 878         # We are at the second screen if the waiting-for-2FA is set in session
 879         # and otp_token param has been passed
 880         if (   $require_2FA
 881             && $auth_state eq 'additional-auth-needed'
 882             && ( my $otp_token = $query->param('otp_token') ) )
 883         {
 884             my $patron    = Koha::Patrons->find( { userid => $userid } );
 885             my $auth      = Koha::Auth::TwoFactorAuth->new( { patron => $patron } );
 886             my $verified = $auth->verify($otp_token);
 887             $auth->clear;
 888             if ( $verified ) {
 889                 # The token is correct, the user is fully logged in!
 890                 $auth_state = 'completed';
 891                 $session->param( 'waiting-for-2FA', 0 );
 892                 $session->param( 'waiting-for-2FA-setup', 0 );
 893
 894                # This is an ugly trick to pass the test
 895                # $query->param('koha_login_context') && ( $q_userid ne $userid )
 896                # few lines later
 897                 $q_userid = $userid;
 898             }
 899             else {
 900                 $invalid_otp_token = 1;
 901             }
 902         }
 903
 904         if ( $auth_state eq 'completed' ) {
 905             Koha::Logger->get->debug(sprintf "AUTH_SESSION: (%s)\t%s %s - %s", map { $session->param($_) || q{} } qw(cardnumber firstname surname branch));
 906
 907             if ( ( $query->param('koha_login_context') && ( $q_userid ne $userid ) )
 908                 || ( $cas && $query->param('ticket') && !C4::Context->userenv->{'id'} )
 909                 || ( $shib && $shib_login && !$logout && !C4::Context->userenv->{'id'} )
 910             ) {
 911
 912                 #if a user enters an id ne to the id in the current session, we need to log them in...
 913                 #first we need to clear the anonymous session...
 914                 $anon_search_history = $session->param('search_history');
 915                 $session->delete();
 916                 $session->flush;
 917                 $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 918                 C4::Context::_unset_userenv($sessionID);
 919                 $sessionID = undef;
 920                 undef $userid; # IMPORTANT: this assures us a new session in code below
 921                 $auth_state = 'failed';
 922             } elsif (!$logout) {
 923
 924                 $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 925                     -name     => 'CGISESSID',
 926                     -value    => $session->id,
 927                     -HttpOnly => 1,
 928                     -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 929                     -sameSite => 'Lax',
 930                 ));
 931
 932                 $flags = haspermission( $userid, $flagsrequired );
 933                 unless ( $flags ) {
 934                     $auth_state = 'failed';
 935                     $info{'nopermission'} = 1;
 936                 }
 937             }
 938         } elsif ( !$logout ) {
 939             if ( $return eq 'expired' ) {
 940                 $info{timed_out} = 1;
 941             } elsif ( $return eq 'restricted' ) {
 942                 $info{oldip}        = $more_info->{old_ip};
 943                 $info{newip}        = $more_info->{new_ip};
 944                 $info{different_ip} = 1;
 945             } elsif ( $return eq 'password_expired' ) {
 946                 $info{password_has_expired} = 1;
 947             }
 948         }
 949     }
 950
 951     if ( $auth_state eq 'failed' || $logout ) {
 952         $sessionID = undef;
 953         $userid    = undef;
 954     }
 955
 956     if ($logout) {
 957
 958         # voluntary logout the user
 959         # check wether the user was using their shibboleth session or a local one
 960         my $shibSuccess = C4::Context->userenv ? C4::Context->userenv->{'shibboleth'} : undef;
 961         if ( $session ) {
 962             $session->delete();
 963             $session->flush;
 964         }
 965         C4::Context::_unset_userenv($sessionID);
 966         $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 967
 968         if ($cas and $caslogout) {
 969             logout_cas($query, $type);
 970         }
 971
 972         # If we are in a shibboleth session (shibboleth is enabled, a shibboleth match attribute is set and matches koha matchpoint)
 973         if ( $shib and $shib_login and $shibSuccess) {
 974             logout_shib($query);
 975         }
 976
 977         $session   = undef;
 978         $auth_state = 'logout';
 979     }
 980
 981     unless ( $userid ) {
 982         #we initiate a session prior to checking for a username to allow for anonymous sessions...
 983         if( !$session or !$sessionID ) { # if we cleared sessionID, we need a new session
 984             $session = get_session() or die "Auth ERROR: Cannot get_session()";
 985         }
 986
 987         # Save anonymous search history in new session so it can be retrieved
 988         # by get_template_and_user to store it in user's search history after
 989         # a successful login.
 990         if ($anon_search_history) {
 991             $session->param( 'search_history', $anon_search_history );
 992         }
 993
 994         $sessionID = $session->id;
 995         C4::Context->_new_userenv($sessionID);
 996         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 997             -name     => 'CGISESSID',
 998             -value    => $sessionID,
 999             -HttpOnly => 1,
1000             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1001             -sameSite => 'Lax',
1002         ));
1003         my $pki_field = C4::Context->preference('AllowPKIAuth');
1004         if ( !defined($pki_field) ) {
1005             print STDERR "ERROR: Missing system preference AllowPKIAuth.\n";
1006             $pki_field = 'None';
1007         }
1008         if ( ( $cas && $query->param('ticket') )
1009             || $q_userid
1010             || ( $shib && $shib_login )
1011             || $pki_field ne 'None'
1012             || $emailaddress )
1013         {
1014             my $password    = $query->param('password');
1015             my $shibSuccess = 0;
1016             my ( $return, $cardnumber );
1017
1018             # If shib is enabled and we have a shib login, does the login match a valid koha user
1019             if ( $shib && $shib_login ) {
1020                 my $retuserid;
1021
1022                 # Do not pass password here, else shib will not be checked in checkpw.
1023                 ( $return, $cardnumber, $retuserid ) = checkpw( $q_userid, undef, $query );
1024                 $userid      = $retuserid;
1025                 $shibSuccess = $return;
1026                 $info{'invalidShibLogin'} = 1 unless ($return);
1027             }
1028
1029             # If shib login and match were successful, skip further login methods
1030             unless ($shibSuccess) {
1031                 if ( $cas && $query->param('ticket') ) {
1032                     my $retuserid;
1033                     ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1034                       checkpw( $userid, $password, $query, $type );
1035                     $userid = $retuserid;
1036                     $info{'invalidCasLogin'} = 1 unless ($return);
1037                 }
1038
1039                 elsif ( $emailaddress ) {
1040                     my $value = $emailaddress;
1041
1042                     # If we're looking up the email, there's a chance that the person
1043                     # doesn't have a userid. So if there is none, we pass along the
1044                     # borrower number, and the bits of code that need to know the user
1045                     # ID will have to be smart enough to handle that.
1046                     my $patrons = Koha::Patrons->search({ email => $value });
1047                     if ($patrons->count) {
1048
1049                         # First the userid, then the borrowernum
1050                         my $patron = $patrons->next;
1051                         $value = $patron->userid || $patron->borrowernumber;
1052                     } else {
1053                         undef $value;
1054                     }
1055                     $return = $value ? 1 : 0;
1056                     $userid = $value;
1057                 }
1058
1059                 elsif (
1060                     ( $pki_field eq 'Common Name' && $ENV{'SSL_CLIENT_S_DN_CN'} )
1061                     || ( $pki_field eq 'emailAddress'
1062                         && $ENV{'SSL_CLIENT_S_DN_Email'} )
1063                   )
1064                 {
1065                     my $value;
1066                     if ( $pki_field eq 'Common Name' ) {
1067                         $value = $ENV{'SSL_CLIENT_S_DN_CN'};
1068                     }
1069                     elsif ( $pki_field eq 'emailAddress' ) {
1070                         $value = $ENV{'SSL_CLIENT_S_DN_Email'};
1071
1072                         # If we're looking up the email, there's a chance that the person
1073                         # doesn't have a userid. So if there is none, we pass along the
1074                         # borrower number, and the bits of code that need to know the user
1075                         # ID will have to be smart enough to handle that.
1076                         my $patrons = Koha::Patrons->search({ email => $value });
1077                         if ($patrons->count) {
1078
1079                             # First the userid, then the borrowernum
1080                             my $patron = $patrons->next;
1081                             $value = $patron->userid || $patron->borrowernumber;
1082                         } else {
1083                             undef $value;
1084                         }
1085                     }
1086
1087                     $return = $value ? 1 : 0;
1088                     $userid = $value;
1089
1090                 }
1091                 else {
1092                     my $retuserid;
1093                     my $request_method = $query->request_method // q{};
1094
1095                     if (
1096                         $request_method eq 'POST'
1097                         || ( C4::Context->preference('AutoSelfCheckID')
1098                             && $q_userid eq C4::Context->preference('AutoSelfCheckID') )
1099                       )
1100                     {
1101
1102                         ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1103                           checkpw( $q_userid, $password, $query, $type );
1104                         $userid = $retuserid if ($retuserid);
1105                         $info{'invalid_username_or_password'} = 1 unless ($return);
1106                     }
1107                 }
1108             }
1109
1110             # If shib configured and shibOnly enabled, we should ignore anything other than a shibboleth type login.
1111             if (
1112                    $shib
1113                 && !$shibSuccess
1114                 && (
1115                     (
1116                         ( $type eq 'opac' )
1117                         && C4::Context->preference('OPACShibOnly')
1118                     )
1119                     || ( ( $type ne 'opac' )
1120                         && C4::Context->preference('staffShibOnly') )
1121                 )
1122               )
1123             {
1124                 $return = 0;
1125             }
1126
1127             # $return: 1 = valid user
1128             if( $return && $return > 0 ) {
1129
1130                 if ( $flags = haspermission( $userid, $flagsrequired ) ) {
1131                     $auth_state = "logged_in";
1132                 }
1133                 else {
1134                     $auth_state = 'failed';
1135                     # FIXME We could add $return = 0; or even delete the session?
1136                     # Currently return == 1 and we will fill session info later on,
1137                     # although we do present an authorization failure. (Yes, the
1138                     # authentication was actually correct.)
1139                     $info{'nopermission'} = 1;
1140                     C4::Context::_unset_userenv($sessionID);
1141                 }
1142                 my ( $borrowernumber, $firstname, $surname, $userflags,
1143                     $branchcode, $branchname, $emailaddress, $desk_id,
1144                     $desk_name, $register_id, $register_name );
1145
1146                 if ( $return == 1 ) {
1147                     my $select = "
1148                     SELECT borrowernumber, firstname, surname, flags, borrowers.branchcode,
1149                     branches.branchname    as branchname, email
1150                     FROM borrowers
1151                     LEFT JOIN branches on borrowers.branchcode=branches.branchcode
1152                     ";
1153                     my $dbh = C4::Context->dbh;
1154                     my $sth = $dbh->prepare("$select where userid=?");
1155                     $sth->execute($userid);
1156                     unless ( $sth->rows ) {
1157                         $sth = $dbh->prepare("$select where cardnumber=?");
1158                         $sth->execute($cardnumber);
1159
1160                         unless ( $sth->rows ) {
1161                             $sth->execute($userid);
1162                         }
1163                     }
1164                     if ( $sth->rows ) {
1165                         ( $borrowernumber, $firstname, $surname, $userflags,
1166                             $branchcode, $branchname, $emailaddress ) = $sth->fetchrow;
1167                     }
1168
1169                     # launch a sequence to check if we have a ip for the branch, i
1170                     # if we have one we replace the branchcode of the userenv by the branch bound in the ip.
1171
1172                     my $ip = $ENV{'REMOTE_ADDR'};
1173
1174                     # if they specify at login, use that
1175                     my $patron = Koha::Patrons->find({userid => $userid});
1176                     if ( $query->param('branch')  && ( haspermission($userid, {  'loggedinlibrary'=> 1 }) || $patron->is_superlibrarian ) ) {
1177                         $branchcode = $query->param('branch');
1178                         my $library = Koha::Libraries->find($branchcode);
1179                         $branchname = $library? $library->branchname: '';
1180                     }
1181                     if ( $query->param('desk_id') ) {
1182                         $desk_id = $query->param('desk_id');
1183                         my $desk = Koha::Desks->find($desk_id);
1184                         $desk_name = $desk ? $desk->desk_name : '';
1185                     }
1186                     if ( C4::Context->preference('UseCashRegisters') ) {
1187                         my $register =
1188                           $query->param('register_id')
1189                           ? Koha::Cash::Registers->find($query->param('register_id'))
1190                           : Koha::Cash::Registers->search(
1191                             { branch => $branchcode, branch_default => 1 },
1192                             { rows   => 1 } )->single;
1193                         $register_id   = $register->id   if ($register);
1194                         $register_name = $register->name if ($register);
1195                     }
1196                     my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1197                     if ( $type ne 'opac' and C4::Context->preference('AutoLocation') ) {
1198
1199                         # we have to check they are coming from the right ip range
1200                         my $domain = $branches->{$branchcode}->{'branchip'};
1201                         $domain =~ s|\.\*||g;
1202                         if ( $ip !~ /^$domain/ ) {
1203                             $loggedin = 0;
1204                             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1205                                 -name     => 'CGISESSID',
1206                                 -value    => '',
1207                                 -HttpOnly => 1,
1208                                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1209                                 -sameSite => 'Lax',
1210                             ));
1211                             $info{'wrongip'} = 1;
1212                         }
1213                     }
1214
1215                     foreach my $br ( keys %$branches ) {
1216
1217                         #     now we work with the treatment of ip
1218                         my $domain = $branches->{$br}->{'branchip'};
1219                         if ( $domain && $ip =~ /^$domain/ ) {
1220                             $branchcode = $branches->{$br}->{'branchcode'};
1221
1222                             # new op dev : add the branchname to the cookie
1223                             $branchname    = $branches->{$br}->{'branchname'};
1224                         }
1225                     }
1226
1227                     my $is_sco_user = 0;
1228                     if ( $query->param('sco_user_login') && ( $query->param('sco_user_login') eq '1' ) ){
1229                         $is_sco_user = 1;
1230                     }
1231
1232                     $session->param( 'number',       $borrowernumber );
1233                     $session->param( 'id',           $userid );
1234                     $session->param( 'cardnumber',   $cardnumber );
1235                     $session->param( 'firstname',    $firstname );
1236                     $session->param( 'surname',      $surname );
1237                     $session->param( 'branch',       $branchcode );
1238                     $session->param( 'branchname',   $branchname );
1239                     $session->param( 'desk_id',      $desk_id);
1240                     $session->param( 'desk_name',     $desk_name);
1241                     $session->param( 'flags',        $userflags );
1242                     $session->param( 'emailaddress', $emailaddress );
1243                     $session->param( 'ip',           $session->remote_addr() );
1244                     $session->param( 'lasttime',     time() );
1245                     $session->param( 'interface',    $type);
1246                     $session->param( 'shibboleth',   $shibSuccess );
1247                     $session->param( 'register_id',  $register_id );
1248                     $session->param( 'register_name',  $register_name );
1249                     $session->param( 'sco_user', $is_sco_user );
1250                 }
1251                 $session->param('cas_ticket', $cas_ticket) if $cas_ticket;
1252                 C4::Context->set_userenv(
1253                     $session->param('number'),       $session->param('id'),
1254                     $session->param('cardnumber'),   $session->param('firstname'),
1255                     $session->param('surname'),      $session->param('branch'),
1256                     $session->param('branchname'),   $session->param('flags'),
1257                     $session->param('emailaddress'), $session->param('shibboleth'),
1258                     $session->param('desk_id'),      $session->param('desk_name'),
1259                     $session->param('register_id'),  $session->param('register_name')
1260                 );
1261
1262             }
1263             # $return: 0 = invalid user
1264             # reset to anonymous session
1265             else {
1266                 if ($userid) {
1267                     $info{'invalid_username_or_password'} = 1;
1268                     C4::Context::_unset_userenv($sessionID);
1269                 }
1270                 $session->param( 'lasttime', time() );
1271                 $session->param( 'ip',       $session->remote_addr() );
1272                 $session->param( 'sessiontype', 'anon' );
1273                 $session->param( 'interface', $type);
1274             }
1275         }    # END if ( $q_userid
1276         elsif ( $type eq "opac" ) {
1277
1278             # anonymous sessions are created only for the OPAC
1279
1280             # setting a couple of other session vars...
1281             $session->param( 'ip',          $session->remote_addr() );
1282             $session->param( 'lasttime',    time() );
1283             $session->param( 'sessiontype', 'anon' );
1284             $session->param( 'interface', $type);
1285         }
1286         $session->flush;
1287     }    # END unless ($userid)
1288
1289
1290     if ( $auth_state eq 'logged_in' ) {
1291         $auth_state = 'completed';
1292
1293         # Auth is completed unless an additional auth is needed
1294         if ( $require_2FA ) {
1295             my $patron = Koha::Patrons->find({userid => $userid});
1296             if ( C4::Context->preference('TwoFactorAuthentication') eq "enforced" && $patron->auth_method eq 'password' ) {
1297                 $auth_state = 'setup-additional-auth-needed';
1298                 $session->param('waiting-for-2FA-setup', 1);
1299                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1300             } elsif ( $patron->auth_method eq 'two-factor' ) {
1301                 # Ask for the OTP token
1302                 $auth_state = 'additional-auth-needed';
1303                 $session->param('waiting-for-2FA', 1);
1304                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1305             }
1306         }
1307     }
1308
1309     # finished authentification, now respond
1310     if ( $auth_state eq 'completed' || $authnotrequired ) {
1311         # successful login
1312         unless (@$cookie) {
1313             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1314                 -name     => 'CGISESSID',
1315                 -value    => '',
1316                 -HttpOnly => 1,
1317                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1318                 -sameSite => 'Lax',
1319             ));
1320         }
1321
1322         my $patron = $userid ? Koha::Patrons->find({ userid => $userid }) : undef;
1323         $patron->update_lastseen('login') if $patron;
1324
1325         # In case, that this request was a login attempt, we want to prevent that users can repost the opac login
1326         # request. We therefore redirect the user to the requested page again without the login parameters.
1327         # See Post/Redirect/Get (PRG) design pattern: https://en.wikipedia.org/wiki/Post/Redirect/Get
1328         if ( $type eq "opac" && $query->param('koha_login_context') && $query->param('koha_login_context') ne 'sco' && $query->param('password') && $query->param('userid') ) {
1329             my $uri = URI->new($query->url(-relative=>1, -query_string=>1));
1330             $uri->query_param_delete('userid');
1331             $uri->query_param_delete('password');
1332             $uri->query_param_delete('koha_login_context');
1333             print $query->redirect(-uri => $uri->as_string, -cookie => $cookie, -status=>'303 See other');
1334             safe_exit;
1335         }
1336
1337         return ( $userid, $cookie, $sessionID, $flags );
1338     }
1339
1340     #
1341     #
1342     # AUTH rejected, show the login/password template, after checking the DB.
1343     #
1344     #
1345
1346     my $patron = Koha::Patrons->find({ userid => $q_userid }); # Not necessary logged in!
1347
1348     # get the inputs from the incoming query
1349     my @inputs = ();
1350     my @inputs_to_clean = qw( userid password ticket logout.x otp_token );
1351     foreach my $name ( param $query) {
1352         next if grep { $name eq $_ } @inputs_to_clean;
1353         my @value = $query->multi_param($name);
1354         push @inputs, { name => $name, value => $_ } for @value;
1355     }
1356
1357     my $LibraryNameTitle = C4::Context->preference("LibraryName");
1358     $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
1359     $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
1360
1361     my $auth_template_name = ( $type eq 'opac' ) ? 'opac-auth.tt' : 'auth.tt';
1362     my $auth_error = $query->param('auth_error');
1363     my $template = C4::Templates::gettemplate( $auth_template_name, $type, $query );
1364     $template->param(
1365         login                                 => 1,
1366         INPUTS                                => \@inputs,
1367         script_name                           => get_script_name(),
1368         casAuthentication                     => C4::Context->preference("casAuthentication"),
1369         shibbolethAuthentication              => $shib,
1370         suggestion                            => C4::Context->preference("suggestion"),
1371         virtualshelves                        => C4::Context->preference("virtualshelves"),
1372         LibraryName                           => "" . C4::Context->preference("LibraryName"),
1373         LibraryNameTitle                      => "" . $LibraryNameTitle,
1374         opacuserlogin                         => C4::Context->preference("opacuserlogin"),
1375         OpacFavicon                           => C4::Context->preference("OpacFavicon"),
1376         opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
1377         opaclanguagesdisplay                  => C4::Context->preference("opaclanguagesdisplay"),
1378         opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
1379         OpacCloud                             => C4::Context->preference("OpacCloud"),
1380         OpacTopissue                          => C4::Context->preference("OpacTopissue"),
1381         OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
1382         OpacBrowser                           => C4::Context->preference("OpacBrowser"),
1383         TagsEnabled                           => C4::Context->preference("TagsEnabled"),
1384         intranetcolorstylesheet               => C4::Context->preference("intranetcolorstylesheet"),
1385         intranetstylesheet                    => C4::Context->preference("intranetstylesheet"),
1386         IntranetNav                           => C4::Context->preference("IntranetNav"),
1387         IntranetFavicon                       => C4::Context->preference("IntranetFavicon"),
1388         IntranetUserCSS                       => C4::Context->preference("IntranetUserCSS"),
1389         IntranetUserJS                        => C4::Context->preference("IntranetUserJS"),
1390         IndependentBranches                   => C4::Context->preference("IndependentBranches"),
1391         AutoLocation                          => C4::Context->preference("AutoLocation"),
1392         wrongip                               => $info{'wrongip'},
1393         PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
1394         PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
1395         opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
1396         too_many_login_attempts               => ( $patron and $patron->account_locked ),
1397         password_has_expired                  => ( $patron and $patron->password_expired ),
1398         auth_error                            => $auth_error,
1399     );
1400
1401     $template->param( SCO_login => 1 ) if ( $query->param('sco_user_login') );
1402     $template->param( SCI_login => 1 ) if ( $query->param('sci_user_login') );
1403     $template->param( OpacPublic => C4::Context->preference("OpacPublic") );
1404     $template->param( loginprompt => 1 ) unless $info{'nopermission'};
1405     if ( $auth_state eq 'additional-auth-needed' ) {
1406         my $patron = Koha::Patrons->find( { userid => $userid } );
1407         $template->param(
1408             TwoFA_prompt => 1,
1409             invalid_otp_token => $invalid_otp_token,
1410             notice_email_address => $patron->notice_email_address, # We could also pass logged_in_user if necessary
1411         );
1412     }
1413
1414     if ( $auth_state eq 'setup-additional-auth-needed' ) {
1415         $template->param(
1416             TwoFA_setup => 1,
1417         );
1418     }
1419
1420     if ( $type eq 'opac' ) {
1421         require Koha::Virtualshelves;
1422         my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1423             {
1424                 public => 1,
1425             }
1426         );
1427         $template->param(
1428             some_public_shelves  => $some_public_shelves,
1429         );
1430     }
1431
1432     if ($cas) {
1433
1434         # Is authentication against multiple CAS servers enabled?
1435         require C4::Auth_with_cas;
1436         if ( multipleAuth() && !$casparam ) {
1437             my $casservers = getMultipleAuth();
1438             my @tmplservers;
1439             foreach my $key ( keys %$casservers ) {
1440                 push @tmplservers, { name => $key, value => login_cas_url( $query, $key, $type ) . "?cas=$key" };
1441             }
1442             $template->param(
1443                 casServersLoop => \@tmplservers
1444             );
1445         } else {
1446             $template->param(
1447                 casServerUrl => login_cas_url($query, undef, $type),
1448             );
1449         }
1450
1451         $template->param(
1452             invalidCasLogin => $info{'invalidCasLogin'}
1453         );
1454     }
1455
1456     if ($shib) {
1457         #If shibOnly is enabled just go ahead and redirect directly
1458         if ( (($type eq 'opac') && C4::Context->preference('OPACShibOnly')) || (($type ne 'opac') && C4::Context->preference('staffShibOnly')) ) {
1459             my $redirect_url = login_shib_url( $query );
1460             print $query->redirect( -uri => "$redirect_url", -status => 303 );
1461             safe_exit;
1462         }
1463
1464         $template->param(
1465             shibbolethAuthentication => $shib,
1466             shibbolethLoginUrl       => login_shib_url($query),
1467         );
1468     }
1469
1470     if (C4::Context->preference('GoogleOpenIDConnect')) {
1471         if ($query->param("OpenIDConnectFailed")) {
1472             my $reason = $query->param('OpenIDConnectFailed');
1473             $template->param(invalidGoogleOpenIDConnectLogin => $reason);
1474         }
1475     }
1476
1477     $template->param(
1478         LibraryName => C4::Context->preference("LibraryName"),
1479     );
1480     $template->param(%info);
1481
1482     #    $cookie = $query->cookie(CGISESSID => $session->id
1483     #   );
1484     print $query->header(
1485         {   type              => 'text/html',
1486             charset           => 'utf-8',
1487             cookie            => $cookie,
1488             'X-Frame-Options' => 'SAMEORIGIN',
1489             -sameSite => 'Lax'
1490         }
1491       ),
1492       $template->output;
1493     safe_exit;
1494 }
1495
1496 =head2 check_api_auth
1497
1498   ($status, $cookie, $sessionId) = check_api_auth($query, $userflags);
1499
1500 Given a CGI query containing the parameters 'userid' and 'password' and/or a session
1501 cookie, determine if the user has the privileges specified by C<$userflags>.
1502
1503 C<check_api_auth> is is meant for authenticating users of web services, and
1504 consequently will always return and will not attempt to redirect the user
1505 agent.
1506
1507 If a valid session cookie is already present, check_api_auth will return a status
1508 of "ok", the cookie, and the Koha session ID.
1509
1510 If no session cookie is present, check_api_auth will check the 'userid' and 'password
1511 parameters and create a session cookie and Koha session if the supplied credentials
1512 are OK.
1513
1514 Possible return values in C<$status> are:
1515
1516 =over
1517
1518 =item "ok" -- user authenticated; C<$cookie> and C<$sessionid> have valid values.
1519
1520 =item "failed" -- credentials are not correct; C<$cookie> and C<$sessionid> are undef
1521
1522 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1523
1524 =item "expired -- session cookie has expired; API user should resubmit userid and password
1525
1526 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1527
1528 =item "additional-auth-needed -- User is in an authentication process that is not finished
1529
1530 =back
1531
1532 =cut
1533
1534 sub check_api_auth {
1535
1536     my $query         = shift;
1537     my $flagsrequired = shift;
1538     my $timeout = _timeout_syspref();
1539
1540     unless ( C4::Context->preference('Version') ) {
1541
1542         # database has not been installed yet
1543         return ( "maintenance", undef, undef );
1544     }
1545     my $kohaversion = Koha::version();
1546     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1547     if ( C4::Context->preference('Version') < $kohaversion ) {
1548
1549         # database in need of version update; assume that
1550         # no API should be called while databsae is in
1551         # this condition.
1552         return ( "maintenance", undef, undef );
1553     }
1554
1555     my ( $sessionID, $session );
1556     unless ( $query->param('userid') ) {
1557         $sessionID = $query->cookie("CGISESSID");
1558     }
1559     if ( $sessionID && not( $cas && $query->param('PT') ) ) {
1560
1561         my $return;
1562         ( $return, $session, undef ) = check_cookie_auth(
1563             $sessionID, $flagsrequired, { remote_addr => $ENV{REMOTE_ADDR} } );
1564
1565         return ( $return, undef, undef ) # Cookie auth failed
1566             if $return ne "ok";
1567
1568         my $cookie = $query->cookie(
1569             -name     => 'CGISESSID',
1570             -value    => $session->id,
1571             -HttpOnly => 1,
1572             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1573             -sameSite => 'Lax'
1574         );
1575         return ( $return, $cookie, $session ); # return == 'ok' here
1576
1577     } else {
1578
1579         # new login
1580         my $userid   = $query->param('userid');
1581         my $password = $query->param('password');
1582         my ( $return, $cardnumber, $cas_ticket );
1583
1584         # Proxy CAS auth
1585         if ( $cas && $query->param('PT') ) {
1586             my $retuserid;
1587
1588             # In case of a CAS authentication, we use the ticket instead of the password
1589             my $PT = $query->param('PT');
1590             ( $return, $cardnumber, $userid, $cas_ticket ) = check_api_auth_cas( $PT, $query );    # EXTERNAL AUTH
1591         } else {
1592
1593             # User / password auth
1594             unless ( $userid and $password ) {
1595
1596                 # caller did something wrong, fail the authenticateion
1597                 return ( "failed", undef, undef );
1598             }
1599             my $newuserid;
1600             ( $return, $cardnumber, $newuserid, $cas_ticket ) = checkpw( $userid, $password, $query );
1601         }
1602
1603         if ( $return and haspermission( $userid, $flagsrequired ) ) {
1604             my $session = get_session("");
1605             return ( "failed", undef, undef ) unless $session;
1606
1607             my $sessionID = $session->id;
1608             C4::Context->_new_userenv($sessionID);
1609             my $cookie = $query->cookie(
1610                 -name     => 'CGISESSID',
1611                 -value    => $sessionID,
1612                 -HttpOnly => 1,
1613                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1614                 -sameSite => 'Lax'
1615             );
1616             if ( $return == 1 ) {
1617                 my (
1618                     $borrowernumber, $firstname,  $surname,
1619                     $userflags,      $branchcode, $branchname,
1620                     $emailaddress
1621                 );
1622                 my $dbh = C4::Context->dbh;
1623                 my $sth =
1624                   $dbh->prepare(
1625 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where userid=?"
1626                   );
1627                 $sth->execute($userid);
1628                 (
1629                     $borrowernumber, $firstname,  $surname,
1630                     $userflags,      $branchcode, $branchname,
1631                     $emailaddress
1632                 ) = $sth->fetchrow if ( $sth->rows );
1633
1634                 unless ( $sth->rows ) {
1635                     my $sth = $dbh->prepare(
1636 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1637                     );
1638                     $sth->execute($cardnumber);
1639                     (
1640                         $borrowernumber, $firstname,  $surname,
1641                         $userflags,      $branchcode, $branchname,
1642                         $emailaddress
1643                     ) = $sth->fetchrow if ( $sth->rows );
1644
1645                     unless ( $sth->rows ) {
1646                         $sth->execute($userid);
1647                         (
1648                             $borrowernumber, $firstname,  $surname,       $userflags,
1649                             $branchcode,     $branchname, $emailaddress
1650                         ) = $sth->fetchrow if ( $sth->rows );
1651                     }
1652                 }
1653
1654                 my $ip = $ENV{'REMOTE_ADDR'};
1655
1656                 # if they specify at login, use that
1657                 if ( $query->param('branch') ) {
1658                     $branchcode = $query->param('branch');
1659                     my $library = Koha::Libraries->find($branchcode);
1660                     $branchname = $library? $library->branchname: '';
1661                 }
1662                 my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1663                 foreach my $br ( keys %$branches ) {
1664
1665                     #     now we work with the treatment of ip
1666                     my $domain = $branches->{$br}->{'branchip'};
1667                     if ( $domain && $ip =~ /^$domain/ ) {
1668                         $branchcode = $branches->{$br}->{'branchcode'};
1669
1670                         # new op dev : add the branchname to the cookie
1671                         $branchname    = $branches->{$br}->{'branchname'};
1672                     }
1673                 }
1674                 $session->param( 'number',       $borrowernumber );
1675                 $session->param( 'id',           $userid );
1676                 $session->param( 'cardnumber',   $cardnumber );
1677                 $session->param( 'firstname',    $firstname );
1678                 $session->param( 'surname',      $surname );
1679                 $session->param( 'branch',       $branchcode );
1680                 $session->param( 'branchname',   $branchname );
1681                 $session->param( 'flags',        $userflags );
1682                 $session->param( 'emailaddress', $emailaddress );
1683                 $session->param( 'ip',           $session->remote_addr() );
1684                 $session->param( 'lasttime',     time() );
1685                 $session->param( 'interface',    'api'  );
1686             }
1687             $session->param( 'cas_ticket', $cas_ticket);
1688             C4::Context->set_userenv(
1689                 $session->param('number'),       $session->param('id'),
1690                 $session->param('cardnumber'),   $session->param('firstname'),
1691                 $session->param('surname'),      $session->param('branch'),
1692                 $session->param('branchname'),   $session->param('flags'),
1693                 $session->param('emailaddress'), $session->param('shibboleth'),
1694                 $session->param('desk_id'),      $session->param('desk_name'),
1695                 $session->param('register_id'),  $session->param('register_name')
1696             );
1697             return ( "ok", $cookie, $sessionID );
1698         } else {
1699             return ( "failed", undef, undef );
1700         }
1701     }
1702 }
1703
1704 =head2 check_cookie_auth
1705
1706   ($status, $sessionId) = check_cookie_auth($cookie, $userflags);
1707
1708 Given a CGISESSID cookie set during a previous login to Koha, determine
1709 if the user has the privileges specified by C<$userflags>. C<$userflags>
1710 is passed unaltered into C<haspermission> and as such accepts all options
1711 avaiable to that routine with the one caveat that C<check_api_auth> will
1712 also allow 'undef' to be passed and in such a case the permissions check
1713 will be skipped altogether.
1714
1715 C<check_cookie_auth> is meant for authenticating special services
1716 such as tools/upload-file.pl that are invoked by other pages that
1717 have been authenticated in the usual way.
1718
1719 Possible return values in C<$status> are:
1720
1721 =over
1722
1723 =item "ok" -- user authenticated; C<$sessionID> have valid values.
1724
1725 =item "anon" -- user not authenticated but valid for anonymous session.
1726
1727 =item "failed" -- credentials are not correct; C<$sessionid> are undef
1728
1729 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1730
1731 =item "expired -- session cookie has expired; API user should resubmit userid and password
1732
1733 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1734
1735 =back
1736
1737 =cut
1738
1739 sub check_cookie_auth {
1740     my $sessionID     = shift;
1741     my $flagsrequired = shift;
1742     my $params        = shift;
1743
1744     my $remote_addr = $params->{remote_addr} || $ENV{REMOTE_ADDR};
1745
1746     my $skip_version_check = $params->{skip_version_check}; # Only for checkauth
1747
1748     unless ( $skip_version_check ) {
1749         unless ( C4::Context->preference('Version') ) {
1750
1751             # database has not been installed yet
1752             return ( "maintenance", undef );
1753         }
1754         my $kohaversion = Koha::version();
1755         $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1756         if ( C4::Context->preference('Version') < $kohaversion ) {
1757
1758             # database in need of version update; assume that
1759             # no API should be called while databsae is in
1760             # this condition.
1761             return ( "maintenance", undef );
1762         }
1763     }
1764
1765     # see if we have a valid session cookie already
1766     # however, if a userid parameter is present (i.e., from
1767     # a form submission, assume that any current cookie
1768     # is to be ignored
1769     unless ( $sessionID ) {
1770         return ( "failed", undef );
1771     }
1772     C4::Context::_unset_userenv($sessionID); # remove old userenv first
1773     my $session   = get_session($sessionID);
1774     if ($session) {
1775         my $userid   = $session->param('id');
1776         my $ip       = $session->param('ip');
1777         my $lasttime = $session->param('lasttime');
1778         my $timeout = _timeout_syspref();
1779
1780         if ( !$lasttime || ( $lasttime < time() - $timeout ) ) {
1781             # time out
1782             $session->delete();
1783             $session->flush;
1784             return ("expired", undef);
1785
1786         } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $remote_addr ) {
1787             # IP address changed
1788             $session->delete();
1789             $session->flush;
1790             return ( "restricted", undef, { old_ip => $ip, new_ip => $remote_addr});
1791
1792         } elsif ( $userid ) {
1793             $session->param( 'lasttime', time() );
1794             my $patron = Koha::Patrons->find({ userid => $userid });
1795
1796             # If the user modify their own userid
1797             # Better than 500 but we could do better
1798             unless ( $patron ) {
1799                 $session->delete();
1800                 $session->flush;
1801                 return ("expired", undef);
1802             }
1803
1804             $patron = Koha::Patrons->find({ cardnumber => $userid })
1805               unless $patron;
1806             return ("password_expired", undef ) if $patron->password_expired;
1807             my $flags = defined($flagsrequired) ? haspermission( $userid, $flagsrequired ) : 1;
1808             if ($flags) {
1809                 C4::Context->_new_userenv($sessionID);
1810                 if ( !C4::Context->interface ) {
1811                     # No need to override the interface, most often set by get_template_and_user
1812                     C4::Context->interface( $session->param('interface') );
1813                 }
1814                 C4::Context->set_userenv(
1815                     $session->param('number'),       $session->param('id') // '',
1816                     $session->param('cardnumber'),   $session->param('firstname'),
1817                     $session->param('surname'),      $session->param('branch'),
1818                     $session->param('branchname'),   $session->param('flags'),
1819                     $session->param('emailaddress'), $session->param('shibboleth'),
1820                     $session->param('desk_id'),      $session->param('desk_name'),
1821                     $session->param('register_id'),  $session->param('register_name')
1822                 );
1823                 if ( C4::Context->preference('TwoFactorAuthentication') ne 'disabled' ) {
1824                     return ( "additional-auth-needed", $session )
1825                         if $session->param('waiting-for-2FA');
1826
1827                     return ( "setup-additional-auth-needed", $session )
1828                         if $session->param('waiting-for-2FA-setup');
1829                 }
1830
1831                 return ( "ok", $session );
1832             } else {
1833                 $session->delete();
1834                 $session->flush;
1835                 return ( "failed", undef );
1836             }
1837
1838         } else {
1839             C4::Context->_new_userenv($sessionID);
1840             C4::Context->interface($session->param('interface'));
1841             C4::Context->set_userenv( undef, q{} );
1842             return ( "anon", $session );
1843         }
1844     } else {
1845         return ( "expired", undef );
1846     }
1847 }
1848
1849 =head2 get_session
1850
1851   use CGI::Session;
1852   my $session = get_session($sessionID);
1853
1854 Given a session ID, retrieve the CGI::Session object used to store
1855 the session's state.  The session object can be used to store
1856 data that needs to be accessed by different scripts during a
1857 user's session.
1858
1859 If the C<$sessionID> parameter is an empty string, a new session
1860 will be created.
1861
1862 =cut
1863
1864 sub _get_session_params {
1865     my $storage_method = C4::Context->preference('SessionStorage');
1866     if ( $storage_method eq 'mysql' ) {
1867         my $dbh = C4::Context->dbh;
1868         return { dsn => "serializer:yamlxs;driver:MySQL;id:md5", dsn_args => { Handle => $dbh } };
1869     }
1870     elsif ( $storage_method eq 'Pg' ) {
1871         my $dbh = C4::Context->dbh;
1872         return { dsn => "serializer:yamlxs;driver:PostgreSQL;id:md5", dsn_args => { Handle => $dbh } };
1873     }
1874     elsif ( $storage_method eq 'memcached' && Koha::Caches->get_instance->memcached_cache ) {
1875         my $memcached = Koha::Caches->get_instance()->memcached_cache;
1876         return { dsn => "serializer:yamlxs;driver:memcached;id:md5", dsn_args => { Memcached => $memcached } };
1877     }
1878     else {
1879         # catch all defaults to tmp should work on all systems
1880         my $dir = C4::Context::temporary_directory;
1881         my $instance = C4::Context->config( 'database' ); #actually for packages not exactly the instance name, but generally safer to leave it as it is
1882         return { dsn => "serializer:yamlxs;driver:File;id:md5", dsn_args => { Directory => "$dir/cgisess_$instance" } };
1883     }
1884 }
1885
1886 sub get_session {
1887     my $sessionID      = shift;
1888     my $params = _get_session_params();
1889     my $session;
1890     if( $sessionID ) { # find existing
1891         CGI::Session::ErrorHandler->set_error( q{} ); # clear error, cpan issue #111463
1892         $session = CGI::Session->load( $params->{dsn}, $sessionID, $params->{dsn_args} );
1893     } else {
1894         $session = CGI::Session->new( $params->{dsn}, $sessionID, $params->{dsn_args} );
1895         # no need to flush here
1896     }
1897     return $session;
1898 }
1899
1900 =head2 create_basic_session
1901
1902 my $session = create_basic_session({ patron => $patron, interface => $interface });
1903
1904 Creates a session and adds all basic parameters for a session to work
1905
1906 =cut
1907
1908 sub create_basic_session {
1909     my $params    = shift;
1910     my $patron    = $params->{patron};
1911     my $interface = $params->{interface};
1912
1913     $interface = 'intranet' if $interface eq 'staff';
1914
1915     my $session = get_session("");
1916
1917     $session->param( 'number',       $patron->borrowernumber );
1918     $session->param( 'id',           $patron->userid );
1919     $session->param( 'cardnumber',   $patron->cardnumber );
1920     $session->param( 'firstname',    $patron->firstname );
1921     $session->param( 'surname',      $patron->surname );
1922     $session->param( 'branch',       $patron->branchcode );
1923     $session->param( 'branchname',   $patron->library->branchname );
1924     $session->param( 'flags',        $patron->flags );
1925     $session->param( 'emailaddress', $patron->email );
1926     $session->param( 'ip',           $session->remote_addr() );
1927     $session->param( 'lasttime',     time() );
1928     $session->param( 'interface',    $interface);
1929
1930     return $session;
1931 }
1932
1933
1934 # FIXME no_set_userenv may be replaced with force_branchcode_for_userenv
1935 # (or something similar)
1936 # Currently it's only passed from C4::SIP::ILS::Patron::check_password, but
1937 # not having a userenv defined could cause a crash.
1938 sub checkpw {
1939     my ( $userid, $password, $query, $type, $no_set_userenv ) = @_;
1940     $type = 'opac' unless $type;
1941
1942     # Get shibboleth login attribute
1943     my $shib = C4::Context->config('useshibboleth') && shib_ok();
1944     my $shib_login = $shib ? get_login_shib() : undef;
1945
1946     my @return;
1947     my $patron;
1948     if ( defined $userid ){
1949         $patron = Koha::Patrons->find({ userid => $userid });
1950         $patron = Koha::Patrons->find({ cardnumber => $userid }) unless $patron;
1951     }
1952     my $check_internal_as_fallback = 0;
1953     my $passwd_ok = 0;
1954     # Note: checkpw_* routines returns:
1955     # 1 if auth is ok
1956     # 0 if auth is nok
1957     # -1 if user bind failed (LDAP only)
1958
1959     if ( $patron and ( $patron->account_locked )  ) {
1960         # Nothing to check, account is locked
1961     } elsif ($ldap && defined($password)) {
1962         my ( $retval, $retcard, $retuserid ) = checkpw_ldap(@_);    # EXTERNAL AUTH
1963         if ( $retval == 1 ) {
1964             @return = ( $retval, $retcard, $retuserid );
1965             $passwd_ok = 1;
1966         }
1967         $check_internal_as_fallback = 1 if $retval == 0;
1968
1969     } elsif ( $cas && $query && $query->param('ticket') ) {
1970
1971         # In case of a CAS authentication, we use the ticket instead of the password
1972         my $ticket = $query->param('ticket');
1973         $query->delete('ticket');                                   # remove ticket to come back to original URL
1974         my ( $retval, $retcard, $retuserid, $cas_ticket ) = checkpw_cas( $ticket, $query, $type );    # EXTERNAL AUTH
1975         if ( $retval ) {
1976             @return = ( $retval, $retcard, $retuserid, $cas_ticket );
1977         } else {
1978             @return = (0);
1979         }
1980         $passwd_ok = $retval;
1981     }
1982
1983     # If we are in a shibboleth session (shibboleth is enabled, and a shibboleth match attribute is present)
1984     # Check for password to asertain whether we want to be testing against shibboleth or another method this
1985     # time around.
1986     elsif ( $shib && $shib_login && !$password ) {
1987
1988         # In case of a Shibboleth authentication, we expect a shibboleth user attribute
1989         # (defined under shibboleth mapping in koha-conf.xml) to contain the login of the
1990         # shibboleth-authenticated user
1991
1992         # Then, we check if it matches a valid koha user
1993         if ($shib_login) {
1994             my ( $retval, $retcard, $retuserid ) = C4::Auth_with_shibboleth::checkpw_shib($shib_login);    # EXTERNAL AUTH
1995             if ( $retval ) {
1996                 @return = ( $retval, $retcard, $retuserid );
1997             }
1998             $passwd_ok = $retval;
1999         }
2000     } else {
2001         $check_internal_as_fallback = 1;
2002     }
2003
2004     # INTERNAL AUTH
2005     if ( $check_internal_as_fallback ) {
2006         @return = checkpw_internal( $userid, $password, $no_set_userenv);
2007         $passwd_ok = 1 if $return[0] > 0; # 1 or 2
2008     }
2009
2010     if( $patron ) {
2011         if ( $passwd_ok ) {
2012             $patron->update({ login_attempts => 0 });
2013             if( $patron->password_expired ){
2014                 @return = (-2);
2015             }
2016         } elsif( !$patron->account_locked ) {
2017             $patron->update({ login_attempts => $patron->login_attempts + 1 });
2018         }
2019     }
2020
2021     # Optionally log success or failure
2022     if( $patron && $passwd_ok && C4::Context->preference('AuthSuccessLog') ) {
2023         logaction( 'AUTH', 'SUCCESS', $patron->id, "Valid password for $userid", $type );
2024     } elsif( !$passwd_ok && C4::Context->preference('AuthFailureLog') ) {
2025         logaction( 'AUTH', 'FAILURE', $patron ? $patron->id : 0, "Wrong password for $userid", $type );
2026     }
2027
2028     return @return;
2029 }
2030
2031 sub checkpw_internal {
2032     my ( $userid, $password, $no_set_userenv ) = @_;
2033
2034     $password = Encode::encode( 'UTF-8', $password )
2035       if Encode::is_utf8($password);
2036
2037     my $dbh = C4::Context->dbh;
2038     my $sth =
2039       $dbh->prepare(
2040         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where userid=?"
2041       );
2042     $sth->execute($userid);
2043     if ( $sth->rows ) {
2044         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2045             $surname, $branchcode, $branchname, $flags )
2046           = $sth->fetchrow;
2047
2048         if ( checkpw_hash( $password, $stored_hash ) ) {
2049
2050             C4::Context->set_userenv( "$borrowernumber", $userid, $cardnumber,
2051                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2052             return 1, $cardnumber, $userid;
2053         }
2054     }
2055     $sth =
2056       $dbh->prepare(
2057         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
2058       );
2059     $sth->execute($userid);
2060     if ( $sth->rows ) {
2061         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2062             $surname, $branchcode, $branchname, $flags )
2063           = $sth->fetchrow;
2064
2065         if ( checkpw_hash( $password, $stored_hash ) ) {
2066
2067             C4::Context->set_userenv( $borrowernumber, $userid, $cardnumber,
2068                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2069             return 1, $cardnumber, $userid;
2070         }
2071     }
2072     return 0;
2073 }
2074
2075 sub checkpw_hash {
2076     my ( $password, $stored_hash ) = @_;
2077
2078     return if $stored_hash eq '!';
2079
2080     # check what encryption algorithm was implemented: Bcrypt - if the hash starts with '$2' it is Bcrypt else md5
2081     my $hash;
2082     if ( substr( $stored_hash, 0, 2 ) eq '$2' ) {
2083         $hash = hash_password( $password, $stored_hash );
2084     } else {
2085         $hash = md5_base64($password);
2086     }
2087     return $hash eq $stored_hash;
2088 }
2089
2090 =head2 getuserflags
2091
2092     my $authflags = getuserflags($flags, $userid, [$dbh]);
2093
2094 Translates integer flags into permissions strings hash.
2095
2096 C<$flags> is the integer userflags value ( borrowers.userflags )
2097 C<$userid> is the members.userid, used for building subpermissions
2098 C<$authflags> is a hashref of permissions
2099
2100 =cut
2101
2102 sub getuserflags {
2103     my $flags  = shift;
2104     my $userid = shift;
2105     my $dbh    = @_ ? shift : C4::Context->dbh;
2106     my $userflags;
2107     {
2108         # I don't want to do this, but if someone logs in as the database
2109         # user, it would be preferable not to spam them to death with
2110         # numeric warnings. So, we make $flags numeric.
2111         no warnings 'numeric';
2112         $flags += 0;
2113     }
2114     my $sth = $dbh->prepare("SELECT bit, flag, defaulton FROM userflags");
2115     $sth->execute;
2116
2117     while ( my ( $bit, $flag, $defaulton ) = $sth->fetchrow ) {
2118         if ( ( $flags & ( 2**$bit ) ) || $defaulton ) {
2119             $userflags->{$flag} = 1;
2120         }
2121         else {
2122             $userflags->{$flag} = 0;
2123         }
2124     }
2125
2126     # get subpermissions and merge with top-level permissions
2127     my $user_subperms = get_user_subpermissions($userid);
2128     foreach my $module ( keys %$user_subperms ) {
2129         next if $userflags->{$module} == 1;    # user already has permission for everything in this module
2130         $userflags->{$module} = $user_subperms->{$module};
2131     }
2132
2133     return $userflags;
2134 }
2135
2136 =head2 get_user_subpermissions
2137
2138   $user_perm_hashref = get_user_subpermissions($userid);
2139
2140 Given the userid (note, not the borrowernumber) of a staff user,
2141 return a hashref of hashrefs of the specific subpermissions
2142 accorded to the user.  An example return is
2143
2144  {
2145     tools => {
2146         export_catalog => 1,
2147         import_patrons => 1,
2148     }
2149  }
2150
2151 The top-level hash-key is a module or function code from
2152 userflags.flag, while the second-level key is a code
2153 from permissions.
2154
2155 The results of this function do not give a complete picture
2156 of the functions that a staff user can access; it is also
2157 necessary to check borrowers.flags.
2158
2159 =cut
2160
2161 sub get_user_subpermissions {
2162     my $userid = shift;
2163
2164     my $dbh = C4::Context->dbh;
2165     my $sth = $dbh->prepare( "SELECT flag, user_permissions.code
2166                              FROM user_permissions
2167                              JOIN permissions USING (module_bit, code)
2168                              JOIN userflags ON (module_bit = bit)
2169                              JOIN borrowers USING (borrowernumber)
2170                              WHERE userid = ?" );
2171     $sth->execute($userid);
2172
2173     my $user_perms = {};
2174     while ( my $perm = $sth->fetchrow_hashref ) {
2175         $user_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2176     }
2177     return $user_perms;
2178 }
2179
2180 =head2 get_all_subpermissions
2181
2182   my $perm_hashref = get_all_subpermissions();
2183
2184 Returns a hashref of hashrefs defining all specific
2185 permissions currently defined.  The return value
2186 has the same structure as that of C<get_user_subpermissions>,
2187 except that the innermost hash value is the description
2188 of the subpermission.
2189
2190 =cut
2191
2192 sub get_all_subpermissions {
2193     my $dbh = C4::Context->dbh;
2194     my $sth = $dbh->prepare( "SELECT flag, code
2195                              FROM permissions
2196                              JOIN userflags ON (module_bit = bit)" );
2197     $sth->execute();
2198
2199     my $all_perms = {};
2200     while ( my $perm = $sth->fetchrow_hashref ) {
2201         $all_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2202     }
2203     return $all_perms;
2204 }
2205
2206 =head2 get_cataloguing_page_permissions
2207
2208     my $required_permissions = get_cataloguing_page_permissions();
2209
2210 Returns the required permissions to access the main cataloguing page. Useful for building
2211 the global I<can_see_cataloguing_module> template variable, and also for reusing in
2212 I<cataloging-home.pl>.
2213
2214 =cut
2215
2216 sub get_cataloguing_page_permissions {
2217
2218     my @cataloguing_tools_subperms = qw(
2219         inventory
2220         items_batchdel
2221         items_batchmod
2222         items_batchmod
2223         label_creator
2224         manage_staged_marc
2225         marc_modification_templates
2226         records_batchdel
2227         records_batchmod
2228         stage_marc_import
2229         upload_cover_images
2230     );
2231
2232     return [
2233         { editcatalogue => '*' }, { tools => \@cataloguing_tools_subperms },
2234         C4::Context->preference('StockRotation') ? { stockrotation => 'manage_rotas' } : ()
2235     ];
2236 }
2237
2238 =head2 haspermission
2239
2240   $flagsrequired = '*';                                 # Any permission at all
2241   $flagsrequired = 'a_flag';                            # a_flag must be satisfied (all subpermissions)
2242   $flagsrequired = [ 'a_flag', 'b_flag' ];              # a_flag OR b_flag must be satisfied
2243   $flagsrequired = { 'a_flag => 1, 'b_flag' => 1 };     # a_flag AND b_flag must be satisfied
2244   $flagsrequired = { 'a_flag' => 'sub_a' };             # sub_a of a_flag must be satisfied
2245   $flagsrequired = { 'a_flag' => [ 'sub_a, 'sub_b' ] }; # sub_a OR sub_b of a_flag must be satisfied
2246
2247   $flags = ($userid, $flagsrequired);
2248
2249 C<$userid> the userid of the member
2250 C<$flags> is a query structure similar to that used by SQL::Abstract that
2251 denotes the combination of flags required. It is a required parameter.
2252
2253 The main logic of this method is that things in arrays are OR'ed, and things
2254 in hashes are AND'ed. The `*` character can be used, at any depth, to denote `ANY`
2255
2256 Returns member's flags or 0 if a permission is not met.
2257
2258 =cut
2259
2260 sub _dispatch {
2261     my ($required, $flags) = @_;
2262
2263     my $ref = ref($required);
2264     if ($ref eq '') {
2265         if ($required eq '*') {
2266             return 0 unless ( $flags or ref( $flags ) );
2267         } else {
2268             return 0 unless ( $flags and (!ref( $flags ) || $flags->{$required} ));
2269         }
2270     } elsif ($ref eq 'HASH') {
2271         foreach my $key (keys %{$required}) {
2272             next if $flags == 1;
2273             my $require = $required->{$key};
2274             my $rflags  = $flags->{$key};
2275             return 0 unless _dispatch($require, $rflags);
2276         }
2277     } elsif ($ref eq 'ARRAY') {
2278         my $satisfied = 0;
2279         foreach my $require ( @{$required} ) {
2280             my $rflags =
2281               ( ref($flags) && !ref($require) && ( $require ne '*' ) )
2282               ? $flags->{$require}
2283               : $flags;
2284             $satisfied++ if _dispatch( $require, $rflags );
2285         }
2286         return 0 unless $satisfied;
2287     } else {
2288         croak "Unexpected structure found: $ref";
2289     }
2290
2291     return $flags;
2292 };
2293
2294 sub haspermission {
2295     my ( $userid, $flagsrequired ) = @_;
2296
2297     #Koha::Exceptions::WrongParameter->throw('$flagsrequired should not be undef')
2298     #  unless defined($flagsrequired);
2299
2300     my $sth = C4::Context->dbh->prepare("SELECT flags FROM borrowers WHERE userid=?");
2301     $sth->execute($userid);
2302     my $row = $sth->fetchrow();
2303     my $flags = getuserflags( $row, $userid );
2304
2305     return $flags unless defined($flagsrequired);
2306     return $flags if $flags->{superlibrarian};
2307     return _dispatch($flagsrequired, $flags);
2308
2309     #FIXME - This fcn should return the failed permission so a suitable error msg can be delivered.
2310 }
2311
2312 =head2 in_iprange
2313
2314   $flags = ($iprange);
2315
2316 C<$iprange> A space separated string describing an IP range. Can include single IPs or ranges
2317
2318 Returns 1 if the remote address is in the provided iprange, or 0 otherwise.
2319
2320 =cut
2321
2322 sub in_iprange {
2323     my ($iprange) = @_;
2324     my $result = 1;
2325     my @allowedipranges = $iprange ? split(' ', $iprange) : ();
2326     if (scalar @allowedipranges > 0) {
2327         my @rangelist;
2328         eval { @rangelist = Net::CIDR::range2cidr(@allowedipranges); }; return 0 if $@;
2329         eval { $result = Net::CIDR::cidrlookup($ENV{'REMOTE_ADDR'}, @rangelist) } || Koha::Logger->get->warn('cidrlookup failed for ' . join(' ',@rangelist) );
2330      }
2331      return $result ? 1 : 0;
2332 }
2333
2334 sub getborrowernumber {
2335     my ($userid) = @_;
2336     my $userenv = C4::Context->userenv;
2337     if ( defined($userenv) && ref($userenv) eq 'HASH' && $userenv->{number} ) {
2338         return $userenv->{number};
2339     }
2340     my $dbh = C4::Context->dbh;
2341     for my $field ( 'userid', 'cardnumber' ) {
2342         my $sth =
2343           $dbh->prepare("select borrowernumber from borrowers where $field=?");
2344         $sth->execute($userid);
2345         if ( $sth->rows ) {
2346             my ($bnumber) = $sth->fetchrow;
2347             return $bnumber;
2348         }
2349     }
2350     return 0;
2351 }
2352
2353 END { }    # module clean-up code here (global destructor)
2354 1;
2355 __END__
2356
2357 =head1 SEE ALSO
2358
2359 CGI(3)
2360
2361 C4::Output(3)
2362
2363 Crypt::Eksblowfish::Bcrypt(3)
2364
2365 Digest::MD5(3)
2366
2367 =cut