misc/search_tools/rebuild_elasticsearch.pl

   1 #!/usr/bin/perl
   2
   3 # This inserts records from a Koha database into elastic search
   4
   5 # Copyright 2014 Catalyst IT
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 =head1 NAME
  23
  24 rebuild_elasticsearch.pl - inserts records from a Koha database into Elasticsearch
  25
  26 =head1 SYNOPSIS
  27
  28 B<rebuild_elasticsearch.pl>
  29 [B<-c|--commit>=C<count>]
  30 [B<-d|--delete>]
  31 [B<-r|--reset>]
  32 [B<-a|--authorities>]
  33 [B<-b|--biblios>]
  34 [B<--desc>]
  35 [B<-bn|--bnumber>]
  36 [B<-ai|--authid>]
  37 [B<-p|--processes>]
  38 [B<-v|--verbose>]
  39 [B<-h|--help>]
  40 [B<--man>]
  41
  42 =head1 DESCRIPTION
  43
  44 Inserts records from a Koha database into Elasticsearch.
  45
  46 =head1 OPTIONS
  47
  48 =over
  49
  50 =item B<-c|--commit>=C<count>
  51
  52 Specify how many records will be batched up before they're added to Elasticsearch.
  53 Higher should be faster, but will cause more RAM usage. Default is 5000.
  54
  55 =item B<-d|--delete>
  56
  57 Delete the index and recreate it before indexing.
  58
  59 =item B<-r|--reset>
  60
  61 Reload mappings from files (specified in koha-conf.xml) before indexing.
  62 Implies --delete.
  63
  64 =item B<-a|--authorities>
  65
  66 Index the authorities only. Combining this with B<-b> is the same as
  67 specifying neither and so both get indexed.
  68
  69 =item B<-b|--biblios>
  70
  71 Index the biblios only. Combining this with B<-a> is the same as
  72 specifying neither and so both get indexed.
  73
  74 =item B<--desc>
  75
  76 Index the records in descending id order. Intended to index newer record before older records.
  77 Default is to index in ascending order.
  78 Does not work with --bnumber or --authid
  79
  80 =item B<-bn|--bnumber>
  81
  82 Only index the supplied biblionumber, mostly for testing purposes. May be
  83 repeated.
  84
  85 =item B<-ai|--authid>
  86
  87 Only index the supplied authority id, mostly for testing purposes. May be
  88 repeated.
  89
  90 =item B<-p|--processes>
  91
  92 Number of processes to use for indexing. This can be used to do more indexing
  93 work in parallel on multicore systems. By default, a single process is used.
  94
  95 =item B<-v|--verbose>
  96
  97 By default, this program only emits warnings and errors. This makes it talk
  98 more. Add more to make it even more wordy, in particular when debugging.
  99
 100 =item B<-h|--help>
 101
 102 Help!
 103
 104 =item B<--man>
 105
 106 Full documentation.
 107
 108 =back
 109
 110 =head1 IMPLEMENTATION
 111
 112 =cut
 113
 114 use autodie;
 115 use Getopt::Long;
 116 use Koha::Script;
 117 use C4::Context;
 118 use Koha::MetadataRecord::Authority;
 119 use Koha::BiblioUtils;
 120 use Koha::SearchEngine::Elasticsearch;
 121 use Koha::SearchEngine::Elasticsearch::Indexer;
 122 use MARC::Field;
 123 use MARC::Record;
 124 use Modern::Perl;
 125 use Pod::Usage;
 126
 127 my $verbose = 0;
 128 my $commit = 5000;
 129 my ($delete, $reset, $help, $man, $processes);
 130 my ($index_biblios, $index_authorities);
 131 my (@biblionumbers,@authids);
 132 my $desc;
 133
 134 $|=1; # flushes output
 135
 136 GetOptions(
 137     'c|commit=i'    => \$commit,
 138     'd|delete'      => \$delete,
 139     'r|reset'       => \$reset,
 140     'a|authorities' => \$index_authorities,
 141     'b|biblios'     => \$index_biblios,
 142     'desc'          => \$desc,
 143     'bn|bnumber=i'  => \@biblionumbers,
 144     'ai|authid=i'   => \@authids,
 145     'p|processes=i' => \$processes,
 146     'v|verbose+'    => \$verbose,
 147     'h|help'        => \$help,
 148     'man'           => \$man,
 149 );
 150
 151 # Default is to do both
 152 unless ($index_authorities || $index_biblios) {
 153     $index_authorities = $index_biblios = 1;
 154 }
 155
 156 if ($processes && ( @biblionumbers || @authids) ) {
 157     die "Argument p|processes cannot be combined with bn|bnumber or ai|authid";
 158 }
 159
 160 pod2usage(1) if $help;
 161 pod2usage( -exitstatus => 0, -verbose => 2 ) if $man;
 162
 163 _sanity_check();
 164
 165 if ($reset){
 166     Koha::SearchEngine::Elasticsearch->reset_elasticsearch_mappings;
 167     $delete = 1;
 168 }
 169
 170 _verify_index_state($Koha::SearchEngine::Elasticsearch::BIBLIOS_INDEX, $delete) if ($index_biblios);
 171 _verify_index_state($Koha::SearchEngine::Elasticsearch::AUTHORITIES_INDEX, $delete) if ($index_authorities);
 172
 173 my $slice_index = 0;
 174 my $slice_count = ( $processes //= 1 );
 175 my %iterator_options;
 176
 177 if ($slice_count > 1) {
 178     # Fire up child processes for processing slices from 2 on. This main process will handle slice 1.
 179     $slice_index = 0;
 180     for (my $proc = 1; $proc < $slice_count; $proc++) {
 181         my $pid = fork();
 182         die "Failed to fork a child process\n" unless defined $pid;
 183         if ($pid == 0) {
 184             # Child process, give it a slice to process
 185             $slice_index = $proc;
 186             last;
 187         }
 188     }
 189     # Fudge the commit count a bit to spread out the Elasticsearch commits
 190     $commit *= 1 + 0.10 * $slice_index;
 191     _log(1, "Processing slice @{[$slice_index + 1]} of $slice_count\n");
 192     $iterator_options{slice} = { index => $slice_index, count => $slice_count };
 193 }
 194
 195 if( $desc ){
 196     $iterator_options{desc} = 1;
 197 }
 198
 199 my $next;
 200 if ($index_biblios) {
 201     _log(1, "Indexing biblios\n");
 202     if (@biblionumbers) {
 203         $next = sub {
 204             my $r = shift @biblionumbers;
 205             return () unless defined $r;
 206             return ($r, Koha::BiblioUtils->get_from_biblionumber($r, item_data => 1 ));
 207         };
 208     } else {
 209         my $records = Koha::BiblioUtils->get_all_biblios_iterator(%iterator_options);
 210         $next = sub {
 211             $records->next();
 212         }
 213     }
 214     _do_reindex($next, $Koha::SearchEngine::Elasticsearch::BIBLIOS_INDEX);
 215 }
 216 if ($index_authorities) {
 217     _log(1, "Indexing authorities\n");
 218     if (@authids) {
 219         $next = sub {
 220             my $r = shift @authids;
 221             return () unless defined $r;
 222             my $a = Koha::MetadataRecord::Authority->get_from_authid($r);
 223             return ($r, $a);
 224         };
 225     } else {
 226         my $records = Koha::MetadataRecord::Authority->get_all_authorities_iterator(%iterator_options);
 227         $next = sub {
 228             $records->next();
 229         }
 230     }
 231     _do_reindex($next, $Koha::SearchEngine::Elasticsearch::AUTHORITIES_INDEX);
 232 }
 233
 234 if ($slice_index == 0) {
 235     # Main process, wait for children
 236     for (my $proc = 1; $proc < $processes; $proc++) {
 237         wait();
 238     }
 239 }
 240
 241 =head1 INTERNAL METHODS
 242
 243 =head2 _verify_index_state
 244
 245     _verify_index_state($Koha::SearchEngine::Elasticsearch::BIBLIOS_INDEX, 1);
 246
 247 Checks the index state and recreates it if requested.
 248
 249 =cut
 250
 251 sub _verify_index_state {
 252     my ( $index_name, $recreate ) = @_;
 253
 254     _log(1, "Checking state of $index_name index\n");
 255     my $indexer = Koha::SearchEngine::Elasticsearch::Indexer->new( { index => $index_name } );
 256
 257     if ($recreate) {
 258         _log(1, "Dropping and recreating $index_name index\n");
 259         $indexer->drop_index() if $indexer->index_exists();
 260         $indexer->create_index();
 261     }
 262     elsif (!$indexer->index_exists) {
 263         # Create index if does not exist
 264         $indexer->create_index();
 265     } elsif ($indexer->is_index_status_ok) {
 266         # Update mapping unless index is some kind of problematic state
 267         $indexer->update_mappings();
 268     } elsif ($indexer->is_index_status_recreate_required) {
 269         warn qq/Index "$index_name" has status "recreate required", suggesting it should be recreated/;
 270     }
 271 }
 272
 273 =head2 _do_reindex
 274
 275     _do_reindex($callback, $Koha::SearchEngine::Elasticsearch::BIBLIOS_INDEX);
 276
 277 Does the actual reindexing. $callback is a function that always returns the next record.
 278 For each index we iterate through the records, committing at specified count
 279
 280 =cut
 281
 282 sub _do_reindex {
 283     my ( $next, $index_name ) = @_;
 284
 285     my $indexer = Koha::SearchEngine::Elasticsearch::Indexer->new( { index => $index_name } );
 286
 287     my $count        = 0;
 288     my $commit_count = $commit;
 289     my ( @id_buffer, @commit_buffer );
 290     while ( my $record = $next->() ) {
 291         my $id     = $record->id // $record->authid;
 292         my $record = $record->record;
 293         $count++;
 294         if ( $verbose == 1 ) {
 295             _log( 1, "$count records processed\n" ) if ( $count % 1000 == 0);
 296         } else {
 297             _log( 2, "$id\n" );
 298         }
 299
 300         push @id_buffer,     $id;
 301         push @commit_buffer, $record;
 302         if ( !( --$commit_count ) ) {
 303             _log( 1, "Committing $commit records...\n" );
 304             my $response = $indexer->update_index( \@id_buffer, \@commit_buffer );
 305             _handle_response($response);
 306             $commit_count  = $commit;
 307             @id_buffer     = ();
 308             @commit_buffer = ();
 309             _log( 1, "Commit complete\n" );
 310         }
 311     }
 312
 313     # There are probably uncommitted records
 314     _log( 1, "Committing final records...\n" );
 315     my $response = $indexer->update_index( \@id_buffer, \@commit_buffer );
 316     _handle_response($response);
 317     _log( 1, "Total $count records indexed\n" );
 318 }
 319
 320 =head2 _sanity_check
 321
 322     _sanity_check();
 323
 324 Checks some basic stuff to ensure that it's sane before we start.
 325
 326 =cut
 327
 328 sub _sanity_check {
 329     # Do we have an elasticsearch block defined?
 330     my $conf = C4::Context->config('elasticsearch');
 331     die "No 'elasticsearch' block is defined in koha-conf.xml.\n" if ( !$conf );
 332 }
 333
 334 =head2 _handle_response
 335
 336 Parse the return from update_index and display errors depending on verbosity of the script
 337
 338 =cut
 339
 340 sub _handle_response {
 341     my ($response) = @_;
 342     if( $response->{errors} eq 'true' ){
 343         _log( 1, "There were errors during indexing\n" );
 344         if ( $verbose > 1 ){
 345             foreach my $item (@{$response->{items}}){
 346                 next unless defined $item->{index}->{error};
 347                 print "Record #" . $item->{index}->{_id} . " " .
 348                       $item->{index}->{error}->{reason} . " (" . $item->{index}->{error}->{type} . ") : " .
 349                       $item->{index}->{error}->{caused_by}->{type} . " (" . $item->{index}->{error}->{caused_by}->{reason} . ")\n";
 350             }
 351         }
 352     }
 353 }
 354
 355 =head2 _log
 356
 357     _log($level, "Message\n");
 358
 359 Output progress information.
 360
 361 Will output the message if verbosity level is set to $level or more. Will not
 362 include a trailing newline automatically.
 363
 364 =cut
 365
 366 sub _log {
 367     my ($level, $msg) = @_;
 368
 369     print "[$$] $msg" if ($verbose >= $level);
 370 }