Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use List::MoreUtils qw( any uniq );
  25 use JSON qw( to_json );
  26 use Unicode::Normalize;
  27
  28 use C4::Context;
  29 use C4::Log;
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use Koha::AuthUtils;
  33 use Koha::Checkouts;
  34 use Koha::Club::Enrollments;
  35 use Koha::Database;
  36 use Koha::DateUtils;
  37 use Koha::Exceptions::Password;
  38 use Koha::Holds;
  39 use Koha::Old::Checkouts;
  40 use Koha::Patron::Attributes;
  41 use Koha::Patron::Categories;
  42 use Koha::Patron::HouseboundProfile;
  43 use Koha::Patron::HouseboundRole;
  44 use Koha::Patron::Images;
  45 use Koha::Patron::Modifications;
  46 use Koha::Patron::Relationships;
  47 use Koha::Patrons;
  48 use Koha::Plugins;
  49 use Koha::Subscription::Routinglists;
  50 use Koha::Token;
  51 use Koha::Virtualshelves;
  52
  53 use base qw(Koha::Object);
  54
  55 use constant ADMINISTRATIVE_LOCKOUT => -1;
  56
  57 our $RESULTSET_PATRON_ID_MAPPING = {
  58     Accountline          => 'borrowernumber',
  59     Aqbasketuser         => 'borrowernumber',
  60     Aqbudget             => 'budget_owner_id',
  61     Aqbudgetborrower     => 'borrowernumber',
  62     ArticleRequest       => 'borrowernumber',
  63     BorrowerAttribute    => 'borrowernumber',
  64     BorrowerDebarment    => 'borrowernumber',
  65     BorrowerFile         => 'borrowernumber',
  66     BorrowerModification => 'borrowernumber',
  67     ClubEnrollment       => 'borrowernumber',
  68     Issue                => 'borrowernumber',
  69     ItemsLastBorrower    => 'borrowernumber',
  70     Linktracker          => 'borrowernumber',
  71     Message              => 'borrowernumber',
  72     MessageQueue         => 'borrowernumber',
  73     OldIssue             => 'borrowernumber',
  74     OldReserve           => 'borrowernumber',
  75     Rating               => 'borrowernumber',
  76     Reserve              => 'borrowernumber',
  77     Review               => 'borrowernumber',
  78     SearchHistory        => 'userid',
  79     Statistic            => 'borrowernumber',
  80     Suggestion           => 'suggestedby',
  81     TagAll               => 'borrowernumber',
  82     Virtualshelfcontent  => 'borrowernumber',
  83     Virtualshelfshare    => 'borrowernumber',
  84     Virtualshelve        => 'owner',
  85 };
  86
  87 =head1 NAME
  88
  89 Koha::Patron - Koha Patron Object class
  90
  91 =head1 API
  92
  93 =head2 Class Methods
  94
  95 =head3 new
  96
  97 =cut
  98
  99 sub new {
 100     my ( $class, $params ) = @_;
 101
 102     return $class->SUPER::new($params);
 103 }
 104
 105 =head3 fixup_cardnumber
 106
 107 Autogenerate next cardnumber from highest value found in database
 108
 109 =cut
 110
 111 sub fixup_cardnumber {
 112     my ( $self ) = @_;
 113     my $max = Koha::Patrons->search({
 114         cardnumber => {-regexp => '^-?[0-9]+$'}
 115     }, {
 116         select => \'CAST(cardnumber AS SIGNED)',
 117         as => ['cast_cardnumber']
 118     })->_resultset->get_column('cast_cardnumber')->max;
 119     $self->cardnumber(($max || 0) +1);
 120 }
 121
 122 =head3 trim_whitespace
 123
 124 trim whitespace from data which has some non-whitespace in it.
 125 Could be moved to Koha::Object if need to be reused
 126
 127 =cut
 128
 129 sub trim_whitespaces {
 130     my( $self ) = @_;
 131
 132     my $schema  = Koha::Database->new->schema;
 133     my @columns = $schema->source($self->_type)->columns;
 134
 135     for my $column( @columns ) {
 136         my $value = $self->$column;
 137         if ( defined $value ) {
 138             $value =~ s/^\s*|\s*$//g;
 139             $self->$column($value);
 140         }
 141     }
 142     return $self;
 143 }
 144
 145 =head3 plain_text_password
 146
 147 $patron->plain_text_password( $password );
 148
 149 stores a copy of the unencrypted password in the object
 150 for use in code before encrypting for db
 151
 152 =cut
 153
 154 sub plain_text_password {
 155     my ( $self, $password ) = @_;
 156     if ( $password ) {
 157         $self->{_plain_text_password} = $password;
 158         return $self;
 159     }
 160     return $self->{_plain_text_password}
 161         if $self->{_plain_text_password};
 162
 163     return;
 164 }
 165
 166 =head3 store
 167
 168 Patron specific store method to cleanup record
 169 and do other necessary things before saving
 170 to db
 171
 172 =cut
 173
 174 sub store {
 175     my ($self) = @_;
 176
 177     $self->_result->result_source->schema->txn_do(
 178         sub {
 179             if (
 180                 C4::Context->preference("autoMemberNum")
 181                 and ( not defined $self->cardnumber
 182                     or $self->cardnumber eq '' )
 183               )
 184             {
 185                 # Warning: The caller is responsible for locking the members table in write
 186                 # mode, to avoid database corruption.
 187                 # We are in a transaction but the table is not locked
 188                 $self->fixup_cardnumber;
 189             }
 190
 191             unless( $self->category->in_storage ) {
 192                 Koha::Exceptions::Object::FKConstraint->throw(
 193                     broken_fk => 'categorycode',
 194                     value     => $self->categorycode,
 195                 );
 196             }
 197
 198             $self->trim_whitespaces;
 199
 200             # Set surname to uppercase if uppercasesurname is true
 201             $self->surname( uc($self->surname) )
 202                 if C4::Context->preference("uppercasesurnames");
 203
 204             $self->relationship(undef) # We do not want to store an empty string in this field
 205               if defined $self->relationship
 206                      and $self->relationship eq "";
 207
 208             unless ( $self->in_storage ) {    #AddMember
 209
 210                 # Generate a valid userid/login if needed
 211                 $self->generate_userid
 212                   if not $self->userid or not $self->has_valid_userid;
 213
 214                 # Add expiration date if it isn't already there
 215                 unless ( $self->dateexpiry ) {
 216                     $self->dateexpiry( $self->category->get_expiry_date );
 217                 }
 218
 219                 # Add enrollment date if it isn't already there
 220                 unless ( $self->dateenrolled ) {
 221                     $self->dateenrolled(dt_from_string);
 222                 }
 223
 224                 # Set the privacy depending on the patron's category
 225                 my $default_privacy = $self->category->default_privacy || q{};
 226                 $default_privacy =
 227                     $default_privacy eq 'default' ? 1
 228                   : $default_privacy eq 'never'   ? 2
 229                   : $default_privacy eq 'forever' ? 0
 230                   :                                                   undef;
 231                 $self->privacy($default_privacy);
 232
 233                 # Call any check_password plugins if password is passed
 234                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 235                     my @plugins = Koha::Plugins->new()->GetPlugins({
 236                         method => 'check_password',
 237                     });
 238                     foreach my $plugin ( @plugins ) {
 239                         # This plugin hook will also be used by a plugin for the Norwegian national
 240                         # patron database. This is why we need to pass both the password and the
 241                         # borrowernumber to the plugin.
 242                         my $ret = $plugin->check_password(
 243                             {
 244                                 password       => $self->password,
 245                                 borrowernumber => $self->borrowernumber
 246                             }
 247                         );
 248                         if ( $ret->{'error'} == 1 ) {
 249                             Koha::Exceptions::Password::Plugin->throw();
 250                         }
 251                     }
 252                 }
 253
 254                 # Make a copy of the plain text password for later use
 255                 $self->plain_text_password( $self->password );
 256
 257                 # Create a disabled account if no password provided
 258                 $self->password( $self->password
 259                     ? Koha::AuthUtils::hash_password( $self->password )
 260                     : '!' );
 261
 262                 $self->borrowernumber(undef);
 263
 264                 $self = $self->SUPER::store;
 265
 266                 $self->add_enrolment_fee_if_needed(0);
 267
 268                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 269                   if C4::Context->preference("BorrowersLog");
 270             }
 271             else {    #ModMember
 272
 273                 my $self_from_storage = $self->get_from_storage;
 274                 # FIXME We should not deal with that here, callers have to do this job
 275                 # Moved from ModMember to prevent regressions
 276                 unless ( $self->userid ) {
 277                     my $stored_userid = $self_from_storage->userid;
 278                     $self->userid($stored_userid);
 279                 }
 280
 281                 # Password must be updated using $self->set_password
 282                 $self->password($self_from_storage->password);
 283
 284                 if ( $self->category->categorycode ne
 285                     $self_from_storage->category->categorycode )
 286                 {
 287                     # Add enrolement fee on category change if required
 288                     $self->add_enrolment_fee_if_needed(1)
 289                       if C4::Context->preference('FeeOnChangePatronCategory');
 290
 291                     # Clean up guarantors on category change if required
 292                     $self->guarantor_relationships->delete
 293                       if ( $self->category->category_type ne 'C'
 294                         && $self->category->category_type ne 'P' );
 295
 296                 }
 297
 298                 # Actionlogs
 299                 if ( C4::Context->preference("BorrowersLog") ) {
 300                     my $info;
 301                     my $from_storage = $self_from_storage->unblessed;
 302                     my $from_object  = $self->unblessed;
 303                     my @skip_fields  = (qw/lastseen updated_on/);
 304                     for my $key ( keys %{$from_storage} ) {
 305                         next if any { /$key/ } @skip_fields;
 306                         if (
 307                             (
 308                                   !defined( $from_storage->{$key} )
 309                                 && defined( $from_object->{$key} )
 310                             )
 311                             || ( defined( $from_storage->{$key} )
 312                                 && !defined( $from_object->{$key} ) )
 313                             || (
 314                                    defined( $from_storage->{$key} )
 315                                 && defined( $from_object->{$key} )
 316                                 && ( $from_storage->{$key} ne
 317                                     $from_object->{$key} )
 318                             )
 319                           )
 320                         {
 321                             $info->{$key} = {
 322                                 before => $from_storage->{$key},
 323                                 after  => $from_object->{$key}
 324                             };
 325                         }
 326                     }
 327
 328                     if ( defined($info) ) {
 329                         logaction(
 330                             "MEMBERS",
 331                             "MODIFY",
 332                             $self->borrowernumber,
 333                             to_json(
 334                                 $info,
 335                                 { utf8 => 1, pretty => 1, canonical => 1 }
 336                             )
 337                         );
 338                     }
 339                 }
 340
 341                 # Final store
 342                 $self = $self->SUPER::store;
 343             }
 344         }
 345     );
 346     return $self;
 347 }
 348
 349 =head3 delete
 350
 351 $patron->delete
 352
 353 Delete patron's holds, lists and finally the patron.
 354
 355 Lists owned by the borrower are deleted, but entries from the borrower to
 356 other lists are kept.
 357
 358 =cut
 359
 360 sub delete {
 361     my ($self) = @_;
 362
 363     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 364     return $self if $anonymous_patron && $self->id eq $anonymous_patron;
 365
 366     $self->_result->result_source->schema->txn_do(
 367         sub {
 368             # Cancel Patron's holds
 369             my $holds = $self->holds;
 370             while( my $hold = $holds->next ){
 371                 $hold->cancel;
 372             }
 373
 374             # Delete all lists and all shares of this borrower
 375             # Consistent with the approach Koha uses on deleting individual lists
 376             # Note that entries in virtualshelfcontents added by this borrower to
 377             # lists of others will be handled by a table constraint: the borrower
 378             # is set to NULL in those entries.
 379             # NOTE:
 380             # We could handle the above deletes via a constraint too.
 381             # But a new BZ report 11889 has been opened to discuss another approach.
 382             # Instead of deleting we could also disown lists (based on a pref).
 383             # In that way we could save shared and public lists.
 384             # The current table constraints support that idea now.
 385             # This pref should then govern the results of other routines/methods such as
 386             # Koha::Virtualshelf->new->delete too.
 387             # FIXME Could be $patron->get_lists
 388             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } );
 389
 390             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 391             # for patron selfreg
 392             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } );
 393
 394             $self->SUPER::delete;
 395
 396             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 397         }
 398     );
 399     return $self;
 400 }
 401
 402
 403 =head3 category
 404
 405 my $patron_category = $patron->category
 406
 407 Return the patron category for this patron
 408
 409 =cut
 410
 411 sub category {
 412     my ( $self ) = @_;
 413     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 414 }
 415
 416 =head3 image
 417
 418 =cut
 419
 420 sub image {
 421     my ( $self ) = @_;
 422
 423     return Koha::Patron::Images->find( $self->borrowernumber );
 424 }
 425
 426 =head3 library
 427
 428 Returns a Koha::Library object representing the patron's home library.
 429
 430 =cut
 431
 432 sub library {
 433     my ( $self ) = @_;
 434     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 435 }
 436
 437 =head3 sms_provider
 438
 439 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 440
 441 =cut
 442
 443 sub sms_provider {
 444     my ( $self ) = @_;
 445     my $sms_provider_rs = $self->_result->sms_provider;
 446     return unless $sms_provider_rs;
 447     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 448 }
 449
 450 =head3 guarantor_relationships
 451
 452 Returns Koha::Patron::Relationships object for this patron's guarantors
 453
 454 Returns the set of relationships for the patrons that are guarantors for this patron.
 455
 456 This is returned instead of a Koha::Patron object because the guarantor
 457 may not exist as a patron in Koha. If this is true, the guarantors name
 458 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 459
 460 =cut
 461
 462 sub guarantor_relationships {
 463     my ($self) = @_;
 464
 465     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 466 }
 467
 468 =head3 guarantee_relationships
 469
 470 Returns Koha::Patron::Relationships object for this patron's guarantors
 471
 472 Returns the set of relationships for the patrons that are guarantees for this patron.
 473
 474 The method returns Koha::Patron::Relationship objects for the sake
 475 of consistency with the guantors method.
 476 A guarantee by definition must exist as a patron in Koha.
 477
 478 =cut
 479
 480 sub guarantee_relationships {
 481     my ($self) = @_;
 482
 483     return Koha::Patron::Relationships->search(
 484         { guarantor_id => $self->id },
 485         {
 486             prefetch => 'guarantee',
 487             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 488         }
 489     );
 490 }
 491
 492 =head3 relationships_debt
 493
 494 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 495
 496 =cut
 497
 498 sub relationships_debt {
 499     my ($self, $params) = @_;
 500
 501     my $include_guarantors  = $params->{include_guarantors};
 502     my $only_this_guarantor = $params->{only_this_guarantor};
 503     my $include_this_patron = $params->{include_this_patron};
 504
 505     my @guarantors;
 506     if ( $only_this_guarantor ) {
 507         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 508         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 509     } elsif ( $self->guarantor_relationships->count ) {
 510         # I am a guarantee, just get all my guarantors
 511         @guarantors = $self->guarantor_relationships->guarantors;
 512     } else {
 513         # I am a guarantor, I need to get all the guarantors of all my guarantees
 514         @guarantors = map { $_->guarantor_relationships->guarantors } $self->guarantee_relationships->guarantees;
 515     }
 516
 517     my $non_issues_charges = 0;
 518     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 519     foreach my $guarantor (@guarantors) {
 520         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 521
 522         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 523         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships();
 524         my $guarantees_non_issues_charges = 0;
 525         foreach my $guarantee (@guarantees) {
 526             next if $seen->{ $guarantee->id };
 527             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 528             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 529             $seen->{ $guarantee->id } = 1;
 530         }
 531
 532         $non_issues_charges += $guarantees_non_issues_charges;
 533         $seen->{ $guarantor->id } = 1;
 534     }
 535
 536     return $non_issues_charges;
 537 }
 538
 539 =head3 housebound_profile
 540
 541 Returns the HouseboundProfile associated with this patron.
 542
 543 =cut
 544
 545 sub housebound_profile {
 546     my ( $self ) = @_;
 547     my $profile = $self->_result->housebound_profile;
 548     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 549         if ( $profile );
 550     return;
 551 }
 552
 553 =head3 housebound_role
 554
 555 Returns the HouseboundRole associated with this patron.
 556
 557 =cut
 558
 559 sub housebound_role {
 560     my ( $self ) = @_;
 561
 562     my $role = $self->_result->housebound_role;
 563     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 564     return;
 565 }
 566
 567 =head3 siblings
 568
 569 Returns the siblings of this patron.
 570
 571 =cut
 572
 573 sub siblings {
 574     my ($self) = @_;
 575
 576     my @guarantors = $self->guarantor_relationships()->guarantors();
 577
 578     return unless @guarantors;
 579
 580     my @siblings =
 581       map { $_->guarantee_relationships()->guarantees() } @guarantors;
 582
 583     return unless @siblings;
 584
 585     my %seen;
 586     @siblings =
 587       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 588
 589     return wantarray ? @siblings : Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 590 }
 591
 592 =head3 merge_with
 593
 594     my $patron = Koha::Patrons->find($id);
 595     $patron->merge_with( \@patron_ids );
 596
 597     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 598     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 599     of the keeper patron.
 600
 601 =cut
 602
 603 sub merge_with {
 604     my ( $self, $patron_ids ) = @_;
 605
 606     my @patron_ids = @{ $patron_ids };
 607
 608     # Ensure the keeper isn't in the list of patrons to merge
 609     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 610
 611     my $schema = Koha::Database->new()->schema();
 612
 613     my $results;
 614
 615     $self->_result->result_source->schema->txn_do( sub {
 616         foreach my $patron_id (@patron_ids) {
 617
 618             if ( my $anonymous_patron = C4::Context->preference("AnonymousPatron") ) {
 619                 next if $patron_id eq $anonymous_patron;
 620             }
 621
 622             my $patron = Koha::Patrons->find( $patron_id );
 623
 624             next unless $patron;
 625
 626             # Unbless for safety, the patron will end up being deleted
 627             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 628
 629             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 630                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 631                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 632                 $rs->update({ $field => $self->id });
 633             }
 634
 635             $patron->move_to_deleted();
 636             $patron->delete();
 637         }
 638     });
 639
 640     return $results;
 641 }
 642
 643
 644
 645 =head3 wants_check_for_previous_checkout
 646
 647     $wants_check = $patron->wants_check_for_previous_checkout;
 648
 649 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 650
 651 =cut
 652
 653 sub wants_check_for_previous_checkout {
 654     my ( $self ) = @_;
 655     my $syspref = C4::Context->preference("checkPrevCheckout");
 656
 657     # Simple cases
 658     ## Hard syspref trumps all
 659     return 1 if ($syspref eq 'hardyes');
 660     return 0 if ($syspref eq 'hardno');
 661     ## Now, patron pref trumps all
 662     return 1 if ($self->checkprevcheckout eq 'yes');
 663     return 0 if ($self->checkprevcheckout eq 'no');
 664
 665     # More complex: patron inherits -> determine category preference
 666     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 667     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 668     return 0 if ($checkPrevCheckoutByCat eq 'no');
 669
 670     # Finally: category preference is inherit, default to 0
 671     if ($syspref eq 'softyes') {
 672         return 1;
 673     } else {
 674         return 0;
 675     }
 676 }
 677
 678 =head3 do_check_for_previous_checkout
 679
 680     $do_check = $patron->do_check_for_previous_checkout($item);
 681
 682 Return 1 if the bib associated with $ITEM has previously been checked out to
 683 $PATRON, 0 otherwise.
 684
 685 =cut
 686
 687 sub do_check_for_previous_checkout {
 688     my ( $self, $item ) = @_;
 689
 690     my @item_nos;
 691     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 692     if ( $biblio->is_serial ) {
 693         push @item_nos, $item->{itemnumber};
 694     } else {
 695         # Get all itemnumbers for given bibliographic record.
 696         @item_nos = $biblio->items->get_column( 'itemnumber' );
 697     }
 698
 699     # Create (old)issues search criteria
 700     my $criteria = {
 701         borrowernumber => $self->borrowernumber,
 702         itemnumber => \@item_nos,
 703     };
 704
 705     # Check current issues table
 706     my $issues = Koha::Checkouts->search($criteria);
 707     return 1 if $issues->count; # 0 || N
 708
 709     # Check old issues table
 710     my $old_issues = Koha::Old::Checkouts->search($criteria);
 711     return $old_issues->count;  # 0 || N
 712 }
 713
 714 =head3 is_debarred
 715
 716 my $debarment_expiration = $patron->is_debarred;
 717
 718 Returns the date a patron debarment will expire, or undef if the patron is not
 719 debarred
 720
 721 =cut
 722
 723 sub is_debarred {
 724     my ($self) = @_;
 725
 726     return unless $self->debarred;
 727     return $self->debarred
 728       if $self->debarred =~ '^9999'
 729       or dt_from_string( $self->debarred ) > dt_from_string;
 730     return;
 731 }
 732
 733 =head3 is_expired
 734
 735 my $is_expired = $patron->is_expired;
 736
 737 Returns 1 if the patron is expired or 0;
 738
 739 =cut
 740
 741 sub is_expired {
 742     my ($self) = @_;
 743     return 0 unless $self->dateexpiry;
 744     return 0 if $self->dateexpiry =~ '^9999';
 745     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 746     return 0;
 747 }
 748
 749 =head3 is_going_to_expire
 750
 751 my $is_going_to_expire = $patron->is_going_to_expire;
 752
 753 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 754
 755 =cut
 756
 757 sub is_going_to_expire {
 758     my ($self) = @_;
 759
 760     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 761
 762     return 0 unless $delay;
 763     return 0 unless $self->dateexpiry;
 764     return 0 if $self->dateexpiry =~ '^9999';
 765     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 766     return 0;
 767 }
 768
 769 =head3 set_password
 770
 771     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 772
 773 Set the patron's password.
 774
 775 =head4 Exceptions
 776
 777 The passed string is validated against the current password enforcement policy.
 778 Validation can be skipped by passing the I<skip_validation> parameter.
 779
 780 Exceptions are thrown if the password is not good enough.
 781
 782 =over 4
 783
 784 =item Koha::Exceptions::Password::TooShort
 785
 786 =item Koha::Exceptions::Password::WhitespaceCharacters
 787
 788 =item Koha::Exceptions::Password::TooWeak
 789
 790 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 791
 792 =back
 793
 794 =cut
 795
 796 sub set_password {
 797     my ( $self, $args ) = @_;
 798
 799     my $password = $args->{password};
 800
 801     unless ( $args->{skip_validation} ) {
 802         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 803
 804         if ( !$is_valid ) {
 805             if ( $error eq 'too_short' ) {
 806                 my $min_length = $self->category->effective_min_password_length;
 807                 $min_length = 3 if not $min_length or $min_length < 3;
 808
 809                 my $password_length = length($password);
 810                 Koha::Exceptions::Password::TooShort->throw(
 811                     length => $password_length, min_length => $min_length );
 812             }
 813             elsif ( $error eq 'has_whitespaces' ) {
 814                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 815             }
 816             elsif ( $error eq 'too_weak' ) {
 817                 Koha::Exceptions::Password::TooWeak->throw();
 818             }
 819         }
 820     }
 821
 822     if ( C4::Context->config("enable_plugins") ) {
 823         # Call any check_password plugins
 824         my @plugins = Koha::Plugins->new()->GetPlugins({
 825             method => 'check_password',
 826         });
 827         foreach my $plugin ( @plugins ) {
 828             # This plugin hook will also be used by a plugin for the Norwegian national
 829             # patron database. This is why we need to pass both the password and the
 830             # borrowernumber to the plugin.
 831             my $ret = $plugin->check_password(
 832                 {
 833                     password       => $password,
 834                     borrowernumber => $self->borrowernumber
 835                 }
 836             );
 837             # This plugin hook will also be used by a plugin for the Norwegian national
 838             # patron database. This is why we need to call the actual plugins and then
 839             # check skip_validation afterwards.
 840             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 841                 Koha::Exceptions::Password::Plugin->throw();
 842             }
 843         }
 844     }
 845
 846     my $digest = Koha::AuthUtils::hash_password($password);
 847
 848     # We do not want to call $self->store and retrieve password from DB
 849     $self->password($digest);
 850     $self->login_attempts(0);
 851     $self->SUPER::store;
 852
 853     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 854         if C4::Context->preference("BorrowersLog");
 855
 856     return $self;
 857 }
 858
 859
 860 =head3 renew_account
 861
 862 my $new_expiry_date = $patron->renew_account
 863
 864 Extending the subscription to the expiry date.
 865
 866 =cut
 867
 868 sub renew_account {
 869     my ($self) = @_;
 870     my $date;
 871     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 872         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 873     } else {
 874         $date =
 875             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 876             ? dt_from_string( $self->dateexpiry )
 877             : dt_from_string;
 878     }
 879     my $expiry_date = $self->category->get_expiry_date($date);
 880
 881     $self->dateexpiry($expiry_date);
 882     $self->date_renewed( dt_from_string() );
 883     $self->store();
 884
 885     $self->add_enrolment_fee_if_needed(1);
 886
 887     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 888     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 889 }
 890
 891 =head3 has_overdues
 892
 893 my $has_overdues = $patron->has_overdues;
 894
 895 Returns the number of patron's overdues
 896
 897 =cut
 898
 899 sub has_overdues {
 900     my ($self) = @_;
 901     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 902     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 903 }
 904
 905 =head3 track_login
 906
 907     $patron->track_login;
 908     $patron->track_login({ force => 1 });
 909
 910     Tracks a (successful) login attempt.
 911     The preference TrackLastPatronActivity must be enabled. Or you
 912     should pass the force parameter.
 913
 914 =cut
 915
 916 sub track_login {
 917     my ( $self, $params ) = @_;
 918     return if
 919         !$params->{force} &&
 920         !C4::Context->preference('TrackLastPatronActivity');
 921     $self->lastseen( dt_from_string() )->store;
 922 }
 923
 924 =head3 move_to_deleted
 925
 926 my $is_moved = $patron->move_to_deleted;
 927
 928 Move a patron to the deletedborrowers table.
 929 This can be done before deleting a patron, to make sure the data are not completely deleted.
 930
 931 =cut
 932
 933 sub move_to_deleted {
 934     my ($self) = @_;
 935     my $patron_infos = $self->unblessed;
 936     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 937     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 938 }
 939
 940 =head3 article_requests
 941
 942 my @requests = $borrower->article_requests();
 943 my $requests = $borrower->article_requests();
 944
 945 Returns either a list of ArticleRequests objects,
 946 or an ArtitleRequests object, depending on the
 947 calling context.
 948
 949 =cut
 950
 951 sub article_requests {
 952     my ( $self ) = @_;
 953
 954     $self->{_article_requests} ||= Koha::ArticleRequests->search({ borrowernumber => $self->borrowernumber() });
 955
 956     return $self->{_article_requests};
 957 }
 958
 959 =head3 article_requests_current
 960
 961 my @requests = $patron->article_requests_current
 962
 963 Returns the article requests associated with this patron that are incomplete
 964
 965 =cut
 966
 967 sub article_requests_current {
 968     my ( $self ) = @_;
 969
 970     $self->{_article_requests_current} ||= Koha::ArticleRequests->search(
 971         {
 972             borrowernumber => $self->id(),
 973             -or          => [
 974                 { status => Koha::ArticleRequest::Status::Pending },
 975                 { status => Koha::ArticleRequest::Status::Processing }
 976             ]
 977         }
 978     );
 979
 980     return $self->{_article_requests_current};
 981 }
 982
 983 =head3 article_requests_finished
 984
 985 my @requests = $biblio->article_requests_finished
 986
 987 Returns the article requests associated with this patron that are completed
 988
 989 =cut
 990
 991 sub article_requests_finished {
 992     my ( $self, $borrower ) = @_;
 993
 994     $self->{_article_requests_finished} ||= Koha::ArticleRequests->search(
 995         {
 996             borrowernumber => $self->id(),
 997             -or          => [
 998                 { status => Koha::ArticleRequest::Status::Completed },
 999                 { status => Koha::ArticleRequest::Status::Canceled }
1000             ]
1001         }
1002     );
1003
1004     return $self->{_article_requests_finished};
1005 }
1006
1007 =head3 add_enrolment_fee_if_needed
1008
1009 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1010
1011 Add enrolment fee for a patron if needed.
1012
1013 $renewal - boolean denoting whether this is an account renewal or not
1014
1015 =cut
1016
1017 sub add_enrolment_fee_if_needed {
1018     my ($self, $renewal) = @_;
1019     my $enrolment_fee = $self->category->enrolmentfee;
1020     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1021         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1022         $self->account->add_debit(
1023             {
1024                 amount     => $enrolment_fee,
1025                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1026                 interface  => C4::Context->interface,
1027                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1028                 type       => $type
1029             }
1030         );
1031     }
1032     return $enrolment_fee || 0;
1033 }
1034
1035 =head3 checkouts
1036
1037 my $checkouts = $patron->checkouts
1038
1039 =cut
1040
1041 sub checkouts {
1042     my ($self) = @_;
1043     my $checkouts = $self->_result->issues;
1044     return Koha::Checkouts->_new_from_dbic( $checkouts );
1045 }
1046
1047 =head3 pending_checkouts
1048
1049 my $pending_checkouts = $patron->pending_checkouts
1050
1051 This method will return the same as $self->checkouts, but with a prefetch on
1052 items, biblio and biblioitems.
1053
1054 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1055
1056 It should not be used directly, prefer to access fields you need instead of
1057 retrieving all these fields in one go.
1058
1059 =cut
1060
1061 sub pending_checkouts {
1062     my( $self ) = @_;
1063     my $checkouts = $self->_result->issues->search(
1064         {},
1065         {
1066             order_by => [
1067                 { -desc => 'me.timestamp' },
1068                 { -desc => 'issuedate' },
1069                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1070             ],
1071             prefetch => { item => { biblio => 'biblioitems' } },
1072         }
1073     );
1074     return Koha::Checkouts->_new_from_dbic( $checkouts );
1075 }
1076
1077 =head3 old_checkouts
1078
1079 my $old_checkouts = $patron->old_checkouts
1080
1081 =cut
1082
1083 sub old_checkouts {
1084     my ($self) = @_;
1085     my $old_checkouts = $self->_result->old_issues;
1086     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1087 }
1088
1089 =head3 get_overdues
1090
1091 my $overdue_items = $patron->get_overdues
1092
1093 Return the overdue items
1094
1095 =cut
1096
1097 sub get_overdues {
1098     my ($self) = @_;
1099     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1100     return $self->checkouts->search(
1101         {
1102             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1103         },
1104         {
1105             prefetch => { item => { biblio => 'biblioitems' } },
1106         }
1107     );
1108 }
1109
1110 =head3 get_routing_lists
1111
1112 my @routinglists = $patron->get_routing_lists
1113
1114 Returns the routing lists a patron is subscribed to.
1115
1116 =cut
1117
1118 sub get_routing_lists {
1119     my ($self) = @_;
1120     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1121     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1122 }
1123
1124 =head3 get_age
1125
1126 my $age = $patron->get_age
1127
1128 Return the age of the patron
1129
1130 =cut
1131
1132 sub get_age {
1133     my ($self)    = @_;
1134     my $today_str = dt_from_string->strftime("%Y-%m-%d");
1135     return unless $self->dateofbirth;
1136     my $dob_str   = dt_from_string( $self->dateofbirth )->strftime("%Y-%m-%d");
1137
1138     my ( $dob_y,   $dob_m,   $dob_d )   = split /-/, $dob_str;
1139     my ( $today_y, $today_m, $today_d ) = split /-/, $today_str;
1140
1141     my $age = $today_y - $dob_y;
1142     if ( $dob_m . $dob_d > $today_m . $today_d ) {
1143         $age--;
1144     }
1145
1146     return $age;
1147 }
1148
1149 =head3 is_valid_age
1150
1151 my $is_valid = $patron->is_valid_age
1152
1153 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1154
1155 =cut
1156
1157 sub is_valid_age {
1158     my ($self) = @_;
1159     my $age = $self->get_age;
1160
1161     my $patroncategory = $self->category;
1162     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1163
1164     return (defined($age) && (($high && ($age > $high)) or ($age < $low))) ? 0 : 1;
1165 }
1166
1167 =head3 account
1168
1169 my $account = $patron->account
1170
1171 =cut
1172
1173 sub account {
1174     my ($self) = @_;
1175     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1176 }
1177
1178 =head3 holds
1179
1180 my $holds = $patron->holds
1181
1182 Return all the holds placed by this patron
1183
1184 =cut
1185
1186 sub holds {
1187     my ($self) = @_;
1188     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1189     return Koha::Holds->_new_from_dbic($holds_rs);
1190 }
1191
1192 =head3 old_holds
1193
1194 my $old_holds = $patron->old_holds
1195
1196 Return all the historical holds for this patron
1197
1198 =cut
1199
1200 sub old_holds {
1201     my ($self) = @_;
1202     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1203     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1204 }
1205
1206 =head3 return_claims
1207
1208 my $return_claims = $patron->return_claims
1209
1210 =cut
1211
1212 sub return_claims {
1213     my ($self) = @_;
1214     my $return_claims = $self->_result->return_claims_borrowernumbers;
1215     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1216 }
1217
1218 =head3 notice_email_address
1219
1220   my $email = $patron->notice_email_address;
1221
1222 Return the email address of patron used for notices.
1223 Returns the empty string if no email address.
1224
1225 =cut
1226
1227 sub notice_email_address{
1228     my ( $self ) = @_;
1229
1230     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1231     # if syspref is set to 'first valid' (value == OFF), look up email address
1232     if ( $which_address eq 'OFF' ) {
1233         return $self->first_valid_email_address;
1234     }
1235
1236     return $self->$which_address || '';
1237 }
1238
1239 =head3 first_valid_email_address
1240
1241 my $first_valid_email_address = $patron->first_valid_email_address
1242
1243 Return the first valid email address for a patron.
1244 For now, the order  is defined as email, emailpro, B_email.
1245 Returns the empty string if the borrower has no email addresses.
1246
1247 =cut
1248
1249 sub first_valid_email_address {
1250     my ($self) = @_;
1251
1252     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1253 }
1254
1255 =head3 get_club_enrollments
1256
1257 =cut
1258
1259 sub get_club_enrollments {
1260     my ( $self, $return_scalar ) = @_;
1261
1262     my $e = Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1263
1264     return $e if $return_scalar;
1265
1266     return wantarray ? $e->as_list : $e;
1267 }
1268
1269 =head3 get_enrollable_clubs
1270
1271 =cut
1272
1273 sub get_enrollable_clubs {
1274     my ( $self, $is_enrollable_from_opac, $return_scalar ) = @_;
1275
1276     my $params;
1277     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1278       if $is_enrollable_from_opac;
1279     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1280
1281     $params->{borrower} = $self;
1282
1283     my $e = Koha::Clubs->get_enrollable($params);
1284
1285     return $e if $return_scalar;
1286
1287     return wantarray ? $e->as_list : $e;
1288 }
1289
1290 =head3 account_locked
1291
1292 my $is_locked = $patron->account_locked
1293
1294 Return true if the patron has reached the maximum number of login attempts
1295 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1296 as an administrative lockout (independent of FailedLoginAttempts; see also
1297 Koha::Patron->lock).
1298 Otherwise return false.
1299 If the pref is not set (empty string, null or 0), the feature is considered as
1300 disabled.
1301
1302 =cut
1303
1304 sub account_locked {
1305     my ($self) = @_;
1306     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1307     return 1 if $FailedLoginAttempts
1308           and $self->login_attempts
1309           and $self->login_attempts >= $FailedLoginAttempts;
1310     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1311     return 0;
1312 }
1313
1314 =head3 can_see_patron_infos
1315
1316 my $can_see = $patron->can_see_patron_infos( $patron );
1317
1318 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1319
1320 =cut
1321
1322 sub can_see_patron_infos {
1323     my ( $self, $patron ) = @_;
1324     return unless $patron;
1325     return $self->can_see_patrons_from( $patron->library->branchcode );
1326 }
1327
1328 =head3 can_see_patrons_from
1329
1330 my $can_see = $patron->can_see_patrons_from( $branchcode );
1331
1332 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1333
1334 =cut
1335
1336 sub can_see_patrons_from {
1337     my ( $self, $branchcode ) = @_;
1338     my $can = 0;
1339     if ( $self->branchcode eq $branchcode ) {
1340         $can = 1;
1341     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1342         $can = 1;
1343     } elsif ( my $library_groups = $self->library->library_groups ) {
1344         while ( my $library_group = $library_groups->next ) {
1345             if ( $library_group->parent->has_child( $branchcode ) ) {
1346                 $can = 1;
1347                 last;
1348             }
1349         }
1350     }
1351     return $can;
1352 }
1353
1354 =head3 libraries_where_can_see_patrons
1355
1356 my $libraries = $patron-libraries_where_can_see_patrons;
1357
1358 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1359 The branchcodes are arbitrarily returned sorted.
1360 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1361
1362 An empty array means no restriction, the patron can see patron's infos from any libraries.
1363
1364 =cut
1365
1366 sub libraries_where_can_see_patrons {
1367     my ( $self ) = @_;
1368     my $userenv = C4::Context->userenv;
1369
1370     return () unless $userenv; # For tests, but userenv should be defined in tests...
1371
1372     my @restricted_branchcodes;
1373     if (C4::Context::only_my_library) {
1374         push @restricted_branchcodes, $self->branchcode;
1375     }
1376     else {
1377         unless (
1378             $self->has_permission(
1379                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1380             )
1381           )
1382         {
1383             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1384             if ( $library_groups->count )
1385             {
1386                 while ( my $library_group = $library_groups->next ) {
1387                     my $parent = $library_group->parent;
1388                     if ( $parent->has_child( $self->branchcode ) ) {
1389                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1390                     }
1391                 }
1392             }
1393
1394             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1395         }
1396     }
1397
1398     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1399     @restricted_branchcodes = uniq(@restricted_branchcodes);
1400     @restricted_branchcodes = sort(@restricted_branchcodes);
1401     return @restricted_branchcodes;
1402 }
1403
1404 =head3 has_permission
1405
1406 my $permission = $patron->has_permission($required);
1407
1408 See C4::Auth::haspermission for details of syntax for $required
1409
1410 =cut
1411
1412 sub has_permission {
1413     my ( $self, $flagsrequired ) = @_;
1414     return unless $self->userid;
1415     # TODO code from haspermission needs to be moved here!
1416     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1417 }
1418
1419 =head3 is_superlibrarian
1420
1421   my $is_superlibrarian = $patron->is_superlibrarian;
1422
1423 Return true if the patron is a superlibrarian.
1424
1425 =cut
1426
1427 sub is_superlibrarian {
1428     my ($self) = @_;
1429     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1430 }
1431
1432 =head3 is_adult
1433
1434 my $is_adult = $patron->is_adult
1435
1436 Return true if the patron has a category with a type Adult (A) or Organization (I)
1437
1438 =cut
1439
1440 sub is_adult {
1441     my ( $self ) = @_;
1442     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1443 }
1444
1445 =head3 is_child
1446
1447 my $is_child = $patron->is_child
1448
1449 Return true if the patron has a category with a type Child (C)
1450
1451 =cut
1452
1453 sub is_child {
1454     my( $self ) = @_;
1455     return $self->category->category_type eq 'C' ? 1 : 0;
1456 }
1457
1458 =head3 has_valid_userid
1459
1460 my $patron = Koha::Patrons->find(42);
1461 $patron->userid( $new_userid );
1462 my $has_a_valid_userid = $patron->has_valid_userid
1463
1464 my $patron = Koha::Patron->new( $params );
1465 my $has_a_valid_userid = $patron->has_valid_userid
1466
1467 Return true if the current userid of this patron is valid/unique, otherwise false.
1468
1469 Note that this should be done in $self->store instead and raise an exception if needed.
1470
1471 =cut
1472
1473 sub has_valid_userid {
1474     my ($self) = @_;
1475
1476     return 0 unless $self->userid;
1477
1478     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1479
1480     my $already_exists = Koha::Patrons->search(
1481         {
1482             userid => $self->userid,
1483             (
1484                 $self->in_storage
1485                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1486                 : ()
1487             ),
1488         }
1489     )->count;
1490     return $already_exists ? 0 : 1;
1491 }
1492
1493 =head3 generate_userid
1494
1495 my $patron = Koha::Patron->new( $params );
1496 $patron->generate_userid
1497
1498 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1499
1500 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1501
1502 =cut
1503
1504 sub generate_userid {
1505     my ($self) = @_;
1506     my $offset = 0;
1507     my $firstname = $self->firstname // q{};
1508     my $surname = $self->surname // q{};
1509     #The script will "do" the following code and increment the $offset until the generated userid is unique
1510     do {
1511       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1512       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1513       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1514       $userid = NFKD( $userid );
1515       $userid =~ s/\p{NonspacingMark}//g;
1516       $userid .= $offset unless $offset == 0;
1517       $self->userid( $userid );
1518       $offset++;
1519      } while (! $self->has_valid_userid );
1520
1521      return $self;
1522 }
1523
1524 =head3 add_extended_attribute
1525
1526 =cut
1527
1528 sub add_extended_attribute {
1529     my ($self, $attribute) = @_;
1530     $attribute->{borrowernumber} = $self->borrowernumber;
1531     return Koha::Patron::Attribute->new($attribute)->store;
1532 }
1533
1534 =head3 extended_attributes
1535
1536 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1537
1538 Or setter FIXME
1539
1540 =cut
1541
1542 sub extended_attributes {
1543     my ( $self, $attributes ) = @_;
1544     if ($attributes) {    # setter
1545         my $schema = $self->_result->result_source->schema;
1546         $schema->txn_do(
1547             sub {
1548                 # Remove the existing one
1549                 $self->extended_attributes->filter_by_branch_limitations->delete;
1550
1551                 # Insert the new ones
1552                 for my $attribute (@$attributes) {
1553                     eval {
1554                         $self->_result->create_related('borrower_attributes', $attribute);
1555                     };
1556                     # FIXME We should:
1557                     # 1 - Raise an exception
1558                     # 2 - Execute in a transaction and don't save
1559                     #  or Insert anyway but display a message on the UI
1560                     warn $@ if $@;
1561                 }
1562             }
1563         );
1564     }
1565
1566     my $rs = $self->_result->borrower_attributes;
1567     # We call search to use the filters in Koha::Patron::Attributes->search
1568     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1569 }
1570
1571 =head3 lock
1572
1573     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1574
1575     Lock and optionally expire a patron account.
1576     Remove holds and article requests if remove flag set.
1577     In order to distinguish from locking by entering a wrong password, let's
1578     call this an administrative lockout.
1579
1580 =cut
1581
1582 sub lock {
1583     my ( $self, $params ) = @_;
1584     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1585     if( $params->{expire} ) {
1586         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1587     }
1588     $self->store;
1589     if( $params->{remove} ) {
1590         $self->holds->delete;
1591         $self->article_requests->delete;
1592     }
1593     return $self;
1594 }
1595
1596 =head3 anonymize
1597
1598     Koha::Patrons->find($id)->anonymize;
1599
1600     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1601     are randomized, other personal data is cleared too.
1602     Patrons with issues are skipped.
1603
1604 =cut
1605
1606 sub anonymize {
1607     my ( $self ) = @_;
1608     if( $self->_result->issues->count ) {
1609         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1610         return;
1611     }
1612     # Mandatory fields come from the corresponding pref, but email fields
1613     # are removed since scrambled email addresses only generate errors
1614     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1615         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1616     $mandatory->{userid} = 1; # needed since sub store does not clear field
1617     my @columns = $self->_result->result_source->columns;
1618     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized/ } @columns;
1619     push @columns, 'dateofbirth'; # add this date back in
1620     foreach my $col (@columns) {
1621         $self->_anonymize_column($col, $mandatory->{lc $col} );
1622     }
1623     $self->anonymized(1)->store;
1624 }
1625
1626 sub _anonymize_column {
1627     my ( $self, $col, $mandatory ) = @_;
1628     my $col_info = $self->_result->result_source->column_info($col);
1629     my $type = $col_info->{data_type};
1630     my $nullable = $col_info->{is_nullable};
1631     my $val;
1632     if( $type =~ /char|text/ ) {
1633         $val = $mandatory
1634             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1635             : $nullable
1636             ? undef
1637             : q{};
1638     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1639         $val = $nullable ? undef : 0;
1640     } elsif( $type =~ /date|time/ ) {
1641         $val = $nullable ? undef : dt_from_string;
1642     }
1643     $self->$col($val);
1644 }
1645
1646 =head3 add_guarantor
1647
1648     my @relationships = $patron->add_guarantor(
1649         {
1650             borrowernumber => $borrowernumber,
1651             relationships  => $relationship,
1652         }
1653     );
1654
1655     Adds a new guarantor to a patron.
1656
1657 =cut
1658
1659 sub add_guarantor {
1660     my ( $self, $params ) = @_;
1661
1662     my $guarantor_id = $params->{guarantor_id};
1663     my $relationship = $params->{relationship};
1664
1665     return Koha::Patron::Relationship->new(
1666         {
1667             guarantee_id => $self->id,
1668             guarantor_id => $guarantor_id,
1669             relationship => $relationship
1670         }
1671     )->store();
1672 }
1673
1674 =head3 get_extended_attribute
1675
1676 my $attribute_value = $patron->get_extended_attribute( $code );
1677
1678 Return the attribute for the code passed in parameter.
1679
1680 It not exist it returns undef
1681
1682 Note that this will not work for repeatable attribute types.
1683
1684 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1685 (which should be a real patron's attribute (not extended)
1686
1687 =cut
1688
1689 sub get_extended_attribute {
1690     my ( $self, $code, $value ) = @_;
1691     my $rs = $self->_result->borrower_attributes;
1692     return unless $rs;
1693     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1694     return unless $attribute->count;
1695     return $attribute->next;
1696 }
1697
1698 =head3 to_api
1699
1700     my $json = $patron->to_api;
1701
1702 Overloaded method that returns a JSON representation of the Koha::Patron object,
1703 suitable for API output.
1704
1705 =cut
1706
1707 sub to_api {
1708     my ( $self, $params ) = @_;
1709
1710     my $json_patron = $self->SUPER::to_api( $params );
1711
1712     $json_patron->{restricted} = ( $self->is_debarred )
1713                                     ? Mojo::JSON->true
1714                                     : Mojo::JSON->false;
1715
1716     return $json_patron;
1717 }
1718
1719 =head3 to_api_mapping
1720
1721 This method returns the mapping for representing a Koha::Patron object
1722 on the API.
1723
1724 =cut
1725
1726 sub to_api_mapping {
1727     return {
1728         borrowernotes       => 'staff_notes',
1729         borrowernumber      => 'patron_id',
1730         branchcode          => 'library_id',
1731         categorycode        => 'category_id',
1732         checkprevcheckout   => 'check_previous_checkout',
1733         contactfirstname    => undef,                     # Unused
1734         contactname         => undef,                     # Unused
1735         contactnote         => 'altaddress_notes',
1736         contacttitle        => undef,                     # Unused
1737         dateenrolled        => 'date_enrolled',
1738         dateexpiry          => 'expiry_date',
1739         dateofbirth         => 'date_of_birth',
1740         debarred            => undef,                     # replaced by 'restricted'
1741         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1742         emailpro            => 'secondary_email',
1743         flags               => undef,    # permissions manipulation handled in /permissions
1744         gonenoaddress       => 'incorrect_address',
1745         guarantorid         => 'guarantor_id',
1746         lastseen            => 'last_seen',
1747         lost                => 'patron_card_lost',
1748         opacnote            => 'opac_notes',
1749         othernames          => 'other_name',
1750         password            => undef,            # password manipulation handled in /password
1751         phonepro            => 'secondary_phone',
1752         relationship        => 'relationship_type',
1753         sex                 => 'gender',
1754         smsalertnumber      => 'sms_number',
1755         sort1               => 'statistics_1',
1756         sort2               => 'statistics_2',
1757         autorenew_checkouts => 'autorenew_checkouts',
1758         streetnumber        => 'street_number',
1759         streettype          => 'street_type',
1760         zipcode             => 'postal_code',
1761         B_address           => 'altaddress_address',
1762         B_address2          => 'altaddress_address2',
1763         B_city              => 'altaddress_city',
1764         B_country           => 'altaddress_country',
1765         B_email             => 'altaddress_email',
1766         B_phone             => 'altaddress_phone',
1767         B_state             => 'altaddress_state',
1768         B_streetnumber      => 'altaddress_street_number',
1769         B_streettype        => 'altaddress_street_type',
1770         B_zipcode           => 'altaddress_postal_code',
1771         altcontactaddress1  => 'altcontact_address',
1772         altcontactaddress2  => 'altcontact_address2',
1773         altcontactaddress3  => 'altcontact_city',
1774         altcontactcountry   => 'altcontact_country',
1775         altcontactfirstname => 'altcontact_firstname',
1776         altcontactphone     => 'altcontact_phone',
1777         altcontactsurname   => 'altcontact_surname',
1778         altcontactstate     => 'altcontact_state',
1779         altcontactzipcode   => 'altcontact_postal_code'
1780     };
1781 }
1782
1783 =head2 Internal methods
1784
1785 =head3 _type
1786
1787 =cut
1788
1789 sub _type {
1790     return 'Borrower';
1791 }
1792
1793 =head1 AUTHORS
1794
1795 Kyle M Hall <kyle@bywatersolutions.com>
1796 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
1797 Martin Renvoize <martin.renvoize@ptfs-europe.com>
1798
1799 =cut
1800
1801 1;