Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Context;
  29 use C4::Log qw( logaction );
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use C4::Letters;
  33 use Koha::AuthUtils;
  34 use Koha::Checkouts;
  35 use Koha::CirculationRules;
  36 use Koha::Club::Enrollments;
  37 use Koha::Database;
  38 use Koha::DateUtils qw( dt_from_string );
  39 use Koha::Encryption;
  40 use Koha::Exceptions::Password;
  41 use Koha::Holds;
  42 use Koha::Old::Checkouts;
  43 use Koha::Patron::Attributes;
  44 use Koha::Patron::Categories;
  45 use Koha::Patron::Debarments;
  46 use Koha::Patron::HouseboundProfile;
  47 use Koha::Patron::HouseboundRole;
  48 use Koha::Patron::Images;
  49 use Koha::Patron::Messages;
  50 use Koha::Patron::Modifications;
  51 use Koha::Patron::Relationships;
  52 use Koha::Patrons;
  53 use Koha::Plugins;
  54 use Koha::Recalls;
  55 use Koha::Result::Boolean;
  56 use Koha::Subscription::Routinglists;
  57 use Koha::Token;
  58 use Koha::Virtualshelves;
  59
  60 use base qw(Koha::Object);
  61
  62 use constant ADMINISTRATIVE_LOCKOUT => -1;
  63
  64 our $RESULTSET_PATRON_ID_MAPPING = {
  65     Accountline          => 'borrowernumber',
  66     Aqbasketuser         => 'borrowernumber',
  67     Aqbudget             => 'budget_owner_id',
  68     Aqbudgetborrower     => 'borrowernumber',
  69     ArticleRequest       => 'borrowernumber',
  70     BorrowerDebarment    => 'borrowernumber',
  71     BorrowerFile         => 'borrowernumber',
  72     BorrowerModification => 'borrowernumber',
  73     ClubEnrollment       => 'borrowernumber',
  74     Issue                => 'borrowernumber',
  75     ItemsLastBorrower    => 'borrowernumber',
  76     Linktracker          => 'borrowernumber',
  77     Message              => 'borrowernumber',
  78     MessageQueue         => 'borrowernumber',
  79     OldIssue             => 'borrowernumber',
  80     OldReserve           => 'borrowernumber',
  81     Rating               => 'borrowernumber',
  82     Reserve              => 'borrowernumber',
  83     Review               => 'borrowernumber',
  84     SearchHistory        => 'userid',
  85     Statistic            => 'borrowernumber',
  86     Suggestion           => 'suggestedby',
  87     TagAll               => 'borrowernumber',
  88     Virtualshelfcontent  => 'borrowernumber',
  89     Virtualshelfshare    => 'borrowernumber',
  90     Virtualshelve        => 'owner',
  91 };
  92
  93 =head1 NAME
  94
  95 Koha::Patron - Koha Patron Object class
  96
  97 =head1 API
  98
  99 =head2 Class Methods
 100
 101 =head3 new
 102
 103 =cut
 104
 105 sub new {
 106     my ( $class, $params ) = @_;
 107
 108     return $class->SUPER::new($params);
 109 }
 110
 111 =head3 fixup_cardnumber
 112
 113 Autogenerate next cardnumber from highest value found in database
 114
 115 =cut
 116
 117 sub fixup_cardnumber {
 118     my ( $self ) = @_;
 119
 120     my $max = $self->cardnumber;
 121     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 122
 123     $max ||= Koha::Patrons->search({
 124         cardnumber => {-regexp => '^-?[0-9]+$'}
 125     }, {
 126         select => \'CAST(cardnumber AS SIGNED)',
 127         as => ['cast_cardnumber']
 128     })->_resultset->get_column('cast_cardnumber')->max;
 129     $self->cardnumber(($max || 0) +1);
 130 }
 131
 132 =head3 trim_whitespace
 133
 134 trim whitespace from data which has some non-whitespace in it.
 135 Could be moved to Koha::Object if need to be reused
 136
 137 =cut
 138
 139 sub trim_whitespaces {
 140     my( $self ) = @_;
 141
 142     my $schema  = Koha::Database->new->schema;
 143     my @columns = $schema->source($self->_type)->columns;
 144
 145     for my $column( @columns ) {
 146         my $value = $self->$column;
 147         if ( defined $value ) {
 148             $value =~ s/^\s*|\s*$//g;
 149             $self->$column($value);
 150         }
 151     }
 152     return $self;
 153 }
 154
 155 =head3 plain_text_password
 156
 157 $patron->plain_text_password( $password );
 158
 159 stores a copy of the unencrypted password in the object
 160 for use in code before encrypting for db
 161
 162 =cut
 163
 164 sub plain_text_password {
 165     my ( $self, $password ) = @_;
 166     if ( $password ) {
 167         $self->{_plain_text_password} = $password;
 168         return $self;
 169     }
 170     return $self->{_plain_text_password}
 171         if $self->{_plain_text_password};
 172
 173     return;
 174 }
 175
 176 =head3 store
 177
 178 Patron specific store method to cleanup record
 179 and do other necessary things before saving
 180 to db
 181
 182 =cut
 183
 184 sub store {
 185     my ($self) = @_;
 186
 187     $self->_result->result_source->schema->txn_do(
 188         sub {
 189             if (
 190                 C4::Context->preference("autoMemberNum")
 191                 and ( not defined $self->cardnumber
 192                     or $self->cardnumber eq '' )
 193               )
 194             {
 195                 # Warning: The caller is responsible for locking the members table in write
 196                 # mode, to avoid database corruption.
 197                 # We are in a transaction but the table is not locked
 198                 $self->fixup_cardnumber;
 199             }
 200
 201             unless( $self->category->in_storage ) {
 202                 Koha::Exceptions::Object::FKConstraint->throw(
 203                     broken_fk => 'categorycode',
 204                     value     => $self->categorycode,
 205                 );
 206             }
 207
 208             $self->trim_whitespaces;
 209
 210             my $new_cardnumber = $self->cardnumber;
 211             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 212             $self->cardnumber( $new_cardnumber );
 213
 214             # Set surname to uppercase if uppercasesurname is true
 215             $self->surname( uc($self->surname) )
 216                 if C4::Context->preference("uppercasesurnames");
 217
 218             $self->relationship(undef) # We do not want to store an empty string in this field
 219               if defined $self->relationship
 220                      and $self->relationship eq "";
 221
 222             unless ( $self->in_storage ) {    #AddMember
 223
 224                 # Generate a valid userid/login if needed
 225                 $self->generate_userid
 226                   if not $self->userid or not $self->has_valid_userid;
 227
 228                 # Add expiration date if it isn't already there
 229                 unless ( $self->dateexpiry ) {
 230                     $self->dateexpiry( $self->category->get_expiry_date );
 231                 }
 232
 233                 # Add enrollment date if it isn't already there
 234                 unless ( $self->dateenrolled ) {
 235                     $self->dateenrolled(dt_from_string);
 236                 }
 237
 238                 # Set the privacy depending on the patron's category
 239                 my $default_privacy = $self->category->default_privacy || q{};
 240                 $default_privacy =
 241                     $default_privacy eq 'default' ? 1
 242                   : $default_privacy eq 'never'   ? 2
 243                   : $default_privacy eq 'forever' ? 0
 244                   :                                                   undef;
 245                 $self->privacy($default_privacy);
 246
 247                 # Call any check_password plugins if password is passed
 248                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 249                     my @plugins = Koha::Plugins->new()->GetPlugins({
 250                         method => 'check_password',
 251                     });
 252                     foreach my $plugin ( @plugins ) {
 253                         # This plugin hook will also be used by a plugin for the Norwegian national
 254                         # patron database. This is why we need to pass both the password and the
 255                         # borrowernumber to the plugin.
 256                         my $ret = $plugin->check_password(
 257                             {
 258                                 password       => $self->password,
 259                                 borrowernumber => $self->borrowernumber
 260                             }
 261                         );
 262                         if ( $ret->{'error'} == 1 ) {
 263                             Koha::Exceptions::Password::Plugin->throw();
 264                         }
 265                     }
 266                 }
 267
 268                 # Make a copy of the plain text password for later use
 269                 $self->plain_text_password( $self->password );
 270
 271                 $self->password_expiration_date( $self->password
 272                     ? $self->category->get_password_expiry_date || undef
 273                     : undef );
 274                 # Create a disabled account if no password provided
 275                 $self->password( $self->password
 276                     ? Koha::AuthUtils::hash_password( $self->password )
 277                     : '!' );
 278
 279                 $self->borrowernumber(undef);
 280
 281                 $self = $self->SUPER::store;
 282
 283                 $self->add_enrolment_fee_if_needed(0);
 284
 285                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 286                   if C4::Context->preference("BorrowersLog");
 287             }
 288             else {    #ModMember
 289
 290                 my $self_from_storage = $self->get_from_storage;
 291                 # FIXME We should not deal with that here, callers have to do this job
 292                 # Moved from ModMember to prevent regressions
 293                 unless ( $self->userid ) {
 294                     my $stored_userid = $self_from_storage->userid;
 295                     $self->userid($stored_userid);
 296                 }
 297
 298                 # Password must be updated using $self->set_password
 299                 $self->password($self_from_storage->password);
 300
 301                 if ( $self->category->categorycode ne
 302                     $self_from_storage->category->categorycode )
 303                 {
 304                     # Add enrolement fee on category change if required
 305                     $self->add_enrolment_fee_if_needed(1)
 306                       if C4::Context->preference('FeeOnChangePatronCategory');
 307
 308                     # Clean up guarantors on category change if required
 309                     $self->guarantor_relationships->delete
 310                       unless ( $self->category->can_be_guarantee );
 311
 312                 }
 313
 314                 # Actionlogs
 315                 if ( C4::Context->preference("BorrowersLog") ) {
 316                     my $info;
 317                     my $from_storage = $self_from_storage->unblessed;
 318                     my $from_object  = $self->unblessed;
 319                     my @skip_fields  = (qw/lastseen updated_on/);
 320                     for my $key ( keys %{$from_storage} ) {
 321                         next if any { /$key/ } @skip_fields;
 322                         if (
 323                             (
 324                                   !defined( $from_storage->{$key} )
 325                                 && defined( $from_object->{$key} )
 326                             )
 327                             || ( defined( $from_storage->{$key} )
 328                                 && !defined( $from_object->{$key} ) )
 329                             || (
 330                                    defined( $from_storage->{$key} )
 331                                 && defined( $from_object->{$key} )
 332                                 && ( $from_storage->{$key} ne
 333                                     $from_object->{$key} )
 334                             )
 335                           )
 336                         {
 337                             $info->{$key} = {
 338                                 before => $from_storage->{$key},
 339                                 after  => $from_object->{$key}
 340                             };
 341                         }
 342                     }
 343
 344                     if ( defined($info) ) {
 345                         logaction(
 346                             "MEMBERS",
 347                             "MODIFY",
 348                             $self->borrowernumber,
 349                             to_json(
 350                                 $info,
 351                                 { utf8 => 1, pretty => 1, canonical => 1 }
 352                             )
 353                         );
 354                     }
 355                 }
 356
 357                 # Final store
 358                 $self = $self->SUPER::store;
 359             }
 360         }
 361     );
 362     return $self;
 363 }
 364
 365 =head3 delete
 366
 367 $patron->delete
 368
 369 Delete patron's holds, lists and finally the patron.
 370
 371 Lists owned by the borrower are deleted or ownership is transfered depending on the
 372 ListOwnershipUponPatronDeletion pref, but entries from the borrower to other lists are kept.
 373
 374 =cut
 375
 376 sub delete {
 377     my ($self) = @_;
 378
 379     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 380     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 381
 382     $self->_result->result_source->schema->txn_do(
 383         sub {
 384             # Cancel Patron's holds
 385             my $holds = $self->holds;
 386             while( my $hold = $holds->next ){
 387                 $hold->cancel;
 388             }
 389
 390             # FIXME Could be $patron->get_lists
 391             # If ListOwnershipUponPatronDeletion = transfer, change ownership of all
 392             # public and shared lists to the user who deleted them.
 393             if ( C4::Context->preference('ListOwnershipUponPatronDeletion') eq 'transfer' ) {
 394                 my $userenv = C4::Context->userenv();
 395                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : 0;
 396                 my @publiclists = Koha::Virtualshelves->get_public_shelves;
 397                 my @sharedlists = Koha::Virtualshelves->get_shared_shelves({ borrowernumber => $self->borrowernumber });
 398                 foreach my $plist ( @publiclists ) {
 399                     if ( $plist->owner == $self->borrowernumber ) {
 400                         my $unique_name = $plist->shelfname . '_' . $self->borrowernumber;
 401                         $plist->set({ owner => $usernumber, shelfname => $unique_name })->store;
 402                     }
 403                 }
 404                 foreach my $slist ( @sharedlists ) {
 405                     my $unique_name = $slist->shelfname . '_' . $self->borrowernumber;
 406                     $slist->set({ owner => $usernumber, shelfname => $unique_name })->store;
 407                     # if staff member had a share, remove it
 408                     $slist->remove_share( $usernumber );
 409                 }
 410             }
 411
 412             # Delete any remaining lists that this user is an owner of (always private lists,
 413             # only public and shared lists if ListOwnershipUponPatronDeletion = delete)
 414             $_->delete for Koha::Virtualshelves->search({ owner => $self->borrowernumber });
 415
 416             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 417             # for patron selfreg
 418             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 419
 420             $self->SUPER::delete;
 421
 422             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 423         }
 424     );
 425     return $self;
 426 }
 427
 428
 429 =head3 category
 430
 431 my $patron_category = $patron->category
 432
 433 Return the patron category for this patron
 434
 435 =cut
 436
 437 sub category {
 438     my ( $self ) = @_;
 439     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 440 }
 441
 442 =head3 image
 443
 444 =cut
 445
 446 sub image {
 447     my ( $self ) = @_;
 448
 449     return Koha::Patron::Images->find( $self->borrowernumber );
 450 }
 451
 452 =head3 library
 453
 454 Returns a Koha::Library object representing the patron's home library.
 455
 456 =cut
 457
 458 sub library {
 459     my ( $self ) = @_;
 460     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 461 }
 462
 463 =head3 sms_provider
 464
 465 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 466
 467 =cut
 468
 469 sub sms_provider {
 470     my ( $self ) = @_;
 471     my $sms_provider_rs = $self->_result->sms_provider;
 472     return unless $sms_provider_rs;
 473     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 474 }
 475
 476 =head3 guarantor_relationships
 477
 478 Returns Koha::Patron::Relationships object for this patron's guarantors
 479
 480 Returns the set of relationships for the patrons that are guarantors for this patron.
 481
 482 This is returned instead of a Koha::Patron object because the guarantor
 483 may not exist as a patron in Koha. If this is true, the guarantors name
 484 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 485
 486 =cut
 487
 488 sub guarantor_relationships {
 489     my ($self) = @_;
 490
 491     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 492 }
 493
 494 =head3 guarantee_relationships
 495
 496 Returns Koha::Patron::Relationships object for this patron's guarantors
 497
 498 Returns the set of relationships for the patrons that are guarantees for this patron.
 499
 500 The method returns Koha::Patron::Relationship objects for the sake
 501 of consistency with the guantors method.
 502 A guarantee by definition must exist as a patron in Koha.
 503
 504 =cut
 505
 506 sub guarantee_relationships {
 507     my ($self) = @_;
 508
 509     return Koha::Patron::Relationships->search(
 510         { guarantor_id => $self->id },
 511         {
 512             prefetch => 'guarantee',
 513             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 514         }
 515     );
 516 }
 517
 518 =head3 relationships_debt
 519
 520 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 521
 522 =cut
 523
 524 sub relationships_debt {
 525     my ($self, $params) = @_;
 526
 527     my $include_guarantors  = $params->{include_guarantors};
 528     my $only_this_guarantor = $params->{only_this_guarantor};
 529     my $include_this_patron = $params->{include_this_patron};
 530
 531     my @guarantors;
 532     if ( $only_this_guarantor ) {
 533         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 534         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 535     } elsif ( $self->guarantor_relationships->count ) {
 536         # I am a guarantee, just get all my guarantors
 537         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 538     } else {
 539         # I am a guarantor, I need to get all the guarantors of all my guarantees
 540         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 541     }
 542
 543     my $non_issues_charges = 0;
 544     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 545     foreach my $guarantor (@guarantors) {
 546         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 547
 548         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 549         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 550         my $guarantees_non_issues_charges = 0;
 551         foreach my $guarantee (@guarantees) {
 552             next if $seen->{ $guarantee->id };
 553             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 554             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 555             $seen->{ $guarantee->id } = 1;
 556         }
 557
 558         $non_issues_charges += $guarantees_non_issues_charges;
 559         $seen->{ $guarantor->id } = 1;
 560     }
 561
 562     return $non_issues_charges;
 563 }
 564
 565 =head3 housebound_profile
 566
 567 Returns the HouseboundProfile associated with this patron.
 568
 569 =cut
 570
 571 sub housebound_profile {
 572     my ( $self ) = @_;
 573     my $profile = $self->_result->housebound_profile;
 574     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 575         if ( $profile );
 576     return;
 577 }
 578
 579 =head3 housebound_role
 580
 581 Returns the HouseboundRole associated with this patron.
 582
 583 =cut
 584
 585 sub housebound_role {
 586     my ( $self ) = @_;
 587
 588     my $role = $self->_result->housebound_role;
 589     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 590     return;
 591 }
 592
 593 =head3 siblings
 594
 595 Returns the siblings of this patron.
 596
 597 =cut
 598
 599 sub siblings {
 600     my ($self) = @_;
 601
 602     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 603
 604     return unless @guarantors;
 605
 606     my @siblings =
 607       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 608
 609     return unless @siblings;
 610
 611     my %seen;
 612     @siblings =
 613       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 614
 615     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 616 }
 617
 618 =head3 merge_with
 619
 620     my $patron = Koha::Patrons->find($id);
 621     $patron->merge_with( \@patron_ids );
 622
 623     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 624     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 625     of the keeper patron.
 626
 627 =cut
 628
 629 sub merge_with {
 630     my ( $self, $patron_ids ) = @_;
 631
 632     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 633     return if $anonymous_patron && $self->id eq $anonymous_patron;
 634
 635     my @patron_ids = @{ $patron_ids };
 636
 637     # Ensure the keeper isn't in the list of patrons to merge
 638     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 639
 640     my $schema = Koha::Database->new()->schema();
 641
 642     my $results;
 643
 644     $self->_result->result_source->schema->txn_do( sub {
 645         foreach my $patron_id (@patron_ids) {
 646
 647             next if $patron_id eq $anonymous_patron;
 648
 649             my $patron = Koha::Patrons->find( $patron_id );
 650
 651             next unless $patron;
 652
 653             # Unbless for safety, the patron will end up being deleted
 654             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 655
 656             my $attributes = $patron->extended_attributes;
 657             my $new_attributes = [
 658                 map { { code => $_->code, attribute => $_->attribute } }
 659                     $attributes->as_list
 660             ];
 661             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 662             for my $attribute ( @$new_attributes ) {
 663                 try {
 664                     $self->add_extended_attribute($attribute);
 665                 } catch {
 666                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 667                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 668                         $_->rethrow;
 669                     }
 670                 };
 671             }
 672
 673             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 674                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 675                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 676                 $rs->update({ $field => $self->id });
 677                 if ( $r eq 'BorrowerDebarment' ) {
 678                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 679                 }
 680             }
 681
 682             $patron->move_to_deleted();
 683             $patron->delete();
 684         }
 685     });
 686
 687     return $results;
 688 }
 689
 690
 691
 692 =head3 wants_check_for_previous_checkout
 693
 694     $wants_check = $patron->wants_check_for_previous_checkout;
 695
 696 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 697
 698 =cut
 699
 700 sub wants_check_for_previous_checkout {
 701     my ( $self ) = @_;
 702     my $syspref = C4::Context->preference("checkPrevCheckout");
 703
 704     # Simple cases
 705     ## Hard syspref trumps all
 706     return 1 if ($syspref eq 'hardyes');
 707     return 0 if ($syspref eq 'hardno');
 708     ## Now, patron pref trumps all
 709     return 1 if ($self->checkprevcheckout eq 'yes');
 710     return 0 if ($self->checkprevcheckout eq 'no');
 711
 712     # More complex: patron inherits -> determine category preference
 713     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 714     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 715     return 0 if ($checkPrevCheckoutByCat eq 'no');
 716
 717     # Finally: category preference is inherit, default to 0
 718     if ($syspref eq 'softyes') {
 719         return 1;
 720     } else {
 721         return 0;
 722     }
 723 }
 724
 725 =head3 do_check_for_previous_checkout
 726
 727     $do_check = $patron->do_check_for_previous_checkout($item);
 728
 729 Return 1 if the bib associated with $ITEM has previously been checked out to
 730 $PATRON, 0 otherwise.
 731
 732 =cut
 733
 734 sub do_check_for_previous_checkout {
 735     my ( $self, $item ) = @_;
 736
 737     my @item_nos;
 738     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 739     if ( $biblio->is_serial ) {
 740         push @item_nos, $item->{itemnumber};
 741     } else {
 742         # Get all itemnumbers for given bibliographic record.
 743         @item_nos = $biblio->items->get_column( 'itemnumber' );
 744     }
 745
 746     # Create (old)issues search criteria
 747     my $criteria = {
 748         borrowernumber => $self->borrowernumber,
 749         itemnumber => \@item_nos,
 750     };
 751
 752     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 753     if ($delay) {
 754         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 755         my $newer_than = dt_from_string()->subtract( days => $delay );
 756         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 757     }
 758
 759     # Check current issues table
 760     my $issues = Koha::Checkouts->search($criteria);
 761     return 1 if $issues->count; # 0 || N
 762
 763     # Check old issues table
 764     my $old_issues = Koha::Old::Checkouts->search($criteria);
 765     return $old_issues->count;  # 0 || N
 766 }
 767
 768 =head3 is_debarred
 769
 770 my $debarment_expiration = $patron->is_debarred;
 771
 772 Returns the date a patron debarment will expire, or undef if the patron is not
 773 debarred
 774
 775 =cut
 776
 777 sub is_debarred {
 778     my ($self) = @_;
 779
 780     return unless $self->debarred;
 781     return $self->debarred
 782       if $self->debarred =~ '^9999'
 783       or dt_from_string( $self->debarred ) > dt_from_string;
 784     return;
 785 }
 786
 787 =head3 is_expired
 788
 789 my $is_expired = $patron->is_expired;
 790
 791 Returns 1 if the patron is expired or 0;
 792
 793 =cut
 794
 795 sub is_expired {
 796     my ($self) = @_;
 797     return 0 unless $self->dateexpiry;
 798     return 0 if $self->dateexpiry =~ '^9999';
 799     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 800     return 0;
 801 }
 802
 803 =head3 password_expired
 804
 805 my $password_expired = $patron->password_expired;
 806
 807 Returns 1 if the patron's password is expired or 0;
 808
 809 =cut
 810
 811 sub password_expired {
 812     my ($self) = @_;
 813     return 0 unless $self->password_expiration_date;
 814     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 815     return 0;
 816 }
 817
 818 =head3 is_going_to_expire
 819
 820 my $is_going_to_expire = $patron->is_going_to_expire;
 821
 822 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 823
 824 =cut
 825
 826 sub is_going_to_expire {
 827     my ($self) = @_;
 828
 829     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 830
 831     return 0 unless $delay;
 832     return 0 unless $self->dateexpiry;
 833     return 0 if $self->dateexpiry =~ '^9999';
 834     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 835     return 0;
 836 }
 837
 838 =head3 set_password
 839
 840     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 841
 842 Set the patron's password.
 843
 844 =head4 Exceptions
 845
 846 The passed string is validated against the current password enforcement policy.
 847 Validation can be skipped by passing the I<skip_validation> parameter.
 848
 849 Exceptions are thrown if the password is not good enough.
 850
 851 =over 4
 852
 853 =item Koha::Exceptions::Password::TooShort
 854
 855 =item Koha::Exceptions::Password::WhitespaceCharacters
 856
 857 =item Koha::Exceptions::Password::TooWeak
 858
 859 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 860
 861 =back
 862
 863 =cut
 864
 865 sub set_password {
 866     my ( $self, $args ) = @_;
 867
 868     my $password = $args->{password};
 869
 870     unless ( $args->{skip_validation} ) {
 871         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 872
 873         if ( !$is_valid ) {
 874             if ( $error eq 'too_short' ) {
 875                 my $min_length = $self->category->effective_min_password_length;
 876                 $min_length = 3 if not $min_length or $min_length < 3;
 877
 878                 my $password_length = length($password);
 879                 Koha::Exceptions::Password::TooShort->throw(
 880                     length => $password_length, min_length => $min_length );
 881             }
 882             elsif ( $error eq 'has_whitespaces' ) {
 883                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 884             }
 885             elsif ( $error eq 'too_weak' ) {
 886                 Koha::Exceptions::Password::TooWeak->throw();
 887             }
 888         }
 889     }
 890
 891     if ( C4::Context->config("enable_plugins") ) {
 892         # Call any check_password plugins
 893         my @plugins = Koha::Plugins->new()->GetPlugins({
 894             method => 'check_password',
 895         });
 896         foreach my $plugin ( @plugins ) {
 897             # This plugin hook will also be used by a plugin for the Norwegian national
 898             # patron database. This is why we need to pass both the password and the
 899             # borrowernumber to the plugin.
 900             my $ret = $plugin->check_password(
 901                 {
 902                     password       => $password,
 903                     borrowernumber => $self->borrowernumber
 904                 }
 905             );
 906             # This plugin hook will also be used by a plugin for the Norwegian national
 907             # patron database. This is why we need to call the actual plugins and then
 908             # check skip_validation afterwards.
 909             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 910                 Koha::Exceptions::Password::Plugin->throw();
 911             }
 912         }
 913     }
 914
 915     my $digest = Koha::AuthUtils::hash_password($password);
 916
 917     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 918
 919     # We do not want to call $self->store and retrieve password from DB
 920     $self->password($digest);
 921     $self->login_attempts(0);
 922     $self->SUPER::store;
 923
 924     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 925         if C4::Context->preference("BorrowersLog");
 926
 927     return $self;
 928 }
 929
 930
 931 =head3 renew_account
 932
 933 my $new_expiry_date = $patron->renew_account
 934
 935 Extending the subscription to the expiry date.
 936
 937 =cut
 938
 939 sub renew_account {
 940     my ($self) = @_;
 941     my $date;
 942     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 943         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 944     } else {
 945         $date =
 946             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 947             ? dt_from_string( $self->dateexpiry )
 948             : dt_from_string;
 949     }
 950     my $expiry_date = $self->category->get_expiry_date($date);
 951
 952     $self->dateexpiry($expiry_date);
 953     $self->date_renewed( dt_from_string() );
 954     $self->store();
 955
 956     $self->add_enrolment_fee_if_needed(1);
 957
 958     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 959     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 960 }
 961
 962 =head3 has_overdues
 963
 964 my $has_overdues = $patron->has_overdues;
 965
 966 Returns the number of patron's overdues
 967
 968 =cut
 969
 970 sub has_overdues {
 971     my ($self) = @_;
 972     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 973     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 974 }
 975
 976 =head3 track_login
 977
 978     $patron->track_login;
 979     $patron->track_login({ force => 1 });
 980
 981     Tracks a (successful) login attempt.
 982     The preference TrackLastPatronActivity must be enabled. Or you
 983     should pass the force parameter.
 984
 985 =cut
 986
 987 sub track_login {
 988     my ( $self, $params ) = @_;
 989     return if
 990         !$params->{force} &&
 991         !C4::Context->preference('TrackLastPatronActivity');
 992     $self->lastseen( dt_from_string() )->store;
 993 }
 994
 995 =head3 move_to_deleted
 996
 997 my $is_moved = $patron->move_to_deleted;
 998
 999 Move a patron to the deletedborrowers table.
