C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number blessed );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfersFromTo
 110       updateWrongTransfer
 111       CalcDateDue
 112       CheckValidBarcode
 113       IsBranchTransferAllowed
 114       CreateBranchTransferLimit
 115       DeleteBranchTransferLimits
 116       TransferSlip
 117
 118       GetOfflineOperations
 119       GetOfflineOperation
 120       AddOfflineOperation
 121       DeleteOfflineOperation
 122       ProcessOfflineOperation
 123       ProcessOfflinePayment
 124       ProcessOfflineIssue
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168
 169     return unless defined $barcode;
 170
 171     my $branch = C4::Context::mybranch();
 172     $barcode =~ s/^\s+|\s+$//g;
 173     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 174     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 175     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 176         if ($filter eq 'whitespace') {
 177                 $barcode =~ s/\s//g;
 178         } elsif ($filter eq 'cuecat') {
 179                 chomp($barcode);
 180             my @fields = split( /\./, $barcode );
 181             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 182             ($#results == 2) and return $results[2];
 183         } elsif ($filter eq 'T-prefix') {
 184                 if ($barcode =~ /^[Tt](\d)/) {
 185                         (defined($1) and $1 eq '0') and return $barcode;
 186             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 187                 }
 188         return sprintf("T%07d", $barcode);
 189         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 190         # Why drop the nonzero digit after the T?
 191         # Why pass non-digits (or empty string) to "T%07d"?
 192         } elsif ($filter eq 'libsuite8') {
 193                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 194                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 195                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 196                         }else{
 197                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 198                         }
 199                 }
 200     } elsif ($filter eq 'EAN13') {
 201         my $ean = CheckDigits('ean');
 202         if ( $ean->is_valid($barcode) ) {
 203             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 204             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 205         } else {
 206             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 207         }
 208         }
 209     return $barcode;    # return barcode, modified or not
 210 }
 211
 212 =head2 _decode
 213
 214   $str = &_decode($chunk);
 215
 216 Decodes a segment of a string emitted by a CueCat barcode scanner and
 217 returns it.
 218
 219 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 220 or Javascript based decoding on the client side.
 221
 222 =cut
 223
 224 sub _decode {
 225     my ($encoded) = @_;
 226     my $seq =
 227       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 228     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 229     my $l = ( $#s + 1 ) % 4;
 230     if ($l) {
 231         if ( $l == 1 ) {
 232             # warn "Error: Cuecat decode parsing failed!";
 233             return;
 234         }
 235         $l = 4 - $l;
 236         $#s += $l;
 237     }
 238     my $r = '';
 239     while ( $#s >= 0 ) {
 240         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 241         $r .=
 242             chr( ( $n >> 16 ) ^ 67 )
 243          .chr( ( $n >> 8 & 255 ) ^ 67 )
 244          .chr( ( $n & 255 ) ^ 67 );
 245         @s = @s[ 4 .. $#s ];
 246     }
 247     $r = substr( $r, 0, length($r) - $l );
 248     return $r;
 249 }
 250
 251 =head2 transferbook
 252
 253   ($dotransfer, $messages, $iteminformation) = &transferbook({
 254                                                    from_branch => $frombranch
 255                                                    to_branch => $tobranch,
 256                                                    barcode => $barcode,
 257                                                    ignore_reserves => $ignore_reserves,
 258                                                    trigger => $trigger
 259                                                 });
 260
 261 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 262
 263 C<$fbr> is the code for the branch initiating the transfer.
 264 C<$tbr> is the code for the branch to which the item should be transferred.
 265
 266 C<$barcode> is the barcode of the item to be transferred.
 267
 268 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 269 Otherwise, if an item is reserved, the transfer fails.
 270
 271 C<$trigger> is the enum value for what triggered the transfer.
 272
 273 Returns three values:
 274
 275 =over
 276
 277 =item $dotransfer
 278
 279 is true if the transfer was successful.
 280
 281 =item $messages
 282
 283 is a reference-to-hash which may have any of the following keys:
 284
 285 =over
 286
 287 =item C<BadBarcode>
 288
 289 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 290
 291 =item C<DestinationEqualsHolding>
 292
 293 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 294
 295 =item C<WasReturned>
 296
 297 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 298
 299 =item C<ResFound>
 300
 301 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 302
 303 =item C<WasTransferred>
 304
 305 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 306
 307 =item C<RecallPlacedAtHoldingBranch>
 308
 309 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 310
 311 =item C<RecallFound>
 312
 313 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 314
 315 =back
 316
 317 =back
 318
 319 =cut
 320
 321 sub transferbook {
 322     my $params = shift;
 323     my $tbr      = $params->{to_branch};
 324     my $fbr      = $params->{from_branch};
 325     my $ignoreRs = $params->{ignore_reserves};
 326     my $barcode  = $params->{barcode};
 327     my $trigger  = $params->{trigger};
 328     my $messages;
 329     my $dotransfer      = 1;
 330     my $item = Koha::Items->find( { barcode => $barcode } );
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: from_branch")
 334       unless $fbr;
 335
 336     Koha::Exceptions::MissingParameter->throw(
 337         "Missing mandatory parameter: to_branch")
 338       unless $tbr;
 339
 340     # bad barcode..
 341     unless ( $item ) {
 342         $messages->{'BadBarcode'} = $barcode;
 343         $dotransfer = 0;
 344         return ( $dotransfer, $messages );
 345     }
 346
 347     my $itemnumber = $item->itemnumber;
 348     # get branches of book...
 349     my $hbr = $item->homebranch;
 350
 351     # if using Branch Transfer Limits
 352     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 353         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 354         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 355             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 356                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 357                 $dotransfer = 0;
 358             }
 359         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 360             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 361             $dotransfer = 0;
 362         }
 363     }
 364
 365     # can't transfer book if is already there....
 366     if ( $fbr eq $tbr ) {
 367         $messages->{'DestinationEqualsHolding'} = 1;
 368         $dotransfer = 0;
 369     }
 370
 371     # check if it is still issued to someone, return it...
 372     my $issue = $item->checkout;
 373     if ( $issue ) {
 374         AddReturn( $barcode, $fbr );
 375         $messages->{'WasReturned'} = $issue->borrowernumber;
 376     }
 377
 378     # find reserves.....
 379     # That'll save a database query.
 380     my ( $resfound, $resrec, undef ) =
 381       CheckReserves( $item );
 382     if ( $resfound ) {
 383         $resrec->{'ResFound'} = $resfound;
 384         $messages->{'ResFound'} = $resrec;
 385         $dotransfer = 0 unless $ignoreRs;
 386     }
 387
 388     # find recall
 389     if ( C4::Context->preference('UseRecalls') ) {
 390         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 391         if ( defined $recall ) {
 392             # do a transfer if the recall branch is different to the item holding branch
 393             if ( $recall->pickup_library_id eq $fbr ) {
 394                 $dotransfer = 0;
 395                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 396             } else {
 397                 $dotransfer = 1;
 398                 $messages->{'RecallFound'} = $recall;
 399             }
 400         }
 401     }
 402
 403     #actually do the transfer....
 404     if ($dotransfer) {
 405         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 406
 407         # don't need to update MARC anymore, we do it in batch now
 408         $messages->{'WasTransfered'} = $tbr;
 409
 410     }
 411     ModDateLastSeen( $itemnumber );
 412     return ( $dotransfer, $messages );
 413 }
 414
 415
 416 sub TooMany {
 417     my $borrower        = shift;
 418     my $item_object = shift;
 419     my $params = shift;
 420     my $onsite_checkout = $params->{onsite_checkout} || 0;
 421     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 422     my $cat_borrower    = $borrower->{'categorycode'};
 423     my $dbh             = C4::Context->dbh;
 424     # Get which branchcode we need
 425     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 426     my $type = $item_object->effective_itemtype;
 427
 428     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 429     $type_object = Koha::ItemTypes->find( $type );
 430     $parent_type = $type_object->parent_type if $type_object;
 431     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 432     # Find any children if we are a parent_type;
 433
 434     # given branch, patron category, and item type, determine
 435     # applicable issuing rule
 436
 437     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 438         {
 439             categorycode => $cat_borrower,
 440             itemtype     => $parent_type,
 441             branchcode   => $branch,
 442             rule_name    => 'maxissueqty',
 443         }
 444     ) if $parent_type;
 445     # If the parent rule is for default type we discount it
 446     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 447
 448     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 449         {
 450             categorycode => $cat_borrower,
 451             itemtype     => $type,
 452             branchcode   => $branch,
 453             rule_name    => 'maxissueqty',
 454         }
 455     );
 456
 457     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 458         {
 459             categorycode => $cat_borrower,
 460             itemtype     => $type,
 461             branchcode   => $branch,
 462             rule_name    => 'maxonsiteissueqty',
 463         }
 464     );
 465
 466
 467     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 468     # if a rule is found and has a loan limit set, count
 469     # how many loans the patron already has that meet that
 470     # rule
 471     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 472
 473         my $checkouts;
 474         if ( $maxissueqty_rule->branchcode ) {
 475             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 476                 $checkouts = $patron->checkouts->search(
 477                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 478             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 479                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 480             } else {
 481                 my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 482                 $checkouts = $patron->checkouts->search(
 483                     { "item.$branch_type" => $maxissueqty_rule->branchcode } );
 484             }
 485         } else {
 486             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 487         }
 488         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 489
 490         my $sum_checkouts;
 491         my $rule_itemtype = $maxissueqty_rule->itemtype;
 492
 493         my @types;
 494         unless ( $rule_itemtype ) {
 495             # matching rule has the default item type, so count only
 496             # those existing loans that don't fall under a more
 497             # specific rule
 498             @types = Koha::CirculationRules->search(
 499                 {
 500                     branchcode => $maxissueqty_rule->branchcode,
 501                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 502                     itemtype  => { '!=' => undef },
 503                     rule_name => 'maxissueqty'
 504                 }
 505             )->get_column('itemtype');
 506         } else {
 507             if ( $parent_maxissueqty_rule ) {
 508                 # if we have a parent item type then we count loans of the
 509                 # specific item type or its siblings or parent
 510                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 511                 @types = $children->get_column('itemtype');
 512                 push @types, $parent_type;
 513             } elsif ( $child_types ) {
 514                 # If we are a parent type, we need to count all child types and our own type
 515                 @types = $child_types->get_column('itemtype');
 516                 push @types, $type; # And don't forget to count our own types
 517             } else {
 518                 # Otherwise only count the specific itemtype
 519                 push @types, $type;
 520             }
 521         }
 522
 523         while ( my $c = $checkouts->next ) {
 524             my $itemtype = $c->item->effective_itemtype;
 525
 526             unless ( $rule_itemtype ) {
 527                 next if grep {$_ eq $itemtype} @types;
 528             } else {
 529                 next unless grep {$_ eq $itemtype} @types;
 530             }
 531
 532             $sum_checkouts->{total}++;
 533             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 534             $sum_checkouts->{itemtype}->{$itemtype}++;
 535         }
 536
 537         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 538         my $checkout_count = $sum_checkouts->{total} || 0;
 539         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 540
 541         my $checkout_rules = {
 542             checkout_count               => $checkout_count,
 543             onsite_checkout_count        => $onsite_checkout_count,
 544             onsite_checkout              => $onsite_checkout,
 545             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 546             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 547             switch_onsite_checkout       => $switch_onsite_checkout,
 548         };
 549         # If parent rules exists
 550         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 551             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 552             my $qty_over = _check_max_qty($checkout_rules);
 553             return $qty_over if defined $qty_over;
 554
 555             # If the parent rule is less than or equal to the child, we only need check the parent
 556             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 557                 $checkout_rules->{checkout_count} = $checkout_count_type;
 558                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 559                 my $qty_over = _check_max_qty($checkout_rules);
 560                 return $qty_over if defined $qty_over;
 561             }
 562         } else {
 563             my $qty_over = _check_max_qty($checkout_rules);
 564             return $qty_over if defined $qty_over;
 565         }
 566     }
 567
 568     # Now count total loans against the limit for the branch
 569     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 570     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 571         my $checkouts;
 572         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 573             $checkouts = $patron->checkouts->search(
 574                 { 'me.branchcode' => $branch} );
 575         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 576             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 577         } else {
 578             my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 579             $checkouts = $patron->checkouts->search(
 580                 { "item.$branch_type" => $branch},
 581                 { prefetch            => 'item' } );
 582         }
 583
 584         my $checkout_count = $checkouts->count;
 585         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 586         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 587         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 588
 589         my $qty_over = _check_max_qty(
 590             {
 591                 checkout_count               => $checkout_count,
 592                 onsite_checkout_count        => $onsite_checkout_count,
 593                 onsite_checkout              => $onsite_checkout,
 594                 max_checkouts_allowed        => $max_checkouts_allowed,
 595                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 596                 switch_onsite_checkout       => $switch_onsite_checkout
 597             }
 598         );
 599         return $qty_over if defined $qty_over;
 600     }
 601
 602     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 603         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 604     }
 605
 606     # OK, the patron can issue !!!
 607     return;
 608 }
 609
 610 sub _check_max_qty {
 611     my $params                       = shift;
 612     my $checkout_count               = $params->{checkout_count};
 613     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 614     my $onsite_checkout              = $params->{onsite_checkout};
 615     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 616     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 617     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 618
 619     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 620         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 621         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 622             return {
 623                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 624                 count       => $onsite_checkout_count,
 625                 max_allowed => $max_onsite_checkouts_allowed,
 626             };
 627         }
 628     }
 629     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 630         if ( $max_checkouts_allowed eq '' ) { return; }
 631         my $delta = $switch_onsite_checkout ? 1 : 0;
 632         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 633             return {
 634                 reason      => 'TOO_MANY_CHECKOUTS',
 635                 count       => $checkout_count,
 636                 max_allowed => $max_checkouts_allowed,
 637             };
 638         }
 639     }
 640     elsif ( not $onsite_checkout ) {
 641         if ( $max_checkouts_allowed eq '' ) { return; }
 642         if (
 643             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 644         {
 645             return {
 646                 reason      => 'TOO_MANY_CHECKOUTS',
 647                 count       => $checkout_count - $onsite_checkout_count,
 648                 max_allowed => $max_checkouts_allowed,
 649             };
 650         }
 651     }
 652
 653     return;
 654 }
 655
 656 =head2 CanBookBeIssued
 657
 658   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 659                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 660
 661 Check if a book can be issued.
 662
 663 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 664
 665 IMPORTANT: The assumption by users of this routine is that causes blocking
 666 the issue are keyed by uppercase labels and other returned
 667 data is keyed in lower case!
 668
 669 =over 4
 670
 671 =item C<$patron> is a Koha::Patron
 672
 673 =item C<$barcode> is the bar code of the book being issued.
 674
 675 =item C<$duedates> is a DateTime object.
 676
 677 =item C<$inprocess> boolean switch
 678
 679 =item C<$ignore_reserves> boolean switch
 680
 681 =item C<$params> Hashref of additional parameters
 682
 683 Available keys:
 684     override_high_holds - Ignore high holds
 685     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 686
 687 =back
 688
 689 Returns :
 690
 691 =over 4
 692
 693 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 694 Possible values are :
 695
 696 =back
 697
 698 =head3 INVALID_DATE
 699
 700 sticky due date is invalid
 701
 702 =head3 GNA
 703
 704 borrower gone with no address
 705
 706 =head3 CARD_LOST
 707
 708 borrower declared it's card lost
 709
 710 =head3 DEBARRED
 711
 712 borrower debarred
 713
 714 =head3 UNKNOWN_BARCODE
 715
 716 barcode unknown
 717
 718 =head3 NOT_FOR_LOAN
 719
 720 item is not for loan
 721
 722 =head3 WTHDRAWN
 723
 724 item withdrawn.
 725
 726 =head3 RESTRICTED
 727
 728 item is restricted (set by ??)
 729
 730 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 731 could be prevented, but ones that can be overriden by the operator.
 732
 733 Possible values are :
 734
 735 =head3 DEBT
 736
 737 borrower has debts.
 738
 739 =head3 RENEW_ISSUE
 740
 741 renewing, not issuing
 742
 743 =head3 ISSUED_TO_ANOTHER
 744
 745 issued to someone else.
 746
 747 =head3 RESERVED
 748
 749 reserved for someone else.
 750
 751 =head3 TRANSFERRED
 752
 753 reserved and being transferred for someone else.
 754
 755 =head3 INVALID_DATE
 756
 757 sticky due date is invalid or due date in the past
 758
 759 =head3 TOO_MANY
 760
 761 if the borrower borrows to much things
 762
 763 =head3 RECALLED
 764
 765 recalled by someone else
 766
 767 =cut
 768
 769 sub CanBookBeIssued {
 770     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 771     my %needsconfirmation;    # filled with problems that needs confirmations
 772     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 773     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 774     my %messages;             # filled with information messages that should be displayed.
 775
 776     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 777     my $override_high_holds = $params->{override_high_holds} || 0;
 778
 779     my $item_object = Koha::Items->find({barcode => $barcode });
 780
 781     # MANDATORY CHECKS - unless item exists, nothing else matters
 782     unless ( $item_object ) {
 783         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 784     }
 785     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 786
 787     my $item_unblessed = $item_object->unblessed; # Transition...
 788     my $issue = $item_object->checkout;
 789     my $biblio = $item_object->biblio;
 790
 791     my $biblioitem = $biblio->biblioitem;
 792     my $effective_itemtype = $item_object->effective_itemtype;
 793     my $dbh             = C4::Context->dbh;
 794     my $patron_unblessed = $patron->unblessed;
 795
 796     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 797
 798     my $now = dt_from_string();
 799     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 800     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 801          $needsconfirmation{INVALID_DATE} = $duedate;
 802     }
 803
 804     my $fees = Koha::Charges::Fees->new(
 805         {
 806             patron    => $patron,
 807             library   => $circ_library,
 808             item      => $item_object,
 809             to_date   => $duedate,
 810         }
 811     );
 812
 813     #
 814     # BORROWER STATUS
 815     #
 816     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 817         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 818         C4::Stats::UpdateStats(
 819             {
 820                 branch         => C4::Context->userenv->{'branch'},
 821                 type           => 'localuse',
 822                 itemnumber     => $item_object->itemnumber,
 823                 itemtype       => $effective_itemtype,
 824                 borrowernumber => $patron->borrowernumber,
 825                 ccode          => $item_object->ccode,
 826                 categorycode   => $patron->categorycode,
 827                 location       => $item_object->location,
 828                 interface      => C4::Context->interface,
 829             }
 830         );
 831         my $block_lost_return = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
 832         my ( $stats_return, $stats_messages, $stats_iteminformation, $stats_borrower ) =
 833             AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
 834         ModDateLastSeen( $item_object->itemnumber, $block_lost_return );    # FIXME Move to Koha::Item
 835         return (
 836             {
 837                 STATS     => 1,
 838                 CHECKEDIN => $stats_return,
 839                 MESSAGES  => $stats_messages,
 840                 ITEM      => $stats_iteminformation,
 841                 BORROWER  => $stats_borrower,
 842             },
 843             {}
 844         );
 845     }
 846
 847     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 848         $issuingimpossible{GNA} = 1;
 849     }
 850
 851     if ( $patron->lost && $patron->lost == 1 ) {
 852         $issuingimpossible{CARD_LOST} = 1;
 853     }
 854     if ( $patron->is_debarred ) {
 855         $issuingimpossible{DEBARRED} = 1;
 856     }
 857
 858     if ( $patron->is_expired ) {
 859         $issuingimpossible{EXPIRED} = 1;
 860     }
 861
 862     #
 863     # BORROWER STATUS
 864     #
 865
 866     # DEBTS
 867     my $account = $patron->account;
 868     my $balance = $account->balance;
 869     my $non_issues_charges = $account->non_issues_charges;
 870     my $other_charges = $balance - $non_issues_charges;
 871
 872     my $amountlimit = C4::Context->preference("noissuescharge");
 873     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 874     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 875
 876     # Check the debt of this patrons guarantees
 877     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 878     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 879     if ( defined $no_issues_charge_guarantees ) {
 880         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 881         my $guarantees_non_issues_charges = 0;
 882         foreach my $g ( @guarantees ) {
 883             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 884         }
 885
 886         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 887             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 888         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 889             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 890         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 891             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 892         }
 893     }
 894
 895     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 896     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 897     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 898     if ( defined $no_issues_charge_guarantors ) {
 899         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 900
 901         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 902             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 903         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 904             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 905         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 906             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 907         }
 908     }
 909
 910     if ( C4::Context->preference("IssuingInProcess") ) {
 911         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 912             $issuingimpossible{DEBT} = $non_issues_charges;
 913         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 914             $needsconfirmation{DEBT} = $non_issues_charges;
 915         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 916             $needsconfirmation{DEBT} = $non_issues_charges;
 917         }
 918     }
 919     else {
 920         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 921             $needsconfirmation{DEBT} = $non_issues_charges;
 922         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 923             $issuingimpossible{DEBT} = $non_issues_charges;
 924         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 925             $needsconfirmation{DEBT} = $non_issues_charges;
 926         }
 927     }
 928
 929     if ($balance > 0 && $other_charges > 0) {
 930         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 931     }
 932
 933     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 934     $patron_unblessed = $patron->unblessed;
 935
 936     if ( my $debarred_date = $patron->is_debarred ) {
 937          # patron has accrued fine days or has a restriction. $count is a date
 938         if ($debarred_date eq '9999-12-31') {
 939             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 940         }
 941         else {
 942             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 943         }
 944     } elsif ( my $num_overdues = $patron->has_overdues ) {
 945         ## patron has outstanding overdue loans
 946         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 947             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 948         }
 949         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 950             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 951         }
 952     }
 953
 954     # Additional Materials Check
 955     if ( C4::Context->preference("CircConfirmItemParts")
 956         && $item_object->materials )
 957     {
 958         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 959     }
 960
 961     #
 962     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 963     #
 964     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 965
 966         # Already issued to current borrower.
 967         # If it is an on-site checkout if it can be switched to a normal checkout
 968         # or ask whether the loan should be renewed
 969
 970         if ( $issue->onsite_checkout
 971                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 972             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 973         } else {
 974             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed($patron, $issue);
 975             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 976                 if ( $renewerror eq 'onsite_checkout' ) {
 977                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 978                 }
 979                 else {
 980                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 981                 }
 982             }
 983             else {
 984                 $needsconfirmation{RENEW_ISSUE} = 1;
 985             }
 986         }
 987     }
 988     elsif ( $issue ) {
 989
 990         # issued to someone else
 991
 992         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 993
 994         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 995
 996         if ( !$can_be_returned ) {
 997             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 998             $issuingimpossible{branch_to_return} = $message;
 999         } else {
1000             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
1001                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
1002             }
1003             else {
1004                 $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
1005                 $needsconfirmation{issued_firstname} = $patron->firstname;
1006                 $needsconfirmation{issued_surname} = $patron->surname;
1007                 $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
1008                 $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
1009             }
1010         }
1011     }
1012
1013     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1014     #
1015     my $switch_onsite_checkout = (
1016           C4::Context->preference('SwitchOnSiteCheckouts')
1017       and $issue
1018       and $issue->onsite_checkout
1019       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1020     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1021     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1022     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1023         if ( $toomany->{max_allowed} == 0 ) {
1024             $needsconfirmation{PATRON_CANT} = 1;
1025         }
1026         if ( C4::Context->preference("AllowTooManyOverride") ) {
1027             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1028             $needsconfirmation{current_loan_count} = $toomany->{count};
1029             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1030         } else {
1031             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1032             $issuingimpossible{current_loan_count} = $toomany->{count};
1033             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1034         }
1035     }
1036
1037     #
1038     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1039     #
1040     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1041     if ( $patron->wants_check_for_previous_checkout && $patron->do_check_for_previous_checkout($item_unblessed) ) {
1042         $needsconfirmation{PREVISSUE} = 1;
1043     }
1044
1045     #
1046     # ITEM CHECKING
1047     #
1048     if ( $item_object->notforloan )
1049     {
1050         if(!C4::Context->preference("AllowNotForLoanOverride")){
1051             $issuingimpossible{NOT_FOR_LOAN} = 1;
1052             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1053         }else{
1054             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1055             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1056         }
1057     }
1058     else {
1059         # we have to check itemtypes.notforloan also
1060         if (C4::Context->preference('item-level_itypes')){
1061             # this should probably be a subroutine
1062             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1063             $sth->execute($effective_itemtype);
1064             my $notforloan=$sth->fetchrow_hashref();
1065             if ($notforloan->{'notforloan'}) {
1066                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1067                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1068                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1069                 } else {
1070                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1071                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1072                 }
1073             }
1074         }
1075         else {
1076             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1077             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1078                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1079                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1080                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1081                 } else {
1082                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1083                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1084                 }
1085             }
1086         }
1087     }
1088     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1089     {
1090         $issuingimpossible{WTHDRAWN} = 1;
1091     }
1092     if (   $item_object->restricted
1093         && $item_object->restricted == 1 )
1094     {
1095         $issuingimpossible{RESTRICTED} = 1;
1096     }
1097     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1098         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1099         my $code = $av->count ? $av->next->lib : '';
1100         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1101         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1102     }
1103     if ( C4::Context->preference("IndependentBranches") ) {
1104         my $userenv = C4::Context->userenv;
1105         unless ( C4::Context->IsSuperLibrarian() ) {
1106             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1107             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1108                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1109                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1110             }
1111             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1112               if ( $patron->branchcode ne $userenv->{branch} );
1113         }
1114     }
1115
1116     #
1117     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1118     #
1119     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1120     if ($rentalConfirmation) {
1121         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1122
1123         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1124         if ($itemtype_object) {
1125             my $accumulate_charge = $fees->accumulate_rentalcharge();
1126             if ( $accumulate_charge > 0 ) {
1127                 $rentalCharge += $accumulate_charge;
1128             }
1129         }
1130
1131         if ( $rentalCharge > 0 ) {
1132             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1133         }
1134     }
1135
1136     my $recall;
1137     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1138     # Only bother doing this if UseRecalls is enabled and the item is recallable
1139     # Don't look at recalls that are in transit
1140     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1141         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1142
1143         foreach my $r ( @recalls ) {
1144             if ( $r->item_id and
1145                 $r->item_id == $item_object->itemnumber and
1146                 $r->patron_id == $patron->borrowernumber and
1147                 ( $r->waiting or $r->requested ) ) {
1148                 $messages{RECALLED} = $r->id;
1149                 $recall = $r;
1150                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1151                 last;
1152             }
1153             elsif ( $r->item_id and
1154                 $r->item_id == $item_object->itemnumber and
1155                 $r->in_transit ) {
1156                 # recalled item is in transit
1157                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1158             }
1159             elsif ( $r->item_level and
1160                 $r->item_id == $item_object->itemnumber and
1161                 $r->patron_id != $patron->borrowernumber and
1162                 !$r->in_transit ) {
1163                 # this specific item has been recalled by a different patron
1164                 $needsconfirmation{RECALLED} = $r;
1165                 $recall = $r;
1166                 last;
1167             }
1168             elsif ( !$r->item_level and
1169                 $r->patron_id != $patron->borrowernumber and
1170                 !$r->in_transit ) {
1171                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1172                 $needsconfirmation{RECALLED} = $r;
1173                 $recall = $r;
1174                 last;
1175             }
1176         }
1177     }
1178
1179     unless ( $ignore_reserves and defined $recall ) {
1180         # See if the item is on reserve.
1181         my ( $restype, $res ) = CheckReserves( $item_object );
1182         if ($restype) {
1183             my $resbor = $res->{'borrowernumber'};
1184             if ( $resbor ne $patron->borrowernumber ) {
1185                 my $patron = Koha::Patrons->find( $resbor );
1186                 if ( $restype eq "Waiting" )
1187                 {
1188                     # The item is on reserve and waiting, but has been
1189                     # reserved by some other patron.
1190                     $needsconfirmation{RESERVE_WAITING} = 1;
1191                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1192                     $needsconfirmation{'ressurname'} = $patron->surname;
1193                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1194                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1195                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1196                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1197                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1198                 }
1199                 elsif ( $restype eq "Reserved" ) {
1200                     # The item is on reserve for someone else.
1201                     $needsconfirmation{RESERVED} = 1;
1202                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1203                     $needsconfirmation{'ressurname'} = $patron->surname;
1204                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1205                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1206                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1207                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1208                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1209                 }
1210                 elsif ( $restype eq "Transferred" ) {
1211                     # The item is determined hold being transferred for someone else.
1212                     $needsconfirmation{TRANSFERRED} = 1;
1213                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1214                     $needsconfirmation{'ressurname'} = $patron->surname;
1215                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1216                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1217                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1218                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1219                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1220                 }
1221                 elsif ( $restype eq "Processing" ) {
1222                     # The item is determined hold being processed for someone else.
1223                     $needsconfirmation{PROCESSING} = 1;
1224                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1225                     $needsconfirmation{'ressurname'} = $patron->surname;
1226                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1227                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1228                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1229                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1230                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1231                 }
1232             }
1233         }
1234     }
1235
1236     ## CHECK AGE RESTRICTION
1237     my $agerestriction  = $biblioitem->agerestriction;
1238     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1239     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1240         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1241             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1242         }
1243         else {
1244             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1245         }
1246     }
1247
1248     ## check for high holds decreasing loan period
1249     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1250         my $check = checkHighHolds( $item_object, $patron );
1251
1252         if ( $check->{exceeded} ) {
1253             my $highholds = {
1254                 num_holds  => $check->{outstanding},
1255                 duration   => $check->{duration},
1256                 returndate => $check->{due_date},
1257             };
1258             if ($override_high_holds) {
1259                 $alerts{HIGHHOLDS} = $highholds;
1260             }
1261             else {
1262                 $needsconfirmation{HIGHHOLDS} = $highholds;
1263             }
1264         }
1265     }
1266
1267     if (
1268         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1269         # don't do the multiple loans per bib check if we've
1270         # already determined that we've got a loan on the same item
1271         !$issuingimpossible{NO_MORE_RENEWALS} &&
1272         !$needsconfirmation{RENEW_ISSUE}
1273     ) {
1274         # Check if borrower has already issued an item from the same biblio
1275         # Only if it's not a subscription
1276         my $biblionumber = $item_object->biblionumber;
1277         require C4::Serials;
1278         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1279         unless ($is_a_subscription) {
1280             # FIXME Should be $patron->checkouts($args);
1281             my $checkouts = Koha::Checkouts->search(
1282                 {
1283                     borrowernumber => $patron->borrowernumber,
1284                     biblionumber   => $biblionumber,
1285                 },
1286                 {
1287                     join => 'item',
1288                 }
1289             );
1290             # if we get here, we don't already have a loan on this item,
1291             # so if there are any loans on this bib, ask for confirmation
1292             if ( $checkouts->count ) {
1293                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1294             }
1295         }
1296     }
1297
1298     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1299 }
1300
1301 =head2 CanBookBeReturned
1302
1303   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1304
1305 Check whether the item can be returned to the provided branch
1306
1307 =over 4
1308
1309 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1310
1311 =item C<$branch> is the branchcode where the return is taking place
1312
1313 =back
1314
1315 Returns:
1316
1317 =over 4
1318
1319 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1320
1321 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1322
1323 =back
1324
1325 =cut
1326
1327 sub CanBookBeReturned {
1328   my ($item, $branch) = @_;
1329   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1330
1331   # assume return is allowed to start
1332   my $allowed = 1;
1333   my $message;
1334
1335   # identify all cases where return is forbidden
1336   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1337      $allowed = 0;
1338      $message = $item->{'homebranch'};
1339   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1340      $allowed = 0;
1341      $message = $item->{'holdingbranch'};
1342   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1343      $allowed = 0;
1344      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1345   }
1346
1347   return ($allowed, $message);
1348 }
1349
1350 =head2 CheckHighHolds
1351
1352     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1353     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1354     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1355
1356 =cut
1357
1358 sub checkHighHolds {
1359     my ( $item, $patron ) = @_;
1360     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1361
1362     my $return_data = {
1363         exceeded    => 0,
1364         outstanding => 0,
1365         duration    => 0,
1366         due_date    => undef,
1367     };
1368
1369
1370     # Count holds on this record, ignoring the borrowers own holds as they would be filled by the checkout
1371     my $holds = Koha::Holds->search({
1372         biblionumber => $item->biblionumber,
1373         borrowernumber => { '!=' => $patron->borrowernumber }
1374     });
1375
1376     if ( $holds->count() ) {
1377         $return_data->{outstanding} = $holds->count();
1378
1379         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1380         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1381         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1382
1383         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1384
1385         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1386
1387             # static means just more than a given number of holds on the record
1388
1389             # If the number of holds is not above the threshold, we can stop here
1390             if ( $holds->count() <= $decreaseLoanHighHoldsValue ) {
1391                 return $return_data;
1392             }
1393         }
1394         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1395
1396             # dynamic means X more than the number of holdable items on the record
1397
1398             # let's get the items
1399             my @items = $holds->next()->biblio()->items()->as_list;
1400
1401             # Remove any items with status defined to be ignored even if the would not make item unholdable
1402             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1403                 @items = grep { !$_->$status } @items;
1404             }
1405
1406             # Remove any items that are not holdable for this patron
1407             # We need to ignore hold counts as the borrower's own hold that will be filled by the checkout
1408             # could prevent them from placing further holds
1409             @items = grep { CanItemBeReserved( $patron, $_, undef, { ignore_hold_counts => 1 } )->{status} eq 'OK' } @items;
1410
1411             my $items_count = scalar @items;
1412
1413             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1414
1415             # If the number of holds is less than the count of items we have
1416             # plus the number of holds allowed above that count, we can stop here
1417             if ( $holds->count() <= $threshold ) {
1418                 return $return_data;
1419             }
1420         }
1421
1422         my $issuedate = dt_from_string();
1423
1424         my $itype = $item->effective_itemtype;
1425         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1426             {
1427                 categorycode => $patron->categorycode,
1428                 itemtype     => $itype,
1429                 branchcode   => $branchcode,
1430             }
1431         );
1432         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1433
1434         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1435
1436         my $rule = Koha::CirculationRules->get_effective_rule_value(
1437             {
1438                 categorycode => $patron->categorycode,
1439                 itemtype     => $item->effective_itemtype,
1440                 branchcode   => $branchcode,
1441                 rule_name    => 'decreaseloanholds',
1442             }
1443         );
1444
1445         my $duration;
1446         if ( defined($rule) && $rule ne '' ){
1447             # overrides decreaseLoanHighHoldsDuration syspref
1448             $duration = $rule;
1449         } else {
1450             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1451         }
1452         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1453         $reduced_datedue->set_hour($orig_due->hour);
1454         $reduced_datedue->set_minute($orig_due->minute);
1455         $reduced_datedue->truncate( to => 'minute' );
1456
1457         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1458             $return_data->{exceeded} = 1;
1459             $return_data->{duration} = $duration;
1460             $return_data->{due_date} = $reduced_datedue;
1461         }
1462     }
1463
1464     return $return_data;
1465 }
1466
1467 =head2 AddIssue
1468
1469   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1470
1471 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1472
1473 =over 4
1474
1475 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1476
1477 =item C<$barcode> is the barcode of the item being issued.
1478
1479 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1480 Calculated if empty.
1481
1482 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1483
1484 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1485 Defaults to today.
1486
1487 AddIssue does the following things :
1488
1489   - step 01: check that there is a borrowernumber & a barcode provided
1490   - check for RENEWAL (book issued & being issued to the same patron)
1491       - renewal YES = Calculate Charge & renew
1492       - renewal NO  =
1493           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1494           * RESERVE PLACED ?
1495               - fill reserve if reserve to this patron
1496               - cancel reserve or not, otherwise
1497           * RECALL PLACED ?
1498               - fill recall if recall to this patron
1499               - cancel recall or not
1500               - revert recall's waiting status or not
1501           * TRANSFERT PENDING ?
1502               - complete the transfert
1503           * ISSUE THE BOOK
1504
1505 =back
1506
1507 =cut
1508
1509 sub AddIssue {
1510     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1511
1512     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1513     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1514     my $auto_renew = $params && $params->{auto_renew};
1515     my $cancel_recall = $params && $params->{cancel_recall};
1516     my $recall_id = $params && $params->{recall_id};
1517     my $dbh          = C4::Context->dbh;
1518     my $barcodecheck = CheckValidBarcode($barcode);
1519
1520     my $issue;
1521
1522     if ( $datedue && ref $datedue ne 'DateTime' ) {
1523         $datedue = dt_from_string($datedue);
1524     }
1525
1526     # $issuedate defaults to today.
1527     if ( !defined $issuedate ) {
1528         $issuedate = dt_from_string();
1529     }
1530     else {
1531         if ( ref $issuedate ne 'DateTime' ) {
1532             $issuedate = dt_from_string($issuedate);
1533
1534         }
1535     }
1536
1537     # Stop here if the patron or barcode doesn't exist
1538     if ( $borrower && $barcode && $barcodecheck ) {
1539         # find which item we issue
1540         my $item_object = Koha::Items->find({ barcode => $barcode })
1541           or return;    # if we don't get an Item, abort.
1542         my $item_unblessed = $item_object->unblessed;
1543
1544         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1545
1546         # get actual issuing if there is one
1547         my $actualissue = $item_object->checkout;
1548
1549         # check if we just renew the issue.
1550         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1551                 and not $switch_onsite_checkout ) {
1552             $datedue = AddRenewal(
1553                 $borrower->{'borrowernumber'},
1554                 $item_object->itemnumber,
1555                 $branchcode,
1556                 $datedue,
1557                 $issuedate,    # here interpreted as the renewal date
1558             );
1559         }
1560         else {
1561
1562             unless ($datedue) {
1563                 my $itype = $item_object->effective_itemtype;
1564                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1565
1566             }
1567
1568             # Check if we need to use an exact due date set by the ILL module
1569             if ( C4::Context->preference('ILLModule') ) {
1570                 # Check if there is an ILL connected with the biblio of the item we are issuing
1571                 my $ill_request = Koha::Illrequests->search({
1572                     biblio_id => $item_object->biblionumber,
1573                     borrowernumber => $borrower->{'borrowernumber'},
1574                     completed => undef,
1575                     due_date => { '!=', undef },
1576                 })->next;
1577
1578                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1579                     my $ill_dt = dt_from_string( $ill_request->due_date );
1580                     $ill_dt->set_hour(23);
1581                     $ill_dt->set_minute(59);
1582                     $datedue = $ill_dt;
1583                 }
1584             }
1585
1586             $datedue->truncate( to => 'minute' );
1587
1588             my $patron = Koha::Patrons->find( $borrower );
1589             my $library = Koha::Libraries->find( $branchcode );
1590             my $fees = Koha::Charges::Fees->new(
1591                 {
1592                     patron    => $patron,
1593                     library   => $library,
1594                     item      => $item_object,
1595                     to_date   => $datedue,
1596                 }
1597             );
1598
1599             # it's NOT a renewal
1600             if ( $actualissue and not $switch_onsite_checkout ) {
1601                 # This book is currently on loan, but not to the person
1602                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1603                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1604                 return unless $allowed;
1605                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1606                 # AddReturn certainly has side-effects, like onloan => undef
1607                 $item_object->discard_changes;
1608             }
1609
1610             if ( C4::Context->preference('UseRecalls') ) {
1611                 Koha::Recalls->move_recall(
1612                     {
1613                         action         => $cancel_recall,
1614                         recall_id      => $recall_id,
1615                         item           => $item_object,
1616                         borrowernumber => $borrower->{borrowernumber},
1617                     }
1618                 );
1619             }
1620
1621             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1622
1623             # Starting process for transfer job (checking transfert and validate it if we have one)
1624             if ( my $transfer = $item_object->get_transfer ) {
1625                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1626                 $transfer->set(
1627                     {
1628                         datearrived => dt_from_string,
1629                         tobranch    => C4::Context->userenv->{branch},
1630                         comments    => 'Forced branchtransfer'
1631                     }
1632                 )->store;
1633                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1634                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1635                     if ( $hold ) { # Is this really needed?
1636                         $hold->set( { found => undef } )->store;
1637                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1638                     }
1639                 }
1640             }
1641
1642             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1643             unless ($auto_renew) {
1644                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1645                     {
1646                         categorycode => $borrower->{categorycode},
1647                         itemtype     => $item_object->effective_itemtype,
1648                         branchcode   => $branchcode,
1649                         rule_name    => 'auto_renew'
1650                     }
1651                 );
1652
1653                 $auto_renew = $rule if defined $rule && $rule ne '';
1654             }
1655
1656             my $issue_attributes = {
1657                 borrowernumber  => $borrower->{'borrowernumber'},
1658                 issuedate       => $issuedate,
1659                 date_due        => $datedue,
1660                 branchcode      => C4::Context->userenv->{'branch'},
1661                 onsite_checkout => $onsite_checkout,
1662                 auto_renew      => $auto_renew ? 1 : 0,
1663             };
1664
1665             # Get ID of logged in user.  if called from a batch job,
1666             # no user session exists and C4::Context->userenv() returns
1667             # the scalar '0'. Only do this if the syspref says so
1668             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1669                 my $userenv = C4::Context->userenv();
1670                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1671                 if ($usernumber) {
1672                     $issue_attributes->{issuer_id} = $usernumber;
1673                 }
1674             }
1675
1676             # In the case that the borrower has an on-site checkout
1677             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1678             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1679             if ($issue) {
1680                 $issue->set($issue_attributes)->store;
1681             }
1682             else {
1683                 $issue = Koha::Checkout->new(
1684                     {
1685                         itemnumber => $item_object->itemnumber,
1686                         %$issue_attributes,
1687                     }
1688                 )->store;
1689             }
1690             $issue->discard_changes;
1691             C4::Auth::track_login_daily( $borrower->{userid} );
1692             if ( $item_object->location && $item_object->location eq 'CART'
1693                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1694             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1695                 CartToShelf( $item_object->itemnumber );
1696             }
1697
1698             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1699                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1700             }
1701
1702             # Record if item was lost
1703             my $was_lost = $item_object->itemlost;
1704
1705             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1706             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1707             $item_object->itemlost(0);
1708             $item_object->onloan($datedue->ymd());
1709             $item_object->datelastborrowed( dt_from_string()->ymd() );
1710             $item_object->datelastseen( dt_from_string() );
1711             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1712
1713             # If the item was lost, it has now been found, charge the overdue if necessary
1714             if ($was_lost) {
1715                 if ( $item_object->{_charge} ) {
1716                     $actualissue //= Koha::Old::Checkouts->search(
1717                         { itemnumber => $item_unblessed->{itemnumber} },
1718                         {
1719                             order_by => { '-desc' => 'returndate' },
1720                             rows     => 1
1721                         }
1722                     )->single;
1723                     unless ( exists( $borrower->{branchcode} ) ) {
1724                         my $patron = $actualissue->patron;
1725                         $borrower = $patron->unblessed;
1726                     }
1727                     _CalculateAndUpdateFine(
1728                         {
1729                             issue       => $actualissue,
1730                             item        => $item_unblessed,
1731                             borrower    => $borrower,
1732                             return_date => $issuedate
1733                         }
1734                     );
1735                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1736                         $item_object->itemnumber, undef, 'RENEWED' );
1737                 }
1738             }
1739
1740             # If it costs to borrow this book, charge it to the patron's account.
1741             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1742             if ( $charge && $charge > 0 ) {
1743                 AddIssuingCharge( $issue, $charge, 'RENT' );
1744             }
1745
1746             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1747             if ( $itemtype_object ) {
1748                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1749                 if ( $accumulate_charge > 0 ) {
1750                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1751                     $charge += $accumulate_charge;
1752                     $item_unblessed->{charge} = $charge;
1753                 }
1754             }
1755
1756             my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckout');
1757             if ($yaml) {
1758                 $yaml = "$yaml\n\n";
1759
1760                 my $rules;
1761                 eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
1762                 if ($@) {
1763                     warn "Unable to parse UpdateNotForLoanStatusOnCheckout syspref : $@";
1764                 }
1765                 else {
1766                     foreach my $key ( keys %$rules ) {
1767                         if ( $item_object->notforloan eq $key ) {
1768                             $item_object->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
1769                             last;
1770                         }
1771                     }
1772                 }
1773             }
1774
1775             # Record the fact that this book was issued.
1776             C4::Stats::UpdateStats(
1777                 {
1778                     branch => C4::Context->userenv->{'branch'},
1779                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1780                     amount         => $charge,
1781                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1782                     itemnumber     => $item_object->itemnumber,
1783                     itemtype       => $item_object->effective_itemtype,
1784                     location       => $item_object->location,
1785                     borrowernumber => $borrower->{'borrowernumber'},
1786                     ccode          => $item_object->ccode,
1787                     categorycode   => $borrower->{'categorycode'},
1788                     interface      => C4::Context->interface,
1789                 }
1790             );
1791
1792             # Send a checkout slip.
1793             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1794             my %conditions        = (
1795                 branchcode   => $branchcode,
1796                 categorycode => $borrower->{categorycode},
1797                 item_type    => $item_object->effective_itemtype,
1798                 notification => 'CHECKOUT',
1799             );
1800             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1801                 SendCirculationAlert(
1802                     {
1803                         type     => 'CHECKOUT',
1804                         item     => $item_object->unblessed,
1805                         borrower => $borrower,
1806                         branch   => $branchcode,
1807                     }
1808                 );
1809             }
1810             logaction(
1811                 "CIRCULATION", "ISSUE",
1812                 $borrower->{'borrowernumber'},
1813                 $item_object->itemnumber,
1814             ) if C4::Context->preference("IssueLog");
1815
1816             Koha::Plugins->call('after_circ_action', {
1817                 action  => 'checkout',
1818                 payload => {
1819                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1820                     checkout => $issue->get_from_storage
1821                 }
1822             });
1823
1824             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1825                 {
1826                     biblio_ids => [ $item_object->biblionumber ]
1827                 }
1828             ) if C4::Context->preference('RealTimeHoldsQueue');
1829         }
1830     }
1831     return $issue;
1832 }
1833
1834 =head2 GetLoanLength
1835
1836   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1837
1838 Get loan length for an itemtype, a borrower type and a branch
1839
1840 =cut
1841
1842 sub GetLoanLength {
1843     my ( $categorycode, $itemtype, $branchcode ) = @_;
1844
1845     # Initialize default values
1846     my $rules = {
1847         issuelength   => 0,
1848         renewalperiod => 0,
1849         lengthunit    => 'days',
1850     };
1851
1852     my $found = Koha::CirculationRules->get_effective_rules( {
1853         branchcode => $branchcode,
1854         categorycode => $categorycode,
1855         itemtype => $itemtype,
1856         rules => [
1857             'issuelength',
1858             'renewalperiod',
1859             'lengthunit'
1860         ],
1861     } );
1862
1863     # Search for rules!
1864     foreach my $rule_name (keys %$found) {
1865         $rules->{$rule_name} = $found->{$rule_name};
1866     }
1867
1868     return $rules;
1869 }
1870
1871
1872 =head2 GetHardDueDate
1873
1874   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1875
1876 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1877
1878 =cut
1879
1880 sub GetHardDueDate {
1881     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1882
1883     my $rules = Koha::CirculationRules->get_effective_rules(
1884         {
1885             categorycode => $borrowertype,
1886             itemtype     => $itemtype,
1887             branchcode   => $branchcode,
1888             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1889         }
1890     );
1891
1892     if ( defined( $rules->{hardduedate} ) ) {
1893         if ( $rules->{hardduedate} ) {
1894             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1895         }
1896         else {
1897             return ( undef, undef );
1898         }
1899     }
1900 }
1901
1902 =head2 GetBranchBorrowerCircRule
1903
1904   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1905
1906 Retrieves circulation rule attributes that apply to the given
1907 branch and patron category, regardless of item type.
1908 The return value is a hashref containing the following key:
1909
1910 patron_maxissueqty - maximum number of loans that a
1911 patron of the given category can have at the given
1912 branch.  If the value is undef, no limit.
1913
1914 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1915 patron of the given category can have at the given
1916 branch.  If the value is undef, no limit.
1917
1918 This will check for different branch/category combinations in the following order:
1919 branch and category
1920 branch only
1921 category only
1922 default branch and category
1923
1924 If no rule has been found in the database, it will default to
1925 the buillt in rule:
1926
1927 patron_maxissueqty - undef
1928 patron_maxonsiteissueqty - undef
1929
1930 C<$branchcode> and C<$categorycode> should contain the
1931 literal branch code and patron category code, respectively - no
1932 wildcards.
1933
1934 =cut
1935
1936 sub GetBranchBorrowerCircRule {
1937     my ( $branchcode, $categorycode ) = @_;
1938
1939     # Initialize default values
1940     my $rules = {
1941         patron_maxissueqty       => undef,
1942         patron_maxonsiteissueqty => undef,
1943     };
1944
1945     # Search for rules!
1946     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1947         my $rule = Koha::CirculationRules->get_effective_rule(
1948             {
1949                 categorycode => $categorycode,
1950                 itemtype     => undef,
1951                 branchcode   => $branchcode,
1952                 rule_name    => $rule_name,
1953             }
1954         );
1955
1956         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1957     }
1958
1959     return $rules;
1960 }
1961
1962 =head2 GetBranchItemRule
1963
1964   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1965
1966 Retrieves circulation rule attributes that apply to the given
1967 branch and item type, regardless of patron category.
1968
1969 The return value is a hashref containing the following keys:
1970
1971 holdallowed => Hold policy for this branch and itemtype. Possible values:
1972   not_allowed:           No holds allowed.
1973   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1974   from_any_library:      Holds allowed from any patron.
1975   from_local_hold_group: Holds allowed from libraries in hold group
1976
1977 This searches branchitemrules in the following order:
1978
1979   * Same branchcode and itemtype
1980   * Same branchcode, itemtype '*'
1981   * branchcode '*', same itemtype
1982   * branchcode and itemtype '*'
1983
1984 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1985
1986 =cut
1987
1988 sub GetBranchItemRule {
1989     my ( $branchcode, $itemtype ) = @_;
1990
1991     # Search for rules!
1992     my $rules = Koha::CirculationRules->get_effective_rules({
1993         branchcode => $branchcode,
1994         itemtype => $itemtype,
1995         rules => ['holdallowed', 'hold_fulfillment_policy']
1996     });
1997
1998     # built-in default circulation rule
1999     $rules->{holdallowed} //= 'from_any_library';
2000     $rules->{hold_fulfillment_policy} //= 'any';
2001
2002     return $rules;
2003 }
2004
2005 =head2 AddReturn
2006
2007   ($doreturn, $messages, $iteminformation, $borrower) =
2008       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
2009
2010 Returns a book.
2011
2012 =over 4
2013
2014 =item C<$barcode> is the bar code of the book being returned.
2015
2016 =item C<$branch> is the code of the branch where the book is being returned.
2017
2018 =item C<$exemptfine> indicates that overdue charges for the item will be
2019 removed. Optional.
2020
2021 =item C<$return_date> allows the default return date to be overridden
2022 by the given return date. Optional.
2023
2024 =back
2025
2026 C<&AddReturn> returns a list of four items:
2027
2028 C<$doreturn> is true iff the return succeeded.
2029
2030 C<$messages> is a reference-to-hash giving feedback on the operation.
2031 The keys of the hash are:
2032
2033 =over 4
2034
2035 =item C<BadBarcode>
2036
2037 No item with this barcode exists. The value is C<$barcode>.
2038
2039 =item C<NotIssued>
2040
2041 The book is not currently on loan. The value is C<$barcode>.
2042
2043 =item C<withdrawn>
2044
2045 This book has been withdrawn/cancelled. The value should be ignored.
2046
2047 =item C<Wrongbranch>
2048
2049 This book has was returned to the wrong branch.  The value is a hashref
2050 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2051 contain the branchcode of the incorrect and correct return library, respectively.
2052
2053 =item C<ResFound>
2054
2055 The item was reserved. The value is a reference-to-hash whose keys are
2056 fields from the reserves table of the Koha database, and
2057 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2058 either C<Waiting>, C<Reserved>, or 0.
2059
2060 =item C<WasReturned>
2061
2062 Value 1 if return is successful.
2063
2064 =item C<NeedsTransfer>
2065
2066 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2067
2068 =item C<RecallFound>
2069
2070 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2071 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2072 branchcode.
2073
2074 =item C<TransferredRecall>
2075
2076 This item has been transferred to this branch to fill a recall. The recall object is returned.
2077
2078 =back
2079
2080 C<$iteminformation> is a reference-to-hash, giving information about the
2081 returned item from the issues table.
2082
2083 C<$borrower> is a reference-to-hash, giving information about the
2084 patron who last borrowed the book.
2085
2086 =cut
2087
2088 sub AddReturn {
2089     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2090
2091     if ($branch and not Koha::Libraries->find($branch)) {
2092         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2093         undef $branch;
2094     }
2095     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2096     my $return_date_specified = !!$return_date;
2097     $return_date //= dt_from_string();
2098     my $messages;
2099     my $patron;
2100     my $doreturn       = 1;
2101     my $validTransfer = 1;
2102     my $stat_type = 'return';
2103
2104     # get information on item
2105     my $item = Koha::Items->find({ barcode => $barcode });
2106     unless ($item) {
2107         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2108     }
2109
2110     my $itemnumber = $item->itemnumber;
2111     my $itemtype = $item->effective_itemtype;
2112
2113     my $issue  = $item->checkout;
2114     if ( $issue ) {
2115         $patron = $issue->patron
2116             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2117                 . Dumper($issue->unblessed) . "\n";
2118     } else {
2119         $messages->{'NotIssued'} = $barcode;
2120         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2121
2122         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2123         $doreturn = 0;
2124         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2125         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2126         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2127            $messages->{'LocalUse'} = 1;
2128            $stat_type = 'localuse';
2129         }
2130     }
2131
2132     if ( $item->withdrawn ) { # book has been cancelled
2133         $messages->{'withdrawn'} = 1;
2134
2135         # In the case where we block return of withdrawn, we should completely block the return
2136         # without updating item statuses, so we exit early
2137         return ( 0, $messages, $issue, ( $patron ? $patron->unblessed : {} ))
2138             if C4::Context->preference("BlockReturnOfWithdrawnItems");
2139     }
2140
2141
2142         # full item data, but no borrowernumber or checkout info (no issue)
2143     my $hbr = Koha::CirculationRules->get_return_branch_policy($item);
2144         # get the proper branch to which to return the item
2145     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2146         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2147     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2148
2149     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2150     my $patron_unblessed = $patron ? $patron->unblessed : {};
2151
2152     my $update_loc_rules = C4::Context->yaml_preference('UpdateItemLocationOnCheckin');
2153     if ($update_loc_rules) {
2154         if ( defined $update_loc_rules->{_ALL_} ) {
2155             if ( $update_loc_rules->{_ALL_} eq '_PERM_' ) {
2156                 $update_loc_rules->{_ALL_} = $item->permanent_location;
2157             }
2158             if ( $update_loc_rules->{_ALL_} eq '_BLANK_' ) {
2159                 $update_loc_rules->{_ALL_} = '';
2160             }
2161             if (
2162                 (
2163                     defined $item->location
2164                     && $item->location ne $update_loc_rules->{_ALL_}
2165                 )
2166                 || ( !defined $item->location
2167                     && $update_loc_rules->{_ALL_} ne "" )
2168               )
2169             {
2170                 $messages->{'ItemLocationUpdated'} =
2171                   { from => $item->location, to => $update_loc_rules->{_ALL_} };
2172                 $item->location( $update_loc_rules->{_ALL_} )->store(
2173                     {
2174                         log_action        => 0,
2175                         skip_record_index => 1,
2176                         skip_holds_queue  => 1
2177                     }
2178                 );
2179             }
2180         }
2181         else {
2182             foreach my $key ( keys %$update_loc_rules ) {
2183                 if ( $update_loc_rules->{$key} eq '_PERM_' ) {
2184                     $update_loc_rules->{$key} = $item->permanent_location;
2185                 }
2186                 elsif ( $update_loc_rules->{$key} eq '_BLANK_' ) {
2187                     $update_loc_rules->{$key} = '';
2188                 }
2189                 if (
2190                     (
2191                            defined $item->location
2192                         && $item->location eq $key
2193                         && $item->location ne $update_loc_rules->{$key}
2194                     )
2195                     || (   $key eq '_BLANK_'
2196                         && ( !defined $item->location || $item->location eq '' )
2197                         && $update_loc_rules->{$key} ne '' )
2198                   )
2199                 {
2200                     $messages->{'ItemLocationUpdated'} = {
2201                         from => $item->location,
2202                         to   => $update_loc_rules->{$key}
2203                     };
2204                     $item->location( $update_loc_rules->{$key} )->store(
2205                         {
2206                             log_action        => 0,
2207                             skip_record_index => 1,
2208                             skip_holds_queue  => 1
2209                         }
2210                     );
2211                     last;
2212                 }
2213             }
2214         }
2215     }
2216
2217     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2218     if ($yaml) {
2219         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2220         my $rules;
2221         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2222         if ($@) {
2223             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2224         }
2225         else {
2226             foreach my $key ( keys %$rules ) {
2227                 if ( $item->notforloan eq $key ) {
2228                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2229                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 }) unless $rules->{$key} eq 'ONLYMESSAGE';
2230                     last;
2231                 }
2232             }
2233         }
2234     }
2235
2236     # check if the return is allowed at this branch
2237     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2238     unless ($returnallowed){
2239         $messages->{'Wrongbranch'} = {
2240             Wrongbranch => $branch,
2241             Rightbranch => $message
2242         };
2243         $doreturn = 0;
2244         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2245         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2246         return ( $doreturn, $messages, $issue, $patron_unblessed);
2247     }
2248
2249     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2250         $doreturn = 0;
2251     }
2252
2253     # case of a return of document (deal with issues and holdingbranch)
2254     if ($doreturn) {
2255         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2256         $patron or warn "AddReturn without current borrower";
2257
2258         if ($patron) {
2259             eval {
2260                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2261             };
2262             unless ( $@ ) {
2263                 if (
2264                     (
2265                         C4::Context->preference('CalculateFinesOnReturn')
2266                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2267                     )
2268                     && !$item->itemlost
2269                   )
2270                 {
2271                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2272                 }
2273             } else {
2274                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2275
2276                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2277                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2278
2279                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2280             }
2281
2282             # FIXME is the "= 1" right?  This could be the borrower hash.
2283             $messages->{'WasReturned'} = 1;
2284
2285         } else {
2286             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2287         }
2288     }
2289
2290     # the holdingbranch is updated if the document is returned to another location.
2291     # this is always done regardless of whether the item was on loan or not
2292     if ($item->holdingbranch ne $branch) {
2293         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2294     }
2295
2296     my $item_was_lost = $item->itemlost;
2297     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2298     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2299
2300     # fix up the accounts.....
2301     if ($item_was_lost) {
2302         $messages->{'WasLost'} = 1;
2303         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2304             my @object_messages = @{ $updated_item->object_messages };
2305             for my $message (@object_messages) {
2306                 $messages->{'LostItemFeeRefunded'} = 1
2307                   if $message->message eq 'lost_refunded';
2308                 $messages->{'ProcessingFeeRefunded'} = 1
2309                   if $message->message eq 'processing_refunded';
2310                 $messages->{'LostItemFeeRestored'} = 1
2311                   if $message->message eq 'lost_restored';
2312
2313                 if ( $message->message eq 'lost_charge' ) {
2314                     $issue //= Koha::Old::Checkouts->search(
2315                         { itemnumber => $item->itemnumber },
2316                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2317                     )->single;
2318                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2319                         my $patron = $issue->patron;
2320                         $patron_unblessed = $patron->unblessed;
2321                     }
2322                     _CalculateAndUpdateFine(
2323                         {
2324                             issue       => $issue,
2325                             item        => $item->unblessed,
2326                             borrower    => $patron_unblessed,
2327                             return_date => $return_date
2328                         }
2329                     );
2330                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2331                         $item->itemnumber, undef, 'RETURNED' );
2332                     $messages->{'LostItemFeeCharged'} = 1;
2333                 }
2334             }
2335         }
2336     }
2337
2338     # check if we have a transfer for this document
2339     my $transfer = $item->get_transfer;
2340
2341     # if we have a transfer to complete, we update the line of transfers with the datearrived
2342     if ($transfer) {
2343         $validTransfer = 0;
2344         if ( $transfer->in_transit ) {
2345             if ( $transfer->tobranch eq $branch ) {
2346                 $transfer->receive;
2347                 $messages->{'TransferArrived'} = $transfer->frombranch;
2348                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2349                 $validTransfer = 1
2350                   if defined $transfer->reason && $transfer->reason eq 'Reserve';
2351             }
2352             else {
2353                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2354                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2355                 $messages->{'TransferTrigger'}   = $transfer->reason;
2356             }
2357         }
2358         else {
2359             if ( $transfer->tobranch eq $branch ) {
2360                 $transfer->receive;
2361                 $messages->{'TransferArrived'} = $transfer->frombranch;
2362                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2363                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2364             }
2365             else {
2366                 $messages->{'TransferTrigger'} = $transfer->reason;
2367                 if ( $transfer->frombranch eq $branch ) {
2368                     $transfer->transit;
2369                     $messages->{'WasTransfered'}   = $transfer->tobranch;
2370                 }
2371                 else {
2372                     $messages->{'WrongTransfer'}     = $transfer->tobranch;
2373                     $messages->{'WrongTransferItem'} = $item->itemnumber;
2374                 }
2375             }
2376         }
2377     }
2378
2379     # fix up the overdues in accounts...
2380     if ($borrowernumber) {
2381         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2382         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2383
2384         if ( $issue and $issue->is_overdue($return_date) ) {
2385         # fix fine days
2386             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2387             if ($debardate and $debardate ne "9999-12-31") {
2388                 if ($reminder){
2389                     $messages->{'PrevDebarred'} = $debardate;
2390                 } else {
2391                     $messages->{'Debarred'} = $debardate;
2392                 }
2393             } elsif ($patron->debarred) {
2394                 if ( $patron->debarred eq "9999-12-31") {
2395                     $messages->{'ForeverDebarred'} = $patron->debarred;
2396                 } else {
2397                     my $borrower_debar_dt = dt_from_string( $patron->debarred );
2398                     $borrower_debar_dt->truncate(to => 'day');
2399                     my $today_dt = $return_date->clone()->truncate(to => 'day');
2400                     if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2401                         $messages->{'PrevDebarred'} = $patron->debarred;
2402                     }
2403                 }
2404             }
2405         # there's no overdue on the item but borrower had been previously debarred
2406         } elsif ( $issue->date_due and $patron->debarred ) {
2407              if ( $patron->debarred eq "9999-12-31") {
2408                 $messages->{'ForeverDebarred'} = $patron->debarred;
2409              } else {
2410                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2411                   $borrower_debar_dt->truncate(to => 'day');
2412                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2413                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2414                       $messages->{'PrevDebarred'} = $patron->debarred;
2415                   }
2416              }
2417         }
2418     }
2419
2420     # find recalls...
2421     if ( C4::Context->preference('UseRecalls') ) {
2422         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2423         my $recall = undef;
2424         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2425         if ( defined $recall ) {
2426             $messages->{RecallFound} = $recall;
2427             if ( $recall->pickup_library_id ne $branch ) {
2428                 $messages->{RecallNeedsTransfer} = $branch;
2429             }
2430         }
2431     }
2432
2433     # find reserves.....
2434     # launch the Checkreserves routine to find any holds
2435     my ($resfound, $resrec);
2436     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2437     ($resfound, $resrec, undef) = CheckReserves( $item, $lookahead ) unless ( $item->withdrawn );
2438     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2439     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2440         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2441         $resfound = 'Reserved';
2442         $resrec = $hold->unblessed;
2443     }
2444     if ($resfound) {
2445           $resrec->{'ResFound'} = $resfound;
2446         $messages->{'ResFound'} = $resrec;
2447     }
2448
2449     # Record the fact that this book was returned.
2450     my $categorycode = $patron_unblessed ? $patron_unblessed->{categorycode} : undef;
2451     C4::Stats::UpdateStats({
2452         branch         => $branch,
2453         type           => $stat_type,
2454         itemnumber     => $itemnumber,
2455         itemtype       => $itemtype,
2456         location       => $item->location,
2457         borrowernumber => $borrowernumber,
2458         ccode          => $item->ccode,
2459         categorycode   => $categorycode,
2460         interface      => C4::Context->interface,
2461     });
2462
2463     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2464     if ( $patron ) {
2465         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2466         my %conditions = (
2467             branchcode   => $branch,
2468             categorycode => $patron->categorycode,
2469             item_type    => $itemtype,
2470             notification => 'CHECKIN',
2471         );
2472         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2473             SendCirculationAlert({
2474                 type     => 'CHECKIN',
2475                 item     => $item->unblessed,
2476                 borrower => $patron->unblessed,
2477                 branch   => $branch,
2478                 issue    => $issue
2479             });
2480         }
2481
2482         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2483             if C4::Context->preference("ReturnLog");
2484         }
2485
2486     # Check if this item belongs to a biblio record that is attached to an
2487     # ILL request, if it is we need to update the ILL request's status
2488     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2489         my $request = Koha::Illrequests->find(
2490             { biblio_id => $item->biblio->biblionumber }
2491         );
2492         $request->status('RET') if $request;
2493     }
2494
2495     if ( C4::Context->preference('UseRecalls') ) {
2496         # all recalls that have triggered a transfer will have an allocated itemnumber
2497         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2498         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2499             $messages->{TransferredRecall} = $transfer_recall;
2500         }
2501     }
2502
2503     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2504     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2505         && ( $doreturn or $messages->{'NotIssued'} )
2506         and !$resfound
2507         and ( $branch ne $returnbranch )
2508         and not $messages->{'WrongTransfer'}
2509         and not $messages->{'WasTransfered'}
2510         and not $messages->{TransferredRecall}
2511         and not $messages->{RecallNeedsTransfer} )
2512     {
2513         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2514         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2515             (C4::Context->preference("UseBranchTransferLimits") and
2516              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2517            )) {
2518             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2519             $messages->{'WasTransfered'} = $returnbranch;
2520             $messages->{'TransferTrigger'} = $transfer_trigger;
2521         } else {
2522             $messages->{'NeedsTransfer'} = $returnbranch;
2523             $messages->{'TransferTrigger'} = $transfer_trigger;
2524         }
2525     }
2526
2527     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2528         my $claims = Koha::Checkouts::ReturnClaims->search(
2529            {
2530                itemnumber => $item->id,
2531                resolution => undef,
2532            }
2533         );
2534
2535         if ( $claims->count ) {
2536             $messages->{ReturnClaims} = $claims;
2537         }
2538     }
2539
2540     # Check for bundle status
2541     if ( $item->in_bundle ) {
2542         my $host = $item->bundle_host;
2543         $messages->{InBundle} = $host;
2544     }
2545
2546     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2547     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2548
2549     if ( $doreturn and $issue ) {
2550         my $checkin = Koha::Old::Checkouts->find($issue->id);
2551
2552         Koha::Plugins->call('after_circ_action', {
2553             action  => 'checkin',
2554             payload => {
2555                 checkout=> $checkin
2556             }
2557         });
2558
2559         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2560             {
2561                 biblio_ids => [ $item->biblionumber ]
2562             }
2563         ) if C4::Context->preference('RealTimeHoldsQueue');
2564     }
2565
2566     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2567 }
2568
2569 =head2 MarkIssueReturned
2570
2571   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2572
2573 Unconditionally marks an issue as being returned by
2574 moving the C<issues> row to C<old_issues> and
2575 setting C<returndate> to the current date.
2576
2577 if C<$returndate> is specified (in iso format), it is used as the date
2578 of the return.
2579
2580 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2581 the old_issue is immediately anonymised
2582
2583 Ideally, this function would be internal to C<C4::Circulation>,
2584 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2585 and offline_circ/process_koc.pl.
2586
2587 The last optional parameter allos passing skip_record_index to the item store call.
2588
2589 =cut
2590
2591 sub MarkIssueReturned {
2592     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2593
2594     # Retrieve the issue
2595     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2596
2597     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2598
2599     my $issue_id = $issue->issue_id;
2600
2601     my $schema = Koha::Database->schema;
2602
2603     # FIXME Improve the return value and handle it from callers
2604     $schema->txn_do(sub {
2605
2606         my $patron = Koha::Patrons->find( $borrowernumber );
2607
2608         # Update the returndate value
2609         if ( $returndate ) {
2610             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2611         }
2612         else {
2613             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2614         }
2615
2616         # Create the old_issues entry
2617         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2618
2619         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2620         if ( $privacy && $privacy == 2) {
2621             $old_checkout->anonymize;
2622         }
2623
2624         # And finally delete the issue
2625         $issue->delete;
2626
2627         $issue->item->onloan(undef)->store(
2628             {   log_action        => 0,
2629                 skip_record_index => $params->{skip_record_index},
2630                 skip_holds_queue  => $params->{skip_holds_queue}
2631             }
2632         );
2633
2634         if ( C4::Context->preference('StoreLastBorrower') ) {
2635             my $item = Koha::Items->find( $itemnumber );
2636             $item->last_returned_by( $patron->borrowernumber )->store;
2637         }
2638
2639         # Remove any OVERDUES related debarment if the borrower has no overdues
2640         my $overdue_restrictions = $patron->restrictions->search({ type => 'OVERDUES' });
2641         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2642           && $patron->debarred
2643           && !$patron->has_overdues
2644           && $overdue_restrictions->count
2645         ) {
2646             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2647         }
2648
2649     });
2650
2651     return $issue_id;
2652 }
2653
2654 =head2 _debar_user_on_return
2655
2656     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2657
2658 C<$borrower> borrower hashref
2659
2660 C<$item> item hashref
2661
2662 C<$datedue> date due DateTime object
2663
2664 C<$returndate> DateTime object representing the return time
2665
2666 Internal function, called only by AddReturn that calculates and updates
2667  the user fine days, and debars them if necessary.
2668
2669 Should only be called for overdue returns
2670
2671 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2672 to ease testing.
2673
2674 =cut
2675
2676 sub _calculate_new_debar_dt {
2677     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2678
2679     my $branchcode = _GetCircControlBranch( $item, $borrower );
2680     my $circcontrol = C4::Context->preference('CircControl');
2681     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2682         {   categorycode => $borrower->{categorycode},
2683             itemtype     => $item->{itype},
2684             branchcode   => $branchcode,
2685             rules => [
2686                 'finedays',
2687                 'lengthunit',
2688                 'firstremind',
2689                 'maxsuspensiondays',
2690                 'suspension_chargeperiod',
2691             ]
2692         }
2693     );
2694     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2695     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2696     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2697
2698     return unless $finedays;
2699
2700     # finedays is in days, so hourly loans must multiply by 24
2701     # thus 1 hour late equals 1 day suspension * finedays rate
2702     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2703
2704     # grace period is measured in the same units as the loan
2705     my $grace =
2706       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2707
2708     my $deltadays = DateTime::Duration->new(
2709         days => $chargeable_units
2710     );
2711
2712     if ( $deltadays->subtract($grace)->is_positive() ) {
2713         my $suspension_days = $deltadays * $finedays;
2714
2715         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2716             # No need to / 1 and do not consider / 0
2717             $suspension_days = DateTime::Duration->new(
2718                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2719             );
2720         }
2721
2722         # If the max suspension days is < than the suspension days
2723         # the suspension days is limited to this maximum period.
2724         my $max_sd = $issuing_rule->{maxsuspensiondays};
2725         if ( defined $max_sd && $max_sd ne '' ) {
2726             $max_sd = DateTime::Duration->new( days => $max_sd );
2727             $suspension_days = $max_sd
2728               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2729         }
2730
2731         my ( $has_been_extended );
2732         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2733             my $patron = Koha::Patrons->find($borrower->{borrowernumber});
2734             my $debarment = $patron->restrictions->search({type => 'SUSPENSION' },{rows => 1})->single;
2735             if ( $debarment ) {
2736                 $return_date = dt_from_string( $debarment->expiration, 'sql' );
2737                 $has_been_extended = 1;
2738             }
2739         }
2740
2741         my $new_debar_dt;
2742         # Use the calendar or not to calculate the debarment date
2743         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2744             my $calendar = Koha::Calendar->new(
2745                 branchcode => $branchcode,
2746                 days_mode  => 'Calendar'
2747             );
2748             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2749         }
2750         else {
2751             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2752         }
2753         return $new_debar_dt;
2754     }
2755     return;
2756 }
2757
2758 sub _debar_user_on_return {
2759     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2760
2761     $return_date //= dt_from_string();
2762
2763     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2764
2765     return unless $new_debar_dt;
2766
2767     Koha::Patron::Debarments::AddUniqueDebarment({
2768         borrowernumber => $borrower->{borrowernumber},
2769         expiration     => $new_debar_dt->ymd(),
2770         type           => 'SUSPENSION',
2771     });
2772     # if borrower was already debarred but does not get an extra debarment
2773     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2774     my ($new_debarment_str, $is_a_reminder);
2775     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2776         $is_a_reminder = 1;
2777         $new_debarment_str = $borrower->{debarred};
2778     } else {
2779         $new_debarment_str = $new_debar_dt->ymd();
2780     }
2781     # FIXME Should return a DateTime object
2782     return $new_debarment_str, $is_a_reminder;
2783 }
2784
2785 =head2 _FixOverduesOnReturn
2786
2787    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2788
2789 C<$borrowernumber> borrowernumber
2790
2791 C<$itemnumber> itemnumber
2792
2793 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2794
2795 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2796
2797 Internal function
2798
2799 =cut
2800
2801 sub _FixOverduesOnReturn {
2802     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2803     unless( $borrowernumber ) {
2804         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2805         return;
2806     }
2807     unless( $item ) {
2808         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2809         return;
2810     }
2811     unless( $status ) {
2812         warn "_FixOverduesOnReturn() not supplied valid status";
2813         return;
2814     }
2815
2816     my $schema = Koha::Database->schema;
2817
2818     my $result = $schema->txn_do(
2819         sub {
2820             # check for overdue fine
2821             my $accountlines = Koha::Account::Lines->search(
2822                 {
2823                     borrowernumber  => $borrowernumber,
2824                     itemnumber      => $item,
2825                     debit_type_code => 'OVERDUE',
2826                     status          => 'UNRETURNED'
2827                 }
2828             );
2829             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2830
2831             my $accountline = $accountlines->next;
2832             my $payments = $accountline->credits;
2833
2834             my $amountoutstanding = $accountline->amountoutstanding;
2835             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2836                 $accountline->delete;
2837                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2838             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2839                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2840                 my $credit = $account->add_credit(
2841                     {
2842                         amount     => $amountoutstanding,
2843                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2844                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2845                         interface  => C4::Context->interface,
2846                         type       => 'FORGIVEN',
2847                         item_id    => $item
2848                     }
2849                 );
2850
2851                 $credit->apply({ debits => [ $accountline ] });
2852
2853                 if (C4::Context->preference("FinesLog")) {
2854                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2855                 }
2856             }
2857
2858             $accountline->status($status);
2859             return $accountline->store();
2860         }
2861     );
2862
2863     return $result;
2864 }
2865
2866 =head2 _GetCircControlBranch
2867
2868    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2869
2870 Internal function :
2871
2872 Return the library code to be used to determine which circulation
2873 policy applies to a transaction.  Looks up the CircControl and
2874 HomeOrHoldingBranch system preferences.
2875
2876 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2877
2878 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2879
2880 =cut
2881
2882 sub _GetCircControlBranch {
2883     my ($item, $borrower) = @_;
2884     my $circcontrol = C4::Context->preference('CircControl');
2885     my $branch;
2886
2887     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2888         $branch= C4::Context->userenv->{'branch'};
2889     } elsif ($circcontrol eq 'PatronLibrary') {
2890         $branch=$borrower->{branchcode};
2891     } else {
2892         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2893         $branch = $item->{$branchfield};
2894         # default to item home branch if holdingbranch is used
2895         # and is not defined
2896         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2897             $branch = $item->{homebranch};
2898         }
2899     }
2900     return $branch;
2901 }
2902
2903 =head2 GetUpcomingDueIssues
2904
2905   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2906
2907 =cut
2908
2909 sub GetUpcomingDueIssues {
2910     my $params = shift;
2911
2912     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2913     my $dbh = C4::Context->dbh;
2914     my $statement;
2915     $statement = q{
2916         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2917         FROM issues
2918         LEFT JOIN items USING (itemnumber)
2919         LEFT JOIN branches ON branches.branchcode =
2920     };
2921     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2922     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2923     my @bind_parameters = ( $params->{'days_in_advance'} );
2924
2925     my $sth = $dbh->prepare( $statement );
2926     $sth->execute( @bind_parameters );
2927     my $upcoming_dues = $sth->fetchall_arrayref({});
2928
2929     return $upcoming_dues;
2930 }
2931
2932 =head2 CanBookBeRenewed
2933
2934   ($ok,$error,$info) = &CanBookBeRenewed($patron, $issue, $override_limit);
2935
2936 Find out whether a borrowed item may be renewed.
2937
2938 C<$patron> is the patron who currently has the issue.
2939
2940 C<$issue> is the checkout to renew.
2941
2942 C<$override_limit>, if supplied with a true value, causes
2943 the limit on the number of times that the loan can be renewed
2944 (as controlled by the item type) to be ignored. Overriding also allows
2945 to renew sooner than "No renewal before" and to manually renew loans
2946 that are automatically renewed.
2947
2948 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2949 item must currently be on loan to the specified borrower; renewals
2950 must be allowed for the item's type; and the borrower must not have
2951 already renewed the loan.
2952     $error will contain the reason the renewal can not proceed
2953     $info will contain a hash of additional info
2954       currently 'soonest_renew_date' if error is 'too soon'
2955
2956 =cut
2957
2958 sub CanBookBeRenewed {
2959     my ( $patron, $issue, $override_limit, $cron ) = @_;
2960
2961     my $auto_renew = "no";
2962     my $soonest;
2963     my $item = $issue->item;
2964
2965     return ( 0, 'no_item' ) unless $item;
2966     return ( 0, 'no_checkout' ) unless $issue;
2967     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2968     return ( 0, 'item_issued_to_other_patron') if $issue->borrowernumber != $patron->borrowernumber;
2969     return ( 0, 'item_denied_renewal') if $item->is_denied_renewal;
2970
2971        # override_limit will override anything else except on_reserve
2972     unless ( $override_limit ){
2973         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2974         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2975             {
2976                 categorycode => $patron->categorycode,
2977                 itemtype     => $item->effective_itemtype,
2978                 branchcode   => $branchcode,
2979                 rules => [
2980                     'renewalsallowed',
2981                     'lengthunit',
2982                     'unseen_renewals_allowed'
2983                 ]
2984             }
2985         );
2986
2987         return ( 0, "too_many" )
2988           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
2989
2990         return ( 0, "too_unseen" )
2991           if C4::Context->preference('UnseenRenewals') &&
2992             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
2993             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2994
2995         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2996         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2997         my $restricted  = $patron->is_debarred;
2998         my $hasoverdues = $patron->has_overdues;
2999
3000         if ( $restricted and $restrictionblockrenewing ) {
3001             return ( 0, 'restriction');
3002         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
3003             return ( 0, 'overdue');
3004         }
3005
3006         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
3007             patron     => $patron,
3008             item       => $item,
3009             branchcode => $branchcode,
3010             issue      => $issue
3011         });
3012         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
3013         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
3014         # extra notices being sent. Cron also implies no override
3015         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
3016         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
3017         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
3018     }
3019
3020     if ( C4::Context->preference('UseRecalls') ) {
3021         my $recall = undef;
3022         $recall = $item->check_recalls if $item->can_be_waiting_recall;
3023         if ( defined $recall ) {
3024             if ( $recall->item_level ) {
3025                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
3026                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
3027             } else {
3028                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
3029                 return ( 0, 'recalled' ) unless ( $recall->waiting );
3030             }
3031         }
3032     }
3033
3034     # There is an item level hold on this item, no other item can fill the hold
3035     return ( 0, "on_reserve" )
3036       if ( $item->current_holds->search( { non_priority => 0 } )->count );
3037
3038     my $fillable_holds = Koha::Holds->search(
3039         {
3040             biblionumber => $item->biblionumber,
3041             non_priority => 0,
3042             found        => undef,
3043             reservedate  => { '<=' => \'NOW()' },
3044             suspend      => 0
3045         }
3046     );
3047     if ( $fillable_holds->count ) {
3048         if ( C4::Context->preference('AllowRenewalIfOtherItemsAvailable') ) {
3049             my @possible_holds = $fillable_holds->as_list;
3050
3051             # Get all other items that could possibly fill reserves
3052             # FIXME We could join reserves (or more tables) here to eliminate some checks later
3053             my @other_items = Koha::Items->search({
3054                 biblionumber => $item->biblionumber,
3055                 onloan       => undef,
3056                 notforloan   => 0,
3057                 -not         => { itemnumber => $item->itemnumber } })->as_list;
3058
3059             return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
3060
3061             my %matched_items;
3062             foreach my $possible_hold (@possible_holds) {
3063                 my $fillable = 0;
3064                 my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
3065
3066                 # FIXME: We are not checking whether the item we are renewing can fill the hold
3067
3068                 foreach my $other_item (@other_items) {
3069                   next if defined $matched_items{$other_item->itemnumber};
3070                   next if IsItemOnHoldAndFound( $other_item->itemnumber );
3071                   next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef);
3072                   next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
3073                   # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
3074                   # CanItemBeReserved checks 'rules' and 'policies' which means
3075                   # items will fill holds at checkin that are rejected here
3076                   $fillable = 1;
3077                   $matched_items{$other_item->itemnumber} = 1;
3078                   last;
3079                 }
3080                 return ( 0, "on_reserve" ) unless $fillable;
3081             }
3082         }
3083         else {
3084             my ($status, $matched_reserve, $possible_reserves) = CheckReserves($item);
3085             return ( 0, "on_reserve" ) if $status;
3086         }
3087     }
3088
3089     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
3090     $soonest = GetSoonestRenewDate($patron, $issue);
3091     if ( $soonest > dt_from_string() ){
3092         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
3093     }
3094
3095     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
3096
3097     return ( 1, undef );
3098 }
3099
3100 =head2 AddRenewal
3101
3102   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen], [$automatic]);
3103
3104 Renews a loan.
3105
3106 C<$borrowernumber> is the borrower number of the patron who currently
3107 has the item.
3108
3109 C<$itemnumber> is the number of the item to renew.
3110
3111 C<$branch> is the library where the renewal took place (if any).
3112            The library that controls the circ policies for the renewal is retrieved from the issues record.
3113
3114 C<$datedue> can be a DateTime object used to set the due date.
3115
3116 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3117 this parameter is not supplied, lastreneweddate is set to the current date.
3118
3119 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3120 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3121 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3122 syspref)
3123
3124 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3125 from the book's item type.
3126
3127 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3128 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3129 fallback to a true value
3130
3131 C<$automatic> is a boolean flag indicating the renewal was triggered automatically and not by a person ( librarian or patron )
3132
3133 C<$skip_record_index> is an optional boolean flag to indicate whether queuing the search indexing
3134 should be skipped for this renewal.
3135
3136 =cut
3137
3138 sub AddRenewal {
3139     my $borrowernumber  = shift;
3140     my $itemnumber      = shift or return;
3141     my $branch          = shift;
3142     my $datedue         = shift;
3143     my $lastreneweddate = shift || dt_from_string();
3144     my $skipfinecalc    = shift;
3145     my $seen            = shift;
3146     my $automatic       = shift;
3147     my $skip_record_index = shift;
3148
3149     # Fallback on a 'seen' renewal
3150     $seen = defined $seen && $seen == 0 ? 0 : 1;
3151
3152     my $item_object   = Koha::Items->find($itemnumber) or return;
3153     my $biblio = $item_object->biblio;
3154     my $issue  = $item_object->checkout;
3155     my $item_unblessed = $item_object->unblessed;
3156
3157     my $renewal_type = $automatic ? "Automatic" : "Manual";
3158
3159     my $dbh = C4::Context->dbh;
3160
3161     return unless $issue;
3162
3163     $borrowernumber ||= $issue->borrowernumber;
3164
3165     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3166         $datedue = dt_from_string($datedue, 'sql');
3167     }
3168
3169     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3170     my $patron_unblessed = $patron->unblessed;
3171
3172     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3173
3174     my $schema = Koha::Database->schema;
3175     $schema->txn_do(sub{
3176
3177         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3178             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3179         }
3180         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3181
3182         # If the due date wasn't specified, calculate it by adding the
3183         # book's loan length to today's date or the current due date
3184         # based on the value of the RenewalPeriodBase syspref.
3185         my $itemtype = $item_object->effective_itemtype;
3186         unless ($datedue) {
3187
3188             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3189                                             dt_from_string( $issue->date_due, 'sql' ) :
3190                                             dt_from_string();
3191             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3192         }
3193
3194         my $fees = Koha::Charges::Fees->new(
3195             {
3196                 patron    => $patron,
3197                 library   => $circ_library,
3198                 item      => $item_object,
3199                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3200                 to_date   => dt_from_string($datedue),
3201             }
3202         );
3203
3204         # Increment the unseen renewals, if appropriate
3205         # We only do so if the syspref is enabled and
3206         # a maximum value has been set in the circ rules
3207         my $unseen_renewals = $issue->unseen_renewals;
3208         if (C4::Context->preference('UnseenRenewals')) {
3209             my $rule = Koha::CirculationRules->get_effective_rule(
3210                 {   categorycode => $patron->categorycode,
3211                     itemtype     => $item_object->effective_itemtype,
3212                     branchcode   => $circ_library->branchcode,
3213                     rule_name    => 'unseen_renewals_allowed'
3214                 }
3215             );
3216             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3217                 $unseen_renewals++;
3218             } else {
3219                 # If the renewal is seen, unseen should revert to 0
3220                 $unseen_renewals = 0;
3221             }
3222         }
3223
3224         # Update the issues record to have the new due date, and a new count
3225         # of how many times it has been renewed.
3226         my $renews = ( $issue->renewals_count || 0 ) + 1;
3227         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3228
3229         eval{
3230             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3231         };
3232         if( $sth->err ){
3233             Koha::Exceptions::Checkout::FailedRenewal->throw(
3234                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3235             );
3236         }
3237
3238         # Update the renewal count on the item, and tell zebra to reindex
3239         $renews = ( $item_object->renewals || 0 ) + 1;
3240         $item_object->renewals($renews);
3241         $item_object->onloan($datedue);
3242         # Don't index as we are in a transaction, skip hardcoded here
3243         $item_object->store({ log_action => 0, skip_record_index => 1 });
3244
3245         # Charge a new rental fee, if applicable
3246         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3247         if ( $charge > 0 ) {
3248             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3249         }
3250
3251         # Charge a new accumulate rental fee, if applicable
3252         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3253         if ( $itemtype_object ) {
3254             my $accumulate_charge = $fees->accumulate_rentalcharge();
3255             if ( $accumulate_charge > 0 ) {
3256                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3257             }
3258             $charge += $accumulate_charge;
3259         }
3260
3261         # Send a renewal slip according to checkout alert preferencei
3262         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3263             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3264             my %conditions        = (
3265                 branchcode   => $branch,
3266                 categorycode => $patron->categorycode,
3267                 item_type    => $itemtype,
3268                 notification => 'CHECKOUT',
3269             );
3270             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3271                 SendCirculationAlert(
3272                     {
3273                         type     => 'RENEWAL',
3274                         item     => $item_unblessed,
3275                         borrower => $patron->unblessed,
3276                         branch   => $branch,
3277                     }
3278                 );
3279             }
3280         }
3281
3282         # Remove any OVERDUES related debarment if the borrower has no overdues
3283         my $overdue_restrictions = $patron->restrictions->search({ type => 'OVERDUES' });
3284         if ( $patron
3285           && $patron->is_debarred
3286           && ! $patron->has_overdues
3287           && $overdue_restrictions->count
3288         ) {
3289             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3290         }
3291
3292         # Add renewal record
3293         my $renewal = Koha::Checkouts::Renewal->new(
3294             {
3295                 checkout_id  => $issue->issue_id,
3296                 interface    => C4::Context->interface,
3297                 renewal_type => $renewal_type,
3298                 renewer_id   => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3299                 seen         => $seen,
3300             }
3301         )->store();
3302
3303         # Add the renewal to stats
3304         C4::Stats::UpdateStats(
3305             {
3306                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3307                 type           => 'renew',
3308                 amount         => $charge,
3309                 itemnumber     => $itemnumber,
3310                 itemtype       => $itemtype,
3311                 location       => $item_object->location,
3312                 borrowernumber => $borrowernumber,
3313                 ccode          => $item_object->ccode,
3314                 categorycode   => $patron->categorycode,
3315                 interface      => C4::Context->interface,
3316             }
3317         );
3318
3319         #Log the renewal
3320         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3321
3322         Koha::Plugins->call('after_circ_action', {
3323             action  => 'renewal',
3324             payload => {
3325                 checkout  => $issue->get_from_storage
3326             }
3327         });
3328     });
3329
3330     unless( $skip_record_index ){
3331         # We index now, after the transaction is committed
3332         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
3333         $indexer->index_records( $item_object->biblionumber, "specialUpdate", "biblioserver" );
3334     }
3335
3336     return $datedue;
3337 }
3338
3339 sub GetRenewCount {
3340     # check renewal status
3341     my ( $borrowernumber_or_patron, $itemnumber_or_item ) = @_;
3342
3343     my $dbh           = C4::Context->dbh;
3344     my $renewcount    = 0;
3345     my $unseencount    = 0;
3346     my $renewsallowed = 0;
3347     my $unseenallowed = 0;
3348     my $renewsleft    = 0;
3349     my $unseenleft    = 0;
3350     my $patron = blessed $borrowernumber_or_patron ?
3351         $borrowernumber_or_patron : Koha::Patrons->find($borrowernumber_or_patron);
3352     my $item = blessed $itemnumber_or_item ?
3353         $itemnumber_or_item : Koha::Items->find($itemnumber_or_item);
3354
3355     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3356
3357     # Look in the issues table for this item, lent to this borrower,
3358     # and not yet returned.
3359
3360     # FIXME - I think this function could be redone to use only one SQL call.
3361     my $sth = $dbh->prepare(q{
3362         SELECT * FROM issues
3363         WHERE  (borrowernumber = ?) AND (itemnumber = ?)
3364     });
3365     $sth->execute( $patron->borrowernumber, $item->itemnumber );
3366     my $data = $sth->fetchrow_hashref;
3367     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3368     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3369     # $item and $borrower should be calculated
3370     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3371
3372     my $rules = Koha::CirculationRules->get_effective_rules(
3373         {
3374             categorycode => $patron->categorycode,
3375             itemtype     => $item->effective_itemtype,
3376             branchcode   => $branchcode,
3377             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3378         }
3379     );
3380     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3381     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3382         $rules->{unseen_renewals_allowed} :
3383         0;
3384     $renewsleft    = $renewsallowed - $renewcount;
3385     $unseenleft    = $unseenallowed - $unseencount;
3386     if($renewsleft < 0){ $renewsleft = 0; }
3387     if($unseenleft < 0){ $unseenleft = 0; }
3388     return (
3389         $renewcount,
3390         $renewsallowed,
3391         $renewsleft,
3392         $unseencount,
3393         $unseenallowed,
3394         $unseenleft
3395     );
3396 }
3397
3398 =head2 GetSoonestRenewDate
3399
3400   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($patron, $issue);
3401
3402 Find out the soonest possible renew date of a borrowed item.
3403
3404 C<$patron> is the patron who currently has the item on loan.
3405
3406 C<$issue> is the the item issue.
3407
3408 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3409 renew date, based on the value "No renewal before" of the applicable
3410 issuing rule. Returns the current date if the item can already be
3411 renewed, and returns undefined if the patron, item, or checkout
3412 cannot be found.
3413
3414 =cut
3415
3416 sub GetSoonestRenewDate {
3417     my ( $patron, $issue ) = @_;
3418     return unless $issue;
3419     return unless $patron;
3420
3421     my $item = $issue->item;
3422     return unless $item;
3423
3424     my $dbh = C4::Context->dbh;
3425
3426     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3427     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3428         {   categorycode => $patron->categorycode,
3429             itemtype     => $item->effective_itemtype,
3430             branchcode   => $branchcode,
3431             rules => [
3432                 'norenewalbefore',
3433                 'lengthunit',
3434             ]
3435         }
3436     );
3437
3438     my $now = dt_from_string;
3439
3440     if ( defined $issuing_rule->{norenewalbefore}
3441         and $issuing_rule->{norenewalbefore} ne "" )
3442     {
3443         my $soonestrenewal =
3444           dt_from_string( $issue->date_due )->subtract(
3445             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3446
3447         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3448             and $issuing_rule->{lengthunit} eq 'days' )
3449         {
3450             $soonestrenewal->truncate( to => 'day' );
3451         }
3452         return $soonestrenewal;
3453     } elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
3454         # Checkouts with auto-renewing fall back to due date
3455         my $soonestrenewal = dt_from_string( $issue->date_due );
3456         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3457             and $issuing_rule->{lengthunit} eq 'days' )
3458         {
3459             $soonestrenewal->truncate( to => 'day' );
3460         }
3461         return $soonestrenewal;
3462     }
3463     return $now;
3464 }
3465
3466 =head2 GetLatestAutoRenewDate
3467
3468   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($patron, $issue);
3469
3470 Find out the latest possible auto renew date of a borrowed item.
3471
3472 C<$patron> is the patron who currently has the item on loan.
3473
3474 C<$issue> is the item issue.
3475
3476 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3477 auto renew date, based on the value "No auto renewal after" and the "No auto
3478 renewal after (hard limit) of the applicable issuing rule.
3479 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3480 or item cannot be found.
3481
3482 =cut
3483
3484 sub GetLatestAutoRenewDate {
3485     my ( $patron, $issue ) = @_;
3486     return unless $issue;
3487     return unless $patron;
3488
3489     my $item = $issue->item;
3490     return unless $item;
3491
3492     my $dbh = C4::Context->dbh;
3493
3494     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3495     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3496         {
3497             categorycode => $patron->categorycode,
3498             itemtype     => $item->effective_itemtype,
3499             branchcode   => $branchcode,
3500             rules => [
3501                 'no_auto_renewal_after',
3502                 'no_auto_renewal_after_hard_limit',
3503                 'lengthunit',
3504             ]
3505         }
3506     );
3507
3508     return unless $circulation_rules;
3509     return
3510       if ( not $circulation_rules->{no_auto_renewal_after}
3511             or $circulation_rules->{no_auto_renewal_after} eq '' )
3512       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3513              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3514
3515     my $maximum_renewal_date;
3516     if ( $circulation_rules->{no_auto_renewal_after} ) {
3517         $maximum_renewal_date = dt_from_string($issue->issuedate);
3518         $maximum_renewal_date->add(
3519             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3520         );
3521     }
3522
3523     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3524         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3525         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3526     }
3527     return $maximum_renewal_date;
3528 }
3529
3530
3531 =head2 GetIssuingCharges
3532
3533   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3534
3535 Calculate how much it would cost for a given patron to borrow a given
3536 item, including any applicable discounts.
3537
3538 C<$itemnumber> is the item number of item the patron wishes to borrow.
3539
3540 C<$borrowernumber> is the patron's borrower number.
3541
3542 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3543 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3544 if it's a video).
3545
3546 =cut
3547
3548 sub GetIssuingCharges {
3549
3550     # calculate charges due
3551     my ( $itemnumber, $borrowernumber ) = @_;
3552     my $charge = 0;
3553     my $dbh    = C4::Context->dbh;
3554     my $item_type;
3555
3556     # Get the book's item type and rental charge (via its biblioitem).
3557     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3558         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3559     $charge_query .= (C4::Context->preference('item-level_itypes'))
3560         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3561         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3562
3563     $charge_query .= ' WHERE items.itemnumber =?';
3564
3565     my $sth = $dbh->prepare($charge_query);
3566     $sth->execute($itemnumber);
3567     my $patron;
3568     if ( my $item_data = $sth->fetchrow_hashref ) {
3569         $item_type = $item_data->{itemtype};
3570         $charge    = $item_data->{rentalcharge};
3571         if ($charge) {
3572             # FIXME This should follow CircControl
3573             my $branch = C4::Context::mybranch();
3574             $patron //= Koha::Patrons->find( $borrowernumber );
3575             my $discount = Koha::CirculationRules->get_effective_rule({
3576                 categorycode => $patron->categorycode,
3577                 branchcode   => $branch,
3578                 itemtype     => $item_type,
3579                 rule_name    => 'rentaldiscount'
3580             });
3581             if ($discount) {
3582                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3583             }
3584             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3585         }
3586     }
3587
3588     return ( $charge, $item_type );
3589 }
3590
3591 =head2 AddIssuingCharge
3592
3593   &AddIssuingCharge( $checkout, $charge, $type )
3594
3595 =cut
3596
3597 sub AddIssuingCharge {
3598     my ( $checkout, $charge, $type ) = @_;
3599
3600     # FIXME What if checkout does not exist?
3601
3602     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3603     my $accountline = $account->add_debit(
3604         {
3605             amount      => $charge,
3606             note        => undef,
3607             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3608             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3609             interface   => C4::Context->interface,
3610             type        => $type,
3611             item_id     => $checkout->itemnumber,
3612             issue_id    => $checkout->issue_id,
3613         }
3614     );
3615 }
3616
3617 =head2 GetTransfersFromTo
3618
3619   @results = GetTransfersFromTo($frombranch,$tobranch);
3620
3621 Returns the list of pending transfers between $from and $to branch
3622
3623 =cut
3624
3625 sub GetTransfersFromTo {
3626     my ( $frombranch, $tobranch ) = @_;
3627     return unless ( $frombranch && $tobranch );
3628     my $dbh   = C4::Context->dbh;
3629     my $query = "
3630         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3631         FROM   branchtransfers
3632         WHERE  frombranch=?
3633           AND  tobranch=?
3634           AND datecancelled IS NULL
3635           AND datesent IS NOT NULL
3636           AND datearrived IS NULL
3637     ";
3638     my $sth = $dbh->prepare($query);
3639     $sth->execute( $frombranch, $tobranch );
3640     my @gettransfers;
3641
3642     while ( my $data = $sth->fetchrow_hashref ) {
3643         push @gettransfers, $data;
3644     }
3645     return (@gettransfers);
3646 }
3647
3648 =head2 SendCirculationAlert
3649
3650 Send out a C<check-in> or C<checkout> alert using the messaging system.
3651
3652 B<Parameters>:
3653
3654 =over 4
3655
3656 =item type
3657
3658 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3659
3660 =item item
3661
3662 Hashref of information about the item being checked in or out.
3663
3664 =item borrower
3665
3666 Hashref of information about the borrower of the item.
3667
3668 =item branch
3669
3670 The branchcode from where the checkout or check-in took place.
3671
3672 =back
3673
3674 B<Example>:
3675
3676     SendCirculationAlert({
3677         type     => 'CHECKOUT',
3678         item     => $item,
3679         borrower => $borrower,
3680         branch   => $branch,
3681     });
3682
3683 =cut
3684
3685 sub SendCirculationAlert {
3686     my ($opts) = @_;
3687     my ($type, $item, $borrower, $branch, $issue) =
3688         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3689     my %message_name = (
3690         CHECKIN  => 'Item_Check_in',
3691         CHECKOUT => 'Item_Checkout',
3692         RENEWAL  => 'Item_Checkout',
3693     );
3694     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3695         borrowernumber => $borrower->{borrowernumber},
3696         message_name   => $message_name{$type},
3697     });
3698
3699
3700     my $tables = {
3701         items => $item->{itemnumber},
3702         biblio      => $item->{biblionumber},
3703         biblioitems => $item->{biblionumber},
3704         borrowers   => $borrower,
3705         branches    => $branch,
3706     };
3707
3708     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3709     # See C4::Letters:: _parseletter_sth
3710     if( $type eq 'CHECKIN' ){
3711         $tables->{old_issues} = $issue->issue_id;
3712     } else {
3713         $tables->{issues} = $item->{itemnumber};
3714     }
3715
3716     my $schema = Koha::Database->new->schema;
3717     my @transports = keys %{ $borrower_preferences->{transports} };
3718
3719     # From the MySQL doc:
3720     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3721     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3722     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3723     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3724
3725     for my $mtt (@transports) {
3726         my $letter =  C4::Letters::GetPreparedLetter (
3727             module => 'circulation',
3728             letter_code => $type,
3729             branchcode => $branch,
3730             message_transport_type => $mtt,
3731             lang => $borrower->{lang},
3732             tables => $tables,
3733         ) or next;
3734
3735         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3736         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3737         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3738         unless ( $message ) {
3739             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3740             my $patron = Koha::Patrons->find($borrower->{borrowernumber});
3741             C4::Message->enqueue($letter, $patron, $mtt);
3742         } else {
3743             $message->append($letter);
3744             $message->update;
3745         }
3746         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3747     }
3748
3749     return;
3750 }
3751
3752 =head2 updateWrongTransfer
3753
3754   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3755
3756 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3757
3758 =cut
3759
3760 sub updateWrongTransfer {
3761         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3762
3763     # first step: cancel the original transfer
3764     my $item = Koha::Items->find($itemNumber);
3765     my $transfer = $item->get_transfer;
3766     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3767
3768     # second step: create a new transfer to the right location
3769     my $new_transfer = $item->request_transfer(
3770         {
3771             to            => $transfer->to_library,
3772             reason        => $transfer->reason,
3773             comment       => $transfer->comments,
3774             ignore_limits => 1,
3775             enqueue       => 1
3776         }
3777     );
3778
3779     return $new_transfer;
3780 }
3781
3782 =head2 CalcDateDue
3783
3784 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3785
3786 this function calculates the due date given the start date and configured circulation rules,
3787 checking against the holidays calendar as per the daysmode circulation rule.
3788 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3789 C<$itemtype>  = itemtype code of item in question
3790 C<$branch>  = location whose calendar to use
3791 C<$borrower> = Borrower object
3792 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3793
3794 =cut
3795
3796 sub CalcDateDue {
3797     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3798
3799     $isrenewal ||= 0;
3800
3801     # loanlength now a href
3802     my $loanlength =
3803             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3804
3805     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3806             ? qq{renewalperiod}
3807             : qq{issuelength};
3808
3809     my $datedue;
3810     if ( $startdate ) {
3811         if (ref $startdate ne 'DateTime' ) {
3812             $datedue = dt_from_string($datedue);
3813         } else {
3814             $datedue = $startdate->clone;
3815         }
3816     } else {
3817         $datedue = dt_from_string()->truncate( to => 'minute' );
3818     }
3819
3820
3821     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3822         {
3823             categorycode => $borrower->{categorycode},
3824             itemtype     => $itemtype,
3825             branchcode   => $branch,
3826         }
3827     );
3828
3829     # calculate the datedue as normal
3830     if ( $daysmode eq 'Days' )
3831     {    # ignoring calendar
3832         if ( $loanlength->{lengthunit} eq 'hours' ) {
3833             $datedue->add( hours => $loanlength->{$length_key} );
3834         } else {    # days
3835             $datedue->add( days => $loanlength->{$length_key} );
3836             $datedue->set_hour(23);
3837             $datedue->set_minute(59);
3838         }
3839     } else {
3840         my $dur;
3841         if ($loanlength->{lengthunit} eq 'hours') {
3842             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3843         }
3844         else { # days
3845             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3846         }
3847         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3848         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3849         if ($loanlength->{lengthunit} eq 'days') {
3850             $datedue->set_hour(23);
3851             $datedue->set_minute(59);
3852         }
3853     }
3854
3855     # if Hard Due Dates are used, retrieve them and apply as necessary
3856     my ( $hardduedate, $hardduedatecompare ) =
3857       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3858     if ($hardduedate) {    # hardduedates are currently dates
3859         $hardduedate->truncate( to => 'minute' );
3860         $hardduedate->set_hour(23);
3861         $hardduedate->set_minute(59);
3862         my $cmp = DateTime->compare( $hardduedate, $datedue );
3863
3864 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3865 # if the calculated date is before the 'after' Hard Due Date (floor), override
3866 # if the hard due date is set to 'exactly', overrride
3867         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3868             $datedue = $hardduedate->clone;
3869         }
3870
3871         # in all other cases, keep the date due as it is
3872
3873     }
3874
3875     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3876     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3877         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3878         if( $expiry_dt ) { #skip empty expiry date..
3879             $expiry_dt->set( hour => 23, minute => 59);
3880             my $d1= $datedue->clone->set_time_zone('floating');
3881             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3882                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3883             }
3884         }
3885         if ( $daysmode ne 'Days' ) {
3886           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3887           if ( $calendar->is_holiday($datedue) ) {
3888               # Don't return on a closed day
3889               $datedue = $calendar->prev_open_days( $datedue, 1 );
3890           }
3891         }
3892     }
3893
3894     return $datedue;
3895 }
3896
3897
3898 sub CheckValidBarcode{
3899 my ($barcode) = @_;
3900 my $dbh = C4::Context->dbh;
3901 my $query=qq|SELECT count(*)
3902              FROM items
3903              WHERE barcode=?
3904             |;
3905 my $sth = $dbh->prepare($query);
3906 $sth->execute($barcode);
3907 my $exist=$sth->fetchrow ;
3908 return $exist;
3909 }
3910
3911 =head2 IsBranchTransferAllowed
3912
3913   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3914
3915 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3916
3917 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3918 Koha::Item->can_be_transferred.
3919
3920 =cut
3921
3922 sub IsBranchTransferAllowed {
3923         my ( $toBranch, $fromBranch, $code ) = @_;
3924
3925         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3926
3927         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3928         my $dbh = C4::Context->dbh;
3929
3930         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3931         $sth->execute( $toBranch, $fromBranch, $code );
3932         my $limit = $sth->fetchrow_hashref();
3933
3934         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3935         if ( $limit->{'limitId'} ) {
3936                 return 0;
3937         } else {
3938                 return 1;
3939         }
3940 }
3941
3942 =head2 CreateBranchTransferLimit
3943
3944   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3945
3946 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3947
3948 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3949
3950 =cut
3951
3952 sub CreateBranchTransferLimit {
3953    my ( $toBranch, $fromBranch, $code ) = @_;
3954    return unless defined($toBranch) && defined($fromBranch);
3955    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3956
3957    my $dbh = C4::Context->dbh;
3958
3959    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3960    return $sth->execute( $code, $toBranch, $fromBranch );
3961 }
3962
3963 =head2 DeleteBranchTransferLimits
3964
3965     my $result = DeleteBranchTransferLimits($frombranch);
3966
3967 Deletes all the library transfer limits for one library.  Returns the
3968 number of limits deleted, 0e0 if no limits were deleted, or undef if
3969 no arguments are supplied.
3970
3971 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3972     fromBranch => $fromBranch
3973     })->delete.
3974
3975 =cut
3976
3977 sub DeleteBranchTransferLimits {
3978     my $branch = shift;
3979     return unless defined $branch;
3980     my $dbh    = C4::Context->dbh;
3981     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3982     return $sth->execute($branch);
3983 }
3984
3985 sub ReturnLostItem{
3986     my ( $borrowernumber, $itemnum ) = @_;
3987     MarkIssueReturned( $borrowernumber, $itemnum );
3988 }
3989
3990 =head2 LostItem
3991
3992   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3993
3994 The final optional parameter, C<$params>, expected to contain
3995 'skip_record_index' key, which relayed down to Koha::Item/store,
3996 there it prevents calling of ModZebra index_records,
3997 which takes most of the time in batch adds/deletes: index_records better
3998 to be called later in C<additem.pl> after the whole loop.
3999
4000 $params:
4001     skip_record_index => 1|0
4002
4003 =cut
4004
4005 sub LostItem{
4006     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
4007
4008     unless ( $mark_lost_from ) {
4009         # Temporary check to avoid regressions
4010         die q|LostItem called without $mark_lost_from, check the API.|;
4011     }
4012
4013     my $mark_returned;
4014     if ( $force_mark_returned ) {
4015         $mark_returned = 1;
4016     } else {
4017         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
4018         $mark_returned = ( $pref =~ m|$mark_lost_from| );
4019     }
4020
4021     my $dbh = C4::Context->dbh();
4022     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
4023                            FROM issues
4024                            JOIN items USING (itemnumber)
4025                            JOIN biblio USING (biblionumber)
4026                            WHERE issues.itemnumber=?");
4027     $sth->execute($itemnumber);
4028     my $issues=$sth->fetchrow_hashref();
4029
4030     # If a borrower lost the item, add a replacement cost to the their record
4031     if ( my $borrowernumber = $issues->{borrowernumber} ){
4032         my $patron = Koha::Patrons->find( $borrowernumber );
4033
4034         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
4035         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
4036
4037         if (C4::Context->preference('WhenLostChargeReplacementFee')){
4038             C4::Accounts::chargelostitem(
4039                 $borrowernumber,
4040                 $itemnumber,
4041                 $issues->{'replacementprice'},
4042                 sprintf( "%s %s %s",
4043                     $issues->{'title'}          || q{},
4044                     $issues->{'barcode'}        || q{},
4045                     $issues->{'itemcallnumber'} || q{},
4046                 ),
4047             );
4048             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
4049             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
4050         }
4051
4052         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
4053     }
4054
4055     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
4056     my $item = Koha::Items->find($itemnumber);
4057     my $transfers = $item->get_transfers;
4058     while (my $transfer = $transfers->next) {
4059         $transfer->cancel({ reason => 'ItemLost', force => 1 });
4060     }
4061 }
4062
4063 sub GetOfflineOperations {
4064     my $dbh = C4::Context->dbh;
4065     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
4066     $sth->execute(C4::Context->userenv->{'branch'});
4067     my $results = $sth->fetchall_arrayref({});
4068     return $results;
4069 }
4070
4071 sub GetOfflineOperation {
4072     my $operationid = shift;
4073     return unless $operationid;
4074     my $dbh = C4::Context->dbh;
4075     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
4076     $sth->execute( $operationid );
4077     return $sth->fetchrow_hashref;
4078 }
4079
4080 sub AddOfflineOperation {
4081     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
4082     my $dbh = C4::Context->dbh;
4083     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
4084     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
4085     return "Added.";
4086 }
4087
4088 sub DeleteOfflineOperation {
4089     my $dbh = C4::Context->dbh;
4090     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4091     $sth->execute( shift );
4092     return "Deleted.";
4093 }
4094
4095 sub ProcessOfflineOperation {
4096     my $operation = shift;
4097
4098     my $report;
4099     if ( $operation->{action} eq 'return' ) {
4100         $report = ProcessOfflineReturn( $operation );
4101     } elsif ( $operation->{action} eq 'issue' ) {
4102         $report = ProcessOfflineIssue( $operation );
4103     } elsif ( $operation->{action} eq 'payment' ) {
4104         $report = ProcessOfflinePayment( $operation );
4105     }
4106
4107     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4108
4109     return $report;
4110 }
4111
4112 sub ProcessOfflineReturn {
4113     my $operation = shift;
4114
4115     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4116
4117     if ( $item ) {
4118         my $itemnumber = $item->itemnumber;
4119         my $issue = $item->checkout;
4120         if ( $issue ) {
4121             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4122             ModDateLastSeen( $itemnumber, $leave_item_lost );
4123             MarkIssueReturned(
4124                 $issue->borrowernumber,
4125                 $itemnumber,
4126                 $operation->{timestamp},
4127             );
4128             $item->onloan(undef);
4129             $item->store({ log_action => 0 });
4130             return "Success.";
4131         } else {
4132             return "Item not issued.";
4133         }
4134     } else {
4135         return "Item not found.";
4136     }
4137 }
4138
4139 sub ProcessOfflineIssue {
4140     my $operation = shift;
4141
4142     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4143
4144     if ( $patron ) {
4145         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4146         unless ($item) {
4147             return "Barcode not found.";
4148         }
4149         my $itemnumber = $item->itemnumber;
4150         my $issue = $item->checkout;
4151
4152         if ( $issue and ( $issue->borrowernumber ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4153             MarkIssueReturned(
4154                 $issue->borrowernumber,
4155                 $itemnumber,
4156                 $operation->{timestamp},
4157             );
4158         }
4159         AddIssue(
4160             $patron->unblessed,
4161             $operation->{'barcode'},
4162             undef,
4163             undef,
4164             $operation->{timestamp},
4165             undef,
4166         );
4167         return "Success.";
4168     } else {
4169         return "Borrower not found.";
4170     }
4171 }
4172
4173 sub ProcessOfflinePayment {
4174     my $operation = shift;
4175
4176     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4177
4178     $patron->account->pay(
4179         {
4180             amount     => $operation->{amount},
4181             library_id => $operation->{branchcode},
4182             interface  => 'koc'
4183         }
4184     );
4185
4186     return "Success.";
4187 }
4188
4189 =head2 TransferSlip
4190
4191   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4192
4193   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4194
4195 =cut
4196
4197 sub TransferSlip {
4198     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4199
4200     my $item =
4201       $itemnumber
4202       ? Koha::Items->find($itemnumber)
4203       : Koha::Items->find( { barcode => $barcode } );
4204
4205     $item or return;
4206
4207     return C4::Letters::GetPreparedLetter (
4208         module => 'circulation',
4209         letter_code => 'TRANSFERSLIP',
4210         branchcode => $branch,
4211         tables => {
4212             'branches'    => $to_branch,
4213             'biblio'      => $item->biblionumber,
4214             'items'       => $item->unblessed,
4215         },
4216     );
4217 }
4218
4219 =head2 CheckIfIssuedToPatron
4220
4221   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4222
4223   Return 1 if any record item is issued to patron, otherwise return 0
4224
4225 =cut
4226
4227 sub CheckIfIssuedToPatron {
4228     my ($borrowernumber, $biblionumber) = @_;
4229
4230     my $dbh = C4::Context->dbh;
4231     my $query = q|
4232         SELECT COUNT(*) FROM issues
4233         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4234         WHERE items.biblionumber = ?
4235         AND issues.borrowernumber = ?
4236     |;
4237     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4238     return 1 if $is_issued;
4239     return;
4240 }
4241
4242 =head2 IsItemIssued
4243
4244   IsItemIssued( $itemnumber )
4245
4246   Return 1 if the item is on loan, otherwise return 0
4247
4248 =cut
4249
4250 sub IsItemIssued {
4251     my $itemnumber = shift;
4252     my $dbh = C4::Context->dbh;
4253     my $sth = $dbh->prepare(q{
4254         SELECT COUNT(*)
4255         FROM issues
4256         WHERE itemnumber = ?
4257     });
4258     $sth->execute($itemnumber);
4259     return $sth->fetchrow;
4260 }
4261
4262 =head2 GetAgeRestriction
4263
4264   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4265   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4266
4267   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4268   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4269
4270 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4271 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4272 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4273          Negative days mean the borrower has gone past the age restriction age.
4274
4275 =cut
4276
4277 sub GetAgeRestriction {
4278     my ($record_restrictions, $borrower) = @_;
4279     my $markers = C4::Context->preference('AgeRestrictionMarker');
4280
4281     return unless $record_restrictions;
4282     # Split $record_restrictions to something like FSK 16 or PEGI 6
4283     my @values = split ' ', uc($record_restrictions);
4284     return unless @values;
4285
4286     # Search first occurrence of one of the markers
4287     my @markers = split /\|/, uc($markers);
4288     return unless @markers;
4289
4290     my $index            = 0;
4291     my $restriction_year = 0;
4292     for my $value (@values) {
4293         $index++;
4294         for my $marker (@markers) {
4295             $marker =~ s/^\s+//;    #remove leading spaces
4296             $marker =~ s/\s+$//;    #remove trailing spaces
4297             if ( $marker eq $value ) {
4298                 if ( $index <= $#values ) {
4299                     $restriction_year += $values[$index];
4300                 }
4301                 last;
4302             }
4303             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4304
4305                 # Perhaps it is something like "K16" (as in Finland)
4306                 $restriction_year += $1;
4307                 last;
4308             }
4309         }
4310         last if ( $restriction_year > 0 );
4311     }
4312
4313     #Check if the borrower is age restricted for this material and for how long.
4314     if ($restriction_year && $borrower) {
4315         if ( $borrower->{'dateofbirth'} ) {
4316             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4317             $alloweddate[0] += $restriction_year;
4318
4319             #Prevent runime eror on leap year (invalid date)
4320             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4321                 $alloweddate[2] = 28;
4322             }
4323
4324             #Get how many days the borrower has to reach the age restriction
4325             my @Today = split /-/, dt_from_string()->ymd();
4326             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4327             #Negative days means the borrower went past the age restriction age
4328             return ($restriction_year, $daysToAgeRestriction);
4329         }
4330     }
4331
4332     return ($restriction_year);
4333 }
4334
4335
4336 =head2 GetPendingOnSiteCheckouts
4337
4338 =cut
4339
4340 sub GetPendingOnSiteCheckouts {
4341     my $dbh = C4::Context->dbh;
4342     return $dbh->selectall_arrayref(q|
4343         SELECT
4344           items.barcode,
4345           items.biblionumber,
4346           items.itemnumber,
4347           items.itemnotes,
4348           items.itemcallnumber,
4349           items.location,
4350           issues.date_due,
4351           issues.branchcode,
4352           issues.date_due < NOW() AS is_overdue,
4353           biblio.author,
4354           biblio.title,
4355           borrowers.firstname,
4356           borrowers.surname,
4357           borrowers.cardnumber,
4358           borrowers.borrowernumber
4359         FROM items
4360         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4361         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4362         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4363         WHERE issues.onsite_checkout = 1
4364     |, { Slice => {} } );
4365 }
4366
4367 sub GetTopIssues {
4368     my ($params) = @_;
4369
4370     my ($count, $branch, $itemtype, $ccode, $newness)
4371         = @$params{qw(count branch itemtype ccode newness)};
4372
4373     my $dbh = C4::Context->dbh;
4374     my $query = q{
4375         SELECT * FROM (
4376         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4377           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4378           i.ccode, SUM(i.issues) AS count
4379         FROM biblio b
4380         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4381         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4382     };
4383
4384     my (@where_strs, @where_args);
4385
4386     if ($branch) {
4387         push @where_strs, 'i.homebranch = ?';
4388         push @where_args, $branch;
4389     }
4390     if ($itemtype) {
4391         if (C4::Context->preference('item-level_itypes')){
4392             push @where_strs, 'i.itype = ?';
4393             push @where_args, $itemtype;
4394         } else {
4395             push @where_strs, 'bi.itemtype = ?';
4396             push @where_args, $itemtype;
4397         }
4398     }
4399     if ($ccode) {
4400         push @where_strs, 'i.ccode = ?';
4401         push @where_args, $ccode;
4402     }
4403     if ($newness) {
4404         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4405         push @where_args, $newness;
4406     }
4407
4408     if (@where_strs) {
4409         $query .= 'WHERE ' . join(' AND ', @where_strs);
4410     }
4411
4412     $query .= q{
4413         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4414           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4415           i.ccode
4416         ORDER BY count DESC
4417     };
4418
4419     $query .= q{ ) xxx WHERE count > 0 };
4420     $count = int($count);
4421     if ($count > 0) {
4422         $query .= "LIMIT $count";
4423     }
4424
4425     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4426
4427     return @$rows;
4428 }
4429
4430 =head2 Internal methods
4431
4432 =cut
4433
4434 sub _CalculateAndUpdateFine {
4435     my ($params) = @_;
4436
4437     my $borrower    = $params->{borrower};
4438     my $item        = $params->{item};
4439     my $issue       = $params->{issue};
4440     my $return_date = $params->{return_date};
4441
4442     unless ($borrower) { carp "No borrower passed in!" && return; }
4443     unless ($item)     { carp "No item passed in!"     && return; }
4444     unless ($issue)    { carp "No issue passed in!"    && return; }
4445
4446     my $datedue = dt_from_string( $issue->date_due );
4447
4448     # we only need to calculate and change the fines if we want to do that on return
4449     # Should be on for hourly loans
4450     my $control = C4::Context->preference('CircControl');
4451     my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
4452     my $control_branchcode =
4453         ( $control eq 'ItemHomeLibrary' ) ? $item->{$branch_type}
4454       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4455       :                                     $issue->branchcode;
4456
4457     my $date_returned = $return_date ? $return_date : dt_from_string();
4458
4459     my ( $amount, $unitcounttotal, $unitcount  ) =
4460       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4461
4462     if ( C4::Context->preference('finesMode') eq 'production' ) {
4463         if ( $amount > 0 ) {
4464             C4::Overdues::UpdateFine({
4465                 issue_id       => $issue->issue_id,
4466                 itemnumber     => $issue->itemnumber,
4467                 borrowernumber => $issue->borrowernumber,
4468                 amount         => $amount,
4469                 due            => $datedue,
4470             });
4471         }
4472         elsif ($return_date) {
4473
4474             # Backdated returns may have fines that shouldn't exist,
4475             # so in this case, we need to drop those fines to 0
4476
4477             C4::Overdues::UpdateFine({
4478                 issue_id       => $issue->issue_id,
4479                 itemnumber     => $issue->itemnumber,
4480                 borrowernumber => $issue->borrowernumber,
4481                 amount         => 0,
4482                 due            => $datedue,
4483             });
4484         }
4485     }
4486 }
4487
4488 sub _CanBookBeAutoRenewed {
4489     my ( $params ) = @_;
4490     my $patron = $params->{patron};
4491     my $item = $params->{item};
4492     my $branchcode = $params->{branchcode};
4493     my $issue = $params->{issue};
4494
4495     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4496
4497     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4498         {
4499             categorycode => $patron->categorycode,
4500             itemtype     => $item->effective_itemtype,
4501             branchcode   => $branchcode,
4502             rules => [
4503                 'no_auto_renewal_after',
4504                 'no_auto_renewal_after_hard_limit',
4505                 'lengthunit',
4506                 'norenewalbefore',
4507             ]
4508         }
4509     );
4510
4511     if ( $patron->is_expired && $patron->category->effective_BlockExpiredPatronOpacActions ) {
4512         return 'auto_account_expired';
4513     }
4514
4515     if ( defined $issuing_rule->{no_auto_renewal_after}
4516             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4517         # Get issue_date and add no_auto_renewal_after
4518         # If this is greater than today, it's too late for renewal.
4519         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4520         $maximum_renewal_date->add(
4521             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4522         );
4523         my $now = dt_from_string;
4524         if ( $now >= $maximum_renewal_date ) {
4525             return "auto_too_late";
4526         }
4527     }
4528     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4529                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4530         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4531         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4532             return "auto_too_late";
4533         }
4534     }
4535
4536     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4537         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4538         my $amountoutstanding =
4539           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4540           ? $patron->account->balance
4541           : $patron->account->outstanding_debits->total_outstanding;
4542         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4543             return "auto_too_much_oweing";
4544         }
4545     }
4546
4547     my $soonest = GetSoonestRenewDate($patron, $issue);
4548     if ( $soonest > dt_from_string() )
4549     {
4550         return ( "auto_too_soon", $soonest );
4551     }
4552
4553     return "ok";
4554 }
4555
4556
4557 1;
4558
4559 __END__
4560
4561 =head1 AUTHOR
4562
4563 Koha Development Team <http://koha-community.org/>
4564
4565 =cut