C4/Letters.pm

   1 package C4::Letters;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp qw( carp croak );
  23 use Template;
  24 use Module::Load::Conditional qw( can_load );
  25
  26 use Try::Tiny;
  27
  28 use C4::Members;
  29 use C4::Log qw( logaction );
  30 use C4::SMS;
  31 use C4::Templates;
  32 use Koha::SMS::Providers;
  33
  34 use Koha::Email;
  35 use Koha::Notice::Messages;
  36 use Koha::Notice::Templates;
  37 use Koha::Notice::Util;
  38 use Koha::DateUtils qw( dt_from_string output_pref );
  39 use Koha::Auth::TwoFactorAuth;
  40 use Koha::Patrons;
  41 use Koha::SMTP::Servers;
  42 use Koha::Subscriptions;
  43
  44 use constant SERIALIZED_EMAIL_CONTENT_TYPE => 'message/rfc822';
  45
  46 our (@ISA, @EXPORT_OK);
  47 BEGIN {
  48     require Exporter;
  49     @ISA = qw(Exporter);
  50     @EXPORT_OK = qw(
  51       GetLetters
  52       GetLettersAvailableForALibrary
  53       GetLetterTemplates
  54       DelLetter
  55       GetPreparedLetter
  56       GetWrappedLetter
  57       SendAlerts
  58       GetPrintMessages
  59       GetQueuedMessages
  60       GetMessage
  61       GetMessageTransportTypes
  62
  63       EnqueueLetter
  64       SendQueuedMessages
  65       ResendMessage
  66     );
  67 }
  68
  69 our $domain_limits = {};
  70
  71 =head1 NAME
  72
  73 C4::Letters - Give functions for Letters management
  74
  75 =head1 SYNOPSIS
  76
  77   use C4::Letters;
  78
  79 =head1 DESCRIPTION
  80
  81   "Letters" is the tool used in Koha to manage informations sent to the patrons and/or the library. This include some cron jobs like
  82   late issues, as well as other tasks like sending a mail to users that have subscribed to a "serial issue alert" (= being warned every time a new issue has arrived at the library)
  83
  84   Letters are managed through "alerts" sent by Koha on some events. All "alert" related functions are in this module too.
  85
  86 =head2 GetLetters([$module])
  87
  88   $letters = &GetLetters($module);
  89   returns informations about letters.
  90   if needed, $module filters for letters given module
  91
  92   DEPRECATED - You must use Koha::Notice::Templates instead
  93   The group by clause is confusing and can lead to issues
  94
  95 =cut
  96
  97 sub GetLetters {
  98     my ($filters) = @_;
  99     my $module    = $filters->{module};
 100     my $code      = $filters->{code};
 101     my $branchcode = $filters->{branchcode};
 102     my $dbh       = C4::Context->dbh;
 103     my $letters   = $dbh->selectall_arrayref(
 104         q|
 105             SELECT code, module, name
 106             FROM letter
 107             WHERE 1
 108         |
 109           . ( $module ? q| AND module = ?| : q|| )
 110           . ( $code   ? q| AND code = ?|   : q|| )
 111           . ( defined $branchcode   ? q| AND branchcode = ?|   : q|| )
 112           . q| GROUP BY code, module, name ORDER BY name|, { Slice => {} }
 113         , ( $module ? $module : () )
 114         , ( $code ? $code : () )
 115         , ( defined $branchcode ? $branchcode : () )
 116     );
 117
 118     return $letters;
 119 }
 120
 121 =head2 GetLetterTemplates
 122
 123     my $letter_templates = GetLetterTemplates(
 124         {
 125             module => 'circulation',
 126             code => 'my code',
 127             branchcode => 'CPL', # '' for default,
 128         }
 129     );
 130
 131     Return a hashref of letter templates.
 132
 133 =cut
 134
 135 sub GetLetterTemplates {
 136     my ( $params ) = @_;
 137
 138     my $module    = $params->{module};
 139     my $code      = $params->{code};
 140     my $branchcode = $params->{branchcode} // '';
 141     my $dbh       = C4::Context->dbh;
 142     return Koha::Notice::Templates->search(
 143         {
 144             module     => $module,
 145             code       => $code,
 146             branchcode => $branchcode,
 147             (
 148                 C4::Context->preference('TranslateNotices')
 149                 ? ()
 150                 : ( lang => 'default' )
 151             )
 152         }
 153     )->unblessed;
 154 }
 155
 156 =head2 GetLettersAvailableForALibrary
 157
 158     my $letters = GetLettersAvailableForALibrary(
 159         {
 160             branchcode => 'CPL', # '' for default
 161             module => 'circulation',
 162         }
 163     );
 164
 165     Return an arrayref of letters, sorted by name.
 166     If a specific letter exist for the given branchcode, it will be retrieve.
 167     Otherwise the default letter will be.
 168
 169 =cut
 170
 171 sub GetLettersAvailableForALibrary {
 172     my ($filters)  = @_;
 173     my $branchcode = $filters->{branchcode};
 174     my $module     = $filters->{module};
 175
 176     croak "module should be provided" unless $module;
 177
 178     my $dbh             = C4::Context->dbh;
 179     my $default_letters = $dbh->selectall_arrayref(
 180         q|
 181             SELECT module, code, branchcode, name
 182             FROM letter
 183             WHERE 1
 184         |
 185           . q| AND branchcode = ''|
 186           . ( $module ? q| AND module = ?| : q|| )
 187           . q| ORDER BY name|, { Slice => {} }
 188         , ( $module ? $module : () )
 189     );
 190
 191     my $specific_letters;
 192     if ($branchcode) {
 193         $specific_letters = $dbh->selectall_arrayref(
 194             q|
 195                 SELECT module, code, branchcode, name
 196                 FROM letter
 197                 WHERE 1
 198             |
 199               . q| AND branchcode = ?|
 200               . ( $module ? q| AND module = ?| : q|| )
 201               . q| ORDER BY name|, { Slice => {} }
 202             , $branchcode
 203             , ( $module ? $module : () )
 204         );
 205     }
 206
 207     my %letters;
 208     for my $l (@$default_letters) {
 209         $letters{ $l->{code} } = $l;
 210     }
 211     for my $l (@$specific_letters) {
 212         # Overwrite the default letter with the specific one.
 213         $letters{ $l->{code} } = $l;
 214     }
 215
 216     return [ map { $letters{$_} }
 217           sort { $letters{$a}->{name} cmp $letters{$b}->{name} }
 218           keys %letters ];
 219
 220 }
 221
 222 =head2 DelLetter
 223
 224     DelLetter(
 225         {
 226             branchcode => 'CPL',
 227             module => 'circulation',
 228             code => 'my code',
 229             [ mtt => 'email', ]
 230         }
 231     );
 232
 233     Delete the letter. The mtt parameter is facultative.
 234     If not given, all templates mathing the other parameters will be removed.
 235
 236 =cut
 237
 238 sub DelLetter {
 239     my ($params)   = @_;
 240     my $branchcode = $params->{branchcode};
 241     my $module     = $params->{module};
 242     my $code       = $params->{code};
 243     my $mtt        = $params->{mtt};
 244     my $lang       = $params->{lang};
 245     my $dbh        = C4::Context->dbh;
 246     $dbh->do(q|
 247         DELETE FROM letter
 248         WHERE branchcode = ?
 249           AND module = ?
 250           AND code = ?
 251     |
 252     . ( $mtt ? q| AND message_transport_type = ?| : q|| )
 253     . ( $lang? q| AND lang = ?| : q|| )
 254     , undef, $branchcode, $module, $code, ( $mtt ? $mtt : () ), ( $lang ? $lang : () ) );
 255 }
 256
 257 =head2 SendAlerts
 258
 259     my $err = &SendAlerts($type, $externalid, $letter_code);
 260
 261     Parameters:
 262       - $type : the type of alert
 263       - $externalid : the id of the "object" to query
 264       - $letter_code : the notice template to use
 265
 266     C<&SendAlerts> sends an email notice directly to a patron or a vendor.
 267
 268     Currently it supports ($type):
 269       - claim serial issues (claimissues)
 270       - claim acquisition orders (claimacquisition)
 271       - send acquisition orders to the vendor (orderacquisition)
 272       - notify patrons about newly received serial issues (issue)
 273       - notify patrons when their account is created (members)
 274
 275     Returns undef or { error => 'message } on failure.
 276     Returns true on success.
 277
 278 =cut
 279
 280 sub SendAlerts {
 281     my ( $type, $externalid, $letter_code ) = @_;
 282     my $dbh = C4::Context->dbh;
 283     my $error;
 284
 285     if ( $type eq 'issue' ) {
 286
 287         # prepare the letter...
 288         # search the subscriptionid
 289         my $sth =
 290           $dbh->prepare(
 291             "SELECT subscriptionid FROM serial WHERE serialid=?");
 292         $sth->execute($externalid);
 293         my ($subscriptionid) = $sth->fetchrow
 294           or warn( "No subscription for '$externalid'" ),
 295              return;
 296
 297         # search the biblionumber
 298         $sth =
 299           $dbh->prepare(
 300             "SELECT biblionumber FROM subscription WHERE subscriptionid=?");
 301         $sth->execute($subscriptionid);
 302         my ($biblionumber) = $sth->fetchrow
 303           or warn( "No biblionumber for '$subscriptionid'" ),
 304              return;
 305
 306         # find the list of subscribers to notify
 307         my $subscription = Koha::Subscriptions->find( $subscriptionid );
 308         my $subscribers = $subscription->subscribers;
 309         while ( my $patron = $subscribers->next ) {
 310             my $email = $patron->email or next;
 311
 312 #                    warn "sending issues...";
 313             my $userenv = C4::Context->userenv;
 314             my $library = $patron->library;
 315             my $letter = GetPreparedLetter (
 316                 module => 'serial',
 317                 letter_code => $letter_code,
 318                 branchcode => $userenv->{branch},
 319                 tables => {
 320                     'branches'    => $library->branchcode,
 321                     'biblio'      => $biblionumber,
 322                     'biblioitems' => $biblionumber,
 323                     'borrowers'   => $patron->unblessed,
 324                     'subscription' => $subscriptionid,
 325                     'serial' => $externalid,
 326                 },
 327                 want_librarian => 1,
 328             ) or return;
 329
 330             # FIXME: This 'default' behaviour should be moved to Koha::Email
 331             my $mail = Koha::Email->create(
 332                 {
 333                     to       => $email,
 334                     from     => $library->branchemail,
 335                     reply_to => $library->branchreplyto,
 336                     sender   => $library->branchreturnpath,
 337                     subject  => "" . $letter->{title},
 338                 }
 339             );
 340
 341             if ( $letter->{is_html} ) {
 342                 $mail->html_body( _wrap_html( $letter->{content}, "" . $letter->{title} ) );
 343             }
 344             else {
 345                 $mail->text_body( $letter->{content} );
 346             }
 347
 348             my $success = try {
 349                 $mail->send_or_die({ transport => $library->smtp_server->transport });
 350             }
 351             catch {
 352                 # We expect ref($_) eq 'Email::Sender::Failure'
 353                 $error = $_->message;
 354
 355                 carp "$_";
 356                 return;
 357             };
 358
 359             return { error => $error }
 360                 unless $success;
 361         }
 362     }
 363     elsif ( $type eq 'claimacquisition' or $type eq 'claimissues' or $type eq 'orderacquisition' ) {
 364
 365         # prepare the letter...
 366         my $strsth;
 367         my $sthorders;
 368         my $dataorders;
 369         my $action;
 370         my $basketno;
 371         my %loops;
 372         if ( $type eq 'claimacquisition') {
 373             $strsth = qq{
 374             SELECT aqorders.*,aqbasket.*,biblio.*,biblioitems.*
 375             FROM aqorders
 376             LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
 377             LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
 378             LEFT JOIN biblioitems ON aqorders.biblionumber=biblioitems.biblionumber
 379             WHERE aqorders.ordernumber IN (
 380             };
 381
 382             if (!@$externalid){
 383                 carp "No order selected";
 384                 return { error => "no_order_selected" };
 385             }
 386             $strsth .= join( ",", ('?') x @$externalid ) . ")";
 387             $action = "ACQUISITION CLAIM";
 388             $sthorders = $dbh->prepare($strsth);
 389             $sthorders->execute( @$externalid );
 390             $dataorders = $sthorders->fetchall_arrayref( {} );
 391         }
 392
 393         if ($type eq 'claimissues') {
 394             $strsth = qq{
 395             SELECT serial.*,subscription.*, biblio.*, biblioitems.*, aqbooksellers.*,
 396             aqbooksellers.id AS booksellerid
 397             FROM serial
 398             LEFT JOIN subscription ON serial.subscriptionid=subscription.subscriptionid
 399             LEFT JOIN biblio ON serial.biblionumber=biblio.biblionumber
 400             LEFT JOIN biblioitems ON serial.biblionumber = biblioitems.biblionumber
 401             LEFT JOIN aqbooksellers ON subscription.aqbooksellerid=aqbooksellers.id
 402             WHERE serial.serialid IN (
 403             };
 404
 405             if (!@$externalid){
 406                 carp "No issues selected";
 407                 return { error => "no_issues_selected" };
 408             }
 409
 410             $strsth .= join( ",", ('?') x @$externalid ) . ")";
 411             $action = "SERIAL CLAIM";
 412             $sthorders = $dbh->prepare($strsth);
 413             $sthorders->execute( @$externalid );
 414             $dataorders = $sthorders->fetchall_arrayref( {} );
 415         }
 416
 417         if ( $type eq 'orderacquisition') {
 418             $basketno = $externalid;
 419             $strsth = qq{
 420             SELECT aqorders.*,aqbasket.*,biblio.*,biblioitems.*
 421             FROM aqorders
 422             LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
 423             LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
 424             LEFT JOIN biblioitems ON aqorders.biblionumber=biblioitems.biblionumber
 425             WHERE aqbasket.basketno = ?
 426             AND orderstatus IN ('new','ordered')
 427             };
 428
 429             unless ( $basketno ) {
 430                 carp "No basketnumber given";
 431                 return { error => "no_basketno" };
 432             }
 433             $action = "ACQUISITION ORDER";
 434             $sthorders = $dbh->prepare($strsth);
 435             $sthorders->execute($basketno);
 436             $dataorders = $sthorders->fetchall_arrayref( {} );
 437             %loops = (
 438                 aqorders => [ map { $_->{ordernumber} } @$dataorders ]
 439             );
 440         }
 441
 442         my $booksellerid = $dataorders->[0]->{booksellerid};
 443         my $addressee =  $type eq 'claimacquisition' || $type eq 'orderacquisition' ? 'acqprimary' : 'serialsprimary';
 444
 445         my $sthcontact =
 446           $dbh->prepare("SELECT * FROM aqcontacts WHERE booksellerid=? AND $type=1 ORDER BY $addressee DESC");
 447         $sthcontact->execute( $booksellerid );
 448         my $datacontact = $sthcontact->fetchrow_hashref;
 449
 450         my @email;
 451         my @cc;
 452         push @email, $datacontact->{email}           if ( $datacontact && $datacontact->{email} );
 453         unless (@email) {
 454             warn "Bookseller $booksellerid without emails";
 455             return { error => "no_email" };
 456         }
 457         my $addlcontact;
 458         while ($addlcontact = $sthcontact->fetchrow_hashref) {
 459             push @cc, $addlcontact->{email} if ( $addlcontact && $addlcontact->{email} );
 460         }
 461
 462         my $userenv = C4::Context->userenv;
 463         my $letter = GetPreparedLetter (
 464             module => $type,
 465             letter_code => $letter_code,
 466             branchcode => $userenv->{branch},
 467             tables => {
 468                 'branches'      => $userenv->{branch},
 469                 'aqbooksellers' => $booksellerid,
 470                 'aqcontacts'    => $datacontact,
 471                 'aqbasket'      => $basketno,
 472             },
 473             repeat => $dataorders,
 474             loops => \%loops,
 475             want_librarian => 1,
 476         ) or return { error => "no_letter" };
 477
 478         # Remove the order tag
 479         $letter->{content} =~ s/<order>(.*?)<\/order>/$1/gxms;
 480
 481         # ... then send mail
 482         my $library = Koha::Libraries->find( $userenv->{branch} );
 483         my $mail = Koha::Email->create(
 484             {
 485                 to => join( ',', @email ),
 486                 cc => join( ',', @cc ),
 487                 (
 488                     (
 489                         C4::Context->preference("ClaimsBccCopy")
 490                           && ( $type eq 'claimacquisition'
 491                             || $type eq 'claimissues' )
 492                     )
 493                     ? ( bcc => $userenv->{emailaddress} )
 494                     : ()
 495                 ),
 496                 from => $library->branchemail
 497                   || C4::Context->preference('KohaAdminEmailAddress'),
 498                 subject => "" . $letter->{title},
 499             }
 500         );
 501
 502         if ( $letter->{is_html} ) {
 503             $mail->html_body( _wrap_html( $letter->{content}, "" . $letter->{title} ) );
 504         }
 505         else {
 506             $mail->text_body( "" . $letter->{content} );
 507         }
 508
 509         my $success = try {
 510             $mail->send_or_die({ transport => $library->smtp_server->transport });
 511         }
 512         catch {
 513             # We expect ref($_) eq 'Email::Sender::Failure'
 514             $error = $_->message;
 515
 516             carp "$_";
 517             return;
 518         };
 519
 520         return { error => $error }
 521             unless $success;
 522
 523         my $log_object = $action eq 'ACQUISITION ORDER' ? $externalid : undef;
 524         my $module = $action eq 'ACQUISITION ORDER' ? 'ACQUISITIONS' : 'CLAIMS';
 525         logaction(
 526             $module,
 527             $action,
 528             $log_object,
 529             "To="
 530                 . join( ',', @email )
 531                 . " Title="
 532                 . $letter->{title}
 533                 . " Content="
 534                 . $letter->{content}
 535         ) if C4::Context->preference("ClaimsLog");
 536     }
 537
 538     # If we come here, return an OK status
 539     return 1;
 540 }
 541
 542 =head2 GetPreparedLetter( %params )
 543
 544     %params hash:
 545       module => letter module, mandatory
 546       letter_code => letter code, mandatory
 547       branchcode => for letter selection, if missing default system letter taken
 548       tables => a hashref with table names as keys. Values are either:
 549         - a scalar - primary key value
 550         - an arrayref - primary key values
 551         - a hashref - full record
 552       substitute => custom substitution key/value pairs
 553       repeat => records to be substituted on consecutive lines:
 554         - an arrayref - tries to guess what needs substituting by
 555           taking remaining << >> tokensr; not recommended
 556         - a hashref token => @tables - replaces <token> << >> << >> </token>
 557           subtemplate for each @tables row; table is a hashref as above
 558       want_librarian => boolean,  if set to true triggers librarian details
 559         substitution from the userenv
 560     Return value:
 561       letter fields hashref (title & content useful)
 562
 563 =cut
 564
 565 sub GetPreparedLetter {
 566     my %params = @_;
 567
 568     my $letter = $params{letter};
 569     my $lang   = $params{lang} || 'default';
 570
 571     unless ( $letter ) {
 572         my $module      = $params{module} or croak "No module";
 573         my $letter_code = $params{letter_code} or croak "No letter_code";
 574         my $branchcode  = $params{branchcode} || '';
 575         my $mtt         = $params{message_transport_type} || 'email';
 576
 577         my $template = Koha::Notice::Templates->find_effective_template(
 578             {
 579                 module                 => $module,
 580                 code                   => $letter_code,
 581                 branchcode             => $branchcode,
 582                 message_transport_type => $mtt,
 583                 lang                   => $lang
 584             }
 585         );
 586
 587         unless ( $template ) {
 588             warn( "No $module $letter_code letter transported by " . $mtt );
 589             return;
 590         }
 591
 592         $letter = $template->unblessed;
 593         $letter->{'content-type'} = 'text/html; charset="UTF-8"' if $letter->{is_html};
 594     }
 595
 596     my $objects = $params{objects} || {};
 597     my $tables = $params{tables} || {};
 598     my $substitute = $params{substitute} || {};
 599     my $loops  = $params{loops} || {}; # loops is not supported for historical notices syntax
 600     my $repeat = $params{repeat};
 601     %$tables || %$substitute || $repeat || %$loops || %$objects
 602       or carp( "ERROR: nothing to substitute - all of 'objects', 'tables', 'loops' and 'substitute' are empty" ),
 603          return;
 604     my $want_librarian = $params{want_librarian};
 605
 606     if (%$substitute) {
 607         while ( my ($token, $val) = each %$substitute ) {
 608             $val //= q{};
 609             if ( $token eq 'items.content' ) {
 610                 $val =~ s|\n|<br/>|g if $letter->{is_html};
 611             }
 612
 613             $letter->{title} =~ s/<<$token>>/$val/g;
 614             $letter->{content} =~ s/<<$token>>/$val/g;
 615        }
 616     }
 617
 618     my $OPACBaseURL = C4::Context->preference('OPACBaseURL');
 619     $letter->{content} =~ s/<<OPACBaseURL>>/$OPACBaseURL/go;
 620
 621     if ($want_librarian) {
 622         # parsing librarian name
 623         my $userenv = C4::Context->userenv;
 624         $letter->{content} =~ s/<<LibrarianFirstname>>/$userenv->{firstname}/go;
 625         $letter->{content} =~ s/<<LibrarianSurname>>/$userenv->{surname}/go;
 626         $letter->{content} =~ s/<<LibrarianEmailaddress>>/$userenv->{emailaddress}/go;
 627     }
 628
 629     my ($repeat_no_enclosing_tags, $repeat_enclosing_tags);
 630
 631     if ($repeat) {
 632         if (ref ($repeat) eq 'ARRAY' ) {
 633             $repeat_no_enclosing_tags = $repeat;
 634         } else {
 635             $repeat_enclosing_tags = $repeat;
 636         }
 637     }
 638
 639     if ($repeat_enclosing_tags) {
 640         while ( my ($tag, $tag_tables) = each %$repeat_enclosing_tags ) {
 641             if ( $letter->{content} =~ m!<$tag>(.*)</$tag>!s ) {
 642                 my $subcontent = $1;
 643                 my @lines = map {
 644                     my %subletter = ( title => '', content => $subcontent );
 645                     _substitute_tables( \%subletter, $_ );
 646                     $subletter{content};
 647                 } @$tag_tables;
 648                 $letter->{content} =~ s!<$tag>.*</$tag>!join( "\n", @lines )!se;
 649             }
 650         }
 651     }
 652
 653     if (%$tables) {
 654         _substitute_tables( $letter, $tables );
 655     }
 656
 657     if ($repeat_no_enclosing_tags) {
 658         if ( $letter->{content} =~ m/[^\n]*<<.*>>[^\n]*/so ) {
 659             my $line = $&;
 660             my $i = 1;
 661             my @lines = map {
 662                 my $c = $line;
 663                 $c =~ s/<<count>>/$i/go;
 664                 foreach my $field ( keys %{$_} ) {
 665                     $c =~ s/(<<[^\.]+.$field>>)/$_->{$field}/;
 666                 }
 667                 $i++;
 668                 $c;
 669             } @$repeat_no_enclosing_tags;
 670
 671             my $replaceby = join( "\n", @lines );
 672             $letter->{content} =~ s/\Q$line\E/$replaceby/s;
 673         }
 674     }
 675
 676     $letter->{content} = _process_tt(
 677         {
 678             content    => $letter->{content},
 679             lang       => $lang,
 680             loops      => $loops,
 681             objects    => $objects,
 682             substitute => $substitute,
 683             tables     => $tables,
 684         }
 685     );
 686
 687     $letter->{title} = _process_tt(
 688         {
 689             content    => $letter->{title},
 690             lang       => $lang,
 691             loops      => $loops,
 692             objects    => $objects,
 693             substitute => $substitute,
 694             tables     => $tables,
 695         }
 696     );
 697
 698     $letter->{content} =~ s/<<\S*>>//go; #remove any stragglers
 699
 700     return $letter;
 701 }
 702
 703 sub _substitute_tables {
 704     my ( $letter, $tables ) = @_;
 705     while ( my ($table, $param) = each %$tables ) {
 706         next unless $param;
 707
 708         my $ref = ref $param;
 709
 710         my $values;
 711         if ($ref && $ref eq 'HASH') {
 712             $values = $param;
 713         }
 714         else {
 715             my $sth = _parseletter_sth($table);
 716             unless ($sth) {
 717                 warn "_parseletter_sth('$table') failed to return a valid sth.  No substitution will be done for that table.";
 718                 return;
 719             }
 720             $sth->execute( $ref ? @$param : $param );
 721
 722             $values = $sth->fetchrow_hashref;
 723             $sth->finish();
 724         }
 725
 726         _parseletter ( $letter, $table, $values );
 727     }
 728 }
 729
 730 sub _parseletter_sth {
 731     my $table = shift;
 732     my $sth;
 733     unless ($table) {
 734         carp "ERROR: _parseletter_sth() called without argument (table)";
 735         return;
 736     }
 737     # NOTE: we used to check whether we had a statement handle cached in
 738     #       a %handles module-level variable. This was a dumb move and
 739     #       broke things for the rest of us. prepare_cached is a better
 740     #       way to cache statement handles anyway.
 741     my $query =
 742     ($table eq 'accountlines' )    ? "SELECT * FROM $table WHERE   accountlines_id = ?"                               :
 743     ($table eq 'biblio'       )    ? "SELECT * FROM $table WHERE   biblionumber = ?"                                  :
 744     ($table eq 'biblioitems'  )    ? "SELECT * FROM $table WHERE   biblionumber = ?"                                  :
 745     ($table eq 'tickets'      )    ? "SELECT * FROM $table WHERE   id = ?"                                            :
 746     ($table eq 'ticket_updates' )  ? "SELECT * FROM $table WHERE   id = ?"                                            :
 747     ($table eq 'credits'      )    ? "SELECT * FROM accountlines WHERE   accountlines_id = ?"                         :
 748     ($table eq 'debits'       )    ? "SELECT * FROM accountlines WHERE   accountlines_id = ?"                         :
 749     ($table eq 'items'        )    ? "SELECT * FROM $table WHERE     itemnumber = ?"                                  :
 750     ($table eq 'issues'       )    ? "SELECT * FROM $table WHERE     itemnumber = ?"                                  :
 751     ($table eq 'old_issues'   )    ? "SELECT * FROM $table WHERE     issue_id = ?"  :
 752     ($table eq 'reserves'     )    ? "SELECT * FROM $table WHERE borrowernumber = ? and biblionumber = ?"             :
 753     ($table eq 'borrowers'    )    ? "SELECT * FROM $table WHERE borrowernumber = ?"                                  :
 754     ($table eq 'branches'     )    ? "SELECT * FROM $table WHERE     branchcode = ?"                                  :
 755     ($table eq 'suggestions'  )    ? "SELECT * FROM $table WHERE   suggestionid = ?"                                  :
 756     ($table eq 'aqbooksellers')    ? "SELECT * FROM $table WHERE             id = ?"                                  :
 757     ($table eq 'aqorders'     )    ? "SELECT * FROM $table WHERE    ordernumber = ?"                                  :
 758     ($table eq 'aqbasket'     )    ? "SELECT * FROM $table WHERE       basketno = ?"                                  :
 759     ($table eq 'illrequests'  )    ? "SELECT * FROM $table WHERE  illrequest_id = ?"                                  :
 760     ($table eq 'article_requests') ? "SELECT * FROM $table WHERE             id = ?"                                  :
 761     ($table eq 'borrower_modifications') ? "SELECT * FROM $table WHERE verification_token = ?" :
 762     ($table eq 'subscription') ? "SELECT * FROM $table WHERE subscriptionid = ?" :
 763     ($table eq 'serial') ? "SELECT * FROM $table WHERE serialid = ?" :
 764     ($table eq 'problem_reports') ? "SELECT * FROM $table WHERE reportid = ?" :
 765     ($table eq 'additional_contents' || $table eq 'opac_news') ? "SELECT * FROM additional_contents WHERE idnew = ?" :
 766     ($table eq 'recalls') ? "SELECT * FROM $table WHERE recall_id = ?" :
 767     undef ;
 768     unless ($query) {
 769         warn "ERROR: No _parseletter_sth query for table '$table'";
 770         return;     # nothing to get
 771     }
 772     unless ($sth = C4::Context->dbh->prepare_cached($query)) {
 773         warn "ERROR: Failed to prepare query: '$query'";
 774         return;
 775     }
 776     return $sth;    # now cache is populated for that $table
 777 }
 778
 779 =head2 _parseletter($letter, $table, $values)
 780
 781     parameters :
 782     - $letter : a hash to letter fields (title & content useful)
 783     - $table : the Koha table to parse.
 784     - $values_in : table record hashref
 785     parse all fields from a table, and replace values in title & content with the appropriate value
 786     (not exported sub, used only internally)
 787
 788 =cut
 789
 790 sub _parseletter {
 791     my ( $letter, $table, $values_in ) = @_;
 792
 793     # Work on a local copy of $values_in (passed by reference) to avoid side effects
 794     # in callers ( by changing / formatting values )
 795     my $values = $values_in ? { %$values_in } : {};
 796
 797     # FIXME Dates formatting must be done in notice's templates
 798     if ( $table eq 'borrowers' && $values->{'dateexpiry'} ){
 799         $values->{'dateexpiry'} = output_pref({ dt => dt_from_string( $values->{'dateexpiry'} ), dateonly => 1 });
 800     }
 801
 802     if ( $table eq 'reserves' && $values->{'waitingdate'} ) {
 803         $values->{'waitingdate'} = output_pref({ dt => dt_from_string( $values->{'waitingdate'} ), dateonly => 1 });
 804     }
 805
 806     if ($letter->{content} && $letter->{content} =~ /<<today>>/) {
 807         my $todaysdate = output_pref( dt_from_string() );
 808         $letter->{content} =~ s/<<today>>/$todaysdate/go;
 809     }
 810
 811     while ( my ($field, $val) = each %$values ) {
 812         $val =~ s/\p{P}$// if $val && $table=~/biblio/;
 813             #BZ 9886: Assuming that we want to eliminate ISBD punctuation here
 814             #Therefore adding the test on biblio. This includes biblioitems,
 815             #but excludes items. Removed unneeded global and lookahead.
 816
 817         if ( $table=~/^borrowers$/ && $field=~/^streettype$/ ) {
 818             my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $val });
 819             $val = $av->count ? $av->next->lib : '';
 820         }
 821
 822         # Dates replacement
 823         my $replacedby   = defined ($val) ? $val : '';
 824         if (    $replacedby
 825             and not $replacedby =~ m|9999-12-31|
 826             and $replacedby =~ m|^\d{4}-\d{2}-\d{2}( \d{2}:\d{2}:\d{2})?$| )
 827         {
 828             # If the value is XXXX-YY-ZZ[ AA:BB:CC] we assume it is a date
 829             my $dateonly = defined $1 ? 0 : 1; #$1 refers to the capture group wrapped in parentheses. In this case, that's the hours, minutes, seconds.
 830             my $re_dateonly_filter = qr{ $field( \s* \| \s* dateonly\s*)?>> }xms;
 831
 832             for my $letter_field ( qw( title content ) ) {
 833                 my $filter_string_used = q{};
 834                 if ( $letter->{ $letter_field } =~ $re_dateonly_filter ) {
 835                     # We overwrite $dateonly if the filter exists and we have a time in the datetime
 836                     $filter_string_used = $1 || q{};
 837                     $dateonly = $1 unless $dateonly;
 838                 }
 839                 my $replacedby_date = eval {
 840                     output_pref({ dt => scalar dt_from_string( $replacedby ), dateonly => $dateonly });
 841                 };
 842                 $replacedby_date //= q{};
 843
 844                 if ( $letter->{ $letter_field } ) {
 845                     $letter->{ $letter_field } =~ s/\Q<<$table.$field$filter_string_used>>\E/$replacedby_date/g;
 846                     $letter->{ $letter_field } =~ s/\Q<<$field$filter_string_used>>\E/$replacedby_date/g;
 847                 }
 848             }
 849         }
 850         # Other fields replacement
 851         else {
 852             for my $letter_field ( qw( title content ) ) {
 853                 if ( $letter->{ $letter_field } ) {
 854                     $letter->{ $letter_field }   =~ s/<<$table.$field>>/$replacedby/g;
 855                     $letter->{ $letter_field }   =~ s/<<$field>>/$replacedby/g;
 856                 }
 857             }
 858         }
 859     }
 860
 861     if ($table eq 'borrowers' && $letter->{content}) {
 862         my $patron = Koha::Patrons->find( $values->{borrowernumber} );
 863         if ( $patron ) {
 864             my $attributes = $patron->extended_attributes;
 865             my %attr;
 866             while ( my $attribute = $attributes->next ) {
 867                 my $code = $attribute->code;
 868                 my $val  = $attribute->description; # FIXME - we always display intranet description here!
 869                 $val =~ s/\p{P}(?=$)//g if $val;
 870                 next unless $val gt '';
 871                 $attr{$code} ||= [];
 872                 push @{ $attr{$code} }, $val;
 873             }
 874             while ( my ($code, $val_ar) = each %attr ) {
 875                 my $replacefield = "<<borrower-attribute:$code>>";
 876                 my $replacedby   = join ',', @$val_ar;
 877                 $letter->{content} =~ s/$replacefield/$replacedby/g;
 878             }
 879         }
 880     }
 881     return $letter;
 882 }
 883
 884 =head2 EnqueueLetter
 885
 886   my $success = EnqueueLetter( { letter => $letter,
 887         borrowernumber => '12', message_transport_type => 'email' } )
 888
 889 Places a letter in the message_queue database table, which will
 890 eventually get processed (sent) by the process_message_queue.pl
 891 cronjob when it calls SendQueuedMessages.
 892
 893 Return message_id on success
 894
 895 Parameters
 896 * letter - required; A letter hashref as returned from GetPreparedLetter
 897 * message_transport_type - required; One of the available mtts
 898 * borrowernumber - optional if 'to_address' is passed; The borrowernumber of the patron we enqueuing the notice for
 899 * to_address - optional if 'borrowernumber' is passed; The destination email address for the notice (defaults to patron->notice_email_address)
 900 * from_address - optional; The from address for the notice, defaults to patron->library->from_email_address
 901 * reply_address - optional; The reply address for the notice, defaults to patron->library->reply_to
 902
 903 =cut
 904
 905 sub EnqueueLetter {
 906     my $params = shift or return;
 907
 908     return unless exists $params->{'letter'};
 909 #   return unless exists $params->{'borrowernumber'};
 910     return unless exists $params->{'message_transport_type'};
 911
 912     my $content = $params->{letter}->{content};
 913     $content =~ s/\s+//g if(defined $content);
 914     if ( not defined $content or $content eq '' ) {
 915         Koha::Logger->get->info("Trying to add an empty message to the message queue");
 916         return;
 917     }
 918
 919     # If we have any attachments we should encode then into the body.
 920     if ( $params->{'attachments'} ) {
 921         $params->{'letter'} = _add_attachments(
 922             {   letter      => $params->{'letter'},
 923                 attachments => $params->{'attachments'},
 924             }
 925         );
 926     }
 927
 928     my $dbh       = C4::Context->dbh();
 929     my $statement = << 'ENDSQL';
 930 INSERT INTO message_queue
 931 ( letter_id, borrowernumber, subject, content, metadata, letter_code, message_transport_type, status, time_queued, to_address, from_address, reply_address, content_type, failure_code )
 932 VALUES ( ?, ?, ?, ?, ?, ?, ?, ?, CAST(NOW() AS DATETIME), ?, ?, ?, ?, ? )
 933 ENDSQL
 934
 935     my $sth    = $dbh->prepare($statement);
 936     my $result = $sth->execute(
 937         $params->{letter}->{id} || undef,         # letter.id
 938         $params->{'borrowernumber'},              # borrowernumber
 939         $params->{'letter'}->{'title'},           # subject
 940         $params->{'letter'}->{'content'},         # content
 941         $params->{'letter'}->{'metadata'} || '',  # metadata
 942         $params->{'letter'}->{'code'}     || '',  # letter_code
 943         $params->{'message_transport_type'},      # message_transport_type
 944         'pending',                                # status
 945         $params->{'to_address'},                  # to_address
 946         $params->{'from_address'},                # from_address
 947         $params->{'reply_address'},               # reply_address
 948         $params->{'letter'}->{'content-type'},    # content_type
 949         $params->{'failure_code'}        || '',   # failure_code
 950     );
 951     return $dbh->last_insert_id(undef,undef,'message_queue', undef);
 952 }
 953
 954 =head2 SendQueuedMessages ([$hashref])
 955
 956     my $sent = SendQueuedMessages({
 957         message_id => $id,
 958         borrowernumber => $who_letter_is_for,
 959         letter_code => $letter_code, # can be scalar or arrayref
 960         type => $type, # can be scalar or arrayref
 961         limit => 50,
 962         verbose => 1,
 963         where => $where,
 964     });
 965
 966 Sends 'pending' messages from the queue, based on parameters.
 967
 968 The (optional) message_id, borrowernumber, letter_code, type and where
 969 parameter are used to select which pending messages will be processed. The
 970 limit parameter determines the volume of results, i.e. sent messages.
 971
 972 The optional verbose parameter can be used to generate debugging output.
 973
 974 Returns number of messages sent.
 975
 976 =cut
 977
 978 sub SendQueuedMessages {
 979     my $params = shift;
 980     my $limit = $params->{limit};
 981     my $where = $params->{where};
 982
 983     my $smtp_transports = {};
 984
 985     my $count_messages = 0;
 986     my $unsent_messages = Koha::Notice::Messages->search({
 987         status  => 'pending',
 988         $params->{message_id} ? ( message_id => $params->{message_id} ) : (),
 989         $params->{borrowernumber} ? ( borrowernumber => $params->{borrowernumber} ) : (),
 990         # Check for scalar or array in letter_code and type
 991         ref($params->{letter_code}) && @{$params->{letter_code}} ? ( letter_code => $params->{letter_code} ) : (),
 992         !ref($params->{letter_code}) && $params->{letter_code} ? ( letter_code => $params->{letter_code} ) : (),
 993         ref($params->{type}) && @{$params->{type}} ? ( message_transport_type => $params->{type} ) : (), #TODO Existing inconsistency
 994         !ref($params->{type}) && $params->{type} ? ( message_transport_type => $params->{type} ) : (), #TODO Existing inconsistency
 995     });
 996     $unsent_messages = $unsent_messages->search( \$where ) if $where;
 997
 998     $domain_limits = Koha::Notice::Util->load_domain_limits; # (re)initialize per run
 999     while( ( my $message_object = $unsent_messages->next ) && ( !$limit || $count_messages < $limit ) ) {
1000         my $message = $message_object->unblessed;
1001
1002         # If this fails the database is unwritable and we won't manage to send a message that continues to be marked 'pending'
1003         $message_object->make_column_dirty('status');
1004         return unless $message_object->store;
1005
1006         # warn Data::Dumper->Dump( [ $message ], [ 'message' ] );
1007         warn sprintf( 'Processing %s message to patron: %s',
1008                       $message->{'message_transport_type'},
1009                       $message->{'borrowernumber'} || 'Admin' )
1010           if $params->{'verbose'};
1011         # This is just begging for subclassing
1012         next if ( lc($message->{'message_transport_type'}) eq 'rss' );
1013         if ( lc( $message->{'message_transport_type'} ) eq 'email' ) {
1014             my $rv = _send_message_by_email( $message, $params->{'username'}, $params->{'password'}, $params->{'method'}, $smtp_transports );
1015             $count_messages++ if $rv;
1016         }
1017         elsif ( lc( $message->{'message_transport_type'} ) eq 'sms' ) {
1018             if ( C4::Context->preference('SMSSendDriver') eq 'Email' ) {
1019                 my $patron = Koha::Patrons->find( $message->{borrowernumber} );
1020                 my $sms_provider = Koha::SMS::Providers->find( $patron->sms_provider_id );
1021                 unless ( $sms_provider ) {
1022                     warn sprintf( "Patron %s has no sms provider id set!", $message->{'borrowernumber'} ) if $params->{'verbose'};
1023                     _set_message_status( { message_id => $message->{'message_id'}, status => 'failed' } );
1024                     next;
1025                 }
1026                 unless ( $patron->smsalertnumber ) {
1027                     _set_message_status( { message_id => $message->{'message_id'}, status => 'failed' } );
1028                     warn sprintf( "No smsalertnumber found for patron %s!", $message->{'borrowernumber'} ) if $params->{'verbose'};
1029                     next;
1030                 }
1031                 $message->{to_address}  = $patron->smsalertnumber; #Sometime this is set to email - sms should always use smsalertnumber
1032                 $message->{to_address} .= '@' . $sms_provider->domain();
1033
1034                 # Check for possible from_address override
1035                 my $from_address = C4::Context->preference('EmailSMSSendDriverFromAddress');
1036                 if ($from_address && $message->{from_address} ne $from_address) {
1037                     $message->{from_address} = $from_address;
1038                     _update_message_from_address($message->{'message_id'}, $message->{from_address});
1039                 }
1040
1041                 _update_message_to_address($message->{'message_id'}, $message->{to_address});
1042                 my $rv = _send_message_by_email( $message, $params->{'username'}, $params->{'password'}, $params->{'method'} );
1043                 $count_messages++ if $rv;
1044             } else {
1045                 my $rv = _send_message_by_sms( $message );
1046                 $count_messages++ if $rv;
1047             }
1048         }
1049     }
1050     return $count_messages;
1051 }
1052
1053 =head2 GetRSSMessages
1054
1055   my $message_list = GetRSSMessages( { limit => 10, borrowernumber => '14' } )
1056
1057 returns a listref of all queued RSS messages for a particular person.
1058
1059 =cut
1060
1061 sub GetRSSMessages {
1062     my $params = shift;
1063
1064     return unless $params;
1065     return unless ref $params;
1066     return unless $params->{'borrowernumber'};
1067
1068     return _get_unsent_messages( { message_transport_type => 'rss',
1069                                    limit                  => $params->{'limit'},
1070                                    borrowernumber         => $params->{'borrowernumber'}, } );
1071 }
1072
1073 =head2 GetPrintMessages
1074
1075   my $message_list = GetPrintMessages( { borrowernumber => $borrowernumber } )
1076
1077 Returns a arrayref of all queued print messages (optionally, for a particular
1078 person).
1079
1080 =cut
1081
1082 sub GetPrintMessages {
1083     my $params = shift || {};
1084
1085     return _get_unsent_messages( { message_transport_type => 'print',
1086                                    borrowernumber         => $params->{'borrowernumber'},
1087                                  } );
1088 }
1089
1090 =head2 GetQueuedMessages ([$hashref])
1091
1092   my $messages = GetQueuedMessage( { borrowernumber => '123', limit => 20 } );
1093
1094 Fetches a list of messages from the message queue optionally filtered by borrowernumber
1095 and limited to specified limit.
1096
1097 Return is an arrayref of hashes, each has represents a message in the message queue.
1098
1099 =cut
1100
1101 sub GetQueuedMessages {
1102     my $params = shift;
1103
1104     my $dbh = C4::Context->dbh();
1105     my $statement = << 'ENDSQL';
1106 SELECT message_id, borrowernumber, subject, content, message_transport_type, status, time_queued, updated_on, failure_code
1107 FROM message_queue
1108 ENDSQL
1109
1110     my @query_params;
1111     my @whereclauses;
1112     if ( exists $params->{'borrowernumber'} ) {
1113         push @whereclauses, ' borrowernumber = ? ';
1114         push @query_params, $params->{'borrowernumber'};
1115     }
1116
1117     if ( @whereclauses ) {
1118         $statement .= ' WHERE ' . join( 'AND', @whereclauses );
1119     }
1120
1121     if ( defined $params->{'limit'} ) {
1122         $statement .= ' LIMIT ? ';
1123         push @query_params, $params->{'limit'};
1124     }
1125
1126     my $sth = $dbh->prepare( $statement );
1127     my $result = $sth->execute( @query_params );
1128     return $sth->fetchall_arrayref({});
1129 }
1130
1131 =head2 GetMessageTransportTypes
1132
1133   my @mtt = GetMessageTransportTypes();
1134
1135   returns an arrayref of transport types
1136
1137 =cut
1138
1139 sub GetMessageTransportTypes {
1140     my $dbh = C4::Context->dbh();
1141     my $mtts = $dbh->selectcol_arrayref("
1142         SELECT message_transport_type
1143         FROM message_transport_types
1144         ORDER BY message_transport_type
1145     ");
1146     return $mtts;
1147 }
1148
1149 =head2 GetMessage
1150
1151     my $message = C4::Letters::Message($message_id);
1152
1153 =cut
1154
1155 sub GetMessage {
1156     my ( $message_id ) = @_;
1157     return unless $message_id;
1158     my $dbh = C4::Context->dbh;
1159     return $dbh->selectrow_hashref(q|
1160         SELECT message_id, borrowernumber, subject, content, metadata, letter_code, message_transport_type, status, time_queued, updated_on, to_address, from_address, reply_address, content_type, failure_code
1161         FROM message_queue
1162         WHERE message_id = ?
1163     |, {}, $message_id );
1164 }
1165
1166 =head2 ResendMessage
1167
1168   Attempt to resend a message which has failed previously.
1169
1170   my $has_been_resent = C4::Letters::ResendMessage($message_id);
1171
1172   Updates the message to 'pending' status so that
1173   it will be resent later on.
1174
1175   returns 1 on success, 0 on failure, undef if no message was found
1176
1177 =cut
1178
1179 sub ResendMessage {
1180     my $message_id = shift;
1181     return unless $message_id;
1182
1183     my $message = GetMessage( $message_id );
1184     return unless $message;
1185     my $rv = 0;
1186     if ( $message->{status} ne 'pending' ) {
1187         $rv = C4::Letters::_set_message_status({
1188             message_id => $message_id,
1189             status => 'pending',
1190         });
1191         $rv = $rv > 0? 1: 0;
1192         # Clear destination email address to force address update
1193         _update_message_to_address( $message_id, undef ) if $rv &&
1194             $message->{message_transport_type} eq 'email';
1195     }
1196     return $rv;
1197 }
1198
1199 =head2 _add_attachements
1200
1201   _add_attachments({ letter => $letter, attachments => $attachments });
1202
1203   named parameters:
1204   letter - the standard letter hashref
1205   attachments - listref of attachments. each attachment is a hashref of:
1206     type - the mime type, like 'text/plain'
1207     content - the actual attachment
1208     filename - the name of the attachment.
1209
1210   returns your letter object, with the content updated.
1211   This routine picks the I<content> of I<letter> and generates a MIME
1212   email, attaching the passed I<attachments> using Koha::Email. The
1213   content is replaced by the string representation of the MIME object,
1214   and the content-type is updated for later handling.
1215
1216 =cut
1217
1218 sub _add_attachments {
1219     my $params = shift;
1220
1221     my $letter = $params->{letter};
1222     my $attachments = $params->{attachments};
1223     return $letter unless @$attachments;
1224
1225     my $message = Koha::Email->new;
1226
1227     if ( $letter->{is_html} ) {
1228         $message->html_body( _wrap_html( $letter->{content}, $letter->{title} ) );
1229     }
1230     else {
1231         $message->text_body( $letter->{content} );
1232     }
1233
1234     foreach my $attachment ( @$attachments ) {
1235         $message->attach(
1236             Encode::encode( "UTF-8", $attachment->{content} ),
1237             content_type => $attachment->{type} || 'application/octet-stream',
1238             name         => $attachment->{filename},
1239             disposition  => 'attachment',
1240         );
1241     }
1242
1243     $letter->{'content-type'} = SERIALIZED_EMAIL_CONTENT_TYPE;
1244     $letter->{content} = $message->as_string;
1245
1246     return $letter;
1247
1248 }
1249
1250 =head2 _get_unsent_messages
1251
1252   This function's parameter hash reference takes the following
1253   optional named parameters:
1254    message_transport_type: method of message sending (e.g. email, sms, etc.)
1255                            Can be a single string, or an arrayref of strings
1256    borrowernumber        : who the message is to be sent
1257    letter_code           : type of message being sent (e.g. PASSWORD_RESET)
1258                            Can be a single string, or an arrayref of strings
1259    message_id            : the message_id of the message. In that case the sub will return only 1 result
1260    limit                 : maximum number of messages to send
1261
1262   This function returns an array of matching hash referenced rows from
1263   message_queue with some borrower information added.
1264
1265 =cut
1266
1267 sub _get_unsent_messages {
1268     my $params = shift;
1269
1270     my $dbh = C4::Context->dbh();
1271     my $statement = qq{
1272         SELECT mq.message_id, mq.borrowernumber, mq.subject, mq.content, mq.message_transport_type, mq.status, mq.time_queued, mq.from_address, mq.reply_address, mq.to_address, mq.content_type, b.branchcode, mq.letter_code, mq.failure_code
1273         FROM message_queue mq
1274         LEFT JOIN borrowers b ON b.borrowernumber = mq.borrowernumber
1275         WHERE status = ?
1276     };
1277
1278     my @query_params = ('pending');
1279     if ( ref $params ) {
1280         if ( $params->{'borrowernumber'} ) {
1281             $statement .= ' AND mq.borrowernumber = ? ';
1282             push @query_params, $params->{'borrowernumber'};
1283         }
1284         if ( $params->{'letter_code'} ) {
1285             my @letter_codes = ref $params->{'letter_code'} eq "ARRAY" ? @{$params->{'letter_code'}} : $params->{'letter_code'};
1286             if ( @letter_codes ) {
1287                 my $q = join( ",", ("?") x @letter_codes );
1288                 $statement .= " AND mq.letter_code IN ( $q ) ";
1289                 push @query_params, @letter_codes;
1290             }
1291         }
1292         if ( $params->{'message_transport_type'} ) {
1293             my @types = ref $params->{'message_transport_type'} eq "ARRAY" ? @{$params->{'message_transport_type'}} : $params->{'message_transport_type'};
1294             if ( @types ) {
1295                 my $q = join( ",", ("?") x @types );
1296                 $statement .= " AND message_transport_type IN ( $q ) ";
1297                 push @query_params, @types;
1298             }
1299         }
1300         if ( $params->{message_id} ) {
1301             $statement .= ' AND message_id = ?';
1302             push @query_params, $params->{message_id};
1303         }
1304         if ( $params->{where} ) {
1305             $statement .= " AND $params->{where} ";
1306         }
1307         if ( $params->{'limit'} ) {
1308             $statement .= ' limit ? ';
1309             push @query_params, $params->{'limit'};
1310         }
1311     }
1312
1313     my $sth = $dbh->prepare( $statement );
1314     my $result = $sth->execute( @query_params );
1315     return $sth->fetchall_arrayref({});
1316 }
1317
1318 sub _send_message_by_email {
1319     my $message = shift or return;
1320     my ( $username, $password, $method, $smtp_transports ) = @_;
1321
1322     my $patron;
1323     my $to_address = $message->{'to_address'};
1324     unless ($to_address) {
1325         $patron = Koha::Patrons->find( $message->{borrowernumber} );
1326         unless ($patron) {
1327             warn "FAIL: No 'to_address' and INVALID borrowernumber ($message->{borrowernumber})";
1328             _set_message_status(
1329                 {
1330                     message_id   => $message->{'message_id'},
1331                     status       => 'failed',
1332                     failure_code => 'INVALID_BORNUMBER'
1333                 }
1334             );
1335             return;
1336         }
1337         $to_address = $patron->notice_email_address;
1338         unless ($to_address) {
1339             # warn "FAIL: No 'to_address' and no email for " . ($member->{surname} ||'') . ", borrowernumber ($message->{borrowernumber})";
1340             # warning too verbose for this more common case?
1341             _set_message_status(
1342                 {
1343                     message_id   => $message->{'message_id'},
1344                     status       => 'failed',
1345                     failure_code => 'NO_EMAIL'
1346                 }
1347             );
1348             return;
1349         }
1350     }
1351
1352     # Skip this message if we exceed domain limits in this run
1353     if( Koha::Notice::Util->exceeds_limit({ to => $to_address, limits => $domain_limits }) ) {
1354         # Save the to_address if you delay the message so that we dont need to look it up again
1355         _update_message_to_address( $message->{'message_id'}, $to_address )
1356             if !$message->{to_address};
1357         return;
1358     }
1359
1360     my $subject = $message->{'subject'};
1361
1362     my $content = $message->{'content'};
1363     my $content_type = $message->{'content_type'} || 'text/plain; charset="UTF-8"';
1364     my $is_html = $content_type =~ m/html/io;
1365
1366     my $branch_email = undef;
1367     my $branch_replyto = undef;
1368     my $branch_returnpath = undef;
1369     my $library;
1370
1371     $patron //= Koha::Patrons->find( $message->{borrowernumber} ); # we might already found him
1372     if ($patron) {
1373         $library           = $patron->library;
1374         $branch_email      = $library->from_email_address;
1375         $branch_replyto    = $library->branchreplyto;
1376         $branch_returnpath = $library->branchreturnpath;
1377     }
1378
1379     # NOTE: Patron may not be defined above so branch_email may be undefined still
1380     # so we need to fallback to KohaAdminEmailAddress as a last resort.
1381     my $from_address =
1382          $message->{'from_address'}
1383       || $branch_email
1384       || C4::Context->preference('KohaAdminEmailAddress');
1385     if( !$from_address ) {
1386         _set_message_status(
1387             {
1388                 message_id   => $message->{'message_id'},
1389                 status       => 'failed',
1390                 failure_code => 'NO_FROM',
1391             }
1392         );
1393         return;
1394     };
1395     my $email;
1396
1397     try {
1398
1399         my $params = {
1400             to => $to_address,
1401             (
1402                 C4::Context->preference('NoticeBcc')
1403                 ? ( bcc => C4::Context->preference('NoticeBcc') )
1404                 : ()
1405             ),
1406             from     => $from_address,
1407             reply_to => $message->{'reply_address'} || $branch_replyto,
1408             sender   => $branch_returnpath,
1409             subject  => "" . $message->{subject}
1410         };
1411
1412         if ( $message->{'content_type'} && $message->{'content_type'} eq SERIALIZED_EMAIL_CONTENT_TYPE ) {
1413
1414             # The message has been previously composed as a valid MIME object
1415             # and serialized as a string on the DB
1416             $email = Koha::Email->new_from_string($content);
1417             $email->create($params);
1418         } else {
1419             $email = Koha::Email->create($params);
1420             if ($is_html) {
1421                 $email->html_body( _wrap_html( $content, $subject ) );
1422             } else {
1423                 $email->text_body($content);
1424             }
1425         }
1426     }
1427     catch {
1428         if ( ref($_) eq 'Koha::Exceptions::BadParameter' ) {
1429             _set_message_status(
1430                 {
1431                     message_id   => $message->{'message_id'},
1432                     status       => 'failed',
1433                     failure_code => "INVALID_EMAIL:".$_->parameter
1434                 }
1435             );
1436         } else {
1437             _set_message_status(
1438                 {
1439                     message_id   => $message->{'message_id'},
1440                     status       => 'failed',
1441                     failure_code => 'UNKNOWN_ERROR'
1442                 }
1443             );
1444         }
1445         return 0;
1446     };
1447     return unless $email;
1448
1449     my $smtp_server;
1450     if ( $library ) {
1451         $smtp_server = $library->smtp_server;
1452     }
1453     else {
1454         $smtp_server = Koha::SMTP::Servers->get_default;
1455     }
1456
1457     if ( $username ) {
1458         $smtp_server->set(
1459             {
1460                 sasl_username => $username,
1461                 sasl_password => $password,
1462             }
1463         );
1464     }
1465
1466 # if initial message address was empty, coming here means that a to address was found and
1467 # queue should be updated; same if to address was overriden by Koha::Email->create
1468     _update_message_to_address( $message->{'message_id'}, $email->email->header('To') )
1469       if !$message->{to_address}
1470       || $message->{to_address} ne $email->email->header('To');
1471
1472     $smtp_transports->{ $smtp_server->id // 'default' } ||= $smtp_server->transport;
1473     my $smtp_transport = $smtp_transports->{ $smtp_server->id // 'default' };
1474
1475     try {
1476         $email->send_or_die({ transport => $smtp_transport });
1477
1478         _set_message_status(
1479             {
1480                 message_id => $message->{'message_id'},
1481                 status     => 'sent',
1482                 failure_code => ''
1483             }
1484         );
1485         return 1;
1486     }
1487     catch {
1488         _set_message_status(
1489             {
1490                 message_id => $message->{'message_id'},
1491                 status     => 'failed',
1492                 failure_code => 'SENDMAIL'
1493             }
1494         );
1495         carp "$_";
1496         carp "$Mail::Sendmail::error";
1497         return;
1498     };
1499 }
1500
1501 sub _wrap_html {
1502     my ($content, $title) = @_;
1503
1504     my $css = C4::Context->preference("NoticeCSS") || '';
1505     $css = qq{<link rel="stylesheet" type="text/css" href="$css">} if $css;
1506     return <<EOS;
1507 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1508     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1509 <html lang="en" xml:lang="en" xmlns="http://www.w3.org/1999/xhtml">
1510 <head>
1511 <title>$title</title>
1512 <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1513 $css
1514 </head>
1515 <body>
1516 $content
1517 </body>
1518 </html>
1519 EOS
1520 }
1521
1522 sub _is_duplicate {
1523     my ( $message ) = @_;
1524     my $dbh = C4::Context->dbh;
1525     my $count = $dbh->selectrow_array(q|
1526         SELECT COUNT(*)
1527         FROM message_queue
1528         WHERE message_transport_type = ?
1529         AND borrowernumber = ?
1530         AND letter_code = ?
1531         AND CAST(updated_on AS date) = CAST(NOW() AS date)
1532         AND status="sent"
1533         AND content = ?
1534     |, {}, $message->{message_transport_type}, $message->{borrowernumber}, $message->{letter_code}, $message->{content} );
1535     return $count;
1536 }
1537
1538 sub _send_message_by_sms {
1539     my $message = shift or return;
1540     my $patron = Koha::Patrons->find( $message->{borrowernumber} );
1541     _update_message_to_address($message->{message_id}, $patron->smsalertnumber) if $patron;
1542
1543     unless ( $patron and $patron->smsalertnumber ) {
1544         _set_message_status( { message_id => $message->{'message_id'},
1545                                status     => 'failed',
1546                                failure_code => 'MISSING_SMS' } );
1547         return;
1548     }
1549
1550     if ( _is_duplicate( $message ) ) {
1551         _set_message_status(
1552             {
1553                 message_id   => $message->{'message_id'},
1554                 status       => 'failed',
1555                 failure_code => 'DUPLICATE_MESSAGE'
1556             }
1557         );
1558         return;
1559     }
1560
1561     my $success = C4::SMS->send_sms(
1562         {
1563             destination => $patron->smsalertnumber,
1564             message     => $message->{'content'},
1565         }
1566     );
1567
1568     if ($success) {
1569         _set_message_status(
1570             {
1571                 message_id   => $message->{'message_id'},
1572                 status       => 'sent',
1573                 failure_code => ''
1574             }
1575         );
1576     }
1577     else {
1578         _set_message_status(
1579             {
1580                 message_id   => $message->{'message_id'},
1581                 status       => 'failed',
1582                 failure_code => 'NO_NOTES'
1583             }
1584         );
1585     }
1586
1587     return $success;
1588 }
1589
1590 sub _update_message_to_address {
1591     my ($id, $to)= @_;
1592     my $dbh = C4::Context->dbh();
1593     $dbh->do('UPDATE message_queue SET to_address=? WHERE message_id=?',undef,($to,$id));
1594 }
1595
1596 sub _update_message_from_address {
1597     my ($message_id, $from_address) = @_;
1598     my $dbh = C4::Context->dbh();
1599     $dbh->do('UPDATE message_queue SET from_address = ? WHERE message_id = ?', undef, ($from_address, $message_id));
1600 }
1601
1602 sub _set_message_status {
1603     my $params = shift or return;
1604
1605     foreach my $required_parameter ( qw( message_id status ) ) {
1606         return unless exists $params->{ $required_parameter };
1607     }
1608
1609     my $dbh = C4::Context->dbh();
1610     my $statement = 'UPDATE message_queue SET status= ?, failure_code= ? WHERE message_id = ?';
1611     my $sth = $dbh->prepare( $statement );
1612     my $result = $sth->execute( $params->{'status'},
1613                                 $params->{'failure_code'} || '',
1614                                 $params->{'message_id'} );
1615     return $result;
1616 }
1617
1618 sub _process_tt {
1619     my ( $params ) = @_;
1620
1621     my $content    = $params->{content};
1622     my $tables     = $params->{tables};
1623     my $loops      = $params->{loops};
1624     my $objects    = $params->{objects} || {};
1625     my $substitute = $params->{substitute} || {};
1626     my $lang = defined($params->{lang}) && $params->{lang} ne 'default' ? $params->{lang} : 'en';
1627     my ($theme, $availablethemes);
1628
1629     my $htdocs = C4::Context->config('intrahtdocs');
1630     ($theme, $lang, $availablethemes)= C4::Templates::availablethemes( $htdocs, 'about.tt', 'intranet', $lang);
1631     my @includes;
1632     foreach (@$availablethemes) {
1633         push @includes, "$htdocs/$_/$lang/includes";
1634         push @includes, "$htdocs/$_/en/includes" unless $lang eq 'en';
1635     }
1636
1637     my $use_template_cache = C4::Context->config('template_cache_dir') && defined $ENV{GATEWAY_INTERFACE};
1638     my $template           = Template->new(
1639         {
1640             EVAL_PERL    => 1,
1641             ABSOLUTE     => 1,
1642             PLUGIN_BASE  => 'Koha::Template::Plugin',
1643             COMPILE_EXT  => $use_template_cache ? '.ttc' : '',
1644             COMPILE_DIR  => $use_template_cache ? C4::Context->config('template_cache_dir') : '',
1645             INCLUDE_PATH => \@includes,
1646             FILTERS      => {},
1647             ENCODING     => 'UTF-8',
1648         }
1649     ) or die Template->error();
1650
1651     my $tt_params = { %{ _get_tt_params( $tables ) }, %{ _get_tt_params( $loops, 'is_a_loop' ) }, %$substitute, %$objects };
1652
1653     $content = add_tt_filters( $content );
1654     $content = qq|[% USE KohaDates %][% USE Remove_MARC_punctuation %]$content|;
1655
1656     my $output;
1657     my $schema = Koha::Database->new->schema;
1658     $schema->txn_begin;
1659     my $processed = try {
1660         $template->process( \$content, $tt_params, \$output );
1661     }
1662     finally {
1663         $schema->txn_rollback;
1664     };
1665     croak "ERROR PROCESSING TEMPLATE: " . $template->error() unless $processed;
1666
1667     return $output;
1668 }
1669
1670 sub _get_tt_params {
1671     my ($tables, $is_a_loop) = @_;
1672
1673     my $params;
1674     $is_a_loop ||= 0;
1675
1676     my $config = {
1677         article_requests => {
1678             module   => 'Koha::ArticleRequests',
1679             singular => 'article_request',
1680             plural   => 'article_requests',
1681             pk       => 'id',
1682         },
1683         aqbasket => {
1684             module   => 'Koha::Acquisition::Baskets',
1685             singular => 'basket',
1686             plural   => 'baskets',
1687             pk       => 'basketno',
1688         },
1689         aqbooksellers => {
1690             module   => 'Koha::Acquisition::Booksellers',
1691             singular => 'bookseller',
1692             plural   => 'booksellers',
1693             pk       => 'id',
1694         },
1695         biblio => {
1696             module   => 'Koha::Biblios',
1697             singular => 'biblio',
1698             plural   => 'biblios',
1699             pk       => 'biblionumber',
1700         },
1701         biblioitems => {
1702             module   => 'Koha::Biblioitems',
1703             singular => 'biblioitem',
1704             plural   => 'biblioitems',
1705             pk       => 'biblioitemnumber',
1706         },
1707         borrowers => {
1708             module   => 'Koha::Patrons',
1709             singular => 'borrower',
1710             plural   => 'borrowers',
1711             pk       => 'borrowernumber',
1712         },
1713         branches => {
1714             module   => 'Koha::Libraries',
1715             singular => 'branch',
1716             plural   => 'branches',
1717             pk       => 'branchcode',
1718         },
1719         credits => {
1720             module => 'Koha::Account::Lines',
1721             singular => 'credit',
1722             plural => 'credits',
1723             pk => 'accountlines_id',
1724         },
1725         debits => {
1726             module => 'Koha::Account::Lines',
1727             singular => 'debit',
1728             plural => 'debits',
1729             pk => 'accountlines_id',
1730         },
1731         items => {
1732             module   => 'Koha::Items',
1733             singular => 'item',
1734             plural   => 'items',
1735             pk       => 'itemnumber',
1736         },
1737         additional_contents => {
1738             module   => 'Koha::AdditionalContents',
1739             singular => 'additional_content',
1740             plural   => 'additional_contents',
1741             pk       => 'idnew',
1742         },
1743         opac_news => {
1744             module   => 'Koha::AdditionalContents',
1745             singular => 'news',
1746             plural   => 'news',
1747             pk       => 'idnew',
1748         },
1749         aqorders => {
1750             module   => 'Koha::Acquisition::Orders',
1751             singular => 'order',
1752             plural   => 'orders',
1753             pk       => 'ordernumber',
1754         },
1755         reserves => {
1756             module   => 'Koha::Holds',
1757             singular => 'hold',
1758             plural   => 'holds',
1759             pk       => 'reserve_id',
1760         },
1761         serial => {
1762             module   => 'Koha::Serials',
1763             singular => 'serial',
1764             plural   => 'serials',
1765             pk       => 'serialid',
1766         },
1767         subscription => {
1768             module   => 'Koha::Subscriptions',
1769             singular => 'subscription',
1770             plural   => 'subscriptions',
1771             pk       => 'subscriptionid',
1772         },
1773         suggestions => {
1774             module   => 'Koha::Suggestions',
1775             singular => 'suggestion',
1776             plural   => 'suggestions',
1777             pk       => 'suggestionid',
1778         },
1779         tickets => {
1780             module   => 'Koha::Tickets',
1781             singular => 'ticket',
1782             plural   => 'tickets',
1783             pk       => 'id',
1784         },
1785         ticket_updates => {
1786             module   => 'Koha::Ticket::Updates',
1787             singular => 'ticket_update',
1788             plural   => 'ticket_updates',
1789             pk       => 'id',
1790         },
1791         issues => {
1792             module   => 'Koha::Checkouts',
1793             singular => 'checkout',
1794             plural   => 'checkouts',
1795             fk       => 'itemnumber',
1796         },
1797         old_issues => {
1798             module   => 'Koha::Old::Checkouts',
1799             singular => 'old_checkout',
1800             plural   => 'old_checkouts',
1801             pk       => 'issue_id',
1802         },
1803         overdues => {
1804             module   => 'Koha::Checkouts',
1805             singular => 'overdue',
1806             plural   => 'overdues',
1807             fk       => 'itemnumber',
1808         },
1809         borrower_modifications => {
1810             module   => 'Koha::Patron::Modifications',
1811             singular => 'patron_modification',
1812             plural   => 'patron_modifications',
1813             fk       => 'verification_token',
1814         },
1815         illrequests => {
1816             module   => 'Koha::Illrequests',
1817             singular => 'illrequest',
1818             plural   => 'illrequests',
1819             pk       => 'illrequest_id'
1820         }
1821     };
1822
1823     foreach my $table ( keys %$tables ) {
1824         next unless $config->{$table};
1825
1826         my $ref = ref( $tables->{$table} ) || q{};
1827         my $module = $config->{$table}->{module};
1828
1829         if ( can_load( modules => { $module => undef } ) ) {
1830             my $pk = $config->{$table}->{pk};
1831             my $fk = $config->{$table}->{fk};
1832
1833             if ( $is_a_loop ) {
1834                 my $values = $tables->{$table} || [];
1835                 unless ( ref( $values ) eq 'ARRAY' ) {
1836                     croak "ERROR processing table $table. Wrong API call.";
1837                 }
1838                 my $key = $pk ? $pk : $fk;
1839                 # $key does not come from user input
1840                 my $objects = $module->search(
1841                     { $key => $values },
1842                     {
1843                             # We want to retrieve the data in the same order
1844                             # FIXME MySQLism
1845                             # field is a MySQLism, but they are no other way to do it
1846                             # To be generic we could do it in perl, but we will need to fetch
1847                             # all the data then order them
1848                         @$values ? ( order_by => \[ "field($key, " . join( ', ', @$values ) . ")" ] ) : ()
1849                     }
1850                 );
1851                 $params->{ $config->{$table}->{plural} } = $objects;
1852             }
1853             elsif ( $ref eq q{} || $ref eq 'HASH' ) {
1854                 my $id = ref $ref eq 'HASH' ? $tables->{$table}->{$pk} : $tables->{$table};
1855                 my $object;
1856                 if ( $fk ) { # Using a foreign key for lookup
1857                     if ( ref( $fk ) eq 'ARRAY' ) { # Foreign key is multi-column
1858                         my $search;
1859                         foreach my $key ( @$fk ) {
1860                             $search->{$key} = $id->{$key};
1861                         }
1862                         $object = $module->search( $search )->last();
1863                     } else { # Foreign key is single column
1864                         $object = $module->search( { $fk => $id } )->last();
1865                     }
1866                 } else { # using the table's primary key for lookup
1867                     $object = $module->find($id);
1868                 }
1869                 $params->{ $config->{$table}->{singular} } = $object;
1870             }
1871             else {    # $ref eq 'ARRAY'
1872                 my $object;
1873                 if ( @{ $tables->{$table} } == 1 ) {    # Param is a single key
1874                     $object = $module->search( { $pk => $tables->{$table} } )->last();
1875                 }
1876                 else {                                  # Params are mutliple foreign keys
1877                     croak "Multiple foreign keys (table $table) should be passed using an hashref";
1878                 }
1879                 $params->{ $config->{$table}->{singular} } = $object;
1880             }
1881         }
1882         else {
1883             croak "ERROR LOADING MODULE $module: $Module::Load::Conditional::ERROR";
1884         }
1885     }
1886
1887     $params->{today} = output_pref({ dt => dt_from_string, dateformat => 'iso' });
1888
1889     return $params;
1890 }
1891
1892 =head3 add_tt_filters
1893
1894 $content = add_tt_filters( $content );
1895
1896 Add TT filters to some specific fields if needed.
1897
1898 For now we only add the Remove_MARC_punctuation TT filter to biblio and biblioitem fields
1899
1900 =cut
1901
1902 sub add_tt_filters {
1903     my ( $content ) = @_;
1904     $content =~ s|\[%\s*biblio\.(.*?)\s*%\]|[% biblio.$1 \| \$Remove_MARC_punctuation %]|gxms;
1905     $content =~ s|\[%\s*biblioitem\.(.*?)\s*%\]|[% biblioitem.$1 \| \$Remove_MARC_punctuation %]|gxms;
1906     return $content;
1907 }
1908
1909 =head2 get_item_content
1910
1911     my $item = Koha::Items->find(...)->unblessed;
1912     my @item_content_fields = qw( date_due title barcode author itemnumber );
1913     my $item_content = C4::Letters::get_item_content({
1914                              item => $item,
1915                              item_content_fields => \@item_content_fields
1916                        });
1917
1918 This function generates a tab-separated list of values for the passed item. Dates
1919 are formatted following the current setup.
1920
1921 =cut
1922
1923 sub get_item_content {
1924     my ( $params ) = @_;
1925     my $item = $params->{item};
1926     my $dateonly = $params->{dateonly} || 0;
1927     my $item_content_fields = $params->{item_content_fields} || [];
1928
1929     return unless $item;
1930
1931     my @item_info = map {
1932         $_ =~ /^date|date$/
1933           ? eval {
1934             output_pref(
1935                 { dt => dt_from_string( $item->{$_} ), dateonly => $dateonly } );
1936           }
1937           : $item->{$_}
1938           || ''
1939     } @$item_content_fields;
1940     return join( "\t", @item_info ) . "\n";
1941 }
1942
1943 1;
1944 __END__