opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use JSON qw( to_json );
  23 use List::MoreUtils qw( any each_array uniq );
  24 use String::Random qw( random_string );
  25 use Try::Tiny;
  26
  27 use C4::Auth qw( get_template_and_user );
  28 use C4::Output qw( output_html_with_http_headers );
  29 use C4::Context;
  30 use C4::Letters qw( GetPreparedLetter EnqueueLetter SendQueuedMessages );
  31 use C4::Members qw( checkcardnumber );
  32 use C4::Form::MessagingPreferences;
  33 use Koha::AuthUtils;
  34 use Koha::Patrons;
  35 use Koha::Patron::Consent;
  36 use Koha::Patron::Modification;
  37 use Koha::Patron::Modifications;
  38 use C4::Scrubber;
  39 use Koha::DateUtils qw( dt_from_string );
  40 use Koha::Email;
  41 use Koha::Libraries;
  42 use Koha::Patron::Attribute::Types;
  43 use Koha::Patron::Attributes;
  44 use Koha::Patron::Images;
  45 use Koha::Patron::Categories;
  46 use Koha::Token;
  47 use Koha::AuthorisedValues;
  48 my $cgi = CGI->new;
  49 my $dbh = C4::Context->dbh;
  50
  51 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  52     {
  53         template_name   => "opac-memberentry.tt",
  54         type            => "opac",
  55         query           => $cgi,
  56         authnotrequired => 1,
  57     }
  58 );
  59
  60 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  61 {
  62     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  63     exit;
  64 }
  65
  66 my $action = $cgi->param('action') || q{};
  67 if ( $borrowernumber && ( $action eq 'create' || $action eq 'new' ) ) {
  68     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  69     exit;
  70 }
  71
  72 if ( $action eq q{} ) {
  73     if ($borrowernumber) {
  74         $action = 'edit';
  75     }
  76     else {
  77         $action = 'new';
  78     }
  79 }
  80
  81 my $mandatory = GetMandatoryFields($action);
  82
  83 my $params = {};
  84 if ( $action eq 'create' || $action eq 'new' ) {
  85     my @PatronSelfRegistrationLibraryList = split '\|', C4::Context->preference('PatronSelfRegistrationLibraryList');
  86     $params = { branchcode => { -in => \@PatronSelfRegistrationLibraryList } }
  87       if @PatronSelfRegistrationLibraryList;
  88 }
  89 my $libraries = Koha::Libraries->search( $params, { order_by => ['branchname'] } );
  90
  91 my ( $min, $max ) = C4::Members::get_cardnumber_length();
  92 if ( defined $min ) {
  93      $template->param(
  94          minlength_cardnumber => $min,
  95          maxlength_cardnumber => $max
  96      );
  97  }
  98
  99 my $defaultCategory = Koha::Patron::Categories->find(C4::Context->preference('PatronSelfRegistrationDefaultCategory'));
 100
 101 $template->param(
 102     action            => $action,
 103     hidden            => GetHiddenFields( $mandatory, $action ),
 104     mandatory         => $mandatory,
 105     libraries         => $libraries,
 106     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
 107     defaultCategory  => $defaultCategory,
 108 );
 109
 110 my $attributes = ParsePatronAttributes($borrowernumber,$cgi);
 111 my $conflicting_attribute = 0;
 112
 113 foreach my $attr (@$attributes) {
 114     my $attribute = Koha::Patron::Attribute->new($attr);
 115     if ( !$attribute->unique_ok ) {
 116         my $attr_type = Koha::Patron::Attribute::Types->find($attr->{code});
 117         $template->param(
 118             extended_unique_id_failed_code => $attr->{code},
 119             extended_unique_id_failed_value => $attr->{attribute},
 120             extended_unique_id_failed_description => $attr_type->description,
 121         );
 122         $conflicting_attribute = 1;
 123     }
 124 }
 125
 126 if ( $action eq 'create' ) {
 127
 128     my %borrower = ParseCgiForBorrower($cgi);
 129
 130     %borrower = DelEmptyFields(%borrower);
 131     $borrower{categorycode} ||= C4::Context->preference('PatronSelfRegistrationDefaultCategory');
 132
 133     my @empty_mandatory_fields = (CheckMandatoryFields( \%borrower, $action ), CheckMandatoryAttributes( \%borrower, $attributes ) );
 134     my $invalidformfields = CheckForInvalidFields(\%borrower);
 135     delete $borrower{'password2'};
 136     my $cardnumber_error_code;
 137     if ( !grep { $_ eq 'cardnumber' } @empty_mandatory_fields ) {
 138         # No point in checking the cardnumber if it's missing and mandatory, it'll just generate a
 139         # spurious length warning.
 140         $cardnumber_error_code = checkcardnumber( $borrower{cardnumber}, $borrower{borrowernumber} );
 141     }
 142
 143     if ( @empty_mandatory_fields || @$invalidformfields || $cardnumber_error_code || $conflicting_attribute ) {
 144         if ( $cardnumber_error_code == 1 ) {
 145             $template->param( cardnumber_already_exists => 1 );
 146         } elsif ( $cardnumber_error_code == 2 ) {
 147             $template->param( cardnumber_wrong_length => 1 );
 148         }
 149
 150         $template->param(
 151             empty_mandatory_fields => \@empty_mandatory_fields,
 152             invalid_form_fields    => $invalidformfields,
 153             borrower               => \%borrower
 154         );
 155         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 156     }
 157     elsif (
 158         md5_base64( uc( $cgi->param('captcha') ) ) ne $cgi->param('captcha_digest') )
 159     {
 160         $template->param(
 161             failed_captcha => 1,
 162             borrower       => \%borrower
 163         );
 164         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 165     } elsif ( !$libraries->find($borrower{branchcode}) ) {
 166         die "Branchcode not allowed"; # They hack the form
 167     }
 168     else {
 169         if (
 170             C4::Context->preference(
 171                 'PatronSelfRegistrationVerifyByEmail')
 172           )
 173         {
 174             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 175                 {
 176                     template_name   => "opac-registration-email-sent.tt",
 177                     type            => "opac",
 178                     query           => $cgi,
 179                     authnotrequired => 1,
 180                 }
 181             );
 182             $template->param( 'email' => $borrower{'email'} );
 183
 184             my $verification_token = md5_hex( time().{}.rand().{}.$$ );
 185             while ( Koha::Patron::Modifications->search( { verification_token => $verification_token } )->count() ) {
 186                 $verification_token = md5_hex( time().{}.rand().{}.$$ );
 187             }
 188
 189             $borrower{password}          = Koha::AuthUtils::generate_password(Koha::Patron::Categories->find($borrower{categorycode})) unless $borrower{password};
 190             $borrower{verification_token} = $verification_token;
 191
 192             $borrower{extended_attributes} = to_json($attributes);
 193             Koha::Patron::Modification->new( \%borrower )->store();
 194
 195             #Send verification email
 196             my $letter = C4::Letters::GetPreparedLetter(
 197                 module      => 'members',
 198                 letter_code => 'OPAC_REG_VERIFY',
 199                 lang        => 'default', # Patron does not have a preferred language defined yet
 200                 tables      => {
 201                     borrower_modifications => $verification_token,
 202                 },
 203             );
 204
 205             my $message_id = C4::Letters::EnqueueLetter(
 206                 {
 207                     letter                 => $letter,
 208                     message_transport_type => 'email',
 209                     to_address             => $borrower{'email'},
 210                     from_address =>
 211                       C4::Context->preference('KohaAdminEmailAddress'),
 212                 }
 213             );
 214             C4::Letters::SendQueuedMessages( { message_id => $message_id } ) if $message_id;
 215         }
 216         else {
 217             $borrower{password}         ||= Koha::AuthUtils::generate_password(Koha::Patron::Categories->find($borrower{categorycode}));
 218             my $consent_dt = delete $borrower{gdpr_proc_consent};
 219             my $patron;
 220             try {
 221                 $patron = Koha::Patron->new( \%borrower )->store;
 222                 Koha::Patron::Consent->new({ borrowernumber => $patron->borrowernumber, type => 'GDPR_PROCESSING', given_on => $consent_dt })->store if $patron && $consent_dt;
 223             } catch {
 224                 my $type = ref($_);
 225                 my $info = "$_";
 226                 $template->param( error_type => $type, error_info => $info );
 227                 $template->param( borrower => \%borrower );
 228             };
 229
 230             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 231                 {
 232                     template_name   => "opac-registration-confirmation.tt",
 233                     type            => "opac",
 234                     query           => $cgi,
 235                     authnotrequired => 1,
 236                 }
 237             ) if $patron;
 238
 239             if ( $patron ) {
 240                 $patron->extended_attributes->filter_by_branch_limitations->delete;
 241                 $patron->extended_attributes($attributes);
 242                 if ( C4::Context->preference('EnhancedMessagingPreferences') ) {
 243                     C4::Form::MessagingPreferences::handle_form_action(
 244                         $cgi,
 245                         { borrowernumber => $patron->borrowernumber },
 246                         $template,
 247                         1,
 248                         C4::Context->preference('PatronSelfRegistrationDefaultCategory')
 249                     );
 250                 }
 251
 252                 $template->param( password_cleartext => $patron->plain_text_password );
 253                 $template->param( borrower => $patron->unblessed );
 254
 255                 # If 'AutoEmailNewUser' syspref is on, email user their account details from the 'notice' that matches the user's branchcode.
 256                 if ( C4::Context->preference("AutoEmailNewUser") ) {
 257                     #look for defined primary email address, if blank - attempt to use borr.email and borr.emailpro instead
 258                     my $emailaddr = $patron->notice_email_address;
 259                     # if we manage to find a valid email address, send notice
 260                     if ($emailaddr) {
 261                         eval {
 262                             my $letter = GetPreparedLetter(
 263                                 module      => 'members',
 264                                 letter_code => 'WELCOME',
 265                                 branchcode  => $patron->branchcode,,
 266                                 lang        => $patron->lang || 'default',
 267                                 tables      => {
 268                                     'branches'  => $patron->branchcode,
 269                                     'borrowers' => $patron->borrowernumber,
 270                                 },
 271                                 want_librarian => 1,
 272                             ) or return;
 273
 274                             my $message_id = EnqueueLetter(
 275                                 {
 276                                     letter                 => $letter,
 277                                     borrowernumber         => $patron->id,
 278                                     to_address             => $emailaddr,
 279                                     message_transport_type => 'email'
 280                                 }
 281                             );
 282                             SendQueuedMessages( { message_id => $message_id } ) if $message_id;
 283                         };
 284                     }
 285                 }
 286
 287                 # Notify library of new patron registration
 288                 my $notify_library = C4::Context->preference('EmailPatronRegistrations');
 289                 if ($notify_library) {
 290                     $patron->notify_library_of_registration($notify_library);
 291                 }
 292
 293             }
 294             $template->param(
 295                 PatronSelfRegistrationAdditionalInstructions =>
 296                   C4::Context->preference(
 297                     'PatronSelfRegistrationAdditionalInstructions')
 298             );
 299         }
 300     }
 301 }
 302 elsif ( $action eq 'update' ) {
 303
 304     my $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 305     die "Wrong CSRF token"
 306         unless Koha::Token->new->check_csrf({
 307             session_id => scalar $cgi->cookie('CGISESSID'),
 308             token  => scalar $cgi->param('csrf_token'),
 309         });
 310
 311     my %borrower = ParseCgiForBorrower($cgi);
 312     $borrower{borrowernumber} = $borrowernumber;
 313
 314     my @empty_mandatory_fields = grep { $_ ne 'password' } # password is not required when editing personal details
 315       ( CheckMandatoryFields( \%borrower, $action ), CheckMandatoryAttributes( \%borrower, $attributes ) );
 316     my $invalidformfields = CheckForInvalidFields(\%borrower);
 317
 318     # Send back the data to the template
 319     %borrower = ( %$borrower, %borrower );
 320
 321     if (@empty_mandatory_fields || @$invalidformfields) {
 322         $template->param(
 323             empty_mandatory_fields => \@empty_mandatory_fields,
 324             invalid_form_fields    => $invalidformfields,
 325             borrower               => \%borrower,
 326             csrf_token             => Koha::Token->new->generate_csrf({
 327                 session_id => scalar $cgi->cookie('CGISESSID'),
 328             }),
 329         );
 330         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ) );
 331
 332         $template->param( action => 'edit' );
 333     }
 334     else {
 335         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 336         $borrower_changes{'changed_fields'} = join ',', keys %borrower_changes;
 337         my $extended_attributes_changes = FilterUnchangedAttributes( $borrowernumber, $attributes );
 338
 339         if ( %borrower_changes || scalar @{$extended_attributes_changes} > 0 ) {
 340             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 341                 {
 342                     template_name   => "opac-memberentry-update-submitted.tt",
 343                     type            => "opac",
 344                     query           => $cgi,
 345                     authnotrequired => 1,
 346                 }
 347             );
 348
 349             $borrower_changes{borrowernumber} = $borrowernumber;
 350             $borrower_changes{extended_attributes} = to_json($extended_attributes_changes);
 351
 352             Koha::Patron::Modifications->search({ borrowernumber => $borrowernumber })->delete;
 353
 354             my $m = Koha::Patron::Modification->new( \%borrower_changes )->store();
 355             #Automatically approve patron profile changes if set in syspref
 356
 357             if (C4::Context->preference('AutoApprovePatronProfileSettings')) {
 358                 # Need to get the object from database, otherwise it is not complete enough to allow deletion
 359                 # when approval has been performed.
 360                 my $tmp_m = Koha::Patron::Modifications->find({borrowernumber => $borrowernumber});
 361                 $tmp_m->approve() if $tmp_m;
 362             }
 363
 364             my $patron = Koha::Patrons->find( $borrowernumber );
 365             $template->param( borrower => $patron->unblessed );
 366         }
 367         else {
 368             my $patron = Koha::Patrons->find( $borrowernumber );
 369             $template->param(
 370                 action => 'edit',
 371                 nochanges => 1,
 372                 borrower => $patron->unblessed,
 373                 patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ),
 374                 csrf_token => Koha::Token->new->generate_csrf({
 375                     session_id => scalar $cgi->cookie('CGISESSID'),
 376                 }),
 377             );
 378         }
 379     }
 380 }
 381 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 382     my $patron = Koha::Patrons->find( $borrowernumber );
 383     my $borrower = $patron->unblessed;
 384
 385     $template->param(
 386         borrower  => $borrower,
 387         hidden => GetHiddenFields( $mandatory, 'edit' ),
 388         csrf_token => Koha::Token->new->generate_csrf({
 389             session_id => scalar $cgi->cookie('CGISESSID'),
 390         }),
 391     );
 392
 393     if (C4::Context->preference('OPACpatronimages')) {
 394         $template->param( display_patron_image => 1 ) if $patron->image;
 395     }
 396
 397     $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber ) );
 398 } else {
 399     # Render self-registration page
 400     $template->param( patron_attribute_classes => GeneratePatronAttributesForm() );
 401 }
 402
 403 my $captcha = random_string("CCCCC");
 404 my $patron_param = Koha::Patrons->find( $borrowernumber );
 405 $template->param(
 406     has_guarantor_flag => $patron_param->guarantor_relationships->guarantors->_resultset->count
 407 ) if $patron_param;
 408
 409 $template->param(
 410     captcha        => $captcha,
 411     captcha_digest => md5_base64($captcha),
 412     patron         => $patron_param
 413 );
 414
 415 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };
 416
 417 sub GetHiddenFields {
 418     my ( $mandatory, $action ) = @_;
 419     my %hidden_fields;
 420
 421     my $BorrowerUnwantedField = $action eq 'edit' || $action eq 'update' ?
 422       C4::Context->preference( "PatronSelfModificationBorrowerUnwantedField" ) :
 423       C4::Context->preference( "PatronSelfRegistrationBorrowerUnwantedField" );
 424
 425     my @fields = split( /\|/, $BorrowerUnwantedField || q|| );
 426     foreach (@fields) {
 427         next unless m/\w/o;
 428         #Don't hide mandatory fields
 429         next if $mandatory->{$_};
 430         $hidden_fields{$_} = 1;
 431     }
 432
 433     return \%hidden_fields;
 434 }
 435
 436 sub GetMandatoryFields {
 437     my ($action) = @_;
 438
 439     my %mandatory_fields;
 440
 441     my $BorrowerMandatoryField = $action eq 'edit' || $action eq 'update' ?
 442       C4::Context->preference("PatronSelfModificationMandatoryField") :
 443       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 444
 445     my @fields = split( /\|/, $BorrowerMandatoryField );
 446     push @fields, 'gdpr_proc_consent' if C4::Context->preference('PrivacyPolicyConsent') && $action eq 'create';
 447
 448     foreach (@fields) {
 449         $mandatory_fields{$_} = 1;
 450     }
 451
 452     if ( $action eq 'create' || $action eq 'new' ) {
 453         $mandatory_fields{'email'} = 1
 454           if C4::Context->preference(
 455             'PatronSelfRegistrationVerifyByEmail');
 456     }
 457
 458     return \%mandatory_fields;
 459 }
 460
 461 sub CheckMandatoryFields {
 462     my ( $borrower, $action ) = @_;
 463
 464     my @empty_mandatory_fields;
 465
 466     my $mandatory_fields = GetMandatoryFields($action);
 467     delete $mandatory_fields->{'cardnumber'};
 468
 469     foreach my $key ( keys %$mandatory_fields ) {
 470         push( @empty_mandatory_fields, $key )
 471           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 472     }
 473
 474     return @empty_mandatory_fields;
 475 }
 476
 477 sub CheckMandatoryAttributes{
 478     my ( $borrower, $attributes ) = @_;
 479
 480     my @empty_mandatory_fields;
 481
 482     for my $attribute (@$attributes ) {
 483         my $attr = Koha::Patron::Attribute::Types->find($attribute->{code});
 484         push @empty_mandatory_fields, $attribute->{code}
 485             if $attr && $attr->mandatory && $attribute->{attribute} =~ m|^\s*$|;
 486     }
 487
 488     return @empty_mandatory_fields;
 489 }
 490
 491 sub CheckForInvalidFields {
 492     my $borrower = shift;
 493     my @invalidFields;
 494     if ($borrower->{'email'}) {
 495         unless ( Koha::Email->is_valid($borrower->{email}) ) {
 496             push(@invalidFields, "email");
 497         } elsif ( C4::Context->preference("PatronSelfRegistrationEmailMustBeUnique") ) {
 498             my $patrons_with_same_email = Koha::Patrons->search( # FIXME Should be search_limited?
 499                 {
 500                     email => $borrower->{email},
 501                     (
 502                         exists $borrower->{borrowernumber}
 503                         ? ( borrowernumber =>
 504                               { '!=' => $borrower->{borrowernumber} } )
 505                         : ()
 506                     )
 507                 }
 508             )->count;
 509             if ( $patrons_with_same_email ) {
 510                 push @invalidFields, "duplicate_email";
 511             }
 512         } elsif ( C4::Context->preference("PatronSelfRegistrationConfirmEmail")
 513             && $borrower->{'email'} ne $borrower->{'repeat_email'}
 514             && !defined $borrower->{borrowernumber} ) {
 515             push @invalidFields, "email_match";
 516         }
 517         # email passed all tests, so prevent attempting to store repeat_email
 518         delete $borrower->{'repeat_email'};
 519     }
 520     if ($borrower->{'emailpro'}) {
 521         push(@invalidFields, "emailpro") unless Koha::Email->is_valid($borrower->{'emailpro'});
 522     }
 523     if ($borrower->{'B_email'}) {
 524         push(@invalidFields, "B_email") unless Koha::Email->is_valid($borrower->{'B_email'});
 525     }
 526     if ( defined $borrower->{'password'}
 527         and $borrower->{'password'} ne $borrower->{'password2'} )
 528     {
 529         push( @invalidFields, "password_match" );
 530     }
 531     if ( $borrower->{'password'} ) {
 532         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $borrower->{password}, Koha::Patron::Categories->find($borrower->{categorycode}||C4::Context->preference('PatronSelfRegistrationDefaultCategory')) );
 533           unless ( $is_valid ) {
 534               push @invalidFields, 'password_too_short' if $error eq 'too_short';
 535               push @invalidFields, 'password_too_weak' if $error eq 'too_weak';
 536               push @invalidFields, 'password_has_whitespaces' if $error eq 'has_whitespaces';
 537           }
 538     }
 539
 540     return \@invalidFields;
 541 }
 542
 543 sub ParseCgiForBorrower {
 544     my ($cgi) = @_;
 545
 546     my $scrubber = C4::Scrubber->new();
 547     my %borrower;
 548
 549     foreach my $field ( $cgi->param ) {
 550         if ( $field =~ '^borrower_' ) {
 551             my ($key) = substr( $field, 9 );
 552             if ( $field !~ '^borrower_password' ) {
 553                 $borrower{$key} = $scrubber->scrub( scalar $cgi->param($field) );
 554             } else {
 555                 # Allow html characters for passwords
 556                 $borrower{$key} = $cgi->param($field);
 557             }
 558         }
 559     }
 560
 561     # Replace checkbox 'agreed' by datetime in gdpr_proc_consent
 562     $borrower{gdpr_proc_consent} = dt_from_string if  $borrower{gdpr_proc_consent} && $borrower{gdpr_proc_consent} eq 'agreed';
 563
 564     delete $borrower{$_} for qw/borrowernumber date_renewed debarred debarredcomment flags privacy privacy_guarantor_fines privacy_guarantor_checkouts checkprevcheckout updated_on lastseen lang login_attempts overdrive_auth_token anonymized/; # See also members/memberentry.pl
 565     delete $borrower{$_} for qw/dateenrolled dateexpiry borrowernotes opacnote sort1 sort2 sms_provider_id autorenew_checkouts gonenoaddress lost relationship/; # On OPAC only
 566     delete $borrower{$_} for split( /\s*\|\s*/, C4::Context->preference('PatronSelfRegistrationBorrowerUnwantedField') || q{} );
 567
 568     return %borrower;
 569 }
 570
 571 sub DelUnchangedFields {
 572     my ( $borrowernumber, %new_data ) = @_;
 573     # get the mandatory fields so we can get the hidden fields
 574     my $mandatory = GetMandatoryFields('edit');
 575     my $patron = Koha::Patrons->find( $borrowernumber );
 576     my $current_data = $patron->unblessed;
 577     # get the hidden fields so we don't obliterate them should they have data patrons aren't allowed to modify
 578     my $hidden_fields = GetHiddenFields($mandatory, 'edit');
 579
 580
 581     foreach my $key ( keys %new_data ) {
 582         next if defined($new_data{$key}) xor defined($current_data->{$key});
 583         if ( !defined($new_data{$key}) || $current_data->{$key} eq $new_data{$key} || $hidden_fields->{$key} ) {
 584            delete $new_data{$key};
 585         }
 586     }
 587
 588     return %new_data;
 589 }
 590
 591 sub DelEmptyFields {
 592     my (%borrower) = @_;
 593
 594     foreach my $key ( keys %borrower ) {
 595         delete $borrower{$key} unless $borrower{$key};
 596     }
 597
 598     return %borrower;
 599 }
 600
 601 sub FilterUnchangedAttributes {
 602     my ( $borrowernumber, $entered_attributes ) = @_;
 603
 604     my @patron_attributes = grep {$_->type->opac_editable ? $_ : ()} Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 605
 606     my $patron_attribute_types;
 607     foreach my $attr (@patron_attributes) {
 608         $patron_attribute_types->{ $attr->code } += 1;
 609     }
 610
 611     my $passed_attribute_types;
 612     foreach my $attr (@{ $entered_attributes }) {
 613         $passed_attribute_types->{ $attr->{ code } } += 1;
 614     }
 615
 616     my @changed_attributes;
 617
 618     # Loop through the current patron attributes
 619     foreach my $attribute_type ( keys %{ $patron_attribute_types } ) {
 620         if ( $patron_attribute_types->{ $attribute_type } !=  $passed_attribute_types->{ $attribute_type } ) {
 621             # count differs, overwrite all attributes for given type
 622             foreach my $attr (@{ $entered_attributes }) {
 623                 push @changed_attributes, $attr
 624                     if $attr->{ code } eq $attribute_type;
 625             }
 626         } else {
 627             # count matches, check values
 628             my $changes = 0;
 629             foreach my $attr (grep { $_->code eq $attribute_type } @patron_attributes) {
 630                 $changes = 1
 631                     unless any { $_->{ value } eq $attr->attribute } @{ $entered_attributes };
 632                 last if $changes;
 633             }
 634
 635             if ( $changes ) {
 636                 foreach my $attr (@{ $entered_attributes }) {
 637                     push @changed_attributes, $attr
 638                         if $attr->{ code } eq $attribute_type;
 639                 }
 640             }
 641         }
 642     }
 643
 644     # Loop through passed attributes, looking for new ones
 645     foreach my $attribute_type ( keys %{ $passed_attribute_types } ) {
 646         if ( !defined $patron_attribute_types->{ $attribute_type } ) {
 647             # YAY, new stuff
 648             foreach my $attr (grep { $_->{code} eq $attribute_type } @{ $entered_attributes }) {
 649                 push @changed_attributes, $attr;
 650             }
 651         }
 652     }
 653
 654     return \@changed_attributes;
 655 }
 656
 657 sub GeneratePatronAttributesForm {
 658     my ( $borrowernumber, $entered_attributes ) = @_;
 659
 660     # Get all attribute types and the values for this patron (if applicable)
 661     my @types = grep { $_->opac_editable() or $_->opac_display } # FIXME filter using DBIC
 662         Koha::Patron::Attribute::Types->search()->as_list();
 663     if ( scalar(@types) == 0 ) {
 664         return [];
 665     }
 666
 667     my @displayable_attributes = grep { $_->type->opac_display ? $_ : () }
 668         Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 669
 670     my %attr_values = ();
 671
 672     # Build the attribute values list either from the passed values
 673     # or taken from the patron itself
 674     if ( defined $entered_attributes ) {
 675         foreach my $attr (@$entered_attributes) {
 676             push @{ $attr_values{ $attr->{code} } }, $attr->{value};
 677         }
 678     }
 679     elsif ( defined $borrowernumber ) {
 680         my @editable_attributes = grep { $_->type->opac_editable ? $_ : () } @displayable_attributes;
 681         foreach my $attr (@editable_attributes) {
 682             push @{ $attr_values{ $attr->code } }, $attr->attribute;
 683         }
 684     }
 685
 686     # Add the non-editable attributes (that don't come from the form)
 687     foreach my $attr ( grep { !$_->type->opac_editable } @displayable_attributes ) {
 688         push @{ $attr_values{ $attr->code } }, $attr->attribute;
 689     }
 690
 691     # Find all existing classes
 692     my @classes = sort( uniq( map { $_->class } @types ) );
 693     my %items_by_class;
 694
 695     foreach my $attr_type (@types) {
 696         push @{ $items_by_class{ $attr_type->class() } }, {
 697             type => $attr_type,
 698             # If editable, make sure there's at least one empty entry,
 699             # to make the template's job easier
 700             values => $attr_values{ $attr_type->code() } || ['']
 701         }
 702             unless !defined $attr_values{ $attr_type->code() }
 703                     and !$attr_type->opac_editable;
 704     }
 705
 706     # Finally, build a list of containing classes
 707     my @class_loop;
 708     foreach my $class (@classes) {
 709         next unless ( $items_by_class{$class} );
 710
 711         my $av = Koha::AuthorisedValues->search(
 712             { category => 'PA_CLASS', authorised_value => $class } );
 713
 714         my $lib = $av->count ? $av->next->opac_description : $class;
 715
 716         push @class_loop,
 717             {
 718             class => $class,
 719             items => $items_by_class{$class},
 720             lib   => $lib,
 721             };
 722     }
 723
 724     return \@class_loop;
 725 }
 726
 727 sub ParsePatronAttributes {
 728     my ( $borrowernumber, $cgi ) = @_;
 729
 730     my @codes  = $cgi->multi_param('patron_attribute_code');
 731     my @values = $cgi->multi_param('patron_attribute_value');
 732
 733     my @editable_attribute_types
 734         = map { $_->code } Koha::Patron::Attribute::Types->search({ opac_editable => 1 })->as_list;
 735
 736     my $ea = each_array( @codes, @values );
 737     my @attributes;
 738
 739     my $delete_candidates = {};
 740
 741     my $scrubber = C4::Scrubber->new();
 742     while ( my ( $code, $value ) = $ea->() ) {
 743         if ( any { $_ eq $code } @editable_attribute_types ) {
 744             # It is an editable attribute
 745             if ( !defined($value) or $value eq '' ) {
 746                 $delete_candidates->{$code} = 1
 747                     unless $delete_candidates->{$code};
 748             }
 749             else {
 750                 # we've got a value
 751                 push @attributes, { code => $code, attribute => $scrubber->scrub( $value ) };
 752
 753                 # 'code' is no longer a delete candidate
 754                 delete $delete_candidates->{$code}
 755                     if defined $delete_candidates->{$code};
 756             }
 757         }
 758     }
 759
 760     foreach my $code ( keys %{$delete_candidates} ) {
 761         if ( not $borrowernumber # self-registration
 762             || Koha::Patron::Attributes->search({
 763                 borrowernumber => $borrowernumber, code => $code })->count > 0 )
 764         {
 765             push @attributes, { code => $code, attribute => '' }
 766                 unless any { $_->{code} eq $code } @attributes;
 767         }
 768     }
 769
 770     return \@attributes;
 771 }
 772
 773
 774 1;