Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use vars qw(@ISA @EXPORT_OK);
  25 BEGIN {
  26     require Exporter;
  27     @ISA = qw(Exporter);
  28
  29     @EXPORT_OK = qw(
  30         dt_from_string
  31         output_pref
  32         format_sqldatetime
  33     );
  34 }
  35
  36 =head1 DateUtils
  37
  38 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  39
  40 =head1 DESCRIPTION
  41
  42 Koha has historically only used dates not datetimes and been content to
  43 handle these as strings. It also has confused formatting with actual dates
  44 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  45
  46 =cut
  47
  48 =head2 dt_ftom_string
  49
  50 $dt = dt_from_string($date_string, [$format, $timezone ]);
  51
  52 Passed a date string returns a DateTime object format and timezone default
  53 to the system preferences. If the date string is empty DateTime->now is returned
  54
  55 =cut
  56
  57 sub dt_from_string {
  58     my ( $date_string, $date_format, $tz ) = @_;
  59
  60     return if $date_string and $date_string =~ m|^0000-0|;
  61
  62     my $do_fallback = defined($date_format) ? 0 : 1;
  63     my $server_tz = C4::Context->tz;
  64     $tz = C4::Context->tz unless $tz;
  65
  66     return DateTime->now( time_zone => $tz ) unless $date_string;
  67
  68     $date_format = C4::Context->preference('dateformat') unless $date_format;
  69
  70     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  71         return $date_string;
  72     }
  73
  74     my $regex;
  75
  76     # The fallback format is sql/iso
  77     my $fallback_re = qr|
  78         (?<year>\d{4})
  79         -
  80         (?<month>\d{2})
  81         -
  82         (?<day>\d{2})
  83     |xms;
  84
  85     if ( $date_format eq 'metric' ) {
  86         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  87         $regex = qr|
  88             (?<day>\d{2})
  89             /
  90             (?<month>\d{2})
  91             /
  92             (?<year>\d{4})
  93         |xms;
  94     }
  95     elsif ( $date_format eq 'dmydot' ) {
  96         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  97         $regex = qr|
  98             (?<day>\d{2})
  99             .
 100             (?<month>\d{2})
 101             .
 102             (?<year>\d{4})
 103         |xms;
 104     }
 105     elsif ( $date_format eq 'us' ) {
 106         # us format is "mm/dd/yyyy[ hh:mm:ss]"
 107         $regex = qr|
 108             (?<month>\d{2})
 109             /
 110             (?<day>\d{2})
 111             /
 112             (?<year>\d{4})
 113         |xms;
 114     }
 115     elsif ( $date_format eq 'rfc3339' ) {
 116         $regex = qr/
 117             (?<year>\d{4})
 118             -
 119             (?<month>\d{2})
 120             -
 121             (?<day>\d{2})
 122             ([Tt\s])
 123             (?<hour>\d{2})
 124             :
 125             (?<minute>\d{2})
 126             :
 127             (?<second>\d{2})
 128             (\.\d{1,3})?(([Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):(?<minutes>[0-5][0-9])))
 129         /xms;
 130
 131         # Default to UTC (when 'Z' is passed) for inbound timezone.
 132         $tz = DateTime::TimeZone->new( name => 'UTC' );
 133     }
 134     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 135         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 136         $regex = $fallback_re;
 137     }
 138     else {
 139         die "Invalid dateformat parameter ($date_format)";
 140     }
 141
 142     # Add the faculative time part [hh:mm[:ss]]
 143     my $time_re .= qr|
 144             (
 145                 \s*
 146                 (?<hour>\d{2})
 147                 :
 148                 (?<minute>\d{2})
 149                 (
 150                     :
 151                     (?<second>\d{2})
 152                 )?
 153                 (
 154                     \s
 155                     (?<ampm>\w{2})
 156                 )?
 157             )?
 158     |xms;
 159     $regex .= $time_re unless ( $date_format eq 'rfc3339' );
 160     $fallback_re .= $time_re;
 161
 162     my %dt_params;
 163     my $ampm;
 164     if ( $date_string =~ $regex ) {
 165         %dt_params = (
 166             year   => $+{year},
 167             month  => $+{month},
 168             day    => $+{day},
 169             hour   => $+{hour},
 170             minute => $+{minute},
 171             second => $+{second},
 172         );
 173         $ampm = $+{ampm};
 174         if ( $+{offset} ) {
 175             # If offset given, set inbound timezone using it.
 176             $tz = DateTime::TimeZone->new( name => $+{offset} . $+{hours} . $+{minutes} );
 177         }
 178     } elsif ( $do_fallback && $date_string =~ $fallback_re ) {
 179         %dt_params = (
 180             year   => $+{year},
 181             month  => $+{month},
 182             day    => $+{day},
 183             hour   => $+{hour},
 184             minute => $+{minute},
 185             second => $+{second},
 186         );
 187         $ampm = $+{ampm};
 188     }
 189     else {
 190         die "The given date ($date_string) does not match the date format ($date_format)";
 191     }
 192
 193     # system allows the 0th of the month
 194     $dt_params{day} = '01' if $dt_params{day} eq '00';
 195
 196     # Set default hh:mm:ss to 00:00:00
 197     my $date_only = ( !defined( $dt_params{hour} )
 198         && !defined( $dt_params{minute} )
 199         && !defined( $dt_params{second} ) );
 200     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 201     $dt_params{minute} = 00 unless defined $dt_params{minute};
 202     $dt_params{second} = 00 unless defined $dt_params{second};
 203
 204     if ( $ampm ) {
 205         if ( $ampm eq 'AM' ) {
 206             $dt_params{hour} = 00 if $dt_params{hour} == 12;
 207         } elsif ( $dt_params{hour} != 12 ) { # PM
 208             $dt_params{hour} += 12;
 209             $dt_params{hour} = 00 if $dt_params{hour} == 24;
 210         }
 211     }
 212
 213     my $floating = 0;
 214     my $dt = eval {
 215         DateTime->new(
 216             %dt_params,
 217             # No TZ for dates 'infinite' => see bug 13242
 218             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 219         );
 220     };
 221     if ($@) {
 222         $tz = DateTime::TimeZone->new( name => 'floating' );
 223         $floating = 1;
 224         $dt = DateTime->new(
 225             %dt_params,
 226             # No TZ for dates 'infinite' => see bug 13242
 227             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 228         );
 229     }
 230
 231     # Convert to configured timezone (unless we started with a dateonly string or had to drop to floating time)
 232     $dt->set_time_zone($server_tz) unless ( $date_only || $floating );
 233
 234     return $dt;
 235 }
 236
 237 =head2 output_pref
 238
 239 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 240 $date_string = output_pref( $dt );
 241
 242 Returns a string containing the time & date formatted as per the C4::Context setting,
 243 or C<undef> if C<undef> was provided.
 244
 245 This routine can either be passed a DateTime object or or a hashref.  If it is
 246 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 247 an optional 'dateformat' to override the dateformat system preference, an
 248 optional 'timeformat' to override the TimeFormat system preference value,
 249 and an optional 'dateonly' to specify that only the formatted date string
 250 should be returned without the time.
 251
 252 =cut
 253
 254 sub output_pref {
 255     my $params = shift;
 256     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 257     if ( ref $params eq 'HASH' ) {
 258         $dt         = $params->{dt};
 259         $str        = $params->{str};
 260         $force_pref = $params->{dateformat};         # if testing we want to override Context
 261         $force_time = $params->{timeformat};
 262         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 263         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 264     } else {
 265         $dt = $params;
 266     }
 267
 268     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 269
 270     if ( $str ) {
 271         local $@;
 272         $dt = eval { dt_from_string( $str ) };
 273         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 274     }
 275
 276     return if !defined $dt; # NULL date
 277     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 278
 279     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 280     if ( $dt->ymd !~ /^9999/ ) {
 281         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 282         $dt->set_time_zone( $tz );
 283     }
 284
 285     my $pref =
 286       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 287
 288     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 289     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 290     my $date;
 291     if ( $pref =~ m/^iso/ ) {
 292         $date = $dateonly
 293           ? $dt->strftime("%Y-%m-%d")
 294           : $dt->strftime("%Y-%m-%d $time");
 295     }
 296     elsif ( $pref =~ m/^rfc3339/ ) {
 297         if (!$dateonly) {
 298             $date = $dt->strftime('%FT%T%z');
 299             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 300         }
 301         else {
 302             $date = $dt->strftime("%Y-%m-%d");
 303         }
 304     }
 305     elsif ( $pref =~ m/^metric/ ) {
 306         $date = $dateonly
 307           ? $dt->strftime("%d/%m/%Y")
 308           : $dt->strftime("%d/%m/%Y $time");
 309     }
 310     elsif ( $pref =~ m/^dmydot/ ) {
 311         $date = $dateonly
 312           ? $dt->strftime("%d.%m.%Y")
 313           : $dt->strftime("%d.%m.%Y $time");
 314     }
 315
 316     elsif ( $pref =~ m/^us/ ) {
 317         $date = $dateonly
 318           ? $dt->strftime("%m/%d/%Y")
 319           : $dt->strftime("%m/%d/%Y $time");
 320     }
 321     else {
 322         $date = $dateonly
 323           ? $dt->strftime("%Y-%m-%d")
 324           : $dt->strftime("%Y-%m-%d $time");
 325     }
 326
 327     if ( $as_due_date ) {
 328         $time_format eq '12hr'
 329             ? $date =~ s| 11:59 PM$||
 330             : $date =~ s| 23:59$||;
 331     }
 332
 333     return $date;
 334 }
 335
 336 =head2 format_sqldatetime
 337
 338 $string = format_sqldatetime( $string_as_returned_from_db );
 339
 340 a convenience routine for calling dt_from_string and formatting the result
 341 with output_pref as it is a frequent activity in scripts
 342
 343 =cut
 344
 345 sub format_sqldatetime {
 346     my $str        = shift;
 347     my $force_pref = shift;    # if testing we want to override Context
 348     my $force_time = shift;
 349     my $dateonly   = shift;
 350
 351     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 352         my $dt = dt_from_string( $str, 'sql' );
 353         return q{} unless $dt;
 354         $dt->truncate( to => 'minute' );
 355         return output_pref({
 356             dt => $dt,
 357             dateformat => $force_pref,
 358             timeformat => $force_time,
 359             dateonly => $dateonly
 360         });
 361     }
 362     return q{};
 363 }
 364
 365 1;