suggestion/suggestion.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # Copyright 2006-2010 BibLibre
   5
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 require Exporter;
  22 use CGI qw ( -utf8 );
  23 use C4::Auth qw( get_template_and_user );
  24 use C4::Output qw( output_html_with_http_headers output_and_exit_if_error );
  25 use C4::Suggestions;
  26 use C4::Koha qw( GetAuthorisedValues );
  27 use C4::Budgets qw( GetBudget GetBudgets GetBudgetHierarchy CanUserUseBudget );
  28 use C4::Search qw( FindDuplicate GetDistinctValues );
  29 use C4::Members;
  30 use Koha::DateUtils qw( dt_from_string );
  31 use Koha::AuthorisedValues;
  32 use Koha::Acquisition::Currencies;
  33 use Koha::Libraries;
  34 use Koha::Patrons;
  35 use Koha::Suggestions;
  36 use Koha::Token;
  37
  38 use URI::Escape qw( uri_escape );
  39
  40 sub Init{
  41     my $suggestion= shift @_;
  42     # "Managed by" is used only when a suggestion is being edited (not when created)
  43     if ($suggestion->{'suggesteddate'} eq "") {
  44         # new suggestion
  45         $suggestion->{suggesteddate} = dt_from_string;
  46         $suggestion->{'suggestedby'} = C4::Context->userenv->{"number"} unless ($suggestion->{'suggestedby'});
  47     }
  48     else {
  49         # editing of an existing suggestion
  50         $suggestion->{manageddate} = dt_from_string;
  51         $suggestion->{'managedby'} = C4::Context->userenv->{"number"} unless ($suggestion->{'managedby'});
  52     }
  53     $suggestion->{'branchcode'}=C4::Context->userenv->{"branch"} unless ($suggestion->{'branchcode'});
  54 }
  55
  56 sub GetCriteriumDesc{
  57     my ($criteriumvalue,$displayby)=@_;
  58     if ($displayby =~ /status/i) {
  59         unless ( grep { /$criteriumvalue/ } qw(ASKED ACCEPTED REJECTED CHECKED ORDERED AVAILABLE) ) {
  60             my $av = Koha::AuthorisedValues->search({ category => 'SUGGEST_STATUS', authorised_value => $criteriumvalue });
  61             return $av->count ? $av->next->lib : 'Unknown';
  62         }
  63         return ($criteriumvalue eq 'ASKED'?"Pending":ucfirst(lc( $criteriumvalue))) if ($displayby =~/status/i);
  64     }
  65     if ( $displayby =~ /branchcode/ ) {
  66         return $criteriumvalue ? Koha::Libraries->find($criteriumvalue)->branchname : "__ANY__";
  67     }
  68     if ( $displayby =~ /itemtype/ ) {
  69         my $av = Koha::AuthorisedValues->search({ category => 'SUGGEST_FORMAT', authorised_value => $criteriumvalue });
  70         return $av->count ? $av->next->lib : 'Unknown';
  71     }
  72     if ($displayby =~/suggestedby/||$displayby =~/managedby/||$displayby =~/acceptedby/){
  73         my $patron = Koha::Patrons->find( $criteriumvalue );
  74         return "" unless $patron;
  75         return $patron->surname . ", " . $patron->firstname;
  76     }
  77     if ( $displayby =~ /budgetid/) {
  78         my $budget = GetBudget($criteriumvalue);
  79         return "" unless $budget;
  80         return $$budget{budget_name};
  81     }
  82 }
  83
  84 my $input           = CGI->new;
  85 my $redirect  = $input->param('redirect');
  86 my $suggestedbyme   = (defined $input->param('suggestedbyme')? $input->param('suggestedbyme'):1);
  87 my $op              = $input->param('op')||'else';
  88 my @editsuggestions = $input->multi_param('suggestionid');
  89 my $suggestedby     = $input->param('suggestedby');
  90 my $returnsuggestedby = $input->param('returnsuggestedby');
  91 my $returnsuggested = $input->param('returnsuggested');
  92 my $managedby       = $input->param('managedby');
  93 my $displayby       = $input->param('displayby') || '';
  94 my $tabcode         = $input->param('tabcode');
  95 my $save_confirmed  = $input->param('save_confirmed') || 0;
  96 my $notify          = $input->param('notify');
  97 my $filter_archived = $input->param('filter_archived') || 0;
  98 my $new_itemtype    = $input->param('suggestion_itemtype');
  99 my $sugg_managedby  = $input->param('suggestion_managedby');
 100
 101 my $reasonsloop     = GetAuthorisedValues("SUGGEST");
 102
 103 my $suggestion_ref  = { $input->Vars };
 104 delete $suggestion_ref->{$_} for qw(csrf_token suggestion_itemtype suggestion_managedby table_1_length);
 105
 106 # get only the columns of Suggestion
 107 my $schema = Koha::Database->new()->schema;
 108 my $columns = ' '.join(' ', $schema->source('Suggestion')->columns).' ';
 109 my $suggestion_only = { map { $columns =~ / $_ / ? ($_ => $suggestion_ref->{$_}) : () } keys %$suggestion_ref };
 110 $suggestion_only->{STATUS} = $suggestion_ref->{STATUS};
 111
 112 delete $$suggestion_ref{$_}
 113     foreach
 114     qw( suggestedbyme op displayby tabcode notify filter_archived koha_login_context auth_forwarded_hash password userid );
 115 foreach (keys %$suggestion_ref){
 116     delete $$suggestion_ref{$_} if (!$$suggestion_ref{$_} && ($op eq 'else' ));
 117 }
 118 delete $suggestion_only->{branchcode} if $suggestion_only->{branchcode} eq '__ANY__';
 119 delete $suggestion_only->{budgetid}   if $suggestion_only->{budgetid}   eq '__ANY__';
 120 while ( my ( $k, $v ) = each %$suggestion_only ) {
 121     delete $suggestion_only->{$k} if $v eq '';
 122 }
 123
 124 my ( $template, $borrowernumber, $cookie, $userflags ) = get_template_and_user(
 125         {
 126             template_name   => "suggestion/suggestion.tt",
 127             query           => $input,
 128             type            => "intranet",
 129             flagsrequired   => { suggestions => 'suggestions_manage' },
 130         }
 131     );
 132
 133 $borrowernumber = $input->param('borrowernumber') if ( $input->param('borrowernumber') );
 134 $template->param('borrowernumber' => $borrowernumber);
 135 my $branchfilter = $input->param('branchcode') || C4::Context->userenv->{'branch'};
 136
 137 #########################################
 138 ##  Operations
 139 ##
 140
 141 if ( $op =~ /cud-save/ ) {
 142     my @messages;
 143     my $biblio = MarcRecordFromNewSuggestion({
 144             title => $suggestion_only->{title},
 145             author => $suggestion_only->{author},
 146             itemtype => $suggestion_only->{itemtype},
 147             isbn => $suggestion_only->{isbn},
 148     });
 149
 150     my $manager = Koha::Patrons->find( $suggestion_only->{managedby} );
 151     if ( $manager && not $manager->has_permission({suggestions => 'suggestions_manage'})) {
 152         push @messages, { type => 'error', code => 'manager_not_enough_permissions' };
 153         $template->param(
 154             messages => \@messages,
 155         );
 156         delete $suggestion_ref->{suggesteddate};
 157         delete $suggestion_ref->{manageddate};
 158         delete $suggestion_ref->{managedby};
 159         Init($suggestion_ref);
 160     }
 161     elsif ( !$suggestion_only->{suggestionid} && ( my ($duplicatebiblionumber, $duplicatetitle) = FindDuplicate($biblio) ) && !$save_confirmed ) {
 162         push @messages, { type => 'error', code => 'biblio_exists', id => $duplicatebiblionumber, title => $duplicatetitle };
 163         $template->param(
 164             messages => \@messages,
 165             need_confirm => 1
 166         );
 167         delete $suggestion_ref->{suggesteddate};
 168         delete $suggestion_ref->{manageddate};
 169         Init($suggestion_ref);
 170     }
 171     else {
 172
 173         for my $date_key ( qw( suggesteddate manageddate accepteddate rejecteddate ) ) {
 174             # FIXME Do we need this?
 175             $suggestion_only->{$date_key} = dt_from_string( $suggestion_only->{$date_key} )
 176                 if $suggestion_only->{$date_key};
 177         }
 178
 179         if ( $suggestion_only->{"STATUS"} ) {
 180             if ( my $tmpstatus = lc( $suggestion_only->{"STATUS"} ) =~ /ACCEPTED|REJECTED/i ) {
 181                 $suggestion_only->{ lc( $suggestion_only->{"STATUS"}) . "date" } = dt_from_string;
 182                 $suggestion_only->{ lc( $suggestion_only->{"STATUS"}) . "by" }   = C4::Context->userenv->{number};
 183             }
 184             $suggestion_only->{manageddate} = dt_from_string;
 185             $suggestion_only->{"managedby"} ||= C4::Context->userenv->{number};
 186         }
 187
 188         my $otherreason = $input->param('other_reason');
 189         if ($suggestion_only->{reason} eq 'other' && $otherreason) {
 190             $suggestion_only->{reason} = $otherreason;
 191         }
 192
 193         if ( $suggestion_only->{'suggestionid'} > 0 ) {
 194
 195             $suggestion_only->{lastmodificationdate} = dt_from_string;
 196             $suggestion_only->{lastmodificationby}   = C4::Context->userenv->{number};
 197             $suggestion_only->{branchcode} = undef
 198               if exists $suggestion_only->{branchcode}
 199               && $suggestion_only->{branchcode} eq "";
 200
 201             &ModSuggestion($suggestion_only);
 202
 203             if ( $notify ) {
 204                 my $patron = Koha::Patrons->find( $suggestion_only->{managedby} );
 205                 my $email_address = $patron->notice_email_address;
 206                 if ($patron->notice_email_address) {
 207
 208                     my $letter = C4::Letters::GetPreparedLetter(
 209                         module      => 'suggestions',
 210                         letter_code => 'NOTIFY_MANAGER',
 211                         branchcode  => $patron->branchcode,
 212                         lang        => $patron->lang,
 213                         tables      => {
 214                             suggestions => $suggestion_only->{suggestionid},
 215                             branches    => $patron->branchcode,
 216                             borrowers   => $patron->borrowernumber,
 217                         },
 218                     );
 219                     C4::Letters::EnqueueLetter(
 220                         {
 221                             letter                 => $letter,
 222                             borrowernumber         => $patron->borrowernumber,
 223                             message_transport_type => 'email'
 224                         }
 225                     );
 226                 }
 227             }
 228         } else {
 229             ###FIXME:Search here if suggestion already exists.
 230             my $suggestions= Koha::Suggestions->search_limited( $suggestion_only );
 231             if ( $suggestions->count ) {
 232                 #some suggestion are answering the request Donot Add
 233                 my @messages;
 234                 while ( my $suggestion = $suggestions->next ) {
 235                     push @messages, { type => 'error', code => 'already_exists', id => $suggestion->suggestionid };
 236                 }
 237                 $template->param( messages => \@messages );
 238             }
 239             else {
 240                 ## Adding some informations related to suggestion
 241                 Koha::Suggestion->new($suggestion_only)->store();
 242             }
 243             # empty fields, to avoid filter in "SearchSuggestion"
 244         }
 245         map{delete $$suggestion_ref{$_} unless $_ eq 'branchcode' } keys %$suggestion_ref;
 246         $op = 'else';
 247
 248         if( $redirect eq 'purchase_suggestions' ) {
 249             print $input->redirect("/cgi-bin/koha/members/purchase-suggestions.pl?borrowernumber=$borrowernumber");
 250         }
 251     }
 252 }
 253 elsif ( $op eq 'add_form' ) {
 254     #Adds suggestion
 255     Init($suggestion_ref);
 256     $op ='save';
 257 }
 258 elsif ( $op eq 'edit_form' ) {
 259     #Edit suggestion
 260     $suggestion_ref=&GetSuggestion($$suggestion_ref{'suggestionid'});
 261     $suggestion_ref->{reasonsloop} = $reasonsloop;
 262     my $other_reason = 1;
 263     foreach my $reason ( @{ $reasonsloop } ) {
 264         if ($suggestion_ref->{reason} eq $reason->{lib}) {
 265             $other_reason = 0;
 266         }
 267     }
 268     $other_reason = 0 unless $suggestion_ref->{reason};
 269     $template->param(other_reason => $other_reason);
 270     Init($suggestion_ref);
 271     $op ='save';
 272 }
 273 elsif ($op eq "cud-update_status" ) {
 274     my $suggestion;
 275     # set accepted/rejected/managed informations if applicable
 276     # ie= if the librarian has chosen some action on the suggestions
 277     my $STATUS      = $input->param('STATUS');
 278     my $accepted_by = $input->param('acceptedby');
 279     if ( $STATUS eq "ACCEPTED" ) {
 280         $suggestion = {
 281             accepteddate => dt_from_string,
 282             acceptedby => C4::Context->userenv->{number},
 283         };
 284     }
 285     elsif ( $STATUS eq "REJECTED" ) {
 286         $suggestion = {
 287             rejecteddate => dt_from_string,
 288             rejectedby   => C4::Context->userenv->{number},
 289         };
 290     }
 291     if ($STATUS) {
 292         $suggestion->{manageddate} = dt_from_string;
 293         $suggestion->{managedby}   = C4::Context->userenv->{number};
 294         $suggestion->{STATUS}      = $STATUS;
 295     }
 296     if ( my $reason = $input->param("reason") ) {
 297         if ( $reason eq "other" ) {
 298             $reason = $input->param("other_reason");
 299         }
 300         $suggestion->{reason} = $reason;
 301     }
 302
 303     foreach my $suggestionid (@editsuggestions) {
 304         next unless $suggestionid;
 305         $suggestion->{suggestionid} = $suggestionid;
 306         &ModSuggestion($suggestion);
 307     }
 308     redirect_with_params($input);
 309 }elsif ($op eq "cud-delete" ) {
 310     foreach my $delete_field (@editsuggestions) {
 311         &DelSuggestion( $borrowernumber, $delete_field,'intranet' );
 312     }
 313     redirect_with_params($input);
 314 }
 315 elsif ($op eq "cud-archive" ) {
 316     Koha::Suggestions->find($_)->update({ archived => 1 }) for @editsuggestions;
 317     redirect_with_params($input);
 318 }
 319 elsif ($op eq "cud-unarchive" ) {
 320     Koha::Suggestions->find($_)->update({ archived => 0 }) for @editsuggestions;
 321     redirect_with_params($input);
 322 }
 323 elsif ( $op eq 'cud-update_itemtype' ) {
 324     foreach my $suggestionid (@editsuggestions) {
 325         next unless $suggestionid;
 326         &ModSuggestion({ suggestionid => $suggestionid, itemtype => $new_itemtype });
 327     }
 328     redirect_with_params($input);
 329 }
 330 elsif ( $op eq 'cud-update_manager' ) {
 331     foreach my $suggestionid (@editsuggestions) {
 332         next unless $suggestionid;
 333         &ModSuggestion({ suggestionid => $suggestionid, managedby => $sugg_managedby });
 334     }
 335     redirect_with_params($input);
 336 }
 337 elsif ( $op eq 'show' ) {
 338     $suggestion_ref=&GetSuggestion($$suggestion_ref{'suggestionid'});
 339     my $budget = GetBudget $$suggestion_ref{budgetid};
 340     $$suggestion_ref{budgetname} = $$budget{budget_name};
 341     Init($suggestion_ref);
 342 }
 343
 344 if ( $op eq 'else' ) {
 345
 346     $displayby||="STATUS";
 347     # distinct values of display by
 348     my $criteria_list=GetDistinctValues("suggestions.".$displayby);
 349     my (@criteria_dv, $criteria_has_empty);
 350     foreach (@$criteria_list) {
 351         if ($_->{value}) {
 352             push @criteria_dv, $_->{value};
 353         } else {
 354             $criteria_has_empty = 1;
 355         }
 356     }
 357     # aggregate null and empty values under empty value
 358     push @criteria_dv, '' if $criteria_has_empty;
 359
 360     # Hack to not modify GetDistinctValues for this specific case
 361     if (   $displayby eq 'branchcode'
 362         && C4::Context->preference('IndependentBranches')
 363         && not C4::Context->IsSuperLibrarian )
 364     {
 365         @criteria_dv = ( C4::Context->userenv->{'branch'} );
 366     }
 367     # Pending tab first
 368     if ( $displayby eq 'STATUS' ) {
 369         @criteria_dv = grep { $_ ne 'ASKED' } @criteria_dv;
 370         unshift @criteria_dv, 'ASKED';
 371     }
 372
 373     unless ( exists $suggestion_ref->{branchcode} ) {
 374         $suggestion_ref->{branchcode} = C4::Context->userenv->{'branch'};
 375     }
 376
 377     my @allsuggestions;
 378     foreach my $criteriumvalue ( @criteria_dv ) {
 379         my $search_params = {%$suggestion_ref};
 380
 381         next
 382           if $search_params->{STATUS}
 383           && $displayby eq 'STATUS'
 384           && $criteriumvalue ne $search_params->{STATUS};
 385
 386         # By default, display suggestions from current working branch
 387         my $definedvalue = defined $$suggestion_ref{$displayby} && $$suggestion_ref{$displayby} ne "";
 388
 389         next if ( $definedvalue && $$suggestion_ref{$displayby} ne $criteriumvalue ) and ($displayby ne 'branchcode' && $branchfilter ne '__ANY__' );
 390
 391         $search_params->{$displayby} = $criteriumvalue;
 392
 393         # filter on date fields
 394         foreach my $field (qw( suggesteddate manageddate accepteddate )) {
 395             my $from    = delete $search_params->{"${field}_from"};
 396             my $to      = delete $search_params->{"${field}_to"};
 397
 398             my $from_dt = $from && eval { dt_from_string($from) };
 399             my $to_dt   = $to && eval { dt_from_string($to) };
 400
 401             if ( $from_dt || $to_dt ) {
 402                 my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 403                 if ( $from_dt && $to_dt ) {
 404                     $search_params->{$field} = { -between => [ $dtf->format_date($from_dt), $dtf->format_date($to_dt) ] };
 405                 } elsif ( $from_dt ) {
 406                     $search_params->{$field} = { '>=' => $dtf->format_date($from_dt) };
 407                 } elsif ( $to_dt ) {
 408                     $search_params->{$field} = { '<=' => $dtf->format_date($to_dt) };
 409                 }
 410             }
 411         }
 412         if ( $search_params->{budgetid} && $search_params->{budgetid} eq '__NONE__' ) {
 413             $search_params->{budgetid} = [undef, '' ];
 414         }
 415         for my $f (qw (branchcode budgetid)) {
 416             delete $search_params->{$f}
 417               if $search_params->{$f} eq '__ANY__'
 418               || $search_params->{$f} eq '';
 419         }
 420         for my $bi (qw (title author isbn publishercode copyrightdate collectiontitle)) {
 421             $search_params->{$bi} = { 'LIKE' => "%" . $search_params->{$bi} . "%" } if $search_params->{$bi};
 422         }
 423
 424         $search_params->{archived} = 0 if !$filter_archived;
 425         my @suggestions = Koha::Suggestions->search_limited($search_params)->as_list;
 426
 427         push @allsuggestions,
 428           {
 429             "suggestiontype"      => $criteriumvalue || "suggest",
 430             "suggestiontypelabel" => GetCriteriumDesc( $criteriumvalue, $displayby ) || "",
 431             'suggestions'         => \@suggestions,
 432             'reasonsloop'         => $reasonsloop,
 433           }
 434           if scalar @suggestions > 0;
 435
 436         delete $$suggestion_ref{$displayby} unless $definedvalue;
 437     }
 438
 439     $template->param(
 440         "displayby"=> $displayby,
 441         "notabs"=> $displayby eq "",
 442         suggestions       => \@allsuggestions,
 443     );
 444 }
 445
 446 $template->param(
 447     "${_}_patron" => scalar Koha::Patrons->find( $suggestion_ref->{$_} ) )
 448   for qw(managedby suggestedby acceptedby lastmodificationby);
 449
 450 $template->param(
 451     %$suggestion_ref,
 452     filter_archived => $filter_archived,
 453     "op"             =>$op,
 454 );
 455
 456 if(defined($returnsuggested) and $returnsuggested ne "noone")
 457 {
 458     print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=".$returnsuggested."#suggestions");
 459 }
 460
 461 $template->param(
 462     branchfilter => $branchfilter,
 463 );
 464
 465 $template->param( returnsuggestedby => $returnsuggestedby );
 466
 467 my $patron_reason_loop = GetAuthorisedValues("OPAC_SUG");
 468 $template->param(patron_reason_loop=>$patron_reason_loop);
 469
 470 # Budgets for filtering
 471 my $budgets = GetBudgets;
 472 my @budgets_loop;
 473 foreach my $budget ( @{$budgets} ) {
 474     next unless (CanUserUseBudget($borrowernumber, $budget, $userflags));
 475
 476     ## Please see file perltidy.ERR
 477     $budget->{'selected'} = 1
 478         if ($$suggestion_ref{'budgetid'}
 479         && $budget->{'budget_id'} eq $$suggestion_ref{'budgetid'});
 480
 481     push @budgets_loop, $budget;
 482 }
 483 $template->param( budgetsloop => \@budgets_loop);
 484
 485 # Budgets for suggestion add or edition
 486 my $sugg_budget_loop = [];
 487 my $sugg_budgets     = GetBudgetHierarchy();
 488 foreach my $r ( @{$sugg_budgets} ) {
 489     next unless ( CanUserUseBudget( $borrowernumber, $r, $userflags ) );
 490     my $selected = ( $$suggestion_ref{budgetid} && $r->{budget_id} eq $$suggestion_ref{budgetid} ) ? 1 : 0;
 491     push @{$sugg_budget_loop},
 492       {
 493         b_id     => $r->{budget_id},
 494         b_txt    => $r->{budget_name},
 495         b_active => $r->{budget_period_active},
 496         selected => $selected,
 497       };
 498 }
 499 @{$sugg_budget_loop} = sort { uc( $a->{b_txt} ) cmp uc( $b->{b_txt} ) } @{$sugg_budget_loop};
 500 $template->param( sugg_budgets => $sugg_budget_loop);
 501
 502 if( $suggestion_ref->{STATUS} ) {
 503     $template->param(
 504         "statusselected_".$suggestion_ref->{STATUS} => 1,
 505         selected_status => $suggestion_ref->{STATUS}, # We need template var selected_status in the second part of the template where template var suggestion.STATUS is out of scope
 506     );
 507 }
 508
 509 my $currencies = Koha::Acquisition::Currencies->search;
 510 $template->param(
 511     currencies   => $currencies,
 512     suggestion   => $suggestion_ref,
 513     price        => sprintf("%.2f", $$suggestion_ref{'price'}||0),
 514     total            => sprintf("%.2f", $$suggestion_ref{'total'}||0),
 515 );
 516
 517 # lists of distinct values (without empty) for filters
 518 my %hashlists;
 519 foreach my $field ( qw(managedby acceptedby suggestedby budgetid) ) {
 520     my $values_list;
 521     $values_list = GetDistinctValues( "suggestions." . $field );
 522     my @codes_list = map {
 523         {   'code' => $$_{'value'},
 524             'desc' => GetCriteriumDesc( $$_{'value'}, $field ) || $$_{'value'},
 525             'selected' => ($$suggestion_ref{$field}) ? $$_{'value'} eq $$suggestion_ref{$field} : 0,
 526         }
 527     } grep {
 528         $$_{'value'}
 529     } @$values_list;
 530     @codes_list = sort { $a->{desc} cmp $b->{desc} } @codes_list;
 531     $hashlists{ lc($field) . "_loop" } = \@codes_list;
 532 }
 533
 534 $template->param(
 535     %hashlists,
 536     borrowernumber     => ( $input->param('borrowernumber') // undef ),
 537     SuggestionStatuses => GetAuthorisedValues('SUGGEST_STATUS'),
 538 );
 539
 540 output_html_with_http_headers $input, $cookie, $template->output;
 541
 542 sub redirect_with_params {
 543     my ( $input ) = @_;
 544     my $params = '';
 545     foreach my $key (
 546         qw(
 547         displayby branchcode title author isbn publishercode copyrightdate
 548         collectiontitle suggestedby suggesteddate_from suggesteddate_to
 549         manageddate_from manageddate_to accepteddate_from
 550         accepteddate_to budgetid filter_archived
 551         )
 552       )
 553     {
 554         $params .= $key . '=' . uri_escape(scalar $input->param($key)) . '&'
 555           if defined($input->param($key));
 556     }
 557     print $input->redirect("/cgi-bin/koha/suggestion/suggestion.pl?$params");
 558 }