opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use JSON qw( to_json );
  23 use List::MoreUtils qw( any each_array uniq );
  24 use String::Random qw( random_string );
  25
  26 use C4::Auth qw( get_template_and_user );
  27 use C4::Output qw( output_html_with_http_headers );
  28 use C4::Context;
  29 use C4::Letters qw( GetPreparedLetter EnqueueLetter SendQueuedMessages );
  30 use C4::Members qw( checkcardnumber );
  31 use C4::Form::MessagingPreferences;
  32 use Koha::AuthUtils;
  33 use Koha::Patrons;
  34 use Koha::Patron::Consent;
  35 use Koha::Patron::Modification;
  36 use Koha::Patron::Modifications;
  37 use C4::Scrubber;
  38 use Koha::DateUtils qw( dt_from_string output_pref );
  39 use Koha::Email;
  40 use Koha::Libraries;
  41 use Koha::Patron::Attribute::Types;
  42 use Koha::Patron::Attributes;
  43 use Koha::Patron::Images;
  44 use Koha::Patron::Modification;
  45 use Koha::Patron::Modifications;
  46 use Koha::Patron::Categories;
  47 use Koha::Token;
  48 use Koha::AuthorisedValues;
  49 my $cgi = CGI->new;
  50 my $dbh = C4::Context->dbh;
  51
  52 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  53     {
  54         template_name   => "opac-memberentry.tt",
  55         type            => "opac",
  56         query           => $cgi,
  57         authnotrequired => 1,
  58     }
  59 );
  60
  61 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  62 {
  63     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  64     exit;
  65 }
  66
  67 my $action = $cgi->param('action') || q{};
  68 if ( $borrowernumber && ( $action eq 'create' || $action eq 'new' ) ) {
  69     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  70     exit;
  71 }
  72
  73 if ( $action eq q{} ) {
  74     if ($borrowernumber) {
  75         $action = 'edit';
  76     }
  77     else {
  78         $action = 'new';
  79     }
  80 }
  81
  82 my $mandatory = GetMandatoryFields($action);
  83
  84 my $params = {};
  85 if ( $action eq 'create' || $action eq 'new' ) {
  86     my @PatronSelfRegistrationLibraryList = split '\|', C4::Context->preference('PatronSelfRegistrationLibraryList');
  87     $params = { branchcode => { -in => \@PatronSelfRegistrationLibraryList } }
  88       if @PatronSelfRegistrationLibraryList;
  89 }
  90 my $libraries = Koha::Libraries->search($params);
  91
  92 my ( $min, $max ) = C4::Members::get_cardnumber_length();
  93 if ( defined $min ) {
  94      $template->param(
  95          minlength_cardnumber => $min,
  96          maxlength_cardnumber => $max
  97      );
  98  }
  99
 100 my $defaultCategory = Koha::Patron::Categories->find(C4::Context->preference('PatronSelfRegistrationDefaultCategory'));
 101
 102 $template->param(
 103     action            => $action,
 104     hidden            => GetHiddenFields( $mandatory, $action ),
 105     mandatory         => $mandatory,
 106     libraries         => $libraries,
 107     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
 108     defaultCategory  => $defaultCategory,
 109 );
 110
 111 my $attributes = ParsePatronAttributes($borrowernumber,$cgi);
 112 my $conflicting_attribute = 0;
 113
 114 foreach my $attr (@$attributes) {
 115     my $attribute = Koha::Patron::Attribute->new($attr);
 116     if ( !$attribute->unique_ok ) {
 117         my $attr_type = Koha::Patron::Attribute::Types->find($attr->{code});
 118         $template->param(
 119             extended_unique_id_failed_code => $attr->{code},
 120             extended_unique_id_failed_value => $attr->{attribute},
 121             extended_unique_id_failed_description => $attr_type->description,
 122         );
 123         $conflicting_attribute = 1;
 124     }
 125 }
 126
 127 if ( $action eq 'create' ) {
 128
 129     my %borrower = ParseCgiForBorrower($cgi);
 130
 131     %borrower = DelEmptyFields(%borrower);
 132     $borrower{categorycode} ||= C4::Context->preference('PatronSelfRegistrationDefaultCategory');
 133
 134     my @empty_mandatory_fields = (CheckMandatoryFields( \%borrower, $action ), CheckMandatoryAttributes( \%borrower, $attributes ) );
 135     my $invalidformfields = CheckForInvalidFields(\%borrower);
 136     delete $borrower{'password2'};
 137     my $cardnumber_error_code;
 138     if ( !grep { $_ eq 'cardnumber' } @empty_mandatory_fields ) {
 139         # No point in checking the cardnumber if it's missing and mandatory, it'll just generate a
 140         # spurious length warning.
 141         $cardnumber_error_code = checkcardnumber( $borrower{cardnumber}, $borrower{borrowernumber} );
 142     }
 143
 144     if ( @empty_mandatory_fields || @$invalidformfields || $cardnumber_error_code || $conflicting_attribute ) {
 145         if ( $cardnumber_error_code == 1 ) {
 146             $template->param( cardnumber_already_exists => 1 );
 147         } elsif ( $cardnumber_error_code == 2 ) {
 148             $template->param( cardnumber_wrong_length => 1 );
 149         }
 150
 151         $template->param(
 152             empty_mandatory_fields => \@empty_mandatory_fields,
 153             invalid_form_fields    => $invalidformfields,
 154             borrower               => \%borrower
 155         );
 156         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 157     }
 158     elsif (
 159         md5_base64( uc( $cgi->param('captcha') ) ) ne $cgi->param('captcha_digest') )
 160     {
 161         $template->param(
 162             failed_captcha => 1,
 163             borrower       => \%borrower
 164         );
 165         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 166     } elsif ( !$libraries->find($borrower{branchcode}) ) {
 167         die "Branchcode not allowed"; # They hack the form
 168     }
 169     else {
 170         if (
 171             C4::Context->preference(
 172                 'PatronSelfRegistrationVerifyByEmail')
 173           )
 174         {
 175             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 176                 {
 177                     template_name   => "opac-registration-email-sent.tt",
 178                     type            => "opac",
 179                     query           => $cgi,
 180                     authnotrequired => 1,
 181                 }
 182             );
 183             $template->param( 'email' => $borrower{'email'} );
 184
 185             my $verification_token = md5_hex( time().{}.rand().{}.$$ );
 186             while ( Koha::Patron::Modifications->search( { verification_token => $verification_token } )->count() ) {
 187                 $verification_token = md5_hex( time().{}.rand().{}.$$ );
 188             }
 189
 190             $borrower{password}          = Koha::AuthUtils::generate_password(Koha::Patron::Categories->find($borrower{categorycode})) unless $borrower{password};
 191             $borrower{verification_token} = $verification_token;
 192
 193             Koha::Patron::Modification->new( \%borrower )->store();
 194
 195             #Send verification email
 196             my $letter = C4::Letters::GetPreparedLetter(
 197                 module      => 'members',
 198                 letter_code => 'OPAC_REG_VERIFY',
 199                 lang        => 'default', # Patron does not have a preferred language defined yet
 200                 tables      => {
 201                     borrower_modifications => $verification_token,
 202                 },
 203             );
 204
 205             my $message_id = C4::Letters::EnqueueLetter(
 206                 {
 207                     letter                 => $letter,
 208                     message_transport_type => 'email',
 209                     to_address             => $borrower{'email'},
 210                     from_address =>
 211                       C4::Context->preference('KohaAdminEmailAddress'),
 212                 }
 213             );
 214             C4::Letters::SendQueuedMessages({ message_id => $message_id });
 215         }
 216         else {
 217             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 218                 {
 219                     template_name   => "opac-registration-confirmation.tt",
 220                     type            => "opac",
 221                     query           => $cgi,
 222                     authnotrequired => 1,
 223                 }
 224             );
 225
 226             $borrower{password}         ||= Koha::AuthUtils::generate_password(Koha::Patron::Categories->find($borrower{categorycode}));
 227             my $consent_dt = delete $borrower{gdpr_proc_consent};
 228             my $patron = Koha::Patron->new( \%borrower )->store;
 229             Koha::Patron::Consent->new({ borrowernumber => $patron->borrowernumber, type => 'GDPR_PROCESSING', given_on => $consent_dt })->store if $consent_dt;
 230             if ( $patron ) {
 231                 $patron->extended_attributes->filter_by_branch_limitations->delete;
 232                 $patron->extended_attributes($attributes);
 233                 if ( C4::Context->preference('EnhancedMessagingPreferences') ) {
 234                     C4::Form::MessagingPreferences::handle_form_action(
 235                         $cgi,
 236                         { borrowernumber => $patron->borrowernumber },
 237                         $template,
 238                         1,
 239                         C4::Context->preference('PatronSelfRegistrationDefaultCategory')
 240                     );
 241                 }
 242
 243                 $template->param( password_cleartext => $patron->plain_text_password );
 244                 $template->param( borrower => $patron->unblessed );
 245
 246                 # If 'AutoEmailOpacUser' syspref is on, email user their account details from the 'notice' that matches the user's branchcode.
 247                 if ( C4::Context->preference("AutoEmailOpacUser") ) {
 248                     #look for defined primary email address, if blank - attempt to use borr.email and borr.emailpro instead
 249                     my $emailaddr = $patron->notice_email_address;
 250                     # if we manage to find a valid email address, send notice
 251                     if ($emailaddr) {
 252                         eval {
 253                             my $letter = GetPreparedLetter(
 254                                 module      => 'members',
 255                                 letter_code => 'ACCTDETAILS',
 256                                 branchcode  => $patron->branchcode,,
 257                                 lang        => $patron->lang || 'default',
 258                                 tables      => {
 259                                     'branches'  => $patron->branchcode,
 260                                     'borrowers' => $patron->borrowernumber,
 261                                 },
 262                                 want_librarian => 1,
 263                             ) or return;
 264
 265                             my $message_id = EnqueueLetter(
 266                                 {
 267                                     letter                 => $letter,
 268                                     borrowernumber         => $patron->id,
 269                                     to_address             => $emailaddr,
 270                                     message_transport_type => 'email'
 271                                 }
 272                             );
 273                             SendQueuedMessages({ message_id => $message_id });
 274                         };
 275                     }
 276                 }
 277             } else {
 278                 # FIXME Handle possible errors here
 279             }
 280             $template->param(
 281                 PatronSelfRegistrationAdditionalInstructions =>
 282                   C4::Context->preference(
 283                     'PatronSelfRegistrationAdditionalInstructions')
 284             );
 285         }
 286     }
 287 }
 288 elsif ( $action eq 'update' ) {
 289
 290     my $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 291     die "Wrong CSRF token"
 292         unless Koha::Token->new->check_csrf({
 293             session_id => scalar $cgi->cookie('CGISESSID'),
 294             token  => scalar $cgi->param('csrf_token'),
 295         });
 296
 297     my %borrower = ParseCgiForBorrower($cgi);
 298     $borrower{borrowernumber} = $borrowernumber;
 299
 300     my @empty_mandatory_fields = grep { $_ ne 'password' } # password is not required when editing personal details
 301       ( CheckMandatoryFields( \%borrower, $action ), CheckMandatoryAttributes( \%borrower, $attributes ) );
 302     my $invalidformfields = CheckForInvalidFields(\%borrower);
 303
 304     # Send back the data to the template
 305     %borrower = ( %$borrower, %borrower );
 306
 307     if (@empty_mandatory_fields || @$invalidformfields) {
 308         $template->param(
 309             empty_mandatory_fields => \@empty_mandatory_fields,
 310             invalid_form_fields    => $invalidformfields,
 311             borrower               => \%borrower,
 312             csrf_token             => Koha::Token->new->generate_csrf({
 313                 session_id => scalar $cgi->cookie('CGISESSID'),
 314             }),
 315         );
 316         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ) );
 317
 318         $template->param( action => 'edit' );
 319     }
 320     else {
 321         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 322         $borrower_changes{'changed_fields'} = join ',', keys %borrower_changes;
 323         my $extended_attributes_changes = FilterUnchangedAttributes( $borrowernumber, $attributes );
 324
 325         if ( %borrower_changes || scalar @{$extended_attributes_changes} > 0 ) {
 326             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 327                 {
 328                     template_name   => "opac-memberentry-update-submitted.tt",
 329                     type            => "opac",
 330                     query           => $cgi,
 331                     authnotrequired => 1,
 332                 }
 333             );
 334
 335             $borrower_changes{borrowernumber} = $borrowernumber;
 336             $borrower_changes{extended_attributes} = to_json($extended_attributes_changes);
 337
 338             Koha::Patron::Modifications->search({ borrowernumber => $borrowernumber })->delete;
 339
 340             my $m = Koha::Patron::Modification->new( \%borrower_changes )->store();
 341             #Automatically approve patron profile changes if set in syspref
 342
 343             if (C4::Context->preference('AutoApprovePatronProfileSettings')) {
 344                 # Need to get the object from database, otherwise it is not complete enough to allow deletion
 345                 # when approval has been performed.
 346                 my $tmp_m = Koha::Patron::Modifications->find({borrowernumber => $borrowernumber});
 347                 $tmp_m->approve() if $tmp_m;
 348             }
 349
 350             my $patron = Koha::Patrons->find( $borrowernumber );
 351             $template->param( borrower => $patron->unblessed );
 352         }
 353         else {
 354             my $patron = Koha::Patrons->find( $borrowernumber );
 355             $template->param(
 356                 action => 'edit',
 357                 nochanges => 1,
 358                 borrower => $patron->unblessed,
 359                 patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ),
 360                 csrf_token => Koha::Token->new->generate_csrf({
 361                     session_id => scalar $cgi->cookie('CGISESSID'),
 362                 }),
 363             );
 364         }
 365     }
 366 }
 367 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 368     my $patron = Koha::Patrons->find( $borrowernumber );
 369     my $borrower = $patron->unblessed;
 370
 371     $template->param(
 372         borrower  => $borrower,
 373         hidden => GetHiddenFields( $mandatory, 'edit' ),
 374         csrf_token => Koha::Token->new->generate_csrf({
 375             session_id => scalar $cgi->cookie('CGISESSID'),
 376         }),
 377     );
 378
 379     if (C4::Context->preference('OPACpatronimages')) {
 380         $template->param( display_patron_image => 1 ) if $patron->image;
 381     }
 382
 383     $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber ) );
 384 } else {
 385     # Render self-registration page
 386     $template->param( patron_attribute_classes => GeneratePatronAttributesForm() );
 387 }
 388
 389 my $captcha = random_string("CCCCC");
 390 my $patron_param = Koha::Patrons->find( $borrowernumber );
 391 $template->param(
 392     has_guarantor_flag => $patron_param->guarantor_relationships->guarantors->_resultset->count
 393 ) if $patron_param;
 394
 395 $template->param(
 396     captcha        => $captcha,
 397     captcha_digest => md5_base64($captcha),
 398     patron         => $patron_param
 399 );
 400
 401 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };
 402
 403 sub GetHiddenFields {
 404     my ( $mandatory, $action ) = @_;
 405     my %hidden_fields;
 406
 407     my $BorrowerUnwantedField = $action eq 'edit' || $action eq 'update' ?
 408       C4::Context->preference( "PatronSelfModificationBorrowerUnwantedField" ) :
 409       C4::Context->preference( "PatronSelfRegistrationBorrowerUnwantedField" );
 410
 411     my @fields = split( /\|/, $BorrowerUnwantedField || q|| );
 412     foreach (@fields) {
 413         next unless m/\w/o;
 414         #Don't hide mandatory fields
 415         next if $mandatory->{$_};
 416         $hidden_fields{$_} = 1;
 417     }
 418
 419     return \%hidden_fields;
 420 }
 421
 422 sub GetMandatoryFields {
 423     my ($action) = @_;
 424
 425     my %mandatory_fields;
 426
 427     my $BorrowerMandatoryField = $action eq 'edit' || $action eq 'update' ?
 428       C4::Context->preference("PatronSelfModificationMandatoryField") :
 429       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 430
 431     my @fields = split( /\|/, $BorrowerMandatoryField );
 432     push @fields, 'gdpr_proc_consent' if C4::Context->preference('GDPR_Policy') && $action eq 'create';
 433
 434     foreach (@fields) {
 435         $mandatory_fields{$_} = 1;
 436     }
 437
 438     if ( $action eq 'create' || $action eq 'new' ) {
 439         $mandatory_fields{'email'} = 1
 440           if C4::Context->preference(
 441             'PatronSelfRegistrationVerifyByEmail');
 442     }
 443
 444     return \%mandatory_fields;
 445 }
 446
 447 sub CheckMandatoryFields {
 448     my ( $borrower, $action ) = @_;
 449
 450     my @empty_mandatory_fields;
 451
 452     my $mandatory_fields = GetMandatoryFields($action);
 453     delete $mandatory_fields->{'cardnumber'};
 454
 455     foreach my $key ( keys %$mandatory_fields ) {
 456         push( @empty_mandatory_fields, $key )
 457           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 458     }
 459
 460     return @empty_mandatory_fields;
 461 }
 462
 463 sub CheckMandatoryAttributes{
 464     my ( $borrower, $attributes ) = @_;
 465
 466     my @empty_mandatory_fields;
 467
 468     for my $attribute (@$attributes ) {
 469         my $attr = Koha::Patron::Attribute::Types->find($attribute->{code});
 470         push @empty_mandatory_fields, $attribute->{code}
 471             if $attr && $attr->mandatory && $attribute->{attribute} =~ m|^\s*$|;
 472     }
 473
 474     return @empty_mandatory_fields;
 475 }
 476
 477 sub CheckForInvalidFields {
 478     my $borrower = shift;
 479     my @invalidFields;
 480     if ($borrower->{'email'}) {
 481         unless ( Koha::Email->is_valid($borrower->{email}) ) {
 482             push(@invalidFields, "email");
 483         } elsif ( C4::Context->preference("PatronSelfRegistrationEmailMustBeUnique") ) {
 484             my $patrons_with_same_email = Koha::Patrons->search( # FIXME Should be search_limited?
 485                 {
 486                     email => $borrower->{email},
 487                     (
 488                         exists $borrower->{borrowernumber}
 489                         ? ( borrowernumber =>
 490                               { '!=' => $borrower->{borrowernumber} } )
 491                         : ()
 492                     )
 493                 }
 494             )->count;
 495             if ( $patrons_with_same_email ) {
 496                 push @invalidFields, "duplicate_email";
 497             }
 498         } elsif ( C4::Context->preference("PatronSelfRegistrationConfirmEmail")
 499             && $borrower->{'email'} ne $borrower->{'repeat_email'}
 500             && !defined $borrower->{borrowernumber} ) {
 501             push @invalidFields, "email_match";
 502         }
 503         # email passed all tests, so prevent attempting to store repeat_email
 504         delete $borrower->{'repeat_email'};
 505     }
 506     if ($borrower->{'emailpro'}) {
 507         push(@invalidFields, "emailpro") unless Koha::Email->is_valid($borrower->{'emailpro'});
 508     }
 509     if ($borrower->{'B_email'}) {
 510         push(@invalidFields, "B_email") unless Koha::Email->is_valid($borrower->{'B_email'});
 511     }
 512     if ( defined $borrower->{'password'}
 513         and $borrower->{'password'} ne $borrower->{'password2'} )
 514     {
 515         push( @invalidFields, "password_match" );
 516     }
 517     if ( $borrower->{'password'} ) {
 518         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $borrower->{password}, Koha::Patron::Categories->find($borrower->{categorycode}||C4::Context->preference('PatronSelfRegistrationDefaultCategory')) );
 519           unless ( $is_valid ) {
 520               push @invalidFields, 'password_too_short' if $error eq 'too_short';
 521               push @invalidFields, 'password_too_weak' if $error eq 'too_weak';
 522               push @invalidFields, 'password_has_whitespaces' if $error eq 'has_whitespaces';
 523           }
 524     }
 525
 526     return \@invalidFields;
 527 }
 528
 529 sub ParseCgiForBorrower {
 530     my ($cgi) = @_;
 531
 532     my $scrubber = C4::Scrubber->new();
 533     my %borrower;
 534
 535     foreach my $field ( $cgi->param ) {
 536         if ( $field =~ '^borrower_' ) {
 537             my ($key) = substr( $field, 9 );
 538             if ( $field !~ '^borrower_password' ) {
 539                 $borrower{$key} = $scrubber->scrub( scalar $cgi->param($field) );
 540             } else {
 541                 # Allow html characters for passwords
 542                 $borrower{$key} = $cgi->param($field);
 543             }
 544         }
 545     }
 546
 547     if ( defined $borrower{'dateofbirth'} ) {
 548         my $dob_dt;
 549         $dob_dt = eval { dt_from_string( $borrower{'dateofbirth'} ); }
 550             if ( $borrower{'dateofbirth'} );
 551
 552         if ( $dob_dt ) {
 553             $borrower{'dateofbirth'} = output_pref( { dt => $dob_dt, dateonly => 1, dateformat => 'iso' } );
 554         }
 555         else {
 556             # Trigger validation
 557             $borrower{'dateofbirth'} = undef;
 558         }
 559     }
 560
 561     # Replace checkbox 'agreed' by datetime in gdpr_proc_consent
 562     $borrower{gdpr_proc_consent} = dt_from_string if  $borrower{gdpr_proc_consent} && $borrower{gdpr_proc_consent} eq 'agreed';
 563
 564     delete $borrower{$_} for qw/borrowernumber date_renewed debarred debarredcomment flags privacy privacy_guarantor_fines privacy_guarantor_checkouts checkprevcheckout updated_on lastseen lang login_attempts overdrive_auth_token anonymized/; # See also members/memberentry.pl
 565     delete $borrower{$_} for qw/dateenrolled dateexpiry borrowernotes opacnote sort1 sort2 sms_provider_id autorenew_checkouts gonenoaddress lost relationship/; # On OPAC only
 566     delete $borrower{$_} for split( /\s*\|\s*/, C4::Context->preference('PatronSelfRegistrationBorrowerUnwantedField') || q{} );
 567
 568     return %borrower;
 569 }
 570
 571 sub DelUnchangedFields {
 572     my ( $borrowernumber, %new_data ) = @_;
 573     # get the mandatory fields so we can get the hidden fields
 574     my $mandatory = GetMandatoryFields('edit');
 575     my $patron = Koha::Patrons->find( $borrowernumber );
 576     my $current_data = $patron->unblessed;
 577     # get the hidden fields so we don't obliterate them should they have data patrons aren't allowed to modify
 578     my $hidden_fields = GetHiddenFields($mandatory, 'edit');
 579
 580
 581     foreach my $key ( keys %new_data ) {
 582         next if defined($new_data{$key}) xor defined($current_data->{$key});
 583         if ( !defined($new_data{$key}) || $current_data->{$key} eq $new_data{$key} || $hidden_fields->{$key} ) {
 584            delete $new_data{$key};
 585         }
 586     }
 587
 588     return %new_data;
 589 }
 590
 591 sub DelEmptyFields {
 592     my (%borrower) = @_;
 593
 594     foreach my $key ( keys %borrower ) {
 595         delete $borrower{$key} unless $borrower{$key};
 596     }
 597
 598     return %borrower;
 599 }
 600
 601 sub FilterUnchangedAttributes {
 602     my ( $borrowernumber, $entered_attributes ) = @_;
 603
 604     my @patron_attributes = grep {$_->type->opac_editable ? $_ : ()} Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 605
 606     my $patron_attribute_types;
 607     foreach my $attr (@patron_attributes) {
 608         $patron_attribute_types->{ $attr->code } += 1;
 609     }
 610
 611     my $passed_attribute_types;
 612     foreach my $attr (@{ $entered_attributes }) {
 613         $passed_attribute_types->{ $attr->{ code } } += 1;
 614     }
 615
 616     my @changed_attributes;
 617
 618     # Loop through the current patron attributes
 619     foreach my $attribute_type ( keys %{ $patron_attribute_types } ) {
 620         if ( $patron_attribute_types->{ $attribute_type } !=  $passed_attribute_types->{ $attribute_type } ) {
 621             # count differs, overwrite all attributes for given type
 622             foreach my $attr (@{ $entered_attributes }) {
 623                 push @changed_attributes, $attr
 624                     if $attr->{ code } eq $attribute_type;
 625             }
 626         } else {
 627             # count matches, check values
 628             my $changes = 0;
 629             foreach my $attr (grep { $_->code eq $attribute_type } @patron_attributes) {
 630                 $changes = 1
 631                     unless any { $_->{ value } eq $attr->attribute } @{ $entered_attributes };
 632                 last if $changes;
 633             }
 634
 635             if ( $changes ) {
 636                 foreach my $attr (@{ $entered_attributes }) {
 637                     push @changed_attributes, $attr
 638                         if $attr->{ code } eq $attribute_type;
 639                 }
 640             }
 641         }
 642     }
 643
 644     # Loop through passed attributes, looking for new ones
 645     foreach my $attribute_type ( keys %{ $passed_attribute_types } ) {
 646         if ( !defined $patron_attribute_types->{ $attribute_type } ) {
 647             # YAY, new stuff
 648             foreach my $attr (grep { $_->{code} eq $attribute_type } @{ $entered_attributes }) {
 649                 push @changed_attributes, $attr;
 650             }
 651         }
 652     }
 653
 654     return \@changed_attributes;
 655 }
 656
 657 sub GeneratePatronAttributesForm {
 658     my ( $borrowernumber, $entered_attributes ) = @_;
 659
 660     # Get all attribute types and the values for this patron (if applicable)
 661     my @types = grep { $_->opac_editable() or $_->opac_display } # FIXME filter using DBIC
 662         Koha::Patron::Attribute::Types->search()->as_list();
 663     if ( scalar(@types) == 0 ) {
 664         return [];
 665     }
 666
 667     my @displayable_attributes = grep { $_->type->opac_display ? $_ : () }
 668         Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 669
 670     my %attr_values = ();
 671
 672     # Build the attribute values list either from the passed values
 673     # or taken from the patron itself
 674     if ( defined $entered_attributes ) {
 675         foreach my $attr (@$entered_attributes) {
 676             push @{ $attr_values{ $attr->{code} } }, $attr->{value};
 677         }
 678     }
 679     elsif ( defined $borrowernumber ) {
 680         my @editable_attributes = grep { $_->type->opac_editable ? $_ : () } @displayable_attributes;
 681         foreach my $attr (@editable_attributes) {
 682             push @{ $attr_values{ $attr->code } }, $attr->attribute;
 683         }
 684     }
 685
 686     # Add the non-editable attributes (that don't come from the form)
 687     foreach my $attr ( grep { !$_->type->opac_editable } @displayable_attributes ) {
 688         push @{ $attr_values{ $attr->code } }, $attr->attribute;
 689     }
 690
 691     # Find all existing classes
 692     my @classes = sort( uniq( map { $_->class } @types ) );
 693     my %items_by_class;
 694
 695     foreach my $attr_type (@types) {
 696         push @{ $items_by_class{ $attr_type->class() } }, {
 697             type => $attr_type,
 698             # If editable, make sure there's at least one empty entry,
 699             # to make the template's job easier
 700             values => $attr_values{ $attr_type->code() } || ['']
 701         }
 702             unless !defined $attr_values{ $attr_type->code() }
 703                     and !$attr_type->opac_editable;
 704     }
 705
 706     # Finally, build a list of containing classes
 707     my @class_loop;
 708     foreach my $class (@classes) {
 709         next unless ( $items_by_class{$class} );
 710
 711         my $av = Koha::AuthorisedValues->search(
 712             { category => 'PA_CLASS', authorised_value => $class } );
 713
 714         my $lib = $av->count ? $av->next->opac_description : $class;
 715
 716         push @class_loop,
 717             {
 718             class => $class,
 719             items => $items_by_class{$class},
 720             lib   => $lib,
 721             };
 722     }
 723
 724     return \@class_loop;
 725 }
 726
 727 sub ParsePatronAttributes {
 728     my ( $borrowernumber, $cgi ) = @_;
 729
 730     my @codes  = $cgi->multi_param('patron_attribute_code');
 731     my @values = $cgi->multi_param('patron_attribute_value');
 732
 733     my @editable_attribute_types
 734         = map { $_->code } Koha::Patron::Attribute::Types->search({ opac_editable => 1 })->as_list;
 735
 736     my $ea = each_array( @codes, @values );
 737     my @attributes;
 738
 739     my $delete_candidates = {};
 740
 741     while ( my ( $code, $value ) = $ea->() ) {
 742         if ( any { $_ eq $code } @editable_attribute_types ) {
 743             # It is an editable attribute
 744             if ( !defined($value) or $value eq '' ) {
 745                 $delete_candidates->{$code} = 1
 746                     unless $delete_candidates->{$code};
 747             }
 748             else {
 749                 # we've got a value
 750                 push @attributes, { code => $code, attribute => $value };
 751
 752                 # 'code' is no longer a delete candidate
 753                 delete $delete_candidates->{$code}
 754                     if defined $delete_candidates->{$code};
 755             }
 756         }
 757     }
 758
 759     foreach my $code ( keys %{$delete_candidates} ) {
 760         if ( not $borrowernumber # self-registration
 761             || Koha::Patron::Attributes->search({
 762                 borrowernumber => $borrowernumber, code => $code })->count > 0 )
 763         {
 764             push @attributes, { code => $code, attribute => '' }
 765                 unless any { $_->{code} eq $code } @attributes;
 766         }
 767     }
 768
 769     return \@attributes;
 770 }
 771
 772
 773 1;