C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetOpenIssue
  99       GetUpcomingDueIssues
 100       CheckIfIssuedToPatron
 101       IsItemIssued
 102       GetAgeRestriction
 103       GetTopIssues
 104
 105       AddReturn
 106       MarkIssueReturned
 107
 108       transferbook
 109       TooMany
 110       GetTransfers
 111       GetTransfersFromTo
 112       updateWrongTransfer
 113       CalcDateDue
 114       CheckValidBarcode
 115       IsBranchTransferAllowed
 116       CreateBranchTransferLimit
 117       DeleteBranchTransferLimits
 118       TransferSlip
 119
 120       GetOfflineOperations
 121       GetOfflineOperation
 122       AddOfflineOperation
 123       DeleteOfflineOperation
 124       ProcessOfflineOperation
 125       ProcessOfflinePayment
 126       ProcessOfflineIssue
 127     );
 128     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 129 }
 130
 131 =head1 NAME
 132
 133 C4::Circulation - Koha circulation module
 134
 135 =head1 SYNOPSIS
 136
 137 use C4::Circulation;
 138
 139 =head1 DESCRIPTION
 140
 141 The functions in this module deal with circulation, issues, and
 142 returns, as well as general information about the library.
 143 Also deals with inventory.
 144
 145 =head1 FUNCTIONS
 146
 147 =head2 barcodedecode
 148
 149   $str = &barcodedecode($barcode, [$filter]);
 150
 151 Generic filter function for barcode string.
 152 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 153 Will do some manipulation of the barcode for systems that deliver a barcode
 154 to circulation.pl that differs from the barcode stored for the item.
 155 For proper functioning of this filter, calling the function on the
 156 correct barcode string (items.barcode) should return an unaltered barcode.
 157 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 158
 159 The optional $filter argument is to allow for testing or explicit
 160 behavior that ignores the System Pref.  Valid values are the same as the
 161 System Pref options.
 162
 163 =cut
 164
 165 # FIXME -- the &decode fcn below should be wrapped into this one.
 166 # FIXME -- these plugins should be moved out of Circulation.pm
 167 #
 168 sub barcodedecode {
 169     my ($barcode, $filter) = @_;
 170
 171     return unless defined $barcode;
 172
 173     my $branch = C4::Context::mybranch();
 174     $barcode =~ s/^\s+|\s+$//g;
 175     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 176     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 177     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 178         if ($filter eq 'whitespace') {
 179                 $barcode =~ s/\s//g;
 180         } elsif ($filter eq 'cuecat') {
 181                 chomp($barcode);
 182             my @fields = split( /\./, $barcode );
 183             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 184             ($#results == 2) and return $results[2];
 185         } elsif ($filter eq 'T-prefix') {
 186                 if ($barcode =~ /^[Tt](\d)/) {
 187                         (defined($1) and $1 eq '0') and return $barcode;
 188             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 189                 }
 190         return sprintf("T%07d", $barcode);
 191         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 192         # Why drop the nonzero digit after the T?
 193         # Why pass non-digits (or empty string) to "T%07d"?
 194         } elsif ($filter eq 'libsuite8') {
 195                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 196                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 197                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 198                         }else{
 199                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 200                         }
 201                 }
 202     } elsif ($filter eq 'EAN13') {
 203         my $ean = CheckDigits('ean');
 204         if ( $ean->is_valid($barcode) ) {
 205             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 206             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 207         } else {
 208             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 209         }
 210         }
 211     return $barcode;    # return barcode, modified or not
 212 }
 213
 214 =head2 _decode
 215
 216   $str = &_decode($chunk);
 217
 218 Decodes a segment of a string emitted by a CueCat barcode scanner and
 219 returns it.
 220
 221 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 222 or Javascript based decoding on the client side.
 223
 224 =cut
 225
 226 sub _decode {
 227     my ($encoded) = @_;
 228     my $seq =
 229       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 230     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 231     my $l = ( $#s + 1 ) % 4;
 232     if ($l) {
 233         if ( $l == 1 ) {
 234             # warn "Error: Cuecat decode parsing failed!";
 235             return;
 236         }
 237         $l = 4 - $l;
 238         $#s += $l;
 239     }
 240     my $r = '';
 241     while ( $#s >= 0 ) {
 242         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 243         $r .=
 244             chr( ( $n >> 16 ) ^ 67 )
 245          .chr( ( $n >> 8 & 255 ) ^ 67 )
 246          .chr( ( $n & 255 ) ^ 67 );
 247         @s = @s[ 4 .. $#s ];
 248     }
 249     $r = substr( $r, 0, length($r) - $l );
 250     return $r;
 251 }
 252
 253 =head2 transferbook
 254
 255   ($dotransfer, $messages, $iteminformation) = &transferbook({
 256                                                    from_branch => $frombranch
 257                                                    to_branch => $tobranch,
 258                                                    barcode => $barcode,
 259                                                    ignore_reserves => $ignore_reserves,
 260                                                    trigger => $trigger
 261                                                 });
 262
 263 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 264
 265 C<$fbr> is the code for the branch initiating the transfer.
 266 C<$tbr> is the code for the branch to which the item should be transferred.
 267
 268 C<$barcode> is the barcode of the item to be transferred.
 269
 270 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 271 Otherwise, if an item is reserved, the transfer fails.
 272
 273 C<$trigger> is the enum value for what triggered the transfer.
 274
 275 Returns three values:
 276
 277 =over
 278
 279 =item $dotransfer
 280
 281 is true if the transfer was successful.
 282
 283 =item $messages
 284
 285 is a reference-to-hash which may have any of the following keys:
 286
 287 =over
 288
 289 =item C<BadBarcode>
 290
 291 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 292
 293 =item C<DestinationEqualsHolding>
 294
 295 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 296
 297 =item C<WasReturned>
 298
 299 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 300
 301 =item C<ResFound>
 302
 303 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 304
 305 =item C<WasTransferred>
 306
 307 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 308
 309 =item C<RecallPlacedAtHoldingBranch>
 310
 311 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 312
 313 =item C<RecallFound>
 314
 315 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 316
 317 =back
 318
 319 =back
 320
 321 =cut
 322
 323 sub transferbook {
 324     my $params = shift;
 325     my $tbr      = $params->{to_branch};
 326     my $fbr      = $params->{from_branch};
 327     my $ignoreRs = $params->{ignore_reserves};
 328     my $barcode  = $params->{barcode};
 329     my $trigger  = $params->{trigger};
 330     my $messages;
 331     my $dotransfer      = 1;
 332     my $item = Koha::Items->find( { barcode => $barcode } );
 333
 334     Koha::Exceptions::MissingParameter->throw(
 335         "Missing mandatory parameter: from_branch")
 336       unless $fbr;
 337
 338     Koha::Exceptions::MissingParameter->throw(
 339         "Missing mandatory parameter: to_branch")
 340       unless $tbr;
 341
 342     # bad barcode..
 343     unless ( $item ) {
 344         $messages->{'BadBarcode'} = $barcode;
 345         $dotransfer = 0;
 346         return ( $dotransfer, $messages );
 347     }
 348
 349     my $itemnumber = $item->itemnumber;
 350     # get branches of book...
 351     my $hbr = $item->homebranch;
 352
 353     # if using Branch Transfer Limits
 354     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 355         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 356         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 357             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 358                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 359                 $dotransfer = 0;
 360             }
 361         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 362             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 363             $dotransfer = 0;
 364         }
 365     }
 366
 367     # can't transfer book if is already there....
 368     if ( $fbr eq $tbr ) {
 369         $messages->{'DestinationEqualsHolding'} = 1;
 370         $dotransfer = 0;
 371     }
 372
 373     # check if it is still issued to someone, return it...
 374     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 375     if ( $issue ) {
 376         AddReturn( $barcode, $fbr );
 377         $messages->{'WasReturned'} = $issue->borrowernumber;
 378     }
 379
 380     # find reserves.....
 381     # That'll save a database query.
 382     my ( $resfound, $resrec, undef ) =
 383       CheckReserves( $itemnumber );
 384     if ( $resfound ) {
 385         $resrec->{'ResFound'} = $resfound;
 386         $messages->{'ResFound'} = $resrec;
 387         $dotransfer = 0 unless $ignoreRs;
 388     }
 389
 390     # find recall
 391     if ( C4::Context->preference('UseRecalls') ) {
 392         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 393         if ( defined $recall ) {
 394             # do a transfer if the recall branch is different to the item holding branch
 395             if ( $recall->pickup_library_id eq $fbr ) {
 396                 $dotransfer = 0;
 397                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 398             } else {
 399                 $dotransfer = 1;
 400                 $messages->{'RecallFound'} = $recall;
 401             }
 402         }
 403     }
 404
 405     #actually do the transfer....
 406     if ($dotransfer) {
 407         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 408
 409         # don't need to update MARC anymore, we do it in batch now
 410         $messages->{'WasTransfered'} = $tbr;
 411
 412     }
 413     ModDateLastSeen( $itemnumber );
 414     return ( $dotransfer, $messages );
 415 }
 416
 417
 418 sub TooMany {
 419     my $borrower        = shift;
 420     my $item_object = shift;
 421     my $params = shift;
 422     my $onsite_checkout = $params->{onsite_checkout} || 0;
 423     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 424     my $cat_borrower    = $borrower->{'categorycode'};
 425     my $dbh             = C4::Context->dbh;
 426     # Get which branchcode we need
 427     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 428     my $type = $item_object->effective_itemtype;
 429
 430     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 431     $type_object = Koha::ItemTypes->find( $type );
 432     $parent_type = $type_object->parent_type if $type_object;
 433     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 434     # Find any children if we are a parent_type;
 435
 436     # given branch, patron category, and item type, determine
 437     # applicable issuing rule
 438
 439     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 440         {
 441             categorycode => $cat_borrower,
 442             itemtype     => $parent_type,
 443             branchcode   => $branch,
 444             rule_name    => 'maxissueqty',
 445         }
 446     ) if $parent_type;
 447     # If the parent rule is for default type we discount it
 448     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 449
 450     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 451         {
 452             categorycode => $cat_borrower,
 453             itemtype     => $type,
 454             branchcode   => $branch,
 455             rule_name    => 'maxissueqty',
 456         }
 457     );
 458
 459     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 460         {
 461             categorycode => $cat_borrower,
 462             itemtype     => $type,
 463             branchcode   => $branch,
 464             rule_name    => 'maxonsiteissueqty',
 465         }
 466     );
 467
 468
 469     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 470     # if a rule is found and has a loan limit set, count
 471     # how many loans the patron already has that meet that
 472     # rule
 473     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 474
 475         my $checkouts;
 476         if ( $maxissueqty_rule->branchcode ) {
 477             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 478                 $checkouts = $patron->checkouts->search(
 479                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 480             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 481                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 482             } else {
 483                 $checkouts = $patron->checkouts->search(
 484                     { 'item.homebranch' => $maxissueqty_rule->branchcode } );
 485             }
 486         } else {
 487             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 488         }
 489         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 490
 491         my $sum_checkouts;
 492         my $rule_itemtype = $maxissueqty_rule->itemtype;
 493
 494         my @types;
 495         unless ( $rule_itemtype ) {
 496             # matching rule has the default item type, so count only
 497             # those existing loans that don't fall under a more
 498             # specific rule
 499             @types = Koha::CirculationRules->search(
 500                 {
 501                     branchcode => $maxissueqty_rule->branchcode,
 502                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 503                     itemtype  => { '!=' => undef },
 504                     rule_name => 'maxissueqty'
 505                 }
 506             )->get_column('itemtype');
 507         } else {
 508             if ( $parent_maxissueqty_rule ) {
 509                 # if we have a parent item type then we count loans of the
 510                 # specific item type or its siblings or parent
 511                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 512                 @types = $children->get_column('itemtype');
 513                 push @types, $parent_type;
 514             } elsif ( $child_types ) {
 515                 # If we are a parent type, we need to count all child types and our own type
 516                 @types = $child_types->get_column('itemtype');
 517                 push @types, $type; # And don't forget to count our own types
 518             } else {
 519                 # Otherwise only count the specific itemtype
 520                 push @types, $type;
 521             }
 522         }
 523
 524         while ( my $c = $checkouts->next ) {
 525             my $itemtype = $c->item->effective_itemtype;
 526
 527             unless ( $rule_itemtype ) {
 528                 next if grep {$_ eq $itemtype} @types;
 529             } else {
 530                 next unless grep {$_ eq $itemtype} @types;
 531             }
 532
 533             $sum_checkouts->{total}++;
 534             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 535             $sum_checkouts->{itemtype}->{$itemtype}++;
 536         }
 537
 538         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 539         my $checkout_count = $sum_checkouts->{total} || 0;
 540         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 541
 542         my $checkout_rules = {
 543             checkout_count               => $checkout_count,
 544             onsite_checkout_count        => $onsite_checkout_count,
 545             onsite_checkout              => $onsite_checkout,
 546             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 547             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 548             switch_onsite_checkout       => $switch_onsite_checkout,
 549         };
 550         # If parent rules exists
 551         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 552             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 553             my $qty_over = _check_max_qty($checkout_rules);
 554             return $qty_over if defined $qty_over;
 555
 556             # If the parent rule is less than or equal to the child, we only need check the parent
 557             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 558                 $checkout_rules->{checkout_count} = $checkout_count_type;
 559                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 560                 my $qty_over = _check_max_qty($checkout_rules);
 561                 return $qty_over if defined $qty_over;
 562             }
 563         } else {
 564             my $qty_over = _check_max_qty($checkout_rules);
 565             return $qty_over if defined $qty_over;
 566         }
 567     }
 568
 569     # Now count total loans against the limit for the branch
 570     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 571     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 572         my $checkouts;
 573         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 574             $checkouts = $patron->checkouts->search(
 575                 { 'me.branchcode' => $branch} );
 576         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 577             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 578         } else {
 579             $checkouts = $patron->checkouts->search(
 580                 { 'item.homebranch' => $branch},
 581                 { prefetch          => 'item' } );
 582         }
 583
 584         my $checkout_count = $checkouts->count;
 585         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 586         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 587         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 588
 589         my $qty_over = _check_max_qty(
 590             {
 591                 checkout_count               => $checkout_count,
 592                 onsite_checkout_count        => $onsite_checkout_count,
 593                 onsite_checkout              => $onsite_checkout,
 594                 max_checkouts_allowed        => $max_checkouts_allowed,
 595                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 596                 switch_onsite_checkout       => $switch_onsite_checkout
 597             }
 598         );
 599         return $qty_over if defined $qty_over;
 600     }
 601
 602     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 603         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 604     }
 605
 606     # OK, the patron can issue !!!
 607     return;
 608 }
 609
 610 sub _check_max_qty {
 611     my $params                       = shift;
 612     my $checkout_count               = $params->{checkout_count};
 613     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 614     my $onsite_checkout              = $params->{onsite_checkout};
 615     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 616     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 617     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 618
 619     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 620         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 621         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 622             return {
 623                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 624                 count       => $onsite_checkout_count,
 625                 max_allowed => $max_onsite_checkouts_allowed,
 626             };
 627         }
 628     }
 629     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 630         if ( $max_checkouts_allowed eq '' ) { return; }
 631         my $delta = $switch_onsite_checkout ? 1 : 0;
 632         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 633             return {
 634                 reason      => 'TOO_MANY_CHECKOUTS',
 635                 count       => $checkout_count,
 636                 max_allowed => $max_checkouts_allowed,
 637             };
 638         }
 639     }
 640     elsif ( not $onsite_checkout ) {
 641         if ( $max_checkouts_allowed eq '' ) { return; }
 642         if (
 643             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 644         {
 645             return {
 646                 reason      => 'TOO_MANY_CHECKOUTS',
 647                 count       => $checkout_count - $onsite_checkout_count,
 648                 max_allowed => $max_checkouts_allowed,
 649             };
 650         }
 651     }
 652
 653     return;
 654 }
 655
 656 =head2 CanBookBeIssued
 657
 658   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 659                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 660
 661 Check if a book can be issued.
 662
 663 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 664
 665 IMPORTANT: The assumption by users of this routine is that causes blocking
 666 the issue are keyed by uppercase labels and other returned
 667 data is keyed in lower case!
 668
 669 =over 4
 670
 671 =item C<$patron> is a Koha::Patron
 672
 673 =item C<$barcode> is the bar code of the book being issued.
 674
 675 =item C<$duedates> is a DateTime object.
 676
 677 =item C<$inprocess> boolean switch
 678
 679 =item C<$ignore_reserves> boolean switch
 680
 681 =item C<$params> Hashref of additional parameters
 682
 683 Available keys:
 684     override_high_holds - Ignore high holds
 685     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 686
 687 =back
 688
 689 Returns :
 690
 691 =over 4
 692
 693 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 694 Possible values are :
 695
 696 =back
 697
 698 =head3 INVALID_DATE
 699
 700 sticky due date is invalid
 701
 702 =head3 GNA
 703
 704 borrower gone with no address
 705
 706 =head3 CARD_LOST
 707
 708 borrower declared it's card lost
 709
 710 =head3 DEBARRED
 711
 712 borrower debarred
 713
 714 =head3 UNKNOWN_BARCODE
 715
 716 barcode unknown
 717
 718 =head3 NOT_FOR_LOAN
 719
 720 item is not for loan
 721
 722 =head3 WTHDRAWN
 723
 724 item withdrawn.
 725
 726 =head3 RESTRICTED
 727
 728 item is restricted (set by ??)
 729
 730 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 731 could be prevented, but ones that can be overriden by the operator.
 732
 733 Possible values are :
 734
 735 =head3 DEBT
 736
 737 borrower has debts.
 738
 739 =head3 RENEW_ISSUE
 740
 741 renewing, not issuing
 742
 743 =head3 ISSUED_TO_ANOTHER
 744
 745 issued to someone else.
 746
 747 =head3 RESERVED
 748
 749 reserved for someone else.
 750
 751 =head3 TRANSFERRED
 752
 753 reserved and being transferred for someone else.
 754
 755 =head3 INVALID_DATE
 756
 757 sticky due date is invalid or due date in the past
 758
 759 =head3 TOO_MANY
 760
 761 if the borrower borrows to much things
 762
 763 =head3 RECALLED
 764
 765 recalled by someone else
 766
 767 =cut
 768
 769 sub CanBookBeIssued {
 770     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 771     my %needsconfirmation;    # filled with problems that needs confirmations
 772     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 773     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 774     my %messages;             # filled with information messages that should be displayed.
 775
 776     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 777     my $override_high_holds = $params->{override_high_holds} || 0;
 778
 779     my $item_object = Koha::Items->find({barcode => $barcode });
 780
 781     # MANDATORY CHECKS - unless item exists, nothing else matters
 782     unless ( $item_object ) {
 783         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 784     }
 785     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 786
 787     my $item_unblessed = $item_object->unblessed; # Transition...
 788     my $issue = $item_object->checkout;
 789     my $biblio = $item_object->biblio;
 790
 791     my $biblioitem = $biblio->biblioitem;
 792     my $effective_itemtype = $item_object->effective_itemtype;
 793     my $dbh             = C4::Context->dbh;
 794     my $patron_unblessed = $patron->unblessed;
 795
 796     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 797
 798     my $now = dt_from_string();
 799     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 800     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 801          $needsconfirmation{INVALID_DATE} = $duedate;
 802     }
 803
 804     my $fees = Koha::Charges::Fees->new(
 805         {
 806             patron    => $patron,
 807             library   => $circ_library,
 808             item      => $item_object,
 809             to_date   => $duedate,
 810         }
 811     );
 812
 813     #
 814     # BORROWER STATUS
 815     #
 816     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 817         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 818         C4::Stats::UpdateStats({
 819                      branch => C4::Context->userenv->{'branch'},
 820                      type => 'localuse',
 821                      itemnumber => $item_object->itemnumber,
 822                      itemtype => $effective_itemtype,
 823                      borrowernumber => $patron->borrowernumber,
 824                      ccode => $item_object->ccode}
 825                     );
 826         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 827         return( { STATS => 1 }, {});
 828     }
 829
 830     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 831         $issuingimpossible{GNA} = 1;
 832     }
 833
 834     if ( $patron->lost && $patron->lost == 1 ) {
 835         $issuingimpossible{CARD_LOST} = 1;
 836     }
 837     if ( $patron->is_debarred ) {
 838         $issuingimpossible{DEBARRED} = 1;
 839     }
 840
 841     if ( $patron->is_expired ) {
 842         $issuingimpossible{EXPIRED} = 1;
 843     }
 844
 845     #
 846     # BORROWER STATUS
 847     #
 848
 849     # DEBTS
 850     my $account = $patron->account;
 851     my $balance = $account->balance;
 852     my $non_issues_charges = $account->non_issues_charges;
 853     my $other_charges = $balance - $non_issues_charges;
 854
 855     my $amountlimit = C4::Context->preference("noissuescharge");
 856     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 857     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 858
 859     # Check the debt of this patrons guarantees
 860     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 861     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 862     if ( defined $no_issues_charge_guarantees ) {
 863         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 864         my $guarantees_non_issues_charges = 0;
 865         foreach my $g ( @guarantees ) {
 866             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 867         }
 868
 869         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 870             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 871         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 872             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 873         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 874             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 875         }
 876     }
 877
 878     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 879     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 880     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 881     if ( defined $no_issues_charge_guarantors ) {
 882         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 883
 884         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 885             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 886         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 887             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 888         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 889             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 890         }
 891     }
 892
 893     if ( C4::Context->preference("IssuingInProcess") ) {
 894         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 895             $issuingimpossible{DEBT} = $non_issues_charges;
 896         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 897             $needsconfirmation{DEBT} = $non_issues_charges;
 898         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 899             $needsconfirmation{DEBT} = $non_issues_charges;
 900         }
 901     }
 902     else {
 903         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 904             $needsconfirmation{DEBT} = $non_issues_charges;
 905         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 906             $issuingimpossible{DEBT} = $non_issues_charges;
 907         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 908             $needsconfirmation{DEBT} = $non_issues_charges;
 909         }
 910     }
 911
 912     if ($balance > 0 && $other_charges > 0) {
 913         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 914     }
 915
 916     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 917     $patron_unblessed = $patron->unblessed;
 918
 919     if ( my $debarred_date = $patron->is_debarred ) {
 920          # patron has accrued fine days or has a restriction. $count is a date
 921         if ($debarred_date eq '9999-12-31') {
 922             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 923         }
 924         else {
 925             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 926         }
 927     } elsif ( my $num_overdues = $patron->has_overdues ) {
 928         ## patron has outstanding overdue loans
 929         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 930             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 931         }
 932         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 933             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 934         }
 935     }
 936
 937     # Additional Materials Check
 938     if ( C4::Context->preference("CircConfirmItemParts")
 939         && $item_object->materials )
 940     {
 941         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 942     }
 943
 944     #
 945     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 946     #
 947     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 948
 949         # Already issued to current borrower.
 950         # If it is an on-site checkout if it can be switched to a normal checkout
 951         # or ask whether the loan should be renewed
 952
 953         if ( $issue->onsite_checkout
 954                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 955             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 956         } else {
 957             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 958                 $patron->borrowernumber,
 959                 $item_object->itemnumber,
 960             );
 961             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 962                 if ( $renewerror eq 'onsite_checkout' ) {
 963                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 964                 }
 965                 else {
 966                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 967                 }
 968             }
 969             else {
 970                 $needsconfirmation{RENEW_ISSUE} = 1;
 971             }
 972         }
 973     }
 974     elsif ( $issue ) {
 975
 976         # issued to someone else
 977
 978         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 979
 980         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 981
 982         unless ( $can_be_returned ) {
 983             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 984             $issuingimpossible{branch_to_return} = $message;
 985         } else {
 986             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 987                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 988             } else {
 989             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 990             $needsconfirmation{issued_firstname} = $patron->firstname;
 991             $needsconfirmation{issued_surname} = $patron->surname;
 992             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 993             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 994             }
 995         }
 996     }
 997
 998     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 999     #
