serials/serials-edit.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Parts Copyright 2010 Biblibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 =head1 NAME
  22
  23 serials-edit.pl
  24
  25 =head1 Parameters
  26
  27 =over 4
  28
  29 =item op
  30 op can be :
  31     * modsubscriptionhistory :to modify the subscription history
  32     * serialchangestatus     :to modify the status of this subscription
  33
  34 =item subscriptionid
  35
  36 =item user
  37
  38 =item histstartdate
  39
  40 =item enddate
  41
  42 =item recievedlist
  43
  44 =item missinglist
  45
  46 =item opacnote
  47
  48 =item librariannote
  49
  50 =item serialid
  51
  52 =item serialseq
  53
  54 =item planneddate
  55
  56 =item notes
  57
  58 =item status
  59
  60 =back
  61
  62 =cut
  63
  64 use Modern::Perl;
  65 use CGI qw ( -utf8 );
  66 use Encode;
  67 use C4::Auth qw( get_template_and_user haspermission );
  68 use C4::Biblio qw( GetMarcFromKohaField TransformHtmlToXml );
  69 use C4::Items qw( AddItemFromMarc ModItemFromMarc PrepareItemrecordDisplay );
  70 use C4::Output qw( output_html_with_http_headers );
  71 use C4::Context;
  72 use C4::Serials qw( GetSerials GetSerials2 GetSerialInformation HasSubscriptionExpired GetSubscription abouttoexpire NewIssue ModSerialStatus GetPreviousSerialid AddItem2Serial );
  73 use C4::Search qw( enabled_staff_search_views );
  74
  75 use Koha::DateUtils qw( dt_from_string );
  76 use Koha::Items;
  77 use Koha::Serial::Items;
  78
  79 use List::MoreUtils qw( uniq );
  80 use List::Util qw( min );
  81
  82 my $query           = CGI->new();
  83 my $dbh             = C4::Context->dbh;
  84 my @serialids       = $query->multi_param('serialid');
  85 my @serialseqs      = $query->multi_param('serialseq');
  86 my @planneddates    = $query->multi_param('planneddate');
  87 my @publisheddates  = $query->multi_param('publisheddate');
  88 my @publisheddatetexts = $query->multi_param('publisheddatetext');
  89 my @status          = $query->multi_param('status');
  90 my @notes           = $query->multi_param('notes');
  91 my @subscriptionids = $query->multi_param('subscriptionid');
  92 my $op              = $query->param('op');
  93 if ( scalar(@subscriptionids) == 1 && index( $subscriptionids[0], q|,| ) > 0 ) {
  94     @subscriptionids = split( /,/, $subscriptionids[0] );
  95 }
  96 my @errors;
  97 my @errseq;
  98
  99 # If user comes from subscription details
 100 unless (@serialids) {
 101     my $serstatus = $query->param('serstatus');
 102     my @statuses = split ',', $serstatus;
 103     if ($serstatus) {
 104         foreach my $subscriptionid (@subscriptionids) {
 105             my @tmpser = GetSerials2( $subscriptionid, \@statuses );
 106             push @serialids, map { $_->{serialid} } @tmpser;
 107         }
 108     }
 109 }
 110
 111 unless ( @serialids ) {
 112     my $string =
 113       'serials-collection.pl?subscriptionid=' . join ',', uniq @subscriptionids;
 114     $string =~ s/,$//;
 115
 116     print $query->redirect($string);
 117     exit;
 118 }
 119
 120 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 121     {
 122         template_name   => 'serials/serials-edit.tt',
 123         query           => $query,
 124         type            => 'intranet',
 125         flagsrequired   => { serials => 'receive_serials' },
 126     }
 127 );
 128
 129 my @serialdatalist;
 130 my %processedserialid;
 131
 132 my $today = dt_from_string;
 133
 134 foreach my $serialid (@serialids) {
 135
 136     #filtering serialid for duplication
 137     #NEW serial should appear only once and are created afterwards
 138     if (   $serialid
 139         && $serialid =~ /^[0-9]+$/
 140         && !$processedserialid{$serialid} )
 141     {
 142         my $serinfo = GetSerialInformation($serialid); #TODO duplicates work done by GetSerials2 above
 143
 144         $serinfo->{arriveddate} = $today;
 145
 146         $serinfo->{'editdisable'} = (
 147             (
 148                 HasSubscriptionExpired( $serinfo->{subscriptionid} )
 149                 && $serinfo->{'status1'}
 150             )
 151             || $serinfo->{'cannotedit'}
 152         );
 153         $serinfo->{editdisable} = 0 if C4::Auth::haspermission( C4::Context->userenv->{id}, { serials => 'receive_serials' } );
 154         $serinfo->{editdisable} ||= ($serinfo->{status8} and $serinfo->{closed});
 155         push @serialdatalist, $serinfo;
 156         $processedserialid{$serialid} = 1;
 157     }
 158 }
 159 my $biblio = Koha::Biblios->find( $serialdatalist[0]->{biblionumber} );
 160
 161 my @newserialloop;
 162 my @subscriptionloop;
 163
 164 # check, for each subscription edited, that we have an empty item line if applicable for the subscription
 165 my %processedsubscriptionid;
 166 foreach my $subscriptionid (@subscriptionids) {
 167
 168     #Do not process subscriptionid twice if it was already processed.
 169     if ( $subscriptionid && !$processedsubscriptionid{$subscriptionid} )
 170     {
 171         my $cell;
 172         if ( $serialdatalist[0]->{'serialsadditems'} ) {
 173
 174             #Create New empty item
 175             $cell =
 176               PrepareItemrecordDisplay( $serialdatalist[0]->{'biblionumber'},
 177                 '', GetSubscription($subscriptionid) );
 178             $cell->{serialsadditems} = 1;
 179         }
 180         $cell->{'subscriptionid'} = $subscriptionid;
 181         $cell->{biblionumber} = $serialdatalist[0]->{'biblionumber'};
 182         $cell->{'itemid'}         = 'NNEW';
 183         $cell->{'serialid'}       = 'NEW';
 184         $cell->{'issuesatonce'}   = 1;
 185         $cell->{arriveddate}      = $today;
 186
 187         push @newserialloop, $cell;
 188         push @subscriptionloop,
 189           {
 190             'subscriptionid'      => $subscriptionid,
 191             'abouttoexpire'       => abouttoexpire($subscriptionid),
 192             'subscriptionexpired' => HasSubscriptionExpired($subscriptionid),
 193           };
 194         $processedsubscriptionid{$subscriptionid} = 1;
 195     }
 196 }
 197 $template->param( newserialloop => \@newserialloop );
 198 $template->param( subscriptions => \@subscriptionloop );
 199
 200 if ( $op and $op eq 'serialchangestatus' ) {
 201
 202     # Convert serialseqs to UTF-8 to prevent encoding problems
 203     foreach my $seq (@serialseqs) {
 204         $seq = Encode::decode('UTF-8', $seq) unless Encode::is_utf8($seq);
 205     }
 206
 207     my $newserial;
 208     for ( my $i = 0 ; $i <= $#serialids ; $i++ ) {
 209         my ($plan_date, $pub_date);
 210
 211         if (defined $planneddates[$i] && $planneddates[$i] ne 'XXX') {
 212             $plan_date = $planneddates[$i];
 213         }
 214         if (defined $publisheddates[$i] && $publisheddates[$i] ne 'XXX') {
 215             $pub_date = $publisheddates[$i];
 216         }
 217
 218         if ( $serialids[$i] && $serialids[$i] eq 'NEW' ) {
 219             if ( $serialseqs[$i] ) {
 220
 221             #IF newserial was provided a name Then we have to create a newSerial
 222                 ### FIXME if NewIssue is modified to use subscription biblionumber, then biblionumber would not be useful.
 223                 $newserial = NewIssue(
 224                     $serialseqs[$i],
 225                     $subscriptionids[0],
 226                     $serialdatalist[0]->{'biblionumber'},
 227                     $status[$i],
 228                     $plan_date,
 229                     $pub_date,
 230                     $publisheddatetexts[$i],
 231                     $notes[$i],
 232                     $serialdatalist[0]->{'routingnotes'}
 233                 );
 234             }
 235         }
 236         elsif ( $serialids[$i] ) {
 237             ModSerialStatus(
 238                 $serialids[$i],
 239                 $serialseqs[$i],
 240                 $plan_date,
 241                 $pub_date,
 242                 $publisheddatetexts[$i],
 243                 $status[$i],
 244                 $notes[$i]
 245             );
 246         }
 247         my $makePreviousSerialAvailable = C4::Context->preference('makePreviousSerialAvailable');
 248         if ($makePreviousSerialAvailable && $serialids[$i] ne "NEW") {
 249             # We already have created the new expected serial at this point, so we get the second previous serial
 250             my $previous = GetPreviousSerialid($subscriptionids[$i]);
 251             if ($previous) {
 252
 253                 my $serialitem = Koha::Serial::Items->search( {serialid => $previous} )->next;
 254                 my $itemnumber = $serialitem ? $serialitem->itemnumber : undef;
 255                 if ($itemnumber) {
 256
 257                     # Getting the itemtype to set from the database
 258                     my $subscriptioninfos = GetSubscription($subscriptionids[$i]);
 259
 260                     # Changing the status to "available" and the itemtype according to the previousitemtype db field
 261                     my $item = Koha::Items->find($itemnumber);
 262                     $item->set(
 263                         {
 264                             notforloan => 0,
 265                             itype => $subscriptioninfos->{'previousitemtype'}
 266                         }
 267                     )->store;
 268                 }
 269             }
 270         }
 271
 272     }
 273     my @moditems = $query->multi_param('moditem');
 274     if ( scalar(@moditems) ) {
 275         my @tags         = $query->multi_param('tag');
 276         my @subfields    = $query->multi_param('subfield');
 277         my @field_values = $query->multi_param('field_value');
 278         my @serials      = $query->multi_param('serial');
 279         my @bibnums      = $query->multi_param('bibnum');
 280         my @itemid       = $query->multi_param('itemid');
 281         my @num_copies   = map { min($_, 1000); } $query->multi_param('number_of_copies');
 282
 283         #Rebuilding ALL the data for items into a hash
 284         # parting them on $itemid.
 285         my %itemhash;
 286         my $countdistinct = 0;
 287         my $range = scalar(@itemid);
 288         for ( my $i = 0 ; $i < $range ; $i++ ) {
 289             unless ( $itemhash{ $itemid[$i] } ) {
 290                 if (   $serials[$countdistinct]
 291                     && $serials[$countdistinct] ne "NEW" )
 292                 {
 293                     $itemhash{ $itemid[$i] }->{'serial'} =
 294                       $serials[$countdistinct];
 295                 }
 296                 else {
 297                     $itemhash{ $itemid[$i] }->{'serial'} = $newserial;
 298                 }
 299                 $itemhash{ $itemid[$i] }->{'bibnum'} = $bibnums[$countdistinct];
 300                 $itemhash{ $itemid[$i] }->{'num_copies'} = $num_copies[$countdistinct];
 301                 $countdistinct++;
 302             }
 303             push @{ $itemhash{ $itemid[$i] }->{'tags'} },      $tags[$i];
 304             push @{ $itemhash{ $itemid[$i] }->{'subfields'} }, $subfields[$i];
 305             push @{ $itemhash{ $itemid[$i] }->{'field_values'} },
 306               $field_values[$i];
 307         }
 308         foreach my $item ( keys %itemhash ) {
 309
 310        # Verify Itemization is "Valid", i.e. serial status is Arrived or Missing
 311             my $index = -1;
 312             for ( my $i = 0 ; $i < scalar(@serialids) ; $i++ ) {
 313                   if (
 314                     $itemhash{$item}->{serial} eq $serialids[$i]
 315                     || (   $itemhash{$item}->{serial} == $newserial
 316                         && $serialids[$i] eq 'NEW' )
 317                 ) {
 318                     $index = $i
 319                   }
 320             }
 321             if ( $index >= 0 && $status[$index] == 2 ) {
 322                 my $xml = TransformHtmlToXml(
 323                     $itemhash{$item}->{'tags'},
 324                     $itemhash{$item}->{'subfields'},
 325                     $itemhash{$item}->{'field_values'},
 326                     undef,
 327                     undef
 328                 );
 329
 330                 # warn $xml;
 331                 my $bib_record = MARC::Record::new_from_xml( $xml, 'UTF-8' );
 332                 if ( $item =~ /^N/ ) {
 333
 334                 $itemhash{$item}->{'num_copies'} //= 1;
 335
 336                 for (my $copy = 0; $copy < $itemhash{$item}->{'num_copies'};){
 337
 338                 # New Item
 339
 340                   # if autoBarcode is set to 'incremental', calculate barcode...
 341                     my ( $barcodetagfield, $barcodetagsubfield ) = GetMarcFromKohaField( 'items.barcode' );
 342                     if ( C4::Context->preference('autoBarcode') eq
 343                         'incremental' )
 344                     {
 345                         if (
 346                             !(
 347                                    $bib_record->field($barcodetagfield)
 348                                 && $bib_record->field($barcodetagfield)->subfield($barcodetagsubfield)
 349                             )
 350                           )
 351                         {
 352                             my $sth_barcode = $dbh->prepare(
 353                                 'select max(abs(barcode)) from items');
 354                             $sth_barcode->execute;
 355                             my ($newbarcode) = $sth_barcode->fetchrow;
 356
 357                             # OK, we have the new barcode, add the entry in MARC record # FIXME -> should be  using barcode plugin here.
 358                             $bib_record->field($barcodetagfield)->update( $barcodetagsubfield => ++$newbarcode );
 359                         }
 360                     }
 361
 362                     # check for item barcode # being unique
 363                     my $exists;
 364                     if ( $bib_record->subfield( $barcodetagfield, $barcodetagsubfield ) ) {
 365                         my $barcode = $bib_record->subfield( $barcodetagfield, $barcodetagsubfield );
 366
 367                         if ($copy > 0){
 368                             use C4::Barcodes;
 369                             my $barcodeobj = C4::Barcodes->new;
 370                             my $newbarcode = $barcodeobj->next_value($barcode);
 371                             $barcode = $newbarcode;
 372                             $bib_record->field($barcodetagfield)->update($barcodetagsubfield => $barcode);
 373                         }
 374
 375                         $exists = Koha::Items->find({barcode => $barcode});
 376                     }
 377
 378                     #           push @errors,"barcode_not_unique" if($exists);
 379                     # if barcode exists, don't create, but report The problem.
 380                     if ($exists) {
 381                         push @errors, 'barcode_not_unique';
 382                         push @errseq, { serialseq => $serialseqs[$index] };
 383                     }
 384                     else {
 385                         my ( $biblionumber, $bibitemnum, $itemnumber ) =
 386                           AddItemFromMarc( $bib_record,
 387                             $itemhash{$item}->{bibnum} );
 388                         AddItem2Serial( $itemhash{$item}->{serial},
 389                             $itemnumber );
 390                     }
 391                     $copy++;
 392                 }
 393
 394                 } # if ( $item =~ /^N/ ) {
 395
 396                 else {
 397
 398                     #modify item
 399                     my ( $oldbiblionumber, $oldbibnum, $itemnumber ) =
 400                       ModItemFromMarc( $bib_record,
 401                         $itemhash{$item}->{'bibnum'}, $item );
 402                 }
 403             }
 404         }
 405     }
 406
 407
 408     if ( @errors ) {
 409         $template->param( Errors => 1 );
 410         if ( @errseq ) {
 411             $template->param( barcode_not_unique => 1, errseq => \@errseq );
 412         }
 413     }
 414     else {
 415         my $redirect = 'serials-collection.pl?';
 416         $redirect .= join( '&', map { 'subscriptionid=' . $_ } @subscriptionids );
 417         print $query->redirect($redirect);
 418     }
 419 }
 420 my $location = $serialdatalist[0]->{'location'};
 421
 422 $template->param(
 423     subscriptionid  => $serialdatalist[0]->{subscriptionid},
 424     serialsadditems => $serialdatalist[0]->{'serialsadditems'},
 425     callnumber       => $serialdatalist[0]->{'callnumber'},
 426     internalnotes   => $serialdatalist[0]->{'internalnotes'},
 427     bibliotitle     => $biblio->title,
 428     biblionumber    => $serialdatalist[0]->{'biblionumber'},
 429     serialslist     => \@serialdatalist,
 430     location         => $location,
 431     (uc(C4::Context->preference("marcflavour"))) => 1
 432
 433 );
 434 output_html_with_http_headers $query, $cookie, $template->output;