C4/Auth.pm

   1 package C4::Auth;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use Carp qw( croak );
  23
  24 use Digest::MD5 qw( md5_base64 );
  25 use CGI::Session;
  26 use CGI::Session::ErrorHandler;
  27 use URI;
  28 use URI::QueryParam;
  29
  30 use C4::Context;
  31 use C4::Templates;    # to get the template
  32 use C4::Languages;
  33 use C4::Search::History;
  34 use Koha;
  35 use Koha::Logger;
  36 use Koha::Caches;
  37 use Koha::AuthUtils qw( get_script_name hash_password );
  38 use Koha::Auth::TwoFactorAuth;
  39 use Koha::Checkouts;
  40 use Koha::DateUtils qw( dt_from_string );
  41 use Koha::Library::Groups;
  42 use Koha::Libraries;
  43 use Koha::Cash::Registers;
  44 use Koha::Desks;
  45 use Koha::Patrons;
  46 use Koha::Patron::Consents;
  47 use List::MoreUtils qw( any );
  48 use Encode;
  49 use C4::Auth_with_shibboleth qw( shib_ok get_login_shib login_shib_url logout_shib checkpw_shib );
  50 use Net::CIDR;
  51 use C4::Log qw( logaction );
  52 use Koha::CookieManager;
  53 use Koha::Auth::Permissions;
  54 use Koha::Token;
  55
  56 # use utf8;
  57
  58 use vars qw($ldap $cas $caslogout);
  59 our (@ISA, @EXPORT_OK);
  60
  61 #NOTE: The utility of keeping the safe_exit function is that it can be easily re-defined in unit tests and plugins
  62 sub safe_exit {
  63     # It's fine for us to "exit" because CGI::Compile (used in Plack::App::WrapCGI) redefines "exit" for us automatically.
  64     # Since we only seem to use C4::Auth::safe_exit in a CGI context, we don't actually need PSGI detection at all here.
  65     exit;
  66 }
  67
  68
  69 BEGIN {
  70     C4::Context->set_remote_address;
  71
  72     require Exporter;
  73     @ISA = qw(Exporter);
  74
  75     @EXPORT_OK = qw(
  76         checkauth check_api_auth get_session check_cookie_auth checkpw checkpw_internal checkpw_hash
  77         get_all_subpermissions get_cataloguing_page_permissions get_user_subpermissions in_iprange
  78         get_template_and_user haspermission create_basic_session
  79     );
  80
  81     $ldap      = C4::Context->config('useldapserver') || 0;
  82     $cas       = C4::Context->preference('casAuthentication');
  83     $caslogout = C4::Context->preference('casLogout');
  84
  85     if ($ldap) {
  86         require C4::Auth_with_ldap;
  87         import C4::Auth_with_ldap qw(checkpw_ldap);
  88     }
  89     if ($cas) {
  90         require C4::Auth_with_cas;    # no import
  91         import C4::Auth_with_cas qw(check_api_auth_cas checkpw_cas login_cas logout_cas login_cas_url logout_if_required multipleAuth getMultipleAuth);
  92     }
  93
  94 }
  95
  96 =head1 NAME
  97
  98 C4::Auth - Authenticates Koha users
  99
 100 =head1 SYNOPSIS
 101
 102   use CGI qw ( -utf8 );
 103   use C4::Auth;
 104   use C4::Output;
 105
 106   my $query = CGI->new;
 107
 108   my ($template, $borrowernumber, $cookie)
 109     = get_template_and_user(
 110         {
 111             template_name   => "opac-main.tt",
 112             query           => $query,
 113       type            => "opac",
 114       authnotrequired => 0,
 115       flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 116   }
 117     );
 118
 119   output_html_with_http_headers $query, $cookie, $template->output;
 120
 121 =head1 DESCRIPTION
 122
 123 The main function of this module is to provide
 124 authentification. However the get_template_and_user function has
 125 been provided so that a users login information is passed along
 126 automatically. This gets loaded into the template.
 127
 128 =head1 FUNCTIONS
 129
 130 =head2 get_template_and_user
 131
 132  my ($template, $borrowernumber, $cookie)
 133      = get_template_and_user(
 134        {
 135          template_name   => "opac-main.tt",
 136          query           => $query,
 137          type            => "opac",
 138          authnotrequired => 0,
 139          flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 140        }
 141      );
 142
 143 This call passes the C<query>, C<flagsrequired> and C<authnotrequired>
 144 to C<&checkauth> (in this module) to perform authentification.
 145 See C<&checkauth> for an explanation of these parameters.
 146
 147 The C<template_name> is then used to find the correct template for
 148 the page. The authenticated users details are loaded onto the
 149 template in the logged_in_user variable (which is a Koha::Patron object). Also the
 150 C<sessionID> is passed to the template. This can be used in templates
 151 if cookies are disabled. It needs to be put as and input to every
 152 authenticated page.
 153
 154 More information on the C<gettemplate> sub can be found in the
 155 Output.pm module.
 156
 157 =cut
 158
 159 sub get_template_and_user {
 160
 161     my $in = shift;
 162     my ( $user, $cookie, $sessionID, $flags );
 163     $cookie = [];
 164
 165     my $cookie_mgr = Koha::CookieManager->new;
 166
 167     # Get shibboleth login attribute
 168     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 169     my $shib_login = $shib ? get_login_shib() : undef;
 170
 171     C4::Context->interface( $in->{type} );
 172
 173     $in->{'authnotrequired'} ||= 0;
 174
 175     # the following call includes a bad template check; might croak
 176     my $template = C4::Templates::gettemplate(
 177         $in->{'template_name'},
 178         $in->{'type'},
 179         $in->{'query'},
 180     );
 181
 182     if ( $in->{'template_name'} !~ m/maintenance/ ) {
 183         ( $user, $cookie, $sessionID, $flags ) = checkauth(
 184             $in->{'query'},
 185             $in->{'authnotrequired'},
 186             $in->{'flagsrequired'},
 187             $in->{'type'},
 188             undef,
 189             $in->{template_name},
 190         );
 191     }
 192
 193     # If we enforce GDPR and the user did not consent, redirect
 194     # Exceptions for consent page itself and SCI/SCO system
 195     if( $in->{type} eq 'opac' && $user &&
 196         $in->{'template_name'} !~ /^(opac-page|opac-patron-consent|sc[io]\/)/ &&
 197         C4::Context->preference('PrivacyPolicyConsent') eq 'Enforced' )
 198     {
 199         my $consent = Koha::Patron::Consents->search({
 200             borrowernumber => getborrowernumber($user),
 201             type => 'GDPR_PROCESSING',
 202             given_on => { '!=', undef },
 203         })->next;
 204         if( !$consent ) {
 205             print $in->{query}->redirect(-uri => '/cgi-bin/koha/opac-patron-consent.pl', -cookie => $cookie);
 206             safe_exit;
 207         }
 208     }
 209
 210     if ( $in->{type} eq 'opac' && $user ) {
 211         my $is_sco_user;
 212         if ($sessionID){
 213             my $session = get_session($sessionID);
 214             if ($session){
 215                 $is_sco_user = $session->param('sco_user');
 216             }
 217         }
 218         my $kick_out;
 219
 220         if (
 221 # If the user logged in is the SCO user and they try to go out of the SCO module,
 222 # log the user out removing the CGISESSID cookie
 223             $in->{template_name} !~ m|sco/| && $in->{template_name} !~ m|errors/errorpage.tt|
 224             && (
 225                 $is_sco_user ||
 226                 (
 227                     C4::Context->preference('AutoSelfCheckID')
 228                     && $user eq C4::Context->preference('AutoSelfCheckID')
 229                 )
 230             )
 231           )
 232         {
 233             $kick_out = 1;
 234         }
 235         elsif (
 236 # If the user logged in is the SCI user and they try to go out of the SCI module,
 237 # kick them out unless it is SCO with a valid permission
 238 # or they are a superlibrarian
 239                $in->{template_name} !~ m|sci/|
 240             && haspermission( $user, { self_check => 'self_checkin_module' } )
 241             && !(
 242                 $in->{template_name} =~ m|sco/| && haspermission(
 243                     $user, { self_check => 'self_checkout_module' }
 244                 )
 245             )
 246             && $flags && $flags->{superlibrarian} != 1
 247           )
 248         {
 249             $kick_out = 1;
 250         }
 251
 252         if ($kick_out) {
 253             $template = C4::Templates::gettemplate( 'opac-auth.tt', 'opac',
 254                 $in->{query} );
 255             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 256                 -name     => 'CGISESSID',
 257                 -value    => '',
 258                 -HttpOnly => 1,
 259                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 260                 -sameSite => 'Lax',
 261             ));
 262
 263             #NOTE: This JWT should only be used by the self-check controllers
 264             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 265                 -name     => 'JWT',
 266                 -value    => '',
 267                 -HttpOnly => 1,
 268                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 269                 -sameSite => 'Lax',
 270             ));
 271
 272             my $auth_error = $in->{query}->param('auth_error');
 273
 274             $template->param(
 275                 loginprompt => 1,
 276                 script_name => get_script_name(),
 277                 auth_error  => $auth_error,
 278             );
 279
 280             print $in->{query}->header(
 281                 {
 282                     type              => 'text/html',
 283                     charset           => 'utf-8',
 284                     cookie            => $cookie,
 285                     'X-Frame-Options' => 'SAMEORIGIN'
 286                 }
 287               ),
 288               $template->output;
 289             safe_exit;
 290         }
 291     }
 292
 293     my $borrowernumber;
 294     if ($user) {
 295
 296         # It's possible for $user to be the borrowernumber if they don't have a
 297         # userid defined (and are logging in through some other method, such
 298         # as SSL certs against an email address)
 299         my $patron;
 300         $borrowernumber = getborrowernumber($user) if defined($user);
 301         if ( !defined($borrowernumber) && defined($user) ) {
 302             $patron = Koha::Patrons->find( $user );
 303             if ($patron) {
 304                 $borrowernumber = $user;
 305
 306                 # A bit of a hack, but I don't know there's a nicer way
 307                 # to do it.
 308                 $user = $patron->firstname . ' ' . $patron->surname;
 309             }
 310         } else {
 311             $patron = Koha::Patrons->find( $borrowernumber );
 312             # FIXME What to do if $patron does not exist?
 313         }
 314
 315         # user info
 316         $template->param( loggedinusername   => $user ); # OBSOLETE - Do not reuse this in template, use logged_in_user.userid instead
 317         $template->param( loggedinusernumber => $borrowernumber ); # FIXME Should be replaced with logged_in_user.borrowernumber
 318         $template->param( logged_in_user     => $patron );
 319         $template->param( sessionID          => $sessionID );
 320
 321         if ( $in->{'type'} eq 'opac' ) {
 322             require Koha::Virtualshelves;
 323             my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 324                 {
 325                     borrowernumber => $borrowernumber,
 326                     public         => 0,
 327                 }
 328             );
 329             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 330                 {
 331                     public => 1,
 332                 }
 333             );
 334             $template->param(
 335                 some_private_shelves => $some_private_shelves,
 336                 some_public_shelves  => $some_public_shelves,
 337             );
 338         }
 339
 340         # We are going to use the $flags returned by checkauth
 341         # to create the template's parameters that will indicate
 342         # which menus the user can access.
 343         my $authz = Koha::Auth::Permissions->get_authz_from_flags({ flags => $flags });
 344         foreach my $permission ( keys %{ $authz } ){
 345             $template->param( $permission => $authz->{$permission} );
 346         }
 347
 348         # Logged-in opac search history
 349         # If the requested template is an opac one and opac search history is enabled
 350         if ( $in->{type} eq 'opac' && C4::Context->preference('EnableOpacSearchHistory') ) {
 351             my $dbh   = C4::Context->dbh;
 352             my $query = "SELECT COUNT(*) FROM search_history WHERE userid=?";
 353             my $sth   = $dbh->prepare($query);
 354             $sth->execute($borrowernumber);
 355
 356             # If at least one search has already been performed
 357             if ( $sth->fetchrow_array > 0 ) {
 358
 359                 # We show the link in opac
 360                 $template->param( EnableOpacSearchHistory => 1 );
 361             }
 362             if (C4::Context->preference('LoadSearchHistoryToTheFirstLoggedUser'))
 363             {
 364                 # And if there are searches performed when the user was not logged in,
 365                 # we add them to the logged-in search history
 366                 my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 367                 if (@recentSearches) {
 368                     my $query = q{
 369                         INSERT INTO search_history(userid, sessionid, query_desc, query_cgi, type,  total, time )
 370                         VALUES (?, ?, ?, ?, ?, ?, ?)
 371                     };
 372                     my $sth = $dbh->prepare($query);
 373                     $sth->execute( $borrowernumber,
 374                         $in->{query}->cookie("CGISESSID"),
 375                         $_->{query_desc},
 376                         $_->{query_cgi},
 377                         $_->{type} || 'biblio',
 378                         $_->{total},
 379                         $_->{time},
 380                     ) foreach @recentSearches;
 381
 382                     # clear out the search history from the session now that
 383                     # we've saved it to the database
 384                  }
 385               }
 386               C4::Search::History::set_to_session( { cgi => $in->{'query'}, search_history => [] } );
 387
 388         } elsif ( $in->{type} eq 'intranet' and C4::Context->preference('EnableSearchHistory') ) {
 389             $template->param( EnableSearchHistory => 1 );
 390         }
 391     }
 392     else {    # if this is an anonymous session, setup to display public lists...
 393
 394         # If shibboleth is enabled, and we're in an anonymous session, we should allow
 395         # the user to attempt login via shibboleth.
 396         if ($shib) {
 397             $template->param( shibbolethAuthentication => $shib,
 398                 shibbolethLoginUrl => login_shib_url( $in->{'query'} ),
 399             );
 400
 401             # If shibboleth is enabled and we have a shibboleth login attribute,
 402             # but we are in an anonymous session, then we clearly have an invalid
 403             # shibboleth koha account.
 404             if ($shib_login) {
 405                 $template->param( invalidShibLogin => '1' );
 406             }
 407         }
 408
 409         $template->param( sessionID => $sessionID );
 410
 411         if ( $in->{'type'} eq 'opac' ){
 412             require Koha::Virtualshelves;
 413             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 414                 {
 415                     public => 1,
 416                 }
 417             );
 418             $template->param(
 419                 some_public_shelves  => $some_public_shelves,
 420             );
 421
 422             # Set default branch if one has been passed by the environment.
 423             $template->param( default_branch => $ENV{OPAC_BRANCH_DEFAULT} ) if $ENV{OPAC_BRANCH_DEFAULT};
 424         }
 425     }
 426
 427     # Sysprefs disabled via URL param
 428     # Note that value must be defined in order to override via ENV
 429     foreach my $syspref (
 430         qw(
 431             OPACUserCSS
 432             OPACUserJS
 433             IntranetUserCSS
 434             IntranetUserJS
 435             OpacAdditionalStylesheet
 436             opaclayoutstylesheet
 437             intranetcolorstylesheet
 438             intranetstylesheet
 439         )
 440       )
 441     {
 442         $ENV{"OVERRIDE_SYSPREF_$syspref"} = q{}
 443           if $in->{'query'}->param("DISABLE_SYSPREF_$syspref");
 444     }
 445
 446     # Anonymous opac search history
 447     # If opac search history is enabled and at least one search has already been performed
 448     if ( C4::Context->preference('EnableOpacSearchHistory') ) {
 449         my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 450         if (@recentSearches) {
 451             $template->param( EnableOpacSearchHistory => 1 );
 452         }
 453     }
 454
 455     if ( C4::Context->preference('dateformat') ) {
 456         $template->param( dateformat => C4::Context->preference('dateformat') );
 457     }
 458
 459     $template->param(auth_forwarded_hash => scalar $in->{'query'}->param('auth_forwarded_hash'));
 460
 461     # these template parameters are set the same regardless of $in->{'type'}
 462
 463     my $minPasswordLength = C4::Context->preference('minPasswordLength');
 464     $minPasswordLength = 3 if not $minPasswordLength or $minPasswordLength < 3;
 465     $template->param(
 466         EnhancedMessagingPreferences                                       => C4::Context->preference('EnhancedMessagingPreferences'),
 467         GoogleJackets                                                      => C4::Context->preference("GoogleJackets"),
 468         OpenLibraryCovers                                                  => C4::Context->preference("OpenLibraryCovers"),
 469         KohaAdminEmailAddress                                              => "" . C4::Context->preference("KohaAdminEmailAddress"),
 470         LoginFirstname  => ( C4::Context->userenv ? C4::Context->userenv->{"firstname"} : "Bel" ),
 471         LoginSurname    => C4::Context->userenv ? C4::Context->userenv->{"surname"}      : "Inconnu",
 472         emailaddress    => C4::Context->userenv ? C4::Context->userenv->{"emailaddress"} : undef,
 473         TagsEnabled     => C4::Context->preference("TagsEnabled"),
 474         hide_marc       => C4::Context->preference("hide_marc"),
 475         item_level_itypes  => C4::Context->preference('item-level_itypes'),
 476         patronimages       => C4::Context->preference("patronimages"),
 477         singleBranchMode   => ( Koha::Libraries->search->count == 1 ),
 478         noItemTypeImages   => C4::Context->preference("noItemTypeImages"),
 479         marcflavour        => C4::Context->preference("marcflavour"),
 480         OPACBaseURL        => C4::Context->preference('OPACBaseURL'),
 481         minPasswordLength  => $minPasswordLength,
 482     );
 483     if ( $in->{'type'} eq "intranet" ) {
 484
 485         $template->param(
 486             advancedMARCEditor           => C4::Context->preference("advancedMARCEditor"),
 487             AllowMultipleCovers          => C4::Context->preference('AllowMultipleCovers'),
 488             AmazonCoverImages            => C4::Context->preference("AmazonCoverImages"),
 489             AutoLocation                 => C4::Context->preference("AutoLocation"),
 490             can_see_cataloguing_module   => haspermission( $user, get_cataloguing_page_permissions() ) ? 1 : 0,
 491             canreservefromotherbranches  => C4::Context->preference('canreservefromotherbranches'),
 492             EasyAnalyticalRecords        => C4::Context->preference('EasyAnalyticalRecords'),
 493             EnableBorrowerFiles          => C4::Context->preference('EnableBorrowerFiles'),
 494             FRBRizeEditions              => C4::Context->preference("FRBRizeEditions"),
 495             IndependentBranches          => C4::Context->preference("IndependentBranches"),
 496             intranetcolorstylesheet      => C4::Context->preference("intranetcolorstylesheet"),
 497             IntranetFavicon              => C4::Context->preference("IntranetFavicon"),
 498             IntranetmainUserblock        => C4::Context->preference("IntranetmainUserblock"),
 499             IntranetNav                  => C4::Context->preference("IntranetNav"),
 500             intranetreadinghistory       => C4::Context->preference("intranetreadinghistory"),
 501             IntranetReadingHistoryHolds  => C4::Context->preference("IntranetReadingHistoryHolds"),
 502             intranetstylesheet           => C4::Context->preference("intranetstylesheet"),
 503             IntranetUserCSS              => C4::Context->preference("IntranetUserCSS"),
 504             IntranetUserJS               => C4::Context->preference("IntranetUserJS"),
 505             LibraryName                  => C4::Context->preference("LibraryName"),
 506             LocalCoverImages             => C4::Context->preference('LocalCoverImages'),
 507             OPACLocalCoverImages         => C4::Context->preference('OPACLocalCoverImages'),
 508             PatronAutoComplete           => C4::Context->preference("PatronAutoComplete"),
 509             pending_checkout_notes       => Koha::Checkouts->search( { noteseen => 0 } ),
 510             plugins_enabled              => C4::Context->config("enable_plugins"),
 511             StaffSerialIssueDisplayCount => C4::Context->preference("StaffSerialIssueDisplayCount"),
 512             UseCourseReserves            => C4::Context->preference("UseCourseReserves"),
 513             useDischarge                 => C4::Context->preference('useDischarge'),
 514             virtualshelves               => C4::Context->preference("virtualshelves"),
 515         );
 516     }
 517     else {
 518         warn "template type should be OPAC, here it is=[" . $in->{'type'} . "]" unless ( $in->{'type'} eq 'opac' );
 519
 520         #TODO : replace LibraryName syspref with 'system name', and remove this html processing
 521         my $LibraryNameTitle = C4::Context->preference("LibraryName");
 522         $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
 523         $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
 524
 525         # clean up the busc param in the session
 526         # if the page is not opac-detail and not the "add to list" page
 527         # and not the "edit comments" page
 528         if ( C4::Context->preference("OpacBrowseResults")
 529             && $in->{'template_name'} =~ /opac-(.+)\.(?:tt|tmpl)$/ ) {
 530             my $pagename = $1;
 531             unless ( $pagename =~ /^(?:MARC|ISBD)?detail$/
 532                 or $pagename =~ /^showmarc$/
 533                 or $pagename =~ /^addbybiblionumber$/
 534                 or $pagename =~ /^review$/ )
 535             {
 536                 my $sessionSearch = get_session( $sessionID );
 537                 $sessionSearch->clear( ["busc"] ) if $sessionSearch;
 538             }
 539         }
 540
 541         # variables passed from CGI: opac_css_override and opac_search_limits.
 542         my $opac_search_limit   = $ENV{'OPAC_SEARCH_LIMIT'};
 543         my $opac_limit_override = $ENV{'OPAC_LIMIT_OVERRIDE'};
 544         my $opac_name           = '';
 545         if (
 546             ( $opac_limit_override && $opac_search_limit && $opac_search_limit =~ /branch:([\w-]+)/ ) ||
 547             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /branch:([\w-]+)/ ) ||
 548             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /multibranchlimit:(\w+)/ )
 549           ) {
 550             $opac_name = $1;    # opac_search_limit is a branch, so we use it.
 551         } elsif ( $in->{'query'}->param('multibranchlimit') ) {
 552             $opac_name = $in->{'query'}->param('multibranchlimit');
 553         } elsif ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv && C4::Context->userenv->{'branch'} ) {
 554             $opac_name = C4::Context->userenv->{'branch'};
 555         }
 556
 557         # Decide if the patron can make suggestions in the OPAC
 558         my $can_make_suggestions;
 559         if ( C4::Context->preference('Suggestion') && C4::Context->preference('AnonSuggestions') ) {
 560             $can_make_suggestions = 1;
 561         } elsif ( C4::Context->userenv && C4::Context->userenv->{'number'} ) {
 562             $can_make_suggestions = Koha::Patrons->find(C4::Context->userenv->{'number'})->category->can_make_suggestions;
 563         }
 564
 565         my @search_groups = Koha::Library::Groups->get_search_groups({ interface => 'opac' })->as_list;
 566         $template->param(
 567             AnonSuggestions                       => "" . C4::Context->preference("AnonSuggestions"),
 568             LibrarySearchGroups                   => \@search_groups,
 569             opac_name                             => $opac_name,
 570             LibraryName                           => "" . C4::Context->preference("LibraryName"),
 571             LibraryNameTitle                      => "" . $LibraryNameTitle,
 572             OPACAmazonCoverImages                 => C4::Context->preference("OPACAmazonCoverImages"),
 573             OPACFRBRizeEditions                   => C4::Context->preference("OPACFRBRizeEditions"),
 574             OpacHighlightedWords                  => C4::Context->preference("OpacHighlightedWords"),
 575             OPACShelfBrowser                      => "" . C4::Context->preference("OPACShelfBrowser"),
 576             OPACURLOpenInNewWindow                => "" . C4::Context->preference("OPACURLOpenInNewWindow"),
 577             OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
 578             opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
 579             opac_search_limit                     => $opac_search_limit,
 580             opac_limit_override                   => $opac_limit_override,
 581             OpacBrowser                           => C4::Context->preference("OpacBrowser"),
 582             OpacCloud                             => C4::Context->preference("OpacCloud"),
 583             OpacKohaUrl                           => C4::Context->preference("OpacKohaUrl"),
 584             OpacPasswordChange                    => C4::Context->preference("OpacPasswordChange"),
 585             OPACPatronDetails                     => C4::Context->preference("OPACPatronDetails"),
 586             OPACPrivacy                           => C4::Context->preference("OPACPrivacy"),
 587             OPACFinesTab                          => C4::Context->preference("OPACFinesTab"),
 588             OpacTopissue                          => C4::Context->preference("OpacTopissue"),
 589             'Version'                             => C4::Context->preference('Version'),
 590             hidelostitems                         => C4::Context->preference("hidelostitems"),
 591             mylibraryfirst                        => ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv ) ? C4::Context->userenv->{'branch'} : '',
 592             opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
 593             OpacFavicon                           => C4::Context->preference("OpacFavicon"),
 594             opaclanguagesdisplay                  => "" . C4::Context->preference("opaclanguagesdisplay"),
 595             opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
 596             opacuserlogin                         => "" . C4::Context->preference("opacuserlogin"),
 597             OpenLibrarySearch                     => C4::Context->preference("OpenLibrarySearch"),
 598             ShowReviewer                          => C4::Context->preference("ShowReviewer"),
 599             ShowReviewerPhoto                     => C4::Context->preference("ShowReviewerPhoto"),
 600             suggestion                            => $can_make_suggestions,
 601             virtualshelves                        => "" . C4::Context->preference("virtualshelves"),
 602             OPACSerialIssueDisplayCount           => C4::Context->preference("OPACSerialIssueDisplayCount"),
 603             SyndeticsClientCode                   => C4::Context->preference("SyndeticsClientCode"),
 604             SyndeticsEnabled                      => C4::Context->preference("SyndeticsEnabled"),
 605             SyndeticsCoverImages                  => C4::Context->preference("SyndeticsCoverImages"),
 606             SyndeticsTOC                          => C4::Context->preference("SyndeticsTOC"),
 607             SyndeticsSummary                      => C4::Context->preference("SyndeticsSummary"),
 608             SyndeticsEditions                     => C4::Context->preference("SyndeticsEditions"),
 609             SyndeticsExcerpt                      => C4::Context->preference("SyndeticsExcerpt"),
 610             SyndeticsReviews                      => C4::Context->preference("SyndeticsReviews"),
 611             SyndeticsAuthorNotes                  => C4::Context->preference("SyndeticsAuthorNotes"),
 612             SyndeticsAwards                       => C4::Context->preference("SyndeticsAwards"),
 613             SyndeticsSeries                       => C4::Context->preference("SyndeticsSeries"),
 614             SyndeticsCoverImageSize               => C4::Context->preference("SyndeticsCoverImageSize"),
 615             OPACLocalCoverImages                  => C4::Context->preference("OPACLocalCoverImages"),
 616             PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
 617             PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
 618             useDischarge                 => C4::Context->preference('useDischarge'),
 619         );
 620
 621         $template->param( OpacPublic => '1' ) if ( $user || C4::Context->preference("OpacPublic") );
 622     }
 623
 624     # Check if we were asked using parameters to force a specific language
 625     if ( defined $in->{'query'}->param('language') ) {
 626
 627         # Extract the language, let C4::Languages::getlanguage choose
 628         # what to do
 629         my $language = C4::Languages::getlanguage( $in->{'query'} );
 630         my $languagecookie = C4::Templates::getlanguagecookie( $in->{'query'}, $language );
 631         $cookie = $cookie_mgr->replace_in_list( $cookie, $languagecookie );
 632     }
 633
 634     return ( $template, $borrowernumber, $cookie, $flags );
 635 }
 636
 637 =head2 checkauth
 638
 639   ($userid, $cookie, $sessionID) = &checkauth($query, $noauth, $flagsrequired, $type);
 640
 641 Verifies that the user is authorized to run this script.  If
 642 the user is authorized, a (userid, cookie, session-id, flags)
 643 quadruple is returned.  If the user is not authorized but does
 644 not have the required privilege (see $flagsrequired below), it
 645 displays an error page and exits.  Otherwise, it displays the
 646 login page and exits.
 647
 648 Note that C<&checkauth> will return if and only if the user
 649 is authorized, so it should be called early on, before any
 650 unfinished operations (e.g., if you've opened a file, then
 651 C<&checkauth> won't close it for you).
 652
 653 C<$query> is the CGI object for the script calling C<&checkauth>.
 654
 655 The C<$noauth> argument is optional. If it is set, then no
 656 authorization is required for the script.
 657
 658 C<&checkauth> fetches user and session information from C<$query> and
 659 ensures that the user is authorized to run scripts that require
 660 authorization.
 661
 662 The C<$flagsrequired> argument specifies the required privileges
 663 the user must have if the username and password are correct.
 664 It should be specified as a reference-to-hash; keys in the hash
 665 should be the "flags" for the user, as specified in the Members
 666 intranet module. Any key specified must correspond to a "flag"
 667 in the userflags table. E.g., { circulate => 1 } would specify
 668 that the user must have the "circulate" privilege in order to
 669 proceed. To make sure that access control is correct, the
 670 C<$flagsrequired> parameter must be specified correctly.
 671
 672 Koha also has a concept of sub-permissions, also known as
 673 granular permissions.  This makes the value of each key
 674 in the C<flagsrequired> hash take on an additional
 675 meaning, i.e.,
 676
 677  1
 678
 679 The user must have access to all subfunctions of the module
 680 specified by the hash key.
 681
 682  *
 683
 684 The user must have access to at least one subfunction of the module
 685 specified by the hash key.
 686
 687  specific permission, e.g., 'export_catalog'
 688
 689 The user must have access to the specific subfunction list, which
 690 must correspond to a row in the permissions table.
 691
 692 The C<$type> argument specifies whether the template should be
 693 retrieved from the opac or intranet directory tree.  "opac" is
 694 assumed if it is not specified; however, if C<$type> is specified,
 695 "intranet" is assumed if it is not "opac".
 696
 697 If C<$query> does not have a valid session ID associated with it
 698 (i.e., the user has not logged in) or if the session has expired,
 699 C<&checkauth> presents the user with a login page (from the point of
 700 view of the original script, C<&checkauth> does not return). Once the
 701 user has authenticated, C<&checkauth> restarts the original script
 702 (this time, C<&checkauth> returns).
 703
 704 The login page is provided using a HTML::Template, which is set in the
 705 systempreferences table or at the top of this file. The variable C<$type>
 706 selects which template to use, either the opac or the intranet
 707 authentification template.
 708
 709 C<&checkauth> returns a user ID, a cookie, and a session ID. The
 710 cookie should be sent back to the browser; it verifies that the user
 711 has authenticated.
 712
 713 =cut
 714
 715 sub _version_check {
 716     my $type  = shift;
 717     my $query = shift;
 718     my $version;
 719
 720     # If version syspref is unavailable, it means Koha is being installed,
 721     # and so we must redirect to OPAC maintenance page or to the WebInstaller
 722     # also, if OpacMaintenance is ON, OPAC should redirect to maintenance
 723     if ( C4::Context->preference('OpacMaintenance') && $type eq 'opac' ) {
 724         warn "OPAC Install required, redirecting to maintenance";
 725         print $query->redirect("/cgi-bin/koha/maintenance.pl");
 726         safe_exit;
 727     }
 728     unless ( $version = C4::Context->preference('Version') ) {    # assignment, not comparison
 729         if ( $type ne 'opac' ) {
 730             warn "Install required, redirecting to Installer";
 731             print $query->redirect("/cgi-bin/koha/installer/install.pl");
 732         } else {
 733             warn "OPAC Install required, redirecting to maintenance";
 734             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 735         }
 736         safe_exit;
 737     }
 738
 739     # check that database and koha version are the same
 740     # there is no DB version, it's a fresh install,
 741     # go to web installer
 742     # there is a DB version, compare it to the code version
 743     my $kohaversion = Koha::version();
 744
 745     # remove the 3 last . to have a Perl number
 746     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 747     Koha::Logger->get->debug("kohaversion : $kohaversion");
 748     if ( $version < $kohaversion ) {
 749         my $warning = "Database update needed, redirecting to %s. Database is $version and Koha is $kohaversion";
 750         if ( $type ne 'opac' ) {
 751             warn sprintf( $warning, 'Installer' );
 752             print $query->redirect("/cgi-bin/koha/installer/install.pl?step=1&op=updatestructure");
 753         } else {
 754             warn sprintf( "OPAC: " . $warning, 'maintenance' );
 755             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 756         }
 757         safe_exit;
 758     }
 759 }
 760
 761 sub _timeout_syspref {
 762     my $default_timeout = 600;
 763     my $timeout = C4::Context->preference('timeout') || $default_timeout;
 764
 765     # value in days, convert in seconds
 766     if ( $timeout =~ /^(\d+)[dD]$/ ) {
 767         $timeout = $1 * 86400;
 768     }
 769     # value in hours, convert in seconds
 770     elsif ( $timeout =~ /^(\d+)[hH]$/ ) {
 771         $timeout = $1 * 3600;
 772     }
 773     elsif ( $timeout !~ m/^\d+$/ ) {
 774         warn "The value of the system preference 'timeout' is not correct, defaulting to $default_timeout";
 775         $timeout = $default_timeout;
 776     }
 777
 778     return $timeout;
 779 }
 780
 781 sub checkauth {
 782     my $query = shift;
 783
 784     # Get shibboleth login attribute
 785     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 786     my $shib_login = $shib ? get_login_shib() : undef;
 787
 788     # $authnotrequired will be set for scripts which will run without authentication
 789     my $authnotrequired = shift;
 790     my $flagsrequired   = shift;
 791     my $type            = shift;
 792     my $emailaddress    = shift;
 793     my $template_name   = shift;
 794     my $params          = shift || {}; # do_not_print
 795     $type = 'opac' unless $type;
 796
 797     if ( $type eq 'opac' && !C4::Context->preference("OpacPublic") ) {
 798         my @allowed_scripts_for_private_opac = qw(
 799             opac-memberentry.tt
 800             opac-registration-email-sent.tt
 801             opac-registration-confirmation.tt
 802             opac-memberentry-update-submitted.tt
 803             opac-password-recovery.tt
 804             opac-reset-password.tt
 805             ilsdi.tt
 806         );
 807         $authnotrequired = 0 unless grep { $_ eq $template_name }
 808             @allowed_scripts_for_private_opac;
 809     }
 810
 811     my $timeout = _timeout_syspref();
 812
 813     my $cookie_mgr = Koha::CookieManager->new;
 814
 815     _version_check( $type, $query );
 816
 817     # state variables
 818     my $auth_state = 'failed';
 819     my %info;
 820     my ( $userid, $cookie, $sessionID, $flags );
 821     $cookie = [];
 822     my $logout = $query->param('logout.x');
 823
 824     my $anon_search_history;
 825     my $cas_ticket = '';
 826     # This parameter is the name of the CAS server we want to authenticate against,
 827     # when using authentication against multiple CAS servers, as configured in Auth_cas_servers.yaml
 828     my $casparam = $query->param('cas');
 829     my $q_userid = $query->param('userid') // '';
 830
 831     my $session;
 832     my $invalid_otp_token;
 833     my $require_2FA =
 834       ( $type ne "opac" # Only available for the staff interface
 835           && C4::Context->preference('TwoFactorAuthentication') ne "disabled" ) # If "enabled" or "enforced"
 836       ? 1 : 0;
 837
 838     # Basic authentication is incompatible with the use of Shibboleth,
 839     # as Shibboleth may return REMOTE_USER as a Shibboleth attribute,
 840     # and it may not be the attribute we want to use to match the koha login.
 841     #
 842     # Also, do not consider an empty REMOTE_USER.
 843     #
 844     # Finally, after those tests, we can assume (although if it would be better with
 845     # a syspref) that if we get a REMOTE_USER, that's from basic authentication,
 846     # and we can affect it to $userid.
 847     if ( !$shib and defined( $ENV{'REMOTE_USER'} ) and $ENV{'REMOTE_USER'} ne '' and $userid = $ENV{'REMOTE_USER'} ) {
 848
 849         # Using Basic Authentication, no cookies required
 850         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 851             -name     => 'CGISESSID',
 852             -value    => '',
 853             -HttpOnly => 1,
 854             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 855             -sameSite => 'Lax',
 856         ));
 857     }
 858     elsif ( $emailaddress) {
 859         # the Google OpenID Connect passes an email address
 860     }
 861     elsif ( $sessionID = $query->cookie("CGISESSID") ) {    # assignment, not comparison
 862         my ( $return, $more_info );
 863         # NOTE: $flags in the following call is still undefined !
 864         ( $return, $session, $more_info ) = check_cookie_auth( $sessionID, $flags,
 865             { remote_addr => $ENV{REMOTE_ADDR}, skip_version_check => 1 }
 866         );
 867
 868         if ( $return eq 'ok' || $return eq 'additional-auth-needed' ) {
 869             $userid = $session->param('id');
 870         }
 871
 872         $auth_state =
 873             $return eq 'ok'                     ? 'completed'
 874           : $return eq 'additional-auth-needed' ? 'additional-auth-needed'
 875           :                                       'failed';
 876
 877         # We are at the second screen if the waiting-for-2FA is set in session
 878         # and otp_token param has been passed
 879         if (   $require_2FA
 880             && $auth_state eq 'additional-auth-needed'
 881             && ( my $otp_token = $query->param('otp_token') ) )
 882         {
 883             my $patron    = Koha::Patrons->find( { userid => $userid } );
 884             my $auth      = Koha::Auth::TwoFactorAuth->new( { patron => $patron } );
 885             my $verified = $auth->verify($otp_token);
 886             $auth->clear;
 887             if ( $verified ) {
 888                 # The token is correct, the user is fully logged in!
 889                 $auth_state = 'completed';
 890                 $session->param( 'waiting-for-2FA', 0 );
 891                 $session->param( 'waiting-for-2FA-setup', 0 );
 892
 893                # This is an ugly trick to pass the test
 894                # $query->param('koha_login_context') && ( $q_userid ne $userid )
 895                # few lines later
 896                 $q_userid = $userid;
 897             }
 898             else {
 899                 $invalid_otp_token = 1;
 900             }
 901         }
 902
 903         if ( $auth_state eq 'completed' ) {
 904             Koha::Logger->get->debug(sprintf "AUTH_SESSION: (%s)\t%s %s - %s", map { $session->param($_) || q{} } qw(cardnumber firstname surname branch));
 905
 906             if ( ( $query->param('koha_login_context') && ( $q_userid ne $userid ) )
 907                 || ( $cas && $query->param('ticket') && !C4::Context->userenv->{'id'} )
 908                 || ( $shib && $shib_login && !$logout && !C4::Context->userenv->{'id'} )
 909             ) {
 910
 911                 #if a user enters an id ne to the id in the current session, we need to log them in...
 912                 #first we need to clear the anonymous session...
 913                 $anon_search_history = $session->param('search_history');
 914                 $session->delete();
 915                 $session->flush;
 916                 $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 917                 C4::Context::_unset_userenv($sessionID);
 918                 $sessionID = undef;
 919                 undef $userid; # IMPORTANT: this assures us a new session in code below
 920                 $auth_state = 'failed';
 921             } elsif (!$logout) {
 922
 923                 $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 924                     -name     => 'CGISESSID',
 925                     -value    => $session->id,
 926                     -HttpOnly => 1,
 927                     -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 928                     -sameSite => 'Lax',
 929                 ));
 930
 931                 $flags = haspermission( $userid, $flagsrequired );
 932                 unless ( $flags ) {
 933                     $auth_state = 'failed';
 934                     $info{'nopermission'} = 1;
 935                 }
 936             }
 937         } elsif ( !$logout ) {
 938             if ( $return eq 'expired' ) {
 939                 $info{timed_out} = 1;
 940             } elsif ( $return eq 'restricted' ) {
 941                 $info{oldip}        = $more_info->{old_ip};
 942                 $info{newip}        = $more_info->{new_ip};
 943                 $info{different_ip} = 1;
 944             } elsif ( $return eq 'password_expired' ) {
 945                 $info{password_has_expired} = 1;
 946             }
 947         }
 948     }
 949
 950     if ( $auth_state eq 'failed' || $logout ) {
 951         $sessionID = undef;
 952         $userid    = undef;
 953     }
 954
 955     if ($logout) {
 956
 957         # voluntary logout the user
 958         # check wether the user was using their shibboleth session or a local one
 959         my $shibSuccess = C4::Context->userenv ? C4::Context->userenv->{'shibboleth'} : undef;
 960         if ( $session ) {
 961             $session->delete();
 962             $session->flush;
 963         }
 964         C4::Context::_unset_userenv($sessionID);
 965         $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 966
 967         if ($cas and $caslogout) {
 968             logout_cas($query, $type);
 969         }
 970
 971         # If we are in a shibboleth session (shibboleth is enabled, a shibboleth match attribute is set and matches koha matchpoint)
 972         if ( $shib and $shib_login and $shibSuccess) {
 973             logout_shib($query);
 974         }
 975
 976         $session   = undef;
 977         $auth_state = 'logout';
 978     }
 979
 980     unless ( $userid ) {
 981         #we initiate a session prior to checking for a username to allow for anonymous sessions...
 982         if( !$session or !$sessionID ) { # if we cleared sessionID, we need a new session
 983             $session = get_session() or die "Auth ERROR: Cannot get_session()";
 984         }
 985
 986         # Save anonymous search history in new session so it can be retrieved
 987         # by get_template_and_user to store it in user's search history after
 988         # a successful login.
 989         if ($anon_search_history) {
 990             $session->param( 'search_history', $anon_search_history );
 991         }
 992
 993         $sessionID = $session->id;
 994         C4::Context->_new_userenv($sessionID);
 995         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 996             -name     => 'CGISESSID',
 997             -value    => $sessionID,
 998             -HttpOnly => 1,
 999             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1000             -sameSite => 'Lax',
1001         ));
1002         my $pki_field = C4::Context->preference('AllowPKIAuth');
1003         if ( !defined($pki_field) ) {
1004             print STDERR "ERROR: Missing system preference AllowPKIAuth.\n";
1005             $pki_field = 'None';
1006         }
1007         if ( ( $cas && $query->param('ticket') )
1008             || $q_userid
1009             || ( $shib && $shib_login )
1010             || $pki_field ne 'None'
1011             || $emailaddress )
1012         {
1013             my $password    = $query->param('password');
1014             my $shibSuccess = 0;
1015             my ( $return, $cardnumber );
1016
1017             # If shib is enabled and we have a shib login, does the login match a valid koha user
1018             if ( $shib && $shib_login ) {
1019                 my $retuserid;
1020
1021                 # Do not pass password here, else shib will not be checked in checkpw.
1022                 ( $return, $cardnumber, $retuserid ) = checkpw( $q_userid, undef, $query );
1023                 $userid      = $retuserid;
1024                 $shibSuccess = $return;
1025                 $info{'invalidShibLogin'} = 1 unless ($return);
1026             }
1027
1028             # If shib login and match were successful, skip further login methods
1029             unless ($shibSuccess) {
1030                 if ( $cas && $query->param('ticket') ) {
1031                     my $retuserid;
1032                     my $patron;
1033                     ( $return, $cardnumber, $retuserid, $patron, $cas_ticket ) =
1034                       checkpw( $userid, $password, $query, $type );
1035                     $userid = $retuserid;
1036                     $info{'invalidCasLogin'} = 1 unless ($return);
1037                 }
1038
1039                 elsif ( $emailaddress ) {
1040                     my $value = $emailaddress;
1041
1042                     # If we're looking up the email, there's a chance that the person
1043                     # doesn't have a userid. So if there is none, we pass along the
1044                     # borrower number, and the bits of code that need to know the user
1045                     # ID will have to be smart enough to handle that.
1046                     my $patrons = Koha::Patrons->search({ email => $value });
1047                     if ($patrons->count) {
1048
1049                         # First the userid, then the borrowernum
1050                         my $patron = $patrons->next;
1051                         $value = $patron->userid || $patron->borrowernumber;
1052                     } else {
1053                         undef $value;
1054                     }
1055                     $return = $value ? 1 : 0;
1056                     $userid = $value;
1057                 }
1058
1059                 elsif (
1060                     ( $pki_field eq 'Common Name' && $ENV{'SSL_CLIENT_S_DN_CN'} )
1061                     || ( $pki_field eq 'emailAddress'
1062                         && $ENV{'SSL_CLIENT_S_DN_Email'} )
1063                   )
1064                 {
1065                     my $value;
1066                     if ( $pki_field eq 'Common Name' ) {
1067                         $value = $ENV{'SSL_CLIENT_S_DN_CN'};
1068                     }
1069                     elsif ( $pki_field eq 'emailAddress' ) {
1070                         $value = $ENV{'SSL_CLIENT_S_DN_Email'};
1071
1072                         # If we're looking up the email, there's a chance that the person
1073                         # doesn't have a userid. So if there is none, we pass along the
1074                         # borrower number, and the bits of code that need to know the user
1075                         # ID will have to be smart enough to handle that.
1076                         my $patrons = Koha::Patrons->search({ email => $value });
1077                         if ($patrons->count) {
1078
1079                             # First the userid, then the borrowernum
1080                             my $patron = $patrons->next;
1081                             $value = $patron->userid || $patron->borrowernumber;
1082                         } else {
1083                             undef $value;
1084                         }
1085                     }
1086
1087                     $return = $value ? 1 : 0;
1088                     $userid = $value;
1089
1090                 }
1091                 else {
1092                     my $retuserid;
1093                     my $request_method = $query->request_method // q{};
1094
1095                     if (
1096                         $request_method eq 'POST'
1097                         || ( C4::Context->preference('AutoSelfCheckID')
1098                             && $q_userid eq C4::Context->preference('AutoSelfCheckID') )
1099                       )
1100                     {
1101                         my $patron;
1102
1103                         ( $return, $cardnumber, $retuserid, $patron, $cas_ticket ) =
1104                           checkpw( $q_userid, $password, $query, $type );
1105                         $userid = $retuserid if ($retuserid);
1106                         $info{'invalid_username_or_password'} = 1 unless ($return);
1107                     }
1108                 }
1109             }
1110
1111             # If shib configured and shibOnly enabled, we should ignore anything other than a shibboleth type login.
1112             if (
1113                    $shib
1114                 && !$shibSuccess
1115                 && (
1116                     (
1117                         ( $type eq 'opac' )
1118                         && C4::Context->preference('OPACShibOnly')
1119                     )
1120                     || ( ( $type ne 'opac' )
1121                         && C4::Context->preference('staffShibOnly') )
1122                 )
1123               )
1124             {
1125                 $return = 0;
1126             }
1127
1128             # $return: 1 = valid user
1129             if( $return && $return > 0 ) {
1130
1131                 if ( $flags = haspermission( $userid, $flagsrequired ) ) {
1132                     $auth_state = "logged_in";
1133                 }
1134                 else {
1135                     $auth_state = 'failed';
1136                     # FIXME We could add $return = 0; or even delete the session?
1137                     # Currently return == 1 and we will fill session info later on,
1138                     # although we do present an authorization failure. (Yes, the
1139                     # authentication was actually correct.)
1140                     $info{'nopermission'} = 1;
1141                     C4::Context::_unset_userenv($sessionID);
1142                 }
1143                 my ( $borrowernumber, $firstname, $surname, $userflags,
1144                     $branchcode, $branchname, $emailaddress, $desk_id,
1145                     $desk_name, $register_id, $register_name );
1146
1147                 if ( $return == 1 ) {
1148                     my $select = "
1149                     SELECT borrowernumber, firstname, surname, flags, borrowers.branchcode,
1150                     branches.branchname    as branchname, email
1151                     FROM borrowers
1152                     LEFT JOIN branches on borrowers.branchcode=branches.branchcode
1153                     ";
1154                     my $dbh = C4::Context->dbh;
1155                     my $sth = $dbh->prepare("$select where userid=?");
1156                     $sth->execute($userid);
1157                     unless ( $sth->rows ) {
1158                         $sth = $dbh->prepare("$select where cardnumber=?");
1159                         $sth->execute($cardnumber);
1160
1161                         unless ( $sth->rows ) {
1162                             $sth->execute($userid);
1163                         }
1164                     }
1165                     if ( $sth->rows ) {
1166                         ( $borrowernumber, $firstname, $surname, $userflags,
1167                             $branchcode, $branchname, $emailaddress ) = $sth->fetchrow;
1168                     }
1169
1170                     # launch a sequence to check if we have a ip for the branch, i
1171                     # if we have one we replace the branchcode of the userenv by the branch bound in the ip.
1172
1173                     my $ip = $ENV{'REMOTE_ADDR'};
1174
1175                     # if they specify at login, use that
1176                     my $patron = Koha::Patrons->find({userid => $userid});
1177                     if ( $query->param('branch')  && ( haspermission($userid, {  'loggedinlibrary'=> 1 }) || $patron->is_superlibrarian ) ) {
1178                         $branchcode = $query->param('branch');
1179                         my $library = Koha::Libraries->find($branchcode);
1180                         $branchname = $library? $library->branchname: '';
1181                     }
1182                     if ( $query->param('desk_id') ) {
1183                         $desk_id = $query->param('desk_id');
1184                         my $desk = Koha::Desks->find($desk_id);
1185                         $desk_name = $desk ? $desk->desk_name : '';
1186                     }
1187                     if ( C4::Context->preference('UseCashRegisters') ) {
1188                         my $register =
1189                           $query->param('register_id')
1190                           ? Koha::Cash::Registers->find($query->param('register_id'))
1191                           : Koha::Cash::Registers->search(
1192                             { branch => $branchcode, branch_default => 1 },
1193                             { rows   => 1 } )->single;
1194                         $register_id   = $register->id   if ($register);
1195                         $register_name = $register->name if ($register);
1196                     }
1197                     my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1198                     if ( $type ne 'opac' and C4::Context->preference('AutoLocation') ) {
1199
1200                         # we have to check they are coming from the right ip range
1201                         my $domain = $branches->{$branchcode}->{'branchip'};
1202                         $domain =~ s|\.\*||g;
1203                         if ( $ip !~ /^$domain/ ) {
1204                             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1205                                 -name     => 'CGISESSID',
1206                                 -value    => '',
1207                                 -HttpOnly => 1,
1208                                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1209                                 -sameSite => 'Lax',
1210                             ));
1211                             $info{'wrongip'} = 1;
1212                         }
1213                     }
1214
1215                     foreach my $br ( keys %$branches ) {
1216
1217                         #     now we work with the treatment of ip
1218                         my $domain = $branches->{$br}->{'branchip'};
1219                         if ( $domain && $ip =~ /^$domain/ ) {
1220                             $branchcode = $branches->{$br}->{'branchcode'};
1221
1222                             # new op dev : add the branchname to the cookie
1223                             $branchname    = $branches->{$br}->{'branchname'};
1224                         }
1225                     }
1226
1227                     my $is_sco_user = 0;
1228                     if ( $query->param('sco_user_login') && ( $query->param('sco_user_login') eq '1' ) ){
1229                         $is_sco_user = 1;
1230                     }
1231
1232                     $session->param( 'number',       $borrowernumber );
1233                     $session->param( 'id',           $userid );
1234                     $session->param( 'cardnumber',   $cardnumber );
1235                     $session->param( 'firstname',    $firstname );
1236                     $session->param( 'surname',      $surname );
1237                     $session->param( 'branch',       $branchcode );
1238                     $session->param( 'branchname',   $branchname );
1239                     $session->param( 'desk_id',      $desk_id);
1240                     $session->param( 'desk_name',     $desk_name);
1241                     $session->param( 'flags',        $userflags );
1242                     $session->param( 'emailaddress', $emailaddress );
1243                     $session->param( 'ip',           $session->remote_addr() );
1244                     $session->param( 'lasttime',     time() );
1245                     $session->param( 'interface',    $type);
1246                     $session->param( 'shibboleth',   $shibSuccess );
1247                     $session->param( 'register_id',  $register_id );
1248                     $session->param( 'register_name',  $register_name );
1249                     $session->param( 'sco_user', $is_sco_user );
1250                 }
1251                 $session->param('cas_ticket', $cas_ticket) if $cas_ticket;
1252                 C4::Context->set_userenv(
1253                     $session->param('number'),       $session->param('id'),
1254                     $session->param('cardnumber'),   $session->param('firstname'),
1255                     $session->param('surname'),      $session->param('branch'),
1256                     $session->param('branchname'),   $session->param('flags'),
1257                     $session->param('emailaddress'), $session->param('shibboleth'),
1258                     $session->param('desk_id'),      $session->param('desk_name'),
1259                     $session->param('register_id'),  $session->param('register_name')
1260                 );
1261
1262             }
1263             # $return: 0 = invalid user
1264             # reset to anonymous session
1265             else {
1266                 if ($userid) {
1267                     $info{'invalid_username_or_password'} = 1;
1268                     C4::Context::_unset_userenv($sessionID);
1269                 }
1270                 $session->param( 'lasttime', time() );
1271                 $session->param( 'ip',       $session->remote_addr() );
1272                 $session->param( 'sessiontype', 'anon' );
1273                 $session->param( 'interface', $type);
1274             }
1275         }    # END if ( $q_userid
1276         elsif ( $type eq "opac" ) {
1277
1278             # anonymous sessions are created only for the OPAC
1279
1280             # setting a couple of other session vars...
1281             $session->param( 'ip',          $session->remote_addr() );
1282             $session->param( 'lasttime',    time() );
1283             $session->param( 'sessiontype', 'anon' );
1284             $session->param( 'interface', $type);
1285         }
1286         $session->flush;
1287     }    # END unless ($userid)
1288
1289
1290     if ( $auth_state eq 'logged_in' ) {
1291         $auth_state = 'completed';
1292
1293         # Auth is completed unless an additional auth is needed
1294         if ( $require_2FA ) {
1295             my $patron = Koha::Patrons->find({userid => $userid});
1296             if ( C4::Context->preference('TwoFactorAuthentication') eq "enforced" && $patron->auth_method eq 'password' ) {
1297                 $auth_state = 'setup-additional-auth-needed';
1298                 $session->param('waiting-for-2FA-setup', 1);
1299                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1300             } elsif ( $patron->auth_method eq 'two-factor' ) {
1301                 # Ask for the OTP token
1302                 $auth_state = 'additional-auth-needed';
1303                 $session->param('waiting-for-2FA', 1);
1304                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1305             }
1306         }
1307     }
1308
1309     # finished authentification, now respond
1310     if ( $auth_state eq 'completed' || $authnotrequired ) {
1311         # successful login
1312         unless (@$cookie) {
1313             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1314                 -name     => 'CGISESSID',
1315                 -value    => '',
1316                 -HttpOnly => 1,
1317                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1318                 -sameSite => 'Lax',
1319             ));
1320         }
1321
1322         my $patron = $userid ? Koha::Patrons->find({ userid => $userid }) : undef;
1323         $patron->update_lastseen('login') if $patron;
1324
1325         # In case, that this request was a login attempt, we want to prevent that users can repost the opac login
1326         # request. We therefore redirect the user to the requested page again without the login parameters.
1327         # See Post/Redirect/Get (PRG) design pattern: https://en.wikipedia.org/wiki/Post/Redirect/Get
1328         if ( $type eq "opac" && $query->param('koha_login_context') && $query->param('koha_login_context') ne 'sco' && $query->param('password') && $query->param('userid') ) {
1329             my $uri = URI->new($query->url(-relative=>1, -query_string=>1));
1330             $uri->query_param_delete('userid');
1331             $uri->query_param_delete('password');
1332             $uri->query_param_delete('koha_login_context');
1333             unless ( $params->{do_not_print} ) {
1334                 print $query->redirect(-uri => $uri->as_string, -cookie => $cookie, -status=>'303 See other');
1335                 safe_exit;
1336             }
1337         }
1338
1339         return ( $userid, $cookie, $sessionID, $flags );
1340     }
1341
1342     #
1343     #
1344     # AUTH rejected, show the login/password template, after checking the DB.
1345     #
1346     #
1347
1348     my $patron = Koha::Patrons->find({ userid => $q_userid }); # Not necessary logged in!
1349
1350     # get the inputs from the incoming query
1351     my @inputs = ();
1352     my @inputs_to_clean = qw( userid password ticket logout.x otp_token );
1353     foreach my $name ( param $query) {
1354         next if grep { $name eq $_ } @inputs_to_clean;
1355         my @value = $query->multi_param($name);
1356         push @inputs, { name => $name, value => $_ } for @value;
1357     }
1358
1359     my $LibraryNameTitle = C4::Context->preference("LibraryName");
1360     $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
1361     $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
1362
1363     my $auth_template_name = ( $type eq 'opac' ) ? 'opac-auth.tt' : 'auth.tt';
1364     my $auth_error = $query->param('auth_error');
1365     my $template = C4::Templates::gettemplate( $auth_template_name, $type, $query );
1366     $template->param(
1367         login                                 => 1,
1368         INPUTS                                => \@inputs,
1369         script_name                           => get_script_name(),
1370         casAuthentication                     => C4::Context->preference("casAuthentication"),
1371         shibbolethAuthentication              => $shib,
1372         suggestion                            => C4::Context->preference("suggestion"),
1373         virtualshelves                        => C4::Context->preference("virtualshelves"),
1374         LibraryName                           => "" . C4::Context->preference("LibraryName"),
1375         LibraryNameTitle                      => "" . $LibraryNameTitle,
1376         opacuserlogin                         => C4::Context->preference("opacuserlogin"),
1377         OpacFavicon                           => C4::Context->preference("OpacFavicon"),
1378         opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
1379         opaclanguagesdisplay                  => C4::Context->preference("opaclanguagesdisplay"),
1380         opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
1381         OpacCloud                             => C4::Context->preference("OpacCloud"),
1382         OpacTopissue                          => C4::Context->preference("OpacTopissue"),
1383         OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
1384         OpacBrowser                           => C4::Context->preference("OpacBrowser"),
1385         TagsEnabled                           => C4::Context->preference("TagsEnabled"),
1386         intranetcolorstylesheet               => C4::Context->preference("intranetcolorstylesheet"),
1387         intranetstylesheet                    => C4::Context->preference("intranetstylesheet"),
1388         IntranetNav                           => C4::Context->preference("IntranetNav"),
1389         IntranetFavicon                       => C4::Context->preference("IntranetFavicon"),
1390         IntranetUserCSS                       => C4::Context->preference("IntranetUserCSS"),
1391         IntranetUserJS                        => C4::Context->preference("IntranetUserJS"),
1392         IndependentBranches                   => C4::Context->preference("IndependentBranches"),
1393         AutoLocation                          => C4::Context->preference("AutoLocation"),
1394         wrongip                               => $info{'wrongip'},
1395         PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
1396         PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
1397         opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
1398         too_many_login_attempts               => ( $patron and $patron->account_locked ),
1399         password_has_expired                  => ( $patron and $patron->password_expired ),
1400         auth_error                            => $auth_error,
1401     );
1402
1403     $template->param( SCO_login => 1 ) if ( $query->param('sco_user_login') );
1404     $template->param( SCI_login => 1 ) if ( $query->param('sci_user_login') );
1405     $template->param( OpacPublic => C4::Context->preference("OpacPublic") );
1406     $template->param( loginprompt => 1 ) unless $info{'nopermission'};
1407     if ( $auth_state eq 'additional-auth-needed' ) {
1408         my $patron = Koha::Patrons->find( { userid => $userid } );
1409         $template->param(
1410             TwoFA_prompt => 1,
1411             invalid_otp_token => $invalid_otp_token,
1412             notice_email_address => $patron->notice_email_address, # We could also pass logged_in_user if necessary
1413         );
1414     }
1415
1416     if ( $auth_state eq 'setup-additional-auth-needed' ) {
1417         $template->param(
1418             TwoFA_setup => 1,
1419         );
1420     }
1421
1422     if ( $type eq 'opac' ) {
1423         require Koha::Virtualshelves;
1424         my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1425             {
1426                 public => 1,
1427             }
1428         );
1429         $template->param(
1430             some_public_shelves  => $some_public_shelves,
1431         );
1432     }
1433
1434     if ($cas) {
1435
1436         # Is authentication against multiple CAS servers enabled?
1437         require C4::Auth_with_cas;
1438         if ( multipleAuth() && !$casparam ) {
1439             my $casservers = getMultipleAuth();
1440             my @tmplservers;
1441             foreach my $key ( keys %$casservers ) {
1442                 push @tmplservers, { name => $key, value => login_cas_url( $query, $key, $type ) . "?cas=$key" };
1443             }
1444             $template->param(
1445                 casServersLoop => \@tmplservers
1446             );
1447         } else {
1448             $template->param(
1449                 casServerUrl => login_cas_url($query, undef, $type),
1450             );
1451         }
1452
1453         $template->param(
1454             invalidCasLogin => $info{'invalidCasLogin'}
1455         );
1456     }
1457
1458     if ($shib) {
1459         #If shibOnly is enabled just go ahead and redirect directly
1460         if ( (($type eq 'opac') && C4::Context->preference('OPACShibOnly')) || (($type ne 'opac') && C4::Context->preference('staffShibOnly')) ) {
1461             my $redirect_url = login_shib_url( $query );
1462             print $query->redirect( -uri => "$redirect_url", -status => 303 );
1463             safe_exit;
1464         }
1465
1466         $template->param(
1467             shibbolethAuthentication => $shib,
1468             shibbolethLoginUrl       => login_shib_url($query),
1469         );
1470     }
1471
1472     if (C4::Context->preference('GoogleOpenIDConnect')) {
1473         if ($query->param("OpenIDConnectFailed")) {
1474             my $reason = $query->param('OpenIDConnectFailed');
1475             $template->param(invalidGoogleOpenIDConnectLogin => $reason);
1476         }
1477     }
1478
1479     $template->param(
1480         LibraryName => C4::Context->preference("LibraryName"),
1481     );
1482     $template->param(%info);
1483
1484     if ( $params->{do_not_print} ) {
1485         # This must be used for testing purpose only!
1486         return ( undef, undef, undef, undef, $template );
1487     }
1488
1489     print $query->header(
1490         {   type              => 'text/html',
1491             charset           => 'utf-8',
1492             cookie            => $cookie,
1493             'X-Frame-Options' => 'SAMEORIGIN',
1494             -sameSite => 'Lax'
1495         }
1496       ),
1497       $template->output;
1498     safe_exit;
1499 }
1500
1501 =head2 check_api_auth
1502
1503   ($status, $cookie, $sessionId) = check_api_auth($query, $userflags);
1504
1505 Given a CGI query containing the parameters 'userid' and 'password' and/or a session
1506 cookie, determine if the user has the privileges specified by C<$userflags>.
1507
1508 C<check_api_auth> is is meant for authenticating users of web services, and
1509 consequently will always return and will not attempt to redirect the user
1510 agent.
1511
1512 If a valid session cookie is already present, check_api_auth will return a status
1513 of "ok", the cookie, and the Koha session ID.
1514
1515 If no session cookie is present, check_api_auth will check the 'userid' and 'password
1516 parameters and create a session cookie and Koha session if the supplied credentials
1517 are OK.
1518
1519 Possible return values in C<$status> are:
1520
1521 =over
1522
1523 =item "ok" -- user authenticated; C<$cookie> and C<$sessionid> have valid values.
1524
1525 =item "failed" -- credentials are not correct; C<$cookie> and C<$sessionid> are undef
1526
1527 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1528
1529 =item "expired -- session cookie has expired; API user should resubmit userid and password
1530
1531 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1532
1533 =item "additional-auth-needed -- User is in an authentication process that is not finished
1534
1535 =back
1536
1537 =cut
1538
1539 sub check_api_auth {
1540
1541     my $query         = shift;
1542     my $flagsrequired = shift;
1543     my $timeout = _timeout_syspref();
1544
1545     unless ( C4::Context->preference('Version') ) {
1546
1547         # database has not been installed yet
1548         return ( "maintenance", undef, undef );
1549     }
1550     my $kohaversion = Koha::version();
1551     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1552     if ( C4::Context->preference('Version') < $kohaversion ) {
1553
1554         # database in need of version update; assume that
1555         # no API should be called while databsae is in
1556         # this condition.
1557         return ( "maintenance", undef, undef );
1558     }
1559
1560     my ( $sessionID, $session );
1561     unless ( $query->param('userid') ) {
1562         $sessionID = $query->cookie("CGISESSID");
1563     }
1564     if ( $sessionID && not( $cas && $query->param('PT') ) ) {
1565
1566         my $return;
1567         ( $return, $session, undef ) = check_cookie_auth(
1568             $sessionID, $flagsrequired, { remote_addr => $ENV{REMOTE_ADDR} } );
1569
1570         return ( $return, undef, undef ) # Cookie auth failed
1571             if $return ne "ok";
1572
1573         my $cookie = $query->cookie(
1574             -name     => 'CGISESSID',
1575             -value    => $session->id,
1576             -HttpOnly => 1,
1577             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1578             -sameSite => 'Lax'
1579         );
1580         return ( $return, $cookie, $session ); # return == 'ok' here
1581
1582     } else {
1583
1584         # new login
1585         my $userid   = $query->param('userid');
1586         my $password = $query->param('password');
1587         my ( $return, $cardnumber, $cas_ticket );
1588
1589         # Proxy CAS auth
1590         if ( $cas && $query->param('PT') ) {
1591             my $retuserid;
1592
1593             # In case of a CAS authentication, we use the ticket instead of the password
1594             my $PT = $query->param('PT');
1595             ( $return, $cardnumber, $userid, $cas_ticket ) = check_api_auth_cas( $PT, $query );    # EXTERNAL AUTH
1596         } else {
1597
1598             # User / password auth
1599             unless ( $userid and $password ) {
1600
1601                 # caller did something wrong, fail the authenticateion
1602                 return ( "failed", undef, undef );
1603             }
1604             my $newuserid;
1605             my $patron;
1606             ( $return, $cardnumber, $newuserid, $patron, $cas_ticket ) = checkpw( $userid, $password, $query );
1607         }
1608
1609         if ( $return and haspermission( $userid, $flagsrequired ) ) {
1610             my $session = get_session("");
1611             return ( "failed", undef, undef ) unless $session;
1612
1613             my $sessionID = $session->id;
1614             C4::Context->_new_userenv($sessionID);
1615             my $cookie = $query->cookie(
1616                 -name     => 'CGISESSID',
1617                 -value    => $sessionID,
1618                 -HttpOnly => 1,
1619                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1620                 -sameSite => 'Lax'
1621             );
1622             if ( $return == 1 ) {
1623                 my (
1624                     $borrowernumber, $firstname,  $surname,
1625                     $userflags,      $branchcode, $branchname,
1626                     $emailaddress
1627                 );
1628                 my $dbh = C4::Context->dbh;
1629                 my $sth =
1630                   $dbh->prepare(
1631 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where userid=?"
1632                   );
1633                 $sth->execute($userid);
1634                 (
1635                     $borrowernumber, $firstname,  $surname,
1636                     $userflags,      $branchcode, $branchname,
1637                     $emailaddress
1638                 ) = $sth->fetchrow if ( $sth->rows );
1639
1640                 unless ( $sth->rows ) {
1641                     my $sth = $dbh->prepare(
1642 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1643                     );
1644                     $sth->execute($cardnumber);
1645                     (
1646                         $borrowernumber, $firstname,  $surname,
1647                         $userflags,      $branchcode, $branchname,
1648                         $emailaddress
1649                     ) = $sth->fetchrow if ( $sth->rows );
1650
1651                     unless ( $sth->rows ) {
1652                         $sth->execute($userid);
1653                         (
1654                             $borrowernumber, $firstname,  $surname,       $userflags,
1655                             $branchcode,     $branchname, $emailaddress
1656                         ) = $sth->fetchrow if ( $sth->rows );
1657                     }
1658                 }
1659
1660                 my $ip = $ENV{'REMOTE_ADDR'};
1661
1662                 # if they specify at login, use that
1663                 if ( $query->param('branch') ) {
1664                     $branchcode = $query->param('branch');
1665                     my $library = Koha::Libraries->find($branchcode);
1666                     $branchname = $library? $library->branchname: '';
1667                 }
1668                 my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1669                 foreach my $br ( keys %$branches ) {
1670
1671                     #     now we work with the treatment of ip
1672                     my $domain = $branches->{$br}->{'branchip'};
1673                     if ( $domain && $ip =~ /^$domain/ ) {
1674                         $branchcode = $branches->{$br}->{'branchcode'};
1675
1676                         # new op dev : add the branchname to the cookie
1677                         $branchname    = $branches->{$br}->{'branchname'};
1678                     }
1679                 }
1680                 $session->param( 'number',       $borrowernumber );
1681                 $session->param( 'id',           $userid );
1682                 $session->param( 'cardnumber',   $cardnumber );
1683                 $session->param( 'firstname',    $firstname );
1684                 $session->param( 'surname',      $surname );
1685                 $session->param( 'branch',       $branchcode );
1686                 $session->param( 'branchname',   $branchname );
1687                 $session->param( 'flags',        $userflags );
1688                 $session->param( 'emailaddress', $emailaddress );
1689                 $session->param( 'ip',           $session->remote_addr() );
1690                 $session->param( 'lasttime',     time() );
1691                 $session->param( 'interface',    'api'  );
1692             }
1693             $session->param( 'cas_ticket', $cas_ticket);
1694             C4::Context->set_userenv(
1695                 $session->param('number'),       $session->param('id'),
1696                 $session->param('cardnumber'),   $session->param('firstname'),
1697                 $session->param('surname'),      $session->param('branch'),
1698                 $session->param('branchname'),   $session->param('flags'),
1699                 $session->param('emailaddress'), $session->param('shibboleth'),
1700                 $session->param('desk_id'),      $session->param('desk_name'),
1701                 $session->param('register_id'),  $session->param('register_name')
1702             );
1703             return ( "ok", $cookie, $sessionID );
1704         } else {
1705             return ( "failed", undef, undef );
1706         }
1707     }
1708 }
1709
1710 =head2 check_cookie_auth
1711
1712   ($status, $sessionId) = check_cookie_auth($cookie, $userflags);
1713
1714 Given a CGISESSID cookie set during a previous login to Koha, determine
1715 if the user has the privileges specified by C<$userflags>. C<$userflags>
1716 is passed unaltered into C<haspermission> and as such accepts all options
1717 avaiable to that routine with the one caveat that C<check_api_auth> will
1718 also allow 'undef' to be passed and in such a case the permissions check
1719 will be skipped altogether.
1720
1721 C<check_cookie_auth> is meant for authenticating special services
1722 such as tools/upload-file.pl that are invoked by other pages that
1723 have been authenticated in the usual way.
1724
1725 Possible return values in C<$status> are:
1726
1727 =over
1728
1729 =item "ok" -- user authenticated; C<$sessionID> have valid values.
1730
1731 =item "anon" -- user not authenticated but valid for anonymous session.
1732
1733 =item "failed" -- credentials are not correct; C<$sessionid> are undef
1734
1735 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1736
1737 =item "expired -- session cookie has expired; API user should resubmit userid and password
1738
1739 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1740
1741 =back
1742
1743 =cut
1744
1745 sub check_cookie_auth {
1746     my $sessionID     = shift;
1747     my $flagsrequired = shift;
1748     my $params        = shift;
1749
1750     my $remote_addr = $params->{remote_addr} || $ENV{REMOTE_ADDR};
1751
1752     my $skip_version_check = $params->{skip_version_check}; # Only for checkauth
1753
1754     unless ( $skip_version_check ) {
1755         unless ( C4::Context->preference('Version') ) {
1756
1757             # database has not been installed yet
1758             return ( "maintenance", undef );
1759         }
1760         my $kohaversion = Koha::version();
1761         $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1762         if ( C4::Context->preference('Version') < $kohaversion ) {
1763
1764             # database in need of version update; assume that
1765             # no API should be called while databsae is in
1766             # this condition.
1767             return ( "maintenance", undef );
1768         }
1769     }
1770
1771     # see if we have a valid session cookie already
1772     # however, if a userid parameter is present (i.e., from
1773     # a form submission, assume that any current cookie
1774     # is to be ignored
1775     unless ( $sessionID ) {
1776         return ( "failed", undef );
1777     }
1778     C4::Context::_unset_userenv($sessionID); # remove old userenv first
1779     my $session   = get_session($sessionID);
1780     if ($session) {
1781         my $userid   = $session->param('id');
1782         my $ip       = $session->param('ip');
1783         my $lasttime = $session->param('lasttime');
1784         my $timeout = _timeout_syspref();
1785
1786         if ( !$lasttime || ( $lasttime < time() - $timeout ) ) {
1787             # time out
1788             $session->delete();
1789             $session->flush;
1790             return ("expired", undef);
1791
1792         } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $remote_addr ) {
1793             # IP address changed
1794             $session->delete();
1795             $session->flush;
1796             return ( "restricted", undef, { old_ip => $ip, new_ip => $remote_addr});
1797
1798         } elsif ( $userid ) {
1799             $session->param( 'lasttime', time() );
1800             my $patron = Koha::Patrons->find({ userid => $userid });
1801
1802             # If the user modify their own userid
1803             # Better than 500 but we could do better
1804             unless ( $patron ) {
1805                 $session->delete();
1806                 $session->flush;
1807                 return ("expired", undef);
1808             }
1809
1810             $patron = Koha::Patrons->find({ cardnumber => $userid })
1811               unless $patron;
1812             return ("password_expired", undef ) if $patron->password_expired;
1813             my $flags = defined($flagsrequired) ? haspermission( $userid, $flagsrequired ) : 1;
1814             if ($flags) {
1815                 C4::Context->_new_userenv($sessionID);
1816                 if ( !C4::Context->interface ) {
1817                     # No need to override the interface, most often set by get_template_and_user
1818                     C4::Context->interface( $session->param('interface') );
1819                 }
1820                 C4::Context->set_userenv(
1821                     $session->param('number'),       $session->param('id') // '',
1822                     $session->param('cardnumber'),   $session->param('firstname'),
1823                     $session->param('surname'),      $session->param('branch'),
1824                     $session->param('branchname'),   $session->param('flags'),
1825                     $session->param('emailaddress'), $session->param('shibboleth'),
1826                     $session->param('desk_id'),      $session->param('desk_name'),
1827                     $session->param('register_id'),  $session->param('register_name')
1828                 );
1829                 if ( C4::Context->preference('TwoFactorAuthentication') ne 'disabled' ) {
1830                     return ( "additional-auth-needed", $session )
1831                         if $session->param('waiting-for-2FA');
1832
1833                     return ( "setup-additional-auth-needed", $session )
1834                         if $session->param('waiting-for-2FA-setup');
1835                 }
1836
1837                 return ( "ok", $session );
1838             } else {
1839                 $session->delete();
1840                 $session->flush;
1841                 return ( "failed", undef );
1842             }
1843
1844         } else {
1845             C4::Context->_new_userenv($sessionID);
1846             C4::Context->interface($session->param('interface'));
1847             C4::Context->set_userenv( undef, q{} );
1848             return ( "anon", $session );
1849         }
1850     } else {
1851         return ( "expired", undef );
1852     }
1853 }
1854
1855 =head2 get_session
1856
1857   use CGI::Session;
1858   my $session = get_session($sessionID);
1859
1860 Given a session ID, retrieve the CGI::Session object used to store
1861 the session's state.  The session object can be used to store
1862 data that needs to be accessed by different scripts during a
1863 user's session.
1864
1865 If the C<$sessionID> parameter is an empty string, a new session
1866 will be created.
1867
1868 =cut
1869
1870 sub _get_session_params {
1871     my $storage_method = C4::Context->preference('SessionStorage');
1872     if ( $storage_method eq 'mysql' ) {
1873         my $dbh = C4::Context->dbh;
1874         return { dsn => "serializer:yamlxs;driver:MySQL;id:md5", dsn_args => { Handle => $dbh } };
1875     }
1876     elsif ( $storage_method eq 'Pg' ) {
1877         my $dbh = C4::Context->dbh;
1878         return { dsn => "serializer:yamlxs;driver:PostgreSQL;id:md5", dsn_args => { Handle => $dbh } };
1879     }
1880     elsif ( $storage_method eq 'memcached' && Koha::Caches->get_instance->memcached_cache ) {
1881         my $memcached = Koha::Caches->get_instance()->memcached_cache;
1882         return { dsn => "serializer:yamlxs;driver:memcached;id:md5", dsn_args => { Memcached => $memcached } };
1883     }
1884     else {
1885         # catch all defaults to tmp should work on all systems
1886         my $dir = C4::Context::temporary_directory;
1887         my $instance = C4::Context->config( 'database' ); #actually for packages not exactly the instance name, but generally safer to leave it as it is
1888         return { dsn => "serializer:yamlxs;driver:File;id:md5", dsn_args => { Directory => "$dir/cgisess_$instance" } };
1889     }
1890 }
1891
1892 sub get_session {
1893     my $sessionID      = shift;
1894     my $params = _get_session_params();
1895     my $session;
1896     if( $sessionID ) { # find existing
1897         CGI::Session::ErrorHandler->set_error( q{} ); # clear error, cpan issue #111463
1898         $session = CGI::Session->load( $params->{dsn}, $sessionID, $params->{dsn_args} );
1899     } else {
1900         $session = CGI::Session->new( $params->{dsn}, $sessionID, $params->{dsn_args} );
1901         # no need to flush here
1902     }
1903     return $session;
1904 }
1905
1906 =head2 create_basic_session
1907
1908 my $session = create_basic_session({ patron => $patron, interface => $interface });
1909
1910 Creates a session and adds all basic parameters for a session to work
1911
1912 =cut
1913
1914 sub create_basic_session {
1915     my $params    = shift;
1916     my $patron    = $params->{patron};
1917     my $interface = $params->{interface};
1918
1919     $interface = 'intranet' if $interface eq 'staff';
1920
1921     my $session = get_session("");
1922
1923     $session->param( 'number',       $patron->borrowernumber );
1924     $session->param( 'id',           $patron->userid );
1925     $session->param( 'cardnumber',   $patron->cardnumber );
1926     $session->param( 'firstname',    $patron->firstname );
1927     $session->param( 'surname',      $patron->surname );
1928     $session->param( 'branch',       $patron->branchcode );
1929     $session->param( 'branchname',   $patron->library->branchname );
1930     $session->param( 'flags',        $patron->flags );
1931     $session->param( 'emailaddress', $patron->email );
1932     $session->param( 'ip',           $session->remote_addr() );
1933     $session->param( 'lasttime',     time() );
1934     $session->param( 'interface',    $interface);
1935
1936     return $session;
1937 }
1938
1939
1940 # FIXME no_set_userenv may be replaced with force_branchcode_for_userenv
1941 # (or something similar)
1942 # Currently it's only passed from C4::SIP::ILS::Patron::check_password, but
1943 # not having a userenv defined could cause a crash.
1944 sub checkpw {
1945     my ( $userid, $password, $query, $type, $no_set_userenv ) = @_;
1946     $type = 'opac' unless $type;
1947
1948     # Get shibboleth login attribute
1949     my $shib       = C4::Context->config('useshibboleth') && shib_ok();
1950     my $shib_login = $shib ? get_login_shib() : undef;
1951
1952     my @return;
1953     my $patron;
1954     if ( defined $userid ) {
1955         $patron = Koha::Patrons->find( { userid     => $userid } );
1956         $patron = Koha::Patrons->find( { cardnumber => $userid } ) unless $patron;
1957     }
1958     my $check_internal_as_fallback = 0;
1959     my $passwd_ok                  = 0;
1960
1961     # Note: checkpw_* routines returns:
1962     # 1 if auth is ok
1963     # 0 if auth is nok
1964     # -1 if user bind failed (LDAP only)
1965
1966     if ( $patron and ( $patron->account_locked ) ) {
1967
1968         # Nothing to check, account is locked
1969     } elsif ( $ldap && defined($password) ) {
1970         my ( $retval, $retcard, $retuserid );
1971         ( $retval, $retcard, $retuserid, $patron ) = checkpw_ldap(@_);    # EXTERNAL AUTH
1972         if ( $retval == 1 ) {
1973             @return    = ( $retval, $retcard, $retuserid, $patron );
1974             $passwd_ok = 1;
1975         }
1976         $check_internal_as_fallback = 1 if $retval == 0;
1977
1978     } elsif ( $cas && $query && $query->param('ticket') ) {
1979
1980         # In case of a CAS authentication, we use the ticket instead of the password
1981         my $ticket = $query->param('ticket');
1982         $query->delete('ticket');                                         # remove ticket to come back to original URL
1983         my ( $retval, $retcard, $retuserid, $cas_ticket, $patron ) =
1984             checkpw_cas( $ticket, $query, $type );                        # EXTERNAL AUTH
1985         if ($retval) {
1986             @return = ( $retval, $retcard, $retuserid, $patron, $cas_ticket );
1987         } else {
1988             @return = (0);
1989         }
1990         $passwd_ok = $retval;
1991     }
1992
1993     # If we are in a shibboleth session (shibboleth is enabled, and a shibboleth match attribute is present)
1994     # Check for password to asertain whether we want to be testing against shibboleth or another method this
1995     # time around.
1996     elsif ( $shib && $shib_login && !$password ) {
1997
1998         # In case of a Shibboleth authentication, we expect a shibboleth user attribute
1999         # (defined under shibboleth mapping in koha-conf.xml) to contain the login of the
2000         # shibboleth-authenticated user
2001
2002         # Then, we check if it matches a valid koha user
2003         if ($shib_login) {
2004             my ( $retval, $retcard, $retuserid, $patron ) =
2005                 C4::Auth_with_shibboleth::checkpw_shib($shib_login);    # EXTERNAL AUTH
2006             if ($retval) {
2007                 @return = ( $retval, $retcard, $retuserid, $patron );
2008             }
2009             $passwd_ok = $retval;
2010         }
2011     } else {
2012         $check_internal_as_fallback = 1;
2013     }
2014
2015     # INTERNAL AUTH
2016     if ($check_internal_as_fallback) {
2017         @return = checkpw_internal( $userid, $password, $no_set_userenv );
2018         push( @return, $patron );
2019         $passwd_ok = 1 if $return[0] > 0;    # 1 or 2
2020     }
2021
2022     if ($patron) {
2023         if ($passwd_ok) {
2024             $patron->update( { login_attempts => 0 } );
2025             if ( $patron->password_expired ) {
2026                 @return = ( -2, $patron );
2027             }
2028         } elsif ( !$patron->account_locked ) {
2029             $patron->update( { login_attempts => $patron->login_attempts + 1 } );
2030         }
2031     }
2032
2033     # Optionally log success or failure
2034     if ( $patron && $passwd_ok && C4::Context->preference('AuthSuccessLog') ) {
2035         logaction( 'AUTH', 'SUCCESS', $patron->id, "Valid password for $userid", $type );
2036     } elsif ( !$passwd_ok && C4::Context->preference('AuthFailureLog') ) {
2037         logaction( 'AUTH', 'FAILURE', $patron ? $patron->id : 0, "Wrong password for $userid", $type );
2038     }
2039
2040     return @return;
2041 }
2042
2043 sub checkpw_internal {
2044     my ( $userid, $password, $no_set_userenv ) = @_;
2045
2046     $password = Encode::encode( 'UTF-8', $password )
2047       if Encode::is_utf8($password);
2048
2049     my $dbh = C4::Context->dbh;
2050     my $sth =
2051       $dbh->prepare(
2052         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where userid=?"
2053       );
2054     $sth->execute($userid);
2055     if ( $sth->rows ) {
2056         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2057             $surname, $branchcode, $branchname, $flags )
2058           = $sth->fetchrow;
2059
2060         if ( checkpw_hash( $password, $stored_hash ) ) {
2061
2062             C4::Context->set_userenv( "$borrowernumber", $userid, $cardnumber,
2063                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2064             return 1, $cardnumber, $userid;
2065         }
2066     }
2067     $sth =
2068       $dbh->prepare(
2069         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
2070       );
2071     $sth->execute($userid);
2072     if ( $sth->rows ) {
2073         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2074             $surname, $branchcode, $branchname, $flags )
2075           = $sth->fetchrow;
2076
2077         if ( checkpw_hash( $password, $stored_hash ) ) {
2078
2079             C4::Context->set_userenv( $borrowernumber, $userid, $cardnumber,
2080                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2081             return 1, $cardnumber, $userid;
2082         }
2083     }
2084     return 0;
2085 }
2086
2087 sub checkpw_hash {
2088     my ( $password, $stored_hash ) = @_;
2089
2090     return if $stored_hash eq '!';
2091
2092     # check what encryption algorithm was implemented: Bcrypt - if the hash starts with '$2' it is Bcrypt else md5
2093     my $hash;
2094     if ( substr( $stored_hash, 0, 2 ) eq '$2' ) {
2095         $hash = hash_password( $password, $stored_hash );
2096     } else {
2097         $hash = md5_base64($password);
2098     }
2099     return $hash eq $stored_hash;
2100 }
2101
2102 =head2 getuserflags
2103
2104     my $authflags = getuserflags($flags, $userid, [$dbh]);
2105
2106 Translates integer flags into permissions strings hash.
2107
2108 C<$flags> is the integer userflags value ( borrowers.userflags )
2109 C<$userid> is the members.userid, used for building subpermissions
2110 C<$authflags> is a hashref of permissions
2111
2112 =cut
2113
2114 sub getuserflags {
2115     my $flags  = shift;
2116     my $userid = shift;
2117     my $dbh    = @_ ? shift : C4::Context->dbh;
2118     my $userflags;
2119     {
2120         # I don't want to do this, but if someone logs in as the database
2121         # user, it would be preferable not to spam them to death with
2122         # numeric warnings. So, we make $flags numeric.
2123         no warnings 'numeric';
2124         $flags += 0;
2125     }
2126     my $sth = $dbh->prepare("SELECT bit, flag, defaulton FROM userflags");
2127     $sth->execute;
2128
2129     while ( my ( $bit, $flag, $defaulton ) = $sth->fetchrow ) {
2130         if ( ( $flags & ( 2**$bit ) ) || $defaulton ) {
2131             $userflags->{$flag} = 1;
2132         }
2133         else {
2134             $userflags->{$flag} = 0;
2135         }
2136     }
2137
2138     # get subpermissions and merge with top-level permissions
2139     my $user_subperms = get_user_subpermissions($userid);
2140     foreach my $module ( keys %$user_subperms ) {
2141         next if $userflags->{$module} == 1;    # user already has permission for everything in this module
2142         $userflags->{$module} = $user_subperms->{$module};
2143     }
2144
2145     return $userflags;
2146 }
2147
2148 =head2 get_user_subpermissions
2149
2150   $user_perm_hashref = get_user_subpermissions($userid);
2151
2152 Given the userid (note, not the borrowernumber) of a staff user,
2153 return a hashref of hashrefs of the specific subpermissions
2154 accorded to the user.  An example return is
2155
2156  {
2157     tools => {
2158         export_catalog => 1,
2159         import_patrons => 1,
2160     }
2161  }
2162
2163 The top-level hash-key is a module or function code from
2164 userflags.flag, while the second-level key is a code
2165 from permissions.
2166
2167 The results of this function do not give a complete picture
2168 of the functions that a staff user can access; it is also
2169 necessary to check borrowers.flags.
2170
2171 =cut
2172
2173 sub get_user_subpermissions {
2174     my $userid = shift;
2175
2176     my $dbh = C4::Context->dbh;
2177     my $sth = $dbh->prepare( "SELECT flag, user_permissions.code
2178                              FROM user_permissions
2179                              JOIN permissions USING (module_bit, code)
2180                              JOIN userflags ON (module_bit = bit)
2181                              JOIN borrowers USING (borrowernumber)
2182                              WHERE userid = ?" );
2183     $sth->execute($userid);
2184
2185     my $user_perms = {};
2186     while ( my $perm = $sth->fetchrow_hashref ) {
2187         $user_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2188     }
2189     return $user_perms;
2190 }
2191
2192 =head2 get_all_subpermissions
2193
2194   my $perm_hashref = get_all_subpermissions();
2195
2196 Returns a hashref of hashrefs defining all specific
2197 permissions currently defined.  The return value
2198 has the same structure as that of C<get_user_subpermissions>,
2199 except that the innermost hash value is the description
2200 of the subpermission.
2201
2202 =cut
2203
2204 sub get_all_subpermissions {
2205     my $dbh = C4::Context->dbh;
2206     my $sth = $dbh->prepare( "SELECT flag, code
2207                              FROM permissions
2208                              JOIN userflags ON (module_bit = bit)" );
2209     $sth->execute();
2210
2211     my $all_perms = {};
2212     while ( my $perm = $sth->fetchrow_hashref ) {
2213         $all_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2214     }
2215     return $all_perms;
2216 }
2217
2218 =head2 get_cataloguing_page_permissions
2219
2220     my $required_permissions = get_cataloguing_page_permissions();
2221
2222 Returns the required permissions to access the main cataloguing page. Useful for building
2223 the global I<can_see_cataloguing_module> template variable, and also for reusing in
2224 I<cataloging-home.pl>.
2225
2226 =cut
2227
2228 sub get_cataloguing_page_permissions {
2229
2230     my @cataloguing_tools_subperms = qw(
2231         inventory
2232         items_batchdel
2233         items_batchmod
2234         items_batchmod
2235         label_creator
2236         manage_staged_marc
2237         marc_modification_templates
2238         records_batchdel
2239         records_batchmod
2240         stage_marc_import
2241         upload_cover_images
2242     );
2243
2244     return [
2245         { editcatalogue => '*' }, { tools => \@cataloguing_tools_subperms },
2246         C4::Context->preference('StockRotation') ? { stockrotation => 'manage_rotas' } : ()
2247     ];
2248 }
2249
2250 =head2 haspermission
2251
2252   $flagsrequired = '*';                                 # Any permission at all
2253   $flagsrequired = 'a_flag';                            # a_flag must be satisfied (all subpermissions)
2254   $flagsrequired = [ 'a_flag', 'b_flag' ];              # a_flag OR b_flag must be satisfied
2255   $flagsrequired = { 'a_flag => 1, 'b_flag' => 1 };     # a_flag AND b_flag must be satisfied
2256   $flagsrequired = { 'a_flag' => 'sub_a' };             # sub_a of a_flag must be satisfied
2257   $flagsrequired = { 'a_flag' => [ 'sub_a, 'sub_b' ] }; # sub_a OR sub_b of a_flag must be satisfied
2258
2259   $flags = ($userid, $flagsrequired);
2260
2261 C<$userid> the userid of the member
2262 C<$flags> is a query structure similar to that used by SQL::Abstract that
2263 denotes the combination of flags required. It is a required parameter.
2264
2265 The main logic of this method is that things in arrays are OR'ed, and things
2266 in hashes are AND'ed. The `*` character can be used, at any depth, to denote `ANY`
2267
2268 Returns member's flags or 0 if a permission is not met.
2269
2270 =cut
2271
2272 sub _dispatch {
2273     my ($required, $flags) = @_;
2274
2275     my $ref = ref($required);
2276     if ($ref eq '') {
2277         if ($required eq '*') {
2278             return 0 unless ( $flags or ref( $flags ) );
2279         } else {
2280             return 0 unless ( $flags and (!ref( $flags ) || $flags->{$required} ));
2281         }
2282     } elsif ($ref eq 'HASH') {
2283         foreach my $key (keys %{$required}) {
2284             next if $flags == 1;
2285             my $require = $required->{$key};
2286             my $rflags  = $flags->{$key};
2287             return 0 unless _dispatch($require, $rflags);
2288         }
2289     } elsif ($ref eq 'ARRAY') {
2290         my $satisfied = 0;
2291         foreach my $require ( @{$required} ) {
2292             my $rflags =
2293               ( ref($flags) && !ref($require) && ( $require ne '*' ) )
2294               ? $flags->{$require}
2295               : $flags;
2296             $satisfied++ if _dispatch( $require, $rflags );
2297         }
2298         return 0 unless $satisfied;
2299     } else {
2300         croak "Unexpected structure found: $ref";
2301     }
2302
2303     return $flags;
2304 };
2305
2306 sub haspermission {
2307     my ( $userid, $flagsrequired ) = @_;
2308
2309     #Koha::Exceptions::WrongParameter->throw('$flagsrequired should not be undef')
2310     #  unless defined($flagsrequired);
2311
2312     my $sth = C4::Context->dbh->prepare("SELECT flags FROM borrowers WHERE userid=?");
2313     $sth->execute($userid);
2314     my $row = $sth->fetchrow();
2315     my $flags = getuserflags( $row, $userid );
2316
2317     return $flags unless defined($flagsrequired);
2318     return $flags if $flags->{superlibrarian};
2319     return _dispatch($flagsrequired, $flags);
2320
2321     #FIXME - This fcn should return the failed permission so a suitable error msg can be delivered.
2322 }
2323
2324 =head2 in_iprange
2325
2326   $flags = ($iprange);
2327
2328 C<$iprange> A space separated string describing an IP range. Can include single IPs or ranges
2329
2330 Returns 1 if the remote address is in the provided iprange, or 0 otherwise.
2331
2332 =cut
2333
2334 sub in_iprange {
2335     my ($iprange) = @_;
2336     my $result = 1;
2337     my @allowedipranges = $iprange ? split(' ', $iprange) : ();
2338     if (scalar @allowedipranges > 0) {
2339         my @rangelist;
2340         eval { @rangelist = Net::CIDR::range2cidr(@allowedipranges); }; return 0 if $@;
2341         eval { $result = Net::CIDR::cidrlookup($ENV{'REMOTE_ADDR'}, @rangelist) } || Koha::Logger->get->warn('cidrlookup failed for ' . join(' ',@rangelist) );
2342      }
2343      return $result ? 1 : 0;
2344 }
2345
2346 sub getborrowernumber {
2347     my ($userid) = @_;
2348     my $userenv = C4::Context->userenv;
2349     if ( defined($userenv) && ref($userenv) eq 'HASH' && $userenv->{number} ) {
2350         return $userenv->{number};
2351     }
2352     my $dbh = C4::Context->dbh;
2353     for my $field ( 'userid', 'cardnumber' ) {
2354         my $sth =
2355           $dbh->prepare("select borrowernumber from borrowers where $field=?");
2356         $sth->execute($userid);
2357         if ( $sth->rows ) {
2358             my ($bnumber) = $sth->fetchrow;
2359             return $bnumber;
2360         }
2361     }
2362     return 0;
2363 }
2364
2365 END { }    # module clean-up code here (global destructor)
2366 1;
2367 __END__
2368
2369 =head1 SEE ALSO
2370
2371 CGI(3)
2372
2373 C4::Output(3)
2374
2375 Crypt::Eksblowfish::Bcrypt(3)
2376
2377 Digest::MD5(3)
2378
2379 =cut