1000     my $switch_onsite_checkout = (
1001           C4::Context->preference('SwitchOnSiteCheckouts')
1002       and $issue
1003       and $issue->onsite_checkout
1004       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1005     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1006     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1007     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1008         if ( $toomany->{max_allowed} == 0 ) {
1009             $needsconfirmation{PATRON_CANT} = 1;
1010         }
1011         if ( C4::Context->preference("AllowTooManyOverride") ) {
1012             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1013             $needsconfirmation{current_loan_count} = $toomany->{count};
1014             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1015         } else {
1016             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1017             $issuingimpossible{current_loan_count} = $toomany->{count};
1018             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1019         }
1020     }
1021
1022     #
1023     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1024     #
1025     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1026     my $wants_check = $patron->wants_check_for_previous_checkout;
1027     $needsconfirmation{PREVISSUE} = 1
1028         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1029
1030     #
1031     # ITEM CHECKING
1032     #
1033     if ( $item_object->notforloan )
1034     {
1035         if(!C4::Context->preference("AllowNotForLoanOverride")){
1036             $issuingimpossible{NOT_FOR_LOAN} = 1;
1037             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1038         }else{
1039             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1040             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1041         }
1042     }
1043     else {
1044         # we have to check itemtypes.notforloan also
1045         if (C4::Context->preference('item-level_itypes')){
1046             # this should probably be a subroutine
1047             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1048             $sth->execute($effective_itemtype);
1049             my $notforloan=$sth->fetchrow_hashref();
1050             if ($notforloan->{'notforloan'}) {
1051                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1052                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1053                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1054                 } else {
1055                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1056                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1057                 }
1058             }
1059         }
1060         else {
1061             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1062             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1063                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1064                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1065                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1066                 } else {
1067                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1068                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1069                 }
1070             }
1071         }
1072     }
1073     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1074     {
1075         $issuingimpossible{WTHDRAWN} = 1;
1076     }
1077     if (   $item_object->restricted
1078         && $item_object->restricted == 1 )
1079     {
1080         $issuingimpossible{RESTRICTED} = 1;
1081     }
1082     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1083         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1084         my $code = $av->count ? $av->next->lib : '';
1085         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1086         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1087     }
1088     if ( C4::Context->preference("IndependentBranches") ) {
1089         my $userenv = C4::Context->userenv;
1090         unless ( C4::Context->IsSuperLibrarian() ) {
1091             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1092             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1093                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1094                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1095             }
1096             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1097               if ( $patron->branchcode ne $userenv->{branch} );
1098         }
1099     }
1100
1101     #
1102     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1103     #
1104     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1105     if ($rentalConfirmation) {
1106         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1107
1108         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1109         if ($itemtype_object) {
1110             my $accumulate_charge = $fees->accumulate_rentalcharge();
1111             if ( $accumulate_charge > 0 ) {
1112                 $rentalCharge += $accumulate_charge;
1113             }
1114         }
1115
1116         if ( $rentalCharge > 0 ) {
1117             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1118         }
1119     }
1120
1121     my $recall;
1122     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1123     # Only bother doing this if UseRecalls is enabled and the item is recallable
1124     # Don't look at recalls that are in transit
1125     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1126         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1127
1128         foreach my $r ( @recalls ) {
1129             if ( $r->item_id and
1130                 $r->item_id == $item_object->itemnumber and
1131                 $r->patron_id == $patron->borrowernumber and
1132                 ( $r->waiting or $r->requested ) ) {
1133                 $messages{RECALLED} = $r->id;
1134                 $recall = $r;
1135                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1136                 last;
1137             }
1138             elsif ( $r->item_id and
1139                 $r->item_id == $item_object->itemnumber and
1140                 $r->in_transit ) {
1141                 # recalled item is in transit
1142                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1143             }
1144             elsif ( $r->item_level and
1145                 $r->item_id == $item_object->itemnumber and
1146                 $r->patron_id != $patron->borrowernumber and
1147                 !$r->in_transit ) {
1148                 # this specific item has been recalled by a different patron
1149                 $needsconfirmation{RECALLED} = $r;
1150                 $recall = $r;
1151                 last;
1152             }
1153             elsif ( !$r->item_level and
1154                 $r->patron_id != $patron->borrowernumber and
1155                 !$r->in_transit ) {
1156                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1157                 $needsconfirmation{RECALLED} = $r;
1158                 $recall = $r;
1159                 last;
1160             }
1161         }
1162     }
1163
1164     unless ( $ignore_reserves and defined $recall ) {
1165         # See if the item is on reserve.
1166         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1167         if ($restype) {
1168             my $resbor = $res->{'borrowernumber'};
1169             if ( $resbor ne $patron->borrowernumber ) {
1170                 my $patron = Koha::Patrons->find( $resbor );
1171                 if ( $restype eq "Waiting" )
1172                 {
1173                     # The item is on reserve and waiting, but has been
1174                     # reserved by some other patron.
1175                     $needsconfirmation{RESERVE_WAITING} = 1;
1176                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1177                     $needsconfirmation{'ressurname'} = $patron->surname;
1178                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1179                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1180                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1181                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1182                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1183                 }
1184                 elsif ( $restype eq "Reserved" ) {
1185                     # The item is on reserve for someone else.
1186                     $needsconfirmation{RESERVED} = 1;
1187                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1188                     $needsconfirmation{'ressurname'} = $patron->surname;
1189                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1190                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1191                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1192                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1193                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1194                 }
1195                 elsif ( $restype eq "Transferred" ) {
1196                     # The item is determined hold being transferred for someone else.
1197                     $needsconfirmation{TRANSFERRED} = 1;
1198                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1199                     $needsconfirmation{'ressurname'} = $patron->surname;
1200                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1201                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1202                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1203                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1204                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1205                 }
1206                 elsif ( $restype eq "Processing" ) {
1207                     # The item is determined hold being processed for someone else.
1208                     $needsconfirmation{PROCESSING} = 1;
1209                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1210                     $needsconfirmation{'ressurname'} = $patron->surname;
1211                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1212                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1213                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1214                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1215                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1216                 }
1217             }
1218         }
1219     }
1220
1221     ## CHECK AGE RESTRICTION
1222     my $agerestriction  = $biblioitem->agerestriction;
1223     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1224     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1225         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1226             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1227         }
1228         else {
1229             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1230         }
1231     }
1232
1233     ## check for high holds decreasing loan period
1234     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1235         my $check = checkHighHolds( $item_object, $patron );
1236
1237         if ( $check->{exceeded} ) {
1238             my $highholds = {
1239                 num_holds  => $check->{outstanding},
1240                 duration   => $check->{duration},
1241                 returndate => $check->{due_date},
1242             };
1243             if ($override_high_holds) {
1244                 $alerts{HIGHHOLDS} = $highholds;
1245             }
1246             else {
1247                 $needsconfirmation{HIGHHOLDS} = $highholds;
1248             }
1249         }
1250     }
1251
1252     if (
1253         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1254         # don't do the multiple loans per bib check if we've
1255         # already determined that we've got a loan on the same item
1256         !$issuingimpossible{NO_MORE_RENEWALS} &&
1257         !$needsconfirmation{RENEW_ISSUE}
1258     ) {
1259         # Check if borrower has already issued an item from the same biblio
1260         # Only if it's not a subscription
1261         my $biblionumber = $item_object->biblionumber;
1262         require C4::Serials;
1263         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1264         unless ($is_a_subscription) {
1265             # FIXME Should be $patron->checkouts($args);
1266             my $checkouts = Koha::Checkouts->search(
1267                 {
1268                     borrowernumber => $patron->borrowernumber,
1269                     biblionumber   => $biblionumber,
1270                 },
1271                 {
1272                     join => 'item',
1273                 }
1274             );
1275             # if we get here, we don't already have a loan on this item,
1276             # so if there are any loans on this bib, ask for confirmation
1277             if ( $checkouts->count ) {
1278                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1279             }
1280         }
1281     }
1282
1283     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1284 }
1285
1286 =head2 CanBookBeReturned
1287
1288   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1289
1290 Check whether the item can be returned to the provided branch
1291
1292 =over 4
1293
1294 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1295
1296 =item C<$branch> is the branchcode where the return is taking place
1297
1298 =back
1299
1300 Returns:
1301
1302 =over 4
1303
1304 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1305
1306 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1307
1308 =back
1309
1310 =cut
1311
1312 sub CanBookBeReturned {
1313   my ($item, $branch) = @_;
1314   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1315
1316   # assume return is allowed to start
1317   my $allowed = 1;
1318   my $message;
1319
1320   # identify all cases where return is forbidden
1321   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1322      $allowed = 0;
1323      $message = $item->{'homebranch'};
1324   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1325      $allowed = 0;
1326      $message = $item->{'holdingbranch'};
1327   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1328      $allowed = 0;
1329      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1330   }
1331
1332   return ($allowed, $message);
1333 }
1334
1335 =head2 CheckHighHolds
1336
1337     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1338     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1339     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1340
1341 =cut
1342
1343 sub checkHighHolds {
1344     my ( $item, $patron ) = @_;
1345     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1346
1347     my $return_data = {
1348         exceeded    => 0,
1349         outstanding => 0,
1350         duration    => 0,
1351         due_date    => undef,
1352     };
1353
1354     my $holds = Koha::Holds->search( { biblionumber => $item->biblionumber } );
1355
1356     if ( $holds->count() ) {
1357         $return_data->{outstanding} = $holds->count();
1358
1359         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1360         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1361         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1362
1363         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1364
1365         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1366
1367             # static means just more than a given number of holds on the record
1368
1369             # If the number of holds is less than the threshold, we can stop here
1370             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1371                 return $return_data;
1372             }
1373         }
1374         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1375
1376             # dynamic means X more than the number of holdable items on the record
1377
1378             # let's get the items
1379             my @items = $holds->next()->biblio()->items()->as_list;
1380
1381             # Remove any items with status defined to be ignored even if the would not make item unholdable
1382             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1383                 @items = grep { !$_->$status } @items;
1384             }
1385
1386             # Remove any items that are not holdable for this patron
1387             @items = grep { CanItemBeReserved( $patron , $_, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1388
1389             my $items_count = scalar @items;
1390
1391             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1392
1393             # If the number of holds is less than the count of items we have
1394             # plus the number of holds allowed above that count, we can stop here
1395             if ( $holds->count() <= $threshold ) {
1396                 return $return_data;
1397             }
1398         }
1399
1400         my $issuedate = dt_from_string();
1401
1402         my $itype = $item->effective_itemtype;
1403         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1404             {
1405                 categorycode => $patron->categorycode,
1406                 itemtype     => $itype,
1407                 branchcode   => $branchcode,
1408             }
1409         );
1410         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1411
1412         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1413
1414         my $rule = Koha::CirculationRules->get_effective_rule_value(
1415             {
1416                 categorycode => $patron->categorycode,
1417                 itemtype     => $item->effective_itemtype,
1418                 branchcode   => $branchcode,
1419                 rule_name    => 'decreaseloanholds',
1420             }
1421         );
1422
1423         my $duration;
1424         if ( defined($rule) && $rule ne '' ){
1425             # overrides decreaseLoanHighHoldsDuration syspref
1426             $duration = $rule;
1427         } else {
1428             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1429         }
1430         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1431         $reduced_datedue->set_hour($orig_due->hour);
1432         $reduced_datedue->set_minute($orig_due->minute);
1433         $reduced_datedue->truncate( to => 'minute' );
1434
1435         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1436             $return_data->{exceeded} = 1;
1437             $return_data->{duration} = $duration;
1438             $return_data->{due_date} = $reduced_datedue;
1439         }
1440     }
1441
1442     return $return_data;
1443 }
1444
1445 =head2 AddIssue
1446
1447   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1448
1449 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1450
1451 =over 4
1452
1453 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1454
1455 =item C<$barcode> is the barcode of the item being issued.
1456
1457 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1458 Calculated if empty.
1459
1460 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1461
1462 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1463 Defaults to today.
1464
1465 AddIssue does the following things :
1466
1467   - step 01: check that there is a borrowernumber & a barcode provided
1468   - check for RENEWAL (book issued & being issued to the same patron)
1469       - renewal YES = Calculate Charge & renew
1470       - renewal NO  =
1471           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1472           * RESERVE PLACED ?
1473               - fill reserve if reserve to this patron
1474               - cancel reserve or not, otherwise
1475           * RECALL PLACED ?
1476               - fill recall if recall to this patron
1477               - cancel recall or not
1478               - revert recall's waiting status or not
1479           * TRANSFERT PENDING ?
1480               - complete the transfert
1481           * ISSUE THE BOOK
1482
1483 =back
1484
1485 =cut
1486
1487 sub AddIssue {
1488     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1489
1490     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1491     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1492     my $auto_renew = $params && $params->{auto_renew};
1493     my $cancel_recall = $params && $params->{cancel_recall};
1494     my $recall_id = $params && $params->{recall_id};
1495     my $dbh          = C4::Context->dbh;
1496     my $barcodecheck = CheckValidBarcode($barcode);
1497
1498     my $issue;
1499
1500     if ( $datedue && ref $datedue ne 'DateTime' ) {
1501         $datedue = dt_from_string($datedue);
1502     }
1503
1504     # $issuedate defaults to today.
1505     if ( !defined $issuedate ) {
1506         $issuedate = dt_from_string();
1507     }
1508     else {
1509         if ( ref $issuedate ne 'DateTime' ) {
1510             $issuedate = dt_from_string($issuedate);
1511
1512         }
1513     }
1514
1515     # Stop here if the patron or barcode doesn't exist
1516     if ( $borrower && $barcode && $barcodecheck ) {
1517         # find which item we issue
1518         my $item_object = Koha::Items->find({ barcode => $barcode })
1519           or return;    # if we don't get an Item, abort.
1520         my $item_unblessed = $item_object->unblessed;
1521
1522         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1523
1524         # get actual issuing if there is one
1525         my $actualissue = $item_object->checkout;
1526
1527         # check if we just renew the issue.
1528         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1529                 and not $switch_onsite_checkout ) {
1530             $datedue = AddRenewal(
1531                 $borrower->{'borrowernumber'},
1532                 $item_object->itemnumber,
1533                 $branchcode,
1534                 $datedue,
1535                 $issuedate,    # here interpreted as the renewal date
1536             );
1537         }
1538         else {
1539             unless ($datedue) {
1540                 my $itype = $item_object->effective_itemtype;
1541                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1542
1543             }
1544
1545             # Check if we need to use an exact due date set by the ILL module
1546             if ( C4::Context->preference('ILLModule') ) {
1547                 # Check if there is an ILL connected with the biblio of the item we are issuing
1548                 my $ill_request = Koha::Illrequests->search({
1549                     biblio_id => $item_object->biblionumber,
1550                     borrowernumber => $borrower->{'borrowernumber'},
1551                     completed => undef,
1552                     due_date => { '!=', undef },
1553                 })->next;
1554
1555                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1556                     my $ill_dt = dt_from_string( $ill_request->due_date );
1557                     $ill_dt->set_hour(23);
1558                     $ill_dt->set_minute(59);
1559                     $datedue = $ill_dt;
1560                 }
1561             }
1562
1563             $datedue->truncate( to => 'minute' );
1564
1565             my $patron = Koha::Patrons->find( $borrower );
1566             my $library = Koha::Libraries->find( $branchcode );
1567             my $fees = Koha::Charges::Fees->new(
1568                 {
1569                     patron    => $patron,
1570                     library   => $library,
1571                     item      => $item_object,
1572                     to_date   => $datedue,
1573                 }
1574             );
1575
1576             # it's NOT a renewal
1577             if ( $actualissue and not $switch_onsite_checkout ) {
1578                 # This book is currently on loan, but not to the person
1579                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1580                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1581                 return unless $allowed;
1582                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1583                 # AddReturn certainly has side-effects, like onloan => undef
1584                 $item_object->discard_changes;
1585             }
1586
1587             if ( C4::Context->preference('UseRecalls') ) {
1588                 Koha::Recalls->move_recall(
1589                     {
1590                         action         => $cancel_recall,
1591                         recall_id      => $recall_id,
1592                         item           => $item_object,
1593                         borrowernumber => $borrower->{borrowernumber},
1594                     }
1595                 );
1596             }
1597
1598             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1599
1600             # Starting process for transfer job (checking transfert and validate it if we have one)
1601             if ( my $transfer = $item_object->get_transfer ) {
1602                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1603                 $transfer->set(
1604                     {
1605                         datearrived => dt_from_string,
1606                         tobranch    => C4::Context->userenv->{branch},
1607                         comments    => 'Forced branchtransfer'
1608                     }
1609                 )->store;
1610                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1611                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1612                     if ( $hold ) { # Is this really needed?
1613                         $hold->set( { found => undef } )->store;
1614                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1615                     }
1616                 }
1617             }
1618
1619             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1620             unless ($auto_renew) {
1621                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1622                     {
1623                         categorycode => $borrower->{categorycode},
1624                         itemtype     => $item_object->effective_itemtype,
1625                         branchcode   => $branchcode,
1626                         rule_name    => 'auto_renew'
1627                     }
1628                 );
1629
1630                 $auto_renew = $rule if defined $rule && $rule ne '';
1631             }
1632
1633             my $issue_attributes = {
1634                 borrowernumber  => $borrower->{'borrowernumber'},
1635                 issuedate       => $issuedate,
1636                 date_due        => $datedue,
1637                 branchcode      => C4::Context->userenv->{'branch'},
1638                 onsite_checkout => $onsite_checkout,
1639                 auto_renew      => $auto_renew ? 1 : 0,
1640             };
1641
1642             # Get ID of logged in user.  if called from a batch job,
1643             # no user session exists and C4::Context->userenv() returns
1644             # the scalar '0'. Only do this if the syspref says so
1645             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1646                 my $userenv = C4::Context->userenv();
1647                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1648                 if ($usernumber) {
1649                     $issue_attributes->{issuer_id} = $usernumber;
1650                 }
1651             }
1652
1653             # In the case that the borrower has an on-site checkout
1654             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1655             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1656             if ($issue) {
1657                 $issue->set($issue_attributes)->store;
1658             }
1659             else {
1660                 $issue = Koha::Checkout->new(
1661                     {
1662                         itemnumber => $item_object->itemnumber,
1663                         %$issue_attributes,
1664                     }
1665                 )->store;
1666             }
1667             $issue->discard_changes;
1668             C4::Auth::track_login_daily( $borrower->{userid} );
1669             if ( $item_object->location && $item_object->location eq 'CART'
1670                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1671             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1672                 CartToShelf( $item_object->itemnumber );
1673             }
1674
1675             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1676                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1677             }
1678
1679             # Record if item was lost
1680             my $was_lost = $item_object->itemlost;
1681
1682             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1683             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1684             $item_object->itemlost(0);
1685             $item_object->onloan($datedue->ymd());
1686             $item_object->datelastborrowed( dt_from_string()->ymd() );
1687             $item_object->datelastseen( dt_from_string()->ymd() );
1688             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1689
1690             # If the item was lost, it has now been found, charge the overdue if necessary
1691             if ($was_lost) {
1692                 if ( $item_object->{_charge} ) {
1693                     $actualissue //= Koha::Old::Checkouts->search(
1694                         { itemnumber => $item_unblessed->{itemnumber} },
1695                         {
1696                             order_by => { '-desc' => 'returndate' },
1697                             rows     => 1
1698                         }
1699                     )->single;
1700                     unless ( exists( $borrower->{branchcode} ) ) {
1701                         my $patron = $actualissue->patron;
1702                         $borrower = $patron->unblessed;
1703                     }
1704                     _CalculateAndUpdateFine(
1705                         {
1706                             issue       => $actualissue,
1707                             item        => $item_unblessed,
1708                             borrower    => $borrower,
1709                             return_date => $issuedate
1710                         }
1711                     );
1712                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1713                         $item_object->itemnumber, undef, 'RENEWED' );
1714                 }
1715             }
1716
1717             # If it costs to borrow this book, charge it to the patron's account.
1718             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1719             if ( $charge && $charge > 0 ) {
1720                 AddIssuingCharge( $issue, $charge, 'RENT' );
1721             }
1722
1723             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1724             if ( $itemtype_object ) {
1725                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1726                 if ( $accumulate_charge > 0 ) {
1727                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1728                     $charge += $accumulate_charge;
1729                     $item_unblessed->{charge} = $charge;
1730                 }
1731             }
1732
1733             # Record the fact that this book was issued.
1734             C4::Stats::UpdateStats(
1735                 {
1736                     branch => C4::Context->userenv->{'branch'},
1737                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1738                     amount         => $charge,
1739                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1740                     itemnumber     => $item_object->itemnumber,
1741                     itemtype       => $item_object->effective_itemtype,
1742                     location       => $item_object->location,
1743                     borrowernumber => $borrower->{'borrowernumber'},
1744                     ccode          => $item_object->ccode,
1745                 }
1746             );
1747
1748             # Send a checkout slip.
1749             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1750             my %conditions        = (
1751                 branchcode   => $branchcode,
1752                 categorycode => $borrower->{categorycode},
1753                 item_type    => $item_object->effective_itemtype,
1754                 notification => 'CHECKOUT',
1755             );
1756             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1757                 SendCirculationAlert(
1758                     {
1759                         type     => 'CHECKOUT',
1760                         item     => $item_object->unblessed,
1761                         borrower => $borrower,
1762                         branch   => $branchcode,
1763                     }
1764                 );
1765             }
1766             logaction(
1767                 "CIRCULATION", "ISSUE",
1768                 $borrower->{'borrowernumber'},
1769                 $item_object->itemnumber,
1770             ) if C4::Context->preference("IssueLog");
1771
1772             Koha::Plugins->call('after_circ_action', {
1773                 action  => 'checkout',
1774                 payload => {
1775                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1776                     checkout => $issue->get_from_storage
1777                 }
1778             });
1779
1780             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1781                 {
1782                     biblio_ids => [ $item_object->biblionumber ]
1783                 }
1784             ) if C4::Context->preference('RealTimeHoldsQueue');
1785         }
1786     }
1787     return $issue;
1788 }
1789
1790 =head2 GetLoanLength
1791
1792   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1793
1794 Get loan length for an itemtype, a borrower type and a branch
1795
1796 =cut
1797
1798 sub GetLoanLength {
1799     my ( $categorycode, $itemtype, $branchcode ) = @_;
1800
1801     # Initialize default values
1802     my $rules = {
1803         issuelength   => 0,
1804         renewalperiod => 0,
1805         lengthunit    => 'days',
1806     };
1807
1808     my $found = Koha::CirculationRules->get_effective_rules( {
1809         branchcode => $branchcode,
1810         categorycode => $categorycode,
1811         itemtype => $itemtype,
1812         rules => [
1813             'issuelength',
1814             'renewalperiod',
1815             'lengthunit'
1816         ],
1817     } );
1818
1819     # Search for rules!
1820     foreach my $rule_name (keys %$found) {
1821         $rules->{$rule_name} = $found->{$rule_name};
1822     }
1823
1824     return $rules;
1825 }
1826
1827
1828 =head2 GetHardDueDate
1829
1830   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1831
1832 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1833
1834 =cut
1835
1836 sub GetHardDueDate {
1837     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1838
1839     my $rules = Koha::CirculationRules->get_effective_rules(
1840         {
1841             categorycode => $borrowertype,
1842             itemtype     => $itemtype,
1843             branchcode   => $branchcode,
1844             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1845         }
1846     );
1847
1848     if ( defined( $rules->{hardduedate} ) ) {
1849         if ( $rules->{hardduedate} ) {
1850             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1851         }
1852         else {
1853             return ( undef, undef );
1854         }
1855     }
1856 }
1857
1858 =head2 GetBranchBorrowerCircRule
1859
1860   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1861
1862 Retrieves circulation rule attributes that apply to the given
1863 branch and patron category, regardless of item type.
1864 The return value is a hashref containing the following key:
1865
1866 patron_maxissueqty - maximum number of loans that a
1867 patron of the given category can have at the given
1868 branch.  If the value is undef, no limit.
1869
1870 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1871 patron of the given category can have at the given
1872 branch.  If the value is undef, no limit.
1873
1874 This will check for different branch/category combinations in the following order:
1875 branch and category
1876 branch only
1877 category only
1878 default branch and category
1879
1880 If no rule has been found in the database, it will default to
1881 the buillt in rule:
1882
1883 patron_maxissueqty - undef
1884 patron_maxonsiteissueqty - undef
1885
1886 C<$branchcode> and C<$categorycode> should contain the
1887 literal branch code and patron category code, respectively - no
1888 wildcards.
1889
1890 =cut
1891
1892 sub GetBranchBorrowerCircRule {
1893     my ( $branchcode, $categorycode ) = @_;
1894
1895     # Initialize default values
1896     my $rules = {
1897         patron_maxissueqty       => undef,
1898         patron_maxonsiteissueqty => undef,
1899     };
1900
1901     # Search for rules!
1902     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1903         my $rule = Koha::CirculationRules->get_effective_rule(
1904             {
1905                 categorycode => $categorycode,
1906                 itemtype     => undef,
1907                 branchcode   => $branchcode,
1908                 rule_name    => $rule_name,
1909             }
1910         );
1911
1912         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1913     }
1914
1915     return $rules;
1916 }
1917
1918 =head2 GetBranchItemRule
1919
1920   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1921
1922 Retrieves circulation rule attributes that apply to the given
1923 branch and item type, regardless of patron category.
1924
1925 The return value is a hashref containing the following keys:
1926
1927 holdallowed => Hold policy for this branch and itemtype. Possible values:
1928   not_allowed:           No holds allowed.
1929   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1930   from_any_library:      Holds allowed from any patron.
1931   from_local_hold_group: Holds allowed from libraries in hold group
1932
1933 returnbranch => branch to which to return item.  Possible values:
1934   noreturn: do not return, let item remain where checked in (floating collections)
1935   homebranch: return to item's home branch
1936   holdingbranch: return to issuer branch
1937
1938 This searches branchitemrules in the following order:
1939
1940   * Same branchcode and itemtype
1941   * Same branchcode, itemtype '*'
1942   * branchcode '*', same itemtype
1943   * branchcode and itemtype '*'
1944
1945 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1946
1947 =cut
1948
1949 sub GetBranchItemRule {
1950     my ( $branchcode, $itemtype ) = @_;
1951
1952     # Search for rules!
1953     my $rules = Koha::CirculationRules->get_effective_rules({
1954         branchcode => $branchcode,
1955         itemtype => $itemtype,
1956         rules => ['holdallowed', 'hold_fulfillment_policy', 'returnbranch']
1957     });
1958
1959     # built-in default circulation rule
1960     $rules->{holdallowed} //= 'from_any_library';
1961     $rules->{hold_fulfillment_policy} //= 'any';
1962     $rules->{returnbranch} //= 'homebranch';
1963
1964     return $rules;
1965 }
1966
1967 =head2 AddReturn
1968
1969   ($doreturn, $messages, $iteminformation, $borrower) =
1970       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1971
1972 Returns a book.
1973
1974 =over 4
1975
1976 =item C<$barcode> is the bar code of the book being returned.
1977
1978 =item C<$branch> is the code of the branch where the book is being returned.
1979
1980 =item C<$exemptfine> indicates that overdue charges for the item will be
1981 removed. Optional.
1982
1983 =item C<$return_date> allows the default return date to be overridden
1984 by the given return date. Optional.
1985
1986 =back
1987
1988 C<&AddReturn> returns a list of four items:
1989
1990 C<$doreturn> is true iff the return succeeded.
1991
1992 C<$messages> is a reference-to-hash giving feedback on the operation.
1993 The keys of the hash are:
1994
1995 =over 4
1996
1997 =item C<BadBarcode>
1998
1999 No item with this barcode exists. The value is C<$barcode>.
2000
2001 =item C<NotIssued>
2002
2003 The book is not currently on loan. The value is C<$barcode>.
2004
2005 =item C<withdrawn>
2006
2007 This book has been withdrawn/cancelled. The value should be ignored.
2008
2009 =item C<Wrongbranch>
2010
2011 This book has was returned to the wrong branch.  The value is a hashref
2012 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2013 contain the branchcode of the incorrect and correct return library, respectively.
2014
2015 =item C<ResFound>
2016
2017 The item was reserved. The value is a reference-to-hash whose keys are
2018 fields from the reserves table of the Koha database, and
2019 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2020 either C<Waiting>, C<Reserved>, or 0.
2021
2022 =item C<WasReturned>
2023
2024 Value 1 if return is successful.
2025
2026 =item C<NeedsTransfer>
2027
2028 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2029
2030 =item C<RecallFound>
2031
2032 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2033 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2034 branchcode.
2035
2036 =item C<TransferredRecall>
2037
2038 This item has been transferred to this branch to fill a recall. The recall object is returned.
2039
2040 =back
2041
2042 C<$iteminformation> is a reference-to-hash, giving information about the
2043 returned item from the issues table.
2044
2045 C<$borrower> is a reference-to-hash, giving information about the
2046 patron who last borrowed the book.
2047
2048 =cut
2049
2050 sub AddReturn {
2051     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2052
2053     if ($branch and not Koha::Libraries->find($branch)) {
2054         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2055         undef $branch;
2056     }
2057     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2058     my $return_date_specified = !!$return_date;
2059     $return_date //= dt_from_string();
2060     my $messages;
2061     my $patron;
2062     my $doreturn       = 1;
2063     my $validTransfer = 1;
2064     my $stat_type = 'return';
2065
2066     # get information on item
2067     my $item = Koha::Items->find({ barcode => $barcode });
2068     unless ($item) {
2069         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2070     }
2071
2072     my $itemnumber = $item->itemnumber;
2073     my $itemtype = $item->effective_itemtype;
2074
2075     my $issue  = $item->checkout;
2076     if ( $issue ) {
2077         $patron = $issue->patron
2078             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2079                 . Dumper($issue->unblessed) . "\n";
2080     } else {
2081         $messages->{'NotIssued'} = $barcode;
2082         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2083
2084         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2085         $doreturn = 0;
2086         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2087         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2088         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2089            $messages->{'LocalUse'} = 1;
2090            $stat_type = 'localuse';
2091         }
2092     }
2093
2094         # full item data, but no borrowernumber or checkout info (no issue)
2095     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2096         # get the proper branch to which to return the item
2097     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2098         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2099     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2100
2101     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2102     my $patron_unblessed = $patron ? $patron->unblessed : {};
2103
2104     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2105     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2106     if ($update_loc_rules) {
2107         if (defined $update_loc_rules->{_ALL_}) {
2108             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2109             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2110             if (
2111                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2112                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2113                ) {
2114                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2115                 $item->location($update_loc_rules->{_ALL_})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2116             }
2117         }
2118         else {
2119             foreach my $key ( keys %$update_loc_rules ) {
2120                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2121                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2122                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2123                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2124                     $item->location($update_loc_rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2125                     last;
2126                 }
2127             }
2128         }
2129     }
2130
2131     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2132     if ($yaml) {
2133         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2134         my $rules;
2135         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2136         if ($@) {
2137             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2138         }
2139         else {
2140             foreach my $key ( keys %$rules ) {
2141                 if ( $item->notforloan eq $key ) {
2142                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2143                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2144                     last;
2145                 }
2146             }
2147         }
2148     }
2149
2150     # check if the return is allowed at this branch
2151     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2152     unless ($returnallowed){
2153         $messages->{'Wrongbranch'} = {
2154             Wrongbranch => $branch,
2155             Rightbranch => $message
2156         };
2157         $doreturn = 0;
2158         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2159         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2160         return ( $doreturn, $messages, $issue, $patron_unblessed);
2161     }
2162
2163     if ( $item->withdrawn ) { # book has been cancelled
2164         $messages->{'withdrawn'} = 1;
2165         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2166     }
2167
2168     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2169         $doreturn = 0;
2170     }
2171
2172     # case of a return of document (deal with issues and holdingbranch)
2173     if ($doreturn) {
2174         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2175         $patron or warn "AddReturn without current borrower";
2176
2177         if ($patron) {
2178             eval {
2179                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2180             };
2181             unless ( $@ ) {
2182                 if (
2183                     (
2184                         C4::Context->preference('CalculateFinesOnReturn')
2185                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2186                     )
2187                     && !$item->itemlost
2188                   )
2189                 {
2190                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2191                 }
2192             } else {
2193                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2194
2195                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2196                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2197
2198                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2199             }
2200
2201             # FIXME is the "= 1" right?  This could be the borrower hash.
2202             $messages->{'WasReturned'} = 1;
2203
2204         } else {
2205             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2206         }
2207     }
2208
2209     # the holdingbranch is updated if the document is returned to another location.
2210     # this is always done regardless of whether the item was on loan or not
2211     if ($item->holdingbranch ne $branch) {
2212         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2213     }
2214
2215     my $item_was_lost = $item->itemlost;
2216     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2217     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2218
2219     # fix up the accounts.....
2220     if ($item_was_lost) {
2221         $messages->{'WasLost'} = 1;
2222         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2223             my @object_messages = @{ $updated_item->object_messages };
2224             for my $message (@object_messages) {
2225                 $messages->{'LostItemFeeRefunded'} = 1
2226                   if $message->message eq 'lost_refunded';
2227                 $messages->{'LostItemFeeRestored'} = 1
2228                   if $message->message eq 'lost_restored';
2229
2230                 if ( $message->message eq 'lost_charge' ) {
2231                     $issue //= Koha::Old::Checkouts->search(
2232                         { itemnumber => $item->itemnumber },
2233                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2234                     )->single;
2235                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2236                         my $patron = $issue->patron;
2237                         $patron_unblessed = $patron->unblessed;
2238                     }
2239                     _CalculateAndUpdateFine(
2240                         {
2241                             issue       => $issue,
2242                             item        => $item->unblessed,
2243                             borrower    => $patron_unblessed,
2244                             return_date => $return_date
2245                         }
2246                     );
2247                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2248                         $item->itemnumber, undef, 'RETURNED' );
2249                     $messages->{'LostItemFeeCharged'} = 1;
2250                 }
2251             }
2252         }
2253     }
2254
2255     # check if we have a transfer for this document
2256     my $transfer = $item->get_transfer;
2257
2258     # if we have a transfer to complete, we update the line of transfers with the datearrived
2259     if ($transfer) {
2260         $validTransfer = 0;
2261         if ( $transfer->in_transit ) {
2262             if ( $transfer->tobranch eq $branch ) {
2263                 $transfer->receive;
2264                 $messages->{'TransferArrived'} = $transfer->frombranch;
2265                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2266                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2267             }
2268             else {
2269                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2270                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2271                 $messages->{'TransferTrigger'}   = $transfer->reason;
2272             }
2273         }
2274         else {
2275             if ( $transfer->tobranch eq $branch ) {
2276                 $transfer->receive;
2277                 $messages->{'TransferArrived'} = $transfer->frombranch;
2278                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2279                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2280             }
2281             else {
2282                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2283                 $messages->{'TransferTrigger'} = $transfer->reason;
2284             }
2285         }
2286     }
2287
2288     # fix up the overdues in accounts...
2289     if ($borrowernumber) {
2290         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2291         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2292
2293         if ( $issue and $issue->is_overdue($return_date) ) {
2294         # fix fine days
2295             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2296             if ($reminder){
2297                 $messages->{'PrevDebarred'} = $debardate;
2298             } else {
2299                 $messages->{'Debarred'} = $debardate if $debardate;
2300             }
2301         # there's no overdue on the item but borrower had been previously debarred
2302         } elsif ( $issue->date_due and $patron->debarred ) {
2303              if ( $patron->debarred eq "9999-12-31") {
2304                 $messages->{'ForeverDebarred'} = $patron->debarred;
2305              } else {
2306                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2307                   $borrower_debar_dt->truncate(to => 'day');
2308                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2309                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2310                       $messages->{'PrevDebarred'} = $patron->debarred;
2311                   }
2312              }
2313         }
2314     }
2315
2316     # find recalls...
2317     if ( C4::Context->preference('UseRecalls') ) {
2318         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2319         my $recall = undef;
2320         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2321         if ( defined $recall ) {
2322             $messages->{RecallFound} = $recall;
2323             if ( $recall->pickup_library_id ne $branch ) {
2324                 $messages->{RecallNeedsTransfer} = $branch;
2325             }
2326         }
2327     }
2328
2329     # find reserves.....
2330     # launch the Checkreserves routine to find any holds
2331     my ($resfound, $resrec);
2332     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2333     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2334     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2335     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2336         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2337         $resfound = 'Reserved';
2338         $resrec = $hold->unblessed;
2339     }
2340     if ($resfound) {
2341           $resrec->{'ResFound'} = $resfound;
2342         $messages->{'ResFound'} = $resrec;
2343     }
2344
2345     # Record the fact that this book was returned.
2346     C4::Stats::UpdateStats({
2347         branch         => $branch,
2348         type           => $stat_type,
2349         itemnumber     => $itemnumber,
2350         itemtype       => $itemtype,
2351         location       => $item->location,
2352         borrowernumber => $borrowernumber,
2353         ccode          => $item->ccode,
2354     });
2355
2356     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2357     if ( $patron ) {
2358         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2359         my %conditions = (
2360             branchcode   => $branch,
2361             categorycode => $patron->categorycode,
2362             item_type    => $itemtype,
2363             notification => 'CHECKIN',
2364         );
2365         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2366             SendCirculationAlert({
2367                 type     => 'CHECKIN',
2368                 item     => $item->unblessed,
2369                 borrower => $patron->unblessed,
2370                 branch   => $branch,
2371                 issue    => $issue
2372             });
2373         }
2374
2375         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2376             if C4::Context->preference("ReturnLog");
2377         }
2378
2379     # Check if this item belongs to a biblio record that is attached to an
2380     # ILL request, if it is we need to update the ILL request's status
2381     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2382         my $request = Koha::Illrequests->find(
2383             { biblio_id => $item->biblio->biblionumber }
2384         );
2385         $request->status('RET') if $request;
2386     }
2387
2388     if ( C4::Context->preference('UseRecalls') ) {
2389         # all recalls that have triggered a transfer will have an allocated itemnumber
2390         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2391         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2392             $messages->{TransferredRecall} = $transfer_recall;
2393         }
2394     }
2395
2396     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2397     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2398         && ( $doreturn or $messages->{'NotIssued'} )
2399         and !$resfound
2400         and ( $branch ne $returnbranch )
2401         and not $messages->{'WrongTransfer'}
2402         and not $messages->{'WasTransfered'}
2403         and not $messages->{TransferredRecall}
2404         and not $messages->{RecallNeedsTransfer} )
2405     {
2406         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2407         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2408             (C4::Context->preference("UseBranchTransferLimits") and
2409              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2410            )) {
2411             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2412             $messages->{'WasTransfered'} = $returnbranch;
2413             $messages->{'TransferTrigger'} = $transfer_trigger;
2414         } else {
2415             $messages->{'NeedsTransfer'} = $returnbranch;
2416             $messages->{'TransferTrigger'} = $transfer_trigger;
2417         }
2418     }
2419
2420     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2421         my $claims = Koha::Checkouts::ReturnClaims->search(
2422            {
2423                itemnumber => $item->id,
2424                resolution => undef,
2425            }
2426         );
2427
2428         if ( $claims->count ) {
2429             $messages->{ReturnClaims} = $claims;
2430         }
2431     }
2432
2433     # Check for bundle status
2434     if ( $item->in_bundle ) {
2435         my $host = $item->bundle_host;
2436         $messages->{InBundle} = $host;
2437     }
2438
2439     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2440     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2441
2442     if ( $doreturn and $issue ) {
2443         my $checkin = Koha::Old::Checkouts->find($issue->id);
2444
2445         Koha::Plugins->call('after_circ_action', {
2446             action  => 'checkin',
2447             payload => {
2448                 checkout=> $checkin
2449             }
2450         });
2451
2452         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2453             {
2454                 biblio_ids => [ $item->biblionumber ]
2455             }
2456         ) if C4::Context->preference('RealTimeHoldsQueue');
2457     }
2458
2459     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2460 }
2461
2462 =head2 MarkIssueReturned
2463
2464   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2465
2466 Unconditionally marks an issue as being returned by
2467 moving the C<issues> row to C<old_issues> and
2468 setting C<returndate> to the current date.
2469
2470 if C<$returndate> is specified (in iso format), it is used as the date
2471 of the return.
2472
2473 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2474 the old_issue is immediately anonymised
2475
2476 Ideally, this function would be internal to C<C4::Circulation>,
2477 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2478 and offline_circ/process_koc.pl.
2479
2480 The last optional parameter allos passing skip_record_index to the item store call.
2481
2482 =cut
2483
2484 sub MarkIssueReturned {
2485     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2486
2487     # Retrieve the issue
2488     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2489
2490     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2491
2492     my $issue_id = $issue->issue_id;
2493
2494     my $schema = Koha::Database->schema;
2495
2496     # FIXME Improve the return value and handle it from callers
2497     $schema->txn_do(sub {
2498
2499         my $patron = Koha::Patrons->find( $borrowernumber );
2500
2501         # Update the returndate value
2502         if ( $returndate ) {
2503             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2504         }
2505         else {
2506             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2507         }
2508
2509         # Create the old_issues entry
2510         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2511
2512         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2513         if ( $privacy && $privacy == 2) {
2514             $old_checkout->anonymize;
2515         }
2516
2517         # And finally delete the issue
2518         $issue->delete;
2519
2520         $issue->item->onloan(undef)->store(
2521             {   log_action        => 0,
2522                 skip_record_index => $params->{skip_record_index},
2523                 skip_holds_queue  => $params->{skip_holds_queue}
2524             }
2525         );
2526
2527         if ( C4::Context->preference('StoreLastBorrower') ) {
2528             my $item = Koha::Items->find( $itemnumber );
2529             $item->last_returned_by( $patron );
2530         }
2531
2532         # Remove any OVERDUES related debarment if the borrower has no overdues
2533         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2534           && $patron->debarred
2535           && !$patron->has_overdues
2536           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2537         ) {
2538             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2539         }
2540
2541     });
2542
2543     return $issue_id;
2544 }
2545
2546 =head2 _debar_user_on_return
2547
2548     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2549
2550 C<$borrower> borrower hashref
2551
2552 C<$item> item hashref
2553
2554 C<$datedue> date due DateTime object
2555
2556 C<$returndate> DateTime object representing the return time
2557
2558 Internal function, called only by AddReturn that calculates and updates
2559  the user fine days, and debars them if necessary.
2560
2561 Should only be called for overdue returns
2562
2563 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2564 to ease testing.
2565
2566 =cut
2567
2568 sub _calculate_new_debar_dt {
2569     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2570
2571     my $branchcode = _GetCircControlBranch( $item, $borrower );
2572     my $circcontrol = C4::Context->preference('CircControl');
2573     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2574         {   categorycode => $borrower->{categorycode},
2575             itemtype     => $item->{itype},
2576             branchcode   => $branchcode,
2577             rules => [
2578                 'finedays',
2579                 'lengthunit',
2580                 'firstremind',
2581                 'maxsuspensiondays',
2582                 'suspension_chargeperiod',
2583             ]
2584         }
2585     );
2586     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2587     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2588     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2589
2590     return unless $finedays;
2591
2592     # finedays is in days, so hourly loans must multiply by 24
2593     # thus 1 hour late equals 1 day suspension * finedays rate
2594     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2595
2596     # grace period is measured in the same units as the loan
2597     my $grace =
2598       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2599
2600     my $deltadays = DateTime::Duration->new(
2601         days => $chargeable_units
2602     );
2603
2604     if ( $deltadays->subtract($grace)->is_positive() ) {
2605         my $suspension_days = $deltadays * $finedays;
2606
2607         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2608             # No need to / 1 and do not consider / 0
2609             $suspension_days = DateTime::Duration->new(
2610                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2611             );
2612         }
2613
2614         # If the max suspension days is < than the suspension days
2615         # the suspension days is limited to this maximum period.
2616         my $max_sd = $issuing_rule->{maxsuspensiondays};
2617         if ( defined $max_sd && $max_sd ne '' ) {
2618             $max_sd = DateTime::Duration->new( days => $max_sd );
2619             $suspension_days = $max_sd
2620               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2621         }
2622
2623         my ( $has_been_extended );
2624         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2625             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2626             if ( $debarment ) {
2627                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2628                 $has_been_extended = 1;
2629             }
2630         }
2631
2632         my $new_debar_dt;
2633         # Use the calendar or not to calculate the debarment date
2634         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2635             my $calendar = Koha::Calendar->new(
2636                 branchcode => $branchcode,
2637                 days_mode  => 'Calendar'
2638             );
2639             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2640         }
2641         else {
2642             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2643         }
2644         return $new_debar_dt;
2645     }
2646     return;
2647 }
2648
2649 sub _debar_user_on_return {
2650     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2651
2652     $return_date //= dt_from_string();
2653
2654     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2655
2656     return unless $new_debar_dt;
2657
2658     Koha::Patron::Debarments::AddUniqueDebarment({
2659         borrowernumber => $borrower->{borrowernumber},
2660         expiration     => $new_debar_dt->ymd(),
2661         type           => 'SUSPENSION',
2662     });
2663     # if borrower was already debarred but does not get an extra debarment
2664     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2665     my ($new_debarment_str, $is_a_reminder);
2666     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2667         $is_a_reminder = 1;
2668         $new_debarment_str = $borrower->{debarred};
2669     } else {
2670         $new_debarment_str = $new_debar_dt->ymd();
2671     }
2672     # FIXME Should return a DateTime object
2673     return $new_debarment_str, $is_a_reminder;
2674 }
2675
2676 =head2 _FixOverduesOnReturn
2677
2678    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2679
2680 C<$borrowernumber> borrowernumber
2681
2682 C<$itemnumber> itemnumber
2683
2684 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2685
2686 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2687
2688 Internal function
2689
2690 =cut
2691
2692 sub _FixOverduesOnReturn {
2693     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2694     unless( $borrowernumber ) {
2695         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2696         return;
2697     }
2698     unless( $item ) {
2699         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2700         return;
2701     }
2702     unless( $status ) {
2703         warn "_FixOverduesOnReturn() not supplied valid status";
2704         return;
2705     }
2706
2707     my $schema = Koha::Database->schema;
2708
2709     my $result = $schema->txn_do(
2710         sub {
2711             # check for overdue fine
2712             my $accountlines = Koha::Account::Lines->search(
2713                 {
2714                     borrowernumber  => $borrowernumber,
2715                     itemnumber      => $item,
2716                     debit_type_code => 'OVERDUE',
2717                     status          => 'UNRETURNED'
2718                 }
2719             );
2720             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2721
2722             my $accountline = $accountlines->next;
2723             my $payments = $accountline->credits;
2724
2725             my $amountoutstanding = $accountline->amountoutstanding;
2726             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2727                 $accountline->delete;
2728                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2729             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2730                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2731                 my $credit = $account->add_credit(
2732                     {
2733                         amount     => $amountoutstanding,
2734                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2735                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2736                         interface  => C4::Context->interface,
2737                         type       => 'FORGIVEN',
2738                         item_id    => $item
2739                     }
2740                 );
2741
2742                 $credit->apply({ debits => [ $accountline ] });
2743
2744                 if (C4::Context->preference("FinesLog")) {
2745                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2746                 }
2747             }
2748
2749             $accountline->status($status);
2750             return $accountline->store();
2751         }
2752     );
2753
2754     return $result;
2755 }
2756
2757 =head2 _GetCircControlBranch
2758
2759    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2760
2761 Internal function :
2762
2763 Return the library code to be used to determine which circulation
2764 policy applies to a transaction.  Looks up the CircControl and
2765 HomeOrHoldingBranch system preferences.
2766
2767 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2768
2769 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2770
2771 =cut
2772
2773 sub _GetCircControlBranch {
2774     my ($item, $borrower) = @_;
2775     my $circcontrol = C4::Context->preference('CircControl');
2776     my $branch;
2777
2778     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2779         $branch= C4::Context->userenv->{'branch'};
2780     } elsif ($circcontrol eq 'PatronLibrary') {
2781         $branch=$borrower->{branchcode};
2782     } else {
2783         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2784         $branch = $item->{$branchfield};
2785         # default to item home branch if holdingbranch is used
2786         # and is not defined
2787         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2788             $branch = $item->{homebranch};
2789         }
2790     }
2791     return $branch;
2792 }
2793
2794 =head2 GetOpenIssue
2795
2796   $issue = GetOpenIssue( $itemnumber );
2797
2798 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2799
2800 C<$itemnumber> is the item's itemnumber
2801
2802 Returns a hashref
2803
2804 =cut
2805
2806 sub GetOpenIssue {
2807   my ( $itemnumber ) = @_;
2808   return unless $itemnumber;
2809   my $dbh = C4::Context->dbh;
2810   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2811   $sth->execute( $itemnumber );
2812   return $sth->fetchrow_hashref();
2813
2814 }
2815
2816 =head2 GetUpcomingDueIssues
2817
2818   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2819
2820 =cut
2821
2822 sub GetUpcomingDueIssues {
2823     my $params = shift;
2824
2825     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2826     my $dbh = C4::Context->dbh;
2827     my $statement;
2828     $statement = q{
2829         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2830         FROM issues
2831         LEFT JOIN items USING (itemnumber)
2832         LEFT JOIN branches ON branches.branchcode =
2833     };
2834     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2835     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2836     my @bind_parameters = ( $params->{'days_in_advance'} );
2837
2838     my $sth = $dbh->prepare( $statement );
2839     $sth->execute( @bind_parameters );
2840     my $upcoming_dues = $sth->fetchall_arrayref({});
2841
2842     return $upcoming_dues;
2843 }
2844
2845 =head2 CanBookBeRenewed
2846
2847   ($ok,$error,$info) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2848
2849 Find out whether a borrowed item may be renewed.
2850
2851 C<$borrowernumber> is the borrower number of the patron who currently
2852 has the item on loan.
2853
2854 C<$itemnumber> is the number of the item to renew.
2855
2856 C<$override_limit>, if supplied with a true value, causes
2857 the limit on the number of times that the loan can be renewed
2858 (as controlled by the item type) to be ignored. Overriding also allows
2859 to renew sooner than "No renewal before" and to manually renew loans
2860 that are automatically renewed.
2861
2862 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2863 item must currently be on loan to the specified borrower; renewals
2864 must be allowed for the item's type; and the borrower must not have
2865 already renewed the loan.
2866     $error will contain the reason the renewal can not proceed
2867     $info will contain a hash of additional info
2868       currently 'soonest_renew_date' if error is 'too soon'
2869
2870 =cut
2871
2872 sub CanBookBeRenewed {
2873     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2874
2875     my $auto_renew = "no";
2876     my $soonest;
2877
2878     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2879     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2880     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2881     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2882
2883     my $patron = $issue->patron or return;
2884
2885     # override_limit will override anything else except on_reserve
2886     unless ( $override_limit ){
2887         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2888         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2889             {
2890                 categorycode => $patron->categorycode,
2891                 itemtype     => $item->effective_itemtype,
2892                 branchcode   => $branchcode,
2893                 rules => [
2894                     'renewalsallowed',
2895                     'lengthunit',
2896                     'unseen_renewals_allowed'
2897                 ]
2898             }
2899         );
2900
2901         return ( 0, "too_many" )
2902           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
2903
2904         return ( 0, "too_unseen" )
2905           if C4::Context->preference('UnseenRenewals') &&
2906             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
2907             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2908
2909         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2910         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2911         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2912         my $restricted  = $patron->is_debarred;
2913         my $hasoverdues = $patron->has_overdues;
2914
2915         if ( $restricted and $restrictionblockrenewing ) {
2916             return ( 0, 'restriction');
2917         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2918             return ( 0, 'overdue');
2919         }
2920
2921         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
2922             patron     => $patron,
2923             item       => $item,
2924             branchcode => $branchcode,
2925             issue      => $issue
2926         });
2927         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
2928         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2929         # extra notices being sent. Cron also implies no override
2930         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2931         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2932         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2933     }
2934
2935     if ( C4::Context->preference('UseRecalls') ) {
2936         my $recall = undef;
2937         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2938         if ( defined $recall ) {
2939             if ( $recall->item_level ) {
2940                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2941                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
2942             } else {
2943                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2944                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2945             }
2946         }
2947     }
2948
2949     # Note: possible_reserves will contain all title level holds on this bib and item level
2950     # holds on the checked out item
2951     my ( $resfound, $resrec, $possible_reserves ) = C4::Reserves::CheckReserves($itemnumber);
2952
2953     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2954     if ( $resfound && $resrec->{non_priority} ) {
2955         $resfound = Koha::Holds->search(
2956             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2957           ->count > 0;
2958     }
2959
2960
2961
2962     # This item can fill one or more unfilled reserve, can those unfilled reserves
2963     # all be filled by other available items?
2964     if ( $resfound
2965         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2966     {
2967         my $item_holds = Koha::Holds->search( { itemnumber => $itemnumber, found => undef } )->count();
2968         if ($item_holds) {
2969             # There is an item level hold on this item, no other item can fill the hold
2970             $resfound = 1;
2971         }
2972         else {
2973
2974             # Get all other items that could possibly fill reserves
2975             # FIXME We could join reserves (or more tables) here to eliminate some checks later
2976             my $items = Koha::Items->search({
2977                 biblionumber => $resrec->{biblionumber},
2978                 onloan       => undef,
2979                 notforloan   => 0,
2980                 -not         => { itemnumber => $itemnumber }
2981             });
2982             my $item_count = $items->count();
2983
2984             # Get all other reserves that could have been filled by this item
2985             my @borrowernumbers = map { $_->{borrowernumber} } @$possible_reserves;
2986             # Note: fetching the patrons in this manner means that a patron with 2 holds will
2987             # not block renewal if one reserve can be satisfied i.e. each patron is checked once
2988             my $patrons = Koha::Patrons->search({
2989                 borrowernumber => { -in => \@borrowernumbers }
2990             });
2991             my $patron_count = $patrons->count();
2992
2993             return ( 0, "on_reserve" ) if ($patron_count > $item_count);
2994             # We cannot possibly fill all reserves if we don't have enough items
2995
2996             # If we can fill each hold that has been found with the available items on the record
2997             # then the patron can renew. If we cannot, they cannot renew.
2998             # FIXME This code does not check whether the item we are renewing can fill
2999             # any of the existing reserves.
3000             my $reservable = 0;
3001             my %matched_items;
3002             my $seen = 0;
3003             PATRON: while ( my $patron = $patrons->next ) {
3004                 # If there is a reserve that cannot be filled we are done
3005                 return ( 0, "on_reserve" ) if ( $seen > $reservable );
3006                 my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
3007                 while ( my $other_item = $items->next ) {
3008                     next if defined $matched_items{$other_item->itemnumber};
3009                     next if IsItemOnHoldAndFound( $other_item->itemnumber );
3010                     next unless IsAvailableForItemLevelRequest($other_item, $patron, undef, $items_any_available);
3011                     next unless CanItemBeReserved($patron,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
3012                     # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
3013                     # CanItemBeReserved checks 'rules' and 'policies' which means
3014                     # items will fill holds at checkin that are rejected here
3015                     $reservable++;
3016                     if ($reservable >= $patron_count) {
3017                         $resfound = 0;
3018                         last PATRON;
3019                     }
3020                     $matched_items{$other_item->itemnumber} = 1;
3021                     last;
3022                 }
3023                 $items->reset;
3024                 $seen++;
3025             }
3026         }
3027     }
3028
3029     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
3030     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
3031     $soonest = GetSoonestRenewDate($borrowernumber, $itemnumber);
3032     if ( $soonest > dt_from_string() ){
3033         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
3034     }
3035
3036     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
3037
3038     return ( 1, undef );
3039 }
3040
3041 =head2 AddRenewal
3042
3043   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
3044
3045 Renews a loan.
3046
3047 C<$borrowernumber> is the borrower number of the patron who currently
3048 has the item.
3049
3050 C<$itemnumber> is the number of the item to renew.
3051
3052 C<$branch> is the library where the renewal took place (if any).
3053            The library that controls the circ policies for the renewal is retrieved from the issues record.
3054
3055 C<$datedue> can be a DateTime object used to set the due date.
3056
3057 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3058 this parameter is not supplied, lastreneweddate is set to the current date.
3059
3060 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3061 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3062 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3063 syspref)
3064
3065 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3066 from the book's item type.
3067
3068 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3069 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3070 fallback to a true value
3071
3072 =cut
3073
3074 sub AddRenewal {
3075     my $borrowernumber  = shift;
3076     my $itemnumber      = shift or return;
3077     my $branch          = shift;
3078     my $datedue         = shift;
3079     my $lastreneweddate = shift || dt_from_string();
3080     my $skipfinecalc    = shift;
3081     my $seen            = shift;
3082
3083     # Fallback on a 'seen' renewal
3084     $seen = defined $seen && $seen == 0 ? 0 : 1;
3085
3086     my $item_object   = Koha::Items->find($itemnumber) or return;
3087     my $biblio = $item_object->biblio;
3088     my $issue  = $item_object->checkout;
3089     my $item_unblessed = $item_object->unblessed;
3090
3091     my $dbh = C4::Context->dbh;
3092
3093     return unless $issue;
3094
3095     $borrowernumber ||= $issue->borrowernumber;
3096
3097     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3098         $datedue = dt_from_string($datedue, 'sql');
3099     }
3100
3101     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3102     my $patron_unblessed = $patron->unblessed;
3103
3104     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3105
3106     my $schema = Koha::Database->schema;
3107     $schema->txn_do(sub{
3108
3109         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3110             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3111         }
3112         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3113
3114         # If the due date wasn't specified, calculate it by adding the
3115         # book's loan length to today's date or the current due date
3116         # based on the value of the RenewalPeriodBase syspref.
3117         my $itemtype = $item_object->effective_itemtype;
3118         unless ($datedue) {
3119
3120             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3121                                             dt_from_string( $issue->date_due, 'sql' ) :
3122                                             dt_from_string();
3123             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3124         }
3125
3126         my $fees = Koha::Charges::Fees->new(
3127             {
3128                 patron    => $patron,
3129                 library   => $circ_library,
3130                 item      => $item_object,
3131                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3132                 to_date   => dt_from_string($datedue),
3133             }
3134         );
3135
3136         # Increment the unseen renewals, if appropriate
3137         # We only do so if the syspref is enabled and
3138         # a maximum value has been set in the circ rules
3139         my $unseen_renewals = $issue->unseen_renewals;
3140         if (C4::Context->preference('UnseenRenewals')) {
3141             my $rule = Koha::CirculationRules->get_effective_rule(
3142                 {   categorycode => $patron->categorycode,
3143                     itemtype     => $item_object->effective_itemtype,
3144                     branchcode   => $circ_library->branchcode,
3145                     rule_name    => 'unseen_renewals_allowed'
3146                 }
3147             );
3148             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3149                 $unseen_renewals++;
3150             } else {
3151                 # If the renewal is seen, unseen should revert to 0
3152                 $unseen_renewals = 0;
3153             }
3154         }
3155
3156         # Update the issues record to have the new due date, and a new count
3157         # of how many times it has been renewed.
3158         my $renews = ( $issue->renewals_count || 0 ) + 1;
3159         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3160
3161         eval{
3162             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3163         };
3164         if( $sth->err ){
3165             Koha::Exceptions::Checkout::FailedRenewal->throw(
3166                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3167             );
3168         }
3169
3170         # Update the renewal count on the item, and tell zebra to reindex
3171         $renews = ( $item_object->renewals || 0 ) + 1;
3172         $item_object->renewals($renews);
3173         $item_object->onloan($datedue);
3174         $item_object->store({ log_action => 0 });
3175
3176         # Charge a new rental fee, if applicable
3177         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3178         if ( $charge > 0 ) {
3179             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3180         }
3181
3182         # Charge a new accumulate rental fee, if applicable
3183         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3184         if ( $itemtype_object ) {
3185             my $accumulate_charge = $fees->accumulate_rentalcharge();
3186             if ( $accumulate_charge > 0 ) {
3187                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3188             }
3189             $charge += $accumulate_charge;
3190         }
3191
3192         # Send a renewal slip according to checkout alert preferencei
3193         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3194             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3195             my %conditions        = (
3196                 branchcode   => $branch,
3197                 categorycode => $patron->categorycode,
3198                 item_type    => $itemtype,
3199                 notification => 'CHECKOUT',
3200             );
3201             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3202                 SendCirculationAlert(
3203                     {
3204                         type     => 'RENEWAL',
3205                         item     => $item_unblessed,
3206                         borrower => $patron->unblessed,
3207                         branch   => $branch,
3208                     }
3209                 );
3210             }
3211         }
3212
3213         # Remove any OVERDUES related debarment if the borrower has no overdues
3214         if ( $patron
3215           && $patron->is_debarred
3216           && ! $patron->has_overdues
3217           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3218         ) {
3219             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3220         }
3221
3222         # Add renewal record
3223         my $renewal = Koha::Checkouts::Renewal->new(
3224             {
3225                 checkout_id => $issue->issue_id,
3226                 renewer_id  => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3227                 seen        => $seen,
3228                 interface   => C4::Context->interface
3229             }
3230         )->store();
3231
3232         # Add the renewal to stats
3233         C4::Stats::UpdateStats(
3234             {
3235                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3236                 type           => 'renew',
3237                 amount         => $charge,
3238                 itemnumber     => $itemnumber,
3239                 itemtype       => $itemtype,
3240                 location       => $item_object->location,
3241                 borrowernumber => $borrowernumber,
3242                 ccode          => $item_object->ccode,
3243             }
3244         );
3245
3246         #Log the renewal
3247         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3248
3249         Koha::Plugins->call('after_circ_action', {
3250             action  => 'renewal',
3251             payload => {
3252                 checkout  => $issue->get_from_storage
3253             }
3254         });
3255     });
3256
3257     return $datedue;
3258 }
3259
3260 sub GetRenewCount {
3261     # check renewal status
3262     my ( $bornum, $itemno ) = @_;
3263     my $dbh           = C4::Context->dbh;
3264     my $renewcount    = 0;
3265     my $unseencount    = 0;
3266     my $renewsallowed = 0;
3267     my $unseenallowed = 0;
3268     my $renewsleft    = 0;
3269     my $unseenleft    = 0;
3270
3271     my $patron = Koha::Patrons->find( $bornum );
3272     my $item   = Koha::Items->find($itemno);
3273
3274     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3275
3276     # Look in the issues table for this item, lent to this borrower,
3277     # and not yet returned.
3278
3279     # FIXME - I think this function could be redone to use only one SQL call.
3280     my $sth = $dbh->prepare(
3281         "select * from issues
3282                                 where (borrowernumber = ?)
3283                                 and (itemnumber = ?)"
3284     );
3285     $sth->execute( $bornum, $itemno );
3286     my $data = $sth->fetchrow_hashref;
3287     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3288     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3289     # $item and $borrower should be calculated
3290     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3291
3292     my $rules = Koha::CirculationRules->get_effective_rules(
3293         {
3294             categorycode => $patron->categorycode,
3295             itemtype     => $item->effective_itemtype,
3296             branchcode   => $branchcode,
3297             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3298         }
3299     );
3300     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3301     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3302         $rules->{unseen_renewals_allowed} :
3303         0;
3304     $renewsleft    = $renewsallowed - $renewcount;
3305     $unseenleft    = $unseenallowed - $unseencount;
3306     if($renewsleft < 0){ $renewsleft = 0; }
3307     if($unseenleft < 0){ $unseenleft = 0; }
3308     return (
3309         $renewcount,
3310         $renewsallowed,
3311         $renewsleft,
3312         $unseencount,
3313         $unseenallowed,
3314         $unseenleft
3315     );
3316 }
3317
3318 =head2 GetSoonestRenewDate
3319
3320   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3321
3322 Find out the soonest possible renew date of a borrowed item.
3323
3324 C<$borrowernumber> is the borrower number of the patron who currently
3325 has the item on loan.
3326
3327 C<$itemnumber> is the number of the item to renew.
3328
3329 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3330 renew date, based on the value "No renewal before" of the applicable
3331 issuing rule. Returns the current date if the item can already be
3332 renewed, and returns undefined if the borrower, loan, or item
3333 cannot be found.
3334
3335 =cut
3336
3337 sub GetSoonestRenewDate {
3338     my ( $borrowernumber, $itemnumber ) = @_;
3339
3340     my $dbh = C4::Context->dbh;
3341
3342     my $item      = Koha::Items->find($itemnumber)      or return;
3343     my $itemissue = $item->checkout or return;
3344
3345     $borrowernumber ||= $itemissue->borrowernumber;
3346     my $patron = Koha::Patrons->find( $borrowernumber )
3347       or return;
3348
3349     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3350     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3351         {   categorycode => $patron->categorycode,
3352             itemtype     => $item->effective_itemtype,
3353             branchcode   => $branchcode,
3354             rules => [
3355                 'norenewalbefore',
3356                 'lengthunit',
3357             ]
3358         }
3359     );
3360
3361     my $now = dt_from_string;
3362
3363     if ( defined $issuing_rule->{norenewalbefore}
3364         and $issuing_rule->{norenewalbefore} ne "" )
3365     {
3366         my $soonestrenewal =
3367           dt_from_string( $itemissue->date_due )->subtract(
3368             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3369
3370         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3371             and $issuing_rule->{lengthunit} eq 'days' )
3372         {
3373             $soonestrenewal->truncate( to => 'day' );
3374         }
3375         return $soonestrenewal if $now < $soonestrenewal;
3376     } elsif ( $itemissue->auto_renew && $patron->autorenew_checkouts ) {
3377         # Checkouts with auto-renewing fall back to due date
3378         my $soonestrenewal = dt_from_string( $itemissue->date_due );
3379         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3380             and $issuing_rule->{lengthunit} eq 'days' )
3381         {
3382             $soonestrenewal->truncate( to => 'day' );
3383         }
3384         return $soonestrenewal;
3385     }
3386     return $now;
3387 }
3388
3389 =head2 GetLatestAutoRenewDate
3390
3391   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3392
3393 Find out the latest possible auto renew date of a borrowed item.
3394
3395 C<$borrowernumber> is the borrower number of the patron who currently
3396 has the item on loan.
3397
3398 C<$itemnumber> is the number of the item to renew.
3399
3400 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3401 auto renew date, based on the value "No auto renewal after" and the "No auto
3402 renewal after (hard limit) of the applicable issuing rule.
3403 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3404 or item cannot be found.
3405
3406 =cut
3407
3408 sub GetLatestAutoRenewDate {
3409     my ( $borrowernumber, $itemnumber ) = @_;
3410
3411     my $dbh = C4::Context->dbh;
3412
3413     my $item      = Koha::Items->find($itemnumber)  or return;
3414     my $itemissue = $item->checkout                 or return;
3415
3416     $borrowernumber ||= $itemissue->borrowernumber;
3417     my $patron = Koha::Patrons->find( $borrowernumber )
3418       or return;
3419
3420     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3421     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3422         {
3423             categorycode => $patron->categorycode,
3424             itemtype     => $item->effective_itemtype,
3425             branchcode   => $branchcode,
3426             rules => [
3427                 'no_auto_renewal_after',
3428                 'no_auto_renewal_after_hard_limit',
3429                 'lengthunit',
3430             ]
3431         }
3432     );
3433
3434     return unless $circulation_rules;
3435     return
3436       if ( not $circulation_rules->{no_auto_renewal_after}
3437             or $circulation_rules->{no_auto_renewal_after} eq '' )
3438       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3439              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3440
3441     my $maximum_renewal_date;
3442     if ( $circulation_rules->{no_auto_renewal_after} ) {
3443         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3444         $maximum_renewal_date->add(
3445             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3446         );
3447     }
3448
3449     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3450         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3451         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3452     }
3453     return $maximum_renewal_date;
3454 }
3455
3456
3457 =head2 GetIssuingCharges
3458
3459   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3460
3461 Calculate how much it would cost for a given patron to borrow a given
3462 item, including any applicable discounts.
3463
3464 C<$itemnumber> is the item number of item the patron wishes to borrow.
3465
3466 C<$borrowernumber> is the patron's borrower number.
3467
3468 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3469 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3470 if it's a video).
3471
3472 =cut
3473
3474 sub GetIssuingCharges {
3475
3476     # calculate charges due
3477     my ( $itemnumber, $borrowernumber ) = @_;
3478     my $charge = 0;
3479     my $dbh    = C4::Context->dbh;
3480     my $item_type;
3481
3482     # Get the book's item type and rental charge (via its biblioitem).
3483     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3484         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3485     $charge_query .= (C4::Context->preference('item-level_itypes'))
3486         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3487         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3488
3489     $charge_query .= ' WHERE items.itemnumber =?';
3490
3491     my $sth = $dbh->prepare($charge_query);
3492     $sth->execute($itemnumber);
3493     if ( my $item_data = $sth->fetchrow_hashref ) {
3494         $item_type = $item_data->{itemtype};
3495         $charge    = $item_data->{rentalcharge};
3496         if ($charge) {
3497             # FIXME This should follow CircControl
3498             my $branch = C4::Context::mybranch();
3499             my $patron = Koha::Patrons->find( $borrowernumber );
3500             my $discount = Koha::CirculationRules->get_effective_rule({
3501                 categorycode => $patron->categorycode,
3502                 branchcode   => $branch,
3503                 itemtype     => $item_type,
3504                 rule_name    => 'rentaldiscount'
3505             });
3506             if ($discount) {
3507                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3508             }
3509             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3510         }
3511     }
3512
3513     return ( $charge, $item_type );
3514 }
3515
3516 =head2 AddIssuingCharge
3517
3518   &AddIssuingCharge( $checkout, $charge, $type )
3519
3520 =cut
3521
3522 sub AddIssuingCharge {
3523     my ( $checkout, $charge, $type ) = @_;
3524
3525     # FIXME What if checkout does not exist?
3526
3527     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3528     my $accountline = $account->add_debit(
3529         {
3530             amount      => $charge,
3531             note        => undef,
3532             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3533             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3534             interface   => C4::Context->interface,
3535             type        => $type,
3536             item_id     => $checkout->itemnumber,
3537             issue_id    => $checkout->issue_id,
3538         }
3539     );
3540 }
3541
3542 =head2 GetTransfers
3543
3544   GetTransfers($itemnumber);
3545
3546 =cut
3547
3548 sub GetTransfers {
3549     my ($itemnumber) = @_;
3550
3551     my $dbh = C4::Context->dbh;
3552
3553     my $query = '
3554         SELECT datesent,
3555                frombranch,
3556                tobranch,
3557                branchtransfer_id,
3558                daterequested,
3559                reason
3560         FROM branchtransfers
3561         WHERE itemnumber = ?
3562           AND datearrived IS NULL
3563           AND datecancelled IS NULL
3564         ';
3565     my $sth = $dbh->prepare($query);
3566     $sth->execute($itemnumber);
3567     my @row = $sth->fetchrow_array();
3568     return @row;
3569 }
3570
3571 =head2 GetTransfersFromTo
3572
3573   @results = GetTransfersFromTo($frombranch,$tobranch);
3574
3575 Returns the list of pending transfers between $from and $to branch
3576
3577 =cut
3578
3579 sub GetTransfersFromTo {
3580     my ( $frombranch, $tobranch ) = @_;
3581     return unless ( $frombranch && $tobranch );
3582     my $dbh   = C4::Context->dbh;
3583     my $query = "
3584         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3585         FROM   branchtransfers
3586         WHERE  frombranch=?
3587           AND  tobranch=?
3588           AND datecancelled IS NULL
3589           AND datesent IS NOT NULL
3590           AND datearrived IS NULL
3591     ";
3592     my $sth = $dbh->prepare($query);
3593     $sth->execute( $frombranch, $tobranch );
3594     my @gettransfers;
3595
3596     while ( my $data = $sth->fetchrow_hashref ) {
3597         push @gettransfers, $data;
3598     }
3599     return (@gettransfers);
3600 }
3601
3602 =head2 SendCirculationAlert
3603
3604 Send out a C<check-in> or C<checkout> alert using the messaging system.
3605
3606 B<Parameters>:
3607
3608 =over 4
3609
3610 =item type
3611
3612 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3613
3614 =item item
3615
3616 Hashref of information about the item being checked in or out.
3617
3618 =item borrower
3619
3620 Hashref of information about the borrower of the item.
3621
3622 =item branch
3623
3624 The branchcode from where the checkout or check-in took place.
3625
3626 =back
3627
3628 B<Example>:
3629
3630     SendCirculationAlert({
3631         type     => 'CHECKOUT',
3632         item     => $item,
3633         borrower => $borrower,
3634         branch   => $branch,
3635     });
3636
3637 =cut
3638
3639 sub SendCirculationAlert {
3640     my ($opts) = @_;
3641     my ($type, $item, $borrower, $branch, $issue) =
3642         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3643     my %message_name = (
3644         CHECKIN  => 'Item_Check_in',
3645         CHECKOUT => 'Item_Checkout',
3646         RENEWAL  => 'Item_Checkout',
3647     );
3648     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3649         borrowernumber => $borrower->{borrowernumber},
3650         message_name   => $message_name{$type},
3651     });
3652
3653
3654     my $tables = {
3655         items => $item->{itemnumber},
3656         biblio      => $item->{biblionumber},
3657         biblioitems => $item->{biblionumber},
3658         borrowers   => $borrower,
3659         branches    => $branch,
3660     };
3661
3662     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3663     # See C4::Letters:: _parseletter_sth
3664     if( $type eq 'CHECKIN' ){
3665         $tables->{old_issues} = $issue->issue_id;
3666     } else {
3667         $tables->{issues} = $item->{itemnumber};
3668     }
3669
3670     my $schema = Koha::Database->new->schema;
3671     my @transports = keys %{ $borrower_preferences->{transports} };
3672
3673     # From the MySQL doc:
3674     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3675     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3676     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3677     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3678
3679     for my $mtt (@transports) {
3680         my $letter =  C4::Letters::GetPreparedLetter (
3681             module => 'circulation',
3682             letter_code => $type,
3683             branchcode => $branch,
3684             message_transport_type => $mtt,
3685             lang => $borrower->{lang},
3686             tables => $tables,
3687         ) or next;
3688
3689         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3690         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3691         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3692         unless ( $message ) {
3693             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3694             C4::Message->enqueue($letter, $borrower, $mtt);
3695         } else {
3696             $message->append($letter);
3697             $message->update;
3698         }
3699         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3700     }
3701
3702     return;
3703 }
3704
3705 =head2 updateWrongTransfer
3706
3707   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3708
3709 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3710
3711 =cut
3712
3713 sub updateWrongTransfer {
3714         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3715
3716     # first step: cancel the original transfer
3717     my $item = Koha::Items->find($itemNumber);
3718     my $transfer = $item->get_transfer;
3719     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3720
3721     # second step: create a new transfer to the right location
3722     my $new_transfer = $item->request_transfer(
3723         {
3724             to            => $transfer->to_library,
3725             reason        => $transfer->reason,
3726             comment       => $transfer->comments,
3727             ignore_limits => 1,
3728             enqueue       => 1
3729         }
3730     );
3731
3732     return $new_transfer;
3733 }
3734
3735 =head2 CalcDateDue
3736
3737 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3738
3739 this function calculates the due date given the start date and configured circulation rules,
3740 checking against the holidays calendar as per the daysmode circulation rule.
3741 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3742 C<$itemtype>  = itemtype code of item in question
3743 C<$branch>  = location whose calendar to use
3744 C<$borrower> = Borrower object
3745 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3746
3747 =cut
3748
3749 sub CalcDateDue {
3750     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3751
3752     $isrenewal ||= 0;
3753
3754     # loanlength now a href
3755     my $loanlength =
3756             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3757
3758     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3759             ? qq{renewalperiod}
3760             : qq{issuelength};
3761
3762     my $datedue;
3763     if ( $startdate ) {
3764         if (ref $startdate ne 'DateTime' ) {
3765             $datedue = dt_from_string($datedue);
3766         } else {
3767             $datedue = $startdate->clone;
3768         }
3769     } else {
3770         $datedue = dt_from_string()->truncate( to => 'minute' );
3771     }
3772
3773
3774     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3775         {
3776             categorycode => $borrower->{categorycode},
3777             itemtype     => $itemtype,
3778             branchcode   => $branch,
3779         }
3780     );
3781
3782     # calculate the datedue as normal
3783     if ( $daysmode eq 'Days' )
3784     {    # ignoring calendar
3785         if ( $loanlength->{lengthunit} eq 'hours' ) {
3786             $datedue->add( hours => $loanlength->{$length_key} );
3787         } else {    # days
3788             $datedue->add( days => $loanlength->{$length_key} );
3789             $datedue->set_hour(23);
3790             $datedue->set_minute(59);
3791         }
3792     } else {
3793         my $dur;
3794         if ($loanlength->{lengthunit} eq 'hours') {
3795             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3796         }
3797         else { # days
3798             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3799         }
3800         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3801         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3802         if ($loanlength->{lengthunit} eq 'days') {
3803             $datedue->set_hour(23);
3804             $datedue->set_minute(59);
3805         }
3806     }
3807
3808     # if Hard Due Dates are used, retrieve them and apply as necessary
3809     my ( $hardduedate, $hardduedatecompare ) =
3810       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3811     if ($hardduedate) {    # hardduedates are currently dates
3812         $hardduedate->truncate( to => 'minute' );
3813         $hardduedate->set_hour(23);
3814         $hardduedate->set_minute(59);
3815         my $cmp = DateTime->compare( $hardduedate, $datedue );
3816
3817 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3818 # if the calculated date is before the 'after' Hard Due Date (floor), override
3819 # if the hard due date is set to 'exactly', overrride
3820         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3821             $datedue = $hardduedate->clone;
3822         }
3823
3824         # in all other cases, keep the date due as it is
3825
3826     }
3827
3828     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3829     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3830         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3831         if( $expiry_dt ) { #skip empty expiry date..
3832             $expiry_dt->set( hour => 23, minute => 59);
3833             my $d1= $datedue->clone->set_time_zone('floating');
3834             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3835                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3836             }
3837         }
3838         if ( $daysmode ne 'Days' ) {
3839           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3840           if ( $calendar->is_holiday($datedue) ) {
3841               # Don't return on a closed day
3842               $datedue = $calendar->prev_open_days( $datedue, 1 );
3843           }
3844         }
3845     }
3846
3847     return $datedue;
3848 }
3849
3850
3851 sub CheckValidBarcode{
3852 my ($barcode) = @_;
3853 my $dbh = C4::Context->dbh;
3854 my $query=qq|SELECT count(*)
3855              FROM items
3856              WHERE barcode=?
3857             |;
3858 my $sth = $dbh->prepare($query);
3859 $sth->execute($barcode);
3860 my $exist=$sth->fetchrow ;
3861 return $exist;
3862 }
3863
3864 =head2 IsBranchTransferAllowed
3865
3866   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3867
3868 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3869
3870 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3871 Koha::Item->can_be_transferred.
3872
3873 =cut
3874
3875 sub IsBranchTransferAllowed {
3876         my ( $toBranch, $fromBranch, $code ) = @_;
3877
3878         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3879
3880         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3881         my $dbh = C4::Context->dbh;
3882
3883         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3884         $sth->execute( $toBranch, $fromBranch, $code );
3885         my $limit = $sth->fetchrow_hashref();
3886
3887         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3888         if ( $limit->{'limitId'} ) {
3889                 return 0;
3890         } else {
3891                 return 1;
3892         }
3893 }
3894
3895 =head2 CreateBranchTransferLimit
3896
3897   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3898
3899 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3900
3901 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3902
3903 =cut
3904
3905 sub CreateBranchTransferLimit {
3906    my ( $toBranch, $fromBranch, $code ) = @_;
3907    return unless defined($toBranch) && defined($fromBranch);
3908    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3909
3910    my $dbh = C4::Context->dbh;
3911
3912    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3913    return $sth->execute( $code, $toBranch, $fromBranch );
3914 }
3915
3916 =head2 DeleteBranchTransferLimits
3917
3918     my $result = DeleteBranchTransferLimits($frombranch);
3919
3920 Deletes all the library transfer limits for one library.  Returns the
3921 number of limits deleted, 0e0 if no limits were deleted, or undef if
3922 no arguments are supplied.
3923
3924 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3925     fromBranch => $fromBranch
3926     })->delete.
3927
3928 =cut
3929
3930 sub DeleteBranchTransferLimits {
3931     my $branch = shift;
3932     return unless defined $branch;
3933     my $dbh    = C4::Context->dbh;
3934     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3935     return $sth->execute($branch);
3936 }
3937
3938 sub ReturnLostItem{
3939     my ( $borrowernumber, $itemnum ) = @_;
3940     MarkIssueReturned( $borrowernumber, $itemnum );
3941 }
3942
3943 =head2 LostItem
3944
3945   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3946
3947 The final optional parameter, C<$params>, expected to contain
3948 'skip_record_index' key, which relayed down to Koha::Item/store,
3949 there it prevents calling of ModZebra index_records,
3950 which takes most of the time in batch adds/deletes: index_records better
3951 to be called later in C<additem.pl> after the whole loop.
3952
3953 $params:
3954     skip_record_index => 1|0
3955
3956 =cut
3957
3958 sub LostItem{
3959     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3960
3961     unless ( $mark_lost_from ) {
3962         # Temporary check to avoid regressions
3963         die q|LostItem called without $mark_lost_from, check the API.|;
3964     }
3965
3966     my $mark_returned;
3967     if ( $force_mark_returned ) {
3968         $mark_returned = 1;
3969     } else {
3970         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3971         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3972     }
3973
3974     my $dbh = C4::Context->dbh();
3975     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3976                            FROM issues
3977                            JOIN items USING (itemnumber)
3978                            JOIN biblio USING (biblionumber)
3979                            WHERE issues.itemnumber=?");
3980     $sth->execute($itemnumber);
3981     my $issues=$sth->fetchrow_hashref();
3982
3983     # If a borrower lost the item, add a replacement cost to the their record
3984     if ( my $borrowernumber = $issues->{borrowernumber} ){
3985         my $patron = Koha::Patrons->find( $borrowernumber );
3986
3987         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3988         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3989
3990         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3991             C4::Accounts::chargelostitem(
3992                 $borrowernumber,
3993                 $itemnumber,
3994                 $issues->{'replacementprice'},
3995                 sprintf( "%s %s %s",
3996                     $issues->{'title'}          || q{},
3997                     $issues->{'barcode'}        || q{},
3998                     $issues->{'itemcallnumber'} || q{},
3999                 ),
4000             );
4001             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
4002             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
4003         }
4004
4005         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
4006     }
4007
4008     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
4009     my $item = Koha::Items->find($itemnumber);
4010     my $transfers = $item->get_transfers;
4011     while (my $transfer = $transfers->next) {
4012         $transfer->cancel({ reason => 'ItemLost', force => 1 });
4013     }
4014 }
4015
4016 sub GetOfflineOperations {
4017     my $dbh = C4::Context->dbh;
4018     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
4019     $sth->execute(C4::Context->userenv->{'branch'});
4020     my $results = $sth->fetchall_arrayref({});
4021     return $results;
4022 }
4023
4024 sub GetOfflineOperation {
4025     my $operationid = shift;
4026     return unless $operationid;
4027     my $dbh = C4::Context->dbh;
4028     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
4029     $sth->execute( $operationid );
4030     return $sth->fetchrow_hashref;
4031 }
4032
4033 sub AddOfflineOperation {
4034     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
4035     my $dbh = C4::Context->dbh;
4036     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
4037     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
4038     return "Added.";
4039 }
4040
4041 sub DeleteOfflineOperation {
4042     my $dbh = C4::Context->dbh;
4043     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4044     $sth->execute( shift );
4045     return "Deleted.";
4046 }
4047
4048 sub ProcessOfflineOperation {
4049     my $operation = shift;
4050
4051     my $report;
4052     if ( $operation->{action} eq 'return' ) {
4053         $report = ProcessOfflineReturn( $operation );
4054     } elsif ( $operation->{action} eq 'issue' ) {
4055         $report = ProcessOfflineIssue( $operation );
4056     } elsif ( $operation->{action} eq 'payment' ) {
4057         $report = ProcessOfflinePayment( $operation );
4058     }
4059
4060     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4061
4062     return $report;
4063 }
4064
4065 sub ProcessOfflineReturn {
4066     my $operation = shift;
4067
4068     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4069
4070     if ( $item ) {
4071         my $itemnumber = $item->itemnumber;
4072         my $issue = GetOpenIssue( $itemnumber );
4073         if ( $issue ) {
4074             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4075             ModDateLastSeen( $itemnumber, $leave_item_lost );
4076             MarkIssueReturned(
4077                 $issue->{borrowernumber},
4078                 $itemnumber,
4079                 $operation->{timestamp},
4080             );
4081             $item->renewals_count(0);
4082             $item->onloan(undef);
4083             $item->store({ log_action => 0 });
4084             return "Success.";
4085         } else {
4086             return "Item not issued.";
4087         }
4088     } else {
4089         return "Item not found.";
4090     }
4091 }
4092
4093 sub ProcessOfflineIssue {
4094     my $operation = shift;
4095
4096     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4097
4098     if ( $patron ) {
4099         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4100         unless ($item) {
4101             return "Barcode not found.";
4102         }
4103         my $itemnumber = $item->itemnumber;
4104         my $issue = GetOpenIssue( $itemnumber );
4105
4106         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4107             MarkIssueReturned(
4108                 $issue->{borrowernumber},
4109                 $itemnumber,
4110                 $operation->{timestamp},
4111             );
4112         }
4113         AddIssue(
4114             $patron->unblessed,
4115             $operation->{'barcode'},
4116             undef,
4117             undef,
4118             $operation->{timestamp},
4119             undef,
4120         );
4121         return "Success.";
4122     } else {
4123         return "Borrower not found.";
4124     }
4125 }
4126
4127 sub ProcessOfflinePayment {
4128     my $operation = shift;
4129
4130     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4131
4132     $patron->account->pay(
4133         {
4134             amount     => $operation->{amount},
4135             library_id => $operation->{branchcode},
4136             interface  => 'koc'
4137         }
4138     );
4139
4140     return "Success.";
4141 }
4142
4143 =head2 TransferSlip
4144
4145   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4146
4147   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4148
4149 =cut
4150
4151 sub TransferSlip {
4152     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4153
4154     my $item =
4155       $itemnumber
4156       ? Koha::Items->find($itemnumber)
4157       : Koha::Items->find( { barcode => $barcode } );
4158
4159     $item or return;
4160
4161     return C4::Letters::GetPreparedLetter (
4162         module => 'circulation',
4163         letter_code => 'TRANSFERSLIP',
4164         branchcode => $branch,
4165         tables => {
4166             'branches'    => $to_branch,
4167             'biblio'      => $item->biblionumber,
4168             'items'       => $item->unblessed,
4169         },
4170     );
4171 }
4172
4173 =head2 CheckIfIssuedToPatron
4174
4175   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4176
4177   Return 1 if any record item is issued to patron, otherwise return 0
4178
4179 =cut
4180
4181 sub CheckIfIssuedToPatron {
4182     my ($borrowernumber, $biblionumber) = @_;
4183
4184     my $dbh = C4::Context->dbh;
4185     my $query = q|
4186         SELECT COUNT(*) FROM issues
4187         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4188         WHERE items.biblionumber = ?
4189         AND issues.borrowernumber = ?
4190     |;
4191     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4192     return 1 if $is_issued;
4193     return;
4194 }
4195
4196 =head2 IsItemIssued
4197
4198   IsItemIssued( $itemnumber )
4199
4200   Return 1 if the item is on loan, otherwise return 0
4201
4202 =cut
4203
4204 sub IsItemIssued {
4205     my $itemnumber = shift;
4206     my $dbh = C4::Context->dbh;
4207     my $sth = $dbh->prepare(q{
4208         SELECT COUNT(*)
4209         FROM issues
4210         WHERE itemnumber = ?
4211     });
4212     $sth->execute($itemnumber);
4213     return $sth->fetchrow;
4214 }
4215
4216 =head2 GetAgeRestriction
4217
4218   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4219   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4220
4221   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4222   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4223
4224 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4225 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4226 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4227          Negative days mean the borrower has gone past the age restriction age.
4228
4229 =cut
4230
4231 sub GetAgeRestriction {
4232     my ($record_restrictions, $borrower) = @_;
4233     my $markers = C4::Context->preference('AgeRestrictionMarker');
4234
4235     return unless $record_restrictions;
4236     # Split $record_restrictions to something like FSK 16 or PEGI 6
4237     my @values = split ' ', uc($record_restrictions);
4238     return unless @values;
4239
4240     # Search first occurrence of one of the markers
4241     my @markers = split /\|/, uc($markers);
4242     return unless @markers;
4243
4244     my $index            = 0;
4245     my $restriction_year = 0;
4246     for my $value (@values) {
4247         $index++;
4248         for my $marker (@markers) {
4249             $marker =~ s/^\s+//;    #remove leading spaces
4250             $marker =~ s/\s+$//;    #remove trailing spaces
4251             if ( $marker eq $value ) {
4252                 if ( $index <= $#values ) {
4253                     $restriction_year += $values[$index];
4254                 }
4255                 last;
4256             }
4257             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4258
4259                 # Perhaps it is something like "K16" (as in Finland)
4260                 $restriction_year += $1;
4261                 last;
4262             }
4263         }
4264         last if ( $restriction_year > 0 );
4265     }
4266
4267     #Check if the borrower is age restricted for this material and for how long.
4268     if ($restriction_year && $borrower) {
4269         if ( $borrower->{'dateofbirth'} ) {
4270             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4271             $alloweddate[0] += $restriction_year;
4272
4273             #Prevent runime eror on leap year (invalid date)
4274             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4275                 $alloweddate[2] = 28;
4276             }
4277
4278             #Get how many days the borrower has to reach the age restriction
4279             my @Today = split /-/, dt_from_string()->ymd();
4280             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4281             #Negative days means the borrower went past the age restriction age
4282             return ($restriction_year, $daysToAgeRestriction);
4283         }
4284     }
4285
4286     return ($restriction_year);
4287 }
4288
4289
4290 =head2 GetPendingOnSiteCheckouts
4291
4292 =cut
4293
4294 sub GetPendingOnSiteCheckouts {
4295     my $dbh = C4::Context->dbh;
4296     return $dbh->selectall_arrayref(q|
4297         SELECT
4298           items.barcode,
4299           items.biblionumber,
4300           items.itemnumber,
4301           items.itemnotes,
4302           items.itemcallnumber,
4303           items.location,
4304           issues.date_due,
4305           issues.branchcode,
4306           issues.date_due < NOW() AS is_overdue,
4307           biblio.author,
4308           biblio.title,
4309           borrowers.firstname,
4310           borrowers.surname,
4311           borrowers.cardnumber,
4312           borrowers.borrowernumber
4313         FROM items
4314         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4315         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4316         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4317         WHERE issues.onsite_checkout = 1
4318     |, { Slice => {} } );
4319 }
4320
4321 sub GetTopIssues {
4322     my ($params) = @_;
4323
4324     my ($count, $branch, $itemtype, $ccode, $newness)
4325         = @$params{qw(count branch itemtype ccode newness)};
4326
4327     my $dbh = C4::Context->dbh;
4328     my $query = q{
4329         SELECT * FROM (
4330         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4331           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4332           i.ccode, SUM(i.issues) AS count
4333         FROM biblio b
4334         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4335         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4336     };
4337
4338     my (@where_strs, @where_args);
4339
4340     if ($branch) {
4341         push @where_strs, 'i.homebranch = ?';
4342         push @where_args, $branch;
4343     }
4344     if ($itemtype) {
4345         if (C4::Context->preference('item-level_itypes')){
4346             push @where_strs, 'i.itype = ?';
4347             push @where_args, $itemtype;
4348         } else {
4349             push @where_strs, 'bi.itemtype = ?';
4350             push @where_args, $itemtype;
4351         }
4352     }
4353     if ($ccode) {
4354         push @where_strs, 'i.ccode = ?';
4355         push @where_args, $ccode;
4356     }
4357     if ($newness) {
4358         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4359         push @where_args, $newness;
4360     }
4361
4362     if (@where_strs) {
4363         $query .= 'WHERE ' . join(' AND ', @where_strs);
4364     }
4365
4366     $query .= q{
4367         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4368           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4369           i.ccode
4370         ORDER BY count DESC
4371     };
4372
4373     $query .= q{ ) xxx WHERE count > 0 };
4374     $count = int($count);
4375     if ($count > 0) {
4376         $query .= "LIMIT $count";
4377     }
4378
4379     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4380
4381     return @$rows;
4382 }
4383
4384 =head2 Internal methods
4385
4386 =cut
4387
4388 sub _CalculateAndUpdateFine {
4389     my ($params) = @_;
4390
4391     my $borrower    = $params->{borrower};
4392     my $item        = $params->{item};
4393     my $issue       = $params->{issue};
4394     my $return_date = $params->{return_date};
4395
4396     unless ($borrower) { carp "No borrower passed in!" && return; }
4397     unless ($item)     { carp "No item passed in!"     && return; }
4398     unless ($issue)    { carp "No issue passed in!"    && return; }
4399
4400     my $datedue = dt_from_string( $issue->date_due );
4401
4402     # we only need to calculate and change the fines if we want to do that on return
4403     # Should be on for hourly loans
4404     my $control = C4::Context->preference('CircControl');
4405     my $control_branchcode =
4406         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4407       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4408       :                                     $issue->branchcode;
4409
4410     my $date_returned = $return_date ? $return_date : dt_from_string();
4411
4412     my ( $amount, $unitcounttotal, $unitcount  ) =
4413       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4414
4415     if ( C4::Context->preference('finesMode') eq 'production' ) {
4416         if ( $amount > 0 ) {
4417             C4::Overdues::UpdateFine({
4418                 issue_id       => $issue->issue_id,
4419                 itemnumber     => $issue->itemnumber,
4420                 borrowernumber => $issue->borrowernumber,
4421                 amount         => $amount,
4422                 due            => $datedue,
4423             });
4424         }
4425         elsif ($return_date) {
4426
4427             # Backdated returns may have fines that shouldn't exist,
4428             # so in this case, we need to drop those fines to 0
4429
4430             C4::Overdues::UpdateFine({
4431                 issue_id       => $issue->issue_id,
4432                 itemnumber     => $issue->itemnumber,
4433                 borrowernumber => $issue->borrowernumber,
4434                 amount         => 0,
4435                 due            => $datedue,
4436             });
4437         }
4438     }
4439 }
4440
4441 sub _CanBookBeAutoRenewed {
4442     my ( $params ) = @_;
4443     my $patron = $params->{patron};
4444     my $item = $params->{item};
4445     my $branchcode = $params->{branchcode};
4446     my $issue = $params->{issue};
4447
4448     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4449
4450     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4451         {
4452             categorycode => $patron->categorycode,
4453             itemtype     => $item->effective_itemtype,
4454             branchcode   => $branchcode,
4455             rules => [
4456                 'no_auto_renewal_after',
4457                 'no_auto_renewal_after_hard_limit',
4458                 'lengthunit',
4459                 'norenewalbefore',
4460             ]
4461         }
4462     );
4463
4464     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4465         return 'auto_account_expired';
4466     }
4467
4468     if ( defined $issuing_rule->{no_auto_renewal_after}
4469             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4470         # Get issue_date and add no_auto_renewal_after
4471         # If this is greater than today, it's too late for renewal.
4472         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4473         $maximum_renewal_date->add(
4474             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4475         );
4476         my $now = dt_from_string;
4477         if ( $now >= $maximum_renewal_date ) {
4478             return "auto_too_late";
4479         }
4480     }
4481     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4482                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4483         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4484         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4485             return "auto_too_late";
4486         }
4487     }
4488
4489     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4490         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4491         my $amountoutstanding =
4492           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4493           ? $patron->account->balance
4494           : $patron->account->outstanding_debits->total_outstanding;
4495         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4496             return "auto_too_much_oweing";
4497         }
4498     }
4499
4500     my $soonest = GetSoonestRenewDate($patron->id, $item->id);
4501     if ( $soonest > dt_from_string() )
4502     {
4503         return ( "auto_too_soon", $soonest );
4504     }
4505
4506     return "ok";
4507 }
4508
4509 sub _item_denied_renewal {
4510     my ($params) = @_;
4511
4512     my $item = $params->{item};
4513     return unless $item;
4514
4515     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4516     return unless $denyingrules;
4517     foreach my $field (keys %$denyingrules) {
4518         my $val = $item->$field;
4519         if( !defined $val) {
4520             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4521                 return 1;
4522             }
4523         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4524            # If the results matches the values in the syspref
4525            # We return true if match found
4526             return 1;
4527         }
4528     }
4529     return 0;
4530 }
4531
4532 1;
4533
4534 __END__
4535
4536 =head1 AUTHOR
4537
4538 Koha Development Team <http://koha-community.org/>
4539
4540 =cut