Koha/BackgroundJob/BatchUpdateBiblioHoldsQueue.pm

   1 package Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use JSON qw( encode_json decode_json );
  21 use Try::Tiny;
  22
  23 use Koha::Biblios;
  24 use Koha::Exceptions;
  25
  26 use C4::HoldsQueue
  27   qw(load_branches_to_pull_from TransportCostMatrix update_queue_for_biblio);
  28
  29 use base 'Koha::BackgroundJob';
  30
  31 =head1 NAME
  32
  33 Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue - Update the holds queue
  34 for a specified list of biblios.
  35
  36 This is a subclass of Koha::BackgroundJob.
  37
  38 =head1 API
  39
  40 =head2 Class methods
  41
  42 =head3 job_type
  43
  44 Returns a string representing the job type. In this case I<update_holds_queue_for_biblios>.
  45
  46 =cut
  47
  48 sub job_type {
  49     return 'update_holds_queue_for_biblios';
  50 }
  51
  52 =head3 process
  53
  54 Perform the expected action.
  55
  56 =cut
  57
  58 sub process {
  59     my ( $self, $args ) = @_;
  60
  61     my $schema = Koha::Database->new->schema;
  62
  63     $self->set(
  64         {
  65             started_on => \'NOW()',
  66             progress   => 0,
  67             status     => 'started',
  68         }
  69     )->store;
  70
  71     my @biblio_ids = @{ $args->{biblio_ids} };
  72
  73     my $report = {
  74         total_biblios => scalar @biblio_ids,
  75         total_success => 0,
  76     };
  77
  78     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
  79     my $transport_cost_matrix = $use_transport_cost_matrix ? TransportCostMatrix() : undef;
  80     my $branches_to_use = load_branches_to_pull_from($use_transport_cost_matrix);
  81
  82     my @messages;
  83
  84     foreach my $biblio_id (@biblio_ids) {
  85         try {
  86
  87             $schema->storage->txn_begin;
  88
  89             my $result = update_queue_for_biblio(
  90                 {
  91                     biblio_id             => $biblio_id,
  92                     branches_to_use       => $branches_to_use,
  93                     delete                => 1,
  94                     transport_cost_matrix => $transport_cost_matrix
  95                 }
  96             );
  97             push @messages,
  98               {
  99                 type           => 'success',
 100                 code           => 'holds_queue_updated',
 101                 biblio_id      => $biblio_id,
 102               };
 103             $report->{total_success}++;
 104
 105             $schema->storage->txn_commit;
 106         }
 107         catch {
 108
 109             push @messages,
 110               {
 111                 type      => 'error',
 112                 code      => 'holds_queue_update_error',
 113                 biblio_id => $biblio_id,
 114                 error     => "$_",
 115               };
 116
 117             $schema->storage->txn_rollback;
 118         };
 119
 120         $self->progress( $self->progress + 1 )->store;
 121     }
 122
 123     my $job_data = decode_json $self->data;
 124     $job_data->{messages} = \@messages;
 125     $job_data->{report}   = $report;
 126
 127     $self->set(
 128         {
 129             ended_on => \'NOW()',
 130             data     => encode_json $job_data,
 131             status   => 'finished',
 132         }
 133     )->store;
 134 }
 135
 136 =head3 enqueue
 137
 138 Enqueue the new job
 139
 140 =cut
 141
 142 sub enqueue {
 143     my ( $self, $args ) = @_;
 144
 145     Koha::Exceptions::MissingParameter->throw(
 146         "Missing biblio_ids parameter is mandatory")
 147       unless exists $args->{biblio_ids};
 148
 149     my @biblio_ids = @{ $args->{biblio_ids} };
 150
 151     $self->SUPER::enqueue(
 152         {
 153             job_size => scalar @biblio_ids,
 154             job_args => { biblio_ids => \@biblio_ids }
 155         }
 156     );
 157 }
 158
 159 =head3 additional_report
 160
 161 Pass the biblio's title and patron's name
 162
 163 =cut
 164
 165 sub additional_report {
 166     my ( $self, $args ) = @_;
 167
 168     my $messages = $self->messages;
 169     for my $m (@$messages) {
 170         $m->{biblio} = Koha::Biblios->find( $m->{biblio_id} );
 171     }
 172     return { report_messages => $messages };
 173 }
 174
 175 1;