misc/workers/background_jobs_worker.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 =head1 NAME
  19
  20 background_jobs_worker.pl - Worker script that will process background jobs
  21
  22 =head1 SYNOPSIS
  23
  24 ./background_jobs_worker.pl [--queue QUEUE] [-m|--max-processes MAX_PROCESSES]
  25
  26 =head1 DESCRIPTION
  27
  28 This script will connect to the Stomp server (RabbitMQ) and subscribe to the queues passed in parameter (or the 'default' queue),
  29 or if a Stomp server is not active it will poll the database every 10s for new jobs in the passed queue.
  30
  31 You can specify some queues only (using --queue, which is repeatable) if you want to run several workers that will handle their own jobs.
  32
  33 --m --max-processes specifies how many jobs to process simultaneously
  34
  35 Max processes will be set from the command line option, the environment variable MAX_PROCESSES, or the koha-conf file, in that order of precedence.
  36 By default the script will only run one job at a time.
  37
  38 =head1 OPTIONS
  39
  40 =over
  41
  42 =item B<--queue>
  43
  44 Repeatable. Give the job queues this worker will process.
  45
  46 The different values available are:
  47
  48     default
  49     long_tasks
  50
  51 =back
  52
  53 =cut
  54
  55 use Modern::Perl;
  56 use JSON qw( decode_json );
  57 use Try::Tiny;
  58 use Pod::Usage;
  59 use Getopt::Long;
  60 use Parallel::ForkManager;
  61
  62 use C4::Context;
  63 use Koha::Logger;
  64 use Koha::BackgroundJobs;
  65 use C4::Context;
  66
  67 $SIG{'PIPE'} = 'IGNORE';    # See BZ 35111; added to ignore PIPE error when connection lost on Ubuntu.
  68
  69 my ( $help, @queues );
  70
  71 my $max_processes = $ENV{MAX_PROCESSES};
  72 $max_processes ||= C4::Context->config('background_jobs_worker')->{max_processes} if C4::Context->config('background_jobs_worker');
  73 $max_processes ||= 1;
  74
  75 GetOptions(
  76     'm|max-processes=i' => \$max_processes,
  77     'h|help' => \$help,
  78     'queue=s' => \@queues,
  79 ) || pod2usage(1);
  80
  81
  82 pod2usage(0) if $help;
  83
  84 unless (@queues) {
  85     push @queues, 'default';
  86 }
  87
  88 my $conn;
  89 try {
  90     $conn = Koha::BackgroundJob->connect;
  91 } catch {
  92     warn sprintf "Cannot connect to the message broker, the jobs will be processed anyway (%s)", $_;
  93 };
  94
  95 my $pm = Parallel::ForkManager->new($max_processes);
  96
  97 if ( $conn ) {
  98     # FIXME cf note in Koha::BackgroundJob about $namespace
  99     my $namespace = C4::Context->config('memcached_namespace');
 100     for my $queue (@queues) {
 101         $conn->subscribe(
 102             {
 103                 destination      => sprintf( "/queue/%s-%s", $namespace, $queue ),
 104                 ack              => 'client',
 105                 'prefetch-count' => 1,
 106             }
 107         );
 108     }
 109 }
 110 while (1) {
 111     if ( $conn ) {
 112         my $frame = $conn->receive_frame;
 113         if ( !defined $frame ) {
 114             # maybe log connection problems
 115             next;    # will reconnect automatically
 116         }
 117
 118         my $args = try {
 119             my $body = $frame->body;
 120             decode_json($body); # TODO Should this be from_json? Check utf8 flag.
 121         } catch {
 122             Koha::Logger->get({ interface => 'worker' })->warn(sprintf "Frame not processed - %s", $_);
 123             return;
 124         } finally {
 125             $conn->ack( { frame => $frame } );
 126         };
 127
 128         next unless $args;
 129
 130         # FIXME This means we need to have create the DB entry before
 131         # It could work in a first step, but then we will want to handle job that will be created from the message received
 132         my $job = Koha::BackgroundJobs->search( { id => $args->{job_id}, status => 'new' } )->next;
 133
 134         unless( $job ) {
 135             Koha::Logger->get( { interface => 'worker' } )
 136                 ->warn( sprintf "Job %s not found, or has wrong status", $args->{job_id} );
 137             next;
 138         }
 139
 140         $pm->start and next;
 141         srand();    # ensure each child process begins with a new seed
 142         process_job( $job, $args );
 143         $pm->finish;
 144
 145     } else {
 146         my $jobs = Koha::BackgroundJobs->search({ status => 'new', queue => \@queues });
 147         while ( my $job = $jobs->next ) {
 148             my $args = try {
 149                 $job->json->decode($job->data);
 150             } catch {
 151                 Koha::Logger->get({ interface => 'worker' })->warn(sprintf "Cannot decode data for job id=%s", $job->id);
 152                 $job->status('failed')->store;
 153                 return;
 154             };
 155
 156             next unless $args;
 157
 158             $pm->start and next;
 159             srand();    # ensure each child process begins with a new seed
 160             process_job( $job, { job_id => $job->id, %$args } );
 161             $pm->finish;
 162
 163         }
 164         sleep 10;
 165     }
 166 }
 167 $conn->disconnect;
 168 $pm->wait_all_children;
 169
 170 sub process_job {
 171     my ( $job, $args ) = @_;
 172     try {
 173         $job->process( $args );
 174     } catch {
 175         $job->status('failed')->store;
 176     };
 177 }