cataloguing/additem.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2004-2010 BibLibre
   5 # Parts Copyright Catalyst IT 2011
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use C4::Auth qw( get_template_and_user haspermission );
  26 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  27 use C4::Biblio qw(
  28     GetFrameworkCode
  29     GetMarcBiblio
  30     GetMarcFromKohaField
  31     GetMarcStructure
  32     IsMarcStructureInternal
  33     ModBiblio
  34 );
  35 use C4::Context;
  36 use C4::Circulation qw( barcodedecode LostItem );
  37 use C4::Barcodes;
  38 use C4::Barcodes::ValueBuilder;
  39 use Koha::DateUtils qw( dt_from_string );
  40 use Koha::Items;
  41 use Koha::ItemTypes;
  42 use Koha::Libraries;
  43 use Koha::Patrons;
  44 use Koha::SearchEngine::Indexer;
  45 use C4::Search qw( enabled_staff_search_views );
  46 use Storable qw( freeze thaw );
  47 use URI::Escape qw( uri_escape_utf8 );
  48 use C4::Members;
  49 use Koha::UI::Form::Builder::Item;
  50
  51 use MARC::File::XML;
  52 use URI::Escape qw( uri_escape_utf8 );
  53 use Encode qw( encode_utf8 );
  54 use MIME::Base64 qw( decode_base64url encode_base64url );
  55 use List::Util qw( first );
  56 use List::MoreUtils qw( any uniq );
  57
  58 our $dbh = C4::Context->dbh;
  59
  60 sub get_item_from_cookie {
  61     my ( $input ) = @_;
  62
  63     my $item_from_cookie;
  64     my $lastitemcookie = $input->cookie('LastCreatedItem');
  65     if ($lastitemcookie) {
  66         $lastitemcookie = decode_base64url($lastitemcookie);
  67         eval {
  68             if ( thaw($lastitemcookie) ) {
  69                 $item_from_cookie = thaw($lastitemcookie);
  70             }
  71         };
  72         if ($@) {
  73             $lastitemcookie ||= 'undef';
  74             warn "Storable::thaw failed to thaw LastCreatedItem-cookie. Cookie value '".encode_base64url($lastitemcookie)."'. Caught error follows: '$@'";
  75         }
  76     }
  77     return $item_from_cookie;
  78 }
  79
  80 my $input        = CGI->new;
  81
  82 my $biblionumber;
  83 my $itemnumber;
  84 if( $input->param('itemnumber') && !$input->param('biblionumber') ){
  85     $itemnumber = $input->param('itemnumber');
  86     my $item = Koha::Items->find( $itemnumber );
  87     $biblionumber = $item->biblionumber;
  88 } else {
  89     $biblionumber = $input->param('biblionumber');
  90     $itemnumber = $input->param('itemnumber');
  91 }
  92
  93 my $biblio = Koha::Biblios->find($biblionumber);
  94
  95 my $op           = $input->param('op') || q{};
  96 my $hostitemnumber = $input->param('hostitemnumber');
  97 my $marcflavour  = C4::Context->preference("marcflavour");
  98 my $searchid     = $input->param('searchid');
  99 # fast cataloguing datas
 100 my $fa_circborrowernumber = $input->param('circborrowernumber');
 101 my $fa_barcode            = $input->param('barcode');
 102 my $fa_branch             = $input->param('branch');
 103 my $fa_stickyduedate      = $input->param('stickyduedate');
 104 my $fa_duedatespec        = $input->param('duedatespec');
 105
 106 our $frameworkcode = &GetFrameworkCode($biblionumber);
 107
 108 # Defining which userflag is needing according to the framework currently used
 109 my $userflags;
 110 if (defined $input->param('frameworkcode')) {
 111     $userflags = ($input->param('frameworkcode') eq 'FA') ? "fast_cataloging" : "edit_items";
 112 }
 113
 114 if (not defined $userflags) {
 115     $userflags = ($frameworkcode eq 'FA') ? "fast_cataloging" : "edit_items";
 116 }
 117
 118 my ($template, $loggedinuser, $cookie)
 119     = get_template_and_user({template_name => "cataloguing/additem.tt",
 120                  query => $input,
 121                  type => "intranet",
 122                  flagsrequired => {editcatalogue => $userflags},
 123                  });
 124
 125
 126 # Does the user have a restricted item editing permission?
 127 my $uid = Koha::Patrons->find( $loggedinuser )->userid;
 128 my $restrictededition = $uid ? haspermission($uid,  {'editcatalogue' => 'edit_items_restricted'}) : undef;
 129 # In case user is a superlibrarian, editing is not restricted
 130 $restrictededition = 0 if ($restrictededition != 0 &&  C4::Context->IsSuperLibrarian());
 131 # In case user has fast cataloging permission (and we're in fast cataloging), editing is not restricted
 132 $restrictededition = 0 if ($restrictededition != 0 && $frameworkcode eq 'FA' && haspermission($uid, {'editcatalogue' => 'fast_cataloging'}));
 133
 134 our $tagslib = &GetMarcStructure(1,$frameworkcode);
 135 my $record = GetMarcBiblio({ biblionumber => $biblionumber });
 136
 137 output_and_exit_if_error( $input, $cookie, $template,
 138     { module => 'cataloguing', record => $record } );
 139
 140 my $current_item;
 141 my $nextop="additem";
 142 my @errors; # store errors found while checking data BEFORE saving item.
 143
 144 # Getting last created item cookie
 145 my $prefillitem = C4::Context->preference('PrefillItem');
 146
 147 #-------------------------------------------------------------------------------
 148 if ($op eq "additem") {
 149
 150     my $add_submit                 = $input->param('add_submit');
 151     my $add_duplicate_submit       = $input->param('add_duplicate_submit');
 152     my $add_multiple_copies_submit = $input->param('add_multiple_copies_submit');
 153     my $number_of_copies           = $input->param('number_of_copies');
 154
 155     my @columns = Koha::Items->columns;
 156     my $item = Koha::Item->new;
 157     $item->biblionumber($biblio->biblionumber);
 158     for my $c ( @columns ) {
 159         if ( $c eq 'more_subfields_xml' ) {
 160             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 161             my @unlinked_item_subfields;
 162             for my $subfield ( @more_subfields_xml ) {
 163                 my $v = $input->param('items.more_subfields_xml_' . $subfield);
 164                 push @unlinked_item_subfields, $subfield, $v;
 165             }
 166             if ( @unlinked_item_subfields ) {
 167                 my $marc = MARC::Record->new();
 168                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 169                 # used in the framework
 170                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 171                 $marc->encoding("UTF-8");
 172                 $item->more_subfields_xml($marc->as_xml("USMARC"));
 173                 next;
 174             }
 175             $item->more_subfields_xml(undef);
 176         } else {
 177             my @v = grep { $_ ne "" }
 178                 uniq $input->multi_param( "items." . $c );
 179
 180             next unless @v;
 181
 182             if ( $c eq 'permanent_location' ) { # See 27837
 183                 $item->make_column_dirty('permanent_location');
 184             }
 185
 186             $item->$c(join ' | ', @v);
 187         }
 188     }
 189
 190     # if autoBarcode is set to 'incremental', calculate barcode...
 191     if ( ! defined $item->barcode && C4::Context->preference('autoBarcode') eq 'incremental' ) {
 192         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 193         $item->barcode($barcode);
 194     }
 195
 196     $item->barcode(barcodedecode($item->barcode));
 197
 198     # If we have to add or add & duplicate, we add the item
 199     if ( $add_submit || $add_duplicate_submit || $prefillitem) {
 200
 201         # check for item barcode # being unique
 202         if ( defined $item->barcode
 203             && Koha::Items->search( { barcode => $item->barcode } )->count )
 204         {
 205             # if barcode exists, don't create, but report The problem.
 206             push @errors, "barcode_not_unique";
 207
 208             $current_item = $item->unblessed; # Restore edit form for the same item
 209         }
 210         else {
 211             $item->store->discard_changes;
 212
 213             # This is a bit tricky : if there is a cookie for the last created item and
 214             # we just added an item, the cookie value is not correct yet (it will be updated
 215             # next page). To prevent the form from being filled with outdated values, we
 216             # force the use of "add and duplicate" feature, so the form will be filled with
 217             # correct values.
 218
 219             # Pushing the last created item cookie back
 220             if ( $prefillitem ) {
 221                 my $last_created_item_cookie = $input->cookie(
 222                     -name => 'LastCreatedItem',
 223                     # We encode_base64url the whole freezed structure so we're sure we won't have any encoding problems
 224                     -value   => encode_base64url( freeze( { %{$item->unblessed}, itemnumber => undef } ) ),
 225                     -HttpOnly => 1,
 226                     -expires => ''
 227                 );
 228
 229                 $cookie = [ $cookie, $last_created_item_cookie ];
 230             }
 231
 232         }
 233         $nextop = "additem";
 234
 235     }
 236
 237     # If we have to add & duplicate
 238     if ($prefillitem || $add_duplicate_submit) {
 239
 240         $current_item = $item->unblessed;
 241
 242         if (C4::Context->preference('autoBarcode') eq 'incremental') {
 243             my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 244             $current_item->{barcode} = $barcode;
 245         }
 246         else {
 247             # we have to clear the barcode field in the duplicate item record to make way for the new one generated by the javascript plugin
 248             $current_item->{barcode} = undef; # FIXME or delete?
 249         }
 250
 251         # Don't use the "prefill" feature if we want to generate the form with all the info from this item
 252         # It will remove subfields that are not in SubfieldsToUseWhenPrefill.
 253         $prefillitem = 0 if $add_duplicate_submit;
 254     }
 255
 256     # If we have to add multiple copies
 257     if ($add_multiple_copies_submit) {
 258
 259         $current_item = $item->unblessed;
 260
 261         my $copynumber = $current_item->{copynumber};
 262         my $oldbarcode = $current_item->{barcode};
 263
 264         # If there is a barcode and we can't find their new values, we can't add multiple copies
 265         my $testbarcode;
 266         my $barcodeobj = C4::Barcodes->new;
 267         $testbarcode = $barcodeobj->next_value($oldbarcode) if $barcodeobj;
 268         if ( $oldbarcode && !$testbarcode ) {
 269
 270             push @errors, "no_next_barcode";
 271
 272         }
 273         else {
 274             # We add each item
 275
 276             # For the first iteration
 277             my $barcodevalue = $oldbarcode;
 278             my $exist_itemnumber;
 279
 280             for ( my $i = 0 ; $i < $number_of_copies ; ) {
 281
 282                 # If there is a barcode
 283                 if ($barcodevalue) {
 284
 285 # Getting a new barcode (if it is not the first iteration or the barcode we tried already exists)
 286                     $barcodevalue = $barcodeobj->next_value($oldbarcode)
 287                       if ( $i > 0 || $exist_itemnumber );
 288
 289                     # Putting it into the record
 290                     if ($barcodevalue) {
 291                         if ( C4::Context->preference("autoBarcode") eq
 292                             'hbyymmincr' && $i > 0 )
 293                         { # The first copy already contains the homebranch prefix
 294                              # This is terribly hacky but the easiest way to fix the way hbyymmincr is working
 295                              # Contrary to what one might think, the barcode plugin does not prefix the returned string with the homebranch
 296                              # For a single item, it is handled with some JS code (see cataloguing/value_builder/barcode.pl)
 297                              # But when adding multiple copies we need to prefix it here,
 298                              # so we retrieve the homebranch from the item and prefix the barcode with it.
 299                             my $homebranch = $current_item->{homebranch};
 300                             $barcodevalue = $homebranch . $barcodevalue;
 301                         }
 302                         $current_item->{barcode} = $barcodevalue;
 303                     }
 304
 305                     # Checking if the barcode already exists
 306                     $exist_itemnumber = Koha::Items->search({ barcode => $barcodevalue })->count;
 307                 }
 308
 309                 # Updating record with the new copynumber
 310                 if ($copynumber) {
 311                     $current_item->{copynumber} = $copynumber;
 312                 }
 313
 314                 # Adding the item
 315                 if ( !$exist_itemnumber ) {
 316                     delete $current_item->{itemnumber};
 317                     $current_item = Koha::Item->new($current_item)->store(
 318                         { skip_record_index => 1 } );
 319                     $current_item->discard_changes; # Cannot chain discard_changes
 320                     $current_item = $current_item->unblessed;
 321
 322 # We count the item only if it was really added
 323 # That way, all items are added, even if there was some already existing barcodes
 324 # FIXME : Please note that there is a risk of infinite loop here if we never find a suitable barcode
 325                     $i++;
 326
 327                     # Only increment copynumber if item was really added
 328                     $copynumber++ if ( $copynumber && $copynumber =~ m/^\d+$/ );
 329                 }
 330
 331                 # Preparing the next iteration
 332                 $oldbarcode = $barcodevalue;
 333             }
 334
 335             my $indexer = Koha::SearchEngine::Indexer->new(
 336                 { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 337             $indexer->index_records( $biblionumber, "specialUpdate",
 338                 "biblioserver" );
 339
 340             undef($current_item);
 341         }
 342     }
 343     if ($frameworkcode eq 'FA' && $fa_circborrowernumber){
 344         print $input->redirect(
 345            '/cgi-bin/koha/circ/circulation.pl?'
 346            .'borrowernumber='.$fa_circborrowernumber
 347            .'&barcode='.uri_escape_utf8($fa_barcode)
 348            .'&duedatespec='.$fa_duedatespec
 349            .'&stickyduedate='.$fa_stickyduedate
 350         );
 351         exit;
 352     }
 353
 354
 355 #-------------------------------------------------------------------------------
 356 } elsif ($op eq "edititem") {
 357 #-------------------------------------------------------------------------------
 358 # retrieve item if exist => then, it's a modif
 359     $current_item = Koha::Items->find($itemnumber)->unblessed;
 360     # FIXME Handle non existent item
 361     $nextop = "saveitem";
 362 #-------------------------------------------------------------------------------
 363 } elsif ($op eq "dupeitem") {
 364 #-------------------------------------------------------------------------------
 365 # retrieve item if exist => then, it's a modif
 366     $current_item = Koha::Items->find($itemnumber)->unblessed;
 367     # FIXME Handle non existent item
 368     if (C4::Context->preference('autoBarcode') eq 'incremental') {
 369         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 370         $current_item->{barcode} = $barcode;
 371     }
 372     else {
 373         $current_item->{barcode} = undef; # Don't save it!
 374     }
 375
 376     $nextop = "additem";
 377 #-------------------------------------------------------------------------------
 378 } elsif ($op eq "delitem") {
 379 #-------------------------------------------------------------------------------
 380     # check that there is no issue on this item before deletion.
 381     my $item = Koha::Items->find($itemnumber);
 382     my $error = $item->safe_delete;
 383     if(ref($error) eq 'Koha::Item'){
 384         print $input->redirect("additem.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid");
 385     }else{
 386         push @errors,$error;
 387         $nextop="additem";
 388     }
 389 #-------------------------------------------------------------------------------
 390 } elsif ($op eq "delallitems") {
 391 #-------------------------------------------------------------------------------
 392     my $items = Koha::Items->search({ biblionumber => $biblionumber });
 393     while ( my $item = $items->next ) {
 394         my $error = $item->safe_delete({ skip_record_index => 1 });
 395         next if ref $error eq 'Koha::Item'; # Deleted item is returned if deletion successful
 396         push @errors,$error;
 397     }
 398     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 399     $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 400     if ( @errors ) {
 401         $nextop="additem";
 402     } else {
 403         my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 404         my $views = { C4::Search::enabled_staff_search_views };
 405         if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 406             print $input->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 407         } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 408             print $input->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 409         } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 410             print $input->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 411         } else {
 412             print $input->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&searchid=$searchid");
 413         }
 414         exit;
 415     }
 416 #-------------------------------------------------------------------------------
 417 } elsif ($op eq "saveitem") {
 418 #-------------------------------------------------------------------------------
 419
 420     my $itemnumber = $input->param('itemnumber');
 421     my $item = Koha::Items->find($itemnumber);
 422     # FIXME Handle non existent item
 423     my $olditemlost = $item->itemlost;
 424     my @columns = Koha::Items->columns;
 425     my $new_values = $item->unblessed;
 426     for my $c ( @columns ) {
 427         if ( $c eq 'more_subfields_xml' ) {
 428             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 429             my @unlinked_item_subfields;
 430             for my $subfield ( uniq @more_subfields_xml ) {
 431                 my @v = $input->multi_param('items.more_subfields_xml_' . encode_utf8($subfield));
 432                 push @unlinked_item_subfields, $subfield, $_ for @v;
 433             }
 434             if ( @unlinked_item_subfields ) {
 435                 my $marc = MARC::Record->new();
 436                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 437                 # used in the framework
 438                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 439                 $marc->encoding("UTF-8");
 440                 $new_values->{more_subfields_xml} = $marc->as_xml("USMARC");
 441                 next;
 442             }
 443             $item->more_subfields_xml(undef);
 444         } else {
 445             my @v = map { ( defined $_ && $_ eq '' ) ? undef : $_ } $input->multi_param( "items." . $c );
 446             next unless @v;
 447
 448             if ( $c eq 'permanent_location' ) { # See 27837
 449                 $item->make_column_dirty('permanent_location');
 450             }
 451
 452             if ( scalar(@v) == 1 && not defined $v[0] ) {
 453                 delete $new_values->{$c};
 454             } else {
 455                 $new_values->{$c} = join ' | ', @v;
 456             }
 457         }
 458     }
 459     $item = $item->set_or_blank($new_values);
 460
 461     # check that the barcode don't exist already
 462     if (
 463         defined $item->barcode
 464         && Koha::Items->search(
 465             {
 466                 barcode    => $item->barcode,
 467                 itemnumber => { '!=' => $item->itemnumber }
 468             }
 469         )->count
 470       )
 471     {
 472         # FIXME We shouldn't need that, ->store would explode as there is a unique constraint on items.barcode
 473         push @errors,"barcode_not_unique";
 474         $current_item = $item->unblessed; # Restore edit form for the same item
 475     } else {
 476         my $newitemlost = $item->itemlost;
 477         if ( $newitemlost && $newitemlost ge '1' && !$olditemlost ) {
 478             LostItem( $item->itemnumber, 'additem' );
 479         }
 480         $item->store;
 481     }
 482
 483     $nextop="additem";
 484 } elsif ($op eq "delinkitem"){
 485
 486     my $analyticfield = '773';
 487     if ($marcflavour  eq 'MARC21'){
 488         $analyticfield = '773';
 489     } elsif ($marcflavour eq 'UNIMARC') {
 490         $analyticfield = '461';
 491     }
 492     foreach my $field ($record->field($analyticfield)){
 493         if ($field->subfield('9') eq $hostitemnumber){
 494             $record->delete_field($field);
 495             last;
 496         }
 497     }
 498         my $modbibresult = ModBiblio($record, $biblionumber,'');
 499 }
 500
 501 # update OAI-PMH sets
 502 if ($op) {
 503     if (C4::Context->preference("OAI-PMH:AutoUpdateSets")) {
 504         C4::OAI::Sets::UpdateOAISetsBiblio($biblionumber, $record);
 505     }
 506 }
 507
 508 #
 509 #-------------------------------------------------------------------------------
 510 # build screen with existing items. and "new" one
 511 #-------------------------------------------------------------------------------
 512
 513 # now, build existiing item list
 514
 515 my @items;
 516 for my $item ( $biblio->items->as_list, $biblio->host_items->as_list ) {
 517     push @items, $item->columns_to_str;
 518 }
 519
 520 my @witness_attributes = uniq map {
 521     my $item = $_;
 522     map { defined $item->{$_} && $item->{$_} ne "" ? $_ : () } keys %$item
 523 } @items;
 524
 525 our ( $itemtagfield, $itemtagsubfield ) = GetMarcFromKohaField("items.itemnumber");
 526
 527 my $subfieldcode_attribute_mappings;
 528 for my $subfield_code ( keys %{ $tagslib->{$itemtagfield} } ) {
 529
 530     my $subfield = $tagslib->{$itemtagfield}->{$subfield_code};
 531
 532     next if IsMarcStructureInternal( $subfield );
 533     next unless $subfield->{tab} eq 10; # Is this really needed?
 534
 535     my $attribute;
 536     if ( $subfield->{kohafield} ) {
 537         ( $attribute = $subfield->{kohafield} ) =~ s|^items\.||;
 538     } else {
 539         $attribute = $subfield_code; # It's in more_subfields_xml
 540     }
 541     next unless grep { $attribute eq $_ } @witness_attributes;
 542     $subfieldcode_attribute_mappings->{$subfield_code} = $attribute;
 543 }
 544
 545 my @header_value_loop = map {
 546     {
 547         header_value  => $tagslib->{$itemtagfield}->{$_}->{lib},
 548         attribute     => $subfieldcode_attribute_mappings->{$_},
 549         subfield_code => $_,
 550     }
 551 } sort keys %$subfieldcode_attribute_mappings;
 552
 553 # Using last created item if it exists
 554 if (   $prefillitem
 555     && $op ne "additem"
 556     && $op ne "edititem"
 557     && $op ne "dupeitem" )
 558 {
 559     my $item_from_cookie = get_item_from_cookie($input);
 560     $current_item = $item_from_cookie if $item_from_cookie;
 561 }
 562
 563 if ( $current_item->{more_subfields_xml} ) {
 564     # FIXME Use Maybe MARC::Record::new_from_xml if encoding issues on subfield (??)
 565     $current_item->{marc_more_subfields_xml} = MARC::Record->new_from_xml($current_item->{more_subfields_xml}, 'UTF-8');
 566 }
 567
 568 my $branchcode = $input->param('branch') || C4::Context->userenv->{branch};
 569
 570 # If we are not adding a new item
 571 # OR
 572 # If the subfield must be prefilled with last catalogued item
 573 my @subfields_to_prefill;
 574 if ( $nextop eq 'additem' && $op ne 'dupeitem' && $prefillitem ) {
 575     @subfields_to_prefill = split(' ', C4::Context->preference('SubfieldsToUseWhenPrefill'));
 576     # Setting to 1 element if SubfieldsToUseWhenPrefill is empty to prevent all the subfields to be prefilled
 577     @subfields_to_prefill = ("") unless @subfields_to_prefill;
 578 }
 579
 580 # Getting list of subfields to keep when restricted editing is enabled
 581 my @subfields_to_allow = $restrictededition ? split ' ', C4::Context->preference('SubfieldsToAllowForRestrictedEditing') : ();
 582
 583 my $subfields =
 584   Koha::UI::Form::Builder::Item->new(
 585     { biblionumber => $biblionumber, item => $current_item } )->edit_form(
 586     {
 587         branchcode           => $branchcode,
 588         restricted_editition => $restrictededition,
 589         (
 590             @subfields_to_allow
 591             ? ( subfields_to_allow => \@subfields_to_allow )
 592             : ()
 593         ),
 594         (
 595             @subfields_to_prefill
 596             ? ( subfields_to_prefill => \@subfields_to_prefill )
 597             : ()
 598         ),
 599         prefill_with_default_values => 1,
 600         branch_limit => C4::Context->userenv->{"branch"},
 601         (
 602             $op eq 'dupeitem'
 603             ? ( ignore_invisible_subfields => 1 )
 604             : ()
 605         ),
 606     }
 607 );
 608
 609 if (   $frameworkcode eq 'FA' ) {
 610     my ( $barcode_field ) = grep {$_->{kohafield} eq 'items.barcode'} @$subfields;
 611     $barcode_field->{marc_value}->{value} ||= $input->param('barcode');
 612 }
 613
 614 if( my $default_location = C4::Context->preference('NewItemsDefaultLocation') ) {
 615     my ( $location_field ) = grep {$_->{kohafield} eq 'items.location'} @$subfields;
 616     $location_field->{marc_value}->{value} ||= $default_location;
 617 }
 618
 619 # what's the next op ? it's what we are not in : an add if we're editing, otherwise, and edit.
 620 $template->param(
 621     biblio       => $biblio,
 622     items        => \@items,
 623     item_header_loop => \@header_value_loop,
 624     subfields        => $subfields,
 625     itemnumber       => $itemnumber,
 626     barcode          => $current_item->{barcode},
 627     op      => $nextop,
 628     popup => scalar $input->param('popup') ? 1: 0,
 629     C4::Search::enabled_staff_search_views,
 630 );
 631 $template->{'VARS'}->{'searchid'} = $searchid;
 632
 633 if ($frameworkcode eq 'FA'){
 634     # fast cataloguing datas
 635     $template->param(
 636         'circborrowernumber' => $fa_circborrowernumber,
 637         'barcode'            => $fa_barcode,
 638         'branch'             => $fa_branch,
 639         'stickyduedate'      => $fa_stickyduedate,
 640         'duedatespec'        => $fa_duedatespec,
 641     );
 642 }
 643
 644 foreach my $error (@errors) {
 645     $template->param($error => 1);
 646 }
 647 output_html_with_http_headers $input, $cookie, $template->output;