misc/add_date_fields_to_marc_records.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Koha::Script;
  21
  22 use Getopt::Long qw( GetOptions );
  23 use Pod::Usage qw( pod2usage );
  24 use MARC::Field;
  25
  26 use C4::Biblio;
  27 use Koha::Biblios;
  28 use Koha::DateUtils qw( dt_from_string );
  29
  30 my ( $verbose, $help, $confirm, $where, @fields, $date_field, $unless_exists_field );
  31 my $dbh = C4::Context->dbh;
  32
  33 GetOptions(
  34     'help|h'    => \$help,
  35     'verbose|v' => \$verbose,
  36     'confirm|c' => \$confirm,
  37     'where=s'   => \$where,
  38     'field=s@'  => \@fields,
  39     'date-field=s' => \$date_field,
  40     'unless-exists=s' => \$unless_exists_field,
  41 ) || podusage(1);
  42
  43 pod2usage(1) if $help;
  44 pod2usage("Parameter field is mandatory") unless @fields;
  45
  46 say "Confirm flag not passed, running in dry-run mode..." unless $confirm;
  47
  48 my @fields_to_add;
  49 unless ( $date_field ) {
  50     my $dt = dt_from_string;
  51     for my $field (@fields) {
  52         my ( $f_sf, $value )    = split '=',  $field;
  53         my ( $tag,  $subfield ) = split '\$', $f_sf;
  54         push @fields_to_add,
  55           MARC::Field->new( $tag, '', '', $subfield => $dt->strftime($value) );
  56     }
  57
  58     if ($verbose) {
  59         say "The following MARC fields will be added:";
  60         say "\t" . $_->as_formatted for @fields_to_add;
  61     }
  62 }
  63
  64 $where = $where ? "WHERE $where" : '';
  65 my $sth =
  66   $dbh->prepare("SELECT biblionumber, frameworkcode FROM biblio $where");
  67 $sth->execute();
  68
  69 while ( my ( $biblionumber, $frameworkcode ) = $sth->fetchrow_array ) {
  70     my $biblio = Koha::Biblios->find($biblionumber);
  71     my $marc_record = $biblio->metadata->record;
  72     next unless $marc_record;
  73     if ( $unless_exists_field ) {
  74         my ( $tag,  $subfield ) = split '\$', $unless_exists_field;
  75         next if $marc_record->subfield($tag, $subfield);
  76     }
  77     if ( $date_field ) {
  78         @fields_to_add = ();
  79         my ( $tag,  $subfield ) = split '\$', $date_field;
  80         my $date = $marc_record->subfield($tag, $subfield);
  81         next unless $date;
  82         warn $date;
  83         my $dt = dt_from_string($date);
  84         for my $field (@fields) {
  85             my ( $f_sf, $value )    = split '=',  $field;
  86             my ( $tag,  $subfield ) = split '\$', $f_sf;
  87             push @fields_to_add,
  88               MARC::Field->new( $tag, '', '', $subfield => $dt->strftime($value) );
  89         }
  90         if ($verbose) {
  91             say sprintf "The following MARC fields will be added to record %s:", $biblionumber;
  92             say "\t" . $_->as_formatted for @fields_to_add;
  93         }
  94     }
  95
  96     $marc_record->append_fields(@fields_to_add);
  97
  98     if ($confirm) {
  99         my $modified =
 100           C4::Biblio::ModBiblio( $marc_record, $biblionumber, $frameworkcode );
 101         say "Bibliographic record $biblionumber has been modified"
 102           if $verbose and $modified;
 103     }
 104     elsif ($verbose) {
 105         say "Bibliographic record $biblionumber would have been modified";
 106     }
 107 }
 108
 109 =head1 NAME
 110
 111 add_date_fields_to_marc_records.pl
 112
 113 =head1 SYNOPSIS
 114
 115   perl add_date_fields_to_marc_records.pl --help
 116
 117   perl add_date_fields_to_marc_records.pl --field='905$a=0/%Y' --field='905$a=1/%Y/%b-%m' --field='905$a=2/%Y/%b-%m/%d' --unless-exists='905$a' --verbose --confirm
 118
 119   perl add_date_fields_to_marc_records.pl --field='905$a=0/%Y' --field='905$a=1/%Y/%b-%m' --field='905$a=2/%Y/%b-%m/%d' --unless-exists='905$a' --where "biblionumber=42" --verbose --confirm
 120
 121   perl add_date_fields_to_marc_records.pl --field='905$a=0/%Y' --field='905$a=1/%Y/%b-%m' --field='905$a=2/%Y/%b-%m/%d' --date-field='908$a' --verbose --confirm
 122
 123 =head1 DESCRIPTION
 124
 125 Add some MARC fields to bibliographic records.
 126
 127 The replacement tokens are the ones used by strftime.
 128
 129 =head1 OPTIONS
 130
 131 =over 8
 132
 133 =item B<--help>
 134
 135 Prints this help
 136
 137 =item B<--verbose>
 138
 139 Verbose mode.
 140
 141 =item B<--confirm>
 142
 143 Confirmation flag, the script will be running in dry-run mode if set not.
 144
 145 =item B<--where>
 146
 147 Limits the search on bibliographic records with a user-specified WHERE clause.
 148
 149 Only the columns from the biblio table are available.
 150
 151 =item B<--field>
 152
 153 Fields to add to the bibliographic records.
 154
 155 Must be formatted as 'tag' $ 'subfield' = 'value'
 156
 157 For instance:
 158
 159 905$a=0/%Y will add a new field 905$a with the value '0/2019' (if run in 2019)
 160
 161 905$a=2/%Y/%b-%m/%d'will a a new field 905$a with the value '2/2019/Mar-03/13' if run on March 13th 2019
 162
 163 =item B<--unless-exists>
 164
 165 Will only create the new fields if this field does not exist.
 166
 167 For instance, if --field='905$a=0/%Y' and --unless-exists='905$a' are provided, a 905$a will be created unless there is already one.
 168 If --unless-exists is not passed, a new 905$a will be created in any case.
 169
 170 =item B<--date-field>
 171
 172 The date will be picked from a specific marc field.
 173
 174 For instance, if the record contains a date formatted YYYY-MM-DD in 908$a, you can pass --date-field='908$a'
 175 Note that the date format used will be the one defined in the syspref 'dateformat', or iso format.
 176
 177 =back
 178
 179 =cut