C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number blessed );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfersFromTo
 110       updateWrongTransfer
 111       CalcDateDue
 112       CheckValidBarcode
 113       IsBranchTransferAllowed
 114       CreateBranchTransferLimit
 115       DeleteBranchTransferLimits
 116       TransferSlip
 117
 118       GetOfflineOperations
 119       GetOfflineOperation
 120       AddOfflineOperation
 121       DeleteOfflineOperation
 122       ProcessOfflineOperation
 123       ProcessOfflinePayment
 124       ProcessOfflineIssue
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168
 169     return unless defined $barcode;
 170
 171     my $branch = C4::Context::mybranch();
 172     $barcode =~ s/^\s+|\s+$//g;
 173     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 174     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 175     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 176         if ($filter eq 'whitespace') {
 177                 $barcode =~ s/\s//g;
 178         } elsif ($filter eq 'cuecat') {
 179                 chomp($barcode);
 180             my @fields = split( /\./, $barcode );
 181             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 182             ($#results == 2) and return $results[2];
 183         } elsif ($filter eq 'T-prefix') {
 184                 if ($barcode =~ /^[Tt](\d)/) {
 185                         (defined($1) and $1 eq '0') and return $barcode;
 186             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 187                 }
 188         return sprintf("T%07d", $barcode);
 189         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 190         # Why drop the nonzero digit after the T?
 191         # Why pass non-digits (or empty string) to "T%07d"?
 192         } elsif ($filter eq 'libsuite8') {
 193                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 194                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 195                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 196                         }else{
 197                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 198                         }
 199                 }
 200     } elsif ($filter eq 'EAN13') {
 201         my $ean = CheckDigits('ean');
 202         if ( $ean->is_valid($barcode) ) {
 203             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 204             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 205         } else {
 206             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 207         }
 208         }
 209     return $barcode;    # return barcode, modified or not
 210 }
 211
 212 =head2 _decode
 213
 214   $str = &_decode($chunk);
 215
 216 Decodes a segment of a string emitted by a CueCat barcode scanner and
 217 returns it.
 218
 219 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 220 or Javascript based decoding on the client side.
 221
 222 =cut
 223
 224 sub _decode {
 225     my ($encoded) = @_;
 226     my $seq =
 227       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 228     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 229     my $l = ( $#s + 1 ) % 4;
 230     if ($l) {
 231         if ( $l == 1 ) {
 232             # warn "Error: Cuecat decode parsing failed!";
 233             return;
 234         }
 235         $l = 4 - $l;
 236         $#s += $l;
 237     }
 238     my $r = '';
 239     while ( $#s >= 0 ) {
 240         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 241         $r .=
 242             chr( ( $n >> 16 ) ^ 67 )
 243          .chr( ( $n >> 8 & 255 ) ^ 67 )
 244          .chr( ( $n & 255 ) ^ 67 );
 245         @s = @s[ 4 .. $#s ];
 246     }
 247     $r = substr( $r, 0, length($r) - $l );
 248     return $r;
 249 }
 250
 251 =head2 transferbook
 252
 253   ($dotransfer, $messages, $iteminformation) = &transferbook({
 254                                                    from_branch => $frombranch
 255                                                    to_branch => $tobranch,
 256                                                    barcode => $barcode,
 257                                                    ignore_reserves => $ignore_reserves,
 258                                                    trigger => $trigger
 259                                                 });
 260
 261 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 262
 263 C<$fbr> is the code for the branch initiating the transfer.
 264 C<$tbr> is the code for the branch to which the item should be transferred.
 265
 266 C<$barcode> is the barcode of the item to be transferred.
 267
 268 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 269 Otherwise, if an item is reserved, the transfer fails.
 270
 271 C<$trigger> is the enum value for what triggered the transfer.
 272
 273 Returns three values:
 274
 275 =over
 276
 277 =item $dotransfer
 278
 279 is true if the transfer was successful.
 280
 281 =item $messages
 282
 283 is a reference-to-hash which may have any of the following keys:
 284
 285 =over
 286
 287 =item C<BadBarcode>
 288
 289 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 290
 291 =item C<DestinationEqualsHolding>
 292
 293 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 294
 295 =item C<WasReturned>
 296
 297 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 298
 299 =item C<ResFound>
 300
 301 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 302
 303 =item C<WasTransferred>
 304
 305 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 306
 307 =item C<RecallPlacedAtHoldingBranch>
 308
 309 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 310
 311 =item C<RecallFound>
 312
 313 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 314
 315 =back
 316
 317 =back
 318
 319 =cut
 320
 321 sub transferbook {
 322     my $params = shift;
 323     my $tbr      = $params->{to_branch};
 324     my $fbr      = $params->{from_branch};
 325     my $ignoreRs = $params->{ignore_reserves};
 326     my $barcode  = $params->{barcode};
 327     my $trigger  = $params->{trigger};
 328     my $messages;
 329     my $dotransfer      = 1;
 330     my $item = Koha::Items->find( { barcode => $barcode } );
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: from_branch")
 334       unless $fbr;
 335
 336     Koha::Exceptions::MissingParameter->throw(
 337         "Missing mandatory parameter: to_branch")
 338       unless $tbr;
 339
 340     # bad barcode..
 341     unless ( $item ) {
 342         $messages->{'BadBarcode'} = $barcode;
 343         $dotransfer = 0;
 344         return ( $dotransfer, $messages );
 345     }
 346
 347     my $itemnumber = $item->itemnumber;
 348     # get branches of book...
 349     my $hbr = $item->homebranch;
 350
 351     # if using Branch Transfer Limits
 352     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 353         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 354         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 355             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 356                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 357                 $dotransfer = 0;
 358             }
 359         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 360             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 361             $dotransfer = 0;
 362         }
 363     }
 364
 365     # can't transfer book if is already there....
 366     if ( $fbr eq $tbr ) {
 367         $messages->{'DestinationEqualsHolding'} = 1;
 368         $dotransfer = 0;
 369     }
 370
 371     # check if it is still issued to someone, return it...
 372     my $issue = $item->checkout;
 373     if ( $issue ) {
 374         AddReturn( $barcode, $fbr );
 375         $messages->{'WasReturned'} = $issue->borrowernumber;
 376     }
 377
 378     # find reserves.....
 379     # That'll save a database query.
 380     my ( $resfound, $resrec, undef ) =
 381       CheckReserves( $item );
 382     if ( $resfound ) {
 383         $resrec->{'ResFound'} = $resfound;
 384         $messages->{'ResFound'} = $resrec;
 385         $dotransfer = 0 unless $ignoreRs;
 386     }
 387
 388     # find recall
 389     if ( C4::Context->preference('UseRecalls') ) {
 390         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 391         if ( defined $recall ) {
 392             # do a transfer if the recall branch is different to the item holding branch
 393             if ( $recall->pickup_library_id eq $fbr ) {
 394                 $dotransfer = 0;
 395                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 396             } else {
 397                 $dotransfer = 1;
 398                 $messages->{'RecallFound'} = $recall;
 399             }
 400         }
 401     }
 402
 403     #actually do the transfer....
 404     if ($dotransfer) {
 405         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 406
 407         # don't need to update MARC anymore, we do it in batch now
 408         $messages->{'WasTransfered'} = $tbr;
 409
 410     }
 411     ModDateLastSeen( $itemnumber );
 412     return ( $dotransfer, $messages );
 413 }
 414
 415
 416 sub TooMany {
 417     my ($patron, $item, $params) = @_;
 418     my $onsite_checkout = $params->{onsite_checkout} || 0;
 419     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 420     my $cat_borrower    = $patron->categorycode;
 421     my $dbh             = C4::Context->dbh;
 422     # Get which branchcode we need
 423     my $branch = _GetCircControlBranch($item, $patron);
 424     my $type = $item->effective_itemtype;
 425
 426     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 427     $type_object = Koha::ItemTypes->find( $type );
 428     $parent_type = $type_object->parent_type if $type_object;
 429     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 430     # Find any children if we are a parent_type;
 431
 432     # given branch, patron category, and item type, determine
 433     # applicable issuing rule
 434
 435     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 436         {
 437             categorycode => $cat_borrower,
 438             itemtype     => $parent_type,
 439             branchcode   => $branch,
 440             rule_name    => 'maxissueqty',
 441         }
 442     ) if $parent_type;
 443     # If the parent rule is for default type we discount it
 444     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 445
 446     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 447         {
 448             categorycode => $cat_borrower,
 449             itemtype     => $type,
 450             branchcode   => $branch,
 451             rule_name    => 'maxissueqty',
 452         }
 453     );
 454
 455     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 456         {
 457             categorycode => $cat_borrower,
 458             itemtype     => $type,
 459             branchcode   => $branch,
 460             rule_name    => 'maxonsiteissueqty',
 461         }
 462     );
 463
 464     # if a rule is found and has a loan limit set, count
 465     # how many loans the patron already has that meet that
 466     # rule
 467     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 468
 469         my $checkouts;
 470         if ( $maxissueqty_rule->branchcode ) {
 471             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 472                 $checkouts = $patron->checkouts->search(
 473                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 474             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 475                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 476             } else {
 477                 my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 478                 $checkouts = $patron->checkouts->search(
 479                     { "item.$branch_type" => $maxissueqty_rule->branchcode } );
 480             }
 481         } else {
 482             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 483         }
 484         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 485
 486         my $sum_checkouts;
 487         my $rule_itemtype = $maxissueqty_rule->itemtype;
 488
 489         my @types;
 490         unless ( $rule_itemtype ) {
 491             # matching rule has the default item type, so count only
 492             # those existing loans that don't fall under a more
 493             # specific rule
 494             @types = Koha::CirculationRules->search(
 495                 {
 496                     branchcode => $maxissueqty_rule->branchcode,
 497                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 498                     itemtype  => { '!=' => undef },
 499                     rule_name => 'maxissueqty'
 500                 }
 501             )->get_column('itemtype');
 502         } else {
 503             if ( $parent_maxissueqty_rule ) {
 504                 # if we have a parent item type then we count loans of the
 505                 # specific item type or its siblings or parent
 506                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 507                 @types = $children->get_column('itemtype');
 508                 push @types, $parent_type;
 509             } elsif ( $child_types ) {
 510                 # If we are a parent type, we need to count all child types and our own type
 511                 @types = $child_types->get_column('itemtype');
 512                 push @types, $type; # And don't forget to count our own types
 513             } else {
 514                 # Otherwise only count the specific itemtype
 515                 push @types, $type;
 516             }
 517         }
 518
 519         while ( my $c = $checkouts->next ) {
 520             my $itemtype = $c->item->effective_itemtype;
 521
 522             unless ( $rule_itemtype ) {
 523                 next if grep {$_ eq $itemtype} @types;
 524             } else {
 525                 next unless grep {$_ eq $itemtype} @types;
 526             }
 527
 528             $sum_checkouts->{total}++;
 529             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 530             $sum_checkouts->{itemtype}->{$itemtype}++;
 531         }
 532
 533         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 534         my $checkout_count = $sum_checkouts->{total} || 0;
 535         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 536
 537         my $checkout_rules = {
 538             checkout_count               => $checkout_count,
 539             onsite_checkout_count        => $onsite_checkout_count,
 540             onsite_checkout              => $onsite_checkout,
 541             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 542             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 543             switch_onsite_checkout       => $switch_onsite_checkout,
 544         };
 545         # If parent rules exists
 546         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 547             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 548             my $qty_over = _check_max_qty($checkout_rules);
 549             return $qty_over if defined $qty_over;
 550
 551             # If the parent rule is less than or equal to the child, we only need check the parent
 552             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 553                 $checkout_rules->{checkout_count} = $checkout_count_type;
 554                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 555                 my $qty_over = _check_max_qty($checkout_rules);
 556                 return $qty_over if defined $qty_over;
 557             }
 558         } else {
 559             my $qty_over = _check_max_qty($checkout_rules);
 560             return $qty_over if defined $qty_over;
 561         }
 562     }
 563
 564     # Now count total loans against the limit for the branch
 565     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 566     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 567         my $checkouts;
 568         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 569             $checkouts = $patron->checkouts->search(
 570                 { 'me.branchcode' => $branch} );
 571         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 572             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 573         } else {
 574             my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 575             $checkouts = $patron->checkouts->search(
 576                 { "item.$branch_type" => $branch},
 577                 { prefetch            => 'item' } );
 578         }
 579
 580         my $checkout_count = $checkouts->count;
 581         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 582         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 583         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 584
 585         my $qty_over = _check_max_qty(
 586             {
 587                 checkout_count               => $checkout_count,
 588                 onsite_checkout_count        => $onsite_checkout_count,
 589                 onsite_checkout              => $onsite_checkout,
 590                 max_checkouts_allowed        => $max_checkouts_allowed,
 591                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 592                 switch_onsite_checkout       => $switch_onsite_checkout
 593             }
 594         );
 595         return $qty_over if defined $qty_over;
 596     }
 597
 598     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 599         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 600     }
 601
 602     # OK, the patron can issue !!!
 603     return;
 604 }
 605
 606 sub _check_max_qty {
 607     my $params                       = shift;
 608     my $checkout_count               = $params->{checkout_count};
 609     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 610     my $onsite_checkout              = $params->{onsite_checkout};
 611     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 612     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 613     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 614
 615     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 616         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 617         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 618             return {
 619                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 620                 count       => $onsite_checkout_count,
 621                 max_allowed => $max_onsite_checkouts_allowed,
 622             };
 623         }
 624     }
 625     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 626         if ( $max_checkouts_allowed eq '' ) { return; }
 627         my $delta = $switch_onsite_checkout ? 1 : 0;
 628         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 629             return {
 630                 reason      => 'TOO_MANY_CHECKOUTS',
 631                 count       => $checkout_count,
 632                 max_allowed => $max_checkouts_allowed,
 633             };
 634         }
 635     }
 636     elsif ( not $onsite_checkout ) {
 637         if ( $max_checkouts_allowed eq '' ) { return; }
 638         if (
 639             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 640         {
 641             return {
 642                 reason      => 'TOO_MANY_CHECKOUTS',
 643                 count       => $checkout_count - $onsite_checkout_count,
 644                 max_allowed => $max_checkouts_allowed,
 645             };
 646         }
 647     }
 648
 649     return;
 650 }
 651
 652 =head2 CanBookBeIssued
 653
 654   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 655                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 656
 657 Check if a book can be issued.
 658
 659 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 660
 661 IMPORTANT: The assumption by users of this routine is that causes blocking
 662 the issue are keyed by uppercase labels and other returned
 663 data is keyed in lower case!
 664
 665 =over 4
 666
 667 =item C<$patron> is a Koha::Patron
 668
 669 =item C<$barcode> is the bar code of the book being issued.
 670
 671 =item C<$duedates> is a DateTime object.
 672
 673 =item C<$inprocess> boolean switch
 674
 675 =item C<$ignore_reserves> boolean switch
 676
 677 =item C<$params> Hashref of additional parameters
 678
 679 Available keys:
 680     override_high_holds - Ignore high holds
 681     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 682     item                - Optionally pass the object for the item we are checking out to save a lookup
 683
 684 =back
 685
 686 Returns :
 687
 688 =over 4
 689
 690 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 691 Possible values are :
 692
 693 =back
 694
 695 =head3 INVALID_DATE
 696
 697 sticky due date is invalid
 698
 699 =head3 GNA
 700
 701 borrower gone with no address
 702
 703 =head3 CARD_LOST
 704
 705 borrower declared it's card lost
 706
 707 =head3 DEBARRED
 708
 709 borrower debarred
 710
 711 =head3 UNKNOWN_BARCODE
 712
 713 barcode unknown
 714
 715 =head3 NOT_FOR_LOAN
 716
 717 item is not for loan
 718
 719 =head3 WTHDRAWN
 720
 721 item withdrawn.
 722
 723 =head3 RESTRICTED
 724
 725 item is restricted (set by ??)
 726
 727 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 728 could be prevented, but ones that can be overriden by the operator.
 729
 730 Possible values are :
 731
 732 =head3 DEBT
 733
 734 borrower has debts.
 735
 736 =head3 RENEW_ISSUE
 737
 738 renewing, not issuing
 739
 740 =head3 ISSUED_TO_ANOTHER
 741
 742 issued to someone else.
 743
 744 =head3 RESERVED
 745
 746 reserved for someone else.
 747
 748 =head3 TRANSFERRED
 749
 750 reserved and being transferred for someone else.
 751
 752 =head3 INVALID_DATE
 753
 754 sticky due date is invalid or due date in the past
 755
 756 =head3 TOO_MANY
 757
 758 if the borrower borrows to much things
 759
 760 =head3 RECALLED
 761
 762 recalled by someone else
 763
 764 =cut
 765
 766 sub CanBookBeIssued {
 767     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 768     my %needsconfirmation;    # filled with problems that needs confirmations
 769     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 770     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 771     my %messages;             # filled with information messages that should be displayed.
 772
 773     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 774     my $override_high_holds = $params->{override_high_holds} || 0;
 775
 776     my $item_object = $params->{item}
 777       // Koha::Items->find( { barcode => $barcode } );
 778
 779     # MANDATORY CHECKS - unless item exists, nothing else matters
 780     unless ( $item_object ) {
 781         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 782     }
 783     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 784
 785     my $item_unblessed = $item_object->unblessed; # Transition...
 786     my $issue = $item_object->checkout;
 787     my $biblio = $item_object->biblio;
 788
 789     my $biblioitem = $biblio->biblioitem;
 790     my $effective_itemtype = $item_object->effective_itemtype;
 791     my $dbh             = C4::Context->dbh;
 792     my $patron_unblessed = $patron->unblessed;
 793
 794     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_object, $patron) );
 795
 796     my $now = dt_from_string();
 797     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron );
 798     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 799          $needsconfirmation{INVALID_DATE} = $duedate;
 800     }
 801
 802     my $fees = Koha::Charges::Fees->new(
 803         {
 804             patron    => $patron,
 805             library   => $circ_library,
 806             item      => $item_object,
 807             to_date   => $duedate,
 808         }
 809     );
 810
 811     #
 812     # BORROWER STATUS
 813     #
 814     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 815         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 816         C4::Stats::UpdateStats(
 817             {
 818                 branch         => C4::Context->userenv->{'branch'},
 819                 type           => 'localuse',
 820                 itemnumber     => $item_object->itemnumber,
 821                 itemtype       => $effective_itemtype,
 822                 borrowernumber => $patron->borrowernumber,
 823                 ccode          => $item_object->ccode,
 824                 categorycode   => $patron->categorycode,
 825                 location       => $item_object->location,
 826                 interface      => C4::Context->interface,
 827             }
 828         );
 829         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 830         return( { STATS => 1 }, {});
 831     }
 832
 833     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 834         $issuingimpossible{GNA} = 1;
 835     }
 836
 837     if ( $patron->lost && $patron->lost == 1 ) {
 838         $issuingimpossible{CARD_LOST} = 1;
 839     }
 840     if ( $patron->is_debarred ) {
 841         $issuingimpossible{DEBARRED} = 1;
 842     }
 843
 844     if ( $patron->is_expired ) {
 845         $issuingimpossible{EXPIRED} = 1;
 846     }
 847
 848     #
 849     # BORROWER STATUS
 850     #
 851
 852     # DEBTS
 853     my $account = $patron->account;
 854     my $balance = $account->balance;
 855     my $non_issues_charges = $account->non_issues_charges;
 856     my $other_charges = $balance - $non_issues_charges;
 857
 858     my $amountlimit = C4::Context->preference("noissuescharge");
 859     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 860     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 861
 862     # Check the debt of this patrons guarantees
 863     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 864     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 865     if ( defined $no_issues_charge_guarantees ) {
 866         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 867         my $guarantees_non_issues_charges = 0;
 868         foreach my $g ( @guarantees ) {
 869             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 870         }
 871
 872         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 873             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 874         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 875             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 876         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 877             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 878         }
 879     }
 880
 881     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 882     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 883     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 884     if ( defined $no_issues_charge_guarantors ) {
 885         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 886
 887         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 888             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 889         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 890             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 891         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 892             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 893         }
 894     }
 895
 896     if ( C4::Context->preference("IssuingInProcess") ) {
 897         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 898             $issuingimpossible{DEBT} = $non_issues_charges;
 899         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 900             $needsconfirmation{DEBT} = $non_issues_charges;
 901         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 902             $needsconfirmation{DEBT} = $non_issues_charges;
 903         }
 904     }
 905     else {
 906         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 907             $needsconfirmation{DEBT} = $non_issues_charges;
 908         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 909             $issuingimpossible{DEBT} = $non_issues_charges;
 910         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 911             $needsconfirmation{DEBT} = $non_issues_charges;
 912         }
 913     }
 914
 915     if ($balance > 0 && $other_charges > 0) {
 916         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 917     }
 918
 919     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 920     $patron_unblessed = $patron->unblessed;
 921
 922     if ( my $debarred_date = $patron->is_debarred ) {
 923          # patron has accrued fine days or has a restriction. $count is a date
 924         if ($debarred_date eq '9999-12-31') {
 925             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 926         }
 927         else {
 928             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 929         }
 930     } elsif ( my $num_overdues = $patron->has_overdues ) {
 931         ## patron has outstanding overdue loans
 932         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 933             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 934         }
 935         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 936             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 937         }
 938     }
 939
 940     # Additional Materials Check
 941     if ( C4::Context->preference("CircConfirmItemParts")
 942         && $item_object->materials )
 943     {
 944         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 945     }
 946
 947     #
 948     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 949     #
 950     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 951
 952         # Already issued to current borrower.
 953         # If it is an on-site checkout if it can be switched to a normal checkout
 954         # or ask whether the loan should be renewed
 955
 956         if ( $issue->onsite_checkout
 957                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 958             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 959         } else {
 960             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed($patron, $issue);
 961             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 962                 if ( $renewerror eq 'onsite_checkout' ) {
 963                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 964                 }
 965                 else {
 966                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 967                 }
 968             }
 969             else {
 970                 $needsconfirmation{RENEW_ISSUE} = 1;
 971             }
 972         }
 973     }
 974     elsif ( $issue ) {
 975
 976         # issued to someone else
 977
 978         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 979
 980         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 981
 982         if ( !$can_be_returned ) {
 983             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 984             $issuingimpossible{branch_to_return} = $message;
 985         } else {
 986             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 987                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 988             }
 989             else {
 990                 $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 991                 $needsconfirmation{issued_firstname} = $patron->firstname;
 992                 $needsconfirmation{issued_surname} = $patron->surname;
 993                 $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 994                 $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 995             }
 996         }
 997     }
 998
 999     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1000     #
