C4/Auth.pm

   1 package C4::Auth;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use Carp qw( croak );
  23
  24 use Digest::MD5 qw( md5_base64 );
  25 use CGI::Session;
  26 use CGI::Session::ErrorHandler;
  27 use URI;
  28 use URI::QueryParam;
  29 use List::MoreUtils qw( uniq );
  30
  31 use C4::Context;
  32 use C4::Templates;    # to get the template
  33 use C4::Languages;
  34 use C4::Search::History;
  35 use Koha;
  36 use Koha::Logger;
  37 use Koha::Caches;
  38 use Koha::AuthUtils qw( get_script_name hash_password );
  39 use Koha::Auth::TwoFactorAuth;
  40 use Koha::Checkouts;
  41 use Koha::DateUtils qw( dt_from_string );
  42 use Koha::Library::Groups;
  43 use Koha::Libraries;
  44 use Koha::Cash::Registers;
  45 use Koha::Desks;
  46 use Koha::Patrons;
  47 use Koha::Patron::Consents;
  48 use List::MoreUtils qw( any );
  49 use Encode;
  50 use C4::Auth_with_shibboleth qw( shib_ok get_login_shib login_shib_url logout_shib checkpw_shib );
  51 use Net::CIDR;
  52 use C4::Log qw( logaction );
  53 use Koha::CookieManager;
  54 use Koha::Auth::Permissions;
  55 use Koha::Token;
  56 use Koha::Session;
  57
  58 # use utf8;
  59
  60 use vars qw($ldap $cas $caslogout);
  61 our (@ISA, @EXPORT_OK);
  62
  63 #NOTE: The utility of keeping the safe_exit function is that it can be easily re-defined in unit tests and plugins
  64 sub safe_exit {
  65     # It's fine for us to "exit" because CGI::Compile (used in Plack::App::WrapCGI) redefines "exit" for us automatically.
  66     # Since we only seem to use C4::Auth::safe_exit in a CGI context, we don't actually need PSGI detection at all here.
  67     exit;
  68 }
  69
  70
  71 BEGIN {
  72     C4::Context->set_remote_address;
  73
  74     require Exporter;
  75     @ISA = qw(Exporter);
  76
  77     @EXPORT_OK = qw(
  78         checkauth check_api_auth get_session check_cookie_auth checkpw checkpw_internal checkpw_hash
  79         get_all_subpermissions get_cataloguing_page_permissions get_user_subpermissions in_iprange
  80         get_template_and_user haspermission create_basic_session
  81     );
  82
  83     $ldap      = C4::Context->config('useldapserver') || 0;
  84     $cas       = C4::Context->preference('casAuthentication');
  85     $caslogout = C4::Context->preference('casLogout');
  86
  87     if ($ldap) {
  88         require C4::Auth_with_ldap;
  89         import C4::Auth_with_ldap qw(checkpw_ldap);
  90     }
  91     if ($cas) {
  92         require C4::Auth_with_cas;    # no import
  93         import C4::Auth_with_cas qw(check_api_auth_cas checkpw_cas login_cas logout_cas login_cas_url logout_if_required multipleAuth getMultipleAuth);
  94     }
  95
  96 }
  97
  98 =head1 NAME
  99
 100 C4::Auth - Authenticates Koha users
 101
 102 =head1 SYNOPSIS
 103
 104   use CGI qw ( -utf8 );
 105   use C4::Auth;
 106   use C4::Output;
 107
 108   my $query = CGI->new;
 109
 110   my ($template, $borrowernumber, $cookie)
 111     = get_template_and_user(
 112         {
 113             template_name   => "opac-main.tt",
 114             query           => $query,
 115       type            => "opac",
 116       authnotrequired => 0,
 117       flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 118   }
 119     );
 120
 121   output_html_with_http_headers $query, $cookie, $template->output;
 122
 123 =head1 DESCRIPTION
 124
 125 The main function of this module is to provide
 126 authentification. However the get_template_and_user function has
 127 been provided so that a users login information is passed along
 128 automatically. This gets loaded into the template.
 129
 130 =head1 FUNCTIONS
 131
 132 =head2 get_template_and_user
 133
 134  my ($template, $borrowernumber, $cookie)
 135      = get_template_and_user(
 136        {
 137          template_name   => "opac-main.tt",
 138          query           => $query,
 139          type            => "opac",
 140          authnotrequired => 0,
 141          flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 142        }
 143      );
 144
 145 This call passes the C<query>, C<flagsrequired> and C<authnotrequired>
 146 to C<&checkauth> (in this module) to perform authentification.
 147 See C<&checkauth> for an explanation of these parameters.
 148
 149 The C<template_name> is then used to find the correct template for
 150 the page. The authenticated users details are loaded onto the
 151 template in the logged_in_user variable (which is a Koha::Patron object). Also the
 152 C<sessionID> is passed to the template. This can be used in templates
 153 if cookies are disabled. It needs to be put as and input to every
 154 authenticated page.
 155
 156 More information on the C<gettemplate> sub can be found in the
 157 Output.pm module.
 158
 159 =cut
 160
 161 sub get_template_and_user {
 162
 163     my $in = shift;
 164     my ( $user, $cookie, $sessionID, $flags );
 165     $cookie = [];
 166
 167     my $cookie_mgr = Koha::CookieManager->new;
 168
 169     # Get shibboleth login attribute
 170     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 171     my $shib_login = $shib ? get_login_shib() : undef;
 172
 173     C4::Context->interface( $in->{type} );
 174
 175     $in->{'authnotrequired'} ||= 0;
 176
 177     # the following call includes a bad template check; might croak
 178     my $template = C4::Templates::gettemplate(
 179         $in->{'template_name'},
 180         $in->{'type'},
 181         $in->{'query'},
 182     );
 183
 184     if ( $in->{'template_name'} !~ m/maintenance/ ) {
 185         ( $user, $cookie, $sessionID, $flags ) = checkauth(
 186             $in->{'query'},
 187             $in->{'authnotrequired'},
 188             $in->{'flagsrequired'},
 189             $in->{'type'},
 190             undef,
 191             $in->{template_name},
 192         );
 193     }
 194
 195     # If we enforce GDPR and the user did not consent, redirect
 196     # Exceptions for consent page itself and SCI/SCO system
 197     if( $in->{type} eq 'opac' && $user &&
 198         $in->{'template_name'} !~ /^(opac-page|opac-patron-consent|sc[io]\/)/ &&
 199         C4::Context->preference('PrivacyPolicyConsent') eq 'Enforced' )
 200     {
 201         my $consent = Koha::Patron::Consents->search({
 202             borrowernumber => getborrowernumber($user),
 203             type => 'GDPR_PROCESSING',
 204             given_on => { '!=', undef },
 205         })->next;
 206         if( !$consent ) {
 207             print $in->{query}->redirect(-uri => '/cgi-bin/koha/opac-patron-consent.pl', -cookie => $cookie);
 208             safe_exit;
 209         }
 210     }
 211
 212     if ( $in->{type} eq 'opac' && $user ) {
 213         my $is_sco_user;
 214         if ($sessionID){
 215             my $session = get_session($sessionID);
 216             if ($session){
 217                 $is_sco_user = $session->param('sco_user');
 218             }
 219         }
 220         my $kick_out;
 221
 222         if (
 223 # If the user logged in is the SCO user and they try to go out of the SCO module,
 224 # log the user out removing the CGISESSID cookie
 225             $in->{template_name} !~ m|sco/| && $in->{template_name} !~ m|errors/errorpage.tt|
 226             && (
 227                 $is_sco_user ||
 228                 (
 229                     C4::Context->preference('AutoSelfCheckID')
 230                     && $user eq C4::Context->preference('AutoSelfCheckID')
 231                 )
 232             )
 233           )
 234         {
 235             $kick_out = 1;
 236         }
 237         elsif (
 238 # If the user logged in is the SCI user and they try to go out of the SCI module,
 239 # kick them out unless it is SCO with a valid permission
 240 # or they are a superlibrarian
 241                $in->{template_name} !~ m|sci/|
 242             && haspermission( $user, { self_check => 'self_checkin_module' } )
 243             && !(
 244                 $in->{template_name} =~ m|sco/| && haspermission(
 245                     $user, { self_check => 'self_checkout_module' }
 246                 )
 247             )
 248             && $flags && $flags->{superlibrarian} != 1
 249           )
 250         {
 251             $kick_out = 1;
 252         }
 253
 254         if ($kick_out) {
 255             $template = C4::Templates::gettemplate( 'opac-auth.tt', 'opac',
 256                 $in->{query} );
 257             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 258                 -name     => 'CGISESSID',
 259                 -value    => '',
 260                 -HttpOnly => 1,
 261                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 262                 -sameSite => 'Lax',
 263             ));
 264
 265             #NOTE: This JWT should only be used by the self-check controllers
 266             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 267                 -name     => 'JWT',
 268                 -value    => '',
 269                 -HttpOnly => 1,
 270                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 271                 -sameSite => 'Lax',
 272             ));
 273
 274             my $auth_error = $in->{query}->param('auth_error');
 275
 276             $template->param(
 277                 loginprompt => 1,
 278                 script_name => get_script_name(),
 279                 auth_error  => $auth_error,
 280             );
 281
 282             print $in->{query}->header(
 283                 {
 284                     type              => 'text/html',
 285                     charset           => 'utf-8',
 286                     cookie            => $cookie,
 287                     'X-Frame-Options' => 'SAMEORIGIN'
 288                 }
 289               ),
 290               $template->output;
 291             safe_exit;
 292         }
 293     }
 294
 295     my $borrowernumber;
 296     my $patron;
 297     if ($user) {
 298
 299         # It's possible for $user to be the borrowernumber if they don't have a
 300         # userid defined (and are logging in through some other method, such
 301         # as SSL certs against an email address)
 302         $borrowernumber = getborrowernumber($user) if defined($user);
 303         if ( !defined($borrowernumber) && defined($user) ) {
 304             $patron = Koha::Patrons->find( $user );
 305             if ($patron) {
 306                 $borrowernumber = $user;
 307
 308                 # A bit of a hack, but I don't know there's a nicer way
 309                 # to do it.
 310                 $user = $patron->firstname . ' ' . $patron->surname;
 311             }
 312         } else {
 313             $patron = Koha::Patrons->find( $borrowernumber );
 314             # FIXME What to do if $patron does not exist?
 315         }
 316
 317         if ( $in->{'type'} eq 'opac' ) {
 318             require Koha::Virtualshelves;
 319             my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 320                 {
 321                     borrowernumber => $borrowernumber,
 322                     public         => 0,
 323                 }
 324             );
 325             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 326                 {
 327                     public => 1,
 328                 }
 329             );
 330             $template->param(
 331                 some_private_shelves => $some_private_shelves,
 332                 some_public_shelves  => $some_public_shelves,
 333             );
 334         }
 335
 336         # We are going to use the $flags returned by checkauth
 337         # to create the template's parameters that will indicate
 338         # which menus the user can access.
 339         my $authz = Koha::Auth::Permissions->get_authz_from_flags({ flags => $flags });
 340         foreach my $permission ( keys %{ $authz } ){
 341             $template->param( $permission => $authz->{$permission} );
 342         }
 343
 344         # Logged-in opac search history
 345         # If the requested template is an opac one and opac search history is enabled
 346         if ( $in->{type} eq 'opac' && C4::Context->preference('EnableOpacSearchHistory') ) {
 347             my $dbh   = C4::Context->dbh;
 348             my $query = "SELECT COUNT(*) FROM search_history WHERE userid=?";
 349             my $sth   = $dbh->prepare($query);
 350             $sth->execute($borrowernumber);
 351
 352             # If at least one search has already been performed
 353             if ( $sth->fetchrow_array > 0 ) {
 354
 355                 # We show the link in opac
 356                 $template->param( EnableOpacSearchHistory => 1 );
 357             }
 358             if (C4::Context->preference('LoadSearchHistoryToTheFirstLoggedUser'))
 359             {
 360                 # And if there are searches performed when the user was not logged in,
 361                 # we add them to the logged-in search history
 362                 my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 363                 if (@recentSearches) {
 364                     my $query = q{
 365                         INSERT INTO search_history(userid, sessionid, query_desc, query_cgi, type,  total, time )
 366                         VALUES (?, ?, ?, ?, ?, ?, ?)
 367                     };
 368                     my $sth = $dbh->prepare($query);
 369                     $sth->execute( $borrowernumber,
 370                         $in->{query}->cookie("CGISESSID"),
 371                         $_->{query_desc},
 372                         $_->{query_cgi},
 373                         $_->{type} || 'biblio',
 374                         $_->{total},
 375                         $_->{time},
 376                     ) foreach @recentSearches;
 377
 378                     # clear out the search history from the session now that
 379                     # we've saved it to the database
 380                  }
 381               }
 382               C4::Search::History::set_to_session( { cgi => $in->{'query'}, search_history => [] } );
 383
 384         } elsif ( $in->{type} eq 'intranet' and C4::Context->preference('EnableSearchHistory') ) {
 385             $template->param( EnableSearchHistory => 1 );
 386         }
 387     }
 388     else {    # if this is an anonymous session, setup to display public lists...
 389
 390         # If shibboleth is enabled, and we're in an anonymous session, we should allow
 391         # the user to attempt login via shibboleth.
 392         if ($shib) {
 393             $template->param( shibbolethAuthentication => $shib,
 394                 shibbolethLoginUrl => login_shib_url( $in->{'query'} ),
 395             );
 396
 397             # If shibboleth is enabled and we have a shibboleth login attribute,
 398             # but we are in an anonymous session, then we clearly have an invalid
 399             # shibboleth koha account.
 400             if ($shib_login) {
 401                 $template->param( invalidShibLogin => '1' );
 402             }
 403         }
 404
 405         if ( $in->{'type'} eq 'opac' ){
 406             require Koha::Virtualshelves;
 407             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 408                 {
 409                     public => 1,
 410                 }
 411             );
 412             $template->param(
 413                 some_public_shelves  => $some_public_shelves,
 414             );
 415
 416             # Set default branch if one has been passed by the environment.
 417             $template->param( default_branch => $ENV{OPAC_BRANCH_DEFAULT} ) if $ENV{OPAC_BRANCH_DEFAULT};
 418         }
 419     }
 420
 421     # Sysprefs disabled via URL param
 422     # Note that value must be defined in order to override via ENV
 423     foreach my $syspref (
 424         qw(
 425             OPACUserCSS
 426             OPACUserJS
 427             IntranetUserCSS
 428             IntranetUserJS
 429             OpacAdditionalStylesheet
 430             opaclayoutstylesheet
 431             intranetcolorstylesheet
 432             intranetstylesheet
 433         )
 434       )
 435     {
 436         $ENV{"OVERRIDE_SYSPREF_$syspref"} = q{}
 437           if $in->{'query'}->param("DISABLE_SYSPREF_$syspref");
 438     }
 439
 440     # Anonymous opac search history
 441     # If opac search history is enabled and at least one search has already been performed
 442     if ( C4::Context->preference('EnableOpacSearchHistory') ) {
 443         my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 444         if (@recentSearches) {
 445             $template->param( EnableOpacSearchHistory => 1 );
 446         }
 447     }
 448
 449     if ( C4::Context->preference('dateformat') ) {
 450         $template->param( dateformat => C4::Context->preference('dateformat') );
 451     }
 452
 453     $template->param(auth_forwarded_hash => scalar $in->{'query'}->param('auth_forwarded_hash'));
 454
 455     # these template parameters are set the same regardless of $in->{'type'}
 456
 457     my $minPasswordLength = C4::Context->preference('minPasswordLength');
 458     $minPasswordLength = 3 if not $minPasswordLength or $minPasswordLength < 3;
 459     $template->param(
 460         EnhancedMessagingPreferences                                       => C4::Context->preference('EnhancedMessagingPreferences'),
 461         GoogleJackets                                                      => C4::Context->preference("GoogleJackets"),
 462         OpenLibraryCovers                                                  => C4::Context->preference("OpenLibraryCovers"),
 463         KohaAdminEmailAddress                                              => "" . C4::Context->preference("KohaAdminEmailAddress"),
 464         LoginFirstname  => ( C4::Context->userenv ? C4::Context->userenv->{"firstname"} : "Bel" ),
 465         LoginSurname    => C4::Context->userenv ? C4::Context->userenv->{"surname"}      : "Inconnu",
 466         emailaddress    => C4::Context->userenv ? C4::Context->userenv->{"emailaddress"} : undef,
 467         TagsEnabled     => C4::Context->preference("TagsEnabled"),
 468         hide_marc       => C4::Context->preference("hide_marc"),
 469         item_level_itypes  => C4::Context->preference('item-level_itypes'),
 470         patronimages       => C4::Context->preference("patronimages"),
 471         singleBranchMode   => ( Koha::Libraries->search->count == 1 ),
 472         noItemTypeImages   => C4::Context->preference("noItemTypeImages"),
 473         marcflavour        => C4::Context->preference("marcflavour"),
 474         OPACBaseURL        => C4::Context->preference('OPACBaseURL'),
 475         minPasswordLength  => $minPasswordLength,
 476     );
 477     if ( $in->{'type'} eq "intranet" ) {
 478
 479         $template->param(
 480             advancedMARCEditor           => C4::Context->preference("advancedMARCEditor"),
 481             AllowMultipleCovers          => C4::Context->preference('AllowMultipleCovers'),
 482             AmazonCoverImages            => C4::Context->preference("AmazonCoverImages"),
 483             AutoLocation                 => C4::Context->preference("AutoLocation"),
 484             can_see_cataloguing_module   => haspermission( $user, get_cataloguing_page_permissions() ) ? 1 : 0,
 485             canreservefromotherbranches  => C4::Context->preference('canreservefromotherbranches'),
 486             EasyAnalyticalRecords        => C4::Context->preference('EasyAnalyticalRecords'),
 487             EnableBorrowerFiles          => C4::Context->preference('EnableBorrowerFiles'),
 488             FRBRizeEditions              => C4::Context->preference("FRBRizeEditions"),
 489             IndependentBranches          => C4::Context->preference("IndependentBranches"),
 490             intranetcolorstylesheet      => C4::Context->preference("intranetcolorstylesheet"),
 491             IntranetFavicon              => C4::Context->preference("IntranetFavicon"),
 492             IntranetmainUserblock        => C4::Context->preference("IntranetmainUserblock"),
 493             IntranetNav                  => C4::Context->preference("IntranetNav"),
 494             intranetreadinghistory       => C4::Context->preference("intranetreadinghistory"),
 495             IntranetReadingHistoryHolds  => C4::Context->preference("IntranetReadingHistoryHolds"),
 496             intranetstylesheet           => C4::Context->preference("intranetstylesheet"),
 497             IntranetUserCSS              => C4::Context->preference("IntranetUserCSS"),
 498             IntranetUserJS               => C4::Context->preference("IntranetUserJS"),
 499             LibraryName                  => C4::Context->preference("LibraryName"),
 500             LocalCoverImages             => C4::Context->preference('LocalCoverImages'),
 501             OPACLocalCoverImages         => C4::Context->preference('OPACLocalCoverImages'),
 502             PatronAutoComplete           => C4::Context->preference("PatronAutoComplete"),
 503             pending_checkout_notes       => Koha::Checkouts->search( { noteseen => 0 } ),
 504             plugins_enabled              => C4::Context->config("enable_plugins"),
 505             StaffSerialIssueDisplayCount => C4::Context->preference("StaffSerialIssueDisplayCount"),
 506             UseCourseReserves            => C4::Context->preference("UseCourseReserves"),
 507             useDischarge                 => C4::Context->preference('useDischarge'),
 508             virtualshelves               => C4::Context->preference("virtualshelves"),
 509         );
 510     }
 511     else {
 512         warn "template type should be OPAC, here it is=[" . $in->{'type'} . "]" unless ( $in->{'type'} eq 'opac' );
 513
 514         #TODO : replace LibraryName syspref with 'system name', and remove this html processing
 515         my $LibraryNameTitle = C4::Context->preference("LibraryName");
 516         $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
 517         $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
 518
 519         # clean up the busc param in the session
 520         # if the page is not opac-detail and not the "add to list" page
 521         # and not the "edit comments" page
 522         if ( C4::Context->preference("OpacBrowseResults")
 523             && $in->{'template_name'} =~ /opac-(.+)\.(?:tt|tmpl)$/ ) {
 524             my $pagename = $1;
 525             unless ( $pagename =~ /^(?:MARC|ISBD)?detail$/
 526                 or $pagename =~ /^showmarc$/
 527                 or $pagename =~ /^addbybiblionumber$/
 528                 or $pagename =~ /^review$/ )
 529             {
 530                 my $sessionSearch = get_session( $sessionID );
 531                 $sessionSearch->clear( ["busc"] ) if $sessionSearch;
 532             }
 533         }
 534
 535         # variables passed from CGI: opac_css_override and opac_search_limits.
 536         my $opac_search_limit   = $ENV{'OPAC_SEARCH_LIMIT'};
 537         my $opac_limit_override = $ENV{'OPAC_LIMIT_OVERRIDE'};
 538         my $opac_name           = '';
 539         if (
 540             ( $opac_limit_override && $opac_search_limit && $opac_search_limit =~ /branch:([\w-]+)/ ) ||
 541             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /branch:([\w-]+)/ ) ||
 542             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /multibranchlimit:(\w+)/ )
 543           ) {
 544             $opac_name = $1;    # opac_search_limit is a branch, so we use it.
 545         } elsif ( $in->{'query'}->param('multibranchlimit') ) {
 546             $opac_name = $in->{'query'}->param('multibranchlimit');
 547         } elsif ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv && C4::Context->userenv->{'branch'} ) {
 548             $opac_name = C4::Context->userenv->{'branch'};
 549         }
 550
 551         # Decide if the patron can make suggestions in the OPAC
 552         my $can_make_suggestions;
 553         if ( C4::Context->preference('Suggestion') && C4::Context->preference('AnonSuggestions') ) {
 554             $can_make_suggestions = 1;
 555         } elsif ( C4::Context->userenv && C4::Context->userenv->{'number'} ) {
 556             $can_make_suggestions = Koha::Patrons->find(C4::Context->userenv->{'number'})->category->can_make_suggestions;
 557         }
 558
 559         my @search_groups = Koha::Library::Groups->get_search_groups({ interface => 'opac' })->as_list;
 560         $template->param(
 561             AnonSuggestions                       => "" . C4::Context->preference("AnonSuggestions"),
 562             LibrarySearchGroups                   => \@search_groups,
 563             opac_name                             => $opac_name,
 564             LibraryName                           => "" . C4::Context->preference("LibraryName"),
 565             LibraryNameTitle                      => "" . $LibraryNameTitle,
 566             OPACAmazonCoverImages                 => C4::Context->preference("OPACAmazonCoverImages"),
 567             OPACFRBRizeEditions                   => C4::Context->preference("OPACFRBRizeEditions"),
 568             OpacHighlightedWords                  => C4::Context->preference("OpacHighlightedWords"),
 569             OPACShelfBrowser                      => "" . C4::Context->preference("OPACShelfBrowser"),
 570             OPACURLOpenInNewWindow                => "" . C4::Context->preference("OPACURLOpenInNewWindow"),
 571             OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
 572             opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
 573             opac_search_limit                     => $opac_search_limit,
 574             opac_limit_override                   => $opac_limit_override,
 575             OpacBrowser                           => C4::Context->preference("OpacBrowser"),
 576             OpacCloud                             => C4::Context->preference("OpacCloud"),
 577             OpacKohaUrl                           => C4::Context->preference("OpacKohaUrl"),
 578             OpacPasswordChange                    => C4::Context->preference("OpacPasswordChange"),
 579             OPACPatronDetails                     => C4::Context->preference("OPACPatronDetails"),
 580             OPACPrivacy                           => C4::Context->preference("OPACPrivacy"),
 581             OPACFinesTab                          => C4::Context->preference("OPACFinesTab"),
 582             OpacTopissue                          => C4::Context->preference("OpacTopissue"),
 583             'Version'                             => C4::Context->preference('Version'),
 584             hidelostitems                         => C4::Context->preference("hidelostitems"),
 585             mylibraryfirst                        => ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv ) ? C4::Context->userenv->{'branch'} : '',
 586             opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
 587             OpacFavicon                           => C4::Context->preference("OpacFavicon"),
 588             opaclanguagesdisplay                  => "" . C4::Context->preference("opaclanguagesdisplay"),
 589             opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
 590             opacuserlogin                         => "" . C4::Context->preference("opacuserlogin"),
 591             OpenLibrarySearch                     => C4::Context->preference("OpenLibrarySearch"),
 592             ShowReviewer                          => C4::Context->preference("ShowReviewer"),
 593             ShowReviewerPhoto                     => C4::Context->preference("ShowReviewerPhoto"),
 594             suggestion                            => $can_make_suggestions,
 595             virtualshelves                        => "" . C4::Context->preference("virtualshelves"),
 596             OPACSerialIssueDisplayCount           => C4::Context->preference("OPACSerialIssueDisplayCount"),
 597             SyndeticsClientCode                   => C4::Context->preference("SyndeticsClientCode"),
 598             SyndeticsEnabled                      => C4::Context->preference("SyndeticsEnabled"),
 599             SyndeticsCoverImages                  => C4::Context->preference("SyndeticsCoverImages"),
 600             SyndeticsTOC                          => C4::Context->preference("SyndeticsTOC"),
 601             SyndeticsSummary                      => C4::Context->preference("SyndeticsSummary"),
 602             SyndeticsEditions                     => C4::Context->preference("SyndeticsEditions"),
 603             SyndeticsExcerpt                      => C4::Context->preference("SyndeticsExcerpt"),
 604             SyndeticsReviews                      => C4::Context->preference("SyndeticsReviews"),
 605             SyndeticsAuthorNotes                  => C4::Context->preference("SyndeticsAuthorNotes"),
 606             SyndeticsAwards                       => C4::Context->preference("SyndeticsAwards"),
 607             SyndeticsSeries                       => C4::Context->preference("SyndeticsSeries"),
 608             SyndeticsCoverImageSize               => C4::Context->preference("SyndeticsCoverImageSize"),
 609             OPACLocalCoverImages                  => C4::Context->preference("OPACLocalCoverImages"),
 610             PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
 611             PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
 612             useDischarge                 => C4::Context->preference('useDischarge'),
 613         );
 614
 615         $template->param( OpacPublic => '1' ) if ( $user || C4::Context->preference("OpacPublic") );
 616     }
 617
 618     # Check if we were asked using parameters to force a specific language
 619     if ( defined $in->{'query'}->param('language') ) {
 620
 621         # Extract the language, let C4::Languages::getlanguage choose
 622         # what to do
 623         my $language = C4::Languages::getlanguage( $in->{'query'} );
 624         my $languagecookie = C4::Templates::getlanguagecookie( $in->{'query'}, $language );
 625         $cookie = $cookie_mgr->replace_in_list( $cookie, $languagecookie );
 626     }
 627
 628     # user info
 629     $template->param( loggedinusername   => $user ); # OBSOLETE - Do not reuse this in template, use logged_in_user.userid instead
 630     $template->param( loggedinusernumber => $borrowernumber ); # FIXME Should be replaced with logged_in_user.borrowernumber
 631     $template->param( logged_in_user     => $patron );
 632     $template->param( sessionID          => $sessionID );
 633
 634     return ( $template, $borrowernumber, $cookie, $flags );
 635 }
 636
 637 =head2 checkauth
 638
 639   ($userid, $cookie, $sessionID) = &checkauth($query, $noauth, $flagsrequired, $type);
 640
 641 Verifies that the user is authorized to run this script.  If
 642 the user is authorized, a (userid, cookie, session-id, flags)
 643 quadruple is returned.  If the user is not authorized but does
 644 not have the required privilege (see $flagsrequired below), it
 645 displays an error page and exits.  Otherwise, it displays the
 646 login page and exits.
 647
 648 Note that C<&checkauth> will return if and only if the user
 649 is authorized, so it should be called early on, before any
 650 unfinished operations (e.g., if you've opened a file, then
 651 C<&checkauth> won't close it for you).
 652
 653 C<$query> is the CGI object for the script calling C<&checkauth>.
 654
 655 The C<$noauth> argument is optional. If it is set, then no
 656 authorization is required for the script.
 657
 658 C<&checkauth> fetches user and session information from C<$query> and
 659 ensures that the user is authorized to run scripts that require
 660 authorization.
 661
 662 The C<$flagsrequired> argument specifies the required privileges
 663 the user must have if the username and password are correct.
 664 It should be specified as a reference-to-hash; keys in the hash
 665 should be the "flags" for the user, as specified in the Members
 666 intranet module. Any key specified must correspond to a "flag"
 667 in the userflags table. E.g., { circulate => 1 } would specify
 668 that the user must have the "circulate" privilege in order to
 669 proceed. To make sure that access control is correct, the
 670 C<$flagsrequired> parameter must be specified correctly.
 671
 672 Koha also has a concept of sub-permissions, also known as
 673 granular permissions.  This makes the value of each key
 674 in the C<flagsrequired> hash take on an additional
 675 meaning, i.e.,
 676
 677  1
 678
 679 The user must have access to all subfunctions of the module
 680 specified by the hash key.
 681
 682  *
 683
 684 The user must have access to at least one subfunction of the module
 685 specified by the hash key.
 686
 687  specific permission, e.g., 'export_catalog'
 688
 689 The user must have access to the specific subfunction list, which
 690 must correspond to a row in the permissions table.
 691
 692 The C<$type> argument specifies whether the template should be
 693 retrieved from the opac or intranet directory tree.  "opac" is
 694 assumed if it is not specified; however, if C<$type> is specified,
 695 "intranet" is assumed if it is not "opac".
 696
 697 If C<$query> does not have a valid session ID associated with it
 698 (i.e., the user has not logged in) or if the session has expired,
 699 C<&checkauth> presents the user with a login page (from the point of
 700 view of the original script, C<&checkauth> does not return). Once the
 701 user has authenticated, C<&checkauth> restarts the original script
 702 (this time, C<&checkauth> returns).
 703
 704 The login page is provided using a HTML::Template, which is set in the
 705 systempreferences table or at the top of this file. The variable C<$type>
 706 selects which template to use, either the opac or the intranet
 707 authentification template.
 708
 709 C<&checkauth> returns a user ID, a cookie, and a session ID. The
 710 cookie should be sent back to the browser; it verifies that the user
 711 has authenticated.
 712
 713 =cut
 714
 715 sub _version_check {
 716     my $type  = shift;
 717     my $query = shift;
 718     my $version;
 719
 720     # If version syspref is unavailable, it means Koha is being installed,
 721     # and so we must redirect to OPAC maintenance page or to the WebInstaller
 722     # also, if OpacMaintenance is ON, OPAC should redirect to maintenance
 723     if ( C4::Context->preference('OpacMaintenance') && $type eq 'opac' ) {
 724         warn "OPAC Install required, redirecting to maintenance";
 725         print $query->redirect("/cgi-bin/koha/maintenance.pl");
 726         safe_exit;
 727     }
 728     unless ( $version = C4::Context->preference('Version') ) {    # assignment, not comparison
 729         if ( $type ne 'opac' ) {
 730             warn "Install required, redirecting to Installer";
 731             print $query->redirect("/cgi-bin/koha/installer/install.pl");
 732         } else {
 733             warn "OPAC Install required, redirecting to maintenance";
 734             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 735         }
 736         safe_exit;
 737     }
 738
 739     # check that database and koha version are the same
 740     # there is no DB version, it's a fresh install,
 741     # go to web installer
 742     # there is a DB version, compare it to the code version
 743     my $kohaversion = Koha::version();
 744
 745     # remove the 3 last . to have a Perl number
 746     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 747     Koha::Logger->get->debug("kohaversion : $kohaversion");
 748     if ( $version < $kohaversion ) {
 749         my $warning = "Database update needed, redirecting to %s. Database is $version and Koha is $kohaversion";
 750         if ( $type ne 'opac' ) {
 751             warn sprintf( $warning, 'Installer' );
 752             print $query->redirect("/cgi-bin/koha/installer/install.pl?step=1&op=updatestructure");
 753         } else {
 754             warn sprintf( "OPAC: " . $warning, 'maintenance' );
 755             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 756         }
 757         safe_exit;
 758     }
 759 }
 760
 761 sub _timeout_syspref {
 762     my $default_timeout = 600;
 763     my $timeout = C4::Context->preference('timeout') || $default_timeout;
 764
 765     # value in days, convert in seconds
 766     if ( $timeout =~ /^(\d+)[dD]$/ ) {
 767         $timeout = $1 * 86400;
 768     }
 769     # value in hours, convert in seconds
 770     elsif ( $timeout =~ /^(\d+)[hH]$/ ) {
 771         $timeout = $1 * 3600;
 772     }
 773     elsif ( $timeout !~ m/^\d+$/ ) {
 774         warn "The value of the system preference 'timeout' is not correct, defaulting to $default_timeout";
 775         $timeout = $default_timeout;
 776     }
 777
 778     return $timeout;
 779 }
 780
 781 sub checkauth {
 782     my $query = shift;
 783
 784     # Get shibboleth login attribute
 785     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 786     my $shib_login = $shib ? get_login_shib() : undef;
 787
 788     # $authnotrequired will be set for scripts which will run without authentication
 789     my $authnotrequired = shift;
 790     my $flagsrequired   = shift;
 791     my $type            = shift;
 792     my $emailaddress    = shift;
 793     my $template_name   = shift;
 794     my $params          = shift || {};    # do_not_print
 795     $type = 'opac' unless $type;
 796
 797     if ( $type eq 'opac' && !C4::Context->preference("OpacPublic") ) {
 798         my @allowed_scripts_for_private_opac = qw(
 799             opac-memberentry.tt
 800             opac-registration-email-sent.tt
 801             opac-registration-confirmation.tt
 802             opac-memberentry-update-submitted.tt
 803             opac-password-recovery.tt
 804             opac-reset-password.tt
 805             ilsdi.tt
 806         );
 807         $authnotrequired = 0 unless grep { $_ eq $template_name }
 808             @allowed_scripts_for_private_opac;
 809     }
 810
 811     my $timeout = _timeout_syspref();
 812
 813     my $cookie_mgr = Koha::CookieManager->new;
 814
 815     _version_check( $type, $query );
 816
 817     # state variables
 818     my $auth_state = 'failed';
 819     my %info;
 820     my ( $userid, $cookie, $sessionID, $flags );
 821     $cookie = [];
 822     my $logout = $query->param('logout.x');
 823
 824     my $anon_search_history;
 825     my $cas_ticket = '';
 826     # This parameter is the name of the CAS server we want to authenticate against,
 827     # when using authentication against multiple CAS servers, as configured in Auth_cas_servers.yaml
 828     my $casparam = $query->param('cas');
 829     my $q_userid = $query->param('userid') // '';
 830
 831     my $session;
 832     my $invalid_otp_token;
 833     my $require_2FA =
 834       ( $type ne "opac" # Only available for the staff interface
 835           && C4::Context->preference('TwoFactorAuthentication') ne "disabled" ) # If "enabled" or "enforced"
 836       ? 1 : 0;
 837
 838     # Basic authentication is incompatible with the use of Shibboleth,
 839     # as Shibboleth may return REMOTE_USER as a Shibboleth attribute,
 840     # and it may not be the attribute we want to use to match the koha login.
 841     #
 842     # Also, do not consider an empty REMOTE_USER.
 843     #
 844     # Finally, after those tests, we can assume (although if it would be better with
 845     # a syspref) that if we get a REMOTE_USER, that's from basic authentication,
 846     # and we can affect it to $userid.
 847     if ( !$shib and defined( $ENV{'REMOTE_USER'} ) and $ENV{'REMOTE_USER'} ne '' and $userid = $ENV{'REMOTE_USER'} ) {
 848
 849         # Using Basic Authentication, no cookies required
 850         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 851             -name     => 'CGISESSID',
 852             -value    => '',
 853             -HttpOnly => 1,
 854             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 855             -sameSite => 'Lax',
 856         ));
 857     }
 858     elsif ( $emailaddress) {
 859         # the Google OpenID Connect passes an email address
 860     }
 861     elsif ( $sessionID = $query->cookie("CGISESSID") ) {    # assignment, not comparison
 862         my ( $return, $more_info );
 863         # NOTE: $flags in the following call is still undefined !
 864         ( $return, $session, $more_info ) = check_cookie_auth( $sessionID, $flags,
 865             { remote_addr => $ENV{REMOTE_ADDR}, skip_version_check => 1 }
 866         );
 867
 868         if ( $return eq 'ok' || $return eq 'additional-auth-needed' ) {
 869             $userid = $session->param('id');
 870         }
 871
 872         $auth_state =
 873             $return eq 'ok'                     ? 'completed'
 874           : $return eq 'additional-auth-needed' ? 'additional-auth-needed'
 875           :                                       'failed';
 876
 877         # We are at the second screen if the waiting-for-2FA is set in session
 878         # and otp_token param has been passed
 879         if (   $require_2FA
 880             && $auth_state eq 'additional-auth-needed'
 881             && ( my $otp_token = $query->param('otp_token') ) )
 882         {
 883             my $patron    = Koha::Patrons->find( { userid => $userid } );
 884             my $auth      = Koha::Auth::TwoFactorAuth->new( { patron => $patron } );
 885             my $verified = $auth->verify($otp_token);
 886             $auth->clear;
 887             if ( $verified ) {
 888                 # The token is correct, the user is fully logged in!
 889                 $auth_state = 'completed';
 890                 $session->param( 'waiting-for-2FA', 0 );
 891                 $session->param( 'waiting-for-2FA-setup', 0 );
 892
 893                # This is an ugly trick to pass the test
 894                # $query->param('koha_login_context') && ( $q_userid ne $userid )
 895                # few lines later
 896                 $q_userid = $userid;
 897             }
 898             else {
 899                 $invalid_otp_token = 1;
 900             }
 901         }
 902
 903         if ( $auth_state eq 'completed' ) {
 904             Koha::Logger->get->debug(sprintf "AUTH_SESSION: (%s)\t%s %s - %s", map { $session->param($_) || q{} } qw(cardnumber firstname surname branch));
 905
 906             if ( ( $query->param('koha_login_context') && ( $q_userid ne $userid ) )
 907                 || ( $cas && $query->param('ticket') && !C4::Context->userenv->{'id'} )
 908                 || ( $shib && $shib_login && !$logout && !C4::Context->userenv->{'id'} )
 909             ) {
 910
 911                 #if a user enters an id ne to the id in the current session, we need to log them in...
 912                 #first we need to clear the anonymous session...
 913                 $anon_search_history = $session->param('search_history');
 914                 $session->delete();
 915                 $session->flush;
 916                 $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 917                 C4::Context::_unset_userenv($sessionID);
 918                 $sessionID = undef;
 919                 undef $userid; # IMPORTANT: this assures us a new session in code below
 920                 $auth_state = 'failed';
 921             } elsif (!$logout) {
 922
 923                 $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 924                     -name     => 'CGISESSID',
 925                     -value    => $session->id,
 926                     -HttpOnly => 1,
 927                     -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 928                     -sameSite => 'Lax',
 929                 ));
 930
 931                 $flags = haspermission( $userid, $flagsrequired );
 932                 unless ( $flags ) {
 933                     $auth_state = 'failed';
 934                     $info{'nopermission'} = 1;
 935                 }
 936             }
 937         } elsif ( !$logout ) {
 938             if ( $return eq 'expired' ) {
 939                 $info{timed_out} = 1;
 940             } elsif ( $return eq 'restricted' ) {
 941                 $info{oldip}        = $more_info->{old_ip};
 942                 $info{newip}        = $more_info->{new_ip};
 943                 $info{different_ip} = 1;
 944             } elsif ( $return eq 'password_expired' ) {
 945                 $info{password_has_expired} = 1;
 946             }
 947         }
 948     }
 949
 950     my $request_method = $query->request_method // q{};
 951
 952     if ( $auth_state eq 'failed' || $logout ) {
 953         $sessionID = undef;
 954         $userid    = undef;
 955     }
 956
 957     if ($logout) {
 958
 959         # voluntary logout the user
 960         # check wether the user was using their shibboleth session or a local one
 961         my $shibSuccess = C4::Context->userenv ? C4::Context->userenv->{'shibboleth'} : undef;
 962         if ( $session ) {
 963             $session->delete();
 964             $session->flush;
 965         }
 966         C4::Context::_unset_userenv($sessionID);
 967         $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 968
 969         if ($cas and $caslogout) {
 970             logout_cas($query, $type);
 971         }
 972
 973         # If we are in a shibboleth session (shibboleth is enabled, a shibboleth match attribute is set and matches koha matchpoint)
 974         if ( $shib and $shib_login and $shibSuccess) {
 975             logout_shib($query);
 976         }
 977
 978         $session   = undef;
 979         $auth_state = 'logout';
 980     }
 981
 982     unless ( $userid ) {
 983         #we initiate a session prior to checking for a username to allow for anonymous sessions...
 984         if( !$session or !$sessionID ) { # if we cleared sessionID, we need a new session
 985             $session = get_session() or die "Auth ERROR: Cannot get_session()";
 986         }
 987
 988         # Save anonymous search history in new session so it can be retrieved
 989         # by get_template_and_user to store it in user's search history after
 990         # a successful login.
 991         if ($anon_search_history) {
 992             $session->param( 'search_history', $anon_search_history );
 993         }
 994
 995         $sessionID = $session->id;
 996         C4::Context->_new_userenv($sessionID);
 997         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 998             -name     => 'CGISESSID',
 999             -value    => $sessionID,
1000             -HttpOnly => 1,
1001             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1002             -sameSite => 'Lax',
1003         ));
1004         my $pki_field = C4::Context->preference('AllowPKIAuth');
1005         if ( !defined($pki_field) ) {
1006             print STDERR "ERROR: Missing system preference AllowPKIAuth.\n";
1007             $pki_field = 'None';
1008         }
1009         if ( ( $cas && $query->param('ticket') )
1010             || $q_userid
1011             || ( $shib && $shib_login )
1012             || $pki_field ne 'None'
1013             || $emailaddress )
1014         {
1015             my $password    = $query->param('password');
1016             my $shibSuccess = 0;
1017             my ( $return, $cardnumber );
1018
1019             # If shib is enabled and we have a shib login, does the login match a valid koha user
1020             if ( $shib && $shib_login ) {
1021                 my $retuserid;
1022
1023                 # Do not pass password here, else shib will not be checked in checkpw.
1024                 ( $return, $cardnumber, $retuserid ) = checkpw( $q_userid, undef, $query );
1025                 $userid      = $retuserid;
1026                 $shibSuccess = $return;
1027                 $info{'invalidShibLogin'} = 1 unless ($return);
1028             }
1029
1030             # If shib login and match were successful, skip further login methods
1031             unless ($shibSuccess) {
1032                 if ( $cas && $query->param('ticket') ) {
1033                     my $retuserid;
1034                     my $patron;
1035                     ( $return, $cardnumber, $retuserid, $patron, $cas_ticket ) =
1036                       checkpw( $userid, $password, $query, $type );
1037                     $userid = $retuserid;
1038                     $info{'invalidCasLogin'} = 1 unless ($return);
1039                 }
1040
1041                 elsif ( $emailaddress ) {
1042                     my $value = $emailaddress;
1043
1044                     # If we're looking up the email, there's a chance that the person
1045                     # doesn't have a userid. So if there is none, we pass along the
1046                     # borrower number, and the bits of code that need to know the user
1047                     # ID will have to be smart enough to handle that.
1048                     my $patrons = Koha::Patrons->search({ email => $value });
1049                     if ($patrons->count) {
1050
1051                         # First the userid, then the borrowernum
1052                         my $patron = $patrons->next;
1053                         $value = $patron->userid || $patron->borrowernumber;
1054                     } else {
1055                         undef $value;
1056                     }
1057                     $return = $value ? 1 : 0;
1058                     $userid = $value;
1059                 }
1060
1061                 elsif (
1062                     ( $pki_field eq 'Common Name' && $ENV{'SSL_CLIENT_S_DN_CN'} )
1063                     || ( $pki_field eq 'emailAddress'
1064                         && $ENV{'SSL_CLIENT_S_DN_Email'} )
1065                   )
1066                 {
1067                     my $value;
1068                     if ( $pki_field eq 'Common Name' ) {
1069                         $value = $ENV{'SSL_CLIENT_S_DN_CN'};
1070                     }
1071                     elsif ( $pki_field eq 'emailAddress' ) {
1072                         $value = $ENV{'SSL_CLIENT_S_DN_Email'};
1073
1074                         # If we're looking up the email, there's a chance that the person
1075                         # doesn't have a userid. So if there is none, we pass along the
1076                         # borrower number, and the bits of code that need to know the user
1077                         # ID will have to be smart enough to handle that.
1078                         my $patrons = Koha::Patrons->search({ email => $value });
1079                         if ($patrons->count) {
1080
1081                             # First the userid, then the borrowernum
1082                             my $patron = $patrons->next;
1083                             $value = $patron->userid || $patron->borrowernumber;
1084                         } else {
1085                             undef $value;
1086                         }
1087                     }
1088
1089                     $return = $value ? 1 : 0;
1090                     $userid = $value;
1091
1092                 }
1093                 else {
1094                     my $retuserid;
1095
1096                     if (
1097                         $request_method eq 'POST'
1098                         || ( C4::Context->preference('AutoSelfCheckID')
1099                             && $q_userid eq C4::Context->preference('AutoSelfCheckID') )
1100                       )
1101                     {
1102                         my $patron;
1103
1104                         ( $return, $cardnumber, $retuserid, $patron, $cas_ticket ) =
1105                           checkpw( $q_userid, $password, $query, $type );
1106                         $userid = $retuserid if ($retuserid);
1107                         $info{'invalid_username_or_password'} = 1 unless ($return);
1108                     }
1109                 }
1110             }
1111
1112             # If shib configured and shibOnly enabled, we should ignore anything other than a shibboleth type login.
1113             if (
1114                    $shib
1115                 && !$shibSuccess
1116                 && (
1117                     (
1118                         ( $type eq 'opac' )
1119                         && C4::Context->preference('OPACShibOnly')
1120                     )
1121                     || ( ( $type ne 'opac' )
1122                         && C4::Context->preference('staffShibOnly') )
1123                 )
1124               )
1125             {
1126                 $return = 0;
1127             }
1128
1129             # $return: 1 = valid user
1130             if( $return && $return > 0 ) {
1131
1132                 if ( $flags = haspermission( $userid, $flagsrequired ) ) {
1133                     $auth_state = "logged_in";
1134                 }
1135                 else {
1136                     $auth_state = 'failed';
1137                     # FIXME We could add $return = 0; or even delete the session?
1138                     # Currently return == 1 and we will fill session info later on,
1139                     # although we do present an authorization failure. (Yes, the
1140                     # authentication was actually correct.)
1141                     $info{'nopermission'} = 1;
1142                     C4::Context::_unset_userenv($sessionID);
1143                 }
1144                 my ( $borrowernumber, $firstname, $surname, $userflags,
1145                     $branchcode, $branchname, $emailaddress, $desk_id,
1146                     $desk_name, $register_id, $register_name );
1147
1148                 if ( $return == 1 ) {
1149                     my $select = "
1150                     SELECT borrowernumber, firstname, surname, flags, borrowers.branchcode,
1151                     branches.branchname    as branchname, email
1152                     FROM borrowers
1153                     LEFT JOIN branches on borrowers.branchcode=branches.branchcode
1154                     ";
1155                     my $dbh = C4::Context->dbh;
1156                     my $sth = $dbh->prepare("$select where userid=?");
1157                     $sth->execute($userid);
1158                     unless ( $sth->rows ) {
1159                         $sth = $dbh->prepare("$select where cardnumber=?");
1160                         $sth->execute($cardnumber);
1161
1162                         unless ( $sth->rows ) {
1163                             $sth->execute($userid);
1164                         }
1165                     }
1166                     if ( $sth->rows ) {
1167                         ( $borrowernumber, $firstname, $surname, $userflags,
1168                             $branchcode, $branchname, $emailaddress ) = $sth->fetchrow;
1169                     }
1170
1171                     # launch a sequence to check if we have a ip for the branch, i
1172                     # if we have one we replace the branchcode of the userenv by the branch bound in the ip.
1173
1174                     my $ip = $ENV{'REMOTE_ADDR'};
1175
1176                     # if they specify at login, use that
1177                     my $patron = Koha::Patrons->find({userid => $userid});
1178                     if ( $query->param('branch')  && ( haspermission($userid, {  'loggedinlibrary'=> 1 }) || $patron->is_superlibrarian ) ) {
1179                         $branchcode = $query->param('branch');
1180                         my $library = Koha::Libraries->find($branchcode);
1181                         $branchname = $library? $library->branchname: '';
1182                     }
1183                     if ( $query->param('desk_id') ) {
1184                         $desk_id = $query->param('desk_id');
1185                         my $desk = Koha::Desks->find($desk_id);
1186                         $desk_name = $desk ? $desk->desk_name : '';
1187                     }
1188                     if ( C4::Context->preference('UseCashRegisters') ) {
1189                         my $register =
1190                           $query->param('register_id')
1191                           ? Koha::Cash::Registers->find($query->param('register_id'))
1192                           : Koha::Cash::Registers->search(
1193                             { branch => $branchcode, branch_default => 1 },
1194                             { rows   => 1 } )->single;
1195                         $register_id   = $register->id   if ($register);
1196                         $register_name = $register->name if ($register);
1197                     }
1198                     my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1199                     if ( $type ne 'opac' and C4::Context->preference('AutoLocation') ) {
1200
1201                         # we have to check they are coming from the right ip range
1202                         my $domain = $branches->{$branchcode}->{'branchip'};
1203                         $domain =~ s|\.\*||g;
1204                         if ( $ip !~ /^$domain/ ) {
1205                             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1206                                 -name     => 'CGISESSID',
1207                                 -value    => '',
1208                                 -HttpOnly => 1,
1209                                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1210                                 -sameSite => 'Lax',
1211                             ));
1212                             $info{'wrongip'} = 1;
1213                             $auth_state = "failed";
1214                         }
1215                     }
1216
1217                     if ( C4::Context->preference('AutoLocation') && $auth_state ne 'failed' ) {
1218                         foreach my $br ( uniq( $branchcode, keys %$branches ) ) {
1219
1220                             #     now we work with the treatment of ip
1221                             my $domain = $branches->{$br}->{'branchip'};
1222                             if ( $domain && $ip =~ /^$domain/ ) {
1223                                 $branchcode = $branches->{$br}->{'branchcode'};
1224
1225                                 # new op dev : add the branchname to the cookie
1226                                 $branchname = $branches->{$br}->{'branchname'};
1227                                 last;
1228                             }
1229                         }
1230                     }
1231
1232                     my $is_sco_user = 0;
1233                     if ( $query->param('sco_user_login') && ( $query->param('sco_user_login') eq '1' ) ){
1234                         $is_sco_user = 1;
1235                     }
1236
1237                     $session->param( 'number',       $borrowernumber );
1238                     $session->param( 'id',           $userid );
1239                     $session->param( 'cardnumber',   $cardnumber );
1240                     $session->param( 'firstname',    $firstname );
1241                     $session->param( 'surname',      $surname );
1242                     $session->param( 'branch',       $branchcode );
1243                     $session->param( 'branchname',   $branchname );
1244                     $session->param( 'desk_id',      $desk_id);
1245                     $session->param( 'desk_name',     $desk_name);
1246                     $session->param( 'flags',        $userflags );
1247                     $session->param( 'emailaddress', $emailaddress );
1248                     $session->param( 'ip',           $session->remote_addr() );
1249                     $session->param( 'lasttime',     time() );
1250                     $session->param( 'interface',    $type);
1251                     $session->param( 'shibboleth',   $shibSuccess );
1252                     $session->param( 'register_id',  $register_id );
1253                     $session->param( 'register_name',  $register_name );
1254                     $session->param( 'sco_user', $is_sco_user );
1255                 }
1256                 $session->param('cas_ticket', $cas_ticket) if $cas_ticket;
1257                 C4::Context->set_userenv(
1258                     $session->param('number'),       $session->param('id'),
1259                     $session->param('cardnumber'),   $session->param('firstname'),
1260                     $session->param('surname'),      $session->param('branch'),
1261                     $session->param('branchname'),   $session->param('flags'),
1262                     $session->param('emailaddress'), $session->param('shibboleth'),
1263                     $session->param('desk_id'),      $session->param('desk_name'),
1264                     $session->param('register_id'),  $session->param('register_name')
1265                 );
1266
1267             }
1268             # $return: 0 = invalid user
1269             # reset to anonymous session
1270             else {
1271                 if ($userid) {
1272                     $info{'invalid_username_or_password'} = 1;
1273                     C4::Context::_unset_userenv($sessionID);
1274                 }
1275                 $session->param( 'lasttime', time() );
1276                 $session->param( 'ip',       $session->remote_addr() );
1277                 $session->param( 'sessiontype', 'anon' );
1278                 $session->param( 'interface', $type);
1279             }
1280         }    # END if ( $q_userid
1281         elsif ( $type eq "opac" ) {
1282
1283             # anonymous sessions are created only for the OPAC
1284
1285             # setting a couple of other session vars...
1286             $session->param( 'ip',          $session->remote_addr() );
1287             $session->param( 'lasttime',    time() );
1288             $session->param( 'sessiontype', 'anon' );
1289             $session->param( 'interface', $type);
1290         }
1291         $session->flush;
1292     }    # END unless ($userid)
1293
1294
1295     if ( $auth_state eq 'logged_in' ) {
1296         $auth_state = 'completed';
1297
1298         # Auth is completed unless an additional auth is needed
1299         if ( $require_2FA ) {
1300             my $patron = Koha::Patrons->find({userid => $userid});
1301             if ( C4::Context->preference('TwoFactorAuthentication') eq "enforced" && $patron->auth_method eq 'password' ) {
1302                 $auth_state = 'setup-additional-auth-needed';
1303                 $session->param('waiting-for-2FA-setup', 1);
1304                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1305             } elsif ( $patron->auth_method eq 'two-factor' ) {
1306                 # Ask for the OTP token
1307                 $auth_state = 'additional-auth-needed';
1308                 $session->param('waiting-for-2FA', 1);
1309                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1310             }
1311         }
1312     }
1313
1314     # finished authentification, now respond
1315     my $auth_template_name = ( $type eq 'opac' ) ? 'opac-auth.tt' : 'auth.tt';
1316     if ( $auth_state eq 'completed' || $authnotrequired ) {
1317         # successful login
1318         unless (@$cookie) {
1319             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1320                 -name     => 'CGISESSID',
1321                 -value    => '',
1322                 -HttpOnly => 1,
1323                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1324                 -sameSite => 'Lax',
1325             ));
1326         }
1327
1328         my $patron = $userid ? Koha::Patrons->find({ userid => $userid }) : undef;
1329         $patron->update_lastseen('login') if $patron;
1330
1331         my $original_op_cud = $query->param('op-cud');
1332         if ( $request_method eq 'GET' ) {
1333             $query->param('op-cud', undef);
1334         } elsif ( $request_method eq 'POST' ) {
1335             $query->param('op', undef);
1336         }
1337
1338         if ( defined $original_op_cud ) {
1339             die "Cannot use GET for this request"
1340                 if $request_method ne 'POST';
1341
1342             print $query->header(
1343                 {
1344                     type              => 'text/html',
1345                     charset           => 'utf-8',
1346                     cookie            => $cookie,
1347                     'X-Frame-Options' => 'SAMEORIGIN',
1348                     -sameSite         => 'Lax'
1349                 }
1350             );
1351
1352             my $template = C4::Templates::gettemplate( $auth_template_name, $type, $query );
1353             output_and_exit( $query, $cookie, $template, 'wrong_csrf_token' )
1354                 unless Koha::Token->new->check_csrf(
1355                     {
1356                         session_id => scalar $query->cookie('CGISESSID'),
1357                         token      => scalar $query->param('csrf_token'),
1358                     }
1359                 );
1360         }
1361
1362         # In case, that this request was a login attempt, we want to prevent that users can repost the opac login
1363         # request. We therefore redirect the user to the requested page again without the login parameters.
1364         # See Post/Redirect/Get (PRG) design pattern: https://en.wikipedia.org/wiki/Post/Redirect/Get
1365         if ( $type eq "opac" && $query->param('koha_login_context') && $query->param('koha_login_context') ne 'sco' && $query->param('password') && $query->param('userid') ) {
1366             my $uri = URI->new($query->url(-relative=>1, -query_string=>1));
1367             $uri->query_param_delete('userid');
1368             $uri->query_param_delete('password');
1369             $uri->query_param_delete('koha_login_context');
1370             unless ( $params->{do_not_print} ) {
1371                 print $query->redirect( -uri => $uri->as_string, -cookie => $cookie, -status => '303 See other' );
1372                 safe_exit;
1373             }
1374         }
1375
1376         return ( $userid, $cookie, $sessionID, $flags );
1377     }
1378
1379     #
1380     #
1381     # AUTH rejected, show the login/password template, after checking the DB.
1382     #
1383     #
1384
1385     my $patron = Koha::Patrons->find({ userid => $q_userid }); # Not necessary logged in!
1386
1387     # get the inputs from the incoming query
1388     my @inputs = ();
1389     my @inputs_to_clean = qw( userid password ticket logout.x otp_token );
1390     foreach my $name ( param $query) {
1391         next if grep { $name eq $_ } @inputs_to_clean;
1392         my @value = $query->multi_param($name);
1393         push @inputs, { name => $name, value => $_ } for @value;
1394     }
1395
1396     my $LibraryNameTitle = C4::Context->preference("LibraryName");
1397     $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
1398     $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
1399
1400     my $auth_error = $query->param('auth_error');
1401     my $template = C4::Templates::gettemplate( $auth_template_name, $type, $query );
1402     $template->param(
1403         login                                 => 1,
1404         INPUTS                                => \@inputs,
1405         script_name                           => get_script_name(),
1406         casAuthentication                     => C4::Context->preference("casAuthentication"),
1407         shibbolethAuthentication              => $shib,
1408         suggestion                            => C4::Context->preference("suggestion"),
1409         virtualshelves                        => C4::Context->preference("virtualshelves"),
1410         LibraryName                           => "" . C4::Context->preference("LibraryName"),
1411         LibraryNameTitle                      => "" . $LibraryNameTitle,
1412         opacuserlogin                         => C4::Context->preference("opacuserlogin"),
1413         OpacFavicon                           => C4::Context->preference("OpacFavicon"),
1414         opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
1415         opaclanguagesdisplay                  => C4::Context->preference("opaclanguagesdisplay"),
1416         opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
1417         OpacCloud                             => C4::Context->preference("OpacCloud"),
1418         OpacTopissue                          => C4::Context->preference("OpacTopissue"),
1419         OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
1420         OpacBrowser                           => C4::Context->preference("OpacBrowser"),
1421         TagsEnabled                           => C4::Context->preference("TagsEnabled"),
1422         intranetcolorstylesheet               => C4::Context->preference("intranetcolorstylesheet"),
1423         intranetstylesheet                    => C4::Context->preference("intranetstylesheet"),
1424         IntranetNav                           => C4::Context->preference("IntranetNav"),
1425         IntranetFavicon                       => C4::Context->preference("IntranetFavicon"),
1426         IntranetUserCSS                       => C4::Context->preference("IntranetUserCSS"),
1427         IntranetUserJS                        => C4::Context->preference("IntranetUserJS"),
1428         IndependentBranches                   => C4::Context->preference("IndependentBranches"),
1429         AutoLocation                          => C4::Context->preference("AutoLocation"),
1430         wrongip                               => $info{'wrongip'},
1431         PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
1432         PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
1433         opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
1434         too_many_login_attempts               => ( $patron and $patron->account_locked ),
1435         password_has_expired                  => ( $patron and $patron->password_expired ),
1436         auth_error                            => $auth_error,
1437     );
1438
1439     $template->param( SCO_login => 1 ) if ( $query->param('sco_user_login') );
1440     $template->param( SCI_login => 1 ) if ( $query->param('sci_user_login') );
1441     $template->param( OpacPublic => C4::Context->preference("OpacPublic") );
1442     $template->param( loginprompt => 1 ) unless $info{'nopermission'};
1443     if ( $auth_state eq 'additional-auth-needed' ) {
1444         my $patron = Koha::Patrons->find( { userid => $userid } );
1445         $template->param(
1446             TwoFA_prompt => 1,
1447             invalid_otp_token => $invalid_otp_token,
1448             notice_email_address => $patron->notice_email_address, # We could also pass logged_in_user if necessary
1449         );
1450     }
1451
1452     if ( $auth_state eq 'setup-additional-auth-needed' ) {
1453         $template->param(
1454             TwoFA_setup => 1,
1455         );
1456     }
1457
1458     if ( $type eq 'opac' ) {
1459         require Koha::Virtualshelves;
1460         my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1461             {
1462                 public => 1,
1463             }
1464         );
1465         $template->param(
1466             some_public_shelves  => $some_public_shelves,
1467         );
1468     }
1469
1470     if ($cas) {
1471
1472         # Is authentication against multiple CAS servers enabled?
1473         require C4::Auth_with_cas;
1474         if ( multipleAuth() && !$casparam ) {
1475             my $casservers = getMultipleAuth();
1476             my @tmplservers;
1477             foreach my $key ( keys %$casservers ) {
1478                 push @tmplservers, { name => $key, value => login_cas_url( $query, $key, $type ) . "?cas=$key" };
1479             }
1480             $template->param(
1481                 casServersLoop => \@tmplservers
1482             );
1483         } else {
1484             $template->param(
1485                 casServerUrl => login_cas_url($query, undef, $type),
1486             );
1487         }
1488
1489         $template->param(
1490             invalidCasLogin => $info{'invalidCasLogin'}
1491         );
1492     }
1493
1494     if ($shib) {
1495         #If shibOnly is enabled just go ahead and redirect directly
1496         if ( (($type eq 'opac') && C4::Context->preference('OPACShibOnly')) || (($type ne 'opac') && C4::Context->preference('staffShibOnly')) ) {
1497             my $redirect_url = login_shib_url( $query );
1498             print $query->redirect( -uri => "$redirect_url", -status => 303 );
1499             safe_exit;
1500         }
1501
1502         $template->param(
1503             shibbolethAuthentication => $shib,
1504             shibbolethLoginUrl       => login_shib_url($query),
1505         );
1506     }
1507
1508     if (C4::Context->preference('GoogleOpenIDConnect')) {
1509         if ($query->param("OpenIDConnectFailed")) {
1510             my $reason = $query->param('OpenIDConnectFailed');
1511             $template->param(invalidGoogleOpenIDConnectLogin => $reason);
1512         }
1513     }
1514
1515     $template->param(
1516         LibraryName => C4::Context->preference("LibraryName"),
1517         %info,
1518         sessionID => $session->id,
1519     );
1520
1521     if ( $params->{do_not_print} ) {
1522         # This must be used for testing purpose only!
1523         return ( undef, undef, undef, undef, $template );
1524     }
1525
1526     print $query->header(
1527         {   type              => 'text/html',
1528             charset           => 'utf-8',
1529             cookie            => $cookie,
1530             'X-Frame-Options' => 'SAMEORIGIN',
1531             -sameSite => 'Lax'
1532         }
1533       ),
1534       $template->output;
1535     safe_exit;
1536 }
1537
1538 =head2 check_api_auth
1539
1540   ($status, $cookie, $sessionId) = check_api_auth($query, $userflags);
1541
1542 Given a CGI query containing the parameters 'userid' and 'password' and/or a session
1543 cookie, determine if the user has the privileges specified by C<$userflags>.
1544
1545 C<check_api_auth> is is meant for authenticating users of web services, and
1546 consequently will always return and will not attempt to redirect the user
1547 agent.
1548
1549 If a valid session cookie is already present, check_api_auth will return a status
1550 of "ok", the cookie, and the Koha session ID.
1551
1552 If no session cookie is present, check_api_auth will check the 'userid' and 'password
1553 parameters and create a session cookie and Koha session if the supplied credentials
1554 are OK.
1555
1556 Possible return values in C<$status> are:
1557
1558 =over
1559
1560 =item "ok" -- user authenticated; C<$cookie> and C<$sessionid> have valid values.
1561
1562 =item "failed" -- credentials are not correct; C<$cookie> and C<$sessionid> are undef
1563
1564 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1565
1566 =item "expired -- session cookie has expired; API user should resubmit userid and password
1567
1568 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1569
1570 =item "additional-auth-needed -- User is in an authentication process that is not finished
1571
1572 =back
1573
1574 =cut
1575
1576 sub check_api_auth {
1577
1578     my $query         = shift;
1579     my $flagsrequired = shift;
1580     my $timeout = _timeout_syspref();
1581
1582     unless ( C4::Context->preference('Version') ) {
1583
1584         # database has not been installed yet
1585         return ( "maintenance", undef, undef );
1586     }
1587     my $kohaversion = Koha::version();
1588     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1589     if ( C4::Context->preference('Version') < $kohaversion ) {
1590
1591         # database in need of version update; assume that
1592         # no API should be called while databsae is in
1593         # this condition.
1594         return ( "maintenance", undef, undef );
1595     }
1596
1597     my ( $sessionID, $session );
1598     unless ( $query->param('userid') ) {
1599         $sessionID = $query->cookie("CGISESSID");
1600     }
1601     if ( $sessionID && not( $cas && $query->param('PT') ) ) {
1602
1603         my $return;
1604         ( $return, $session, undef ) = check_cookie_auth(
1605             $sessionID, $flagsrequired, { remote_addr => $ENV{REMOTE_ADDR} } );
1606
1607         return ( $return, undef, undef ) # Cookie auth failed
1608             if $return ne "ok";
1609
1610         my $cookie = $query->cookie(
1611             -name     => 'CGISESSID',
1612             -value    => $session->id,
1613             -HttpOnly => 1,
1614             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1615             -sameSite => 'Lax'
1616         );
1617         return ( $return, $cookie, $session ); # return == 'ok' here
1618
1619     } else {
1620
1621         # new login
1622         my $userid   = $query->param('userid');
1623         my $password = $query->param('password');
1624         my ( $return, $cardnumber, $cas_ticket );
1625
1626         # Proxy CAS auth
1627         if ( $cas && $query->param('PT') ) {
1628             my $retuserid;
1629
1630             # In case of a CAS authentication, we use the ticket instead of the password
1631             my $PT = $query->param('PT');
1632             ( $return, $cardnumber, $userid, $cas_ticket ) = check_api_auth_cas( $PT, $query );    # EXTERNAL AUTH
1633         } else {
1634
1635             # User / password auth
1636             unless ( $userid and $password ) {
1637
1638                 # caller did something wrong, fail the authenticateion
1639                 return ( "failed", undef, undef );
1640             }
1641             my $newuserid;
1642             my $patron;
1643             ( $return, $cardnumber, $newuserid, $patron, $cas_ticket ) = checkpw( $userid, $password, $query );
1644         }
1645
1646         if ( $return and haspermission( $userid, $flagsrequired ) ) {
1647             my $session = get_session("");
1648             return ( "failed", undef, undef ) unless $session;
1649
1650             my $sessionID = $session->id;
1651             C4::Context->_new_userenv($sessionID);
1652             my $cookie = $query->cookie(
1653                 -name     => 'CGISESSID',
1654                 -value    => $sessionID,
1655                 -HttpOnly => 1,
1656                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1657                 -sameSite => 'Lax'
1658             );
1659             if ( $return == 1 ) {
1660                 my (
1661                     $borrowernumber, $firstname,  $surname,
1662                     $userflags,      $branchcode, $branchname,
1663                     $emailaddress
1664                 );
1665                 my $dbh = C4::Context->dbh;
1666                 my $sth =
1667                   $dbh->prepare(
1668 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where userid=?"
1669                   );
1670                 $sth->execute($userid);
1671                 (
1672                     $borrowernumber, $firstname,  $surname,
1673                     $userflags,      $branchcode, $branchname,
1674                     $emailaddress
1675                 ) = $sth->fetchrow if ( $sth->rows );
1676
1677                 unless ( $sth->rows ) {
1678                     my $sth = $dbh->prepare(
1679 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1680                     );
1681                     $sth->execute($cardnumber);
1682                     (
1683                         $borrowernumber, $firstname,  $surname,
1684                         $userflags,      $branchcode, $branchname,
1685                         $emailaddress
1686                     ) = $sth->fetchrow if ( $sth->rows );
1687
1688                     unless ( $sth->rows ) {
1689                         $sth->execute($userid);
1690                         (
1691                             $borrowernumber, $firstname,  $surname,       $userflags,
1692                             $branchcode,     $branchname, $emailaddress
1693                         ) = $sth->fetchrow if ( $sth->rows );
1694                     }
1695                 }
1696
1697                 my $ip = $ENV{'REMOTE_ADDR'};
1698
1699                 # if they specify at login, use that
1700                 if ( $query->param('branch') ) {
1701                     $branchcode = $query->param('branch');
1702                     my $library = Koha::Libraries->find($branchcode);
1703                     $branchname = $library? $library->branchname: '';
1704                 }
1705                 my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1706                 foreach my $br ( keys %$branches ) {
1707
1708                     #     now we work with the treatment of ip
1709                     my $domain = $branches->{$br}->{'branchip'};
1710                     if ( $domain && $ip =~ /^$domain/ ) {
1711                         $branchcode = $branches->{$br}->{'branchcode'};
1712
1713                         # new op dev : add the branchname to the cookie
1714                         $branchname    = $branches->{$br}->{'branchname'};
1715                     }
1716                 }
1717                 $session->param( 'number',       $borrowernumber );
1718                 $session->param( 'id',           $userid );
1719                 $session->param( 'cardnumber',   $cardnumber );
1720                 $session->param( 'firstname',    $firstname );
1721                 $session->param( 'surname',      $surname );
1722                 $session->param( 'branch',       $branchcode );
1723                 $session->param( 'branchname',   $branchname );
1724                 $session->param( 'flags',        $userflags );
1725                 $session->param( 'emailaddress', $emailaddress );
1726                 $session->param( 'ip',           $session->remote_addr() );
1727                 $session->param( 'lasttime',     time() );
1728                 $session->param( 'interface',    'api'  );
1729             }
1730             $session->param( 'cas_ticket', $cas_ticket);
1731             C4::Context->set_userenv(
1732                 $session->param('number'),       $session->param('id'),
1733                 $session->param('cardnumber'),   $session->param('firstname'),
1734                 $session->param('surname'),      $session->param('branch'),
1735                 $session->param('branchname'),   $session->param('flags'),
1736                 $session->param('emailaddress'), $session->param('shibboleth'),
1737                 $session->param('desk_id'),      $session->param('desk_name'),
1738                 $session->param('register_id'),  $session->param('register_name')
1739             );
1740             return ( "ok", $cookie, $sessionID );
1741         } else {
1742             return ( "failed", undef, undef );
1743         }
1744     }
1745 }
1746
1747 =head2 check_cookie_auth
1748
1749   ($status, $sessionId) = check_cookie_auth($cookie, $userflags);
1750
1751 Given a CGISESSID cookie set during a previous login to Koha, determine
1752 if the user has the privileges specified by C<$userflags>. C<$userflags>
1753 is passed unaltered into C<haspermission> and as such accepts all options
1754 avaiable to that routine with the one caveat that C<check_api_auth> will
1755 also allow 'undef' to be passed and in such a case the permissions check
1756 will be skipped altogether.
1757
1758 C<check_cookie_auth> is meant for authenticating special services
1759 such as tools/upload-file.pl that are invoked by other pages that
1760 have been authenticated in the usual way.
1761
1762 Possible return values in C<$status> are:
1763
1764 =over
1765
1766 =item "ok" -- user authenticated; C<$sessionID> have valid values.
1767
1768 =item "anon" -- user not authenticated but valid for anonymous session.
1769
1770 =item "failed" -- credentials are not correct; C<$sessionid> are undef
1771
1772 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1773
1774 =item "expired -- session cookie has expired; API user should resubmit userid and password
1775
1776 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1777
1778 =back
1779
1780 =cut
1781
1782 sub check_cookie_auth {
1783     my $sessionID     = shift;
1784     my $flagsrequired = shift;
1785     my $params        = shift;
1786
1787     my $remote_addr = $params->{remote_addr} || $ENV{REMOTE_ADDR};
1788
1789     my $skip_version_check = $params->{skip_version_check}; # Only for checkauth
1790
1791     unless ( $skip_version_check ) {
1792         unless ( C4::Context->preference('Version') ) {
1793
1794             # database has not been installed yet
1795             return ( "maintenance", undef );
1796         }
1797         my $kohaversion = Koha::version();
1798         $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1799         if ( C4::Context->preference('Version') < $kohaversion ) {
1800
1801             # database in need of version update; assume that
1802             # no API should be called while databsae is in
1803             # this condition.
1804             return ( "maintenance", undef );
1805         }
1806     }
1807
1808     # see if we have a valid session cookie already
1809     # however, if a userid parameter is present (i.e., from
1810     # a form submission, assume that any current cookie
1811     # is to be ignored
1812     unless ( $sessionID ) {
1813         return ( "failed", undef );
1814     }
1815     C4::Context::_unset_userenv($sessionID); # remove old userenv first
1816     my $session   = get_session($sessionID);
1817     if ($session) {
1818         my $userid   = $session->param('id');
1819         my $ip       = $session->param('ip');
1820         my $lasttime = $session->param('lasttime');
1821         my $timeout = _timeout_syspref();
1822
1823         if ( !$lasttime || ( $lasttime < time() - $timeout ) ) {
1824             # time out
1825             $session->delete();
1826             $session->flush;
1827             return ("expired", undef);
1828
1829         } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $remote_addr ) {
1830             # IP address changed
1831             $session->delete();
1832             $session->flush;
1833             return ( "restricted", undef, { old_ip => $ip, new_ip => $remote_addr});
1834
1835         } elsif ( $userid ) {
1836             $session->param( 'lasttime', time() );
1837             my $patron = Koha::Patrons->find({ userid => $userid });
1838
1839             # If the user modify their own userid
1840             # Better than 500 but we could do better
1841             unless ( $patron ) {
1842                 $session->delete();
1843                 $session->flush;
1844                 return ("expired", undef);
1845             }
1846
1847             $patron = Koha::Patrons->find({ cardnumber => $userid })
1848               unless $patron;
1849             return ("password_expired", undef ) if $patron->password_expired;
1850             my $flags = defined($flagsrequired) ? haspermission( $userid, $flagsrequired ) : 1;
1851             if ($flags) {
1852                 C4::Context->_new_userenv($sessionID);
1853                 if ( !C4::Context->interface ) {
1854                     # No need to override the interface, most often set by get_template_and_user
1855                     C4::Context->interface( $session->param('interface') );
1856                 }
1857                 C4::Context->set_userenv(
1858                     $session->param('number'),       $session->param('id') // '',
1859                     $session->param('cardnumber'),   $session->param('firstname'),
1860                     $session->param('surname'),      $session->param('branch'),
1861                     $session->param('branchname'),   $session->param('flags'),
1862                     $session->param('emailaddress'), $session->param('shibboleth'),
1863                     $session->param('desk_id'),      $session->param('desk_name'),
1864                     $session->param('register_id'),  $session->param('register_name')
1865                 );
1866                 if ( C4::Context->preference('TwoFactorAuthentication') ne 'disabled' ) {
1867                     return ( "additional-auth-needed", $session )
1868                         if $session->param('waiting-for-2FA');
1869
1870                     return ( "setup-additional-auth-needed", $session )
1871                         if $session->param('waiting-for-2FA-setup');
1872                 }
1873
1874                 return ( "ok", $session );
1875             } else {
1876                 $session->delete();
1877                 $session->flush;
1878                 return ( "failed", undef );
1879             }
1880
1881         } else {
1882             C4::Context->_new_userenv($sessionID);
1883             C4::Context->interface($session->param('interface'));
1884             C4::Context->set_userenv( undef, q{} );
1885             return ( "anon", $session );
1886         }
1887     } else {
1888         return ( "expired", undef );
1889     }
1890 }
1891
1892 =head2 get_session
1893
1894   use CGI::Session;
1895   my $session = get_session($sessionID);
1896
1897 Given a session ID, retrieve the CGI::Session object used to store
1898 the session's state.  The session object can be used to store
1899 data that needs to be accessed by different scripts during a
1900 user's session.
1901
1902 If the C<$sessionID> parameter is an empty string, a new session
1903 will be created.
1904
1905 =cut
1906
1907 #NOTE: We're keeping this for backwards compatibility
1908 sub _get_session_params {
1909     return Koha::Session->_get_session_params();
1910 }
1911
1912 #NOTE: We're keeping this for backwards compatibility
1913 sub get_session {
1914     my $sessionID = shift;
1915     my $session   = Koha::Session->get_session( { sessionID => $sessionID } );
1916     return $session;
1917 }
1918
1919 =head2 create_basic_session
1920
1921 my $session = create_basic_session({ patron => $patron, interface => $interface });
1922
1923 Creates a session and adds all basic parameters for a session to work
1924
1925 =cut
1926
1927 sub create_basic_session {
1928     my $params    = shift;
1929     my $patron    = $params->{patron};
1930     my $interface = $params->{interface};
1931
1932     $interface = 'intranet' if $interface eq 'staff';
1933
1934     my $session = get_session("");
1935
1936     $session->param( 'number',       $patron->borrowernumber );
1937     $session->param( 'id',           $patron->userid );
1938     $session->param( 'cardnumber',   $patron->cardnumber );
1939     $session->param( 'firstname',    $patron->firstname );
1940     $session->param( 'surname',      $patron->surname );
1941     $session->param( 'branch',       $patron->branchcode );
1942     $session->param( 'branchname',   $patron->library->branchname );
1943     $session->param( 'flags',        $patron->flags );
1944     $session->param( 'emailaddress', $patron->email );
1945     $session->param( 'ip',           $session->remote_addr() );
1946     $session->param( 'lasttime',     time() );
1947     $session->param( 'interface',    $interface);
1948
1949     return $session;
1950 }
1951
1952
1953 # FIXME no_set_userenv may be replaced with force_branchcode_for_userenv
1954 # (or something similar)
1955 # Currently it's only passed from C4::SIP::ILS::Patron::check_password, but
1956 # not having a userenv defined could cause a crash.
1957 sub checkpw {
1958     my ( $userid, $password, $query, $type, $no_set_userenv ) = @_;
1959     $type = 'opac' unless $type;
1960
1961     # Get shibboleth login attribute
1962     my $shib       = C4::Context->config('useshibboleth') && shib_ok();
1963     my $shib_login = $shib ? get_login_shib() : undef;
1964
1965     my @return;
1966     my $patron;
1967     if ( defined $userid ) {
1968         $patron = Koha::Patrons->find( { userid     => $userid } );
1969         $patron = Koha::Patrons->find( { cardnumber => $userid } ) unless $patron;
1970     }
1971     my $check_internal_as_fallback = 0;
1972     my $passwd_ok                  = 0;
1973
1974     # Note: checkpw_* routines returns:
1975     # 1 if auth is ok
1976     # 0 if auth is nok
1977     # -1 if user bind failed (LDAP only)
1978
1979     if ( $patron and ( $patron->account_locked ) ) {
1980
1981         # Nothing to check, account is locked
1982     } elsif ( $ldap && defined($password) ) {
1983         my ( $retval, $retcard, $retuserid );
1984         ( $retval, $retcard, $retuserid, $patron ) = checkpw_ldap(@_);    # EXTERNAL AUTH
1985         if ( $retval == 1 ) {
1986             @return    = ( $retval, $retcard, $retuserid, $patron );
1987             $passwd_ok = 1;
1988         }
1989         $check_internal_as_fallback = 1 if $retval == 0;
1990
1991     } elsif ( $cas && $query && $query->param('ticket') ) {
1992
1993         # In case of a CAS authentication, we use the ticket instead of the password
1994         my $ticket = $query->param('ticket');
1995         $query->delete('ticket');                                         # remove ticket to come back to original URL
1996         my ( $retval, $retcard, $retuserid, $cas_ticket, $patron ) =
1997             checkpw_cas( $ticket, $query, $type );                        # EXTERNAL AUTH
1998         if ($retval) {
1999             @return = ( $retval, $retcard, $retuserid, $patron, $cas_ticket );
2000         } else {
2001             @return = (0);
2002         }
2003         $passwd_ok = $retval;
2004     }
2005
2006     # If we are in a shibboleth session (shibboleth is enabled, and a shibboleth match attribute is present)
2007     # Check for password to asertain whether we want to be testing against shibboleth or another method this
2008     # time around.
2009     elsif ( $shib && $shib_login && !$password ) {
2010
2011         # In case of a Shibboleth authentication, we expect a shibboleth user attribute
2012         # (defined under shibboleth mapping in koha-conf.xml) to contain the login of the
2013         # shibboleth-authenticated user
2014
2015         # Then, we check if it matches a valid koha user
2016         if ($shib_login) {
2017             my ( $retval, $retcard, $retuserid, $patron ) =
2018                 C4::Auth_with_shibboleth::checkpw_shib($shib_login);    # EXTERNAL AUTH
2019             if ($retval) {
2020                 @return = ( $retval, $retcard, $retuserid, $patron );
2021             }
2022             $passwd_ok = $retval;
2023         }
2024     } else {
2025         $check_internal_as_fallback = 1;
2026     }
2027
2028     # INTERNAL AUTH
2029     if ($check_internal_as_fallback) {
2030         @return = checkpw_internal( $userid, $password, $no_set_userenv );
2031         push( @return, $patron );
2032         $passwd_ok = 1 if $return[0] > 0;    # 1 or 2
2033     }
2034
2035     if ($patron) {
2036         if ($passwd_ok) {
2037             $patron->update( { login_attempts => 0 } );
2038             if ( $patron->password_expired ) {
2039                 @return = ( -2, $patron );
2040             }
2041         } elsif ( !$patron->account_locked ) {
2042             $patron->update( { login_attempts => $patron->login_attempts + 1 } );
2043         }
2044     }
2045
2046     # Optionally log success or failure
2047     if ( $patron && $passwd_ok && C4::Context->preference('AuthSuccessLog') ) {
2048         logaction( 'AUTH', 'SUCCESS', $patron->id, "Valid password for $userid", $type );
2049     } elsif ( !$passwd_ok && C4::Context->preference('AuthFailureLog') ) {
2050         logaction( 'AUTH', 'FAILURE', $patron ? $patron->id : 0, "Wrong password for $userid", $type );
2051     }
2052
2053     return @return;
2054 }
2055
2056 sub checkpw_internal {
2057     my ( $userid, $password, $no_set_userenv ) = @_;
2058
2059     $password = Encode::encode( 'UTF-8', $password )
2060       if Encode::is_utf8($password);
2061
2062     my $dbh = C4::Context->dbh;
2063     my $sth =
2064       $dbh->prepare(
2065         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where userid=?"
2066       );
2067     $sth->execute($userid);
2068     if ( $sth->rows ) {
2069         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2070             $surname, $branchcode, $branchname, $flags )
2071           = $sth->fetchrow;
2072
2073         if ( checkpw_hash( $password, $stored_hash ) ) {
2074
2075             C4::Context->set_userenv( "$borrowernumber", $userid, $cardnumber,
2076                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2077             return 1, $cardnumber, $userid;
2078         }
2079     }
2080     $sth =
2081       $dbh->prepare(
2082         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
2083       );
2084     $sth->execute($userid);
2085     if ( $sth->rows ) {
2086         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2087             $surname, $branchcode, $branchname, $flags )
2088           = $sth->fetchrow;
2089
2090         if ( checkpw_hash( $password, $stored_hash ) ) {
2091
2092             C4::Context->set_userenv( $borrowernumber, $userid, $cardnumber,
2093                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2094             return 1, $cardnumber, $userid;
2095         }
2096     }
2097     return 0;
2098 }
2099
2100 sub checkpw_hash {
2101     my ( $password, $stored_hash ) = @_;
2102
2103     return if $stored_hash eq '!';
2104
2105     # check what encryption algorithm was implemented: Bcrypt - if the hash starts with '$2' it is Bcrypt else md5
2106     my $hash;
2107     if ( substr( $stored_hash, 0, 2 ) eq '$2' ) {
2108         $hash = hash_password( $password, $stored_hash );
2109     } else {
2110         $hash = md5_base64($password);
2111     }
2112     return $hash eq $stored_hash;
2113 }
2114
2115 =head2 getuserflags
2116
2117     my $authflags = getuserflags($flags, $userid, [$dbh]);
2118
2119 Translates integer flags into permissions strings hash.
2120
2121 C<$flags> is the integer userflags value ( borrowers.userflags )
2122 C<$userid> is the members.userid, used for building subpermissions
2123 C<$authflags> is a hashref of permissions
2124
2125 =cut
2126
2127 sub getuserflags {
2128     my $flags  = shift;
2129     my $userid = shift;
2130     my $dbh    = @_ ? shift : C4::Context->dbh;
2131     my $userflags;
2132     {
2133         # I don't want to do this, but if someone logs in as the database
2134         # user, it would be preferable not to spam them to death with
2135         # numeric warnings. So, we make $flags numeric.
2136         no warnings 'numeric';
2137         $flags += 0;
2138     }
2139     my $sth = $dbh->prepare("SELECT bit, flag, defaulton FROM userflags");
2140     $sth->execute;
2141
2142     while ( my ( $bit, $flag, $defaulton ) = $sth->fetchrow ) {
2143         if ( ( $flags & ( 2**$bit ) ) || $defaulton ) {
2144             $userflags->{$flag} = 1;
2145         }
2146         else {
2147             $userflags->{$flag} = 0;
2148         }
2149     }
2150
2151     # get subpermissions and merge with top-level permissions
2152     my $user_subperms = get_user_subpermissions($userid);
2153     foreach my $module ( keys %$user_subperms ) {
2154         next if $userflags->{$module} == 1;    # user already has permission for everything in this module
2155         $userflags->{$module} = $user_subperms->{$module};
2156     }
2157
2158     return $userflags;
2159 }
2160
2161 =head2 get_user_subpermissions
2162
2163   $user_perm_hashref = get_user_subpermissions($userid);
2164
2165 Given the userid (note, not the borrowernumber) of a staff user,
2166 return a hashref of hashrefs of the specific subpermissions
2167 accorded to the user.  An example return is
2168
2169  {
2170     tools => {
2171         export_catalog => 1,
2172         import_patrons => 1,
2173     }
2174  }
2175
2176 The top-level hash-key is a module or function code from
2177 userflags.flag, while the second-level key is a code
2178 from permissions.
2179
2180 The results of this function do not give a complete picture
2181 of the functions that a staff user can access; it is also
2182 necessary to check borrowers.flags.
2183
2184 =cut
2185
2186 sub get_user_subpermissions {
2187     my $userid = shift;
2188
2189     my $dbh = C4::Context->dbh;
2190     my $sth = $dbh->prepare( "SELECT flag, user_permissions.code
2191                              FROM user_permissions
2192                              JOIN permissions USING (module_bit, code)
2193                              JOIN userflags ON (module_bit = bit)
2194                              JOIN borrowers USING (borrowernumber)
2195                              WHERE userid = ?" );
2196     $sth->execute($userid);
2197
2198     my $user_perms = {};
2199     while ( my $perm = $sth->fetchrow_hashref ) {
2200         $user_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2201     }
2202     return $user_perms;
2203 }
2204
2205 =head2 get_all_subpermissions
2206
2207   my $perm_hashref = get_all_subpermissions();
2208
2209 Returns a hashref of hashrefs defining all specific
2210 permissions currently defined.  The return value
2211 has the same structure as that of C<get_user_subpermissions>,
2212 except that the innermost hash value is the description
2213 of the subpermission.
2214
2215 =cut
2216
2217 sub get_all_subpermissions {
2218     my $dbh = C4::Context->dbh;
2219     my $sth = $dbh->prepare( "SELECT flag, code
2220                              FROM permissions
2221                              JOIN userflags ON (module_bit = bit)" );
2222     $sth->execute();
2223
2224     my $all_perms = {};
2225     while ( my $perm = $sth->fetchrow_hashref ) {
2226         $all_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2227     }
2228     return $all_perms;
2229 }
2230
2231 =head2 get_cataloguing_page_permissions
2232
2233     my $required_permissions = get_cataloguing_page_permissions();
2234
2235 Returns the required permissions to access the main cataloguing page. Useful for building
2236 the global I<can_see_cataloguing_module> template variable, and also for reusing in
2237 I<cataloging-home.pl>.
2238
2239 =cut
2240
2241 sub get_cataloguing_page_permissions {
2242
2243     my @cataloguing_tools_subperms = qw(
2244         inventory
2245         items_batchdel
2246         items_batchmod
2247         items_batchmod
2248         label_creator
2249         manage_staged_marc
2250         marc_modification_templates
2251         records_batchdel
2252         records_batchmod
2253         stage_marc_import
2254         upload_cover_images
2255     );
2256
2257     return [
2258         { editcatalogue => '*' }, { tools => \@cataloguing_tools_subperms },
2259         C4::Context->preference('StockRotation') ? { stockrotation => 'manage_rotas' } : ()
2260     ];
2261 }
2262
2263 =head2 haspermission
2264
2265   $flagsrequired = '*';                                 # Any permission at all
2266   $flagsrequired = 'a_flag';                            # a_flag must be satisfied (all subpermissions)
2267   $flagsrequired = [ 'a_flag', 'b_flag' ];              # a_flag OR b_flag must be satisfied
2268   $flagsrequired = { 'a_flag => 1, 'b_flag' => 1 };     # a_flag AND b_flag must be satisfied
2269   $flagsrequired = { 'a_flag' => 'sub_a' };             # sub_a of a_flag must be satisfied
2270   $flagsrequired = { 'a_flag' => [ 'sub_a, 'sub_b' ] }; # sub_a OR sub_b of a_flag must be satisfied
2271
2272   $flags = ($userid, $flagsrequired);
2273
2274 C<$userid> the userid of the member
2275 C<$flags> is a query structure similar to that used by SQL::Abstract that
2276 denotes the combination of flags required. It is a required parameter.
2277
2278 The main logic of this method is that things in arrays are OR'ed, and things
2279 in hashes are AND'ed. The `*` character can be used, at any depth, to denote `ANY`
2280
2281 Returns member's flags or 0 if a permission is not met.
2282
2283 =cut
2284
2285 sub _dispatch {
2286     my ($required, $flags) = @_;
2287
2288     my $ref = ref($required);
2289     if ($ref eq '') {
2290         if ($required eq '*') {
2291             return 0 unless ( $flags or ref( $flags ) );
2292         } else {
2293             return 0 unless ( $flags and (!ref( $flags ) || $flags->{$required} ));
2294         }
2295     } elsif ($ref eq 'HASH') {
2296         foreach my $key (keys %{$required}) {
2297             next if $flags == 1;
2298             my $require = $required->{$key};
2299             my $rflags  = $flags->{$key};
2300             return 0 unless _dispatch($require, $rflags);
2301         }
2302     } elsif ($ref eq 'ARRAY') {
2303         my $satisfied = 0;
2304         foreach my $require ( @{$required} ) {
2305             my $rflags =
2306               ( ref($flags) && !ref($require) && ( $require ne '*' ) )
2307               ? $flags->{$require}
2308               : $flags;
2309             $satisfied++ if _dispatch( $require, $rflags );
2310         }
2311         return 0 unless $satisfied;
2312     } else {
2313         croak "Unexpected structure found: $ref";
2314     }
2315
2316     return $flags;
2317 };
2318
2319 sub haspermission {
2320     my ( $userid, $flagsrequired ) = @_;
2321
2322     #Koha::Exceptions::WrongParameter->throw('$flagsrequired should not be undef')
2323     #  unless defined($flagsrequired);
2324
2325     my $sth = C4::Context->dbh->prepare("SELECT flags FROM borrowers WHERE userid=?");
2326     $sth->execute($userid);
2327     my $row = $sth->fetchrow();
2328     my $flags = getuserflags( $row, $userid );
2329
2330     return $flags unless defined($flagsrequired);
2331     return $flags if $flags->{superlibrarian};
2332     return _dispatch($flagsrequired, $flags);
2333
2334     #FIXME - This fcn should return the failed permission so a suitable error msg can be delivered.
2335 }
2336
2337 =head2 in_iprange
2338
2339   $flags = ($iprange);
2340
2341 C<$iprange> A space separated string describing an IP range. Can include single IPs or ranges
2342
2343 Returns 1 if the remote address is in the provided iprange, or 0 otherwise.
2344
2345 =cut
2346
2347 sub in_iprange {
2348     my ($iprange) = @_;
2349     my $result = 1;
2350     my @allowedipranges = $iprange ? split(' ', $iprange) : ();
2351     if (scalar @allowedipranges > 0) {
2352         my @rangelist;
2353         eval { @rangelist = Net::CIDR::range2cidr(@allowedipranges); }; return 0 if $@;
2354         eval { $result = Net::CIDR::cidrlookup($ENV{'REMOTE_ADDR'}, @rangelist) } || Koha::Logger->get->warn('cidrlookup failed for ' . join(' ',@rangelist) );
2355      }
2356      return $result ? 1 : 0;
2357 }
2358
2359 sub getborrowernumber {
2360     my ($userid) = @_;
2361     my $userenv = C4::Context->userenv;
2362     if ( defined($userenv) && ref($userenv) eq 'HASH' && $userenv->{number} ) {
2363         return $userenv->{number};
2364     }
2365     my $dbh = C4::Context->dbh;
2366     for my $field ( 'userid', 'cardnumber' ) {
2367         my $sth =
2368           $dbh->prepare("select borrowernumber from borrowers where $field=?");
2369         $sth->execute($userid);
2370         if ( $sth->rows ) {
2371             my ($bnumber) = $sth->fetchrow;
2372             return $bnumber;
2373         }
2374     }
2375     return 0;
2376 }
2377
2378 END { }    # module clean-up code here (global destructor)
2379 1;
2380 __END__
2381
2382 =head1 SEE ALSO
2383
2384 CGI(3)
2385
2386 C4::Output(3)
2387
2388 Crypt::Eksblowfish::Bcrypt(3)
2389
2390 Digest::MD5(3)
2391
2392 =cut