Koha/Checkouts.pm

   1 package Koha::Checkouts;
   2
   3 # Copyright ByWater Solutions 2015
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use C4::Context;
  24 use C4::Circulation qw( AddReturn );
  25 use Koha::Checkout;
  26 use Koha::Database;
  27 use Koha::DateUtils qw( dt_from_string );
  28
  29 use base qw(Koha::Objects);
  30
  31
  32 =head1 NAME
  33
  34 Koha::Checkouts - Koha Checkout object set class
  35
  36 =head1 API
  37
  38 =head2 Class Methods
  39
  40 =cut
  41
  42 =head3 calculate_dropbox_date
  43
  44 my $dt = Koha::Checkouts::calculate_dropbox_date();
  45
  46 =cut
  47
  48 sub calculate_dropbox_date {
  49     my $userenv    = C4::Context->userenv;
  50     my $branchcode = $userenv->{branch} // q{};
  51
  52     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
  53         {
  54             categorycode => undef,
  55             itemtype     => undef,
  56             branchcode   => $branchcode,
  57         }
  58     );
  59     my $calendar     = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
  60     my $today        = dt_from_string;
  61     my $dropbox_date = $calendar->addDuration( $today, -1 );
  62
  63     return $dropbox_date;
  64 }
  65
  66 =head3 automatic_checkin
  67
  68 my $automatic_checkins = Koha::Checkouts->automatic_checkin()
  69
  70 Checks in every due issue which itemtype has automatic_checkin enabled. Also if the AutoCheckinAutoFill sys. pref. is enabled, the item is trapped for the next patron.
  71
  72 =cut
  73
  74 sub automatic_checkin {
  75     my ($self, $params) = @_;
  76
  77     my $current_date = dt_from_string;
  78
  79     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
  80     my $due_checkouts = $self->search(
  81         { date_due => { '<=' => $dtf->format_datetime($current_date) } },
  82         { prefetch => 'item'}
  83     );
  84
  85     my $autofill_next = C4::Context->preference('AutomaticCheckinAutoFill');
  86
  87     while ( my $checkout = $due_checkouts->next ) {
  88         if ( $checkout->item->itemtype->automatic_checkin ) {
  89             my ( undef, $messages) = C4::Circulation::AddReturn($checkout->item->barcode, $checkout->branchcode, undef, dt_from_string($checkout->date_due) );
  90             if ( $autofill_next ){
  91                 if ( $messages->{ResFound} ){
  92                     my $is_transfer = $checkout->branchcode ne $messages->{ResFound}->{branchcode};
  93                     C4::Reserves::ModReserveAffect($checkout->item->itemnumber, $checkout->borrowernumber, $is_transfer, $messages->{ResFound}->{reserve_id}, $checkout->{desk_id}, 0);
  94                     if( $is_transfer ){
  95                         C4::Items::ModItemTransfer($checkout->item->itemnumber,$checkout->branchcode, $messages->{ResFound}->{branchcode},"Reserve");
  96                     }
  97                 }
  98             }
  99         }
 100     }
 101 }
 102
 103 =head3 type
 104
 105 =cut
 106
 107 sub _type {
 108     return 'Issue';
 109 }
 110
 111 =head3 object_class
 112
 113 =cut
 114
 115 sub object_class {
 116     return 'Koha::Checkout';
 117 }
 118
 119 =head1 AUTHOR
 120
 121 Kyle M Hall <kyle@bywatersolutions.com>
 122
 123 =cut
 124
 125 1;