svc/checkouts

   1 #!/usr/bin/perl
   2
   3 # Copyright 2014 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI;
  23 use JSON qw(to_json);
  24
  25 use C4::Auth qw(check_cookie_auth haspermission get_session);
  26 use C4::Circulation qw(GetIssuingCharges CanBookBeRenewed GetRenewCount GetSoonestRenewDate);
  27 use C4::Overdues qw(GetFine);
  28 use C4::Context;
  29
  30 use Koha::AuthorisedValues;
  31 use Koha::DateUtils;
  32 use Koha::ItemTypes;
  33
  34 my $input = CGI->new;
  35
  36 my ( $auth_status, $sessionID ) = check_cookie_auth( $input->cookie('CGISESSID'));
  37 if( $auth_status ne 'ok' ) {
  38     print CGI::header( '-status' => '401' );
  39     exit 0;
  40 }
  41
  42 my $session   = get_session($sessionID);
  43 my $userid   = $session->param('id');
  44
  45 unless (haspermission($userid, { circulate => 'circulate_remaining_permissions' })
  46     || haspermission($userid, { borrowers => 'edit_borrowers' })) {
  47     exit 0;
  48 }
  49
  50 my @sort_columns = qw/date_due title itype issuedate branchcode itemcallnumber/;
  51
  52 my @borrowernumber   = $input->multi_param('borrowernumber');
  53 my $offset           = $input->param('iDisplayStart');
  54 my $results_per_page = $input->param('iDisplayLength') || -1;
  55
  56 my $sorting_column = $input->param('iSortCol_0') || q{};
  57 $sorting_column = ( $sorting_column && $sort_columns[$sorting_column] ) ? $sort_columns[$sorting_column] : 'issuedate';
  58
  59 my $sorting_direction = $input->param('sSortDir_0') || q{};
  60 $sorting_direction = $sorting_direction eq 'asc' ? 'asc' : 'desc';
  61
  62 $results_per_page = undef if ( $results_per_page == -1 );
  63
  64 binmode STDOUT, ":encoding(UTF-8)";
  65 print $input->header( -type => 'text/plain', -charset => 'UTF-8' );
  66
  67 my @parameters;
  68 my $sql = '
  69     SELECT
  70         issues.issuedate,
  71         issues.date_due,
  72         issues.date_due < now() as date_due_overdue,
  73         issues.timestamp,
  74
  75         issues.onsite_checkout,
  76
  77         biblio.biblionumber,
  78         biblio.title,
  79         biblio.subtitle,
  80         biblio.medium,
  81         biblio.part_number,
  82         biblio.part_name,
  83         biblio.author,
  84
  85         items.itemnumber,
  86         items.barcode,
  87         branches2.branchname AS homebranch,
  88         items.itemnotes,
  89         items.itemnotes_nonpublic,
  90         items.itemcallnumber,
  91         items.copynumber,
  92         items.replacementprice,
  93
  94         issues.branchcode,
  95         branches.branchname,
  96
  97         items.itype,
  98         biblioitems.itemtype,
  99
 100         items.ccode AS collection,
 101
 102         borrowers.borrowernumber,
 103         borrowers.surname,
 104         borrowers.firstname,
 105         borrowers.cardnumber,
 106
 107         items.itemlost,
 108         items.damaged,
 109         items.location,
 110         items.enumchron,
 111         items.materials,
 112
 113         DATEDIFF( issues.issuedate, CURRENT_DATE() ) AS not_issued_today,
 114
 115         return_claims.id AS return_claim_id,
 116         return_claims.notes AS return_claim_notes,
 117         return_claims.created_on AS return_claim_created_on,
 118         return_claims.updated_on AS return_claim_updated_on
 119
 120     FROM issues
 121         LEFT JOIN items USING ( itemnumber )
 122         LEFT JOIN biblio USING ( biblionumber )
 123         LEFT JOIN biblioitems USING ( biblionumber )
 124         LEFT JOIN borrowers USING ( borrowernumber )
 125         LEFT JOIN branches ON ( issues.branchcode = branches.branchcode )
 126         LEFT JOIN branches branches2 ON ( items.homebranch = branches2.branchcode )
 127         LEFT JOIN return_claims USING ( issue_id )
 128     WHERE issues.borrowernumber
 129 ';
 130
 131 if ( @borrowernumber == 1 ) {
 132     $sql .= '= ?';
 133 }
 134 else {
 135     $sql .= ' IN (' . join( ',', ('?') x @borrowernumber ) . ') ';
 136 }
 137 push( @parameters, @borrowernumber );
 138
 139 $sql .= " ORDER BY $sorting_column $sorting_direction ";
 140
 141 my $dbh = C4::Context->dbh();
 142 my $sth = $dbh->prepare($sql);
 143 $sth->execute(@parameters);
 144
 145 my $item_level_itypes = C4::Context->preference('item-level_itypes');
 146 my $claims_returned_lost_value = C4::Context->preference('ClaimReturnedLostValue');
 147 my $confirm_parts_required = C4::Context->preference("CircConfirmItemParts");
 148
 149 my $itemtypes = { map { $_->{itemtype} => $_->{translated_description} } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 150
 151 my @checkouts_today;
 152 my @checkouts_previous;
 153 while ( my $c = $sth->fetchrow_hashref() ) {
 154     my ($charge) = GetIssuingCharges( $c->{itemnumber}, $c->{borrowernumber} );
 155     my $fine = GetFine( $c->{itemnumber}, $c->{borrowernumber} );
 156
 157     my ( $can_renew, $can_renew_error ) =
 158       CanBookBeRenewed( $c->{borrowernumber}, $c->{itemnumber} );
 159     my $can_renew_date =
 160       $can_renew_error && $can_renew_error eq 'too_soon'
 161       ? output_pref(
 162         {
 163             dt => GetSoonestRenewDate( $c->{borrowernumber}, $c->{itemnumber} ),
 164             as_due_date => 1
 165         }
 166       )
 167       : undef;
 168
 169     my (
 170         $renewals_count,
 171         $renewals_allowed,
 172         $renewals_remaining,
 173         $unseen_count,
 174         $unseen_allowed,
 175         $unseen_remaining
 176     ) =
 177       GetRenewCount( $c->{borrowernumber}, $c->{itemnumber} );
 178
 179     my ( $itemtype, $recordtype, $type_for_stat );
 180     $itemtype      = $itemtypes->{ $c->{itype} }    if $c->{itype};
 181     $recordtype    = $itemtypes->{ $c->{itemtype} } if $c->{itemtype};
 182     $type_for_stat = $item_level_itypes ? $itemtype : $recordtype;
 183
 184     my $location;
 185     if ( $c->{location} ) {
 186         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 187             { kohafield => 'items.location', authorised_value => $c->{location} } );
 188         $location = $av->{lib} ? $av->{lib} : '';
 189     }
 190     my $collection;
 191     if ( $c->{collection} ) {
 192         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 193             { kohafield => 'items.ccode', authorised_value => $c->{collection} } );
 194         $collection = $av->{lib} ? $av->{lib} : '';
 195     }
 196     my $lost;
 197     my $claims_returned;
 198     if ( $c->{itemlost} ) {
 199         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 200             { kohafield => 'items.itemlost', authorised_value => $c->{itemlost} } );
 201         $lost            = $av->{lib} ? $av->{lib} : '';
 202         $claims_returned = $c->{itemlost} eq $claims_returned_lost_value;
 203     }
 204     my $damaged;
 205     if ( $c->{damaged} ) {
 206         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 207             { kohafield => 'items.damaged', authorised_value => $c->{damaged} } );
 208         $damaged = $av->{lib} ? $av->{lib} : '';
 209     }
 210     my $materials;
 211     if ( $c->{materials} && $confirm_parts_required ) {
 212         my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => '', kohafield =>'items.materials', authorised_value => $c->{materials} });
 213         $materials = $descriptions->{lib} // $c->{materials};
 214     }
 215     my @subtitles = split(/ \| /, $c->{'subtitle'} // '' );
 216     my $checkout = {
 217         DT_RowId             => $c->{itemnumber} . '-' . $c->{borrowernumber},
 218         title                => $c->{title},
 219         subtitle             => \@subtitles,
 220         medium               => $c->{medium} // '',
 221         part_number          => $c->{part_number} // '',
 222         part_name            => $c->{part_name} // '',
 223         author               => $c->{author},
 224         barcode              => $c->{barcode},
 225         type_for_stat          => $type_for_stat || q{},
 226         itemtype_description   => $itemtype || q{},
 227         recordtype_description => $recordtype || q{},
 228         collection           => $collection,
 229         location             => $location,
 230         homebranch           => $c->{homebranch},
 231         itemnotes            => $c->{itemnotes},
 232         itemnotes_nonpublic  => $c->{itemnotes_nonpublic},
 233         branchcode           => $c->{branchcode},
 234         branchname           => $c->{branchname},
 235         itemcallnumber       => $c->{itemcallnumber} || q{},
 236         copynumber           => $c->{copynumber} || q{},
 237         charge         => $charge,
 238         fine           => $fine,
 239         price          => $c->{replacementprice} || q{},
 240         can_renew      => $can_renew,
 241         can_renew_error     => $can_renew_error,
 242         can_renew_date      => $can_renew_date,
 243         itemnumber          => $c->{itemnumber},
 244         borrowernumber      => $c->{borrowernumber},
 245         biblionumber        => $c->{biblionumber},
 246         issuedate           => $c->{issuedate},
 247         date_due            => $c->{date_due},
 248         date_due_overdue    => $c->{date_due_overdue} ? JSON::true : JSON::false,
 249         timestamp           => $c->{timestamp},
 250         onsite_checkout     => $c->{onsite_checkout},
 251         enumchron           => $c->{enumchron},
 252         renewals_count      => $renewals_count,
 253         renewals_allowed    => $renewals_allowed || 0,
 254         renewals_remaining  => $renewals_remaining,
 255         unseen_count        => $unseen_count,
 256         unseen_allowed      => $unseen_allowed,
 257         unseen_remaining    => $unseen_remaining,
 258
 259         return_claim_id         => $c->{return_claim_id},
 260         return_claim_notes      => $c->{return_claim_notes},
 261         return_claim_created_on => $c->{return_claim_created_on},
 262         return_claim_updated_on => $c->{return_claim_updated_on},
 263         return_claim_created_on_formatted => $c->{return_claim_created_on} ? output_pref({ dt => dt_from_string( $c->{return_claim_created_on} ) }) : undef,
 264         return_claim_updated_on_formatted => $c->{return_claim_updated_on} ? output_pref({ dt => dt_from_string( $c->{return_claim_updated_on} ) }) : undef,
 265
 266         issuedate_formatted => output_pref(
 267             {
 268                 dt          => dt_from_string( $c->{issuedate} ),
 269                 as_due_date => 1
 270             }
 271         ),
 272         date_due_formatted => output_pref(
 273             {
 274                 dt          => dt_from_string( $c->{date_due} ),
 275                 as_due_date => 1
 276             }
 277         ),
 278         lost    => $lost,
 279         claims_returned => $claims_returned,
 280         damaged => $damaged,
 281         materials => $materials,
 282         borrower => {
 283             surname    => $c->{surname},
 284             firstname  => $c->{firstname},
 285             cardnumber => $c->{cardnumber},
 286         },
 287         issued_today => !$c->{not_issued_today},
 288     };
 289
 290     if ( $c->{not_issued_today} ) {
 291         push( @checkouts_previous, $checkout );
 292     }
 293     else {
 294         push( @checkouts_today, $checkout );
 295     }
 296 }
 297
 298
 299 @checkouts_today = sort { $a->{timestamp} cmp $b->{timestamp} } @checkouts_today;    # latest to earliest
 300 @checkouts_today = reverse(@checkouts_today)
 301   if ( C4::Context->preference('todaysIssuesDefaultSortOrder') eq 'desc' );      # earliest to latest
 302
 303 @checkouts_previous =
 304   sort { $a->{date_due} cmp $b->{date_due} || $a->{timestamp} cmp $b->{timestamp} }
 305   @checkouts_previous;                                                               # latest to earliest
 306 @checkouts_previous = reverse(@checkouts_previous)
 307   if ( C4::Context->preference('previousIssuesDefaultSortOrder') eq 'desc' );    # earliest to latest
 308
 309 my @checkouts = ( @checkouts_today, @checkouts_previous );
 310
 311 my $i = 1;
 312 map { $_->{sort_order} = $i++ } @checkouts;
 313
 314
 315 my $data;
 316 $data->{'iTotalRecords'}        = scalar @checkouts;
 317 $data->{'iTotalDisplayRecords'} = scalar @checkouts;
 318 $data->{'sEcho'}                = $input->param('sEcho') || undef;
 319 $data->{'aaData'}               = \@checkouts;
 320
 321 print to_json($data);