Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Context;
  29 use C4::Auth qw( checkpw_hash );
  30 use C4::Log qw( logaction );
  31 use Koha::Account;
  32 use Koha::ArticleRequests;
  33 use C4::Letters qw( GetPreparedLetter EnqueueLetter SendQueuedMessages );
  34 use Koha::AuthUtils;
  35 use Koha::Checkouts;
  36 use Koha::CirculationRules;
  37 use Koha::Club::Enrollments;
  38 use Koha::Database;
  39 use Koha::DateUtils qw( dt_from_string );
  40 use Koha::Encryption;
  41 use Koha::Exceptions::Password;
  42 use Koha::Holds;
  43 use Koha::CurbsidePickups;
  44 use Koha::Old::Checkouts;
  45 use Koha::Patron::Attributes;
  46 use Koha::Patron::Categories;
  47 use Koha::Patron::Debarments;
  48 use Koha::Patron::HouseboundProfile;
  49 use Koha::Patron::HouseboundRole;
  50 use Koha::Patron::Images;
  51 use Koha::Patron::Messages;
  52 use Koha::Patron::Modifications;
  53 use Koha::Patron::MessagePreferences;
  54 use Koha::Patron::Relationships;
  55 use Koha::Patron::Restrictions;
  56 use Koha::Patrons;
  57 use Koha::Plugins;
  58 use Koha::Recalls;
  59 use Koha::Result::Boolean;
  60 use Koha::Subscription::Routinglists;
  61 use Koha::Token;
  62 use Koha::Virtualshelves;
  63
  64 use base qw(Koha::Object);
  65
  66 use constant ADMINISTRATIVE_LOCKOUT => -1;
  67
  68 our $RESULTSET_PATRON_ID_MAPPING = {
  69     Accountline          => 'borrowernumber',
  70     Aqbasketuser         => 'borrowernumber',
  71     Aqbudget             => 'budget_owner_id',
  72     Aqbudgetborrower     => 'borrowernumber',
  73     ArticleRequest       => 'borrowernumber',
  74     BorrowerDebarment    => 'borrowernumber',
  75     BorrowerFile         => 'borrowernumber',
  76     BorrowerModification => 'borrowernumber',
  77     ClubEnrollment       => 'borrowernumber',
  78     Issue                => 'borrowernumber',
  79     ItemsLastBorrower    => 'borrowernumber',
  80     Linktracker          => 'borrowernumber',
  81     Message              => 'borrowernumber',
  82     MessageQueue         => 'borrowernumber',
  83     OldIssue             => 'borrowernumber',
  84     OldReserve           => 'borrowernumber',
  85     Rating               => 'borrowernumber',
  86     Reserve              => 'borrowernumber',
  87     Review               => 'borrowernumber',
  88     SearchHistory        => 'userid',
  89     Statistic            => 'borrowernumber',
  90     Suggestion           => 'suggestedby',
  91     TagAll               => 'borrowernumber',
  92     Virtualshelfcontent  => 'borrowernumber',
  93     Virtualshelfshare    => 'borrowernumber',
  94     Virtualshelve        => 'owner',
  95 };
  96
  97 =head1 NAME
  98
  99 Koha::Patron - Koha Patron Object class
 100
 101 =head1 API
 102
 103 =head2 Class Methods
 104
 105 =head3 new
 106
 107 =cut
 108
 109 sub new {
 110     my ( $class, $params ) = @_;
 111
 112     return $class->SUPER::new($params);
 113 }
 114
 115 =head3 fixup_cardnumber
 116
 117 Autogenerate next cardnumber from highest value found in database
 118
 119 =cut
 120
 121 sub fixup_cardnumber {
 122     my ( $self ) = @_;
 123
 124     my $max = $self->cardnumber;
 125     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 126
 127     $max ||= Koha::Patrons->search({
 128         cardnumber => {-regexp => '^-?[0-9]+$'}
 129     }, {
 130         select => \'CAST(cardnumber AS SIGNED)',
 131         as => ['cast_cardnumber']
 132     })->_resultset->get_column('cast_cardnumber')->max;
 133     $self->cardnumber(($max || 0) +1);
 134 }
 135
 136 =head3 trim_whitespace
 137
 138 trim whitespace from data which has some non-whitespace in it.
 139 Could be moved to Koha::Object if need to be reused
 140
 141 =cut
 142
 143 sub trim_whitespaces {
 144     my( $self ) = @_;
 145
 146     my $schema  = Koha::Database->new->schema;
 147     my @columns = $schema->source($self->_type)->columns;
 148
 149     for my $column( @columns ) {
 150         my $value = $self->$column;
 151         if ( defined $value ) {
 152             $value =~ s/^\s*|\s*$//g;
 153             $self->$column($value);
 154         }
 155     }
 156     return $self;
 157 }
 158
 159 =head3 plain_text_password
 160
 161 $patron->plain_text_password( $password );
 162
 163 stores a copy of the unencrypted password in the object
 164 for use in code before encrypting for db
 165
 166 =cut
 167
 168 sub plain_text_password {
 169     my ( $self, $password ) = @_;
 170     if ( $password ) {
 171         $self->{_plain_text_password} = $password;
 172         return $self;
 173     }
 174     return $self->{_plain_text_password}
 175         if $self->{_plain_text_password};
 176
 177     return;
 178 }
 179
 180 =head3 store
 181
 182 Patron specific store method to cleanup record
 183 and do other necessary things before saving
 184 to db
 185
 186 =cut
 187
 188 sub store {
 189     my ($self) = @_;
 190
 191     $self->_result->result_source->schema->txn_do(
 192         sub {
 193             if (
 194                 C4::Context->preference("autoMemberNum")
 195                 and ( not defined $self->cardnumber
 196                     or $self->cardnumber eq '' )
 197               )
 198             {
 199                 # Warning: The caller is responsible for locking the members table in write
 200                 # mode, to avoid database corruption.
 201                 # We are in a transaction but the table is not locked
 202                 $self->fixup_cardnumber;
 203             }
 204
 205             unless( $self->category->in_storage ) {
 206                 Koha::Exceptions::Object::FKConstraint->throw(
 207                     broken_fk => 'categorycode',
 208                     value     => $self->categorycode,
 209                 );
 210             }
 211
 212             $self->trim_whitespaces;
 213
 214             my $new_cardnumber = $self->cardnumber;
 215             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 216             $self->cardnumber( $new_cardnumber );
 217
 218             # Set surname to uppercase if uppercasesurname is true
 219             $self->surname( uc($self->surname) )
 220                 if C4::Context->preference("uppercasesurnames");
 221
 222             $self->relationship(undef) # We do not want to store an empty string in this field
 223               if defined $self->relationship
 224                      and $self->relationship eq "";
 225
 226             unless ( $self->in_storage ) {    #AddMember
 227
 228                 # Generate a valid userid/login if needed
 229                 $self->generate_userid unless $self->userid;
 230                 Koha::Exceptions::Patron::InvalidUserid->throw( userid => $self->userid )
 231                     unless $self->has_valid_userid;
 232
 233                 # Add expiration date if it isn't already there
 234                 unless ( $self->dateexpiry ) {
 235                     $self->dateexpiry( $self->category->get_expiry_date );
 236                 }
 237
 238                 # Add enrollment date if it isn't already there
 239                 unless ( $self->dateenrolled ) {
 240                     $self->dateenrolled(dt_from_string);
 241                 }
 242
 243                 # Set the privacy depending on the patron's category
 244                 my $default_privacy = $self->category->default_privacy || q{};
 245                 $default_privacy =
 246                     $default_privacy eq 'default' ? 1
 247                   : $default_privacy eq 'never'   ? 2
 248                   : $default_privacy eq 'forever' ? 0
 249                   :                                                   undef;
 250                 $self->privacy($default_privacy);
 251
 252                 # Call any check_password plugins if password is passed
 253                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 254                     my @plugins = Koha::Plugins->new()->GetPlugins({
 255                         method => 'check_password',
 256                     });
 257                     foreach my $plugin ( @plugins ) {
 258                         # This plugin hook will also be used by a plugin for the Norwegian national
 259                         # patron database. This is why we need to pass both the password and the
 260                         # borrowernumber to the plugin.
 261                         my $ret = $plugin->check_password(
 262                             {
 263                                 password       => $self->password,
 264                                 borrowernumber => $self->borrowernumber
 265                             }
 266                         );
 267                         if ( $ret->{'error'} == 1 ) {
 268                             Koha::Exceptions::Password::Plugin->throw();
 269                         }
 270                     }
 271                 }
 272
 273                 # Make a copy of the plain text password for later use
 274                 $self->plain_text_password( $self->password );
 275
 276                 $self->password_expiration_date( $self->password
 277                     ? $self->category->get_password_expiry_date || undef
 278                     : undef );
 279                 # Create a disabled account if no password provided
 280                 $self->password( $self->password
 281                     ? Koha::AuthUtils::hash_password( $self->password )
 282                     : '!' );
 283
 284                 $self->borrowernumber(undef);
 285
 286                 $self = $self->SUPER::store;
 287
 288                 $self->add_enrolment_fee_if_needed(0);
 289
 290                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 291                   if C4::Context->preference("BorrowersLog");
 292             }
 293             else {    #ModMember
 294
 295                 my $self_from_storage = $self->get_from_storage;
 296
 297                 # Do not accept invalid userid here
 298                 $self->generate_userid unless $self->userid;
 299                 Koha::Exceptions::Patron::InvalidUserid->throw( userid => $self->userid )
 300                       unless $self->has_valid_userid;
 301
 302                 # If a borrower has set their privacy to never we should immediately anonymize
 303                 # their checkouts
 304                 if( $self->privacy() == 2 && $self_from_storage->privacy() != 2 ){
 305                     try{
 306                         $self->old_checkouts->anonymize;
 307                     }
 308                     catch {
 309                         Koha::Exceptions::Patron::FailedAnonymizing->throw(
 310                             error => @_
 311                         );
 312                     };
 313                 }
 314
 315                 # Password must be updated using $self->set_password
 316                 $self->password($self_from_storage->password);
 317
 318                 if ( $self->category->categorycode ne
 319                     $self_from_storage->category->categorycode )
 320                 {
 321                     # Add enrolement fee on category change if required
 322                     $self->add_enrolment_fee_if_needed(1)
 323                       if C4::Context->preference('FeeOnChangePatronCategory');
 324
 325                     # Clean up guarantors on category change if required
 326                     $self->guarantor_relationships->delete
 327                       unless ( $self->category->can_be_guarantee );
 328
 329                 }
 330
 331                 # Actionlogs
 332                 if ( C4::Context->preference("BorrowersLog") ) {
 333                     my $info;
 334                     my $from_storage = $self_from_storage->unblessed;
 335                     my $from_object  = $self->unblessed;
 336                     my @skip_fields  = (qw/lastseen updated_on/);
 337                     for my $key ( keys %{$from_storage} ) {
 338                         next if any { /$key/ } @skip_fields;
 339                         if (
 340                             (
 341                                   !defined( $from_storage->{$key} )
 342                                 && defined( $from_object->{$key} )
 343                             )
 344                             || ( defined( $from_storage->{$key} )
 345                                 && !defined( $from_object->{$key} ) )
 346                             || (
 347                                    defined( $from_storage->{$key} )
 348                                 && defined( $from_object->{$key} )
 349                                 && ( $from_storage->{$key} ne
 350                                     $from_object->{$key} )
 351                             )
 352                           )
 353                         {
 354                             $info->{$key} = {
 355                                 before => $from_storage->{$key},
 356                                 after  => $from_object->{$key}
 357                             };
 358                         }
 359                     }
 360
 361                     if ( defined($info) ) {
 362                         logaction(
 363                             "MEMBERS",
 364                             "MODIFY",
 365                             $self->borrowernumber,
 366                             to_json(
 367                                 $info,
 368                                 { utf8 => 1, pretty => 1, canonical => 1 }
 369                             )
 370                         );
 371                     }
 372                 }
 373
 374                 # Final store
 375                 $self = $self->SUPER::store;
 376             }
 377         }
 378     );
 379     return $self;
 380 }
 381
 382 =head3 delete
 383
 384 $patron->delete
 385
 386 Delete patron's holds, lists and finally the patron.
 387
 388 Lists owned by the borrower are deleted or ownership is transferred depending on the
 389 ListOwnershipUponPatronDeletion pref, but entries from the borrower to other lists are kept.
 390
 391 =cut
 392
 393 sub delete {
 394     my ($self) = @_;
 395
 396     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 397     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 398
 399     $self->_result->result_source->schema->txn_do(
 400         sub {
 401             # Cancel Patron's holds
 402             my $holds = $self->holds;
 403             while( my $hold = $holds->next ){
 404                 $hold->cancel;
 405             }
 406
 407             # Handle lists (virtualshelves)
 408             $self->virtualshelves->disown_or_delete;
 409
 410             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 411             # for patron selfreg
 412             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 413
 414             $self->SUPER::delete;
 415
 416             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 417         }
 418     );
 419     return $self;
 420 }
 421
 422 =head3 category
 423
 424 my $patron_category = $patron->category
 425
 426 Return the patron category for this patron
 427
 428 =cut
 429
 430 sub category {
 431     my ( $self ) = @_;
 432     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 433 }
 434
 435 =head3 image
 436
 437 =cut
 438
 439 sub image {
 440     my ( $self ) = @_;
 441
 442     return Koha::Patron::Images->find( $self->borrowernumber );
 443 }
 444
 445 =head3 library
 446
 447 Returns a Koha::Library object representing the patron's home library.
 448
 449 =cut
 450
 451 sub library {
 452     my ( $self ) = @_;
 453     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 454 }
 455
 456 =head3 sms_provider
 457
 458 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 459
 460 =cut
 461
 462 sub sms_provider {
 463     my ( $self ) = @_;
 464     my $sms_provider_rs = $self->_result->sms_provider;
 465     return unless $sms_provider_rs;
 466     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 467 }
 468
 469 =head3 guarantor_relationships
 470
 471 Returns Koha::Patron::Relationships object for this patron's guarantors
 472
 473 Returns the set of relationships for the patrons that are guarantors for this patron.
 474
 475 Note that a guarantor should exist as a patron in Koha; it was not possible
 476 to add them without a guarantor_id in the interface for some time. Bug 30472
 477 restricts it on db level.
 478
 479 =cut
 480
 481 sub guarantor_relationships {
 482     my ($self) = @_;
 483
 484     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 485 }
 486
 487 =head3 guarantee_relationships
 488
 489 Returns Koha::Patron::Relationships object for this patron's guarantors
 490
 491 Returns the set of relationships for the patrons that are guarantees for this patron.
 492
 493 The method returns Koha::Patron::Relationship objects for the sake
 494 of consistency with the guantors method.
 495 A guarantee by definition must exist as a patron in Koha.
 496
 497 =cut
 498
 499 sub guarantee_relationships {
 500     my ($self) = @_;
 501
 502     return Koha::Patron::Relationships->search(
 503         { guarantor_id => $self->id },
 504         {
 505             prefetch => 'guarantee',
 506             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 507         }
 508     );
 509 }
 510
 511 =head3 relationships_debt
 512
 513 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 514
 515 =cut
 516
 517 sub relationships_debt {
 518     my ($self, $params) = @_;
 519
 520     my $include_guarantors  = $params->{include_guarantors};
 521     my $only_this_guarantor = $params->{only_this_guarantor};
 522     my $include_this_patron = $params->{include_this_patron};
 523
 524     my @guarantors;
 525     if ( $only_this_guarantor ) {
 526         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 527         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 528     } elsif ( $self->guarantor_relationships->count ) {
 529         # I am a guarantee, just get all my guarantors
 530         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 531     } else {
 532         # I am a guarantor, I need to get all the guarantors of all my guarantees
 533         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 534     }
 535
 536     my $non_issues_charges = 0;
 537     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 538     foreach my $guarantor (@guarantors) {
 539         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 540
 541         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 542         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 543         my $guarantees_non_issues_charges = 0;
 544         foreach my $guarantee (@guarantees) {
 545             next if $seen->{ $guarantee->id };
 546             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 547             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 548             $seen->{ $guarantee->id } = 1;
 549         }
 550
 551         $non_issues_charges += $guarantees_non_issues_charges;
 552         $seen->{ $guarantor->id } = 1;
 553     }
 554
 555     return $non_issues_charges;
 556 }
 557
 558 =head3 housebound_profile
 559
 560 Returns the HouseboundProfile associated with this patron.
 561
 562 =cut
 563
 564 sub housebound_profile {
 565     my ( $self ) = @_;
 566     my $profile = $self->_result->housebound_profile;
 567     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 568         if ( $profile );
 569     return;
 570 }
 571
 572 =head3 housebound_role
 573
 574 Returns the HouseboundRole associated with this patron.
 575
 576 =cut
 577
 578 sub housebound_role {
 579     my ( $self ) = @_;
 580
 581     my $role = $self->_result->housebound_role;
 582     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 583     return;
 584 }
 585
 586 =head3 siblings
 587
 588 Returns the siblings of this patron.
 589
 590 =cut
 591
 592 sub siblings {
 593     my ($self) = @_;
 594
 595     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 596
 597     return unless @guarantors;
 598
 599     my @siblings =
 600       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 601
 602     return unless @siblings;
 603
 604     my %seen;
 605     @siblings =
 606       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 607
 608     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 609 }
 610
 611 =head3 merge_with
 612
 613     my $patron = Koha::Patrons->find($id);
 614     $patron->merge_with( \@patron_ids );
 615
 616     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 617     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 618     of the keeper patron.
 619
 620 =cut
 621
 622 sub merge_with {
 623     my ( $self, $patron_ids ) = @_;
 624
 625     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 626     return if $anonymous_patron && $self->id eq $anonymous_patron;
 627
 628     my @patron_ids = @{ $patron_ids };
 629
 630     # Ensure the keeper isn't in the list of patrons to merge
 631     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 632
 633     my $schema = Koha::Database->new()->schema();
 634
 635     my $results;
 636
 637     $self->_result->result_source->schema->txn_do( sub {
 638         foreach my $patron_id (@patron_ids) {
 639
 640             next if $patron_id eq $anonymous_patron;
 641
 642             my $patron = Koha::Patrons->find( $patron_id );
 643
 644             next unless $patron;
 645
 646             # Unbless for safety, the patron will end up being deleted
 647             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 648
 649             my $attributes = $patron->extended_attributes;
 650             my $new_attributes = [
 651                 map { { code => $_->code, attribute => $_->attribute } }
 652                     $attributes->as_list
 653             ];
 654             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 655             for my $attribute ( @$new_attributes ) {
 656                 try {
 657                     $self->add_extended_attribute($attribute);
 658                 } catch {
 659                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 660                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 661                         $_->rethrow;
 662                     }
 663                 };
 664             }
 665
 666             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 667                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 668                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 669                 $rs->update({ $field => $self->id });
 670                 if ( $r eq 'BorrowerDebarment' ) {
 671                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 672                 }
 673             }
 674
 675             $patron->move_to_deleted();
 676             $patron->delete();
 677         }
 678     });
 679
 680     return $results;
 681 }
 682
 683
 684 =head3 messaging_preferences
 685
 686     my $patron = Koha::Patrons->find($id);
 687     $patron->messaging_preferences();
 688
 689 =cut
 690
 691 sub messaging_preferences {
 692     my ( $self ) = @_;
 693
 694     return Koha::Patron::MessagePreferences->search({
 695         borrowernumber => $self->borrowernumber,
 696     });
 697 }
 698
 699 =head3 wants_check_for_previous_checkout
 700
 701     $wants_check = $patron->wants_check_for_previous_checkout;
 702
 703 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 704
 705 =cut
 706
 707 sub wants_check_for_previous_checkout {
 708     my ( $self ) = @_;
 709     my $syspref = C4::Context->preference("checkPrevCheckout");
 710
 711     # Simple cases
 712     ## Hard syspref trumps all
 713     return 1 if ($syspref eq 'hardyes');
 714     return 0 if ($syspref eq 'hardno');
 715     ## Now, patron pref trumps all
 716     return 1 if ($self->checkprevcheckout eq 'yes');
 717     return 0 if ($self->checkprevcheckout eq 'no');
 718
 719     # More complex: patron inherits -> determine category preference
 720     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 721     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 722     return 0 if ($checkPrevCheckoutByCat eq 'no');
 723
 724     # Finally: category preference is inherit, default to 0
 725     if ($syspref eq 'softyes') {
 726         return 1;
 727     } else {
 728         return 0;
 729     }
 730 }
 731
 732 =head3 do_check_for_previous_checkout
 733
 734     $do_check = $patron->do_check_for_previous_checkout($item);
 735
 736 Return 1 if the bib associated with $ITEM has previously been checked out to
 737 $PATRON, 0 otherwise.
 738
 739 =cut
 740
 741 sub do_check_for_previous_checkout {
 742     my ( $self, $item ) = @_;
 743
 744     my @item_nos;
 745     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 746     if ( $biblio->is_serial ) {
 747         push @item_nos, $item->{itemnumber};
 748     } else {
 749         # Get all itemnumbers for given bibliographic record.
 750         @item_nos = $biblio->items->get_column( 'itemnumber' );
 751     }
 752
 753     # Create (old)issues search criteria
 754     my $criteria = {
 755         borrowernumber => $self->borrowernumber,
 756         itemnumber => \@item_nos,
 757     };
 758
 759     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 760     if ($delay) {
 761         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 762         my $newer_than = dt_from_string()->subtract( days => $delay );
 763         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 764     }
 765
 766     # Check current issues table
 767     my $issues = Koha::Checkouts->search($criteria);
 768     return 1 if $issues->count; # 0 || N
 769
 770     # Check old issues table
 771     my $old_issues = Koha::Old::Checkouts->search($criteria);
 772     return $old_issues->count;  # 0 || N
 773 }
 774
 775 =head3 is_debarred
 776
 777 my $debarment_expiration = $patron->is_debarred;
 778
 779 Returns the date a patron debarment will expire, or undef if the patron is not
 780 debarred
 781
 782 =cut
 783
 784 sub is_debarred {
 785     my ($self) = @_;
 786
 787     return unless $self->debarred;
 788     return $self->debarred
 789       if $self->debarred =~ '^9999'
 790       or dt_from_string( $self->debarred ) > dt_from_string;
 791     return;
 792 }
 793
 794 =head3 is_expired
 795
 796 my $is_expired = $patron->is_expired;
 797
 798 Returns 1 if the patron is expired or 0;
 799
 800 =cut
 801
 802 sub is_expired {
 803     my ($self) = @_;
 804     return 0 unless $self->dateexpiry;
 805     return 0 if $self->dateexpiry =~ '^9999';
 806     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 807     return 0;
 808 }
 809
 810 =head3 password_expired
 811
 812 my $password_expired = $patron->password_expired;
 813
 814 Returns 1 if the patron's password is expired or 0;
 815
 816 =cut
 817
 818 sub password_expired {
 819     my ($self) = @_;
 820     return 0 unless $self->password_expiration_date;
 821     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 822     return 0;
 823 }
 824
 825 =head3 is_going_to_expire
 826
 827 my $is_going_to_expire = $patron->is_going_to_expire;
 828
 829 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 830
 831 =cut
 832
 833 sub is_going_to_expire {
 834     my ($self) = @_;
 835
 836     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 837
 838     return 0 unless $delay;
 839     return 0 unless $self->dateexpiry;
 840     return 0 if $self->dateexpiry =~ '^9999';
 841     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 842     return 0;
 843 }
 844
 845 =head3 set_password
 846
 847     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 848
 849 Set the patron's password.
 850
 851 =head4 Exceptions
 852
 853 The passed string is validated against the current password enforcement policy.
 854 Validation can be skipped by passing the I<skip_validation> parameter.
 855
 856 Exceptions are thrown if the password is not good enough.
 857
 858 =over 4
 859
 860 =item Koha::Exceptions::Password::TooShort
 861
 862 =item Koha::Exceptions::Password::WhitespaceCharacters
 863
 864 =item Koha::Exceptions::Password::TooWeak
 865
 866 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 867
 868 =back
 869
 870 =cut
 871
 872 sub set_password {
 873     my ( $self, $args ) = @_;
 874
 875     my $password = $args->{password};
 876
 877     unless ( $args->{skip_validation} ) {
 878         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 879
 880         if ( !$is_valid ) {
 881             if ( $error eq 'too_short' ) {
 882                 my $min_length = $self->category->effective_min_password_length;
 883                 $min_length = 3 if not $min_length or $min_length < 3;
 884
 885                 my $password_length = length($password);
 886                 Koha::Exceptions::Password::TooShort->throw(
 887                     length => $password_length, min_length => $min_length );
 888             }
 889             elsif ( $error eq 'has_whitespaces' ) {
 890                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 891             }
 892             elsif ( $error eq 'too_weak' ) {
 893                 Koha::Exceptions::Password::TooWeak->throw();
 894             }
 895         }
 896     }
 897
 898     if ( C4::Context->config("enable_plugins") ) {
 899         # Call any check_password plugins
 900         my @plugins = Koha::Plugins->new()->GetPlugins({
 901             method => 'check_password',
 902         });
 903         foreach my $plugin ( @plugins ) {
 904             # This plugin hook will also be used by a plugin for the Norwegian national
 905             # patron database. This is why we need to pass both the password and the
 906             # borrowernumber to the plugin.
 907             my $ret = $plugin->check_password(
 908                 {
 909                     password       => $password,
 910                     borrowernumber => $self->borrowernumber
 911                 }
 912             );
 913             # This plugin hook will also be used by a plugin for the Norwegian national
 914             # patron database. This is why we need to call the actual plugins and then
 915             # check skip_validation afterwards.
 916             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 917                 Koha::Exceptions::Password::Plugin->throw();
 918             }
 919         }
 920     }
 921
 922     if ( C4::Context->preference('NotifyPasswordChange') ) {
 923         my $self_from_storage = $self->get_from_storage;
 924         if ( !C4::Auth::checkpw_hash( $password, $self_from_storage->password ) ) {
 925             my $emailaddr = $self_from_storage->notice_email_address;
 926
 927             # if we manage to find a valid email address, send notice
 928             if ($emailaddr) {
 929                 my $letter = C4::Letters::GetPreparedLetter(
 930                     module      => 'members',
 931                     letter_code => 'PASSWORD_CHANGE',
 932                     branchcode  => $self_from_storage->branchcode,
 933                     ,
 934                     lang   => $self_from_storage->lang || 'default',
 935                     tables => {
 936                         'branches'  => $self_from_storage->branchcode,
 937                         'borrowers' => $self_from_storage->borrowernumber,
 938                     },
 939                     want_librarian => 1,
 940                 ) or return;
 941
 942                 my $message_id = C4::Letters::EnqueueLetter(
 943                     {
 944                         letter                 => $letter,
 945                         borrowernumber         => $self_from_storage->id,
 946                         to_address             => $emailaddr,
 947                         message_transport_type => 'email'
 948                     }
 949                 );
 950                 C4::Letters::SendQueuedMessages( { message_id => $message_id } ) if $message_id;
 951             }
 952         }
 953     }
 954
 955     my $digest = Koha::AuthUtils::hash_password($password);
 956
 957     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 958
 959     # We do not want to call $self->store and retrieve password from DB
 960     $self->password($digest);
 961     $self->login_attempts(0);
 962     $self->SUPER::store;
 963
 964     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 965         if C4::Context->preference("BorrowersLog");
 966
 967     return $self;
 968 }
 969
 970
 971 =head3 renew_account
 972
 973 my $new_expiry_date = $patron->renew_account
 974
 975 Extending the subscription to the expiry date.
 976
 977 =cut
 978
 979 sub renew_account {
 980     my ($self) = @_;
 981     my $date;
 982     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 983         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 984     } else {
 985         $date =
 986             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 987             ? dt_from_string( $self->dateexpiry )
 988             : dt_from_string;
 989     }
 990     my $expiry_date = $self->category->get_expiry_date($date);
 991
 992     $self->dateexpiry($expiry_date);
 993     $self->date_renewed( dt_from_string() );
 994     $self->store();
 995
 996     $self->add_enrolment_fee_if_needed(1);
 997
 998     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 999     return dt_from_string( $expiry_date )->truncate( to => 'day' );
