C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use Encode;
 101 use ZOOM;
 102 use XML::Simple;
 103 use Koha::Cache;
 104 use POSIX ();
 105 use DateTime::TimeZone;
 106 use Module::Load::Conditional qw(can_load);
 107 use Carp;
 108
 109 use C4::Boolean;
 110 use C4::Debug;
 111 use Koha;
 112 use Koha::Config::SysPref;
 113 use Koha::Config::SysPrefs;
 114
 115 =head1 NAME
 116
 117 C4::Context - Maintain and manipulate the context of a Koha script
 118
 119 =head1 SYNOPSIS
 120
 121   use C4::Context;
 122
 123   use C4::Context("/path/to/koha-conf.xml");
 124
 125   $config_value = C4::Context->config("config_variable");
 126
 127   $koha_preference = C4::Context->preference("preference");
 128
 129   $db_handle = C4::Context->dbh;
 130
 131   $Zconn = C4::Context->Zconn;
 132
 133   $stopwordhash = C4::Context->stopwords;
 134
 135 =head1 DESCRIPTION
 136
 137 When a Koha script runs, it makes use of a certain number of things:
 138 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 139 databases, and so forth. These things make up the I<context> in which
 140 the script runs.
 141
 142 This module takes care of setting up the context for a script:
 143 figuring out which configuration file to load, and loading it, opening
 144 a connection to the right database, and so forth.
 145
 146 Most scripts will only use one context. They can simply have
 147
 148   use C4::Context;
 149
 150 at the top.
 151
 152 Other scripts may need to use several contexts. For instance, if a
 153 library has two databases, one for a certain collection, and the other
 154 for everything else, it might be necessary for a script to use two
 155 different contexts to search both databases. Such scripts should use
 156 the C<&set_context> and C<&restore_context> functions, below.
 157
 158 By default, C4::Context reads the configuration from
 159 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 160 environment variable to the pathname of a configuration file to use.
 161
 162 =head1 METHODS
 163
 164 =cut
 165
 166 #'
 167 # In addition to what is said in the POD above, a Context object is a
 168 # reference-to-hash with the following fields:
 169 #
 170 # config
 171 #    A reference-to-hash whose keys and values are the
 172 #    configuration variables and values specified in the config
 173 #    file (/etc/koha/koha-conf.xml).
 174 # dbh
 175 #    A handle to the appropriate database for this context.
 176 # dbh_stack
 177 #    Used by &set_dbh and &restore_dbh to hold other database
 178 #    handles for this context.
 179 # Zconn
 180 #     A connection object for the Zebra server
 181
 182 # Koha's main configuration file koha-conf.xml
 183 # is searched for according to this priority list:
 184 #
 185 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 186 # 2. Path supplied in KOHA_CONF environment variable.
 187 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 188 #    as value has changed from its default of
 189 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 190 #    when Koha is installed in 'standard' or 'single'
 191 #    mode.
 192 # 4. Path supplied in CONFIG_FNAME.
 193 #
 194 # The first entry that refers to a readable file is used.
 195
 196 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 197                 # Default config file, if none is specified
 198
 199 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 200                 # path to config file set by installer
 201                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 202                 # when Koha is installed in 'standard' or 'single'
 203                 # mode.  If Koha was installed in 'dev' mode,
 204                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 205                 # developers should set the KOHA_CONF environment variable
 206
 207 $context = undef;        # Initially, no context is set
 208 @context_stack = ();        # Initially, no saved contexts
 209
 210
 211 =head2 read_config_file
 212
 213 Reads the specified Koha config file.
 214
 215 Returns an object containing the configuration variables. The object's
 216 structure is a bit complex to the uninitiated ... take a look at the
 217 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 218 here are a few examples that may give you what you need:
 219
 220 The simple elements nested within the <config> element:
 221
 222     my $pass = $koha->{'config'}->{'pass'};
 223
 224 The <listen> elements:
 225
 226     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 227
 228 The elements nested within the <server> element:
 229
 230     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 231
 232 Returns undef in case of error.
 233
 234 =cut
 235
 236 sub read_config_file {          # Pass argument naming config file to read
 237     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 238
 239     if ($ismemcached) {
 240       $memcached->set('kohaconf',$koha);
 241     }
 242
 243     return $koha;                       # Return value: ref-to-hash holding the configuration
 244 }
 245
 246 =head2 ismemcached
 247
 248 Returns the value of the $ismemcached variable (0/1)
 249
 250 =cut
 251
 252 sub ismemcached {
 253     return $ismemcached;
 254 }
 255
 256 =head2 memcached
 257
 258 If $ismemcached is true, returns the $memcache variable.
 259 Returns undef otherwise
 260
 261 =cut
 262
 263 sub memcached {
 264     if ($ismemcached) {
 265       return $memcached;
 266     } else {
 267       return;
 268     }
 269 }
 270
 271 =head2 db_scheme2dbi
 272
 273     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 274
 275 This routines translates a database type to part of the name
 276 of the appropriate DBD driver to use when establishing a new
 277 database connection.  It recognizes 'mysql' and 'Pg'; if any
 278 other scheme is supplied it defaults to 'mysql'.
 279
 280 =cut
 281
 282 sub db_scheme2dbi {
 283     my $scheme = shift // '';
 284     return $scheme eq 'Pg' ? $scheme : 'mysql';
 285 }
 286
 287 sub import {
 288     # Create the default context ($C4::Context::Context)
 289     # the first time the module is called
 290     # (a config file can be optionaly passed)
 291
 292     # default context already exists?
 293     return if $context;
 294
 295     # no ? so load it!
 296     my ($pkg,$config_file) = @_ ;
 297     my $new_ctx = __PACKAGE__->new($config_file);
 298     return unless $new_ctx;
 299
 300     # if successfully loaded, use it by default
 301     $new_ctx->set_context;
 302     1;
 303 }
 304
 305 =head2 new
 306
 307   $context = new C4::Context;
 308   $context = new C4::Context("/path/to/koha-conf.xml");
 309
 310 Allocates a new context. Initializes the context from the specified
 311 file, which defaults to either the file given by the C<$KOHA_CONF>
 312 environment variable, or F</etc/koha/koha-conf.xml>.
 313
 314 It saves the koha-conf.xml values in the declared memcached server(s)
 315 if currently available and uses those values until them expire and
 316 re-reads them.
 317
 318 C<&new> does not set this context as the new default context; for
 319 that, use C<&set_context>.
 320
 321 =cut
 322
 323 #'
 324 # Revision History:
 325 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 326 sub new {
 327     my $class = shift;
 328     my $conf_fname = shift;        # Config file to load
 329     my $self = {};
 330
 331     # check that the specified config file exists and is not empty
 332     undef $conf_fname unless
 333         (defined $conf_fname && -s $conf_fname);
 334     # Figure out a good config file to load if none was specified.
 335     if (!defined($conf_fname))
 336     {
 337         # If the $KOHA_CONF environment variable is set, use
 338         # that. Otherwise, use the built-in default.
 339         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 340             $conf_fname = $ENV{"KOHA_CONF"};
 341         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 342             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 343             # regex to anything else -- don't want installer to rewrite it
 344             $conf_fname = $INSTALLED_CONFIG_FNAME;
 345         } elsif (-s CONFIG_FNAME) {
 346             $conf_fname = CONFIG_FNAME;
 347         } else {
 348             warn "unable to locate Koha configuration file koha-conf.xml";
 349             return;
 350         }
 351     }
 352
 353     if ($ismemcached) {
 354         # retrieve from memcached
 355         $self = $memcached->get('kohaconf');
 356         if (not defined $self) {
 357             # not in memcached yet
 358             $self = read_config_file($conf_fname);
 359         }
 360     } else {
 361         # non-memcached env, read from file
 362         $self = read_config_file($conf_fname);
 363     }
 364
 365     $self->{"config_file"} = $conf_fname;
 366     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 367     return if !defined($self->{"config"});
 368
 369     $self->{"Zconn"} = undef;    # Zebra Connections
 370     $self->{"stopwords"} = undef; # stopwords list
 371     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 372     $self->{"userenv"} = undef;        # User env
 373     $self->{"activeuser"} = undef;        # current active user
 374     $self->{"shelves"} = undef;
 375     $self->{tz} = undef; # local timezone object
 376
 377     bless $self, $class;
 378     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 379     return $self;
 380 }
 381
 382 =head2 set_context
 383
 384   $context = new C4::Context;
 385   $context->set_context();
 386 or
 387   set_context C4::Context $context;
 388
 389   ...
 390   restore_context C4::Context;
 391
 392 In some cases, it might be necessary for a script to use multiple
 393 contexts. C<&set_context> saves the current context on a stack, then
 394 sets the context to C<$context>, which will be used in future
 395 operations. To restore the previous context, use C<&restore_context>.
 396
 397 =cut
 398
 399 #'
 400 sub set_context
 401 {
 402     my $self = shift;
 403     my $new_context;    # The context to set
 404
 405     # Figure out whether this is a class or instance method call.
 406     #
 407     # We're going to make the assumption that control got here
 408     # through valid means, i.e., that the caller used an instance
 409     # or class method call, and that control got here through the
 410     # usual inheritance mechanisms. The caller can, of course,
 411     # break this assumption by playing silly buggers, but that's
 412     # harder to do than doing it properly, and harder to check
 413     # for.
 414     if (ref($self) eq "")
 415     {
 416         # Class method. The new context is the next argument.
 417         $new_context = shift;
 418     } else {
 419         # Instance method. The new context is $self.
 420         $new_context = $self;
 421     }
 422
 423     # Save the old context, if any, on the stack
 424     push @context_stack, $context if defined($context);
 425
 426     # Set the new context
 427     $context = $new_context;
 428 }
 429
 430 =head2 restore_context
 431
 432   &restore_context;
 433
 434 Restores the context set by C<&set_context>.
 435
 436 =cut
 437
 438 #'
 439 sub restore_context
 440 {
 441     my $self = shift;
 442
 443     if ($#context_stack < 0)
 444     {
 445         # Stack underflow.
 446         die "Context stack underflow";
 447     }
 448
 449     # Pop the old context and set it.
 450     $context = pop @context_stack;
 451
 452     # FIXME - Should this return something, like maybe the context
 453     # that was current when this was called?
 454 }
 455
 456 =head2 config
 457
 458   $value = C4::Context->config("config_variable");
 459
 460   $value = C4::Context->config_variable;
 461
 462 Returns the value of a variable specified in the configuration file
 463 from which the current context was created.
 464
 465 The second form is more compact, but of course may conflict with
 466 method names. If there is a configuration variable called "new", then
 467 C<C4::Config-E<gt>new> will not return it.
 468
 469 =cut
 470
 471 sub _common_config {
 472         my $var = shift;
 473         my $term = shift;
 474     return if !defined($context->{$term});
 475        # Presumably $self->{$term} might be
 476        # undefined if the config file given to &new
 477        # didn't exist, and the caller didn't bother
 478        # to check the return value.
 479
 480     # Return the value of the requested config variable
 481     return $context->{$term}->{$var};
 482 }
 483
 484 sub config {
 485         return _common_config($_[1],'config');
 486 }
 487 sub zebraconfig {
 488         return _common_config($_[1],'server');
 489 }
 490 sub ModZebrations {
 491         return _common_config($_[1],'serverinfo');
 492 }
 493
 494 =head2 preference
 495
 496   $sys_preference = C4::Context->preference('some_variable');
 497
 498 Looks up the value of the given system preference in the
 499 systempreferences table of the Koha database, and returns it. If the
 500 variable is not set or does not exist, undef is returned.
 501
 502 In case of an error, this may return 0.
 503
 504 Note: It is impossible to tell the difference between system
 505 preferences which do not exist, and those whose values are set to NULL
 506 with this method.
 507
 508 =cut
 509
 510 my $syspref_cache = Koha::Cache->get_instance();
 511 my %syspref_L1_cache;
 512 my $use_syspref_cache = 1;
 513 sub preference {
 514     my $self = shift;
 515     my $var  = shift;    # The system preference to return
 516
 517     $var = lc $var;
 518
 519     return $ENV{"OVERRIDE_SYSPREF_$var"}
 520         if defined $ENV{"OVERRIDE_SYSPREF_$var"};
 521
 522     # Return the value if the var has already been accessed
 523     if ($use_syspref_cache && exists $syspref_L1_cache{$var}) {
 524         return $syspref_L1_cache{$var};
 525     }
 526
 527     my $cached_var = $use_syspref_cache
 528         ? $syspref_cache->get_from_cache("syspref_$var")
 529         : undef;
 530     return $cached_var if defined $cached_var;
 531
 532     my $syspref;
 533     eval { $syspref = Koha::Config::SysPrefs->find( lc $var ) };
 534     my $value = $syspref ? $syspref->value() : undef;
 535
 536     if ( $use_syspref_cache ) {
 537         $syspref_cache->set_in_cache("syspref_$var", $value);
 538         $syspref_L1_cache{$var} = $value;
 539     }
 540     return $value;
 541 }
 542
 543 sub boolean_preference {
 544     my $self = shift;
 545     my $var = shift;        # The system preference to return
 546     my $it = preference($self, $var);
 547     return defined($it)? C4::Boolean::true_p($it): undef;
 548 }
 549
 550 =head2 enable_syspref_cache
 551
 552   C4::Context->enable_syspref_cache();
 553
 554 Enable the in-memory syspref cache used by C4::Context. This is the
 555 default behavior.
 556
 557 =cut
 558
 559 sub enable_syspref_cache {
 560     my ($self) = @_;
 561     $use_syspref_cache = 1;
 562     # We need to clear the cache to have it up-to-date
 563     $self->clear_syspref_cache();
 564 }
 565
 566 =head2 disable_syspref_cache
 567
 568   C4::Context->disable_syspref_cache();
 569
 570 Disable the in-memory syspref cache used by C4::Context. This should be
 571 used with Plack and other persistent environments.
 572
 573 =cut
 574
 575 sub disable_syspref_cache {
 576     my ($self) = @_;
 577     $use_syspref_cache = 0;
 578     $self->clear_syspref_cache();
 579 }
 580
 581 =head2 clear_syspref_cache
 582
 583   C4::Context->clear_syspref_cache();
 584
 585 cleans the internal cache of sysprefs. Please call this method if
 586 you update the systempreferences table. Otherwise, your new changes
 587 will not be seen by this process.
 588
 589 =cut
 590
 591 sub clear_syspref_cache {
 592     return unless $use_syspref_cache;
 593     $syspref_cache->flush_all;
 594     clear_syspref_L1_cache()
 595 }
 596
 597 sub clear_syspref_L1_cache {
 598     %syspref_L1_cache = ();
 599 }
 600
 601 =head2 set_preference
 602
 603   C4::Context->set_preference( $variable, $value, [ $explanation, $type, $options ] );
 604
 605 This updates a preference's value both in the systempreferences table and in
 606 the sysprefs cache. If the optional parameters are provided, then the query
 607 becomes a create. It won't update the parameters (except value) for an existing
 608 preference.
 609
 610 =cut
 611
 612 sub set_preference {
 613     my ( $self, $variable, $value, $explanation, $type, $options ) = @_;
 614
 615     $variable = lc $variable;
 616
 617     my $syspref = Koha::Config::SysPrefs->find($variable);
 618     $type =
 619         $type    ? $type
 620       : $syspref ? $syspref->type
 621       :            undef;
 622
 623     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 624
 625     # force explicit protocol on OPACBaseURL
 626     if ( $variable eq 'opacbaseurl' && substr( $value, 0, 4 ) !~ /http/ ) {
 627         $value = 'http://' . $value;
 628     }
 629
 630     if ($syspref) {
 631         $syspref->set(
 632             {   ( defined $value ? ( value       => $value )       : () ),
 633                 ( $explanation   ? ( explanation => $explanation ) : () ),
 634                 ( $type          ? ( type        => $type )        : () ),
 635                 ( $options       ? ( options     => $options )     : () ),
 636             }
 637         )->store;
 638     } else {
 639         $syspref = Koha::Config::SysPref->new(
 640             {   variable    => $variable,
 641                 value       => $value,
 642                 explanation => $explanation || undef,
 643                 type        => $type,
 644                 options     => $options || undef,
 645             }
 646         )->store();
 647     }
 648
 649     if ( $use_syspref_cache ) {
 650         $syspref_cache->set_in_cache( "syspref_$variable", $value );
 651         $syspref_L1_cache{$variable} = $value;
 652     }
 653
 654     return $syspref;
 655 }
 656
 657 =head2 delete_preference
 658
 659     C4::Context->delete_preference( $variable );
 660
 661 This deletes a system preference from the database. Returns a true value on
 662 success. Failure means there was an issue with the database, not that there
 663 was no syspref of the name.
 664
 665 =cut
 666
 667 sub delete_preference {
 668     my ( $self, $var ) = @_;
 669
 670     if ( Koha::Config::SysPrefs->find( $var )->delete ) {
 671         if ( $use_syspref_cache ) {
 672             $syspref_cache->clear_from_cache("syspref_$var");
 673             delete $syspref_L1_cache{$var};
 674         }
 675
 676         return 1;
 677     }
 678     return 0;
 679 }
 680
 681 =head2 Zconn
 682
 683   $Zconn = C4::Context->Zconn
 684
 685 Returns a connection to the Zebra database
 686
 687 C<$self>
 688
 689 C<$server> one of the servers defined in the koha-conf.xml file
 690
 691 C<$async> whether this is a asynchronous connection
 692
 693 =cut
 694
 695 sub Zconn {
 696     my ($self, $server, $async ) = @_;
 697     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 698     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 699         # if we are running the script from the commandline, lets try to use the caching
 700         return $context->{"Zconn"}->{$cache_key};
 701     }
 702     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 703     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 704     return $context->{"Zconn"}->{$cache_key};
 705 }
 706
 707 =head2 _new_Zconn
 708
 709 $context->{"Zconn"} = &_new_Zconn($server,$async);
 710
 711 Internal function. Creates a new database connection from the data given in the current context and returns it.
 712
 713 C<$server> one of the servers defined in the koha-conf.xml file
 714
 715 C<$async> whether this is a asynchronous connection
 716
 717 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 718
 719 =cut
 720
 721 sub _new_Zconn {
 722     my ( $server, $async ) = @_;
 723
 724     my $tried=0; # first attempt
 725     my $Zconn; # connection object
 726     my $elementSetName;
 727     my $index_mode;
 728     my $syntax;
 729
 730     $server //= "biblioserver";
 731
 732     if ( $server eq 'biblioserver' ) {
 733         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'dom';
 734     } elsif ( $server eq 'authorityserver' ) {
 735         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 736     }
 737
 738     if ( $index_mode eq 'grs1' ) {
 739         $elementSetName = 'F';
 740         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 741                 ? 'unimarc'
 742                 : 'usmarc';
 743
 744     } else { # $index_mode eq 'dom'
 745         $syntax = 'xml';
 746         $elementSetName = 'marcxml';
 747     }
 748
 749     my $host = $context->{'listen'}->{$server}->{'content'};
 750     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 751     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 752     eval {
 753         # set options
 754         my $o = new ZOOM::Options();
 755         $o->option(user => $user) if $user && $password;
 756         $o->option(password => $password) if $user && $password;
 757         $o->option(async => 1) if $async;
 758         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 759         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 760         $o->option(preferredRecordSyntax => $syntax);
 761         $o->option(elementSetName => $elementSetName) if $elementSetName;
 762         $o->option(databaseName => $context->{"config"}->{$server}||"biblios");
 763
 764         # create a new connection object
 765         $Zconn= create ZOOM::Connection($o);
 766
 767         # forge to server
 768         $Zconn->connect($host, 0);
 769
 770         # check for errors and warn
 771         if ($Zconn->errcode() !=0) {
 772             warn "something wrong with the connection: ". $Zconn->errmsg();
 773         }
 774     };
 775     return $Zconn;
 776 }
 777
 778 # _new_dbh
 779 # Internal helper function (not a method!). This creates a new
 780 # database connection from the data given in the current context, and
 781 # returns it.
 782 sub _new_dbh
 783 {
 784
 785     Koha::Database->schema({ new => 1 })->storage->dbh;
 786 }
 787
 788 =head2 dbh
 789
 790   $dbh = C4::Context->dbh;
 791
 792 Returns a database handle connected to the Koha database for the
 793 current context. If no connection has yet been made, this method
 794 creates one, and connects to the database.
 795
 796 This database handle is cached for future use: if you call
 797 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 798 times. If you need a second database handle, use C<&new_dbh> and
 799 possibly C<&set_dbh>.
 800
 801 =cut
 802
 803 #'
 804 sub dbh
 805 {
 806     my $self = shift;
 807     my $params = shift;
 808     my $sth;
 809
 810     unless ( $params->{new} ) {
 811         return Koha::Database->schema->storage->dbh;
 812     }
 813
 814     return Koha::Database->schema({ new => 1 })->storage->dbh;
 815 }
 816
 817 =head2 new_dbh
 818
 819   $dbh = C4::Context->new_dbh;
 820
 821 Creates a new connection to the Koha database for the current context,
 822 and returns the database handle (a C<DBI::db> object).
 823
 824 The handle is not saved anywhere: this method is strictly a
 825 convenience function; the point is that it knows which database to
 826 connect to so that the caller doesn't have to know.
 827
 828 =cut
 829
 830 #'
 831 sub new_dbh
 832 {
 833     my $self = shift;
 834
 835     return &dbh({ new => 1 });
 836 }
 837
 838 =head2 set_dbh
 839
 840   $my_dbh = C4::Connect->new_dbh;
 841   C4::Connect->set_dbh($my_dbh);
 842   ...
 843   C4::Connect->restore_dbh;
 844
 845 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 846 C<&set_context> and C<&restore_context>.
 847
 848 C<&set_dbh> saves the current database handle on a stack, then sets
 849 the current database handle to C<$my_dbh>.
 850
 851 C<$my_dbh> is assumed to be a good database handle.
 852
 853 =cut
 854
 855 #'
 856 sub set_dbh
 857 {
 858     my $self = shift;
 859     my $new_dbh = shift;
 860
 861     # Save the current database handle on the handle stack.
 862     # We assume that $new_dbh is all good: if the caller wants to
 863     # screw himself by passing an invalid handle, that's fine by
 864     # us.
 865     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 866     $context->{"dbh"} = $new_dbh;
 867 }
 868
 869 =head2 restore_dbh
 870
 871   C4::Context->restore_dbh;
 872
 873 Restores the database handle saved by an earlier call to
 874 C<C4::Context-E<gt>set_dbh>.
 875
 876 =cut
 877
 878 #'
 879 sub restore_dbh
 880 {
 881     my $self = shift;
 882
 883     if ($#{$context->{"dbh_stack"}} < 0)
 884     {
 885         # Stack underflow
 886         die "DBH stack underflow";
 887     }
 888
 889     # Pop the old database handle and set it.
 890     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 891
 892     # FIXME - If it is determined that restore_context should
 893     # return something, then this function should, too.
 894 }
 895
 896 =head2 queryparser
 897
 898   $queryparser = C4::Context->queryparser
 899
 900 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 901
 902 =cut
 903
 904 sub queryparser {
 905     my $self = shift;
 906     unless (defined $context->{"queryparser"}) {
 907         $context->{"queryparser"} = &_new_queryparser();
 908     }
 909
 910     return
 911       defined( $context->{"queryparser"} )
 912       ? $context->{"queryparser"}->new
 913       : undef;
 914 }
 915
 916 =head2 _new_queryparser
 917
 918 Internal helper function to create a new QueryParser object. QueryParser
 919 is loaded dynamically so as to keep the lack of the QueryParser library from
 920 getting in anyone's way.
 921
 922 =cut
 923
 924 sub _new_queryparser {
 925     my $qpmodules = {
 926         'OpenILS::QueryParser'           => undef,
 927         'Koha::QueryParser::Driver::PQF' => undef
 928     };
 929     if ( can_load( 'modules' => $qpmodules ) ) {
 930         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 931         my $config_file = $context->config('queryparser_config');
 932         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 933         if ( $QParser->load_config($config_file) ) {
 934             # Set 'keyword' as the default search class
 935             $QParser->default_search_class('keyword');
 936             # TODO: allow indexes to be configured in the database
 937             return $QParser;
 938         }
 939     }
 940     return;
 941 }
 942
 943 =head2 marcfromkohafield
 944
 945   $dbh = C4::Context->marcfromkohafield;
 946
 947 Returns a hash with marcfromkohafield.
 948
 949 This hash is cached for future use: if you call
 950 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
 951
 952 =cut
 953
 954 #'
 955 sub marcfromkohafield
 956 {
 957     my $retval = {};
 958
 959     # If the hash already exists, return it.
 960     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
 961
 962     # No hash. Create one.
 963     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
 964
 965     return $context->{"marcfromkohafield"};
 966 }
 967
 968 # _new_marcfromkohafield
 969 # Internal helper function (not a method!). This creates a new
 970 # hash with stopwords
 971 sub _new_marcfromkohafield
 972 {
 973     my $dbh = C4::Context->dbh;
 974     my $marcfromkohafield;
 975     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
 976     $sth->execute;
 977     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
 978         my $retval = {};
 979         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
 980     }
 981     return $marcfromkohafield;
 982 }
 983
 984 =head2 stopwords
 985
 986   $dbh = C4::Context->stopwords;
 987
 988 Returns a hash with stopwords.
 989
 990 This hash is cached for future use: if you call
 991 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
 992
 993 =cut
 994
 995 #'
 996 sub stopwords
 997 {
 998     my $retval = {};
 999
1000     # If the hash already exists, return it.
1001     return $context->{"stopwords"} if defined($context->{"stopwords"});
1002
1003     # No hash. Create one.
1004     $context->{"stopwords"} = &_new_stopwords();
1005
1006     return $context->{"stopwords"};
1007 }
1008
1009 # _new_stopwords
1010 # Internal helper function (not a method!). This creates a new
1011 # hash with stopwords
1012 sub _new_stopwords
1013 {
1014     my $dbh = C4::Context->dbh;
1015     my $stopwordlist;
1016     my $sth = $dbh->prepare("select word from stopwords");
1017     $sth->execute;
1018     while (my $stopword = $sth->fetchrow_array) {
1019         $stopwordlist->{$stopword} = uc($stopword);
1020     }
1021     $stopwordlist->{A} = "A" unless $stopwordlist;
1022     return $stopwordlist;
1023 }
1024
1025 =head2 userenv
1026
1027   C4::Context->userenv;
1028
1029 Retrieves a hash for user environment variables.
1030
1031 This hash shall be cached for future use: if you call
1032 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1033
1034 =cut
1035
1036 #'
1037 sub userenv {
1038     my $var = $context->{"activeuser"};
1039     if (defined $var and defined $context->{"userenv"}->{$var}) {
1040         return $context->{"userenv"}->{$var};
1041     } else {
1042         return;
1043     }
1044 }
1045
1046 =head2 set_userenv
1047
1048   C4::Context->set_userenv($usernum, $userid, $usercnum,
1049                            $userfirstname, $usersurname,
1050                            $userbranch, $branchname, $userflags,
1051                            $emailaddress, $branchprinter, $persona);
1052
1053 Establish a hash of user environment variables.
1054
1055 set_userenv is called in Auth.pm
1056
1057 =cut
1058
1059 #'
1060 sub set_userenv {
1061     shift @_;
1062     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona, $shibboleth)=
1063     map { Encode::is_utf8( $_ ) ? $_ : Encode::decode('UTF-8', $_) } # CGI::Session doesn't handle utf-8, so we decode it here
1064     @_;
1065     my $var=$context->{"activeuser"} || '';
1066     my $cell = {
1067         "number"     => $usernum,
1068         "id"         => $userid,
1069         "cardnumber" => $usercnum,
1070         "firstname"  => $userfirstname,
1071         "surname"    => $usersurname,
1072         #possibly a law problem
1073         "branch"     => $userbranch,
1074         "branchname" => $branchname,
1075         "flags"      => $userflags,
1076         "emailaddress"     => $emailaddress,
1077         "branchprinter"    => $branchprinter,
1078         "persona"    => $persona,
1079         "shibboleth" => $shibboleth,
1080     };
1081     $context->{userenv}->{$var} = $cell;
1082     return $cell;
1083 }
1084
1085 sub set_shelves_userenv {
1086         my ($type, $shelves) = @_ or return;
1087         my $activeuser = $context->{activeuser} or return;
1088         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1089         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1090         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1091 }
1092
1093 sub get_shelves_userenv {
1094         my $active;
1095         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1096                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1097                 return;
1098         }
1099         my $totshelves = $active->{totshelves} or undef;
1100         my $pubshelves = $active->{pubshelves} or undef;
1101         my $barshelves = $active->{barshelves} or undef;
1102         return ($totshelves, $pubshelves, $barshelves);
1103 }
1104
1105 =head2 _new_userenv
1106
1107   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1108
1109 Builds a hash for user environment variables.
1110
1111 This hash shall be cached for future use: if you call
1112 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1113
1114 _new_userenv is called in Auth.pm
1115
1116 =cut
1117
1118 #'
1119 sub _new_userenv
1120 {
1121     shift;  # Useless except it compensates for bad calling style
1122     my ($sessionID)= @_;
1123      $context->{"activeuser"}=$sessionID;
1124 }
1125
1126 =head2 _unset_userenv
1127
1128   C4::Context->_unset_userenv;
1129
1130 Destroys the hash for activeuser user environment variables.
1131
1132 =cut
1133
1134 #'
1135
1136 sub _unset_userenv
1137 {
1138     my ($sessionID)= @_;
1139     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1140 }
1141
1142
1143 =head2 get_versions
1144
1145   C4::Context->get_versions
1146
1147 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1148
1149 =cut
1150
1151 #'
1152
1153 # A little example sub to show more debugging info for CGI::Carp
1154 sub get_versions {
1155     my %versions;
1156     $versions{kohaVersion}  = Koha::version();
1157     $versions{kohaDbVersion} = C4::Context->preference('version');
1158     $versions{osVersion} = join(" ", POSIX::uname());
1159     $versions{perlVersion} = $];
1160     {
1161         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1162         $versions{mysqlVersion}  = `mysql -V`;
1163         $versions{apacheVersion} = (`apache2ctl -v`)[0];
1164         $versions{apacheVersion} = `httpd -v`             unless  $versions{apacheVersion} ;
1165         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1166         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1167         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1168     }
1169     return %versions;
1170 }
1171
1172
1173 =head2 tz
1174
1175   C4::Context->tz
1176
1177   Returns a DateTime::TimeZone object for the system timezone
1178
1179 =cut
1180
1181 sub tz {
1182     my $self = shift;
1183     if (!defined $context->{tz}) {
1184         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1185     }
1186     return $context->{tz};
1187 }
1188
1189
1190 =head2 IsSuperLibrarian
1191
1192     C4::Context->IsSuperLibrarian();
1193
1194 =cut
1195
1196 sub IsSuperLibrarian {
1197     my $userenv = C4::Context->userenv;
1198
1199     unless ( $userenv and exists $userenv->{flags} ) {
1200         # If we reach this without a user environment,
1201         # assume that we're running from a command-line script,
1202         # and act as a superlibrarian.
1203         carp("C4::Context->userenv not defined!");
1204         return 1;
1205     }
1206
1207     return ($userenv->{flags}//0) % 2;
1208 }
1209
1210 =head2 interface
1211
1212 Sets the current interface for later retrieval in any Perl module
1213
1214     C4::Context->interface('opac');
1215     C4::Context->interface('intranet');
1216     my $interface = C4::Context->interface;
1217
1218 =cut
1219
1220 sub interface {
1221     my ($class, $interface) = @_;
1222
1223     if (defined $interface) {
1224         $interface = lc $interface;
1225         if ($interface eq 'opac' || $interface eq 'intranet') {
1226             $context->{interface} = $interface;
1227         } else {
1228             warn "invalid interface : '$interface'";
1229         }
1230     }
1231
1232     return $context->{interface} // 'opac';
1233 }
1234
1235 1;
1236 __END__
1237
1238 =head1 ENVIRONMENT
1239
1240 =head2 C<KOHA_CONF>
1241
1242 Specifies the configuration file to read.
1243
1244 =head1 SEE ALSO
1245
1246 XML::Simple
1247
1248 =head1 AUTHORS
1249
1250 Andrew Arensburger <arensb at ooblick dot com>
1251
1252 Joshua Ferraro <jmf at liblime dot com>
1253