1001     my $switch_onsite_checkout = (
1002           C4::Context->preference('SwitchOnSiteCheckouts')
1003       and $issue
1004       and $issue->onsite_checkout
1005       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1006     my $toomany = TooMany( $patron, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1007     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1008     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1009         if ( $toomany->{max_allowed} == 0 ) {
1010             $needsconfirmation{PATRON_CANT} = 1;
1011         }
1012         if ( C4::Context->preference("AllowTooManyOverride") ) {
1013             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1014             $needsconfirmation{current_loan_count} = $toomany->{count};
1015             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1016         } else {
1017             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1018             $issuingimpossible{current_loan_count} = $toomany->{count};
1019             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1020         }
1021     }
1022
1023     #
1024     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1025     #
1026     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1027     if ( $patron->wants_check_for_previous_checkout && $patron->do_check_for_previous_checkout($item_unblessed) ) {
1028         $needsconfirmation{PREVISSUE} = 1;
1029     }
1030
1031     #
1032     # ITEM CHECKING
1033     #
1034     if ( $item_object->notforloan )
1035     {
1036         if(!C4::Context->preference("AllowNotForLoanOverride")){
1037             $issuingimpossible{NOT_FOR_LOAN} = 1;
1038             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1039         }else{
1040             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1041             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1042         }
1043     }
1044     else {
1045         # we have to check itemtypes.notforloan also
1046         if (C4::Context->preference('item-level_itypes')){
1047             # this should probably be a subroutine
1048             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1049             $sth->execute($effective_itemtype);
1050             my $notforloan=$sth->fetchrow_hashref();
1051             if ($notforloan->{'notforloan'}) {
1052                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1053                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1054                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1055                 } else {
1056                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1057                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1058                 }
1059             }
1060         }
1061         else {
1062             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1063             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1064                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1065                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1066                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1067                 } else {
1068                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1069                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1070                 }
1071             }
1072         }
1073     }
1074     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1075     {
1076         $issuingimpossible{WTHDRAWN} = 1;
1077     }
1078     if (   $item_object->restricted
1079         && $item_object->restricted == 1 )
1080     {
1081         $issuingimpossible{RESTRICTED} = 1;
1082     }
1083     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1084         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1085         my $code = $av->count ? $av->next->lib : '';
1086         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1087         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1088     }
1089     if ( C4::Context->preference("IndependentBranches") ) {
1090         my $userenv = C4::Context->userenv;
1091         unless ( C4::Context->IsSuperLibrarian() ) {
1092             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1093             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1094                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1095                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1096             }
1097             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1098               if ( $patron->branchcode ne $userenv->{branch} );
1099         }
1100     }
1101
1102     #
1103     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1104     #
1105     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1106     if ($rentalConfirmation) {
1107         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1108
1109         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1110         if ($itemtype_object) {
1111             my $accumulate_charge = $fees->accumulate_rentalcharge();
1112             if ( $accumulate_charge > 0 ) {
1113                 $rentalCharge += $accumulate_charge;
1114             }
1115         }
1116
1117         if ( $rentalCharge > 0 ) {
1118             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1119         }
1120     }
1121
1122     my $recall;
1123     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1124     # Only bother doing this if UseRecalls is enabled and the item is recallable
1125     # Don't look at recalls that are in transit
1126     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1127         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1128
1129         foreach my $r ( @recalls ) {
1130             if ( $r->item_id and
1131                 $r->item_id == $item_object->itemnumber and
1132                 $r->patron_id == $patron->borrowernumber and
1133                 ( $r->waiting or $r->requested ) ) {
1134                 $messages{RECALLED} = $r->id;
1135                 $recall = $r;
1136                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1137                 last;
1138             }
1139             elsif ( $r->item_id and
1140                 $r->item_id == $item_object->itemnumber and
1141                 $r->in_transit ) {
1142                 # recalled item is in transit
1143                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1144             }
1145             elsif ( $r->item_level and
1146                 $r->item_id == $item_object->itemnumber and
1147                 $r->patron_id != $patron->borrowernumber and
1148                 !$r->in_transit ) {
1149                 # this specific item has been recalled by a different patron
1150                 $needsconfirmation{RECALLED} = $r;
1151                 $recall = $r;
1152                 last;
1153             }
1154             elsif ( !$r->item_level and
1155                 $r->patron_id != $patron->borrowernumber and
1156                 !$r->in_transit ) {
1157                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1158                 $needsconfirmation{RECALLED} = $r;
1159                 $recall = $r;
1160                 last;
1161             }
1162         }
1163     }
1164
1165     unless ( $ignore_reserves and defined $recall ) {
1166         # See if the item is on reserve.
1167         my ( $restype, $res ) = CheckReserves( $item_object );
1168         if ($restype) {
1169             my $resbor = $res->{'borrowernumber'};
1170             if ( $resbor ne $patron->borrowernumber ) {
1171                 my $patron = Koha::Patrons->find( $resbor );
1172                 if ( $restype eq "Waiting" )
1173                 {
1174                     # The item is on reserve and waiting, but has been
1175                     # reserved by some other patron.
1176                     $needsconfirmation{RESERVE_WAITING} = 1;
1177                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1178                     $needsconfirmation{'ressurname'} = $patron->surname;
1179                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1180                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1181                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1182                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1183                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1184                 }
1185                 elsif ( $restype eq "Reserved" ) {
1186                     # The item is on reserve for someone else.
1187                     $needsconfirmation{RESERVED} = 1;
1188                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1189                     $needsconfirmation{'ressurname'} = $patron->surname;
1190                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1191                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1192                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1193                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1194                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1195                 }
1196                 elsif ( $restype eq "Transferred" ) {
1197                     # The item is determined hold being transferred for someone else.
1198                     $needsconfirmation{TRANSFERRED} = 1;
1199                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1200                     $needsconfirmation{'ressurname'} = $patron->surname;
1201                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1202                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1203                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1204                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1205                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1206                 }
1207                 elsif ( $restype eq "Processing" ) {
1208                     # The item is determined hold being processed for someone else.
1209                     $needsconfirmation{PROCESSING} = 1;
1210                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1211                     $needsconfirmation{'ressurname'} = $patron->surname;
1212                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1213                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1214                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1215                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1216                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1217                 }
1218             }
1219         }
1220     }
1221
1222     ## CHECK AGE RESTRICTION
1223     my $agerestriction  = $biblioitem->agerestriction;
1224     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1225     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1226         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1227             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1228         }
1229         else {
1230             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1231         }
1232     }
1233
1234     ## check for high holds decreasing loan period
1235     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1236         my $check = checkHighHolds( $item_object, $patron );
1237
1238         if ( $check->{exceeded} ) {
1239             my $highholds = {
1240                 num_holds  => $check->{outstanding},
1241                 duration   => $check->{duration},
1242                 returndate => $check->{due_date},
1243             };
1244             if ($override_high_holds) {
1245                 $alerts{HIGHHOLDS} = $highholds;
1246             }
1247             else {
1248                 $needsconfirmation{HIGHHOLDS} = $highholds;
1249             }
1250         }
1251     }
1252
1253     if (
1254         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1255         # don't do the multiple loans per bib check if we've
1256         # already determined that we've got a loan on the same item
1257         !$issuingimpossible{NO_MORE_RENEWALS} &&
1258         !$needsconfirmation{RENEW_ISSUE}
1259     ) {
1260         # Check if borrower has already issued an item from the same biblio
1261         # Only if it's not a subscription
1262         my $biblionumber = $item_object->biblionumber;
1263         require C4::Serials;
1264         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1265         unless ($is_a_subscription) {
1266             # FIXME Should be $patron->checkouts($args);
1267             my $checkouts = Koha::Checkouts->search(
1268                 {
1269                     borrowernumber => $patron->borrowernumber,
1270                     biblionumber   => $biblionumber,
1271                 },
1272                 {
1273                     join => 'item',
1274                 }
1275             );
1276             # if we get here, we don't already have a loan on this item,
1277             # so if there are any loans on this bib, ask for confirmation
1278             if ( $checkouts->count ) {
1279                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1280             }
1281         }
1282     }
1283
1284     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1285 }
1286
1287 =head2 CanBookBeReturned
1288
1289   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1290
1291 Check whether the item can be returned to the provided branch
1292
1293 =over 4
1294
1295 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1296
1297 =item C<$branch> is the branchcode where the return is taking place
1298
1299 =back
1300
1301 Returns:
1302
1303 =over 4
1304
1305 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1306
1307 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1308
1309 =back
1310
1311 =cut
1312
1313 sub CanBookBeReturned {
1314   my ($item, $branch) = @_;
1315   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1316
1317   # assume return is allowed to start
1318   my $allowed = 1;
1319   my $message;
1320
1321   # identify all cases where return is forbidden
1322   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1323      $allowed = 0;
1324      $message = $item->{'homebranch'};
1325   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1326      $allowed = 0;
1327      $message = $item->{'holdingbranch'};
1328   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1329      $allowed = 0;
1330      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1331   }
1332
1333   return ($allowed, $message);
1334 }
1335
1336 =head2 CheckHighHolds
1337
1338     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1339     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1340     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1341
1342 =cut
1343
1344 sub checkHighHolds {
1345     my ( $item, $patron ) = @_;
1346     my $branchcode = _GetCircControlBranch( $item, $patron );
1347
1348     my $return_data = {
1349         exceeded    => 0,
1350         outstanding => 0,
1351         duration    => 0,
1352         due_date    => undef,
1353     };
1354
1355
1356     # Count holds on this record, ignoring the borrowers own holds as they would be filled by the checkout
1357     my $holds = Koha::Holds->search({
1358         biblionumber => $item->biblionumber,
1359         borrowernumber => { '!=' => $patron->borrowernumber }
1360     });
1361
1362     if ( $holds->count() ) {
1363         $return_data->{outstanding} = $holds->count();
1364
1365         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1366         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1367         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1368
1369         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1370
1371         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1372
1373             # static means just more than a given number of holds on the record
1374
1375             # If the number of holds is not above the threshold, we can stop here
1376             if ( $holds->count() <= $decreaseLoanHighHoldsValue ) {
1377                 return $return_data;
1378             }
1379         }
1380         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1381
1382             # dynamic means X more than the number of holdable items on the record
1383
1384             # let's get the items
1385             my @items = $holds->next()->biblio()->items()->as_list;
1386
1387             # Remove any items with status defined to be ignored even if the would not make item unholdable
1388             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1389                 @items = grep { !$_->$status } @items;
1390             }
1391
1392             # Remove any items that are not holdable for this patron
1393             # We need to ignore hold counts as the borrower's own hold that will be filled by the checkout
1394             # could prevent them from placing further holds
1395             @items = grep { CanItemBeReserved( $patron, $_, undef, { ignore_hold_counts => 1 } )->{status} eq 'OK' } @items;
1396
1397             my $items_count = scalar @items;
1398
1399             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1400
1401             # If the number of holds is less than the count of items we have
1402             # plus the number of holds allowed above that count, we can stop here
1403             if ( $holds->count() <= $threshold ) {
1404                 return $return_data;
1405             }
1406         }
1407
1408         my $issuedate = dt_from_string();
1409
1410         my $itype = $item->effective_itemtype;
1411         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1412             {
1413                 categorycode => $patron->categorycode,
1414                 itemtype     => $itype,
1415                 branchcode   => $branchcode,
1416             }
1417         );
1418         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1419
1420         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron );
1421
1422         my $rule = Koha::CirculationRules->get_effective_rule_value(
1423             {
1424                 categorycode => $patron->categorycode,
1425                 itemtype     => $item->effective_itemtype,
1426                 branchcode   => $branchcode,
1427                 rule_name    => 'decreaseloanholds',
1428             }
1429         );
1430
1431         my $duration;
1432         if ( defined($rule) && $rule ne '' ){
1433             # overrides decreaseLoanHighHoldsDuration syspref
1434             $duration = $rule;
1435         } else {
1436             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1437         }
1438         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1439         $reduced_datedue->set_hour($orig_due->hour);
1440         $reduced_datedue->set_minute($orig_due->minute);
1441         $reduced_datedue->truncate( to => 'minute' );
1442
1443         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1444             $return_data->{exceeded} = 1;
1445             $return_data->{duration} = $duration;
1446             $return_data->{due_date} = $reduced_datedue;
1447         }
1448     }
1449
1450     return $return_data;
1451 }
1452
1453 =head2 AddIssue
1454
1455   &AddIssue($patron, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1456
1457 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1458
1459 =over 4
1460
1461 =item C<$patron> is a patron object.
1462
1463 =item C<$barcode> is the barcode of the item being issued.
1464
1465 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1466 Calculated if empty.
1467
1468 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1469
1470 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1471 Defaults to today.
1472
1473 AddIssue does the following things :
1474
1475   - step 01: check that there is a borrowernumber & a barcode provided
1476   - check for RENEWAL (book issued & being issued to the same patron)
1477       - renewal YES = Calculate Charge & renew
1478       - renewal NO  =
1479           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1480           * RESERVE PLACED ?
1481               - fill reserve if reserve to this patron
1482               - cancel reserve or not, otherwise
1483           * RECALL PLACED ?
1484               - fill recall if recall to this patron
1485               - cancel recall or not
1486               - revert recall's waiting status or not
1487           * TRANSFERT PENDING ?
1488               - complete the transfert
1489           * ISSUE THE BOOK
1490
1491 =back
1492
1493 =cut
1494
1495 sub AddIssue {
1496     my ( $patron, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1497
1498     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1499     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1500     my $auto_renew = $params && $params->{auto_renew};
1501     my $cancel_recall = $params && $params->{cancel_recall};
1502     my $recall_id = $params && $params->{recall_id};
1503     my $dbh          = C4::Context->dbh;
1504     my $barcodecheck = CheckValidBarcode($barcode);
1505
1506     my $issue;
1507
1508     if ( $datedue && ref $datedue ne 'DateTime' ) {
1509         $datedue = dt_from_string($datedue);
1510     }
1511
1512     # $issuedate defaults to today.
1513     if ( !defined $issuedate ) {
1514         $issuedate = dt_from_string();
1515     }
1516     else {
1517         if ( ref $issuedate ne 'DateTime' ) {
1518             $issuedate = dt_from_string($issuedate);
1519
1520         }
1521     }
1522
1523     # Stop here if the patron or barcode doesn't exist
1524     if ( $patron && $barcode && $barcodecheck ) {
1525         # find which item we issue
1526         my $item_object = Koha::Items->find({ barcode => $barcode })
1527           or return;    # if we don't get an Item, abort.
1528         my $item_unblessed = $item_object->unblessed;
1529
1530         my $branchcode = _GetCircControlBranch( $item_object, $patron );
1531
1532         # get actual issuing if there is one
1533         my $actualissue = $item_object->checkout;
1534
1535         # check if we just renew the issue.
1536         if ( $actualissue and $actualissue->borrowernumber eq $patron->borrowernumber
1537                 and not $switch_onsite_checkout ) {
1538             $datedue = AddRenewal(
1539                 {
1540                     borrowernumber => $patron->borrowernumber,
1541                     itemnumber     => $item_object->itemnumber,
1542                     branch         => $branchcode,
1543                     datedue        => $datedue,
1544                     lastreneweddate =>
1545                       $issuedate,    # here interpreted as the renewal date
1546                 }
1547             );
1548             $issue = $item_object->checkout;
1549         }
1550         else {
1551
1552             unless ($datedue) {
1553                 my $itype = $item_object->effective_itemtype;
1554                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $patron );
1555
1556             }
1557
1558             # Check if we need to use an exact due date set by the ILL module
1559             if ( C4::Context->preference('ILLModule') ) {
1560                 # Check if there is an ILL connected with the biblio of the item we are issuing
1561                 my $ill_request = Koha::Illrequests->search({
1562                     biblio_id => $item_object->biblionumber,
1563                     borrowernumber => $patron->borrowernumber,
1564                     completed => undef,
1565                     due_date => { '!=', undef },
1566                 })->next;
1567
1568                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1569                     my $ill_dt = dt_from_string( $ill_request->due_date );
1570                     $ill_dt->set_hour(23);
1571                     $ill_dt->set_minute(59);
1572                     $datedue = $ill_dt;
1573                 }
1574             }
1575
1576             $datedue->truncate( to => 'minute' );
1577
1578             my $library = Koha::Libraries->find( $branchcode );
1579             my $fees = Koha::Charges::Fees->new(
1580                 {
1581                     patron    => $patron,
1582                     library   => $library,
1583                     item      => $item_object,
1584                     to_date   => $datedue,
1585                 }
1586             );
1587
1588             # it's NOT a renewal
1589             if ( $actualissue and not $switch_onsite_checkout ) {
1590                 # This book is currently on loan, but not to the person
1591                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1592                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1593                 return unless $allowed;
1594                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1595                 # AddReturn certainly has side-effects, like onloan => undef
1596                 $item_object->discard_changes;
1597             }
1598
1599             if ( C4::Context->preference('UseRecalls') ) {
1600                 Koha::Recalls->move_recall(
1601                     {
1602                         action         => $cancel_recall,
1603                         recall_id      => $recall_id,
1604                         item           => $item_object,
1605                         borrowernumber => $patron->borrowernumber,
1606                     }
1607                 );
1608             }
1609
1610             C4::Reserves::MoveReserve( $item_object->itemnumber, $patron->borrowernumber, $cancelreserve );
1611
1612             # Starting process for transfer job (checking transfert and validate it if we have one)
1613             if ( my $transfer = $item_object->get_transfer ) {
1614                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1615                 $transfer->set(
1616                     {
1617                         datearrived => dt_from_string,
1618                         tobranch    => C4::Context->userenv->{branch},
1619                         comments    => 'Forced branchtransfer'
1620                     }
1621                 )->store;
1622                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1623                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1624                     if ( $hold ) { # Is this really needed?
1625                         $hold->set( { found => undef } )->store;
1626                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1627                     }
1628                 }
1629             }
1630
1631             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1632             unless ($auto_renew) {
1633                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1634                     {
1635                         categorycode => $patron->categorycode,
1636                         itemtype     => $item_object->effective_itemtype,
1637                         branchcode   => $branchcode,
1638                         rule_name    => 'auto_renew'
1639                     }
1640                 );
1641
1642                 $auto_renew = $rule if defined $rule && $rule ne '';
1643             }
1644
1645             my $issue_attributes = {
1646                 borrowernumber  => $patron->borrowernumber,
1647                 issuedate       => $issuedate,
1648                 date_due        => $datedue,
1649                 branchcode      => C4::Context->userenv->{'branch'},
1650                 onsite_checkout => $onsite_checkout,
1651                 auto_renew      => $auto_renew ? 1 : 0,
1652             };
1653
1654             # Get ID of logged in user.  if called from a batch job,
1655             # no user session exists and C4::Context->userenv() returns
1656             # the scalar '0'. Only do this if the syspref says so
1657             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1658                 my $userenv = C4::Context->userenv();
1659                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1660                 if ($usernumber) {
1661                     $issue_attributes->{issuer_id} = $usernumber;
1662                 }
1663             }
1664
1665             # In the case that the borrower has an on-site checkout
1666             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1667             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1668             if ($issue) {
1669                 $issue->set($issue_attributes)->store;
1670             }
1671             else {
1672                 $issue = Koha::Checkout->new(
1673                     {
1674                         itemnumber => $item_object->itemnumber,
1675                         %$issue_attributes,
1676                     }
1677                 )->store;
1678             }
1679             $issue->discard_changes;
1680             C4::Auth::track_login_daily( $patron->userid );
1681             if ( $item_object->location && $item_object->location eq 'CART'
1682                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1683             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1684                 CartToShelf( $item_object->itemnumber );
1685             }
1686
1687             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1688                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1689             }
1690
1691             # Record if item was lost
1692             my $was_lost = $item_object->itemlost;
1693
1694             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1695             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1696             $item_object->itemlost(0);
1697             $item_object->onloan($datedue->ymd());
1698             $item_object->datelastborrowed( dt_from_string()->ymd() );
1699             $item_object->datelastseen( dt_from_string() );
1700             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1701
1702             # If the item was lost, it has now been found, charge the overdue if necessary
1703             if ($was_lost) {
1704                 if ( $item_object->{_charge} ) {
1705                     $actualissue //= Koha::Old::Checkouts->search(
1706                         { itemnumber => $item_object->itemnumber },
1707                         {
1708                             order_by => { '-desc' => 'returndate' },
1709                             rows     => 1
1710                         }
1711                     )->single;
1712                     unless ( $patron->branchcode ) {
1713                         $patron = $actualissue->patron;
1714                     }
1715                     _CalculateAndUpdateFine(
1716                         {
1717                             issue       => $actualissue,
1718                             item        => $item_unblessed,
1719                             borrower    => $patron->unblessed,
1720                             return_date => $issuedate
1721                         }
1722                     );
1723                     _FixOverduesOnReturn( $patron->borrowernumber,
1724                         $item_object->itemnumber, undef, 'RENEWED' );
1725                 }
1726             }
1727
1728             # If it costs to borrow this book, charge it to the patron's account.
1729             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1730             if ( $charge && $charge > 0 ) {
1731                 AddIssuingCharge( $issue, $charge, 'RENT' );
1732             }
1733
1734             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1735             if ( $itemtype_object ) {
1736                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1737                 if ( $accumulate_charge > 0 ) {
1738                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1739                     $charge += $accumulate_charge;
1740                     $item_unblessed->{charge} = $charge;
1741                 }
1742             }
1743
1744             my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckout');
1745             if ($yaml) {
1746                 $yaml = "$yaml\n\n";
1747
1748                 my $rules;
1749                 eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
1750                 if ($@) {
1751                     warn "Unable to parse UpdateNotForLoanStatusOnCheckout syspref : $@";
1752                 }
1753                 else {
1754                     foreach my $key ( keys %$rules ) {
1755                         if ( $item_object->notforloan eq $key ) {
1756                             $item_object->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
1757                             last;
1758                         }
1759                     }
1760                 }
1761             }
1762
1763             # Record the fact that this book was issued.
1764             C4::Stats::UpdateStats(
1765                 {
1766                     branch => C4::Context->userenv->{'branch'},
1767                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1768                     amount         => $charge,
1769                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1770                     itemnumber     => $item_object->itemnumber,
1771                     itemtype       => $item_object->effective_itemtype,
1772                     location       => $item_object->location,
1773                     borrowernumber => $patron->borrowernumber,
1774                     ccode          => $item_object->ccode,
1775                     categorycode   => $patron->categorycode
1776                 }
1777             );
1778
1779             # Send a checkout slip.
1780             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1781             my %conditions        = (
1782                 branchcode   => $branchcode,
1783                 categorycode => $patron->categorycode,
1784                 item_type    => $item_object->effective_itemtype,
1785                 notification => 'CHECKOUT',
1786             );
1787             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1788                 SendCirculationAlert(
1789                     {
1790                         type     => 'CHECKOUT',
1791                         item     => $item_object->unblessed,
1792                         borrower => $patron->unblessed,
1793                         branch   => $branchcode,
1794                     }
1795                 );
1796             }
1797             logaction(
1798                 "CIRCULATION", "ISSUE",
1799                 $patron->borrowernumber,
1800                 $item_object->itemnumber,
1801             ) if C4::Context->preference("IssueLog");
1802
1803             Koha::Plugins->call('after_circ_action', {
1804                 action  => 'checkout',
1805                 payload => {
1806                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1807                     checkout => $issue->get_from_storage
1808                 }
1809             });
1810
1811             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1812                 {
1813                     biblio_ids => [ $item_object->biblionumber ]
1814                 }
1815             ) if C4::Context->preference('RealTimeHoldsQueue');
1816         }
1817     }
1818     return $issue;
1819 }
1820
1821 =head2 GetLoanLength
1822
1823   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1824
1825 Get loan length for an itemtype, a borrower type and a branch
1826
1827 =cut
1828
1829 sub GetLoanLength {
1830     my ( $categorycode, $itemtype, $branchcode ) = @_;
1831
1832     # Initialize default values
1833     my $rules = {
1834         issuelength   => 0,
1835         renewalperiod => 0,
1836         lengthunit    => 'days',
1837     };
1838
1839     my $found = Koha::CirculationRules->get_effective_rules( {
1840         branchcode => $branchcode,
1841         categorycode => $categorycode,
1842         itemtype => $itemtype,
1843         rules => [
1844             'issuelength',
1845             'renewalperiod',
1846             'lengthunit'
1847         ],
1848     } );
1849
1850     # Search for rules!
1851     foreach my $rule_name (keys %$found) {
1852         $rules->{$rule_name} = $found->{$rule_name};
1853     }
1854
1855     return $rules;
1856 }
1857
1858
1859 =head2 GetHardDueDate
1860
1861   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1862
1863 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1864
1865 =cut
1866
1867 sub GetHardDueDate {
1868     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1869
1870     my $rules = Koha::CirculationRules->get_effective_rules(
1871         {
1872             categorycode => $borrowertype,
1873             itemtype     => $itemtype,
1874             branchcode   => $branchcode,
1875             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1876         }
1877     );
1878
1879     if ( defined( $rules->{hardduedate} ) ) {
1880         if ( $rules->{hardduedate} ) {
1881             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1882         }
1883         else {
1884             return ( undef, undef );
1885         }
1886     }
1887 }
1888
1889 =head2 GetBranchBorrowerCircRule
1890
1891   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1892
1893 Retrieves circulation rule attributes that apply to the given
1894 branch and patron category, regardless of item type.
1895 The return value is a hashref containing the following key:
1896
1897 patron_maxissueqty - maximum number of loans that a
1898 patron of the given category can have at the given
1899 branch.  If the value is undef, no limit.
1900
1901 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1902 patron of the given category can have at the given
1903 branch.  If the value is undef, no limit.
1904
1905 This will check for different branch/category combinations in the following order:
1906 branch and category
1907 branch only
1908 category only
1909 default branch and category
1910
1911 If no rule has been found in the database, it will default to
1912 the buillt in rule:
1913
1914 patron_maxissueqty - undef
1915 patron_maxonsiteissueqty - undef
1916
1917 C<$branchcode> and C<$categorycode> should contain the
1918 literal branch code and patron category code, respectively - no
1919 wildcards.
1920
1921 =cut
1922
1923 sub GetBranchBorrowerCircRule {
1924     my ( $branchcode, $categorycode ) = @_;
1925
1926     # Initialize default values
1927     my $rules = {
1928         patron_maxissueqty       => undef,
1929         patron_maxonsiteissueqty => undef,
1930     };
1931
1932     # Search for rules!
1933     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1934         my $rule = Koha::CirculationRules->get_effective_rule(
1935             {
1936                 categorycode => $categorycode,
1937                 itemtype     => undef,
1938                 branchcode   => $branchcode,
1939                 rule_name    => $rule_name,
1940             }
1941         );
1942
1943         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1944     }
1945
1946     return $rules;
1947 }
1948
1949 =head2 GetBranchItemRule
1950
1951   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1952
1953 Retrieves circulation rule attributes that apply to the given
1954 branch and item type, regardless of patron category.
1955
1956 The return value is a hashref containing the following keys:
1957
1958 holdallowed => Hold policy for this branch and itemtype. Possible values:
1959   not_allowed:           No holds allowed.
1960   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1961   from_any_library:      Holds allowed from any patron.
1962   from_local_hold_group: Holds allowed from libraries in hold group
1963
1964 This searches branchitemrules in the following order:
1965
1966   * Same branchcode and itemtype
1967   * Same branchcode, itemtype '*'
1968   * branchcode '*', same itemtype
1969   * branchcode and itemtype '*'
1970
1971 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1972
1973 =cut
1974
1975 sub GetBranchItemRule {
1976     my ( $branchcode, $itemtype ) = @_;
1977
1978     # Search for rules!
1979     my $rules = Koha::CirculationRules->get_effective_rules({
1980         branchcode => $branchcode,
1981         itemtype => $itemtype,
1982         rules => ['holdallowed', 'hold_fulfillment_policy']
1983     });
1984
1985     # built-in default circulation rule
1986     $rules->{holdallowed} //= 'from_any_library';
1987     $rules->{hold_fulfillment_policy} //= 'any';
1988
1989     return $rules;
1990 }
1991
1992 =head2 AddReturn
1993
1994   ($doreturn, $messages, $iteminformation, $borrower) =
1995       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1996
1997 Returns a book.
1998
1999 =over 4
2000
2001 =item C<$barcode> is the bar code of the book being returned.
2002
2003 =item C<$branch> is the code of the branch where the book is being returned.
2004
2005 =item C<$exemptfine> indicates that overdue charges for the item will be
2006 removed. Optional.
2007
2008 =item C<$return_date> allows the default return date to be overridden
2009 by the given return date. Optional.
2010
2011 =back
2012
2013 C<&AddReturn> returns a list of four items:
2014
2015 C<$doreturn> is true iff the return succeeded.
2016
2017 C<$messages> is a reference-to-hash giving feedback on the operation.
2018 The keys of the hash are:
2019
2020 =over 4
2021
2022 =item C<BadBarcode>
2023
2024 No item with this barcode exists. The value is C<$barcode>.
2025
2026 =item C<NotIssued>
2027
2028 The book is not currently on loan. The value is C<$barcode>.
2029
2030 =item C<withdrawn>
2031
2032 This book has been withdrawn/cancelled. The value should be ignored.
2033
2034 =item C<Wrongbranch>
2035
2036 This book has was returned to the wrong branch.  The value is a hashref
2037 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2038 contain the branchcode of the incorrect and correct return library, respectively.
2039
2040 =item C<ResFound>
2041
2042 The item was reserved. The value is a reference-to-hash whose keys are
2043 fields from the reserves table of the Koha database, and
2044 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2045 either C<Waiting>, C<Reserved>, or 0.
2046
2047 =item C<WasReturned>
2048
2049 Value 1 if return is successful.
2050
2051 =item C<NeedsTransfer>
2052
2053 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2054
2055 =item C<RecallFound>
2056
2057 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2058 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2059 branchcode.
2060
2061 =item C<TransferredRecall>
2062
2063 This item has been transferred to this branch to fill a recall. The recall object is returned.
2064
2065 =back
2066
2067 C<$iteminformation> is a reference-to-hash, giving information about the
2068 returned item from the issues table.
2069
2070 C<$borrower> is a reference-to-hash, giving information about the
2071 patron who last borrowed the book.
2072
2073 =cut
2074
2075 sub AddReturn {
2076     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2077
2078     if ($branch and not Koha::Libraries->find($branch)) {
2079         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2080         undef $branch;
2081     }
2082     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2083     my $return_date_specified = !!$return_date;
2084     $return_date //= dt_from_string();
2085     my $messages;
2086     my $patron;
2087     my $doreturn       = 1;
2088     my $validTransfer = 1;
2089     my $stat_type = 'return';
2090
2091     # get information on item
2092     my $item = Koha::Items->find({ barcode => $barcode });
2093     unless ($item) {
2094         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2095     }
2096
2097     my $itemnumber = $item->itemnumber;
2098     my $itemtype = $item->effective_itemtype;
2099
2100     my $issue  = $item->checkout;
2101     if ( $issue ) {
2102         $patron = $issue->patron
2103             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2104                 . Dumper($issue->unblessed) . "\n";
2105     } else {
2106         $messages->{'NotIssued'} = $barcode;
2107         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2108
2109         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2110         $doreturn = 0;
2111         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2112         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2113         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2114            $messages->{'LocalUse'} = 1;
2115            $stat_type = 'localuse';
2116         }
2117     }
2118
2119     if ( $item->withdrawn ) { # book has been cancelled
2120         $messages->{'withdrawn'} = 1;
2121
2122         # In the case where we block return of withdrawn, we should completely block the return
2123         # without updating item statuses, so we exit early
2124         return ( 0, $messages, $issue, ( $patron ? $patron->unblessed : {} ))
2125             if C4::Context->preference("BlockReturnOfWithdrawnItems");
2126     }
2127
2128
2129     # full item data, but no borrowernumber or checkout info (no issue)
2130     my $hbr = Koha::CirculationRules->get_return_branch_policy($item);
2131
2132     # check if returnbranch and homebranch belong to the same float group
2133     my $validate_float =
2134         Koha::Libraries->find( $item->homebranch )->validate_float_sibling( { branchcode => $branch } );
2135
2136     # get the proper branch to which to return the item
2137     my $returnbranch;
2138     if ( $hbr eq 'noreturn' ) {
2139         $returnbranch = $branch;
2140     } elsif ( $hbr eq 'returnbylibrarygroup' ) {
2141
2142         # if library isn't in same the float group, transfer item to homebranch
2143         $hbr          = 'homebranch';
2144         $returnbranch = $validate_float ? $branch : $item->$hbr;
2145     } else {
2146         $returnbranch = $item->$hbr;
2147     }
2148
2149     # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2150     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2151
2152     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2153     my $patron_unblessed = $patron ? $patron->unblessed : {};
2154
2155     my $update_loc_rules = C4::Context->yaml_preference('UpdateItemLocationOnCheckin');
2156     if ($update_loc_rules) {
2157         if ( defined $update_loc_rules->{_ALL_} ) {
2158             if ( $update_loc_rules->{_ALL_} eq '_PERM_' ) {
2159                 $update_loc_rules->{_ALL_} = $item->permanent_location;
2160             }
2161             if ( $update_loc_rules->{_ALL_} eq '_BLANK_' ) {
2162                 $update_loc_rules->{_ALL_} = '';
2163             }
2164             if (
2165                 (
2166                     defined $item->location
2167                     && $item->location ne $update_loc_rules->{_ALL_}
2168                 )
2169                 || ( !defined $item->location
2170                     && $update_loc_rules->{_ALL_} ne "" )
2171               )
2172             {
2173                 $messages->{'ItemLocationUpdated'} =
2174                   { from => $item->location, to => $update_loc_rules->{_ALL_} };
2175                 $item->location( $update_loc_rules->{_ALL_} )->store(
2176                     {
2177                         log_action        => 0,
2178                         skip_record_index => 1,
2179                         skip_holds_queue  => 1
2180                     }
2181                 );
2182             }
2183         }
2184         else {
2185             foreach my $key ( keys %$update_loc_rules ) {
2186                 if ( $update_loc_rules->{$key} eq '_PERM_' ) {
2187                     $update_loc_rules->{$key} = $item->permanent_location;
2188                 }
2189                 elsif ( $update_loc_rules->{$key} eq '_BLANK_' ) {
2190                     $update_loc_rules->{$key} = '';
2191                 }
2192                 if (
2193                     (
2194                            defined $item->location
2195                         && $item->location eq $key
2196                         && $item->location ne $update_loc_rules->{$key}
2197                     )
2198                     || (   $key eq '_BLANK_'
2199                         && ( !defined $item->location || $item->location eq '' )
2200                         && $update_loc_rules->{$key} ne '' )
2201                   )
2202                 {
2203                     $messages->{'ItemLocationUpdated'} = {
2204                         from => $item->location,
2205                         to   => $update_loc_rules->{$key}
2206                     };
2207                     $item->location( $update_loc_rules->{$key} )->store(
2208                         {
2209                             log_action        => 0,
2210                             skip_record_index => 1,
2211                             skip_holds_queue  => 1
2212                         }
2213                     );
2214                     last;
2215                 }
2216             }
2217         }
2218     }
2219
2220     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2221     if ($yaml) {
2222         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2223         my $rules;
2224         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2225         if ($@) {
2226             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2227         }
2228         else {
2229             if ( defined $rules->{$item->itype} ) {
2230                 foreach my $notloan_rule_key (keys %{ $rules->{$item->itype}} ) {
2231                     if ( $item->notforloan eq $notloan_rule_key ) {
2232                         $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$item->itype}->{$notloan_rule_key} };
2233                         $item->notforloan($rules->{$item->itype}->{$notloan_rule_key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2234                         last;
2235                     }
2236                 }
2237             } elsif ( defined $rules->{'_ALL_'} ) {
2238                 foreach my $notloan_rule_key (keys %{ $rules->{'_ALL_'}} ) {
2239                     if ( $item->notforloan eq $notloan_rule_key ) {
2240                         $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{'_ALL_'}->{$notloan_rule_key} };
2241                         $item->notforloan($rules->{'_ALL_'}->{$notloan_rule_key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2242                         last;
2243                     }
2244                 }
2245             }
2246         }
2247     }
2248
2249     # check if the return is allowed at this branch
2250     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2251     unless ($returnallowed){
2252         $messages->{'Wrongbranch'} = {
2253             Wrongbranch => $branch,
2254             Rightbranch => $message
2255         };
2256         $doreturn = 0;
2257         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2258         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2259         return ( $doreturn, $messages, $issue, $patron_unblessed);
2260     }
2261
2262     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2263         $doreturn = 0;
2264     }
2265
2266     # case of a return of document (deal with issues and holdingbranch)
2267     if ($doreturn) {
2268         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2269         $patron or warn "AddReturn without current borrower";
2270
2271         if ($patron) {
2272             eval {
2273                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2274             };
2275             unless ( $@ ) {
2276                 if (
2277                     (
2278                         C4::Context->preference('CalculateFinesOnReturn')
2279                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2280                     )
2281                     && !$item->itemlost
2282                   )
2283                 {
2284                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2285                 }
2286             } else {
2287                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2288
2289                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2290                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2291
2292                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2293             }
2294
2295             # FIXME is the "= 1" right?  This could be the borrower hash.
2296             $messages->{'WasReturned'} = 1;
2297
2298         } else {
2299             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2300         }
2301     }
2302
2303     # the holdingbranch is updated if the document is returned to another location.
2304     # this is always done regardless of whether the item was on loan or not
2305     if ($item->holdingbranch ne $branch) {
2306         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2307     }
2308
2309     my $item_was_lost = $item->itemlost;
2310     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2311     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2312
2313     # fix up the accounts.....
2314     if ($item_was_lost) {
2315         $messages->{'WasLost'} = 1;
2316         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2317             my @object_messages = @{ $updated_item->object_messages };
2318             for my $message (@object_messages) {
2319                 $messages->{'LostItemFeeRefunded'} = 1
2320                   if $message->message eq 'lost_refunded';
2321                 $messages->{'ProcessingFeeRefunded'} = 1
2322                   if $message->message eq 'processing_refunded';
2323                 $messages->{'LostItemFeeRestored'} = 1
2324                   if $message->message eq 'lost_restored';
2325
2326                 if ( $message->message eq 'lost_charge' ) {
2327                     $issue //= Koha::Old::Checkouts->search(
2328                         { itemnumber => $item->itemnumber },
2329                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2330                     )->single;
2331                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2332                         my $patron = $issue->patron;
2333                         $patron_unblessed = $patron->unblessed;
2334                     }
2335                     _CalculateAndUpdateFine(
2336                         {
2337                             issue       => $issue,
2338                             item        => $item->unblessed,
2339                             borrower    => $patron_unblessed,
2340                             return_date => $return_date
2341                         }
2342                     );
2343                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2344                         $item->itemnumber, undef, 'RETURNED' );
2345                     $messages->{'LostItemFeeCharged'} = 1;
2346                 }
2347             }
2348         }
2349     }
2350
2351     # check if we have a transfer for this document
2352     my $transfer = $item->get_transfer;
2353
2354     # if we have a transfer to complete, we update the line of transfers with the datearrived
2355     if ($transfer) {
2356         $validTransfer = 0;
2357         if ( $transfer->in_transit ) {
2358             if ( $transfer->tobranch eq $branch ) {
2359                 $transfer->receive;
2360                 $messages->{'TransferArrived'} = $transfer->frombranch;
2361                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2362                 $validTransfer = 1
2363                   if defined $transfer->reason && $transfer->reason eq 'Reserve';
2364             }
2365             else {
2366                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2367                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2368                 $messages->{'TransferTrigger'}   = $transfer->reason;
2369             }
2370         }
2371         else {
2372             if ( $transfer->tobranch eq $branch ) {
2373                 $transfer->receive;
2374                 $messages->{'TransferArrived'} = $transfer->frombranch;
2375                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2376                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2377             }
2378             else {
2379                 $messages->{'TransferTrigger'} = $transfer->reason;
2380                 if ( $transfer->frombranch eq $branch ) {
2381                     $transfer->transit;
2382                     $messages->{'WasTransfered'}   = $transfer->tobranch;
2383                 }
2384                 else {
2385                     $messages->{'WrongTransfer'}     = $transfer->tobranch;
2386                     $messages->{'WrongTransferItem'} = $item->itemnumber;
2387                 }
2388             }
2389         }
2390     }
2391
2392     # fix up the overdues in accounts...
2393     if ($borrowernumber) {
2394         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2395         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2396
2397         if ( $issue and $issue->is_overdue($return_date) ) {
2398         # fix fine days
2399             my ($debardate,$reminder) = _debar_user_on_return( $patron, $item, dt_from_string($issue->date_due), $return_date );
2400             if ($debardate and $debardate ne "9999-12-31") {
2401                 if ($reminder){
2402                     $messages->{'PrevDebarred'} = $debardate;
2403                 } else {
2404                     $messages->{'Debarred'} = $debardate;
2405                 }
2406             } elsif ($patron->debarred) {
2407                 if ( $patron->debarred eq "9999-12-31") {
2408                     $messages->{'ForeverDebarred'} = $patron->debarred;
2409                 } else {
2410                     my $borrower_debar_dt = dt_from_string( $patron->debarred );
2411                     $borrower_debar_dt->truncate(to => 'day');
2412                     my $today_dt = $return_date->clone()->truncate(to => 'day');
2413                     if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2414                         $messages->{'PrevDebarred'} = $patron->debarred;
2415                     }
2416                 }
2417             }
2418         # there's no overdue on the item but borrower had been previously debarred
2419         } elsif ( $issue->date_due and $patron->debarred ) {
2420              if ( $patron->debarred eq "9999-12-31") {
2421                 $messages->{'ForeverDebarred'} = $patron->debarred;
2422              } else {
2423                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2424                   $borrower_debar_dt->truncate(to => 'day');
2425                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2426                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2427                       $messages->{'PrevDebarred'} = $patron->debarred;
2428                   }
2429              }
2430         }
2431     }
2432
2433     # find recalls...
2434     if ( C4::Context->preference('UseRecalls') ) {
2435         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2436         my $recall = undef;
2437         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2438         if ( defined $recall ) {
2439             $messages->{RecallFound} = $recall;
2440             if ( $recall->pickup_library_id ne $branch ) {
2441                 $messages->{RecallNeedsTransfer} = $branch;
2442             }
2443         }
2444     }
2445
2446     # find reserves.....
2447     # launch the Checkreserves routine to find any holds
2448     my ($resfound, $resrec);
2449     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2450     ($resfound, $resrec, undef) = CheckReserves( $item, $lookahead ) unless ( $item->withdrawn );
2451     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2452     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2453         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2454         $resfound = 'Reserved';
2455         $resrec = $hold->unblessed;
2456     }
2457     if ($resfound) {
2458           $resrec->{'ResFound'} = $resfound;
2459         $messages->{'ResFound'} = $resrec;
2460     }
2461
2462     # Record the fact that this book was returned.
2463     my $categorycode = $patron_unblessed ? $patron_unblessed->{categorycode} : undef;
2464     C4::Stats::UpdateStats({
2465         branch         => $branch,
2466         type           => $stat_type,
2467         itemnumber     => $itemnumber,
2468         itemtype       => $itemtype,
2469         location       => $item->location,
2470         borrowernumber => $borrowernumber,
2471         ccode          => $item->ccode,
2472         categorycode   => $categorycode,
2473         interface      => C4::Context->interface,
2474     });
2475
2476     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2477     if ( $patron ) {
2478         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2479         my %conditions = (
2480             branchcode   => $branch,
2481             categorycode => $patron->categorycode,
2482             item_type    => $itemtype,
2483             notification => 'CHECKIN',
2484         );
2485         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2486             SendCirculationAlert({
2487                 type     => 'CHECKIN',
2488                 item     => $item->unblessed,
2489                 borrower => $patron->unblessed,
2490                 branch   => $branch,
2491                 issue    => $issue
2492             });
2493         }
2494
2495         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2496             if C4::Context->preference("ReturnLog");
2497         }
2498
2499     # Check if this item belongs to a biblio record that is attached to an
2500     # ILL request, if it is we need to update the ILL request's status
2501     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2502         my $request = Koha::Illrequests->find(
2503             { biblio_id => $item->biblio->biblionumber }
2504         );
2505         $request->status('RET') if $request;
2506     }
2507
2508     if ( C4::Context->preference('UseRecalls') ) {
2509         # all recalls that have triggered a transfer will have an allocated itemnumber
2510         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2511         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2512             $messages->{TransferredRecall} = $transfer_recall;
2513         }
2514     }
2515
2516     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2517     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2518         && ( $doreturn or $messages->{'NotIssued'} )
2519         and !$resfound
2520         and ( $branch ne $returnbranch )
2521         and not $messages->{'WrongTransfer'}
2522         and not $messages->{'WasTransfered'}
2523         and not $messages->{TransferredRecall}
2524         and not $messages->{RecallNeedsTransfer} )
2525     {
2526         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2527         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2528             (C4::Context->preference("UseBranchTransferLimits") and
2529              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2530            )) {
2531             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2532             $messages->{'WasTransfered'} = $returnbranch;
2533             $messages->{'TransferTrigger'} = $transfer_trigger;
2534         } else {
2535             $messages->{'NeedsTransfer'} = $returnbranch;
2536             $messages->{'TransferTrigger'} = $transfer_trigger;
2537         }
2538     }
2539
2540     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2541         my $claims = Koha::Checkouts::ReturnClaims->search(
2542            {
2543                itemnumber => $item->id,
2544                resolution => undef,
2545            }
2546         );
2547
2548         if ( $claims->count ) {
2549             $messages->{ReturnClaims} = $claims;
2550         }
2551     }
2552
2553     # Check for bundle status
2554     if ( $item->in_bundle ) {
2555         my $host = $item->bundle_host;
2556         $messages->{InBundle} = $host;
2557     }
2558
2559     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2560     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2561
2562     if ( $doreturn and $issue ) {
2563         my $checkin = Koha::Old::Checkouts->find($issue->id);
2564
2565         Koha::Plugins->call('after_circ_action', {
2566             action  => 'checkin',
2567             payload => {
2568                 checkout=> $checkin
2569             }
2570         });
2571
2572         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2573             {
2574                 biblio_ids => [ $item->biblionumber ]
2575             }
2576         ) if C4::Context->preference('RealTimeHoldsQueue');
2577     }
2578
2579     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2580 }
2581
2582 =head2 MarkIssueReturned
2583
2584   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2585
2586 Unconditionally marks an issue as being returned by
2587 moving the C<issues> row to C<old_issues> and
2588 setting C<returndate> to the current date.
2589
2590 if C<$returndate> is specified (in iso format), it is used as the date
2591 of the return.
2592
2593 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2594 the old_issue is immediately anonymised
2595
2596 Ideally, this function would be internal to C<C4::Circulation>,
2597 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2598 and offline_circ/process_koc.pl.
2599
2600 The last optional parameter allos passing skip_record_index to the item store call.
2601
2602 =cut
2603
2604 sub MarkIssueReturned {
2605     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2606
2607     # Retrieve the issue
2608     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2609     my $issue_branchcode = $issue->branchcode;
2610
2611     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2612
2613     my $issue_id = $issue->issue_id;
2614
2615     my $schema = Koha::Database->schema;
2616
2617     # FIXME Improve the return value and handle it from callers
2618     $schema->txn_do(sub {
2619
2620         my $patron = Koha::Patrons->find( $borrowernumber );
2621
2622         # Update the returndate value
2623         if ( $returndate ) {
2624             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2625         }
2626         else {
2627             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2628         }
2629
2630         # Create the old_issues entry
2631         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2632
2633         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2634         if ( $privacy && $privacy == 2) {
2635             $old_checkout->anonymize;
2636         }
2637
2638         # And finally delete the issue
2639         $issue->delete;
2640
2641         $issue->item->onloan(undef)->store(
2642             {   log_action        => 0,
2643                 skip_record_index => $params->{skip_record_index},
2644                 skip_holds_queue  => $params->{skip_holds_queue}
2645             }
2646         );
2647
2648         if ( C4::Context->preference('StoreLastBorrower') ) {
2649             my $item = Koha::Items->find( $itemnumber );
2650             $item->last_returned_by( $patron->borrowernumber )->store;
2651         }
2652
2653         # Possibly remove any OVERDUES related debarment
2654         my $overdue_restrictions = $patron->restrictions->search( { type => 'OVERDUES' } );
2655         if ( C4::Context->preference('AutoRemoveOverduesRestrictions') ne 'no' && $patron->is_debarred ) {
2656             my $remove_restrictions =
2657                 C4::Context->preference('AutoRemoveOverduesRestrictions') eq 'when_no_overdue_causing_debarment'
2658                 ? !$patron->has_restricting_overdues( { issue_branchcode => $issue_branchcode } )
2659                 : !$patron->has_overdues;
2660             if ( $remove_restrictions && $overdue_restrictions->count ) {
2661                 DelUniqueDebarment( { borrowernumber => $borrowernumber, type => 'OVERDUES' } );
2662             }
2663         }
2664
2665     });
2666
2667     return $issue_id;
2668 }
2669
2670 =head2 _debar_user_on_return
2671
2672     _debar_user_on_return($patron, $item, $datedue, $returndate);
2673
2674 C<$patron> patron object
2675
2676 C<$item> item object
2677
2678 C<$datedue> date due DateTime object
2679
2680 C<$returndate> DateTime object representing the return time
2681
2682 Internal function, called only by AddReturn that calculates and updates
2683  the user fine days, and debars them if necessary.
2684
2685 Should only be called for overdue returns
2686
2687 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2688 to ease testing.
2689
2690 =cut
2691
2692 sub _calculate_new_debar_dt {
2693     my ( $patron, $item, $dt_due, $return_date ) = @_;
2694
2695     my $branchcode = _GetCircControlBranch( $item, $patron );
2696     my $circcontrol = C4::Context->preference('CircControl');
2697     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2698         {   categorycode => $patron->categorycode,
2699             itemtype     => $item->effective_itemtype,
2700             branchcode   => $branchcode,
2701             rules => [
2702                 'finedays',
2703                 'lengthunit',
2704                 'firstremind',
2705                 'maxsuspensiondays',
2706                 'suspension_chargeperiod',
2707             ]
2708         }
2709     );
2710     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2711     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2712     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2713
2714     return unless $finedays;
2715
2716     # finedays is in days, so hourly loans must multiply by 24
2717     # thus 1 hour late equals 1 day suspension * finedays rate
2718     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2719
2720     # grace period is measured in the same units as the loan
2721     my $grace =
2722       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2723
2724     my $deltadays = DateTime::Duration->new(
2725         days => $chargeable_units
2726     );
2727
2728     if ( $deltadays->subtract($grace)->is_positive() ) {
2729         my $suspension_days = $deltadays * $finedays;
2730
2731         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2732             # No need to / 1 and do not consider / 0
2733             $suspension_days = DateTime::Duration->new(
2734                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2735             );
2736         }
2737
2738         # If the max suspension days is < than the suspension days
2739         # the suspension days is limited to this maximum period.
2740         my $max_sd = $issuing_rule->{maxsuspensiondays};
2741         if ( defined $max_sd && $max_sd ne '' ) {
2742             $max_sd = DateTime::Duration->new( days => $max_sd );
2743             $suspension_days = $max_sd
2744               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2745         }
2746
2747         my ( $has_been_extended );
2748         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $patron->is_debarred ) {
2749             my $debarment = $patron->restrictions->search({type => 'SUSPENSION' },{rows => 1})->single;
2750             if ( $debarment ) {
2751                 $return_date = dt_from_string( $debarment->expiration, 'sql' );
2752                 $has_been_extended = 1;
2753             }
2754         }
2755
2756         my $new_debar_dt;
2757         # Use the calendar or not to calculate the debarment date
2758         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2759             my $calendar = Koha::Calendar->new(
2760                 branchcode => $branchcode,
2761                 days_mode  => 'Calendar'
2762             );
2763             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2764         }
2765         else {
2766             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2767         }
2768         return $new_debar_dt;
2769     }
2770     return;
2771 }
2772
2773 sub _debar_user_on_return {
2774     my ( $patron, $item, $dt_due, $return_date ) = @_;
2775
2776     $return_date //= dt_from_string();
2777
2778     my $new_debar_dt = _calculate_new_debar_dt($patron, $item, $dt_due, $return_date);
2779
2780     return unless $new_debar_dt;
2781
2782     Koha::Patron::Debarments::AddUniqueDebarment({
2783         borrowernumber => $patron->borrowernumber,
2784         expiration     => $new_debar_dt->ymd(),
2785         type           => 'SUSPENSION',
2786     });
2787     # if borrower was already debarred but does not get an extra debarment
2788     my ($new_debarment_str, $is_a_reminder);
2789     if ( $patron->is_debarred ) {
2790         $is_a_reminder = 1;
2791         $new_debarment_str = $patron->debarred;
2792     } else {
2793         $new_debarment_str = $new_debar_dt->ymd();
2794     }
2795     # FIXME Should return a DateTime object
2796     return $new_debarment_str, $is_a_reminder;
2797 }
2798
2799 =head2 _FixOverduesOnReturn
2800
2801    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2802
2803 C<$borrowernumber> borrowernumber
2804
2805 C<$itemnumber> itemnumber
2806
2807 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2808
2809 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2810
2811 Internal function
2812
2813 =cut
2814
2815 sub _FixOverduesOnReturn {
2816     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2817     unless( $borrowernumber ) {
2818         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2819         return;
2820     }
2821     unless( $item ) {
2822         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2823         return;
2824     }
2825     unless( $status ) {
2826         warn "_FixOverduesOnReturn() not supplied valid status";
2827         return;
2828     }
2829
2830     my $schema = Koha::Database->schema;
2831
2832     my $result = $schema->txn_do(
2833         sub {
2834             # check for overdue fine
2835             my $accountlines = Koha::Account::Lines->search(
2836                 {
2837                     borrowernumber  => $borrowernumber,
2838                     itemnumber      => $item,
2839                     debit_type_code => 'OVERDUE',
2840                     status          => 'UNRETURNED'
2841                 }
2842             );
2843             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2844
2845             my $accountline = $accountlines->next;
2846             my $payments = $accountline->credits;
2847
2848             my $amountoutstanding = $accountline->amountoutstanding;
2849             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2850                 $accountline->delete;
2851                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2852             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2853                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2854                 my $credit = $account->add_credit(
2855                     {
2856                         amount     => $amountoutstanding,
2857                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2858                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2859                         interface  => C4::Context->interface,
2860                         type       => 'FORGIVEN',
2861                         item_id    => $item
2862                     }
2863                 );
2864
2865                 $credit->apply({ debits => [ $accountline ] });
2866
2867                 if (C4::Context->preference("FinesLog")) {
2868                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2869                 }
2870             }
2871
2872             $accountline->status($status);
2873             return $accountline->store();
2874         }
2875     );
2876
2877     return $result;
2878 }
2879
2880 =head2 _GetCircControlBranch
2881
2882    my $circ_control_branch = _GetCircControlBranch($item, $patron);
2883
2884 Internal function :
2885
2886 Return the library code to be used to determine which circulation
2887 policy applies to a transaction.  Looks up the CircControl and
2888 HomeOrHoldingBranch system preferences.
2889
2890 C<$item> is an item object.
2891
2892 C<$patron> is a patron object.
2893
2894 =cut
2895
2896 sub _GetCircControlBranch {
2897     my ($item, $patron) = @_;
2898     my $circcontrol = C4::Context->preference('CircControl');
2899     my $branch;
2900
2901     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2902         $branch = C4::Context->userenv->{'branch'};
2903     } elsif ($circcontrol eq 'PatronLibrary') {
2904         $branch = $patron->branchcode;
2905     } else {
2906         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2907         $branch = $item->get_column($branchfield);
2908         # default to item home branch if holdingbranch is used
2909         # and is not defined
2910         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2911             $branch = $item->homebranch;
2912         }
2913     }
2914     return $branch;
2915 }
2916
2917 =head2 GetUpcomingDueIssues
2918
2919   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2920
2921 =cut
2922
2923 sub GetUpcomingDueIssues {
2924     my $params = shift;
2925
2926     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2927     my $dbh = C4::Context->dbh;
2928     my $statement;
2929     $statement = q{
2930         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2931         FROM issues
2932         LEFT JOIN items USING (itemnumber)
2933         LEFT JOIN branches ON branches.branchcode =
2934     };
2935     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2936     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2937     my @bind_parameters = ( $params->{'days_in_advance'} );
2938
2939     my $sth = $dbh->prepare( $statement );
2940     $sth->execute( @bind_parameters );
2941     my $upcoming_dues = $sth->fetchall_arrayref({});
2942
2943     return $upcoming_dues;
2944 }
2945
2946 =head2 CanBookBeRenewed
2947
2948   ($ok,$error,$info) = &CanBookBeRenewed($patron, $issue, $override_limit);
2949
2950 Find out whether a borrowed item may be renewed.
2951
2952 C<$patron> is the patron who currently has the issue.
2953
2954 C<$issue> is the checkout to renew.
2955
2956 C<$override_limit>, if supplied with a true value, causes
2957 the limit on the number of times that the loan can be renewed
2958 (as controlled by the item type) to be ignored. Overriding also allows
2959 to renew sooner than "No renewal before" and to manually renew loans
2960 that are automatically renewed.
2961
2962 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2963 item must currently be on loan to the specified borrower; renewals
2964 must be allowed for the item's type; and the borrower must not have
2965 already renewed the loan.
2966     $error will contain the reason the renewal can not proceed
2967     $info will contain a hash of additional info
2968       currently 'soonest_renew_date' if error is 'too soon'
2969
2970 =cut
2971
2972 sub CanBookBeRenewed {
2973     my ( $patron, $issue, $override_limit, $cron ) = @_;
2974
2975     my $auto_renew = "no";
2976     my $soonest;
2977     my $item = $issue->item;
2978
2979     return ( 0, 'no_item' ) unless $item;
2980     return ( 0, 'no_checkout' ) unless $issue;
2981     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2982     return ( 0, 'item_issued_to_other_patron') if $issue->borrowernumber != $patron->borrowernumber;
2983     return ( 0, 'item_denied_renewal') if $item->is_denied_renewal;
2984
2985        # override_limit will override anything else except on_reserve
2986     unless ( $override_limit ){
2987         my $branchcode = _GetCircControlBranch( $item, $patron );
2988         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2989             {
2990                 categorycode => $patron->categorycode,
2991                 itemtype     => $item->effective_itemtype,
2992                 branchcode   => $branchcode,
2993                 rules => [
2994                     'renewalsallowed',
2995                     'lengthunit',
2996                     'unseen_renewals_allowed'
2997                 ]
2998             }
2999         );
3000
3001         return ( 0, "too_many" )
3002           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
3003
3004         return ( 0, "too_unseen" )
3005           if C4::Context->preference('UnseenRenewals') &&
3006             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
3007             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
3008
3009         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
3010         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
3011         my $restricted  = $patron->is_debarred;
3012         my $hasoverdues = $patron->has_overdues;
3013
3014         if ( $restricted and $restrictionblockrenewing ) {
3015             return ( 0, 'restriction');
3016         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
3017             return ( 0, 'overdue');
3018         }
3019
3020         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
3021             patron     => $patron,
3022             item       => $item,
3023             branchcode => $branchcode,
3024             issue      => $issue
3025         });
3026         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
3027         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
3028         # extra notices being sent. Cron also implies no override
3029         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
3030         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
3031         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
3032     }
3033
3034     if ( C4::Context->preference('UseRecalls') ) {
3035         my $recall = undef;
3036         $recall = $item->check_recalls if $item->can_be_waiting_recall;
3037         if ( defined $recall ) {
3038             if ( $recall->item_level ) {
3039                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
3040                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
3041             } else {
3042                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
3043                 return ( 0, 'recalled' ) unless ( $recall->waiting );
3044             }
3045         }
3046     }
3047
3048     # There is an item level hold on this item, no other item can fill the hold
3049     return ( 0, "on_reserve" )
3050       if ( $item->current_holds->search( { non_priority => 0 } )->count );
3051
3052     my $fillable_holds = Koha::Holds->search(
3053         {
3054             biblionumber => $item->biblionumber,
3055             non_priority => 0,
3056             found        => undef,
3057             reservedate  => { '<=' => \'NOW()' },
3058             suspend      => 0
3059         }
3060     );
3061     if ( $fillable_holds->count ) {
3062         if ( C4::Context->preference('AllowRenewalIfOtherItemsAvailable') ) {
3063             my @possible_holds = $fillable_holds->as_list;
3064
3065             # Get all other items that could possibly fill reserves
3066             # FIXME We could join reserves (or more tables) here to eliminate some checks later
3067             my @other_items = Koha::Items->search({
3068                 biblionumber => $item->biblionumber,
3069                 onloan       => undef,
3070                 notforloan   => 0,
3071                 -not         => { itemnumber => $item->itemnumber } })->as_list;
3072
3073             return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
3074
3075             my %matched_items;
3076             foreach my $possible_hold (@possible_holds) {
3077                 my $fillable = 0;
3078                 my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
3079
3080                 # FIXME: We are not checking whether the item we are renewing can fill the hold
3081
3082                 foreach my $other_item (@other_items) {
3083                   next if defined $matched_items{$other_item->itemnumber};
3084                   next if IsItemOnHoldAndFound( $other_item->itemnumber );
3085                   next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef);
3086                   next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
3087                   # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
3088                   # CanItemBeReserved checks 'rules' and 'policies' which means
3089                   # items will fill holds at checkin that are rejected here
3090                   $fillable = 1;
3091                   $matched_items{$other_item->itemnumber} = 1;
3092                   last;
3093                 }
3094                 return ( 0, "on_reserve" ) unless $fillable;
3095             }
3096         }
3097         else {
3098             my ($status, $matched_reserve, $possible_reserves) = CheckReserves($item);
3099             return ( 0, "on_reserve" ) if $status;
3100         }
3101     }
3102
3103     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
3104     $soonest = GetSoonestRenewDate($patron, $issue);
3105     if ( $soonest > dt_from_string() ){
3106         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
3107     }
3108
3109     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
3110
3111     return ( 1, undef );
3112 }
3113
3114 =head2 AddRenewal
3115
3116   $new_date_due = AddRenewal({
3117       borrowernumber   => $borrowernumber,
3118       itemnumber       => $itemnumber,
3119       branch           => $branch,
3120       [datedue         => $datedue],
3121       [lastreneweddate => $lastreneweddate],
3122       [skipfinecalc    => $skipfinecalc],
3123       [seen            => $seen],
3124       [automatic       => $automatic],
3125       [skip_record_index => $skip_record_index]
3126   });
3127
3128 Renews a loan, returns the updated due date upon success.
3129
3130 C<$borrowernumber> is the borrower number of the patron who currently
3131 has the item.
3132
3133 C<$itemnumber> is the number of the item to renew.
3134
3135 C<$branch> is the library where the renewal took place (if any).
3136            The library that controls the circ policies for the renewal is retrieved from the issues record.
3137
3138 C<$datedue> can be a DateTime object used to set the due date.
3139
3140 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3141 this parameter is not supplied, lastreneweddate is set to the current date.
3142
3143 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3144 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3145 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3146 syspref)
3147
3148 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3149 from the book's item type.
3150
3151 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3152 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3153 fallback to a true value
3154
3155 C<$automatic> is a boolean flag indicating the renewal was triggered automatically and not by a person ( librarian or patron )
3156
3157 C<$skip_record_index> is an optional boolean flag to indicate whether queuing the search indexing
3158 should be skipped for this renewal.
3159
3160 =cut
3161
3162 sub AddRenewal {
3163     my $params = shift;
3164
3165     my $borrowernumber  = $params->{borrowernumber};
3166     my $itemnumber      = $params->{itemnumber};
3167     return unless $itemnumber;
3168
3169     my $branch            = $params->{branch};
3170     my $datedue           = $params->{datedue};
3171     my $lastreneweddate   = $params->{lastreneweddate} // dt_from_string();
3172     my $skipfinecalc      = $params->{skipfinecalc};
3173     my $seen              = $params->{seen};
3174     my $automatic         = $params->{automatic};
3175     my $skip_record_index = $params->{skip_record_index};
3176
3177     # Fallback on a 'seen' renewal
3178     $seen = defined $seen && $seen == 0 ? 0 : 1;
3179
3180     my $item_object   = Koha::Items->find($itemnumber) or return;
3181     my $biblio = $item_object->biblio;
3182     my $issue  = $item_object->checkout;
3183     my $item_unblessed = $item_object->unblessed;
3184
3185     my $renewal_type = $automatic ? "Automatic" : "Manual";
3186
3187     my $dbh = C4::Context->dbh;
3188
3189     return unless $issue;
3190
3191     $borrowernumber ||= $issue->borrowernumber;
3192
3193     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3194         $datedue = dt_from_string($datedue, 'sql');
3195     }
3196
3197     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3198     my $patron_unblessed = $patron->unblessed;
3199
3200     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_object, $patron) );
3201
3202     my $schema = Koha::Database->schema;
3203     $schema->txn_do(sub{
3204
3205         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3206             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3207         }
3208         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3209
3210         # If the due date wasn't specified, calculate it by adding the
3211         # book's loan length to today's date or the current due date
3212         # based on the value of the RenewalPeriodBase syspref.
3213         my $itemtype = $item_object->effective_itemtype;
3214         unless ($datedue) {
3215
3216             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3217                                             dt_from_string( $issue->date_due, 'sql' ) :
3218                                             dt_from_string();
3219             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron, 'is a renewal');
3220         }
3221
3222         my $fees = Koha::Charges::Fees->new(
3223             {
3224                 patron    => $patron,
3225                 library   => $circ_library,
3226                 item      => $item_object,
3227                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3228                 to_date   => dt_from_string($datedue),
3229             }
3230         );
3231
3232         # Increment the unseen renewals, if appropriate
3233         # We only do so if the syspref is enabled and
3234         # a maximum value has been set in the circ rules
3235         my $unseen_renewals = $issue->unseen_renewals;
3236         if (C4::Context->preference('UnseenRenewals')) {
3237             my $rule = Koha::CirculationRules->get_effective_rule(
3238                 {   categorycode => $patron->categorycode,
3239                     itemtype     => $item_object->effective_itemtype,
3240                     branchcode   => $circ_library->branchcode,
3241                     rule_name    => 'unseen_renewals_allowed'
3242                 }
3243             );
3244             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3245                 $unseen_renewals++;
3246             } else {
3247                 # If the renewal is seen, unseen should revert to 0
3248                 $unseen_renewals = 0;
3249             }
3250         }
3251
3252         # Update the issues record to have the new due date, and a new count
3253         # of how many times it has been renewed.
3254         my $renews = ( $issue->renewals_count || 0 ) + 1;
3255         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3256
3257         eval{
3258             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3259         };
3260         if( $sth->err ){
3261             Koha::Exceptions::Checkout::FailedRenewal->throw(
3262                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3263             );
3264         }
3265
3266         # Update the renewal count on the item, and tell zebra to reindex
3267         $renews = ( $item_object->renewals || 0 ) + 1;
3268         $item_object->renewals($renews);
3269         $item_object->onloan($datedue);
3270         # Don't index as we are in a transaction, skip hardcoded here
3271         $item_object->store({ log_action => 0, skip_record_index => 1 });
3272
3273         # Charge a new rental fee, if applicable
3274         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3275         if ( $charge > 0 ) {
3276             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3277         }
3278
3279         # Charge a new accumulate rental fee, if applicable
3280         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3281         if ( $itemtype_object ) {
3282             my $accumulate_charge = $fees->accumulate_rentalcharge();
3283             if ( $accumulate_charge > 0 ) {
3284                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3285             }
3286             $charge += $accumulate_charge;
3287         }
3288
3289         # Send a renewal slip according to checkout alert preferencei
3290         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3291             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3292             my %conditions        = (
3293                 branchcode   => $branch,
3294                 categorycode => $patron->categorycode,
3295                 item_type    => $itemtype,
3296                 notification => 'CHECKOUT',
3297             );
3298             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3299                 SendCirculationAlert(
3300                     {
3301                         type     => 'RENEWAL',
3302                         item     => $item_unblessed,
3303                         borrower => $patron->unblessed,
3304                         branch   => $branch,
3305                     }
3306                 );
3307             }
3308         }
3309
3310         # Remove any OVERDUES related debarment if the borrower has no overdues
3311         my $overdue_restrictions = $patron->restrictions->search({ type => 'OVERDUES' });
3312         if ( $patron
3313           && $patron->is_debarred
3314           && ! $patron->has_overdues
3315           && $overdue_restrictions->count
3316         ) {
3317             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3318         }
3319
3320         # Add renewal record
3321         my $renewal = Koha::Checkouts::Renewal->new(
3322             {
3323                 checkout_id  => $issue->issue_id,
3324                 interface    => C4::Context->interface,
3325                 renewal_type => $renewal_type,
3326                 renewer_id   => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3327                 seen         => $seen,
3328             }
3329         )->store();
3330
3331         # Add the renewal to stats
3332         C4::Stats::UpdateStats(
3333             {
3334                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3335                 type           => 'renew',
3336                 amount         => $charge,
3337                 itemnumber     => $itemnumber,
3338                 itemtype       => $itemtype,
3339                 location       => $item_object->location,
3340                 borrowernumber => $borrowernumber,
3341                 ccode          => $item_object->ccode,
3342                 categorycode   => $patron->categorycode,
3343                 interface      => C4::Context->interface,
3344             }
3345         );
3346
3347         #Log the renewal
3348         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3349
3350         Koha::Plugins->call('after_circ_action', {
3351             action  => 'renewal',
3352             payload => {
3353                 checkout  => $issue->get_from_storage
3354             }
3355         });
3356     });
3357
3358     unless( $skip_record_index ){
3359         # We index now, after the transaction is committed
3360         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
3361         $indexer->index_records( $item_object->biblionumber, "specialUpdate", "biblioserver" );
3362     }
3363
3364     return $datedue;
3365 }
3366
3367 sub GetRenewCount {
3368     # check renewal status
3369     my ( $borrowernumber_or_patron, $itemnumber_or_item ) = @_;
3370
3371     my $dbh           = C4::Context->dbh;
3372     my $renewcount    = 0;
3373     my $unseencount    = 0;
3374     my $renewsallowed = 0;
3375     my $unseenallowed = 0;
3376     my $renewsleft    = 0;
3377     my $unseenleft    = 0;
3378     my $patron = blessed $borrowernumber_or_patron ?
3379         $borrowernumber_or_patron : Koha::Patrons->find($borrowernumber_or_patron);
3380     my $item = blessed $itemnumber_or_item ?
3381         $itemnumber_or_item : Koha::Items->find($itemnumber_or_item);
3382
3383     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3384
3385     # Look in the issues table for this item, lent to this borrower,
3386     # and not yet returned.
3387
3388     # FIXME - I think this function could be redone to use only one SQL call.
3389     my $sth = $dbh->prepare(q{
3390         SELECT * FROM issues
3391         WHERE  (borrowernumber = ?) AND (itemnumber = ?)
3392     });
3393     $sth->execute( $patron->borrowernumber, $item->itemnumber );
3394     my $data = $sth->fetchrow_hashref;
3395     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3396     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3397     # $item and $borrower should be calculated
3398     my $branchcode = _GetCircControlBranch($item, $patron);
3399
3400     my $rules = Koha::CirculationRules->get_effective_rules(
3401         {
3402             categorycode => $patron->categorycode,
3403             itemtype     => $item->effective_itemtype,
3404             branchcode   => $branchcode,
3405             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3406         }
3407     );
3408     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3409     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3410         $rules->{unseen_renewals_allowed} :
3411         0;
3412     $renewsleft    = $renewsallowed - $renewcount;
3413     $unseenleft    = $unseenallowed - $unseencount;
3414     if($renewsleft < 0){ $renewsleft = 0; }
3415     if($unseenleft < 0){ $unseenleft = 0; }
3416     return (
3417         $renewcount,
3418         $renewsallowed,
3419         $renewsleft,
3420         $unseencount,
3421         $unseenallowed,
3422         $unseenleft
3423     );
3424 }
3425
3426 =head2 GetSoonestRenewDate
3427
3428   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($patron, $issue);
3429
3430 Find out the soonest possible renew date of a borrowed item.
3431
3432 C<$patron> is the patron who currently has the item on loan.
3433
3434 C<$issue> is the the item issue.
3435
3436 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3437 renew date, based on the value "No renewal before" of the applicable
3438 issuing rule. Returns the current date if the item can already be
3439 renewed, and returns undefined if the patron, item, or checkout
3440 cannot be found.
3441
3442 =cut
3443
3444 sub GetSoonestRenewDate {
3445     my ( $patron, $issue ) = @_;
3446     return unless $issue;
3447     return unless $patron;
3448
3449     my $item = $issue->item;
3450     return unless $item;
3451
3452     my $dbh = C4::Context->dbh;
3453
3454     my $branchcode = _GetCircControlBranch( $item, $patron );
3455     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3456         {   categorycode => $patron->categorycode,
3457             itemtype     => $item->effective_itemtype,
3458             branchcode   => $branchcode,
3459             rules => [
3460                 'norenewalbefore',
3461                 'lengthunit',
3462             ]
3463         }
3464     );
3465
3466     my $now = dt_from_string;
3467
3468     if ( defined $issuing_rule->{norenewalbefore}
3469         and $issuing_rule->{norenewalbefore} ne "" )
3470     {
3471         my $soonestrenewal =
3472           dt_from_string( $issue->date_due )->subtract(
3473             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3474
3475         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3476             and $issuing_rule->{lengthunit} eq 'days' )
3477         {
3478             $soonestrenewal->truncate( to => 'day' );
3479         }
3480         return $soonestrenewal;
3481     } elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
3482         # Checkouts with auto-renewing fall back to due date
3483         my $soonestrenewal = dt_from_string( $issue->date_due );
3484         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3485             and $issuing_rule->{lengthunit} eq 'days' )
3486         {
3487             $soonestrenewal->truncate( to => 'day' );
3488         }
3489         return $soonestrenewal;
3490     }
3491     return $now;
3492 }
3493
3494 =head2 GetLatestAutoRenewDate
3495
3496   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($patron, $issue);
3497
3498 Find out the latest possible auto renew date of a borrowed item.
3499
3500 C<$patron> is the patron who currently has the item on loan.
3501
3502 C<$issue> is the item issue.
3503
3504 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3505 auto renew date, based on the value "No auto renewal after" and the "No auto
3506 renewal after (hard limit) of the applicable issuing rule.
3507 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3508 or item cannot be found.
3509
3510 =cut
3511
3512 sub GetLatestAutoRenewDate {
3513     my ( $patron, $issue ) = @_;
3514     return unless $issue;
3515     return unless $patron;
3516
3517     my $item = $issue->item;
3518     return unless $item;
3519
3520     my $dbh = C4::Context->dbh;
3521     my $branchcode = _GetCircControlBranch( $item, $patron );
3522
3523     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3524         {
3525             categorycode => $patron->categorycode,
3526             itemtype     => $item->effective_itemtype,
3527             branchcode   => $branchcode,
3528             rules => [
3529                 'no_auto_renewal_after',
3530                 'no_auto_renewal_after_hard_limit',
3531                 'lengthunit',
3532             ]
3533         }
3534     );
3535
3536     return unless $circulation_rules;
3537     return
3538       if ( not $circulation_rules->{no_auto_renewal_after}
3539             or $circulation_rules->{no_auto_renewal_after} eq '' )
3540       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3541              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3542
3543     my $maximum_renewal_date;
3544     if ( $circulation_rules->{no_auto_renewal_after} ) {
3545         $maximum_renewal_date = dt_from_string($issue->issuedate);
3546         $maximum_renewal_date->add(
3547             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3548         );
3549     }
3550
3551     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3552         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3553         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3554     }
3555     return $maximum_renewal_date;
3556 }
3557
3558
3559 =head2 GetIssuingCharges
3560
3561   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3562
3563 Calculate how much it would cost for a given patron to borrow a given
3564 item, including any applicable discounts.
3565
3566 C<$itemnumber> is the item number of item the patron wishes to borrow.
3567
3568 C<$borrowernumber> is the patron's borrower number.
3569
3570 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3571 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3572 if it's a video).
3573
3574 =cut
3575
3576 sub GetIssuingCharges {
3577
3578     # calculate charges due
3579     my ( $itemnumber, $borrowernumber ) = @_;
3580     my $charge = 0;
3581     my $dbh    = C4::Context->dbh;
3582     my $item_type;
3583
3584     # Get the book's item type and rental charge (via its biblioitem).
3585     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3586         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3587     $charge_query .= (C4::Context->preference('item-level_itypes'))
3588         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3589         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3590
3591     $charge_query .= ' WHERE items.itemnumber =?';
3592
3593     my $sth = $dbh->prepare($charge_query);
3594     $sth->execute($itemnumber);
3595     my $patron;
3596     if ( my $item_data = $sth->fetchrow_hashref ) {
3597         $item_type = $item_data->{itemtype};
3598         $charge    = $item_data->{rentalcharge};
3599         if ($charge) {
3600             # FIXME This should follow CircControl
3601             my $branch = C4::Context::mybranch();
3602             $patron //= Koha::Patrons->find( $borrowernumber );
3603             my $discount = Koha::CirculationRules->get_effective_rule({
3604                 categorycode => $patron->categorycode,
3605                 branchcode   => $branch,
3606                 itemtype     => $item_type,
3607                 rule_name    => 'rentaldiscount'
3608             });
3609             if ($discount) {
3610                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3611             }
3612             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3613         }
3614     }
3615
3616     return ( $charge, $item_type );
3617 }
3618
3619 =head2 AddIssuingCharge
3620
3621   &AddIssuingCharge( $checkout, $charge, $type )
3622
3623 =cut
3624
3625 sub AddIssuingCharge {
3626     my ( $checkout, $charge, $type ) = @_;
3627
3628     # FIXME What if checkout does not exist?
3629
3630     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3631     my $accountline = $account->add_debit(
3632         {
3633             amount      => $charge,
3634             note        => undef,
3635             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3636             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3637             interface   => C4::Context->interface,
3638             type        => $type,
3639             item_id     => $checkout->itemnumber,
3640             issue_id    => $checkout->issue_id,
3641         }
3642     );
3643 }
3644
3645 =head2 GetTransfersFromTo
3646
3647   @results = GetTransfersFromTo($frombranch,$tobranch);
3648
3649 Returns the list of pending transfers between $from and $to branch
3650
3651 =cut
3652
3653 sub GetTransfersFromTo {
3654     my ( $frombranch, $tobranch ) = @_;
3655     return unless ( $frombranch && $tobranch );
3656     my $dbh   = C4::Context->dbh;
3657     my $query = "
3658         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3659         FROM   branchtransfers
3660         WHERE  frombranch=?
3661           AND  tobranch=?
3662           AND datecancelled IS NULL
3663           AND datesent IS NOT NULL
3664           AND datearrived IS NULL
3665     ";
3666     my $sth = $dbh->prepare($query);
3667     $sth->execute( $frombranch, $tobranch );
3668     my @gettransfers;
3669
3670     while ( my $data = $sth->fetchrow_hashref ) {
3671         push @gettransfers, $data;
3672     }
3673     return (@gettransfers);
3674 }
3675
3676 =head2 SendCirculationAlert
3677
3678 Send out a C<check-in> or C<checkout> alert using the messaging system.
3679
3680 B<Parameters>:
3681
3682 =over 4
3683
3684 =item type
3685
3686 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3687
3688 =item item
3689
3690 Hashref of information about the item being checked in or out.
3691
3692 =item borrower
3693
3694 Hashref of information about the borrower of the item.
3695
3696 =item branch
3697
3698 The branchcode from where the checkout or check-in took place.
3699
3700 =back
3701
3702 B<Example>:
3703
3704     SendCirculationAlert({
3705         type     => 'CHECKOUT',
3706         item     => $item,
3707         borrower => $borrower,
3708         branch   => $branch,
3709     });
3710
3711 =cut
3712
3713 sub SendCirculationAlert {
3714     my ($opts) = @_;
3715     my ($type, $item, $borrower, $branch, $issue) =
3716         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3717     my %message_name = (
3718         CHECKIN  => 'Item_Check_in',
3719         CHECKOUT => 'Item_Checkout',
3720         RENEWAL  => 'Item_Checkout',
3721     );
3722     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3723         borrowernumber => $borrower->{borrowernumber},
3724         message_name   => $message_name{$type},
3725     });
3726
3727
3728     my $tables = {
3729         items => $item->{itemnumber},
3730         biblio      => $item->{biblionumber},
3731         biblioitems => $item->{biblionumber},
3732         borrowers   => $borrower,
3733         branches    => $branch,
3734     };
3735
3736     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3737     # See C4::Letters:: _parseletter_sth
3738     if( $type eq 'CHECKIN' ){
3739         $tables->{old_issues} = $issue->issue_id;
3740     } else {
3741         $tables->{issues} = $item->{itemnumber};
3742     }
3743
3744     my $schema = Koha::Database->new->schema;
3745     my @transports = keys %{ $borrower_preferences->{transports} };
3746
3747     # From the MySQL doc:
3748     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3749     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3750     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3751     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3752
3753     for my $mtt (@transports) {
3754         my $letter =  C4::Letters::GetPreparedLetter (
3755             module => 'circulation',
3756             letter_code => $type,
3757             branchcode => $branch,
3758             message_transport_type => $mtt,
3759             lang => $borrower->{lang},
3760             tables => $tables,
3761         ) or next;
3762
3763         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3764         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3765         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3766         unless ( $message ) {
3767             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3768             my $patron = Koha::Patrons->find($borrower->{borrowernumber});
3769             C4::Message->enqueue($letter, $patron, $mtt);
3770         } else {
3771             $message->append($letter);
3772             $message->update;
3773         }
3774         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3775     }
3776
3777     return;
3778 }
3779
3780 =head2 updateWrongTransfer
3781
3782   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3783
3784 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3785
3786 =cut
3787
3788 sub updateWrongTransfer {
3789         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3790
3791     # first step: cancel the original transfer
3792     my $item = Koha::Items->find($itemNumber);
3793     my $transfer = $item->get_transfer;
3794     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3795
3796     # second step: create a new transfer to the right location
3797     my $new_transfer = $item->request_transfer(
3798         {
3799             to            => $transfer->to_library,
3800             reason        => $transfer->reason,
3801             comment       => $transfer->comments,
3802             ignore_limits => 1,
3803             enqueue       => 1
3804         }
3805     );
3806
3807     return $new_transfer;
3808 }
3809
3810 =head2 CalcDateDue
3811
3812 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3813
3814 this function calculates the due date given the start date and configured circulation rules,
3815 checking against the holidays calendar as per the daysmode circulation rule.
3816 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3817 C<$itemtype>  = itemtype code of item in question
3818 C<$branch>  = location whose calendar to use
3819 C<$patron> = Patron object
3820 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3821
3822 =cut
3823
3824 sub CalcDateDue {
3825     my ( $startdate, $itemtype, $branch, $patron, $isrenewal ) = @_;
3826
3827     $isrenewal ||= 0;
3828
3829     # loanlength now a href
3830     my $loanlength =
3831             GetLoanLength( $patron->categorycode, $itemtype, $branch );
3832
3833     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3834             ? qq{renewalperiod}
3835             : qq{issuelength};
3836
3837     my $datedue;
3838     if ( $startdate ) {
3839         if (ref $startdate ne 'DateTime' ) {
3840             $datedue = dt_from_string($datedue);
3841         } else {
3842             $datedue = $startdate->clone;
3843         }
3844     } else {
3845         $datedue = dt_from_string()->truncate( to => 'minute' );
3846     }
3847
3848
3849     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3850         {
3851             categorycode => $patron->categorycode,
3852             itemtype     => $itemtype,
3853             branchcode   => $branch,
3854         }
3855     );
3856
3857     # calculate the datedue as normal
3858     if ( $daysmode eq 'Days' )
3859     {    # ignoring calendar
3860         if ( $loanlength->{lengthunit} eq 'hours' ) {
3861             $datedue->add( hours => $loanlength->{$length_key} );
3862         } else {    # days
3863             $datedue->add( days => $loanlength->{$length_key} );
3864             $datedue->set_hour(23);
3865             $datedue->set_minute(59);
3866         }
3867     } else {
3868         my $dur;
3869         if ($loanlength->{lengthunit} eq 'hours') {
3870             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3871         }
3872         else { # days
3873             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3874         }
3875         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3876         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3877         if ($loanlength->{lengthunit} eq 'days') {
3878             $datedue->set_hour(23);
3879             $datedue->set_minute(59);
3880         }
3881     }
3882
3883     # if Hard Due Dates are used, retrieve them and apply as necessary
3884     my ( $hardduedate, $hardduedatecompare ) =
3885       GetHardDueDate( $patron->categorycode, $itemtype, $branch );
3886     if ($hardduedate) {    # hardduedates are currently dates
3887         $hardduedate->truncate( to => 'minute' );
3888         $hardduedate->set_hour(23);
3889         $hardduedate->set_minute(59);
3890         my $cmp = DateTime->compare( $hardduedate, $datedue );
3891
3892 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3893 # if the calculated date is before the 'after' Hard Due Date (floor), override
3894 # if the hard due date is set to 'exactly', overrride
3895         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3896             $datedue = $hardduedate->clone;
3897         }
3898
3899         # in all other cases, keep the date due as it is
3900
3901     }
3902
3903     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3904     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3905         my $expiry_dt = dt_from_string( $patron->dateexpiry, 'iso', 'floating');
3906         if( $expiry_dt ) { #skip empty expiry date..
3907             $expiry_dt->set( hour => 23, minute => 59);
3908             my $d1= $datedue->clone->set_time_zone('floating');
3909             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3910                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3911             }
3912         }
3913         if ( $daysmode ne 'Days' ) {
3914           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3915           if ( $calendar->is_holiday($datedue) ) {
3916               # Don't return on a closed day
3917               $datedue = $calendar->prev_open_days( $datedue, 1 );
3918           }
3919         }
3920     }
3921
3922     return $datedue;
3923 }
3924
3925
3926 sub CheckValidBarcode{
3927 my ($barcode) = @_;
3928 my $dbh = C4::Context->dbh;
3929 my $query=qq|SELECT count(*)
3930              FROM items
3931              WHERE barcode=?
3932             |;
3933 my $sth = $dbh->prepare($query);
3934 $sth->execute($barcode);
3935 my $exist=$sth->fetchrow ;
3936 return $exist;
3937 }
3938
3939 =head2 IsBranchTransferAllowed
3940
3941   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3942
3943 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3944
3945 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3946 Koha::Item->can_be_transferred.
3947
3948 =cut
3949
3950 sub IsBranchTransferAllowed {
3951         my ( $toBranch, $fromBranch, $code ) = @_;
3952
3953         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3954
3955         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3956         my $dbh = C4::Context->dbh;
3957
3958         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3959         $sth->execute( $toBranch, $fromBranch, $code );
3960         my $limit = $sth->fetchrow_hashref();
3961
3962         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3963         if ( $limit->{'limitId'} ) {
3964                 return 0;
3965         } else {
3966                 return 1;
3967         }
3968 }
3969
3970 =head2 CreateBranchTransferLimit
3971
3972   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3973
3974 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3975
3976 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3977
3978 =cut
3979
3980 sub CreateBranchTransferLimit {
3981    my ( $toBranch, $fromBranch, $code ) = @_;
3982    return unless defined($toBranch) && defined($fromBranch);
3983    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3984
3985    my $dbh = C4::Context->dbh;
3986
3987    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3988    return $sth->execute( $code, $toBranch, $fromBranch );
3989 }
3990
3991 =head2 DeleteBranchTransferLimits
3992
3993     my $result = DeleteBranchTransferLimits($frombranch);
3994
3995 Deletes all the library transfer limits for one library.  Returns the
3996 number of limits deleted, 0e0 if no limits were deleted, or undef if
3997 no arguments are supplied.
3998
3999 Deprecated in favor of Koha::Item::Transfer::Limits->search({
4000     fromBranch => $fromBranch
4001     })->delete.
4002
4003 =cut
4004
4005 sub DeleteBranchTransferLimits {
4006     my $branch = shift;
4007     return unless defined $branch;
4008     my $dbh    = C4::Context->dbh;
4009     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
4010     return $sth->execute($branch);
4011 }
4012
4013 sub ReturnLostItem{
4014     my ( $borrowernumber, $itemnum ) = @_;
4015     MarkIssueReturned( $borrowernumber, $itemnum );
4016 }
4017
4018 =head2 LostItem
4019
4020   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
4021
4022 The final optional parameter, C<$params>, expected to contain
4023 'skip_record_index' key, which relayed down to Koha::Item/store,
4024 there it prevents calling of ModZebra index_records,
4025 which takes most of the time in batch adds/deletes: index_records better
4026 to be called later in C<additem.pl> after the whole loop.
4027
4028 $params:
4029     skip_record_index => 1|0
4030
4031 =cut
4032
4033 sub LostItem{
4034     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
4035
4036     unless ( $mark_lost_from ) {
4037         # Temporary check to avoid regressions
4038         die q|LostItem called without $mark_lost_from, check the API.|;
4039     }
4040
4041     my $mark_returned;
4042     if ( $force_mark_returned ) {
4043         $mark_returned = 1;
4044     } else {
4045         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
4046         $mark_returned = ( $pref =~ m|$mark_lost_from| );
4047     }
4048
4049     my $dbh = C4::Context->dbh();
4050     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
4051                            FROM issues
4052                            JOIN items USING (itemnumber)
4053                            JOIN biblio USING (biblionumber)
4054                            WHERE issues.itemnumber=?");
4055     $sth->execute($itemnumber);
4056     my $issues=$sth->fetchrow_hashref();
4057
4058     # If a borrower lost the item, add a replacement cost to the their record
4059     if ( my $borrowernumber = $issues->{borrowernumber} ){
4060         my $patron = Koha::Patrons->find( $borrowernumber );
4061
4062         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
4063         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
4064
4065         if (C4::Context->preference('WhenLostChargeReplacementFee')){
4066             C4::Accounts::chargelostitem(
4067                 $borrowernumber,
4068                 $itemnumber,
4069                 $issues->{'replacementprice'},
4070                 sprintf( "%s %s %s",
4071                     $issues->{'title'}          || q{},
4072                     $issues->{'barcode'}        || q{},
4073                     $issues->{'itemcallnumber'} || q{},
4074                 ),
4075             );
4076             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
4077             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
4078         }
4079
4080         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
4081     }
4082
4083     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
4084     my $item = Koha::Items->find($itemnumber);
4085     my $transfers = $item->get_transfers;
4086     while (my $transfer = $transfers->next) {
4087         $transfer->cancel({ reason => 'ItemLost', force => 1 });
4088     }
4089 }
4090
4091 sub GetOfflineOperations {
4092     my $dbh = C4::Context->dbh;
4093     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
4094     $sth->execute(C4::Context->userenv->{'branch'});
4095     my $results = $sth->fetchall_arrayref({});
4096     return $results;
4097 }
4098
4099 sub GetOfflineOperation {
4100     my $operationid = shift;
4101     return unless $operationid;
4102     my $dbh = C4::Context->dbh;
4103     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
4104     $sth->execute( $operationid );
4105     return $sth->fetchrow_hashref;
4106 }
4107
4108 sub AddOfflineOperation {
4109     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
4110     my $dbh = C4::Context->dbh;
4111     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
4112     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
4113     return "Added.";
4114 }
4115
4116 sub DeleteOfflineOperation {
4117     my $dbh = C4::Context->dbh;
4118     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4119     $sth->execute( shift );
4120     return "Deleted.";
4121 }
4122
4123 sub ProcessOfflineOperation {
4124     my $operation = shift;
4125
4126     my $report;
4127     if ( $operation->{action} eq 'return' ) {
4128         $report = ProcessOfflineReturn( $operation );
4129     } elsif ( $operation->{action} eq 'issue' ) {
4130         $report = ProcessOfflineIssue( $operation );
4131     } elsif ( $operation->{action} eq 'payment' ) {
4132         $report = ProcessOfflinePayment( $operation );
4133     }
4134
4135     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4136
4137     return $report;
4138 }
4139
4140 sub ProcessOfflineReturn {
4141     my $operation = shift;
4142
4143     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4144
4145     if ( $item ) {
4146         my $itemnumber = $item->itemnumber;
4147         my $issue = $item->checkout;
4148         if ( $issue ) {
4149             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4150             ModDateLastSeen( $itemnumber, $leave_item_lost );
4151             MarkIssueReturned(
4152                 $issue->borrowernumber,
4153                 $itemnumber,
4154                 $operation->{timestamp},
4155             );
4156             $item->onloan(undef);
4157             $item->store({ log_action => 0 });
4158             return "Success.";
4159         } else {
4160             return "Item not issued.";
4161         }
4162     } else {
4163         return "Item not found.";
4164     }
4165 }
4166
4167 sub ProcessOfflineIssue {
4168     my $operation = shift;
4169
4170     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4171
4172     if ( $patron ) {
4173         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4174         unless ($item) {
4175             return "Barcode not found.";
4176         }
4177         my $itemnumber = $item->itemnumber;
4178         my $issue = $item->checkout;
4179
4180         if ( $issue and ( $issue->borrowernumber ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4181             MarkIssueReturned(
4182                 $issue->borrowernumber,
4183                 $itemnumber,
4184                 $operation->{timestamp},
4185             );
4186         }
4187         AddIssue(
4188             $patron,
4189             $operation->{'barcode'},
4190             undef,
4191             undef,
4192             $operation->{timestamp},
4193             undef,
4194         );
4195         return "Success.";
4196     } else {
4197         return "Borrower not found.";
4198     }
4199 }
4200
4201 sub ProcessOfflinePayment {
4202     my $operation = shift;
4203
4204     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4205
4206     $patron->account->pay(
4207         {
4208             amount     => $operation->{amount},
4209             library_id => $operation->{branchcode},
4210             interface  => 'koc'
4211         }
4212     );
4213
4214     return "Success.";
4215 }
4216
4217 =head2 TransferSlip
4218
4219   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4220
4221   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4222
4223 =cut
4224
4225 sub TransferSlip {
4226     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4227
4228     my $item =
4229       $itemnumber
4230       ? Koha::Items->find($itemnumber)
4231       : Koha::Items->find( { barcode => $barcode } );
4232
4233     $item or return;
4234
4235     return C4::Letters::GetPreparedLetter (
4236         module => 'circulation',
4237         letter_code => 'TRANSFERSLIP',
4238         branchcode => $branch,
4239         tables => {
4240             'branches'    => $to_branch,
4241             'biblio'      => $item->biblionumber,
4242             'items'       => $item->unblessed,
4243         },
4244     );
4245 }
4246
4247 =head2 CheckIfIssuedToPatron
4248
4249   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4250
4251   Return 1 if any record item is issued to patron, otherwise return 0
4252
4253 =cut
4254
4255 sub CheckIfIssuedToPatron {
4256     my ($borrowernumber, $biblionumber) = @_;
4257
4258     my $dbh = C4::Context->dbh;
4259     my $query = q|
4260         SELECT COUNT(*) FROM issues
4261         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4262         WHERE items.biblionumber = ?
4263         AND issues.borrowernumber = ?
4264     |;
4265     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4266     return 1 if $is_issued;
4267     return;
4268 }
4269
4270 =head2 IsItemIssued
4271
4272   IsItemIssued( $itemnumber )
4273
4274   Return 1 if the item is on loan, otherwise return 0
4275
4276 =cut
4277
4278 sub IsItemIssued {
4279     my $itemnumber = shift;
4280     my $dbh = C4::Context->dbh;
4281     my $sth = $dbh->prepare(q{
4282         SELECT COUNT(*)
4283         FROM issues
4284         WHERE itemnumber = ?
4285     });
4286     $sth->execute($itemnumber);
4287     return $sth->fetchrow;
4288 }
4289
4290 =head2 GetAgeRestriction
4291
4292   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4293   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4294
4295   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4296   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4297
4298 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4299 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4300 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4301          Negative days mean the borrower has gone past the age restriction age.
4302
4303 =cut
4304
4305 sub GetAgeRestriction {
4306     my ($record_restrictions, $borrower) = @_;
4307     my $markers = C4::Context->preference('AgeRestrictionMarker');
4308
4309     return unless $record_restrictions;
4310     # Split $record_restrictions to something like FSK 16 or PEGI 6
4311     my @values = split ' ', uc($record_restrictions);
4312     return unless @values;
4313
4314     # Search first occurrence of one of the markers
4315     my @markers = split /\|/, uc($markers);
4316     return unless @markers;
4317
4318     my $index            = 0;
4319     my $restriction_year = 0;
4320     for my $value (@values) {
4321         $index++;
4322         for my $marker (@markers) {
4323             $marker =~ s/^\s+//;    #remove leading spaces
4324             $marker =~ s/\s+$//;    #remove trailing spaces
4325             if ( $marker eq $value ) {
4326                 if ( $index <= $#values ) {
4327                     $restriction_year += $values[$index];
4328                 }
4329                 last;
4330             }
4331             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4332
4333                 # Perhaps it is something like "K16" (as in Finland)
4334                 $restriction_year += $1;
4335                 last;
4336             }
4337         }
4338         last if ( $restriction_year > 0 );
4339     }
4340
4341     #Check if the borrower is age restricted for this material and for how long.
4342     if ($restriction_year && $borrower) {
4343         if ( $borrower->{'dateofbirth'} ) {
4344             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4345             $alloweddate[0] += $restriction_year;
4346
4347             #Prevent runime eror on leap year (invalid date)
4348             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4349                 $alloweddate[2] = 28;
4350             }
4351
4352             #Get how many days the borrower has to reach the age restriction
4353             my @Today = split /-/, dt_from_string()->ymd();
4354             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4355             #Negative days means the borrower went past the age restriction age
4356             return ($restriction_year, $daysToAgeRestriction);
4357         }
4358     }
4359
4360     return ($restriction_year);
4361 }
4362
4363
4364 =head2 GetPendingOnSiteCheckouts
4365
4366 =cut
4367
4368 sub GetPendingOnSiteCheckouts {
4369     my $dbh = C4::Context->dbh;
4370     return $dbh->selectall_arrayref(q|
4371         SELECT
4372           items.barcode,
4373           items.biblionumber,
4374           items.itemnumber,
4375           items.itemnotes,
4376           items.itemcallnumber,
4377           items.location,
4378           issues.date_due,
4379           issues.branchcode,
4380           issues.date_due < NOW() AS is_overdue,
4381           biblio.author,
4382           biblio.title,
4383           borrowers.firstname,
4384           borrowers.surname,
4385           borrowers.cardnumber,
4386           borrowers.borrowernumber
4387         FROM items
4388         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4389         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4390         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4391         WHERE issues.onsite_checkout = 1
4392     |, { Slice => {} } );
4393 }
4394
4395 sub GetTopIssues {
4396     my ($params) = @_;
4397
4398     my ($count, $branch, $itemtype, $ccode, $newness)
4399         = @$params{qw(count branch itemtype ccode newness)};
4400
4401     my $dbh = C4::Context->dbh;
4402     my $query = q{
4403         SELECT * FROM (
4404         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4405           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4406           i.ccode, SUM(i.issues) AS count
4407         FROM biblio b
4408         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4409         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4410     };
4411
4412     my (@where_strs, @where_args);
4413
4414     if ($branch) {
4415         push @where_strs, 'i.homebranch = ?';
4416         push @where_args, $branch;
4417     }
4418     if ($itemtype) {
4419         if (C4::Context->preference('item-level_itypes')){
4420             push @where_strs, 'i.itype = ?';
4421             push @where_args, $itemtype;
4422         } else {
4423             push @where_strs, 'bi.itemtype = ?';
4424             push @where_args, $itemtype;
4425         }
4426     }
4427     if ($ccode) {
4428         push @where_strs, 'i.ccode = ?';
4429         push @where_args, $ccode;
4430     }
4431     if ($newness) {
4432         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4433         push @where_args, $newness;
4434     }
4435
4436     if (@where_strs) {
4437         $query .= 'WHERE ' . join(' AND ', @where_strs);
4438     }
4439
4440     $query .= q{
4441         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4442           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4443           i.ccode
4444         ORDER BY count DESC
4445     };
4446
4447     $query .= q{ ) xxx WHERE count > 0 };
4448     $count = int($count);
4449     if ($count > 0) {
4450         $query .= "LIMIT $count";
4451     }
4452
4453     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4454
4455     return @$rows;
4456 }
4457
4458 =head2 Internal methods
4459
4460 =cut
4461
4462 sub _CalculateAndUpdateFine {
4463     my ($params) = @_;
4464
4465     my $borrower    = $params->{borrower};
4466     my $item        = $params->{item};
4467     my $issue       = $params->{issue};
4468     my $return_date = $params->{return_date};
4469
4470     unless ($borrower) { carp "No borrower passed in!" && return; }
4471     unless ($item)     { carp "No item passed in!"     && return; }
4472     unless ($issue)    { carp "No issue passed in!"    && return; }
4473
4474     my $datedue = dt_from_string( $issue->date_due );
4475
4476     # we only need to calculate and change the fines if we want to do that on return
4477     # Should be on for hourly loans
4478     my $control = C4::Context->preference('CircControl');
4479     my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
4480     my $control_branchcode =
4481         ( $control eq 'ItemHomeLibrary' ) ? $item->{$branch_type}
4482       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4483       :                                     $issue->branchcode;
4484
4485     my $date_returned = $return_date ? $return_date : dt_from_string();
4486
4487     my ( $amount, $unitcounttotal, $unitcount  ) =
4488       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4489
4490     if ( C4::Context->preference('finesMode') eq 'production' ) {
4491         if ( $amount > 0 ) {
4492             C4::Overdues::UpdateFine({
4493                 issue_id       => $issue->issue_id,
4494                 itemnumber     => $issue->itemnumber,
4495                 borrowernumber => $issue->borrowernumber,
4496                 amount         => $amount,
4497                 due            => $datedue,
4498             });
4499         }
4500         elsif ($return_date) {
4501
4502             # Backdated returns may have fines that shouldn't exist,
4503             # so in this case, we need to drop those fines to 0
4504
4505             C4::Overdues::UpdateFine({
4506                 issue_id       => $issue->issue_id,
4507                 itemnumber     => $issue->itemnumber,
4508                 borrowernumber => $issue->borrowernumber,
4509                 amount         => 0,
4510                 due            => $datedue,
4511             });
4512         }
4513     }
4514 }
4515
4516 sub _CanBookBeAutoRenewed {
4517     my ( $params ) = @_;
4518     my $patron = $params->{patron};
4519     my $item = $params->{item};
4520     my $branchcode = $params->{branchcode};
4521     my $issue = $params->{issue};
4522
4523     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4524
4525     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4526         {
4527             categorycode => $patron->categorycode,
4528             itemtype     => $item->effective_itemtype,
4529             branchcode   => $branchcode,
4530             rules => [
4531                 'no_auto_renewal_after',
4532                 'no_auto_renewal_after_hard_limit',
4533                 'lengthunit',
4534                 'norenewalbefore',
4535             ]
4536         }
4537     );
4538
4539     if ( $patron->is_expired && $patron->category->effective_BlockExpiredPatronOpacActions ) {
4540         return 'auto_account_expired';
4541     }
4542
4543     if ( defined $issuing_rule->{no_auto_renewal_after}
4544             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4545         # Get issue_date and add no_auto_renewal_after
4546         # If this is greater than today, it's too late for renewal.
4547         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4548         $maximum_renewal_date->add(
4549             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4550         );
4551         my $now = dt_from_string;
4552         if ( $now >= $maximum_renewal_date ) {
4553             return "auto_too_late";
4554         }
4555     }
4556     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4557                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4558         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4559         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4560             return "auto_too_late";
4561         }
4562     }
4563
4564     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4565         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4566         my $amountoutstanding =
4567           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4568           ? $patron->account->balance
4569           : $patron->account->outstanding_debits->total_outstanding;
4570         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4571             return "auto_too_much_oweing";
4572         }
4573     }
4574
4575     my $soonest = GetSoonestRenewDate($patron, $issue);
4576     if ( $soonest > dt_from_string() )
4577     {
4578         return ( "auto_too_soon", $soonest );
4579     }
4580
4581     return "ok";
4582 }
4583
4584
4585 1;
4586
4587 __END__
4588
4589 =head1 AUTHOR
4590
4591 Koha Development Team <http://koha-community.org/>
4592
4593 =cut