1000 }
1001
1002 =head3 has_overdues
1003
1004 my $has_overdues = $patron->has_overdues;
1005
1006 Returns the number of patron's overdues
1007
1008 =cut
1009
1010 sub has_overdues {
1011     my ($self) = @_;
1012     my $date = dt_from_string();
1013     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1014     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime($date) } })->count;
1015 }
1016
1017 sub has_debarring_overdues {
1018     my ($self, $params) = @_;
1019     $params //= {};
1020     my $date = dt_from_string()->truncate( to => 'day' );
1021
1022     # If ignoring unrestricted overdues, calculate which delay value for
1023     # overdue messages is set with restrictions. Then only include overdue
1024     # issues older than that date when counting.
1025     #TODO: bail out/throw exception if $params->{issue_branchcode} not set?
1026     my $debarred_delay = _get_overdue_debarred_delay($params->{issue_branchcode}, $self->categorycode());
1027     return 0 unless defined $debarred_delay;
1028
1029     # Emulate the conditions in overdue_notices.pl.
1030     # The overdue_notices-script effectively truncates both issues.date_due and current date
1031     # to days when selecting overdue issues.
1032     # Hours and minutes for issues.date_due is usually set to 23 and 59 respectively, though can theoretically
1033     # be set to any other value (truncated to minutes, except if CalcDateDue gets a $startdate)
1034     #
1035     # No matter what time of day date_due is set to, overdue_notices.pl will select all issues that are due
1036     # the current date or later. We can emulate this query by instead of truncating both to days in the SQL-query,
1037     # using the condition that date_due must be less then the current date truncated to days (time set to 00:00:00)
1038     # offset by one day in the future.
1039
1040     $date->add(days => 1);
1041
1042     my $calendar;
1043     if (C4::Context->preference('OverdueNoticeCalendar')) {
1044         $calendar = Koha::Calendar->new( branchcode => $params->{issue_branchcode} );
1045     }
1046
1047     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1048     my $issues = $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime($date) } });
1049     my $now = dt_from_string();
1050
1051     while (my $issue = $issues->next) {
1052         my $days_between = C4::Context->preference('OverdueNoticeCalendar') ?
1053             $calendar->days_between(dt_from_string($issue->date_due), $now)->in_units('days') :
1054             $now->delta_days(dt_from_string($issue->date_due))->in_units('days');
1055         if ($days_between >= $debarred_delay) {
1056             return 1;
1057         }
1058     }
1059     return 0;
1060 }
1061
1062 # Fetch first delayX value from overduerules where debarredX is set, or 0 for no delay
1063 sub _get_overdue_debarred_delay {
1064     my ($branchcode, $categorycode) = @_;
1065     my $dbh = C4::Context->dbh();
1066
1067     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? AND categorycode = ?";
1068
1069     my $rqoverduerules = $dbh->prepare($query);
1070     $rqoverduerules->execute($branchcode, $categorycode);
1071
1072     # We get default rules if there is no rule for this branch
1073     if($rqoverduerules->rows == 0) {
1074         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' AND categorycode = ?";
1075
1076         $rqoverduerules = $dbh->prepare($query);
1077         $rqoverduerules->execute($categorycode);
1078     }
1079
1080     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
1081         return $overdue_rules->{"delay1"} if($overdue_rules->{"debarred1"});
1082         return $overdue_rules->{"delay2"} if($overdue_rules->{"debarred2"});
1083         return $overdue_rules->{"delay3"} if($overdue_rules->{"debarred3"});
1084     }
1085     return undef;
1086 }
1087
1088 =head3 track_login
1089
1090     $patron->track_login;
1091     $patron->track_login({ force => 1 });
1092
1093     Tracks a (successful) login attempt.
1094     The preference TrackLastPatronActivity must be enabled. Or you
1095     should pass the force parameter.
1096
1097 =cut
1098
1099 sub track_login {
1100     my ( $self, $params ) = @_;
1101     return if
1102         !$params->{force} &&
1103         !C4::Context->preference('TrackLastPatronActivity');
1104     $self->lastseen( dt_from_string() )->store;
1105 }
1106
1107 =head3 move_to_deleted
1108
1109 my $is_moved = $patron->move_to_deleted;
1110
1111 Move a patron to the deletedborrowers table.
1112 This can be done before deleting a patron, to make sure the data are not completely deleted.
1113
1114 =cut
1115
1116 sub move_to_deleted {
1117     my ($self) = @_;
1118     my $patron_infos = $self->unblessed;
1119     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
1120     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
1121 }
1122
1123 =head3 can_request_article
1124
1125     if ( $patron->can_request_article( $library->id ) ) { ... }
1126
1127 Returns true if the patron can request articles. As limits apply for the patron
1128 on the same day, those completed the same day are considered as current.
1129
1130 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1131
1132 =cut
1133
1134 sub can_request_article {
1135     my ($self, $library_id) = @_;
1136
1137     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1138
1139     my $rule = Koha::CirculationRules->get_effective_rule(
1140         {
1141             branchcode   => $library_id,
1142             categorycode => $self->categorycode,
1143             rule_name    => 'open_article_requests_limit'
1144         }
1145     );
1146
1147     my $limit = ($rule) ? $rule->rule_value : undef;
1148
1149     return 1 unless defined $limit;
1150
1151     my $count = Koha::ArticleRequests->search(
1152         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1153             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1154         ]
1155     )->count;
1156     return $count < $limit ? 1 : 0;
1157 }
1158
1159 =head3 article_request_fee
1160
1161     my $fee = $patron->article_request_fee(
1162         {
1163           [ library_id => $library->id, ]
1164         }
1165     );
1166
1167 Returns the fee to be charged to the patron when it places an article request.
1168
1169 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1170
1171 =cut
1172
1173 sub article_request_fee {
1174     my ($self, $params) = @_;
1175
1176     my $library_id = $params->{library_id};
1177
1178     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1179
1180     my $rule = Koha::CirculationRules->get_effective_rule(
1181         {
1182             branchcode   => $library_id,
1183             categorycode => $self->categorycode,
1184             rule_name    => 'article_request_fee'
1185         }
1186     );
1187
1188     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1189
1190     return $fee;
1191 }
1192
1193 =head3 add_article_request_fee_if_needed
1194
1195     my $fee = $patron->add_article_request_fee_if_needed(
1196         {
1197           [ item_id    => $item->id,
1198             library_id => $library->id, ]
1199         }
1200     );
1201
1202 If an article request fee needs to be charged, it adds a debit to the patron's
1203 account.
1204
1205 Returns the fee line.
1206
1207 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1208
1209 =cut
1210
1211 sub add_article_request_fee_if_needed {
1212     my ($self, $params) = @_;
1213
1214     my $library_id = $params->{library_id};
1215     my $item_id    = $params->{item_id};
1216
1217     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1218
1219     my $amount = $self->article_request_fee(
1220         {
1221             library_id => $library_id,
1222         }
1223     );
1224
1225     my $debit_line;
1226
1227     if ( $amount > 0 ) {
1228         $debit_line = $self->account->add_debit(
1229             {
1230                 amount     => $amount,
1231                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1232                 interface  => C4::Context->interface,
1233                 library_id => $library_id,
1234                 type       => 'ARTICLE_REQUEST',
1235                 item_id    => $item_id,
1236             }
1237         );
1238     }
1239
1240     return $debit_line;
1241 }
1242
1243 =head3 article_requests
1244
1245     my $article_requests = $patron->article_requests;
1246
1247 Returns the patron article requests.
1248
1249 =cut
1250
1251 sub article_requests {
1252     my ($self) = @_;
1253
1254     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1255 }
1256
1257 =head3 add_enrolment_fee_if_needed
1258
1259 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1260
1261 Add enrolment fee for a patron if needed.
1262
1263 $renewal - boolean denoting whether this is an account renewal or not
1264
1265 =cut
1266
1267 sub add_enrolment_fee_if_needed {
1268     my ($self, $renewal) = @_;
1269     my $enrolment_fee = $self->category->enrolmentfee;
1270     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1271         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1272         $self->account->add_debit(
1273             {
1274                 amount     => $enrolment_fee,
1275                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1276                 interface  => C4::Context->interface,
1277                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1278                 type       => $type
1279             }
1280         );
1281     }
1282     return $enrolment_fee || 0;
1283 }
1284
1285 =head3 checkouts
1286
1287 my $checkouts = $patron->checkouts
1288
1289 =cut
1290
1291 sub checkouts {
1292     my ($self) = @_;
1293     my $checkouts = $self->_result->issues;
1294     return Koha::Checkouts->_new_from_dbic( $checkouts );
1295 }
1296
1297 =head3 pending_checkouts
1298
1299 my $pending_checkouts = $patron->pending_checkouts
1300
1301 This method will return the same as $self->checkouts, but with a prefetch on
1302 items, biblio and biblioitems.
1303
1304 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1305
1306 It should not be used directly, prefer to access fields you need instead of
1307 retrieving all these fields in one go.
1308
1309 =cut
1310
1311 sub pending_checkouts {
1312     my( $self ) = @_;
1313     my $checkouts = $self->_result->issues->search(
1314         {},
1315         {
1316             order_by => [
1317                 { -desc => 'me.timestamp' },
1318                 { -desc => 'issuedate' },
1319                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1320             ],
1321             prefetch => { item => { biblio => 'biblioitems' } },
1322         }
1323     );
1324     return Koha::Checkouts->_new_from_dbic( $checkouts );
1325 }
1326
1327 =head3 old_checkouts
1328
1329 my $old_checkouts = $patron->old_checkouts
1330
1331 =cut
1332
1333 sub old_checkouts {
1334     my ($self) = @_;
1335     my $old_checkouts = $self->_result->old_issues;
1336     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1337 }
1338
1339 =head3 overdues
1340
1341 my $overdue_items = $patron->overdues
1342
1343 Return the overdue items
1344
1345 =cut
1346
1347 sub overdues {
1348     my ($self) = @_;
1349     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1350     return $self->checkouts->search(
1351         {
1352             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1353         },
1354         {
1355             prefetch => { item => { biblio => 'biblioitems' } },
1356         }
1357     );
1358 }
1359
1360
1361 =head3 restrictions
1362
1363   my $restrictions = $patron->restrictions;
1364
1365 Returns the patron restrictions.
1366
1367 =cut
1368
1369 sub restrictions {
1370     my ($self) = @_;
1371     my $restrictions_rs = $self->_result->restrictions;
1372     return Koha::Patron::Restrictions->_new_from_dbic($restrictions_rs);
1373 }
1374
1375 =head3 get_routing_lists
1376
1377 my $routinglists = $patron->get_routing_lists
1378
1379 Returns the routing lists a patron is subscribed to.
1380
1381 =cut
1382
1383 sub get_routing_lists {
1384     my ($self) = @_;
1385     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1386     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1387 }
1388
1389 =head3 get_age
1390
1391     my $age = $patron->get_age
1392
1393 Return the age of the patron
1394
1395 =cut
1396
1397 sub get_age {
1398     my ($self)    = @_;
1399
1400     return unless $self->dateofbirth;
1401
1402     #Set timezone to floating to avoid any datetime math issues caused by DST
1403     my $date_of_birth = dt_from_string( $self->dateofbirth, undef, 'floating' );
1404     my $today         = dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
1405
1406     return $today->subtract_datetime( $date_of_birth )->years;
1407 }
1408
1409 =head3 is_valid_age
1410
1411 my $is_valid = $patron->is_valid_age
1412
1413 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1414
1415 =cut
1416
1417 sub is_valid_age {
1418     my ($self) = @_;
1419     my $age = $self->get_age;
1420
1421     my $patroncategory = $self->category;
1422     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1423
1424     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1425 }
1426
1427 =head3 account
1428
1429 my $account = $patron->account
1430
1431 =cut
1432
1433 sub account {
1434     my ($self) = @_;
1435     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1436 }
1437
1438 =head3 holds
1439
1440 my $holds = $patron->holds
1441
1442 Return all the holds placed by this patron
1443
1444 =cut
1445
1446 sub holds {
1447     my ($self) = @_;
1448     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1449     return Koha::Holds->_new_from_dbic($holds_rs);
1450 }
1451
1452 =head3 old_holds
1453
1454 my $old_holds = $patron->old_holds
1455
1456 Return all the historical holds for this patron
1457
1458 =cut
1459
1460 sub old_holds {
1461     my ($self) = @_;
1462     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1463     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1464 }
1465
1466 =head3 curbside_pickups
1467
1468 my $curbside_pickups = $patron->curbside_pickups;
1469
1470 Return all the curbside pickups for this patron
1471
1472 =cut
1473
1474 sub curbside_pickups {
1475     my ($self) = @_;
1476     my $curbside_pickups_rs = $self->_result->curbside_pickups_borrowernumbers->search;
1477     return Koha::CurbsidePickups->_new_from_dbic($curbside_pickups_rs);
1478 }
1479
1480 =head3 return_claims
1481
1482 my $return_claims = $patron->return_claims
1483
1484 =cut
1485
1486 sub return_claims {
1487     my ($self) = @_;
1488     my $return_claims = $self->_result->return_claims_borrowernumbers;
1489     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1490 }
1491
1492 =head3 notice_email_address
1493
1494   my $email = $patron->notice_email_address;
1495
1496 Return the email address of patron used for notices.
1497 Returns the empty string if no email address.
1498
1499 =cut
1500
1501 sub notice_email_address{
1502     my ( $self ) = @_;
1503
1504     my $which_address = C4::Context->preference("EmailFieldPrimary");
1505     # if syspref is set to 'first valid' (value == OFF), look up email address
1506     if ( $which_address eq 'OFF' ) {
1507         return $self->first_valid_email_address;
1508     }
1509
1510     return $self->$which_address || '';
1511 }
1512
1513 =head3 first_valid_email_address
1514
1515 my $first_valid_email_address = $patron->first_valid_email_address
1516
1517 Return the first valid email address for a patron.
1518 For now, the order  is defined as email, emailpro, B_email.
1519 Returns the empty string if the borrower has no email addresses.
1520
1521 =cut
1522
1523 sub first_valid_email_address {
1524     my ($self) = @_;
1525
1526     my $email = q{};
1527
1528     my @fields = split /\s*\|\s*/,
1529       C4::Context->preference('EmailFieldPrecedence');
1530     for my $field (@fields) {
1531         $email = $self->$field;
1532         last if ($email);
1533     }
1534
1535     return $email;
1536 }
1537
1538 =head3 get_club_enrollments
1539
1540 =cut
1541
1542 sub get_club_enrollments {
1543     my ( $self ) = @_;
1544
1545     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1546 }
1547
1548 =head3 get_enrollable_clubs
1549
1550 =cut
1551
1552 sub get_enrollable_clubs {
1553     my ( $self, $is_enrollable_from_opac ) = @_;
1554
1555     my $params;
1556     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1557       if $is_enrollable_from_opac;
1558     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1559
1560     $params->{borrower} = $self;
1561
1562     return Koha::Clubs->get_enrollable($params);
1563 }
1564
1565 =head3 account_locked
1566
1567 my $is_locked = $patron->account_locked
1568
1569 Return true if the patron has reached the maximum number of login attempts
1570 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1571 as an administrative lockout (independent of FailedLoginAttempts; see also
1572 Koha::Patron->lock).
1573 Otherwise return false.
1574 If the pref is not set (empty string, null or 0), the feature is considered as
1575 disabled.
1576
1577 =cut
1578
1579 sub account_locked {
1580     my ($self) = @_;
1581     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1582     return 1 if $FailedLoginAttempts
1583           and $self->login_attempts
1584           and $self->login_attempts >= $FailedLoginAttempts;
1585     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1586     return 0;
1587 }
1588
1589 =head3 can_see_patron_infos
1590
1591 my $can_see = $patron->can_see_patron_infos( $patron );
1592
1593 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1594
1595 =cut
1596
1597 sub can_see_patron_infos {
1598     my ( $self, $patron ) = @_;
1599     return unless $patron;
1600     return $self->can_see_patrons_from( $patron->branchcode );
1601 }
1602
1603 =head3 can_see_patrons_from
1604
1605 my $can_see = $patron->can_see_patrons_from( $branchcode );
1606
1607 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1608
1609 =cut
1610
1611 sub can_see_patrons_from {
1612     my ( $self, $branchcode ) = @_;
1613
1614     return $self->can_see_things_from(
1615         {
1616             branchcode => $branchcode,
1617             permission => 'borrowers',
1618             subpermission => 'view_borrower_infos_from_any_libraries',
1619         }
1620     );
1621 }
1622
1623 =head3 can_edit_items_from
1624
1625     my $can_edit = $patron->can_edit_items_from( $branchcode );
1626
1627 Return true if the I<Koha::Patron> can edit items from the given branchcode
1628
1629 =cut
1630
1631 sub can_edit_items_from {
1632     my ( $self, $branchcode ) = @_;
1633
1634     return 1 if C4::Context->IsSuperLibrarian();
1635
1636     my $userenv = C4::Context->userenv();
1637     if ( $userenv && C4::Context->preference('IndependentBranches') ) {
1638         return $userenv->{branch} eq $branchcode;
1639     }
1640
1641     return $self->can_see_things_from(
1642         {
1643             branchcode    => $branchcode,
1644             permission    => 'editcatalogue',
1645             subpermission => 'edit_any_item',
1646         }
1647     );
1648 }
1649
1650 =head3 libraries_where_can_edit_items
1651
1652     my $libraries = $patron->libraries_where_can_edit_items;
1653
1654 Return the list of branchcodes(!) of libraries the patron is allowed to items for.
1655 The branchcodes are arbitrarily returned sorted.
1656 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1657
1658 An empty array means no restriction, the user can edit any item.
1659
1660 =cut
1661
1662 sub libraries_where_can_edit_items {
1663     my ($self) = @_;
1664
1665     return $self->libraries_where_can_see_things(
1666         {
1667             permission    => 'editcatalogue',
1668             subpermission => 'edit_any_item',
1669             group_feature => 'ft_limit_item_editing',
1670         }
1671     );
1672 }
1673
1674 =head3 libraries_where_can_see_patrons
1675
1676 my $libraries = $patron->libraries_where_can_see_patrons;
1677
1678 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1679 The branchcodes are arbitrarily returned sorted.
1680 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1681
1682 An empty array means no restriction, the patron can see patron's infos from any libraries.
1683
1684 =cut
1685
1686 sub libraries_where_can_see_patrons {
1687     my ($self) = @_;
1688
1689     return $self->libraries_where_can_see_things(
1690         {
1691             permission    => 'borrowers',
1692             subpermission => 'view_borrower_infos_from_any_libraries',
1693             group_feature => 'ft_hide_patron_info',
1694         }
1695     );
1696 }
1697
1698 =head3 can_see_things_from
1699
1700 my $can_see = $patron->can_see_things_from( $branchcode );
1701
1702 Return true if the I<Koha::Patron> can perform some action on the given thing
1703
1704 =cut
1705
1706 sub can_see_things_from {
1707     my ( $self, $params ) = @_;
1708
1709     my $branchcode    = $params->{branchcode};
1710     my $permission    = $params->{permission};
1711     my $subpermission = $params->{subpermission};
1712
1713     return 1 if C4::Context->IsSuperLibrarian();
1714
1715     my $can = 0;
1716     if ( $self->branchcode eq $branchcode ) {
1717         $can = 1;
1718     } elsif ( $self->has_permission( { $permission => $subpermission } ) ) {
1719         $can = 1;
1720     } elsif ( my $library_groups = $self->library->library_groups ) {
1721         while ( my $library_group = $library_groups->next ) {
1722             if ( $library_group->parent->has_child( $branchcode ) ) {
1723                 $can = 1;
1724                 last;
1725             }
1726         }
1727     }
1728     return $can;
1729 }
1730
1731 =head3 can_log_into
1732
1733 my $can_log_into = $patron->can_log_into( $library );
1734
1735 Given a I<Koha::Library> object, it returns a boolean representing
1736 the fact the patron can log into a the library.
1737
1738 =cut
1739
1740 sub can_log_into {
1741     my ( $self, $library ) = @_;
1742
1743     my $can = 0;
1744
1745     if ( C4::Context->preference('IndependentBranches') ) {
1746         $can = 1
1747           if $self->is_superlibrarian
1748           or $self->branchcode eq $library->id;
1749     }
1750     else {
1751         # no restrictions
1752         $can = 1;
1753     }
1754
1755    return $can;
1756 }
1757
1758 =head3 libraries_where_can_see_things
1759
1760     my $libraries = $patron->libraries_where_can_see_things;
1761
1762 Returns a list of libraries where an aribitarary action is allowed to be taken by the logged in librarian
1763 against an object based on some branchcode related to the object ( patron branchcode, item homebranch, etc ).
1764
1765 We are supposing here that the object is related to the logged in librarian (use of C4::Context::only_my_library)
1766
1767 An empty array means no restriction, the thing can see thing's infos from any libraries.
1768
1769 =cut
1770
1771 sub libraries_where_can_see_things {
1772     my ( $self, $params ) = @_;
1773     my $permission    = $params->{permission};
1774     my $subpermission = $params->{subpermission};
1775     my $group_feature = $params->{group_feature};
1776
1777     my $userenv = C4::Context->userenv;
1778
1779     return () unless $userenv; # For tests, but userenv should be defined in tests...
1780
1781     my @restricted_branchcodes;
1782     if (C4::Context::only_my_library) {
1783         push @restricted_branchcodes, $self->branchcode;
1784     }
1785     else {
1786         unless (
1787             $self->has_permission(
1788                 { $permission => $subpermission }
1789             )
1790           )
1791         {
1792             my $library_groups = $self->library->library_groups({ $group_feature => 1 });
1793             if ( $library_groups->count )
1794             {
1795                 while ( my $library_group = $library_groups->next ) {
1796                     my $parent = $library_group->parent;
1797                     if ( $parent->has_child( $self->branchcode ) ) {
1798                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1799                     }
1800                 }
1801             }
1802
1803             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1804         }
1805     }
1806
1807     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1808     @restricted_branchcodes = uniq(@restricted_branchcodes);
1809     @restricted_branchcodes = sort(@restricted_branchcodes);
1810     return @restricted_branchcodes;
1811 }
1812
1813 =head3 has_permission
1814
1815 my $permission = $patron->has_permission($required);
1816
1817 See C4::Auth::haspermission for details of syntax for $required
1818
1819 =cut
1820
1821 sub has_permission {
1822     my ( $self, $flagsrequired ) = @_;
1823     return unless $self->userid;
1824     # TODO code from haspermission needs to be moved here!
1825     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1826 }
1827
1828 =head3 is_superlibrarian
1829
1830   my $is_superlibrarian = $patron->is_superlibrarian;
1831
1832 Return true if the patron is a superlibrarian.
1833
1834 =cut
1835
1836 sub is_superlibrarian {
1837     my ($self) = @_;
1838     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1839 }
1840
1841 =head3 is_adult
1842
1843 my $is_adult = $patron->is_adult
1844
1845 Return true if the patron has a category with a type Adult (A) or Organization (I)
1846
1847 =cut
1848
1849 sub is_adult {
1850     my ( $self ) = @_;
1851     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1852 }
1853
1854 =head3 is_child
1855
1856 my $is_child = $patron->is_child
1857
1858 Return true if the patron has a category with a type Child (C)
1859
1860 =cut
1861
1862 sub is_child {
1863     my( $self ) = @_;
1864     return $self->category->category_type eq 'C' ? 1 : 0;
1865 }
1866
1867 =head3 has_valid_userid
1868
1869 my $patron = Koha::Patrons->find(42);
1870 $patron->userid( $new_userid );
1871 my $has_a_valid_userid = $patron->has_valid_userid
1872
1873 my $patron = Koha::Patron->new( $params );
1874 my $has_a_valid_userid = $patron->has_valid_userid
1875
1876 Return true if the current userid of this patron is valid/unique, otherwise false.
1877
1878 Note that this should be done in $self->store instead and raise an exception if needed.
1879
1880 =cut
1881
1882 sub has_valid_userid {
1883     my ($self) = @_;
1884
1885     return 0 unless $self->userid;
1886
1887     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1888
1889     my $already_exists = Koha::Patrons->search(
1890         {
1891             userid => $self->userid,
1892             (
1893                 $self->in_storage
1894                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1895                 : ()
1896             ),
1897         }
1898     )->count;
1899     return $already_exists ? 0 : 1;
1900 }
1901
1902 =head3 generate_userid
1903
1904     $patron->generate_userid;
1905
1906     If you do not have a plugin for generating a userid, we will call
1907     the internal method here that returns firstname.surname[.number],
1908     where number is an optional suffix to make the userid unique.
1909     (Its behavior has not been changed on bug 32426.)
1910
1911     If you have plugin(s), the first valid response will be used.
1912     A plugin is assumed to return a valid userid as suggestion, but not
1913     assumed to save it already.
1914     Does not fallback to internal (you could arrange for that in your plugin).
1915     Clears userid when there are no valid plugin responses.
1916
1917 =cut
1918
1919 sub generate_userid {
1920     my ( $self ) = @_;
1921     my @responses = Koha::Plugins->call(
1922         'patron_generate_userid', { patron => $self },
1923     );
1924     unless( @responses ) {
1925         # Empty list only possible when there are NO enabled plugins for this method.
1926         # In that case we provide internal response.
1927         return $self->_generate_userid_internal;
1928     }
1929     # If a plugin returned false value or invalid value, we do however not return
1930     # internal response. The plugins should deal with that themselves. So we prevent
1931     # unexpected/unwelcome internal codes for plugin failures.
1932     foreach my $response ( grep { $_ } @responses ) {
1933         $self->userid( $response );
1934         return $self if $self->has_valid_userid;
1935     }
1936     $self->userid(undef);
1937     return $self;
1938 }
1939
1940 sub _generate_userid_internal { # as we always did
1941     my ($self) = @_;
1942     my $offset = 0;
1943     my $firstname = $self->firstname // q{};
1944     my $surname = $self->surname // q{};
1945     #The script will "do" the following code and increment the $offset until the generated userid is unique
1946     do {
1947       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1948       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1949       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1950       $userid = NFKD( $userid );
1951       $userid =~ s/\p{NonspacingMark}//g;
1952       $userid .= $offset unless $offset == 0;
1953       $self->userid( $userid );
1954       $offset++;
1955      } while (! $self->has_valid_userid );
1956
1957      return $self;
1958 }
1959
1960 =head3 add_extended_attribute
1961
1962 =cut
1963
1964 sub add_extended_attribute {
1965     my ($self, $attribute) = @_;
1966
1967     return Koha::Patron::Attribute->new(
1968         {
1969             %$attribute,
1970             ( borrowernumber => $self->borrowernumber ),
1971         }
1972     )->store;
1973
1974 }
1975
1976 =head3 extended_attributes
1977
1978 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1979
1980 Or setter FIXME
1981
1982 =cut
1983
1984 sub extended_attributes {
1985     my ( $self, $attributes ) = @_;
1986     if ($attributes) {    # setter
1987         my $schema = $self->_result->result_source->schema;
1988         $schema->txn_do(
1989             sub {
1990                 # Remove the existing one
1991                 $self->extended_attributes->filter_by_branch_limitations->delete;
1992
1993                 # Insert the new ones
1994                 my $new_types = {};
1995                 for my $attribute (@$attributes) {
1996                     $self->add_extended_attribute($attribute);
1997                     $new_types->{$attribute->{code}} = 1;
1998                 }
1999
2000                 # Check globally mandatory types
2001                 my @required_attribute_types =
2002                     Koha::Patron::Attribute::Types->search(
2003                         {
2004                             mandatory => 1,
2005                             category_code => [ undef, $self->categorycode ],
2006                             'borrower_attribute_types_branches.b_branchcode' =>
2007                               undef,
2008                         },
2009                         { join => 'borrower_attribute_types_branches' }
2010                     )->get_column('code');
2011                 for my $type ( @required_attribute_types ) {
2012                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
2013                         type => $type,
2014                     ) if !$new_types->{$type};
2015                 }
2016             }
2017         );
2018     }
2019
2020     my $rs = $self->_result->borrower_attributes;
2021     # We call search to use the filters in Koha::Patron::Attributes->search
2022     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
2023 }
2024
2025 =head3 messages
2026
2027     my $messages = $patron->messages;
2028
2029 Return the message attached to the patron.
2030
2031 =cut
2032
2033 sub messages {
2034     my ( $self ) = @_;
2035     my $messages_rs = $self->_result->messages_borrowernumbers->search;
2036     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
2037 }
2038
2039 =head3 lock
2040
2041     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
2042
2043     Lock and optionally expire a patron account.
2044     Remove holds and article requests if remove flag set.
2045     In order to distinguish from locking by entering a wrong password, let's
2046     call this an administrative lockout.
2047
2048 =cut
2049
2050 sub lock {
2051     my ( $self, $params ) = @_;
2052     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
2053     if( $params->{expire} ) {
2054         $self->dateexpiry( dt_from_string->subtract(days => 1) );
2055     }
2056     $self->store;
2057     if( $params->{remove} ) {
2058         $self->holds->delete;
2059         $self->article_requests->delete;
2060     }
2061     return $self;
2062 }
2063
2064 =head3 anonymize
2065
2066     Koha::Patrons->find($id)->anonymize;
2067
2068     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
2069     are randomized, other personal data is cleared too.
2070     Patrons with issues are skipped.
2071
2072 =cut
2073
2074 sub anonymize {
2075     my ( $self ) = @_;
2076     if( $self->_result->issues->count ) {
2077         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
2078         return;
2079     }
2080     # Mandatory fields come from the corresponding pref, but email fields
2081     # are removed since scrambled email addresses only generate errors
2082     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
2083         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
2084     $mandatory->{userid} = 1; # needed since sub store does not clear field
2085     my @columns = $self->_result->result_source->columns;
2086     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
2087     push @columns, 'dateofbirth'; # add this date back in
2088     foreach my $col (@columns) {
2089         $self->_anonymize_column($col, $mandatory->{lc $col} );
2090     }
2091     $self->anonymized(1)->store;
2092 }
2093
2094 sub _anonymize_column {
2095     my ( $self, $col, $mandatory ) = @_;
2096     my $col_info = $self->_result->result_source->column_info($col);
2097     my $type = $col_info->{data_type};
2098     my $nullable = $col_info->{is_nullable};
2099     my $val;
2100     if( $type =~ /char|text/ ) {
2101         $val = $mandatory
2102             ? Koha::Token->new->generate({ pattern => '\w{10}' })
2103             : $nullable
2104             ? undef
2105             : q{};
2106     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
2107         $val = $nullable ? undef : 0;
2108     } elsif( $type =~ /date|time/ ) {
2109         $val = $nullable ? undef : dt_from_string;
2110     }
2111     $self->$col($val);
2112 }
2113
2114 =head3 add_guarantor
2115
2116     my $relationship = $patron->add_guarantor(
2117         {
2118             borrowernumber => $borrowernumber,
2119             relationships  => $relationship,
2120         }
2121     );
2122
2123     Adds a new guarantor to a patron.
2124
2125 =cut
2126
2127 sub add_guarantor {
2128     my ( $self, $params ) = @_;
2129
2130     my $guarantor_id = $params->{guarantor_id};
2131     my $relationship = $params->{relationship};
2132
2133     return Koha::Patron::Relationship->new(
2134         {
2135             guarantee_id => $self->id,
2136             guarantor_id => $guarantor_id,
2137             relationship => $relationship
2138         }
2139     )->store();
2140 }
2141
2142 =head3 get_extended_attribute
2143
2144 my $attribute_value = $patron->get_extended_attribute( $code );
2145
2146 Return the attribute for the code passed in parameter.
2147
2148 It not exist it returns undef
2149
2150 Note that this will not work for repeatable attribute types.
2151
2152 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
2153 (which should be a real patron's attribute (not extended)
2154
2155 =cut
2156
2157 sub get_extended_attribute {
2158     my ( $self, $code, $value ) = @_;
2159     my $rs = $self->_result->borrower_attributes;
2160     return unless $rs;
2161     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
2162     return unless $attribute->count;
2163     return $attribute->next;
2164 }
2165
2166 =head3 set_default_messaging_preferences
2167
2168     $patron->set_default_messaging_preferences
2169
2170 Sets default messaging preferences on patron.
2171
2172 See Koha::Patron::MessagePreference(s) for more documentation, especially on
2173 thrown exceptions.
2174
2175 =cut
2176
2177 sub set_default_messaging_preferences {
2178     my ($self, $categorycode) = @_;
2179
2180     my $options = Koha::Patron::MessagePreferences->get_options;
2181
2182     foreach my $option (@$options) {
2183         # Check that this option has preference configuration for this category
2184         unless (Koha::Patron::MessagePreferences->search({
2185             message_attribute_id => $option->{message_attribute_id},
2186             categorycode         => $categorycode || $self->categorycode,
2187         })->count) {
2188             next;
2189         }
2190
2191         # Delete current setting
2192         Koha::Patron::MessagePreferences->search({
2193              borrowernumber => $self->borrowernumber,
2194              message_attribute_id => $option->{message_attribute_id},
2195         })->delete;
2196
2197         Koha::Patron::MessagePreference->new_from_default({
2198             borrowernumber => $self->borrowernumber,
2199             categorycode   => $categorycode || $self->categorycode,
2200             message_attribute_id => $option->{message_attribute_id},
2201         });
2202     }
2203
2204     return $self;
2205 }
2206
2207 =head3 to_api
2208
2209     my $json = $patron->to_api;
2210
2211 Overloaded method that returns a JSON representation of the Koha::Patron object,
2212 suitable for API output.
2213
2214 =cut
2215
2216 sub to_api {
2217     my ( $self, $params ) = @_;
2218
2219     my $json_patron = $self->SUPER::to_api( $params );
2220
2221     $json_patron->{restricted} = ( $self->is_debarred )
2222                                     ? Mojo::JSON->true
2223                                     : Mojo::JSON->false;
2224
2225     return $json_patron;
2226 }
2227
2228 =head3 to_api_mapping
2229
2230 This method returns the mapping for representing a Koha::Patron object
2231 on the API.
2232
2233 =cut
2234
2235 sub to_api_mapping {
2236     return {
2237         borrowernotes       => 'staff_notes',
2238         borrowernumber      => 'patron_id',
2239         branchcode          => 'library_id',
2240         categorycode        => 'category_id',
2241         checkprevcheckout   => 'check_previous_checkout',
2242         contactfirstname    => undef,                     # Unused
2243         contactname         => undef,                     # Unused
2244         contactnote         => 'altaddress_notes',
2245         contacttitle        => undef,                     # Unused
2246         dateenrolled        => 'date_enrolled',
2247         dateexpiry          => 'expiry_date',
2248         dateofbirth         => 'date_of_birth',
2249         debarred            => undef,                     # replaced by 'restricted'
2250         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
2251         emailpro            => 'secondary_email',
2252         flags               => undef,    # permissions manipulation handled in /permissions
2253         gonenoaddress       => 'incorrect_address',
2254         lastseen            => 'last_seen',
2255         lost                => 'patron_card_lost',
2256         opacnote            => 'opac_notes',
2257         othernames          => 'other_name',
2258         password            => undef,            # password manipulation handled in /password
2259         phonepro            => 'secondary_phone',
2260         relationship        => 'relationship_type',
2261         sex                 => 'gender',
2262         smsalertnumber      => 'sms_number',
2263         sort1               => 'statistics_1',
2264         sort2               => 'statistics_2',
2265         autorenew_checkouts => 'autorenew_checkouts',
2266         streetnumber        => 'street_number',
2267         streettype          => 'street_type',
2268         zipcode             => 'postal_code',
2269         B_address           => 'altaddress_address',
2270         B_address2          => 'altaddress_address2',
2271         B_city              => 'altaddress_city',
2272         B_country           => 'altaddress_country',
2273         B_email             => 'altaddress_email',
2274         B_phone             => 'altaddress_phone',
2275         B_state             => 'altaddress_state',
2276         B_streetnumber      => 'altaddress_street_number',
2277         B_streettype        => 'altaddress_street_type',
2278         B_zipcode           => 'altaddress_postal_code',
2279         altcontactaddress1  => 'altcontact_address',
2280         altcontactaddress2  => 'altcontact_address2',
2281         altcontactaddress3  => 'altcontact_city',
2282         altcontactcountry   => 'altcontact_country',
2283         altcontactfirstname => 'altcontact_firstname',
2284         altcontactphone     => 'altcontact_phone',
2285         altcontactsurname   => 'altcontact_surname',
2286         altcontactstate     => 'altcontact_state',
2287         altcontactzipcode   => 'altcontact_postal_code',
2288         password_expiration_date => undef,
2289         primary_contact_method => undef,
2290         secret              => undef,
2291         auth_method         => undef,
2292     };
2293 }
2294
2295 =head3 queue_notice
2296
2297     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
2298     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
2299     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
2300
2301     Queue messages to a patron. Can pass a message that is part of the message_attributes
2302     table or supply the transport to use.
2303
2304     If passed a message name we retrieve the patrons preferences for transports
2305     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
2306     we have no address/number for sending
2307
2308     $letter_params is a hashref of the values to be passed to GetPreparedLetter
2309
2310     test_mode will only report which notices would be sent, but nothing will be queued
2311
2312 =cut
2313
2314 sub queue_notice {
2315     my ( $self, $params ) = @_;
2316     my $letter_params = $params->{letter_params};
2317     my $test_mode = $params->{test_mode};
2318
2319     return unless $letter_params;
2320     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
2321
2322     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
2323     my $from_email_address = $library->from_email_address;
2324
2325     my @message_transports;
2326     my $letter_code;
2327     $letter_code = $letter_params->{letter_code};
2328     if( $params->{message_name} ){
2329         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
2330                 borrowernumber => $letter_params->{borrowernumber},
2331                 message_name => $params->{message_name}
2332         } );
2333         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
2334         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
2335     } else {
2336         @message_transports = @{$params->{message_transports}};
2337     }
2338     return unless defined $letter_code;
2339     $letter_params->{letter_code} = $letter_code;
2340     my $print_sent = 0;
2341     my %return;
2342     foreach my $mtt (@message_transports){
2343         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2344         # Notice is handled by TalkingTech_itiva_outbound.pl
2345         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2346             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2347             or ( $mtt eq 'phone' and not $self->phone ) )
2348         {
2349             push @{ $return{fallback} }, $mtt;
2350             $mtt = 'print';
2351         }
2352         next if $mtt eq 'print' && $print_sent;
2353         $letter_params->{message_transport_type} = $mtt;
2354         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2355         C4::Letters::EnqueueLetter({
2356             letter => $letter,
2357             borrowernumber => $self->borrowernumber,
2358             from_address   => $from_email_address,
2359             message_transport_type => $mtt
2360         }) unless $test_mode;
2361         push @{$return{sent}}, $mtt;
2362         $print_sent = 1 if $mtt eq 'print';
2363     }
2364     return \%return;
2365 }
2366
2367 =head3 safe_to_delete
2368
2369     my $result = $patron->safe_to_delete;
2370     if ( $result eq 'has_guarantees' ) { ... }
2371     elsif ( $result ) { ... }
2372     else { # cannot delete }
2373
2374 This method tells if the Koha:Patron object can be deleted. Possible return values
2375
2376 =over 4
2377
2378 =item 'ok'
2379
2380 =item 'has_checkouts'
2381
2382 =item 'has_debt'
2383
2384 =item 'has_guarantees'
2385
2386 =item 'is_anonymous_patron'
2387
2388 =back
2389
2390 =cut
2391
2392 sub safe_to_delete {
2393     my ($self) = @_;
2394
2395     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2396
2397     my $error;
2398
2399     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2400         $error = 'is_anonymous_patron';
2401     }
2402     elsif ( $self->checkouts->count ) {
2403         $error = 'has_checkouts';
2404     }
2405     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2406         $error = 'has_debt';
2407     }
2408     elsif ( $self->guarantee_relationships->count ) {
2409         $error = 'has_guarantees';
2410     }
2411
2412     if ( $error ) {
2413         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2414     }
2415
2416     return Koha::Result::Boolean->new(1);
2417 }
2418
2419 =head3 recalls
2420
2421     my $recalls = $patron->recalls;
2422
2423 Return the patron's recalls.
2424
2425 =cut
2426
2427 sub recalls {
2428     my ( $self ) = @_;
2429
2430     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2431 }
2432
2433 =head3 account_balance
2434
2435     my $balance = $patron->account_balance
2436
2437 Return the patron's account balance
2438
2439 =cut
2440
2441 sub account_balance {
2442     my ($self) = @_;
2443     return $self->account->balance;
2444 }
2445
2446 =head3 notify_library_of_registration
2447
2448 $patron->notify_library_of_registration( $email_patron_registrations );
2449
2450 Send patron registration email to library if EmailPatronRegistrations system preference is enabled.
2451
2452 =cut
2453
2454 sub notify_library_of_registration {
2455     my ( $self, $email_patron_registrations ) = @_;
2456
2457     if (
2458         my $letter = C4::Letters::GetPreparedLetter(
2459             module      => 'members',
2460             letter_code => 'OPAC_REG',
2461             branchcode  => $self->branchcode,
2462             lang        => $self->lang || 'default',
2463             tables      => {
2464                 'borrowers' => $self->borrowernumber
2465             },
2466         )
2467     ) {
2468         my $to_address;
2469         if ( $email_patron_registrations eq "BranchEmailAddress" ) {
2470             my $library = Koha::Libraries->find( $self->branchcode );
2471             $to_address = $library->inbound_email_address;
2472         }
2473         elsif ( $email_patron_registrations eq "KohaAdminEmailAddress" ) {
2474             $to_address = C4::Context->preference('ReplytoDefault')
2475             || C4::Context->preference('KohaAdminEmailAddress');
2476         }
2477         else {
2478             $to_address =
2479                 C4::Context->preference('EmailAddressForPatronRegistrations')
2480                 || C4::Context->preference('ReplytoDefault')
2481                 || C4::Context->preference('KohaAdminEmailAddress');
2482         }
2483
2484         my $message_id = C4::Letters::EnqueueLetter(
2485             {
2486                 letter                 => $letter,
2487                 borrowernumber         => $self->borrowernumber,
2488                 to_address             => $to_address,
2489                 message_transport_type => 'email'
2490             }
2491         ) or warn "can't enqueue letter $letter";
2492         if ( $message_id ) {
2493             return 1;
2494         }
2495     }
2496 }
2497
2498 =head3 has_messaging_preference
2499
2500 my $bool = $patron->has_messaging_preference({
2501     message_name => $message_name, # A value from message_attributes.message_name
2502     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2503     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2504 });
2505
2506 =cut
2507
2508 sub has_messaging_preference {
2509     my ( $self, $params ) = @_;
2510
2511     my $message_name           = $params->{message_name};
2512     my $message_transport_type = $params->{message_transport_type};
2513     my $wants_digest           = $params->{wants_digest};
2514
2515     return $self->_result->search_related_rs(
2516         'borrower_message_preferences',
2517         $params,
2518         {
2519             prefetch =>
2520               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2521         }
2522     )->count;
2523 }
2524
2525 =head3 can_patron_change_staff_only_lists
2526
2527 $patron->can_patron_change_staff_only_lists;
2528
2529 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2530 Otherwise, return 0.
2531
2532 =cut
2533
2534 sub can_patron_change_staff_only_lists {
2535     my ( $self, $params ) = @_;
2536     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2537     return 0;
2538 }
2539
2540 =head3 can_patron_change_permitted_staff_lists
2541
2542 $patron->can_patron_change_permitted_staff_lists;
2543
2544 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' and 'edit_public_list_contents' permissions.
2545 Otherwise, return 0.
2546
2547 =cut
2548
2549 sub can_patron_change_permitted_staff_lists {
2550     my ( $self, $params ) = @_;
2551     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1, lists => 'edit_public_list_contents' } );
2552     return 0;
2553 }
2554
2555 =head3 encode_secret
2556
2557   $patron->encode_secret($secret32);
2558
2559 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2560 You still need to call ->store.
2561
2562 =cut
2563
2564 sub encode_secret {
2565     my ( $self, $secret ) = @_;
2566     if( $secret ) {
2567         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2568     }
2569     return $self->secret($secret);
2570 }
2571
2572 =head3 decoded_secret
2573
2574   my $secret32 = $patron->decoded_secret;
2575
2576 Decode the patron secret. We expect to get back a base32 string, but this
2577 is not checked here. Caller of encode_secret is responsible for that.
2578
2579 =cut
2580
2581 sub decoded_secret {
2582     my ( $self ) = @_;
2583     if( $self->secret ) {
2584         return Koha::Encryption->new->decrypt_hex( $self->secret );
2585     }
2586     return $self->secret;
2587 }
2588
2589 =head3 virtualshelves
2590
2591     my $shelves = $patron->virtualshelves;
2592
2593 =cut
2594
2595 sub virtualshelves {
2596     my $self = shift;
2597     return Koha::Virtualshelves->_new_from_dbic( scalar $self->_result->virtualshelves );
2598 }
2599
2600 =head3 get_savings
2601
2602     my $savings = $patron->get_savings;
2603
2604 Use the replacement price of patron's old and current issues to calculate how much they have 'saved' by using the library.
2605
2606 =cut
2607
2608 sub get_savings {
2609     my ($self) = @_;
2610
2611     my @itemnumbers = grep { defined $_ } ( $self->old_checkouts->get_column('itemnumber'), $self->checkouts->get_column('itemnumber') );
2612
2613     return Koha::Items->search(
2614         { itemnumber => { -in => \@itemnumbers } },
2615         {   select => [ { sum => 'me.replacementprice' } ],
2616             as     => ['total_savings']
2617         }
2618     )->next->get_column('total_savings') // 0;
2619 }
2620
2621 =head2 Internal methods
2622
2623 =head3 _type
2624
2625 =cut
2626
2627 sub _type {
2628     return 'Borrower';
2629 }
2630
2631 =head1 AUTHORS
2632
2633 Kyle M Hall <kyle@bywatersolutions.com>
2634 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2635 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2636
2637 =cut
2638
2639 1;