1000 This can be done before deleting a patron, to make sure the data are not completely deleted.
1001
1002 =cut
1003
1004 sub move_to_deleted {
1005     my ($self) = @_;
1006     my $patron_infos = $self->unblessed;
1007     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
1008     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
1009 }
1010
1011 =head3 can_request_article
1012
1013     if ( $patron->can_request_article( $library->id ) ) { ... }
1014
1015 Returns true if the patron can request articles. As limits apply for the patron
1016 on the same day, those completed the same day are considered as current.
1017
1018 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1019
1020 =cut
1021
1022 sub can_request_article {
1023     my ($self, $library_id) = @_;
1024
1025     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1026
1027     my $rule = Koha::CirculationRules->get_effective_rule(
1028         {
1029             branchcode   => $library_id,
1030             categorycode => $self->categorycode,
1031             rule_name    => 'open_article_requests_limit'
1032         }
1033     );
1034
1035     my $limit = ($rule) ? $rule->rule_value : undef;
1036
1037     return 1 unless defined $limit;
1038
1039     my $count = Koha::ArticleRequests->search(
1040         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1041             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1042         ]
1043     )->count;
1044     return $count < $limit ? 1 : 0;
1045 }
1046
1047 =head3 article_request_fee
1048
1049     my $fee = $patron->article_request_fee(
1050         {
1051           [ library_id => $library->id, ]
1052         }
1053     );
1054
1055 Returns the fee to be charged to the patron when it places an article request.
1056
1057 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1058
1059 =cut
1060
1061 sub article_request_fee {
1062     my ($self, $params) = @_;
1063
1064     my $library_id = $params->{library_id};
1065
1066     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1067
1068     my $rule = Koha::CirculationRules->get_effective_rule(
1069         {
1070             branchcode   => $library_id,
1071             categorycode => $self->categorycode,
1072             rule_name    => 'article_request_fee'
1073         }
1074     );
1075
1076     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1077
1078     return $fee;
1079 }
1080
1081 =head3 add_article_request_fee_if_needed
1082
1083     my $fee = $patron->add_article_request_fee_if_needed(
1084         {
1085           [ item_id    => $item->id,
1086             library_id => $library->id, ]
1087         }
1088     );
1089
1090 If an article request fee needs to be charged, it adds a debit to the patron's
1091 account.
1092
1093 Returns the fee line.
1094
1095 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1096
1097 =cut
1098
1099 sub add_article_request_fee_if_needed {
1100     my ($self, $params) = @_;
1101
1102     my $library_id = $params->{library_id};
1103     my $item_id    = $params->{item_id};
1104
1105     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1106
1107     my $amount = $self->article_request_fee(
1108         {
1109             library_id => $library_id,
1110         }
1111     );
1112
1113     my $debit_line;
1114
1115     if ( $amount > 0 ) {
1116         $debit_line = $self->account->add_debit(
1117             {
1118                 amount     => $amount,
1119                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1120                 interface  => C4::Context->interface,
1121                 library_id => $library_id,
1122                 type       => 'ARTICLE_REQUEST',
1123                 item_id    => $item_id,
1124             }
1125         );
1126     }
1127
1128     return $debit_line;
1129 }
1130
1131 =head3 article_requests
1132
1133     my $article_requests = $patron->article_requests;
1134
1135 Returns the patron article requests.
1136
1137 =cut
1138
1139 sub article_requests {
1140     my ($self) = @_;
1141
1142     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1143 }
1144
1145 =head3 add_enrolment_fee_if_needed
1146
1147 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1148
1149 Add enrolment fee for a patron if needed.
1150
1151 $renewal - boolean denoting whether this is an account renewal or not
1152
1153 =cut
1154
1155 sub add_enrolment_fee_if_needed {
1156     my ($self, $renewal) = @_;
1157     my $enrolment_fee = $self->category->enrolmentfee;
1158     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1159         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1160         $self->account->add_debit(
1161             {
1162                 amount     => $enrolment_fee,
1163                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1164                 interface  => C4::Context->interface,
1165                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1166                 type       => $type
1167             }
1168         );
1169     }
1170     return $enrolment_fee || 0;
1171 }
1172
1173 =head3 checkouts
1174
1175 my $checkouts = $patron->checkouts
1176
1177 =cut
1178
1179 sub checkouts {
1180     my ($self) = @_;
1181     my $checkouts = $self->_result->issues;
1182     return Koha::Checkouts->_new_from_dbic( $checkouts );
1183 }
1184
1185 =head3 pending_checkouts
1186
1187 my $pending_checkouts = $patron->pending_checkouts
1188
1189 This method will return the same as $self->checkouts, but with a prefetch on
1190 items, biblio and biblioitems.
1191
1192 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1193
1194 It should not be used directly, prefer to access fields you need instead of
1195 retrieving all these fields in one go.
1196
1197 =cut
1198
1199 sub pending_checkouts {
1200     my( $self ) = @_;
1201     my $checkouts = $self->_result->issues->search(
1202         {},
1203         {
1204             order_by => [
1205                 { -desc => 'me.timestamp' },
1206                 { -desc => 'issuedate' },
1207                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1208             ],
1209             prefetch => { item => { biblio => 'biblioitems' } },
1210         }
1211     );
1212     return Koha::Checkouts->_new_from_dbic( $checkouts );
1213 }
1214
1215 =head3 old_checkouts
1216
1217 my $old_checkouts = $patron->old_checkouts
1218
1219 =cut
1220
1221 sub old_checkouts {
1222     my ($self) = @_;
1223     my $old_checkouts = $self->_result->old_issues;
1224     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1225 }
1226
1227 =head3 overdues
1228
1229 my $overdue_items = $patron->overdues
1230
1231 Return the overdue items
1232
1233 =cut
1234
1235 sub overdues {
1236     my ($self) = @_;
1237     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1238     return $self->checkouts->search(
1239         {
1240             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1241         },
1242         {
1243             prefetch => { item => { biblio => 'biblioitems' } },
1244         }
1245     );
1246 }
1247
1248 =head3 get_routing_lists
1249
1250 my $routinglists = $patron->get_routing_lists
1251
1252 Returns the routing lists a patron is subscribed to.
1253
1254 =cut
1255
1256 sub get_routing_lists {
1257     my ($self) = @_;
1258     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1259     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1260 }
1261
1262 =head3 get_age
1263
1264     my $age = $patron->get_age
1265
1266 Return the age of the patron
1267
1268 =cut
1269
1270 sub get_age {
1271     my ($self)    = @_;
1272
1273     return unless $self->dateofbirth;
1274
1275     my $date_of_birth = dt_from_string( $self->dateofbirth );
1276     my $today         = dt_from_string->truncate( to => 'day' );
1277
1278     return $today->subtract_datetime( $date_of_birth )->years;
1279 }
1280
1281 =head3 is_valid_age
1282
1283 my $is_valid = $patron->is_valid_age
1284
1285 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1286
1287 =cut
1288
1289 sub is_valid_age {
1290     my ($self) = @_;
1291     my $age = $self->get_age;
1292
1293     my $patroncategory = $self->category;
1294     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1295
1296     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1297 }
1298
1299 =head3 account
1300
1301 my $account = $patron->account
1302
1303 =cut
1304
1305 sub account {
1306     my ($self) = @_;
1307     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1308 }
1309
1310 =head3 holds
1311
1312 my $holds = $patron->holds
1313
1314 Return all the holds placed by this patron
1315
1316 =cut
1317
1318 sub holds {
1319     my ($self) = @_;
1320     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1321     return Koha::Holds->_new_from_dbic($holds_rs);
1322 }
1323
1324 =head3 old_holds
1325
1326 my $old_holds = $patron->old_holds
1327
1328 Return all the historical holds for this patron
1329
1330 =cut
1331
1332 sub old_holds {
1333     my ($self) = @_;
1334     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1335     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1336 }
1337
1338 =head3 return_claims
1339
1340 my $return_claims = $patron->return_claims
1341
1342 =cut
1343
1344 sub return_claims {
1345     my ($self) = @_;
1346     my $return_claims = $self->_result->return_claims_borrowernumbers;
1347     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1348 }
1349
1350 =head3 notice_email_address
1351
1352   my $email = $patron->notice_email_address;
1353
1354 Return the email address of patron used for notices.
1355 Returns the empty string if no email address.
1356
1357 =cut
1358
1359 sub notice_email_address{
1360     my ( $self ) = @_;
1361
1362     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1363     # if syspref is set to 'first valid' (value == OFF), look up email address
1364     if ( $which_address eq 'OFF' ) {
1365         return $self->first_valid_email_address;
1366     }
1367
1368     return $self->$which_address || '';
1369 }
1370
1371 =head3 first_valid_email_address
1372
1373 my $first_valid_email_address = $patron->first_valid_email_address
1374
1375 Return the first valid email address for a patron.
1376 For now, the order  is defined as email, emailpro, B_email.
1377 Returns the empty string if the borrower has no email addresses.
1378
1379 =cut
1380
1381 sub first_valid_email_address {
1382     my ($self) = @_;
1383
1384     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1385 }
1386
1387 =head3 get_club_enrollments
1388
1389 =cut
1390
1391 sub get_club_enrollments {
1392     my ( $self ) = @_;
1393
1394     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1395 }
1396
1397 =head3 get_enrollable_clubs
1398
1399 =cut
1400
1401 sub get_enrollable_clubs {
1402     my ( $self, $is_enrollable_from_opac ) = @_;
1403
1404     my $params;
1405     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1406       if $is_enrollable_from_opac;
1407     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1408
1409     $params->{borrower} = $self;
1410
1411     return Koha::Clubs->get_enrollable($params);
1412 }
1413
1414 =head3 account_locked
1415
1416 my $is_locked = $patron->account_locked
1417
1418 Return true if the patron has reached the maximum number of login attempts
1419 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1420 as an administrative lockout (independent of FailedLoginAttempts; see also
1421 Koha::Patron->lock).
1422 Otherwise return false.
1423 If the pref is not set (empty string, null or 0), the feature is considered as
1424 disabled.
1425
1426 =cut
1427
1428 sub account_locked {
1429     my ($self) = @_;
1430     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1431     return 1 if $FailedLoginAttempts
1432           and $self->login_attempts
1433           and $self->login_attempts >= $FailedLoginAttempts;
1434     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1435     return 0;
1436 }
1437
1438 =head3 can_see_patron_infos
1439
1440 my $can_see = $patron->can_see_patron_infos( $patron );
1441
1442 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1443
1444 =cut
1445
1446 sub can_see_patron_infos {
1447     my ( $self, $patron ) = @_;
1448     return unless $patron;
1449     return $self->can_see_patrons_from( $patron->branchcode );
1450 }
1451
1452 =head3 can_see_patrons_from
1453
1454 my $can_see = $patron->can_see_patrons_from( $branchcode );
1455
1456 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1457
1458 =cut
1459
1460 sub can_see_patrons_from {
1461     my ( $self, $branchcode ) = @_;
1462     my $can = 0;
1463     if ( $self->branchcode eq $branchcode ) {
1464         $can = 1;
1465     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1466         $can = 1;
1467     } elsif ( my $library_groups = $self->library->library_groups ) {
1468         while ( my $library_group = $library_groups->next ) {
1469             if ( $library_group->parent->has_child( $branchcode ) ) {
1470                 $can = 1;
1471                 last;
1472             }
1473         }
1474     }
1475     return $can;
1476 }
1477
1478 =head3 can_log_into
1479
1480 my $can_log_into = $patron->can_log_into( $library );
1481
1482 Given a I<Koha::Library> object, it returns a boolean representing
1483 the fact the patron can log into a the library.
1484
1485 =cut
1486
1487 sub can_log_into {
1488     my ( $self, $library ) = @_;
1489
1490     my $can = 0;
1491
1492     if ( C4::Context->preference('IndependentBranches') ) {
1493         $can = 1
1494           if $self->is_superlibrarian
1495           or $self->branchcode eq $library->id;
1496     }
1497     else {
1498         # no restrictions
1499         $can = 1;
1500     }
1501
1502    return $can;
1503 }
1504
1505 =head3 libraries_where_can_see_patrons
1506
1507 my $libraries = $patron-libraries_where_can_see_patrons;
1508
1509 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1510 The branchcodes are arbitrarily returned sorted.
1511 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1512
1513 An empty array means no restriction, the patron can see patron's infos from any libraries.
1514
1515 =cut
1516
1517 sub libraries_where_can_see_patrons {
1518     my ( $self ) = @_;
1519     my $userenv = C4::Context->userenv;
1520
1521     return () unless $userenv; # For tests, but userenv should be defined in tests...
1522
1523     my @restricted_branchcodes;
1524     if (C4::Context::only_my_library) {
1525         push @restricted_branchcodes, $self->branchcode;
1526     }
1527     else {
1528         unless (
1529             $self->has_permission(
1530                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1531             )
1532           )
1533         {
1534             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1535             if ( $library_groups->count )
1536             {
1537                 while ( my $library_group = $library_groups->next ) {
1538                     my $parent = $library_group->parent;
1539                     if ( $parent->has_child( $self->branchcode ) ) {
1540                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1541                     }
1542                 }
1543             }
1544
1545             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1546         }
1547     }
1548
1549     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1550     @restricted_branchcodes = uniq(@restricted_branchcodes);
1551     @restricted_branchcodes = sort(@restricted_branchcodes);
1552     return @restricted_branchcodes;
1553 }
1554
1555 =head3 has_permission
1556
1557 my $permission = $patron->has_permission($required);
1558
1559 See C4::Auth::haspermission for details of syntax for $required
1560
1561 =cut
1562
1563 sub has_permission {
1564     my ( $self, $flagsrequired ) = @_;
1565     return unless $self->userid;
1566     # TODO code from haspermission needs to be moved here!
1567     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1568 }
1569
1570 =head3 is_superlibrarian
1571
1572   my $is_superlibrarian = $patron->is_superlibrarian;
1573
1574 Return true if the patron is a superlibrarian.
1575
1576 =cut
1577
1578 sub is_superlibrarian {
1579     my ($self) = @_;
1580     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1581 }
1582
1583 =head3 is_adult
1584
1585 my $is_adult = $patron->is_adult
1586
1587 Return true if the patron has a category with a type Adult (A) or Organization (I)
1588
1589 =cut
1590
1591 sub is_adult {
1592     my ( $self ) = @_;
1593     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1594 }
1595
1596 =head3 is_child
1597
1598 my $is_child = $patron->is_child
1599
1600 Return true if the patron has a category with a type Child (C)
1601
1602 =cut
1603
1604 sub is_child {
1605     my( $self ) = @_;
1606     return $self->category->category_type eq 'C' ? 1 : 0;
1607 }
1608
1609 =head3 has_valid_userid
1610
1611 my $patron = Koha::Patrons->find(42);
1612 $patron->userid( $new_userid );
1613 my $has_a_valid_userid = $patron->has_valid_userid
1614
1615 my $patron = Koha::Patron->new( $params );
1616 my $has_a_valid_userid = $patron->has_valid_userid
1617
1618 Return true if the current userid of this patron is valid/unique, otherwise false.
1619
1620 Note that this should be done in $self->store instead and raise an exception if needed.
1621
1622 =cut
1623
1624 sub has_valid_userid {
1625     my ($self) = @_;
1626
1627     return 0 unless $self->userid;
1628
1629     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1630
1631     my $already_exists = Koha::Patrons->search(
1632         {
1633             userid => $self->userid,
1634             (
1635                 $self->in_storage
1636                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1637                 : ()
1638             ),
1639         }
1640     )->count;
1641     return $already_exists ? 0 : 1;
1642 }
1643
1644 =head3 generate_userid
1645
1646 my $patron = Koha::Patron->new( $params );
1647 $patron->generate_userid
1648
1649 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1650
1651 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1652
1653 =cut
1654
1655 sub generate_userid {
1656     my ($self) = @_;
1657     my $offset = 0;
1658     my $firstname = $self->firstname // q{};
1659     my $surname = $self->surname // q{};
1660     #The script will "do" the following code and increment the $offset until the generated userid is unique
1661     do {
1662       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1663       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1664       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1665       $userid = NFKD( $userid );
1666       $userid =~ s/\p{NonspacingMark}//g;
1667       $userid .= $offset unless $offset == 0;
1668       $self->userid( $userid );
1669       $offset++;
1670      } while (! $self->has_valid_userid );
1671
1672      return $self;
1673 }
1674
1675 =head3 add_extended_attribute
1676
1677 =cut
1678
1679 sub add_extended_attribute {
1680     my ($self, $attribute) = @_;
1681
1682     return Koha::Patron::Attribute->new(
1683         {
1684             %$attribute,
1685             ( borrowernumber => $self->borrowernumber ),
1686         }
1687     )->store;
1688
1689 }
1690
1691 =head3 extended_attributes
1692
1693 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1694
1695 Or setter FIXME
1696
1697 =cut
1698
1699 sub extended_attributes {
1700     my ( $self, $attributes ) = @_;
1701     if ($attributes) {    # setter
1702         my $schema = $self->_result->result_source->schema;
1703         $schema->txn_do(
1704             sub {
1705                 # Remove the existing one
1706                 $self->extended_attributes->filter_by_branch_limitations->delete;
1707
1708                 # Insert the new ones
1709                 my $new_types = {};
1710                 for my $attribute (@$attributes) {
1711                     $self->add_extended_attribute($attribute);
1712                     $new_types->{$attribute->{code}} = 1;
1713                 }
1714
1715                 # Check globally mandatory types
1716                 my @required_attribute_types =
1717                     Koha::Patron::Attribute::Types->search(
1718                         {
1719                             mandatory => 1,
1720                             category_code => [ undef, $self->categorycode ],
1721                             'borrower_attribute_types_branches.b_branchcode' =>
1722                               undef,
1723                         },
1724                         { join => 'borrower_attribute_types_branches' }
1725                     )->get_column('code');
1726                 for my $type ( @required_attribute_types ) {
1727                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
1728                         type => $type,
1729                     ) if !$new_types->{$type};
1730                 }
1731             }
1732         );
1733     }
1734
1735     my $rs = $self->_result->borrower_attributes;
1736     # We call search to use the filters in Koha::Patron::Attributes->search
1737     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1738 }
1739
1740 =head3 messages
1741
1742     my $messages = $patron->messages;
1743
1744 Return the message attached to the patron.
1745
1746 =cut
1747
1748 sub messages {
1749     my ( $self ) = @_;
1750     my $messages_rs = $self->_result->messages_borrowernumbers->search;
1751     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
1752 }
1753
1754 =head3 lock
1755
1756     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1757
1758     Lock and optionally expire a patron account.
1759     Remove holds and article requests if remove flag set.
1760     In order to distinguish from locking by entering a wrong password, let's
1761     call this an administrative lockout.
1762
1763 =cut
1764
1765 sub lock {
1766     my ( $self, $params ) = @_;
1767     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1768     if( $params->{expire} ) {
1769         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1770     }
1771     $self->store;
1772     if( $params->{remove} ) {
1773         $self->holds->delete;
1774         $self->article_requests->delete;
1775     }
1776     return $self;
1777 }
1778
1779 =head3 anonymize
1780
1781     Koha::Patrons->find($id)->anonymize;
1782
1783     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1784     are randomized, other personal data is cleared too.
1785     Patrons with issues are skipped.
1786
1787 =cut
1788
1789 sub anonymize {
1790     my ( $self ) = @_;
1791     if( $self->_result->issues->count ) {
1792         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1793         return;
1794     }
1795     # Mandatory fields come from the corresponding pref, but email fields
1796     # are removed since scrambled email addresses only generate errors
1797     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1798         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1799     $mandatory->{userid} = 1; # needed since sub store does not clear field
1800     my @columns = $self->_result->result_source->columns;
1801     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
1802     push @columns, 'dateofbirth'; # add this date back in
1803     foreach my $col (@columns) {
1804         $self->_anonymize_column($col, $mandatory->{lc $col} );
1805     }
1806     $self->anonymized(1)->store;
1807 }
1808
1809 sub _anonymize_column {
1810     my ( $self, $col, $mandatory ) = @_;
1811     my $col_info = $self->_result->result_source->column_info($col);
1812     my $type = $col_info->{data_type};
1813     my $nullable = $col_info->{is_nullable};
1814     my $val;
1815     if( $type =~ /char|text/ ) {
1816         $val = $mandatory
1817             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1818             : $nullable
1819             ? undef
1820             : q{};
1821     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1822         $val = $nullable ? undef : 0;
1823     } elsif( $type =~ /date|time/ ) {
1824         $val = $nullable ? undef : dt_from_string;
1825     }
1826     $self->$col($val);
1827 }
1828
1829 =head3 add_guarantor
1830
1831     my $relationship = $patron->add_guarantor(
1832         {
1833             borrowernumber => $borrowernumber,
1834             relationships  => $relationship,
1835         }
1836     );
1837
1838     Adds a new guarantor to a patron.
1839
1840 =cut
1841
1842 sub add_guarantor {
1843     my ( $self, $params ) = @_;
1844
1845     my $guarantor_id = $params->{guarantor_id};
1846     my $relationship = $params->{relationship};
1847
1848     return Koha::Patron::Relationship->new(
1849         {
1850             guarantee_id => $self->id,
1851             guarantor_id => $guarantor_id,
1852             relationship => $relationship
1853         }
1854     )->store();
1855 }
1856
1857 =head3 get_extended_attribute
1858
1859 my $attribute_value = $patron->get_extended_attribute( $code );
1860
1861 Return the attribute for the code passed in parameter.
1862
1863 It not exist it returns undef
1864
1865 Note that this will not work for repeatable attribute types.
1866
1867 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1868 (which should be a real patron's attribute (not extended)
1869
1870 =cut
1871
1872 sub get_extended_attribute {
1873     my ( $self, $code, $value ) = @_;
1874     my $rs = $self->_result->borrower_attributes;
1875     return unless $rs;
1876     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1877     return unless $attribute->count;
1878     return $attribute->next;
1879 }
1880
1881 =head3 to_api
1882
1883     my $json = $patron->to_api;
1884
1885 Overloaded method that returns a JSON representation of the Koha::Patron object,
1886 suitable for API output.
1887
1888 =cut
1889
1890 sub to_api {
1891     my ( $self, $params ) = @_;
1892
1893     my $json_patron = $self->SUPER::to_api( $params );
1894
1895     $json_patron->{restricted} = ( $self->is_debarred )
1896                                     ? Mojo::JSON->true
1897                                     : Mojo::JSON->false;
1898
1899     return $json_patron;
1900 }
1901
1902 =head3 to_api_mapping
1903
1904 This method returns the mapping for representing a Koha::Patron object
1905 on the API.
1906
1907 =cut
1908
1909 sub to_api_mapping {
1910     return {
1911         borrowernotes       => 'staff_notes',
1912         borrowernumber      => 'patron_id',
1913         branchcode          => 'library_id',
1914         categorycode        => 'category_id',
1915         checkprevcheckout   => 'check_previous_checkout',
1916         contactfirstname    => undef,                     # Unused
1917         contactname         => undef,                     # Unused
1918         contactnote         => 'altaddress_notes',
1919         contacttitle        => undef,                     # Unused
1920         dateenrolled        => 'date_enrolled',
1921         dateexpiry          => 'expiry_date',
1922         dateofbirth         => 'date_of_birth',
1923         debarred            => undef,                     # replaced by 'restricted'
1924         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1925         emailpro            => 'secondary_email',
1926         flags               => undef,    # permissions manipulation handled in /permissions
1927         gonenoaddress       => 'incorrect_address',
1928         lastseen            => 'last_seen',
1929         lost                => 'patron_card_lost',
1930         opacnote            => 'opac_notes',
1931         othernames          => 'other_name',
1932         password            => undef,            # password manipulation handled in /password
1933         phonepro            => 'secondary_phone',
1934         relationship        => 'relationship_type',
1935         sex                 => 'gender',
1936         smsalertnumber      => 'sms_number',
1937         sort1               => 'statistics_1',
1938         sort2               => 'statistics_2',
1939         autorenew_checkouts => 'autorenew_checkouts',
1940         streetnumber        => 'street_number',
1941         streettype          => 'street_type',
1942         zipcode             => 'postal_code',
1943         B_address           => 'altaddress_address',
1944         B_address2          => 'altaddress_address2',
1945         B_city              => 'altaddress_city',
1946         B_country           => 'altaddress_country',
1947         B_email             => 'altaddress_email',
1948         B_phone             => 'altaddress_phone',
1949         B_state             => 'altaddress_state',
1950         B_streetnumber      => 'altaddress_street_number',
1951         B_streettype        => 'altaddress_street_type',
1952         B_zipcode           => 'altaddress_postal_code',
1953         altcontactaddress1  => 'altcontact_address',
1954         altcontactaddress2  => 'altcontact_address2',
1955         altcontactaddress3  => 'altcontact_city',
1956         altcontactcountry   => 'altcontact_country',
1957         altcontactfirstname => 'altcontact_firstname',
1958         altcontactphone     => 'altcontact_phone',
1959         altcontactsurname   => 'altcontact_surname',
1960         altcontactstate     => 'altcontact_state',
1961         altcontactzipcode   => 'altcontact_postal_code',
1962         password_expiration_date => undef,
1963         primary_contact_method => undef,
1964         secret              => undef,
1965         auth_method         => undef,
1966     };
1967 }
1968
1969 =head3 queue_notice
1970
1971     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
1972     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
1973     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
1974
1975     Queue messages to a patron. Can pass a message that is part of the message_attributes
1976     table or supply the transport to use.
1977
1978     If passed a message name we retrieve the patrons preferences for transports
1979     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
1980     we have no address/number for sending
1981
1982     $letter_params is a hashref of the values to be passed to GetPreparedLetter
1983
1984     test_mode will only report which notices would be sent, but nothing will be queued
1985
1986 =cut
1987
1988 sub queue_notice {
1989     my ( $self, $params ) = @_;
1990     my $letter_params = $params->{letter_params};
1991     my $test_mode = $params->{test_mode};
1992
1993     return unless $letter_params;
1994     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
1995
1996     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
1997     my $from_email_address = $library->from_email_address;
1998
1999     my @message_transports;
2000     my $letter_code;
2001     $letter_code = $letter_params->{letter_code};
2002     if( $params->{message_name} ){
2003         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
2004                 borrowernumber => $letter_params->{borrowernumber},
2005                 message_name => $params->{message_name}
2006         } );
2007         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
2008         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
2009     } else {
2010         @message_transports = @{$params->{message_transports}};
2011     }
2012     return unless defined $letter_code;
2013     $letter_params->{letter_code} = $letter_code;
2014     my $print_sent = 0;
2015     my %return;
2016     foreach my $mtt (@message_transports){
2017         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2018         # Notice is handled by TalkingTech_itiva_outbound.pl
2019         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2020             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2021             or ( $mtt eq 'phone' and not $self->phone ) )
2022         {
2023             push @{ $return{fallback} }, $mtt;
2024             $mtt = 'print';
2025         }
2026         next if $mtt eq 'print' && $print_sent;
2027         $letter_params->{message_transport_type} = $mtt;
2028         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2029         C4::Letters::EnqueueLetter({
2030             letter => $letter,
2031             borrowernumber => $self->borrowernumber,
2032             from_address   => $from_email_address,
2033             message_transport_type => $mtt
2034         }) unless $test_mode;
2035         push @{$return{sent}}, $mtt;
2036         $print_sent = 1 if $mtt eq 'print';
2037     }
2038     return \%return;
2039 }
2040
2041 =head3 safe_to_delete
2042
2043     my $result = $patron->safe_to_delete;
2044     if ( $result eq 'has_guarantees' ) { ... }
2045     elsif ( $result ) { ... }
2046     else { # cannot delete }
2047
2048 This method tells if the Koha:Patron object can be deleted. Possible return values
2049
2050 =over 4
2051
2052 =item 'ok'
2053
2054 =item 'has_checkouts'
2055
2056 =item 'has_debt'
2057
2058 =item 'has_guarantees'
2059
2060 =item 'is_anonymous_patron'
2061
2062 =back
2063
2064 =cut
2065
2066 sub safe_to_delete {
2067     my ($self) = @_;
2068
2069     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2070
2071     my $error;
2072
2073     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2074         $error = 'is_anonymous_patron';
2075     }
2076     elsif ( $self->checkouts->count ) {
2077         $error = 'has_checkouts';
2078     }
2079     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2080         $error = 'has_debt';
2081     }
2082     elsif ( $self->guarantee_relationships->count ) {
2083         $error = 'has_guarantees';
2084     }
2085
2086     if ( $error ) {
2087         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2088     }
2089
2090     return Koha::Result::Boolean->new(1);
2091 }
2092
2093 =head3 recalls
2094
2095     my $recalls = $patron->recalls;
2096
2097 Return the patron's recalls.
2098
2099 =cut
2100
2101 sub recalls {
2102     my ( $self ) = @_;
2103
2104     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2105 }
2106
2107 =head3 account_balance
2108
2109     my $balance = $patron->account_balance
2110
2111 Return the patron's account balance
2112
2113 =cut
2114
2115 sub account_balance {
2116     my ($self) = @_;
2117     return $self->account->balance;
2118 }
2119
2120
2121 =head3 has_messaging_preference
2122
2123 my $bool = $patron->has_messaging_preference({
2124     message_name => $message_name, # A value from message_attributes.message_name
2125     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2126     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2127 });
2128
2129 =cut
2130
2131 sub has_messaging_preference {
2132     my ( $self, $params ) = @_;
2133
2134     my $message_name           = $params->{message_name};
2135     my $message_transport_type = $params->{message_transport_type};
2136     my $wants_digest           = $params->{wants_digest};
2137
2138     return $self->_result->search_related_rs(
2139         'borrower_message_preferences',
2140         $params,
2141         {
2142             prefetch =>
2143               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2144         }
2145     )->count;
2146 }
2147
2148 =head3 can_patron_change_staff_only_lists
2149
2150 $patron->can_patron_change_staff_only_lists;
2151
2152 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2153 Otherwise, return 0.
2154
2155 =cut
2156
2157 sub can_patron_change_staff_only_lists {
2158     my ( $self, $params ) = @_;
2159     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2160     return 0;
2161 }
2162
2163 =head3 encode_secret
2164
2165   $patron->encode_secret($secret32);
2166
2167 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2168 You still need to call ->store.
2169
2170 =cut
2171
2172 sub encode_secret {
2173     my ( $self, $secret ) = @_;
2174     if( $secret ) {
2175         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2176     }
2177     return $self->secret($secret);
2178 }
2179
2180 =head3 decoded_secret
2181
2182   my $secret32 = $patron->decoded_secret;
2183
2184 Decode the patron secret. We expect to get back a base32 string, but this
2185 is not checked here. Caller of encode_secret is responsible for that.
2186
2187 =cut
2188
2189 sub decoded_secret {
2190     my ( $self ) = @_;
2191     if( $self->secret ) {
2192         return Koha::Encryption->new->decrypt_hex( $self->secret );
2193     }
2194     return $self->secret;
2195 }
2196
2197 =head2 Internal methods
2198
2199 =head3 _type
2200
2201 =cut
2202
2203 sub _type {
2204     return 'Borrower';
2205 }
2206
2207 =head1 AUTHORS
2208
2209 Kyle M Hall <kyle@bywatersolutions.com>
2210 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2211 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2212
2213 =cut
2214
2215 1;